gcc/testsuite/lib/compat.exp

   1 # Copyright (C) 2002, 2003, 2004, 2005, 2007 Free Software Foundation, Inc.
   2
   3 # This program is free software; you can redistribute it and/or modify
   4 # it under the terms of the GNU General Public License as published by
   5 # the Free Software Foundation; either version 3 of the License, or
   6 # (at your option) any later version.
   7 #
   8 # This program is distributed in the hope that it will be useful,
   9 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  10 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  11 # GNU General Public License for more details.
  12 #
  13 # You should have received a copy of the GNU General Public License
  14 # along with GCC; see the file COPYING3.  If not see
  15 # <http://www.gnu.org/licenses/>.
  16
  17 # This file was written by Janis Johnson, <janis187@us.ibm.com>
  18
  19
  20 # Test interoperability of two compilers that follow the same ABI, or
  21 # compatibility of two versions of GCC.
  22 #
  23 # Each test has a main program that does nothing but call a function,
  24 # plus two additional source files that contain parts of a program that
  25 # rely on the ABI.  those source files are compiled into relocatable
  26 # object files with both compilers.  Executables are built using various
  27 # combinations of those object files, with the main program compiled
  28 # with the compiler under test and using that compiler's runtime support.
  29
  30 # The including .exp file must define these callback procedures.
  31 if [string match "" [info procs "compat-use-alt-compiler"]] then {
  32     error "Proc compat-use-alt-compiler is not defined."
  33 }
  34 if [string match "" [info procs "compat-use-tst-compiler"]] then {
  35     error "Proc compat-use-tst-compiler is not defined."
  36 }
  37
  38 # Each test is run with each pair of compiler options from this list.
  39 # The first set of options in each pair is used by the compiler under
  40 # test, and the second set is used by the alternate compiler.
  41 # The default option lists can be overridden by
  42 # COMPAT_OPTIONS="[list [list {tst_1} {alt_1}]...[list {tst_n} {alt_n}]]"
  43 # where tst_i and alt_i are lists of options.  You can put this in the
  44 # environment before site.exp is written or add it to site.exp directly.
  45 if ![info exists COMPAT_OPTIONS] {
  46     set COMPAT_OPTIONS [list \
  47         [list {} {}]]
  48 }
  49
  50 set option_list $COMPAT_OPTIONS
  51
  52 # Subsets of tests can be selectively disabled by members of this list:
  53 #  - ATTRIBUTE: disable all tests using the __attribute__ extension,
  54 #  - COMPLEX: disable all tests using the complex types feature,
  55 #  - COMPLEX_INT: disable all tests using the complex integral types extension,
  56 #  - VA: disable all tests using the variable number of arguments feature,
  57 #  - VLA_IN_STRUCT: disable all tests using the variable-length arrays as
  58 #    structure members extension,
  59 #  - ZERO_ARRAY: disable all tests using the zero-sized arrays extension.
  60 # The default skip lists can be overriden by
  61 # COMPAT_SKIPS="[list {skip_1}...{skip_n}]"
  62 # where skip_i are skip identifiers.  You can put this in the environment
  63 # before site.exp is written or add it to site.exp directly.
  64 if ![info exists COMPAT_SKIPS] {
  65     set COMPAT_SKIPS [list {}]
  66 }
  67
  68 global compat_skip_list
  69 set compat_skip_list $COMPAT_SKIPS
  70
  71 load_lib dg.exp
  72 load_lib gcc-dg.exp
  73
  74 #
  75 # compat-obj -- compile to an object file
  76 #
  77 # SOURCE is the source file
  78 # DEST is the object file
  79 # OPTALL is the list of compiler options to use with all tests
  80 # OPTFILE is the list of compiler options to use with this file
  81 # OPTSTR is the options to print with test messages
  82 # XFAILDATA is the xfail data to be passed to the compiler
  83 #
  84 proc compat-obj { source dest optall optfile optstr xfaildata } {
  85     global testcase
  86     global tool
  87     global compiler_conditional_xfail_data
  88     global compat_skip_list
  89
  90     # Add the skip specifiers.
  91     foreach skip $compat_skip_list {
  92         if { ![string match $skip ""] } {
  93             lappend optall "-DSKIP_$skip"
  94         }
  95     }
  96
  97     # Set up the options for compiling this file.
  98     set options ""
  99     lappend options "additional_flags=$optfile $optall"
 100
 101     set compiler_conditional_xfail_data $xfaildata
 102     set comp_output [${tool}_target_compile "$source" "$dest" object $options]
 103     ${tool}_check_compile "$testcase $dest compile" $optstr $dest $comp_output
 104 }
 105
 106 # compat-run -- link and run an executable
 107 #
 108 # TESTNAME is the mixture of object files to link
 109 # OBJLIST is the list of object files to link
 110 # DEST is the name of the executable
 111 # OPTALL is a list of compiler and linker options to use for all tests
 112 # OPTFILE is a list of compiler and linker options to use for this test
 113 # OPTSTR is the list of options to list in messages
 114 #
 115 proc compat-run { testname objlist dest optall optfile optstr } {
 116     global testcase
 117     global tool
 118
 119     # Check that all of the objects were built successfully.
 120     foreach obj [split $objlist] {
 121         if ![file_on_host exists $obj] then {
 122             unresolved "$testcase $testname link $optstr"
 123             unresolved "$testcase $testname execute $optstr"
 124             return
 125         }
 126     }
 127
 128     # Set up the options for linking this test.
 129     set options ""
 130     lappend options "additional_flags=$optfile $optall"
 131
 132     # Link the objects into an executable.
 133     set comp_output [${tool}_target_compile "$objlist" $dest executable \
 134                      "$options"]
 135     if ![${tool}_check_compile "$testcase $testname link" "" \
 136          $dest $comp_output] then {
 137         unresolved "$testcase $testname execute $optstr"
 138         return
 139     }
 140
 141     # Run the self-checking executable.
 142     if ![string match "*/*" $dest] then {
 143         set dest "./$dest"
 144     }
 145     set result [${tool}_load $dest "" ""]
 146     set status [lindex $result 0]
 147     if { $status == "pass" } then {
 148         file_on_host delete $dest
 149     }
 150     $status "$testcase $testname execute $optstr"
 151 }
 152
 153 #
 154 # compat-get-options-main -- get target requirements for a test and
 155 # options for the primary source file and the test as a whole
 156 #
 157 # SRC is the full pathname of the primary source file.
 158 #
 159 proc compat-get-options-main { src } {
 160     # dg-options sets a variable called dg-extra-tool-flags.
 161     set dg-extra-tool-flags ""
 162     # dg-options sets a variable called tool_flags.
 163     set tool_flags ""
 164
 165     # dg-require-* sets dg-do-what.
 166     upvar dg-do-what dg-do-what
 167
 168     set tmp [dg-get-options $src]
 169     foreach op $tmp {
 170         set cmd [lindex $op 0]
 171         if { ![string compare "dg-options" $cmd] \
 172              || [string match "dg-skip-if" $cmd] \
 173              || [string match "dg-require-*" $cmd]  } {
 174             set status [catch "$op" errmsg]
 175             if { $status != 0 } {
 176                 perror "src: $errmsg for \"$op\"\n"
 177                 unresolved "$src: $errmsg for \"$op\""
 178                 return
 179             }
 180         } elseif { ![string compare "dg-xfail-if" $cmd] } {
 181             warning "compat.exp does not support $cmd in primary source file"
 182         } else {
 183             # Ignore unrecognized dg- commands, but warn about them.
 184             warning "compat.exp does not support $cmd"
 185         }
 186     }
 187
 188     # Return flags to use for compiling the primary source file and for
 189     # linking.
 190     return ${dg-extra-tool-flags}
 191 }
 192
 193 #
 194 # compat-get-options -- get special tool flags to use for a secondary
 195 # source file
 196 #
 197 # SRC is the full pathname of the source file.
 198 # The result is a list of options to use.
 199 #
 200 # This code is copied from proc dg-test in dg.exp from DejaGNU.
 201 #
 202 proc compat-get-options { src } {
 203     # dg-options sets a variable called dg-extra-tool-flags.
 204     set dg-extra-tool-flags ""
 205
 206     # dg-xfail-if sets compiler_conditional_xfail_data.
 207     global compiler_conditional_xfail_data
 208     set compiler_conditional_xfail_data ""
 209
 210     # dg-xfail-if needs access to dg-do-what.
 211     upvar dg-do-what dg-do-what
 212
 213     set tmp [dg-get-options $src]
 214     foreach op $tmp {
 215         set cmd [lindex $op 0]
 216         if { ![string compare "dg-options" $cmd] \
 217              || ![string compare "dg-xfail-if" $cmd] } {
 218             set status [catch "$op" errmsg]
 219             if { $status != 0 } {
 220                 perror "src: $errmsg for \"$op\"\n"
 221                 unresolved "$src: $errmsg for \"$op\""
 222                 return
 223             }
 224         } elseif { [string match "dg-require-*" $cmd] } {
 225             warning "compat.exp does not support $cmd in secondary source files"
 226         } else {
 227             # Ignore unrecognized dg- commands, but warn about them.
 228             warning "compat.exp does not support $cmd"
 229         }
 230     }
 231
 232     return ${dg-extra-tool-flags}
 233 }
 234
 235 #
 236 # compat-execute -- compile with compatible compilers
 237 #
 238 # SRC1 is the full pathname of the main file of the testcase.
 239 # SID identifies a test suite in the names of temporary files.
 240 # USE_ALT is nonzero if we're using an alternate compiler as well as
 241 #   the compiler under test.
 242 #
 243 proc compat-execute { src1 sid use_alt } {
 244     global srcdir tmpdir
 245     global option_list
 246     global tool
 247     global verbose
 248     global testcase
 249     global gluefile
 250     global compiler_conditional_xfail_data
 251     global dg-do-what-default
 252
 253     # Get extra flags for this test from the primary source file, and
 254     # process other dg-* options that this suite supports.  Warn about
 255     # unsupported flags.
 256     verbose "compat-execute: $src1" 1
 257     set dg-do-what [list ${dg-do-what-default} "" P]
 258     set extra_flags_1 [compat-get-options-main $src1]
 259
 260     # Check whether this test is supported for this target.
 261     if { [lindex ${dg-do-what} 1 ] == "N" } {
 262         unsupported "$src1"
 263         verbose "$src1 not supported on this target, skipping it" 3
 264         return
 265     }
 266
 267     # Set up the names of the other source files.
 268     set dir [file dirname $src1]
 269     set ext [file extension $src1]
 270     set base [file rootname $src1]
 271     set base [string range $base [string length $dir] end]
 272     regsub "_main" $base "" base
 273     set src2 "${dir}/${base}_x${ext}"
 274     set src3 "${dir}/${base}_y${ext}"
 275
 276     # Use the dg-options mechanism to specify extra flags for this test.
 277     # The extra flags in each file are used to compile that file, and the
 278     # extra flags in *_main.* are also used for linking.
 279     set extra_flags_2 [compat-get-options $src2]
 280     set compile_xfail_2 $compiler_conditional_xfail_data
 281     set extra_flags_3 [compat-get-options $src3]
 282     set compile_xfail_3 $compiler_conditional_xfail_data
 283
 284     # On the SPU, most of the compat test cases exceed local store size.
 285     # Use automatic overlay support to make them fit.
 286     if { [check_effective_target_spu_auto_overlay] } {
 287         set extra_flags_1 "$extra_flags_1 -Wl,--auto-overlay"
 288         set extra_flags_1 "$extra_flags_1 -ffunction-sections"
 289         set extra_flags_2 "$extra_flags_2 -ffunction-sections"
 290         set extra_flags_3 "$extra_flags_3 -ffunction-sections"
 291     }
 292
 293     # Define the names of the object files.
 294     regsub "sid" "sid_main_tst.o" $sid obj1
 295     regsub "sid" "sid_x_tst.o" $sid obj2_tst
 296     regsub "sid" "sid_x_alt.o" $sid obj2_alt
 297     regsub "sid" "sid_y_tst.o" $sid obj3_tst
 298     regsub "sid" "sid_y_alt.o" $sid obj3_alt
 299
 300     # Get the base name of this test, for use in messages.
 301     set testcase "$src1"
 302     # Remove the $srcdir and $tmpdir prefixes from $src1.  (It would
 303     # be possible to use "regsub" here, if we were careful to escape
 304     # all regular expression characters in $srcdir and $tmpdir, but
 305     # that would be more complicated that this approach.)
 306     if {[string first "$srcdir/" "$src1"] == 0} {
 307         set testcase [string range "$src1" [string length "$srcdir/"] end]
 308     }
 309     if {[string first "$tmpdir/" "$testcase"] == 0} {
 310         set testcase [string range "$testcase" [string length "$tmpdir/"] end]
 311         set testcase "tmpdir-$testcase"
 312     }
 313     regsub "_main.*" $testcase "" testcase
 314     # Set up the base name of executable files so they'll be unique.
 315     regsub -all "\[./\]" $testcase "-" execbase
 316
 317     # If we couldn't rip $srcdir out of `src1' then just do the best we can.
 318     # The point is to reduce the unnecessary noise in the logs.  Don't strip
 319     # out too much because different testcases with the same name can confuse
 320     # `test-tool'.
 321     if [string match "/*" $testcase] then {
 322         set testcase "[file tail [file dirname $src1]]/[file tail $src1]"
 323     }
 324
 325     # Loop through all of the option lists used for this test.
 326
 327     set count 0
 328     foreach option_pair $option_list {
 329
 330         # Pick out each set of options.
 331         set tst_option [lindex $option_pair 0]
 332         set alt_option [lindex $option_pair 1]
 333         set optstr ""
 334         if { ![string match $tst_option ""] \
 335              || ![string match $alt_option ""] } then {
 336             set optstr "\"$tst_option\",\"$alt_option\""
 337         }
 338         verbose "Testing $testcase, $optstr" 1
 339
 340         # There's a unique name for each executable we generate, based on
 341         # the set of options and how the pieces of the tests are compiled.
 342         set execname1 "${execbase}-${count}1.exe"
 343         set execname2 "${execbase}-${count}2.exe"
 344         set execname3 "${execbase}-${count}3.exe"
 345         set execname4 "${execbase}-${count}4.exe"
 346         incr count
 347
 348         file_on_host delete $execname1
 349         file_on_host delete $execname2
 350         file_on_host delete $execname3
 351         file_on_host delete $execname4
 352
 353         # Compile pieces with the alternate compiler; we'll catch problems
 354         # later.  Skip this if we don't have an alternate compiler.
 355         if { $use_alt != 0 } then {
 356             compat-use-alt-compiler
 357             compat-obj "$src2" "$obj2_alt" $alt_option $extra_flags_2 \
 358                        $optstr $compile_xfail_2
 359             compat-obj "$src3" "$obj3_alt" $alt_option $extra_flags_3 \
 360                        $optstr $compile_xfail_3
 361         }
 362
 363         # Compile pieces with the compiler under test.
 364         compat-use-tst-compiler
 365         compat-obj "$src1" "$obj1" $tst_option $extra_flags_1 $optstr ""
 366         compat-obj "$src2" "$obj2_tst" $tst_option $extra_flags_2 \
 367                    $optstr $compile_xfail_2
 368         compat-obj "$src3" "$obj3_tst" $tst_option $extra_flags_3 \
 369                    $optstr $compile_xfail_3
 370
 371         # Link (using the compiler under test), run, and clean up tests.
 372         compat-run "${obj2_tst}-${obj3_tst}" \
 373             "$obj1 $obj2_tst $obj3_tst" $execname1 \
 374             $tst_option $extra_flags_1 $optstr
 375
 376         # If we've got an alternate compiler try some combinations.
 377         if { $use_alt != 0 } then {
 378             compat-run "${obj2_tst}-${obj3_alt}" "$obj1 $obj2_tst $obj3_alt" \
 379                        $execname2 $tst_option $extra_flags_1 $optstr
 380             compat-run "${obj2_alt}-${obj3_tst}" "$obj1 $obj2_alt $obj3_tst" \
 381                        $execname3 $tst_option $extra_flags_1 $optstr
 382             compat-run "${obj2_alt}-${obj3_alt}" "$obj1 $obj2_alt $obj3_alt" \
 383                        $execname4 $tst_option $extra_flags_1 $optstr
 384         }
 385
 386         # Clean up object files.
 387         set files [glob -nocomplain ${sid}_*.o]
 388         if { $files != "" } {
 389             foreach objfile $files {
 390                 if { ![info exists gluefile] || $objfile != $gluefile } {
 391                     eval "file_on_host delete $objfile"
 392                 }
 393             }
 394         }
 395     }
 396 }