libgfortran/m4/specific.m4

   1 include(head.m4)
   2 define(atype_code,regexp(file,`_\([ircl][0-9]+\).[fF]90',`\1'))dnl
   3 define(atype_letter,substr(atype_code, 0, 1))dnl
   4 define(atype_kind,substr(atype_code, 1))dnl
   5 define(get_typename2, `$1 (kind=$2)')dnl
   6 define(get_typename, `get_typename2(ifelse($1,i,integer,ifelse($1,r,real,ifelse($1,l,logical,ifelse($1,c,complex,unknown)))),`$2')')dnl
   7 define(atype_name, get_typename(atype_letter,atype_kind))dnl
   8 define(name, regexp(regexp(file, `[^/]*$', `\&'), `^_\([^_]*\)_', `\1'))dnl
   9 define(rtype_name,get_typename(ifelse(name,abs,ifelse(atype_letter,c,r,atype_letter),ifelse(name,aimag,ifelse(atype_letter,c,r,atype_letter),atype_letter)),atype_kind))dnl
  10 define(function_name,ifelse(name,conjg,`specific__conjg_'atype_kind,`specific__'name`_'atype_code))dnl
  11
  12 define(type,ifelse(atype_letter,l,LOGICAL,ifelse(atype_letter,i,INTEGER,ifelse(atype_letter,r,REAL,ifelse(atype_letter,c,COMPLEX,UNKNOW)))))dnl
  13 define(Q,ifelse(atype_kind,4,F,ifelse(atype_kind,8,`',ifelse(atype_kind,10,L,ifelse(atype_kind,16,L,`_'atype_kind)))))dnl
  14
  15 dnl A few specifics require a function other than their name, or
  16 dnl nothing. The list is currently:
  17 dnl    - integer and logical specifics require no libm function
  18 dnl    - AINT requires the trunc() family functions
  19 dnl    - ANINT requires round()
  20 dnl    - AIMAG, CONJG, DIM, SIGN require no libm function
  21 define(needed,ifelse(atype_letter,i,`none',ifelse(atype_letter,l,`none',ifelse(name,aint,trunc,ifelse(name,anint,round,ifelse(name,aimag,none,ifelse(name,conjg,none,ifelse(name,dim,none,ifelse(name,sign,none,ifelse(name,abs,fabs,name))))))))))dnl
  22 define(prefix,ifelse(atype_letter,c,C,`'))dnl
  23
  24 dnl Special case for fabs, for which the corresponding complex function
  25 dnl is not cfabs but cabs.
  26 define(NEEDED,translit(ifelse(prefix`'needed,`Cfabs',`abs',needed),`a-z',`A-Z'))dnl
  27
  28 #include "config.h"
  29 #include "kinds.inc"
  30 #include "c99_protos.inc"
  31
  32 `#if defined (HAVE_GFC_'type`_'atype_kind`)'
  33 ifelse(NEEDED,NONE,`',`#ifdef HAVE_'prefix`'NEEDED`'Q)
  34
  35 elemental function function_name (parm)
  36    atype_name, intent (in) :: parm
  37    rtype_name :: function_name
  38
  39    function_name = name (parm)
  40 end function
  41
  42 ifelse(NEEDED,NONE,`',`#endif')
  43 #endif