gcc/configure.in

   1 # configure.in for GCC
   2 # Process this file with autoconf to generate a configuration script.
   3
   4 # Copyright 1997, 1998, 1999, 2000, 2001, 2002, 2003
   5 # Free Software Foundation, Inc.
   6
   7 #This file is part of GCC.
   8
   9 #GCC is free software; you can redistribute it and/or modify it under
  10 #the terms of the GNU General Public License as published by the Free
  11 #Software Foundation; either version 2, or (at your option) any later
  12 #version.
  13
  14 #GCC is distributed in the hope that it will be useful, but WITHOUT
  15 #ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  16 #FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  17 #for more details.
  18
  19 #You should have received a copy of the GNU General Public License
  20 #along with GCC; see the file COPYING.  If not, write to the Free
  21 #Software Foundation, 59 Temple Place - Suite 330, Boston, MA
  22 #02111-1307, USA.
  23
  24 # --------------------------------
  25 # Initialization and sanity checks
  26 # --------------------------------
  27
  28 AC_PREREQ(2.13)
  29 AC_INIT(tree.c)
  30 AC_CONFIG_HEADER(auto-host.h:config.in)
  31
  32 # Determine the host, build, and target systems
  33 AC_CANONICAL_SYSTEM
  34
  35 # Determine the target- and build-specific subdirectories
  36 GCC_TOPLEV_SUBDIRS
  37
  38 # Set program_transform_name
  39 AC_ARG_PROGRAM
  40
  41 # Check for bogus environment variables.
  42 # Test if LIBRARY_PATH contains the notation for the current directory
  43 # since this would lead to problems installing/building glibc.
  44 # LIBRARY_PATH contains the current directory if one of the following
  45 # is true:
  46 # - one of the terminals (":" and ";") is the first or last sign
  47 # - two terminals occur directly after each other
  48 # - the path contains an element with a dot in it
  49 AC_MSG_CHECKING(LIBRARY_PATH variable)
  50 changequote(,)dnl
  51 case ${LIBRARY_PATH} in
  52   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
  53     library_path_setting="contains current directory"
  54     ;;
  55   *)
  56     library_path_setting="ok"
  57     ;;
  58 esac
  59 changequote([,])dnl
  60 AC_MSG_RESULT($library_path_setting)
  61 if test "$library_path_setting" != "ok"; then
  62 AC_MSG_ERROR([
  63 *** LIBRARY_PATH shouldn't contain the current directory when
  64 *** building gcc. Please change the environment variable
  65 *** and run configure again.])
  66 fi
  67
  68 # Test if GCC_EXEC_PREFIX contains the notation for the current directory
  69 # since this would lead to problems installing/building glibc.
  70 # GCC_EXEC_PREFIX contains the current directory if one of the following
  71 # is true:
  72 # - one of the terminals (":" and ";") is the first or last sign
  73 # - two terminals occur directly after each other
  74 # - the path contains an element with a dot in it
  75 AC_MSG_CHECKING(GCC_EXEC_PREFIX variable)
  76 changequote(,)dnl
  77 case ${GCC_EXEC_PREFIX} in
  78   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
  79     gcc_exec_prefix_setting="contains current directory"
  80     ;;
  81   *)
  82     gcc_exec_prefix_setting="ok"
  83     ;;
  84 esac
  85 changequote([,])dnl
  86 AC_MSG_RESULT($gcc_exec_prefix_setting)
  87 if test "$gcc_exec_prefix_setting" != "ok"; then
  88 AC_MSG_ERROR([
  89 *** GCC_EXEC_PREFIX shouldn't contain the current directory when
  90 *** building gcc. Please change the environment variable
  91 *** and run configure again.])
  92 fi
  93
  94 # -----------
  95 # Directories
  96 # -----------
  97
  98 # Specify the local prefix
  99 local_prefix=
 100 AC_ARG_WITH(local-prefix,
 101 [  --with-local-prefix=DIR specifies directory to put local include],
 102 [case "${withval}" in
 103 yes)    AC_MSG_ERROR(bad value ${withval} given for local include directory prefix) ;;
 104 no)     ;;
 105 *)      local_prefix=$with_local_prefix ;;
 106 esac])
 107
 108 # Default local prefix if it is empty
 109 if test x$local_prefix = x; then
 110         local_prefix=/usr/local
 111 fi
 112
 113 # Don't set gcc_gxx_include_dir to gxx_include_dir since that's only
 114 # passed in by the toplevel make and thus we'd get different behavior
 115 # depending on where we built the sources.
 116 gcc_gxx_include_dir=
 117 # Specify the g++ header file directory
 118 AC_ARG_WITH(gxx-include-dir,
 119 [  --with-gxx-include-dir=DIR
 120                           specifies directory to put g++ header files],
 121 [case "${withval}" in
 122 yes)    AC_MSG_ERROR(bad value ${withval} given for g++ include directory) ;;
 123 no)     ;;
 124 *)      gcc_gxx_include_dir=$with_gxx_include_dir ;;
 125 esac])
 126
 127 if test x${gcc_gxx_include_dir} = x; then
 128   if test x${enable_version_specific_runtime_libs} = xyes; then
 129     gcc_gxx_include_dir='${libsubdir}/include/c++'
 130   else
 131     topsrcdir=${srcdir}/.. . ${srcdir}/../config.if
 132 changequote(<<, >>)dnl
 133     gcc_gxx_include_dir="\$(libsubdir)/\$(unlibsubdir)/..\`echo \$(exec_prefix) | sed -e 's|^\$(prefix)||' -e 's|/[^/]*|/..|g'\`/include/"${libstdcxx_incdir}
 134 changequote([, ])dnl
 135   fi
 136 fi
 137
 138 AC_ARG_WITH(cpp_install_dir,
 139 [  --with-cpp-install-dir=DIR
 140                           install the user visible C preprocessor in DIR
 141                           (relative to PREFIX) as well as PREFIX/bin],
 142 [if test x$withval = xyes; then
 143   AC_MSG_ERROR([option --with-cpp-install-dir requires an argument])
 144 elif test x$withval != xno; then
 145   cpp_install_dir=$withval
 146 fi])
 147
 148 # -------------------
 149 # Find default linker
 150 # -------------------
 151
 152 # With GNU ld
 153 AC_ARG_WITH(gnu-ld,
 154 [  --with-gnu-ld           arrange to work with GNU ld.],
 155 gnu_ld_flag="$with_gnu_ld",
 156 gnu_ld_flag=no)
 157
 158 # With pre-defined ld
 159 AC_ARG_WITH(ld,
 160 [  --with-ld               arrange to use the specified ld (full pathname)],
 161 DEFAULT_LINKER="$with_ld")
 162 if test x"${DEFAULT_LINKER+set}" = x"set"; then
 163   if test ! -x "$DEFAULT_LINKER"; then
 164     AC_MSG_WARN([cannot execute: $DEFAULT_LINKER: check --with-ld or env. var. DEFAULT_LINKER])
 165   elif $DEFAULT_LINKER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
 166     gnu_ld_flag=yes
 167   fi
 168   AC_DEFINE_UNQUOTED(DEFAULT_LINKER,"$DEFAULT_LINKER",
 169         [Define to enable the use of a default linker.])
 170 fi
 171
 172 AC_MSG_CHECKING([whether a default linker was specified])
 173 if test x"${DEFAULT_LINKER+set}" = x"set"; then
 174   if test x"$gnu_ld_flag" = x"no"; then
 175     AC_MSG_RESULT([yes ($DEFAULT_LINKER)])
 176   else
 177     AC_MSG_RESULT([yes ($DEFAULT_LINKER - GNU ld)])
 178   fi
 179 else
 180   AC_MSG_RESULT(no)
 181 fi
 182
 183 # ----------------------
 184 # Find default assembler
 185 # ----------------------
 186
 187 # With GNU as
 188 AC_ARG_WITH(gnu-as,
 189 [  --with-gnu-as           arrange to work with GNU as],
 190 gas_flag="$with_gnu_as",
 191 gas_flag=no)
 192
 193 AC_ARG_WITH(as,
 194 [  --with-as               arrange to use the specified as (full pathname)],
 195 DEFAULT_ASSEMBLER="$with_as")
 196 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
 197   if test ! -x "$DEFAULT_ASSEMBLER"; then
 198     AC_MSG_WARN([cannot execute: $DEFAULT_ASSEMBLER: check --with-as or env. var. DEFAULT_ASSEMBLER])
 199   elif $DEFAULT_ASSEMBLER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
 200     gas_flag=yes
 201   fi
 202   AC_DEFINE_UNQUOTED(DEFAULT_ASSEMBLER,"$DEFAULT_ASSEMBLER",
 203         [Define to enable the use of a default assembler.])
 204 fi
 205
 206 AC_MSG_CHECKING([whether a default assembler was specified])
 207 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
 208   if test x"$gas_flag" = x"no"; then
 209     AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER)])
 210   else
 211     AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER - GNU as)])
 212   fi
 213 else
 214   AC_MSG_RESULT(no)
 215 fi
 216
 217 # ---------------
 218 # Find C compiler
 219 # ---------------
 220
 221 # Find the native compiler
 222 AC_PROG_CC
 223 AC_PROG_CC_C_O
 224 # autoconf is lame and doesn't give us any substitution variable for this.
 225 if eval "test \"`echo '$ac_cv_prog_cc_'${ac_cc}_c_o`\" = no"; then
 226   NO_MINUS_C_MINUS_O=yes
 227 else
 228   OUTPUT_OPTION='-o $@'
 229 fi
 230 AC_SUBST(NO_MINUS_C_MINUS_O)
 231 AC_SUBST(OUTPUT_OPTION)
 232
 233 # -------------------------
 234 # Check C compiler features
 235 # -------------------------
 236
 237 AC_CACHE_CHECK(whether ${CC-cc} accepts -Wno-long-long,
 238 ac_cv_prog_cc_no_long_long,
 239 [save_CFLAGS="$CFLAGS"
 240 CFLAGS="-Wno-long-long"
 241 AC_TRY_COMPILE(,,ac_cv_prog_cc_no_long_long=yes,
 242                ac_cv_prog_cc_no_long_long=no)
 243 CFLAGS="$save_CFLAGS"])
 244
 245 AC_PROG_CPP
 246 AC_C_INLINE
 247
 248 gcc_AC_C_LONG_LONG
 249 gcc_AC_C__BOOL
 250
 251 # sizeof(char) is 1 by definition.
 252 AC_COMPILE_CHECK_SIZEOF(short)
 253 AC_COMPILE_CHECK_SIZEOF(int)
 254 AC_COMPILE_CHECK_SIZEOF(long)
 255 if test $ac_cv_c_long_long = yes; then
 256   AC_COMPILE_CHECK_SIZEOF(long long)
 257 fi
 258 if test $ac_cv_c___int64 = yes; then
 259   AC_COMPILE_CHECK_SIZEOF(__int64)
 260 fi
 261
 262 gcc_AC_C_CHARSET
 263
 264 # -----------------
 265 # Find Ada compiler
 266 # -----------------
 267
 268 # See if GNAT has been installed
 269 gcc_AC_PROG_GNAT
 270
 271 if test x$have_gnat != xno ; then
 272 AC_CACHE_CHECK(whether ${ADAC} accepts -Wno-long-long,
 273 ac_cv_prog_adac_no_long_long,
 274 [cat >conftest.adb <<EOF
 275 procedure conftest is begin null; end conftest;
 276 EOF
 277 if $ADAC -Wno-long-long -c conftest.adb 1>&5 2>&5 ; then
 278   ac_cv_prog_adac_no_long_long=yes
 279 else
 280   ac_cv_prog_adac_no_long_long=no
 281 fi
 282 rm -f conftest*])
 283 else
 284   ac_cv_prog_adac_no_long_long=yes
 285 fi
 286
 287 # ---------------------
 288 # Warnings and checking
 289 # ---------------------
 290
 291 strict1_warn=
 292 if test $ac_cv_prog_cc_no_long_long = yes && \
 293     test $ac_cv_prog_adac_no_long_long = yes ; then
 294   strict1_warn="-pedantic -Wno-long-long"
 295 fi
 296 AC_SUBST(strict1_warn)
 297
 298 # If the native compiler is GCC, we can enable warnings even in stage1.
 299 # That's useful for people building cross-compilers, or just running a
 300 # quick `make'.
 301 warn_cflags=
 302 if test "x$GCC" = "xyes"; then
 303   warn_cflags='$(GCC_WARN_CFLAGS)'
 304 fi
 305 AC_SUBST(warn_cflags)
 306
 307 # Enable -Werror in bootstrap stage2 and later.
 308 # Change the default to "no" on release branches.
 309 AC_ARG_ENABLE(werror,
 310 [  --enable-werror         enable -Werror in bootstrap stage2 and later], [],
 311 [enable_werror=yes])
 312 if test x$enable_werror = xyes ; then
 313   WERROR=-Werror
 314 fi
 315 AC_SUBST(WERROR)
 316
 317 # Enable expensive internal checks
 318 AC_ARG_ENABLE(checking,
 319 [  --enable-checking[=LIST]
 320                           enable expensive run-time checks.  With LIST,
 321                           enable only specific categories of checks.
 322                           Categories are: misc,tree,rtl,rtlflag,gc,gcac;
 323                           default is misc,tree,gc,rtlflag],
 324 [ac_checking=
 325 ac_tree_checking=
 326 ac_rtl_checking=
 327 ac_rtlflag_checking=
 328 ac_gc_checking=
 329 ac_gc_always_collect=
 330 case "${enableval}" in
 331 yes)    ac_checking=1 ; ac_tree_checking=1 ; ac_gc_checking=1 ;
 332         ac_rtlflag_checking=1 ;;
 333 no)     ;;
 334 *)      IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 335         set fnord $enableval; shift
 336         IFS="$ac_save_IFS"
 337         for check
 338         do
 339                 case $check in
 340                 misc)   ac_checking=1 ;;
 341                 tree)   ac_tree_checking=1 ;;
 342                 rtlflag)        ac_rtlflag_checking=1 ;;
 343                 rtl)    ac_rtl_checking=1 ;;
 344                 gc)     ac_gc_checking=1 ;;
 345                 gcac)   ac_gc_always_collect=1 ;;
 346                 valgrind)       ac_checking_valgrind=1 ;;
 347                 *)      AC_MSG_ERROR(unknown check category $check) ;;
 348                 esac
 349         done
 350         ;;
 351 esac
 352 ],
 353 # Enable some checks by default for development versions of GCC
 354 [ac_checking=1; ac_tree_checking=1; ac_gc_checking=1; ac_rtlflag_checking=1;])
 355 nocommon_flag=""
 356 if test x$ac_checking != x ; then
 357   AC_DEFINE(ENABLE_CHECKING, 1,
 358 [Define if you want more run-time sanity checks.  This one gets a grab
 359    bag of miscellaneous but relatively cheap checks.])
 360   nocommon_flag=-fno-common
 361 fi
 362 AC_SUBST(nocommon_flag)
 363 if test x$ac_tree_checking != x ; then
 364   AC_DEFINE(ENABLE_TREE_CHECKING, 1,
 365 [Define if you want all operations on trees (the basic data
 366    structure of the front ends) to be checked for dynamic type safety
 367    at runtime.  This is moderately expensive.])
 368 fi
 369 if test x$ac_rtl_checking != x ; then
 370   AC_DEFINE(ENABLE_RTL_CHECKING, 1,
 371 [Define if you want all operations on RTL (the basic data structure
 372    of the optimizer and back end) to be checked for dynamic type safety
 373    at runtime.  This is quite expensive.])
 374 fi
 375 if test x$ac_rtlflag_checking != x ; then
 376   AC_DEFINE(ENABLE_RTL_FLAG_CHECKING, 1,
 377 [Define if you want RTL flag accesses to be checked against the RTL
 378    codes that are supported for each access macro.  This is relatively
 379    cheap.])
 380 fi
 381 if test x$ac_gc_checking != x ; then
 382   AC_DEFINE(ENABLE_GC_CHECKING, 1,
 383 [Define if you want the garbage collector to do object poisoning and
 384    other memory allocation checks.  This is quite expensive.])
 385 fi
 386 if test x$ac_gc_always_collect != x ; then
 387   AC_DEFINE(ENABLE_GC_ALWAYS_COLLECT, 1,
 388 [Define if you want the garbage collector to operate in maximally
 389    paranoid mode, validating the entire heap and collecting garbage at
 390    every opportunity.  This is extremely expensive.])
 391 fi
 392 valgrind_path_defines=
 393 valgrind_command=
 394 if test x$ac_checking_valgrind != x ; then
 395   # It is certainly possible that there's valgrind but no valgrind.h.
 396   # GCC relies on making annotations so we must have both.
 397   AC_MSG_CHECKING(for VALGRIND_DISCARD in <memcheck.h>)
 398   AC_TRY_CPP(
 399     [#include <memcheck.h>
 400 #ifndef VALGRIND_DISCARD
 401 #error VALGRIND_DISCARD not defined
 402 #endif],
 403   [gcc_cv_header_memcheck_h=yes],
 404   gcc_cv_header_memcheck_h=no)
 405   AC_MSG_RESULT($gcc_cv_header_memcheck_h)
 406   AC_CHECK_HEADER(valgrind.h, have_valgrind_h=yes, have_valgrind_h=no)
 407   AM_PATH_PROG_WITH_TEST(valgrind_path, valgrind,
 408         [$ac_dir/$ac_word --version | grep valgrind- >/dev/null 2>&1])
 409   if test "x$valgrind_path" = "x" || (test $have_valgrind_h = no && test $gcc_cv_header_memcheck_h = no); then
 410         AC_MSG_ERROR([*** Can't find both valgrind and valgrind.h/memcheck.h])
 411   fi
 412   valgrind_path_defines=-DVALGRIND_PATH='\"'$valgrind_path'\"'
 413   valgrind_command="$valgrind_path -q"
 414   AC_DEFINE(ENABLE_VALGRIND_CHECKING, 1,
 415 [Define if you want to run subprograms and generated programs
 416    through valgrind (a memory checker).  This is extremely expensive.])
 417   if test $gcc_cv_header_memcheck_h = yes; then
 418     AC_DEFINE(HAVE_MEMCHECK_H, 1,
 419         [Define if valgrind's memcheck.h header is installed.])
 420   fi
 421 fi
 422 AC_SUBST(valgrind_path_defines)
 423 AC_SUBST(valgrind_command)
 424
 425 # Enable code coverage collection
 426 AC_ARG_ENABLE(coverage,
 427 [  --enable-coverage[=LEVEL]
 428                           enable compiler\'s code coverage collection.
 429                           Use to measure compiler performance and locate
 430                           unused parts of the compiler. With LEVEL, specify
 431                           optimization. Values are opt, noopt,
 432                           default is noopt],
 433 [case "${enableval}" in
 434 yes|noopt)
 435         coverage_flags="-fprofile-arcs -ftest-coverage -O0 -DSELF_COVERAGE=1"
 436         ;;
 437 opt)
 438         coverage_flags="-fprofile-arcs -ftest-coverage -O2 -DSELF_COVERAGE=2"
 439         ;;
 440 *)
 441         AC_MSG_ERROR(unknown coverage setting $enableval)
 442         ;;
 443 esac],
 444 [coverage_flags=""])
 445 AC_SUBST(coverage_flags)
 446
 447 # -------------------------------
 448 # Miscenalleous configure options
 449 # -------------------------------
 450
 451 # With stabs
 452 AC_ARG_WITH(stabs,
 453 [  --with-stabs            arrange to use stabs instead of host debug format],
 454 stabs="$with_stabs",
 455 stabs=no)
 456
 457 # With ELF
 458 AC_ARG_WITH(elf,
 459 [  --with-elf              arrange to use ELF instead of host debug format],
 460 elf="$with_elf",
 461 elf=no)
 462
 463 # Determine whether or not multilibs are enabled.
 464 AC_ARG_ENABLE(multilib,
 465 [  --enable-multilib       enable library support for multiple ABIs],
 466 [], [enable_multilib=yes])
 467 AC_SUBST(enable_multilib)
 468
 469 # Enable __cxa_atexit for C++.
 470 AC_ARG_ENABLE(__cxa_atexit,
 471 [  --enable-__cxa_atexit   enable __cxa_atexit for C++],
 472 [], [])
 473
 474 # Enable Multibyte Characters for C/C++
 475 AC_ARG_ENABLE(c-mbchar,
 476 [  --enable-c-mbchar       enable multibyte characters for C and C++],
 477 if test x$enable_c_mbchar != xno; then
 478   AC_DEFINE(MULTIBYTE_CHARS, 1,
 479   [Define if you want the C and C++ compilers to support multibyte
 480    character sets for source code.])
 481 fi)
 482
 483 # Enable threads
 484 # Pass with no value to take the default
 485 # Pass with a value to specify a thread package
 486 AC_ARG_ENABLE(threads,
 487 [  --enable-threads        enable thread usage for target GCC
 488   --enable-threads=LIB    use LIB thread package for target GCC],,
 489 enable_threads='')
 490
 491 enable_threads_flag=$enable_threads
 492 # Check if a valid thread package
 493 case x${enable_threads_flag} in
 494         x | xno)
 495                 # No threads
 496                 target_thread_file='single'
 497                 ;;
 498         xyes)
 499                 # default
 500                 target_thread_file=''
 501                 ;;
 502         xdecosf1 | xirix | xmach | xos2 | xposix | xpthreads | xsingle | \
 503         xsolaris | xwin32 | xdce | xrtems| xvxworks | xaix | xgnat)
 504                 target_thread_file=$enable_threads_flag
 505                 ;;
 506         *)
 507                 echo "$enable_threads is an unknown thread package" 1>&2
 508                 exit 1
 509                 ;;
 510 esac
 511
 512 AC_ARG_ENABLE(objc-gc,
 513 [  --enable-objc-gc       enable the use of Boehm's garbage collector with
 514                           the GNU Objective-C runtime],
 515 if test x$enable_objc_gc = xno; then
 516         objc_boehm_gc=''
 517 else
 518         objc_boehm_gc=1
 519 fi,
 520 objc_boehm_gc='')
 521
 522 AC_ARG_WITH(dwarf2,
 523 [  --with-dwarf2           force the default debug format to be DWARF 2],
 524 dwarf2="$with_dwarf2",
 525 dwarf2=no)
 526
 527 AC_ARG_ENABLE(shared,
 528 [  --disable-shared        don't provide a shared libgcc],
 529 [
 530   case $enable_shared in
 531   yes | no) ;;
 532   *)
 533     enable_shared=no
 534     IFS="${IFS=         }"; ac_save_ifs="$IFS"; IFS="${IFS}:,"
 535     for pkg in $enableval; do
 536       if test "X$pkg" = "Xgcc" || test "X$pkg" = "Xlibgcc"; then
 537         enable_shared=yes
 538       fi
 539     done
 540     IFS="$ac_save_ifs"
 541     ;;
 542   esac
 543 ], [enable_shared=yes])
 544 AC_SUBST(enable_shared)
 545
 546 AC_ARG_WITH(sysroot,
 547 [  --with-sysroot[=DIR] Search for usr/lib, usr/include, et al, within DIR.],
 548 [
 549  case ${with_sysroot} in
 550  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_alias}/sys-root' ;;
 551  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
 552  esac
 553
 554  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
 555  CROSS_SYSTEM_HEADER_DIR='$(TARGET_SYSTEM_ROOT)$(NATIVE_SYSTEM_HEADER_DIR)'
 556
 557  if test "x$exec_prefix" = xNONE; then
 558   if test "x$prefix" = xNONE; then
 559    test_prefix=/usr/local
 560   else
 561    test_prefix=$prefix
 562   fi
 563  else
 564   test_prefix=$exec_prefix
 565  fi
 566  case ${TARGET_SYSTEM_ROOT} in
 567  "${test_prefix}"|"${test_prefix}/"*|\
 568  '${exec_prefix}'|'${exec_prefix}/'*)
 569    t="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE"
 570    TARGET_SYSTEM_ROOT_DEFINE="$t"
 571    ;;
 572  esac
 573 ], [
 574  TARGET_SYSTEM_ROOT=
 575  TARGET_SYSTEM_ROOT_DEFINE=
 576  CROSS_SYSTEM_HEADER_DIR='$(gcc_tooldir)/sys-include'
 577 ])
 578 AC_SUBST(TARGET_SYSTEM_ROOT)
 579 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
 580 AC_SUBST(CROSS_SYSTEM_HEADER_DIR)
 581
 582 # -------------------------
 583 # Checks for other programs
 584 # -------------------------
 585
 586 AC_PROG_MAKE_SET
 587
 588 # Find some useful tools
 589 AC_PROG_AWK
 590 gcc_AC_PROG_LN
 591 gcc_AC_PROG_LN_S
 592 AC_PROG_RANLIB
 593 gcc_AC_PROG_INSTALL
 594
 595 # See if we have the mktemp command.
 596 AC_CHECK_PROG(have_mktemp_command, mktemp, yes, no)
 597
 598 # Do we have a single-tree copy of texinfo?
 599 if test -f $srcdir/../texinfo/Makefile.in; then
 600   MAKEINFO='$(objdir)/../texinfo/makeinfo/makeinfo'
 601   gcc_cv_prog_makeinfo_modern=yes
 602   AC_MSG_RESULT([Using makeinfo from the unified source tree.])
 603 else
 604   # See if makeinfo has been installed and is modern enough
 605   # that we can use it.
 606   gcc_AC_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
 607   [GNU texinfo.* \([0-9][0-9.]*\)],
 608   [4.[2-9]*])
 609 fi
 610
 611 if test $gcc_cv_prog_makeinfo_modern = no; then
 612   AC_MSG_WARN([
 613 *** Makeinfo is missing or too old.
 614 *** Info documentation will not be built.])
 615   BUILD_INFO=
 616 else
 617   BUILD_INFO=info               AC_SUBST(BUILD_INFO)
 618 fi
 619
 620 # Is pod2man recent enough to regenerate manpages?
 621 AC_MSG_CHECKING([for recent Pod::Man])
 622 if (perl -e 'use 1.10 Pod::Man') >/dev/null 2>&1; then
 623   AC_MSG_RESULT(yes)
 624   GENERATED_MANPAGES=generated-manpages         AC_SUBST(GENERATED_MANPAGES)
 625 else
 626   AC_MSG_RESULT(no)
 627   GENERATED_MANPAGES=
 628 fi
 629
 630 # 'make compare' can be significantly faster, if cmp itself can
 631 # skip bytes instead of using tail.  The test being performed is
 632 # "if cmp --ignore-initial=2 t1 t2 && ! cmp --ignore-initial=1 t1 t2"
 633 # but we need to sink errors and handle broken shells.
 634 AC_MSG_CHECKING([for cmp's capabilities])
 635 echo abfoo >t1
 636 echo cdfoo >t2
 637 if cmp --ignore-initial=2 t1 t2 > /dev/null 2>&1; then
 638   if cmp --ignore-initial=1 t1 t2 > /dev/null 2>&1; then
 639     make_compare_target=slowcompare
 640   else
 641     make_compare_target=gnucompare
 642   fi
 643 else
 644   make_compare_target=slowcompare
 645 fi
 646 rm t1 t2
 647 AC_SUBST(make_compare_target)
 648 AC_MSG_RESULT($make_compare_target)
 649
 650 # How about lex?
 651 dnl Don't use AC_PROG_LEX; we insist on flex.
 652 dnl LEXLIB is not useful in gcc.
 653 if test -f $srcdir/../flex/skel.c; then
 654   FLEX='$(objdir)/../flex/flex'
 655 else
 656   AC_CHECK_PROG(FLEX, flex, flex, ${CONFIG_SHELL-/bin/sh} ${srcdir}/../missing flex)
 657 fi
 658
 659 # Bison?
 660 # The -L switch is so bison can find its skeleton file.
 661 if test -f $srcdir/../bison/bison.simple; then
 662   BISON='$(objdir)/../bison/bison -L $(srcdir)/../bison/'
 663 else
 664   AC_CHECK_PROG(BISON, bison, bison, ${CONFIG_SHELL-/bin/sh} ${srcdir}/../missing bison)
 665 fi
 666
 667 # --------------------
 668 # Checks for C headers
 669 # --------------------
 670
 671 AC_MSG_CHECKING(for GNU C library)
 672 AC_CACHE_VAL(gcc_cv_glibc,
 673 [AC_TRY_COMPILE(
 674   [#include <features.h>],[
 675 #if ! (defined __GLIBC__ || defined __GNU_LIBRARY__)
 676 #error Not a GNU C library system
 677 #endif],
 678   [gcc_cv_glibc=yes],
 679   gcc_cv_glibc=no)])
 680 AC_MSG_RESULT($gcc_cv_glibc)
 681 if test $gcc_cv_glibc = yes; then
 682   AC_DEFINE(_GNU_SOURCE, 1, [Always define this when using the GNU C Library])
 683 fi
 684
 685 AC_HEADER_STDC
 686 AC_HEADER_TIME
 687 gcc_AC_HEADER_STDBOOL
 688 gcc_AC_HEADER_STRING
 689 AC_HEADER_SYS_WAIT
 690 AC_CHECK_HEADERS(limits.h stddef.h string.h strings.h stdlib.h time.h \
 691                  fcntl.h unistd.h sys/file.h sys/time.h sys/mman.h \
 692                  sys/resource.h sys/param.h sys/times.h sys/stat.h \
 693                  direct.h malloc.h langinfo.h ldfcn.h wchar.h)
 694
 695 # Check for thread headers.
 696 AC_CHECK_HEADER(thread.h, [have_thread_h=yes], [have_thread_h=])
 697 AC_CHECK_HEADER(pthread.h, [have_pthread_h=yes], [have_pthread_h=])
 698
 699 # These tests can't be done till we know if we have limits.h.
 700 gcc_AC_C_CHAR_BIT
 701 AC_C_BIGENDIAN_CROSS
 702
 703 # --------
 704 # UNSORTED
 705 # --------
 706
 707 # Stage specific cflags for build.
 708 stage1_cflags=
 709 case $build in
 710 vax-*-*)
 711   if test x$GCC = xyes
 712   then
 713     stage1_cflags="-Wa,-J"
 714   else
 715     stage1_cflags="-J"
 716   fi
 717   ;;
 718 powerpc-*-darwin*)
 719   # The spiffy cpp-precomp chokes on some legitimate constructs in GCC
 720   # sources; use -no-cpp-precomp to get to GNU cpp.
 721   # Apple's GCC has bugs in designated initializer handling, so disable
 722   # that too.
 723   stage1_cflags="-no-cpp-precomp -DHAVE_DESIGNATED_INITIALIZERS=0"
 724   ;;
 725 esac
 726 AC_SUBST(stage1_cflags)
 727
 728 # These libraries may be used by collect2.
 729 # We may need a special search path to get them linked.
 730 AC_CACHE_CHECK(for collect2 libraries, gcc_cv_collect2_libs,
 731 [save_LIBS="$LIBS"
 732 for libs in '' -lld -lmld \
 733                 '-L/usr/lib/cmplrs/cc2.11 -lmld' \
 734                 '-L/usr/lib/cmplrs/cc3.11 -lmld'
 735 do
 736         LIBS="$libs"
 737         AC_TRY_LINK_FUNC(ldopen,
 738                 [gcc_cv_collect2_libs="$libs"; break])
 739 done
 740 LIBS="$save_LIBS"
 741 test -z "$gcc_cv_collect2_libs" && gcc_cv_collect2_libs='none required'])
 742 case $gcc_cv_collect2_libs in
 743         "none required")        ;;
 744         *)      COLLECT2_LIBS=$gcc_cv_collect2_libs ;;
 745 esac
 746 AC_SUBST(COLLECT2_LIBS)
 747
 748 # When building Ada code on Alpha, we need exc_resume which is usually in
 749 # -lexc.  So test for it.
 750 save_LIBS="$LIBS"
 751 LIBS=
 752 AC_SEARCH_LIBS(exc_resume, exc)
 753 GNAT_LIBEXC="$LIBS"
 754 LIBS="$save_LIBS"
 755 AC_SUBST(GNAT_LIBEXC)
 756
 757 # Some systems put ldexp and frexp in libm instead of libc; assume
 758 # they're both in the same place.  jcf-dump needs them.
 759 save_LIBS="$LIBS"
 760 LIBS=
 761 AC_SEARCH_LIBS(ldexp, m)
 762 LDEXP_LIB="$LIBS"
 763 LIBS="$save_LIBS"
 764 AC_SUBST(LDEXP_LIB)
 765
 766 # Use <inttypes.h> only if it exists,
 767 # doesn't clash with <sys/types.h>, and declares intmax_t.
 768 AC_MSG_CHECKING(for inttypes.h)
 769 AC_CACHE_VAL(gcc_cv_header_inttypes_h,
 770 [AC_TRY_COMPILE(
 771   [#include <sys/types.h>
 772 #include <inttypes.h>],
 773   [intmax_t i = -1;],
 774   [gcc_cv_header_inttypes_h=yes],
 775   gcc_cv_header_inttypes_h=no)])
 776 AC_MSG_RESULT($gcc_cv_header_inttypes_h)
 777 if test $gcc_cv_header_inttypes_h = yes; then
 778   AC_DEFINE(HAVE_INTTYPES_H, 1,
 779         [Define if you have a working <inttypes.h> header file.])
 780 fi
 781
 782 dnl Disabled until we have a complete test for buggy enum bitfields.
 783 dnl gcc_AC_C_ENUM_BF_UNSIGNED
 784
 785 AC_CHECK_FUNCS(times clock dup2 kill getrlimit setrlimit atoll atoq \
 786         sysconf strsignal putc_unlocked fputc_unlocked fputs_unlocked \
 787         fwrite_unlocked fprintf_unlocked getrusage nl_langinfo lstat \
 788         scandir alphasort gettimeofday mbstowcs wcswidth mmap mincore)
 789
 790 if test x$ac_cv_func_mbstowcs = xyes; then
 791   AC_CACHE_CHECK(whether mbstowcs works, gcc_cv_func_mbstowcs_works,
 792 [    AC_TRY_RUN([#include <stdlib.h>
 793 int main()
 794 {
 795   mbstowcs(0, "", 0);
 796   return 0;
 797 }],
 798     gcc_cv_func_mbstowcs_works=yes,
 799     gcc_cv_func_mbstowcs_works=no,
 800     gcc_cv_func_mbstowcs_works=yes)])
 801   if test x$gcc_cv_func_mbstowcs_works = xyes; then
 802     AC_DEFINE(HAVE_WORKING_MBSTOWCS, 1,
 803   [Define this macro if mbstowcs does not crash when its
 804    first argument is NULL.])
 805   fi
 806 fi
 807
 808 AC_CHECK_TYPE(ssize_t, int)
 809
 810 # Try to determine the array type of the second argument of getgroups
 811 # for the target system (int or gid_t).
 812 AC_TYPE_GETGROUPS
 813 if test "${target}" = "${build}"; then
 814   TARGET_GETGROUPS_T=$ac_cv_type_getgroups
 815 else
 816   case "${target}" in
 817         # This condition may need some tweaking.  It should include all
 818         # targets where the array type of the second argument of getgroups
 819         # is int and the type of gid_t is not equivalent to int.
 820         *-*-sunos* | *-*-ultrix*)
 821                 TARGET_GETGROUPS_T=int
 822                 ;;
 823         *)
 824                 TARGET_GETGROUPS_T=gid_t
 825                 ;;
 826   esac
 827 fi
 828 AC_SUBST(TARGET_GETGROUPS_T)
 829
 830 gcc_AC_FUNC_PRINTF_PTR
 831 gcc_AC_FUNC_MMAP_BLACKLIST
 832
 833 case "${host}" in
 834 *-*-uwin*)
 835   AC_MSG_ERROR([
 836 *** UWIN may not be used as a host platform because
 837 *** linking with posix.dll is not allowed by the GNU GPL])
 838   ;;
 839 *-*-*vms*)
 840   # Under VMS, vfork works very different than on Unix. The standard test
 841   # won't work, and it isn't easily adaptable. It makes more sense to
 842   # just force it.
 843   ac_cv_func_vfork_works=yes
 844   ;;
 845 esac
 846 AC_FUNC_VFORK
 847
 848 AM_ICONV
 849
 850 # We will need to find libiberty.h and ansidecl.h
 851 saved_CFLAGS="$CFLAGS"
 852 CFLAGS="$CFLAGS -I${srcdir} -I${srcdir}/../include"
 853 gcc_AC_CHECK_DECLS(getenv atol sbrk abort atof getcwd getwd \
 854         strsignal putc_unlocked fputs_unlocked fwrite_unlocked \
 855         fprintf_unlocked strstr errno vasprintf \
 856         malloc realloc calloc free basename getopt clock, , ,[
 857 #include "ansidecl.h"
 858 #include "system.h"])
 859
 860 gcc_AC_CHECK_DECLS(getrlimit setrlimit getrusage, , ,[
 861 #include "ansidecl.h"
 862 #include "system.h"
 863 #ifdef HAVE_SYS_RESOURCE_H
 864 #include <sys/resource.h>
 865 #endif
 866 ])
 867
 868 AC_TRY_COMPILE([
 869 #include "ansidecl.h"
 870 #include "system.h"
 871 #ifdef HAVE_SYS_RESOURCE_H
 872 #include <sys/resource.h>
 873 #endif
 874 ],[rlim_t l = 0;],,[AC_DEFINE([rlim_t],[long],
 875 [Define to \`long' if <sys/resource.h> doesn't define.])])
 876
 877 gcc_AC_CHECK_DECLS(ldgetname, , ,[
 878 #include "ansidecl.h"
 879 #include "system.h"
 880 #ifdef HAVE_LDFCN_H
 881 #include <ldfcn.h>
 882 #endif
 883 ])
 884
 885 gcc_AC_CHECK_DECLS(times, , ,[
 886 #include "ansidecl.h"
 887 #include "system.h"
 888 #ifdef HAVE_SYS_TIMES_H
 889 #include <sys/times.h>
 890 #endif
 891 ])
 892
 893 # More time-related stuff.
 894 AC_CACHE_CHECK(for struct tms, ac_cv_struct_tms, [
 895 AC_TRY_COMPILE([
 896 #include "ansidecl.h"
 897 #include "system.h"
 898 #ifdef HAVE_SYS_TIMES_H
 899 #include <sys/times.h>
 900 #endif
 901 ], [struct tms tms;], ac_cv_struct_tms=yes, ac_cv_struct_tms=no)])
 902 if test $ac_cv_struct_tms = yes; then
 903   AC_DEFINE(HAVE_STRUCT_TMS, 1,
 904   [Define if <sys/times.h> defines struct tms.])
 905 fi
 906
 907 # use gcc_cv_* here because this doesn't match the behavior of AC_CHECK_TYPE.
 908 # revisit after autoconf 2.50.
 909 AC_CACHE_CHECK(for clock_t, gcc_cv_type_clock_t, [
 910 AC_TRY_COMPILE([
 911 #include "ansidecl.h"
 912 #include "system.h"
 913 ], [clock_t x;], gcc_cv_type_clock_t=yes, gcc_cv_type_clock_t=no)])
 914 if test $gcc_cv_type_clock_t = yes; then
 915   AC_DEFINE(HAVE_CLOCK_T, 1,
 916   [Define if <time.h> defines clock_t.])
 917 fi
 918
 919 AC_CACHE_CHECK(for uchar, gcc_cv_type_uchar,
 920 [AC_TRY_COMPILE([
 921 #include "ansidecl.h"
 922 #include "system.h"
 923 ],
 924 [if ((uchar *)0) return 0;
 925  if (sizeof(uchar)) return 0;],
 926 ac_cv_type_uchar=yes, ac_cv_type_uchar=no)])
 927 if test $ac_cv_type_uchar = yes; then
 928   AC_DEFINE(HAVE_UCHAR, 1,
 929   [Define if <sys/types.h> defines \`uchar'.])
 930 fi
 931
 932 # Restore CFLAGS from before the gcc_AC_NEED_DECLARATIONS tests.
 933 CFLAGS="$saved_CFLAGS"
 934
 935 gcc_AC_INITFINI_ARRAY
 936
 937 # mkdir takes a single argument on some systems.
 938 gcc_AC_FUNC_MKDIR_TAKES_ONE_ARG
 939
 940 # File extensions
 941 manext='.1'
 942 objext='.o'
 943 AC_SUBST(manext)
 944 AC_SUBST(objext)
 945
 946 # With Setjmp/Longjmp based exception handling.
 947 AC_ARG_ENABLE(sjlj-exceptions,
 948 [  --enable-sjlj-exceptions
 949                           arrange to use setjmp/longjmp exception handling],
 950 [sjlj=`if test $enableval = yes; then echo 1; else echo 0; fi`
 951 AC_DEFINE_UNQUOTED(CONFIG_SJLJ_EXCEPTIONS, $sjlj,
 952   [Define 0/1 to force the choice for exception handling model.])])
 953
 954 AC_CHECK_LIB(unwind, main, use_libunwind_default=yes, use_libunwind_default=no)
 955 # Use libunwind based exception handling.
 956 AC_ARG_ENABLE(libunwind-exceptions,
 957 [  --enable-libunwind-exceptions  force use libunwind for exceptions],
 958 use_libunwind_exceptions=$enableval,
 959 use_libunwind_exceptions=$use_libunwind_default)
 960 if test x"$use_libunwind_exceptions" = xyes; then
 961    AC_DEFINE(USE_LIBUNWIND_EXCEPTIONS, 1,
 962         [Define if gcc should use -lunwind.])
 963 fi
 964
 965 # --------------------------------------------------------
 966 # Build, host, and target specific configuration fragments
 967 # --------------------------------------------------------
 968
 969 target_gtfiles=
 970 build_xm_file=
 971 build_xm_defines=
 972 build_install_headers_dir=install-headers-tar
 973 build_exeext=
 974 host_xm_file=
 975 host_xm_defines=
 976 host_xmake_file=
 977 host_exeext=
 978
 979 # Decode the host machine, then the target machine.
 980 # For the host machine, we save the xm_file variable as host_xm_file;
 981 # then we decode the target machine and forget everything else
 982 # that came from the host machine.
 983 for machine in $build $host $target; do
 984         . ${srcdir}/config.gcc
 985 done
 986
 987 extra_objs="${host_extra_objs} ${extra_objs}"
 988
 989 # Default the target-machine variables that were not explicitly set.
 990 if test x"$tm_file" = x
 991 then tm_file=$cpu_type/$cpu_type.h; fi
 992
 993 if test x"$extra_headers" = x
 994 then extra_headers=; fi
 995
 996 if test x$md_file = x
 997 then md_file=$cpu_type/$cpu_type.md; fi
 998
 999 if test x$out_file = x
1000 then out_file=$cpu_type/$cpu_type.c; fi
1001
1002 if test x"$tmake_file" = x
1003 then tmake_file=$cpu_type/t-$cpu_type
1004 fi
1005
1006 if test x"$dwarf2" = xyes
1007 then tm_file="$tm_file tm-dwarf2.h"
1008 fi
1009
1010 # Say what files are being used for the output code and MD file.
1011 echo "Using \`$srcdir/config/$out_file' for machine-specific logic."
1012 echo "Using \`$srcdir/config/$md_file' as machine description file."
1013
1014 # If any of the xm_file variables contain nonexistent files, warn
1015 # about them and drop them.
1016
1017 bx=
1018 for x in $build_xm_file; do
1019   if    test -f $srcdir/config/$x
1020   then      bx="$bx $x"
1021   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1022   fi
1023 done
1024 build_xm_file="$bx"
1025
1026 hx=
1027 for x in $host_xm_file; do
1028   if    test -f $srcdir/config/$x
1029   then      hx="$hx $x"
1030   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1031   fi
1032 done
1033 host_xm_file="$hx"
1034
1035 tx=
1036 for x in $xm_file; do
1037   if    test -f $srcdir/config/$x
1038   then      tx="$tx $x"
1039   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1040   fi
1041 done
1042 xm_file="$tx"
1043
1044 count=a
1045 for f in $tm_file; do
1046         count=${count}x
1047 done
1048 if test $count = ax; then
1049         echo "Using \`$srcdir/config/$tm_file' as target machine macro file."
1050 else
1051         echo "Using the following target machine macro files:"
1052         for f in $tm_file; do
1053                 echo "  $srcdir/config/$f"
1054         done
1055 fi
1056
1057 if test x$need_64bit_hwint = xyes; then
1058         AC_DEFINE(NEED_64BIT_HOST_WIDE_INT, 1,
1059 [Define to 1 if HOST_WIDE_INT must be 64 bits wide (see hwint.h).])
1060 fi
1061
1062 count=a
1063 for f in $host_xm_file; do
1064         count=${count}x
1065 done
1066 if test $count = a; then
1067         :
1068 elif test $count = ax; then
1069         echo "Using \`$srcdir/config/$host_xm_file' as host machine macro file."
1070 else
1071         echo "Using the following host machine macro files:"
1072         for f in $host_xm_file; do
1073                 echo "  $srcdir/config/$f"
1074         done
1075 fi
1076 echo "Using ${out_host_hook_obj} for host machine hooks."
1077
1078 if test "$host_xm_file" != "$build_xm_file"; then
1079         count=a
1080         for f in $build_xm_file; do
1081                 count=${count}x
1082         done
1083         if test $count = a; then
1084                 :
1085         elif test $count = ax; then
1086                 echo "Using \`$srcdir/config/$build_xm_file' as build machine macro file."
1087         else
1088                 echo "Using the following build machine macro files:"
1089                 for f in $build_xm_file; do
1090                         echo "  $srcdir/config/$f"
1091                 done
1092         fi
1093 fi
1094
1095 if test x$thread_file = x; then
1096         if test x$target_thread_file != x; then
1097                 thread_file=$target_thread_file
1098         else
1099                 thread_file='single'
1100         fi
1101 fi
1102
1103 if test x$enable___cxa_atexit = xyes || \
1104    test x$enable___cxa_atexit = x -a x$default_use_cxa_atexit = xyes; then
1105   AC_DEFINE(DEFAULT_USE_CXA_ATEXIT, 1,
1106   [Define if you want to use __cxa_atexit, rather than atexit, to
1107    register C++ destructors for local statics and global objects.
1108    This is essential for fully standards-compliant handling of
1109    destructors, but requires __cxa_atexit in libc.])
1110 fi
1111
1112 # Look for a file containing extra machine modes.
1113 if test -n "$extra_modes" && test -f $srcdir/config/$extra_modes; then
1114   extra_modes_file='$(srcdir)'/config/${extra_modes}
1115   AC_SUBST(extra_modes_file)
1116   AC_DEFINE_UNQUOTED(EXTRA_MODES_FILE, "$extra_modes",
1117   [Define to the name of a file containing a list of extra machine modes
1118    for this architecture.])
1119   AC_DEFINE(EXTRA_CC_MODES, 1,
1120   [Define if the target architecture needs extra machine modes to represent
1121    the results of comparisons.])
1122 fi
1123
1124 # auto-host.h is the file containing items generated by autoconf and is
1125 # the first file included by config.h.
1126 # If host=build, it is correct to have bconfig include auto-host.h
1127 # as well.  If host!=build, we are in error and need to do more
1128 # work to find out the build config parameters.
1129 if test x$host = x$build
1130 then
1131         build_auto=auto-host.h
1132         FORBUILD=..
1133 else
1134         # We create a subdir, then run autoconf in the subdir.
1135         # To prevent recursion we set host and build for the new
1136         # invocation of configure to the build for this invocation
1137         # of configure.
1138         tempdir=build.$$
1139         rm -rf $tempdir
1140         mkdir $tempdir
1141         cd $tempdir
1142         case ${srcdir} in
1143         /* | [A-Za-z]:[\\/]* ) realsrcdir=${srcdir};;
1144         *) realsrcdir=../${srcdir};;
1145         esac
1146         saved_CFLAGS="${CFLAGS}"
1147         CC="${CC_FOR_BUILD}" CFLAGS="${CFLAGS_FOR_BUILD}" \
1148         ${realsrcdir}/configure \
1149                 --target=$target_alias --host=$build_alias --build=$build_alias
1150         CFLAGS="${saved_CFLAGS}"
1151
1152         # We just finished tests for the build machine, so rename
1153         # the file auto-build.h in the gcc directory.
1154         mv auto-host.h ../auto-build.h
1155         cd ..
1156         rm -rf $tempdir
1157         build_auto=auto-build.h
1158         FORBUILD=../${build_subdir}
1159 fi
1160 AC_SUBST(FORBUILD)
1161
1162 tm_file="${tm_file} defaults.h"
1163 tm_p_file="${tm_p_file} tm-preds.h"
1164 host_xm_file="auto-host.h ansidecl.h ${host_xm_file}"
1165 build_xm_file="${build_auto} ansidecl.h ${build_xm_file}"
1166 # We don't want ansidecl.h in target files, write code there in ISO/GNU C.
1167 # put this back in temporarily.
1168 xm_file="ansidecl.h ${xm_file}"
1169
1170 # --------
1171 # UNSORTED
1172 # --------
1173
1174 # Get the version trigger filename from the toplevel
1175 if test "${with_gcc_version_trigger+set}" = set; then
1176         gcc_version_trigger=$with_gcc_version_trigger
1177 else
1178         gcc_version_trigger=${srcdir}/version.c
1179 fi
1180 changequote(,)dnl
1181 gcc_version_full=`grep version_string ${gcc_version_trigger} | sed -e 's/.*"\([^"]*\)".*/\1/'`
1182 gcc_version=`echo ${gcc_version_full} | sed -e 's/\([^ ]*\) .*/\1/'`
1183
1184 # Compile in configure arguments.
1185 if test -f configargs.h ; then
1186         # Being re-configured.
1187         gcc_config_arguments=`grep configuration_arguments configargs.h | sed -e 's/.*"\([^"]*\)".*/\1/'`
1188         gcc_config_arguments="$gcc_config_arguments : (reconfigured) $TOPLEVEL_CONFIGURE_ARGUMENTS"
1189 else
1190         gcc_config_arguments="$TOPLEVEL_CONFIGURE_ARGUMENTS"
1191 fi
1192 cat > configargs.h <<EOF
1193 /* Generated automatically. */
1194 static const char configuration_arguments[] = "$gcc_config_arguments";
1195 static const char thread_model[] = "$thread_file";
1196
1197 static const struct {
1198   const char *name, *value;
1199 } configure_default_options[] = $configure_default_options;
1200 EOF
1201 changequote([,])dnl
1202
1203 # Internationalization
1204 PACKAGE=gcc
1205 VERSION="$gcc_version"
1206 AC_SUBST(PACKAGE)
1207 AC_SUBST(VERSION)
1208
1209 # Enable NLS support by default
1210 AC_ARG_ENABLE(nls,
1211   [  --enable-nls            use Native Language Support (default)],
1212   , enable_nls=yes)
1213
1214 # if cross compiling, disable NLS support.
1215 # It's not worth the trouble, at least for now.
1216
1217 if test "${build}" != "${host}" && test "x$enable_nls" = "xyes"; then
1218   AC_MSG_WARN(Disabling NLS support for canadian cross compiler.)
1219   enable_nls=no
1220 fi
1221
1222 AM_GNU_GETTEXT
1223
1224 # Windows32 Registry support for specifying GCC installation paths.
1225 AC_ARG_ENABLE(win32-registry,
1226 [  --disable-win32-registry
1227                           disable lookup of installation paths in the
1228                           Registry on Windows hosts
1229   --enable-win32-registry enable registry lookup (default)
1230   --enable-win32-registry=KEY
1231                           use KEY instead of GCC version as the last portion
1232                           of the registry key],,)
1233 case $host_os in
1234         win32 | pe | cygwin* | mingw32* | uwin*)
1235 AC_MSG_CHECKING(whether windows registry support is requested)
1236 if test "x$enable_win32_registry" != xno; then
1237   AC_DEFINE(ENABLE_WIN32_REGISTRY, 1,
1238 [Define to 1 if installation paths should be looked up in Windows32
1239    Registry. Ignored on non windows32 hosts.])
1240   AC_MSG_RESULT(yes)
1241   AC_SEARCH_LIBS(RegOpenKeyExA, advapi32)
1242 else
1243   AC_MSG_RESULT(no)
1244 fi
1245
1246 # Check if user specified a different registry key.
1247 case "x${enable_win32_registry}" in
1248 x | xyes)
1249   # default.
1250   gcc_cv_win32_registry_key="$VERSION"
1251   ;;
1252 xno)
1253   # no registry lookup.
1254   gcc_cv_win32_registry_key=''
1255   ;;
1256 *)
1257   # user-specified key.
1258   gcc_cv_win32_registry_key="$enable_win32_registry"
1259   ;;
1260 esac
1261
1262 if test "x$enable_win32_registry" != xno; then
1263   AC_MSG_CHECKING(registry key on windows hosts)
1264   AC_DEFINE_UNQUOTED(WIN32_REGISTRY_KEY, "$gcc_cv_win32_registry_key",
1265         [Define to be the last portion of registry key on windows hosts.])
1266   AC_MSG_RESULT($gcc_cv_win32_registry_key)
1267 fi
1268 ;;
1269 esac
1270
1271 # Get an absolute path to the GCC top-level source directory
1272 holddir=`${PWDCMD-pwd}`
1273 cd $srcdir
1274 topdir=`${PWDCMD-pwd}`
1275 cd $holddir
1276
1277 # Conditionalize the makefile for this host machine.
1278 # Make-host contains the concatenation of all host makefile fragments
1279 # [there can be more than one].  This file is built by configure.frag.
1280 host_overrides=Make-host
1281 dep_host_xmake_file=
1282 for f in .. ${host_xmake_file}
1283 do
1284         if test -f ${srcdir}/config/$f
1285         then
1286                 dep_host_xmake_file="${dep_host_xmake_file} ${srcdir}/config/$f"
1287         fi
1288 done
1289
1290 # Conditionalize the makefile for this target machine.
1291 # Make-target contains the concatenation of all host makefile fragments
1292 # [there can be more than one].  This file is built by configure.frag.
1293 target_overrides=Make-target
1294 dep_tmake_file=
1295 for f in .. ${tmake_file}
1296 do
1297         if test -f ${srcdir}/config/$f
1298         then
1299                 dep_tmake_file="${dep_tmake_file} ${srcdir}/config/$f"
1300         fi
1301 done
1302
1303 symbolic_link='ln -s'
1304
1305 # If the host doesn't support symlinks, modify CC in
1306 # FLAGS_TO_PASS so CC="stage1/xgcc -Bstage1/" works.
1307 # Otherwise, we can use "CC=$(CC)".
1308 rm -f symtest.tem
1309 if $symbolic_link $srcdir/gcc.c symtest.tem 2>/dev/null
1310 then
1311         cc_set_by_configure="\$(CC)"
1312         quoted_cc_set_by_configure="\$(CC)"
1313         stage_prefix_set_by_configure="\$(STAGE_PREFIX)"
1314         quoted_stage_prefix_set_by_configure="\$(STAGE_PREFIX)"
1315 else
1316         rm -f symtest.tem
1317         if cp -p $srcdir/gcc.c symtest.tem 2>/dev/null
1318         then
1319                 symbolic_link="cp -p"
1320         else
1321                 symbolic_link="cp"
1322         fi
1323         cc_set_by_configure="\`case '\$(CC)' in stage*) echo '\$(CC)' | sed -e 's|stage|../stage|g';; *) echo '\$(CC)';; esac\`"
1324         quoted_cc_set_by_configure="\\\`case '\\\$(CC)' in stage*) echo '\\\$(CC)' | sed -e 's|stage|../stage|g';; *) echo '\\\$(CC)';; esac\\\`"
1325         stage_prefix_set_by_configure="\`case '\$(STAGE_PREFIX)' in stage*) echo '\$(STAGE_PREFIX)' | sed -e 's|stage|../stage|g';; *) echo '\$(STAGE_PREFIX)';; esac\`"
1326         quoted_stage_prefix_set_by_configure="\\\`case '\\\$(STAGE_PREFIX)' in stage*) echo '\\\$(STAGE_PREFIX)' | sed -e 's|stage|../stage|g';; *) echo '\\\$(STAGE_PREFIX)';; esac\\\`"
1327 fi
1328 rm -f symtest.tem
1329
1330 out_object_file=`basename $out_file .c`.o
1331
1332 tm_file_list=
1333 for f in $tm_file; do
1334   case $f in
1335     ansidecl.h )
1336        tm_file_list="${tm_file_list} \$(srcdir)/../include/ansidecl.h" ;;
1337     defaults.h )
1338        tm_file_list="${tm_file_list} \$(srcdir)/$f" ;;
1339     *) tm_file_list="${tm_file_list} \$(srcdir)/config/$f" ;;
1340   esac
1341 done
1342
1343 tm_p_file_list=
1344 for f in $tm_p_file; do
1345   case $f in
1346     tm-preds.h )
1347        tm_p_file_list="${tm_p_file_list} $f" ;;
1348     *) tm_p_file_list="${tm_p_file_list} \$(srcdir)/config/$f" ;;
1349   esac
1350 done
1351
1352 host_xm_file_list=
1353 for f in $host_xm_file; do
1354   case $f in
1355     ansidecl.h )
1356        host_xm_file_list="${host_xm_file_list} \$(srcdir)/../include/ansidecl.h" ;;
1357     auto-host.h )
1358        host_xm_file_list="${host_xm_file_list} $f" ;;
1359     defaults.h )
1360        host_xm_file_list="${host_xm_file_list} \$(srcdir)/$f" ;;
1361     *) host_xm_file_list="${host_xm_file_list} \$(srcdir)/config/$f" ;;
1362   esac
1363 done
1364
1365 build_xm_file_list=
1366 for f in $build_xm_file; do
1367   case $f in
1368     ansidecl.h )
1369        build_xm_file_list="${build_xm_file_list} \$(srcdir)/../include/ansidecl.h" ;;
1370     auto-build.h | auto-host.h )
1371        build_xm_file_list="${build_xm_file_list} $f" ;;
1372     defaults.h )
1373        host_xm_file_list="${host_xm_file_list} \$(srcdir)/$f" ;;
1374     *) build_xm_file_list="${build_xm_file_list} \$(srcdir)/config/$f" ;;
1375   esac
1376 done
1377
1378 # Define macro CROSS_COMPILE in compilation if this is a cross-compiler.
1379 # Also use all.cross instead of all.internal and adjust SYSTEM_HEADER_DIR.
1380 CROSS=                                          AC_SUBST(CROSS)
1381 ALL=all.internal                                AC_SUBST(ALL)
1382 SYSTEM_HEADER_DIR='$(NATIVE_SYSTEM_HEADER_DIR)' AC_SUBST(SYSTEM_HEADER_DIR)
1383 if test x$host != x$target
1384 then
1385         CROSS="-DCROSS_COMPILE"
1386         ALL=all.cross
1387         SYSTEM_HEADER_DIR='$(CROSS_SYSTEM_HEADER_DIR)'
1388         case "$host","$target" in
1389             i?86-*-*,x86_64-*-* \
1390             | powerpc*-*-*,powerpc64*-*-*)
1391                 CROSS="$CROSS -DNATIVE_CROSS" ;;
1392         esac
1393 elif test "x$TARGET_SYSTEM_ROOT" != x; then
1394         # This is just $(TARGET_SYSTEM_ROOT)$(NATIVE_SYSTEM_HEADER_DIR)
1395         SYSTEM_HEADER_DIR='$(CROSS_SYSTEM_HEADER_DIR)'
1396 fi
1397
1398 # If this is a cross-compiler that does not
1399 # have its own set of headers then define
1400 # inhibit_libc
1401
1402 # If this is using newlib, without having the headers available now,
1403 # then define inhibit_libc in LIBGCC2_CFLAGS.
1404 # This prevents libgcc2 from containing any code which requires libc
1405 # support.
1406 inhibit_libc=
1407 if { { test x$host != x$target && test "x$with_sysroot" = x ; } ||
1408        test x$with_newlib = xyes ; } &&
1409      test "x$with_headers" = x ; then
1410        inhibit_libc=-Dinhibit_libc
1411 fi
1412 AC_SUBST(inhibit_libc)
1413
1414 # When building gcc with a cross-compiler, we need to adjust things so
1415 # that the generator programs are still built with the native compiler.
1416 # Also, we cannot run fixincludes or fix-header.
1417
1418 # These are the normal (build=host) settings:
1419 BUILD_PREFIX=                   AC_SUBST(BUILD_PREFIX)
1420 BUILD_PREFIX_1=ignore-          AC_SUBST(BUILD_PREFIX_1)
1421 BUILD_CC='$(CC)'                AC_SUBST(BUILD_CC)
1422 BUILD_CFLAGS='$(ALL_CFLAGS)'    AC_SUBST(BUILD_CFLAGS)
1423
1424 STMP_FIXINC=stmp-fixinc         AC_SUBST(STMP_FIXINC)
1425 STMP_FIXPROTO=stmp-fixproto     AC_SUBST(STMP_FIXPROTO)
1426
1427 # And these apply if build != host.
1428 if test x$build != x$host
1429 then
1430     BUILD_PREFIX=build-
1431     BUILD_PREFIX_1=build-
1432     BUILD_CC='$(CC_FOR_BUILD)'
1433     BUILD_CFLAGS='$(INTERNAL_CFLAGS) $(T_CFLAGS) $(CFLAGS_FOR_BUILD) $(XCFLAGS)'
1434
1435     if test "x$TARGET_SYSTEM_ROOT" = x; then
1436         STMP_FIXINC=
1437         STMP_FIXPROTO=
1438     fi
1439 fi
1440
1441 # Expand extra_headers to include complete path.
1442 # This substitutes for lots of t-* files.
1443 extra_headers_list=
1444 if test "x$extra_headers" = x
1445 then true
1446 else
1447         # Prepend ${srcdir}/config/${cpu_type}/ to every entry in extra_headers.
1448         for file in $extra_headers;
1449         do
1450                 extra_headers_list="${extra_headers_list} \$(srcdir)/config/${cpu_type}/${file}"
1451         done
1452 fi
1453
1454 # Add a definition of USE_COLLECT2 if system wants one.
1455 case $use_collect2 in
1456   no) use_collect2= ;;
1457   "") ;;
1458   *)
1459     host_xm_defines="${host_xm_defines} USE_COLLECT2"
1460     xm_defines="${xm_defines} USE_COLLECT2"
1461     ;;
1462 esac
1463
1464 # Identify the assembler which will work hand-in-glove with the newly
1465 # built GCC, so that we can examine its features.  This is the assembler
1466 # which will be driven by the driver program.
1467 #
1468 # If build != host, and we aren't building gas in-tree, we identify a
1469 # build->target assembler and hope that it will have the same features
1470 # as the host->target assembler we'll be using.
1471 AC_MSG_CHECKING(what assembler to use)
1472 in_tree_gas=no
1473 gcc_cv_as=
1474 gcc_cv_gas_major_version=
1475 gcc_cv_gas_minor_version=
1476 gcc_cv_as_gas_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/gas
1477 if test -x "$DEFAULT_ASSEMBLER"; then
1478         gcc_cv_as="$DEFAULT_ASSEMBLER"
1479 elif test -x "$AS"; then
1480         gcc_cv_as="$AS"
1481 elif test -x as$host_exeext; then
1482         # Build using assembler in the current directory.
1483         gcc_cv_as=./as$host_exeext
1484 elif test -f $gcc_cv_as_gas_srcdir/configure.in \
1485      && test -f ../gas/Makefile; then
1486   # Single tree build which includes gas.
1487   in_tree_gas=yes
1488   _gcc_COMPUTE_GAS_VERSION
1489   rm -f as$host_exeext
1490   $symbolic_link ../gas/as-new$host_exeext as$host_exeext 2>/dev/null
1491 fi
1492
1493 if test "x$gcc_cv_as" = x; then
1494         # Search the same directories that the installed compiler will
1495         # search.  Else we may find the wrong assembler and lose.  If we
1496         # do not find a suitable assembler binary, then try the user's
1497         # path.
1498         #
1499         # Also note we have to check MD_EXEC_PREFIX before checking the
1500         # user's path.  Unfortunately, there is no good way to get at the
1501         # value of MD_EXEC_PREFIX here.  So we do a brute force search
1502         # through all the known MD_EXEC_PREFIX values.  Ugh.  This needs
1503         # to be fixed as part of the make/configure rewrite too.
1504
1505         if test "x$exec_prefix" = xNONE; then
1506                 if test "x$prefix" = xNONE; then
1507                         test_prefix=/usr/local
1508                 else
1509                         test_prefix=$prefix
1510                 fi
1511         else
1512                 test_prefix=$exec_prefix
1513         fi
1514
1515         # If the loop below does not find an assembler, then use whatever
1516         # one we can find in the users's path.
1517         # user's path.
1518         if test "x$program_prefix" != xNONE; then
1519                 gcc_cv_as=${program_prefix}as$host_exeext
1520         else
1521                 gcc_cv_as=`echo as | sed ${program_transform_name}`$host_exeext
1522         fi
1523
1524         test_dirs="$test_prefix/lib/gcc-lib/$target_alias/$gcc_version \
1525                    $test_prefix/lib/gcc-lib/$target_alias \
1526                    /usr/lib/gcc/$target_alias/$gcc_version \
1527                    /usr/lib/gcc/$target_alias \
1528                    $test_prefix/$target_alias/bin/$target_alias/$gcc_version \
1529                    $test_prefix/$target_alias/bin"
1530
1531         if test x$host = x$target; then
1532             test_dirs="$test_dirs \
1533                    /usr/libexec \
1534                    /usr/ccs/gcc \
1535                    /usr/ccs/bin \
1536                    /udk/usr/ccs/bin \
1537                    /bsd43/usr/lib/cmplrs/cc \
1538                    /usr/cross64/usr/bin \
1539                    /usr/lib/cmplrs/cc \
1540                    /sysv/usr/lib/cmplrs/cc \
1541                    /svr4/usr/lib/cmplrs/cc \
1542                    /usr/bin"
1543         fi
1544
1545         for dir in $test_dirs; do
1546                 if test -x $dir/as$host_exeext; then
1547                         gcc_cv_as=$dir/as$host_exeext
1548                         break;
1549                 fi
1550         done
1551 fi
1552 case $in_tree_gas in
1553   yes)
1554     AC_MSG_RESULT("newly built gas")
1555     ;;
1556   no)
1557     AC_MSG_RESULT($gcc_cv_as)
1558     ;;
1559 esac
1560
1561 # Identify the linker which will work hand-in-glove with the newly
1562 # built GCC, so that we can examine its features.  This is the linker
1563 # which will be driven by the driver program.
1564 #
1565 # If build != host, and we aren't building gas in-tree, we identify a
1566 # build->target linker and hope that it will have the same features
1567 # as the host->target linker we'll be using.
1568 AC_MSG_CHECKING(what linker to use)
1569 in_tree_ld=no
1570 gcc_cv_ld=
1571 gcc_cv_gld_major_version=
1572 gcc_cv_gld_minor_version=
1573 gcc_cv_ld_gld_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/ld
1574 gcc_cv_ld_bfd_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/bfd
1575 if test -x "$DEFAULT_LINKER"; then
1576         gcc_cv_ld="$DEFAULT_LINKER"
1577 elif test -x "$LD"; then
1578         gcc_cv_ld="$LD"
1579 elif test -x collect-ld$host_exeext; then
1580         # Build using linker in the current directory.
1581         gcc_cv_ld=./collect-ld$host_exeext
1582 elif test -f $gcc_cv_ld_gld_srcdir/configure.in \
1583      && test -f ../ld/Makefile; then
1584         # Single tree build which includes ld.
1585         in_tree_ld=yes
1586         for f in $gcc_cv_ld_bfd_srcdir/configure $gcc_cv_ld_gld_srcdir/configure $gcc_cv_ld_gld_srcdir/configure.in $gcc_cv_ld_gld_srcdir/Makefile.in
1587         do
1588 changequote(,)dnl
1589                 gcc_cv_gld_version=`grep '^VERSION=[0-9]*\.[0-9]*' $f`
1590 changequote([,])dnl
1591                 if test x$gcc_cv_gld_version != x; then
1592                         break
1593                 fi
1594         done
1595 changequote(,)dnl
1596         gcc_cv_gld_major_version=`expr "$gcc_cv_gld_version" : "VERSION=\([0-9]*\)"`
1597         gcc_cv_gld_minor_version=`expr "$gcc_cv_gld_version" : "VERSION=[0-9]*\.\([0-9]*\)"`
1598 changequote([,])dnl
1599         rm -f collect-ld$host_exeext
1600         $symbolic_link ../ld/ld-new$host_exeext collect-ld$host_exeext \
1601                 2>/dev/null
1602 fi
1603
1604 if test "x$gcc_cv_ld" = x; then
1605         # Search the same directories that the installed compiler will
1606         # search.  Else we may find the wrong linker and lose.  If we
1607         # do not find a suitable linker binary, then try the user's
1608         # path.
1609         #
1610         # Also note we have to check MD_EXEC_PREFIX before checking the
1611         # user's path.  Unfortunately, there is no good way to get at the
1612         # value of MD_EXEC_PREFIX here.  So we do a brute force search
1613         # through all the known MD_EXEC_PREFIX values.  Ugh.  This needs
1614         # to be fixed as part of the make/configure rewrite too.
1615
1616         if test "x$exec_prefix" = xNONE; then
1617                 if test "x$prefix" = xNONE; then
1618                         test_prefix=/usr/local
1619                 else
1620                         test_prefix=$prefix
1621                 fi
1622         else
1623                 test_prefix=$exec_prefix
1624         fi
1625
1626         # If the loop below does not find an linker, then use whatever
1627         # one we can find in the users's path.
1628         # user's path.
1629         if test "x$program_prefix" != xNONE; then
1630                 gcc_cv_ld=${program_prefix}ld$host_exeext
1631         else
1632                 gcc_cv_ld=`echo ld | sed ${program_transform_name}`$host_exeext
1633         fi
1634
1635         test_dirs="$test_prefix/lib/gcc-lib/$target_alias/$gcc_version \
1636                    $test_prefix/lib/gcc-lib/$target_alias \
1637                    /usr/lib/gcc/$target_alias/$gcc_version \
1638                    /usr/lib/gcc/$target_alias \
1639                    $test_prefix/$target_alias/bin/$target_alias/$gcc_version \
1640                    $test_prefix/$target_alias/bin"
1641
1642         if test x$host = x$target; then
1643             test_dirs="$test_dirs \
1644                    /usr/libexec \
1645                    /usr/ccs/gcc \
1646                    /usr/ccs/bin \
1647                    /udk/usr/ccs/bin \
1648                    /bsd43/usr/lib/cmplrs/cc \
1649                    /usr/cross64/usr/bin \
1650                    /usr/lib/cmplrs/cc \
1651                    /sysv/usr/lib/cmplrs/cc \
1652                    /svr4/usr/lib/cmplrs/cc \
1653                    /usr/bin"
1654         fi
1655
1656         for dir in $test_dirs; do
1657                 if test -x $dir/ld$host_exeext; then
1658                         gcc_cv_ld=$dir/ld$host_exeext
1659                         break;
1660                 fi
1661         done
1662 fi
1663 case $in_tree_ld in
1664   yes)
1665     AC_MSG_RESULT("newly built ld")
1666     ;;
1667   no)
1668     AC_MSG_RESULT($gcc_cv_ld)
1669     ;;
1670 esac
1671
1672 # Figure out what nm we will be using.
1673 gcc_cv_binutils_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/binutils
1674 AC_MSG_CHECKING(what nm to use)
1675 in_tree_nm=no
1676 if test -x nm$host_exeext; then
1677         gcc_cv_nm=./nm$host_exeext
1678 elif test -f $gcc_cv_binutils_srcdir/configure.in \
1679      && test -f ../binutils/Makefile; then
1680         # Single tree build which includes binutils.
1681         in_tree_nm=yes
1682         gcc_cv_nm=./nm$host_exeext
1683         rm -f nm$host_exeext
1684         $symbolic_link ../binutils/nm-new$host_exeext nm$host_exeext 2>/dev/null
1685 elif test "x$program_prefix" != xNONE; then
1686         gcc_cv_nm=${program_prefix}nm$host_exeext
1687 else
1688         gcc_cv_nm=`echo nm | sed ${program_transform_name}`$host_exeext
1689 fi
1690 case $in_tree_nm in
1691   yes) AC_MSG_RESULT("newly built nm") ;;
1692   no)  AC_MSG_RESULT($gcc_cv_nm) ;;
1693 esac
1694
1695 # Figure out what objdump we will be using.
1696 AC_MSG_CHECKING(what objdump to use)
1697 in_tree_objdump=no
1698 if test -x objdump$host_exeext; then
1699         gcc_cv_objdump=./objdump$host_exeext
1700 elif test -f $gcc_cv_binutils_srcdir/configure.in \
1701      && test -f ../binutils/Makefile; then
1702         # Single tree build which includes binutils.
1703         in_tree_objdump=yes
1704         gcc_cv_objdump=./objdump$host_exeext
1705         rm -f objdump$host_exeext
1706         $symbolic_link ../binutils/objdump$host_exeext \
1707                 objdump$host_exeext 2>/dev/null
1708 elif test "x$program_prefix" != xNONE; then
1709         gcc_cv_objdump=${program_prefix}objdump$host_exeext
1710 else
1711         gcc_cv_objdump=`echo objdump | \
1712                 sed ${program_transform_name}`$host_exeext
1713 fi
1714 case $in_tree_objdump in
1715   yes) AC_MSG_RESULT("newly built objdump") ;;
1716   no)  AC_MSG_RESULT($gcc_cv_objdump) ;;
1717 esac
1718
1719 # Figure out what assembler alignment features are present.
1720 AC_MSG_CHECKING(assembler alignment features)
1721 gcc_cv_as_alignment_features=none
1722 if test $in_tree_gas = yes; then
1723   # Gas version 2.6 and later support for .balign and .p2align.
1724   gcc_GAS_VERSION_GTE_IFELSE(2,6,0,[
1725     gcc_cv_as_alignment_features=".balign and .p2align"
1726     AC_DEFINE(HAVE_GAS_BALIGN_AND_P2ALIGN)
1727   ])
1728   # Gas version 2.8 and later support specifying the maximum
1729   # bytes to skip when using .p2align.
1730   gcc_GAS_VERSION_GTE_IFELSE(2,8,0,[
1731     gcc_cv_as_alignment_features=".p2align including maximum skip"
1732     AC_DEFINE(HAVE_GAS_MAX_SKIP_P2ALIGN)
1733   ])
1734 elif test x$gcc_cv_as != x; then
1735         # Check if we have .balign and .p2align
1736         echo ".balign  4" > conftest.s
1737         echo ".p2align  2" >> conftest.s
1738         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
1739                 gcc_cv_as_alignment_features=".balign and .p2align"
1740                 AC_DEFINE(HAVE_GAS_BALIGN_AND_P2ALIGN)
1741         fi
1742         rm -f conftest.s conftest.o
1743         # Check if specifying the maximum bytes to skip when
1744         # using .p2align is supported.
1745         echo ".p2align 4,,7" > conftest.s
1746         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
1747                 gcc_cv_as_alignment_features=".p2align including maximum skip"
1748                 AC_DEFINE(HAVE_GAS_MAX_SKIP_P2ALIGN)
1749         fi
1750         rm -f conftest.s conftest.o
1751 fi
1752 AC_MSG_RESULT($gcc_cv_as_alignment_features)
1753
1754 AC_MSG_CHECKING(assembler subsection support)
1755 gcc_cv_as_subsections=no
1756 if test $in_tree_gas = yes ; then
1757   gcc_GAS_VERSION_GTE_IFELSE(2,9,0,[
1758     if grep 'obj_format = elf' ../gas/Makefile > /dev/null; then
1759       gcc_cv_as_subsections="working .subsection -1"
1760     fi
1761   ])
1762 elif test x$gcc_cv_as != x; then
1763         # Check if we have .subsection
1764         echo ".subsection 1" > conftest.s
1765         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
1766                 gcc_cv_as_subsections=".subsection"
1767                 if test x$gcc_cv_nm != x; then
1768                         cat > conftest.s <<EOF
1769 conftest_label1: .word 0
1770 .subsection -1
1771 conftest_label2: .word 0
1772 .previous
1773 EOF
1774                         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
1775                                 $gcc_cv_nm conftest.o | grep conftest_label1 > conftest.nm1
1776                                 $gcc_cv_nm conftest.o | grep conftest_label2 | sed -e 's/label2/label1/' > conftest.nm2
1777                                 if cmp conftest.nm1 conftest.nm2 > /dev/null 2>&1; then
1778                                         :
1779                                 else
1780                                         gcc_cv_as_subsections="working .subsection -1"
1781                                 fi
1782                         fi
1783                 fi
1784         fi
1785         rm -f conftest.s conftest.o conftest.nm1 conftest.nm2
1786 fi
1787 if test x"$gcc_cv_as_subsections" = x"working .subsection -1"; then
1788         AC_DEFINE(HAVE_GAS_SUBSECTION_ORDERING, 1,
1789 [Define if your assembler supports .subsection and .subsection -1 starts
1790    emitting at the beginning of your section.])
1791 fi
1792 AC_MSG_RESULT($gcc_cv_as_subsections)
1793
1794 AC_MSG_CHECKING(assembler weak support)
1795 gcc_cv_as_weak=no
1796 if test $in_tree_gas = yes ; then
1797   gcc_GAS_VERSION_GTE_IFELSE(2,2,0,[
1798     gcc_cv_as_weak="yes"
1799   ])
1800 elif test x$gcc_cv_as != x; then
1801         # Check if we have .weak
1802         echo "  .weak foobar" > conftest.s
1803         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
1804                 gcc_cv_as_weak="yes"
1805         fi
1806         rm -f conftest.s conftest.o conftest.nm1 conftest.nm2
1807 fi
1808 if test x"$gcc_cv_as_weak" = xyes; then
1809         AC_DEFINE(HAVE_GAS_WEAK, 1, [Define if your assembler supports .weak.])
1810 fi
1811 AC_MSG_RESULT($gcc_cv_as_weak)
1812
1813 AC_MSG_CHECKING(assembler hidden support)
1814 gcc_cv_as_hidden=no
1815 if test $in_tree_gas = yes ; then
1816   gcc_GAS_VERSION_GTE_IFELSE(2,12,1,[
1817     if grep 'obj_format = elf' ../gas/Makefile > /dev/null; then
1818       gcc_cv_as_hidden="yes"
1819     fi
1820   ])
1821 elif test x$gcc_cv_as != x; then
1822         # Check if we have .hidden
1823         echo "  .hidden foobar" > conftest.s
1824         echo "foobar:" >> conftest.s
1825         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
1826                 gcc_cv_as_hidden="yes"
1827         fi
1828         rm -f conftest.s conftest.o conftest.nm1 conftest.nm2
1829
1830         # GNU LD versions before 2.12.1 have buggy support for STV_HIDDEN.
1831         # This is irritatingly difficult to feature test for.  Look for
1832         # the date string after the version number.
1833         ld_ver=`$gcc_cv_ld --version 2>/dev/null | head -1`
1834         if echo "$ld_ver" | grep GNU > /dev/null; then
1835 changequote(,)dnl
1836                ld_vers=`echo $ld_ver | sed -n 's,^.*[  ]\([0-9][0-9]*\.[0-9][0-9]*\(\|\.[0-9][0-9]*\(\|\.[0-9][0-9]*\)\)\)\([  ].*\|\)$,\1,p'`
1837                ld_date=`echo $ld_ver | sed -n 's,^.*\([2-9][0-9][0-9][0-9]\)[-]*\([01][0-9]\)[-]*\([0-3][0-9]\).*$,\1\2\3,p'`
1838                 if test 0"$ld_date" -lt 20020404; then
1839                         if test -n "$ld_date"; then
1840                                 # If there was date string, but was earlier than 2002-04-04, fail
1841                                 gcc_cv_as_hidden="no"
1842                         elif test -z "$ld_vers"; then
1843                                 # If there was no date string nor ld version number, something is wrong
1844                                 gcc_cv_as_hidden="no"
1845                         else
1846                                 ld_vers_major=`expr "$ld_vers" : '\([0-9]*\)'`
1847                                 ld_vers_minor=`expr "$ld_vers" : '[0-9]*\.\([0-9]*\)'`
1848                                 ld_vers_patch=`expr "$ld_vers" : '[0-9]*\.[0-9]*\.\([0-9]*\)'`
1849                                 test -z "$ld_vers_patch" && ld_vers_patch=0
1850                                 if test "$ld_vers_major" -lt 2; then
1851                                         gcc_cv_as_hidden="no"
1852                                 elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -lt 12; then
1853                                         gcc_cv_as_hidden="no"
1854                                 elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -eq 12 \
1855                                           -a "$ld_vers_patch" -eq 0; then
1856                                         gcc_cv_as_hidden="no"
1857                                 fi
1858                         fi
1859                 fi
1860 changequote([,])dnl
1861         fi
1862 fi
1863 case "$target" in
1864   mips-sgi-irix6*)
1865     if test x"$gnu_ld_flag" = x"no"; then
1866       # Even if using gas with .hidden support, the resulting object files
1867       # cannot be linked with the IRIX 6 O32 linker.  With the N32 and
1868       # N64 linkers, the problem is that the linker refuses to accept
1869       # -call_shared (passed by default to the linker) and -r (used to
1870       # link the object file generated without .hidden directives with
1871       # one that hides symbols), so we also lose.
1872       gcc_cv_as_hidden=no
1873     fi
1874     ;;
1875 esac
1876 if test x"$gcc_cv_as_hidden" = xyes; then
1877         AC_DEFINE(HAVE_GAS_HIDDEN, 1,
1878                 [Define if your assembler supports .hidden.])
1879 fi
1880 AC_MSG_RESULT($gcc_cv_as_hidden)
1881 libgcc_visibility=$gcc_cv_as_hidden
1882 AC_SUBST(libgcc_visibility)
1883
1884 AC_MSG_CHECKING(assembler leb128 support)
1885 gcc_cv_as_leb128=no
1886 if test $in_tree_gas = yes ; then
1887   gcc_GAS_VERSION_GTE_IFELSE(2,11,0,[
1888     if grep 'obj_format = elf' ../gas/Makefile > /dev/null; then
1889       gcc_cv_as_leb128="yes"
1890     fi
1891   ])
1892 elif test x$gcc_cv_as != x; then
1893         # Check if we have .[us]leb128, and support symbol arithmetic with it.
1894         cat > conftest.s <<EOF
1895         .data
1896         .uleb128 L2 - L1
1897 L1:
1898         .uleb128 1280
1899         .sleb128 -1010
1900 L2:
1901 EOF
1902         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
1903                 gcc_cv_as_leb128="yes"
1904
1905                 # GAS versions before 2.11 do not support uleb128,
1906                 # despite appearing to.
1907                 # ??? There exists an elf-specific test that will crash
1908                 # the assembler.  Perhaps it's better to figure out whether
1909                 # arbitrary sections are supported and try the test.
1910                 as_ver=`$gcc_cv_as --version 2>/dev/null | head -1`
1911                 if echo "$as_ver" | grep GNU > /dev/null; then
1912 changequote(,)dnl
1913                         as_ver=`echo $as_ver | sed -e 's/GNU assembler \([0-9.][0-9.]*\).*/\1/'`
1914                         as_major=`echo $as_ver | sed 's/\..*//'`
1915                         as_minor=`echo $as_ver | sed 's/[^.]*\.\([0-9]*\).*/\1/'`
1916 changequote([,])dnl
1917                         if test $as_major -eq 2 -a $as_minor -lt 11; then
1918                                 gcc_cv_as_leb128="no"
1919                         fi
1920                 fi
1921         fi
1922         rm -f conftest.s conftest.o conftest.nm1 conftest.nm2
1923 fi
1924 if test x"$gcc_cv_as_leb128" = xyes; then
1925         AC_DEFINE(HAVE_AS_LEB128, 1,
1926                 [Define if your assembler supports .uleb128.])
1927 fi
1928 AC_MSG_RESULT($gcc_cv_as_leb128)
1929
1930 AC_MSG_CHECKING(assembler eh_frame optimization)
1931 gcc_cv_as_eh_frame=no
1932 if test $in_tree_gas = yes ; then
1933   gcc_GAS_VERSION_GTE_IFELSE(2,12,0,[
1934     if grep 'obj_format = elf' ../gas/Makefile > /dev/null; then
1935       gcc_cv_as_eh_frame="yes"
1936     fi
1937   ])
1938 elif test x$gcc_cv_as != x; then
1939         # Check if this is GAS.
1940         as_ver=`$gcc_cv_as --version < /dev/null 2> /dev/null | head -1`
1941         rm -f a.out 2> /dev/null
1942         if echo "$as_ver" | grep GNU > /dev/null; then
1943                 # Versions up to and including 2.11.0 may mis-optimize
1944                 # .eh_frame data.  Try something.
1945                 cat > conftest.s <<EOF
1946         .text
1947 .LFB1:
1948         .4byte  0
1949 .L1:
1950         .4byte  0
1951 .LFE1:
1952         .section        .eh_frame,"aw",@progbits
1953 __FRAME_BEGIN__:
1954         .4byte  .LECIE1-.LSCIE1
1955 .LSCIE1:
1956         .4byte  0x0
1957         .byte   0x1
1958         .ascii "z\0"
1959         .byte   0x1
1960         .byte   0x78
1961         .byte   0x1a
1962         .byte   0x0
1963         .byte   0x4
1964         .4byte  1
1965         .p2align 1
1966 .LECIE1:
1967 .LSFDE1:
1968         .4byte  .LEFDE1-.LASFDE1
1969 .LASFDE1:
1970         .4byte  .LASFDE1-__FRAME_BEGIN__
1971         .4byte  .LFB1
1972         .4byte  .LFE1-.LFB1
1973         .byte   0x4
1974         .4byte  .LFE1-.LFB1
1975         .byte   0x4
1976         .4byte  .L1-.LFB1
1977 .LEFDE1:
1978 EOF
1979                 cat > conftest.lit <<EOF
1980  0000 10000000 00000000 017a0001 781a0004  .........z..x...
1981  0010 01000000 12000000 18000000 00000000  ................
1982  0020 08000000 04080000 0044               .........D
1983 EOF
1984                 cat > conftest.big <<EOF
1985  0000 00000010 00000000 017a0001 781a0004  .........z..x...
1986  0010 00000001 00000012 00000018 00000000  ................
1987  0020 00000008 04000000 0844               .........D
1988 EOF
1989                 # If the assembler didn't choke, and we can objdump,
1990                 # and we got the correct data, then succeed.
1991                 if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1 \
1992                    && $gcc_cv_objdump -s -j .eh_frame conftest.o 2>/dev/null \
1993                       | tail -3 > conftest.got \
1994                    && { cmp conftest.lit conftest.got > /dev/null 2>&1 \
1995                         || cmp conftest.big conftest.got > /dev/null 2>&1; }
1996                 then
1997                         gcc_cv_as_eh_frame="yes"
1998                 else
1999                         gcc_cv_as_eh_frame="bad"
2000                         if $gcc_cv_as -o conftest.o --traditional-format /dev/null; then
2001                                 AC_DEFINE(USE_AS_TRADITIONAL_FORMAT, 1,
2002         [Define if your assembler mis-optimizes .eh_frame data.])
2003                         fi
2004                 fi
2005         fi
2006         rm -f conftest.*
2007 fi
2008 AC_MSG_RESULT($gcc_cv_as_eh_frame)
2009
2010 AC_MSG_CHECKING(assembler section merging support)
2011 gcc_cv_as_shf_merge=no
2012 if test $in_tree_gas = yes ; then
2013   gcc_GAS_VERSION_GTE_IFELSE(2,12,0,[
2014     if grep 'obj_format = elf' ../gas/Makefile > /dev/null; then
2015       gcc_cv_as_shf_merge=yes
2016     fi
2017   ])
2018 elif test x$gcc_cv_as != x; then
2019         # Check if we support SHF_MERGE sections
2020         echo '.section .rodata.str, "aMS", @progbits, 1' > conftest.s
2021         if $gcc_cv_as --fatal-warnings -o conftest.o conftest.s > /dev/null 2>&1; then
2022                 gcc_cv_as_shf_merge=yes
2023         fi
2024         rm -f conftest.s conftest.o
2025 fi
2026 if test x"$gcc_cv_as_shf_merge" = xyes; then
2027         AC_DEFINE(HAVE_GAS_SHF_MERGE, 1,
2028 [Define if your assembler supports marking sections with SHF_MERGE flag.])
2029 fi
2030 AC_MSG_RESULT($gcc_cv_as_shf_merge)
2031
2032 AC_MSG_CHECKING(assembler thread-local storage support)
2033 gcc_cv_as_tls=no
2034 conftest_s=
2035 tls_first_major=
2036 tls_first_minor=
2037 tls_as_opt=
2038 case "$target" in
2039 changequote(,)dnl
2040   alpha*-*-*)
2041     conftest_s='
2042         .section ".tdata","awT",@progbits
2043 foo:    .long   25
2044         .text
2045         ldq     $27,__tls_get_addr($29)         !literal!1
2046         lda     $16,foo($29)                    !tlsgd!1
2047         jsr     $26,($27),__tls_get_addr        !lituse_tlsgd!1
2048         ldq     $27,__tls_get_addr($29)         !literal!2
2049         lda     $16,foo($29)                    !tlsldm!2
2050         jsr     $26,($27),__tls_get_addr        !lituse_tlsldm!2
2051         ldq     $1,foo($29)                     !gotdtprel
2052         ldah    $2,foo($29)                     !dtprelhi
2053         lda     $3,foo($2)                      !dtprello
2054         lda     $4,foo($29)                     !dtprel
2055         ldq     $1,foo($29)                     !gottprel
2056         ldah    $2,foo($29)                     !tprelhi
2057         lda     $3,foo($2)                      !tprello
2058         lda     $4,foo($29)                     !tprel'
2059         tls_first_major=2
2060         tls_first_minor=13
2061         ;;
2062   i[34567]86-*-*)
2063 changequote([,])dnl
2064     conftest_s='
2065         .section ".tdata","awT",@progbits
2066 foo:    .long   25
2067         .text
2068         movl    %gs:0, %eax
2069         leal    foo@TLSGD(,%ebx,1), %eax
2070         leal    foo@TLSLDM(%ebx), %eax
2071         leal    foo@DTPOFF(%eax), %edx
2072         movl    foo@GOTTPOFF(%ebx), %eax
2073         subl    foo@GOTTPOFF(%ebx), %eax
2074         addl    foo@GOTNTPOFF(%ebx), %eax
2075         movl    foo@INDNTPOFF, %eax
2076         movl    $foo@TPOFF, %eax
2077         subl    $foo@TPOFF, %eax
2078         leal    foo@NTPOFF(%ecx), %eax'
2079         tls_first_major=2
2080         tls_first_minor=14
2081         ;;
2082   x86_64-*-*)
2083     conftest_s='
2084         .section ".tdata","awT",@progbits
2085 foo:    .long   25
2086         .text
2087         movq    %fs:0, %rax
2088         leaq    foo@TLSGD(%rip), %rdi
2089         leaq    foo@TLSLD(%rip), %rdi
2090         leaq    foo@DTPOFF(%rax), %rdx
2091         movq    foo@GOTTPOFF(%rip), %rax
2092         movq    $foo@TPOFF, %rax'
2093         tls_first_major=2
2094         tls_first_minor=14
2095         ;;
2096   ia64-*-*)
2097     conftest_s='
2098         .section ".tdata","awT",@progbits
2099 foo:    data8   25
2100         .text
2101         addl    r16 = @ltoff(@dtpmod(foo#)), gp
2102         addl    r17 = @ltoff(@dtprel(foo#)), gp
2103         addl    r18 = @ltoff(@tprel(foo#)), gp
2104         addl    r19 = @dtprel(foo#), gp
2105         adds    r21 = @dtprel(foo#), r13
2106         movl    r23 = @dtprel(foo#)
2107         addl    r20 = @tprel(foo#), gp
2108         adds    r22 = @tprel(foo#), r13
2109         movl    r24 = @tprel(foo#)'
2110         tls_first_major=2
2111         tls_first_minor=13
2112         ;;
2113   powerpc-*-*)
2114     conftest_s='
2115         .section ".tdata","awT",@progbits
2116         .align 2
2117 ld0:    .space 4
2118 ld1:    .space 4
2119 x1:     .space 4
2120 x2:     .space 4
2121 x3:     .space 4
2122         .text
2123         addi 3,31,ld0@got@tlsgd
2124         bl __tls_get_addr
2125         addi 3,31,x1@got@tlsld
2126         bl __tls_get_addr
2127         addi 9,3,x1@dtprel
2128         addis 9,3,x2@dtprel@ha
2129         addi 9,9,x2@dtprel@l
2130         lwz 9,x3@got@tprel(31)
2131         add 9,9,x@tls
2132         addi 9,2,x1@tprel
2133         addis 9,2,x2@tprel@ha
2134         addi 9,9,x2@tprel@l'
2135         tls_first_major=2
2136         tls_first_minor=14
2137         tls_as_opt=-a32
2138         ;;
2139   powerpc64-*-*)
2140     conftest_s='
2141         .section ".tdata","awT",@progbits
2142         .align 3
2143 ld0:    .space 8
2144 ld1:    .space 8
2145 x1:     .space 8
2146 x2:     .space 8
2147 x3:     .space 8
2148         .text
2149         addi 3,2,ld0@got@tlsgd
2150         bl .__tls_get_addr
2151         nop
2152         addi 3,2,ld1@toc
2153         bl .__tls_get_addr
2154         nop
2155         addi 3,2,x1@got@tlsld
2156         bl .__tls_get_addr
2157         nop
2158         addi 9,3,x1@dtprel
2159         bl .__tls_get_addr
2160         nop
2161         addis 9,3,x2@dtprel@ha
2162         addi 9,9,x2@dtprel@l
2163         bl .__tls_get_addr
2164         nop
2165         ld 9,x3@got@dtprel(2)
2166         add 9,9,3
2167         bl .__tls_get_addr
2168         nop'
2169         tls_first_major=2
2170         tls_first_minor=14
2171         tls_as_opt=-a64
2172         ;;
2173   s390-*-*)
2174     conftest_s='
2175         .section ".tdata","awT",@progbits
2176 foo:    .long   25
2177         .text
2178         .long   foo@TLSGD
2179         .long   foo@TLSLDM
2180         .long   foo@DTPOFF
2181         .long   foo@NTPOFF
2182         .long   foo@GOTNTPOFF
2183         .long   foo@INDNTPOFF
2184         l       %r1,foo@GOTNTPOFF(%r12)
2185         l       %r1,0(%r1):tls_load:foo
2186         bas     %r14,0(%r1,%r13):tls_gdcall:foo
2187         bas     %r14,0(%r1,%r13):tls_ldcall:foo'
2188         tls_first_major=2
2189         tls_first_minor=14
2190         tls_as_opt=-m31
2191         ;;
2192   s390x-*-*)
2193     conftest_s='
2194         .section ".tdata","awT",@progbits
2195 foo:    .long   25
2196         .text
2197         .quad   foo@TLSGD
2198         .quad   foo@TLSLDM
2199         .quad   foo@DTPOFF
2200         .quad   foo@NTPOFF
2201         .quad   foo@GOTNTPOFF
2202         lg      %r1,foo@GOTNTPOFF(%r12)
2203         larl    %r1,foo@INDNTPOFF
2204         brasl   %r14,__tls_get_offset@PLT:tls_gdcall:foo
2205         brasl   %r14,__tls_get_offset@PLT:tls_ldcall:foo'
2206         tls_first_major=2
2207         tls_first_minor=14
2208         tls_as_opt="-m64 -Aesame"
2209         ;;
2210 esac
2211 if test -z "$tls_first_major"; then
2212   :
2213 elif test $in_tree_gas = yes ; then
2214   gcc_GAS_VERSION_GTE_IFELSE($tls_first_major,$tls_first_minor,0,[
2215     gcc_cv_as_tls=yes
2216   ])
2217 elif test x$gcc_cv_as != x; then
2218   echo "$conftest_s" > conftest.s
2219   if $gcc_cv_as $tls_as_opt --fatal-warnings -o conftest.o conftest.s > /dev/null 2>&1
2220   then
2221     gcc_cv_as_tls=yes
2222   fi
2223   rm -f conftest.s conftest.o
2224 fi
2225 if test "$gcc_cv_as_tls" = yes; then
2226   AC_DEFINE(HAVE_AS_TLS, 1,
2227             [Define if your assembler supports thread-local storage.])
2228 fi
2229 AC_MSG_RESULT($gcc_cv_as_tls)
2230
2231 case "$target" in
2232   # All TARGET_ABI_OSF targets.
2233   alpha*-*-osf* | alpha*-*-linux* | alpha*-*-*bsd*)
2234     AC_CACHE_CHECK([assembler supports explicit relocations],
2235         gcc_cv_as_explicit_relocs, [
2236         gcc_cv_as_explicit_relocs=unknown
2237         if test $in_tree_gas = yes ; then
2238            gcc_GAS_VERSION_GTE_IFELSE(2,12,0,[
2239               gcc_cv_as_explicit_relocs=yes
2240            ])
2241         elif test x$gcc_cv_as != x; then
2242             cat > conftest.s << 'EOF'
2243         .set nomacro
2244         .text
2245         extbl   $3, $2, $3      !lituse_bytoff!1
2246         ldq     $2, a($29)      !literal!1
2247         ldq     $4, b($29)      !literal!2
2248         ldq_u   $3, 0($2)       !lituse_base!1
2249         ldq     $27, f($29)     !literal!5
2250         jsr     $26, ($27), f   !lituse_jsr!5
2251         ldah    $29, 0($26)     !gpdisp!3
2252         lda     $0, c($29)      !gprel
2253         ldah    $1, d($29)      !gprelhigh
2254         lda     $1, d($1)       !gprellow
2255         lda     $29, 0($29)     !gpdisp!3
2256 EOF
2257             if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
2258                 gcc_cv_as_explicit_relocs=yes
2259             else
2260                 gcc_cv_as_explicit_relocs=no
2261             fi
2262             rm -f conftest.s conftest.o
2263         fi
2264     ])
2265     if test "x$gcc_cv_as_explicit_relocs" = xyes; then
2266         AC_DEFINE(HAVE_AS_EXPLICIT_RELOCS, 1,
2267                 [Define if your assembler supports explicit relocations.])
2268     fi
2269     ;;
2270   sparc*-*-*)
2271     AC_CACHE_CHECK([assembler .register pseudo-op support],
2272         gcc_cv_as_register_pseudo_op, [
2273         gcc_cv_as_register_pseudo_op=unknown
2274         if test x$gcc_cv_as != x; then
2275             # Check if we have .register
2276             echo ".register %g2, #scratch" > conftest.s
2277             if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
2278                 gcc_cv_as_register_pseudo_op=yes
2279             else
2280                 gcc_cv_as_register_pseudo_op=no
2281             fi
2282             rm -f conftest.s conftest.o
2283         fi
2284     ])
2285     if test "x$gcc_cv_as_register_pseudo_op" = xyes; then
2286         AC_DEFINE(HAVE_AS_REGISTER_PSEUDO_OP, 1,
2287                 [Define if your assembler supports .register.])
2288     fi
2289
2290     AC_CACHE_CHECK([assembler supports -relax],
2291         gcc_cv_as_relax_opt, [
2292         gcc_cv_as_relax_opt=unknown
2293         if test x$gcc_cv_as != x; then
2294             # Check if gas supports -relax
2295             echo ".text" > conftest.s
2296             if $gcc_cv_as -relax -o conftest.o conftest.s > /dev/null 2>&1; then
2297                 gcc_cv_as_relax_opt=yes
2298             else
2299                 gcc_cv_as_relax_opt=no
2300             fi
2301             rm -f conftest.s conftest.o
2302         fi
2303     ])
2304     if test "x$gcc_cv_as_relax_opt" = xyes; then
2305         AC_DEFINE(HAVE_AS_RELAX_OPTION, 1,
2306                 [Define if your assembler supports -relax option.])
2307     fi
2308
2309     AC_CACHE_CHECK([assembler and linker support unaligned pc related relocs],
2310         gcc_cv_as_sparc_ua_pcrel, [
2311         gcc_cv_as_sparc_ua_pcrel=unknown
2312         if test x$gcc_cv_as != x -a x$gcc_cv_ld != x; then
2313             gcc_cv_as_sparc_ua_pcrel=no
2314             echo ".text; foo: nop; .data; .align 4; .byte 0; .uaword %r_disp32(foo)" > conftest.s
2315             if $gcc_cv_as -K PIC -o conftest.o conftest.s > /dev/null 2>&1 \
2316                && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1; then
2317                 gcc_cv_as_sparc_ua_pcrel=yes
2318             fi
2319             rm -f conftest.s conftest.o conftest
2320         fi
2321     ])
2322     if test "x$gcc_cv_as_sparc_ua_pcrel" = xyes; then
2323         AC_DEFINE(HAVE_AS_SPARC_UA_PCREL, 1,
2324                 [Define if your assembler and linker support unaligned PC relative relocs.])
2325     fi
2326
2327     AC_CACHE_CHECK([assembler and linker support unaligned pc related relocs against hidden symbols],
2328         gcc_cv_as_sparc_ua_pcrel_hidden, [
2329         if test "x$gcc_cv_as_sparc_ua_pcrel" = xyes; then
2330             gcc_cv_as_sparc_ua_pcrel_hidden=unknown
2331             if test x$gcc_cv_objdump != x; then
2332                 gcc_cv_as_sparc_ua_pcrel_hidden=no
2333                 echo ".data; .align 4; .byte 0x31; .uaword %r_disp32(foo)" > conftest.s
2334                 echo ".byte 0x32, 0x33, 0x34; .global foo; .hidden foo" >> conftest.s
2335                 echo "foo: .skip 4" >> conftest.s
2336                 if $gcc_cv_as -K PIC -o conftest.o conftest.s > /dev/null 2>&1 \
2337                    && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1 \
2338                    && $gcc_cv_objdump -s -j .data conftest 2> /dev/null \
2339                       | grep ' 31000000 07323334' > /dev/null 2>&1; then
2340                     if $gcc_cv_objdump -R conftest 2> /dev/null \
2341                        | grep 'DISP32' > /dev/null 2>&1; then
2342                         :
2343                     else
2344                         gcc_cv_as_sparc_ua_pcrel_hidden=yes
2345                     fi
2346                 fi
2347             fi
2348             rm -f conftest.s conftest.o conftest
2349         else
2350             gcc_cv_as_sparc_ua_pcrel_hidden="$gcc_cv_as_sparc_ua_pcrel"
2351         fi
2352     ])
2353     if test "x$gcc_cv_as_sparc_ua_pcrel_hidden" = xyes; then
2354         AC_DEFINE(HAVE_AS_SPARC_UA_PCREL_HIDDEN, 1,
2355                 [Define if your assembler and linker support unaligned PC relative relocs against hidden symbols.])
2356     fi
2357
2358     AC_CACHE_CHECK([for assembler offsetable %lo() support],
2359         gcc_cv_as_offsetable_lo10, [
2360         gcc_cv_as_offsetable_lo10=unknown
2361         if test "x$gcc_cv_as" != x; then
2362             # Check if assembler has offsetable %lo()
2363             echo "or %g1, %lo(ab) + 12, %g1" > conftest.s
2364             echo "or %g1, %lo(ab + 12), %g1" > conftest1.s
2365             if $gcc_cv_as -xarch=v9 -o conftest.o conftest.s \
2366                     > /dev/null 2>&1 &&
2367                $gcc_cv_as -xarch=v9 -o conftest1.o conftest1.s \
2368                     > /dev/null 2>&1; then
2369                 if cmp conftest.o conftest1.o > /dev/null 2>&1; then
2370                     gcc_cv_as_offsetable_lo10=no
2371                 else
2372                     gcc_cv_as_offsetable_lo10=yes
2373                 fi
2374             else
2375                 gcc_cv_as_offsetable_lo10=no
2376             fi
2377             rm -f conftest.s conftest.o conftest1.s conftest1.o
2378         fi
2379     ])
2380     if test "x$gcc_cv_as_offsetable_lo10" = xyes; then
2381         AC_DEFINE(HAVE_AS_OFFSETABLE_LO10, 1,
2382             [Define if your assembler supports offsetable %lo().])
2383     fi
2384
2385     ;;
2386
2387 changequote(,)dnl
2388   i[34567]86-*-* | x86_64-*-*)
2389 changequote([,])dnl
2390     AC_MSG_CHECKING(assembler instructions)
2391     gcc_cv_as_instructions=
2392     if test $in_tree_gas = yes ; then
2393       gcc_GAS_VERSION_GTE_IFELSE(2,9,0,[
2394         gcc_cv_as_instructions="filds fists"
2395       ])
2396     elif test x$gcc_cv_as != x; then
2397         set "filds fists" "filds mem; fists mem"
2398         while test $# -gt 0
2399         do
2400                 echo "$2" > conftest.s
2401                 if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
2402                         gcc_cv_as_instructions=${gcc_cv_as_instructions}$1" "
2403                 fi
2404                 shift 2
2405         done
2406         rm -f conftest.s conftest.o
2407     fi
2408     if test x"$gcc_cv_as_instructions" != x; then
2409         AC_DEFINE_UNQUOTED(HAVE_GAS_`echo "$gcc_cv_as_instructions" | sed -e 's/ $//' | tr '[a-z ]' '[A-Z_]'`)
2410     fi
2411     AC_MSG_RESULT($gcc_cv_as_instructions)
2412
2413     AC_MSG_CHECKING(assembler GOTOFF in data directives)
2414     gcc_cv_as_gotoff_in_data=no
2415     if test $in_tree_gas = yes ; then
2416       gcc_GAS_VERSION_GTE_IFELSE(2,11,0,[
2417         gcc_cv_as_gotoff_in_data=yes
2418       ])
2419     elif test x$gcc_cv_as != x; then
2420         cat > conftest.s <<EOF
2421         .text
2422 .L0:
2423         nop
2424         .data
2425         .long .L0@GOTOFF
2426 EOF
2427         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
2428           gcc_cv_as_gotoff_in_data=yes
2429         fi
2430     fi
2431     AC_DEFINE_UNQUOTED(HAVE_AS_GOTOFF_IN_DATA,
2432       [`if test $gcc_cv_as_gotoff_in_data = yes; then echo 1; else echo 0; fi`],
2433       [Define true if the assembler supports '.long foo@GOTOFF'.])
2434     AC_MSG_RESULT($gcc_cv_as_gotoff_in_data)
2435     ;;
2436
2437   ia64*-*-*)
2438     AC_CACHE_CHECK([assembler supports ltoffx and ldxmov],
2439         gcc_cv_as_ltoffx_ldxmov_relocs, [
2440         gcc_cv_as_ltoffx_ldxmov_relocs=unknown
2441         if test $in_tree_gas = yes ; then
2442           gcc_GAS_VERSION_GTE_IFELSE(2,14,0,[
2443             gcc_cv_as_ltoffx_ldxmov_relocs=yes
2444           ])
2445         elif test x$gcc_cv_as != x; then
2446             cat > conftest.s << 'EOF'
2447 changequote(,)dnl
2448         .text
2449         addl r15 = @ltoffx(x#), gp
2450         ;;
2451         ld8.mov r16 = [r15], x#
2452 EOF
2453 changequote([,])dnl
2454             if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
2455                 gcc_cv_as_ltoffx_ldxmov_relocs=yes
2456             else
2457                 gcc_cv_as_ltoffx_ldxmov_relocs=no
2458             fi
2459             rm -f conftest.s conftest.o
2460         fi
2461     ])
2462     if test "x$gcc_cv_as_ltoffx_ldxmov_relocs" = xyes; then
2463         AC_DEFINE(HAVE_AS_LTOFFX_LDXMOV_RELOCS, 1,
2464           [Define if your assembler supports ltoffx and ldxmov relocations.])
2465     fi
2466     ;;
2467 esac
2468
2469 AC_MSG_CHECKING(assembler dwarf2 debug_line support)
2470 gcc_cv_as_dwarf2_debug_line=no
2471 # ??? Not all targets support dwarf2 debug_line, even within a version
2472 # of gas.  Moreover, we need to emit a valid instruction to trigger any
2473 # info to the output file.  So, as supported targets are added to gas 2.11,
2474 # add some instruction here to (also) show we expect this might work.
2475 # ??? Once 2.11 is released, probably need to add first known working
2476 # version to the per-target configury.
2477 case "$target" in
2478   i?86*-*-* | mips*-*-* | alpha*-*-* | powerpc*-*-* | sparc*-*-* | m68*-*-* \
2479   | x86_64*-*-* | hppa*-*-* | arm*-*-* | strongarm*-*-* | xscale*-*-* \
2480   | xstormy16*-*-* | cris-*-*)
2481     insn="nop"
2482     ;;
2483   ia64*-*-*)
2484     insn="nop 0"
2485     ;;
2486   mmix-*-*)
2487     insn="swym 0"
2488     ;;
2489   esac
2490 if test $in_tree_gas = yes ; then
2491   gcc_GAS_VERSION_GTE_IFELSE(2,11,0,[
2492     if grep 'obj_format = elf' ../gas/Makefile > /dev/null \
2493         && test x"$insn" != x ; then
2494       gcc_cv_as_dwarf2_debug_line="yes"
2495     fi
2496   ])
2497 elif test x$gcc_cv_as != x -a x"$insn" != x ; then
2498         echo '  .file 1 "conftest.s"' > conftest.s
2499         echo '  .loc 1 3 0' >> conftest.s
2500         echo "  $insn" >> conftest.s
2501         # ??? This fails with non-gnu grep.
2502         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1 \
2503            && grep debug_line conftest.o > /dev/null 2>&1 ; then
2504                 # The .debug_line file table must be in the exact order that
2505                 # we specified the files, since these indices are also used
2506                 # by DW_AT_decl_file.  Approximate this test by testing if
2507                 # the assembler bitches if the same index is assigned twice.
2508                 echo '  .file 1 "foo.s"' > conftest.s
2509                 echo '  .file 1 "bar.s"' >> conftest.s
2510                 if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1
2511                 then
2512                   gcc_cv_as_dwarf2_debug_line="no"
2513                 else
2514                   gcc_cv_as_dwarf2_debug_line="yes"
2515                 fi
2516         fi
2517         rm -f conftest.s conftest.o conftest.nm1 conftest.nm2
2518 fi
2519 if test x"$gcc_cv_as_dwarf2_debug_line" = xyes; then
2520         AC_DEFINE(HAVE_AS_DWARF2_DEBUG_LINE, 1,
2521 [Define if your assembler supports dwarf2 .file/.loc directives,
2522    and preserves file table indices exactly as given.])
2523 fi
2524 AC_MSG_RESULT($gcc_cv_as_dwarf2_debug_line)
2525
2526 AC_MSG_CHECKING(assembler --gdwarf2 support)
2527 gcc_cv_as_gdwarf2_flag=no
2528 if test $in_tree_gas = yes ; then
2529   gcc_GAS_VERSION_GTE_IFELSE(2,11,0,[
2530     if grep 'obj_format = elf' ../gas/Makefile > /dev/null \
2531         && test x"$insn" != x ; then
2532       gcc_cv_as_gdwarf2_flag="yes"
2533     fi
2534   ])
2535 elif test x$gcc_cv_as != x -a x"$insn" != x ; then
2536         echo '' > conftest.s
2537         # ??? This fails with non-gnu grep.
2538         if $gcc_cv_as --gdwarf2 -o conftest.o conftest.s > /dev/null 2>&1
2539           then
2540           gcc_cv_as_gdwarf2_flag="yes"
2541         fi
2542         rm -f conftest.s conftest.o
2543 fi
2544 if test x"$gcc_cv_as_gdwarf2_flag" = xyes; then
2545         AC_DEFINE(HAVE_AS_GDWARF2_DEBUG_FLAG, 1,
2546 [Define if your assembler supports the --gdwarf2 option.])
2547 fi
2548 AC_MSG_RESULT($gcc_cv_as_gdwarf2_flag)
2549
2550 AC_MSG_CHECKING(assembler --gstabs support)
2551 gcc_cv_as_gstabs_flag=no
2552 if test $in_tree_gas = yes ; then
2553   gcc_GAS_VERSION_GTE_IFELSE(2,11,0,[
2554     if grep 'obj_format = elf' ../gas/Makefile > /dev/null \
2555         && test x"$insn" != x ; then
2556       gcc_cv_as_gstabs_flag="yes"
2557     fi
2558   ])
2559 elif test x$gcc_cv_as != x -a x"$insn" != x ; then
2560         echo '' > conftest.s
2561         # ??? This fails with non-gnu grep.
2562         if $gcc_cv_as --gstabs -o conftest.o conftest.s > /dev/null 2>&1 ; then
2563           gcc_cv_as_gstabs_flag="yes"
2564         fi
2565         rm -f conftest.s conftest.o
2566 fi
2567 if test x"$gcc_cv_as_gstabs_flag" = xyes; then
2568         AC_DEFINE(HAVE_AS_GSTABS_DEBUG_FLAG, 1,
2569 [Define if your assembler supports the --gstabs option.])
2570 fi
2571 AC_MSG_RESULT($gcc_cv_as_gstabs_flag)
2572
2573 AC_MSG_CHECKING(linker read-only and read-write section mixing)
2574 gcc_cv_ld_ro_rw_mix=unknown
2575 if test $in_tree_ld = yes ; then
2576   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 10 -o "$gcc_cv_gld_major_version" -gt 2 && grep 'EMUL = elf' ../ld/Makefile > /dev/null; then
2577     gcc_cv_ld_ro_rw_mix=read-write
2578   fi
2579 elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x -a x$gcc_cv_objdump != x ; then
2580   echo '.section myfoosect, "a"' > conftest1.s
2581   echo '.section myfoosect, "aw"' > conftest2.s
2582   echo '.byte 1' >> conftest2.s
2583   echo '.section myfoosect, "a"' > conftest3.s
2584   echo '.byte 0' >> conftest3.s
2585   if $gcc_cv_as -o conftest1.o conftest1.s > /dev/null 2>&1 \
2586      && $gcc_cv_as -o conftest2.o conftest2.s > /dev/null 2>&1 \
2587      && $gcc_cv_as -o conftest3.o conftest3.s > /dev/null 2>&1 \
2588      && $gcc_cv_ld -shared -o conftest1.so conftest1.o \
2589         conftest2.o conftest3.o > /dev/null 2>&1; then
2590     gcc_cv_ld_ro_rw_mix=`$gcc_cv_objdump -h conftest1.so \
2591                          | sed -e '/myfoosect/!d' -e N`
2592     if echo "$gcc_cv_ld_ro_rw_mix" | grep CONTENTS > /dev/null; then
2593       if echo "$gcc_cv_ld_ro_rw_mix" | grep READONLY > /dev/null; then
2594         gcc_cv_ld_ro_rw_mix=read-only
2595       else
2596         gcc_cv_ld_ro_rw_mix=read-write
2597       fi
2598     fi
2599   fi
2600 changequote(,)dnl
2601   rm -f conftest.* conftest[123].*
2602 changequote([,])dnl
2603 fi
2604 if test x$gcc_cv_ld_ro_rw_mix = xread-write; then
2605         AC_DEFINE(HAVE_LD_RO_RW_SECTION_MIXING, 1,
2606   [Define if your linker links a mix of read-only
2607    and read-write sections into a read-write section.])
2608 fi
2609 AC_MSG_RESULT($gcc_cv_ld_ro_rw_mix)
2610
2611 AC_MSG_CHECKING(linker PT_GNU_EH_FRAME support)
2612 gcc_cv_ld_eh_frame_hdr=no
2613 if test $in_tree_ld = yes ; then
2614   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 12 -o "$gcc_cv_gld_major_version" -gt 2 && grep 'EMUL = elf' ../ld/Makefile > /dev/null; then
2615     gcc_cv_ld_eh_frame_hdr=yes
2616   fi
2617 elif test x$gcc_cv_ld != x; then
2618         # Check if linker supports --eh-frame-hdr option
2619         if $gcc_cv_ld --help 2>/dev/null | grep eh-frame-hdr > /dev/null; then
2620                 gcc_cv_ld_eh_frame_hdr=yes
2621         fi
2622 fi
2623 if test x"$gcc_cv_ld_eh_frame_hdr" = xyes; then
2624         AC_DEFINE(HAVE_LD_EH_FRAME_HDR, 1,
2625 [Define if your linker supports --eh-frame-hdr option.])
2626 fi
2627 AC_MSG_RESULT($gcc_cv_ld_eh_frame_hdr)
2628
2629 AC_MSG_CHECKING(linker position independent executable support)
2630 gcc_cv_ld_pie=no
2631 if test $in_tree_ld = yes ; then
2632   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 15 -o "$gcc_cv_gld_major_version" -gt 2 && grep 'EMUL = elf' ../ld/Makefile > /dev/null; then
2633     gcc_cv_ld_pie=yes
2634   fi
2635 elif test x$gcc_cv_ld != x; then
2636         # Check if linker supports -pie option
2637         if $gcc_cv_ld --help 2>/dev/null | grep -- -pie > /dev/null; then
2638                 gcc_cv_ld_pie=yes
2639         fi
2640 fi
2641 if test x"$gcc_cv_ld_pie" = xyes; then
2642         AC_DEFINE(HAVE_LD_PIE, 1,
2643 [Define if your linker supports -pie option.])
2644 fi
2645 AC_MSG_RESULT($gcc_cv_ld_pie)
2646
2647 # Miscellaneous target-specific checks.
2648 case "$target" in
2649   mips*-*-*)
2650     AC_MSG_CHECKING(whether libgloss uses STARTUP directives consistently)
2651     gcc_cv_mips_libgloss_startup=no
2652     gcc_cv_libgloss_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/libgloss
2653     if test "x$exec_prefix" = xNONE; then
2654       if test "x$prefix" = xNONE; then
2655         test_prefix=/usr/local
2656       else
2657         test_prefix=$prefix
2658       fi
2659     else
2660       test_prefix=$exec_prefix
2661     fi
2662     for f in $gcc_cv_libgloss_srcdir/mips/idt.ld $test_prefix/$target_alias/lib/idt.ld
2663     do
2664       if grep '^STARTUP' $f > /dev/null 2>&1; then
2665         gcc_cv_mips_libgloss_startup=yes
2666         break
2667       fi
2668     done
2669     if test x"$gcc_cv_mips_libgloss_startup" = xyes; then
2670       AC_DEFINE(HAVE_MIPS_LIBGLOSS_STARTUP_DIRECTIVES, 1,
2671         [Define if your MIPS libgloss linker scripts consistently include STARTUP directives.])
2672     fi
2673     AC_MSG_RESULT($gcc_cv_mips_libgloss_startup)
2674
2675     AC_MSG_CHECKING(whether the assembler has explicit relocation support)
2676     if test x$gcc_cv_mips_explicit_relocs = x; then
2677       gcc_cv_mips_explicit_relocs=no
2678       if test $in_tree_gas = yes; then
2679         gcc_GAS_VERSION_GTE_IFELSE(2,14,0,[
2680           gcc_cv_mips_explicit_relocs=yes
2681         ])
2682       elif test x$gcc_cv_as != x; then
2683         echo '  lw $4,%gp_rel(foo)($4)' > conftest.s
2684         if $gcc_cv_as conftest.s -o conftest.o > /dev/null 2>&1; then
2685           gcc_cv_mips_explicit_relocs=yes
2686         fi
2687         rm -f conftest.s conftest.o
2688       fi
2689     fi
2690     if test $gcc_cv_mips_explicit_relocs = yes; then
2691       test x$target_cpu_default != x || target_cpu_default=0
2692       target_cpu_default="(${target_cpu_default}|MASK_EXPLICIT_RELOCS)"
2693     fi
2694     AC_MSG_RESULT($gcc_cv_mips_explicit_relocs)
2695     ;;
2696 esac
2697
2698 if test x$with_sysroot = x && test x$host = x$target \
2699    && test "$prefix" != "/usr" && test "x$prefix" != "x$local_prefix" ; then
2700   AC_DEFINE_UNQUOTED(PREFIX_INCLUDE_DIR, "$prefix/include")
2701 fi
2702
2703 # Figure out what language subdirectories are present.
2704 # Look if the user specified --enable-languages="..."; if not, use
2705 # the environment variable $LANGUAGES if defined. $LANGUAGES might
2706 # go away some day.
2707 # NB:  embedded tabs in this IF block -- do not untabify
2708 if test x"${enable_languages+set}" != xset; then
2709         if test x"${LANGUAGES+set}" = xset; then
2710                 enable_languages="${LANGUAGES}"
2711                 AC_MSG_WARN([setting LANGUAGES is deprecated, use --enable-languages instead])
2712
2713         else
2714                 enable_languages=all
2715         fi
2716 else
2717         if test x"${enable_languages}" = x \
2718         || test x"${enable_languages}" = xyes;
2719         then
2720                 AC_MSG_ERROR([--enable-languages needs at least one language argument])
2721         fi
2722 fi
2723 enable_languages=`echo "${enable_languages}" | sed -e 's/[[     ,]][[   ,]]*/,/g' -e 's/,$//'`
2724
2725 # First scan to see if an enabled language requires some other language.
2726 # We assume that a given config-lang.in will list all the language
2727 # front ends it requires, even if some are required indirectly.
2728 for lang in ${srcdir}/*/config-lang.in ..
2729 do
2730    case $lang in
2731     ..)
2732        ;;
2733     # The odd quoting in the next line works around
2734     # an apparent bug in bash 1.12 on linux.
2735 changequote(,)dnl
2736     ${srcdir}/[*]/config-lang.in)
2737        ;;
2738     *)
2739        lang_alias=`sed -n -e 's,^language=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^language=\([^      ]*\).*$,\1,p' $lang`
2740        this_lang_requires=`sed -n -e 's,^lang_requires=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^lang_requires=\([^    ]*\).*$,\1,p' $lang`
2741        for other in $this_lang_requires
2742        do
2743           case ,${enable_languages}, in
2744            *,$other,*)
2745               ;;
2746            *,all,*)
2747               ;;
2748            *,$lang_alias,*)
2749               enable_languages="$enable_languages,$other"
2750               ;;
2751           esac
2752        done
2753        ;;
2754 changequote([,])dnl
2755    esac
2756 done
2757
2758 expected_languages=`echo ,${enable_languages}, | sed -e 's:,: :g' -e 's:  *: :g' -e 's:  *: :g' -e 's:^ ::' -e 's: $::'`
2759 found_languages=
2760 subdirs=
2761 for lang in ${srcdir}/*/config-lang.in ..
2762 do
2763         case $lang in
2764         ..) ;;
2765         # The odd quoting in the next line works around
2766         # an apparent bug in bash 1.12 on linux.
2767 changequote(,)dnl
2768         ${srcdir}/[*]/config-lang.in) ;;
2769         *)
2770           lang_alias=`sed -n -e 's,^language=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^language=\([^   ]*\).*$,\1,p' $lang`
2771           this_lang_libs=`sed -n -e 's,^target_libs=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^target_libs=\([^         ]*\).*$,\1,p' $lang`
2772           build_by_default=`sed -n -e 's,^build_by_default=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^build_by_default=\([^     ]*\).*$,\1,p' $lang`
2773           if test "x$lang_alias" = x
2774           then
2775                 echo "$lang doesn't set \$language." 1>&2
2776                 exit 1
2777           fi
2778           case ${build_by_default},${enable_languages}, in
2779           *,$lang_alias,*) add_this_lang=yes ;;
2780           no,*) add_this_lang=no ;;
2781           *,all,*) add_this_lang=yes ;;
2782           *) add_this_lang=no ;;
2783           esac
2784           found_languages="${found_languages} ${lang_alias}"
2785           if test x"${add_this_lang}" = xyes; then
2786                 case $lang in
2787                     ${srcdir}/ada/config-lang.in)
2788                         if test x$have_gnat = xyes ; then
2789                                 subdirs="$subdirs `echo $lang | sed -e 's,^.*/\([^/]*\)/config-lang.in$,\1,'`"
2790                         fi
2791                         ;;
2792                     *)
2793                         subdirs="$subdirs `echo $lang | sed -e 's,^.*/\([^/]*\)/config-lang.in$,\1,'`"
2794                         ;;
2795                 esac
2796           fi
2797           ;;
2798 changequote([,])dnl
2799         esac
2800 done
2801
2802 missing_languages=
2803 for expected_language in ${expected_languages} ..
2804 do
2805     if test "${expected_language}" != ..; then
2806         missing_language="${expected_language}"
2807         if test "${expected_language}" = "c" \
2808            || test "${expected_language}" = "all"; then
2809                 missing_language=
2810         fi
2811         for found_language in ${found_languages} ..
2812         do
2813             if test "${found_language}" != ..; then
2814                 if test "${expected_language}" = "${found_language}"; then
2815                     missing_language=
2816                 fi
2817             fi
2818         done
2819         if test "x${missing_language}" != x; then
2820            missing_languages="${missing_languages} ${missing_language}"
2821         fi
2822     fi
2823 done
2824
2825 if test "x$missing_languages" != x; then
2826   AC_MSG_ERROR([
2827 The following requested languages were not found:${missing_languages}
2828 The following languages were available: c${found_languages}])
2829 fi
2830
2831 # Make gthr-default.h if we have a thread file.
2832 gthread_flags=
2833 if test $thread_file != single; then
2834     rm -f gthr-default.h
2835     echo "#include \"gthr-${thread_file}.h\"" > gthr-default.h
2836     gthread_flags=-DHAVE_GTHR_DEFAULT
2837 fi
2838 AC_SUBST(gthread_flags)
2839
2840 # Find out what GC implementation we want, or may, use.
2841 AC_ARG_WITH(gc,
2842 [  --with-gc={simple,page} choose the garbage collection mechanism to use
2843                           with the compiler],
2844 [case "$withval" in
2845   simple | page)
2846     GGC=ggc-$withval
2847     ;;
2848   *)
2849     AC_MSG_ERROR([$withval is an invalid option to --with-gc])
2850     ;;
2851 esac],
2852 [GGC=ggc-page])
2853 AC_SUBST(GGC)
2854 echo "Using $GGC for garbage collection."
2855
2856 # Use the system's zlib library.
2857 zlibdir=-L../zlib
2858 zlibinc="-I\$(srcdir)/../zlib"
2859 AC_ARG_WITH(system-zlib,
2860 [  --with-system-zlib      use installed libz],
2861 zlibdir=
2862 zlibinc=
2863 )
2864 AC_SUBST(zlibdir)
2865 AC_SUBST(zlibinc)
2866
2867 dnl Very limited version of automake's enable-maintainer-mode
2868
2869 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
2870   dnl maintainer-mode is disabled by default
2871   AC_ARG_ENABLE(maintainer-mode,
2872 [  --enable-maintainer-mode
2873                           enable make rules and dependencies not useful
2874                           (and sometimes confusing) to the casual installer],
2875       maintainer_mode=$enableval,
2876       maintainer_mode=no)
2877
2878 AC_MSG_RESULT($maintainer_mode)
2879
2880 if test "$maintainer_mode" = "yes"; then
2881   MAINT=''
2882 else
2883   MAINT='#'
2884 fi
2885 AC_SUBST(MAINT)dnl
2886
2887 # Make empty files to contain the specs and options for each language.
2888 # Then add #include lines to for a compiler that has specs and/or options.
2889
2890 lang_opt_files=
2891 lang_specs_files=
2892 lang_options_files=
2893 lang_tree_files=
2894 for subdir in . $subdirs
2895 do
2896         if test -f $srcdir/$subdir/lang.opt; then
2897             lang_opt_files="$lang_opt_files $srcdir/$subdir/lang.opt"
2898         fi
2899         if test -f $srcdir/$subdir/lang-specs.h; then
2900             lang_specs_files="$lang_specs_files $srcdir/$subdir/lang-specs.h"
2901         fi
2902         if test -f $srcdir/$subdir/lang-options.h; then
2903             lang_options_files="$lang_options_files $srcdir/$subdir/lang-options.h"
2904         fi
2905         if test -f $srcdir/$subdir/$subdir-tree.def; then
2906             lang_tree_files="$lang_tree_files $srcdir/$subdir/$subdir-tree.def"
2907         fi
2908 done
2909
2910 # These (without "all_") are set in each config-lang.in.
2911 # `language' must be a single word so is spelled singularly.
2912 all_languages=
2913 all_boot_languages=
2914 all_compilers=
2915 all_stagestuff=
2916 all_outputs='Makefile intl/Makefile fixinc/Makefile gccbug mklibgcc mkheaders'
2917 # List of language makefile fragments.
2918 all_lang_makefiles=
2919 # Files for gengtype
2920 all_gtfiles="$target_gtfiles"
2921 # Files for gengtype with language
2922 all_gtfiles_files_langs=
2923 all_gtfiles_files_files=
2924
2925 # Add the language fragments.
2926 # Languages are added via two mechanisms.  Some information must be
2927 # recorded in makefile variables, these are defined in config-lang.in.
2928 # We accumulate them and plug them into the main Makefile.
2929 # The other mechanism is a set of hooks for each of the main targets
2930 # like `clean', `install', etc.
2931
2932 language_fragments="Make-lang"
2933 language_hooks="Make-hooks"
2934
2935 for s in .. $subdirs
2936 do
2937         if test $s != ".."
2938         then
2939                 language=
2940                 boot_language=
2941                 compilers=
2942                 stagestuff=
2943                 outputs=
2944                 gtfiles=
2945                 . ${srcdir}/$s/config-lang.in
2946                 if test "x$language" = x
2947                 then
2948                         echo "${srcdir}/$s/config-lang.in doesn't set \$language." 1>&2
2949                         exit 1
2950                 fi
2951                 all_lang_makefiles="$all_lang_makefiles ${srcdir}/$s/Make-lang.in"
2952                 if test -f ${srcdir}/$s/Makefile.in
2953                 then all_lang_makefiles="$all_lang_makefiles ${srcdir}/$s/Makefile.in"
2954                 fi
2955                 all_languages="$all_languages $language"
2956                 if test "x$boot_language" = xyes
2957                 then
2958                         all_boot_languages="$all_boot_languages $language"
2959                 fi
2960                 all_compilers="$all_compilers $compilers"
2961                 all_stagestuff="$all_stagestuff $stagestuff"
2962                 all_outputs="$all_outputs $outputs"
2963                 all_gtfiles="$all_gtfiles $gtfiles"
2964                 for f in .. $gtfiles
2965                 do
2966                      if test $f != ".."
2967                      then
2968                          all_gtfiles_files_langs="$all_gtfiles_files_langs ${s} "
2969                          all_gtfiles_files_files="$all_gtfiles_files_files ${f} "
2970                      fi
2971                 done
2972         fi
2973 done
2974
2975 # Pick up gtfiles for c
2976 gtfiles=
2977 s="c"
2978 . ${srcdir}/c-config-lang.in
2979 all_gtfiles="$all_gtfiles $gtfiles"
2980 for f in .. $gtfiles
2981 do
2982      if test $f != ".."
2983      then
2984         all_gtfiles_files_langs="$all_gtfiles_files_langs ${s} "
2985         all_gtfiles_files_files="$all_gtfiles_files_files ${f} "
2986      fi
2987 done
2988
2989 check_languages=
2990 for language in .. $all_languages
2991 do
2992         if test $language != ".."
2993         then
2994                 check_languages="$check_languages check-$language"
2995         fi
2996 done
2997
2998 # Since we can't use `::' targets, we link each language in
2999 # with a set of hooks, reached indirectly via lang.${target}.
3000
3001 rm -f Make-hooks
3002 touch Make-hooks
3003 target_list="all.build all.cross start.encap rest.encap tags \
3004         info dvi generated-manpages \
3005         install-normal install-common install-info install-man \
3006         uninstall \
3007         mostlyclean clean distclean extraclean maintainer-clean \
3008         stage1 stage2 stage3 stage4 stageprofile stagefeedback"
3009 for t in $target_list
3010 do
3011         x=
3012         for lang in .. $all_languages
3013         do
3014                 if test $lang != ".."; then
3015                         x="$x $lang.$t"
3016                 fi
3017         done
3018         echo "lang.$t: $x" >> Make-hooks
3019 done
3020
3021 # Create .gdbinit.
3022
3023 echo "dir ." > .gdbinit
3024 echo "dir ${srcdir}" >> .gdbinit
3025 if test x$gdb_needs_out_file_path = xyes
3026 then
3027         echo "dir ${srcdir}/config/"`dirname ${out_file}` >> .gdbinit
3028 fi
3029 if test "x$subdirs" != x; then
3030         for s in $subdirs
3031         do
3032                 echo "dir ${srcdir}/$s" >> .gdbinit
3033         done
3034 fi
3035 echo "source ${srcdir}/gdbinit.in" >> .gdbinit
3036
3037 # If $(exec_prefix) exists and is not the same as $(prefix), then compute an
3038 # absolute path for gcc_tooldir based on inserting the number of up-directory
3039 # movements required to get from $(exec_prefix) to $(prefix) into the basic
3040 # $(libsubdir)/@(unlibsubdir) based path.
3041 # Don't set gcc_tooldir to tooldir since that's only passed in by the toplevel
3042 # make and thus we'd get different behavior depending on where we built the
3043 # sources.
3044 if test x$exec_prefix = xNONE -o x$exec_prefix = x$prefix; then
3045     gcc_tooldir='$(libsubdir)/$(unlibsubdir)/../$(target_alias)'
3046 else
3047 changequote(<<, >>)dnl
3048 # An explanation of the sed strings:
3049 #  -e 's|^\$(prefix)||'   matches and eliminates 'prefix' from 'exec_prefix'
3050 #  -e 's|/$||'            match a trailing forward slash and eliminates it
3051 #  -e 's|^[^/]|/|'        forces the string to start with a forward slash (*)
3052 #  -e 's|/[^/]*|../|g'    replaces each occurrence of /<directory> with ../
3053 #
3054 # (*) Note this pattern overwrites the first character of the string
3055 # with a forward slash if one is not already present.  This is not a
3056 # problem because the exact names of the sub-directories concerned is
3057 # unimportant, just the number of them matters.
3058 #
3059 # The practical upshot of these patterns is like this:
3060 #
3061 #  prefix     exec_prefix        result
3062 #  ------     -----------        ------
3063 #   /foo        /foo/bar          ../
3064 #   /foo/       /foo/bar          ../
3065 #   /foo        /foo/bar/         ../
3066 #   /foo/       /foo/bar/         ../
3067 #   /foo        /foo/bar/ugg      ../../
3068 #
3069     dollar='$$'
3070     gcc_tooldir="\$(libsubdir)/\$(unlibsubdir)/\`echo \$(exec_prefix) | sed -e 's|^\$(prefix)||' -e 's|/\$(dollar)||' -e 's|^[^/]|/|' -e 's|/[^/]*|../|g'\`\$(target_alias)"
3071 changequote([, ])dnl
3072 fi
3073 AC_SUBST(gcc_tooldir)
3074 AC_SUBST(dollar)
3075
3076 # Find a directory in which to install a shared libgcc.
3077
3078 AC_ARG_ENABLE(version-specific-runtime-libs,
3079 [  --enable-version-specific-runtime-libs
3080                           specify that runtime libraries should be
3081                           installed in a compiler-specific directory])
3082
3083 AC_ARG_WITH(slibdir,
3084 [  --with-slibdir=DIR      shared libraries in DIR [LIBDIR]],
3085 slibdir="$with_slibdir",
3086 if test "${enable_version_specific_runtime_libs+set}" = set; then
3087   slibdir='$(libsubdir)'
3088 elif test "$host" != "$target"; then
3089   slibdir='$(build_tooldir)/lib'
3090 else
3091   slibdir='$(libdir)'
3092 fi)
3093 AC_SUBST(slibdir)
3094
3095 objdir=`${PWDCMD-pwd}`
3096 AC_SUBST(objdir)
3097
3098 # Process the language and host/target makefile fragments.
3099 ${CONFIG_SHELL-/bin/sh} $srcdir/configure.frag $srcdir "$subdirs" "$dep_host_xmake_file" "$dep_tmake_file"
3100
3101 # Substitute configuration variables
3102 AC_SUBST(subdirs)
3103 AC_SUBST(srcdir)
3104 AC_SUBST(all_boot_languages)
3105 AC_SUBST(all_compilers)
3106 AC_SUBST(all_gtfiles)
3107 AC_SUBST(all_gtfiles_files_langs)
3108 AC_SUBST(all_gtfiles_files_files)
3109 AC_SUBST(all_lang_makefiles)
3110 AC_SUBST(all_languages)
3111 AC_SUBST(all_stagestuff)
3112 AC_SUBST(build_exeext)
3113 AC_SUBST(build_install_headers_dir)
3114 AC_SUBST(build_xm_file_list)
3115 AC_SUBST(build_xm_file)
3116 AC_SUBST(build_xm_defines)
3117 AC_SUBST(check_languages)
3118 AC_SUBST(cc_set_by_configure)
3119 AC_SUBST(quoted_cc_set_by_configure)
3120 AC_SUBST(cpp_install_dir)
3121 AC_SUBST(dep_host_xmake_file)
3122 AC_SUBST(dep_tmake_file)
3123 AC_SUBST(extra_headers_list)
3124 AC_SUBST(extra_objs)
3125 AC_SUBST(extra_parts)
3126 AC_SUBST(extra_passes)
3127 AC_SUBST(extra_programs)
3128 AC_SUBST(float_h_file)
3129 AC_SUBST(gcc_config_arguments)
3130 AC_SUBST(gcc_gxx_include_dir)
3131 AC_SUBST(libstdcxx_incdir)
3132 AC_SUBST(gcc_version)
3133 AC_SUBST(gcc_version_full)
3134 AC_SUBST(gcc_version_trigger)
3135 AC_SUBST(host_exeext)
3136 AC_SUBST(host_extra_gcc_objs)
3137 AC_SUBST(host_xm_file_list)
3138 AC_SUBST(host_xm_file)
3139 AC_SUBST(host_xm_defines)
3140 AC_SUBST(out_host_hook_obj)
3141 AC_SUBST(install)
3142 AC_SUBST(lang_opt_files)
3143 AC_SUBST(lang_options_files)
3144 AC_SUBST(lang_specs_files)
3145 AC_SUBST(lang_tree_files)
3146 AC_SUBST(local_prefix)
3147 AC_SUBST(md_file)
3148 AC_SUBST(objc_boehm_gc)
3149 AC_SUBST(out_file)
3150 AC_SUBST(out_object_file)
3151 AC_SUBST(stage_prefix_set_by_configure)
3152 AC_SUBST(quoted_stage_prefix_set_by_configure)
3153 AC_SUBST(symbolic_link)
3154 AC_SUBST(thread_file)
3155 AC_SUBST(tm_file_list)
3156 AC_SUBST(tm_file)
3157 AC_SUBST(tm_defines)
3158 AC_SUBST(tm_p_file_list)
3159 AC_SUBST(tm_p_file)
3160 AC_SUBST(xm_file)
3161 AC_SUBST(xm_defines)
3162 AC_SUBST(target_alias)
3163 AC_SUBST(c_target_objs)
3164 AC_SUBST(cxx_target_objs)
3165 AC_SUBST(target_cpu_default)
3166
3167 AC_SUBST_FILE(target_overrides)
3168 AC_SUBST_FILE(host_overrides)
3169 AC_SUBST_FILE(language_fragments)
3170 AC_SUBST_FILE(language_hooks)
3171
3172 # Echo that links are built
3173 if test x$host = x$target
3174 then
3175         str1="native "
3176 else
3177         str1="cross-"
3178         str2=" from $host"
3179 fi
3180
3181 if test x$host != x$build
3182 then
3183         str3=" on a $build system"
3184 fi
3185
3186 if test "x$str2" != x || test "x$str3" != x
3187 then
3188         str4=
3189 fi
3190
3191 echo "Links are now set up to build a ${str1}compiler for ${target}$str4" 1>&2
3192
3193 if test "x$str2" != x || test "x$str3" != x
3194 then
3195         echo " ${str2}${str3}." 1>&2
3196 fi
3197
3198 # Configure the subdirectories
3199 # AC_CONFIG_SUBDIRS($subdirs)
3200
3201 # Create the Makefile
3202 # and configure language subdirectories
3203 AC_OUTPUT($all_outputs,
3204 [
3205 case x$CONFIG_HEADERS in
3206 xauto-host.h:config.in)
3207 echo > cstamp-h ;;
3208 esac
3209 # If the host supports symlinks, point stage[1234] at ../stage[1234] so
3210 # bootstrapping and the installation procedure can still use
3211 # CC="stage1/xgcc -Bstage1/".  If the host doesn't support symlinks,
3212 # FLAGS_TO_PASS has been modified to solve the problem there.
3213 # This is virtually a duplicate of what happens in configure.lang; we do
3214 # an extra check to make sure this only happens if ln -s can be used.
3215 if test "$symbolic_link" = "ln -s"; then
3216  for d in .. ${subdirs} fixinc ; do
3217    if test $d != ..; then
3218         STARTDIR=`${PWDCMD-pwd}`
3219         cd $d
3220         for t in stage1 stage2 stage3 stage4 stageprofile stagefeedback include
3221         do
3222                 rm -f $t
3223                 $symbolic_link ../$t $t 2>/dev/null
3224         done
3225         cd $STARTDIR
3226    fi
3227  done
3228 else true ; fi
3229 # Avoid having to add intl to our include paths.
3230 if test -f intl/libintl.h; then
3231   echo creating libintl.h
3232   echo '#include "intl/libintl.h"' >libintl.h
3233 fi
3234 ],
3235 [subdirs='$subdirs'
3236 symbolic_link='$symbolic_link'
3237 ])