libiberty/configure.in

   1 dnl Process this file with autoconf to produce a configure script
   2
   3 AC_PREREQ(2.57)
   4 AC_INIT(xmalloc.c)
   5
   6 # This works around the fact that libtool configuration may change LD
   7 # for this particular configuration, but some shells, instead of
   8 # keeping the changes in LD private, export them just because LD is
   9 # exported.  We don't use libtool yet, but some day we might, so...
  10 ORIGINAL_LD_FOR_MULTILIBS=$LD
  11
  12 dnl We use these options to decide which functions to include.
  13 AC_ARG_WITH(target-subdir,
  14 [  --with-target-subdir=SUBDIR      Configuring in a subdirectory for target])
  15 AC_ARG_WITH(build-subdir,
  16 [  --with-build-subdir=SUBDIR       Configuring in a subdirectory for build])
  17 AC_ARG_WITH(cross-host,
  18 [  --with-cross-host=HOST           Configuring with a cross compiler])
  19 AC_ARG_WITH(newlib,
  20 [  --with-newlib                    Configuring with newlib])
  21
  22 if test "${srcdir}" = "."; then
  23   if test -n "${with_build_subdir}"; then
  24     libiberty_topdir="${srcdir}/../.."
  25     with_target_subdir=
  26   elif test -z "${with_target_subdir}"; then
  27     libiberty_topdir="${srcdir}/.."
  28   else
  29     if test "${with_target_subdir}" != "."; then
  30       libiberty_topdir="${srcdir}/${with_multisrctop}../.."
  31     else
  32       libiberty_topdir="${srcdir}/${with_multisrctop}.."
  33     fi
  34   fi
  35 else
  36   libiberty_topdir="${srcdir}/.."
  37 fi
  38 AC_SUBST(libiberty_topdir)
  39 AC_CONFIG_AUX_DIR($libiberty_topdir)
  40
  41 dnl Very limited version of automake's enable-maintainer-mode
  42
  43 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
  44   dnl maintainer-mode is disabled by default
  45   AC_ARG_ENABLE(maintainer-mode,
  46 [  --enable-maintainer-mode
  47                           enable make rules and dependencies not useful
  48                           (and sometimes confusing) to the casual installer],
  49       maintainer_mode=$enableval,
  50       maintainer_mode=no)
  51
  52 AC_MSG_RESULT($maintainer_mode)
  53
  54 if test "$maintainer_mode" = "yes"; then
  55   MAINT=''
  56   NOTMAINT='#'
  57 else
  58   MAINT='#'
  59   NOTMAINT=''
  60 fi
  61 AC_SUBST(MAINT)dnl
  62 AC_SUBST(NOTMAINT)dnl
  63
  64 # Do we have a single-tree copy of texinfo?  Even if we do, we can't
  65 # rely on it - libiberty is built before texinfo.
  66 AC_CHECK_PROG(MAKEINFO, makeinfo, makeinfo, )
  67 if test "x$MAKEINFO" = "x"; then
  68     MAKEINFO="@echo makeinfo missing; true"
  69     BUILD_INFO=
  70 else
  71     BUILD_INFO=info
  72     case x"`$MAKEINFO --version | grep 'GNU texinfo'`" in
  73       x*\ [[1-3]].* )
  74         MAKEINFO="@echo $MAKEINFO is too old, 4.0 or newer required; true"
  75         BUILD_INFO=
  76         AC_MSG_WARN([
  77 *** Makeinfo is too old. Info documentation will not be built.])
  78         ;;
  79     esac
  80 fi
  81 AC_SUBST(MAKEINFO)
  82 AC_SUBST(BUILD_INFO)
  83
  84 AC_CHECK_PROG(PERL, perl, perl, )
  85 if test x"$PERL" = x""; then
  86   HAVE_PERL='#'
  87 else
  88   HAVE_PERL=''
  89 fi
  90 AC_SUBST(HAVE_PERL)
  91
  92 AC_CANONICAL_HOST
  93
  94 dnl When we start using automake:
  95 dnl AM_INIT_AUTOMAKE(libiberty, 1.0)
  96
  97 dnl These must be called before AM_PROG_LIBTOOL, because it may want
  98 dnl to call AC_CHECK_PROG.
  99 AC_CHECK_TOOL(AR, ar)
 100 AC_CHECK_TOOL(RANLIB, ranlib, :)
 101
 102 GCC_NO_EXECUTABLES
 103 AC_PROG_CC
 104
 105 if test x$GCC = xyes; then
 106   ac_libiberty_warn_cflags='-W -Wall -Wtraditional -pedantic'
 107 fi
 108 AC_SUBST(ac_libiberty_warn_cflags)
 109
 110 AC_PROG_CC_C_O
 111 # autoconf is lame and doesn't give us any substitution variable for this.
 112 if eval "test \"`echo '$ac_cv_prog_cc_'${ac_cc}_c_o`\" = no"; then
 113   NO_MINUS_C_MINUS_O=yes
 114 else
 115   OUTPUT_OPTION='-o $@'
 116 fi
 117 AC_SUBST(NO_MINUS_C_MINUS_O)
 118 AC_SUBST(OUTPUT_OPTION)
 119
 120 AC_C_CONST
 121 AC_C_INLINE
 122 AC_C_BIGENDIAN_CROSS
 123
 124 dnl When we start using libtool:
 125 dnl Default to a non shared library.  This may be overridden by the
 126 dnl configure option --enable-shared.
 127 dnl AM_DISABLE_SHARED
 128
 129 dnl When we start using libtool:
 130 dnl AM_PROG_LIBTOOL
 131
 132 dnl When we start using automake:
 133 dnl AM_CONFIG_HEADER(config.h:config.in)
 134 AC_CONFIG_HEADER(config.h:config.in)
 135
 136 dnl When we start using automake:
 137 dnl AM_MAINTAINER_MODE
 138 dnl AC_EXEEXT
 139
 140 dnl When we start using automake:
 141 dnl AM_PROG_INSTALL
 142 AC_PROG_INSTALL
 143
 144 . ${srcdir}/config.table
 145 host_makefile_frag=${frag}
 146 AC_SUBST_FILE(host_makefile_frag)
 147
 148 # It's OK to check for header files.  Although the compiler may not be
 149 # able to link anything, it had better be able to at least compile
 150 # something.
 151 AC_CHECK_HEADERS(sys/file.h sys/param.h limits.h stdlib.h malloc.h string.h unistd.h strings.h sys/time.h time.h sys/resource.h sys/stat.h sys/mman.h fcntl.h alloca.h sys/pstat.h sys/sysmp.h sys/sysinfo.h machine/hal_sysinfo.h sys/table.h sys/sysctl.h sys/systemcfg.h)
 152 AC_HEADER_SYS_WAIT
 153 AC_HEADER_TIME
 154
 155 libiberty_AC_DECLARE_ERRNO
 156
 157 AC_CHECK_TYPE(uintptr_t, unsigned long)
 158 # Given the above check, we always have uintptr_t or a fallback
 159 # definition.  So define HAVE_UINTPTR_T in case any imported code
 160 # relies on it.
 161 AC_DEFINE(HAVE_UINTPTR_T, 1, [Define if you have the \`uintptr_t' type.])
 162
 163 AC_TYPE_PID_T
 164
 165 # This is the list of functions which libiberty will provide if they
 166 # are not available on the host.
 167
 168 funcs="asprintf"
 169 funcs="$funcs atexit"
 170 funcs="$funcs basename"
 171 funcs="$funcs bcmp"
 172 funcs="$funcs bcopy"
 173 funcs="$funcs bsearch"
 174 funcs="$funcs bzero"
 175 funcs="$funcs calloc"
 176 funcs="$funcs clock"
 177 funcs="$funcs ffs"
 178 funcs="$funcs getcwd"
 179 funcs="$funcs getpagesize"
 180 funcs="$funcs index"
 181 funcs="$funcs insque"
 182 funcs="$funcs memchr"
 183 funcs="$funcs memcmp"
 184 funcs="$funcs memcpy"
 185 funcs="$funcs memmove"
 186 funcs="$funcs mempcpy"
 187 funcs="$funcs memset"
 188 funcs="$funcs mkstemps"
 189 funcs="$funcs putenv"
 190 funcs="$funcs random"
 191 funcs="$funcs rename"
 192 funcs="$funcs rindex"
 193 funcs="$funcs setenv"
 194 funcs="$funcs snprintf"
 195 funcs="$funcs sigsetmask"
 196 funcs="$funcs stpcpy"
 197 funcs="$funcs stpncpy"
 198 funcs="$funcs strcasecmp"
 199 funcs="$funcs strchr"
 200 funcs="$funcs strdup"
 201 funcs="$funcs strncasecmp"
 202 funcs="$funcs strrchr"
 203 funcs="$funcs strstr"
 204 funcs="$funcs strtod"
 205 funcs="$funcs strtol"
 206 funcs="$funcs strtoul"
 207 funcs="$funcs tmpnam"
 208 funcs="$funcs vasprintf"
 209 funcs="$funcs vfprintf"
 210 funcs="$funcs vprintf"
 211 funcs="$funcs vsnprintf"
 212 funcs="$funcs vsprintf"
 213 funcs="$funcs waitpid"
 214
 215 # Also in the old function.def file: alloca, vfork, getopt.
 216
 217 vars="sys_errlist sys_nerr sys_siglist"
 218
 219 checkfuncs="getrusage on_exit psignal strerror strsignal sysconf times sbrk gettimeofday"
 220 checkfuncs="$checkfuncs realpath canonicalize_file_name pstat_getstatic pstat_getdynamic sysmp"
 221 checkfuncs="$checkfuncs getsysinfo table sysctl"
 222
 223 # These are neither executed nor required, but they help keep
 224 # autoheader happy without adding a bunch of text to acconfig.h.
 225 if test "x" = "y"; then
 226   AC_CHECK_FUNCS(asprintf atexit basename bcmp bcopy bsearch bzero calloc clock \
 227   getcwd getpagesize index insque mkstemps memchr memcmp memcpy \
 228   memmove mempcpy memset putenv random rename rindex sigsetmask \
 229   strcasecmp setenv stpcpy stpncpy strchr strdup strncasecmp strrchr strstr \
 230   strtod strtol strtoul tmpnam vasprintf vfprintf vprintf \
 231   vsprintf waitpid getrusage on_exit psignal strerror strsignal \
 232   sysconf times sbrk gettimeofday ffs snprintf vsnprintf \
 233   pstat_getstatic pstat_getdynamic sysmp getsysinfo table sysctl \
 234   realpath canonicalize_file_name)
 235   AC_DEFINE(HAVE_SYS_ERRLIST, 1, [Define if you have the sys_errlist variable.])
 236   AC_DEFINE(HAVE_SYS_NERR,    1, [Define if you have the sys_nerr variable.])
 237   AC_DEFINE(HAVE_SYS_SIGLIST, 1, [Define if you have the sys_siglist variable.])
 238 fi
 239
 240 # For each of these functions, if the host does not provide the
 241 # function we want to put FN.o in LIBOBJS, and if the host does
 242 # provide the function, we want to define HAVE_FN in config.h.
 243
 244 setobjs=
 245 CHECK=
 246 target_header_dir=
 247 if test -n "${with_target_subdir}"; then
 248
 249   # We are being configured as a target library.  AC_REPLACE_FUNCS
 250   # may not work correctly, because the compiler may not be able to
 251   # link executables.  Note that we may still be being configured
 252   # native.
 253
 254   # If we are being configured for newlib, we know which functions
 255   # newlib provide and which ones we will be expected to provide.
 256
 257   if test "x${with_newlib}" = "xyes"; then
 258     AC_LIBOBJ([asprintf])
 259     AC_LIBOBJ([basename])
 260     AC_LIBOBJ([insque])
 261     AC_LIBOBJ([random])
 262     AC_LIBOBJ([strdup])
 263     AC_LIBOBJ([vasprintf])
 264
 265     for f in $funcs; do
 266       case "$f" in
 267         asprintf | basename | insque | random | strdup | vasprintf)
 268           ;;
 269         *)
 270           n=HAVE_`echo $f | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 271           AC_DEFINE_UNQUOTED($n)
 272           ;;
 273       esac
 274     done
 275
 276     # newlib doesnt provide any of the variables in $vars, so we
 277     # dont have to check them here.
 278
 279     # Of the functions in $checkfuncs, newlib only has strerror.
 280     AC_DEFINE_NOAUTOHEADER(HAVE_STRERROR)
 281
 282     setobjs=yes
 283
 284   fi
 285
 286   # We may wish to install the target headers somewhere.
 287   AC_ARG_ENABLE(install-libiberty,
 288   [  --enable-install-libiberty       Install headers for end users],
 289   enable_install_libiberty=$enableval,
 290   enable_install_libiberty=no)dnl
 291
 292   # Option parsed, now set things appropriately.
 293   case x"$enable_install_libiberty" in
 294     xyes|x)
 295       target_header_dir=libiberty
 296       ;;
 297     xno)
 298       target_header_dir=
 299       ;;
 300     *)
 301       # This could be sanity-checked in various ways...
 302       target_header_dir="${enable_install_libiberty}"
 303       ;;
 304   esac
 305
 306
 307 else
 308
 309    # Not a target library, so we set things up to run the test suite.
 310    CHECK=check-cplus-dem
 311
 312 fi
 313
 314 AC_SUBST(CHECK)
 315 AC_SUBST(target_header_dir)
 316
 317 case "${host}" in
 318   *-*-cygwin* | *-*-mingw*)
 319     AC_DEFINE_NOAUTOHEADER(HAVE_SYS_ERRLIST)
 320     AC_DEFINE_NOAUTOHEADER(HAVE_SYS_NERR)
 321     ;;
 322 esac
 323
 324 if test -z "${setobjs}"; then
 325   case "${host}" in
 326
 327   *-*-vxworks*)
 328     # Handle VxWorks configuration specially, since on VxWorks the
 329     # libraries are actually on the target board, not in the file
 330     # system.
 331     AC_LIBOBJ([basename])
 332     AC_LIBOBJ([getpagesize])
 333     AC_LIBOBJ([insque])
 334     AC_LIBOBJ([random])
 335     AC_LIBOBJ([strcasecmp])
 336     AC_LIBOBJ([strncasecmp])
 337     AC_LIBOBJ([strdup])
 338     AC_LIBOBJ([vfork])
 339     AC_LIBOBJ([waitpid])
 340     AC_LIBOBJ([vasprintf])
 341     for f in $funcs; do
 342       case "$f" in
 343         basename | getpagesize | insque | random | strcasecmp)
 344           ;;
 345         strncasecmp | strdup | vfork | waitpid | vasprintf)
 346           ;;
 347         *)
 348           n=HAVE_`echo $f | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 349           AC_DEFINE_UNQUOTED($n)
 350           ;;
 351       esac
 352     done
 353
 354     # VxWorks doesn't provide any of the variables in $vars, so we
 355     # don't have to check them here.
 356
 357     # Of the functions in $checkfuncs, VxWorks only has strerror.
 358     AC_DEFINE_NOAUTOHEADER(HAVE_STRERROR)
 359
 360     setobjs=yes
 361     ;;
 362
 363   esac
 364 fi
 365
 366 if test -z "${setobjs}"; then
 367
 368   case "${host}" in
 369
 370   *-*-cygwin*)
 371     # The Cygwin library actually uses a couple of files from
 372     # libiberty when it is built.  If we are building a native
 373     # Cygwin, and we run the tests, we will appear to have these
 374     # files.  However, when we go on to build winsup, we will wind up
 375     # with a library which does not have the files, since they should
 376     # have come from libiberty.
 377
 378     # We handle this by removing the functions the winsup library
 379     # provides from our shell variables, so that they appear to be
 380     # missing.
 381
 382     # DJ - only if we're *building* cygwin, not just building *with* cygwin
 383
 384     if test -n "${with_target_subdir}"
 385     then
 386       funcs="`echo $funcs | sed -e 's/random//'`"
 387       AC_LIBOBJ([random])
 388       vars="`echo $vars | sed -e 's/sys_siglist//'`"
 389       checkfuncs="`echo $checkfuncs | sed -e 's/strsignal//' -e 's/psignal//'`"
 390     fi
 391     ;;
 392
 393   *-*-mingw32*)
 394     # Under mingw32, sys_nerr and sys_errlist exist, but they are
 395     # macros, so the test below won't find them.
 396     libiberty_cv_var_sys_nerr=yes
 397     libiberty_cv_var_sys_errlist=yes
 398     ;;
 399
 400   *-*-uwin*)
 401     # Under some versions of uwin, vfork is notoriously buggy and the test
 402     # can hang configure; on other versions, vfork exists just as a stub.
 403     # FIXME: This should be removed once vfork in uwin's runtime is fixed.
 404     ac_cv_func_vfork_works=no
 405     # Under uwin 2.0+, sys_nerr and sys_errlist exist, but they are
 406     # macros (actually, these are imported from a DLL, but the end effect
 407     # is the same), so the test below won't find them.
 408     libiberty_cv_var_sys_nerr=yes
 409     libiberty_cv_var_sys_errlist=yes
 410     ;;
 411
 412   *-*-*vms*)
 413     # Under VMS, vfork works very different than on Unix. The standard test
 414     # won't work, and it isn't easily adaptable. It makes more sense to
 415     # just force it.
 416     ac_cv_func_vfork_works=yes
 417     ;;
 418
 419   esac
 420
 421   # We haven't set the list of objects yet.  Use the standard autoconf
 422   # tests.  This will only work if the compiler works.
 423   AC_ISC_POSIX
 424   AC_REPLACE_FUNCS($funcs)
 425   libiberty_AC_FUNC_C_ALLOCA
 426   AC_FUNC_VFORK
 427   if test $ac_cv_func_vfork_works = no; then
 428     AC_LIBOBJ([vfork])
 429   fi
 430   # We only need _doprnt if we might use it to implement v*printf.
 431   if test $ac_cv_func_vprintf != yes \
 432      || test $ac_cv_func_vfprintf != yes \
 433      || test $ac_cv_func_vsprintf != yes; then
 434     AC_REPLACE_FUNCS(_doprnt)
 435   else
 436     AC_CHECK_FUNCS(_doprnt)
 437   fi
 438
 439   for v in $vars; do
 440     AC_MSG_CHECKING([for $v])
 441     AC_CACHE_VAL(libiberty_cv_var_$v,
 442       [AC_TRY_LINK([int *p;], [extern int $v []; p = $v;],
 443                    [eval "libiberty_cv_var_$v=yes"],
 444                    [eval "libiberty_cv_var_$v=no"])])
 445     if eval "test \"`echo '$libiberty_cv_var_'$v`\" = yes"; then
 446       AC_MSG_RESULT(yes)
 447       n=HAVE_`echo $v | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 448       AC_DEFINE_UNQUOTED($n)
 449     else
 450       AC_MSG_RESULT(no)
 451     fi
 452   done
 453
 454   # special check for _system_configuration because AIX <4.3.2 do not
 455   # contain the `physmem' member.
 456   AC_MSG_CHECKING([for external symbol _system_configuration])
 457   AC_TRY_COMPILE([#include <sys/systemcfg.h>],
 458                  [double x = _system_configuration.physmem;],
 459     [AC_MSG_RESULT([yes])
 460     AC_DEFINE(HAVE__SYSTEM_CONFIGURATION, 1,
 461               [Define if you have the _system_configuration variable.])],
 462     [AC_MSG_RESULT([no])])
 463
 464   AC_CHECK_FUNCS($checkfuncs)
 465   libiberty_NEED_DECLARATION(canonicalize_file_name)
 466 fi
 467
 468 # Figure out which version of pexecute to use.
 469 case "${host}" in
 470      *-*-mingw* | *-*-winnt*)   pexecute=pex-win32.o  ;;
 471      *-*-msdosdjgpp*)           pexecute=pex-djgpp.o  ;;
 472      *-*-msdos*)                pexecute=pex-msdos.o  ;;
 473      *-*-os2-emx*)              pexecute=pex-os2.o    ;;
 474      *)                         pexecute=pex-unix.o   ;;
 475 esac
 476 AC_SUBST(pexecute)
 477
 478 libiberty_AC_FUNC_STRNCMP
 479
 480 # Install a library built with a cross compiler in $(tooldir) rather
 481 # than $(libdir).
 482 if test -z "${with_cross_host}"; then
 483   INSTALL_DEST=libdir
 484 else
 485   INSTALL_DEST=tooldir
 486 fi
 487 AC_SUBST(INSTALL_DEST)
 488
 489 # We need multilib support, but only if configuring for the target.
 490 AC_OUTPUT(Makefile testsuite/Makefile,
 491 [test -z "$CONFIG_HEADERS" || echo timestamp > stamp-h
 492 if test -n "$CONFIG_FILES"; then
 493   if test -n "${with_build_subdir}" || test -n "${with_target_subdir}"; then
 494     # FIXME: We shouldn't need to set ac_file
 495     ac_file=Makefile
 496     LD="${ORIGINAL_LD_FOR_MULTILIBS}"
 497     . ${libiberty_topdir}/config-ml.in
 498   fi
 499 fi],
 500 srcdir=${srcdir}
 501 host=${host}
 502 target=${target}
 503 with_target_subdir=${with_target_subdir}
 504 with_build_subdir=${with_build_subdir}
 505 with_multisubdir=${with_multisubdir}
 506 ac_configure_args="--enable-multilib ${ac_configure_args}"
 507 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
 508 ORIGINAL_LD_FOR_MULTILIBS="${ORIGINAL_LD_FOR_MULTILIBS}"
 509 libiberty_topdir=${libiberty_topdir}
 510 )