gcc/testsuite/lib/target-supports.exp

   1 #   Copyright (C) 1999, 2001, 2003 Free Software Foundation, Inc.
   2
   3 # This program is free software; you can redistribute it and/or modify
   4 # it under the terms of the GNU General Public License as published by
   5 # the Free Software Foundation; either version 2 of the License, or
   6 # (at your option) any later version.
   7 #
   8 # This program is distributed in the hope that it will be useful,
   9 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  10 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  11 # GNU General Public License for more details.
  12 #
  13 # You should have received a copy of the GNU General Public License
  14 # along with this program; if not, write to the Free Software
  15 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  16
  17 # Please email any bugs, comments, and/or additions to this file to:
  18 # gcc-patches@gcc.gnu.org
  19
  20 # This file defines procs for determining features supported by the target.
  21
  22 ###############################
  23 # proc check_weak_available { }
  24 ###############################
  25
  26 # weak symbols are only supported in some configs/object formats
  27 # this proc returns 1 if they're supported, 0 if they're not, or -1 if unsure
  28
  29 proc check_weak_available { } {
  30     global target_triplet
  31     global target_cpu
  32
  33     # All mips targets should support it
  34
  35     if { [ string first "mips" $target_cpu ] >= 0 } {
  36         return 1
  37     }
  38
  39     # All solaris2 targets should support it
  40
  41     if { [regexp ".*-solaris2.*" $target_triplet] } {
  42         return 1
  43     }
  44
  45     # DEC OSF/1/Digital UNIX/Tru64 UNIX supports it
  46
  47     if { [regexp "alpha.*osf.*" $target_triplet] } {
  48         return 1
  49     }
  50
  51     # ELF and ECOFF support it. a.out does with gas/gld but may also with
  52     # other linkers, so we should try it
  53
  54     set objformat [gcc_target_object_format]
  55
  56     switch $objformat {
  57         elf      { return 1 }
  58         ecoff    { return 1 }
  59         a.out    { return 1 }
  60         unknown  { return -1 }
  61         default  { return 0 }
  62     }
  63 }
  64
  65 ###############################
  66 # proc check_visibility_available { }
  67 ###############################
  68
  69 # The visibility attribute is only support in some object formats
  70 # This proc returns 1 if it is supported, 0 if not, -1 if unsure.
  71
  72 proc check_visibility_available { } {
  73     global target_triplet
  74     global target_cpu
  75
  76     # ELF supports it if the system has recent GNU ld and gas.
  77     # As a start we return 1 for all ELF systems; we'll let people
  78     # add exceptions as necessary.
  79
  80     set objformat [gcc_target_object_format]
  81
  82     switch $objformat {
  83         elf      { return 1 }
  84         unknown  { return -1 }
  85         default  { return 0 }
  86     }
  87 }
  88
  89 ###############################
  90 # proc check_alias_available { }
  91 ###############################
  92
  93 # Determine if the target toolchain supports the alias attribute.
  94
  95 # Returns 2 if the target supports aliases.  Returns 1 if the target
  96 # only supports weak aliased.  Returns 0 if the target does not
  97 # support aliases at all.  Returns -1 if support for aliases could not
  98 # be determined.
  99
 100 proc check_alias_available { } {
 101     global alias_available_saved
 102     global tool
 103
 104     if [info exists alias_available_saved] {
 105         verbose "check_alias_available  returning saved $alias_available_saved" 2
 106     } else {
 107         verbose "check_alias_available  compiling testfile" 2
 108         set f [open "tmp.c" "w"]
 109         # Compile a small test program.  The definition of "g" is
 110         # necessary to keep the Solaris assembler from complaining
 111         # about the program.
 112         puts $f "#ifdef __cplusplus\nextern \"C\"\n#endif\n"
 113         puts $f "void g() {} void f() __attribute__((alias(\"g\")));"
 114         close $f
 115         set lines [${tool}_target_compile "tmp.c" "tmp.o" object ""]
 116         file delete "tmp.c"
 117
 118         if [string match "" $lines] then {
 119             # No error messages, everything is OK.
 120             set alias_available_saved 2
 121         } else {
 122             if [regexp "alias definitions not supported" $lines] {
 123                 verbose "check_alias_available  target does not support aliases" 2
 124
 125                 set objformat [gcc_target_object_format]
 126
 127                 if { $objformat == "elf" } {
 128                     verbose "check_alias_available  but target uses ELF format, so it ought to" 2
 129                     set alias_available_saved -1
 130                 } else {
 131                     set alias_available_saved 0
 132                 }
 133             } else {
 134                 if [regexp "only weak aliases are supported" $lines] {
 135                 verbose "check_alias_available  target supports only weak aliases" 2
 136                 set alias_available_saved 1
 137                 } else {
 138                     set alias_available_saved -1
 139                 }
 140             }
 141         }
 142
 143         verbose "check_alias_available  returning $alias_available_saved" 2
 144     }
 145
 146     return $alias_available_saved
 147 }
 148
 149 # Returns true if --gc-sections is supported on the target.
 150
 151 proc check_gc_sections_available { } {
 152     global gc_sections_available_saved
 153     global tool
 154
 155     if {![info exists gc_sections_available_saved]} {
 156         # Check if the ld used by gcc supports --gc-sections.
 157         set gcc_ld [lindex [${tool}_target_compile "-print-prog-name=ld" "" "none" ""] 0]
 158         set ld_output [remote_exec host "$gcc_ld" "--help"]
 159         if { [ string first "--gc-sections" $ld_output ] >= 0 } {
 160             set gc_sections_available_saved 1
 161         } else {
 162             set gc_sections_available_saved 0
 163         }
 164     }
 165     return $gc_sections_available_saved
 166 }
 167
 168 # Return true if profiling is supported on the target.
 169
 170 proc check_profiling_available { test_what } {
 171     global profiling_available_saved
 172
 173     verbose "Profiling argument is <$test_what>" 1
 174
 175     # These conditions depend on the argument so examine them before
 176     # looking at the cache variable.
 177
 178     # Support for -p on solaris2 relies on mcrt1.o which comes with the
 179     # vendor compiler.  We cannot reliably predict the directory where the
 180     # vendor compiler (and thus mcrt1.o) is installed so we can't
 181     # necessarily find mcrt1.o even if we have it.
 182     if { [istarget *-*-solaris2*] && [lindex $test_what 1] == "-p" } {
 183         return 0
 184     }
 185
 186     # Support for -p on irix relies on libprof1.a which doesn't appear to
 187     # exist on any irix6 system currently posting testsuite results.
 188     # Support for -pg on irix relies on gcrt1.o which doesn't exist yet.
 189     # See: http://gcc.gnu.org/ml/gcc/2002-10/msg00169.html
 190     if { [istarget mips*-*-irix*]
 191     && ([lindex $test_what 1] == "-p" || [lindex $test_what 1] == "-pg") } {
 192         return 0
 193     }
 194
 195     # Now examine the cache variable.
 196     if {![info exists profiling_available_saved]} {
 197         # Some targets don't have any implementation of __bb_init_func or are
 198         # missing other needed machinery.
 199         if { [istarget mmix-*-*]
 200              || [istarget arm*-*-elf]
 201              || [istarget strongarm*-*-elf]
 202              || [istarget xscale*-*-elf]
 203              || [istarget cris-*-*]
 204              || [istarget h8300-*-*]
 205              || [istarget *-*-windiss] } {
 206             set profiling_available_saved 0
 207         } else {
 208             set profiling_available_saved 1
 209         }
 210     }
 211
 212     return $profiling_available_saved
 213 }
 214
 215 # Return true if iconv is supported on the target. In particular IBM-1047.
 216
 217 proc check_iconv_available { test_what } {
 218     global tool
 219     global libiconv
 220
 221     set result ""
 222
 223     verbose "check_iconv_available compiling testfile" 1
 224     set f [open "tmp.c" "w"]
 225     # Compile a small test program.
 226     puts $f "#include <iconv.h>\n"
 227     puts $f "int main (void)\n {\n iconv_t cd; \n"
 228     puts $f "cd = iconv_open (\"[lindex $test_what 1]\", \"UTF-8\");\n"
 229     puts $f "if (cd == (iconv_t) -1)\n return 1;\n"
 230     puts $f "return 0;\n}"
 231     close $f
 232
 233     set lines [${tool}_target_compile "tmp.c" "tmp.x" executable "libs=$libiconv" ]
 234
 235     if [string match "" $lines] then {
 236         # No error messages, everything is OK.
 237
 238         set result [${tool}_load "./tmp.x" "" ""]
 239         set status [lindex $result 0];
 240
 241         verbose "status is <$status>"
 242
 243         if { $status == "pass" } then {
 244             return 1
 245         }
 246     }
 247
 248     return 0
 249 }
 250
 251 # Return true if named sections are supported on this target.
 252 # This proc does not cache results, because the answer may vary
 253 # when cycling over subtarget options (e.g. irix o32/n32/n64) in
 254 # the same test run.
 255 proc check_named_sections_available { } {
 256     global tool
 257
 258     set f [open "tmp.c" "w"]
 259     # Compile a small test program.
 260     puts $f "int __attribute__ ((section(\"whatever\"))) foo;"
 261     close $f
 262     set lines [${tool}_target_compile "tmp.c" "tmp.o" object ""]
 263     file delete "tmp.c"
 264
 265     # If we got no error messages, everything is OK.
 266     set answer [string match "" $lines]
 267     verbose "check_named_sections_available  returning $answer" 2
 268     return $answer
 269 }