OSDN Git Service

2005-05-29 Ralf Corsepius <ralf.corsepius@rtems.org>
[pf3gnuchains/gcc-fork.git] / libffi / configure.ac
1 dnl Process this with autoconf to create configure
2
3 AC_PREREQ(2.59)
4
5 AC_INIT([libffi], [2.1], [http://gcc.gnu.org/bugs.html])
6 AC_CONFIG_HEADERS([fficonfig.h])
7
8 AM_ENABLE_MULTILIB(, ..)
9
10 AC_CANONICAL_SYSTEM
11 target_alias=${target_alias-$host_alias}
12
13 . ${srcdir}/configure.host
14
15 AM_INIT_AUTOMAKE
16
17 # The same as in boehm-gc and libstdc++. Have to borrow it from there.
18 # We must force CC to /not/ be precious variables; otherwise
19 # the wrong, non-multilib-adjusted value will be used in multilibs.
20 # As a side effect, we have to subst CFLAGS ourselves.
21
22 m4_rename([_AC_ARG_VAR_PRECIOUS],[real_PRECIOUS])
23 m4_define([_AC_ARG_VAR_PRECIOUS],[])
24 AC_PROG_CC
25 m4_rename([real_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
26
27 AC_SUBST(CFLAGS)
28
29 AM_PROG_AS
30 AM_PROG_CC_C_O
31 AC_PROG_LIBTOOL
32
33 AM_MAINTAINER_MODE
34
35 AC_CHECK_HEADERS(sys/mman.h)
36 AC_CHECK_FUNCS(mmap)
37 AC_FUNC_MMAP_BLACKLIST
38
39 dnl The -no-testsuite modules omit the test subdir.
40 AM_CONDITIONAL(TESTSUBDIR, test -d $srcdir/testsuite)
41
42 TARGETDIR="unknown"
43 case "$host" in
44 i*86-*-linux*) TARGET=X86; TARGETDIR=x86;;
45 i*86-*-solaris*) TARGET=X86; TARGETDIR=x86;;
46 i*86-*-beos*) TARGET=X86; TARGETDIR=x86;;
47 i*86-*-freebsd* | i*86-*-kfreebsd*-gnu) TARGET=X86; TARGETDIR=x86;;
48 i*86-*-netbsdelf* | i*86-*-knetbsd*-gnu) TARGET=X86; TARGETDIR=x86;;
49 i*86-*-rtems*) TARGET=X86; TARGETDIR=x86;;
50 i*86-*-win32*) TARGET=X86_WIN32; TARGETDIR=x86;;
51 i*86-*-cygwin*) TARGET=X86_WIN32; TARGETDIR=x86;;
52 i*86-*-mingw*) TARGET=X86_WIN32; TARGETDIR=x86;;
53 frv-*-*) TARGET=FRV; TARGETDIR=frv;;
54 sparc-sun-4*) TARGET=SPARC; TARGETDIR=sparc;;
55 sparc*-sun-*) TARGET=SPARC; TARGETDIR=sparc;;
56 sparc-*-linux* | sparc-*-netbsdelf* | sparc-*-knetbsd*-gnu) TARGET=SPARC; TARGETDIR=sparc;;
57 sparc*-*-rtems*) TARGET=SPARC; TARGETDIR=sparc;;
58 sparc64-*-linux* | sparc64-*-netbsd* | sparc64-*-knetbsd*-gnu) TARGET=SPARC; TARGETDIR=sparc;;
59 alpha*-*-linux* | alpha*-*-osf* | alpha*-*-freebsd* | alpha*-*-kfreebsd*-gnu | alpha*-*-netbsd* | alpha*-*-knetbsd*-gnu) TARGET=ALPHA; TARGETDIR=alpha;;
60 ia64*-*-*) TARGET=IA64; TARGETDIR=ia64;;
61 m32r*-*-linux* ) TARGET=M32R; TARGETDIR=m32r;;
62 m68k-*-linux*) TARGET=M68K; TARGETDIR=m68k;;
63 mips64*-*);;
64 mips-sgi-irix5.* | mips-sgi-irix6.*) TARGET=MIPS_IRIX; TARGETDIR=mips;;
65 mips*-*-linux*) TARGET=MIPS_LINUX; TARGETDIR=mips;;
66 powerpc*-*-linux* | powerpc-*-sysv*) TARGET=POWERPC; TARGETDIR=powerpc;;
67 powerpc-*-beos*) TARGET=POWERPC; TARGETDIR=powerpc;;
68 powerpc-*-darwin*) TARGET=POWERPC_DARWIN; TARGETDIR=powerpc;;
69 powerpc-*-aix*) TARGET=POWERPC_AIX; TARGETDIR=powerpc;;
70 powerpc*-*-rtems*) TARGET=POWERPC; TARGETDIR=powerpc;;
71 rs6000-*-aix*) TARGET=POWERPC_AIX; TARGETDIR=powerpc;;
72 arm*-*-linux-*) TARGET=ARM; TARGETDIR=arm;;
73 arm*-*-netbsdelf* | arm*-*-knetbsd*-gnu) TARGET=ARM; TARGETDIR=arm;;
74 arm*-*-rtems*) TARGET=ARM; TARGETDIR=arm;;
75 cris-*-*) TARGET=LIBFFI_CRIS; TARGETDIR=cris;;
76 s390-*-linux-*) TARGET=S390; TARGETDIR=s390;;
77 s390x-*-linux-*) TARGET=S390; TARGETDIR=s390;;
78 x86_64-*-linux* | x86_64-*-freebsd* | x86_64-*-kfreebsd*-gnu) TARGET=X86_64; TARGETDIR=x86;;
79 sh-*-linux* | sh[[34]]*-*-linux*) TARGET=SH; TARGETDIR=sh;;
80 sh-*-rtems* | sh[[34]]*-*-linux*) TARGET=SH; TARGETDIR=sh;;
81 sh64-*-linux* | sh5*-*-linux*) TARGET=SH64; TARGETDIR=sh64;;
82 hppa-*-linux* | parisc-*-linux*) TARGET=PA; TARGETDIR=pa;;
83 esac
84
85 AC_SUBST(AM_RUNTESTFLAGS)
86
87 if test $TARGETDIR = unknown; then
88   AC_MSG_ERROR(["libffi has not been ported to $host."])
89 fi
90
91 AM_CONDITIONAL(MIPS_IRIX, test x$TARGET = xMIPS_IRIX)
92 AM_CONDITIONAL(MIPS_LINUX, test x$TARGET = xMIPS_LINUX)
93 AM_CONDITIONAL(SPARC, test x$TARGET = xSPARC)
94 AM_CONDITIONAL(X86, test x$TARGET = xX86)
95 AM_CONDITIONAL(X86_WIN32, test x$TARGET = xX86_WIN32)
96 AM_CONDITIONAL(ALPHA, test x$TARGET = xALPHA)
97 AM_CONDITIONAL(IA64, test x$TARGET = xIA64)
98 AM_CONDITIONAL(M32R, test x$TARGET = xM32R)
99 AM_CONDITIONAL(M68K, test x$TARGET = xM68K)
100 AM_CONDITIONAL(POWERPC, test x$TARGET = xPOWERPC)
101 AM_CONDITIONAL(POWERPC_AIX, test x$TARGET = xPOWERPC_AIX)
102 AM_CONDITIONAL(POWERPC_DARWIN, test x$TARGET = xPOWERPC_DARWIN)
103 AM_CONDITIONAL(ARM, test x$TARGET = xARM)
104 AM_CONDITIONAL(LIBFFI_CRIS, test x$TARGET = xLIBFFI_CRIS)
105 AM_CONDITIONAL(FRV, test x$TARGET = xFRV)
106 AM_CONDITIONAL(S390, test x$TARGET = xS390)
107 AM_CONDITIONAL(X86_64, test x$TARGET = xX86_64)
108 AM_CONDITIONAL(SH, test x$TARGET = xSH)
109 AM_CONDITIONAL(SH64, test x$TARGET = xSH64)
110 AM_CONDITIONAL(PA, test x$TARGET = xPA)
111
112 case x$TARGET in
113   xMIPS*) TARGET=MIPS ;;
114   *) ;;
115 esac
116
117 AC_HEADER_STDC
118 AC_CHECK_FUNCS(memcpy)
119 AC_FUNC_ALLOCA
120
121 AC_COMPILE_CHECK_SIZEOF(double)
122 AC_COMPILE_CHECK_SIZEOF(long double)
123
124 # Also AC_SUBST this variable for ffi.h.
125 HAVE_LONG_DOUBLE=0
126 if test $ac_cv_sizeof_double != $ac_cv_sizeof_long_double; then
127   if test $ac_cv_sizeof_long_double != 0; then
128     HAVE_LONG_DOUBLE=1
129     AC_DEFINE(HAVE_LONG_DOUBLE, 1, [Define if you have the long double type and it is bigger than a double])
130   fi
131 fi
132 AC_SUBST(HAVE_LONG_DOUBLE)
133
134 AC_C_BIGENDIAN_CROSS
135
136 if test x$TARGET = xSPARC; then
137     AC_CACHE_CHECK([assembler and linker support unaligned pc related relocs],
138         libffi_cv_as_sparc_ua_pcrel, [
139         save_CFLAGS="$CFLAGS"
140         save_LDFLAGS="$LDFLAGS"
141         CFLAGS="$CFLAGS -fpic"
142         LDFLAGS="$LDFLAGS -shared"
143         AC_TRY_LINK([asm (".text; foo: nop; .data; .align 4; .byte 0; .uaword %r_disp32(foo); .text");],,
144                     [libffi_cv_as_sparc_ua_pcrel=yes],
145                     [libffi_cv_as_sparc_ua_pcrel=no])
146         CFLAGS="$save_CFLAGS"
147         LDFLAGS="$save_LDFLAGS"])
148     if test "x$libffi_cv_as_sparc_ua_pcrel" = xyes; then
149         AC_DEFINE(HAVE_AS_SPARC_UA_PCREL, 1,
150                   [Define if your assembler and linker support unaligned PC relative relocs.])
151     fi
152
153     AC_CACHE_CHECK([assembler .register pseudo-op support],
154        libffi_cv_as_register_pseudo_op, [
155        libffi_cv_as_register_pseudo_op=unknown
156        # Check if we have .register
157        AC_TRY_COMPILE([asm (".register %g2, #scratch");],,
158                        [libffi_cv_as_register_pseudo_op=yes],
159                        [libffi_cv_as_register_pseudo_op=no])
160     ])
161     if test "x$libffi_cv_as_register_pseudo_op" = xyes; then
162        AC_DEFINE(HAVE_AS_REGISTER_PSEUDO_OP, 1,
163                [Define if your assembler supports .register.])
164     fi
165 fi
166
167 AC_CACHE_CHECK([whether .eh_frame section should be read-only],
168     libffi_cv_ro_eh_frame, [
169         libffi_cv_ro_eh_frame=no
170         echo 'extern void foo (void); void bar (void) { foo (); foo (); }' > conftest.c
171         if $CC $CFLAGS -S -fpic -fexceptions -o conftest.s conftest.c > /dev/null 2>&1; then
172             if grep '.section.*eh_frame.*"a"' conftest.s > /dev/null; then
173                 libffi_cv_ro_eh_frame=yes
174             elif grep '.section.*eh_frame.*#alloc' conftest.c \
175                  | grep -v '#write' > /dev/null; then
176                 libffi_cv_ro_eh_frame=yes
177             fi
178         fi
179         rm -f conftest.*
180     ])
181 if test "x$libffi_cv_ro_eh_frame" = xyes; then
182     AC_DEFINE(HAVE_RO_EH_FRAME, 1,
183               [Define if .eh_frame sections should be read-only.])
184     AC_DEFINE(EH_FRAME_FLAGS, "a",
185               [Define to the flags needed for the .section .eh_frame directive.])
186 else
187     AC_DEFINE(EH_FRAME_FLAGS, "aw",
188               [Define to the flags needed for the .section .eh_frame directive.])
189 fi
190
191 AC_SUBST(TARGET)
192 AC_SUBST(TARGETDIR)
193
194 AC_SUBST(SHELL)
195
196 AC_ARG_ENABLE(debug,
197 [  --enable-debug          debugging mode],
198   if test "$enable_debug" = "yes"; then
199     AC_DEFINE(FFI_DEBUG, 1, [Define this if you want extra debugging.])
200   fi)
201
202 AC_ARG_ENABLE(structs,
203 [  --disable-structs       omit code for struct support],
204   if test "$enable_structs" = "no"; then
205     AC_DEFINE(FFI_NO_STRUCTS, 1, [Define this is you do not want support for aggregate types.])
206   fi)
207
208 AC_ARG_ENABLE(raw-api,
209 [  --disable-raw-api       make the raw api unavailable],
210   if test "$enable_raw_api" = "no"; then
211     AC_DEFINE(FFI_NO_RAW_API, 1, [Define this is you do not want support for the raw API.])
212   fi)
213
214 AC_ARG_ENABLE(purify-safety,
215 [  --enable-purify-safety  purify-safe mode],
216   if test "$enable_purify_safety" = "yes"; then
217     AC_DEFINE(USING_PURIFY, 1, [Define this if you are using Purify and want to suppress spurious messages.])
218   fi)
219
220 if test -n "$with_cross_host" &&
221    test x"$with_cross_host" != x"no"; then
222   toolexecdir='$(exec_prefix)/$(target_alias)'
223   toolexeclibdir='$(toolexecdir)/lib'
224 else
225   toolexecdir='$(libdir)/gcc-lib/$(target_alias)'
226   toolexeclibdir='$(libdir)'
227 fi
228 multi_os_directory=`$CC -print-multi-os-directory`
229 case $multi_os_directory in
230   .) ;; # Avoid trailing /.
231   *) toolexeclibdir=$toolexeclibdir/$multi_os_directory ;;
232 esac
233 AC_SUBST(toolexecdir)
234 AC_SUBST(toolexeclibdir)
235
236 if test "${multilib}" = "yes"; then
237   multilib_arg="--enable-multilib"
238 else
239   multilib_arg=
240 fi
241
242 AC_CONFIG_COMMANDS(include, [test -d include || mkdir include])
243 AC_CONFIG_COMMANDS(src, [
244 test -d src || mkdir src
245 test -d src/$TARGETDIR || mkdir src/$TARGETDIR
246 ], [TARGETDIR="$TARGETDIR"])
247
248 AC_CONFIG_LINKS(include/ffitarget.h:src/$TARGETDIR/ffitarget.h)
249
250 AC_CONFIG_FILES(include/Makefile include/ffi.h Makefile testsuite/Makefile)
251
252 AC_OUTPUT