gcc/testsuite/lib/plugin-support.exp

   1 #   Copyright (C) 2009 Free Software Foundation, Inc.
   2
   3 # This program is free software; you can redistribute it and/or modify
   4 # it under the terms of the GNU General Public License as published by
   5 # the Free Software Foundation; either version 3 of the License, or
   6 # (at your option) any later version.
   7 #
   8 # This program is distributed in the hope that it will be useful,
   9 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  10 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  11 # GNU General Public License for more details.
  12 #
  13 # You should have received a copy of the GNU General Public License
  14 # along with GCC; see the file COPYING3.  If not see
  15 # <http://www.gnu.org/licenses/>.
  16 #
  17
  18 # This file contains the support procedures for testing the plugin mechanism.
  19
  20 load_lib dg.exp
  21 load_lib gcc.exp
  22
  23 #
  24 # plugin-get-options -- process test directives
  25 #
  26 # SRC is the full pathname of the plugin source file.
  27 #
  28 proc plugin-get-options { src } {
  29     # dg-options sets a variable called dg-extra-tool-flags.
  30     set dg-extra-tool-flags ""
  31
  32     # dg-require-* sets dg-do-what.
  33     upvar dg-do-what dg-do-what
  34
  35     set tmp [dg-get-options $src]
  36     foreach op $tmp {
  37         set cmd [lindex $op 0]
  38         if { ![string compare "dg-options" $cmd] } {
  39             set status [catch "$op" errmsg]
  40             if { $status != 0 } {
  41                 perror "src: $errmsg for \"$op\"\n"
  42                 unresolved "$src: $errmsg for \"$op\""
  43                 return
  44             }
  45         } else {
  46             # Ignore unrecognized dg- commands, but warn about them.
  47             warning "plugin.exp does not support $cmd"
  48         }
  49    }
  50
  51     # Return flags to use for compiling the plugin source file
  52     return ${dg-extra-tool-flags}
  53 }
  54
  55 #
  56 # plugin-test-execute -- build the plugin first and then compile the
  57 # test files with the plugin.
  58 #
  59 # PLUGIN_SRC is the full pathname of the plugin source file.
  60 # PLUGIN_TESTS is a list of input test source files.
  61 #
  62 proc plugin-test-execute { plugin_src plugin_tests } {
  63     global srcdir objdir
  64     global verbose
  65     global GMPINC
  66     global PLUGINCC
  67     global PLUGINCFLAGS
  68
  69     set basename [file tail $plugin_src]
  70     set base [file rootname $basename]
  71     set plugin_lib $base.so
  72
  73     verbose "Test the plugin $basename" 1
  74
  75     # Build the plugin itself
  76     set extra_flags [plugin-get-options $plugin_src]
  77
  78     # Note that the plugin test support currently only works when the GCC
  79     # build tree is available. (We make sure that is the case in plugin.exp.)
  80     # Once we have figured out how/where to package/install GCC header files
  81     # for general plugin support, we should modify the following include paths
  82     # accordingly.
  83     set gcc_srcdir "$srcdir/../.."
  84     set gcc_objdir "$objdir/../../.."
  85     set includes "-I. -I${srcdir} -I${gcc_srcdir}/gcc -I${gcc_objdir}/gcc \
  86                   -I${gcc_srcdir}/include -I${gcc_srcdir}/libcpp/include \
  87                   $GMPINC -I${gcc_objdir}/intl"
  88
  89     if { [ ishost *-*-darwin* ] } {
  90         # -mdynamic-no-pic is incompatible with -fPIC.
  91         set plug_cflags ""
  92         foreach op $PLUGINCFLAGS {
  93             if { [string compare "-mdynamic-no-pic" $op] } {
  94                 set plug_cflags [concat $plug_cflags " $op"]
  95             }
  96         }
  97         set optstr "$includes"
  98         foreach op $extra_flags {
  99             if { [string compare "-mdynamic-no-pic" $op] } {
 100                 set optstr [concat $optstr " $op"]
 101             }
 102         }
 103         set optstr [concat $optstr "-DIN_GCC -fPIC -shared -undefined dynamic_lookup"]
 104     } else {
 105         set plug_cflags $PLUGINCFLAGS
 106         set optstr "$includes $extra_flags -DIN_GCC -fPIC -shared"
 107     }
 108
 109     # Temporarily switch to the environment for the plugin compiler.
 110     restore_ld_library_path_env_vars
 111     set status [remote_exec build "$PLUGINCC $plug_cflags $plugin_src $optstr -o $plugin_lib"]
 112     set status [lindex $status 0]
 113     set_ld_library_path_env_vars
 114
 115     if { $status != 0 } then {
 116         unresolved "$basename compilation, $optstr"
 117         return
 118     }
 119
 120     # Compile the input source files with the plugin
 121     global default_flags
 122     set plugin_enabling_flags "-fplugin=./$plugin_lib"
 123     dg-runtest $plugin_tests $plugin_enabling_flags $default_flags
 124
 125     # Clean up
 126     remote_file build delete $plugin_lib
 127 }