libffi/configure.ac

   1 dnl Process this with autoconf to create configure
   2
   3 AC_PREREQ(2.59)
   4
   5 AC_INIT([libffi], [2.1], [http://gcc.gnu.org/bugs.html])
   6 AC_CONFIG_HEADERS([fficonfig.h])
   7
   8 AM_ENABLE_MULTILIB(, ..)
   9
  10 AC_CANONICAL_SYSTEM
  11 target_alias=${target_alias-$host_alias}
  12
  13 . ${srcdir}/configure.host
  14
  15 AM_INIT_AUTOMAKE
  16
  17 # The same as in boehm-gc and libstdc++. Have to borrow it from there.
  18 # We must force CC to /not/ be precious variables; otherwise
  19 # the wrong, non-multilib-adjusted value will be used in multilibs.
  20 # As a side effect, we have to subst CFLAGS ourselves.
  21
  22 m4_rename([_AC_ARG_VAR_PRECIOUS],[real_PRECIOUS])
  23 m4_define([_AC_ARG_VAR_PRECIOUS],[])
  24 AC_PROG_CC
  25 m4_rename([real_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
  26
  27 AC_SUBST(CFLAGS)
  28
  29 AM_PROG_AS
  30 AM_PROG_CC_C_O
  31 AC_PROG_LIBTOOL
  32
  33 AM_MAINTAINER_MODE
  34
  35 AC_CHECK_HEADERS(sys/mman.h)
  36 AC_CHECK_FUNCS(mmap)
  37 AC_FUNC_MMAP_BLACKLIST
  38
  39 dnl The -no-testsuite modules omit the test subdir.
  40 AM_CONDITIONAL(TESTSUBDIR, test -d $srcdir/testsuite)
  41
  42 TARGETDIR="unknown"
  43 case "$host" in
  44   alpha*-*-*)
  45         TARGET=ALPHA; TARGETDIR=alpha;
  46         # Support 128-bit long double, changable via command-line switch.
  47         HAVE_LONG_DOUBLE='defined(__LONG_DOUBLE_128__)'
  48         ;;
  49
  50   arm*-*-*)
  51         TARGET=ARM; TARGETDIR=arm
  52         ;;
  53
  54   cris-*-*)
  55         TARGET=LIBFFI_CRIS; TARGETDIR=cris
  56         ;;
  57
  58   frv-*-*)
  59         TARGET=FRV; TARGETDIR=frv
  60         ;;
  61
  62   hppa*-*-linux* | parisc*-*-linux*)
  63         TARGET=PA_LINUX; TARGETDIR=pa
  64         ;;
  65   hppa*64-*-hpux*)
  66         TARGET=PA64_HPUX; TARGETDIR=pa
  67         ;;
  68   hppa*-*-hpux*)
  69         TARGET=PA_HPUX; TARGETDIR=pa
  70         ;;
  71
  72   i?86-win32* | i?86-*-cygwin* | i?86-*-mingw*)
  73         TARGET=X86_WIN32; TARGETDIR=x86
  74         ;;
  75   i?86-*-darwin*)
  76         TARGET=X86_DARWIN; TARGETDIR=x86
  77         ;;
  78   i?86-*-*)
  79         TARGET=X86; TARGETDIR=x86
  80         ;;
  81
  82   ia64*-*-*)
  83         TARGET=IA64; TARGETDIR=ia64
  84         ;;
  85
  86   m32r*-*-*)
  87         TARGET=M32R; TARGETDIR=m32r
  88         ;;
  89
  90   m68k-*-*)
  91         TARGET=M68K; TARGETDIR=m68k
  92         ;;
  93
  94   mips64*-*)
  95         ;;
  96   mips-sgi-irix5.* | mips-sgi-irix6.*)
  97         TARGET=MIPS_IRIX; TARGETDIR=mips
  98         ;;
  99   mips*-*-linux*)
 100         TARGET=MIPS_LINUX; TARGETDIR=mips
 101         ;;
 102
 103   powerpc*-*-linux* | powerpc-*-sysv*)
 104         TARGET=POWERPC; TARGETDIR=powerpc
 105         ;;
 106   powerpc-*-beos*)
 107         TARGET=POWERPC; TARGETDIR=powerpc
 108         ;;
 109   powerpc-*-darwin*)
 110         TARGET=POWERPC_DARWIN; TARGETDIR=powerpc
 111         ;;
 112   powerpc-*-aix* | rs6000-*-aix*)
 113         TARGET=POWERPC_AIX; TARGETDIR=powerpc
 114         ;;
 115   powerpc-*-freebsd*)
 116         TARGET=POWERPC_FREEBSD; TARGETDIR=powerpc
 117         ;;
 118   powerpc*-*-rtems*)
 119         TARGET=POWERPC; TARGETDIR=powerpc
 120         ;;
 121
 122   s390-*-* | s390x-*-*)
 123         TARGET=S390; TARGETDIR=s390
 124         ;;
 125
 126   sh-*-* | sh[[34]]*-*-*)
 127         TARGET=SH; TARGETDIR=sh
 128         ;;
 129   sh64-*-* | sh5*-*-*)
 130         TARGET=SH64; TARGETDIR=sh64
 131         ;;
 132
 133   sparc*-*-*)
 134         TARGET=SPARC; TARGETDIR=sparc
 135         ;;
 136
 137   x86_64-*-darwin*)
 138         TARGET=X86_DARWIN; TARGETDIR=x86
 139         ;;
 140   x86_64-*-cygwin* | x86_64-*-mingw*)
 141         ;;
 142   x86_64-*-*)
 143         TARGET=X86_64; TARGETDIR=x86
 144         ;;
 145 esac
 146
 147 AC_SUBST(AM_RUNTESTFLAGS)
 148
 149 if test $TARGETDIR = unknown; then
 150   AC_MSG_ERROR(["libffi has not been ported to $host."])
 151 fi
 152
 153 AM_CONDITIONAL(MIPS_IRIX, test x$TARGET = xMIPS_IRIX)
 154 AM_CONDITIONAL(MIPS_LINUX, test x$TARGET = xMIPS_LINUX)
 155 AM_CONDITIONAL(SPARC, test x$TARGET = xSPARC)
 156 AM_CONDITIONAL(X86, test x$TARGET = xX86)
 157 AM_CONDITIONAL(X86_WIN32, test x$TARGET = xX86_WIN32)
 158 AM_CONDITIONAL(X86_DARWIN, test x$TARGET = xX86_DARWIN)
 159 AM_CONDITIONAL(ALPHA, test x$TARGET = xALPHA)
 160 AM_CONDITIONAL(IA64, test x$TARGET = xIA64)
 161 AM_CONDITIONAL(M32R, test x$TARGET = xM32R)
 162 AM_CONDITIONAL(M68K, test x$TARGET = xM68K)
 163 AM_CONDITIONAL(POWERPC, test x$TARGET = xPOWERPC)
 164 AM_CONDITIONAL(POWERPC_AIX, test x$TARGET = xPOWERPC_AIX)
 165 AM_CONDITIONAL(POWERPC_DARWIN, test x$TARGET = xPOWERPC_DARWIN)
 166 AM_CONDITIONAL(POWERPC_FREEBSD, test x$TARGET = xPOWERPC_FREEBSD)
 167 AM_CONDITIONAL(ARM, test x$TARGET = xARM)
 168 AM_CONDITIONAL(LIBFFI_CRIS, test x$TARGET = xLIBFFI_CRIS)
 169 AM_CONDITIONAL(FRV, test x$TARGET = xFRV)
 170 AM_CONDITIONAL(S390, test x$TARGET = xS390)
 171 AM_CONDITIONAL(X86_64, test x$TARGET = xX86_64)
 172 AM_CONDITIONAL(SH, test x$TARGET = xSH)
 173 AM_CONDITIONAL(SH64, test x$TARGET = xSH64)
 174 AM_CONDITIONAL(PA_LINUX, test x$TARGET = xPA_LINUX)
 175 AM_CONDITIONAL(PA_HPUX, test x$TARGET = xPA_HPUX)
 176 AM_CONDITIONAL(PA64_HPUX, test x$TARGET = xPA64_HPUX)
 177
 178 case x$TARGET in
 179   xMIPS*) TARGET=MIPS ;;
 180   *) ;;
 181 esac
 182
 183 AC_HEADER_STDC
 184 AC_CHECK_FUNCS(memcpy)
 185 AC_FUNC_ALLOCA
 186
 187 AC_CHECK_SIZEOF(double)
 188 AC_CHECK_SIZEOF(long double)
 189
 190 # Also AC_SUBST this variable for ffi.h.
 191 if test -z "$HAVE_LONG_DOUBLE"; then
 192   HAVE_LONG_DOUBLE=0
 193   if test $ac_cv_sizeof_double != $ac_cv_sizeof_long_double; then
 194     if test $ac_cv_sizeof_long_double != 0; then
 195       HAVE_LONG_DOUBLE=1
 196       AC_DEFINE(HAVE_LONG_DOUBLE, 1, [Define if you have the long double type and it is bigger than a double])
 197     fi
 198   fi
 199 fi
 200 AC_SUBST(HAVE_LONG_DOUBLE)
 201
 202 AC_C_BIGENDIAN
 203
 204 if test x$TARGET = xSPARC; then
 205     AC_CACHE_CHECK([assembler and linker support unaligned pc related relocs],
 206         libffi_cv_as_sparc_ua_pcrel, [
 207         save_CFLAGS="$CFLAGS"
 208         save_LDFLAGS="$LDFLAGS"
 209         CFLAGS="$CFLAGS -fpic"
 210         LDFLAGS="$LDFLAGS -shared"
 211         AC_TRY_LINK([asm (".text; foo: nop; .data; .align 4; .byte 0; .uaword %r_disp32(foo); .text");],,
 212                     [libffi_cv_as_sparc_ua_pcrel=yes],
 213                     [libffi_cv_as_sparc_ua_pcrel=no])
 214         CFLAGS="$save_CFLAGS"
 215         LDFLAGS="$save_LDFLAGS"])
 216     if test "x$libffi_cv_as_sparc_ua_pcrel" = xyes; then
 217         AC_DEFINE(HAVE_AS_SPARC_UA_PCREL, 1,
 218                   [Define if your assembler and linker support unaligned PC relative relocs.])
 219     fi
 220
 221     AC_CACHE_CHECK([assembler .register pseudo-op support],
 222        libffi_cv_as_register_pseudo_op, [
 223        libffi_cv_as_register_pseudo_op=unknown
 224        # Check if we have .register
 225        AC_TRY_COMPILE([asm (".register %g2, #scratch");],,
 226                        [libffi_cv_as_register_pseudo_op=yes],
 227                        [libffi_cv_as_register_pseudo_op=no])
 228     ])
 229     if test "x$libffi_cv_as_register_pseudo_op" = xyes; then
 230        AC_DEFINE(HAVE_AS_REGISTER_PSEUDO_OP, 1,
 231                [Define if your assembler supports .register.])
 232     fi
 233 fi
 234
 235 AC_CACHE_CHECK([whether .eh_frame section should be read-only],
 236     libffi_cv_ro_eh_frame, [
 237         libffi_cv_ro_eh_frame=no
 238         echo 'extern void foo (void); void bar (void) { foo (); foo (); }' > conftest.c
 239         if $CC $CFLAGS -S -fpic -fexceptions -o conftest.s conftest.c > /dev/null 2>&1; then
 240             if grep '.section.*eh_frame.*"a"' conftest.s > /dev/null; then
 241                 libffi_cv_ro_eh_frame=yes
 242             elif grep '.section.*eh_frame.*#alloc' conftest.c \
 243                  | grep -v '#write' > /dev/null; then
 244                 libffi_cv_ro_eh_frame=yes
 245             fi
 246         fi
 247         rm -f conftest.*
 248     ])
 249 if test "x$libffi_cv_ro_eh_frame" = xyes; then
 250     AC_DEFINE(HAVE_RO_EH_FRAME, 1,
 251               [Define if .eh_frame sections should be read-only.])
 252     AC_DEFINE(EH_FRAME_FLAGS, "a",
 253               [Define to the flags needed for the .section .eh_frame directive.])
 254 else
 255     AC_DEFINE(EH_FRAME_FLAGS, "aw",
 256               [Define to the flags needed for the .section .eh_frame directive.])
 257 fi
 258
 259 AC_CACHE_CHECK([for __attribute__((visibility("hidden")))],
 260     libffi_cv_hidden_visibility_attribute, [
 261         echo 'int __attribute__ ((visibility ("hidden"))) foo (void) { return 1; }' > conftest.c
 262         libffi_cv_hidden_visibility_attribute=no
 263         if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
 264             if grep '\.hidden.*foo' conftest.s >/dev/null; then
 265                 libffi_cv_hidden_visibility_attribute=yes
 266             fi
 267         fi
 268         rm -f conftest.*
 269     ])
 270 if test $libffi_cv_hidden_visibility_attribute = yes; then
 271     AC_DEFINE(HAVE_HIDDEN_VISIBILITY_ATTRIBUTE, 1,
 272               [Define if __attribute__((visibility("hidden"))) is supported.])
 273 fi
 274
 275 AH_BOTTOM([
 276 #ifdef HAVE_HIDDEN_VISIBILITY_ATTRIBUTE
 277 #ifdef LIBFFI_ASM
 278 #define FFI_HIDDEN(name) .hidden name
 279 #else
 280 #define FFI_HIDDEN __attribute__ ((visibility ("hidden")))
 281 #endif
 282 #else
 283 #ifdef LIBFFI_ASM
 284 #define FFI_HIDDEN(name)
 285 #else
 286 #define FFI_HIDDEN
 287 #endif
 288 #endif
 289 ])
 290
 291 AC_SUBST(TARGET)
 292 AC_SUBST(TARGETDIR)
 293
 294 AC_SUBST(SHELL)
 295
 296 AC_ARG_ENABLE(debug,
 297 [  --enable-debug          debugging mode],
 298   if test "$enable_debug" = "yes"; then
 299     AC_DEFINE(FFI_DEBUG, 1, [Define this if you want extra debugging.])
 300   fi)
 301
 302 AC_ARG_ENABLE(structs,
 303 [  --disable-structs       omit code for struct support],
 304   if test "$enable_structs" = "no"; then
 305     AC_DEFINE(FFI_NO_STRUCTS, 1, [Define this is you do not want support for aggregate types.])
 306   fi)
 307
 308 AC_ARG_ENABLE(raw-api,
 309 [  --disable-raw-api       make the raw api unavailable],
 310   if test "$enable_raw_api" = "no"; then
 311     AC_DEFINE(FFI_NO_RAW_API, 1, [Define this is you do not want support for the raw API.])
 312   fi)
 313
 314 AC_ARG_ENABLE(purify-safety,
 315 [  --enable-purify-safety  purify-safe mode],
 316   if test "$enable_purify_safety" = "yes"; then
 317     AC_DEFINE(USING_PURIFY, 1, [Define this if you are using Purify and want to suppress spurious messages.])
 318   fi)
 319
 320 if test -n "$with_cross_host" &&
 321    test x"$with_cross_host" != x"no"; then
 322   toolexecdir='$(exec_prefix)/$(target_alias)'
 323   toolexeclibdir='$(toolexecdir)/lib'
 324 else
 325   toolexecdir='$(libdir)/gcc-lib/$(target_alias)'
 326   toolexeclibdir='$(libdir)'
 327 fi
 328 multi_os_directory=`$CC -print-multi-os-directory`
 329 case $multi_os_directory in
 330   .) ;; # Avoid trailing /.
 331   *) toolexeclibdir=$toolexeclibdir/$multi_os_directory ;;
 332 esac
 333 AC_SUBST(toolexecdir)
 334 AC_SUBST(toolexeclibdir)
 335
 336 if test "${multilib}" = "yes"; then
 337   multilib_arg="--enable-multilib"
 338 else
 339   multilib_arg=
 340 fi
 341
 342 AC_CONFIG_COMMANDS(include, [test -d include || mkdir include])
 343 AC_CONFIG_COMMANDS(src, [
 344 test -d src || mkdir src
 345 test -d src/$TARGETDIR || mkdir src/$TARGETDIR
 346 ], [TARGETDIR="$TARGETDIR"])
 347
 348 AC_CONFIG_LINKS(include/ffitarget.h:src/$TARGETDIR/ffitarget.h)
 349
 350 AC_CONFIG_FILES(include/Makefile include/ffi.h Makefile testsuite/Makefile)
 351
 352 AC_OUTPUT