libffi/configure.in

   1 dnl Process this with autoconf to create configure
   2 AC_INIT(fficonfig.h.in)
   3 AM_CONFIG_HEADER(fficonfig.h)
   4
   5 # This works around the fact that libtool configuration may change LD
   6 # for this particular configuration, but some shells, instead of
   7 # keeping the changes in LD private, export them just because LD is
   8 # exported.
   9 ORIGINAL_LD_FOR_MULTILIBS=$LD
  10
  11 dnl Default to --enable-multilib
  12 AC_ARG_ENABLE(multilib,
  13 [  --enable-multilib       build many library versions (default)],
  14 [case "${enableval}" in
  15   yes) multilib=yes ;;
  16   no)  multilib=no ;;
  17   *)   AC_MSG_ERROR(bad value ${enableval} for multilib option) ;;
  18  esac], [multilib=yes])dnl
  19
  20 dnl We may get other options which we don't document:
  21 dnl --with-target-subdir, --with-multisrctop, --with-multisubdir
  22
  23 if test "${srcdir}" = "."; then
  24   if test "${with_target_subdir}" != "."; then
  25     libffi_basedir="${with_multisrctop}../"
  26   else
  27     libffi_basedir="${with_multisrctop}"
  28   fi
  29 else
  30   libffi_basedir=
  31 fi
  32 AC_SUBST(libffi_basedir)
  33 AC_CONFIG_AUX_DIR(${libffi_basedir}..)
  34
  35 AC_CANONICAL_SYSTEM
  36 target_alias=${target_alias-$host_alias}
  37
  38 AM_PROG_LIBTOOL
  39
  40 AM_INIT_AUTOMAKE(libffi,2.00-beta,no-define)
  41
  42 AC_EXEEXT
  43 AM_MAINTAINER_MODE
  44
  45 AC_PROG_CC
  46
  47 AC_PROG_LIBTOOL
  48
  49 dnl The -no-testsuite modules omit the test subdir.
  50 AM_CONDITIONAL(TESTSUBDIR, test -d $srcdir/testsuite)
  51
  52
  53 TARGETDIR="unknown"
  54 case "$host" in
  55 mips-sgi-irix5.* | mips-sgi-irix6.*) TARGET=MIPS; TARGETDIR=mips;;
  56 i*86-*-linux*) TARGET=X86; TARGETDIR=x86;;
  57 i*86-*-solaris*) TARGET=X86; TARGETDIR=x86;;
  58 i*86-*-beos*) TARGET=X86; TARGETDIR=x86;;
  59 i*86-*-freebsd*) TARGET=X86; TARGETDIR=x86;;
  60 i*86-*-netbsdelf*) TARGET=X86; TARGETDIR=x86;;
  61 i*86-*-win32*) TARGET=X86_WIN32; TARGETDIR=x86;;
  62 i*86-*-cygwin*) TARGET=X86_WIN32; TARGETDIR=x86;;
  63 i*86-*-mingw*) TARGET=X86_WIN32; TARGETDIR=x86;;
  64 sparc-sun-4*) TARGET=SPARC; TARGETDIR=sparc;;
  65 sparc*-sun-*) TARGET=SPARC; TARGETDIR=sparc;;
  66 sparc-*-linux* | sparc-*-netbsdelf*) TARGET=SPARC; TARGETDIR=sparc;;
  67 sparc64-*-linux* | sparc64-*-netbsd*) TARGET=SPARC; TARGETDIR=sparc;;
  68 alpha*-*-linux* | alpha*-*-osf* | alpha*-*-freebsd* | alpha*-*-netbsd*) TARGET=ALPHA; TARGETDIR=alpha;;
  69 ia64*-*-*) TARGET=IA64; TARGETDIR=ia64;;
  70 m68k-*-linux*) TARGET=M68K; TARGETDIR=m68k;;
  71 mips64*-*);;
  72 mips*-*-linux*) TARGET=MIPS_LINUX; TARGETDIR=mips;;
  73 powerpc*-*-linux* | powerpc-*-sysv*) TARGET=POWERPC; TARGETDIR=powerpc;;
  74 powerpc-*-beos*) TARGET=POWERPC; TARGETDIR=powerpc;;
  75 powerpc-*-darwin*) TARGET=POWERPC_DARWIN; TARGETDIR=powerpc;;
  76 powerpc-*-aix*) TARGET=POWERPC_AIX; TARGETDIR=powerpc;;
  77 rs6000-*-aix*) TARGET=POWERPC_AIX; TARGETDIR=powerpc;;
  78 arm*-*-linux-*) TARGET=ARM; TARGETDIR=arm;;
  79 arm*-*-netbsdelf*) TARGET=ARM; TARGETDIR=arm;;
  80 s390-*-linux-*) TARGET=S390; TARGETDIR=s390;;
  81 s390x-*-linux-*) TARGET=S390; TARGETDIR=s390;;
  82 x86_64-*-linux*) TARGET=X86_64; TARGETDIR=x86;;
  83 sh-*-linux* | sh[[34]]*-*-linux*) TARGET=SH; TARGETDIR=sh;;
  84 sh64-*-linux* | sh5*-*-linux*) TARGET=SH64; TARGETDIR=sh64;;
  85 esac
  86
  87 AC_SUBST(AM_RUNTESTFLAGS)
  88
  89 if test $TARGETDIR = unknown; then
  90   AC_ERROR("libffi has not been ported to $host.")
  91 fi
  92
  93 AM_CONDITIONAL(MIPS_GCC, test ${TARGET}${ac_cv_prog_gcc} = MIPSyes)
  94 AM_CONDITIONAL(MIPS_SGI, test ${TARGET}${ac_cv_prog_gcc} = MIPSno)
  95 AM_CONDITIONAL(MIPS_LINUX, test x$TARGET = xMIPS_LINUX)
  96 AM_CONDITIONAL(SPARC, test x$TARGET = xSPARC)
  97 AM_CONDITIONAL(X86, test x$TARGET = xX86)
  98 AM_CONDITIONAL(X86_WIN32, test x$TARGET = xX86_WIN32)
  99 AM_CONDITIONAL(ALPHA, test x$TARGET = xALPHA)
 100 AM_CONDITIONAL(IA64, test x$TARGET = xIA64)
 101 AM_CONDITIONAL(M68K, test x$TARGET = xM68K)
 102 AM_CONDITIONAL(POWERPC, test x$TARGET = xPOWERPC)
 103 AM_CONDITIONAL(POWERPC_AIX, test x$TARGET = xPOWERPC_AIX)
 104 AM_CONDITIONAL(POWERPC_DARWIN, test x$TARGET = xPOWERPC_DARWIN)
 105 AM_CONDITIONAL(ARM, test x$TARGET = xARM)
 106 AM_CONDITIONAL(S390, test x$TARGET = xS390)
 107 AM_CONDITIONAL(X86_64, test x$TARGET = xX86_64)
 108 AM_CONDITIONAL(SH, test x$TARGET = xSH)
 109 AM_CONDITIONAL(SH64, test x$TARGET = xSH64)
 110
 111 if test x$TARGET = xMIPS_LINUX; then
 112   TARGET=MIPS
 113 fi
 114
 115 AC_HEADER_STDC
 116 AC_CHECK_FUNCS(memcpy)
 117 AC_FUNC_ALLOCA
 118
 119 dnl AC_CHECK_SIZEOF(char)
 120 AC_COMPILE_CHECK_SIZEOF(short)
 121 AC_COMPILE_CHECK_SIZEOF(int)
 122 AC_COMPILE_CHECK_SIZEOF(long)
 123 AC_COMPILE_CHECK_SIZEOF(long long)
 124 AC_COMPILE_CHECK_SIZEOF(float)
 125 AC_COMPILE_CHECK_SIZEOF(double)
 126 AC_COMPILE_CHECK_SIZEOF(long double)
 127
 128 AC_COMPILE_CHECK_SIZEOF(void *)
 129 AC_C_BIGENDIAN_CROSS
 130
 131 if test x$TARGET = xSPARC; then
 132     AC_CACHE_CHECK([assembler and linker support unaligned pc related relocs],
 133         libffi_cv_as_sparc_ua_pcrel, [
 134         save_CFLAGS="$CFLAGS"
 135         save_LDFLAGS="$LDFLAGS"
 136         CFLAGS="$CFLAGS -fpic"
 137         LDFLAGS="$LDFLAGS -shared"
 138         AC_TRY_LINK([asm (".text; foo: nop; .data; .align 4; .byte 0; .uaword %r_disp32(foo); .text");],,
 139                     [libffi_cv_as_sparc_ua_pcrel=yes],
 140                     [libffi_cv_as_sparc_ua_pcrel=no])
 141         CFLAGS="$save_CFLAGS"
 142         LDFLAGS="$save_LDFLAGS"])
 143     if test "x$libffi_cv_as_sparc_ua_pcrel" = xyes; then
 144         AC_DEFINE(HAVE_AS_SPARC_UA_PCREL, 1,
 145                   [Define if your assembler and linker support unaligned PC relative relocs.])
 146     fi
 147
 148     AC_CACHE_CHECK([assembler .register pseudo-op support],
 149        libffi_cv_as_register_pseudo_op, [
 150        libffi_cv_as_register_pseudo_op=unknown
 151        # Check if we have .register
 152        AC_TRY_COMPILE([asm (".register %g2, #scratch");],,
 153                        [libffi_cv_as_register_pseudo_op=yes],
 154                        [libffi_cv_as_register_pseudo_op=no])
 155     ])
 156     if test "x$libffi_cv_as_register_pseudo_op" = xyes; then
 157        AC_DEFINE(HAVE_AS_REGISTER_PSEUDO_OP, 1,
 158                [Define if your assembler supports .register.])
 159     fi
 160 fi
 161
 162 AC_CACHE_CHECK([whether .eh_frame section should be read-only],
 163     libffi_cv_ro_eh_frame, [
 164         libffi_cv_ro_eh_frame=no
 165         echo 'extern void foo (void); void bar (void) { foo (); foo (); }' > conftest.c
 166         if $CC $CFLAGS -S -fpic -fexceptions -o conftest.s conftest.c > /dev/null 2>&1; then
 167             if grep '.section.*eh_frame.*"a"' conftest.s > /dev/null; then
 168                 libffi_cv_ro_eh_frame=yes
 169             elif grep '.section.*eh_frame.*#alloc' conftest.c \
 170                  | grep -v '#write' > /dev/null; then
 171                 libffi_cv_ro_eh_frame=yes
 172             fi
 173         fi
 174         rm -f conftest.*
 175     ])
 176 if test "x$libffi_cv_ro_eh_frame" = xyes; then
 177     AC_DEFINE(HAVE_RO_EH_FRAME, 1,
 178               [Define if .eh_frame sections should be read-only.])
 179 fi
 180
 181 AC_SUBST(TARGET)
 182 AC_SUBST(TARGETDIR)
 183
 184 AC_SUBST(SHELL)
 185
 186 AC_ARG_ENABLE(debug,
 187 [  --enable-debug          debugging mode],
 188   if test "$enable_debug" = "yes"; then
 189     AC_DEFINE(FFI_DEBUG)
 190   fi)
 191
 192 AC_ARG_ENABLE(structs,
 193 [  --disable-structs       omit code for struct support],
 194   if test "$enable_structs" = "no"; then
 195     AC_DEFINE(FFI_NO_STRUCTS)
 196   fi)
 197
 198 AC_ARG_ENABLE(raw-api,
 199 [  --disable-raw-api       make the raw api unavailable],
 200   if test "$enable_raw_api" = "no"; then
 201     AC_DEFINE(FFI_NO_RAW_API)
 202   fi)
 203
 204 AC_ARG_ENABLE(purify-safety,
 205 [  --enable-purify-safety  purify-safe mode],
 206   if test "$enable_purify_safety" = "yes"; then
 207     AC_DEFINE(USING_PURIFY)
 208   fi)
 209
 210 if test -n "$with_cross_host" &&
 211    test x"$with_cross_host" != x"no"; then
 212   toolexecdir='$(exec_prefix)/$(target_alias)'
 213   toolexeclibdir='$(toolexecdir)/lib'
 214 else
 215   toolexecdir='$(libdir)/gcc-lib/$(target_alias)'
 216   toolexeclibdir='$(libdir)'
 217 fi
 218 multi_os_directory=`$CC -print-multi-os-directory`
 219 case $multi_os_directory in
 220   .) ;; # Avoid trailing /.
 221   *) toolexeclibdir=$toolexeclibdir/$multi_os_directory ;;
 222 esac
 223 AC_SUBST(toolexecdir)
 224 AC_SUBST(toolexeclibdir)
 225
 226 if test "${multilib}" = "yes"; then
 227   multilib_arg="--enable-multilib"
 228 else
 229   multilib_arg=
 230 fi
 231
 232 AC_OUTPUT(include/Makefile testsuite/Makefile include/ffi.h Makefile,
 233 [
 234 if test -n "$CONFIG_FILES"; then
 235    LD="${ORIGINAL_LD_FOR_MULTILIBS}"
 236    ac_file=Makefile . ${srcdir}/${libffi_basedir}../config-ml.in
 237 fi
 238 ],
 239 srcdir=${srcdir}
 240 host=${host}
 241 target=${target}
 242 with_multisubdir=${with_multisubdir}
 243 ac_configure_args="${multilib_arg} ${ac_configure_args}"
 244 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
 245 libffi_basedir=${libffi_basedir}
 246 CC="${CC}"
 247 DEFS="$DEFS"
 248 ORIGINAL_LD_FOR_MULTILIBS="${ORIGINAL_LD_FOR_MULTILIBS}"
 249 test ! -d include && mkdir include
 250 test ! -f include/fficonfig.h && cp fficonfig.h include/fficonfig.h
 251 if cmp -s fficonfig.h include/fficonfig.h 2>/dev/null; then
 252         echo fficonfig.h unchanged
 253 else
 254         echo Moving fficonfig.h to include/fficonfig.h
 255         cp fficonfig.h include/fficonfig.h
 256 fi
 257 )
 258
 259 # Make target subdirectories if required.
 260 test -d src || mkdir src
 261 test -d src/${TARGETDIR} || mkdir src/${TARGETDIR}