libffi/configure.ac

   1 dnl Process this with autoconf to create configure
   2
   3 AC_PREREQ(2.64)
   4
   5 AC_INIT([libffi], [3.0.9], [http://gcc.gnu.org/bugs.html])
   6 AC_CONFIG_HEADERS([fficonfig.h])
   7
   8 AM_ENABLE_MULTILIB(, ..)
   9
  10 AC_CANONICAL_SYSTEM
  11 target_alias=${target_alias-$host_alias}
  12
  13 . ${srcdir}/configure.host
  14
  15 AM_INIT_AUTOMAKE([no-dist])
  16
  17 # The same as in boehm-gc and libstdc++. Have to borrow it from there.
  18 # We must force CC to /not/ be precious variables; otherwise
  19 # the wrong, non-multilib-adjusted value will be used in multilibs.
  20 # As a side effect, we have to subst CFLAGS ourselves.
  21
  22 m4_rename([_AC_ARG_VAR_PRECIOUS],[real_PRECIOUS])
  23 m4_define([_AC_ARG_VAR_PRECIOUS],[])
  24 AC_PROG_CC
  25 m4_rename_force([real_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
  26
  27 AC_SUBST(CFLAGS)
  28
  29 AM_PROG_AS
  30 AM_PROG_CC_C_O
  31 AC_PROG_LIBTOOL
  32
  33 AM_MAINTAINER_MODE
  34
  35 AC_CHECK_HEADERS(sys/mman.h)
  36 AC_CHECK_FUNCS(mmap)
  37 AC_FUNC_MMAP_BLACKLIST
  38
  39 dnl The -no-testsuite modules omit the test subdir.
  40 AM_CONDITIONAL(TESTSUBDIR, test -d $srcdir/testsuite)
  41
  42 TARGETDIR="unknown"
  43 case "$host" in
  44   alpha*-*-*)
  45         TARGET=ALPHA; TARGETDIR=alpha;
  46         # Support 128-bit long double, changeable via command-line switch.
  47         HAVE_LONG_DOUBLE='defined(__LONG_DOUBLE_128__)'
  48         ;;
  49
  50   arm*-*-*)
  51         TARGET=ARM; TARGETDIR=arm
  52         ;;
  53
  54   amd64-*-freebsd* | amd64-*-openbsd*)
  55         TARGET=X86_64; TARGETDIR=x86
  56         ;;
  57
  58   avr32*-*-*)
  59         TARGET=AVR32; TARGETDIR=avr32
  60         ;;
  61
  62   cris-*-*)
  63         TARGET=LIBFFI_CRIS; TARGETDIR=cris
  64         ;;
  65
  66   frv-*-*)
  67         TARGET=FRV; TARGETDIR=frv
  68         ;;
  69
  70   hppa*-*-linux* | parisc*-*-linux*)
  71         TARGET=PA_LINUX; TARGETDIR=pa
  72         ;;
  73   hppa*64-*-hpux*)
  74         TARGET=PA64_HPUX; TARGETDIR=pa
  75         ;;
  76   hppa*-*-hpux*)
  77         TARGET=PA_HPUX; TARGETDIR=pa
  78         ;;
  79
  80   i?86-*-freebsd* | i?86-*-openbsd*)
  81         TARGET=X86_FREEBSD; TARGETDIR=x86
  82         ;;
  83   i?86-win32* | i?86-*-cygwin* | i?86-*-mingw* | i?86-*-os2*)
  84         TARGET=X86_WIN32; TARGETDIR=x86
  85         # All mingw/cygwin/win32 builds require -no-undefined for sharedlib.
  86         # We must also check with_cross_host to decide if this is a native
  87         # or cross-build and select where to install dlls appropriately.
  88         if test -n "$with_cross_host" &&
  89            test x"$with_cross_host" != x"no"; then
  90           AM_LTLDFLAGS='-no-undefined -bindir "$(toolexeclibdir)"';
  91         else
  92           AM_LTLDFLAGS='-no-undefined -bindir "$(bindir)"';
  93         fi
  94         ;;
  95   i?86-*-darwin*)
  96         TARGET=X86_DARWIN; TARGETDIR=x86
  97         ;;
  98   i?86-*-solaris2.1[[0-9]]*)
  99         TARGET=X86_64; TARGETDIR=x86
 100         ;;
 101   i?86-*-*)
 102         TARGET=X86; TARGETDIR=x86
 103         ;;
 104
 105   ia64*-*-*)
 106         TARGET=IA64; TARGETDIR=ia64
 107         ;;
 108
 109   m32r*-*-*)
 110         TARGET=M32R; TARGETDIR=m32r
 111         ;;
 112
 113   m68k-*-*)
 114         TARGET=M68K; TARGETDIR=m68k
 115         ;;
 116
 117   mips-sgi-irix5.* | mips-sgi-irix6.* | mips*-*-rtems*)
 118         TARGET=MIPS; TARGETDIR=mips
 119         ;;
 120   mips*-*-linux*)
 121         # Support 128-bit long double for NewABI.
 122         HAVE_LONG_DOUBLE='defined(__mips64)'
 123         TARGET=MIPS; TARGETDIR=mips
 124         ;;
 125
 126   powerpc*-*-linux* | powerpc-*-sysv*)
 127         TARGET=POWERPC; TARGETDIR=powerpc
 128         ;;
 129   powerpc-*-beos*)
 130         TARGET=POWERPC; TARGETDIR=powerpc
 131         ;;
 132   powerpc-*-darwin*)
 133         TARGET=POWERPC_DARWIN; TARGETDIR=powerpc
 134         ;;
 135   powerpc-*-aix* | rs6000-*-aix*)
 136         TARGET=POWERPC_AIX; TARGETDIR=powerpc
 137         ;;
 138   powerpc-*-freebsd*)
 139         TARGET=POWERPC_FREEBSD; TARGETDIR=powerpc
 140         ;;
 141  powerpc64-*-freebsd*)
 142         TARGET=POWERPC; TARGETDIR=powerpc
 143         ;;
 144   powerpc*-*-rtems*)
 145         TARGET=POWERPC; TARGETDIR=powerpc
 146         ;;
 147
 148   s390-*-* | s390x-*-*)
 149         TARGET=S390; TARGETDIR=s390
 150         ;;
 151
 152   sh-*-* | sh[[34]]*-*-*)
 153         TARGET=SH; TARGETDIR=sh
 154         ;;
 155   sh64-*-* | sh5*-*-*)
 156         TARGET=SH64; TARGETDIR=sh64
 157         ;;
 158
 159   sparc*-*-*)
 160         TARGET=SPARC; TARGETDIR=sparc
 161         ;;
 162
 163   x86_64-*-darwin*)
 164         TARGET=X86_DARWIN; TARGETDIR=x86
 165         ;;
 166
 167   x86_64-*-cygwin* | x86_64-*-mingw*)
 168         TARGET=X86_WIN64; TARGETDIR=x86
 169         # All mingw/cygwin/win32 builds require -no-undefined for sharedlib.
 170         # We must also check with_cross_host to decide if this is a native
 171         # or cross-build and select where to install dlls appropriately.
 172         if test -n "$with_cross_host" &&
 173            test x"$with_cross_host" != x"no"; then
 174           AM_LTLDFLAGS='-no-undefined -bindir "$(toolexeclibdir)"';
 175         else
 176           AM_LTLDFLAGS='-no-undefined -bindir "$(bindir)"';
 177         fi
 178         ;;
 179
 180   x86_64-*-*)
 181         TARGET=X86_64; TARGETDIR=x86
 182         ;;
 183 esac
 184
 185 AC_SUBST(AM_RUNTESTFLAGS)
 186 AC_SUBST(AM_LTLDFLAGS)
 187
 188 if test $TARGETDIR = unknown; then
 189   AC_MSG_ERROR(["libffi has not been ported to $host."])
 190 fi
 191
 192 AM_CONDITIONAL(MIPS, test x$TARGET = xMIPS)
 193 AM_CONDITIONAL(SPARC, test x$TARGET = xSPARC)
 194 AM_CONDITIONAL(X86, test x$TARGET = xX86)
 195 AM_CONDITIONAL(X86_FREEBSD, test x$TARGET = xX86_FREEBSD)
 196 AM_CONDITIONAL(X86_WIN32, test x$TARGET = xX86_WIN32)
 197 AM_CONDITIONAL(X86_WIN64, test x$TARGET = xX86_WIN64)
 198 AM_CONDITIONAL(X86_DARWIN, test x$TARGET = xX86_DARWIN)
 199 AM_CONDITIONAL(ALPHA, test x$TARGET = xALPHA)
 200 AM_CONDITIONAL(IA64, test x$TARGET = xIA64)
 201 AM_CONDITIONAL(M32R, test x$TARGET = xM32R)
 202 AM_CONDITIONAL(M68K, test x$TARGET = xM68K)
 203 AM_CONDITIONAL(POWERPC, test x$TARGET = xPOWERPC)
 204 AM_CONDITIONAL(POWERPC_AIX, test x$TARGET = xPOWERPC_AIX)
 205 AM_CONDITIONAL(POWERPC_DARWIN, test x$TARGET = xPOWERPC_DARWIN)
 206 AM_CONDITIONAL(POWERPC_FREEBSD, test x$TARGET = xPOWERPC_FREEBSD)
 207 AM_CONDITIONAL(ARM, test x$TARGET = xARM)
 208 AM_CONDITIONAL(AVR32, test x$TARGET = xAVR32)
 209 AM_CONDITIONAL(LIBFFI_CRIS, test x$TARGET = xLIBFFI_CRIS)
 210 AM_CONDITIONAL(FRV, test x$TARGET = xFRV)
 211 AM_CONDITIONAL(S390, test x$TARGET = xS390)
 212 AM_CONDITIONAL(X86_64, test x$TARGET = xX86_64)
 213 AM_CONDITIONAL(SH, test x$TARGET = xSH)
 214 AM_CONDITIONAL(SH64, test x$TARGET = xSH64)
 215 AM_CONDITIONAL(PA_LINUX, test x$TARGET = xPA_LINUX)
 216 AM_CONDITIONAL(PA_HPUX, test x$TARGET = xPA_HPUX)
 217 AM_CONDITIONAL(PA64_HPUX, test x$TARGET = xPA64_HPUX)
 218
 219 AC_HEADER_STDC
 220 AC_CHECK_FUNCS(memcpy)
 221 AC_FUNC_ALLOCA
 222
 223 AC_CHECK_SIZEOF(double)
 224 AC_CHECK_SIZEOF(long double)
 225
 226 # Also AC_SUBST this variable for ffi.h.
 227 if test -z "$HAVE_LONG_DOUBLE"; then
 228   HAVE_LONG_DOUBLE=0
 229   if test $ac_cv_sizeof_double != $ac_cv_sizeof_long_double; then
 230     if test $ac_cv_sizeof_long_double != 0; then
 231       HAVE_LONG_DOUBLE=1
 232       AC_DEFINE(HAVE_LONG_DOUBLE, 1, [Define if you have the long double type and it is bigger than a double])
 233     fi
 234   fi
 235 fi
 236 AC_SUBST(HAVE_LONG_DOUBLE)
 237
 238 AC_C_BIGENDIAN
 239
 240 AC_CACHE_CHECK([assembler .cfi pseudo-op support],
 241     libffi_cv_as_cfi_pseudo_op, [
 242     libffi_cv_as_cfi_pseudo_op=unknown
 243     AC_TRY_COMPILE([asm (".cfi_startproc\n\t.cfi_endproc");],,
 244                    [libffi_cv_as_cfi_pseudo_op=yes],
 245                    [libffi_cv_as_cfi_pseudo_op=no])
 246 ])
 247 if test "x$libffi_cv_as_cfi_pseudo_op" = xyes; then
 248     AC_DEFINE(HAVE_AS_CFI_PSEUDO_OP, 1,
 249               [Define if your assembler supports .cfi_* directives.])
 250 fi
 251
 252 if test x$TARGET = xSPARC; then
 253     AC_CACHE_CHECK([assembler and linker support unaligned pc related relocs],
 254         libffi_cv_as_sparc_ua_pcrel, [
 255         save_CFLAGS="$CFLAGS"
 256         save_LDFLAGS="$LDFLAGS"
 257         CFLAGS="$CFLAGS -fpic"
 258         LDFLAGS="$LDFLAGS -shared"
 259         AC_TRY_LINK([asm (".text; foo: nop; .data; .align 4; .byte 0; .uaword %r_disp32(foo); .text");],,
 260                     [libffi_cv_as_sparc_ua_pcrel=yes],
 261                     [libffi_cv_as_sparc_ua_pcrel=no])
 262         CFLAGS="$save_CFLAGS"
 263         LDFLAGS="$save_LDFLAGS"])
 264     if test "x$libffi_cv_as_sparc_ua_pcrel" = xyes; then
 265         AC_DEFINE(HAVE_AS_SPARC_UA_PCREL, 1,
 266                   [Define if your assembler and linker support unaligned PC relative relocs.])
 267     fi
 268
 269     AC_CACHE_CHECK([assembler .register pseudo-op support],
 270        libffi_cv_as_register_pseudo_op, [
 271        libffi_cv_as_register_pseudo_op=unknown
 272        # Check if we have .register
 273        AC_TRY_COMPILE([asm (".register %g2, #scratch");],,
 274                        [libffi_cv_as_register_pseudo_op=yes],
 275                        [libffi_cv_as_register_pseudo_op=no])
 276     ])
 277     if test "x$libffi_cv_as_register_pseudo_op" = xyes; then
 278        AC_DEFINE(HAVE_AS_REGISTER_PSEUDO_OP, 1,
 279                [Define if your assembler supports .register.])
 280     fi
 281 fi
 282
 283 if test x$TARGET = xX86 || test x$TARGET = xX86_WIN32 || test x$TARGET = xX86_64; then
 284     AC_CACHE_CHECK([assembler supports pc related relocs],
 285         libffi_cv_as_x86_pcrel, [
 286         libffi_cv_as_x86_pcrel=yes
 287         echo '.text; foo: nop; .data; .long foo-.; .text' > conftest.s
 288         if $CC $CFLAGS -c conftest.s 2>&1 | $EGREP -i 'illegal|warning' > /dev/null; then
 289             libffi_cv_as_x86_pcrel=no
 290         fi
 291         ])
 292     if test "x$libffi_cv_as_x86_pcrel" = xyes; then
 293         AC_DEFINE(HAVE_AS_X86_PCREL, 1,
 294                   [Define if your assembler supports PC relative relocs.])
 295     fi
 296
 297     AC_CACHE_CHECK([assembler .ascii pseudo-op support],
 298        libffi_cv_as_ascii_pseudo_op, [
 299        libffi_cv_as_ascii_pseudo_op=unknown
 300        # Check if we have .ascii
 301        AC_TRY_COMPILE([asm (".ascii \\"string\\"");],,
 302                        [libffi_cv_as_ascii_pseudo_op=yes],
 303                        [libffi_cv_as_ascii_pseudo_op=no])
 304     ])
 305     if test "x$libffi_cv_as_ascii_pseudo_op" = xyes; then
 306        AC_DEFINE(HAVE_AS_ASCII_PSEUDO_OP, 1,
 307                [Define if your assembler supports .ascii.])
 308     fi
 309
 310     AC_CACHE_CHECK([assembler .string pseudo-op support],
 311        libffi_cv_as_string_pseudo_op, [
 312        libffi_cv_as_string_pseudo_op=unknown
 313        # Check if we have .string
 314        AC_TRY_COMPILE([asm (".string \\"string\\"");],,
 315                        [libffi_cv_as_string_pseudo_op=yes],
 316                        [libffi_cv_as_string_pseudo_op=no])
 317     ])
 318     if test "x$libffi_cv_as_string_pseudo_op" = xyes; then
 319        AC_DEFINE(HAVE_AS_STRING_PSEUDO_OP, 1,
 320                [Define if your assembler supports .string.])
 321     fi
 322 fi
 323
 324 case "$target" in
 325      *-apple-darwin10* | *-*-freebsd* | *-*-openbsd* | *-pc-solaris*)
 326        AC_DEFINE(FFI_MMAP_EXEC_WRIT, 1,
 327                  [Cannot use malloc on this target, so, we revert to
 328                    alternative means])
 329      ;;
 330 esac
 331
 332 if test x$TARGET = xX86_64; then
 333     AC_CACHE_CHECK([assembler supports unwind section type],
 334         libffi_cv_as_x86_64_unwind_section_type, [
 335         libffi_cv_as_x86_64_unwind_section_type=yes
 336         echo '.section .eh_frame,"a",@unwind' > conftest.s
 337         if $CC $CFLAGS -c conftest.s 2>&1 | grep -i warning > /dev/null; then
 338             libffi_cv_as_x86_64_unwind_section_type=no
 339         fi
 340         ])
 341     if test "x$libffi_cv_as_x86_64_unwind_section_type" = xyes; then
 342         AC_DEFINE(HAVE_AS_X86_64_UNWIND_SECTION_TYPE, 1,
 343                   [Define if your assembler supports unwind section type.])
 344     fi
 345 fi
 346
 347 AC_CACHE_CHECK([whether .eh_frame section should be read-only],
 348     libffi_cv_ro_eh_frame, [
 349         libffi_cv_ro_eh_frame=no
 350         echo 'extern void foo (void); void bar (void) { foo (); foo (); }' > conftest.c
 351         if $CC $CFLAGS -S -fpic -fexceptions -o conftest.s conftest.c > /dev/null 2>&1; then
 352             if grep '.section.*eh_frame.*"a"' conftest.s > /dev/null; then
 353                 libffi_cv_ro_eh_frame=yes
 354             elif grep '.section.*eh_frame.*#alloc' conftest.c \
 355                  | grep -v '#write' > /dev/null; then
 356                 libffi_cv_ro_eh_frame=yes
 357             fi
 358         fi
 359         rm -f conftest.*
 360     ])
 361 if test "x$libffi_cv_ro_eh_frame" = xyes; then
 362     AC_DEFINE(HAVE_RO_EH_FRAME, 1,
 363               [Define if .eh_frame sections should be read-only.])
 364     AC_DEFINE(EH_FRAME_FLAGS, "a",
 365               [Define to the flags needed for the .section .eh_frame directive.])
 366 else
 367     AC_DEFINE(EH_FRAME_FLAGS, "aw",
 368               [Define to the flags needed for the .section .eh_frame directive.])
 369 fi
 370
 371 AC_CACHE_CHECK([for __attribute__((visibility("hidden")))],
 372     libffi_cv_hidden_visibility_attribute, [
 373         echo 'int __attribute__ ((visibility ("hidden"))) foo (void) { return 1; }' > conftest.c
 374         libffi_cv_hidden_visibility_attribute=no
 375         if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
 376             if grep '\.hidden.*foo' conftest.s >/dev/null; then
 377                 libffi_cv_hidden_visibility_attribute=yes
 378             fi
 379         fi
 380         rm -f conftest.*
 381     ])
 382 if test $libffi_cv_hidden_visibility_attribute = yes; then
 383     AC_DEFINE(HAVE_HIDDEN_VISIBILITY_ATTRIBUTE, 1,
 384               [Define if __attribute__((visibility("hidden"))) is supported.])
 385 fi
 386
 387 AH_BOTTOM([
 388 #ifdef HAVE_HIDDEN_VISIBILITY_ATTRIBUTE
 389 #ifdef LIBFFI_ASM
 390 #define FFI_HIDDEN(name) .hidden name
 391 #else
 392 #define FFI_HIDDEN __attribute__ ((visibility ("hidden")))
 393 #endif
 394 #else
 395 #ifdef LIBFFI_ASM
 396 #define FFI_HIDDEN(name)
 397 #else
 398 #define FFI_HIDDEN
 399 #endif
 400 #endif
 401 ])
 402
 403 AC_SUBST(TARGET)
 404 AC_SUBST(TARGETDIR)
 405
 406 AC_SUBST(SHELL)
 407
 408 AC_ARG_ENABLE(debug,
 409 [  --enable-debug          debugging mode],
 410   if test "$enable_debug" = "yes"; then
 411     AC_DEFINE(FFI_DEBUG, 1, [Define this if you want extra debugging.])
 412   fi)
 413
 414 AC_ARG_ENABLE(structs,
 415 [  --disable-structs       omit code for struct support],
 416   if test "$enable_structs" = "no"; then
 417     AC_DEFINE(FFI_NO_STRUCTS, 1, [Define this is you do not want support for aggregate types.])
 418   fi)
 419
 420 AC_ARG_ENABLE(raw-api,
 421 [  --disable-raw-api       make the raw api unavailable],
 422   if test "$enable_raw_api" = "no"; then
 423     AC_DEFINE(FFI_NO_RAW_API, 1, [Define this is you do not want support for the raw API.])
 424   fi)
 425
 426 AC_ARG_ENABLE(purify-safety,
 427 [  --enable-purify-safety  purify-safe mode],
 428   if test "$enable_purify_safety" = "yes"; then
 429     AC_DEFINE(USING_PURIFY, 1, [Define this if you are using Purify and want to suppress spurious messages.])
 430   fi)
 431
 432 if test -n "$with_cross_host" &&
 433    test x"$with_cross_host" != x"no"; then
 434   toolexecdir='$(exec_prefix)/$(target_alias)'
 435   toolexeclibdir='$(toolexecdir)/lib'
 436 else
 437   toolexecdir='$(libdir)/gcc-lib/$(target_alias)'
 438   toolexeclibdir='$(libdir)'
 439 fi
 440 multi_os_directory=`$CC -print-multi-os-directory`
 441 case $multi_os_directory in
 442   .) ;; # Avoid trailing /.
 443   *) toolexeclibdir=$toolexeclibdir/$multi_os_directory ;;
 444 esac
 445 AC_SUBST(toolexecdir)
 446 AC_SUBST(toolexeclibdir)
 447
 448 if test "${multilib}" = "yes"; then
 449   multilib_arg="--enable-multilib"
 450 else
 451   multilib_arg=
 452 fi
 453
 454 AC_CONFIG_COMMANDS(include, [test -d include || mkdir include])
 455 AC_CONFIG_COMMANDS(src, [
 456 test -d src || mkdir src
 457 test -d src/$TARGETDIR || mkdir src/$TARGETDIR
 458 ], [TARGETDIR="$TARGETDIR"])
 459
 460 AC_CONFIG_LINKS(include/ffitarget.h:src/$TARGETDIR/ffitarget.h)
 461
 462 AC_CONFIG_FILES(include/Makefile include/ffi.h Makefile testsuite/Makefile man/Makefile)
 463
 464 AC_OUTPUT