OSDN Git Service

Fix corrupted dwarf2 file table with -fno-eliminate-unused-debug-types.
[pf3gnuchains/gcc-fork.git] / libada / configure.ac
1 # Configure script for libada.
2 #   Copyright 2003, 2004 Free Software Foundation, Inc.
3 #
4 # This file is free software; you can redistribute it and/or modify it
5 # under the terms of the GNU General Public License as published by
6 # the Free Software Foundation; either version 2 of the License, or
7 # (at your option) any later version.
8 #
9 # This program is distributed in the hope that it will be useful, but
10 # WITHOUT ANY WARRANTY; without even the implied warranty of
11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
12 # General Public License for more details.
13 #
14 # You should have received a copy of the GNU General Public License
15 # along with this program; if not, write to the Free Software
16 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
17
18 AC_INIT
19 AC_PREREQ([2.59])
20
21 AC_CONFIG_SRCDIR([Makefile.in])
22
23 # Command-line options.
24 # Very limited version of AC_MAINTAINER_MODE.
25 AC_ARG_ENABLE([maintainer-mode],
26   [AC_HELP_STRING([--enable-maintainer-mode],
27                  [enable make rules and dependencies not useful (and
28                   sometimes confusing) to the casual installer])],
29   [case ${enable_maintainer_mode} in
30      yes) MAINT='' ;;
31      no) MAINT='#' ;;
32      *) AC_MSG_ERROR([--enable-maintainer-mode must be yes or no]) ;;
33    esac
34    maintainer_mode=${enableval}],
35   [MAINT='#'])
36 AC_SUBST([MAINT])dnl
37
38 AC_ARG_ENABLE([shared],
39 [AC_HELP_STRING([--disable-shared],
40                 [don't provide a shared libgnat])],
41 [
42 case $enable_shared in
43   yes | no) ;;
44   *)
45     enable_shared=no
46     IFS="${IFS=         }"; ac_save_ifs="$IFS"; IFS="${IFS}:,"
47     for pkg in $enableval; do
48       case $pkg in
49         ada | libada)
50           enable_shared=yes ;;
51       esac
52     done
53     IFS="$ac_save_ifs"
54     ;;
55 esac
56 ], [enable_shared=yes])
57 AC_SUBST([enable_shared])
58
59 # Start of actual configure tests
60
61 AC_CANONICAL_BUILD
62 AC_CANONICAL_HOST
63 AC_CANONICAL_TARGET
64
65 # Need to pass this down for now :-P
66 AC_PROG_LN_S
67
68 # Determine x_ada_cflags
69 case $host in
70   hppa*) x_ada_cflags=-mdisable-indexing ;;
71   *) x_ada_cflags= ;;
72 esac
73 AC_SUBST([x_ada_cflags])
74
75 # Determine what to build for 'gnatlib'
76 if test $build = $target \
77    && test ${enable_shared} = yes ; then
78   # Note that build=target is almost certainly the wrong test; FIXME
79   default_gnatlib_target="gnatlib-shared"
80 else
81   default_gnatlib_target="gnatlib-plain"
82 fi
83 AC_SUBST([default_gnatlib_target])
84
85 # Output: create a Makefile.
86 AC_CONFIG_FILES([Makefile])
87
88 AC_OUTPUT