OSDN Git Service

Fix problem found by CFLAGS=-fmudflap build.
[pf3gnuchains/gcc-fork.git] / libffi / configure.ac
1 dnl Process this with autoconf to create configure
2
3 AC_PREREQ(2.59)
4
5 AC_INIT([libffi], [2.1], [http://gcc.gnu.org/bugs.html])
6 AC_CONFIG_HEADERS([fficonfig.h])
7
8 AM_ENABLE_MULTILIB(, ..)
9
10 AC_CANONICAL_SYSTEM
11 target_alias=${target_alias-$host_alias}
12
13 . ${srcdir}/configure.host
14
15 AM_INIT_AUTOMAKE
16
17 # The same as in boehm-gc and libstdc++. Have to borrow it from there.
18 # We must force CC to /not/ be precious variables; otherwise
19 # the wrong, non-multilib-adjusted value will be used in multilibs.
20 # As a side effect, we have to subst CFLAGS ourselves.
21
22 m4_rename([_AC_ARG_VAR_PRECIOUS],[real_PRECIOUS])
23 m4_define([_AC_ARG_VAR_PRECIOUS],[])
24 AC_PROG_CC
25 m4_rename([real_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
26
27 AC_SUBST(CFLAGS)
28
29 AM_PROG_AS
30 AM_PROG_CC_C_O
31 AC_PROG_LIBTOOL
32
33 AM_MAINTAINER_MODE
34
35 AC_CHECK_HEADERS(sys/mman.h)
36 AC_CHECK_FUNCS(mmap)
37 AC_FUNC_MMAP_BLACKLIST
38
39 dnl The -no-testsuite modules omit the test subdir.
40 AM_CONDITIONAL(TESTSUBDIR, test -d $srcdir/testsuite)
41
42 TARGETDIR="unknown"
43 case "$host" in
44 i*86-*-linux*) TARGET=X86; TARGETDIR=x86;;
45 i*86-*-solaris*) TARGET=X86; TARGETDIR=x86;;
46 i*86-*-beos*) TARGET=X86; TARGETDIR=x86;;
47 i*86-*-freebsd* | i*86-*-kfreebsd*-gnu) TARGET=X86; TARGETDIR=x86;;
48 i*86-*-netbsdelf* | i*86-*-knetbsd*-gnu) TARGET=X86; TARGETDIR=x86;;
49 i*86-*-win32*) TARGET=X86_WIN32; TARGETDIR=x86;;
50 i*86-*-cygwin*) TARGET=X86_WIN32; TARGETDIR=x86;;
51 i*86-*-mingw*) TARGET=X86_WIN32; TARGETDIR=x86;;
52 frv-*-*) TARGET=FRV; TARGETDIR=frv;;
53 sparc-sun-4*) TARGET=SPARC; TARGETDIR=sparc;;
54 sparc*-sun-*) TARGET=SPARC; TARGETDIR=sparc;;
55 sparc-*-linux* | sparc-*-netbsdelf* | sparc-*-knetbsd*-gnu) TARGET=SPARC; TARGETDIR=sparc;;
56 sparc64-*-linux* | sparc64-*-netbsd* | sparc64-*-knetbsd*-gnu) TARGET=SPARC; TARGETDIR=sparc;;
57 alpha*-*-linux* | alpha*-*-osf* | alpha*-*-freebsd* | alpha*-*-kfreebsd*-gnu | alpha*-*-netbsd* | alpha*-*-knetbsd*-gnu) TARGET=ALPHA; TARGETDIR=alpha;;
58 ia64*-*-*) TARGET=IA64; TARGETDIR=ia64;;
59 m32r*-*-linux* ) TARGET=M32R; TARGETDIR=m32r;;
60 m68k-*-linux*) TARGET=M68K; TARGETDIR=m68k;;
61 mips64*-*);;
62 mips-sgi-irix5.* | mips-sgi-irix6.*) TARGET=MIPS_IRIX; TARGETDIR=mips;;
63 mips*-*-linux*) TARGET=MIPS_LINUX; TARGETDIR=mips;;
64 powerpc*-*-linux* | powerpc-*-sysv*) TARGET=POWERPC; TARGETDIR=powerpc;;
65 powerpc-*-beos*) TARGET=POWERPC; TARGETDIR=powerpc;;
66 powerpc-*-darwin*) TARGET=POWERPC_DARWIN; TARGETDIR=powerpc;;
67 powerpc-*-aix*) TARGET=POWERPC_AIX; TARGETDIR=powerpc;;
68 rs6000-*-aix*) TARGET=POWERPC_AIX; TARGETDIR=powerpc;;
69 arm*-*-linux-*) TARGET=ARM; TARGETDIR=arm;;
70 arm*-*-netbsdelf* | arm*-*-knetbsd*-gnu) TARGET=ARM; TARGETDIR=arm;;
71 s390-*-linux-*) TARGET=S390; TARGETDIR=s390;;
72 s390x-*-linux-*) TARGET=S390; TARGETDIR=s390;;
73 x86_64-*-linux* | x86_64-*-freebsd* | x86_64-*-kfreebsd*-gnu) TARGET=X86_64; TARGETDIR=x86;;
74 sh-*-linux* | sh[[34]]*-*-linux*) TARGET=SH; TARGETDIR=sh;;
75 sh64-*-linux* | sh5*-*-linux*) TARGET=SH64; TARGETDIR=sh64;;
76 hppa-*-linux* | parisc-*-linux*) TARGET=PA; TARGETDIR=pa;;
77 esac
78
79 AC_SUBST(AM_RUNTESTFLAGS)
80
81 if test $TARGETDIR = unknown; then
82   AC_MSG_ERROR(["libffi has not been ported to $host."])
83 fi
84
85 AM_CONDITIONAL(MIPS_IRIX, test x$TARGET = xMIPS_IRIX)
86 AM_CONDITIONAL(MIPS_LINUX, test x$TARGET = xMIPS_LINUX)
87 AM_CONDITIONAL(SPARC, test x$TARGET = xSPARC)
88 AM_CONDITIONAL(X86, test x$TARGET = xX86)
89 AM_CONDITIONAL(X86_WIN32, test x$TARGET = xX86_WIN32)
90 AM_CONDITIONAL(ALPHA, test x$TARGET = xALPHA)
91 AM_CONDITIONAL(IA64, test x$TARGET = xIA64)
92 AM_CONDITIONAL(M32R, test x$TARGET = xM32R)
93 AM_CONDITIONAL(M68K, test x$TARGET = xM68K)
94 AM_CONDITIONAL(POWERPC, test x$TARGET = xPOWERPC)
95 AM_CONDITIONAL(POWERPC_AIX, test x$TARGET = xPOWERPC_AIX)
96 AM_CONDITIONAL(POWERPC_DARWIN, test x$TARGET = xPOWERPC_DARWIN)
97 AM_CONDITIONAL(ARM, test x$TARGET = xARM)
98 AM_CONDITIONAL(FRV, test x$TARGET = xFRV)
99 AM_CONDITIONAL(S390, test x$TARGET = xS390)
100 AM_CONDITIONAL(X86_64, test x$TARGET = xX86_64)
101 AM_CONDITIONAL(SH, test x$TARGET = xSH)
102 AM_CONDITIONAL(SH64, test x$TARGET = xSH64)
103 AM_CONDITIONAL(PA, test x$TARGET = xPA)
104
105 case x$TARGET in
106   xMIPS*) TARGET=MIPS ;;
107   *) ;;
108 esac
109
110 AC_HEADER_STDC
111 AC_CHECK_FUNCS(memcpy)
112 AC_FUNC_ALLOCA
113
114 AC_COMPILE_CHECK_SIZEOF(double)
115 AC_COMPILE_CHECK_SIZEOF(long double)
116
117 # Also AC_SUBST this variable for ffi.h.
118 HAVE_LONG_DOUBLE=0
119 if test $ac_cv_sizeof_double != $ac_cv_sizeof_long_double; then
120   if test $ac_cv_sizeof_long_double != 0; then
121     HAVE_LONG_DOUBLE=1
122     AC_DEFINE(HAVE_LONG_DOUBLE, 1, [Define if you have the long double type and it is bigger than a double])
123   fi
124 fi
125 AC_SUBST(HAVE_LONG_DOUBLE)
126
127 AC_C_BIGENDIAN_CROSS
128
129 if test x$TARGET = xSPARC; then
130     AC_CACHE_CHECK([assembler and linker support unaligned pc related relocs],
131         libffi_cv_as_sparc_ua_pcrel, [
132         save_CFLAGS="$CFLAGS"
133         save_LDFLAGS="$LDFLAGS"
134         CFLAGS="$CFLAGS -fpic"
135         LDFLAGS="$LDFLAGS -shared"
136         AC_TRY_LINK([asm (".text; foo: nop; .data; .align 4; .byte 0; .uaword %r_disp32(foo); .text");],,
137                     [libffi_cv_as_sparc_ua_pcrel=yes],
138                     [libffi_cv_as_sparc_ua_pcrel=no])
139         CFLAGS="$save_CFLAGS"
140         LDFLAGS="$save_LDFLAGS"])
141     if test "x$libffi_cv_as_sparc_ua_pcrel" = xyes; then
142         AC_DEFINE(HAVE_AS_SPARC_UA_PCREL, 1,
143                   [Define if your assembler and linker support unaligned PC relative relocs.])
144     fi
145
146     AC_CACHE_CHECK([assembler .register pseudo-op support],
147        libffi_cv_as_register_pseudo_op, [
148        libffi_cv_as_register_pseudo_op=unknown
149        # Check if we have .register
150        AC_TRY_COMPILE([asm (".register %g2, #scratch");],,
151                        [libffi_cv_as_register_pseudo_op=yes],
152                        [libffi_cv_as_register_pseudo_op=no])
153     ])
154     if test "x$libffi_cv_as_register_pseudo_op" = xyes; then
155        AC_DEFINE(HAVE_AS_REGISTER_PSEUDO_OP, 1,
156                [Define if your assembler supports .register.])
157     fi
158 fi
159
160 AC_CACHE_CHECK([whether .eh_frame section should be read-only],
161     libffi_cv_ro_eh_frame, [
162         libffi_cv_ro_eh_frame=no
163         echo 'extern void foo (void); void bar (void) { foo (); foo (); }' > conftest.c
164         if $CC $CFLAGS -S -fpic -fexceptions -o conftest.s conftest.c > /dev/null 2>&1; then
165             if grep '.section.*eh_frame.*"a"' conftest.s > /dev/null; then
166                 libffi_cv_ro_eh_frame=yes
167             elif grep '.section.*eh_frame.*#alloc' conftest.c \
168                  | grep -v '#write' > /dev/null; then
169                 libffi_cv_ro_eh_frame=yes
170             fi
171         fi
172         rm -f conftest.*
173     ])
174 if test "x$libffi_cv_ro_eh_frame" = xyes; then
175     AC_DEFINE(HAVE_RO_EH_FRAME, 1,
176               [Define if .eh_frame sections should be read-only.])
177     AC_DEFINE(EH_FRAME_FLAGS, "a",
178               [Define to the flags needed for the .section .eh_frame directive.])
179 else
180     AC_DEFINE(EH_FRAME_FLAGS, "aw",
181               [Define to the flags needed for the .section .eh_frame directive.])
182 fi
183
184 AC_SUBST(TARGET)
185 AC_SUBST(TARGETDIR)
186
187 AC_SUBST(SHELL)
188
189 AC_ARG_ENABLE(debug,
190 [  --enable-debug          debugging mode],
191   if test "$enable_debug" = "yes"; then
192     AC_DEFINE(FFI_DEBUG, 1, [Define this if you want extra debugging.])
193   fi)
194
195 AC_ARG_ENABLE(structs,
196 [  --disable-structs       omit code for struct support],
197   if test "$enable_structs" = "no"; then
198     AC_DEFINE(FFI_NO_STRUCTS, 1, [Define this is you do not want support for aggregate types.])
199   fi)
200
201 AC_ARG_ENABLE(raw-api,
202 [  --disable-raw-api       make the raw api unavailable],
203   if test "$enable_raw_api" = "no"; then
204     AC_DEFINE(FFI_NO_RAW_API, 1, [Define this is you do not want support for the raw API.])
205   fi)
206
207 AC_ARG_ENABLE(purify-safety,
208 [  --enable-purify-safety  purify-safe mode],
209   if test "$enable_purify_safety" = "yes"; then
210     AC_DEFINE(USING_PURIFY, 1, [Define this if you are using Purify and want to suppress spurious messages.])
211   fi)
212
213 if test -n "$with_cross_host" &&
214    test x"$with_cross_host" != x"no"; then
215   toolexecdir='$(exec_prefix)/$(target_alias)'
216   toolexeclibdir='$(toolexecdir)/lib'
217 else
218   toolexecdir='$(libdir)/gcc-lib/$(target_alias)'
219   toolexeclibdir='$(libdir)'
220 fi
221 multi_os_directory=`$CC -print-multi-os-directory`
222 case $multi_os_directory in
223   .) ;; # Avoid trailing /.
224   *) toolexeclibdir=$toolexeclibdir/$multi_os_directory ;;
225 esac
226 AC_SUBST(toolexecdir)
227 AC_SUBST(toolexeclibdir)
228
229 TL_AC_GCC_VERSION([$srcdir/..])
230
231 #Figure out where generated headers like ffitarget.h get installed.
232 tool_include_dir='$(libdir)/gcc/$(target_alias)/'${gcc_version}/include
233 AC_SUBST(tool_include_dir)
234
235 if test "${multilib}" = "yes"; then
236   multilib_arg="--enable-multilib"
237 else
238   multilib_arg=
239 fi
240
241 AC_CONFIG_COMMANDS(include, [test -d include || mkdir include])
242 AC_CONFIG_COMMANDS(src, [
243 test -d src || mkdir src
244 test -d src/$TARGETDIR || mkdir src/$TARGETDIR
245 ], [TARGETDIR="$TARGETDIR"])
246
247 AC_CONFIG_LINKS(include/ffitarget.h:src/$TARGETDIR/ffitarget.h)
248
249 AC_CONFIG_FILES(include/Makefile include/ffi.h Makefile testsuite/Makefile)
250
251 AC_OUTPUT