OSDN Git Service

[PATCH] Report LTO phase in lto1 process name v2
[pf3gnuchains/gcc-fork.git] / libiberty / configure.ac
1 dnl Process this file with autoconf to produce a configure script
2
3 AC_PREREQ(2.64)
4 AC_INIT
5 AC_CONFIG_SRCDIR([xmalloc.c])
6
7 # This works around the fact that libtool configuration may change LD
8 # for this particular configuration, but some shells, instead of
9 # keeping the changes in LD private, export them just because LD is
10 # exported.  We don't use libtool yet, but some day we might, so...
11 ORIGINAL_LD_FOR_MULTILIBS=$LD
12
13 dnl We use these options to decide which functions to include.
14 AC_ARG_WITH(target-subdir,
15 [  --with-target-subdir=SUBDIR      Configuring in a subdirectory for target])
16 AC_ARG_WITH(build-subdir,
17 [  --with-build-subdir=SUBDIR       Configuring in a subdirectory for build])
18 AC_ARG_WITH(cross-host,
19 [  --with-cross-host=HOST           Configuring with a cross compiler])
20 AC_ARG_WITH(newlib,
21 [  --with-newlib                    Configuring with newlib])
22
23 if test "${srcdir}" = "."; then
24   if test -n "${with_build_subdir}"; then
25     libiberty_topdir="${srcdir}/../.."
26     with_target_subdir=
27   elif test -z "${with_target_subdir}"; then
28     libiberty_topdir="${srcdir}/.."
29   else
30     if test "${with_target_subdir}" != "."; then
31       libiberty_topdir="${srcdir}/${with_multisrctop}../.."
32     else
33       libiberty_topdir="${srcdir}/${with_multisrctop}.."
34     fi
35   fi
36 else
37   libiberty_topdir="${srcdir}/.."
38 fi
39 AC_SUBST(libiberty_topdir)
40 AC_CONFIG_AUX_DIR($libiberty_topdir)
41
42 dnl Very limited version of automake's enable-maintainer-mode
43
44 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
45   dnl maintainer-mode is disabled by default
46   AC_ARG_ENABLE(maintainer-mode,
47 [  --enable-maintainer-mode
48                           enable make rules and dependencies not useful
49                           (and sometimes confusing) to the casual installer],
50       maintainer_mode=$enableval,
51       maintainer_mode=no)
52
53 AC_MSG_RESULT($maintainer_mode)
54
55 if test "$maintainer_mode" = "yes"; then
56   MAINT=''
57   NOTMAINT='#'
58 else
59   MAINT='#'
60   NOTMAINT=''
61 fi
62 AC_SUBST(MAINT)dnl
63 AC_SUBST(NOTMAINT)dnl
64
65 # Do we have a single-tree copy of texinfo?  Even if we do, we can't
66 # rely on it - libiberty is built before texinfo.
67 AC_CHECK_PROG(MAKEINFO, makeinfo, makeinfo, )
68 if test "x$MAKEINFO" = "x"; then
69     MAKEINFO="@echo makeinfo missing; true"
70     BUILD_INFO=
71 else
72     BUILD_INFO=info
73     case "$MAKEINFO" in
74       */missing\ makeinfo*)
75         BUILD_INFO=
76         AC_MSG_WARN([
77 *** Makeinfo is missing. Info documentation will not be built.])
78         ;;
79       *)
80         case x"`$MAKEINFO --version | grep 'GNU texinfo'`" in
81           x*\ [[1-3]].* )
82             MAKEINFO="@echo $MAKEINFO is too old, 4.0 or newer required; true"
83             BUILD_INFO=
84             AC_MSG_WARN([
85 *** Makeinfo is too old. Info documentation will not be built.])
86           ;;
87         esac
88         ;;
89     esac
90 fi
91 AC_SUBST(MAKEINFO)
92 AC_SUBST(BUILD_INFO)
93
94 AC_CHECK_PROG(PERL, perl, perl, )
95 if test x"$PERL" = x""; then
96   HAVE_PERL='#'
97 else
98   HAVE_PERL=''
99 fi
100 AC_SUBST(HAVE_PERL)
101
102 AC_CANONICAL_HOST
103
104 dnl When we start using automake:
105 dnl AM_INIT_AUTOMAKE(libiberty, 1.0)
106
107 dnl These must be called before AM_PROG_LIBTOOL, because it may want
108 dnl to call AC_CHECK_PROG.
109 AC_CHECK_TOOL(AR, ar)
110 AC_CHECK_TOOL(RANLIB, ranlib, :)
111
112 dnl When switching to automake, replace the following with AM_ENABLE_MULTILIB.
113 # Add --enable-multilib to configure.
114 # Default to --enable-multilib
115 AC_ARG_ENABLE(multilib,
116 [  --enable-multilib       build many library versions (default)],
117 [case "$enableval" in
118   yes) multilib=yes ;;
119   no)  multilib=no ;;
120   *)   AC_MSG_ERROR([bad value $enableval for multilib option]) ;;
121  esac],
122               [multilib=yes])
123
124 # Even if the default multilib is not a cross compilation,
125 # it may be that some of the other multilibs are.
126 if test $cross_compiling = no && test $multilib = yes \
127    && test "x${with_multisubdir}" != x ; then
128    cross_compiling=maybe
129 fi
130
131 GCC_NO_EXECUTABLES
132 AC_PROG_CC
133 AC_SYS_LARGEFILE
134 AC_PROG_CPP_WERROR
135
136 ACX_PROG_CC_WARNING_OPTS([-W -Wall -Wwrite-strings -Wc++-compat \
137                           -Wstrict-prototypes], [ac_libiberty_warn_cflags])
138 ACX_PROG_CC_WARNING_ALMOST_PEDANTIC([], [ac_libiberty_warn_cflags])
139
140 AC_PROG_CC_C_O
141 # autoconf is lame and doesn't give us any substitution variable for this.
142 if eval "test \"`echo '$ac_cv_prog_cc_'${ac_cc}_c_o`\" = no"; then
143   NO_MINUS_C_MINUS_O=yes
144 else
145   OUTPUT_OPTION='-o $@'
146 fi
147 AC_SUBST(NO_MINUS_C_MINUS_O)
148 AC_SUBST(OUTPUT_OPTION)
149
150 AC_C_CONST
151 AC_C_INLINE
152 AC_C_BIGENDIAN
153
154 dnl When we start using libtool:
155 dnl Default to a non shared library.  This may be overridden by the
156 dnl configure option --enable-shared.
157 dnl AM_DISABLE_SHARED
158
159 dnl When we start using libtool:
160 dnl AM_PROG_LIBTOOL
161
162 dnl When we start using automake:
163 dnl AM_CONFIG_HEADER(config.h:config.in)
164 AC_CONFIG_HEADER(config.h:config.in)
165
166 dnl When we start using automake:
167 dnl AM_MAINTAINER_MODE
168 dnl AC_EXEEXT
169
170 dnl When we start using automake:
171 dnl AM_PROG_INSTALL
172 AC_PROG_INSTALL
173
174 # Don't build the shared library for build.
175 if [[ -n "${with_build_subdir}" ]]; then
176   enable_shared=no
177 fi
178
179 frag=
180 case "${host}" in
181   rs6000-ibm-aix3.1 | rs6000-ibm-aix)
182                         frag=mh-aix ;;
183   *-*-cxux7*)           frag=mh-cxux7 ;;
184   *-*-freebsd2.1.*)     frag=mh-fbsd21 ;;
185   *-*-freebsd2.2.[[012]])       frag=mh-fbsd21 ;;
186   i370-*-opened*)       frag=mh-openedition ;;
187   i[[34567]]86-*-windows*)      frag=mh-windows ;;
188 esac
189
190 if [[ -n "${frag}" ]]; then
191   frag=${libiberty_topdir}/libiberty/config/$frag
192 fi
193
194 # If they didn't specify --enable-shared, don't generate shared libs.
195 case "${enable_shared}" in
196   yes) shared=yes ;;
197   no) shared=no ;;
198   "") shared=no ;;
199   *) shared=yes ;;
200 esac
201 if [[ "${shared}" = "yes" ]]; then
202   case "${host}" in
203     *-*-cygwin*)        ;;
204     alpha*-*-linux*)    PICFLAG=-fPIC ;;
205     arm*-*-*)           PICFLAG=-fPIC ;;
206     hppa*-*-*)          PICFLAG=-fPIC ;;
207     i370-*-*)           PICFLAG=-fPIC ;;
208     ia64-*-*)           PICFLAG=-fpic ;;
209     i[[34567]]86-*-* | x86_64-*-*)
210                         PICFLAG=-fpic ;;
211     m68k-*-*)           PICFLAG=-fpic ;;
212     mips*-*-linux*)     PICFLAG=-fPIC ;;
213     powerpc*-*-aix*)    ;;
214     powerpc*-*-*)       PICFLAG=-fPIC ;;
215     sparc*-*-*)         case "${CFLAGS}" in
216                           *-fpic* ) PICFLAG=-fpic ;;
217                           * ) PICFLAG=-fPIC ;;
218                         esac ;;
219     s390*-*-*)          PICFLAG=-fpic ;;
220     sh*-*-*)            PICFLAG=-fPIC ;;
221   esac
222 fi
223 AC_SUBST(PICFLAG)
224
225 echo "# Warning: this fragment is automatically generated" > temp-frag
226
227 if [[ -n "${frag}" ]] && [[ -f "${frag}" ]]; then
228   echo "Appending ${frag} to xhost-mkfrag"
229   echo "# Following fragment copied from ${frag}" >> temp-frag
230   cat ${frag} >> temp-frag
231 fi
232
233 # record if we want to build shared libs.
234 if [[ "${shared}" = "yes" ]]; then
235   echo enable_shared = yes >> temp-frag
236 else
237   echo enable_shared = no >> temp-frag
238 fi
239
240 frag=xhost-mkfrag
241 ${CONFIG_SHELL-/bin/sh} ${libiberty_topdir}/move-if-change temp-frag xhost-mkfrag
242
243 host_makefile_frag=${frag}
244 AC_SUBST_FILE(host_makefile_frag)
245
246 # It's OK to check for header files.  Although the compiler may not be
247 # able to link anything, it had better be able to at least compile
248 # something.
249 AC_CHECK_HEADERS(sys/file.h sys/param.h limits.h stdlib.h malloc.h string.h unistd.h strings.h sys/time.h time.h sys/resource.h sys/stat.h sys/mman.h fcntl.h alloca.h sys/pstat.h sys/sysmp.h sys/sysinfo.h machine/hal_sysinfo.h sys/table.h sys/sysctl.h sys/systemcfg.h stdint.h stdio_ext.h)
250 AC_HEADER_SYS_WAIT
251 AC_HEADER_TIME
252
253 libiberty_AC_DECLARE_ERRNO
254
255 # Determine the size of an int for struct fibnode.
256 AC_CHECK_SIZEOF([int])
257
258 # Look for a 64-bit type.
259 AC_MSG_CHECKING([for a 64-bit type])
260 AC_CACHE_VAL(liberty_cv_uint64,
261 [AC_TRY_COMPILE(
262 [#ifdef HAVE_STDINT_H
263 #include <stdint.h>
264 #endif],
265 [extern uint64_t foo;],
266 liberty_cv_uint64=uint64_t,
267 [AC_TRY_COMPILE(
268 [#ifdef HAVE_LIMITS_H
269 #include <limits.h>
270 #endif
271 #ifndef CHAR_BIT
272 #define CHAR_BIT 8
273 #endif],
274 [extern char foo[sizeof(long) * CHAR_BIT >= 64 ? 1 : -1];],
275 liberty_cv_uint64="unsigned long",
276 [AC_TRY_COMPILE(
277 [#ifdef HAVE_LIMITS_H
278 #include <limits.h>
279 #endif
280 #ifndef CHAR_BIT
281 #define CHAR_BIT 8
282 #endif],
283 [extern char foo[sizeof(long long) * CHAR_BIT >= 64 ? 1 : -1];],
284 liberty_cv_uint64="unsigned long long", liberty_cv_uint64=none)])])])
285 AC_MSG_RESULT($liberty_cv_uint64)
286 if test "$liberty_cv_uint64" != none; then
287   AC_DEFINE_UNQUOTED(UNSIGNED_64BIT_TYPE, $liberty_cv_uint64,
288                      [Define to an unsigned 64-bit type available in the compiler.])
289 fi
290
291 AC_TYPE_INTPTR_T
292 AC_TYPE_UINTPTR_T
293
294 # Given the above check, we always have uintptr_t or a fallback
295 # definition.  So define HAVE_UINTPTR_T in case any imported code
296 # relies on it.
297 AC_DEFINE(HAVE_UINTPTR_T, 1, [Define if you have the \`uintptr_t' type.])
298
299 AC_TYPE_PID_T
300
301 # This is the list of functions which libiberty will provide if they
302 # are not available on the host.
303
304 funcs="asprintf"
305 funcs="$funcs atexit"
306 funcs="$funcs basename"
307 funcs="$funcs bcmp"
308 funcs="$funcs bcopy"
309 funcs="$funcs bsearch"
310 funcs="$funcs bzero"
311 funcs="$funcs calloc"
312 funcs="$funcs clock"
313 funcs="$funcs ffs"
314 funcs="$funcs getcwd"
315 funcs="$funcs getpagesize"
316 funcs="$funcs gettimeofday"
317 funcs="$funcs index"
318 funcs="$funcs insque"
319 funcs="$funcs memchr"
320 funcs="$funcs memcmp"
321 funcs="$funcs memcpy"
322 funcs="$funcs memmem"
323 funcs="$funcs memmove"
324 funcs="$funcs mempcpy"
325 funcs="$funcs memset"
326 funcs="$funcs mkstemps"
327 funcs="$funcs putenv"
328 funcs="$funcs random"
329 funcs="$funcs rename"
330 funcs="$funcs rindex"
331 funcs="$funcs setenv"
332 funcs="$funcs snprintf"
333 funcs="$funcs sigsetmask"
334 funcs="$funcs stpcpy"
335 funcs="$funcs stpncpy"
336 funcs="$funcs strcasecmp"
337 funcs="$funcs strchr"
338 funcs="$funcs strdup"
339 funcs="$funcs strncasecmp"
340 funcs="$funcs strndup"
341 funcs="$funcs strrchr"
342 funcs="$funcs strstr"
343 funcs="$funcs strtod"
344 funcs="$funcs strtol"
345 funcs="$funcs strtoul"
346 funcs="$funcs strverscmp"
347 funcs="$funcs tmpnam"
348 funcs="$funcs vasprintf"
349 funcs="$funcs vfprintf"
350 funcs="$funcs vprintf"
351 funcs="$funcs vsnprintf"
352 funcs="$funcs vsprintf"
353 funcs="$funcs waitpid"
354 funcs="$funcs setproctitle"
355
356 # Also in the old function.def file: alloca, vfork, getopt.
357
358 vars="sys_errlist sys_nerr sys_siglist"
359
360 checkfuncs="getrusage on_exit psignal strerror strsignal sysconf times sbrk gettimeofday"
361 checkfuncs="$checkfuncs realpath canonicalize_file_name pstat_getstatic pstat_getdynamic sysmp"
362 checkfuncs="$checkfuncs getsysinfo table sysctl wait3 wait4 __fsetlocking"
363
364 # These are neither executed nor required, but they help keep
365 # autoheader happy without adding a bunch of text to acconfig.h.
366 if test "x" = "y"; then
367   AC_CHECK_FUNCS(asprintf atexit \
368     basename bcmp bcopy bsearch bzero \
369     calloc canonicalize_file_name clock \
370     ffs __fsetlocking \
371     getcwd getpagesize getrusage getsysinfo gettimeofday \
372     index insque \
373     memchr memcmp memcpy memmem memmove memset mkstemps \
374     on_exit \
375     psignal pstat_getdynamic pstat_getstatic putenv \
376     random realpath rename rindex \
377     sbrk setenv setproctitle sigsetmask snprintf stpcpy stpncpy strcasecmp strchr \
378     strdup \
379      strerror strncasecmp strndup strrchr strsignal strstr strtod strtol \
380      strtoul strverscmp sysconf sysctl sysmp \
381     table times tmpnam \
382     vasprintf vfprintf vprintf vsprintf \
383     wait3 wait4 waitpid)
384   AC_CHECK_DECLS([basename(char *), ffs, asprintf, vasprintf, snprintf, vsnprintf])
385   AC_DEFINE(HAVE_SYS_ERRLIST, 1, [Define if you have the sys_errlist variable.])
386   AC_DEFINE(HAVE_SYS_NERR,    1, [Define if you have the sys_nerr variable.])
387   AC_DEFINE(HAVE_SYS_SIGLIST, 1, [Define if you have the sys_siglist variable.])
388 fi
389
390 # For each of these functions, if the host does not provide the
391 # function we want to put FN.o in LIBOBJS, and if the host does
392 # provide the function, we want to define HAVE_FN in config.h.
393
394 setobjs=
395 CHECK=
396 target_header_dir=
397 if test -n "${with_target_subdir}"; then
398
399   # We are being configured as a target library.  AC_REPLACE_FUNCS
400   # may not work correctly, because the compiler may not be able to
401   # link executables.  Note that we may still be being configured
402   # native.
403
404   # If we are being configured for newlib, we know which functions
405   # newlib provide and which ones we will be expected to provide.
406
407   if test "x${with_newlib}" = "xyes"; then
408     AC_LIBOBJ([asprintf])
409     AC_LIBOBJ([basename])
410     AC_LIBOBJ([insque])
411     AC_LIBOBJ([random])
412     AC_LIBOBJ([strdup])
413     AC_LIBOBJ([vasprintf])
414
415     for f in $funcs; do
416       case "$f" in
417         asprintf | basename | insque | random | strdup | vasprintf)
418           ;;
419         *)
420           n=HAVE_`echo $f | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
421           AC_DEFINE_UNQUOTED($n)
422           ;;
423       esac
424     done
425
426     # newlib doesnt provide any of the variables in $vars, so we
427     # dont have to check them here.
428
429     # Of the functions in $checkfuncs, newlib only has strerror.
430     AC_DEFINE(HAVE_STRERROR)
431
432     setobjs=yes
433
434   fi
435
436   # If we are being configured for Mingw, we know which functions
437   # Mingw provides and which ones we will be expected to provide.
438
439   case "${host}" in
440   *-*-mingw*)
441     AC_LIBOBJ([asprintf])
442     AC_LIBOBJ([basename])
443     AC_LIBOBJ([bcmp])
444     AC_LIBOBJ([bcopy])
445     AC_LIBOBJ([bzero])
446     AC_LIBOBJ([clock])
447     AC_LIBOBJ([ffs])
448     AC_LIBOBJ([getpagesize])
449     AC_LIBOBJ([index])
450     AC_LIBOBJ([insque])
451     AC_LIBOBJ([mempcpy])
452     AC_LIBOBJ([mkstemps])
453     AC_LIBOBJ([random])
454     AC_LIBOBJ([rindex])
455     AC_LIBOBJ([sigsetmask])
456     AC_LIBOBJ([stpcpy])
457     AC_LIBOBJ([stpncpy])
458     AC_LIBOBJ([strndup])
459     AC_LIBOBJ([strverscmp])
460     AC_LIBOBJ([vasprintf])
461     AC_LIBOBJ([waitpid])
462
463     for f in $funcs; do
464       case "$f" in
465         asprintf | basename | bcmp | bcopy | bzero | clock | ffs | getpagesize | index | insque | mempcpy | mkstemps | random | rindex | sigsetmask | stpcpy | stpncpy | strdup | strndup | strverscmp | vasprintf | waitpid)
466           ;;
467         *)
468           n=HAVE_`echo $f | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
469           AC_DEFINE_UNQUOTED($n)
470           ;;
471       esac
472     done
473
474     # Mingw doesnt provide any of the variables in $vars, so we
475     # dont have to check them here.
476
477     # Of the functions in $checkfuncs, Mingw only has strerror.
478     AC_DEFINE(HAVE_STRERROR)
479
480     setobjs=yes
481     ;;
482
483   *-*-msdosdjgpp)
484     AC_LIBOBJ([vasprintf])
485     AC_LIBOBJ([vsnprintf])
486     AC_LIBOBJ([snprintf])
487     AC_LIBOBJ([asprintf])
488
489     for f in atexit basename bcmp bcopy bsearch bzero calloc clock ffs \
490              getcwd getpagesize getrusage gettimeofday \
491              index insque memchr memcmp memcpy memmove memset psignal \
492              putenv random rename rindex sbrk setenv stpcpy strcasecmp \
493              strchr strdup strerror strncasecmp strrchr strstr strtod \
494              strtol strtoul sysconf times tmpnam vfprintf vprintf \
495              vsprintf waitpid
496     do
497       n=HAVE_`echo $f | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
498       AC_DEFINE_UNQUOTED($n)
499     done
500
501
502     setobjs=yes
503     ;;
504
505   esac
506
507   # We may wish to install the target headers somewhere.
508   AC_ARG_ENABLE(install-libiberty,
509   [  --enable-install-libiberty       Install headers for end users],
510   enable_install_libiberty=$enableval,
511   enable_install_libiberty=no)dnl
512   
513   # Option parsed, now set things appropriately.
514   case x"$enable_install_libiberty" in
515     xyes|x)
516       target_header_dir=libiberty
517       ;;
518     xno)   
519       target_header_dir=
520       ;;
521     *) 
522       # This could be sanity-checked in various ways...
523       target_header_dir="${enable_install_libiberty}"
524       ;;
525   esac
526
527
528 else
529
530    # Not a target library, so we set things up to run the test suite.
531    CHECK=really-check
532
533 fi
534
535 AC_SUBST(CHECK)
536 AC_SUBST(target_header_dir)
537
538 # check for prctl PR_SET_NAME
539 AC_RUN_IFELSE([AC_LANG_SOURCE([[
540 #include <sys/prctl.h>
541 int main()
542 {
543   return (prctl(PR_SET_NAME, "foo") == 0) ? 0 : 1;
544 }
545 ]])], AC_DEFINE(HAVE_PRCTL_SET_NAME, 1,
546         [Define if you have prctl PR_SET_NAME]))
547
548 case "${host}" in
549   *-*-cygwin* | *-*-mingw*)
550     AC_DEFINE(HAVE_SYS_ERRLIST)
551     AC_DEFINE(HAVE_SYS_NERR)
552     ;;
553 esac
554
555 if test -z "${setobjs}"; then
556   case "${host}" in
557
558   *-*-vxworks*)
559     # Handle VxWorks configuration specially, since on VxWorks the
560     # libraries are actually on the target board, not in the file
561     # system.
562     AC_LIBOBJ([basename])
563     AC_LIBOBJ([getpagesize])
564     AC_LIBOBJ([insque])
565     AC_LIBOBJ([random])
566     AC_LIBOBJ([strcasecmp])
567     AC_LIBOBJ([strncasecmp])
568     AC_LIBOBJ([strdup])
569     AC_LIBOBJ([vfork])
570     AC_LIBOBJ([waitpid])
571     AC_LIBOBJ([vasprintf])
572     for f in $funcs; do
573       case "$f" in
574         basename | getpagesize | insque | random | strcasecmp)
575           ;;
576         strncasecmp | strdup | vfork | waitpid | vasprintf)
577           ;;
578         *)
579           n=HAVE_`echo $f | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
580           AC_DEFINE_UNQUOTED($n)
581           ;;
582       esac
583     done
584
585     # VxWorks doesn't provide any of the variables in $vars, so we
586     # don't have to check them here.
587
588     # Of the functions in $checkfuncs, VxWorks only has strerror.
589     AC_DEFINE(HAVE_STRERROR)
590
591     setobjs=yes
592     ;;
593
594   esac
595 fi
596
597 if test -z "${setobjs}"; then
598
599   case "${host}" in
600
601   *-*-mingw32*)
602     # Under mingw32, sys_nerr and sys_errlist exist, but they are
603     # macros, so the test below won't find them.
604     libiberty_cv_var_sys_nerr=yes
605     libiberty_cv_var_sys_errlist=yes
606     ;;
607
608   *-*-msdosdjgpp*)
609     # vfork and fork are stubs.
610     ac_cv_func_vfork_works=no
611     ;;
612
613   *-*-uwin*)
614     # Under some versions of uwin, vfork is notoriously buggy and the test 
615     # can hang configure; on other versions, vfork exists just as a stub.
616     # FIXME: This should be removed once vfork in uwin's runtime is fixed.
617     ac_cv_func_vfork_works=no
618     # Under uwin 2.0+, sys_nerr and sys_errlist exist, but they are
619     # macros (actually, these are imported from a DLL, but the end effect 
620     # is the same), so the test below won't find them.
621     libiberty_cv_var_sys_nerr=yes
622     libiberty_cv_var_sys_errlist=yes
623     ;;
624
625   *-*-*vms*)
626     # Under VMS, vfork works very different than on Unix. The standard test 
627     # won't work, and it isn't easily adaptable. It makes more sense to
628     # just force it.
629     ac_cv_func_vfork_works=yes
630     ;;
631
632   esac
633
634   # We haven't set the list of objects yet.  Use the standard autoconf
635   # tests.  This will only work if the compiler works.
636   AC_ISC_POSIX
637   AC_REPLACE_FUNCS($funcs)
638   libiberty_AC_FUNC_C_ALLOCA
639   AC_FUNC_FORK
640   if test $ac_cv_func_vfork_works = no; then
641     AC_LIBOBJ([vfork])
642   fi
643   # We only need _doprnt if we might use it to implement v*printf.
644   if test $ac_cv_func_vprintf != yes \
645      || test $ac_cv_func_vfprintf != yes \
646      || test $ac_cv_func_vsprintf != yes; then
647     AC_REPLACE_FUNCS(_doprnt)
648   else
649     AC_CHECK_FUNCS(_doprnt)
650   fi
651
652   for v in $vars; do
653     AC_MSG_CHECKING([for $v])
654     AC_CACHE_VAL(libiberty_cv_var_$v,
655       [AC_LINK_IFELSE([AC_LANG_PROGRAM([[int *p;]],[[extern int $v []; p = $v;]])],
656                       [eval "libiberty_cv_var_$v=yes"],
657                       [eval "libiberty_cv_var_$v=no"])])
658     if eval "test \"`echo '$libiberty_cv_var_'$v`\" = yes"; then
659       AC_MSG_RESULT(yes)
660       n=HAVE_`echo $v | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
661       AC_DEFINE_UNQUOTED($n)
662     else
663       AC_MSG_RESULT(no)
664     fi
665   done
666
667   # special check for _system_configuration because AIX <4.3.2 do not
668   # contain the `physmem' member.
669   AC_MSG_CHECKING([for external symbol _system_configuration])
670   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/systemcfg.h>]],
671                         [[double x = _system_configuration.physmem;]])],
672     [AC_MSG_RESULT([yes])
673     AC_DEFINE(HAVE__SYSTEM_CONFIGURATION, 1,
674               [Define if you have the _system_configuration variable.])],
675     [AC_MSG_RESULT([no])])
676
677   AC_CHECK_FUNCS($checkfuncs)
678   AC_CHECK_DECLS([basename(char *), ffs, asprintf, vasprintf, snprintf, vsnprintf])
679   AC_CHECK_DECLS([calloc, getenv, getopt, malloc, realloc, sbrk])
680   AC_CHECK_DECLS([strverscmp])
681   libiberty_NEED_DECLARATION(canonicalize_file_name)
682 fi
683
684 # Figure out which version of pexecute to use.
685 case "${host}" in
686      *-*-mingw* | *-*-winnt*)   pexecute=pex-win32  ;;
687      *-*-msdosdjgpp*)           pexecute=pex-djgpp  ;;
688      *-*-msdos*)                pexecute=pex-msdos  ;;
689      *)                         pexecute=pex-unix   ;;
690 esac
691 AC_SUBST(pexecute)
692
693 libiberty_AC_FUNC_STRNCMP
694
695 # Install a library built with a cross compiler in $(tooldir) rather
696 # than $(libdir).
697 if test -z "${with_cross_host}"; then
698   INSTALL_DEST=libdir
699 else
700   INSTALL_DEST=tooldir
701 fi
702 AC_SUBST(INSTALL_DEST)
703
704 m4_pattern_allow(LIBOBJS)
705 L=""
706 for l in x $LIBOBJS; do
707   case $l in
708     x) ;;
709     *) L="$L ./$l" ;;
710   esac
711 done
712 LIBOBJS="$L"
713
714 dnl Required by html and install-html
715 AC_SUBST(datarootdir)
716 AC_SUBST(docdir)
717 AC_SUBST(htmldir)
718
719 # We need multilib support, but only if configuring for the target.
720 AC_CONFIG_FILES([Makefile testsuite/Makefile])
721 AC_CONFIG_COMMANDS([default],
722   [[test -z "$CONFIG_HEADERS" || echo timestamp > stamp-h
723 if test -n "$CONFIG_FILES"; then
724   if test -n "${with_target_subdir}"; then
725     # FIXME: We shouldn't need to set ac_file
726     ac_file=Makefile
727     LD="${ORIGINAL_LD_FOR_MULTILIBS}"
728     . ${libiberty_topdir}/config-ml.in
729   fi
730 fi]],
731 [[srcdir=${srcdir}
732 host=${host}
733 target=${target}
734 with_target_subdir=${with_target_subdir}
735 with_multisubdir=${with_multisubdir}
736 ac_configure_args="--enable-multilib ${ac_configure_args}"
737 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
738 ORIGINAL_LD_FOR_MULTILIBS="${ORIGINAL_LD_FOR_MULTILIBS}"
739 libiberty_topdir=${libiberty_topdir}
740 ]])
741 AC_OUTPUT