libffi/configure.ac

   1 dnl Process this with autoconf to create configure
   2
   3 AC_PREREQ(2.59)
   4
   5 AC_INIT([libffi], [2.1], [http://gcc.gnu.org/bugs.html])
   6 AC_CONFIG_HEADERS([fficonfig.h])
   7
   8 AM_ENABLE_MULTILIB(, ..)
   9
  10 AC_CANONICAL_SYSTEM
  11 target_alias=${target_alias-$host_alias}
  12
  13 . ${srcdir}/configure.host
  14
  15 AM_INIT_AUTOMAKE
  16
  17 # The same as in boehm-gc and libstdc++. Have to borrow it from there.
  18 # We must force CC to /not/ be precious variables; otherwise
  19 # the wrong, non-multilib-adjusted value will be used in multilibs.
  20 # As a side effect, we have to subst CFLAGS ourselves.
  21
  22 m4_rename([_AC_ARG_VAR_PRECIOUS],[real_PRECIOUS])
  23 m4_define([_AC_ARG_VAR_PRECIOUS],[])
  24 AC_PROG_CC
  25 m4_rename([real_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
  26
  27 AC_SUBST(CFLAGS)
  28
  29 AM_PROG_AS
  30 AM_PROG_CC_C_O
  31 AC_PROG_LIBTOOL
  32
  33 AM_MAINTAINER_MODE
  34
  35 AC_CHECK_HEADERS(sys/mman.h)
  36 AC_CHECK_FUNCS(mmap)
  37 AC_FUNC_MMAP_BLACKLIST
  38
  39 dnl The -no-testsuite modules omit the test subdir.
  40 AM_CONDITIONAL(TESTSUBDIR, test -d $srcdir/testsuite)
  41
  42 TARGETDIR="unknown"
  43 case "$host" in
  44 i*86-*-linux*) TARGET=X86; TARGETDIR=x86;;
  45 i*86-*-solaris*) TARGET=X86; TARGETDIR=x86;;
  46 i*86-*-beos*) TARGET=X86; TARGETDIR=x86;;
  47 i*86-*-freebsd* | i*86-*-kfreebsd*-gnu) TARGET=X86; TARGETDIR=x86;;
  48 i*86-*-netbsdelf* | i*86-*-knetbsd*-gnu) TARGET=X86; TARGETDIR=x86;;
  49 i*86-*-win32*) TARGET=X86_WIN32; TARGETDIR=x86;;
  50 i*86-*-cygwin*) TARGET=X86_WIN32; TARGETDIR=x86;;
  51 i*86-*-mingw*) TARGET=X86_WIN32; TARGETDIR=x86;;
  52 frv-*-*) TARGET=FRV; TARGETDIR=frv;;
  53 sparc-sun-4*) TARGET=SPARC; TARGETDIR=sparc;;
  54 sparc*-sun-*) TARGET=SPARC; TARGETDIR=sparc;;
  55 sparc-*-linux* | sparc-*-netbsdelf* | sparc-*-knetbsd*-gnu) TARGET=SPARC; TARGETDIR=sparc;;
  56 sparc64-*-linux* | sparc64-*-netbsd* | sparc64-*-knetbsd*-gnu) TARGET=SPARC; TARGETDIR=sparc;;
  57 alpha*-*-linux* | alpha*-*-osf* | alpha*-*-freebsd* | alpha*-*-kfreebsd*-gnu | alpha*-*-netbsd* | alpha*-*-knetbsd*-gnu) TARGET=ALPHA; TARGETDIR=alpha;;
  58 ia64*-*-*) TARGET=IA64; TARGETDIR=ia64;;
  59 m68k-*-linux*) TARGET=M68K; TARGETDIR=m68k;;
  60 mips64*-*);;
  61 mips-sgi-irix5.* | mips-sgi-irix6.*) TARGET=MIPS_IRIX; TARGETDIR=mips;;
  62 mips*-*-linux*) TARGET=MIPS_LINUX; TARGETDIR=mips;;
  63 powerpc*-*-linux* | powerpc-*-sysv*) TARGET=POWERPC; TARGETDIR=powerpc;;
  64 powerpc-*-beos*) TARGET=POWERPC; TARGETDIR=powerpc;;
  65 powerpc-*-darwin*) TARGET=POWERPC_DARWIN; TARGETDIR=powerpc;;
  66 powerpc-*-aix*) TARGET=POWERPC_AIX; TARGETDIR=powerpc;;
  67 rs6000-*-aix*) TARGET=POWERPC_AIX; TARGETDIR=powerpc;;
  68 arm*-*-linux-*) TARGET=ARM; TARGETDIR=arm;;
  69 arm*-*-netbsdelf* | arm*-*-knetbsd*-gnu) TARGET=ARM; TARGETDIR=arm;;
  70 s390-*-linux-*) TARGET=S390; TARGETDIR=s390;;
  71 s390x-*-linux-*) TARGET=S390; TARGETDIR=s390;;
  72 x86_64-*-linux* | x86_64-*-freebsd* | x86_64-*-kfreebsd*-gnu) TARGET=X86_64; TARGETDIR=x86;;
  73 sh-*-linux* | sh[[34]]*-*-linux*) TARGET=SH; TARGETDIR=sh;;
  74 sh64-*-linux* | sh5*-*-linux*) TARGET=SH64; TARGETDIR=sh64;;
  75 hppa-*-linux* | parisc-*-linux*) TARGET=PA; TARGETDIR=pa;;
  76 esac
  77
  78 AC_SUBST(AM_RUNTESTFLAGS)
  79
  80 if test $TARGETDIR = unknown; then
  81   AC_MSG_ERROR(["libffi has not been ported to $host."])
  82 fi
  83
  84 AM_CONDITIONAL(MIPS_IRIX, test x$TARGET = xMIPS_IRIX)
  85 AM_CONDITIONAL(MIPS_LINUX, test x$TARGET = xMIPS_LINUX)
  86 AM_CONDITIONAL(SPARC, test x$TARGET = xSPARC)
  87 AM_CONDITIONAL(X86, test x$TARGET = xX86)
  88 AM_CONDITIONAL(X86_WIN32, test x$TARGET = xX86_WIN32)
  89 AM_CONDITIONAL(ALPHA, test x$TARGET = xALPHA)
  90 AM_CONDITIONAL(IA64, test x$TARGET = xIA64)
  91 AM_CONDITIONAL(M68K, test x$TARGET = xM68K)
  92 AM_CONDITIONAL(POWERPC, test x$TARGET = xPOWERPC)
  93 AM_CONDITIONAL(POWERPC_AIX, test x$TARGET = xPOWERPC_AIX)
  94 AM_CONDITIONAL(POWERPC_DARWIN, test x$TARGET = xPOWERPC_DARWIN)
  95 AM_CONDITIONAL(ARM, test x$TARGET = xARM)
  96 AM_CONDITIONAL(FRV, test x$TARGET = xFRV)
  97 AM_CONDITIONAL(S390, test x$TARGET = xS390)
  98 AM_CONDITIONAL(X86_64, test x$TARGET = xX86_64)
  99 AM_CONDITIONAL(SH, test x$TARGET = xSH)
 100 AM_CONDITIONAL(SH64, test x$TARGET = xSH64)
 101 AM_CONDITIONAL(PA, test x$TARGET = xPA)
 102
 103 case x$TARGET in
 104   xMIPS*) TARGET=MIPS ;;
 105   *) ;;
 106 esac
 107
 108 AC_HEADER_STDC
 109 AC_CHECK_FUNCS(memcpy)
 110 AC_FUNC_ALLOCA
 111
 112 AC_COMPILE_CHECK_SIZEOF(double)
 113 AC_COMPILE_CHECK_SIZEOF(long double)
 114
 115 # Also AC_SUBST this variable for ffi.h.
 116 HAVE_LONG_DOUBLE=0
 117 if test $ac_cv_sizeof_double != $ac_cv_sizeof_long_double; then
 118   if test $ac_cv_sizeof_long_double != 0; then
 119     HAVE_LONG_DOUBLE=1
 120     AC_DEFINE(HAVE_LONG_DOUBLE, 1, [Define if you have the long double type and it is bigger than a double])
 121   fi
 122 fi
 123 AC_SUBST(HAVE_LONG_DOUBLE)
 124
 125 AC_C_BIGENDIAN_CROSS
 126
 127 if test x$TARGET = xSPARC; then
 128     AC_CACHE_CHECK([assembler and linker support unaligned pc related relocs],
 129         libffi_cv_as_sparc_ua_pcrel, [
 130         save_CFLAGS="$CFLAGS"
 131         save_LDFLAGS="$LDFLAGS"
 132         CFLAGS="$CFLAGS -fpic"
 133         LDFLAGS="$LDFLAGS -shared"
 134         AC_TRY_LINK([asm (".text; foo: nop; .data; .align 4; .byte 0; .uaword %r_disp32(foo); .text");],,
 135                     [libffi_cv_as_sparc_ua_pcrel=yes],
 136                     [libffi_cv_as_sparc_ua_pcrel=no])
 137         CFLAGS="$save_CFLAGS"
 138         LDFLAGS="$save_LDFLAGS"])
 139     if test "x$libffi_cv_as_sparc_ua_pcrel" = xyes; then
 140         AC_DEFINE(HAVE_AS_SPARC_UA_PCREL, 1,
 141                   [Define if your assembler and linker support unaligned PC relative relocs.])
 142     fi
 143
 144     AC_CACHE_CHECK([assembler .register pseudo-op support],
 145        libffi_cv_as_register_pseudo_op, [
 146        libffi_cv_as_register_pseudo_op=unknown
 147        # Check if we have .register
 148        AC_TRY_COMPILE([asm (".register %g2, #scratch");],,
 149                        [libffi_cv_as_register_pseudo_op=yes],
 150                        [libffi_cv_as_register_pseudo_op=no])
 151     ])
 152     if test "x$libffi_cv_as_register_pseudo_op" = xyes; then
 153        AC_DEFINE(HAVE_AS_REGISTER_PSEUDO_OP, 1,
 154                [Define if your assembler supports .register.])
 155     fi
 156 fi
 157
 158 AC_CACHE_CHECK([whether .eh_frame section should be read-only],
 159     libffi_cv_ro_eh_frame, [
 160         libffi_cv_ro_eh_frame=no
 161         echo 'extern void foo (void); void bar (void) { foo (); foo (); }' > conftest.c
 162         if $CC $CFLAGS -S -fpic -fexceptions -o conftest.s conftest.c > /dev/null 2>&1; then
 163             if grep '.section.*eh_frame.*"a"' conftest.s > /dev/null; then
 164                 libffi_cv_ro_eh_frame=yes
 165             elif grep '.section.*eh_frame.*#alloc' conftest.c \
 166                  | grep -v '#write' > /dev/null; then
 167                 libffi_cv_ro_eh_frame=yes
 168             fi
 169         fi
 170         rm -f conftest.*
 171     ])
 172 if test "x$libffi_cv_ro_eh_frame" = xyes; then
 173     AC_DEFINE(HAVE_RO_EH_FRAME, 1,
 174               [Define if .eh_frame sections should be read-only.])
 175     AC_DEFINE(EH_FRAME_FLAGS, "a",
 176               [Define to the flags needed for the .section .eh_frame directive.])
 177 else
 178     AC_DEFINE(EH_FRAME_FLAGS, "aw",
 179               [Define to the flags needed for the .section .eh_frame directive.])
 180 fi
 181
 182 AC_SUBST(TARGET)
 183 AC_SUBST(TARGETDIR)
 184
 185 AC_SUBST(SHELL)
 186
 187 AC_ARG_ENABLE(debug,
 188 [  --enable-debug          debugging mode],
 189   if test "$enable_debug" = "yes"; then
 190     AC_DEFINE(FFI_DEBUG, 1, [Define this if you want extra debugging.])
 191   fi)
 192
 193 AC_ARG_ENABLE(structs,
 194 [  --disable-structs       omit code for struct support],
 195   if test "$enable_structs" = "no"; then
 196     AC_DEFINE(FFI_NO_STRUCTS, 1, [Define this is you do not want support for aggregate types.])
 197   fi)
 198
 199 AC_ARG_ENABLE(raw-api,
 200 [  --disable-raw-api       make the raw api unavailable],
 201   if test "$enable_raw_api" = "no"; then
 202     AC_DEFINE(FFI_NO_RAW_API, 1, [Define this is you do not want support for the raw API.])
 203   fi)
 204
 205 AC_ARG_ENABLE(purify-safety,
 206 [  --enable-purify-safety  purify-safe mode],
 207   if test "$enable_purify_safety" = "yes"; then
 208     AC_DEFINE(USING_PURIFY, 1, [Define this if you are using Purify and want to suppress spurious messages.])
 209   fi)
 210
 211 if test -n "$with_cross_host" &&
 212    test x"$with_cross_host" != x"no"; then
 213   toolexecdir='$(exec_prefix)/$(target_alias)'
 214   toolexeclibdir='$(toolexecdir)/lib'
 215 else
 216   toolexecdir='$(libdir)/gcc-lib/$(target_alias)'
 217   toolexeclibdir='$(libdir)'
 218 fi
 219 multi_os_directory=`$CC -print-multi-os-directory`
 220 case $multi_os_directory in
 221   .) ;; # Avoid trailing /.
 222   *) toolexeclibdir=$toolexeclibdir/$multi_os_directory ;;
 223 esac
 224 AC_SUBST(toolexecdir)
 225 AC_SUBST(toolexeclibdir)
 226
 227 #Figure out where generated headers like ffitarget.h get installed.
 228 changequote(,)dnl
 229 gcc_version_trigger=${srcdir}/../gcc/version.c
 230 gcc_version_full=`grep version_string ${gcc_version_trigger} | sed -e 's/.*\"\([^\"]*\)\".*/\1/'`
 231 gcc_version=`echo ${gcc_version_full} | sed -e 's/\([^ ]*\) .*/\1/'`
 232 tool_include_dir='$(libdir)/gcc/$(target_alias)/'${gcc_version}/include
 233 changequote([,])dnl
 234 AC_SUBST(tool_include_dir)
 235 AC_SUBST(gcc_version)
 236
 237
 238 if test "${multilib}" = "yes"; then
 239   multilib_arg="--enable-multilib"
 240 else
 241   multilib_arg=
 242 fi
 243
 244 AC_CONFIG_COMMANDS(include, [test -d include || mkdir include])
 245 AC_CONFIG_COMMANDS(src, [
 246 test -d src || mkdir src
 247 test -d src/$TARGETDIR || mkdir src/$TARGETDIR
 248 ], [TARGETDIR="$TARGETDIR"])
 249
 250 AC_CONFIG_LINKS(include/ffitarget.h:src/$TARGETDIR/ffitarget.h)
 251
 252 AC_CONFIG_FILES(include/Makefile include/ffi.h Makefile testsuite/Makefile)
 253
 254 AC_OUTPUT