OSDN Git Service

Simplify libgo Makefile conditionals.
[pf3gnuchains/gcc-fork.git] / libgo / configure.ac
1 # configure.ac -- Go library configure script.
2
3 # Copyright 2009 The Go Authors. All rights reserved.
4 # Use of this source code is governed by a BSD-style
5 # license that can be found in the LICENSE file.
6
7 # Process this file with autoreconf to produce configure.
8
9 AC_PREREQ(2.64)
10 AC_INIT(package-unused, version-unused,, libgo)
11 AC_CONFIG_SRCDIR(Makefile.am)
12 AC_CONFIG_HEADER(config.h)
13
14 libtool_VERSION=1:0:0
15 AC_SUBST(libtool_VERSION)
16
17 AM_ENABLE_MULTILIB(, ..)
18
19 AC_CANONICAL_SYSTEM
20 target_alias=${target_alias-$host_alias}
21
22 AM_INIT_AUTOMAKE([1.9.3 no-define foreign -Wall])
23 AH_TEMPLATE(PACKAGE, [Name of package])
24 AH_TEMPLATE(VERSION, [Version number of package])
25
26 m4_rename([_AC_ARG_VAR_PRECIOUS],[glibgo_PRECIOUS])
27 m4_define([_AC_ARG_VAR_PRECIOUS],[])
28 AC_PROG_CC
29 AC_PROG_GO
30 m4_rename_force([glibgo_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
31
32 AC_SUBST(CFLAGS)
33
34 AM_MAINTAINER_MODE
35
36 AC_PROG_LD
37 AC_PROG_RANLIB
38 AC_CHECK_TOOL(OBJCOPY, objcopy, missing-objcopy)
39
40 AC_LIBTOOL_DLOPEN
41 AM_PROG_LIBTOOL
42 AC_SUBST(enable_shared)
43 AC_SUBST(enable_static)
44
45 WARN_FLAGS='-Wall -Wextra -Wwrite-strings -Wcast-qual'
46 AC_SUBST(WARN_FLAGS)
47
48 dnl FIXME: This should be controlled by --enable-maintainer-mode.
49 WERROR="-Werror"
50 AC_SUBST(WERROR)
51
52 glibgo_toolexecdir=no
53 glibgo_toolexeclibdir=no
54 glibgo_prefixdir=$prefix
55
56 AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
57 AC_ARG_ENABLE([version-specific-runtime-libs],
58   AC_HELP_STRING([--enable-version-specific-runtime-libs],
59                  [Specify that runtime libraries should be installed in a compiler-specific directory]),
60   [case "$enableval" in
61     yes) version_specific_libs=yes ;;
62     no)  version_specific_libs=no ;;
63     *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
64    esac],
65   [version_specific_libs=no])
66 AC_MSG_RESULT($version_specific_libs)
67
68 # Version-specific runtime libs processing.
69 if test $version_specific_libs = yes; then
70   glibgo_toolexecdir='${libdir}/gcc/${host_alias}'
71   glibgo_toolexeclibdir='${toolexecdir}/${gcc_version}$(MULTISUBDIR)'
72 fi
73
74 # Calculate glibgo_toolexecdir, glibgo_toolexeclibdir
75 # Install a library built with a cross compiler in tooldir, not libdir.
76 if test x"$glibgo_toolexecdir" = x"no"; then
77   if test -n "$with_cross_host" &&
78      test x"$with_cross_host" != x"no"; then
79     glibgo_toolexecdir='${exec_prefix}/${host_alias}'
80     glibgo_toolexeclibdir='${toolexecdir}/lib'
81   else
82     glibgo_toolexecdir='${libdir}/gcc/${host_alias}'
83     glibgo_toolexeclibdir='${libdir}'
84   fi
85   multi_os_directory=`$CC -print-multi-os-directory`
86   case $multi_os_directory in
87     .) ;; # Avoid trailing /.
88     *) glibgo_toolexeclibdir=$glibgo_toolexeclibdir/$multi_os_directory ;;
89   esac
90 fi
91
92 AC_SUBST(glibgo_prefixdir)
93 AC_SUBST(glibgo_toolexecdir)
94 AC_SUBST(glibgo_toolexeclibdir)
95
96 # See if the user wants to configure without libffi.  Some
97 # architectures don't support it.  FIXME: We should set a default
98 # based on the host.
99 AC_ARG_WITH(libffi,
100   AS_HELP_STRING([--without-libffi],
101                  [don't use libffi]),
102   [:],
103   [with_libffi=${with_libffi_default-yes}])
104
105 LIBFFI=
106 LIBFFIINCS=
107 if test "$with_libffi" != no; then
108    AC_DEFINE(USE_LIBFFI, 1, [Define if we're to use libffi.])
109    LIBFFI=../libffi/libffi_convenience.la
110    LIBFFIINCS='-I$(top_srcdir)/../libffi/include -I../libffi/include'
111 fi
112 AC_SUBST(LIBFFI)
113 AC_SUBST(LIBFFIINCS)
114
115 is_darwin=no
116 is_freebsd=no
117 is_linux=no
118 is_rtems=no
119 GOOS=unknown
120 case ${host} in
121   *-*-darwin*) is_darwin=yes; GOOS=darwin ;;
122   *-*-freebsd*) is_freebsd=yes; GOOS=freebsd ;;
123   *-*-linux*)  is_linux=yes; GOOS=linux  ;;
124   *-*-rtems*)  is_rtems=yes; GOOS=rtems  ;;
125 esac
126 AM_CONDITIONAL(LIBGO_IS_DARWIN, test $is_darwin = yes)
127 AM_CONDITIONAL(LIBGO_IS_FREEBSD, test $is_freebsd = yes)
128 AM_CONDITIONAL(LIBGO_IS_LINUX, test $is_linux = yes)
129 AM_CONDITIONAL(LIBGO_IS_RTEMS, test $is_rtems = yes)
130 AC_SUBST(GOOS)
131
132 is_386=no
133 is_x86_64=no
134 is_arm=no
135 GOARCH=unknown
136 case ${host} in
137 changequote(,)dnl
138   i[34567]86-*-* | x86_64-*-*)
139 changequote([,])dnl
140     AC_PREPROC_IFELSE([
141 #ifdef __x86_64__
142 #error 64-bit
143 #endif],
144 [is_386=yes], [is_x86_64=yes])
145     if test "$is_386" = "yes"; then
146       GOARCH=386
147     else
148       GOARCH=amd64
149     fi
150     ;;
151   arm*-*-* | strongarm*-*-* | ep9312*-*-* | xscale-*-*)
152     is_arm=yes
153     GOARCH=arm
154     ;;
155 esac
156 AM_CONDITIONAL(LIBGO_IS_386, test $is_386 = yes)
157 AM_CONDITIONAL(LIBGO_IS_X86_64, test $is_x86_64 = yes)
158 AM_CONDITIONAL(LIBGO_IS_ARM, test $is_arm = yes)
159 AC_SUBST(GOARCH)
160
161 dnl Use -fsplit-stack when compiling C code if available.
162 AC_CACHE_CHECK([whether -fsplit-stack is supported],
163 [ac_cv_libgo_split_stack_supported],
164 [CFLAGS_hold=$CFLAGS
165 CFLAGS="$CFLAGS -fsplit-stack"
166 AC_COMPILE_IFELSE([[int i;]],
167 [ac_cv_libgo_split_stack_supported=yes],
168 [ac_cv_libgo_split_stack_supported=no])
169 CFLAGS=$CFLAGS_hold])
170 if test "$ac_cv_libgo_split_stack_supported" = yes; then
171   SPLIT_STACK=-fsplit-stack
172   AC_DEFINE(USING_SPLIT_STACK, 1,
173                 [Define if the compiler supports -fsplit-stack])
174 else
175   SPLIT_STACK=
176 fi
177 AC_SUBST(SPLIT_STACK)
178 AM_CONDITIONAL(USING_SPLIT_STACK,
179         test "$ac_cv_libgo_split_stack_supported" = yes)
180
181 dnl Check whether the linker does stack munging when calling from
182 dnl split-stack into non-split-stack code.  We check this by looking
183 dnl at the --help output.  FIXME: This is only half right: it's
184 dnl possible for the linker to support this for some targets but not
185 dnl others.
186 AC_CACHE_CHECK([whether linker supports split stack],
187 [ac_cv_libgo_linker_supports_split_stack],
188 ac_cv_libgo_linker_supports_split_stack=no
189 if $LD --help 2>/dev/null | grep split-stack-adjust-size >/dev/null 2>&1; then
190   ac_cv_libgo_linker_supports_split_stack=yes
191 fi)
192 if test "$ac_cv_libgo_linker_supports_split_stack" = yes; then
193   AC_DEFINE(LINKER_SUPPORTS_SPLIT_STACK, 1,
194             [Define if the linker support split stack adjustments])
195 fi
196
197 dnl Test for the -lm library.
198 MATH_LIBS=
199 AC_CHECK_LIB([m], [sqrt], MATH_LIBS=-lm)
200 AC_SUBST(MATH_LIBS)
201
202 dnl Test whether the compiler supports the -pthread option.
203 AC_CACHE_CHECK([whether -pthread is supported],
204 [ac_cv_libgo_pthread_supported],
205 [CFLAGS_hold=$CFLAGS
206 CFLAGS="$CFLAGS -pthread"
207 AC_COMPILE_IFELSE([[int i;]],
208 [ac_cv_libgo_pthread_supported=yes],
209 [ac_cv_libgo_pthread_supported=no])
210 CFLAGS=$CFLAGS_hold])
211 PTHREAD_CFLAGS=
212 if test "$ac_cv_libgo_pthread_supported" = yes; then
213   PTHREAD_CFLAGS=-pthread
214 fi
215 AC_SUBST(PTHREAD_CFLAGS)
216
217 dnl Test for the -lpthread library.
218 PTHREAD_LIBS=
219 AC_CHECK_LIB([pthread], [pthread_create], PTHREAD_LIBS=-lpthread)
220 AC_SUBST(PTHREAD_LIBS)
221
222 AC_C_BIGENDIAN
223
224 GCC_CHECK_UNWIND_GETIPINFO
225
226 AC_CHECK_HEADERS(sys/mman.h syscall.h sys/epoll.h sys/ptrace.h sys/user.h sys/utsname.h)
227 AM_CONDITIONAL(HAVE_SYS_MMAN_H, test "$ac_cv_header_sys_mman_h" = yes)
228 AC_CHECK_FUNCS(srandom random strsignal)
229
230 dnl For x86 we want to use the -minline-all-stringops option to avoid
231 dnl forcing a stack split when calling memcpy and friends.
232 AC_CACHE_CHECK([whether compiler supports -minline-all-stringops],
233 [ac_cv_libgo_compiler_supports_inline_all_stringops],
234 [CFLAGS_hold=$CFLAGS
235 CFLAGS="$CFLAGS -minline-all-stringops"
236 AC_COMPILE_IFELSE([int i;],
237 [ac_cv_libgo_compiler_supports_inline_all_stringops=yes],
238 [ac_cv_libgo_compiler_supports_inline_all_stringops=no])
239 CFLAGS=$CFLAGS_hold])
240 STRINGOPS_FLAG=
241 if test "$ac_cv_libgo_compiler_supports_inline_all_stringops" = yes; then
242   STRINGOPS_FLAG=-minline-all-stringops
243 fi
244 AC_SUBST(STRINGOPS_FLAG)
245
246 CFLAGS_hold=$CFLAGS
247 CFLAGS="$CFLAGS -D_LARGEFILE_SOURCE -D_LARGEFILE64_SOURCE"
248 AC_CHECK_TYPES(off64_t)
249 CFLAGS=$CFLAGS_hold
250
251 AC_CACHE_SAVE
252
253 if test ${multilib} = yes; then
254   multilib_arg="--enable-multilib"
255 else
256   multilib_arg=
257 fi
258
259 AC_CONFIG_FILES(Makefile testsuite/Makefile)
260
261 AC_CONFIG_COMMANDS([default],
262 [if test -n "$CONFIG_FILES"; then
263    # Multilibs need MULTISUBDIR defined correctly in certain makefiles so
264    # that multilib installs will end up installed in the correct place.
265    # The testsuite needs it for multilib-aware ABI baseline files.
266    # To work around this not being passed down from config-ml.in ->
267    # srcdir/Makefile.am -> srcdir/{src,libsupc++,...}/Makefile.am, manually
268    # append it here.  Only modify Makefiles that have just been created.
269    #
270    # Also, get rid of this simulated-VPATH thing that automake does.
271    cat > vpsed << \_EOF
272 s!`test -f '$<' || echo '$(srcdir)/'`!!
273 _EOF
274    for i in $SUBDIRS; do
275     case $CONFIG_FILES in
276      *${i}/Makefile*)
277        #echo "Adding MULTISUBDIR to $i/Makefile"
278        sed -f vpsed $i/Makefile > tmp
279        grep '^MULTISUBDIR =' Makefile >> tmp
280        mv tmp $i/Makefile
281        ;;
282     esac
283    done
284    rm vpsed
285  fi
286 ],
287 [
288 # Variables needed in config.status (file generation) which aren't already
289 # passed by autoconf.
290 SUBDIRS="$SUBDIRS"
291 ])
292
293 AC_OUTPUT