OSDN Git Service

Add - before rms to be more portable.
[pf3gnuchains/gcc-fork.git] / libffi / configure.in
1 dnl Process this with autoconf to create configure
2 AC_INIT(fficonfig.h.in)
3 AM_CONFIG_HEADER(fficonfig.h)
4
5 AC_MSG_WARN(***********************************************************)
6 AC_MSG_WARN(***********************************************************)
7 AC_MSG_WARN(This is beta code.  If you're looking for a stable release)
8 AC_MSG_WARN(then use the most recent one - libffi-1.20.)
9 AC_MSG_WARN(***********************************************************)
10 AC_MSG_WARN(***********************************************************)
11
12 dnl Default to --enable-multilib
13 AC_ARG_ENABLE(multilib,
14 [  --enable-multilib       build many library versions (default)],
15 [case "${enableval}" in
16   yes) multilib=yes ;;
17   no)  multilib=no ;;
18   *)   AC_MSG_ERROR(bad value ${enableval} for multilib option) ;;
19  esac], [multilib=yes])dnl
20
21 dnl We may get other options which we don't document:
22 dnl --with-target-subdir, --with-multisrctop, --with-multisubdir
23
24 if test "${srcdir}" = "."; then
25   if test "${with_target_subdir}" != "."; then
26     libffi_basedir="${srcdir}/${with_multisrctop}.."
27   else
28     libffi_basedir="${srcdir}/${with_multisrctop}"
29   fi
30 else
31   libffi_basedir="${srcdir}"
32 fi
33 AC_SUBST(libffi_basedir)
34
35 AC_CANONICAL_HOST
36
37 AM_INIT_AUTOMAKE(libffi,2.00-beta,no-define)
38
39 AC_EXEEXT
40 AM_MAINTAINER_MODE
41
42 AC_PROG_CC
43 AC_PROG_LIBTOOL
44
45 TARGETDIR="unknown"
46 case "$host" in
47 mips-sgi-irix5.* | mips-sgi-irix6.*) TARGET=MIPS; TARGETDIR=mips;;
48 i*86-*-linux*) TARGET=X86; TARGETDIR=x86;;
49 i*86-*-solaris*) TARGET=X86; TARGETDIR=x86;;
50 i*86-*-beos*) TARGET=X86; TARGETDIR=x86;;
51 i*86-*-freebsd*) TARGET=X86; TARGETDIR=x86;;
52 sparc-sun-4*) TARGET=SPARC; TARGETDIR=sparc;;
53 sparc-sun-*) TARGET=SPARC; TARGETDIR=sparc;;
54 sparc-*-linux*) TARGET=SPARC; TARGETDIR=sparc;;
55 sparc64-*-linux*) TARGET=SPARC; TARGETDIR=sparc;;
56 alpha*-*-linux* | alpha*-*-osf*) TARGET=ALPHA; TARGETDIR=alpha;;
57 ia64*-*-*) TARGET=IA64; TARGETDIR=ia64;;
58 m68k-*-linux*) TARGET=M68K; TARGETDIR=m68k;;
59 powerpc-*-linux* | powerpc-*-sysv*) TARGET=POWERPC; TARGETDIR=powerpc;;
60 powerpc-*-beos*) TARGET=POWERPC; TARGETDIR=powerpc;;
61 arm*-*-linux-*) TARGET=ARM; TARGETDIR=arm;;
62 esac
63
64 if test $TARGETDIR = unknown; then
65   AC_ERROR("libffi has not been ported to $host.")
66 fi
67
68 AM_CONDITIONAL(MIPS_GCC, test ${TARGET}${ac_cv_prog_gcc} = MIPSyes)
69 AM_CONDITIONAL(MIPS_SGI, test ${TARGET}${ac_cv_prog_gcc} = MIPSno)
70 AM_CONDITIONAL(SPARC, test x$TARGET = xSPARC)
71 AM_CONDITIONAL(X86, test x$TARGET = xX86)
72 AM_CONDITIONAL(ALPHA, test x$TARGET = xALPHA)
73 AM_CONDITIONAL(IA64, test x$TARGET = xIA64)
74 AM_CONDITIONAL(M68K, test x$TARGET = xM68K)
75 AM_CONDITIONAL(POWERPC, test x$TARGET = xPOWERPC)
76 AM_CONDITIONAL(ARM, test x$TARGET = xARM)
77
78 AC_HEADER_STDC
79 AC_CHECK_FUNCS(memcpy)
80 AC_FUNC_ALLOCA
81
82 dnl AC_CHECK_SIZEOF(char)
83 AC_CHECK_SIZEOF(short)
84 AC_CHECK_SIZEOF(int)
85 AC_CHECK_SIZEOF(long)
86 AC_CHECK_SIZEOF(long long)
87 AC_CHECK_SIZEOF(float)
88 AC_CHECK_SIZEOF(double)
89 AC_CHECK_SIZEOF(long double)
90
91 AC_CHECK_SIZEOF(void *)
92 AC_C_BIGENDIAN
93
94 AC_SUBST(TARGET)
95 AC_SUBST(TARGETDIR)
96
97 AC_SUBST(SHELL)
98
99 AC_ARG_ENABLE(debug,[  --enable-debug          debugging mode], AC_DEFINE(FFI_DEBUG))
100
101 AC_ARG_ENABLE(debug,[  --disable-structs       omit code for struct support], AC_DEFINE(FFI_NO_STRUCTS))
102
103 AC_ARG_ENABLE(debug,[  --disable-raw-api       make the raw api unavailable], AC_DEFINE(FFI_NO_RAW_API))
104
105 AC_ARG_ENABLE(purify-safety,
106 [  --enable-purify-safety  purify-safe mode], AC_DEFINE(USING_PURIFY))
107
108 AM_CONDITIONAL(USE_LIBDIR, test -z "$with_cross_host")
109
110 if test "${multilib}" = "yes"; then
111   multilib_arg="--enable-multilib"
112 else
113   multilib_arg=
114 fi
115
116 AC_OUTPUT(include/Makefile include/ffi.h Makefile,
117 [
118 if test -n "$CONFIG_FILES"; then
119    ac_file=Makefile . ${libffi_basedir}/../config-ml.in
120 fi
121 ],
122 srcdir=${srcdir}
123 host=${host}
124 target=${target}
125 with_multisubdir=${with_multisubdir}
126 ac_configure_args="${multilib_arg} ${ac_configure_args}"
127 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
128 libffi_basedir=${libffi_basedir}
129 CC="${CC}"
130 DEFS="$DEFS"
131 test ! -d include && mkdir include
132 test ! -f include/fficonfig.h && cp fficonfig.h include/fficonfig.h
133 if cmp -s fficonfig.h include/fficonfig.h 2>/dev/null; then 
134         echo fficonfig.h unchanged
135 else
136         echo Moving fficonfig.h to include/fficonfig.h
137         cp fficonfig.h include/fficonfig.h
138 fi
139 )