OSDN Git Service

* lib/gcc-simulate-thread.exp: New.
[pf3gnuchains/gcc-fork.git] / gcc / testsuite / lib / gcc-simulate-thread.exp
1 #   Copyright (C) 2011 Free Software Foundation, Inc.
2
3 # This program is free software; you can redistribute it and/or modify
4 # it under the terms of the GNU General Public License as published by
5 # the Free Software Foundation; either version 3 of the License, or
6 # (at your option) any later version.
7 #
8 # This program is distributed in the hope that it will be useful,
9 # but WITHOUT ANY WARRANTY; without even the implied warranty of
10 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
11 # GNU General Public License for more details.
12 #
13 # You should have received a copy of the GNU General Public License
14 # along with GCC; see the file COPYING3.  If not see
15 # <http://www.gnu.org/licenses/>.
16
17 # Utility for running a given test through the simulate-thread harness
18 # using gdb.  This is invoked via dg-final.
19 #
20 # Adapted from the guality harness.
21 #
22 # Call 'fail' if a given test printed "FAIL:", otherwise call 'pass'.
23
24 proc simulate-thread { args } {
25     if { ![isnative] || [is_remote target] } { return }
26
27     if { [llength $args] == 1 } {
28         switch [dg-process-target [lindex $args 0]] {
29                 "F" { setup_xfail "*-*-*" }
30         }
31     }
32
33     # This assumes that we are three frames down from dg-test, and that
34     # it still stores the filename of the testcase in a local variable "name".
35     # A cleaner solution would require a new DejaGnu release.
36     upvar 2 name testcase
37     upvar 2 prog prog
38     upvar 2 srcdir testsuite_dir
39
40     set gdb_name $::env(GDB_FOR_GCC_TESTING)
41     set exec_file "[file rootname [file tail $prog]].exe"
42     set cmd_file "$testsuite_dir/gcc.dg/simulate-thread/simulate-thread.gdb"
43
44     if ![file exists $exec_file] {
45         return
46     }
47
48     send_log "Spawning: $gdb_name -nx -nw -quiet -x $cmd_file ./$exec_file\n"
49     set res [remote_spawn target "$gdb_name -nx -nw  -x $cmd_file ./$exec_file"]
50     if { $res < 0 || $res == "" } {
51         unsupported "$testcase"
52         return
53     }
54
55     set gdb_worked 0
56     remote_expect target [timeout_value] {
57         # Too old GDB
58         -re "Unhandled dwarf expression|Error in sourced command file" {
59             unsupported "$testcase"
60             remote_close target
61             return
62         }
63         -re "FAIL:" {
64             fail "$testcase"
65             remote_close target
66             return
67         }
68         # If the gdb output contained simulate_thread_main, assume
69         # that at the very least, we had a working gdb that was able
70         # to break in simulate_thread_main.
71         -re "simulate_thread_main" {
72             set gdb_worked 1
73             exp_continue
74         }
75         timeout {
76             unsupported "$testcase"
77             remote_close target
78             return
79         }
80     }
81
82     remote_close target
83     if {$gdb_worked} {
84         pass "$testcase"
85     } else {
86         # Fail in the absence of a sane GDB.
87         fail "$testcase"
88     }
89     return
90 }