OSDN Git Service

syscall: Remove a couple more 3-parameter match's in mksyscall.awk.
[pf3gnuchains/gcc-fork.git] / libgo / go / syscall / mksyscall.awk
1 # Copyright 2011 The Go Authors. All rights reserved.
2 # Use of this source code is governed by a BSD-style
3 # license that can be found in the LICENSE file.
4
5 # This AWK script reads a Go file with comments describing syscall
6 # functions and the C routines they map to.  It generates the Go code
7 # which calls the C routines.
8
9 # The syscall functins are marked by lines beginning with "//sys" and
10 # read like func declarations if //sys is replaced by func, but:
11 #       * The parameter lists must give a name for each argument.
12 #         This includes return parameters.
13 #       * The parameter lists must give a type for each argument:
14 #          the (x, y, z int) shorthand is not allowed.
15 #       * If the return parameter is an error number, it must be named errno.
16
17 # A line beginning with //sysnb is like //sys, except that the
18 # goroutine will not be suspended during the execution of the library
19 # call.  This must only be used for library calls which can never
20 # block, as otherwise the library call could cause all goroutines to
21 # hang.
22
23 # After the //sys or //sysnb line comes a second line which describes
24 # the C function.  The name must be the name of the function in the C
25 # library, and may be the same as the Go function.  The limitations on
26 # the argument list are the same as for the //sys line, but there must
27 # be at most one result parameter, and it must be given as just a
28 # type, without a name.
29
30 BEGIN {
31     print "// This file was automatically generated by mksyscall.awk"
32     print ""
33     print "package syscall"
34     print ""
35     print "import \"unsafe\""
36     print ""
37     status = 0
38 }
39
40 /^\/\/sys/ {
41     if ($1 == "//sysnb") {
42         blocking = 0
43     } else {
44         blocking = 1
45     }
46
47     line = $0
48
49     if (match(line, "//sys(nb)?[        ]*[a-zA-Z0-9_]+\\([^()]*\\) *(\\(([^()]+)\\))?") == 0) {
50         print "unmatched line:", $0 | "cat 1>&2"
51         status = 1
52         next
53     }
54
55     # Sets a[1] = //sysnb, a[2] == function name.
56     split(line, a, "[   (]*")
57     gofnname = a[2]
58
59     off = match(line, "\\([^()]*\\)")
60     end = index(substr(line, off, length(line) - off + 1), ")")
61     gofnparams = substr(line, off + 1, end - 2)
62
63     line = substr(line, off + end, length(line) - (off + end) + 1)
64     off = match(line, "\\([^()]*\\)")
65     if (off == 0) {
66         gofnresults = ""
67     } else {
68         end = index(substr(line, off, length(line) - off + 1), ")")
69         gofnresults = substr(line, off + 1, end - 2)
70     }
71
72     getline
73     line = $0
74
75     if (match(line, "//[a-zA-Z0-9_]+\\([^()]*\\)") == 0) {
76         print "unmatched C line", $0, "after", gofnname | "cat 1>&2"
77         status = 1
78         next
79     }
80
81     split(line, a, "[   (]*")
82     cfnname = substr(a[1], 3, length(a[1]) - 2)
83
84     off = match(line, "\\([^()]*\\)")
85     end = index(substr(line, off, length(line) - off + 1), ")")
86     cfnparams = substr(line, off + 1, end - 2)
87
88     line = substr(line, off + end + 1, length(line) - (off + end) + 1)
89     while (substr(line, 1, 1) == " ") {
90         line = substr(line, 2, length(line) - 1)
91     }
92     end = index(line, " ")
93     if (end != 0) {
94         line = substr(line, 1, end)
95     }
96     cfnresult = line
97
98     printf("// Automatically generated wrapper for %s/%s\n", gofnname, cfnname)
99     printf("func c_%s(%s) %s%s__asm__(\"%s\")\n",
100            cfnname, cfnparams, cfnresult, cfnresult == "" ? "" : " ", cfnname)
101     printf("func %s(%s) %s%s%s%s{\n",
102            gofnname, gofnparams, gofnresults == "" ? "" : "(", gofnresults,
103            gofnresults == "" ? "" : ")", gofnresults == "" ? "" : " ")
104
105     if (blocking) {
106         print "\tentersyscall()"
107     }
108
109     loc = gofnname "/" cfnname ":"
110
111     split(gofnparams, goargs, ", *")
112     split(cfnparams, cargs, ", *")
113     args = ""
114     carg = 1
115     for (goarg = 1; goargs[goarg] != ""; goarg++) {
116         if (cargs[carg] == "") {
117             print loc, "not enough C parameters"
118         }
119
120         if (args != "") {
121             args = args ", "
122         }
123
124         if (split(goargs[goarg], a) != 2) {
125             print loc, "bad parameter:", goargs[goarg] | "cat 1>&2"
126             status = 1
127             next
128         }
129
130         goname = a[1]
131         gotype = a[2]
132
133         if (split(cargs[carg], a) != 2) {
134             print loc, "bad C parameter:", cargs[carg] | "cat 1>&2"
135             status = 1
136             next
137         }
138
139         ctype = a[2]
140
141         if (gotype ~ /^\*/) {
142             if (gotype != ctype) {
143                 print loc, "Go/C pointer type mismatch:", gotype, ctype | "cat 1>&2"
144                 status = 1
145                 next
146             }
147             args = args goname
148         } else if (gotype == "string") {
149             if (ctype != "*byte") {
150                 print loc, "Go string not matched to C *byte:", gotype, ctype | "cat 1>&2"
151                 status = 1
152                 next
153             }
154             args = args "StringBytePtr(" goname ")"
155         } else if (gotype ~ /^\[\](.*)/) {
156             if (ctype !~ /^\*/ || cargs[carg + 1] == "") {
157                 print loc, "bad C type for slice:", gotype, ctype | "cat 1>&2"
158                 status = 1
159                 next
160             }
161
162             # Convert a slice into a pair of pointer, length.
163             # Don't try to take the address of the zeroth element of a
164             # nil slice.
165             printf("\tvar _p%d %s\n", goarg, ctype)
166             printf("\tif len(%s) > 0 {\n", goname)
167             printf("\t\t_p%d = (%s)(unsafe.Pointer(&%s[0]))\n", goarg, ctype, goname)
168             printf("\t} else {\n")
169             printf("\t\t_p%d = (%s)(unsafe.Pointer(&_zero))\n", goarg, ctype)
170             printf("\t}\n")
171
172             ++carg
173             if (split(cargs[carg], cparam) != 2) {
174                 print loc, "bad C parameter:", cargs[carg] | "cat 1>&2"
175                 status = 1
176                 next
177             }
178
179             args = sprintf("%s_p%d, %s(len(%s))", args, goarg, cparam[2], goname)
180         } else if (gotype == "uintptr" && ctype ~ /^\*/) {
181             args = sprintf("%s(%s)(unsafe.Pointer(%s))", args, ctype, goname)
182         } else {
183             args = sprintf("%s%s(%s)", args, ctype, goname)
184         }
185
186         carg++
187     }
188
189     if (cargs[carg] != "") {
190         print loc, "too many C parameters" | "cat 1>&2"
191         status = 1
192         next
193     }
194
195     printf("\t")
196     if (gofnresults != "") {
197         printf("_r := ")
198     }
199     printf("c_%s(%s)\n", cfnname, args)
200
201     if (gofnresults != "") {
202         fields = split(gofnresults, goresults, ", *")
203         if (fields > 2) {
204             print loc, "too many Go results" | "cat 1>&2"
205             status = 1
206             next
207         }
208         usedr = 0
209         for (goresult = 1; goresults[goresult] != ""; goresult++) {
210             if (split(goresults[goresult], goparam) != 2) {
211                 print loc, "bad result:", goresults[goresult] | "cat 1>&2"
212                 status = 1
213                 next
214             }
215
216             goname = goparam[1]
217             gotype = goparam[2]
218
219             if (goname == "errno") {
220                 if (cfnresult ~ /^\*/) {
221                     print "\tif _r == nil {"
222                 } else {
223                     print "\tif _r < 0 {"
224                 }
225                 print "\t\terrno = GetErrno()"
226                 print "\t}"
227             } else if (gotype == "uintptr" && cfnresult ~ /^\*/) {
228                 printf("\t%s = (%s)(unsafe.Pointer(_r))\n", goname, gotype)
229             } else {
230                 if (usedr) {
231                     print loc, "two parameters but no errno parameter" | "cat 1>&2"
232                     status = 1
233                     next
234                 }
235                 printf("\t%s = (%s)(_r)\n", goname, gotype)
236                 usedr = 1
237             }
238         }
239     }
240
241     if (blocking) {
242         print "\texitsyscall()"
243     }
244
245     if (gofnresults != "") {
246         print "\treturn"
247     }
248
249     print "}"
250
251     print ""
252
253     next
254 }
255
256 { next }
257
258 END {
259     if (status != 0) {
260         print "*** mksyscall.awk failed" | "cat 1>&2"
261         exit status
262     }
263 }