libffi/configure.ac

   1 dnl Process this with autoconf to create configure
   2
   3 AC_PREREQ(2.59)
   4
   5 AC_INIT([libffi], [2.1], [http://gcc.gnu.org/bugs.html])
   6 AC_CONFIG_HEADERS([fficonfig.h])
   7
   8 AM_ENABLE_MULTILIB(, ..)
   9 if test a = b; then
  10    # This is for automake
  11    AC_CONFIG_AUX_DIR([..])
  12 else
  13    # and this is for autoconf
  14    AC_CONFIG_AUX_DIRS(${multi_basedir})
  15  fi
  16
  17 AC_CANONICAL_SYSTEM
  18 target_alias=${target_alias-$host_alias}
  19
  20 AM_INIT_AUTOMAKE
  21
  22 # The same as in boehm-gc and libstdc++. Have to borrow it from there.
  23 # We must force CC to /not/ be precious variables; otherwise
  24 # the wrong, non-multilib-adjusted value will be used in multilibs.
  25 # As a side effect, we have to subst CFLAGS ourselves.
  26
  27 m4_rename([_AC_ARG_VAR_PRECIOUS],[real_PRECIOUS])
  28 m4_define([_AC_ARG_VAR_PRECIOUS],[])
  29 AC_PROG_CC
  30 m4_rename([real_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
  31
  32 AC_SUBST(CFLAGS)
  33
  34 AM_PROG_AS
  35 AM_PROG_CC_C_O
  36 AC_PROG_LIBTOOL
  37
  38 AM_MAINTAINER_MODE
  39
  40 AC_FUNC_MMAP_BLACKLIST
  41
  42 dnl The -no-testsuite modules omit the test subdir.
  43 AM_CONDITIONAL(TESTSUBDIR, test -d $srcdir/testsuite)
  44
  45 TARGETDIR="unknown"
  46 case "$host" in
  47 i*86-*-linux*) TARGET=X86; TARGETDIR=x86;;
  48 i*86-*-solaris*) TARGET=X86; TARGETDIR=x86;;
  49 i*86-*-beos*) TARGET=X86; TARGETDIR=x86;;
  50 i*86-*-freebsd*) TARGET=X86; TARGETDIR=x86;;
  51 i*86-*-netbsdelf*) TARGET=X86; TARGETDIR=x86;;
  52 i*86-*-win32*) TARGET=X86_WIN32; TARGETDIR=x86;;
  53 i*86-*-cygwin*) TARGET=X86_WIN32; TARGETDIR=x86;;
  54 i*86-*-mingw*) TARGET=X86_WIN32; TARGETDIR=x86;;
  55 sparc-sun-4*) TARGET=SPARC; TARGETDIR=sparc;;
  56 sparc*-sun-*) TARGET=SPARC; TARGETDIR=sparc;;
  57 sparc-*-linux* | sparc-*-netbsdelf*) TARGET=SPARC; TARGETDIR=sparc;;
  58 sparc64-*-linux* | sparc64-*-netbsd*) TARGET=SPARC; TARGETDIR=sparc;;
  59 alpha*-*-linux* | alpha*-*-osf* | alpha*-*-freebsd* | alpha*-*-netbsd*) TARGET=ALPHA; TARGETDIR=alpha;;
  60 ia64*-*-*) TARGET=IA64; TARGETDIR=ia64;;
  61 m68k-*-linux*) TARGET=M68K; TARGETDIR=m68k;;
  62 mips64*-*);;
  63 mips-sgi-irix5.* | mips-sgi-irix6.*) TARGET=MIPS_IRIX; TARGETDIR=mips;;
  64 mips*-*-linux*) TARGET=MIPS_LINUX; TARGETDIR=mips;;
  65 powerpc*-*-linux* | powerpc-*-sysv*) TARGET=POWERPC; TARGETDIR=powerpc;;
  66 powerpc-*-beos*) TARGET=POWERPC; TARGETDIR=powerpc;;
  67 powerpc-*-darwin*) TARGET=POWERPC_DARWIN; TARGETDIR=powerpc;;
  68 powerpc-*-aix*) TARGET=POWERPC_AIX; TARGETDIR=powerpc;;
  69 rs6000-*-aix*) TARGET=POWERPC_AIX; TARGETDIR=powerpc;;
  70 arm*-*-linux-*) TARGET=ARM; TARGETDIR=arm;;
  71 arm*-*-netbsdelf*) TARGET=ARM; TARGETDIR=arm;;
  72 s390-*-linux-*) TARGET=S390; TARGETDIR=s390;;
  73 s390x-*-linux-*) TARGET=S390; TARGETDIR=s390;;
  74 x86_64-*-linux*) TARGET=X86_64; TARGETDIR=x86;;
  75 sh-*-linux* | sh[[34]]*-*-linux*) TARGET=SH; TARGETDIR=sh;;
  76 sh64-*-linux* | sh5*-*-linux*) TARGET=SH64; TARGETDIR=sh64;;
  77 hppa-*-linux* | parisc-*-linux*) TARGET=PA; TARGETDIR=pa;;
  78 esac
  79
  80 AC_SUBST(AM_RUNTESTFLAGS)
  81
  82 if test $TARGETDIR = unknown; then
  83   AC_MSG_ERROR(["libffi has not been ported to $host."])
  84 fi
  85
  86 AM_CONDITIONAL(MIPS_IRIX, test x$TARGET = xMIPS_IRIX)
  87 AM_CONDITIONAL(MIPS_LINUX, test x$TARGET = xMIPS_LINUX)
  88 AM_CONDITIONAL(SPARC, test x$TARGET = xSPARC)
  89 AM_CONDITIONAL(X86, test x$TARGET = xX86)
  90 AM_CONDITIONAL(X86_WIN32, test x$TARGET = xX86_WIN32)
  91 AM_CONDITIONAL(ALPHA, test x$TARGET = xALPHA)
  92 AM_CONDITIONAL(IA64, test x$TARGET = xIA64)
  93 AM_CONDITIONAL(M68K, test x$TARGET = xM68K)
  94 AM_CONDITIONAL(POWERPC, test x$TARGET = xPOWERPC)
  95 AM_CONDITIONAL(POWERPC_AIX, test x$TARGET = xPOWERPC_AIX)
  96 AM_CONDITIONAL(POWERPC_DARWIN, test x$TARGET = xPOWERPC_DARWIN)
  97 AM_CONDITIONAL(ARM, test x$TARGET = xARM)
  98 AM_CONDITIONAL(S390, test x$TARGET = xS390)
  99 AM_CONDITIONAL(X86_64, test x$TARGET = xX86_64)
 100 AM_CONDITIONAL(SH, test x$TARGET = xSH)
 101 AM_CONDITIONAL(SH64, test x$TARGET = xSH64)
 102 AM_CONDITIONAL(PA, test x$TARGET = xPA)
 103
 104 case x$TARGET in
 105   xMIPS*) TARGET=MIPS ;;
 106   *) ;;
 107 esac
 108
 109 AC_HEADER_STDC
 110 AC_CHECK_FUNCS(memcpy)
 111 AC_FUNC_ALLOCA
 112
 113 AC_COMPILE_CHECK_SIZEOF(double)
 114 AC_COMPILE_CHECK_SIZEOF(long double)
 115
 116 # Also AC_SUBST this variable for ffi.h.
 117 HAVE_LONG_DOUBLE=0
 118 if test $ac_cv_sizeof_double != $ac_cv_sizeof_long_double; then
 119   if test $ac_cv_sizeof_long_double != 0; then
 120     HAVE_LONG_DOUBLE=1
 121     AC_DEFINE(HAVE_LONG_DOUBLE, 1, [Define if you have the long double type and it is bigger than a double])
 122   fi
 123 fi
 124 AC_SUBST(HAVE_LONG_DOUBLE)
 125
 126 AC_C_BIGENDIAN_CROSS
 127
 128 if test x$TARGET = xSPARC; then
 129     AC_CACHE_CHECK([assembler and linker support unaligned pc related relocs],
 130         libffi_cv_as_sparc_ua_pcrel, [
 131         save_CFLAGS="$CFLAGS"
 132         save_LDFLAGS="$LDFLAGS"
 133         CFLAGS="$CFLAGS -fpic"
 134         LDFLAGS="$LDFLAGS -shared"
 135         AC_TRY_LINK([asm (".text; foo: nop; .data; .align 4; .byte 0; .uaword %r_disp32(foo); .text");],,
 136                     [libffi_cv_as_sparc_ua_pcrel=yes],
 137                     [libffi_cv_as_sparc_ua_pcrel=no])
 138         CFLAGS="$save_CFLAGS"
 139         LDFLAGS="$save_LDFLAGS"])
 140     if test "x$libffi_cv_as_sparc_ua_pcrel" = xyes; then
 141         AC_DEFINE(HAVE_AS_SPARC_UA_PCREL, 1,
 142                   [Define if your assembler and linker support unaligned PC relative relocs.])
 143     fi
 144
 145     AC_CACHE_CHECK([assembler .register pseudo-op support],
 146        libffi_cv_as_register_pseudo_op, [
 147        libffi_cv_as_register_pseudo_op=unknown
 148        # Check if we have .register
 149        AC_TRY_COMPILE([asm (".register %g2, #scratch");],,
 150                        [libffi_cv_as_register_pseudo_op=yes],
 151                        [libffi_cv_as_register_pseudo_op=no])
 152     ])
 153     if test "x$libffi_cv_as_register_pseudo_op" = xyes; then
 154        AC_DEFINE(HAVE_AS_REGISTER_PSEUDO_OP, 1,
 155                [Define if your assembler supports .register.])
 156     fi
 157 fi
 158
 159 AC_CACHE_CHECK([whether .eh_frame section should be read-only],
 160     libffi_cv_ro_eh_frame, [
 161         libffi_cv_ro_eh_frame=no
 162         echo 'extern void foo (void); void bar (void) { foo (); foo (); }' > conftest.c
 163         if $CC $CFLAGS -S -fpic -fexceptions -o conftest.s conftest.c > /dev/null 2>&1; then
 164             if grep '.section.*eh_frame.*"a"' conftest.s > /dev/null; then
 165                 libffi_cv_ro_eh_frame=yes
 166             elif grep '.section.*eh_frame.*#alloc' conftest.c \
 167                  | grep -v '#write' > /dev/null; then
 168                 libffi_cv_ro_eh_frame=yes
 169             fi
 170         fi
 171         rm -f conftest.*
 172     ])
 173 if test "x$libffi_cv_ro_eh_frame" = xyes; then
 174     AC_DEFINE(HAVE_RO_EH_FRAME, 1,
 175               [Define if .eh_frame sections should be read-only.])
 176     AC_DEFINE(EH_FRAME_FLAGS, "a",
 177               [Define to the flags needed for the .section .eh_frame directive.])
 178 else
 179     AC_DEFINE(EH_FRAME_FLAGS, "aw",
 180               [Define to the flags needed for the .section .eh_frame directive.])
 181 fi
 182
 183 AC_SUBST(TARGET)
 184 AC_SUBST(TARGETDIR)
 185
 186 AC_SUBST(SHELL)
 187
 188 AC_ARG_ENABLE(debug,
 189 [  --enable-debug          debugging mode],
 190   if test "$enable_debug" = "yes"; then
 191     AC_DEFINE(FFI_DEBUG, 1, [Define this if you want extra debugging.])
 192   fi)
 193
 194 AC_ARG_ENABLE(structs,
 195 [  --disable-structs       omit code for struct support],
 196   if test "$enable_structs" = "no"; then
 197     AC_DEFINE(FFI_NO_STRUCTS, 1, [Define this is you do not want support for aggregate types.])
 198   fi)
 199
 200 AC_ARG_ENABLE(raw-api,
 201 [  --disable-raw-api       make the raw api unavailable],
 202   if test "$enable_raw_api" = "no"; then
 203     AC_DEFINE(FFI_NO_RAW_API, 1, [Define this is you do not want support for the raw API.])
 204   fi)
 205
 206 AC_ARG_ENABLE(purify-safety,
 207 [  --enable-purify-safety  purify-safe mode],
 208   if test "$enable_purify_safety" = "yes"; then
 209     AC_DEFINE(USING_PURIFY, 1, [Define this if you are using Purify and want to suppress spurious messages.])
 210   fi)
 211
 212 if test -n "$with_cross_host" &&
 213    test x"$with_cross_host" != x"no"; then
 214   toolexecdir='$(exec_prefix)/$(target_alias)'
 215   toolexeclibdir='$(toolexecdir)/lib'
 216 else
 217   toolexecdir='$(libdir)/gcc-lib/$(target_alias)'
 218   toolexeclibdir='$(libdir)'
 219 fi
 220 multi_os_directory=`$CC -print-multi-os-directory`
 221 case $multi_os_directory in
 222   .) ;; # Avoid trailing /.
 223   *) toolexeclibdir=$toolexeclibdir/$multi_os_directory ;;
 224 esac
 225 AC_SUBST(toolexecdir)
 226 AC_SUBST(toolexeclibdir)
 227
 228 #Figure out where generated headers like ffitarget.h get installed.
 229 changequote(,)dnl
 230 gcc_version_trigger=${srcdir}/../gcc/version.c
 231 gcc_version_full=`grep version_string ${gcc_version_trigger} | sed -e 's/.*\"\([^\"]*\)\".*/\1/'`
 232 gcc_version=`echo ${gcc_version_full} | sed -e 's/\([^ ]*\) .*/\1/'`
 233 tool_include_dir='$(libdir)/gcc/$(target_alias)/'${gcc_version}/include
 234 changequote([,])dnl
 235 AC_SUBST(tool_include_dir)
 236 AC_SUBST(gcc_version)
 237
 238
 239 if test "${multilib}" = "yes"; then
 240   multilib_arg="--enable-multilib"
 241 else
 242   multilib_arg=
 243 fi
 244
 245 AC_CONFIG_COMMANDS(include, [test -d include || mkdir include])
 246 AC_CONFIG_COMMANDS(src, [
 247 test -d src || mkdir src
 248 test -d src/$TARGETDIR || mkdir src/$TARGETDIR
 249 ], [TARGETDIR="$TARGETDIR"])
 250
 251 AC_CONFIG_LINKS(include/ffitarget.h:src/$TARGETDIR/ffitarget.h)
 252
 253 AC_CONFIG_FILES(include/Makefile include/ffi.h Makefile testsuite/Makefile)
 254
 255 AC_OUTPUT