OSDN Git Service

ChangeLog:
[pf3gnuchains/gcc-fork.git] / libffi / configure.ac
1 dnl Process this with autoconf to create configure
2
3 AC_PREREQ(2.59)
4
5 AC_INIT([libffi], [2.1], [http://gcc.gnu.org/bugs.html])
6 AC_CONFIG_HEADERS([fficonfig.h])
7
8 AM_ENABLE_MULTILIB(, ..)
9
10 AC_CANONICAL_SYSTEM
11 target_alias=${target_alias-$host_alias}
12
13 AM_INIT_AUTOMAKE
14
15 # The same as in boehm-gc and libstdc++. Have to borrow it from there.
16 # We must force CC to /not/ be precious variables; otherwise
17 # the wrong, non-multilib-adjusted value will be used in multilibs.
18 # As a side effect, we have to subst CFLAGS ourselves.
19
20 m4_rename([_AC_ARG_VAR_PRECIOUS],[real_PRECIOUS])
21 m4_define([_AC_ARG_VAR_PRECIOUS],[])
22 AC_PROG_CC
23 m4_rename([real_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
24
25 AC_SUBST(CFLAGS)
26
27 AM_PROG_AS
28 AM_PROG_CC_C_O
29 AC_PROG_LIBTOOL
30
31 AM_MAINTAINER_MODE
32
33 AC_CHECK_HEADERS(sys/mman.h)
34 AC_CHECK_FUNCS(mmap)
35 AC_FUNC_MMAP_BLACKLIST
36
37 dnl The -no-testsuite modules omit the test subdir.
38 AM_CONDITIONAL(TESTSUBDIR, test -d $srcdir/testsuite)
39
40 TARGETDIR="unknown"
41 case "$host" in
42 i*86-*-linux*) TARGET=X86; TARGETDIR=x86;;
43 i*86-*-solaris*) TARGET=X86; TARGETDIR=x86;;
44 i*86-*-beos*) TARGET=X86; TARGETDIR=x86;;
45 i*86-*-freebsd* | i*86-*-kfreebsd*-gnu) TARGET=X86; TARGETDIR=x86;;
46 i*86-*-netbsdelf* | i*86-*-knetbsd*-gnu) TARGET=X86; TARGETDIR=x86;;
47 i*86-*-win32*) TARGET=X86_WIN32; TARGETDIR=x86;;
48 i*86-*-cygwin*) TARGET=X86_WIN32; TARGETDIR=x86;;
49 i*86-*-mingw*) TARGET=X86_WIN32; TARGETDIR=x86;;
50 sparc-sun-4*) TARGET=SPARC; TARGETDIR=sparc;;
51 sparc*-sun-*) TARGET=SPARC; TARGETDIR=sparc;;
52 sparc-*-linux* | sparc-*-netbsdelf* | sparc-*-knetbsd*-gnu) TARGET=SPARC; TARGETDIR=sparc;;
53 sparc64-*-linux* | sparc64-*-netbsd* | sparc64-*-knetbsd*-gnu) TARGET=SPARC; TARGETDIR=sparc;;
54 alpha*-*-linux* | alpha*-*-osf* | alpha*-*-freebsd* | alpha*-*-kfreebsd*-gnu | alpha*-*-netbsd* | alpha*-*-knetbsd*-gnu) TARGET=ALPHA; TARGETDIR=alpha;;
55 ia64*-*-*) TARGET=IA64; TARGETDIR=ia64;;
56 m68k-*-linux*) TARGET=M68K; TARGETDIR=m68k;;
57 mips64*-*);;
58 mips-sgi-irix5.* | mips-sgi-irix6.*) TARGET=MIPS_IRIX; TARGETDIR=mips;;
59 mips*-*-linux*) TARGET=MIPS_LINUX; TARGETDIR=mips;;
60 powerpc*-*-linux* | powerpc-*-sysv*) TARGET=POWERPC; TARGETDIR=powerpc;;
61 powerpc-*-beos*) TARGET=POWERPC; TARGETDIR=powerpc;;
62 powerpc-*-darwin*) TARGET=POWERPC_DARWIN; TARGETDIR=powerpc;;
63 powerpc-*-aix*) TARGET=POWERPC_AIX; TARGETDIR=powerpc;;
64 rs6000-*-aix*) TARGET=POWERPC_AIX; TARGETDIR=powerpc;;
65 arm*-*-linux-*) TARGET=ARM; TARGETDIR=arm;;
66 arm*-*-netbsdelf* | arm*-*-knetbsd*-gnu) TARGET=ARM; TARGETDIR=arm;;
67 s390-*-linux-*) TARGET=S390; TARGETDIR=s390;;
68 s390x-*-linux-*) TARGET=S390; TARGETDIR=s390;;
69 x86_64-*-linux* | x86_64-*-freebsd* | x86_64-*-kfreebsd*-gnu) TARGET=X86_64; TARGETDIR=x86;;
70 sh-*-linux* | sh[[34]]*-*-linux*) TARGET=SH; TARGETDIR=sh;;
71 sh64-*-linux* | sh5*-*-linux*) TARGET=SH64; TARGETDIR=sh64;;
72 hppa-*-linux* | parisc-*-linux*) TARGET=PA; TARGETDIR=pa;;
73 esac
74
75 AC_SUBST(AM_RUNTESTFLAGS)
76
77 if test $TARGETDIR = unknown; then
78   AC_MSG_ERROR(["libffi has not been ported to $host."])
79 fi
80
81 AM_CONDITIONAL(MIPS_IRIX, test x$TARGET = xMIPS_IRIX)
82 AM_CONDITIONAL(MIPS_LINUX, test x$TARGET = xMIPS_LINUX)
83 AM_CONDITIONAL(SPARC, test x$TARGET = xSPARC)
84 AM_CONDITIONAL(X86, test x$TARGET = xX86)
85 AM_CONDITIONAL(X86_WIN32, test x$TARGET = xX86_WIN32)
86 AM_CONDITIONAL(ALPHA, test x$TARGET = xALPHA)
87 AM_CONDITIONAL(IA64, test x$TARGET = xIA64)
88 AM_CONDITIONAL(M68K, test x$TARGET = xM68K)
89 AM_CONDITIONAL(POWERPC, test x$TARGET = xPOWERPC)
90 AM_CONDITIONAL(POWERPC_AIX, test x$TARGET = xPOWERPC_AIX)
91 AM_CONDITIONAL(POWERPC_DARWIN, test x$TARGET = xPOWERPC_DARWIN)
92 AM_CONDITIONAL(ARM, test x$TARGET = xARM)
93 AM_CONDITIONAL(S390, test x$TARGET = xS390)
94 AM_CONDITIONAL(X86_64, test x$TARGET = xX86_64)
95 AM_CONDITIONAL(SH, test x$TARGET = xSH)
96 AM_CONDITIONAL(SH64, test x$TARGET = xSH64)
97 AM_CONDITIONAL(PA, test x$TARGET = xPA)
98
99 case x$TARGET in
100   xMIPS*) TARGET=MIPS ;;
101   *) ;;
102 esac
103
104 AC_HEADER_STDC
105 AC_CHECK_FUNCS(memcpy)
106 AC_FUNC_ALLOCA
107
108 AC_COMPILE_CHECK_SIZEOF(double)
109 AC_COMPILE_CHECK_SIZEOF(long double)
110
111 # Also AC_SUBST this variable for ffi.h.
112 HAVE_LONG_DOUBLE=0
113 if test $ac_cv_sizeof_double != $ac_cv_sizeof_long_double; then
114   if test $ac_cv_sizeof_long_double != 0; then
115     HAVE_LONG_DOUBLE=1
116     AC_DEFINE(HAVE_LONG_DOUBLE, 1, [Define if you have the long double type and it is bigger than a double])
117   fi
118 fi
119 AC_SUBST(HAVE_LONG_DOUBLE)
120
121 AC_C_BIGENDIAN_CROSS
122
123 if test x$TARGET = xSPARC; then
124     AC_CACHE_CHECK([assembler and linker support unaligned pc related relocs],
125         libffi_cv_as_sparc_ua_pcrel, [
126         save_CFLAGS="$CFLAGS"
127         save_LDFLAGS="$LDFLAGS"
128         CFLAGS="$CFLAGS -fpic"
129         LDFLAGS="$LDFLAGS -shared"
130         AC_TRY_LINK([asm (".text; foo: nop; .data; .align 4; .byte 0; .uaword %r_disp32(foo); .text");],,
131                     [libffi_cv_as_sparc_ua_pcrel=yes],
132                     [libffi_cv_as_sparc_ua_pcrel=no])
133         CFLAGS="$save_CFLAGS"
134         LDFLAGS="$save_LDFLAGS"])
135     if test "x$libffi_cv_as_sparc_ua_pcrel" = xyes; then
136         AC_DEFINE(HAVE_AS_SPARC_UA_PCREL, 1,
137                   [Define if your assembler and linker support unaligned PC relative relocs.])
138     fi
139
140     AC_CACHE_CHECK([assembler .register pseudo-op support],
141        libffi_cv_as_register_pseudo_op, [
142        libffi_cv_as_register_pseudo_op=unknown
143        # Check if we have .register
144        AC_TRY_COMPILE([asm (".register %g2, #scratch");],,
145                        [libffi_cv_as_register_pseudo_op=yes],
146                        [libffi_cv_as_register_pseudo_op=no])
147     ])
148     if test "x$libffi_cv_as_register_pseudo_op" = xyes; then
149        AC_DEFINE(HAVE_AS_REGISTER_PSEUDO_OP, 1,
150                [Define if your assembler supports .register.])
151     fi
152 fi
153
154 AC_CACHE_CHECK([whether .eh_frame section should be read-only],
155     libffi_cv_ro_eh_frame, [
156         libffi_cv_ro_eh_frame=no
157         echo 'extern void foo (void); void bar (void) { foo (); foo (); }' > conftest.c
158         if $CC $CFLAGS -S -fpic -fexceptions -o conftest.s conftest.c > /dev/null 2>&1; then
159             if grep '.section.*eh_frame.*"a"' conftest.s > /dev/null; then
160                 libffi_cv_ro_eh_frame=yes
161             elif grep '.section.*eh_frame.*#alloc' conftest.c \
162                  | grep -v '#write' > /dev/null; then
163                 libffi_cv_ro_eh_frame=yes
164             fi
165         fi
166         rm -f conftest.*
167     ])
168 if test "x$libffi_cv_ro_eh_frame" = xyes; then
169     AC_DEFINE(HAVE_RO_EH_FRAME, 1,
170               [Define if .eh_frame sections should be read-only.])
171     AC_DEFINE(EH_FRAME_FLAGS, "a",
172               [Define to the flags needed for the .section .eh_frame directive.])
173 else
174     AC_DEFINE(EH_FRAME_FLAGS, "aw",
175               [Define to the flags needed for the .section .eh_frame directive.])
176 fi
177
178 AC_SUBST(TARGET)
179 AC_SUBST(TARGETDIR)
180
181 AC_SUBST(SHELL)
182
183 AC_ARG_ENABLE(debug,
184 [  --enable-debug          debugging mode],
185   if test "$enable_debug" = "yes"; then
186     AC_DEFINE(FFI_DEBUG, 1, [Define this if you want extra debugging.])
187   fi)
188
189 AC_ARG_ENABLE(structs,
190 [  --disable-structs       omit code for struct support],
191   if test "$enable_structs" = "no"; then
192     AC_DEFINE(FFI_NO_STRUCTS, 1, [Define this is you do not want support for aggregate types.])
193   fi)
194
195 AC_ARG_ENABLE(raw-api,
196 [  --disable-raw-api       make the raw api unavailable],
197   if test "$enable_raw_api" = "no"; then
198     AC_DEFINE(FFI_NO_RAW_API, 1, [Define this is you do not want support for the raw API.])
199   fi)
200
201 AC_ARG_ENABLE(purify-safety,
202 [  --enable-purify-safety  purify-safe mode],
203   if test "$enable_purify_safety" = "yes"; then
204     AC_DEFINE(USING_PURIFY, 1, [Define this if you are using Purify and want to suppress spurious messages.])
205   fi)
206
207 if test -n "$with_cross_host" &&
208    test x"$with_cross_host" != x"no"; then
209   toolexecdir='$(exec_prefix)/$(target_alias)'
210   toolexeclibdir='$(toolexecdir)/lib'
211 else
212   toolexecdir='$(libdir)/gcc-lib/$(target_alias)'
213   toolexeclibdir='$(libdir)'
214 fi
215 multi_os_directory=`$CC -print-multi-os-directory`
216 case $multi_os_directory in
217   .) ;; # Avoid trailing /.
218   *) toolexeclibdir=$toolexeclibdir/$multi_os_directory ;;
219 esac
220 AC_SUBST(toolexecdir)
221 AC_SUBST(toolexeclibdir)
222
223 #Figure out where generated headers like ffitarget.h get installed.
224 changequote(,)dnl
225 gcc_version_trigger=${srcdir}/../gcc/version.c
226 gcc_version_full=`grep version_string ${gcc_version_trigger} | sed -e 's/.*\"\([^\"]*\)\".*/\1/'`
227 gcc_version=`echo ${gcc_version_full} | sed -e 's/\([^ ]*\) .*/\1/'`
228 tool_include_dir='$(libdir)/gcc/$(target_alias)/'${gcc_version}/include
229 changequote([,])dnl
230 AC_SUBST(tool_include_dir)
231 AC_SUBST(gcc_version)
232
233
234 if test "${multilib}" = "yes"; then
235   multilib_arg="--enable-multilib"
236 else
237   multilib_arg=
238 fi
239
240 AC_CONFIG_COMMANDS(include, [test -d include || mkdir include])
241 AC_CONFIG_COMMANDS(src, [
242 test -d src || mkdir src
243 test -d src/$TARGETDIR || mkdir src/$TARGETDIR
244 ], [TARGETDIR="$TARGETDIR"])
245
246 AC_CONFIG_LINKS(include/ffitarget.h:src/$TARGETDIR/ffitarget.h)
247
248 AC_CONFIG_FILES(include/Makefile include/ffi.h Makefile testsuite/Makefile)
249
250 AC_OUTPUT