libffi/configure.in

   1 dnl Process this with autoconf to create configure
   2 AC_INIT(fficonfig.h.in)
   3 AM_CONFIG_HEADER(fficonfig.h)
   4
   5 # This works around the fact that libtool configuration may change LD
   6 # for this particular configuration, but some shells, instead of
   7 # keeping the changes in LD private, export them just because LD is
   8 # exported.
   9 ORIGINAL_LD_FOR_MULTILIBS=$LD
  10
  11 dnl Default to --enable-multilib
  12 AC_ARG_ENABLE(multilib,
  13 [  --enable-multilib       build many library versions (default)],
  14 [case "${enableval}" in
  15   yes) multilib=yes ;;
  16   no)  multilib=no ;;
  17   *)   AC_MSG_ERROR(bad value ${enableval} for multilib option) ;;
  18  esac], [multilib=yes])dnl
  19
  20 dnl We may get other options which we don't document:
  21 dnl --with-target-subdir, --with-multisrctop, --with-multisubdir
  22
  23 if test "${srcdir}" = "."; then
  24   if test "${with_target_subdir}" != "."; then
  25     libffi_basedir="${with_multisrctop}../"
  26   else
  27     libffi_basedir="${with_multisrctop}"
  28   fi
  29 else
  30   libffi_basedir=
  31 fi
  32 AC_SUBST(libffi_basedir)
  33 AC_CONFIG_AUX_DIR(${libffi_basedir}..)
  34
  35 AC_CANONICAL_SYSTEM
  36 target_alias=${target_alias-$host_alias}
  37
  38 AM_PROG_LIBTOOL
  39
  40 AM_INIT_AUTOMAKE(libffi,2.00-beta,no-define)
  41
  42 AC_EXEEXT
  43 AM_MAINTAINER_MODE
  44
  45 AC_PROG_CC
  46
  47 AC_PROG_LIBTOOL
  48
  49 AC_FUNC_MMAP_BLACKLIST
  50
  51 dnl The -no-testsuite modules omit the test subdir.
  52 AM_CONDITIONAL(TESTSUBDIR, test -d $srcdir/testsuite)
  53
  54
  55 TARGETDIR="unknown"
  56 case "$host" in
  57 i*86-*-linux*) TARGET=X86; TARGETDIR=x86;;
  58 i*86-*-solaris*) TARGET=X86; TARGETDIR=x86;;
  59 i*86-*-beos*) TARGET=X86; TARGETDIR=x86;;
  60 i*86-*-freebsd*) TARGET=X86; TARGETDIR=x86;;
  61 i*86-*-netbsdelf*) TARGET=X86; TARGETDIR=x86;;
  62 i*86-*-win32*) TARGET=X86_WIN32; TARGETDIR=x86;;
  63 i*86-*-cygwin*) TARGET=X86_WIN32; TARGETDIR=x86;;
  64 i*86-*-mingw*) TARGET=X86_WIN32; TARGETDIR=x86;;
  65 sparc-sun-4*) TARGET=SPARC; TARGETDIR=sparc;;
  66 sparc*-sun-*) TARGET=SPARC; TARGETDIR=sparc;;
  67 sparc-*-linux* | sparc-*-netbsdelf*) TARGET=SPARC; TARGETDIR=sparc;;
  68 sparc64-*-linux* | sparc64-*-netbsd*) TARGET=SPARC; TARGETDIR=sparc;;
  69 alpha*-*-linux* | alpha*-*-osf* | alpha*-*-freebsd* | alpha*-*-netbsd*) TARGET=ALPHA; TARGETDIR=alpha;;
  70 ia64*-*-*) TARGET=IA64; TARGETDIR=ia64;;
  71 m68k-*-linux*) TARGET=M68K; TARGETDIR=m68k;;
  72 mips64*-*);;
  73 mips-sgi-irix5.* | mips-sgi-irix6.*) TARGET=MIPS_IRIX; TARGETDIR=mips;;
  74 mips*-*-linux*) TARGET=MIPS_LINUX; TARGETDIR=mips;;
  75 powerpc*-*-linux* | powerpc-*-sysv*) TARGET=POWERPC; TARGETDIR=powerpc;;
  76 powerpc-*-beos*) TARGET=POWERPC; TARGETDIR=powerpc;;
  77 powerpc-*-darwin*) TARGET=POWERPC_DARWIN; TARGETDIR=powerpc;;
  78 powerpc-*-aix*) TARGET=POWERPC_AIX; TARGETDIR=powerpc;;
  79 rs6000-*-aix*) TARGET=POWERPC_AIX; TARGETDIR=powerpc;;
  80 arm*-*-linux-*) TARGET=ARM; TARGETDIR=arm;;
  81 arm*-*-netbsdelf*) TARGET=ARM; TARGETDIR=arm;;
  82 s390-*-linux-*) TARGET=S390; TARGETDIR=s390;;
  83 s390x-*-linux-*) TARGET=S390; TARGETDIR=s390;;
  84 x86_64-*-linux*) TARGET=X86_64; TARGETDIR=x86;;
  85 sh-*-linux* | sh[[34]]*-*-linux*) TARGET=SH; TARGETDIR=sh;;
  86 sh64-*-linux* | sh5*-*-linux*) TARGET=SH64; TARGETDIR=sh64;;
  87 esac
  88
  89 AC_SUBST(AM_RUNTESTFLAGS)
  90
  91 if test $TARGETDIR = unknown; then
  92   AC_ERROR("libffi has not been ported to $host.")
  93 fi
  94
  95 AM_CONDITIONAL(MIPS_IRIX, test x$TARGET = xMIPS_IRIX)
  96 AM_CONDITIONAL(MIPS_LINUX, test x$TARGET = xMIPS_LINUX)
  97 AM_CONDITIONAL(SPARC, test x$TARGET = xSPARC)
  98 AM_CONDITIONAL(X86, test x$TARGET = xX86)
  99 AM_CONDITIONAL(X86_WIN32, test x$TARGET = xX86_WIN32)
 100 AM_CONDITIONAL(ALPHA, test x$TARGET = xALPHA)
 101 AM_CONDITIONAL(IA64, test x$TARGET = xIA64)
 102 AM_CONDITIONAL(M68K, test x$TARGET = xM68K)
 103 AM_CONDITIONAL(POWERPC, test x$TARGET = xPOWERPC)
 104 AM_CONDITIONAL(POWERPC_AIX, test x$TARGET = xPOWERPC_AIX)
 105 AM_CONDITIONAL(POWERPC_DARWIN, test x$TARGET = xPOWERPC_DARWIN)
 106 AM_CONDITIONAL(ARM, test x$TARGET = xARM)
 107 AM_CONDITIONAL(S390, test x$TARGET = xS390)
 108 AM_CONDITIONAL(X86_64, test x$TARGET = xX86_64)
 109 AM_CONDITIONAL(SH, test x$TARGET = xSH)
 110 AM_CONDITIONAL(SH64, test x$TARGET = xSH64)
 111
 112 case x$TARGET in
 113   xMIPS*) TARGET=MIPS ;;
 114   *) ;;
 115 esac
 116
 117 AC_HEADER_STDC
 118 AC_CHECK_FUNCS(memcpy)
 119 AC_FUNC_ALLOCA
 120
 121 AC_COMPILE_CHECK_SIZEOF(double)
 122 AC_COMPILE_CHECK_SIZEOF(long double)
 123
 124 # Also AC_SUBST this variable for ffi.h.
 125 HAVE_LONG_DOUBLE=0
 126 if test $ac_cv_sizeof_double != $ac_cv_sizeof_long_double; then
 127   if test $ac_cv_sizeof_long_double != 0; then
 128     HAVE_LONG_DOUBLE=1
 129     AC_DEFINE(HAVE_LONG_DOUBLE, 1, [Define if you have the long double type and it is bigger than a double])
 130   fi
 131 fi
 132 AC_SUBST(HAVE_LONG_DOUBLE)
 133
 134 AC_C_BIGENDIAN_CROSS
 135
 136 if test x$TARGET = xSPARC; then
 137     AC_CACHE_CHECK([assembler and linker support unaligned pc related relocs],
 138         libffi_cv_as_sparc_ua_pcrel, [
 139         save_CFLAGS="$CFLAGS"
 140         save_LDFLAGS="$LDFLAGS"
 141         CFLAGS="$CFLAGS -fpic"
 142         LDFLAGS="$LDFLAGS -shared"
 143         AC_TRY_LINK([asm (".text; foo: nop; .data; .align 4; .byte 0; .uaword %r_disp32(foo); .text");],,
 144                     [libffi_cv_as_sparc_ua_pcrel=yes],
 145                     [libffi_cv_as_sparc_ua_pcrel=no])
 146         CFLAGS="$save_CFLAGS"
 147         LDFLAGS="$save_LDFLAGS"])
 148     if test "x$libffi_cv_as_sparc_ua_pcrel" = xyes; then
 149         AC_DEFINE(HAVE_AS_SPARC_UA_PCREL, 1,
 150                   [Define if your assembler and linker support unaligned PC relative relocs.])
 151     fi
 152
 153     AC_CACHE_CHECK([assembler .register pseudo-op support],
 154        libffi_cv_as_register_pseudo_op, [
 155        libffi_cv_as_register_pseudo_op=unknown
 156        # Check if we have .register
 157        AC_TRY_COMPILE([asm (".register %g2, #scratch");],,
 158                        [libffi_cv_as_register_pseudo_op=yes],
 159                        [libffi_cv_as_register_pseudo_op=no])
 160     ])
 161     if test "x$libffi_cv_as_register_pseudo_op" = xyes; then
 162        AC_DEFINE(HAVE_AS_REGISTER_PSEUDO_OP, 1,
 163                [Define if your assembler supports .register.])
 164     fi
 165 fi
 166
 167 AC_CACHE_CHECK([whether .eh_frame section should be read-only],
 168     libffi_cv_ro_eh_frame, [
 169         libffi_cv_ro_eh_frame=no
 170         echo 'extern void foo (void); void bar (void) { foo (); foo (); }' > conftest.c
 171         if $CC $CFLAGS -S -fpic -fexceptions -o conftest.s conftest.c > /dev/null 2>&1; then
 172             if grep '.section.*eh_frame.*"a"' conftest.s > /dev/null; then
 173                 libffi_cv_ro_eh_frame=yes
 174             elif grep '.section.*eh_frame.*#alloc' conftest.c \
 175                  | grep -v '#write' > /dev/null; then
 176                 libffi_cv_ro_eh_frame=yes
 177             fi
 178         fi
 179         rm -f conftest.*
 180     ])
 181 if test "x$libffi_cv_ro_eh_frame" = xyes; then
 182     AC_DEFINE(HAVE_RO_EH_FRAME, 1,
 183               [Define if .eh_frame sections should be read-only.])
 184     AC_DEFINE(EH_FRAME_FLAGS, "a",
 185               [Define to the flags needed for the .section .eh_frame directive.])
 186 else
 187     AC_DEFINE(EH_FRAME_FLAGS, "aw",
 188               [Define to the flags needed for the .section .eh_frame directive.])
 189 fi
 190
 191 AC_SUBST(TARGET)
 192 AC_SUBST(TARGETDIR)
 193
 194 AC_SUBST(SHELL)
 195
 196 AC_ARG_ENABLE(debug,
 197 [  --enable-debug          debugging mode],
 198   if test "$enable_debug" = "yes"; then
 199     AC_DEFINE(FFI_DEBUG, 1, [Define this if you want extra debugging.])
 200   fi)
 201
 202 AC_ARG_ENABLE(structs,
 203 [  --disable-structs       omit code for struct support],
 204   if test "$enable_structs" = "no"; then
 205     AC_DEFINE(FFI_NO_STRUCTS, 1, [Define this is you do not want support for aggregate types.])
 206   fi)
 207
 208 AC_ARG_ENABLE(raw-api,
 209 [  --disable-raw-api       make the raw api unavailable],
 210   if test "$enable_raw_api" = "no"; then
 211     AC_DEFINE(FFI_NO_RAW_API, 1, [Define this is you do not want support for the raw API.])
 212   fi)
 213
 214 AC_ARG_ENABLE(purify-safety,
 215 [  --enable-purify-safety  purify-safe mode],
 216   if test "$enable_purify_safety" = "yes"; then
 217     AC_DEFINE(USING_PURIFY, 1, [Define this if you are using Purify and want to suppress spurious messages.])
 218   fi)
 219
 220 if test -n "$with_cross_host" &&
 221    test x"$with_cross_host" != x"no"; then
 222   toolexecdir='$(exec_prefix)/$(target_alias)'
 223   toolexeclibdir='$(toolexecdir)/lib'
 224 else
 225   toolexecdir='$(libdir)/gcc-lib/$(target_alias)'
 226   toolexeclibdir='$(libdir)'
 227 fi
 228 multi_os_directory=`$CC -print-multi-os-directory`
 229 case $multi_os_directory in
 230   .) ;; # Avoid trailing /.
 231   *) toolexeclibdir=$toolexeclibdir/$multi_os_directory ;;
 232 esac
 233 AC_SUBST(toolexecdir)
 234 AC_SUBST(toolexeclibdir)
 235
 236 #Figure out where generated headers like ffitarget.h get installed.
 237 changequote(,)dnl
 238 gcc_version_trigger=${srcdir}/../gcc/version.c
 239 gcc_version_full=`grep version_string ${gcc_version_trigger} | sed -e 's/.*\"\([^\"]*\)\".*/\1/'`
 240 gcc_version=`echo ${gcc_version_full} | sed -e 's/\([^ ]*\) .*/\1/'`
 241 tool_include_dir='$(libdir)/gcc/$(target_alias)/'${gcc_version}/include
 242 changequote([,])dnl
 243 AC_SUBST(tool_include_dir)
 244 AC_SUBST(gcc_version)
 245
 246
 247 if test "${multilib}" = "yes"; then
 248   multilib_arg="--enable-multilib"
 249 else
 250   multilib_arg=
 251 fi
 252
 253 AC_OUTPUT(include/Makefile testsuite/Makefile include/ffi.h Makefile,
 254 [
 255 if test -n "$CONFIG_FILES"; then
 256    LD="${ORIGINAL_LD_FOR_MULTILIBS}"
 257    ac_file=Makefile . ${srcdir}/${libffi_basedir}../config-ml.in
 258 fi
 259 ],
 260 srcdir=${srcdir}
 261 host=${host}
 262 target=${target}
 263 with_multisubdir=${with_multisubdir}
 264 ac_configure_args="${multilib_arg} ${ac_configure_args}"
 265 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
 266 libffi_basedir=${libffi_basedir}
 267 CC="${CC}"
 268 DEFS="$DEFS"
 269 ORIGINAL_LD_FOR_MULTILIBS="${ORIGINAL_LD_FOR_MULTILIBS}"
 270
 271 # Make target subdirectories if required.
 272 test -d src || mkdir src
 273 test -d src/${TARGETDIR} || mkdir src/${TARGETDIR}
 274 test -d include || mkdir include
 275
 276 AC_LINK_FILES(src/$TARGETDIR/ffitarget.h, include/ffitarget.h)
 277 )