OSDN Git Service

gcc/
[pf3gnuchains/gcc-fork.git] / gcc / testsuite / gcc.test-framework / test-framework.awk
1 # Process the gcc.sum file for a run through gcc.test-framework.
2 # Print result lines that show potential problems.  Report the number
3 # of passing tests.
4 #
5 #
6 # Copyright (c) 2004, 2005, 2006 Free Software Foundation, Inc.
7 #
8 # This file is free software; you can redistribute it and/or modify
9 # it under the terms of the GNU General Public License as published by
10 # the Free Software Foundation; either version 2 of the License, or
11 # (at your option) any later version.
12 #
13 # This program is distributed in the hope that it will be useful,
14 # but WITHOUT ANY WARRANTY; without even the implied warranty of
15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
16 # GNU General Public License for more details.
17 #
18 # For a copy of the GNU General Public License, write the the
19 # Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
20 # Boston, MA 02110-1301, USA.
21
22 function pass(msg)      {
23                           passes++;
24                         # printf("pass   %s\n", $0);
25                         }
26 function fail(msg)      {
27                           fails++;
28                           printf("fail   %s\n", $0);
29                         }
30 function ignore(msg)    {
31                         # printf("ignore %s\n", $0);
32                         }
33
34 BEGIN                   { skip = 1; passes = 0; fails = 0; }
35 /Running.*test-frame/   { skip = 0; next }
36 /gcc Summary/           { skip = 1; next }
37                         { if (skip) next }
38 /^$/                    { next }
39 # The post tests are always expected to pass.
40 /^PASS.*-2.c/           { ignore(); next }
41 # dg-xfail-if applies to the compile step; these should be XPASS for the
42 # compile step on dox tests, which are run tests.
43 /^XPASS.*dox.*xiff.*-1.c.*\(test for excess errors\)/ { ignore(); next }
44 # xfail for scan-assembler-not tests doesn't apply to the compile step.
45 /^PASS.*sa.*-1.c.*\(test for excess errors\)/ { ignore(); next }
46 # ignore compile step, tests for warnings for output-exists[-not] tests.
47 /dg-outexists.*\(test for excess errors)/ { ignore(); next }
48 /dg-outexists.*\(test for warnings/ { ignore(); next }
49 /dg-outexists.*\(test for errors/ { ignore(); next }
50 # The other dox tests pass the compile step; ignore that message.
51 /^PASS.*dox.*\(test for excess errors\)/ { ignore(); next }
52 # The sf tests pass the compile step; ignore that message.
53 /^PASS.*sf.*\(test for excess errors\)/ { ignore(); next }
54 # Ignore lines that begin with comma.
55 /^,/                    { ignore(); next }
56 # For tests of dg-output, ignore successful compilation.
57 /^PASS.*dg-output.*\(test for excess errors\)/  { ignore(); next }
58 # For tests of dg-output, ignore successful execution.
59 /^PASS.*dg-output.*execution test/      { ignore(); next }
60 /^PASS/                 { if (match ($0, "exp-P")) { pass(); next } }
61 /^FAIL/                 { if (match ($0, "exp-F")) { pass(); next } }
62 /^XPASS/                { if (match ($0, "exp-XP")) { pass(); next } }
63 /^XFAIL/                { if (match ($0, "exp-XF")) { pass(); next } }
64 /^UNSUPPORTED/          { if (match ($0, "exp-U")) { pass(); next } }
65                         { fail() }
66 END                     {
67                           printf("\n\t\t=== Test Framework Summary ===\n\n");
68                           printf("# of expected passes\t\t%d\n", passes);
69                           if (fails != 0)
70                             printf("# of unexpected failures\t%d\n", fails);
71                         }