libgomp/configure.ac

   1 # Process this file with autoconf to produce a configure script, like so:
   2 # aclocal -I ../config && autoconf && autoheader && automake
   3
   4 AC_PREREQ(2.59)
   5 AC_INIT([GNU OpenMP Runtime Library], 1.0,,[libgomp])
   6 AC_CONFIG_HEADER(config.h)
   7
   8 # -------
   9 # Options
  10 # -------
  11
  12 AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
  13 LIBGOMP_ENABLE(version-specific-runtime-libs, no, ,
  14    [Specify that runtime libraries should be installed in a compiler-specific directory],
  15    permit yes|no)
  16 AC_MSG_RESULT($enable_version_specific_runtime_libs)
  17
  18 AC_MSG_CHECKING([for --enable-linux-futex])
  19 LIBGOMP_ENABLE(linux-futex, default, ,
  20   [Use the Linux futex system call],
  21   permit yes|no|default)
  22 AC_MSG_RESULT($enable_linux_futex)
  23
  24 # We would like our source tree to be readonly. However when releases or
  25 # pre-releases are generated, the flex/bison generated files as well as the
  26 # various formats of manuals need to be included along with the rest of the
  27 # sources.  Therefore we have --enable-generated-files-in-srcdir to do
  28 # just that.
  29 AC_MSG_CHECKING([for --enable-generated-files-in-srcdir])
  30 LIBGOMP_ENABLE(generated-files-in-srcdir, no, ,
  31    [put copies of generated files in source dir intended for creating source
  32     tarballs for users without texinfo bison or flex.],
  33    permit yes|no)
  34 AC_MSG_RESULT($enable_generated_files_in_srcdir)
  35 AM_CONDITIONAL(GENINSRC, test "$enable_generated_files_in_srcdir" = yes)
  36
  37
  38 # -------
  39 # -------
  40
  41 # Gets build, host, target, *_vendor, *_cpu, *_os, etc.
  42 #
  43 # You will slowly go insane if you do not grok the following fact:  when
  44 # building this library, the top-level /target/ becomes the library's /host/.
  45 #
  46 # configure then causes --target to default to --host, exactly like any
  47 # other package using autoconf.  Therefore, 'target' and 'host' will
  48 # always be the same.  This makes sense both for native and cross compilers
  49 # just think about it for a little while.  :-)
  50 #
  51 # Also, if this library is being configured as part of a cross compiler, the
  52 # top-level configure script will pass the "real" host as $with_cross_host.
  53 #
  54 # Do not delete or change the following two lines.  For why, see
  55 # http://gcc.gnu.org/ml/libstdc++/2003-07/msg00451.html
  56 AC_CANONICAL_SYSTEM
  57 target_alias=${target_alias-$host_alias}
  58
  59 # Sets up automake.  Must come after AC_CANONICAL_SYSTEM.  Each of the
  60 # following is magically included in AUTOMAKE_OPTIONS in each Makefile.am.
  61 #  1.9.0:  minimum required version
  62 #  no-define:  PACKAGE and VERSION will not be #define'd in config.h (a bunch
  63 #              of other PACKAGE_* variables will, however, and there's nothing
  64 #              we can do about that; they come from AC_INIT).
  65 #  foreign:  we don't follow the normal rules for GNU packages (no COPYING
  66 #            file in the top srcdir, etc, etc), so stop complaining.
  67 #  no-dependencies:  turns off auto dependency generation (just for now)
  68 #  -Wall:  turns on all automake warnings...
  69 #  -Wno-portability:  ...except this one, since GNU make is required.
  70 #  -Wno-override: ... and this one, since we do want this in testsuite.
  71 AM_INIT_AUTOMAKE([1.9.0 foreign -Wall -Wno-portability -Wno-override])
  72 AM_ENABLE_MULTILIB(, ..)
  73
  74 # Calculate toolexeclibdir
  75 # Also toolexecdir, though it's only used in toolexeclibdir
  76 case ${enable_version_specific_runtime_libs} in
  77   yes)
  78     # Need the gcc compiler version to know where to install libraries
  79     # and header files if --enable-version-specific-runtime-libs option
  80     # is selected.
  81     toolexecdir='$(libdir)/gcc/$(target_alias)'
  82     toolexeclibdir='$(toolexecdir)/$(gcc_version)$(MULTISUBDIR)'
  83     ;;
  84   no)
  85     if test -n "$with_cross_host" &&
  86        test x"$with_cross_host" != x"no"; then
  87       # Install a library built with a cross compiler in tooldir, not libdir.
  88       toolexecdir='$(exec_prefix)/$(target_alias)'
  89       toolexeclibdir='$(toolexecdir)/lib'
  90     else
  91       toolexecdir='$(libdir)/gcc-lib/$(target_alias)'
  92       toolexeclibdir='$(libdir)'
  93     fi
  94     multi_os_directory=`$CC -print-multi-os-directory`
  95     case $multi_os_directory in
  96       .) ;; # Avoid trailing /.
  97       *) toolexeclibdir=$toolexeclibdir/$multi_os_directory ;;
  98     esac
  99     ;;
 100 esac
 101 AC_SUBST(toolexecdir)
 102 AC_SUBST(toolexeclibdir)
 103
 104 # Check the compiler.
 105 # The same as in boehm-gc and libstdc++. Have to borrow it from there.
 106 # We must force CC to /not/ be precious variables; otherwise
 107 # the wrong, non-multilib-adjusted value will be used in multilibs.
 108 # As a side effect, we have to subst CFLAGS ourselves.
 109
 110 m4_rename([_AC_ARG_VAR_PRECIOUS],[real_PRECIOUS])
 111 m4_define([_AC_ARG_VAR_PRECIOUS],[])
 112 AC_PROG_CC
 113 m4_rename([real_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
 114
 115 AC_SUBST(CFLAGS)
 116
 117 # In order to override CFLAGS_FOR_TARGET, all of our special flags go
 118 # in XCFLAGS.  But we need them in CFLAGS during configury.  So put them
 119 # in both places for now and restore CFLAGS at the end of config.
 120 save_CFLAGS="$CFLAGS"
 121
 122 # Add -Wall -Werror if we are using GCC.
 123 if test "x$GCC" = "xyes"; then
 124   XCFLAGS="$XCFLAGS -Wall -Werror"
 125 fi
 126
 127 # Find other programs we need.
 128 AC_CHECK_TOOL(AR, ar)
 129 AC_CHECK_TOOL(RANLIB, ranlib, ranlib-not-found-in-path-error)
 130 AC_PATH_PROG(PERL, perl, perl-not-found-in-path-error)
 131 AC_PROG_MAKE_SET
 132 AC_PROG_INSTALL
 133
 134 # Configure libtool
 135 AM_PROG_LIBTOOL
 136 AC_SUBST(enable_shared)
 137 AC_SUBST(enable_static)
 138
 139 AM_MAINTAINER_MODE
 140
 141 # We need gfortran to compile parts of the library
 142 # We can't use AC_PROG_FC because it expects a fully working gfortran.
 143 #AC_PROG_FC(gfortran)
 144 FC="$GFORTRAN"
 145 AC_PROG_FC(gfortran)
 146 FCFLAGS="$FCFLAGS -Wall"
 147
 148 # For libtool versioning info, format is CURRENT:REVISION:AGE
 149 libtool_VERSION=1:0:0
 150 AC_SUBST(libtool_VERSION)
 151
 152 # Check header files.
 153 AC_STDC_HEADERS
 154 AC_HEADER_TIME
 155 AC_CHECK_HEADERS(unistd.h semaphore.h sys/loadavg.h sys/time.h)
 156
 157 GCC_HEADER_STDINT(gstdint.h)
 158
 159 # Check to see if -pthread or -lpthread is needed.  Prefer the former.
 160 # In case the pthread.h system header is not found, this test will fail.
 161 XPCFLAGS=""
 162
 163 # Darwin doesn't need the -pthread option since threads are in libSystem
 164 AC_LINK_IFELSE(
 165  [AC_LANG_PROGRAM(
 166   [#include <pthread.h>
 167    void *g(void *d) { return NULL; }],
 168   [pthread_t t; pthread_create(&t,NULL,g,NULL);])],
 169  [case $host in
 170    *-darwin*)
 171      ;;
 172    default)
 173      XPCFLAGS=" -Wc,-pthread"
 174      ;;
 175      esac],
 176  [CFLAGS="$save_CFLAGS" LIBS="-lpthread $LIBS"
 177   AC_LINK_IFELSE(
 178    [AC_LANG_PROGRAM(
 179     [#include <pthread.h>
 180      void *g(void *d) { return NULL; }],
 181     [pthread_t t; pthread_create(&t,NULL,g,NULL);])],
 182    [],
 183    [AC_MSG_ERROR([Pthreads are required to build libgomp])])])
 184
 185 # Check for functions needed.
 186 AC_CHECK_FUNCS(getloadavg clock_gettime)
 187
 188 # Check for broken semaphore implementation on darwin.
 189 # sem_init returns: sem_init error: Function not implemented.
 190 case "$host" in
 191   *-darwin*)
 192     AC_DEFINE(HAVE_BROKEN_POSIX_SEMAPHORES, 1,
 193         Define if the POSIX Semaphores do not work on your system.)
 194     ;;
 195   *-linux*)
 196     case "$enable_linux_futex" in
 197       default)
 198         # If headers don't have gettid/futex syscalls definition, then
 199         # default to no, otherwise there will be compile time failures.
 200         # Otherwise, default to yes.  If we don't detect we are
 201         # compiled/linked against NPTL and not cross-compiling, check
 202         # if programs are run by default against NPTL and if not, issue
 203         # a warning.
 204         enable_linux_futex=no
 205         AC_LINK_IFELSE(
 206          [AC_LANG_PROGRAM(
 207           [#include <sys/syscall.h>
 208            int lk;],
 209           [syscall (SYS_gettid); syscall (SYS_futex, &lk, 0, 0, 0);])],
 210           [AC_LINK_IFELSE(
 211            [AC_LANG_PROGRAM(
 212             [#ifndef _GNU_SOURCE
 213              #define _GNU_SOURCE 1
 214              #endif
 215              #include <pthread.h>
 216              pthread_t th; void *status;],
 217             [pthread_tryjoin_np (th, &status);])],[enable_linux_futex=yes],
 218             [if test x$cross_compiling = xno; then
 219                if getconf GNU_LIBPTHREAD_VERSION 2>/dev/null \
 220                   | LC_ALL=C grep -i NPTL > /dev/null 2>/dev/null; then
 221                  AC_MSG_WARN([The kernel might not support futex or gettid syscalls.
 222 If so, please configure with --disable-linux-futex])
 223                fi
 224              fi
 225              enable_linux_futex=yes])])
 226         ;;
 227       yes)
 228         AC_LINK_IFELSE(
 229          [AC_LANG_PROGRAM(
 230           [#include <sys/syscall.h>
 231            int lk;],
 232           [syscall (SYS_gettid); syscall (SYS_futex, &lk, 0, 0, 0);])],[],
 233           [AC_MSG_ERROR([SYS_gettid and SYS_futex required for --enable-linux-futex])])
 234         ;;
 235     esac
 236     ;;
 237 esac
 238
 239 # At least for glibc, clock_gettime is in librt.  But don't pull that
 240 # in if it still doesn't give us the function we want.
 241 if test $ac_cv_func_clock_gettime = no; then
 242   AC_CHECK_LIB(rt, clock_gettime,
 243     [LIBS="-lrt $LIBS"
 244      AC_DEFINE(HAVE_CLOCK_GETTIME, 1,
 245                [Define to 1 if you have the `clock_gettime' function.])])
 246 fi
 247
 248 # See if we support thread-local storage.
 249 GCC_CHECK_TLS
 250
 251 # See what sort of export controls are availible.
 252 LIBGOMP_CHECK_ATTRIBUTE_VISIBILITY
 253 LIBGOMP_CHECK_ATTRIBUTE_DLLEXPORT
 254 LIBGOMP_CHECK_ATTRIBUTE_ALIAS
 255 LIBGOMP_ENABLE_SYMVERS
 256
 257 # Get target configury.
 258 . ${srcdir}/configure.tgt
 259 CFLAGS="$save_CFLAGS $XCFLAGS"
 260
 261 # Check for __sync_val_compare_and_swap, but only after the target has
 262 # had a chance to set XCFLAGS.
 263 LIBGOMP_CHECK_SYNC_BUILTINS
 264
 265 XCFLAGS="$XCFLAGS$XPCFLAGS"
 266
 267 AC_SUBST(config_path)
 268 AC_SUBST(XCFLAGS)
 269 AC_SUBST(XLDFLAGS)
 270
 271 # Cleanup and exit.
 272 CFLAGS="$save_CFLAGS"
 273 AC_CACHE_SAVE
 274
 275 if test ${multilib} = yes; then
 276   multilib_arg="--enable-multilib"
 277 else
 278   multilib_arg=
 279 fi
 280
 281 # Set up the set of libraries that we need to link against for libgomp.
 282 # Note that the GOMP_SELF_SPEC in gcc.c will force -pthread for -fopenmp,
 283 # which will force linkage against -lpthread (or equivalent for the system).
 284 # That's not 100% ideal, but about the best we can do easily.
 285 if test $enable_shared = yes; then
 286   link_gomp="-lgomp %{static: $LIBS}"
 287 else
 288   link_gomp="-lgomp $LIBS"
 289 fi
 290 AC_SUBST(link_gomp)
 291
 292 AM_CONDITIONAL([USE_FORTRAN], [test "$ac_cv_fc_compiler_gnu" = yes])
 293
 294 # ??? 2006-01-24: Paulo committed to asking autoconf folk to document
 295 # and export AC_COMPUTE_INT.  If that happens, then we'll need to remove
 296 # the underscore here and update the PREREQ.  If it doesn't, then we'll
 297 # need to copy this macro to our acinclude.m4.
 298 save_CFLAGS="$CFLAGS"
 299 for i in $config_path; do
 300   if test -f $srcdir/config/$i/omp-lock.h; then
 301     CFLAGS="$CFLAGS -include $srcdir/config/$i/omp-lock.h"
 302     break
 303   fi
 304 done
 305
 306 _AC_COMPUTE_INT([sizeof (omp_lock_t)], [OMP_LOCK_SIZE],,
 307   [AC_MSG_ERROR([unsupported system, cannot find sizeof (omp_lock_t)])])
 308 _AC_COMPUTE_INT([__alignof (omp_lock_t)], [OMP_LOCK_ALIGN])
 309 _AC_COMPUTE_INT([sizeof (omp_nest_lock_t)], [OMP_NEST_LOCK_SIZE])
 310 _AC_COMPUTE_INT([__alignof (omp_nest_lock_t)], [OMP_NEST_LOCK_ALIGN])
 311
 312 # If the lock fits in an integer, then arrange for Fortran to use that
 313 # integer.  If it doesn't, then arrange for Fortran to use a pointer.
 314 # Except that we don't have a way at present to multi-lib the installed
 315 # Fortran modules, so we assume 8 bytes for pointers, regardless of the
 316 # actual target.
 317 OMP_LOCK_KIND=$OMP_LOCK_SIZE
 318 OMP_NEST_LOCK_KIND=$OMP_NEST_LOCK_SIZE
 319 if test $OMP_LOCK_SIZE -gt 8 || test $OMP_LOCK_ALIGN -gt $OMP_LOCK_SIZE; then
 320   OMP_LOCK_KIND=8
 321 fi
 322 if test $OMP_NEST_LOCK_SIZE -gt 8 || test $OMP_NEST_LOCK_ALIGN -gt $OMP_NEST_LOCK_SIZE; then
 323   OMP_NEST_LOCK_KIND=8
 324 fi
 325
 326 AC_SUBST(OMP_LOCK_SIZE)
 327 AC_SUBST(OMP_LOCK_ALIGN)
 328 AC_SUBST(OMP_NEST_LOCK_SIZE)
 329 AC_SUBST(OMP_NEST_LOCK_ALIGN)
 330 AC_SUBST(OMP_LOCK_KIND)
 331 AC_SUBST(OMP_NEST_LOCK_KIND)
 332 CFLAGS="$save_CFLAGS"
 333
 334 AC_CONFIG_FILES(omp.h omp_lib.h omp_lib.f90 libgomp_f.h)
 335 AC_CONFIG_FILES(Makefile testsuite/Makefile libgomp.spec)
 336 AC_OUTPUT