libiberty/configure.in

   1 dnl Process this file with autoconf to produce a configure script
   2
   3 AC_PREREQ(2.12.1)
   4 AC_INIT(pexecute.c)
   5
   6 dnl We use these options to decide which functions to include.
   7 AC_ARG_WITH(target-subdir,
   8 [  --with-target-subdir=SUBDIR      Configuring in a subdirectory])
   9 AC_ARG_WITH(cross-host,
  10 [  --with-cross-host=HOST           Configuring with a cross compiler])
  11 AC_ARG_WITH(newlib,
  12 [  --with-newlib                    Configuring with newlib])
  13
  14 if test "${srcdir}" = "."; then
  15   if test -z "${with_target_subdir}"; then
  16     libiberty_topdir="${srcdir}/.."
  17   else
  18     if test "${with_target_subdir}" != "."; then
  19       libiberty_topdir="${srcdir}/${with_multisrctop}../.."
  20     else
  21       libiberty_topdir="${srcdir}/${with_multisrctop}.."
  22     fi
  23   fi
  24 else
  25   libiberty_topdir="${srcdir}/.."
  26 fi
  27 AC_CONFIG_AUX_DIR($libiberty_topdir)
  28
  29 AC_CANONICAL_HOST
  30
  31 dnl When we start using automake:
  32 dnl AM_INIT_AUTOMAKE(libiberty, 1.0)
  33
  34 dnl These must be called before AM_PROG_LIBTOOL, because it may want
  35 dnl to call AC_CHECK_PROG.
  36 AC_CHECK_TOOL(AR, ar)
  37 AC_CHECK_TOOL(RANLIB, ranlib, :)
  38
  39 # FIXME: We temporarily define our own version of AC_PROG_CC.  This is
  40 # copied from autoconf 2.12, but does not call AC_PROG_CC_WORKS.  We
  41 # are probably using a cross compiler, which will not be able to fully
  42 # link an executable.  This should really be fixed in autoconf
  43 # itself.
  44
  45 AC_DEFUN(LIB_AC_PROG_CC,
  46 [AC_BEFORE([$0], [AC_PROG_CPP])dnl
  47 AC_PROVIDE([AC_PROG_CC])
  48 AC_CHECK_PROG(CC, gcc, gcc)
  49 if test -z "$CC"; then
  50   AC_CHECK_PROG(CC, cc, cc, , , /usr/ucb/cc)
  51   test -z "$CC" && AC_MSG_ERROR([no acceptable cc found in \$PATH])
  52 fi
  53
  54 AC_PROG_CC_GNU
  55
  56 if test $ac_cv_prog_gcc = yes; then
  57   GCC=yes
  58 dnl Check whether -g works, even if CFLAGS is set, in case the package
  59 dnl plays around with CFLAGS (such as to build both debugging and
  60 dnl normal versions of a library), tasteless as that idea is.
  61   ac_test_CFLAGS="${CFLAGS+set}"
  62   ac_save_CFLAGS="$CFLAGS"
  63   CFLAGS=
  64   AC_PROG_CC_G
  65   if test "$ac_test_CFLAGS" = set; then
  66     CFLAGS="$ac_save_CFLAGS"
  67   elif test $ac_cv_prog_cc_g = yes; then
  68     CFLAGS="-g -O2"
  69   else
  70     CFLAGS="-O2"
  71   fi
  72 else
  73   GCC=
  74   test "${CFLAGS+set}" = set || CFLAGS="-g"
  75 fi
  76 ])
  77
  78 LIB_AC_PROG_CC
  79
  80 AC_ISC_POSIX
  81
  82 dnl When we start using libtool:
  83 dnl Default to a non shared library.  This may be overridden by the
  84 dnl configure option --enable-shared.
  85 dnl AM_DISABLE_SHARED
  86
  87 dnl When we start using libtool:
  88 dnl AM_PROG_LIBTOOL
  89
  90 dnl When we start using automake:
  91 dnl AM_CONFIG_HEADER(config.h:config.in)
  92 AC_CONFIG_HEADER(config.h:config.in)
  93
  94 dnl When we start using automake:
  95 dnl AM_MAINTAINER_MODE
  96 dnl AC_EXEEXT
  97
  98 dnl When we start using automake:
  99 dnl AM_PROG_INSTALL
 100 AC_PROG_INSTALL
 101
 102 . ${srcdir}/config.table
 103 host_makefile_frag=${frag}
 104 AC_SUBST_FILE(host_makefile_frag)
 105
 106 # It's OK to check for header files.  Although the compiler may not be
 107 # able to link anything, it had better be able to at least compile
 108 # something.
 109 AC_CHECK_HEADERS(sys/file.h sys/param.h stdlib.h string.h unistd.h strings.h sys/time.h sys/resource.h)
 110 AC_HEADER_SYS_WAIT
 111
 112 # This is the list of functions which libiberty will provide if they
 113 # are not available on the host.
 114
 115 funcs="asprintf"
 116 funcs="$funcs atexit"
 117 funcs="$funcs basename"
 118 funcs="$funcs bcmp"
 119 funcs="$funcs bcopy"
 120 funcs="$funcs bzero"
 121 funcs="$funcs calloc"
 122 funcs="$funcs clock"
 123 funcs="$funcs getcwd"
 124 funcs="$funcs getpagesize"
 125 funcs="$funcs index"
 126 funcs="$funcs insque"
 127 funcs="$funcs memchr"
 128 funcs="$funcs memcmp"
 129 funcs="$funcs memcpy"
 130 funcs="$funcs memmove"
 131 funcs="$funcs memset"
 132 funcs="$funcs mkstemps"
 133 funcs="$funcs putenv"
 134 funcs="$funcs random"
 135 funcs="$funcs rename"
 136 funcs="$funcs rindex"
 137 funcs="$funcs setenv"
 138 funcs="$funcs sigsetmask"
 139 funcs="$funcs strcasecmp"
 140 funcs="$funcs strchr"
 141 funcs="$funcs strdup"
 142 funcs="$funcs strncasecmp"
 143 funcs="$funcs strrchr"
 144 funcs="$funcs strstr"
 145 funcs="$funcs strtod"
 146 funcs="$funcs strtol"
 147 funcs="$funcs strtoul"
 148 funcs="$funcs tmpnam"
 149 funcs="$funcs vasprintf"
 150 funcs="$funcs vfprintf"
 151 funcs="$funcs vprintf"
 152 funcs="$funcs vsprintf"
 153 funcs="$funcs waitpid"
 154
 155 # Also in the old function.def file: alloca, vfork, getopt.
 156
 157 vars="sys_errlist sys_nerr sys_siglist"
 158
 159 checkfuncs="getrusage on_exit psignal strerror strsignal sysconf times sbrk"
 160
 161 # These are neither executed nor required, but they help keep
 162 # autoheader happy without adding a bunch of text to acconfig.h.
 163 if test "x" = "y"; then
 164   AC_CHECK_FUNCS(asprintf atexit basename bcmp bcopy bzero calloc clock getcwd)
 165   AC_CHECK_FUNCS(getpagesize index insque mkstemps memchr memcmp memcpy memmove)
 166   AC_CHECK_FUNCS(memset putenv random rename rindex sigsetmask strcasecmp)
 167   AC_CHECK_FUNCS(setenv strchr strdup strncasecmp strrchr strstr strtod strtol)
 168   AC_CHECK_FUNCS(strtoul tmpnam vasprintf vfprintf vprintf vsprintf waitpid)
 169   AC_DEFINE(HAVE_SYS_ERRLIST)
 170   AC_DEFINE(HAVE_SYS_NERR)
 171   AC_DEFINE(HAVE_SYS_SIGLIST)
 172   AC_CHECK_FUNCS(getrusage on_exit psignal strerror strsignal sysconf times)
 173   AC_CHECK_FUNCS(sbrk)
 174 fi
 175
 176 # For each of these functions, if the host does not provide the
 177 # function we want to put FN.o in LIBOBJS, and if the host does
 178 # provide the function, we want to define HAVE_FN in config.h.  Also,
 179 # if the host does not provide alloca, we set ALLOCA to alloca.o
 180
 181 setobjs=
 182 CHECK=
 183 if test -n "${with_target_subdir}"; then
 184
 185   # We are being configured as a target library.  AC_REPLACE_FUNCS
 186   # may not work correctly, because the compiler may not be able to
 187   # link executables.  Note that we may still be being configured
 188   # native.
 189
 190   # If we are being configured for newlib, we know which functions
 191   # newlib provide and which ones we will be expected to provide.
 192
 193   if test "x${with_newlib}" = "xyes"; then
 194     ALLOCA="alloca.o"
 195     LIBOBJS="asprintf.o basename.o insque.o random.o strdup.o vasprintf.o"
 196
 197     for f in $funcs; do
 198       case "$f" in
 199         asprintf | basename | insque | random | strdup | vasprintf)
 200           ;;
 201         *)
 202           n=HAVE_`echo $f | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 203           AC_DEFINE_UNQUOTED($n)
 204           ;;
 205       esac
 206     done
 207
 208     # newlib doesnt provide any of the variables in $vars, so we
 209     # dont have to check them here.
 210
 211     # Of the functions in $checkfuncs, newlib only has strerror.
 212     AC_DEFINE(HAVE_STRERROR)
 213
 214     setobjs=yes
 215
 216   fi
 217
 218 else
 219
 220    # Not a target library, so we set things up to run the test suite.
 221    CHECK=check-cplus-dem
 222
 223 fi
 224
 225 AC_SUBST(CHECK)
 226
 227 if test -z "${setobjs}"; then
 228   case "${host}" in
 229
 230   *-*-vxworks*)
 231     # Handle VxWorks configuration specially, since on VxWorks the
 232     # libraries are actually on the target board, not in the file
 233     # system.
 234     LIBOBJS="basename.o getpagesize.o insque.o random.o strcasecmp.o"
 235     LIBOBJS="$LIBOBJS strncasecmp.o strdup.o vfork.o waitpid.o vasprintf.o"
 236     for f in $funcs; do
 237       case "$f" in
 238         basename | getpagesize | insque | random | strcasecmp)
 239           ;;
 240         strncasecmp | strdup | vfork | waitpid | vasprintf)
 241           ;;
 242         *)
 243           n=HAVE_`echo $f | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 244           AC_DEFINE_UNQUOTED($n)
 245           ;;
 246       esac
 247     done
 248
 249     # VxWorks doesn't provide any of the variables in $vars, so we
 250     # don't have to check them here.
 251
 252     # Of the functions in $checkfuncs, VxWorks only has strerror.
 253     AC_DEFINE(HAVE_STRERROR)
 254
 255     setobjs=yes
 256     ;;
 257
 258   esac
 259 fi
 260
 261 if test -z "${setobjs}"; then
 262
 263   case "${host}" in
 264
 265   *-*-cygwin*)
 266     # The Cygwin library actually uses a couple of files from
 267     # libiberty when it is built.  If we are building a native
 268     # Cygwin, and we run the tests, we will appear to have these
 269     # files.  However, when we go on to build winsup, we will wind up
 270     # with a library which does not have the files, since they should
 271     # have come from libiberty.
 272
 273     # We handle this by removing the functions the winsup library
 274     # provides from our shell variables, so that they appear to be
 275     # missing.
 276
 277     funcs="`echo $funcs | sed -e 's/random//'`"
 278     LIBOBJS="$LIBOBJS random.o"
 279     vars="`echo $vars | sed -e 's/sys_siglist//'`"
 280     checkfuncs="`echo $checkfuncs | sed -e 's/strsignal//' -e 's/psignal//'`"
 281     ;;
 282
 283   *-*-mingw32*)
 284     # Under mingw32, sys_nerr and sys_errlist exist, but they are
 285     # macros, so the test below won't find them.
 286     vars="`echo $vars | sed -e 's/sys_nerr//' -e 's/sys_errlist//'`"
 287     AC_DEFINE(HAVE_SYS_NERR)
 288     AC_DEFINE(HAVE_SYS_ERRLIST)
 289     ;;
 290
 291   *-*-uwin*)
 292     # Under some versions of uwin, vfork is notoriously buggy and the test
 293     # can hang configure; on other versions, vfork exists just as a stub.
 294     # FIXME: This should be removed once vfork in uwin's runtime is fixed.
 295     ac_cv_func_vfork_works=no
 296     ;;
 297
 298   esac
 299
 300   # We haven't set the list of objects yet.  Use the standard autoconf
 301   # tests.  This will only work if the compiler works.
 302   AC_PROG_CC_WORKS
 303   AC_REPLACE_FUNCS($funcs)
 304
 305   case "${host}" in
 306   *-*-interix)
 307     # On Interix, it wrongly concludes that the MSVC compiler supports alloca.
 308     # (MSVC does on Win32, not on Interix.)
 309     # This should be temporary.
 310
 311     ac_cv_header_alloca_h=no
 312     ac_cv_func_alloca_works=no
 313     ALLOCA=alloca.o
 314     cat >> confdefs.h <<\EOF
 315 #define C_ALLOCA 1
 316 EOF
 317     cat >> confdefs.h <<EOF
 318 #define STACK_DIRECTION -1
 319 EOF
 320     ;;
 321   *)
 322     AC_FUNC_ALLOCA
 323     ;;
 324   esac
 325
 326   AC_FUNC_VFORK
 327   if test $ac_cv_func_vfork_works = no; then
 328     LIBOBJS="$LIBOBJS vfork.o"
 329   fi
 330   for v in $vars; do
 331     AC_MSG_CHECKING([for $v])
 332     AC_CACHE_VAL(libiberty_cv_var_$v,
 333       [AC_TRY_LINK([int *p;], [extern int $v; p = &$v;],
 334                    [eval "libiberty_cv_var_$v=yes"],
 335                    [eval "libiberty_cv_var_$v=no"])])
 336     if eval "test \"`echo '$libiberty_cv_var_'$v`\" = yes"; then
 337       AC_MSG_RESULT(yes)
 338       n=HAVE_`echo $v | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 339       AC_DEFINE_UNQUOTED($n)
 340     else
 341       AC_MSG_RESULT(no)
 342     fi
 343   done
 344   AC_CHECK_FUNCS($checkfuncs)
 345 fi
 346
 347 # Install a library built with a cross compiler in $(tooldir) rather
 348 # than $(libdir).
 349 if test -z "${with_cross_host}"; then
 350   INSTALL_DEST=libdir
 351 else
 352   INSTALL_DEST=tooldir
 353 fi
 354 AC_SUBST(INSTALL_DEST)
 355
 356 # We need multilib support, but only if configuring for the target.
 357 AC_OUTPUT(Makefile testsuite/Makefile,
 358 [test -z "$CONFIG_HEADERS" || echo timestamp > stamp-h
 359 if test -n "$CONFIG_FILES"; then
 360   if test -n "${with_target_subdir}"; then
 361     # FIXME: We shouldn't need to set ac_file
 362     ac_file=Makefile
 363     . ${libiberty_topdir}/config-ml.in
 364   fi
 365 fi],
 366 srcdir=${srcdir}
 367 host=${host}
 368 target=${target}
 369 with_target_subdir=${with_target_subdir}
 370 with_multisubdir=${with_multisubdir}
 371 ac_configure_args="--enable-multilib ${ac_configure_args}"
 372 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
 373 libiberty_topdir=${libiberty_topdir}
 374 )