OSDN Git Service

GNU/Hurd: remove -bsd command-line option.
[pf3gnuchains/gcc-fork.git] / libffi / configure.ac
1 dnl Process this with autoconf to create configure
2
3 AC_PREREQ(2.64)
4
5 AC_INIT([libffi], [3.0.9], [http://gcc.gnu.org/bugs.html])
6 AC_CONFIG_HEADERS([fficonfig.h])
7
8 AM_ENABLE_MULTILIB(, ..)
9
10 AC_CANONICAL_SYSTEM
11 target_alias=${target_alias-$host_alias}
12
13 . ${srcdir}/configure.host
14
15 AM_INIT_AUTOMAKE
16
17 # The same as in boehm-gc and libstdc++. Have to borrow it from there.
18 # We must force CC to /not/ be precious variables; otherwise
19 # the wrong, non-multilib-adjusted value will be used in multilibs.
20 # As a side effect, we have to subst CFLAGS ourselves.
21
22 m4_rename([_AC_ARG_VAR_PRECIOUS],[real_PRECIOUS])
23 m4_define([_AC_ARG_VAR_PRECIOUS],[])
24 AC_PROG_CC
25 m4_rename_force([real_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
26
27 AC_SUBST(CFLAGS)
28
29 AM_PROG_AS
30 AM_PROG_CC_C_O
31 AC_PROG_LIBTOOL
32
33 AM_MAINTAINER_MODE
34
35 AC_CHECK_HEADERS(sys/mman.h)
36 AC_CHECK_FUNCS(mmap)
37 AC_FUNC_MMAP_BLACKLIST
38
39 dnl The -no-testsuite modules omit the test subdir.
40 AM_CONDITIONAL(TESTSUBDIR, test -d $srcdir/testsuite)
41
42 TARGETDIR="unknown"
43 case "$host" in
44   alpha*-*-*)
45         TARGET=ALPHA; TARGETDIR=alpha;
46         # Support 128-bit long double, changeable via command-line switch.
47         HAVE_LONG_DOUBLE='defined(__LONG_DOUBLE_128__)'
48         ;;
49
50   arm*-*-*)
51         TARGET=ARM; TARGETDIR=arm
52         ;;
53
54   amd64-*-freebsd* | amd64-*-openbsd*)
55         TARGET=X86_64; TARGETDIR=x86
56         ;;
57
58   avr32*-*-*)
59         TARGET=AVR32; TARGETDIR=avr32
60         ;;
61
62   cris-*-*)
63         TARGET=LIBFFI_CRIS; TARGETDIR=cris
64         ;;
65
66   frv-*-*)
67         TARGET=FRV; TARGETDIR=frv
68         ;;
69
70   hppa*-*-linux* | parisc*-*-linux*)
71         TARGET=PA_LINUX; TARGETDIR=pa
72         ;;
73   hppa*64-*-hpux*)
74         TARGET=PA64_HPUX; TARGETDIR=pa
75         ;;
76   hppa*-*-hpux*)
77         TARGET=PA_HPUX; TARGETDIR=pa
78         ;;
79
80   i?86-*-freebsd* | i?86-*-openbsd*)
81         TARGET=X86_FREEBSD; TARGETDIR=x86
82         ;;
83   i?86-win32* | i?86-*-cygwin* | i?86-*-mingw* | i?86-*-os2*)
84         TARGET=X86_WIN32; TARGETDIR=x86
85         # All mingw/cygwin/win32 builds require -no-undefined for sharedlib.
86         # We must also check with_cross_host to decide if this is a native
87         # or cross-build and select where to install dlls appropriately.
88         if test -n "$with_cross_host" &&
89            test x"$with_cross_host" != x"no"; then
90           AM_LTLDFLAGS='-no-undefined -bindir "$(toolexeclibdir)"';
91         else
92           AM_LTLDFLAGS='-no-undefined -bindir "$(bindir)"';
93         fi
94         ;;
95   i?86-*-darwin*)
96         TARGET=X86_DARWIN; TARGETDIR=x86
97         ;;
98   i?86-*-solaris2.1[[0-9]]*)
99         TARGET=X86_64; TARGETDIR=x86
100         ;;
101   i?86-*-*)
102         TARGET=X86; TARGETDIR=x86
103         ;;
104
105   ia64*-*-*)
106         TARGET=IA64; TARGETDIR=ia64
107         ;;
108
109   m32r*-*-*)
110         TARGET=M32R; TARGETDIR=m32r
111         ;;
112
113   m68k-*-*)
114         TARGET=M68K; TARGETDIR=m68k
115         ;;
116
117   mips-sgi-irix5.* | mips-sgi-irix6.*)
118         TARGET=MIPS; TARGETDIR=mips
119         ;;
120   mips*-*-linux*)
121         # Support 128-bit long double for NewABI.
122         HAVE_LONG_DOUBLE='defined(__mips64)'
123         TARGET=MIPS; TARGETDIR=mips
124         ;;
125
126   powerpc*-*-linux* | powerpc-*-sysv*)
127         TARGET=POWERPC; TARGETDIR=powerpc
128         ;;
129   powerpc-*-beos*)
130         TARGET=POWERPC; TARGETDIR=powerpc
131         ;;
132   powerpc-*-darwin*)
133         TARGET=POWERPC_DARWIN; TARGETDIR=powerpc
134         ;;
135   powerpc-*-aix* | rs6000-*-aix*)
136         TARGET=POWERPC_AIX; TARGETDIR=powerpc
137         ;;
138   powerpc-*-freebsd*)
139         TARGET=POWERPC_FREEBSD; TARGETDIR=powerpc
140         ;;
141  powerpc64-*-freebsd*)
142         TARGET=POWERPC; TARGETDIR=powerpc
143         ;;
144   powerpc*-*-rtems*)
145         TARGET=POWERPC; TARGETDIR=powerpc
146         ;;
147
148   s390-*-* | s390x-*-*)
149         TARGET=S390; TARGETDIR=s390
150         ;;
151
152   sh-*-* | sh[[34]]*-*-*)
153         TARGET=SH; TARGETDIR=sh
154         ;;
155   sh64-*-* | sh5*-*-*)
156         TARGET=SH64; TARGETDIR=sh64
157         ;;
158
159   sparc*-*-*)
160         TARGET=SPARC; TARGETDIR=sparc
161         ;;
162
163   x86_64-*-darwin*)
164         TARGET=X86_DARWIN; TARGETDIR=x86
165         ;;
166
167   x86_64-*-cygwin* | x86_64-*-mingw*)
168         TARGET=X86_WIN64; TARGETDIR=x86
169         ;;
170
171   x86_64-*-*)
172         TARGET=X86_64; TARGETDIR=x86
173         ;;
174 esac
175
176 AC_SUBST(AM_RUNTESTFLAGS)
177 AC_SUBST(AM_LTLDFLAGS)
178
179 if test $TARGETDIR = unknown; then
180   AC_MSG_ERROR(["libffi has not been ported to $host."])
181 fi
182
183 AM_CONDITIONAL(MIPS, test x$TARGET = xMIPS)
184 AM_CONDITIONAL(SPARC, test x$TARGET = xSPARC)
185 AM_CONDITIONAL(X86, test x$TARGET = xX86)
186 AM_CONDITIONAL(X86_FREEBSD, test x$TARGET = xX86_FREEBSD)
187 AM_CONDITIONAL(X86_WIN32, test x$TARGET = xX86_WIN32)
188 AM_CONDITIONAL(X86_WIN64, test x$TARGET = xX86_WIN64)
189 AM_CONDITIONAL(X86_DARWIN, test x$TARGET = xX86_DARWIN)
190 AM_CONDITIONAL(ALPHA, test x$TARGET = xALPHA)
191 AM_CONDITIONAL(IA64, test x$TARGET = xIA64)
192 AM_CONDITIONAL(M32R, test x$TARGET = xM32R)
193 AM_CONDITIONAL(M68K, test x$TARGET = xM68K)
194 AM_CONDITIONAL(POWERPC, test x$TARGET = xPOWERPC)
195 AM_CONDITIONAL(POWERPC_AIX, test x$TARGET = xPOWERPC_AIX)
196 AM_CONDITIONAL(POWERPC_DARWIN, test x$TARGET = xPOWERPC_DARWIN)
197 AM_CONDITIONAL(POWERPC_FREEBSD, test x$TARGET = xPOWERPC_FREEBSD)
198 AM_CONDITIONAL(ARM, test x$TARGET = xARM)
199 AM_CONDITIONAL(AVR32, test x$TARGET = xAVR32)
200 AM_CONDITIONAL(LIBFFI_CRIS, test x$TARGET = xLIBFFI_CRIS)
201 AM_CONDITIONAL(FRV, test x$TARGET = xFRV)
202 AM_CONDITIONAL(S390, test x$TARGET = xS390)
203 AM_CONDITIONAL(X86_64, test x$TARGET = xX86_64)
204 AM_CONDITIONAL(SH, test x$TARGET = xSH)
205 AM_CONDITIONAL(SH64, test x$TARGET = xSH64)
206 AM_CONDITIONAL(PA_LINUX, test x$TARGET = xPA_LINUX)
207 AM_CONDITIONAL(PA_HPUX, test x$TARGET = xPA_HPUX)
208 AM_CONDITIONAL(PA64_HPUX, test x$TARGET = xPA64_HPUX)
209
210 AC_HEADER_STDC
211 AC_CHECK_FUNCS(memcpy)
212 AC_FUNC_ALLOCA
213
214 AC_CHECK_SIZEOF(double)
215 AC_CHECK_SIZEOF(long double)
216
217 # Also AC_SUBST this variable for ffi.h.
218 if test -z "$HAVE_LONG_DOUBLE"; then
219   HAVE_LONG_DOUBLE=0
220   if test $ac_cv_sizeof_double != $ac_cv_sizeof_long_double; then
221     if test $ac_cv_sizeof_long_double != 0; then
222       HAVE_LONG_DOUBLE=1
223       AC_DEFINE(HAVE_LONG_DOUBLE, 1, [Define if you have the long double type and it is bigger than a double])
224     fi
225   fi
226 fi
227 AC_SUBST(HAVE_LONG_DOUBLE)
228
229 AC_C_BIGENDIAN
230
231 AC_CACHE_CHECK([assembler .cfi pseudo-op support],
232     libffi_cv_as_cfi_pseudo_op, [
233     libffi_cv_as_cfi_pseudo_op=unknown
234     AC_TRY_COMPILE([asm (".cfi_startproc\n\t.cfi_endproc");],,
235                    [libffi_cv_as_cfi_pseudo_op=yes],
236                    [libffi_cv_as_cfi_pseudo_op=no])
237 ])
238 if test "x$libffi_cv_as_cfi_pseudo_op" = xyes; then
239     AC_DEFINE(HAVE_AS_CFI_PSEUDO_OP, 1,
240               [Define if your assembler supports .cfi_* directives.])
241 fi
242
243 if test x$TARGET = xSPARC; then
244     AC_CACHE_CHECK([assembler and linker support unaligned pc related relocs],
245         libffi_cv_as_sparc_ua_pcrel, [
246         save_CFLAGS="$CFLAGS"
247         save_LDFLAGS="$LDFLAGS"
248         CFLAGS="$CFLAGS -fpic"
249         LDFLAGS="$LDFLAGS -shared"
250         AC_TRY_LINK([asm (".text; foo: nop; .data; .align 4; .byte 0; .uaword %r_disp32(foo); .text");],,
251                     [libffi_cv_as_sparc_ua_pcrel=yes],
252                     [libffi_cv_as_sparc_ua_pcrel=no])
253         CFLAGS="$save_CFLAGS"
254         LDFLAGS="$save_LDFLAGS"])
255     if test "x$libffi_cv_as_sparc_ua_pcrel" = xyes; then
256         AC_DEFINE(HAVE_AS_SPARC_UA_PCREL, 1,
257                   [Define if your assembler and linker support unaligned PC relative relocs.])
258     fi
259
260     AC_CACHE_CHECK([assembler .register pseudo-op support],
261        libffi_cv_as_register_pseudo_op, [
262        libffi_cv_as_register_pseudo_op=unknown
263        # Check if we have .register
264        AC_TRY_COMPILE([asm (".register %g2, #scratch");],,
265                        [libffi_cv_as_register_pseudo_op=yes],
266                        [libffi_cv_as_register_pseudo_op=no])
267     ])
268     if test "x$libffi_cv_as_register_pseudo_op" = xyes; then
269        AC_DEFINE(HAVE_AS_REGISTER_PSEUDO_OP, 1,
270                [Define if your assembler supports .register.])
271     fi
272 fi
273
274 if test x$TARGET = xX86 || test x$TARGET = xX86_WIN32 || test x$TARGET = xX86_64; then
275     AC_CACHE_CHECK([assembler supports pc related relocs],
276         libffi_cv_as_x86_pcrel, [
277         libffi_cv_as_x86_pcrel=yes
278         echo '.text; foo: nop; .data; .long foo-.; .text' > conftest.s
279         if $CC $CFLAGS -c conftest.s 2>&1 | $EGREP -i 'illegal|warning' > /dev/null; then
280             libffi_cv_as_x86_pcrel=no
281         fi
282         ])
283     if test "x$libffi_cv_as_x86_pcrel" = xyes; then
284         AC_DEFINE(HAVE_AS_X86_PCREL, 1,
285                   [Define if your assembler supports PC relative relocs.])
286     fi
287
288     AC_CACHE_CHECK([assembler .ascii pseudo-op support],
289        libffi_cv_as_ascii_pseudo_op, [
290        libffi_cv_as_ascii_pseudo_op=unknown
291        # Check if we have .ascii
292        AC_TRY_COMPILE([asm (".ascii \\"string\\"");],,
293                        [libffi_cv_as_ascii_pseudo_op=yes],
294                        [libffi_cv_as_ascii_pseudo_op=no])
295     ])
296     if test "x$libffi_cv_as_ascii_pseudo_op" = xyes; then
297        AC_DEFINE(HAVE_AS_ASCII_PSEUDO_OP, 1,
298                [Define if your assembler supports .ascii.])
299     fi
300
301     AC_CACHE_CHECK([assembler .string pseudo-op support],
302        libffi_cv_as_string_pseudo_op, [
303        libffi_cv_as_string_pseudo_op=unknown
304        # Check if we have .string
305        AC_TRY_COMPILE([asm (".string \\"string\\"");],,
306                        [libffi_cv_as_string_pseudo_op=yes],
307                        [libffi_cv_as_string_pseudo_op=no])
308     ])
309     if test "x$libffi_cv_as_string_pseudo_op" = xyes; then
310        AC_DEFINE(HAVE_AS_STRING_PSEUDO_OP, 1,
311                [Define if your assembler supports .string.])
312     fi
313 fi
314
315 case "$target" in
316      *-apple-darwin10* | *-*-freebsd* | *-*-openbsd* | *-pc-solaris*)
317        AC_DEFINE(FFI_MMAP_EXEC_WRIT, 1,
318                  [Cannot use malloc on this target, so, we revert to
319                    alternative means])
320      ;;
321 esac
322
323 if test x$TARGET = xX86_64; then
324     AC_CACHE_CHECK([assembler supports unwind section type],
325         libffi_cv_as_x86_64_unwind_section_type, [
326         libffi_cv_as_x86_64_unwind_section_type=yes
327         echo '.section .eh_frame,"a",@unwind' > conftest.s
328         if $CC $CFLAGS -c conftest.s 2>&1 | grep -i warning > /dev/null; then
329             libffi_cv_as_x86_64_unwind_section_type=no
330         fi
331         ])
332     if test "x$libffi_cv_as_x86_64_unwind_section_type" = xyes; then
333         AC_DEFINE(HAVE_AS_X86_64_UNWIND_SECTION_TYPE, 1,
334                   [Define if your assembler supports unwind section type.])
335     fi
336 fi
337
338 AC_CACHE_CHECK([whether .eh_frame section should be read-only],
339     libffi_cv_ro_eh_frame, [
340         libffi_cv_ro_eh_frame=no
341         echo 'extern void foo (void); void bar (void) { foo (); foo (); }' > conftest.c
342         if $CC $CFLAGS -S -fpic -fexceptions -o conftest.s conftest.c > /dev/null 2>&1; then
343             if grep '.section.*eh_frame.*"a"' conftest.s > /dev/null; then
344                 libffi_cv_ro_eh_frame=yes
345             elif grep '.section.*eh_frame.*#alloc' conftest.c \
346                  | grep -v '#write' > /dev/null; then
347                 libffi_cv_ro_eh_frame=yes
348             fi
349         fi
350         rm -f conftest.*
351     ])
352 if test "x$libffi_cv_ro_eh_frame" = xyes; then
353     AC_DEFINE(HAVE_RO_EH_FRAME, 1,
354               [Define if .eh_frame sections should be read-only.])
355     AC_DEFINE(EH_FRAME_FLAGS, "a",
356               [Define to the flags needed for the .section .eh_frame directive.])
357 else
358     AC_DEFINE(EH_FRAME_FLAGS, "aw",
359               [Define to the flags needed for the .section .eh_frame directive.])
360 fi
361
362 AC_CACHE_CHECK([for __attribute__((visibility("hidden")))],
363     libffi_cv_hidden_visibility_attribute, [
364         echo 'int __attribute__ ((visibility ("hidden"))) foo (void) { return 1; }' > conftest.c
365         libffi_cv_hidden_visibility_attribute=no
366         if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
367             if grep '\.hidden.*foo' conftest.s >/dev/null; then
368                 libffi_cv_hidden_visibility_attribute=yes
369             fi
370         fi
371         rm -f conftest.*
372     ])
373 if test $libffi_cv_hidden_visibility_attribute = yes; then
374     AC_DEFINE(HAVE_HIDDEN_VISIBILITY_ATTRIBUTE, 1,
375               [Define if __attribute__((visibility("hidden"))) is supported.])
376 fi
377
378 AH_BOTTOM([
379 #ifdef HAVE_HIDDEN_VISIBILITY_ATTRIBUTE
380 #ifdef LIBFFI_ASM
381 #define FFI_HIDDEN(name) .hidden name
382 #else
383 #define FFI_HIDDEN __attribute__ ((visibility ("hidden")))
384 #endif
385 #else
386 #ifdef LIBFFI_ASM
387 #define FFI_HIDDEN(name)
388 #else
389 #define FFI_HIDDEN
390 #endif
391 #endif
392 ])
393
394 AC_SUBST(TARGET)
395 AC_SUBST(TARGETDIR)
396
397 AC_SUBST(SHELL)
398
399 AC_ARG_ENABLE(debug,
400 [  --enable-debug          debugging mode],
401   if test "$enable_debug" = "yes"; then
402     AC_DEFINE(FFI_DEBUG, 1, [Define this if you want extra debugging.])
403   fi)
404
405 AC_ARG_ENABLE(structs,
406 [  --disable-structs       omit code for struct support],
407   if test "$enable_structs" = "no"; then
408     AC_DEFINE(FFI_NO_STRUCTS, 1, [Define this is you do not want support for aggregate types.])
409   fi)
410
411 AC_ARG_ENABLE(raw-api,
412 [  --disable-raw-api       make the raw api unavailable],
413   if test "$enable_raw_api" = "no"; then
414     AC_DEFINE(FFI_NO_RAW_API, 1, [Define this is you do not want support for the raw API.])
415   fi)
416
417 AC_ARG_ENABLE(purify-safety,
418 [  --enable-purify-safety  purify-safe mode],
419   if test "$enable_purify_safety" = "yes"; then
420     AC_DEFINE(USING_PURIFY, 1, [Define this if you are using Purify and want to suppress spurious messages.])
421   fi)
422
423 if test -n "$with_cross_host" &&
424    test x"$with_cross_host" != x"no"; then
425   toolexecdir='$(exec_prefix)/$(target_alias)'
426   toolexeclibdir='$(toolexecdir)/lib'
427 else
428   toolexecdir='$(libdir)/gcc-lib/$(target_alias)'
429   toolexeclibdir='$(libdir)'
430 fi
431 multi_os_directory=`$CC -print-multi-os-directory`
432 case $multi_os_directory in
433   .) ;; # Avoid trailing /.
434   *) toolexeclibdir=$toolexeclibdir/$multi_os_directory ;;
435 esac
436 AC_SUBST(toolexecdir)
437 AC_SUBST(toolexeclibdir)
438
439 if test "${multilib}" = "yes"; then
440   multilib_arg="--enable-multilib"
441 else
442   multilib_arg=
443 fi
444
445 AC_CONFIG_COMMANDS(include, [test -d include || mkdir include])
446 AC_CONFIG_COMMANDS(src, [
447 test -d src || mkdir src
448 test -d src/$TARGETDIR || mkdir src/$TARGETDIR
449 ], [TARGETDIR="$TARGETDIR"])
450
451 AC_CONFIG_LINKS(include/ffitarget.h:src/$TARGETDIR/ffitarget.h)
452
453 AC_CONFIG_FILES(include/Makefile include/ffi.h Makefile testsuite/Makefile man/Makefile)
454
455 AC_OUTPUT