OSDN Git Service

e498430b9473cdc598a93d2d0159df15e556998f
[pf3gnuchains/gcc-fork.git] / gcc / testsuite / gcc.target / mips / mips.exp
1 #   Copyright (C) 1997, 2007 Free Software Foundation, Inc.
2
3 # This program is free software; you can redistribute it and/or modify
4 # it under the terms of the GNU General Public License as published by
5 # the Free Software Foundation; either version 3 of the License, or
6 # (at your option) any later version.
7
8 # This program is distributed in the hope that it will be useful,
9 # but WITHOUT ANY WARRANTY; without even the implied warranty of
10 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
11 # GNU General Public License for more details.
12
13 # You should have received a copy of the GNU General Public License
14 # along with GCC; see the file COPYING3.  If not see
15 # <http://www.gnu.org/licenses/>.
16
17 # GCC testsuite that uses the `dg.exp' driver.
18
19 # Exit immediately if this isn't a MIPS target.
20 if ![istarget mips*-*-*] {
21   return
22 }
23
24 # Load support procs.
25 load_lib gcc-dg.exp
26
27 # Find out which target is selected by the default compiler flags.
28 # Also remember which aspects of the target are forced on the command
29 # line (as opposed to being overridable defaults).
30 #
31 #    $mips_isa:          the ISA level specified by __mips
32 #    $mips_arch:         the architecture specified by _MIPS_ARCH
33 #    $mips_mips16:       true if MIPS16 mode is selected
34 #    $mips_mips64:       true if 64-bit output is selected
35 #    $mips_float:        "hard" or "soft"
36 #
37 #    $mips_forced_isa:   true if the command line uses -march=* or -mips*
38 #    $mips_forced_abi:   true if the command line uses -mabi=* or -mgp*
39 #    $mips_forced_float: true if the command line uses -mhard/soft-float
40 #    $mips_forced_le     true if the command line uses -EL or -mel
41 proc setup_mips_tests {} {
42     global mips_isa
43     global mips_arch
44     global mips_mips16
45     global mips_mips64
46     global mips_float
47
48     global mips_forced_isa
49     global mips_forced_abi
50     global mips_forced_float
51     global mips_forced_le
52
53     global compiler_flags
54     global tool
55
56     set src dummy[pid].c
57     set f [open $src "w"]
58     puts $f {
59         int isa = __mips;
60         const char *arch = _MIPS_ARCH;
61         #ifdef __mips16
62         int mips16 = 1;
63         #endif
64         #ifdef __mips64
65         int mips64 = 1;
66         #endif
67         #ifdef __mips_hard_float
68         const char *float = "hard";
69         #else
70         const char *float = "soft";
71         #endif
72     }
73     close $f
74     set output [${tool}_target_compile $src "" preprocess ""]
75     file delete $src
76
77     regexp {isa = ([^;]*)} $output dummy mips_isa
78     regexp {arch = "([^"]*)} $output dummy mips_arch
79     set mips_mips16 [regexp {mips16 = 1} $output]
80     set mips_mips64 [regexp {mips64 = 1} $output]
81     regexp {float = "([^"]*)} $output dummy mips_float
82
83     set mips_forced_isa [regexp -- {(-mips|-march)} $compiler_flags]
84     set mips_forced_abi [regexp -- {(-mgp|-mfp|-mabi)} $compiler_flags]
85     set mips_forced_float [regexp -- {-m(hard|soft)-float} $compiler_flags]
86     set mips_forced_le [regexp -- {-(EL|mel)[[:>:]]} $compiler_flags]
87 }
88
89 # Return true if command-line option FLAG forces 32-bit code.
90 proc is_gp32_flag {flag} {
91     switch -glob -- $flag {
92         -msmartmips -
93         -march=mips32* -
94         -mgp32 { return 1 }
95         default { return 0 }
96     }
97 }
98
99 # Like dg-options, but treats certain MIPS-specific options specially:
100 #
101 #    -mgp32
102 #    -march=mips32*
103 #       Force 32-bit code.  Skip the test if the multilib flags force
104 #       a 64-bit ABI.
105 #
106 #    -mgp64
107 #       Force 64-bit code.  Also force a 64-bit target architecture
108 #       if the other flags don't do so.  Skip the test if the multilib
109 #       flags force a 32-bit ABI or a 32-bit architecture.
110 #
111 #    -mno-mips16
112 #       Skip the test for MIPS16 targets.
113 #
114 #    -march=*
115 #    -mips*
116 #       Select the target architecture.  Skip the test for MIPS16 targets
117 #       or if the multilib flags force a different architecture.
118 #
119 #    -msoft-float
120 #    -mhard-float
121 #       Select the given floating-point mode.  Skip the test if the
122 #       multilib flags force a different selection.
123 #
124 #    -EB
125 #       Select big-endian code.  Skip the test if the multilib flags
126 #       force a little-endian target.
127 proc dg-mips-options {args} {
128     upvar dg-extra-tool-flags extra_tool_flags
129     upvar dg-do-what do_what
130
131     global mips_isa
132     global mips_arch
133     global mips_mips16
134     global mips_mips64
135     global mips_float
136
137     global mips_forced_isa
138     global mips_forced_abi
139     global mips_forced_float
140     global mips_forced_le
141
142     set flags [lindex $args 1]
143     set matches 1
144
145     # First handle the -mgp* options.  Add an architecture option if necessary.
146     foreach flag $flags {
147         if {[is_gp32_flag $flag] && $mips_mips64} {
148             if {$mips_forced_abi} {
149                 set matches 0
150             } else {
151                 append flags " -mabi=32"
152             }
153         } elseif {$flag == "-mgp64" && !$mips_mips64} {
154             if {$mips_forced_abi} {
155                 set matches 0
156             } else {
157                 append flags " -mabi=o64"
158                 if {[lsearch -regexp $flags {^(-mips|-march)}] < 0} {
159                     append flags " -mips3"
160                 }
161             }
162         }
163     }
164     # Handle the other options.
165     foreach flag $flags {
166         if {$flag == "-mno-mips16"} {
167             if {$mips_mips16} {
168                 set matches 0
169             }
170         } elseif {$flag == "-mfp64"} {
171             if {$mips_isa < 33 || $mips_float != "hard"} {
172                 set matches 0
173             }
174         } elseif {[regexp -- {^-march=(.*)} $flag dummy arch]} {
175             if {$mips_mips16 || ($arch != $mips_arch && $mips_forced_isa)} {
176                 set matches 0
177             }
178         } elseif {[regexp -- {^-mips(.*)} $flag dummy isa] && $isa != 16} {
179             if {$mips_mips16 || ($isa != $mips_isa && $mips_forced_isa)} {
180                 set matches 0
181             }
182         } elseif {[regexp -- {^-m(hard|soft)-float} $flag dummy float]} {
183             if {$mips_float != $float && $mips_forced_float} {
184                 set matches 0
185             }
186         } elseif {[regexp -- {^-(EB|meb)$} $flag]} {
187             if {$mips_forced_le} {
188                 set matches 0
189             }
190         }
191     }
192     if {$matches} {
193         set extra_tool_flags $flags
194     } else {
195         set do_what [list [lindex $do_what 0] "N" "P"]
196     }
197 }
198
199 setup_mips_tests
200
201 dg-init
202 dg-runtest [lsort [glob -nocomplain $srcdir/$subdir/*.c]] "" ""
203 dg-finish