OSDN Git Service

2004-03-15 Ian Lance Taylor <ian@wasabisystems.com>
[pf3gnuchains/gcc-fork.git] / libffi / configure.ac
1 dnl Process this with autoconf to create configure
2
3 AC_PREREQ(2.59)
4
5 AC_INIT([libffi], [2.1], [http://gcc.gnu.org/bugs.html])
6 AC_CONFIG_HEADERS([fficonfig.h])
7
8 AM_ENABLE_MULTILIB(, ..)
9 if test a = b; then
10    # This is for automake
11    AC_CONFIG_AUX_DIR([..])
12 else
13    # and this is for autoconf
14    AC_CONFIG_AUX_DIRS(${multi_basedir})
15  fi
16
17 AC_CANONICAL_SYSTEM
18 target_alias=${target_alias-$host_alias}
19
20 AM_INIT_AUTOMAKE
21
22 # The same as in boehm-gc and libstdc++. Have to borrow it from there.
23 # We must force CC to /not/ be precious variables; otherwise
24 # the wrong, non-multilib-adjusted value will be used in multilibs.
25 # As a side effect, we have to subst CFLAGS ourselves.
26
27 m4_rename([_AC_ARG_VAR_PRECIOUS],[real_PRECIOUS])
28 m4_define([_AC_ARG_VAR_PRECIOUS],[])
29 AC_PROG_CC
30 m4_rename([real_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
31
32 AC_SUBST(CFLAGS)
33
34 AM_PROG_AS
35 AM_PROG_CC_C_O
36 AC_PROG_LIBTOOL
37
38 AM_MAINTAINER_MODE
39
40 AC_FUNC_MMAP_BLACKLIST
41
42 dnl The -no-testsuite modules omit the test subdir.
43 AM_CONDITIONAL(TESTSUBDIR, test -d $srcdir/testsuite)
44
45 TARGETDIR="unknown"
46 case "$host" in
47 i*86-*-linux*) TARGET=X86; TARGETDIR=x86;;
48 i*86-*-solaris*) TARGET=X86; TARGETDIR=x86;;
49 i*86-*-beos*) TARGET=X86; TARGETDIR=x86;;
50 i*86-*-freebsd*) TARGET=X86; TARGETDIR=x86;;
51 i*86-*-netbsdelf*) TARGET=X86; TARGETDIR=x86;;
52 i*86-*-win32*) TARGET=X86_WIN32; TARGETDIR=x86;;
53 i*86-*-cygwin*) TARGET=X86_WIN32; TARGETDIR=x86;;
54 i*86-*-mingw*) TARGET=X86_WIN32; TARGETDIR=x86;;
55 sparc-sun-4*) TARGET=SPARC; TARGETDIR=sparc;;
56 sparc*-sun-*) TARGET=SPARC; TARGETDIR=sparc;;
57 sparc-*-linux* | sparc-*-netbsdelf*) TARGET=SPARC; TARGETDIR=sparc;;
58 sparc64-*-linux* | sparc64-*-netbsd*) TARGET=SPARC; TARGETDIR=sparc;;
59 alpha*-*-linux* | alpha*-*-osf* | alpha*-*-freebsd* | alpha*-*-netbsd*) TARGET=ALPHA; TARGETDIR=alpha;;
60 ia64*-*-*) TARGET=IA64; TARGETDIR=ia64;;
61 m68k-*-linux*) TARGET=M68K; TARGETDIR=m68k;;
62 mips64*-*);;
63 mips-sgi-irix5.* | mips-sgi-irix6.*) TARGET=MIPS_IRIX; TARGETDIR=mips;;
64 mips*-*-linux*) TARGET=MIPS_LINUX; TARGETDIR=mips;;
65 powerpc*-*-linux* | powerpc-*-sysv*) TARGET=POWERPC; TARGETDIR=powerpc;;
66 powerpc-*-beos*) TARGET=POWERPC; TARGETDIR=powerpc;;
67 powerpc-*-darwin*) TARGET=POWERPC_DARWIN; TARGETDIR=powerpc;;
68 powerpc-*-aix*) TARGET=POWERPC_AIX; TARGETDIR=powerpc;;
69 rs6000-*-aix*) TARGET=POWERPC_AIX; TARGETDIR=powerpc;;
70 arm*-*-linux-*) TARGET=ARM; TARGETDIR=arm;;
71 arm*-*-netbsdelf*) TARGET=ARM; TARGETDIR=arm;;
72 s390-*-linux-*) TARGET=S390; TARGETDIR=s390;;
73 s390x-*-linux-*) TARGET=S390; TARGETDIR=s390;;
74 x86_64-*-linux*) TARGET=X86_64; TARGETDIR=x86;;
75 sh-*-linux* | sh[[34]]*-*-linux*) TARGET=SH; TARGETDIR=sh;;
76 sh64-*-linux* | sh5*-*-linux*) TARGET=SH64; TARGETDIR=sh64;;
77 esac
78
79 AC_SUBST(AM_RUNTESTFLAGS)
80
81 if test $TARGETDIR = unknown; then
82   AC_MSG_ERROR(["libffi has not been ported to $host."])
83 fi
84
85 AM_CONDITIONAL(MIPS_IRIX, test x$TARGET = xMIPS_IRIX)
86 AM_CONDITIONAL(MIPS_LINUX, test x$TARGET = xMIPS_LINUX)
87 AM_CONDITIONAL(SPARC, test x$TARGET = xSPARC)
88 AM_CONDITIONAL(X86, test x$TARGET = xX86)
89 AM_CONDITIONAL(X86_WIN32, test x$TARGET = xX86_WIN32)
90 AM_CONDITIONAL(ALPHA, test x$TARGET = xALPHA)
91 AM_CONDITIONAL(IA64, test x$TARGET = xIA64)
92 AM_CONDITIONAL(M68K, test x$TARGET = xM68K)
93 AM_CONDITIONAL(POWERPC, test x$TARGET = xPOWERPC)
94 AM_CONDITIONAL(POWERPC_AIX, test x$TARGET = xPOWERPC_AIX)
95 AM_CONDITIONAL(POWERPC_DARWIN, test x$TARGET = xPOWERPC_DARWIN)
96 AM_CONDITIONAL(ARM, test x$TARGET = xARM)
97 AM_CONDITIONAL(S390, test x$TARGET = xS390)
98 AM_CONDITIONAL(X86_64, test x$TARGET = xX86_64)
99 AM_CONDITIONAL(SH, test x$TARGET = xSH)
100 AM_CONDITIONAL(SH64, test x$TARGET = xSH64)
101
102 case x$TARGET in
103   xMIPS*) TARGET=MIPS ;;
104   *) ;;
105 esac
106
107 AC_HEADER_STDC
108 AC_CHECK_FUNCS(memcpy)
109 AC_FUNC_ALLOCA
110
111 AC_COMPILE_CHECK_SIZEOF(double)
112 AC_COMPILE_CHECK_SIZEOF(long double)
113
114 # Also AC_SUBST this variable for ffi.h.
115 HAVE_LONG_DOUBLE=0
116 if test $ac_cv_sizeof_double != $ac_cv_sizeof_long_double; then
117   if test $ac_cv_sizeof_long_double != 0; then
118     HAVE_LONG_DOUBLE=1
119     AC_DEFINE(HAVE_LONG_DOUBLE, 1, [Define if you have the long double type and it is bigger than a double])
120   fi
121 fi
122 AC_SUBST(HAVE_LONG_DOUBLE)
123
124 AC_C_BIGENDIAN_CROSS
125
126 if test x$TARGET = xSPARC; then
127     AC_CACHE_CHECK([assembler and linker support unaligned pc related relocs],
128         libffi_cv_as_sparc_ua_pcrel, [
129         save_CFLAGS="$CFLAGS"
130         save_LDFLAGS="$LDFLAGS"
131         CFLAGS="$CFLAGS -fpic"
132         LDFLAGS="$LDFLAGS -shared"
133         AC_TRY_LINK([asm (".text; foo: nop; .data; .align 4; .byte 0; .uaword %r_disp32(foo); .text");],,
134                     [libffi_cv_as_sparc_ua_pcrel=yes],
135                     [libffi_cv_as_sparc_ua_pcrel=no])
136         CFLAGS="$save_CFLAGS"
137         LDFLAGS="$save_LDFLAGS"])
138     if test "x$libffi_cv_as_sparc_ua_pcrel" = xyes; then
139         AC_DEFINE(HAVE_AS_SPARC_UA_PCREL, 1,
140                   [Define if your assembler and linker support unaligned PC relative relocs.])
141     fi
142
143     AC_CACHE_CHECK([assembler .register pseudo-op support],
144        libffi_cv_as_register_pseudo_op, [
145        libffi_cv_as_register_pseudo_op=unknown
146        # Check if we have .register
147        AC_TRY_COMPILE([asm (".register %g2, #scratch");],,
148                        [libffi_cv_as_register_pseudo_op=yes],
149                        [libffi_cv_as_register_pseudo_op=no])
150     ])
151     if test "x$libffi_cv_as_register_pseudo_op" = xyes; then
152        AC_DEFINE(HAVE_AS_REGISTER_PSEUDO_OP, 1,
153                [Define if your assembler supports .register.])
154     fi
155 fi
156
157 AC_CACHE_CHECK([whether .eh_frame section should be read-only],
158     libffi_cv_ro_eh_frame, [
159         libffi_cv_ro_eh_frame=no
160         echo 'extern void foo (void); void bar (void) { foo (); foo (); }' > conftest.c
161         if $CC $CFLAGS -S -fpic -fexceptions -o conftest.s conftest.c > /dev/null 2>&1; then
162             if grep '.section.*eh_frame.*"a"' conftest.s > /dev/null; then
163                 libffi_cv_ro_eh_frame=yes
164             elif grep '.section.*eh_frame.*#alloc' conftest.c \
165                  | grep -v '#write' > /dev/null; then
166                 libffi_cv_ro_eh_frame=yes
167             fi
168         fi
169         rm -f conftest.*
170     ])
171 if test "x$libffi_cv_ro_eh_frame" = xyes; then
172     AC_DEFINE(HAVE_RO_EH_FRAME, 1,
173               [Define if .eh_frame sections should be read-only.])
174     AC_DEFINE(EH_FRAME_FLAGS, "a",
175               [Define to the flags needed for the .section .eh_frame directive.])
176 else
177     AC_DEFINE(EH_FRAME_FLAGS, "aw",
178               [Define to the flags needed for the .section .eh_frame directive.])
179 fi
180
181 AC_SUBST(TARGET)
182 AC_SUBST(TARGETDIR)
183
184 AC_SUBST(SHELL)
185
186 AC_ARG_ENABLE(debug,
187 [  --enable-debug          debugging mode],
188   if test "$enable_debug" = "yes"; then
189     AC_DEFINE(FFI_DEBUG, 1, [Define this if you want extra debugging.])
190   fi)
191
192 AC_ARG_ENABLE(structs,
193 [  --disable-structs       omit code for struct support],
194   if test "$enable_structs" = "no"; then
195     AC_DEFINE(FFI_NO_STRUCTS, 1, [Define this is you do not want support for aggregate types.])
196   fi)
197
198 AC_ARG_ENABLE(raw-api,
199 [  --disable-raw-api       make the raw api unavailable],
200   if test "$enable_raw_api" = "no"; then
201     AC_DEFINE(FFI_NO_RAW_API, 1, [Define this is you do not want support for the raw API.])
202   fi)
203
204 AC_ARG_ENABLE(purify-safety,
205 [  --enable-purify-safety  purify-safe mode],
206   if test "$enable_purify_safety" = "yes"; then
207     AC_DEFINE(USING_PURIFY, 1, [Define this if you are using Purify and want to suppress spurious messages.])
208   fi)
209
210 if test -n "$with_cross_host" &&
211    test x"$with_cross_host" != x"no"; then
212   toolexecdir='$(exec_prefix)/$(target_alias)'
213   toolexeclibdir='$(toolexecdir)/lib'
214 else
215   toolexecdir='$(libdir)/gcc-lib/$(target_alias)'
216   toolexeclibdir='$(libdir)'
217 fi
218 multi_os_directory=`$CC -print-multi-os-directory`
219 case $multi_os_directory in
220   .) ;; # Avoid trailing /.
221   *) toolexeclibdir=$toolexeclibdir/$multi_os_directory ;;
222 esac
223 AC_SUBST(toolexecdir)
224 AC_SUBST(toolexeclibdir)
225
226 #Figure out where generated headers like ffitarget.h get installed.
227 changequote(,)dnl
228 gcc_version_trigger=${srcdir}/../gcc/version.c
229 gcc_version_full=`grep version_string ${gcc_version_trigger} | sed -e 's/.*\"\([^\"]*\)\".*/\1/'`
230 gcc_version=`echo ${gcc_version_full} | sed -e 's/\([^ ]*\) .*/\1/'`
231 tool_include_dir='$(libdir)/gcc/$(target_alias)/'${gcc_version}/include
232 changequote([,])dnl
233 AC_SUBST(tool_include_dir)
234 AC_SUBST(gcc_version)
235
236
237 if test "${multilib}" = "yes"; then
238   multilib_arg="--enable-multilib"
239 else
240   multilib_arg=
241 fi
242
243 AC_CONFIG_COMMANDS(include, [test -d include || mkdir include])
244 AC_CONFIG_COMMANDS(src, [
245 test -d src || mkdir src
246 test -d src/$TARGETDIR || mkdir src/$TARGETDIR
247 ], [TARGETDIR="$TARGETDIR"])
248
249 AC_CONFIG_LINKS(include/ffitarget.h:src/$TARGETDIR/ffitarget.h)
250
251 AC_CONFIG_FILES(include/Makefile include/ffi.h Makefile testsuite/Makefile)
252
253 AC_OUTPUT