OSDN Git Service

2006-12-14 Andreas Tobler <a.tobler@schweiz.org>
[pf3gnuchains/gcc-fork.git] / libffi / configure.ac
1 dnl Process this with autoconf to create configure
2
3 AC_PREREQ(2.59)
4
5 AC_INIT([libffi], [2.1], [http://gcc.gnu.org/bugs.html])
6 AC_CONFIG_HEADERS([fficonfig.h])
7
8 AM_ENABLE_MULTILIB(, ..)
9
10 AC_CANONICAL_SYSTEM
11 target_alias=${target_alias-$host_alias}
12
13 . ${srcdir}/configure.host
14
15 AM_INIT_AUTOMAKE
16
17 # The same as in boehm-gc and libstdc++. Have to borrow it from there.
18 # We must force CC to /not/ be precious variables; otherwise
19 # the wrong, non-multilib-adjusted value will be used in multilibs.
20 # As a side effect, we have to subst CFLAGS ourselves.
21
22 m4_rename([_AC_ARG_VAR_PRECIOUS],[real_PRECIOUS])
23 m4_define([_AC_ARG_VAR_PRECIOUS],[])
24 AC_PROG_CC
25 m4_rename([real_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
26
27 AC_SUBST(CFLAGS)
28
29 AM_PROG_AS
30 AM_PROG_CC_C_O
31 AC_PROG_LIBTOOL
32
33 AM_MAINTAINER_MODE
34
35 AC_CHECK_HEADERS(sys/mman.h)
36 AC_CHECK_FUNCS(mmap)
37 AC_FUNC_MMAP_BLACKLIST
38
39 dnl The -no-testsuite modules omit the test subdir.
40 AM_CONDITIONAL(TESTSUBDIR, test -d $srcdir/testsuite)
41
42 TARGETDIR="unknown"
43 case "$host" in
44 i*86-*-linux*) TARGET=X86; TARGETDIR=x86;;
45 i*86-*-gnu*) TARGET=X86; TARGETDIR=x86;;
46 i*86-*-solaris2.1[[0-9]]*) TARGET=X86_64; TARGETDIR=x86;;
47 i*86-*-solaris*) TARGET=X86; TARGETDIR=x86;;
48 i*86-*-beos*) TARGET=X86; TARGETDIR=x86;;
49 i*86-*-darwin*) TARGET=X86_DARWIN; TARGETDIR=x86;;
50 i*86-*-freebsd* | i*86-*-kfreebsd*-gnu) TARGET=X86; TARGETDIR=x86;;
51 i*86-*-netbsdelf* | i*86-*-knetbsd*-gnu) TARGET=X86; TARGETDIR=x86;;
52 i*86-*-rtems*) TARGET=X86; TARGETDIR=x86;;
53 i*86-*-win32*) TARGET=X86_WIN32; TARGETDIR=x86;;
54 i*86-*-cygwin*) TARGET=X86_WIN32; TARGETDIR=x86;;
55 i*86-*-mingw*) TARGET=X86_WIN32; TARGETDIR=x86;;
56 frv-*-*) TARGET=FRV; TARGETDIR=frv;;
57 sparc-sun-4*) TARGET=SPARC; TARGETDIR=sparc;;
58 sparc*-sun-*) TARGET=SPARC; TARGETDIR=sparc;;
59 sparc-*-linux* | sparc-*-netbsdelf* | sparc-*-knetbsd*-gnu) TARGET=SPARC; TARGETDIR=sparc;;
60 sparc*-*-rtems*) TARGET=SPARC; TARGETDIR=sparc;;
61 sparc64-*-linux* | sparc64-*-freebsd* | sparc64-*-netbsd* | sparc64-*-knetbsd*-gnu) TARGET=SPARC; TARGETDIR=sparc;;
62 alpha*-*-linux* | alpha*-*-osf* | alpha*-*-freebsd* | alpha*-*-kfreebsd*-gnu | alpha*-*-netbsd* | alpha*-*-knetbsd*-gnu) TARGET=ALPHA; TARGETDIR=alpha;;
63 ia64*-*-*) TARGET=IA64; TARGETDIR=ia64;;
64 m32r*-*-linux* ) TARGET=M32R; TARGETDIR=m32r;;
65 m68k-*-linux*) TARGET=M68K; TARGETDIR=m68k;;
66 mips64*-*);;
67 mips-sgi-irix5.* | mips-sgi-irix6.*) TARGET=MIPS_IRIX; TARGETDIR=mips;;
68 mips*-*-linux*) TARGET=MIPS_LINUX; TARGETDIR=mips;;
69 powerpc*-*-linux* | powerpc-*-sysv*) TARGET=POWERPC; TARGETDIR=powerpc;;
70 powerpc-*-beos*) TARGET=POWERPC; TARGETDIR=powerpc;;
71 powerpc-*-darwin*) TARGET=POWERPC_DARWIN; TARGETDIR=powerpc;;
72 powerpc-*-aix*) TARGET=POWERPC_AIX; TARGETDIR=powerpc;;
73 powerpc-*-freebsd*) TARGET=POWERPC_FREEBSD; TARGETDIR=powerpc;;
74 powerpc*-*-rtems*) TARGET=POWERPC; TARGETDIR=powerpc;;
75 rs6000-*-aix*) TARGET=POWERPC_AIX; TARGETDIR=powerpc;;
76 arm*-*-linux-*) TARGET=ARM; TARGETDIR=arm;;
77 arm*-*-netbsdelf* | arm*-*-knetbsd*-gnu) TARGET=ARM; TARGETDIR=arm;;
78 arm*-*-rtems*) TARGET=ARM; TARGETDIR=arm;;
79 cris-*-*) TARGET=LIBFFI_CRIS; TARGETDIR=cris;;
80 s390-*-linux-*) TARGET=S390; TARGETDIR=s390;;
81 s390x-*-linux-*) TARGET=S390; TARGETDIR=s390;;
82 x86_64-*-linux* | x86_64-*-freebsd* | x86_64-*-kfreebsd*-gnu) TARGET=X86_64; TARGETDIR=x86;;
83 x86_64-*-darwin*) TARGET=X86_DARWIN; TARGETDIR=x86;;
84 sh-*-linux* | sh[[34]]*-*-linux*) TARGET=SH; TARGETDIR=sh;;
85 sh-*-rtems*) TARGET=SH; TARGETDIR=sh;;
86 sh64-*-linux* | sh5*-*-linux*) TARGET=SH64; TARGETDIR=sh64;;
87 hppa*-*-linux* | parisc*-*-linux*) TARGET=PA_LINUX; TARGETDIR=pa;;
88 hppa*64-*-hpux*) TARGET=PA64_HPUX; TARGETDIR=pa;;
89 hppa*-*-hpux*) TARGET=PA_HPUX; TARGETDIR=pa;;
90 esac
91
92 AC_SUBST(AM_RUNTESTFLAGS)
93
94 if test $TARGETDIR = unknown; then
95   AC_MSG_ERROR(["libffi has not been ported to $host."])
96 fi
97
98 AM_CONDITIONAL(MIPS_IRIX, test x$TARGET = xMIPS_IRIX)
99 AM_CONDITIONAL(MIPS_LINUX, test x$TARGET = xMIPS_LINUX)
100 AM_CONDITIONAL(SPARC, test x$TARGET = xSPARC)
101 AM_CONDITIONAL(X86, test x$TARGET = xX86)
102 AM_CONDITIONAL(X86_WIN32, test x$TARGET = xX86_WIN32)
103 AM_CONDITIONAL(X86_DARWIN, test x$TARGET = xX86_DARWIN)
104 AM_CONDITIONAL(ALPHA, test x$TARGET = xALPHA)
105 AM_CONDITIONAL(IA64, test x$TARGET = xIA64)
106 AM_CONDITIONAL(M32R, test x$TARGET = xM32R)
107 AM_CONDITIONAL(M68K, test x$TARGET = xM68K)
108 AM_CONDITIONAL(POWERPC, test x$TARGET = xPOWERPC)
109 AM_CONDITIONAL(POWERPC_AIX, test x$TARGET = xPOWERPC_AIX)
110 AM_CONDITIONAL(POWERPC_DARWIN, test x$TARGET = xPOWERPC_DARWIN)
111 AM_CONDITIONAL(POWERPC_FREEBSD, test x$TARGET = xPOWERPC_FREEBSD)
112 AM_CONDITIONAL(ARM, test x$TARGET = xARM)
113 AM_CONDITIONAL(LIBFFI_CRIS, test x$TARGET = xLIBFFI_CRIS)
114 AM_CONDITIONAL(FRV, test x$TARGET = xFRV)
115 AM_CONDITIONAL(S390, test x$TARGET = xS390)
116 AM_CONDITIONAL(X86_64, test x$TARGET = xX86_64)
117 AM_CONDITIONAL(SH, test x$TARGET = xSH)
118 AM_CONDITIONAL(SH64, test x$TARGET = xSH64)
119 AM_CONDITIONAL(PA_LINUX, test x$TARGET = xPA_LINUX)
120 AM_CONDITIONAL(PA_HPUX, test x$TARGET = xPA_HPUX)
121 AM_CONDITIONAL(PA64_HPUX, test x$TARGET = xPA64_HPUX)
122
123 case x$TARGET in
124   xMIPS*) TARGET=MIPS ;;
125   *) ;;
126 esac
127
128 AC_HEADER_STDC
129 AC_CHECK_FUNCS(memcpy)
130 AC_FUNC_ALLOCA
131
132 AC_CHECK_SIZEOF(double)
133 AC_CHECK_SIZEOF(long double)
134
135 # Also AC_SUBST this variable for ffi.h.
136 HAVE_LONG_DOUBLE=0
137 if test $ac_cv_sizeof_double != $ac_cv_sizeof_long_double; then
138   if test $ac_cv_sizeof_long_double != 0; then
139     HAVE_LONG_DOUBLE=1
140     AC_DEFINE(HAVE_LONG_DOUBLE, 1, [Define if you have the long double type and it is bigger than a double])
141   fi
142 fi
143 AC_SUBST(HAVE_LONG_DOUBLE)
144
145 AC_C_BIGENDIAN
146
147 if test x$TARGET = xSPARC; then
148     AC_CACHE_CHECK([assembler and linker support unaligned pc related relocs],
149         libffi_cv_as_sparc_ua_pcrel, [
150         save_CFLAGS="$CFLAGS"
151         save_LDFLAGS="$LDFLAGS"
152         CFLAGS="$CFLAGS -fpic"
153         LDFLAGS="$LDFLAGS -shared"
154         AC_TRY_LINK([asm (".text; foo: nop; .data; .align 4; .byte 0; .uaword %r_disp32(foo); .text");],,
155                     [libffi_cv_as_sparc_ua_pcrel=yes],
156                     [libffi_cv_as_sparc_ua_pcrel=no])
157         CFLAGS="$save_CFLAGS"
158         LDFLAGS="$save_LDFLAGS"])
159     if test "x$libffi_cv_as_sparc_ua_pcrel" = xyes; then
160         AC_DEFINE(HAVE_AS_SPARC_UA_PCREL, 1,
161                   [Define if your assembler and linker support unaligned PC relative relocs.])
162     fi
163
164     AC_CACHE_CHECK([assembler .register pseudo-op support],
165        libffi_cv_as_register_pseudo_op, [
166        libffi_cv_as_register_pseudo_op=unknown
167        # Check if we have .register
168        AC_TRY_COMPILE([asm (".register %g2, #scratch");],,
169                        [libffi_cv_as_register_pseudo_op=yes],
170                        [libffi_cv_as_register_pseudo_op=no])
171     ])
172     if test "x$libffi_cv_as_register_pseudo_op" = xyes; then
173        AC_DEFINE(HAVE_AS_REGISTER_PSEUDO_OP, 1,
174                [Define if your assembler supports .register.])
175     fi
176 fi
177
178 AC_CACHE_CHECK([whether .eh_frame section should be read-only],
179     libffi_cv_ro_eh_frame, [
180         libffi_cv_ro_eh_frame=no
181         echo 'extern void foo (void); void bar (void) { foo (); foo (); }' > conftest.c
182         if $CC $CFLAGS -S -fpic -fexceptions -o conftest.s conftest.c > /dev/null 2>&1; then
183             if grep '.section.*eh_frame.*"a"' conftest.s > /dev/null; then
184                 libffi_cv_ro_eh_frame=yes
185             elif grep '.section.*eh_frame.*#alloc' conftest.c \
186                  | grep -v '#write' > /dev/null; then
187                 libffi_cv_ro_eh_frame=yes
188             fi
189         fi
190         rm -f conftest.*
191     ])
192 if test "x$libffi_cv_ro_eh_frame" = xyes; then
193     AC_DEFINE(HAVE_RO_EH_FRAME, 1,
194               [Define if .eh_frame sections should be read-only.])
195     AC_DEFINE(EH_FRAME_FLAGS, "a",
196               [Define to the flags needed for the .section .eh_frame directive.])
197 else
198     AC_DEFINE(EH_FRAME_FLAGS, "aw",
199               [Define to the flags needed for the .section .eh_frame directive.])
200 fi
201
202 AC_CACHE_CHECK([for __attribute__((visibility("hidden")))],
203     libffi_cv_hidden_visibility_attribute, [
204         echo 'int __attribute__ ((visibility ("hidden"))) foo (void) { return 1; }' > conftest.c
205         libffi_cv_hidden_visibility_attribute=no
206         if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
207             if grep '\.hidden.*foo' conftest.s >/dev/null; then
208                 libffi_cv_hidden_visibility_attribute=yes
209             fi
210         fi
211         rm -f conftest.*
212     ])
213 if test $libffi_cv_hidden_visibility_attribute = yes; then
214     AC_DEFINE(HAVE_HIDDEN_VISIBILITY_ATTRIBUTE, 1,
215               [Define if __attribute__((visibility("hidden"))) is supported.])
216 fi
217
218 AH_BOTTOM([
219 #ifdef HAVE_HIDDEN_VISIBILITY_ATTRIBUTE
220 #ifdef LIBFFI_ASM
221 #define FFI_HIDDEN(name) .hidden name
222 #else
223 #define FFI_HIDDEN __attribute__ ((visibility ("hidden")))
224 #endif
225 #else
226 #ifdef LIBFFI_ASM
227 #define FFI_HIDDEN(name)
228 #else
229 #define FFI_HIDDEN
230 #endif
231 #endif
232 ])
233
234 AC_SUBST(TARGET)
235 AC_SUBST(TARGETDIR)
236
237 AC_SUBST(SHELL)
238
239 AC_ARG_ENABLE(debug,
240 [  --enable-debug          debugging mode],
241   if test "$enable_debug" = "yes"; then
242     AC_DEFINE(FFI_DEBUG, 1, [Define this if you want extra debugging.])
243   fi)
244
245 AC_ARG_ENABLE(structs,
246 [  --disable-structs       omit code for struct support],
247   if test "$enable_structs" = "no"; then
248     AC_DEFINE(FFI_NO_STRUCTS, 1, [Define this is you do not want support for aggregate types.])
249   fi)
250
251 AC_ARG_ENABLE(raw-api,
252 [  --disable-raw-api       make the raw api unavailable],
253   if test "$enable_raw_api" = "no"; then
254     AC_DEFINE(FFI_NO_RAW_API, 1, [Define this is you do not want support for the raw API.])
255   fi)
256
257 AC_ARG_ENABLE(purify-safety,
258 [  --enable-purify-safety  purify-safe mode],
259   if test "$enable_purify_safety" = "yes"; then
260     AC_DEFINE(USING_PURIFY, 1, [Define this if you are using Purify and want to suppress spurious messages.])
261   fi)
262
263 if test -n "$with_cross_host" &&
264    test x"$with_cross_host" != x"no"; then
265   toolexecdir='$(exec_prefix)/$(target_alias)'
266   toolexeclibdir='$(toolexecdir)/lib'
267 else
268   toolexecdir='$(libdir)/gcc-lib/$(target_alias)'
269   toolexeclibdir='$(libdir)'
270 fi
271 multi_os_directory=`$CC -print-multi-os-directory`
272 case $multi_os_directory in
273   .) ;; # Avoid trailing /.
274   *) toolexeclibdir=$toolexeclibdir/$multi_os_directory ;;
275 esac
276 AC_SUBST(toolexecdir)
277 AC_SUBST(toolexeclibdir)
278
279 if test "${multilib}" = "yes"; then
280   multilib_arg="--enable-multilib"
281 else
282   multilib_arg=
283 fi
284
285 AC_CONFIG_COMMANDS(include, [test -d include || mkdir include])
286 AC_CONFIG_COMMANDS(src, [
287 test -d src || mkdir src
288 test -d src/$TARGETDIR || mkdir src/$TARGETDIR
289 ], [TARGETDIR="$TARGETDIR"])
290
291 AC_CONFIG_LINKS(include/ffitarget.h:src/$TARGETDIR/ffitarget.h)
292
293 AC_CONFIG_FILES(include/Makefile include/ffi.h Makefile testsuite/Makefile)
294
295 AC_OUTPUT