libcpp/configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 AC_PREREQ(2.64)
   5 AC_INIT(cpplib, [ ], gcc-bugs@gcc.gnu.org, cpplib)
   6 AC_CONFIG_SRCDIR(ucnid.h)
   7 AC_CONFIG_MACRO_DIR(../config)
   8 AC_CANONICAL_SYSTEM
   9
  10 # Checks for programs.
  11 AC_PROG_MAKE_SET
  12 AC_PROG_INSTALL
  13 AC_PROG_CC
  14 AC_PROG_CXX
  15 AC_PROG_RANLIB
  16
  17 AC_USE_SYSTEM_EXTENSIONS
  18 AC_SYS_LARGEFILE
  19
  20 # See if we are building gcc with C++.
  21 # Do this early so setting lang to C++ affects following tests
  22 AC_ARG_ENABLE(build-with-cxx,
  23 [  --enable-build-with-cxx build with C++ compiler instead of C compiler],
  24 ENABLE_BUILD_WITH_CXX=$enableval,
  25 ENABLE_BUILD_WITH_CXX=no)
  26 AC_SUBST(ENABLE_BUILD_WITH_CXX)
  27
  28 MISSING=`cd $ac_aux_dir && ${PWDCMD-pwd}`/missing
  29 AC_CHECK_PROGS([ACLOCAL], [aclocal], [$MISSING aclocal])
  30 AC_CHECK_PROGS([AUTOCONF], [autoconf], [$MISSING autoconf])
  31 AC_CHECK_PROGS([AUTOHEADER], [autoheader], [$MISSING autoheader])
  32
  33 # Figure out what compiler warnings we can enable.
  34 # See config/warnings.m4 for details.
  35
  36 ACX_PROG_CC_WARNING_OPTS([-W -Wall -Wwrite-strings \
  37                           -Wmissing-format-attribute], [warn])
  38 ACX_PROG_CC_WARNING_OPTS([-Wstrict-prototypes -Wmissing-prototypes \
  39                           -Wold-style-definition -Wc++-compat], [c_warn])
  40 ACX_PROG_CC_WARNING_ALMOST_PEDANTIC([-Wno-long-long])
  41
  42 # Only enable with --enable-werror-always until existing warnings are
  43 # corrected.
  44 ACX_PROG_CC_WARNINGS_ARE_ERRORS([manual])
  45
  46 # Dependency checking.
  47 ZW_CREATE_DEPDIR
  48 if test "$ENABLE_BUILD_WITH_CXX" = "no"; then
  49 ZW_PROG_COMPILER_DEPENDENCIES([CC])
  50 else
  51 AC_LANG_PUSH([C++])
  52 AC_COMPILE_IFELSE([[int i;]], [],
  53                   [AC_MSG_ERROR([C++ compiler missing or inoperational])])
  54 AC_LANG_POP([C++])
  55 ZW_PROG_COMPILER_DEPENDENCIES([CXX])
  56 fi
  57
  58 # Checks for header files.
  59 AC_HEADER_TIME
  60 ACX_HEADER_STRING
  61
  62 AC_CHECK_HEADERS(locale.h fcntl.h limits.h stddef.h \
  63         stdlib.h strings.h string.h sys/file.h unistd.h)
  64
  65 # Checks for typedefs, structures, and compiler characteristics.
  66 AC_C_BIGENDIAN
  67 AC_C_CONST
  68 AC_C_INLINE
  69 AC_FUNC_OBSTACK
  70 AC_TYPE_OFF_T
  71 AC_TYPE_SIZE_T
  72 AC_TYPE_SSIZE_T
  73 AC_TYPE_UINTPTR_T
  74 AC_CHECK_TYPE(ptrdiff_t, int)
  75 AC_STRUCT_TM
  76 AC_CHECK_SIZEOF(int)
  77 AC_CHECK_SIZEOF(long)
  78 define(libcpp_UNLOCKED_FUNCS, clearerr_unlocked feof_unlocked dnl
  79   ferror_unlocked fflush_unlocked fgetc_unlocked fgets_unlocked dnl
  80   fileno_unlocked fprintf_unlocked fputc_unlocked fputs_unlocked dnl
  81   fread_unlocked fwrite_unlocked getchar_unlocked getc_unlocked dnl
  82   putchar_unlocked putc_unlocked)
  83 AC_CHECK_FUNCS(libcpp_UNLOCKED_FUNCS)
  84 AC_CHECK_DECLS([abort, asprintf, basename(char *), errno, getopt, vasprintf])
  85 AC_CHECK_DECLS(m4_split(m4_normalize(libcpp_UNLOCKED_FUNCS)))
  86
  87 # Checks for library functions.
  88 AC_FUNC_ALLOCA
  89 AC_HEADER_STDC
  90 AM_LANGINFO_CODESET
  91 ZW_GNU_GETTEXT_SISTER_DIR
  92
  93 AC_CACHE_CHECK(for uchar, gcc_cv_type_uchar,
  94 [AC_TRY_COMPILE([
  95 #include <sys/types.h>
  96 ],
  97 [if ((uchar *)0) return 0;
  98  if (sizeof(uchar)) return 0;],
  99 ac_cv_type_uchar=yes, ac_cv_type_uchar=no)])
 100 if test $ac_cv_type_uchar = yes; then
 101   AC_DEFINE(HAVE_UCHAR, 1,
 102   [Define if <sys/types.h> defines \`uchar'.])
 103 fi
 104
 105 # g++ on Solaris 10+ defines _XOPEN_SOURCE=600, which exposes a different
 106 # iconv() prototype.
 107 AS_IF([test "$ENABLE_BUILD_WITH_CXX" = "yes"],
 108   [AC_LANG_PUSH([C++])
 109    AM_ICONV
 110    AC_LANG_POP([C++])],
 111   [AM_ICONV])
 112
 113 # More defines and substitutions.
 114 PACKAGE="$PACKAGE_TARNAME"
 115 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Define to the name of this package.])
 116 AC_SUBST(PACKAGE)
 117
 118 if test "x$enable_nls" != xno; then
 119   USED_CATALOGS='$(CATALOGS)'
 120 else
 121   USED_CATALOGS=
 122 fi
 123 AC_SUBST(USED_CATALOGS)
 124
 125 AC_ARG_ENABLE(maintainer-mode,
 126 [  --enable-maintainer-mode enable rules only needed by maintainers],,
 127 enable_maintainer_mode=no)
 128
 129 if test "x$enable_maintainer_mode" = xno; then
 130   MAINT='#'
 131 else
 132   MAINT=
 133 fi
 134 AC_SUBST(MAINT)
 135
 136 AC_ARG_ENABLE(checking,
 137 [  --enable-checking      enable expensive run-time checks],,
 138 enable_checking=no)
 139
 140 if test $enable_checking != no ; then
 141   AC_DEFINE(ENABLE_CHECKING, 1,
 142 [Define if you want more run-time sanity checks.])
 143 fi
 144
 145 m4_changequote(,)
 146 case $target in
 147         alpha*-*-* | \
 148         arm*-*-*eabi* | \
 149         arm*-*-symbianelf* | \
 150         x86_64-*-* | \
 151         ia64-*-* | \
 152         hppa*64*-*-* | \
 153         i[34567]86-*-* | x86_64-*-solaris2.1[0-9]* | \
 154         mips*-*-* | \
 155         mmix-*-* | \
 156         powerpc*-*-* | \
 157         rs6000*-*-* | \
 158         s390*-*-* | \
 159         sparc*-*-* | \
 160         spu-*-* | \
 161         sh[123456789lbe]*-*-* | sh-*-*)
 162                 need_64bit_hwint=yes ;;
 163         *)
 164                 need_64bit_hwint=no ;;
 165 esac
 166
 167 case $need_64bit_hwint:$ac_cv_sizeof_long in
 168         *:8 | no:*) host_wide_int=long ;;
 169         *) host_wide_int='long long' ;;
 170 esac
 171 m4_changequote([,])
 172
 173 AC_DEFINE_UNQUOTED(HOST_WIDE_INT, $host_wide_int,
 174 [Define to the widest efficient host integer type at least
 175    as wide as the target's size_t type.])
 176
 177 case $target in
 178   i?86-* | x86_64-*)
 179     AC_TRY_COMPILE([], [asm ("pcmpestri %0, %%xmm0, %%xmm1" : : "i"(0))],
 180       [AC_DEFINE([HAVE_SSE4], [1],
 181                  [Define to 1 if you can assemble SSE4 insns.])])
 182 esac
 183
 184 # Output.
 185
 186 AC_CONFIG_HEADERS(config.h:config.in, [echo timestamp > stamp-h1])
 187 AC_CONFIG_FILES(Makefile)
 188 AC_OUTPUT