OSDN Git Service

Merge lto branch into trunk.
[pf3gnuchains/gcc-fork.git] / gcc / testsuite / lib / lto.exp
1 # Copyright (C) 2009 Free Software Foundation, Inc.
2
3 # This program is free software; you can redistribute it and/or modify
4 # it under the terms of the GNU General Public License as published by
5 # the Free Software Foundation; either version 3 of the License, or
6 # (at your option) any later version.
7 #
8 # This program is distributed in the hope that it will be useful,
9 # but WITHOUT ANY WARRANTY; without even the implied warranty of
10 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
11 # GNU General Public License for more details.
12 #
13 # You should have received a copy of the GNU General Public License
14 # along with GCC; see the file COPYING3.  If not see
15 # <http://www.gnu.org/licenses/>.
16
17 # Contributed by Diego Novillo <dnovillo@google.com>
18
19
20 # lto_init -- called at the start of eac subdir of tests
21
22 proc lto_init { args } {
23     global LTO_OPTIONS
24
25     # Each test is run with the compiler options from this list.
26     # The default option lists can be overridden by LTO_OPTIONS="[list
27     # {opts_1} {opts_2}... {opts_n}]" where opts_i are lists of options.
28     # You can put this in the environment before site.exp is written or
29     # add it to site.exp directly.
30     if ![info exists LTO_OPTIONS] {
31         set LTO_OPTIONS [list   \
32             {-O0 -fwhopr}       \
33             {-O2 -fwhopr}       \
34             {-O0 -flto}         \
35             {-O2 -flto}         \
36         ]
37     }
38 }
39
40
41 # Subsets of tests can be selectively disabled by members of this list:
42 #  - ATTRIBUTE: disable all tests using the __attribute__ extension,
43 #  - COMPLEX: disable all tests using the complex types feature,
44 #  - COMPLEX_INT: disable all tests using the complex integral types extension,
45 #  - VA: disable all tests using the variable number of arguments feature,
46 #  - VLA_IN_STRUCT: disable all tests using the variable-length arrays as
47 #    structure members extension,
48 #  - ZERO_ARRAY: disable all tests using the zero-sized arrays extension.
49 # The default skip lists can be overriden by
50 # LTO_SKIPS="[list {skip_1}...{skip_n}]"
51 # where skip_i are skip identifiers.  You can put this in the environment
52 # before site.exp is written or add it to site.exp directly.
53 if ![info exists LTO_SKIPS] {
54     set LTO_SKIPS [list {}]
55 }
56
57 global lto_skip_list
58 set lto_skip_list $LTO_SKIPS
59
60 load_lib dg.exp
61 load_lib gcc-dg.exp
62
63 # lto-obj -- compile to an object file
64 #
65 # SOURCE is the source file
66 # DEST is the object file
67 # OPTALL is the list of compiler options to use with all tests
68 # OPTFILE is the list of compiler options to use with this file
69 # OPTSTR is the options to print with test messages
70 # XFAILDATA is the xfail data to be passed to the compiler
71 proc lto-obj { source dest optall optfile optstr xfaildata } {
72     global testcase
73     global tool
74     global compiler_conditional_xfail_data
75     global lto_skip_list
76
77     # Add the skip specifiers.
78     foreach skip $lto_skip_list {
79         if { ![string match $skip ""] } {
80             lappend optall "-DSKIP_$skip"
81         }
82     }
83
84     # Set up the options for compiling this file.
85     set options ""
86     lappend options "additional_flags=$optall $optfile"
87
88     set compiler_conditional_xfail_data $xfaildata
89     set comp_output [${tool}_target_compile "$source" "$dest" object $options]
90     ${tool}_check_compile "$testcase $dest assemble" $optstr $dest $comp_output
91 }
92
93 # lto-link-and-maybe-run -- link the object files and run the executable
94 # if compile_type is set to "run"
95 #
96 # TESTNAME is the mixture of object files to link
97 # OBJLIST is the list of object files to link
98 # DEST is the name of the executable
99 # OPTALL is a list of compiler and linker options to use for all tests
100 # OPTFILE is a list of compiler and linker options to use for this test
101 # OPTSTR is the list of options to list in messages
102 proc lto-link-and-maybe-run { testname objlist dest optall optfile optstr } {
103     global testcase
104     global tool
105     global compile_type
106
107     # Check that all of the objects were built successfully.
108     foreach obj [split $objlist] {
109         if ![file_on_host exists $obj] then {
110             unresolved "$testcase $testname link $optstr"
111             unresolved "$testcase $testname execute $optstr"
112             return
113         }
114     }
115
116     # Set up the options for linking this test.
117     set options ""
118     lappend options "additional_flags=$optall $optfile"
119
120     # Link the objects into an executable.
121     set comp_output [${tool}_target_compile "$objlist" $dest executable \
122                      "$options"]
123     if ![${tool}_check_compile "$testcase $testname link" "" \
124          $dest $comp_output] then {
125         unresolved "$testcase $testname execute $optstr"
126         return
127     }
128
129     # Return if we only needed to link.
130     if { ![string compare "link" $compile_type] } {
131         return
132     }
133
134     # Run the self-checking executable.
135     if ![string match "*/*" $dest] then {
136         set dest "./$dest"
137     }
138     set result [${tool}_load $dest "" ""]
139     set status [lindex $result 0]
140     if { $status == "pass" } then {
141         file_on_host delete $dest
142     }
143     $status "$testcase $testname execute $optstr"
144 }
145
146 # lto-get-options-main -- get target requirements for a test and
147 # options for the primary source file and the test as a whole
148 #
149 # SRC is the full pathname of the primary source file.
150 proc lto-get-options-main { src } {
151     global compile_type
152     global dg-extra-ld-options
153     global dg-suppress-ld-options
154
155     set dg-extra-ld-options ""
156     set dg-suppress-ld-options ""
157
158     # dg-options sets a variable called dg-extra-tool-flags.
159     set dg-extra-tool-flags ""
160
161     # dg-options sets a variable called tool_flags.
162     set tool_flags ""
163
164     # dg-require-* sets dg-do-what.
165     upvar dg-do-what dg-do-what 
166     upvar dg-final-code dg-final-code
167     set dg-final-code ""
168
169     set tmp [dg-get-options $src]
170     verbose "getting options for $src: $tmp"
171     foreach op $tmp {
172         set cmd [lindex $op 0]
173         verbose "cmd is $cmd"
174         if { [string match "dg-skip-if" $cmd] \
175              || [string match "dg-require-*" $cmd] } {
176             set status [catch "$op" errmsg]
177             if { $status != 0 } {
178                 perror "src: $errmsg for \"$op\"\n"
179                 unresolved "$src: $errmsg for \"$op\""
180                 return
181             }
182         } elseif { [string match "dg-lto-options" $cmd] } {
183             set op [lreplace $op 0 0 "dg-options"]
184             set status [catch "$op" errmsg]
185             if { $status != 0 } {
186                 perror "src: $errmsg for \"$op\"\n"
187                 unresolved "$src: $errmsg for \"$op\""
188                 return
189             }
190         } elseif { ![string compare "dg-xfail-if" $cmd] \
191                    || ![string compare "dg-options" $cmd] } {
192             warning "lto.exp does not support $cmd in primary source file"
193         } elseif { ![string compare "dg-lto-do" $cmd] } {
194             set dgdo [lindex $op 2]
195             verbose "dg-lto-do command for \"$op\" is $dgdo"
196             if { ![string compare "assemble" $dgdo] } {
197                 set compile_type "assemble"
198             } elseif { ![string compare "run" $dgdo] } {
199                 set compile_type "run"
200             } elseif { ![string compare "link" $dgdo] } {
201                 set compile_type "link"
202             } else {
203                 warning "lto.exp does not support dg-lto-do $dgdo"
204             }
205         } elseif { ![string compare "dg-extra-ld-options" $cmd] } {
206             set dg-extra-ld-options [lindex $op 2]
207             verbose "dg-extra-ld-options for main is ${dg-extra-ld-options}"
208         } elseif { ![string compare "dg-suppress-ld-options" $cmd] } {
209             set dg-suppress-ld-options [lindex $op 2]
210             verbose \
211               "dg-suppress-ld-options for main is ${dg-suppress-ld-options}"
212         } elseif { ![string compare "dg-final" $cmd] } {
213             if { [llength $op] > 3 } {
214                 error "[lindex $op 0]: too many arguments"
215             } else {
216                 append dg-final-code "[lindex $op 2]\n"
217             }
218         } else {
219             # Ignore unrecognized dg- commands, but warn about them.
220             warning "lto.exp does not support $cmd"
221         }
222     }
223
224     # Return flags to use for compiling the primary source file and for
225     # linking.
226     verbose "dg-extra-tool-flags for main is ${dg-extra-tool-flags}"
227     return ${dg-extra-tool-flags}
228 }
229
230
231 # lto-get-options -- get special tool flags to use for a secondary
232 # source file
233 #
234 # SRC is the full pathname of the source file.
235 # The result is a list of options to use.
236 #
237 # This code is copied from proc dg-test in dg.exp from DejaGNU.
238 proc lto-get-options { src } {
239     # dg-options sets a variable called dg-extra-tool-flags.
240     set dg-extra-tool-flags ""
241
242     # dg-xfail-if sets compiler_conditional_xfail_data.
243     global compiler_conditional_xfail_data
244     set compiler_conditional_xfail_data ""
245
246     # dg-xfail-if needs access to dg-do-what.
247     upvar dg-do-what dg-do-what 
248
249     set tmp [dg-get-options $src]
250     foreach op $tmp {
251         set cmd [lindex $op 0]
252         if { ![string compare "dg-options" $cmd] \
253              || ![string compare "dg-xfail-if" $cmd] } {
254             set status [catch "$op" errmsg]
255             if { $status != 0 } {
256                 perror "src: $errmsg for \"$op\"\n"
257                 unresolved "$src: $errmsg for \"$op\""
258                 return
259             }
260         } elseif { [string match "dg-require-*" $cmd] } {
261             warning "lto.exp does not support $cmd in secondary source files"
262         } else {
263             # Ignore unrecognized dg- commands, but warn about them.
264             warning "lto.exp does not support $cmd in secondary source files"
265         }
266     }
267
268     return ${dg-extra-tool-flags}
269 }
270
271 # lto-execute -- compile multi-file tests
272 #
273 # SRC1 is the full pathname of the main file of the testcase.
274 # SID identifies a test suite in the names of temporary files.
275 proc lto-execute { src1 sid } {
276     global srcdir tmpdir
277     global option_list
278     global tool
279     global verbose
280     global testcase
281     global gluefile
282     global compiler_conditional_xfail_data
283     global dg-do-what-default
284     global compile_type
285     global dg-extra-ld-options
286     global dg-suppress-ld-options
287     global LTO_OPTIONS
288     global dg-final-code
289
290     # Get extra flags for this test from the primary source file, and
291     # process other dg-* options that this suite supports.  Warn about
292     # unsupported flags.
293     verbose "lto-execute: $src1" 1
294     set compile_type "run"
295     set dg-do-what [list ${dg-do-what-default} "" P]
296     set extra_flags(0) [lto-get-options-main $src1]
297     set compile_xfail(0) "" 
298
299     # If the main file defines dg-options, those flags are used to
300     # overwrite the default option_list taken from LTO_OPTIONS.
301     if { [string length $extra_flags(0)] > 0 } {
302         set option_list $extra_flags(0)
303         set extra_flags(0) ""
304     } else {
305         set option_list $LTO_OPTIONS
306     }
307
308     # Check whether this test is supported for this target.
309     if { [lindex ${dg-do-what} 1 ] == "N" } {
310         unsupported "$src1"
311         verbose "$src1 not supported on this target, skipping it" 3
312         return
313     }
314
315     # Set up the names of the other source files.
316     set dir [file dirname $src1]
317     set base [file rootname $src1]
318     set base [string range $base [string length $dir] end]
319     regsub "_0" $base "" base
320     regsub "/" $base "" base
321     set src_list $src1
322     set i 1
323     set done 0
324     while { !$done } {
325         set names [glob -nocomplain -types f -- "${dir}/${base}_${i}.*"]
326         if { [llength ${names}] > 1 } {
327             warning "lto-execute: more than one file matched ${dir}/${base}_${i}.*"
328         }
329         if { [llength ${names}] == 1 } {
330             lappend src_list [lindex ${names} 0]
331             incr i
332         } else {
333             set num_srcs ${i}
334             set done 1
335         }
336     }
337
338     # Use the dg-options mechanism to specify extra flags for each
339     # of the secondary files.
340     # The extra flags in each file are used to compile that file, and the
341     # extra flags in *_0.* are also used for linking.
342     verbose "\tsrc_list is: $src_list"
343     for {set i 1} {$i < $num_srcs} {incr i} {
344         set extra_flags($i) [lto-get-options [lindex $src_list $i]]
345         set compile_xfail($i) $compiler_conditional_xfail_data
346     }
347
348     # Define the names of the object files.
349     set obj_list ""
350     for {set i 0} {$i < $num_srcs} {incr i} {
351         lappend obj_list "${sid}_${base}_${i}.o"
352     }
353
354     # Get the base name of this test, for use in messages.
355     set testcase [lindex ${src_list} 0]
356
357     # Remove the $srcdir and $tmpdir prefixes from $src1.  (It would
358     # be possible to use "regsub" here, if we were careful to escape
359     # all regular expression characters in $srcdir and $tmpdir, but
360     # that would be more complicated that this approach.) 
361     if {[string first "$srcdir/" "${testcase}"] == 0} {
362         set testcase [string range "${testcase}" [string length "$srcdir/"] end]
363     }
364     if {[string first "$tmpdir/" "$testcase"] == 0} {
365         set testcase [string range "$testcase" [string length "$tmpdir/"] end]
366         set testcase "tmpdir-$testcase"
367     }
368     regsub "_0.*" $testcase "" testcase
369
370     # Set up the base name of executable files so they'll be unique.
371     regsub -all "\[./\]" $testcase "-" execbase
372
373     # If we couldn't rip $srcdir out of `src1' then just do the best we can.
374     # The point is to reduce the unnecessary noise in the logs.  Don't strip
375     # out too much because different testcases with the same name can confuse
376     # `test-tool'.
377     if [string match "/*" $testcase] then {
378         set testcase "[file tail [file dirname $src1]]/[file tail $src1]"
379     }
380
381     # Loop through all of the option lists used for this test.
382     set count 0
383     foreach option $option_list {
384         verbose "Testing $testcase, $option"
385
386         # There's a unique name for each executable we generate.
387         set execname "${execbase}-${count}1"
388         incr count
389
390         file_on_host delete $execname
391
392         # Compile pieces with the compiler under test.
393         set i 0
394         foreach src $src_list obj $obj_list {
395             lto-obj $src $obj $option $extra_flags($i) $option \
396                     $compile_xfail($i)
397             incr i
398         }
399
400         # Link (using the compiler under test), run, and clean up tests.
401         if { ![string compare "run" $compile_type] \
402              || ![string compare "link" $compile_type] } {
403
404             # Filter out any link options we were asked to suppress.
405             set reduced {}
406             foreach x [split $option] {
407               if {[lsearch ${dg-suppress-ld-options} $x] == -1} {
408                 lappend reduced $x
409               }
410             }
411             set filtered [join $reduced " "]
412
413             lto-link-and-maybe-run \
414                     "[lindex $obj_list 0]-[lindex $obj_list end]" \
415                     $obj_list $execname $filtered ${dg-extra-ld-options} \
416                     $filtered
417         }
418
419
420         # Are there any further tests to perform?
421         # Note that if the program has special run-time requirements, running
422         # of the program can be delayed until here.  Ditto for other situations.
423         # It would be a bit cumbersome though.
424
425         if ![string match ${dg-final-code} ""] {
426             regsub -all "\\\\(\[{}\])" ${dg-final-code} "\\1" dg-final-code
427             # Note that the use of `args' here makes this a varargs proc.
428             proc dg-final-proc { args } ${dg-final-code}
429             verbose "Running dg-final tests." 3
430             verbose "dg-final-proc:\n[info body dg-final-proc]" 4
431             if [catch "dg-final-proc $src1" errmsg] {
432                 perror "$name: error executing dg-final: $errmsg"
433                 # ??? The call to unresolved here is necessary to clear
434                 # `errcnt'.  What we really need is a proc like perror that
435                 # doesn't set errcnt.  It should also set exit_status to 1.
436                 unresolved "$name: error executing dg-final: $errmsg"
437             }
438         }
439
440         # Clean up object files.
441         set files [glob -nocomplain ${sid}_*.o]
442         if { $files != "" } {
443             foreach objfile $files {
444                 if { ![info exists gluefile] || $objfile != $gluefile } {
445                     eval "file_on_host delete $objfile"
446                 }
447             }
448         }
449
450         if { ![string compare "run" $compile_type] \
451              || ![string compare "link" $compile_type] } {
452             file_on_host delete $execname
453         }
454     }
455 }
456
457 # Utility for scanning a symbol in the final executable, invoked via dg-final.
458 # Call pass if pattern is present, otherwise fail.
459 #
460 # Argument 0 is the regexp to match.
461 # Argument 1 handles expected failures and the like
462 proc scan-symbol { args } {
463     global nm
464     global base_dir
465     upvar 2 execname execname
466
467     if { [llength $args] >= 2 } {
468         switch [dg-process-target [lindex $args 1]] {
469             "S" { }
470             "N" { return }
471             "F" { setup_xfail "*-*-*" }
472             "P" { }
473         }
474     }
475
476     # Find nm like we find g++ in g++.exp.
477     if ![info exists nm]  {
478         set nm [findfile $base_dir/../../../binutils/nm \
479                 $base_dir/../../../binutils/nm \
480                 [findfile $base_dir/../../nm $base_dir/../../nm \
481                       [findfile $base_dir/nm $base_dir/nm \
482                        [transform nm]]]]
483         verbose -log "nm is $nm"
484     }
485
486     set output_file $execname
487     if { $output_file == "" } {
488         fail "scan-symbol $args: dump file does not exist"
489         return
490     }
491
492     set fd [open "| $nm $output_file" r]
493     set text [read $fd]
494     close $fd
495
496     if [regexp -- [lindex $args 0] $text] {
497         pass "scan-symbol $args"
498     } else {
499         fail "scan-symbol $args"
500     }
501 }