OSDN Git Service

* Makefile.am: Add CRIS support.
[pf3gnuchains/gcc-fork.git] / libffi / configure.ac
1 dnl Process this with autoconf to create configure
2
3 AC_PREREQ(2.59)
4
5 AC_INIT([libffi], [2.1], [http://gcc.gnu.org/bugs.html])
6 AC_CONFIG_HEADERS([fficonfig.h])
7
8 AM_ENABLE_MULTILIB(, ..)
9
10 AC_CANONICAL_SYSTEM
11 target_alias=${target_alias-$host_alias}
12
13 . ${srcdir}/configure.host
14
15 AM_INIT_AUTOMAKE
16
17 # The same as in boehm-gc and libstdc++. Have to borrow it from there.
18 # We must force CC to /not/ be precious variables; otherwise
19 # the wrong, non-multilib-adjusted value will be used in multilibs.
20 # As a side effect, we have to subst CFLAGS ourselves.
21
22 m4_rename([_AC_ARG_VAR_PRECIOUS],[real_PRECIOUS])
23 m4_define([_AC_ARG_VAR_PRECIOUS],[])
24 AC_PROG_CC
25 m4_rename([real_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
26
27 AC_SUBST(CFLAGS)
28
29 AM_PROG_AS
30 AM_PROG_CC_C_O
31 AC_PROG_LIBTOOL
32
33 AM_MAINTAINER_MODE
34
35 AC_CHECK_HEADERS(sys/mman.h)
36 AC_CHECK_FUNCS(mmap)
37 AC_FUNC_MMAP_BLACKLIST
38
39 dnl The -no-testsuite modules omit the test subdir.
40 AM_CONDITIONAL(TESTSUBDIR, test -d $srcdir/testsuite)
41
42 TARGETDIR="unknown"
43 case "$host" in
44 i*86-*-linux*) TARGET=X86; TARGETDIR=x86;;
45 i*86-*-solaris*) TARGET=X86; TARGETDIR=x86;;
46 i*86-*-beos*) TARGET=X86; TARGETDIR=x86;;
47 i*86-*-freebsd* | i*86-*-kfreebsd*-gnu) TARGET=X86; TARGETDIR=x86;;
48 i*86-*-netbsdelf* | i*86-*-knetbsd*-gnu) TARGET=X86; TARGETDIR=x86;;
49 i*86-*-win32*) TARGET=X86_WIN32; TARGETDIR=x86;;
50 i*86-*-cygwin*) TARGET=X86_WIN32; TARGETDIR=x86;;
51 i*86-*-mingw*) TARGET=X86_WIN32; TARGETDIR=x86;;
52 frv-*-*) TARGET=FRV; TARGETDIR=frv;;
53 sparc-sun-4*) TARGET=SPARC; TARGETDIR=sparc;;
54 sparc*-sun-*) TARGET=SPARC; TARGETDIR=sparc;;
55 sparc-*-linux* | sparc-*-netbsdelf* | sparc-*-knetbsd*-gnu) TARGET=SPARC; TARGETDIR=sparc;;
56 sparc64-*-linux* | sparc64-*-netbsd* | sparc64-*-knetbsd*-gnu) TARGET=SPARC; TARGETDIR=sparc;;
57 alpha*-*-linux* | alpha*-*-osf* | alpha*-*-freebsd* | alpha*-*-kfreebsd*-gnu | alpha*-*-netbsd* | alpha*-*-knetbsd*-gnu) TARGET=ALPHA; TARGETDIR=alpha;;
58 ia64*-*-*) TARGET=IA64; TARGETDIR=ia64;;
59 m32r*-*-linux* ) TARGET=M32R; TARGETDIR=m32r;;
60 m68k-*-linux*) TARGET=M68K; TARGETDIR=m68k;;
61 mips64*-*);;
62 mips-sgi-irix5.* | mips-sgi-irix6.*) TARGET=MIPS_IRIX; TARGETDIR=mips;;
63 mips*-*-linux*) TARGET=MIPS_LINUX; TARGETDIR=mips;;
64 powerpc*-*-linux* | powerpc-*-sysv*) TARGET=POWERPC; TARGETDIR=powerpc;;
65 powerpc-*-beos*) TARGET=POWERPC; TARGETDIR=powerpc;;
66 powerpc-*-darwin*) TARGET=POWERPC_DARWIN; TARGETDIR=powerpc;;
67 powerpc-*-aix*) TARGET=POWERPC_AIX; TARGETDIR=powerpc;;
68 rs6000-*-aix*) TARGET=POWERPC_AIX; TARGETDIR=powerpc;;
69 arm*-*-linux-*) TARGET=ARM; TARGETDIR=arm;;
70 arm*-*-netbsdelf* | arm*-*-knetbsd*-gnu) TARGET=ARM; TARGETDIR=arm;;
71 cris-*-*) TARGET=LIBFFI_CRIS; TARGETDIR=cris;;
72 s390-*-linux-*) TARGET=S390; TARGETDIR=s390;;
73 s390x-*-linux-*) TARGET=S390; TARGETDIR=s390;;
74 x86_64-*-linux* | x86_64-*-freebsd* | x86_64-*-kfreebsd*-gnu) TARGET=X86_64; TARGETDIR=x86;;
75 sh-*-linux* | sh[[34]]*-*-linux*) TARGET=SH; TARGETDIR=sh;;
76 sh64-*-linux* | sh5*-*-linux*) TARGET=SH64; TARGETDIR=sh64;;
77 hppa-*-linux* | parisc-*-linux*) TARGET=PA; TARGETDIR=pa;;
78 esac
79
80 AC_SUBST(AM_RUNTESTFLAGS)
81
82 if test $TARGETDIR = unknown; then
83   AC_MSG_ERROR(["libffi has not been ported to $host."])
84 fi
85
86 AM_CONDITIONAL(MIPS_IRIX, test x$TARGET = xMIPS_IRIX)
87 AM_CONDITIONAL(MIPS_LINUX, test x$TARGET = xMIPS_LINUX)
88 AM_CONDITIONAL(SPARC, test x$TARGET = xSPARC)
89 AM_CONDITIONAL(X86, test x$TARGET = xX86)
90 AM_CONDITIONAL(X86_WIN32, test x$TARGET = xX86_WIN32)
91 AM_CONDITIONAL(ALPHA, test x$TARGET = xALPHA)
92 AM_CONDITIONAL(IA64, test x$TARGET = xIA64)
93 AM_CONDITIONAL(M32R, test x$TARGET = xM32R)
94 AM_CONDITIONAL(M68K, test x$TARGET = xM68K)
95 AM_CONDITIONAL(POWERPC, test x$TARGET = xPOWERPC)
96 AM_CONDITIONAL(POWERPC_AIX, test x$TARGET = xPOWERPC_AIX)
97 AM_CONDITIONAL(POWERPC_DARWIN, test x$TARGET = xPOWERPC_DARWIN)
98 AM_CONDITIONAL(ARM, test x$TARGET = xARM)
99 AM_CONDITIONAL(LIBFFI_CRIS, test x$TARGET = xLIBFFI_CRIS)
100 AM_CONDITIONAL(FRV, test x$TARGET = xFRV)
101 AM_CONDITIONAL(S390, test x$TARGET = xS390)
102 AM_CONDITIONAL(X86_64, test x$TARGET = xX86_64)
103 AM_CONDITIONAL(SH, test x$TARGET = xSH)
104 AM_CONDITIONAL(SH64, test x$TARGET = xSH64)
105 AM_CONDITIONAL(PA, test x$TARGET = xPA)
106
107 case x$TARGET in
108   xMIPS*) TARGET=MIPS ;;
109   *) ;;
110 esac
111
112 AC_HEADER_STDC
113 AC_CHECK_FUNCS(memcpy)
114 AC_FUNC_ALLOCA
115
116 AC_COMPILE_CHECK_SIZEOF(double)
117 AC_COMPILE_CHECK_SIZEOF(long double)
118
119 # Also AC_SUBST this variable for ffi.h.
120 HAVE_LONG_DOUBLE=0
121 if test $ac_cv_sizeof_double != $ac_cv_sizeof_long_double; then
122   if test $ac_cv_sizeof_long_double != 0; then
123     HAVE_LONG_DOUBLE=1
124     AC_DEFINE(HAVE_LONG_DOUBLE, 1, [Define if you have the long double type and it is bigger than a double])
125   fi
126 fi
127 AC_SUBST(HAVE_LONG_DOUBLE)
128
129 AC_C_BIGENDIAN_CROSS
130
131 if test x$TARGET = xSPARC; then
132     AC_CACHE_CHECK([assembler and linker support unaligned pc related relocs],
133         libffi_cv_as_sparc_ua_pcrel, [
134         save_CFLAGS="$CFLAGS"
135         save_LDFLAGS="$LDFLAGS"
136         CFLAGS="$CFLAGS -fpic"
137         LDFLAGS="$LDFLAGS -shared"
138         AC_TRY_LINK([asm (".text; foo: nop; .data; .align 4; .byte 0; .uaword %r_disp32(foo); .text");],,
139                     [libffi_cv_as_sparc_ua_pcrel=yes],
140                     [libffi_cv_as_sparc_ua_pcrel=no])
141         CFLAGS="$save_CFLAGS"
142         LDFLAGS="$save_LDFLAGS"])
143     if test "x$libffi_cv_as_sparc_ua_pcrel" = xyes; then
144         AC_DEFINE(HAVE_AS_SPARC_UA_PCREL, 1,
145                   [Define if your assembler and linker support unaligned PC relative relocs.])
146     fi
147
148     AC_CACHE_CHECK([assembler .register pseudo-op support],
149        libffi_cv_as_register_pseudo_op, [
150        libffi_cv_as_register_pseudo_op=unknown
151        # Check if we have .register
152        AC_TRY_COMPILE([asm (".register %g2, #scratch");],,
153                        [libffi_cv_as_register_pseudo_op=yes],
154                        [libffi_cv_as_register_pseudo_op=no])
155     ])
156     if test "x$libffi_cv_as_register_pseudo_op" = xyes; then
157        AC_DEFINE(HAVE_AS_REGISTER_PSEUDO_OP, 1,
158                [Define if your assembler supports .register.])
159     fi
160 fi
161
162 AC_CACHE_CHECK([whether .eh_frame section should be read-only],
163     libffi_cv_ro_eh_frame, [
164         libffi_cv_ro_eh_frame=no
165         echo 'extern void foo (void); void bar (void) { foo (); foo (); }' > conftest.c
166         if $CC $CFLAGS -S -fpic -fexceptions -o conftest.s conftest.c > /dev/null 2>&1; then
167             if grep '.section.*eh_frame.*"a"' conftest.s > /dev/null; then
168                 libffi_cv_ro_eh_frame=yes
169             elif grep '.section.*eh_frame.*#alloc' conftest.c \
170                  | grep -v '#write' > /dev/null; then
171                 libffi_cv_ro_eh_frame=yes
172             fi
173         fi
174         rm -f conftest.*
175     ])
176 if test "x$libffi_cv_ro_eh_frame" = xyes; then
177     AC_DEFINE(HAVE_RO_EH_FRAME, 1,
178               [Define if .eh_frame sections should be read-only.])
179     AC_DEFINE(EH_FRAME_FLAGS, "a",
180               [Define to the flags needed for the .section .eh_frame directive.])
181 else
182     AC_DEFINE(EH_FRAME_FLAGS, "aw",
183               [Define to the flags needed for the .section .eh_frame directive.])
184 fi
185
186 AC_SUBST(TARGET)
187 AC_SUBST(TARGETDIR)
188
189 AC_SUBST(SHELL)
190
191 AC_ARG_ENABLE(debug,
192 [  --enable-debug          debugging mode],
193   if test "$enable_debug" = "yes"; then
194     AC_DEFINE(FFI_DEBUG, 1, [Define this if you want extra debugging.])
195   fi)
196
197 AC_ARG_ENABLE(structs,
198 [  --disable-structs       omit code for struct support],
199   if test "$enable_structs" = "no"; then
200     AC_DEFINE(FFI_NO_STRUCTS, 1, [Define this is you do not want support for aggregate types.])
201   fi)
202
203 AC_ARG_ENABLE(raw-api,
204 [  --disable-raw-api       make the raw api unavailable],
205   if test "$enable_raw_api" = "no"; then
206     AC_DEFINE(FFI_NO_RAW_API, 1, [Define this is you do not want support for the raw API.])
207   fi)
208
209 AC_ARG_ENABLE(purify-safety,
210 [  --enable-purify-safety  purify-safe mode],
211   if test "$enable_purify_safety" = "yes"; then
212     AC_DEFINE(USING_PURIFY, 1, [Define this if you are using Purify and want to suppress spurious messages.])
213   fi)
214
215 if test -n "$with_cross_host" &&
216    test x"$with_cross_host" != x"no"; then
217   toolexecdir='$(exec_prefix)/$(target_alias)'
218   toolexeclibdir='$(toolexecdir)/lib'
219 else
220   toolexecdir='$(libdir)/gcc-lib/$(target_alias)'
221   toolexeclibdir='$(libdir)'
222 fi
223 multi_os_directory=`$CC -print-multi-os-directory`
224 case $multi_os_directory in
225   .) ;; # Avoid trailing /.
226   *) toolexeclibdir=$toolexeclibdir/$multi_os_directory ;;
227 esac
228 AC_SUBST(toolexecdir)
229 AC_SUBST(toolexeclibdir)
230
231 if test "${multilib}" = "yes"; then
232   multilib_arg="--enable-multilib"
233 else
234   multilib_arg=
235 fi
236
237 AC_CONFIG_COMMANDS(include, [test -d include || mkdir include])
238 AC_CONFIG_COMMANDS(src, [
239 test -d src || mkdir src
240 test -d src/$TARGETDIR || mkdir src/$TARGETDIR
241 ], [TARGETDIR="$TARGETDIR"])
242
243 AC_CONFIG_LINKS(include/ffitarget.h:src/$TARGETDIR/ffitarget.h)
244
245 AC_CONFIG_FILES(include/Makefile include/ffi.h Makefile testsuite/Makefile)
246
247 AC_OUTPUT