libgcc/configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 sinclude(../config/enable.m4)
   4 sinclude(../config/tls.m4)
   5 sinclude(../config/acx.m4)
   6 sinclude(../config/no-executables.m4)
   7 sinclude(../config/lib-ld.m4)
   8 sinclude(../config/override.m4)
   9 sinclude(../config/picflag.m4)
  10 sinclude(../config/dfp.m4)
  11 sinclude(../config/unwind_ipinfo.m4)
  12
  13 AC_PREREQ(2.64)
  14 AC_INIT([GNU C Runtime Library], 1.0,,[libgcc])
  15 AC_CONFIG_SRCDIR([static-object.mk])
  16
  17 # The libgcc should not depend on any header files
  18 AC_DEFUN([_AC_INCLUDES_DEFAULT_REQUIREMENTS],
  19   [m4_divert_text([DEFAULTS],
  20     [ac_includes_default='/* none */'])])
  21
  22 AC_ARG_WITH(target-subdir,
  23 [  --with-target-subdir=SUBDIR      Configuring in a subdirectory for target])
  24 AC_ARG_WITH(cross-host,
  25 [  --with-cross-host=HOST           Configuring with a cross compiler])
  26 AC_ARG_WITH(ld,
  27 [  --with-ld               arrange to use the specified ld (full pathname)])
  28
  29 if test "${srcdir}" = "."; then
  30   if test -n "${with_build_subdir}"; then
  31     libgcc_topdir="${srcdir}/../.."
  32     with_target_subdir=
  33   elif test -z "${with_target_subdir}"; then
  34     libgcc_topdir="${srcdir}/.."
  35   else
  36     if test "${with_target_subdir}" != "."; then
  37       libgcc_topdir="${srcdir}/${with_multisrctop}../.."
  38     else
  39       libgcc_topdir="${srcdir}/${with_multisrctop}.."
  40     fi
  41   fi
  42 else
  43   libgcc_topdir="${srcdir}/.."
  44 fi
  45 AC_SUBST(libgcc_topdir)
  46 AC_CONFIG_AUX_DIR($libgcc_topdir)
  47
  48 AC_ARG_ENABLE(shared,
  49 [  --disable-shared        don't provide a shared libgcc],
  50 [
  51   case $enable_shared in
  52   yes | no) ;;
  53   *)
  54     enable_shared=no
  55     IFS="${IFS=         }"; ac_save_ifs="$IFS"; IFS="${IFS}:,"
  56     for pkg in $enableval; do
  57       if test "X$pkg" = "Xgcc" || test "X$pkg" = "Xlibgcc"; then
  58         enable_shared=yes
  59       fi
  60     done
  61     IFS="$ac_save_ifs"
  62     ;;
  63   esac
  64 ], [enable_shared=yes])
  65 AC_SUBST(enable_shared)
  66
  67 GCC_PICFLAG
  68 AC_SUBST(PICFLAG)
  69
  70 AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
  71 AC_ARG_ENABLE(version-specific-runtime-libs,
  72 [  --enable-version-specific-runtime-libs    Specify that runtime libraries should be installed in a compiler-specific directory ],
  73 [case "$enableval" in
  74  yes) version_specific_libs=yes ;;
  75  no)  version_specific_libs=no ;;
  76  *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
  77  esac],
  78 [version_specific_libs=no])
  79 AC_MSG_RESULT($version_specific_libs)
  80
  81 AC_ARG_WITH(slibdir,
  82 [  --with-slibdir=DIR      shared libraries in DIR [LIBDIR]],
  83 slibdir="$with_slibdir",
  84 if test "${version_specific_libs}" = yes; then
  85   slibdir='$(libsubdir)'
  86 elif test -n "$with_cross_host" && test x"$with_cross_host" != x"no"; then
  87   slibdir='$(exec_prefix)/$(host_noncanonical)/lib'
  88 else
  89   slibdir='$(libdir)'
  90 fi)
  91 AC_SUBST(slibdir)
  92
  93 # Command-line options.
  94 # Very limited version of AC_MAINTAINER_MODE.
  95 AC_ARG_ENABLE([maintainer-mode],
  96   [AC_HELP_STRING([--enable-maintainer-mode],
  97                  [enable make rules and dependencies not useful (and
  98                   sometimes confusing) to the casual installer])],
  99   [case ${enable_maintainer_mode} in
 100      yes) MAINT='' ;;
 101      no) MAINT='#' ;;
 102      *) AC_MSG_ERROR([--enable-maintainer-mode must be yes or no]) ;;
 103    esac
 104    maintainer_mode=${enableval}],
 105   [MAINT='#'])
 106 AC_SUBST([MAINT])dnl
 107
 108 AC_PROG_INSTALL
 109
 110 AC_PROG_AWK
 111 # We need awk; bail out if it's missing.
 112 case ${AWK} in
 113   "") AC_MSG_ERROR([can't build without awk, bailing out]) ;;
 114 esac
 115
 116 AC_CANONICAL_HOST
 117 ACX_NONCANONICAL_HOST
 118 ACX_NONCANONICAL_TARGET
 119 GCC_TOPLEV_SUBDIRS
 120
 121 # Calculate toolexeclibdir
 122 # Also toolexecdir, though it's only used in toolexeclibdir
 123 case ${version_specific_libs} in
 124   yes)
 125     # Need the gcc compiler version to know where to install libraries
 126     # and header files if --enable-version-specific-runtime-libs option
 127     # is selected.
 128     toolexecdir='$(libdir)/gcc/$(target_noncanonical)'
 129     toolexeclibdir='$(toolexecdir)/$(gcc_version)$(MULTISUBDIR)'
 130     ;;
 131   no)
 132     if test -n "$with_cross_host" &&
 133        test x"$with_cross_host" != x"no"; then
 134       # Install a library built with a cross compiler in tooldir, not libdir.
 135       toolexecdir='$(exec_prefix)/$(target_noncanonical)'
 136       toolexeclibdir='$(toolexecdir)/lib'
 137     else
 138       toolexecdir='$(libdir)/gcc-lib/$(target_noncanonical)'
 139       toolexeclibdir='$(libdir)'
 140     fi
 141     multi_os_directory=`$CC -print-multi-os-directory`
 142     case $multi_os_directory in
 143       .) ;; # Avoid trailing /.
 144       *) toolexeclibdir=$toolexeclibdir/$multi_os_directory ;;
 145     esac
 146     ;;
 147 esac
 148 AC_SUBST(toolexecdir)
 149 AC_SUBST(toolexeclibdir)
 150
 151 dnl These must be called before AM_PROG_LIBTOOL, because it may want
 152 dnl to call AC_CHECK_PROG.
 153 AC_CHECK_TOOL(AR, ar)
 154 AC_CHECK_TOOL(LIPO, lipo, :)
 155 AC_CHECK_TOOL(NM, nm)
 156 AC_CHECK_TOOL(RANLIB, ranlib, :)
 157 AC_CHECK_TOOL(STRIP, strip, :)
 158 AC_PROG_LN_S
 159
 160 GCC_NO_EXECUTABLES
 161 AC_PROG_CC
 162 AC_PROG_CPP_WERROR
 163
 164 AC_CHECK_SIZEOF([double])
 165 AC_CHECK_SIZEOF([long double])
 166 AS_VAR_ARITH([double_type_size], [$ac_cv_sizeof_double \* 8])
 167 AS_VAR_ARITH([long_double_type_size], [$ac_cv_sizeof_long_double \* 8])
 168 AC_SUBST(double_type_size)
 169 AC_SUBST(long_double_type_size)
 170
 171 # Check for decimal float support.
 172 AC_CACHE_CHECK([whether decimal floating point is supported], [libgcc_cv_dfp],
 173                [AC_COMPILE_IFELSE([_Decimal32 x;], [libgcc_cv_dfp=yes],
 174                                   [libgcc_cv_dfp=no])])
 175 decimal_float=$libgcc_cv_dfp
 176 AC_SUBST(decimal_float)
 177
 178 GCC_AC_ENABLE_DECIMAL_FLOAT([$host])
 179
 180 # Check for fixed-point support.
 181 AC_CACHE_CHECK([whether fixed-point is supported], [libgcc_cv_fixed_point],
 182                [AC_COMPILE_IFELSE([_Sat _Fract x;], [libgcc_cv_fixed_point=yes],
 183                                   [libgcc_cv_fixed_point=no])])
 184 fixed_point=$libgcc_cv_fixed_point
 185 AC_SUBST(fixed_point)
 186
 187 # For platforms with the unwind ABI which includes an unwind library,
 188 # libunwind, we can choose to use the system libunwind.
 189 # config.gcc also contains tests of with_system_libunwind.
 190 GCC_CHECK_UNWIND_GETIPINFO
 191
 192 # The sjlj test is almost duplicated here and in libgo/configure.ac (for C),
 193 # libstdc++-v3/acinclude.m4 and libjava/configure.ac (for C++), and
 194 # libobjc/configure.ac (for Objective-C).
 195 # FIXME: This should be centralized in config/sjlj.m4.
 196 AC_ARG_ENABLE(sjlj-exceptions,
 197   AC_HELP_STRING([--enable-sjlj-exceptions],
 198                  [force use of builtin_setjmp for exceptions]),
 199   [case "$enableval" in
 200    yes|no|auto) ;;
 201    *) AC_MSG_ERROR([unknown argument to --enable-sjlj-exceptions]) ;;
 202    esac],
 203   [enable_sjlj_exceptions=auto])
 204
 205 AC_CACHE_CHECK([whether to use setjmp/longjmp exceptions],
 206 [libgcc_cv_lib_sjlj_exceptions],
 207 [AC_LANG_CONFTEST(
 208   [AC_LANG_SOURCE([
 209 void bar ();
 210 void clean (int *);
 211 void foo ()
 212 {
 213   int i __attribute__ ((cleanup (clean)));
 214   bar();
 215 }
 216 ])])
 217 CFLAGS_hold=$CFLAGS
 218 CFLAGS="--save-temps -fexceptions"
 219 libgcc_cv_lib_sjlj_exceptions=unknown
 220 AS_IF([ac_fn_c_try_compile],
 221   [if grep _Unwind_SjLj_Resume conftest.s >/dev/null 2>&1; then
 222     libgcc_cv_lib_sjlj_exceptions=yes
 223   elif grep _Unwind_Resume conftest.s >/dev/null 2>&1; then
 224     libgcc_cv_lib_sjlj_exceptions=no
 225   fi])
 226 CFLAGS=$CFLAGS_hold
 227 rm -f conftest*
 228 ])
 229
 230 if test "$enable_sjlj_exceptions" = "auto"; then
 231   enable_sjlj_exceptions=$libgcc_cv_lib_sjlj_exceptions
 232 fi
 233
 234 case $enable_sjlj_exceptions in
 235 yes)
 236   AC_DEFINE(LIBGCC_SJLJ_EXCEPTIONS, 1,
 237         [Define if the C compiler is configured for setjmp/longjmp exceptions.])
 238   ;;
 239 no)
 240   ;;
 241 *)
 242   AC_MSG_ERROR([unable to detect exception model])
 243   ;;
 244 esac
 245
 246 AC_LIB_PROG_LD_GNU
 247
 248 AC_MSG_CHECKING([for thread model used by GCC])
 249 target_thread_file=`$CC -v 2>&1 | sed -n 's/^Thread model: //p'`
 250 AC_MSG_RESULT([$target_thread_file])
 251
 252 # Check for assembler CFI support.
 253 AC_CACHE_CHECK([whether assembler supports CFI directives], [libgcc_cv_cfi],
 254                [AC_COMPILE_IFELSE(
 255 [asm("\n\
 256         .text\n\
 257         .cfi_startproc\n\
 258         .cfi_personality 0, symbol\n\
 259         .cfi_endproc");],
 260   [libgcc_cv_cfi=yes],
 261   [libgcc_cv_cfi=no])])
 262
 263 # Check 32bit or 64bit
 264 cat > conftest.c <<EOF
 265 #if defined(__x86_64__) || (!defined(__i386__) && defined(__LP64__))
 266 host_address=64
 267 #else
 268 host_address=32
 269 #endif
 270 EOF
 271 eval `${CC-cc} -E conftest.c | grep host_address=`
 272 rm -f conftest.c
 273
 274 # Collect host-machine-specific information.
 275 . ${srcdir}/config.host
 276
 277 # Check if Solaris/x86 linker supports ZERO terminator unwind entries.
 278 # This is after config.host so we can augment tmake_file.
 279 # Link with -nostartfiles -nodefaultlibs since neither are present while
 280 # building libgcc.
 281 case ${host} in
 282 i?86-*-solaris2* | x86_64-*-solaris2.1[[0-9]]*)
 283   cat > conftest.s <<EOF
 284         .section        .eh_frame,"a",@unwind
 285         .zero   4
 286         .section        .jcr,"aw",@progbits
 287         .zero   8
 288 EOF
 289   if AC_TRY_COMMAND(${CC-cc} -shared -nostartfiles -nodefaultlibs -o conftest.so conftest.s 1>&AS_MESSAGE_LOG_FD); then
 290       tmake_file="${tmake_file} i386/t-crtstuff"
 291   fi
 292   ;;
 293 esac
 294
 295 # Check for visibility support.  This is after config.host so that
 296 # we can check for asm_hidden_op.
 297 AC_CACHE_CHECK([for __attribute__((visibility("hidden")))],
 298     libgcc_cv_hidden_visibility_attribute, [
 299         echo 'int __attribute__ ((visibility ("hidden"))) foo (void) { return 1; }' > conftest.c
 300         libgcc_cv_hidden_visibility_attribute=no
 301         if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
 302             if grep "\\$asm_hidden_op.*foo" conftest.s >/dev/null; then
 303                 libgcc_cv_hidden_visibility_attribute=yes
 304             fi
 305         fi
 306         rm -f conftest.*
 307     ])
 308
 309 if test $libgcc_cv_hidden_visibility_attribute = yes; then
 310     vis_hide='-fvisibility=hidden -DHIDE_EXPORTS'
 311 else
 312     vis_hide=
 313 fi
 314 AC_SUBST(vis_hide)
 315
 316 # See if we have thread-local storage.  We can only test assembler
 317 # sicne link-time and run-time tests require the newly built
 318 # gcc, which can't be used to build executable due to that libgcc
 319 # is yet to be built here.
 320 GCC_CHECK_CC_TLS
 321 set_have_cc_tls=
 322 if test "$enable_tls $gcc_cv_have_cc_tls" = "yes yes"; then
 323   set_have_cc_tls="-DHAVE_CC_TLS"
 324 fi
 325 AC_SUBST(set_have_cc_tls)
 326
 327 # See if we have emulated thread-local storage.
 328 GCC_CHECK_EMUTLS
 329 set_use_emutls=
 330 if test "$enable_tls $gcc_cv_use_emutls" = "yes yes"; then
 331   set_use_emutls="-DUSE_EMUTLS"
 332 fi
 333 AC_SUBST(set_use_emutls)
 334
 335 # Conditionalize the sfp-machine.h header for this target machine.
 336 if test -z "${sfp_machine_header}"; then
 337         sfp_machine_header=$cpu_type/sfp-machine.h
 338         if test -f ${srcdir}/config/${sfp_machine_header}; then
 339                 :
 340         else
 341                 sfp_machine_header=no-sfp-machine.h
 342         fi
 343 fi
 344 AC_SUBST(sfp_machine_header)
 345
 346 # Conditionalize the makefile for this target machine.
 347 tmake_file_=
 348 for f in ${tmake_file}
 349 do
 350         if test -f ${srcdir}/config/$f
 351         then
 352                 tmake_file_="${tmake_file_} \$(srcdir)/config/$f"
 353         fi
 354 done
 355 tmake_file="${tmake_file_}"
 356 AC_SUBST(tmake_file)
 357
 358 # Likewise export definitions for libgcc_tm.h
 359 tm_file_=
 360 for f in ${tm_file}
 361 do
 362         tm_file_="${tm_file_} \$(srcdir)/config/$f"
 363 done
 364 tm_file="${tm_file_}"
 365 AC_SUBST(tm_file)
 366 AC_SUBST(tm_defines)
 367
 368 # Map from thread model to thread header.
 369 case $target_thread_file in
 370     aix)        thread_header=config/rs6000/gthr-aix.h ;;
 371     dce)        thread_header=config/pa/gthr-dce.h ;;
 372     lynx)       thread_header=config/gthr-lynx.h ;;
 373     mipssde)    thread_header=config/mips/gthr-mipssde.h ;;
 374     posix)      thread_header=gthr-posix.h ;;
 375     rtems)      thread_header=config/gthr-rtems.h ;;
 376     single)     thread_header=gthr-single.h ;;
 377     tpf)        thread_header=config/s390/gthr-tpf.h ;;
 378     vxworks)    thread_header=config/gthr-vxworks.h ;;
 379     win32)      thread_header=config/i386/gthr-win32.h ;;
 380 esac
 381
 382 # Substitute configuration variables
 383 AC_SUBST(cpu_type)
 384 AC_SUBST(extra_parts)
 385 AC_SUBST(asm_hidden_op)
 386 AC_CONFIG_LINKS([enable-execute-stack.c:$enable_execute_stack])
 387 AC_CONFIG_LINKS([unwind.h:$unwind_header])
 388 AC_CONFIG_LINKS([md-unwind-support.h:config/$md_unwind_header])
 389 AC_CONFIG_LINKS([sfp-machine.h:config/$sfp_machine_header])
 390 AC_CONFIG_LINKS([gthr-default.h:$thread_header])
 391
 392 # We need multilib support.
 393 AC_CONFIG_FILES([Makefile])
 394 AC_CONFIG_COMMANDS([default],
 395   [[test -z "$CONFIG_HEADERS" || echo timestamp > stamp-h
 396 if test -n "$CONFIG_FILES"; then
 397   # FIXME: We shouldn't need to set ac_file
 398   ac_file=Makefile
 399   . ${libgcc_topdir}/config-ml.in
 400 fi]],
 401 [[srcdir=${srcdir}
 402 host=${host}
 403 with_target_subdir=${with_target_subdir}
 404 with_multisubdir=${with_multisubdir}
 405 ac_configure_args="--enable-multilib ${ac_configure_args}"
 406 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
 407 libgcc_topdir=${libgcc_topdir}
 408 CC="${CC}"
 409 ]])
 410 AC_OUTPUT