gcc/optc-gen.awk

   1 #  Copyright (C) 2003,2004 Free Software Foundation, Inc.
   2 #  Contributed by Kelley Cook, June 2004.
   3 #  Original code from Neil Booth, May 2003.
   4 #
   5 # This program is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by the
   7 # Free Software Foundation; either version 2, or (at your option) any
   8 # later version.
   9 #
  10 # This program is distributed in the hope that it will be useful,
  11 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program; if not, write to the Free Software
  17 # Foundation, 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  18
  19 # This Awk script reads in the option records generated from
  20 # opt-gather.awk, combines the flags of duplicat options and generates a
  21 # C file.
  22 #
  23 # This program uses functions from opt-functions.awk
  24 #
  25 # Usage: awk -f opt-functions.awk -f optc-gen.awk \
  26 #            [-v header_name=header.h] < inputfile > options.c
  27
  28 BEGIN {
  29         n_opts = 0
  30         n_langs = 0
  31         quote = "\042"
  32         comma = ","
  33         FS=SUBSEP
  34         # Default the name of header created from opth-gen.awk to options.h
  35         if (header_name == "") header_name="options.h"
  36 }
  37
  38 # Collect the text and flags of each option into an array
  39         {
  40                 if ($1 == "Language") {
  41                         langs[n_langs] = $2
  42                         n_langs++;
  43                 }
  44                 else {
  45                         opts[n_opts]  = $1
  46                         flags[n_opts] = $2
  47                         help[n_opts]  = $3
  48                         n_opts++;
  49                 }
  50         }
  51
  52 # Dump that array of options into a C file.
  53 END {
  54 print "/* This file is auto-generated by opts.sh.  */"
  55 print ""
  56 print "#include <intl.h>"
  57 print "#include " quote header_name quote
  58 print "#include " quote "opts.h" quote
  59 print ""
  60
  61 for (i = 0; i < n_opts; i++) {
  62         name = var_name(flags[i]);
  63         if (name == "")
  64                 continue;
  65
  66         if (flag_set_p("VarExists", flags[i]))
  67                 continue;
  68
  69         init = opt_args("Init", flags[i])
  70         if (init != "")
  71                 init = " = " init;
  72
  73         printf ("/* Set by -%s.\n   %s  */\nint %s%s;\n\n",
  74             opts[i], help[i], name,init)
  75 }
  76
  77
  78 print "const char * const lang_names[] =\n{"
  79 for (i = 0; i < n_langs; i++) {
  80         macros[i] = "CL_" langs[i]
  81         gsub( "[^A-Za-z0-9_]", "X", macros[i] )
  82         s = substr("         ", length (macros[i]))
  83         print "  " quote langs[i] quote ","
  84     }
  85
  86 print "  0\n};\n"
  87 print "const unsigned int cl_options_count = N_OPTS;\n"
  88
  89 print "const struct cl_option cl_options[] =\n{"
  90
  91 for (i = 0; i < n_opts; i++)
  92         back_chain[i] = "N_OPTS";
  93
  94         for (i = 0; i < n_opts; i++) {
  95                 # Combine the flags of identical switches.  Switches
  96                 # appear many times if they are handled by many front
  97                 # ends, for example.
  98                 while( i + 1 != n_opts && opts[i] == opts[i + 1] ) {
  99                         flags[i + 1] = flags[i] " " flags[i + 1];
 100                         i++;
 101                 }
 102
 103                 len = length (opts[i]);
 104                 enum = "OPT_" opts[i]
 105                 if (opts[i] == "finline-limit=")
 106                         enum = enum "eq"
 107                 gsub ("[^A-Za-z0-9]", "_", enum)
 108
 109                 # If this switch takes joined arguments, back-chain all
 110                 # subsequent switches to it for which it is a prefix.  If
 111                 # a later switch S is a longer prefix of a switch T, T
 112                 # will be back-chained to S in a later iteration of this
 113                 # for() loop, which is what we want.
 114                 if (flag_set_p("Joined.*", flags[i])) {
 115                         for (j = i + 1; j < n_opts; j++) {
 116                                 if (substr (opts[j], 1, len) != opts[i])
 117                                         break;
 118                                 back_chain[j] = enum;
 119                         }
 120                 }
 121
 122                 s = substr("                                  ", length (opts[i]))
 123                 if (i + 1 == n_opts)
 124                         comma = ""
 125
 126                 if (help[i] == "")
 127                         hlp = "0"
 128                 else
 129                         hlp = "N_(" quote help[i] quote ")";
 130
 131                 printf("  { %c-%s%c,\n    %s,\n    %s, %u, %s, %s, %s }%s\n",
 132                         quote, opts[i], quote, hlp, back_chain[i], len,
 133                         switch_flags(flags[i]),
 134                         var_ref(flags[i]), var_set(flags[i]), comma)
 135 }
 136
 137 print "};"
 138 }