gcc/opth-gen.awk

   1 #  Copyright (C) 2003,2004 Free Software Foundation, Inc.
   2 #  Contributed by Kelley Cook, June 2004.
   3 #  Original code from Neil Booth, May 2003.
   4 #
   5 # This program is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by the
   7 # Free Software Foundation; either version 2, or (at your option) any
   8 # later version.
   9 #
  10 # This program is distributed in the hope that it will be useful,
  11 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program; if not, write to the Free Software
  17 # Foundation, 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  18
  19 # This Awk script reads in the option records generated from
  20 # opt-gather.awk, combines the flags of duplicate options and generates a
  21 # C header file.
  22 #
  23 # This program uses functions from opt-functions.awk
  24 # Usage: awk -f opt-functions.awk -f opth-gen.awk < inputfile > options.h
  25
  26 BEGIN {
  27         n_opts = 0
  28         n_langs = 0
  29         quote = "\042"
  30         comma = ","
  31         FS=SUBSEP
  32 }
  33
  34 # Collect the text and flags of each option into an array
  35         {
  36                 if ($1 == "Language") {
  37                         langs[n_langs] = $2
  38                         n_langs++;
  39                 }
  40                 else {
  41                         opts[n_opts]  = $1
  42                         flags[n_opts] = $2
  43                         help[n_opts]  = $3
  44                         n_opts++;
  45                 }
  46         }
  47
  48 # Dump out an enumeration into a .h file.
  49 # Combine the flags of duplicate options.
  50 END {
  51 print "/* This file is auto-generated by opts.sh.  */"
  52 print ""
  53 print "#ifndef OPTIONS_H"
  54 print "#define OPTIONS_H"
  55 print ""
  56
  57 for (i = 0; i < n_opts; i++) {
  58         name = var_name(flags[i]);
  59         if (name == "")
  60                 continue;
  61
  62         print "/* Set by -" opts[i] "."
  63         print "   " help[i] "  */"
  64         print "extern int " name ";"
  65         print ""
  66
  67     }
  68
  69
  70 for (i = 0; i < n_langs; i++) {
  71         macros[i] = "CL_" langs[i]
  72         gsub( "[^A-Za-z0-9_]", "X", macros[i] )
  73         s = substr("            ", length (macros[i]))
  74         print "#define " macros[i] s " (1 << " i ")"
  75     }
  76
  77 print ""
  78 print "enum opt_code"
  79 print "{"
  80
  81 for (i = 0; i < n_opts; i++)
  82         back_chain[i] = "N_OPTS";
  83
  84         for (i = 0; i < n_opts; i++) {
  85                 # Combine the flags of identical switches.  Switches
  86                 # appear many times if they are handled by many front
  87                 # ends, for example.
  88                 while( i + 1 != n_opts && opts[i] == opts[i + 1] ) {
  89                         flags[i + 1] = flags[i] " " flags[i + 1];
  90                         i++;
  91                 }
  92
  93         len = length (opts[i]);
  94         enum = "OPT_" opts[i]
  95         if (opts[i] == "finline-limit=")
  96                 enum = enum "eq"
  97         gsub ("[^A-Za-z0-9]", "_", enum)
  98
  99         # If this switch takes joined arguments, back-chain all
 100         # subsequent switches to it for which it is a prefix.  If
 101         # a later switch S is a longer prefix of a switch T, T
 102         # will be back-chained to S in a later iteration of this
 103         # for() loop, which is what we want.
 104         if (flags[i] ~ "Joined") {
 105                 for (j = i + 1; j < n_opts; j++) {
 106                         if (substr (opts[j], 1, len) != opts[i])
 107                                 break;
 108                         back_chain[j] = enum;
 109                 }
 110         }
 111
 112         s = substr("                                     ", length (opts[i]))
 113         if (i + 1 == n_opts)
 114                 comma = ""
 115
 116         if (help[i] == "")
 117                 hlp = "0"
 118         else
 119                 hlp = "N_(\"" help[i] "\")";
 120
 121         print "  " enum "," s "/* -" opts[i] " */"
 122 }
 123
 124 print "  N_OPTS"
 125 print "};"
 126 print ""
 127 print "#endif /* OPTIONS_H */"
 128 }