OSDN Git Service

PR testsuite/41659
[pf3gnuchains/gcc-fork.git] / gcc / testsuite / lib / lto.exp
1 # Copyright (C) 2009 Free Software Foundation, Inc.
2
3 # This program is free software; you can redistribute it and/or modify
4 # it under the terms of the GNU General Public License as published by
5 # the Free Software Foundation; either version 3 of the License, or
6 # (at your option) any later version.
7 #
8 # This program is distributed in the hope that it will be useful,
9 # but WITHOUT ANY WARRANTY; without even the implied warranty of
10 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
11 # GNU General Public License for more details.
12 #
13 # You should have received a copy of the GNU General Public License
14 # along with GCC; see the file COPYING3.  If not see
15 # <http://www.gnu.org/licenses/>.
16
17 # Contributed by Diego Novillo <dnovillo@google.com>
18
19
20 # lto_init -- called at the start of eac subdir of tests
21
22 proc lto_init { args } {
23     global LTO_OPTIONS
24
25     # Each test is run with the compiler options from this list.
26     # The default option lists can be overridden by LTO_OPTIONS="[list
27     # {opts_1} {opts_2}... {opts_n}]" where opts_i are lists of options.
28     # You can put this in the environment before site.exp is written or
29     # add it to site.exp directly.
30     if ![info exists LTO_OPTIONS] {
31         set LTO_OPTIONS [list   \
32             {-O0 -fwhopr}       \
33             {-O2 -fwhopr}       \
34             {-O0 -flto}         \
35             {-O2 -flto}         \
36         ]
37     }
38 }
39
40
41 # Subsets of tests can be selectively disabled by members of this list:
42 #  - ATTRIBUTE: disable all tests using the __attribute__ extension,
43 #  - COMPLEX: disable all tests using the complex types feature,
44 #  - COMPLEX_INT: disable all tests using the complex integral types extension,
45 #  - VA: disable all tests using the variable number of arguments feature,
46 #  - VLA_IN_STRUCT: disable all tests using the variable-length arrays as
47 #    structure members extension,
48 #  - ZERO_ARRAY: disable all tests using the zero-sized arrays extension.
49 # The default skip lists can be overriden by
50 # LTO_SKIPS="[list {skip_1}...{skip_n}]"
51 # where skip_i are skip identifiers.  You can put this in the environment
52 # before site.exp is written or add it to site.exp directly.
53 if ![info exists LTO_SKIPS] {
54     set LTO_SKIPS [list {}]
55 }
56
57 global lto_skip_list
58 set lto_skip_list $LTO_SKIPS
59
60 load_lib dg.exp
61 load_lib gcc-dg.exp
62
63 # lto-obj -- compile to an object file
64 #
65 # SOURCE is the source file
66 # DEST is the object file
67 # OPTALL is the list of compiler options to use with all tests
68 # OPTFILE is the list of compiler options to use with this file
69 # OPTSTR is the options to print with test messages
70 # XFAILDATA is the xfail data to be passed to the compiler
71 proc lto-obj { source dest optall optfile optstr xfaildata } {
72     global testcase
73     global tool
74     global compiler_conditional_xfail_data
75     global lto_skip_list
76
77     # Add the skip specifiers.
78     foreach skip $lto_skip_list {
79         if { ![string match $skip ""] } {
80             lappend optall "-DSKIP_$skip"
81         }
82     }
83
84     # Set up the options for compiling this file.
85     set options ""
86     lappend options "additional_flags=$optall $optfile"
87
88     set compiler_conditional_xfail_data $xfaildata
89     set comp_output [${tool}_target_compile "$source" "$dest" object $options]
90     ${tool}_check_compile "$testcase $dest assemble" $optstr $dest $comp_output
91 }
92
93 # lto-link-and-maybe-run -- link the object files and run the executable
94 # if compile_type is set to "run"
95 #
96 # TESTNAME is the mixture of object files to link
97 # OBJLIST is the list of object files to link
98 # DEST is the name of the executable
99 # OPTALL is a list of compiler and linker options to use for all tests
100 # OPTFILE is a list of compiler and linker options to use for this test
101 # OPTSTR is the list of options to list in messages
102 proc lto-link-and-maybe-run { testname objlist dest optall optfile optstr } {
103     global testcase
104     global tool
105     global compile_type
106
107     # Check that all of the objects were built successfully.
108     foreach obj [split $objlist] {
109         if ![file_on_host exists $obj] then {
110             unresolved "$testcase $testname link $optstr"
111             unresolved "$testcase $testname execute $optstr"
112             return
113         }
114     }
115
116     # Set up the options for linking this test.
117     set options ""
118     lappend options "additional_flags=$optall $optfile"
119
120     # Link the objects into an executable.
121     set comp_output [${tool}_target_compile "$objlist" $dest executable \
122                      "$options"]
123     if ![${tool}_check_compile "$testcase $testname link" "" \
124          $dest $comp_output] then {
125         unresolved "$testcase $testname execute $optstr"
126         return
127     }
128
129     # Return if we only needed to link.
130     if { ![string compare "link" $compile_type] } {
131         return
132     }
133
134     # Run the self-checking executable.
135     if ![string match "*/*" $dest] then {
136         set dest "./$dest"
137     }
138     set result [${tool}_load $dest "" ""]
139     set status [lindex $result 0]
140     if { $status == "pass" } then {
141         file_on_host delete $dest
142     }
143     $status "$testcase $testname execute $optstr"
144 }
145
146 # lto-get-options-main -- get target requirements for a test and
147 # options for the primary source file and the test as a whole
148 #
149 # SRC is the full pathname of the primary source file.
150 proc lto-get-options-main { src } {
151     global compile_type
152     global dg-extra-ld-options
153     global dg-suppress-ld-options
154
155     set dg-extra-ld-options ""
156     set dg-suppress-ld-options ""
157
158     # dg-options sets a variable called dg-extra-tool-flags.
159     set dg-extra-tool-flags ""
160
161     # dg-options sets a variable called tool_flags.
162     set tool_flags ""
163
164     # dg-require-* sets dg-do-what.
165     upvar dg-do-what dg-do-what 
166     upvar dg-final-code dg-final-code
167     set dg-final-code ""
168
169     set tmp [dg-get-options $src]
170     verbose "getting options for $src: $tmp"
171     foreach op $tmp {
172         set cmd [lindex $op 0]
173         verbose "cmd is $cmd"
174         if { [string match "dg-skip-if" $cmd] \
175              || [string match "dg-require-*" $cmd] } {
176             set status [catch "$op" errmsg]
177             if { $status != 0 } {
178                 perror "src: $errmsg for \"$op\"\n"
179                 unresolved "$src: $errmsg for \"$op\""
180                 return
181             }
182         } elseif { [string match "dg-lto-options" $cmd] } {
183             set op [lreplace $op 0 0 "dg-options"]
184             set status [catch "$op" errmsg]
185             if { $status != 0 } {
186                 perror "src: $errmsg for \"$op\"\n"
187                 unresolved "$src: $errmsg for \"$op\""
188                 return
189             }
190         } elseif { ![string compare "dg-xfail-if" $cmd] \
191                    || ![string compare "dg-options" $cmd] } {
192             warning "lto.exp does not support $cmd in primary source file"
193         } elseif { ![string compare "dg-lto-do" $cmd] } {
194             if { [llength $op] > 3 } {
195                 set kw [lindex [lindex $op 3] 0]
196                 if [string match "target" $kw] {
197                     perror "$src: dg-lto-do does not support \"target\""
198                 } elseif [string match "xfail" $kw] {
199                     perror "$src: dg-lto-do does not support \"xfail\""
200                 } else {
201                     perror "$src: dg-lto-do takes a single argument"
202                 }
203             }
204             set dgdo [lindex $op 2]
205             verbose "dg-lto-do command for \"$op\" is $dgdo"
206             if { ![string compare "assemble" $dgdo] } {
207                 set compile_type "assemble"
208             } elseif { ![string compare "run" $dgdo] } {
209                 set compile_type "run"
210             } elseif { ![string compare "link" $dgdo] } {
211                 set compile_type "link"
212             } else {
213                 warning "lto.exp does not support dg-lto-do $dgdo"
214             }
215         } elseif { ![string compare "dg-extra-ld-options" $cmd] } {
216             set dg-extra-ld-options [lindex $op 2]
217             verbose "dg-extra-ld-options for main is ${dg-extra-ld-options}"
218         } elseif { ![string compare "dg-suppress-ld-options" $cmd] } {
219             set dg-suppress-ld-options [lindex $op 2]
220             verbose \
221               "dg-suppress-ld-options for main is ${dg-suppress-ld-options}"
222         } elseif { ![string compare "dg-final" $cmd] } {
223             if { [llength $op] > 3 } {
224                 error "[lindex $op 0]: too many arguments"
225             } else {
226                 append dg-final-code "[lindex $op 2]\n"
227             }
228         } else {
229             # Ignore unrecognized dg- commands, but warn about them.
230             warning "lto.exp does not support $cmd"
231         }
232     }
233
234     # Return flags to use for compiling the primary source file and for
235     # linking.
236     verbose "dg-extra-tool-flags for main is ${dg-extra-tool-flags}"
237     return ${dg-extra-tool-flags}
238 }
239
240
241 # lto-get-options -- get special tool flags to use for a secondary
242 # source file
243 #
244 # SRC is the full pathname of the source file.
245 # The result is a list of options to use.
246 #
247 # This code is copied from proc dg-test in dg.exp from DejaGNU.
248 proc lto-get-options { src } {
249     # dg-options sets a variable called dg-extra-tool-flags.
250     set dg-extra-tool-flags ""
251
252     # dg-xfail-if sets compiler_conditional_xfail_data.
253     global compiler_conditional_xfail_data
254     set compiler_conditional_xfail_data ""
255
256     # dg-xfail-if needs access to dg-do-what.
257     upvar dg-do-what dg-do-what 
258
259     set tmp [dg-get-options $src]
260     foreach op $tmp {
261         set cmd [lindex $op 0]
262         if { ![string compare "dg-options" $cmd] \
263              || ![string compare "dg-xfail-if" $cmd] } {
264             set status [catch "$op" errmsg]
265             if { $status != 0 } {
266                 perror "src: $errmsg for \"$op\"\n"
267                 unresolved "$src: $errmsg for \"$op\""
268                 return
269             }
270         } elseif { [string match "dg-require-*" $cmd] } {
271             warning "lto.exp does not support $cmd in secondary source files"
272         } else {
273             # Ignore unrecognized dg- commands, but warn about them.
274             warning "lto.exp does not support $cmd in secondary source files"
275         }
276     }
277
278     return ${dg-extra-tool-flags}
279 }
280
281 # lto-execute -- compile multi-file tests
282 #
283 # SRC1 is the full pathname of the main file of the testcase.
284 # SID identifies a test suite in the names of temporary files.
285 proc lto-execute { src1 sid } {
286     global srcdir tmpdir
287     global option_list
288     global tool
289     global verbose
290     global testcase
291     global gluefile
292     global compiler_conditional_xfail_data
293     global dg-do-what-default
294     global compile_type
295     global dg-extra-ld-options
296     global dg-suppress-ld-options
297     global LTO_OPTIONS
298     global dg-final-code
299
300     # Get extra flags for this test from the primary source file, and
301     # process other dg-* options that this suite supports.  Warn about
302     # unsupported flags.
303     verbose "lto-execute: $src1" 1
304     set compile_type "run"
305     set dg-do-what [list ${dg-do-what-default} "" P]
306     set extra_flags(0) [lto-get-options-main $src1]
307     set compile_xfail(0) "" 
308
309     # If the main file defines dg-options, those flags are used to
310     # overwrite the default option_list taken from LTO_OPTIONS.
311     if { [string length $extra_flags(0)] > 0 } {
312         set option_list $extra_flags(0)
313         set extra_flags(0) ""
314     } else {
315         set option_list $LTO_OPTIONS
316     }
317
318     # Check whether this test is supported for this target.
319     if { [lindex ${dg-do-what} 1 ] == "N" } {
320         unsupported "$src1"
321         verbose "$src1 not supported on this target, skipping it" 3
322         return
323     }
324
325     # Set up the names of the other source files.
326     set dir [file dirname $src1]
327     set base [file rootname $src1]
328     set base [string range $base [string length $dir] end]
329     regsub "_0" $base "" base
330     regsub "/" $base "" base
331     set src_list $src1
332     set i 1
333     set done 0
334     while { !$done } {
335         set names [glob -nocomplain -types f -- "${dir}/${base}_${i}.*"]
336         if { [llength ${names}] > 1 } {
337             warning "lto-execute: more than one file matched ${dir}/${base}_${i}.*"
338         }
339         if { [llength ${names}] == 1 } {
340             lappend src_list [lindex ${names} 0]
341             incr i
342         } else {
343             set num_srcs ${i}
344             set done 1
345         }
346     }
347
348     # Use the dg-options mechanism to specify extra flags for each
349     # of the secondary files.
350     # The extra flags in each file are used to compile that file, and the
351     # extra flags in *_0.* are also used for linking.
352     verbose "\tsrc_list is: $src_list"
353     for {set i 1} {$i < $num_srcs} {incr i} {
354         set extra_flags($i) [lto-get-options [lindex $src_list $i]]
355         set compile_xfail($i) $compiler_conditional_xfail_data
356     }
357
358     # Define the names of the object files.
359     set obj_list ""
360     for {set i 0} {$i < $num_srcs} {incr i} {
361         lappend obj_list "${sid}_${base}_${i}.o"
362     }
363
364     # Get the base name of this test, for use in messages.
365     set testcase [lindex ${src_list} 0]
366
367     # Remove the $srcdir and $tmpdir prefixes from $src1.  (It would
368     # be possible to use "regsub" here, if we were careful to escape
369     # all regular expression characters in $srcdir and $tmpdir, but
370     # that would be more complicated that this approach.) 
371     if {[string first "$srcdir/" "${testcase}"] == 0} {
372         set testcase [string range "${testcase}" [string length "$srcdir/"] end]
373     }
374     if {[string first "$tmpdir/" "$testcase"] == 0} {
375         set testcase [string range "$testcase" [string length "$tmpdir/"] end]
376         set testcase "tmpdir-$testcase"
377     }
378     regsub "_0.*" $testcase "" testcase
379
380     # Set up the base name of executable files so they'll be unique.
381     regsub -all "\[./\]" $testcase "-" execbase
382
383     # If we couldn't rip $srcdir out of `src1' then just do the best we can.
384     # The point is to reduce the unnecessary noise in the logs.  Don't strip
385     # out too much because different testcases with the same name can confuse
386     # `test-tool'.
387     if [string match "/*" $testcase] then {
388         set testcase "[file tail [file dirname $src1]]/[file tail $src1]"
389     }
390
391     # Loop through all of the option lists used for this test.
392     set count 0
393     foreach option $option_list {
394         verbose "Testing $testcase, $option"
395
396         # There's a unique name for each executable we generate.
397         set execname "${execbase}-${count}1"
398         incr count
399
400         file_on_host delete $execname
401
402         # Compile pieces with the compiler under test.
403         set i 0
404         foreach src $src_list obj $obj_list {
405             lto-obj $src $obj $option $extra_flags($i) $option \
406                     $compile_xfail($i)
407             incr i
408         }
409
410         # Link (using the compiler under test), run, and clean up tests.
411         if { ![string compare "run" $compile_type] \
412              || ![string compare "link" $compile_type] } {
413
414             # Filter out any link options we were asked to suppress.
415             set reduced {}
416             foreach x [split $option] {
417               if {[lsearch ${dg-suppress-ld-options} $x] == -1} {
418                 lappend reduced $x
419               }
420             }
421             set filtered [join $reduced " "]
422
423             lto-link-and-maybe-run \
424                     "[lindex $obj_list 0]-[lindex $obj_list end]" \
425                     $obj_list $execname $filtered ${dg-extra-ld-options} \
426                     $filtered
427         }
428
429
430         # Are there any further tests to perform?
431         # Note that if the program has special run-time requirements, running
432         # of the program can be delayed until here.  Ditto for other situations.
433         # It would be a bit cumbersome though.
434
435         if ![string match ${dg-final-code} ""] {
436             regsub -all "\\\\(\[{}\])" ${dg-final-code} "\\1" dg-final-code
437             # Note that the use of `args' here makes this a varargs proc.
438             proc dg-final-proc { args } ${dg-final-code}
439             verbose "Running dg-final tests." 3
440             verbose "dg-final-proc:\n[info body dg-final-proc]" 4
441             if [catch "dg-final-proc $src1" errmsg] {
442                 perror "$name: error executing dg-final: $errmsg"
443                 # ??? The call to unresolved here is necessary to clear
444                 # `errcnt'.  What we really need is a proc like perror that
445                 # doesn't set errcnt.  It should also set exit_status to 1.
446                 unresolved "$name: error executing dg-final: $errmsg"
447             }
448         }
449
450         # Clean up object files.
451         set files [glob -nocomplain ${sid}_*.o]
452         if { $files != "" } {
453             foreach objfile $files {
454                 if { ![info exists gluefile] || $objfile != $gluefile } {
455                     eval "file_on_host delete $objfile"
456                 }
457             }
458         }
459
460         if { ![string compare "run" $compile_type] \
461              || ![string compare "link" $compile_type] } {
462             file_on_host delete $execname
463         }
464     }
465 }
466
467 # Utility for scanning a symbol in the final executable, invoked via dg-final.
468 # Call pass if pattern is present, otherwise fail.
469 #
470 # Argument 0 is the regexp to match.
471 # Argument 1 handles expected failures and the like
472 proc scan-symbol { args } {
473     global nm
474     global base_dir
475     upvar 2 execname execname
476
477     if { [llength $args] >= 2 } {
478         switch [dg-process-target [lindex $args 1]] {
479             "S" { }
480             "N" { return }
481             "F" { setup_xfail "*-*-*" }
482             "P" { }
483         }
484     }
485
486     # Find nm like we find g++ in g++.exp.
487     if ![info exists nm]  {
488         set nm [findfile $base_dir/../../../binutils/nm \
489                 $base_dir/../../../binutils/nm \
490                 [findfile $base_dir/../../nm $base_dir/../../nm \
491                       [findfile $base_dir/nm $base_dir/nm \
492                        [transform nm]]]]
493         verbose -log "nm is $nm"
494     }
495
496     set output_file $execname
497     if { $output_file == "" } {
498         fail "scan-symbol $args: dump file does not exist"
499         return
500     }
501
502     set fd [open "| $nm $output_file" r]
503     set text [read $fd]
504     close $fd
505
506     if [regexp -- [lindex $args 0] $text] {
507         pass "scan-symbol $args"
508     } else {
509         fail "scan-symbol $args"
510     }
511 }