OSDN Git Service

2008-02-12 Bjoern Koenig <bkoenig@alpha-tierchen.de>
[pf3gnuchains/gcc-fork.git] / libffi / configure.ac
1 dnl Process this with autoconf to create configure
2
3 AC_PREREQ(2.59)
4
5 AC_INIT([libffi], [2.1], [http://gcc.gnu.org/bugs.html])
6 AC_CONFIG_HEADERS([fficonfig.h])
7
8 AM_ENABLE_MULTILIB(, ..)
9
10 AC_CANONICAL_SYSTEM
11 target_alias=${target_alias-$host_alias}
12
13 . ${srcdir}/configure.host
14
15 AM_INIT_AUTOMAKE
16
17 # The same as in boehm-gc and libstdc++. Have to borrow it from there.
18 # We must force CC to /not/ be precious variables; otherwise
19 # the wrong, non-multilib-adjusted value will be used in multilibs.
20 # As a side effect, we have to subst CFLAGS ourselves.
21
22 m4_rename([_AC_ARG_VAR_PRECIOUS],[real_PRECIOUS])
23 m4_define([_AC_ARG_VAR_PRECIOUS],[])
24 AC_PROG_CC
25 m4_rename([real_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
26
27 AC_SUBST(CFLAGS)
28
29 AM_PROG_AS
30 AM_PROG_CC_C_O
31 AC_PROG_LIBTOOL
32
33 AM_MAINTAINER_MODE
34
35 AC_CHECK_HEADERS(sys/mman.h)
36 AC_CHECK_FUNCS(mmap)
37 AC_FUNC_MMAP_BLACKLIST
38
39 dnl The -no-testsuite modules omit the test subdir.
40 AM_CONDITIONAL(TESTSUBDIR, test -d $srcdir/testsuite)
41
42 TARGETDIR="unknown"
43 case "$host" in
44   alpha*-*-*)
45         TARGET=ALPHA; TARGETDIR=alpha;
46         # Support 128-bit long double, changable via command-line switch.
47         HAVE_LONG_DOUBLE='defined(__LONG_DOUBLE_128__)'
48         ;;
49
50   arm*-*-*)
51         TARGET=ARM; TARGETDIR=arm
52         ;;
53
54   amd64-*-freebsd*)
55         TARGET=X86_64; TARGETDIR=x86
56         ;;
57
58   cris-*-*)
59         TARGET=LIBFFI_CRIS; TARGETDIR=cris
60         ;;
61
62   frv-*-*)
63         TARGET=FRV; TARGETDIR=frv
64         ;;
65
66   hppa*-*-linux* | parisc*-*-linux*)
67         TARGET=PA_LINUX; TARGETDIR=pa
68         ;;
69   hppa*64-*-hpux*)
70         TARGET=PA64_HPUX; TARGETDIR=pa
71         ;;
72   hppa*-*-hpux*)
73         TARGET=PA_HPUX; TARGETDIR=pa
74         ;;
75
76   i?86-win32* | i?86-*-cygwin* | i?86-*-mingw*)
77         TARGET=X86_WIN32; TARGETDIR=x86
78         ;;
79   i?86-*-darwin*)
80         TARGET=X86_DARWIN; TARGETDIR=x86
81         ;;
82   i?86-*-solaris2.1[[0-9]]*)
83         TARGET=X86_64; TARGETDIR=x86
84         ;;
85   i?86-*-*)
86         TARGET=X86; TARGETDIR=x86
87         ;;
88
89   ia64*-*-*)
90         TARGET=IA64; TARGETDIR=ia64
91         ;;
92
93   m32r*-*-*)
94         TARGET=M32R; TARGETDIR=m32r
95         ;;
96
97   m68k-*-*)
98         TARGET=M68K; TARGETDIR=m68k
99         ;;
100
101   mips-sgi-irix5.* | mips-sgi-irix6.*)
102         TARGET=MIPS; TARGETDIR=mips
103         ;;
104   mips*-*-linux*)
105         TARGET=MIPS; TARGETDIR=mips
106         ;;
107
108   powerpc*-*-linux* | powerpc-*-sysv*)
109         TARGET=POWERPC; TARGETDIR=powerpc
110         ;;
111   powerpc-*-beos*)
112         TARGET=POWERPC; TARGETDIR=powerpc
113         ;;
114   powerpc-*-darwin*)
115         TARGET=POWERPC_DARWIN; TARGETDIR=powerpc
116         ;;
117   powerpc-*-aix* | rs6000-*-aix*)
118         TARGET=POWERPC_AIX; TARGETDIR=powerpc
119         ;;
120   powerpc-*-freebsd*)
121         TARGET=POWERPC_FREEBSD; TARGETDIR=powerpc
122         ;;
123   powerpc*-*-rtems*)
124         TARGET=POWERPC; TARGETDIR=powerpc
125         ;;
126
127   s390-*-* | s390x-*-*)
128         TARGET=S390; TARGETDIR=s390
129         ;;
130
131   sh-*-* | sh[[34]]*-*-*)
132         TARGET=SH; TARGETDIR=sh
133         ;;
134   sh64-*-* | sh5*-*-*)
135         TARGET=SH64; TARGETDIR=sh64
136         ;;
137
138   sparc*-*-*)
139         TARGET=SPARC; TARGETDIR=sparc
140         ;;
141
142   x86_64-*-darwin*)
143         TARGET=X86_DARWIN; TARGETDIR=x86
144         ;;
145   x86_64-*-cygwin* | x86_64-*-mingw*)
146         ;;
147   x86_64-*-*)
148         TARGET=X86_64; TARGETDIR=x86
149         ;;
150 esac
151
152 AC_SUBST(AM_RUNTESTFLAGS)
153
154 if test $TARGETDIR = unknown; then
155   AC_MSG_ERROR(["libffi has not been ported to $host."])
156 fi
157
158 AM_CONDITIONAL(MIPS, test x$TARGET = xMIPS)
159 AM_CONDITIONAL(SPARC, test x$TARGET = xSPARC)
160 AM_CONDITIONAL(X86, test x$TARGET = xX86)
161 AM_CONDITIONAL(X86_WIN32, test x$TARGET = xX86_WIN32)
162 AM_CONDITIONAL(X86_DARWIN, test x$TARGET = xX86_DARWIN)
163 AM_CONDITIONAL(ALPHA, test x$TARGET = xALPHA)
164 AM_CONDITIONAL(IA64, test x$TARGET = xIA64)
165 AM_CONDITIONAL(M32R, test x$TARGET = xM32R)
166 AM_CONDITIONAL(M68K, test x$TARGET = xM68K)
167 AM_CONDITIONAL(POWERPC, test x$TARGET = xPOWERPC)
168 AM_CONDITIONAL(POWERPC_AIX, test x$TARGET = xPOWERPC_AIX)
169 AM_CONDITIONAL(POWERPC_DARWIN, test x$TARGET = xPOWERPC_DARWIN)
170 AM_CONDITIONAL(POWERPC_FREEBSD, test x$TARGET = xPOWERPC_FREEBSD)
171 AM_CONDITIONAL(ARM, test x$TARGET = xARM)
172 AM_CONDITIONAL(LIBFFI_CRIS, test x$TARGET = xLIBFFI_CRIS)
173 AM_CONDITIONAL(FRV, test x$TARGET = xFRV)
174 AM_CONDITIONAL(S390, test x$TARGET = xS390)
175 AM_CONDITIONAL(X86_64, test x$TARGET = xX86_64)
176 AM_CONDITIONAL(SH, test x$TARGET = xSH)
177 AM_CONDITIONAL(SH64, test x$TARGET = xSH64)
178 AM_CONDITIONAL(PA_LINUX, test x$TARGET = xPA_LINUX)
179 AM_CONDITIONAL(PA_HPUX, test x$TARGET = xPA_HPUX)
180 AM_CONDITIONAL(PA64_HPUX, test x$TARGET = xPA64_HPUX)
181
182 AC_HEADER_STDC
183 AC_CHECK_FUNCS(memcpy)
184 AC_FUNC_ALLOCA
185
186 AC_CHECK_SIZEOF(double)
187 AC_CHECK_SIZEOF(long double)
188
189 # Also AC_SUBST this variable for ffi.h.
190 if test -z "$HAVE_LONG_DOUBLE"; then
191   HAVE_LONG_DOUBLE=0
192   if test $ac_cv_sizeof_double != $ac_cv_sizeof_long_double; then
193     if test $ac_cv_sizeof_long_double != 0; then
194       HAVE_LONG_DOUBLE=1
195       AC_DEFINE(HAVE_LONG_DOUBLE, 1, [Define if you have the long double type and it is bigger than a double])
196     fi
197   fi
198 fi
199 AC_SUBST(HAVE_LONG_DOUBLE)
200
201 AC_C_BIGENDIAN
202
203 AC_CACHE_CHECK([assembler .cfi pseudo-op support],
204     libffi_cv_as_cfi_pseudo_op, [
205     libffi_cv_as_cfi_pseudo_op=unknown
206     AC_TRY_COMPILE([asm (".cfi_startproc\n\t.cfi_endproc");],,
207                    [libffi_cv_as_cfi_pseudo_op=yes],
208                    [libffi_cv_as_cfi_pseudo_op=no])
209 ])
210 if test "x$libffi_cv_as_cfi_pseudo_op" = xyes; then
211     AC_DEFINE(HAVE_AS_CFI_PSEUDO_OP, 1,
212               [Define if your assembler supports .cfi_* directives.])
213 fi
214
215 if test x$TARGET = xSPARC; then
216     AC_CACHE_CHECK([assembler and linker support unaligned pc related relocs],
217         libffi_cv_as_sparc_ua_pcrel, [
218         save_CFLAGS="$CFLAGS"
219         save_LDFLAGS="$LDFLAGS"
220         CFLAGS="$CFLAGS -fpic"
221         LDFLAGS="$LDFLAGS -shared"
222         AC_TRY_LINK([asm (".text; foo: nop; .data; .align 4; .byte 0; .uaword %r_disp32(foo); .text");],,
223                     [libffi_cv_as_sparc_ua_pcrel=yes],
224                     [libffi_cv_as_sparc_ua_pcrel=no])
225         CFLAGS="$save_CFLAGS"
226         LDFLAGS="$save_LDFLAGS"])
227     if test "x$libffi_cv_as_sparc_ua_pcrel" = xyes; then
228         AC_DEFINE(HAVE_AS_SPARC_UA_PCREL, 1,
229                   [Define if your assembler and linker support unaligned PC relative relocs.])
230     fi
231
232     AC_CACHE_CHECK([assembler .register pseudo-op support],
233        libffi_cv_as_register_pseudo_op, [
234        libffi_cv_as_register_pseudo_op=unknown
235        # Check if we have .register
236        AC_TRY_COMPILE([asm (".register %g2, #scratch");],,
237                        [libffi_cv_as_register_pseudo_op=yes],
238                        [libffi_cv_as_register_pseudo_op=no])
239     ])
240     if test "x$libffi_cv_as_register_pseudo_op" = xyes; then
241        AC_DEFINE(HAVE_AS_REGISTER_PSEUDO_OP, 1,
242                [Define if your assembler supports .register.])
243     fi
244 fi
245
246 AC_CACHE_CHECK([whether .eh_frame section should be read-only],
247     libffi_cv_ro_eh_frame, [
248         libffi_cv_ro_eh_frame=no
249         echo 'extern void foo (void); void bar (void) { foo (); foo (); }' > conftest.c
250         if $CC $CFLAGS -S -fpic -fexceptions -o conftest.s conftest.c > /dev/null 2>&1; then
251             if grep '.section.*eh_frame.*"a"' conftest.s > /dev/null; then
252                 libffi_cv_ro_eh_frame=yes
253             elif grep '.section.*eh_frame.*#alloc' conftest.c \
254                  | grep -v '#write' > /dev/null; then
255                 libffi_cv_ro_eh_frame=yes
256             fi
257         fi
258         rm -f conftest.*
259     ])
260 if test "x$libffi_cv_ro_eh_frame" = xyes; then
261     AC_DEFINE(HAVE_RO_EH_FRAME, 1,
262               [Define if .eh_frame sections should be read-only.])
263     AC_DEFINE(EH_FRAME_FLAGS, "a",
264               [Define to the flags needed for the .section .eh_frame directive.])
265 else
266     AC_DEFINE(EH_FRAME_FLAGS, "aw",
267               [Define to the flags needed for the .section .eh_frame directive.])
268 fi
269
270 AC_CACHE_CHECK([for __attribute__((visibility("hidden")))],
271     libffi_cv_hidden_visibility_attribute, [
272         echo 'int __attribute__ ((visibility ("hidden"))) foo (void) { return 1; }' > conftest.c
273         libffi_cv_hidden_visibility_attribute=no
274         if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
275             if grep '\.hidden.*foo' conftest.s >/dev/null; then
276                 libffi_cv_hidden_visibility_attribute=yes
277             fi
278         fi
279         rm -f conftest.*
280     ])
281 if test $libffi_cv_hidden_visibility_attribute = yes; then
282     AC_DEFINE(HAVE_HIDDEN_VISIBILITY_ATTRIBUTE, 1,
283               [Define if __attribute__((visibility("hidden"))) is supported.])
284 fi
285
286 AH_BOTTOM([
287 #ifdef HAVE_HIDDEN_VISIBILITY_ATTRIBUTE
288 #ifdef LIBFFI_ASM
289 #define FFI_HIDDEN(name) .hidden name
290 #else
291 #define FFI_HIDDEN __attribute__ ((visibility ("hidden")))
292 #endif
293 #else
294 #ifdef LIBFFI_ASM
295 #define FFI_HIDDEN(name)
296 #else
297 #define FFI_HIDDEN
298 #endif
299 #endif
300 ])
301
302 AC_SUBST(TARGET)
303 AC_SUBST(TARGETDIR)
304
305 AC_SUBST(SHELL)
306
307 AC_ARG_ENABLE(debug,
308 [  --enable-debug          debugging mode],
309   if test "$enable_debug" = "yes"; then
310     AC_DEFINE(FFI_DEBUG, 1, [Define this if you want extra debugging.])
311   fi)
312
313 AC_ARG_ENABLE(structs,
314 [  --disable-structs       omit code for struct support],
315   if test "$enable_structs" = "no"; then
316     AC_DEFINE(FFI_NO_STRUCTS, 1, [Define this is you do not want support for aggregate types.])
317   fi)
318
319 AC_ARG_ENABLE(raw-api,
320 [  --disable-raw-api       make the raw api unavailable],
321   if test "$enable_raw_api" = "no"; then
322     AC_DEFINE(FFI_NO_RAW_API, 1, [Define this is you do not want support for the raw API.])
323   fi)
324
325 AC_ARG_ENABLE(purify-safety,
326 [  --enable-purify-safety  purify-safe mode],
327   if test "$enable_purify_safety" = "yes"; then
328     AC_DEFINE(USING_PURIFY, 1, [Define this if you are using Purify and want to suppress spurious messages.])
329   fi)
330
331 if test -n "$with_cross_host" &&
332    test x"$with_cross_host" != x"no"; then
333   toolexecdir='$(exec_prefix)/$(target_alias)'
334   toolexeclibdir='$(toolexecdir)/lib'
335 else
336   toolexecdir='$(libdir)/gcc-lib/$(target_alias)'
337   toolexeclibdir='$(libdir)'
338 fi
339 multi_os_directory=`$CC -print-multi-os-directory`
340 case $multi_os_directory in
341   .) ;; # Avoid trailing /.
342   *) toolexeclibdir=$toolexeclibdir/$multi_os_directory ;;
343 esac
344 AC_SUBST(toolexecdir)
345 AC_SUBST(toolexeclibdir)
346
347 if test "${multilib}" = "yes"; then
348   multilib_arg="--enable-multilib"
349 else
350   multilib_arg=
351 fi
352
353 AC_CONFIG_COMMANDS(include, [test -d include || mkdir include])
354 AC_CONFIG_COMMANDS(src, [
355 test -d src || mkdir src
356 test -d src/$TARGETDIR || mkdir src/$TARGETDIR
357 ], [TARGETDIR="$TARGETDIR"])
358
359 AC_CONFIG_LINKS(include/ffitarget.h:src/$TARGETDIR/ffitarget.h)
360
361 AC_CONFIG_FILES(include/Makefile include/ffi.h Makefile testsuite/Makefile)
362
363 AC_OUTPUT