OSDN Git Service

3da2200a194da0ee4fd07898dbdd712c2e10d340
[pf3gnuchains/gcc-fork.git] / gcc / configure.in
1 # configure.in for GCC
2 # Process this file with autoconf to generate a configuration script.
3
4 # Copyright 1997, 1998, 1999, 2000, 2001, 2002, 2003
5 # Free Software Foundation, Inc.
6
7 #This file is part of GCC.
8
9 #GCC is free software; you can redistribute it and/or modify it under
10 #the terms of the GNU General Public License as published by the Free
11 #Software Foundation; either version 2, or (at your option) any later
12 #version.
13
14 #GCC is distributed in the hope that it will be useful, but WITHOUT
15 #ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
16 #FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
17 #for more details.
18
19 #You should have received a copy of the GNU General Public License
20 #along with GCC; see the file COPYING.  If not, write to the Free
21 #Software Foundation, 59 Temple Place - Suite 330, Boston, MA
22 #02111-1307, USA.
23
24 # --------------------------------
25 # Initialization and sanity checks
26 # --------------------------------
27
28 AC_PREREQ(2.13)
29 AC_INIT(tree.c)
30 AC_CONFIG_HEADER(auto-host.h:config.in)
31
32 # Determine the host, build, and target systems
33 AC_CANONICAL_SYSTEM
34
35 # Determine the target- and build-specific subdirectories
36 GCC_TOPLEV_SUBDIRS
37
38 # Set program_transform_name
39 AC_ARG_PROGRAM
40
41 # Check for bogus environment variables.
42 # Test if LIBRARY_PATH contains the notation for the current directory
43 # since this would lead to problems installing/building glibc.
44 # LIBRARY_PATH contains the current directory if one of the following
45 # is true:
46 # - one of the terminals (":" and ";") is the first or last sign
47 # - two terminals occur directly after each other
48 # - the path contains an element with a dot in it
49 AC_MSG_CHECKING(LIBRARY_PATH variable)
50 changequote(,)dnl
51 case ${LIBRARY_PATH} in
52   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
53     library_path_setting="contains current directory"
54     ;;
55   *)
56     library_path_setting="ok"
57     ;;
58 esac
59 changequote([,])dnl
60 AC_MSG_RESULT($library_path_setting)
61 if test "$library_path_setting" != "ok"; then
62 AC_MSG_ERROR([
63 *** LIBRARY_PATH shouldn't contain the current directory when
64 *** building gcc. Please change the environment variable
65 *** and run configure again.])
66 fi
67
68 # Test if GCC_EXEC_PREFIX contains the notation for the current directory
69 # since this would lead to problems installing/building glibc.
70 # GCC_EXEC_PREFIX contains the current directory if one of the following
71 # is true:
72 # - one of the terminals (":" and ";") is the first or last sign
73 # - two terminals occur directly after each other
74 # - the path contains an element with a dot in it
75 AC_MSG_CHECKING(GCC_EXEC_PREFIX variable)
76 changequote(,)dnl
77 case ${GCC_EXEC_PREFIX} in
78   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
79     gcc_exec_prefix_setting="contains current directory"
80     ;;
81   *)
82     gcc_exec_prefix_setting="ok"
83     ;;
84 esac
85 changequote([,])dnl
86 AC_MSG_RESULT($gcc_exec_prefix_setting)
87 if test "$gcc_exec_prefix_setting" != "ok"; then
88 AC_MSG_ERROR([
89 *** GCC_EXEC_PREFIX shouldn't contain the current directory when
90 *** building gcc. Please change the environment variable
91 *** and run configure again.])
92 fi
93
94 # -----------
95 # Directories
96 # -----------
97
98 # Specify the local prefix
99 local_prefix=
100 AC_ARG_WITH(local-prefix,
101 [  --with-local-prefix=DIR specifies directory to put local include],
102 [case "${withval}" in
103 yes)    AC_MSG_ERROR(bad value ${withval} given for local include directory prefix) ;;
104 no)     ;;
105 *)      local_prefix=$with_local_prefix ;;
106 esac])
107
108 # Default local prefix if it is empty
109 if test x$local_prefix = x; then
110         local_prefix=/usr/local
111 fi
112
113 # Don't set gcc_gxx_include_dir to gxx_include_dir since that's only
114 # passed in by the toplevel make and thus we'd get different behavior
115 # depending on where we built the sources.
116 gcc_gxx_include_dir=
117 # Specify the g++ header file directory
118 AC_ARG_WITH(gxx-include-dir,
119 [  --with-gxx-include-dir=DIR
120                           specifies directory to put g++ header files],
121 [case "${withval}" in
122 yes)    AC_MSG_ERROR(bad value ${withval} given for g++ include directory) ;;
123 no)     ;;
124 *)      gcc_gxx_include_dir=$with_gxx_include_dir ;;
125 esac])
126
127 if test x${gcc_gxx_include_dir} = x; then
128   if test x${enable_version_specific_runtime_libs} = xyes; then
129     gcc_gxx_include_dir='${libsubdir}/include/c++'
130   else
131     topsrcdir=${srcdir}/.. . ${srcdir}/../config.if
132 changequote(<<, >>)dnl
133     gcc_gxx_include_dir="\$(libsubdir)/\$(unlibsubdir)/..\`echo \$(exec_prefix) | sed -e 's|^\$(prefix)||' -e 's|/[^/]*|/..|g'\`/include/"${libstdcxx_incdir}
134 changequote([, ])dnl
135   fi
136 fi
137
138 AC_ARG_WITH(cpp_install_dir,
139 [  --with-cpp-install-dir=DIR
140                           install the user visible C preprocessor in DIR
141                           (relative to PREFIX) as well as PREFIX/bin],
142 [if test x$withval = xyes; then
143   AC_MSG_ERROR([option --with-cpp-install-dir requires an argument])
144 elif test x$withval != xno; then
145   cpp_install_dir=$withval
146 fi])
147
148 # -------------------
149 # Find default linker
150 # -------------------
151
152 # With GNU ld
153 AC_ARG_WITH(gnu-ld,
154 [  --with-gnu-ld           arrange to work with GNU ld.],
155 gnu_ld_flag="$with_gnu_ld",
156 gnu_ld_flag=no)
157
158 # With pre-defined ld
159 AC_ARG_WITH(ld,
160 [  --with-ld               arrange to use the specified ld (full pathname)],
161 DEFAULT_LINKER="$with_ld")
162 if test x"${DEFAULT_LINKER+set}" = x"set"; then
163   if test ! -x "$DEFAULT_LINKER"; then
164     AC_MSG_WARN([cannot execute: $DEFAULT_LINKER: check --with-ld or env. var. DEFAULT_LINKER])
165   elif $DEFAULT_LINKER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
166     gnu_ld_flag=yes
167   fi
168   AC_DEFINE_UNQUOTED(DEFAULT_LINKER,"$DEFAULT_LINKER",
169         [Define to enable the use of a default linker.])
170 fi
171
172 AC_MSG_CHECKING([whether a default linker was specified])
173 if test x"${DEFAULT_LINKER+set}" = x"set"; then
174   if test x"$gnu_ld_flag" = x"no"; then
175     AC_MSG_RESULT([yes ($DEFAULT_LINKER)])
176   else
177     AC_MSG_RESULT([yes ($DEFAULT_LINKER - GNU ld)])
178   fi
179 else
180   AC_MSG_RESULT(no)
181 fi
182
183 # ----------------------
184 # Find default assembler
185 # ----------------------
186
187 # With GNU as
188 AC_ARG_WITH(gnu-as,
189 [  --with-gnu-as           arrange to work with GNU as],
190 gas_flag="$with_gnu_as",
191 gas_flag=no)
192
193 AC_ARG_WITH(as,
194 [  --with-as               arrange to use the specified as (full pathname)],
195 DEFAULT_ASSEMBLER="$with_as")
196 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
197   if test ! -x "$DEFAULT_ASSEMBLER"; then
198     AC_MSG_WARN([cannot execute: $DEFAULT_ASSEMBLER: check --with-as or env. var. DEFAULT_ASSEMBLER])
199   elif $DEFAULT_ASSEMBLER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
200     gas_flag=yes
201   fi
202   AC_DEFINE_UNQUOTED(DEFAULT_ASSEMBLER,"$DEFAULT_ASSEMBLER",
203         [Define to enable the use of a default assembler.])
204 fi
205
206 AC_MSG_CHECKING([whether a default assembler was specified])
207 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
208   if test x"$gas_flag" = x"no"; then
209     AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER)])
210   else
211     AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER - GNU as)])
212   fi
213 else
214   AC_MSG_RESULT(no)
215 fi
216
217 # ---------------
218 # Find C compiler
219 # ---------------
220
221 # Find the native compiler
222 AC_PROG_CC
223 AC_PROG_CC_C_O
224 # autoconf is lame and doesn't give us any substitution variable for this.
225 if eval "test \"`echo '$ac_cv_prog_cc_'${ac_cc}_c_o`\" = no"; then
226   NO_MINUS_C_MINUS_O=yes
227 else
228   OUTPUT_OPTION='-o $@'
229 fi
230 AC_SUBST(NO_MINUS_C_MINUS_O)
231 AC_SUBST(OUTPUT_OPTION)
232
233 # -------------------------
234 # Check C compiler features
235 # -------------------------
236
237 AC_CACHE_CHECK(whether ${CC-cc} accepts -Wno-long-long,
238 ac_cv_prog_cc_no_long_long,
239 [save_CFLAGS="$CFLAGS"
240 CFLAGS="-Wno-long-long"
241 AC_TRY_COMPILE(,,ac_cv_prog_cc_no_long_long=yes,
242                ac_cv_prog_cc_no_long_long=no)
243 CFLAGS="$save_CFLAGS"])
244
245 AC_PROG_CPP
246 AC_C_INLINE
247
248 gcc_AC_C_LONG_LONG
249 gcc_AC_C__BOOL
250
251 # sizeof(char) is 1 by definition.
252 AC_COMPILE_CHECK_SIZEOF(void *)
253 AC_COMPILE_CHECK_SIZEOF(short)
254 AC_COMPILE_CHECK_SIZEOF(int)
255 AC_COMPILE_CHECK_SIZEOF(long)
256 if test $ac_cv_c_long_long = yes; then
257   AC_COMPILE_CHECK_SIZEOF(long long)
258 fi
259 if test $ac_cv_c___int64 = yes; then
260   AC_COMPILE_CHECK_SIZEOF(__int64)
261 fi
262
263 # -----------------
264 # Find Ada compiler
265 # -----------------
266
267 # See if GNAT has been installed
268 gcc_AC_PROG_GNAT
269
270 if test x$have_gnat != xno ; then 
271 AC_CACHE_CHECK(whether ${ADAC} accepts -Wno-long-long,
272 ac_cv_prog_adac_no_long_long,
273 [cat >conftest.adb <<EOF
274 procedure conftest is begin null; end conftest;
275 EOF
276 if $ADAC -Wno-long-long -c conftest.adb 1>&5 2>&5 ; then
277   ac_cv_prog_adac_no_long_long=yes
278 else
279   ac_cv_prog_adac_no_long_long=no
280 fi
281 rm -f conftest*])
282 else
283   ac_cv_prog_adac_no_long_long=yes
284 fi
285
286 # ---------------------
287 # Warnings and checking
288 # ---------------------
289
290 strict1_warn=
291 if test $ac_cv_prog_cc_no_long_long = yes && \
292     test $ac_cv_prog_adac_no_long_long = yes ; then
293   strict1_warn="-pedantic -Wno-long-long"
294 fi
295 AC_SUBST(strict1_warn)
296
297 # If the native compiler is GCC, we can enable warnings even in stage1.  
298 # That's useful for people building cross-compilers, or just running a
299 # quick `make'.
300 warn_cflags=
301 if test "x$GCC" = "xyes"; then
302   warn_cflags='$(GCC_WARN_CFLAGS)'
303 fi
304 AC_SUBST(warn_cflags)
305
306 # Enable -Werror in bootstrap stage2 and later.
307 # Change the default to "no" on release branches.
308 AC_ARG_ENABLE(werror, 
309 [  --enable-werror         enable -Werror in bootstrap stage2 and later], [],
310 [enable_werror=yes])
311 if test x$enable_werror = xyes ; then
312   WERROR=-Werror
313 fi
314 AC_SUBST(WERROR)
315
316 # Enable expensive internal checks
317 AC_ARG_ENABLE(checking,
318 [  --enable-checking[=LIST]
319                           enable expensive run-time checks.  With LIST,
320                           enable only specific categories of checks.
321                           Categories are: misc,tree,rtl,rtlflag,gc,gcac,fold;
322                           default is misc,tree,gc,rtlflag],
323 [ac_checking=
324 ac_tree_checking=
325 ac_rtl_checking=
326 ac_rtlflag_checking=
327 ac_gc_checking=
328 ac_gc_always_collect=
329 ac_fold_checking=
330 case "${enableval}" in
331 yes)    ac_checking=1 ; ac_tree_checking=1 ; ac_gc_checking=1 ;
332         ac_rtlflag_checking=1 ;;
333 no)     ;;
334 *)      IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
335         set fnord $enableval; shift
336         IFS="$ac_save_IFS"
337         for check
338         do
339                 case $check in
340                 misc)   ac_checking=1 ;;
341                 tree)   ac_tree_checking=1 ;;
342                 rtlflag)        ac_rtlflag_checking=1 ;;
343                 rtl)    ac_rtl_checking=1 ;;
344                 gc)     ac_gc_checking=1 ;;
345                 gcac)   ac_gc_always_collect=1 ;;
346                 fold)   ac_fold_checking=1 ;;
347                 valgrind)       ac_checking_valgrind=1 ;;
348                 *)      AC_MSG_ERROR(unknown check category $check) ;;
349                 esac
350         done
351         ;;
352 esac
353 ], 
354 # Enable some checks by default for development versions of GCC
355 [ac_checking=1; ac_tree_checking=1; ac_gc_checking=1; ac_rtlflag_checking=1;])
356 nocommon_flag=""
357 if test x$ac_checking != x ; then
358   AC_DEFINE(ENABLE_CHECKING, 1,
359 [Define if you want more run-time sanity checks.  This one gets a grab
360    bag of miscellaneous but relatively cheap checks.])
361   nocommon_flag=-fno-common
362 fi
363 AC_SUBST(nocommon_flag)
364 if test x$ac_tree_checking != x ; then
365   AC_DEFINE(ENABLE_TREE_CHECKING, 1,
366 [Define if you want all operations on trees (the basic data
367    structure of the front ends) to be checked for dynamic type safety
368    at runtime.  This is moderately expensive.])
369 fi
370 if test x$ac_rtl_checking != x ; then
371   AC_DEFINE(ENABLE_RTL_CHECKING, 1,
372 [Define if you want all operations on RTL (the basic data structure
373    of the optimizer and back end) to be checked for dynamic type safety
374    at runtime.  This is quite expensive.])
375 fi
376 if test x$ac_rtlflag_checking != x ; then
377   AC_DEFINE(ENABLE_RTL_FLAG_CHECKING, 1,
378 [Define if you want RTL flag accesses to be checked against the RTL
379    codes that are supported for each access macro.  This is relatively
380    cheap.])
381 fi
382 if test x$ac_gc_checking != x ; then
383   AC_DEFINE(ENABLE_GC_CHECKING, 1,
384 [Define if you want the garbage collector to do object poisoning and
385    other memory allocation checks.  This is quite expensive.])
386 fi
387 if test x$ac_gc_always_collect != x ; then
388   AC_DEFINE(ENABLE_GC_ALWAYS_COLLECT, 1,
389 [Define if you want the garbage collector to operate in maximally
390    paranoid mode, validating the entire heap and collecting garbage at
391    every opportunity.  This is extremely expensive.])
392 fi
393 if test x$ac_fold_checking != x ; then
394   AC_DEFINE(ENABLE_FOLD_CHECKING, 1,
395 [Define if you want fold checked that it never destructs its argument.
396    This is quite expensive.])
397 fi
398 valgrind_path_defines=
399 valgrind_command=
400 if test x$ac_checking_valgrind != x ; then
401   # It is certainly possible that there's valgrind but no valgrind.h.
402   # GCC relies on making annotations so we must have both.
403   AC_MSG_CHECKING(for VALGRIND_DISCARD in <memcheck.h>)
404   AC_TRY_CPP(
405     [#include <memcheck.h>
406 #ifndef VALGRIND_DISCARD
407 #error VALGRIND_DISCARD not defined
408 #endif],
409   [gcc_cv_header_memcheck_h=yes], 
410   gcc_cv_header_memcheck_h=no)
411   AC_MSG_RESULT($gcc_cv_header_memcheck_h)
412   AC_CHECK_HEADER(valgrind.h, have_valgrind_h=yes, have_valgrind_h=no)
413   AM_PATH_PROG_WITH_TEST(valgrind_path, valgrind,
414         [$ac_dir/$ac_word --version | grep valgrind- >/dev/null 2>&1])
415   if test "x$valgrind_path" = "x" || (test $have_valgrind_h = no && test $gcc_cv_header_memcheck_h = no); then
416         AC_MSG_ERROR([*** Can't find both valgrind and valgrind.h/memcheck.h])
417   fi
418   valgrind_path_defines=-DVALGRIND_PATH='\"'$valgrind_path'\"'
419   valgrind_command="$valgrind_path -q"
420   AC_DEFINE(ENABLE_VALGRIND_CHECKING, 1,
421 [Define if you want to run subprograms and generated programs
422    through valgrind (a memory checker).  This is extremely expensive.])
423   if test $gcc_cv_header_memcheck_h = yes; then
424     AC_DEFINE(HAVE_MEMCHECK_H, 1,
425         [Define if valgrind's memcheck.h header is installed.])
426   fi
427 fi
428 AC_SUBST(valgrind_path_defines)
429 AC_SUBST(valgrind_command)
430
431 # Enable code coverage collection
432 AC_ARG_ENABLE(coverage,
433 [  --enable-coverage[=LEVEL]
434                           enable compiler\'s code coverage collection.
435                           Use to measure compiler performance and locate
436                           unused parts of the compiler. With LEVEL, specify
437                           optimization. Values are opt, noopt,
438                           default is noopt],
439 [case "${enableval}" in
440 yes|noopt)
441         coverage_flags="-fprofile-arcs -ftest-coverage -frandom-seed=\$@ -O0"
442         ;;
443 opt)
444         coverage_flags="-fprofile-arcs -ftest-coverage -frandom-seed=\$@ -O2"
445         ;;
446 *)
447         AC_MSG_ERROR(unknown coverage setting $enableval)
448         ;;
449 esac],
450 [coverage_flags=""])
451 AC_SUBST(coverage_flags)
452
453 # -------------------------------
454 # Miscenalleous configure options
455 # -------------------------------
456
457 # With stabs
458 AC_ARG_WITH(stabs,
459 [  --with-stabs            arrange to use stabs instead of host debug format],
460 stabs="$with_stabs",
461 stabs=no)
462
463 # Determine whether or not multilibs are enabled.
464 AC_ARG_ENABLE(multilib,
465 [  --enable-multilib       enable library support for multiple ABIs],
466 [], [enable_multilib=yes])
467 AC_SUBST(enable_multilib)
468
469 # Enable __cxa_atexit for C++.
470 AC_ARG_ENABLE(__cxa_atexit,
471 [  --enable-__cxa_atexit   enable __cxa_atexit for C++],
472 [], [])
473
474 # Enable threads
475 # Pass with no value to take the default
476 # Pass with a value to specify a thread package
477 AC_ARG_ENABLE(threads,
478 [  --enable-threads        enable thread usage for target GCC
479   --enable-threads=LIB    use LIB thread package for target GCC],,
480 enable_threads='')
481 # Save in case it gets overwritten in config.gcc
482 enable_threads_flag=$enable_threads
483
484 AC_ARG_ENABLE(objc-gc,
485 [  --enable-objc-gc       enable the use of Boehm's garbage collector with
486                           the GNU Objective-C runtime],
487 if test x$enable_objc_gc = xno; then
488         objc_boehm_gc=''
489 else
490         objc_boehm_gc=1
491 fi,
492 objc_boehm_gc='')
493
494 AC_ARG_WITH(dwarf2,
495 [  --with-dwarf2           force the default debug format to be DWARF 2],
496 dwarf2="$with_dwarf2",
497 dwarf2=no)
498
499 AC_ARG_ENABLE(shared,
500 [  --disable-shared        don't provide a shared libgcc],
501 [
502   case $enable_shared in
503   yes | no) ;;
504   *)
505     enable_shared=no
506     IFS="${IFS=         }"; ac_save_ifs="$IFS"; IFS="${IFS}:,"
507     for pkg in $enableval; do
508       if test "X$pkg" = "Xgcc" || test "X$pkg" = "Xlibgcc"; then
509         enable_shared=yes
510       fi
511     done
512     IFS="$ac_save_ifs"
513     ;;
514   esac
515 ], [enable_shared=yes])
516 AC_SUBST(enable_shared)
517
518 AC_ARG_WITH(sysroot,
519 [  --with-sysroot[=DIR] Search for usr/lib, usr/include, et al, within DIR.],
520 [
521  case ${with_sysroot} in
522  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_alias}/sys-root' ;;
523  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
524  esac
525    
526  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
527  CROSS_SYSTEM_HEADER_DIR='$(TARGET_SYSTEM_ROOT)$(NATIVE_SYSTEM_HEADER_DIR)'
528
529  if test "x$exec_prefix" = xNONE; then
530   if test "x$prefix" = xNONE; then
531    test_prefix=/usr/local
532   else
533    test_prefix=$prefix
534   fi
535  else
536   test_prefix=$exec_prefix
537  fi
538  case ${TARGET_SYSTEM_ROOT} in
539  "${test_prefix}"|"${test_prefix}/"*|\
540  '${exec_prefix}'|'${exec_prefix}/'*)
541    t="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE"
542    TARGET_SYSTEM_ROOT_DEFINE="$t"
543    ;;
544  esac
545 ], [
546  TARGET_SYSTEM_ROOT=
547  TARGET_SYSTEM_ROOT_DEFINE=
548  CROSS_SYSTEM_HEADER_DIR='$(gcc_tooldir)/sys-include'
549 ])
550 AC_SUBST(TARGET_SYSTEM_ROOT)
551 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
552 AC_SUBST(CROSS_SYSTEM_HEADER_DIR)
553
554 # Build with intermodule optimisations
555 AC_ARG_ENABLE(intermodule,
556 [  --enable-intermodule    build the compiler in one step],
557 [case ${enable_intermodule} in
558   yes) onestep="-onestep";;
559   *) onestep="";;
560 esac],
561 [onestep=""])
562 AC_SUBST(onestep)
563
564 # -------------------------
565 # Checks for other programs
566 # -------------------------
567
568 AC_PROG_MAKE_SET
569
570 # Find some useful tools
571 AC_PROG_AWK
572 gcc_AC_PROG_LN
573 gcc_AC_PROG_LN_S
574 AC_PROG_RANLIB
575 gcc_AC_PROG_INSTALL
576
577 # See if cmp has --ignore-initial.
578 gcc_AC_PROG_CMP_IGNORE_INITIAL
579
580 # See if we have the mktemp command.
581 AC_CHECK_PROG(have_mktemp_command, mktemp, yes, no)
582
583 # Do we have a single-tree copy of texinfo?
584 if test -f $srcdir/../texinfo/Makefile.in; then
585   MAKEINFO='$(objdir)/../texinfo/makeinfo/makeinfo'
586   gcc_cv_prog_makeinfo_modern=yes
587   AC_MSG_RESULT([Using makeinfo from the unified source tree.])
588 else
589   # See if makeinfo has been installed and is modern enough
590   # that we can use it.
591   gcc_AC_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
592   [GNU texinfo.* \([0-9][0-9.]*\)],
593   [4.[2-9]*])
594 fi
595
596 if test $gcc_cv_prog_makeinfo_modern = no; then
597   AC_MSG_WARN([
598 *** Makeinfo is missing or too old.
599 *** Info documentation will not be built.])
600   BUILD_INFO=
601 else
602   BUILD_INFO=info               AC_SUBST(BUILD_INFO)
603 fi
604
605 # Is pod2man recent enough to regenerate manpages?
606 AC_MSG_CHECKING([for recent Pod::Man])
607 if (perl -e 'use 1.10 Pod::Man') >/dev/null 2>&1; then
608   AC_MSG_RESULT(yes)
609   GENERATED_MANPAGES=generated-manpages         AC_SUBST(GENERATED_MANPAGES)
610 else
611   AC_MSG_RESULT(no)
612   GENERATED_MANPAGES=
613 fi
614
615 # How about lex?
616 dnl Don't use AC_PROG_LEX; we insist on flex.
617 dnl LEXLIB is not useful in gcc.
618 if test -f $srcdir/../flex/skel.c; then
619   FLEX='$(objdir)/../flex/flex'
620 else
621   AC_CHECK_PROG(FLEX, flex, flex, ${CONFIG_SHELL-/bin/sh} ${srcdir}/../missing flex)
622 fi
623
624 # Bison?
625 # The -L switch is so bison can find its skeleton file.
626 if test -f $srcdir/../bison/bison.simple; then
627   BISON='$(objdir)/../bison/bison -L $(srcdir)/../bison/'
628 else
629   AC_CHECK_PROG(BISON, bison, bison, ${CONFIG_SHELL-/bin/sh} ${srcdir}/../missing bison)
630 fi
631
632 # --------------------
633 # Checks for C headers
634 # --------------------
635
636 AC_MSG_CHECKING(for GNU C library)
637 AC_CACHE_VAL(gcc_cv_glibc,
638 [AC_TRY_COMPILE(
639   [#include <features.h>],[
640 #if ! (defined __GLIBC__ || defined __GNU_LIBRARY__)
641 #error Not a GNU C library system
642 #endif], 
643   [gcc_cv_glibc=yes], 
644   gcc_cv_glibc=no)])
645 AC_MSG_RESULT($gcc_cv_glibc)
646 if test $gcc_cv_glibc = yes; then
647   AC_DEFINE(_GNU_SOURCE, 1, [Always define this when using the GNU C Library])
648 fi
649
650 AC_HEADER_STDC
651 AC_HEADER_TIME
652 gcc_AC_HEADER_STDBOOL
653 gcc_AC_HEADER_STRING
654 AC_HEADER_SYS_WAIT
655 AC_CHECK_HEADERS(limits.h stddef.h string.h strings.h stdlib.h time.h \
656                  fcntl.h unistd.h sys/file.h sys/time.h sys/mman.h \
657                  sys/resource.h sys/param.h sys/times.h sys/stat.h \
658                  direct.h malloc.h langinfo.h ldfcn.h locale.h wchar.h)
659
660 # Check for thread headers.
661 AC_CHECK_HEADER(thread.h, [have_thread_h=yes], [have_thread_h=])
662 AC_CHECK_HEADER(pthread.h, [have_pthread_h=yes], [have_pthread_h=])
663
664 # These tests can't be done till we know if we have limits.h.
665 gcc_AC_C_CHAR_BIT
666 AC_C_BIGENDIAN_CROSS
667
668 # --------
669 # UNSORTED
670 # --------
671
672 # Stage specific cflags for build.
673 stage1_cflags=
674 case $build in
675 vax-*-*)
676   if test x$GCC = xyes
677   then
678     stage1_cflags="-Wa,-J"
679   else
680     stage1_cflags="-J"
681   fi
682   ;;
683 powerpc-*-darwin*)
684   # The spiffy cpp-precomp chokes on some legitimate constructs in GCC
685   # sources; use -no-cpp-precomp to get to GNU cpp.
686   # Apple's GCC has bugs in designated initializer handling, so disable
687   # that too.
688   stage1_cflags="-no-cpp-precomp -DHAVE_DESIGNATED_INITIALIZERS=0"
689   ;;
690 esac
691 AC_SUBST(stage1_cflags)
692
693 # These libraries may be used by collect2.
694 # We may need a special search path to get them linked.
695 AC_CACHE_CHECK(for collect2 libraries, gcc_cv_collect2_libs,
696 [save_LIBS="$LIBS"
697 for libs in '' -lld -lmld \
698                 '-L/usr/lib/cmplrs/cc2.11 -lmld' \
699                 '-L/usr/lib/cmplrs/cc3.11 -lmld'
700 do
701         LIBS="$libs"
702         AC_TRY_LINK_FUNC(ldopen,
703                 [gcc_cv_collect2_libs="$libs"; break])
704 done
705 LIBS="$save_LIBS"
706 test -z "$gcc_cv_collect2_libs" && gcc_cv_collect2_libs='none required'])
707 case $gcc_cv_collect2_libs in
708         "none required")        ;;
709         *)      COLLECT2_LIBS=$gcc_cv_collect2_libs ;;
710 esac
711 AC_SUBST(COLLECT2_LIBS)
712
713 # When building Ada code on Alpha, we need exc_resume which is usually in
714 # -lexc.  So test for it.
715 save_LIBS="$LIBS"
716 LIBS=
717 AC_SEARCH_LIBS(exc_resume, exc)
718 GNAT_LIBEXC="$LIBS"
719 LIBS="$save_LIBS"
720 AC_SUBST(GNAT_LIBEXC)
721
722 # Some systems put ldexp and frexp in libm instead of libc; assume
723 # they're both in the same place.  jcf-dump needs them.
724 save_LIBS="$LIBS"
725 LIBS=
726 AC_SEARCH_LIBS(ldexp, m)
727 LDEXP_LIB="$LIBS"
728 LIBS="$save_LIBS"
729 AC_SUBST(LDEXP_LIB)
730
731 # Use <inttypes.h> only if it exists,
732 # doesn't clash with <sys/types.h>, and declares intmax_t.
733 AC_MSG_CHECKING(for inttypes.h)
734 AC_CACHE_VAL(gcc_cv_header_inttypes_h,
735 [AC_TRY_COMPILE(
736   [#include <sys/types.h>
737 #include <inttypes.h>],
738   [intmax_t i = -1;],
739   [gcc_cv_header_inttypes_h=yes],
740   gcc_cv_header_inttypes_h=no)])
741 AC_MSG_RESULT($gcc_cv_header_inttypes_h)
742 if test $gcc_cv_header_inttypes_h = yes; then
743   AC_DEFINE(HAVE_INTTYPES_H, 1,
744         [Define if you have a working <inttypes.h> header file.])
745 fi
746
747 dnl Disabled until we have a complete test for buggy enum bitfields.
748 dnl gcc_AC_C_ENUM_BF_UNSIGNED
749
750 AC_CHECK_FUNCS(times clock dup2 kill getrlimit setrlimit atoll atoq \
751         sysconf strsignal putc_unlocked fputc_unlocked fputs_unlocked \
752         fwrite_unlocked fprintf_unlocked getrusage nl_langinfo \
753         scandir alphasort gettimeofday mbstowcs wcswidth mmap mincore \
754         setlocale)
755
756 if test x$ac_cv_func_mbstowcs = xyes; then
757   AC_CACHE_CHECK(whether mbstowcs works, gcc_cv_func_mbstowcs_works,
758 [    AC_TRY_RUN([#include <stdlib.h>
759 int main()
760 {
761   mbstowcs(0, "", 0);
762   return 0;
763 }],
764     gcc_cv_func_mbstowcs_works=yes,
765     gcc_cv_func_mbstowcs_works=no,
766     gcc_cv_func_mbstowcs_works=yes)])
767   if test x$gcc_cv_func_mbstowcs_works = xyes; then
768     AC_DEFINE(HAVE_WORKING_MBSTOWCS, 1,
769   [Define this macro if mbstowcs does not crash when its
770    first argument is NULL.])
771   fi
772 fi
773
774 gcc_AC_CHECK_TYPE(ssize_t, int)
775
776 # Try to determine the array type of the second argument of getgroups
777 # for the target system (int or gid_t).
778 AC_TYPE_GETGROUPS
779 if test "${target}" = "${build}"; then
780   TARGET_GETGROUPS_T=$ac_cv_type_getgroups
781 else
782   case "${target}" in
783         # This condition may need some tweaking.  It should include all
784         # targets where the array type of the second argument of getgroups
785         # is int and the type of gid_t is not equivalent to int.
786         *-*-sunos* | *-*-ultrix*)
787                 TARGET_GETGROUPS_T=int
788                 ;;
789         *)
790                 TARGET_GETGROUPS_T=gid_t
791                 ;;
792   esac
793 fi
794 AC_SUBST(TARGET_GETGROUPS_T)
795
796 gcc_AC_FUNC_PRINTF_PTR
797 gcc_AC_FUNC_MMAP_BLACKLIST
798
799 case "${host}" in
800 *-*-*vms*)
801   # Under VMS, vfork works very differently than on Unix. The standard test 
802   # won't work, and it isn't easily adaptable. It makes more sense to
803   # just force it.
804   ac_cv_func_vfork_works=yes
805   ;;
806 esac
807 AC_FUNC_VFORK
808
809 AM_ICONV
810 # Until we have in-tree GNU iconv:
811 LIBICONV_DEP=
812 AC_SUBST(LIBICONV_DEP)
813
814 AM_LC_MESSAGES
815
816 # We will need to find libiberty.h and ansidecl.h
817 saved_CFLAGS="$CFLAGS"
818 CFLAGS="$CFLAGS -I${srcdir} -I${srcdir}/../include"
819 gcc_AC_CHECK_DECLS(getenv atol sbrk abort atof getcwd getwd \
820         strsignal putc_unlocked fputs_unlocked fwrite_unlocked \
821         fprintf_unlocked strstr errno vasprintf \
822         malloc realloc calloc free basename getopt clock, , ,[
823 #include "ansidecl.h"
824 #include "system.h"])
825
826 gcc_AC_CHECK_DECLS(getrlimit setrlimit getrusage, , ,[
827 #include "ansidecl.h"
828 #include "system.h"
829 #ifdef HAVE_SYS_RESOURCE_H
830 #include <sys/resource.h>
831 #endif
832 ])
833
834 AC_TRY_COMPILE([
835 #include "ansidecl.h"
836 #include "system.h"
837 #ifdef HAVE_SYS_RESOURCE_H
838 #include <sys/resource.h>
839 #endif
840 ],[rlim_t l = 0;],,[AC_DEFINE([rlim_t],[long],
841 [Define to \`long' if <sys/resource.h> doesn't define.])])
842
843 gcc_AC_CHECK_DECLS(ldgetname, , ,[
844 #include "ansidecl.h"
845 #include "system.h"
846 #ifdef HAVE_LDFCN_H
847 #include <ldfcn.h>
848 #endif
849 ])
850
851 gcc_AC_CHECK_DECLS(times, , ,[
852 #include "ansidecl.h"
853 #include "system.h"
854 #ifdef HAVE_SYS_TIMES_H
855 #include <sys/times.h>
856 #endif
857 ])
858
859 # More time-related stuff.
860 AC_CACHE_CHECK(for struct tms, ac_cv_struct_tms, [
861 AC_TRY_COMPILE([
862 #include "ansidecl.h"
863 #include "system.h"
864 #ifdef HAVE_SYS_TIMES_H
865 #include <sys/times.h>
866 #endif
867 ], [struct tms tms;], ac_cv_struct_tms=yes, ac_cv_struct_tms=no)])
868 if test $ac_cv_struct_tms = yes; then
869   AC_DEFINE(HAVE_STRUCT_TMS, 1,
870   [Define if <sys/times.h> defines struct tms.])
871 fi
872
873 # use gcc_cv_* here because this doesn't match the behavior of AC_CHECK_TYPE.
874 # revisit after autoconf 2.50.
875 AC_CACHE_CHECK(for clock_t, gcc_cv_type_clock_t, [
876 AC_TRY_COMPILE([
877 #include "ansidecl.h"
878 #include "system.h"
879 ], [clock_t x;], gcc_cv_type_clock_t=yes, gcc_cv_type_clock_t=no)])
880 if test $gcc_cv_type_clock_t = yes; then
881   AC_DEFINE(HAVE_CLOCK_T, 1,
882   [Define if <time.h> defines clock_t.])
883 fi
884
885 AC_CACHE_CHECK(for uchar, gcc_cv_type_uchar,
886 [AC_TRY_COMPILE([
887 #include "ansidecl.h"
888 #include "system.h"
889 ], 
890 [if ((uchar *)0) return 0;
891  if (sizeof(uchar)) return 0;],
892 ac_cv_type_uchar=yes, ac_cv_type_uchar=no)])
893 if test $ac_cv_type_uchar = yes; then
894   AC_DEFINE(HAVE_UCHAR, 1,
895   [Define if <sys/types.h> defines \`uchar'.])
896 fi
897
898 # Restore CFLAGS from before the gcc_AC_NEED_DECLARATIONS tests.
899 CFLAGS="$saved_CFLAGS"
900
901 gcc_AC_INITFINI_ARRAY
902
903 # mkdir takes a single argument on some systems. 
904 gcc_AC_FUNC_MKDIR_TAKES_ONE_ARG
905
906 # File extensions
907 manext='.1'
908 objext='.o'
909 AC_SUBST(manext)
910 AC_SUBST(objext)
911
912 # With Setjmp/Longjmp based exception handling.
913 AC_ARG_ENABLE(sjlj-exceptions,
914 [  --enable-sjlj-exceptions
915                           arrange to use setjmp/longjmp exception handling],
916 [sjlj=`if test $enableval = yes; then echo 1; else echo 0; fi`
917 AC_DEFINE_UNQUOTED(CONFIG_SJLJ_EXCEPTIONS, $sjlj,
918   [Define 0/1 to force the choice for exception handling model.])])
919
920 if test x$host = x$target; then
921    AC_CHECK_LIB(unwind, main, use_libunwind_default=yes, use_libunwind_default=no)
922 else
923    use_libunwind_default=no
924 fi
925 # Use libunwind based exception handling.
926 AC_ARG_ENABLE(libunwind-exceptions,
927 [  --enable-libunwind-exceptions  force use libunwind for exceptions],
928 use_libunwind_exceptions=$enableval,
929 use_libunwind_exceptions=$use_libunwind_default)
930 if test x"$use_libunwind_exceptions" = xyes; then
931    AC_DEFINE(USE_LIBUNWIND_EXCEPTIONS, 1,
932         [Define if gcc should use -lunwind.])
933 fi
934
935 # --------------------------------------------------------
936 # Build, host, and target specific configuration fragments
937 # --------------------------------------------------------
938
939 # Collect build-machine-specific information.
940 . ${srcdir}/config.build
941
942 # Collect host-machine-specific information.
943 . ${srcdir}/config.host
944
945 target_gtfiles=
946
947 # Collect target-machine-specific information.
948 . ${srcdir}/config.gcc
949
950 extra_objs="${host_extra_objs} ${extra_objs}"
951
952 # Default the target-machine variables that were not explicitly set.
953 if test x"$tm_file" = x
954 then tm_file=$cpu_type/$cpu_type.h; fi
955
956 if test x"$extra_headers" = x
957 then extra_headers=; fi
958
959 if test x$md_file = x
960 then md_file=$cpu_type/$cpu_type.md; fi
961
962 if test x$out_file = x
963 then out_file=$cpu_type/$cpu_type.c; fi
964
965 if test x"$tmake_file" = x
966 then tmake_file=$cpu_type/t-$cpu_type
967 fi
968
969 if test x"$dwarf2" = xyes
970 then tm_file="$tm_file tm-dwarf2.h"
971 fi
972
973 # Say what files are being used for the output code and MD file.
974 echo "Using \`$srcdir/config/$out_file' for machine-specific logic."
975 echo "Using \`$srcdir/config/$md_file' as machine description file."
976
977 # If any of the xm_file variables contain nonexistent files, warn
978 # about them and drop them.
979
980 bx=
981 for x in $build_xm_file; do
982   if    test -f $srcdir/config/$x
983   then      bx="$bx $x"
984   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
985   fi
986 done
987 build_xm_file="$bx"
988
989 hx=
990 for x in $host_xm_file; do
991   if    test -f $srcdir/config/$x
992   then      hx="$hx $x"
993   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
994   fi
995 done
996 host_xm_file="$hx"
997
998 tx=
999 for x in $xm_file; do
1000   if    test -f $srcdir/config/$x
1001   then      tx="$tx $x"
1002   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1003   fi
1004 done
1005 xm_file="$tx"
1006
1007 count=a
1008 for f in $tm_file; do
1009         count=${count}x
1010 done
1011 if test $count = ax; then
1012         echo "Using \`$srcdir/config/$tm_file' as target machine macro file."
1013 else
1014         echo "Using the following target machine macro files:"
1015         for f in $tm_file; do
1016                 echo "  $srcdir/config/$f"
1017         done
1018 fi
1019
1020 if test x$need_64bit_hwint = xyes; then
1021         AC_DEFINE(NEED_64BIT_HOST_WIDE_INT, 1,
1022 [Define to 1 if HOST_WIDE_INT must be 64 bits wide (see hwint.h).])
1023 fi
1024
1025 count=a
1026 for f in $host_xm_file; do
1027         count=${count}x
1028 done
1029 if test $count = a; then
1030         :
1031 elif test $count = ax; then
1032         echo "Using \`$srcdir/config/$host_xm_file' as host machine macro file."
1033 else
1034         echo "Using the following host machine macro files:"
1035         for f in $host_xm_file; do
1036                 echo "  $srcdir/config/$f"
1037         done
1038 fi
1039 echo "Using ${out_host_hook_obj} for host machine hooks."
1040
1041 if test "$host_xm_file" != "$build_xm_file"; then
1042         count=a
1043         for f in $build_xm_file; do
1044                 count=${count}x
1045         done
1046         if test $count = a; then
1047                 :
1048         elif test $count = ax; then
1049                 echo "Using \`$srcdir/config/$build_xm_file' as build machine macro file."
1050         else
1051                 echo "Using the following build machine macro files:"
1052                 for f in $build_xm_file; do
1053                         echo "  $srcdir/config/$f"
1054                 done
1055         fi
1056 fi
1057
1058 # Check if a valid thread package
1059 case ${enable_threads_flag} in
1060   "" | no)
1061     # No threads
1062     target_thread_file='single'
1063     ;;
1064   yes)
1065     # default
1066     target_thread_file='single'
1067     ;;
1068   aix | dce | gnat | irix | posix | rtems | \
1069   single | solaris | vxworks | win32 )
1070     target_thread_file=${enable_threads_flag}
1071     ;;
1072   *)
1073     echo "${enable_threads_flag} is an unknown thread package" 1>&2
1074     exit 1
1075     ;;
1076 esac
1077
1078 if test x${thread_file} = x; then
1079   # No thread file set by target-specific clauses in config.gcc,
1080   # so use file chosen by default logic above
1081   thread_file=${target_thread_file}
1082 fi
1083
1084 if test x$enable___cxa_atexit = xyes || \
1085    test x$enable___cxa_atexit = x -a x$default_use_cxa_atexit = xyes; then
1086   AC_DEFINE(DEFAULT_USE_CXA_ATEXIT, 1,
1087   [Define if you want to use __cxa_atexit, rather than atexit, to
1088    register C++ destructors for local statics and global objects.
1089    This is essential for fully standards-compliant handling of
1090    destructors, but requires __cxa_atexit in libc.])
1091 fi
1092
1093 # Look for a file containing extra machine modes.
1094 if test -n "$extra_modes" && test -f $srcdir/config/$extra_modes; then
1095   extra_modes_file='$(srcdir)'/config/${extra_modes}
1096   AC_SUBST(extra_modes_file)
1097   AC_DEFINE_UNQUOTED(EXTRA_MODES_FILE, "config/$extra_modes",
1098   [Define to the name of a file containing a list of extra machine modes
1099    for this architecture.])
1100 fi
1101
1102 # auto-host.h is the file containing items generated by autoconf and is
1103 # the first file included by config.h.
1104 # If host=build, it is correct to have bconfig include auto-host.h
1105 # as well.  If host!=build, we are in error and need to do more 
1106 # work to find out the build config parameters.
1107 if test x$host = x$build
1108 then
1109         build_auto=auto-host.h
1110         FORBUILD=..
1111 else
1112         # We create a subdir, then run autoconf in the subdir.
1113         # To prevent recursion we set host and build for the new
1114         # invocation of configure to the build for this invocation
1115         # of configure. 
1116         tempdir=build.$$
1117         rm -rf $tempdir
1118         mkdir $tempdir
1119         cd $tempdir
1120         case ${srcdir} in
1121         /* | [A-Za-z]:[\\/]* ) realsrcdir=${srcdir};;
1122         *) realsrcdir=../${srcdir};;
1123         esac
1124         saved_CFLAGS="${CFLAGS}"
1125         CC="${CC_FOR_BUILD}" CFLAGS="${CFLAGS_FOR_BUILD}" \
1126         ${realsrcdir}/configure \
1127                 --target=$target_alias --host=$build_alias --build=$build_alias
1128         CFLAGS="${saved_CFLAGS}"
1129
1130         # We just finished tests for the build machine, so rename
1131         # the file auto-build.h in the gcc directory.
1132         mv auto-host.h ../auto-build.h
1133         cd ..
1134         rm -rf $tempdir
1135         build_auto=auto-build.h
1136         FORBUILD=../${build_subdir}
1137 fi
1138 AC_SUBST(FORBUILD)
1139
1140 tm_file="${tm_file} defaults.h"
1141 tm_p_file="${tm_p_file} tm-preds.h"
1142 host_xm_file="auto-host.h ansidecl.h ${host_xm_file}"
1143 build_xm_file="${build_auto} ansidecl.h ${build_xm_file}"
1144 # We don't want ansidecl.h in target files, write code there in ISO/GNU C.
1145 # put this back in temporarily.
1146 xm_file="ansidecl.h ${xm_file}"
1147
1148 # --------
1149 # UNSORTED
1150 # --------
1151
1152 # Get the version trigger filename from the toplevel
1153 if test "${with_gcc_version_trigger+set}" = set; then
1154         gcc_version_trigger=$with_gcc_version_trigger
1155 else
1156         gcc_version_trigger=${srcdir}/version.c
1157 fi
1158 changequote(,)dnl
1159 gcc_version_full=`grep version_string ${gcc_version_trigger} | sed -e 's/.*"\([^"]*\)".*/\1/'`
1160 gcc_version=`echo ${gcc_version_full} | sed -e 's/\([^ ]*\) .*/\1/'`
1161
1162 # Compile in configure arguments.
1163 if test -f configargs.h ; then
1164         # Being re-configured.
1165         gcc_config_arguments=`grep configuration_arguments configargs.h | sed -e 's/.*"\([^"]*\)".*/\1/'`
1166         gcc_config_arguments="$gcc_config_arguments : (reconfigured) $TOPLEVEL_CONFIGURE_ARGUMENTS"
1167 else
1168         gcc_config_arguments="$TOPLEVEL_CONFIGURE_ARGUMENTS"
1169 fi
1170
1171 # Double all backslashes and backslash all quotes to turn
1172 # gcc_config_arguments into a C string.
1173 sed -e 's/\\/\\\\/g; s/"/\\"/g' <<EOF >conftest.out
1174 $gcc_config_arguments
1175 EOF
1176 gcc_config_arguments_str=`cat conftest.out`
1177 rm -f conftest.out
1178
1179 cat > configargs.h <<EOF
1180 /* Generated automatically. */
1181 static const char configuration_arguments[] = "$gcc_config_arguments_str";
1182 static const char thread_model[] = "$thread_file";
1183
1184 static const struct {
1185   const char *name, *value;
1186 } configure_default_options[] = $configure_default_options;
1187 EOF
1188 changequote([,])dnl
1189
1190 # Internationalization
1191 PACKAGE=gcc
1192 VERSION="$gcc_version"
1193 AC_SUBST(PACKAGE)
1194 AC_SUBST(VERSION)
1195
1196 ZW_GNU_GETTEXT_SISTER_DIR
1197
1198 # If LIBINTL contains LIBICONV, then clear LIBICONV so we don't get
1199 # -liconv on the link line twice.
1200 case "$LIBINTL" in *$LIBICONV*)
1201         LIBICONV= ;;
1202 esac
1203
1204 # Windows32 Registry support for specifying GCC installation paths.
1205 AC_ARG_ENABLE(win32-registry,
1206 [  --disable-win32-registry
1207                           disable lookup of installation paths in the
1208                           Registry on Windows hosts
1209   --enable-win32-registry enable registry lookup (default)
1210   --enable-win32-registry=KEY
1211                           use KEY instead of GCC version as the last portion
1212                           of the registry key],,)
1213 case $host_os in
1214         win32 | pe | cygwin* | mingw32* | uwin*)
1215 AC_MSG_CHECKING(whether windows registry support is requested)
1216 if test "x$enable_win32_registry" != xno; then
1217   AC_DEFINE(ENABLE_WIN32_REGISTRY, 1,
1218 [Define to 1 if installation paths should be looked up in Windows32
1219    Registry. Ignored on non windows32 hosts.])
1220   AC_MSG_RESULT(yes)
1221   AC_SEARCH_LIBS(RegOpenKeyExA, advapi32)
1222 else
1223   AC_MSG_RESULT(no)
1224 fi
1225
1226 # Check if user specified a different registry key.
1227 case "x${enable_win32_registry}" in
1228 x | xyes)
1229   # default.
1230   gcc_cv_win32_registry_key="$VERSION"
1231   ;;
1232 xno)
1233   # no registry lookup.
1234   gcc_cv_win32_registry_key=''
1235   ;;
1236 *)
1237   # user-specified key.
1238   gcc_cv_win32_registry_key="$enable_win32_registry"
1239   ;;
1240 esac
1241
1242 if test "x$enable_win32_registry" != xno; then
1243   AC_MSG_CHECKING(registry key on windows hosts)
1244   AC_DEFINE_UNQUOTED(WIN32_REGISTRY_KEY, "$gcc_cv_win32_registry_key",
1245         [Define to be the last portion of registry key on windows hosts.])
1246   AC_MSG_RESULT($gcc_cv_win32_registry_key)
1247 fi
1248 ;;
1249 esac
1250
1251 # Get an absolute path to the GCC top-level source directory
1252 holddir=`${PWDCMD-pwd}`
1253 cd $srcdir
1254 topdir=`${PWDCMD-pwd}`
1255 cd $holddir
1256
1257 # Conditionalize the makefile for this host machine.
1258 xmake_file=
1259 for f in ${host_xmake_file}
1260 do
1261         if test -f ${srcdir}/config/$f
1262         then
1263                 xmake_file="${xmake_file} \$(srcdir)/config/$f"
1264         fi
1265 done
1266
1267 # Conditionalize the makefile for this target machine.
1268 tmake_file_=
1269 for f in ${tmake_file}
1270 do
1271         if test -f ${srcdir}/config/$f
1272         then
1273                 tmake_file_="${tmake_file_} \$(srcdir)/config/$f"
1274         fi
1275 done
1276 tmake_file="${tmake_file_}"
1277
1278 symbolic_link='ln -s'
1279
1280 # If the host doesn't support symlinks, modify CC in
1281 # FLAGS_TO_PASS so CC="stage1/xgcc -Bstage1/" works.
1282 # Otherwise, we can use "CC=$(CC)".
1283 rm -f symtest.tem
1284 if $symbolic_link $srcdir/gcc.c symtest.tem 2>/dev/null
1285 then
1286         cc_set_by_configure="\$(CC)"
1287         quoted_cc_set_by_configure="\$(CC)"
1288         stage_prefix_set_by_configure="\$(STAGE_PREFIX)"
1289         quoted_stage_prefix_set_by_configure="\$(STAGE_PREFIX)"
1290 else
1291         rm -f symtest.tem
1292         if cp -p $srcdir/gcc.c symtest.tem 2>/dev/null
1293         then
1294                 symbolic_link="cp -p"
1295         else
1296                 symbolic_link="cp"
1297         fi
1298         cc_set_by_configure="\`case '\$(CC)' in stage*) echo '\$(CC)' | sed -e 's|stage|../stage|g';; *) echo '\$(CC)';; esac\`"
1299         quoted_cc_set_by_configure="\\\`case '\\\$(CC)' in stage*) echo '\\\$(CC)' | sed -e 's|stage|../stage|g';; *) echo '\\\$(CC)';; esac\\\`"
1300         stage_prefix_set_by_configure="\`case '\$(STAGE_PREFIX)' in stage*) echo '\$(STAGE_PREFIX)' | sed -e 's|stage|../stage|g';; *) echo '\$(STAGE_PREFIX)';; esac\`"
1301         quoted_stage_prefix_set_by_configure="\\\`case '\\\$(STAGE_PREFIX)' in stage*) echo '\\\$(STAGE_PREFIX)' | sed -e 's|stage|../stage|g';; *) echo '\\\$(STAGE_PREFIX)';; esac\\\`"
1302 fi
1303 rm -f symtest.tem
1304
1305 out_object_file=`basename $out_file .c`.o
1306
1307 tm_file_list=
1308 tm_include_list=
1309 for f in $tm_file; do
1310   case $f in
1311     defaults.h )
1312        tm_file_list="${tm_file_list} \$(srcdir)/$f"
1313        tm_include_list="${tm_include_list} $f"
1314        ;;
1315     * )
1316        tm_file_list="${tm_file_list} \$(srcdir)/config/$f"
1317        tm_include_list="${tm_include_list} config/$f"
1318        ;;
1319   esac
1320 done
1321
1322 tm_p_file_list=
1323 tm_p_include_list=
1324 for f in $tm_p_file; do
1325   case $f in
1326     tm-preds.h )
1327        tm_p_file_list="${tm_p_file_list} $f"
1328        tm_p_include_list="${tm_p_include_list} $f"
1329        ;;
1330     * )
1331        tm_p_file_list="${tm_p_file_list} \$(srcdir)/config/$f"
1332        tm_p_include_list="${tm_p_include_list} config/$f"
1333   esac
1334 done
1335
1336 xm_file_list=
1337 xm_include_list=
1338 for f in $xm_file; do
1339   case $f in
1340     ansidecl.h )
1341        xm_file_list="${xm_file_list} \$(srcdir)/../include/$f"
1342        xm_include_list="${xm_include_list} $f"
1343        ;;
1344     auto-host.h )
1345        xm_file_list="${xm_file_list} $f"
1346        xm_include_list="${xm_include_list} $f"
1347        ;;
1348     * )
1349        xm_file_list="${xm_file_list} \$(srcdir)/config/$f"
1350        xm_include_list="${xm_include_list} config/$f"
1351        ;;
1352   esac
1353 done
1354
1355 host_xm_file_list=
1356 host_xm_include_list=
1357 for f in $host_xm_file; do
1358   case $f in
1359     ansidecl.h )
1360        host_xm_file_list="${host_xm_file_list} \$(srcdir)/../include/$f"
1361        host_xm_include_list="${host_xm_include_list} $f"
1362        ;;
1363     auto-host.h )
1364        host_xm_file_list="${host_xm_file_list} $f"
1365        host_xm_include_list="${host_xm_include_list} $f"
1366        ;;
1367     * )
1368        host_xm_file_list="${host_xm_file_list} \$(srcdir)/config/$f"
1369        host_xm_include_list="${host_xm_include_list} config/$f"
1370        ;;
1371   esac
1372 done
1373
1374 build_xm_file_list=
1375 for f in $build_xm_file; do
1376   case $f in
1377     ansidecl.h )
1378        build_xm_file_list="${build_xm_file_list} \$(srcdir)/../include/$f"
1379        build_xm_include_list="${build_xm_include_list} $f"
1380        ;;
1381     auto-build.h | auto-host.h )
1382        build_xm_file_list="${build_xm_file_list} $f"
1383        build_xm_include_list="${build_xm_include_list} $f"
1384        ;;
1385     * )
1386        build_xm_file_list="${build_xm_file_list} \$(srcdir)/config/$f"
1387        build_xm_include_list="${build_xm_include_list} config/$f"
1388        ;;
1389   esac
1390 done
1391
1392 # Define macro CROSS_COMPILE in compilation if this is a cross-compiler.
1393 # Also use all.cross instead of all.internal and adjust SYSTEM_HEADER_DIR.
1394 CROSS=                                          AC_SUBST(CROSS)
1395 ALL=all.internal                                AC_SUBST(ALL)
1396 SYSTEM_HEADER_DIR='$(NATIVE_SYSTEM_HEADER_DIR)' AC_SUBST(SYSTEM_HEADER_DIR)
1397 if test x$host != x$target
1398 then
1399         CROSS="-DCROSS_COMPILE"
1400         ALL=all.cross
1401         SYSTEM_HEADER_DIR='$(CROSS_SYSTEM_HEADER_DIR)'
1402         case "$host","$target" in
1403         # Darwin crosses can use the host system's libraries and headers,
1404         # because of the fat library support.  Of course, it must be the
1405         # same version of Darwin on both sides.  Allow the user to
1406         # just say --target=foo-darwin without a version number to mean
1407         # "the version on this system".
1408             *-*-darwin*,*-*-darwin*)
1409                 hostos=`echo $host | sed 's/.*-darwin/darwin/'`
1410                 targetos=`echo $target | sed 's/.*-darwin/darwin/'`
1411                 if test $hostos = $targetos -o $targetos = darwin ; then
1412                     CROSS=
1413                     SYSTEM_HEADER_DIR='$(NATIVE_SYSTEM_HEADER_DIR)'
1414                     with_headers=yes
1415                 fi
1416                 ;;
1417
1418             i?86-*-*,x86_64-*-* \
1419             | powerpc*-*-*,powerpc64*-*-*)
1420                 CROSS="$CROSS -DNATIVE_CROSS" ;;
1421         esac
1422 elif test "x$TARGET_SYSTEM_ROOT" != x; then
1423         # This is just $(TARGET_SYSTEM_ROOT)$(NATIVE_SYSTEM_HEADER_DIR)
1424         SYSTEM_HEADER_DIR='$(CROSS_SYSTEM_HEADER_DIR)'
1425 fi
1426
1427 # If this is a cross-compiler that does not
1428 # have its own set of headers then define
1429 # inhibit_libc
1430
1431 # If this is using newlib, without having the headers available now,
1432 # then define inhibit_libc in LIBGCC2_CFLAGS.
1433 # This prevents libgcc2 from containing any code which requires libc
1434 # support.
1435 inhibit_libc=
1436 if { { test x$host != x$target && test "x$with_sysroot" = x ; } ||
1437        test x$with_newlib = xyes ; } &&
1438      { test "x$with_headers" = x || test "x$with_headers" = xno ; } ; then
1439        inhibit_libc=-Dinhibit_libc
1440 fi
1441 AC_SUBST(inhibit_libc)
1442
1443 # When building gcc with a cross-compiler, we need to adjust things so
1444 # that the generator programs are still built with the native compiler.
1445 # Also, we cannot run fixincludes or fix-header.
1446
1447 # These are the normal (build=host) settings:
1448 BUILD_PREFIX=                   AC_SUBST(BUILD_PREFIX)
1449 BUILD_PREFIX_1=ignore-          AC_SUBST(BUILD_PREFIX_1)
1450 CC_FOR_BUILD='$(CC)'            AC_SUBST(CC_FOR_BUILD)
1451 BUILD_CFLAGS='$(ALL_CFLAGS)'    AC_SUBST(BUILD_CFLAGS)
1452
1453 STMP_FIXINC=stmp-fixinc         AC_SUBST(STMP_FIXINC)
1454
1455 # Possibly disable fixproto, on a per-target basis.
1456 case ${use_fixproto} in
1457   no)
1458     STMP_FIXPROTO=
1459     ;;
1460   yes)
1461     STMP_FIXPROTO=stmp-fixproto
1462     ;;
1463 esac
1464 AC_SUBST(STMP_FIXPROTO)
1465
1466 # And these apply if build != host, or we are generating coverage data
1467 if test x$build != x$host || test "x$coverage_flags" != x
1468 then
1469     BUILD_PREFIX=build-
1470     BUILD_PREFIX_1=build-
1471     BUILD_CFLAGS='$(INTERNAL_CFLAGS) $(T_CFLAGS) $(CFLAGS_FOR_BUILD)'
1472
1473     if test "x$TARGET_SYSTEM_ROOT" = x; then
1474         STMP_FIXINC=
1475         STMP_FIXPROTO=
1476     fi
1477 fi
1478
1479 # Expand extra_headers to include complete path.
1480 # This substitutes for lots of t-* files.
1481 extra_headers_list=
1482 # Prepend $(srcdir)/config/${cpu_type}/ to every entry in extra_headers.
1483 for file in ${extra_headers} ; do
1484   extra_headers_list="${extra_headers_list} \$(srcdir)/config/${cpu_type}/${file}"
1485 done
1486
1487 # Add a definition of USE_COLLECT2 if system wants one.
1488 case $use_collect2 in
1489   no) use_collect2= ;;
1490   "") ;;
1491   *) 
1492     host_xm_defines="${host_xm_defines} USE_COLLECT2"
1493     xm_defines="${xm_defines} USE_COLLECT2"
1494     ;;
1495 esac
1496
1497 # Identify the assembler which will work hand-in-glove with the newly
1498 # built GCC, so that we can examine its features.  This is the assembler
1499 # which will be driven by the driver program.
1500 #
1501 # If build != host, and we aren't building gas in-tree, we identify a
1502 # build->target assembler and hope that it will have the same features
1503 # as the host->target assembler we'll be using.
1504 AC_MSG_CHECKING(what assembler to use)
1505 in_tree_gas=no
1506 gcc_cv_as=
1507 gcc_cv_gas_major_version=
1508 gcc_cv_gas_minor_version=
1509 gcc_cv_as_gas_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/gas
1510 if test -x "$DEFAULT_ASSEMBLER"; then
1511         gcc_cv_as="$DEFAULT_ASSEMBLER"
1512 elif test -x "$AS"; then
1513         gcc_cv_as="$AS"
1514 elif test -x as$host_exeext; then
1515         # Build using assembler in the current directory.
1516         gcc_cv_as=./as$host_exeext
1517 elif test -f $gcc_cv_as_gas_srcdir/configure.in \
1518      && test -f ../gas/Makefile; then
1519   # Single tree build which includes gas.
1520   in_tree_gas=yes
1521   _gcc_COMPUTE_GAS_VERSION
1522   rm -f as$host_exeext
1523   $symbolic_link ../gas/as-new$host_exeext as$host_exeext 2>/dev/null
1524   in_tree_gas_is_elf=no
1525   if grep 'obj_format = elf' ../gas/Makefile > /dev/null \
1526      || (grep 'obj_format = multi' ../gas/Makefile \
1527          && grep 'extra_objects =.* obj-elf' ../gas/Makefile) > /dev/null
1528   then
1529     in_tree_gas_is_elf=yes
1530   fi
1531 fi
1532
1533 if test "x$gcc_cv_as" = x; then
1534         # Search the same directories that the installed compiler will
1535         # search.  Else we may find the wrong assembler and lose.  If we
1536         # do not find a suitable assembler binary, then try the user's
1537         # path.
1538         #
1539         # Also note we have to check MD_EXEC_PREFIX before checking the
1540         # user's path.  Unfortunately, there is no good way to get at the
1541         # value of MD_EXEC_PREFIX here.  So we do a brute force search
1542         # through all the known MD_EXEC_PREFIX values.  Ugh.  This needs
1543         # to be fixed as part of the make/configure rewrite too.
1544
1545         if test "x$exec_prefix" = xNONE; then
1546                 if test "x$prefix" = xNONE; then
1547                         test_prefix=/usr/local
1548                 else
1549                         test_prefix=$prefix
1550                 fi
1551         else
1552                 test_prefix=$exec_prefix
1553         fi
1554
1555         # If the loop below does not find an assembler, then use whatever
1556         # one we can find in the users's path.
1557         # user's path.
1558         if test "x$program_prefix" != xNONE; then
1559                 gcc_cv_as=${program_prefix}as$host_exeext
1560         else
1561                 gcc_cv_as=`echo as | sed ${program_transform_name}`$host_exeext
1562         fi
1563
1564         test_dirs="$test_prefix/lib/gcc-lib/$target_alias/$gcc_version \
1565                    $test_prefix/lib/gcc-lib/$target_alias \
1566                    /usr/lib/gcc/$target_alias/$gcc_version \
1567                    /usr/lib/gcc/$target_alias \
1568                    $test_prefix/$target_alias/bin/$target_alias/$gcc_version \
1569                    $test_prefix/$target_alias/bin"
1570
1571         if test x$host = x$target; then
1572             test_dirs="$test_dirs \
1573                    /usr/libexec \
1574                    /usr/ccs/gcc \
1575                    /usr/ccs/bin \
1576                    /udk/usr/ccs/bin \
1577                    /bsd43/usr/lib/cmplrs/cc \
1578                    /usr/cross64/usr/bin \
1579                    /usr/lib/cmplrs/cc \
1580                    /sysv/usr/lib/cmplrs/cc \
1581                    /svr4/usr/lib/cmplrs/cc \
1582                    /usr/bin"
1583         fi
1584
1585         for dir in $test_dirs; do
1586                 if test -x $dir/as$host_exeext; then
1587                         gcc_cv_as=$dir/as$host_exeext
1588                         break;
1589                 fi
1590         done
1591 fi
1592 case $in_tree_gas in
1593   yes)
1594     AC_MSG_RESULT("newly built gas")
1595     ;;
1596   no)
1597     AC_MSG_RESULT($gcc_cv_as)
1598     ;;
1599 esac
1600
1601 # Identify the linker which will work hand-in-glove with the newly
1602 # built GCC, so that we can examine its features.  This is the linker
1603 # which will be driven by the driver program.
1604 #
1605 # If build != host, and we aren't building gas in-tree, we identify a
1606 # build->target linker and hope that it will have the same features
1607 # as the host->target linker we'll be using.
1608 AC_MSG_CHECKING(what linker to use)
1609 in_tree_ld=no
1610 gcc_cv_ld=
1611 gcc_cv_gld_major_version=
1612 gcc_cv_gld_minor_version=
1613 gcc_cv_ld_gld_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/ld
1614 gcc_cv_ld_bfd_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/bfd
1615 if test -x "$DEFAULT_LINKER"; then
1616         gcc_cv_ld="$DEFAULT_LINKER"
1617 elif test -x "$LD"; then
1618         gcc_cv_ld="$LD"
1619 elif test -x collect-ld$host_exeext; then
1620         # Build using linker in the current directory.
1621         gcc_cv_ld=./collect-ld$host_exeext
1622 elif test -f $gcc_cv_ld_gld_srcdir/configure.in \
1623      && test -f ../ld/Makefile; then
1624         # Single tree build which includes ld.
1625         in_tree_ld=yes
1626         in_tree_ld_is_elf=no
1627         if (grep 'EMUL = .*elf' ../ld/Makefile \
1628             || grep 'EMUL = .*linux' ../ld/Makefile) > /dev/null; then
1629           in_tree_ld_is_elf=yes
1630         fi
1631         for f in $gcc_cv_ld_bfd_srcdir/configure $gcc_cv_ld_gld_srcdir/configure $gcc_cv_ld_gld_srcdir/configure.in $gcc_cv_ld_gld_srcdir/Makefile.in
1632         do
1633 changequote(,)dnl
1634                 gcc_cv_gld_version=`grep '^VERSION=[0-9]*\.[0-9]*' $f`
1635 changequote([,])dnl
1636                 if test x$gcc_cv_gld_version != x; then
1637                         break
1638                 fi
1639         done
1640 changequote(,)dnl
1641         gcc_cv_gld_major_version=`expr "$gcc_cv_gld_version" : "VERSION=\([0-9]*\)"`
1642         gcc_cv_gld_minor_version=`expr "$gcc_cv_gld_version" : "VERSION=[0-9]*\.\([0-9]*\)"`
1643 changequote([,])dnl
1644         rm -f collect-ld$host_exeext
1645         $symbolic_link ../ld/ld-new$host_exeext collect-ld$host_exeext \
1646                 2>/dev/null
1647 fi
1648
1649 if test "x$gcc_cv_ld" = x; then
1650         # Search the same directories that the installed compiler will
1651         # search.  Else we may find the wrong linker and lose.  If we
1652         # do not find a suitable linker binary, then try the user's
1653         # path.
1654         #
1655         # Also note we have to check MD_EXEC_PREFIX before checking the
1656         # user's path.  Unfortunately, there is no good way to get at the
1657         # value of MD_EXEC_PREFIX here.  So we do a brute force search
1658         # through all the known MD_EXEC_PREFIX values.  Ugh.  This needs
1659         # to be fixed as part of the make/configure rewrite too.
1660
1661         if test "x$exec_prefix" = xNONE; then
1662                 if test "x$prefix" = xNONE; then
1663                         test_prefix=/usr/local
1664                 else
1665                         test_prefix=$prefix
1666                 fi
1667         else
1668                 test_prefix=$exec_prefix
1669         fi
1670
1671         # If the loop below does not find an linker, then use whatever
1672         # one we can find in the users's path.
1673         # user's path.
1674         if test "x$program_prefix" != xNONE; then
1675                 gcc_cv_ld=${program_prefix}ld$host_exeext
1676         else
1677                 gcc_cv_ld=`echo ld | sed ${program_transform_name}`$host_exeext
1678         fi
1679
1680         test_dirs="$test_prefix/lib/gcc-lib/$target_alias/$gcc_version \
1681                    $test_prefix/lib/gcc-lib/$target_alias \
1682                    /usr/lib/gcc/$target_alias/$gcc_version \
1683                    /usr/lib/gcc/$target_alias \
1684                    $test_prefix/$target_alias/bin/$target_alias/$gcc_version \
1685                    $test_prefix/$target_alias/bin"
1686
1687         if test x$host = x$target; then
1688             test_dirs="$test_dirs \
1689                    /usr/libexec \
1690                    /usr/ccs/gcc \
1691                    /usr/ccs/bin \
1692                    /udk/usr/ccs/bin \
1693                    /bsd43/usr/lib/cmplrs/cc \
1694                    /usr/cross64/usr/bin \
1695                    /usr/lib/cmplrs/cc \
1696                    /sysv/usr/lib/cmplrs/cc \
1697                    /svr4/usr/lib/cmplrs/cc \
1698                    /usr/bin"
1699         fi
1700
1701         for dir in $test_dirs; do
1702                 if test -x $dir/ld$host_exeext; then
1703                         gcc_cv_ld=$dir/ld$host_exeext
1704                         break;
1705                 fi
1706         done
1707 fi
1708 case $in_tree_ld in
1709   yes)
1710     AC_MSG_RESULT("newly built ld")
1711     ;;
1712   no)
1713     AC_MSG_RESULT($gcc_cv_ld)
1714     ;;
1715 esac
1716
1717 # Figure out what nm we will be using.
1718 gcc_cv_binutils_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/binutils
1719 AC_MSG_CHECKING(what nm to use)
1720 in_tree_nm=no
1721 if test -x nm$host_exeext; then
1722         gcc_cv_nm=./nm$host_exeext
1723 elif test -f $gcc_cv_binutils_srcdir/configure.in \
1724      && test -f ../binutils/Makefile; then
1725         # Single tree build which includes binutils.
1726         in_tree_nm=yes
1727         gcc_cv_nm=./nm$host_exeext
1728         rm -f nm$host_exeext
1729         $symbolic_link ../binutils/nm-new$host_exeext nm$host_exeext 2>/dev/null
1730 elif test "x$program_prefix" != xNONE; then
1731         gcc_cv_nm=${program_prefix}nm$host_exeext
1732 else
1733         gcc_cv_nm=`echo nm | sed ${program_transform_name}`$host_exeext
1734 fi
1735 case $in_tree_nm in
1736   yes) AC_MSG_RESULT("newly built nm") ;;
1737   no)  AC_MSG_RESULT($gcc_cv_nm) ;;
1738 esac
1739
1740 # Figure out what objdump we will be using.
1741 AC_MSG_CHECKING(what objdump to use)
1742 in_tree_objdump=no
1743 if test -x objdump$host_exeext; then
1744         gcc_cv_objdump=./objdump$host_exeext
1745 elif test -f $gcc_cv_binutils_srcdir/configure.in \
1746      && test -f ../binutils/Makefile; then
1747         # Single tree build which includes binutils.
1748         in_tree_objdump=yes
1749         gcc_cv_objdump=./objdump$host_exeext
1750         rm -f objdump$host_exeext
1751         $symbolic_link ../binutils/objdump$host_exeext \
1752                 objdump$host_exeext 2>/dev/null
1753 elif test "x$program_prefix" != xNONE; then
1754         gcc_cv_objdump=${program_prefix}objdump$host_exeext
1755 else
1756         gcc_cv_objdump=`echo objdump | \
1757                 sed ${program_transform_name}`$host_exeext
1758 fi
1759 case $in_tree_objdump in
1760   yes) AC_MSG_RESULT("newly built objdump") ;;
1761   no)  AC_MSG_RESULT($gcc_cv_objdump) ;;
1762 esac
1763
1764 # Figure out what assembler alignment features are present.
1765 gcc_GAS_CHECK_FEATURE([.balign and .p2align], gcc_cv_as_balign_and_p2align,
1766  [2,6,0],,
1767 [.balign 4
1768 .p2align 2],,
1769 [AC_DEFINE(HAVE_GAS_BALIGN_AND_P2ALIGN, 1,
1770   [Define if your assembler supports .balign and .p2align.])])
1771
1772 gcc_GAS_CHECK_FEATURE([.p2align with maximum skip], gcc_cv_as_max_skip_p2align,
1773  [2,8,0],,
1774  [.p2align 4,,7],,
1775 [AC_DEFINE(HAVE_GAS_MAX_SKIP_P2ALIGN, 1,
1776   [Define if your assembler supports specifying the maximum number
1777    of bytes to skip when using the GAS .p2align command.])])
1778
1779 gcc_GAS_CHECK_FEATURE([working .subsection -1], gcc_cv_as_subsection_m1,
1780  [elf,2,9,0],,
1781  [conftest_label1: .word 0
1782 .subsection -1
1783 conftest_label2: .word 0
1784 .previous],
1785  [if test x$gcc_cv_nm != x; then
1786     $gcc_cv_nm conftest.o | grep conftest_label1 > conftest.nm1
1787     $gcc_cv_nm conftest.o | grep conftest_label2 | sed -e 's/label2/label1/' > conftest.nm2
1788     if cmp conftest.nm1 conftest.nm2 > /dev/null 2>&1
1789     then :
1790     else gcc_cv_as_subsection_m1=yes
1791     fi
1792     rm -f conftest.nm1 conftest.nm2
1793   fi],
1794  [AC_DEFINE(HAVE_GAS_SUBSECTION_ORDERING, 1,
1795   [Define if your assembler supports .subsection and .subsection -1 starts
1796    emitting at the beginning of your section.])])
1797
1798 gcc_GAS_CHECK_FEATURE([.weak], gcc_cv_as_weak,
1799  [2,2,0],,
1800  [      .weak foobar],,
1801 [AC_DEFINE(HAVE_GAS_WEAK, 1, [Define if your assembler supports .weak.])])
1802
1803 # .hidden needs to be supported in both the assembler and the linker,
1804 # because GNU LD versions before 2.12.1 have buggy support for STV_HIDDEN.
1805 # This is irritatingly difficult to feature test for; we have to check the
1806 # date string after the version number.  If we've got an in-tree
1807 # ld, we don't know its patchlevel version, so we set the baseline at 2.13
1808 # to be safe.
1809 # The gcc_GAS_CHECK_FEATURE call just sets a cache variable.
1810 gcc_GAS_CHECK_FEATURE([.hidden], gcc_cv_as_hidden,
1811  [elf,2,13,0],,
1812 [       .hidden foobar
1813 foobar:])
1814
1815 AC_CACHE_CHECK(linker for .hidden support, gcc_cv_ld_hidden,
1816 [if test $in_tree_ld = yes ; then
1817   gcc_cv_ld_hidden=no
1818   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 13 -o "$gcc_cv_gld_major_version" -gt 2 \
1819      && test $in_tree_ld_is_elf = yes; then
1820      gcc_cv_ld_hidden=yes
1821   fi
1822 else
1823   gcc_cv_ld_hidden=yes
1824   ld_ver=`$gcc_cv_ld --version 2>/dev/null | sed 1q`
1825   if echo "$ld_ver" | grep GNU > /dev/null; then
1826 changequote(,)dnl
1827     ld_vers=`echo $ld_ver | sed -n \
1828         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\)$,\1,p' \
1829         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\)$,\1,p' \
1830         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\)$,\1,p' \
1831         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\)[  ].*$,\1,p' \
1832         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\)[     ].*$,\1,p' \
1833         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\)[        ].*$,\1,p'`
1834     ld_date=`echo $ld_ver | sed -n 's,^.*\([2-9][0-9][0-9][0-9]\)[-]*\([01][0-9]\)[-]*\([0-3][0-9]\).*$,\1\2\3,p'`
1835     if test 0"$ld_date" -lt 20020404; then
1836       if test -n "$ld_date"; then
1837         # If there was date string, but was earlier than 2002-04-04, fail
1838         gcc_cv_ld_hidden=no
1839       elif test -z "$ld_vers"; then
1840         # If there was no date string nor ld version number, something is wrong
1841         gcc_cv_ld_hidden=no
1842       else
1843         ld_vers_major=`expr "$ld_vers" : '\([0-9]*\)'`
1844         ld_vers_minor=`expr "$ld_vers" : '[0-9]*\.\([0-9]*\)'`
1845         ld_vers_patch=`expr "$ld_vers" : '[0-9]*\.[0-9]*\.\([0-9]*\)'`
1846         test -z "$ld_vers_patch" && ld_vers_patch=0
1847         if test "$ld_vers_major" -lt 2; then
1848           gcc_cv_ld_hidden=no
1849         elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -lt 12; then
1850           gcc_cv_ld_hidden="no"
1851         elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -eq 12 -a "$ld_vers_patch" -eq 0; then
1852           gcc_cv_ld_hidden=no
1853         fi
1854       fi
1855 changequote([,])dnl
1856     fi
1857   else
1858     # non-GNU linkers don't seem to support .hidden yet
1859     gcc_cv_ld_hidden=no
1860   fi
1861 fi])
1862 libgcc_visibility=no
1863 AC_SUBST(libgcc_visibility)
1864 if test $gcc_cv_as_hidden = yes && test $gcc_cv_ld_hidden = yes; then
1865   libgcc_visibility=yes
1866   AC_DEFINE(HAVE_GAS_HIDDEN, 1,
1867   [Define if your assembler and linker support .hidden.])
1868 fi
1869
1870 # Check if we have .[us]leb128, and support symbol arithmetic with it.
1871 gcc_GAS_CHECK_FEATURE([.sleb128 and .uleb128], gcc_cv_as_leb128,
1872   [elf,2,11,0],,
1873 [       .data
1874         .uleb128 L2 - L1
1875 L1:
1876         .uleb128 1280
1877         .sleb128 -1010
1878 L2:],
1879  [# GAS versions before 2.11 do not support uleb128,
1880   # despite appearing to.
1881   # ??? There exists an elf-specific test that will crash
1882   # the assembler.  Perhaps it's better to figure out whether
1883   # arbitrary sections are supported and try the test.
1884   as_ver=`$gcc_cv_as --version 2>/dev/null | sed 1q`
1885   if echo "$as_ver" | grep GNU > /dev/null; then
1886 changequote(,)dnl
1887     as_ver=`echo $as_ver | sed -e 's/GNU assembler \([0-9.][0-9.]*\).*/\1/'`
1888     as_major=`echo $as_ver | sed 's/\..*//'`
1889     as_minor=`echo $as_ver | sed 's/[^.]*\.\([0-9]*\).*/\1/'`
1890 changequote([,])dnl
1891     if test $as_major -eq 2 && test $as_minor -lt 11
1892     then :
1893     else gcc_cv_as_leb128=yes
1894     fi
1895   fi],
1896   [AC_DEFINE(HAVE_AS_LEB128, 1,
1897     [Define if your assembler supports .sleb128 and .uleb128.])])
1898
1899 # GAS versions up to and including 2.11.0 may mis-optimize
1900 # .eh_frame data.
1901 gcc_GAS_CHECK_FEATURE(eh_frame optimization, gcc_cv_as_eh_frame,
1902   [elf,2,12,0],,
1903 [       .text
1904 .LFB1:
1905         .4byte  0
1906 .L1:
1907         .4byte  0
1908 .LFE1:
1909         .section        .eh_frame,"aw",@progbits
1910 __FRAME_BEGIN__:
1911         .4byte  .LECIE1-.LSCIE1
1912 .LSCIE1:
1913         .4byte  0x0
1914         .byte   0x1
1915         .ascii "z\0"
1916         .byte   0x1
1917         .byte   0x78
1918         .byte   0x1a
1919         .byte   0x0
1920         .byte   0x4
1921         .4byte  1
1922         .p2align 1
1923 .LECIE1:
1924 .LSFDE1:
1925         .4byte  .LEFDE1-.LASFDE1
1926 .LASFDE1:
1927         .4byte  .LASFDE1-__FRAME_BEGIN__
1928         .4byte  .LFB1
1929         .4byte  .LFE1-.LFB1
1930         .byte   0x4
1931         .4byte  .LFE1-.LFB1
1932         .byte   0x4
1933         .4byte  .L1-.LFB1
1934 .LEFDE1:],
1935 [  cat > conftest.lit <<EOF
1936  0000 10000000 00000000 017a0001 781a0004  .........z..x...
1937  0010 01000000 12000000 18000000 00000000  ................
1938  0020 08000000 04080000 0044               .........D      
1939 EOF
1940   cat > conftest.big <<EOF
1941  0000 00000010 00000000 017a0001 781a0004  .........z..x...
1942  0010 00000001 00000012 00000018 00000000  ................
1943  0020 00000008 04000000 0844               .........D      
1944 EOF
1945   # If the assembler didn't choke, and we can objdump,
1946   # and we got the correct data, then succeed.
1947   if test x$gcc_cv_objdump != x \
1948   && $gcc_cv_objdump -s -j .eh_frame conftest.o 2>/dev/null \
1949      | tail -3 > conftest.got \
1950   && { cmp conftest.lit conftest.got > /dev/null 2>&1 \
1951     || cmp conftest.big conftest.got > /dev/null 2>&1; }
1952   then
1953     gcc_cv_as_eh_frame=yes
1954   elif AC_TRY_COMMAND($gcc_cv_as -o conftest.o --traditional-format /dev/null); then
1955     gcc_cv_as_eh_frame=buggy
1956   else
1957     # Uh oh, what do we do now?
1958     gcc_cv_as_eh_frame=no
1959   fi])
1960
1961 if test $gcc_cv_as_eh_frame = buggy; then
1962   AC_DEFINE(USE_AS_TRADITIONAL_FORMAT, 1,
1963   [Define if your assembler mis-optimizes .eh_frame data.])
1964 fi
1965
1966 gcc_GAS_CHECK_FEATURE(section merging support, gcc_cv_as_shf_merge,
1967  [elf,2,12,0], [--fatal-warnings],
1968  [.section .rodata.str, "aMS", @progbits, 1])
1969 AC_DEFINE_UNQUOTED(HAVE_GAS_SHF_MERGE,
1970   [`if test $gcc_cv_as_shf_merge = yes; then echo 1; else echo 0; fi`],
1971 [Define 0/1 if your assembler supports marking sections with SHF_MERGE flag.])
1972
1973 # Thread-local storage - the check is heavily parametrized.
1974 conftest_s=
1975 tls_first_major=
1976 tls_first_minor=
1977 tls_as_opt=
1978 case "$target" in
1979 changequote(,)dnl
1980   alpha*-*-*)
1981     conftest_s='
1982         .section ".tdata","awT",@progbits
1983 foo:    .long   25
1984         .text
1985         ldq     $27,__tls_get_addr($29)         !literal!1
1986         lda     $16,foo($29)                    !tlsgd!1
1987         jsr     $26,($27),__tls_get_addr        !lituse_tlsgd!1
1988         ldq     $27,__tls_get_addr($29)         !literal!2
1989         lda     $16,foo($29)                    !tlsldm!2
1990         jsr     $26,($27),__tls_get_addr        !lituse_tlsldm!2
1991         ldq     $1,foo($29)                     !gotdtprel
1992         ldah    $2,foo($29)                     !dtprelhi
1993         lda     $3,foo($2)                      !dtprello
1994         lda     $4,foo($29)                     !dtprel
1995         ldq     $1,foo($29)                     !gottprel
1996         ldah    $2,foo($29)                     !tprelhi
1997         lda     $3,foo($2)                      !tprello
1998         lda     $4,foo($29)                     !tprel'
1999         tls_first_major=2
2000         tls_first_minor=13
2001         ;;
2002   i[34567]86-*-*)
2003     conftest_s='
2004         .section ".tdata","awT",@progbits
2005 foo:    .long   25
2006         .text
2007         movl    %gs:0, %eax
2008         leal    foo@TLSGD(,%ebx,1), %eax
2009         leal    foo@TLSLDM(%ebx), %eax
2010         leal    foo@DTPOFF(%eax), %edx
2011         movl    foo@GOTTPOFF(%ebx), %eax
2012         subl    foo@GOTTPOFF(%ebx), %eax
2013         addl    foo@GOTNTPOFF(%ebx), %eax
2014         movl    foo@INDNTPOFF, %eax
2015         movl    $foo@TPOFF, %eax
2016         subl    $foo@TPOFF, %eax
2017         leal    foo@NTPOFF(%ecx), %eax'
2018         tls_first_major=2
2019         tls_first_minor=14
2020         ;;
2021   x86_64-*-*)
2022     conftest_s='
2023         .section ".tdata","awT",@progbits
2024 foo:    .long   25
2025         .text
2026         movq    %fs:0, %rax
2027         leaq    foo@TLSGD(%rip), %rdi
2028         leaq    foo@TLSLD(%rip), %rdi
2029         leaq    foo@DTPOFF(%rax), %rdx
2030         movq    foo@GOTTPOFF(%rip), %rax
2031         movq    $foo@TPOFF, %rax'
2032         tls_first_major=2
2033         tls_first_minor=14
2034         ;;
2035   ia64-*-*)
2036     conftest_s='
2037         .section ".tdata","awT",@progbits
2038 foo:    data8   25
2039         .text
2040         addl    r16 = @ltoff(@dtpmod(foo#)), gp
2041         addl    r17 = @ltoff(@dtprel(foo#)), gp
2042         addl    r18 = @ltoff(@tprel(foo#)), gp
2043         addl    r19 = @dtprel(foo#), gp
2044         adds    r21 = @dtprel(foo#), r13
2045         movl    r23 = @dtprel(foo#)
2046         addl    r20 = @tprel(foo#), gp
2047         adds    r22 = @tprel(foo#), r13
2048         movl    r24 = @tprel(foo#)'
2049         tls_first_major=2
2050         tls_first_minor=13
2051         ;;
2052   powerpc-*-*)
2053     conftest_s='
2054         .section ".tdata","awT",@progbits
2055         .align 2
2056 ld0:    .space 4
2057 ld1:    .space 4
2058 x1:     .space 4
2059 x2:     .space 4
2060 x3:     .space 4
2061         .text
2062         addi 3,31,ld0@got@tlsgd
2063         bl __tls_get_addr
2064         addi 3,31,x1@got@tlsld
2065         bl __tls_get_addr
2066         addi 9,3,x1@dtprel
2067         addis 9,3,x2@dtprel@ha
2068         addi 9,9,x2@dtprel@l
2069         lwz 9,x3@got@tprel(31)
2070         add 9,9,x@tls
2071         addi 9,2,x1@tprel
2072         addis 9,2,x2@tprel@ha
2073         addi 9,9,x2@tprel@l'
2074         tls_first_major=2
2075         tls_first_minor=14
2076         tls_as_opt=-a32
2077         ;;
2078   powerpc64-*-*)
2079     conftest_s='
2080         .section ".tdata","awT",@progbits
2081         .align 3
2082 ld0:    .space 8
2083 ld1:    .space 8
2084 x1:     .space 8
2085 x2:     .space 8
2086 x3:     .space 8
2087         .text
2088         addi 3,2,ld0@got@tlsgd
2089         bl .__tls_get_addr
2090         nop
2091         addi 3,2,ld1@toc
2092         bl .__tls_get_addr
2093         nop
2094         addi 3,2,x1@got@tlsld
2095         bl .__tls_get_addr
2096         nop
2097         addi 9,3,x1@dtprel
2098         bl .__tls_get_addr
2099         nop
2100         addis 9,3,x2@dtprel@ha
2101         addi 9,9,x2@dtprel@l
2102         bl .__tls_get_addr
2103         nop
2104         ld 9,x3@got@dtprel(2)
2105         add 9,9,3
2106         bl .__tls_get_addr
2107         nop'
2108         tls_first_major=2
2109         tls_first_minor=14
2110         tls_as_opt=-a64
2111         ;;
2112   s390-*-*)
2113     conftest_s='
2114         .section ".tdata","awT",@progbits
2115 foo:    .long   25
2116         .text
2117         .long   foo@TLSGD
2118         .long   foo@TLSLDM
2119         .long   foo@DTPOFF
2120         .long   foo@NTPOFF
2121         .long   foo@GOTNTPOFF
2122         .long   foo@INDNTPOFF
2123         l       %r1,foo@GOTNTPOFF(%r12)
2124         l       %r1,0(%r1):tls_load:foo
2125         bas     %r14,0(%r1,%r13):tls_gdcall:foo
2126         bas     %r14,0(%r1,%r13):tls_ldcall:foo'
2127         tls_first_major=2
2128         tls_first_minor=14
2129         tls_as_opt=-m31
2130         ;;
2131   s390x-*-*)
2132     conftest_s='
2133         .section ".tdata","awT",@progbits
2134 foo:    .long   25
2135         .text
2136         .quad   foo@TLSGD
2137         .quad   foo@TLSLDM
2138         .quad   foo@DTPOFF
2139         .quad   foo@NTPOFF
2140         .quad   foo@GOTNTPOFF
2141         lg      %r1,foo@GOTNTPOFF(%r12)
2142         larl    %r1,foo@INDNTPOFF
2143         brasl   %r14,__tls_get_offset@PLT:tls_gdcall:foo
2144         brasl   %r14,__tls_get_offset@PLT:tls_ldcall:foo'
2145         tls_first_major=2
2146         tls_first_minor=14
2147         tls_as_opt="-m64 -Aesame"
2148         ;;
2149   sh-*-* | sh[34]-*-*)
2150     conftest_s='
2151         .section ".tdata","awT",@progbits
2152 foo:    .long   25
2153         .text
2154         .long   foo@TLSGD
2155         .long   foo@TLSLDM
2156         .long   foo@DTPOFF
2157         .long   foo@GOTTPOFF
2158         .long   foo@TPOFF'
2159         tls_first_major=2
2160         tls_first_minor=13
2161         ;;
2162   sparc*-*-*)
2163     conftest_s='
2164         .section ".tdata","awT",@progbits
2165 foo:    .long   25
2166         .text
2167         sethi   %tgd_hi22(foo), %o0
2168         add     %o0, %tgd_lo10(foo), %o1
2169         add     %l7, %o1, %o0, %tgd_add(foo)
2170         call    __tls_get_addr, %tgd_call(foo)
2171         sethi   %tldm_hi22(foo), %l1
2172         add     %l1, %tldm_lo10(foo), %l2
2173         add     %l7, %l2, %o0, %tldm_add(foo)
2174         call    __tls_get_addr, %tldm_call(foo)
2175         sethi   %tldo_hix22(foo), %l3
2176         xor     %l3, %tldo_lox10(foo), %l4
2177         add     %o0, %l4, %l5, %tldo_add(foo)
2178         sethi   %tie_hi22(foo), %o3
2179         add     %o3, %tie_lo10(foo), %o3
2180         ld      [%l7 + %o3], %o2, %tie_ld(foo)
2181         add     %g7, %o2, %o4, %tie_add(foo)
2182         sethi   %tle_hix22(foo), %l1
2183         xor     %l1, %tle_lox10(foo), %o5
2184         ld      [%g7 + %o5], %o1'
2185         tls_first_major=2
2186         tls_first_minor=14
2187         tls_as_opt=-32
2188         ;;
2189 changequote([,])dnl
2190 esac
2191 if test -z "$tls_first_major"; then
2192   : # If we don't have a check, assume no support.
2193 else
2194   gcc_GAS_CHECK_FEATURE(thread-local storage support, gcc_cv_as_tls,
2195   [$tls_first_major,$tls_first_minor,0], [$tls_as_opt --fatal-warnings],
2196   [$conftest_s],,
2197   [AC_DEFINE(HAVE_AS_TLS, 1,
2198             [Define if your assembler supports thread-local storage.])])
2199 fi
2200
2201 # Target-specific assembler checks.
2202
2203 case "$target" in
2204   # All TARGET_ABI_OSF targets.
2205   alpha*-*-osf* | alpha*-*-linux* | alpha*-*-*bsd*)
2206     gcc_GAS_CHECK_FEATURE([explicit relocation support],
2207         gcc_cv_as_alpha_explicit_relocs, [2,12,0],,
2208 [       .set nomacro
2209         .text
2210         extbl   $3, $2, $3      !lituse_bytoff!1
2211         ldq     $2, a($29)      !literal!1
2212         ldq     $4, b($29)      !literal!2
2213         ldq_u   $3, 0($2)       !lituse_base!1
2214         ldq     $27, f($29)     !literal!5
2215         jsr     $26, ($27), f   !lituse_jsr!5
2216         ldah    $29, 0($26)     !gpdisp!3
2217         lda     $0, c($29)      !gprel
2218         ldah    $1, d($29)      !gprelhigh
2219         lda     $1, d($1)       !gprellow
2220         lda     $29, 0($29)     !gpdisp!3],,
2221     [AC_DEFINE(HAVE_AS_EXPLICIT_RELOCS, 1,
2222   [Define if your assembler supports explicit relocations.])])
2223     ;;
2224
2225   sparc*-*-*)
2226     gcc_GAS_CHECK_FEATURE([.register], gcc_cv_as_sparc_register_op,,,
2227       [.register %g2, #scratch],,
2228       [AC_DEFINE(HAVE_AS_REGISTER_PSEUDO_OP, 1,
2229                 [Define if your assembler supports .register.])])
2230
2231     gcc_GAS_CHECK_FEATURE([-relax option], gcc_cv_as_sparc_relax,,
2232       [-relax], [.text],,
2233       [AC_DEFINE(HAVE_AS_RELAX_OPTION, 1,
2234                 [Define if your assembler supports -relax option.])])
2235
2236     gcc_GAS_CHECK_FEATURE([unaligned pcrel relocs],
2237       gcc_cv_as_sparc_ua_pcrel,,
2238       [-K PIC],
2239 [.text
2240 foo:
2241         nop
2242 .data
2243 .align 4
2244 .byte 0
2245 .uaword %r_disp32(foo)],
2246       [if test x$gcc_cv_ld != x \
2247        && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1; then
2248          gcc_cv_as_sparc_ua_pcrel=yes
2249        fi
2250        rm -f conftest],
2251       [AC_DEFINE(HAVE_AS_SPARC_UA_PCREL, 1,
2252                 [Define if your assembler and linker support unaligned PC relative relocs.])
2253
2254       gcc_GAS_CHECK_FEATURE([unaligned pcrel relocs against hidden symbols],
2255         gcc_cv_as_sparc_ua_pcrel_hidden,,
2256         [-K PIC],
2257 [.data
2258 .align 4
2259 .byte 0x31
2260 .uaword %r_disp32(foo)
2261 .byte 0x32, 0x33, 0x34
2262 .global foo
2263 .hidden foo
2264 foo:
2265 .skip 4],
2266         [if test x$gcc_cv_ld != x && test x$gcc_cv_objdump != x \
2267          && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1 \
2268          && $gcc_cv_objdump -s -j .data conftest 2> /dev/null \
2269             | grep ' 31000000 07323334' > /dev/null 2>&1; then
2270             if $gcc_cv_objdump -R conftest 2> /dev/null \
2271                | grep 'DISP32' > /dev/null 2>&1; then
2272                 :
2273             else
2274                 gcc_cv_as_sparc_ua_pcrel_hidden=yes
2275             fi
2276          fi
2277          rm -f conftest],
2278          [AC_DEFINE(HAVE_AS_SPARC_UA_PCREL_HIDDEN, 1,
2279                    [Define if your assembler and linker support unaligned PC relative relocs against hidden symbols.])])
2280     ]) # unaligned pcrel relocs
2281
2282     gcc_GAS_CHECK_FEATURE([offsetable %lo()],
2283       gcc_cv_as_sparc_offsetable_lo10,,
2284       [-xarch=v9],
2285 [.text
2286         or %g1, %lo(ab) + 12, %g1
2287         or %g1, %lo(ab + 12), %g1],
2288       [if test x$gcc_cv_objdump != x \
2289        && %gcc_cv_objdump -s -j .text conftest.o 2> /dev/null \
2290           | grep ' 82106000 82106000' > /dev/null 2>&1; then
2291          gcc_cv_as_offsetable_lo10=yes
2292        fi],
2293        [AC_DEFINE(HAVE_AS_OFFSETABLE_LO10, 1,
2294                  [Define if your assembler supports offsetable %lo().])])
2295     ;;
2296
2297 changequote(,)dnl
2298   i[34567]86-*-* | x86_64-*-*)
2299 changequote([,])dnl
2300     gcc_GAS_CHECK_FEATURE([filds and fists mnemonics],
2301        gcc_cv_as_ix86_filds_fists,
2302       [2,9,0],, [filds mem; fists mem],,
2303       [AC_DEFINE(HAVE_GAS_FILDS_FISTS, 1,
2304         [Define if your assembler uses the new HImode fild and fist notation.])])
2305
2306     gcc_GAS_CHECK_FEATURE([cmov syntax],
2307       gcc_cv_as_ix86_cmov_sun_syntax,,,
2308       [cmovl.l %edx, %eax],,
2309       [AC_DEFINE(HAVE_AS_IX86_CMOV_SUN_SYNTAX, 1,
2310         [Define if your assembler supports the Sun syntax for cmov.])])
2311
2312     # This one is used unconditionally by i386.[ch]; it is to be defined
2313     # to 1 if the feature is present, 0 otherwise.
2314     gcc_GAS_CHECK_FEATURE([GOTOFF in data],
2315         gcc_cv_as_ix86_gotoff_in_data, [2,11,0],,
2316 [       .text
2317 .L0:
2318         nop
2319         .data
2320         .long .L0@GOTOFF])
2321     AC_DEFINE_UNQUOTED(HAVE_AS_GOTOFF_IN_DATA,
2322       [`if test $gcc_cv_as_ix86_gotoff_in_data = yes; then echo 1; else echo 0; fi`],
2323       [Define true if the assembler supports '.long foo@GOTOFF'.])
2324     ;;
2325
2326   ia64*-*-*)
2327     gcc_GAS_CHECK_FEATURE([ltoffx and ldxmov relocs],
2328         gcc_cv_as_ia64_ltoffx_ldxmov_relocs, [2,14,0],,
2329 [       .text
2330         addl r15 = @ltoffx(x#), gp
2331         ;;
2332         ld8.mov r16 = [[r15]], x#],,
2333     [AC_DEFINE(HAVE_AS_LTOFFX_LDXMOV_RELOCS, 1,
2334           [Define if your assembler supports ltoffx and ldxmov relocations.])])
2335
2336     ;;
2337
2338   powerpc*-*-*)
2339     case $target in
2340       *-*-aix) conftest_s='     .csect .text[PR]';;
2341       *)       conftest_s='     .text';;
2342     esac
2343     conftest_s="$conftest_s
2344         mfcr 3,128"
2345
2346     gcc_GAS_CHECK_FEATURE([mfcr field support],
2347       gcc_cv_as_powerpc_mfcrf, [2,14,0],,
2348       [$conftest_s],,
2349       [AC_DEFINE(HAVE_AS_MFCRF, 1,
2350           [Define if your assembler supports mfcr field.])])
2351     ;;
2352
2353   mips*-*-*)
2354     gcc_GAS_CHECK_FEATURE([explicit relocation support],
2355       gcc_cv_as_mips_explicit_relocs, [2,14,0],,
2356 [       lw $4,%gp_rel(foo)($4)],,
2357       [if test x$target_cpu_default = x
2358        then target_cpu_default=MASK_EXPLICIT_RELOCS
2359        else target_cpu_default="($target_cpu_default)|MASK_EXPLICIT_RELOCS"
2360        fi])
2361
2362     ;;
2363 esac
2364 # ??? Not all targets support dwarf2 debug_line, even within a version
2365 # of gas.  Moreover, we need to emit a valid instruction to trigger any
2366 # info to the output file.  So, as supported targets are added to gas 2.11,
2367 # add some instruction here to (also) show we expect this might work.
2368 # ??? Once 2.11 is released, probably need to add first known working
2369 # version to the per-target configury.
2370 case "$target" in
2371   i?86*-*-* | mips*-*-* | alpha*-*-* | powerpc*-*-* | sparc*-*-* | m68*-*-* \
2372   | x86_64*-*-* | hppa*-*-* | arm*-*-* | strongarm*-*-* | xscale*-*-* \
2373   | xstormy16*-*-* | cris-*-*)
2374     insn="nop"
2375     ;;
2376   ia64*-*-*)
2377     insn="nop 0"
2378     ;;
2379   mmix-*-*)
2380     insn="swym 0"
2381     ;;
2382 esac
2383 if test x"$insn" != x; then
2384  conftest_s="\
2385         .file 1 \"conftest.s\"
2386         .loc 1 3 0
2387         $insn"
2388  gcc_GAS_CHECK_FEATURE([dwarf2 debug_line support],
2389   gcc_cv_as_dwarf2_debug_line,
2390   [elf,2,11,0],, [$conftest_s],
2391   [# ??? This fails with non-gnu grep.  Maybe use objdump?
2392    if grep debug_line conftest.o > /dev/null 2>&1; then
2393      gcc_cv_as_dwarf2_debug_line=yes
2394    fi])
2395
2396 # The .debug_line file table must be in the exact order that
2397 # we specified the files, since these indices are also used
2398 # by DW_AT_decl_file.  Approximate this test by testing if
2399 # the assembler bitches if the same index is assigned twice.
2400  gcc_GAS_CHECK_FEATURE([buggy dwarf2 .file directive],
2401   gcc_cv_as_dwarf2_file_buggy,,,
2402 [       .file 1 "foo.s"
2403         .file 1 "bar.s"])
2404
2405  if test $gcc_cv_as_dwarf2_debug_line = yes \
2406  && test $gcc_cv_as_dwarf2_file_buggy = no; then
2407         AC_DEFINE(HAVE_AS_DWARF2_DEBUG_LINE, 1,
2408   [Define if your assembler supports dwarf2 .file/.loc directives,
2409    and preserves file table indices exactly as given.])
2410  fi
2411
2412  gcc_GAS_CHECK_FEATURE([--gdwarf2 option],
2413   gcc_cv_as_gdwarf2_flag,
2414   [elf,2,11,0], [--gdwarf2], [$insn],,
2415   [AC_DEFINE(HAVE_AS_GDWARF2_DEBUG_FLAG, 1,
2416 [Define if your assembler supports the --gdwarf2 option.])])
2417
2418  gcc_GAS_CHECK_FEATURE([--gstabs option],
2419   gcc_cv_as_gstabs_flag,
2420   [elf,2,11,0], [--gstabs], [$insn],
2421   [# The native Solaris 9/Intel assembler doesn't understand --gstabs
2422    # and warns about it, but still exits successfully.  So check for
2423    # this.
2424    if AC_TRY_COMMAND([$gcc_cv_as --gstabs -o conftest.o conftest.s 2>&1 | grep -i warning > /dev/null])
2425    then :
2426    else gcc_cv_as_gstabs_flag=yes
2427    fi],
2428   [AC_DEFINE(HAVE_AS_GSTABS_DEBUG_FLAG, 1,
2429 [Define if your assembler supports the --gstabs option.])])
2430 fi
2431
2432 AC_MSG_CHECKING(linker read-only and read-write section mixing)
2433 gcc_cv_ld_ro_rw_mix=unknown
2434 if test $in_tree_ld = yes ; then
2435   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 10 -o "$gcc_cv_gld_major_version" -gt 2 \
2436      && test $in_tree_ld_is_elf = yes; then
2437     gcc_cv_ld_ro_rw_mix=read-write
2438   fi
2439 elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x -a x$gcc_cv_objdump != x ; then
2440   echo '.section myfoosect, "a"' > conftest1.s
2441   echo '.section myfoosect, "aw"' > conftest2.s
2442   echo '.byte 1' >> conftest2.s
2443   echo '.section myfoosect, "a"' > conftest3.s
2444   echo '.byte 0' >> conftest3.s
2445   if $gcc_cv_as -o conftest1.o conftest1.s > /dev/null 2>&1 \
2446      && $gcc_cv_as -o conftest2.o conftest2.s > /dev/null 2>&1 \
2447      && $gcc_cv_as -o conftest3.o conftest3.s > /dev/null 2>&1 \
2448      && $gcc_cv_ld -shared -o conftest1.so conftest1.o \
2449         conftest2.o conftest3.o > /dev/null 2>&1; then
2450     gcc_cv_ld_ro_rw_mix=`$gcc_cv_objdump -h conftest1.so \
2451                          | sed -e '/myfoosect/!d' -e N`
2452     if echo "$gcc_cv_ld_ro_rw_mix" | grep CONTENTS > /dev/null; then
2453       if echo "$gcc_cv_ld_ro_rw_mix" | grep READONLY > /dev/null; then
2454         gcc_cv_ld_ro_rw_mix=read-only
2455       else
2456         gcc_cv_ld_ro_rw_mix=read-write
2457       fi
2458     fi
2459   fi
2460 changequote(,)dnl
2461   rm -f conftest.* conftest[123].*
2462 changequote([,])dnl
2463 fi
2464 if test x$gcc_cv_ld_ro_rw_mix = xread-write; then
2465         AC_DEFINE(HAVE_LD_RO_RW_SECTION_MIXING, 1,
2466   [Define if your linker links a mix of read-only
2467    and read-write sections into a read-write section.])
2468 fi
2469 AC_MSG_RESULT($gcc_cv_ld_ro_rw_mix)
2470
2471 AC_MSG_CHECKING(linker PT_GNU_EH_FRAME support)
2472 gcc_cv_ld_eh_frame_hdr=no
2473 if test $in_tree_ld = yes ; then
2474   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 12 -o "$gcc_cv_gld_major_version" -gt 2 \
2475      && test $in_tree_ld_is_elf = yes; then
2476     gcc_cv_ld_eh_frame_hdr=yes
2477   fi
2478 elif test x$gcc_cv_ld != x; then
2479         # Check if linker supports --eh-frame-hdr option
2480         if $gcc_cv_ld --help 2>/dev/null | grep eh-frame-hdr > /dev/null; then
2481                 gcc_cv_ld_eh_frame_hdr=yes
2482         fi
2483 fi
2484 if test x"$gcc_cv_ld_eh_frame_hdr" = xyes; then
2485         AC_DEFINE(HAVE_LD_EH_FRAME_HDR, 1,
2486 [Define if your linker supports --eh-frame-hdr option.])
2487 fi
2488 AC_MSG_RESULT($gcc_cv_ld_eh_frame_hdr)
2489
2490 AC_MSG_CHECKING(linker position independent executable support)
2491 gcc_cv_ld_pie=no
2492 if test $in_tree_ld = yes ; then
2493   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 15 -o "$gcc_cv_gld_major_version" -gt 2 \
2494      && test $in_tree_ld_is_elf = yes; then
2495     gcc_cv_ld_pie=yes
2496   fi
2497 elif test x$gcc_cv_ld != x; then
2498         # Check if linker supports -pie option
2499         if $gcc_cv_ld --help 2>/dev/null | grep -- -pie > /dev/null; then
2500                 gcc_cv_ld_pie=yes
2501         fi
2502 fi
2503 if test x"$gcc_cv_ld_pie" = xyes; then
2504         AC_DEFINE(HAVE_LD_PIE, 1,
2505 [Define if your linker supports -pie option.])
2506 fi
2507 AC_MSG_RESULT($gcc_cv_ld_pie)
2508
2509 # Miscellaneous target-specific checks.
2510 case "$target" in
2511   mips*-*-*)
2512     AC_MSG_CHECKING(whether libgloss uses STARTUP directives consistently)
2513     gcc_cv_mips_libgloss_startup=no
2514     gcc_cv_libgloss_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/libgloss
2515     if test "x$exec_prefix" = xNONE; then
2516       if test "x$prefix" = xNONE; then
2517         test_prefix=/usr/local
2518       else
2519         test_prefix=$prefix
2520       fi
2521     else
2522       test_prefix=$exec_prefix
2523     fi
2524     for f in $gcc_cv_libgloss_srcdir/mips/idt.ld $test_prefix/$target_alias/lib/idt.ld
2525     do
2526       if grep '^STARTUP' $f > /dev/null 2>&1; then
2527         gcc_cv_mips_libgloss_startup=yes
2528         break
2529       fi
2530     done
2531     if test x"$gcc_cv_mips_libgloss_startup" = xyes; then
2532       AC_DEFINE(HAVE_MIPS_LIBGLOSS_STARTUP_DIRECTIVES, 1,
2533         [Define if your MIPS libgloss linker scripts consistently include STARTUP directives.])
2534     fi
2535     AC_MSG_RESULT($gcc_cv_mips_libgloss_startup)
2536     ;;
2537 esac
2538
2539 if test x$with_sysroot = x && test x$host = x$target \
2540    && test "$prefix" != "/usr" && test "x$prefix" != "x$local_prefix" ; then
2541   AC_DEFINE_UNQUOTED(PREFIX_INCLUDE_DIR, "$prefix/include",
2542 [Define to PREFIX/include if cpp should also search that directory.])
2543 fi
2544
2545 # Figure out what language subdirectories are present.
2546 # Look if the user specified --enable-languages="..."; if not, use
2547 # the environment variable $LANGUAGES if defined. $LANGUAGES might
2548 # go away some day.
2549 # NB:  embedded tabs in this IF block -- do not untabify
2550 if test x"${enable_languages+set}" != xset; then
2551         if test x"${LANGUAGES+set}" = xset; then
2552                 enable_languages="${LANGUAGES}"
2553                 AC_MSG_WARN([setting LANGUAGES is deprecated, use --enable-languages instead])
2554
2555         else
2556                 enable_languages=all
2557         fi
2558 else
2559         if test x"${enable_languages}" = x \
2560         || test x"${enable_languages}" = xyes;
2561         then
2562                 AC_MSG_ERROR([--enable-languages needs at least one language argument])
2563         fi
2564 fi
2565 enable_languages=`echo "${enable_languages}" | sed -e 's/[[     ,]][[   ,]]*/,/g' -e 's/,$//'`
2566
2567 # First scan to see if an enabled language requires some other language.
2568 # We assume that a given config-lang.in will list all the language
2569 # front ends it requires, even if some are required indirectly.
2570 for lang in ${srcdir}/*/config-lang.in
2571 do
2572    case $lang in
2573     # The odd quoting in the next line works around
2574     # an apparent bug in bash 1.12 on linux.
2575 changequote(,)dnl
2576     ${srcdir}/[*]/config-lang.in)
2577        ;;
2578     *)
2579        lang_alias=`sed -n -e 's,^language=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^language=\([^      ]*\).*$,\1,p' $lang`
2580        this_lang_requires=`sed -n -e 's,^lang_requires=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^lang_requires=\([^    ]*\).*$,\1,p' $lang`
2581        for other in $this_lang_requires
2582        do
2583           case ,${enable_languages}, in
2584            *,$other,*)
2585               ;;
2586            *,all,*)
2587               ;;
2588            *,$lang_alias,*)
2589               enable_languages="$enable_languages,$other"
2590               ;;
2591           esac
2592        done
2593        ;;
2594 changequote([,])dnl
2595    esac
2596 done
2597
2598 expected_languages=`echo ,${enable_languages}, | sed -e 's:,: :g' -e 's:  *: :g' -e 's:  *: :g' -e 's:^ ::' -e 's: $::'`
2599 found_languages=
2600 subdirs=
2601 for lang in ${srcdir}/*/config-lang.in
2602 do
2603         case $lang in
2604         # The odd quoting in the next line works around
2605         # an apparent bug in bash 1.12 on linux.
2606 changequote(,)dnl
2607         ${srcdir}/[*]/config-lang.in) ;;
2608         *)
2609           lang_alias=`sed -n -e 's,^language=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^language=\([^   ]*\).*$,\1,p' $lang`
2610           this_lang_libs=`sed -n -e 's,^target_libs=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^target_libs=\([^         ]*\).*$,\1,p' $lang`
2611           build_by_default=`sed -n -e 's,^build_by_default=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^build_by_default=\([^     ]*\).*$,\1,p' $lang`
2612           if test "x$lang_alias" = x
2613           then
2614                 echo "$lang doesn't set \$language." 1>&2
2615                 exit 1
2616           fi
2617           case ${build_by_default},${enable_languages}, in
2618           *,$lang_alias,*) add_this_lang=yes ;;
2619           no,*) add_this_lang=no ;;
2620           *,all,*) add_this_lang=yes ;;
2621           *) add_this_lang=no ;;
2622           esac
2623           found_languages="${found_languages} ${lang_alias}"
2624           if test x"${add_this_lang}" = xyes; then
2625                 case $lang in
2626                     ${srcdir}/ada/config-lang.in)
2627                         if test x$have_gnat = xyes ; then
2628                                 subdirs="$subdirs `echo $lang | sed -e 's,^.*/\([^/]*\)/config-lang.in$,\1,'`"
2629                         fi
2630                         ;;
2631                     *)
2632                         subdirs="$subdirs `echo $lang | sed -e 's,^.*/\([^/]*\)/config-lang.in$,\1,'`"
2633                         ;;
2634                 esac
2635           fi
2636           ;;
2637 changequote([,])dnl
2638         esac
2639 done
2640
2641 missing_languages=
2642 for expected_language in ${expected_languages} ..
2643 do 
2644     if test "${expected_language}" != ..; then
2645         missing_language="${expected_language}"
2646         if test "${expected_language}" = "c" \
2647            || test "${expected_language}" = "all"; then
2648                 missing_language=
2649         fi
2650         for found_language in ${found_languages} ..
2651         do 
2652             if test "${found_language}" != ..; then
2653                 if test "${expected_language}" = "${found_language}"; then
2654                     missing_language=
2655                 fi
2656             fi
2657         done
2658         if test "x${missing_language}" != x; then
2659            missing_languages="${missing_languages} ${missing_language}"
2660         fi
2661     fi
2662 done
2663
2664 if test "x$missing_languages" != x; then
2665   AC_MSG_ERROR([
2666 The following requested languages were not found:${missing_languages}
2667 The following languages were available: c${found_languages}])
2668 fi
2669
2670 # Make gthr-default.h if we have a thread file.
2671 gthread_flags=
2672 if test $thread_file != single; then
2673     rm -f gthr-default.h
2674     echo "#include \"gthr-${thread_file}.h\"" > gthr-default.h
2675     gthread_flags=-DHAVE_GTHR_DEFAULT
2676 fi
2677 AC_SUBST(gthread_flags)
2678
2679 # Find out what GC implementation we want, or may, use.
2680 AC_ARG_WITH(gc,
2681 [  --with-gc={simple,page} choose the garbage collection mechanism to use
2682                           with the compiler],
2683 [case "$withval" in
2684   simple | page)
2685     GGC=ggc-$withval
2686     ;;
2687   *)
2688     AC_MSG_ERROR([$withval is an invalid option to --with-gc])
2689     ;;
2690 esac],
2691 [GGC=ggc-page])
2692 AC_SUBST(GGC)
2693 echo "Using $GGC for garbage collection."
2694
2695 # Use the system's zlib library.
2696 zlibdir=-L../zlib
2697 zlibinc="-I\$(srcdir)/../zlib"
2698 AC_ARG_WITH(system-zlib,
2699 [  --with-system-zlib      use installed libz],
2700 zlibdir=
2701 zlibinc=
2702 )
2703 AC_SUBST(zlibdir)
2704 AC_SUBST(zlibinc)
2705
2706 dnl Very limited version of automake's enable-maintainer-mode
2707
2708 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
2709   dnl maintainer-mode is disabled by default
2710   AC_ARG_ENABLE(maintainer-mode,
2711 [  --enable-maintainer-mode
2712                           enable make rules and dependencies not useful
2713                           (and sometimes confusing) to the casual installer],
2714       maintainer_mode=$enableval,
2715       maintainer_mode=no)
2716
2717 AC_MSG_RESULT($maintainer_mode)
2718
2719 if test "$maintainer_mode" = "yes"; then
2720   MAINT=''
2721 else
2722   MAINT='#'
2723 fi
2724 AC_SUBST(MAINT)dnl
2725
2726 # Make empty files to contain the specs and options for each language.
2727 # Then add #include lines to for a compiler that has specs and/or options.
2728
2729 lang_opt_files=
2730 lang_specs_files=
2731 lang_tree_files=
2732 for subdir in . $subdirs
2733 do
2734         if test -f $srcdir/$subdir/lang.opt; then
2735             lang_opt_files="$lang_opt_files $srcdir/$subdir/lang.opt"
2736         fi
2737         if test -f $srcdir/$subdir/lang-specs.h; then
2738             lang_specs_files="$lang_specs_files $srcdir/$subdir/lang-specs.h"
2739         fi
2740         if test -f $srcdir/$subdir/$subdir-tree.def; then
2741             lang_tree_files="$lang_tree_files $srcdir/$subdir/$subdir-tree.def"
2742         fi
2743 done
2744
2745 # These (without "all_") are set in each config-lang.in.
2746 # `language' must be a single word so is spelled singularly.
2747 all_languages=
2748 all_boot_languages=
2749 all_compilers=
2750 all_stagestuff=
2751 all_outputs='Makefile fixinc/Makefile gccbug mklibgcc mkheaders'
2752 # List of language makefile fragments.
2753 all_lang_makefrags=
2754 # List of language subdirectory makefiles.  Deprecated.
2755 all_lang_makefiles=
2756 # Files for gengtype
2757 all_gtfiles="$target_gtfiles"
2758 # Files for gengtype with language
2759 all_gtfiles_files_langs=
2760 all_gtfiles_files_files=
2761
2762 # Add the language fragments.
2763 # Languages are added via two mechanisms.  Some information must be
2764 # recorded in makefile variables, these are defined in config-lang.in.
2765 # We accumulate them and plug them into the main Makefile.
2766 # The other mechanism is a set of hooks for each of the main targets
2767 # like `clean', `install', etc.
2768
2769 language_hooks="Make-hooks"
2770
2771 for s in $subdirs
2772 do
2773                 language=
2774                 boot_language=
2775                 compilers=
2776                 stagestuff=
2777                 outputs=
2778                 gtfiles=
2779                 . ${srcdir}/$s/config-lang.in
2780                 if test "x$language" = x
2781                 then
2782                         echo "${srcdir}/$s/config-lang.in doesn't set \$language." 1>&2
2783                         exit 1
2784                 fi
2785                 all_lang_makefrags="$all_lang_makefrags \$(srcdir)/$s/Make-lang.in"
2786                 if test -f ${srcdir}/$s/Makefile.in
2787                 then all_lang_makefiles="$s/Makefile"
2788                 fi
2789                 all_languages="$all_languages $language"
2790                 if test "x$boot_language" = xyes
2791                 then
2792                         all_boot_languages="$all_boot_languages $language"
2793                 fi
2794                 all_compilers="$all_compilers $compilers"
2795                 all_stagestuff="$all_stagestuff $stagestuff"
2796                 all_outputs="$all_outputs $outputs"
2797                 all_gtfiles="$all_gtfiles $gtfiles"
2798                 for f in $gtfiles
2799                 do
2800                          all_gtfiles_files_langs="$all_gtfiles_files_langs ${s} "
2801                          all_gtfiles_files_files="$all_gtfiles_files_files ${f} "
2802                 done
2803 done
2804
2805 # Pick up gtfiles for c
2806 gtfiles=
2807 s="c"
2808 . ${srcdir}/c-config-lang.in
2809 all_gtfiles="$all_gtfiles $gtfiles"
2810 for f in $gtfiles
2811 do
2812         all_gtfiles_files_langs="$all_gtfiles_files_langs ${s} "
2813         all_gtfiles_files_files="$all_gtfiles_files_files ${f} "
2814 done
2815
2816 check_languages=
2817 for language in $all_languages
2818 do
2819                 check_languages="$check_languages check-$language"
2820 done
2821
2822 # We link each language in with a set of hooks, reached indirectly via
2823 # lang.${target}.
2824
2825 rm -f Make-hooks
2826 touch Make-hooks
2827 target_list="all.build all.cross start.encap rest.encap tags \
2828         install-normal install-common install-info install-man \
2829         uninstall \
2830         mostlyclean clean distclean extraclean maintainer-clean \
2831         stage1 stage2 stage3 stage4 stageprofile stagefeedback"
2832 for t in $target_list
2833 do
2834         x=
2835         for lang in $all_languages
2836         do
2837                         x="$x $lang.$t"
2838         done
2839         echo "lang.$t: $x" >> Make-hooks
2840 done
2841
2842 # Create .gdbinit.
2843
2844 echo "dir ." > .gdbinit
2845 echo "dir ${srcdir}" >> .gdbinit
2846 if test x$gdb_needs_out_file_path = xyes
2847 then
2848         echo "dir ${srcdir}/config/"`dirname ${out_file}` >> .gdbinit
2849 fi
2850 if test "x$subdirs" != x; then
2851         for s in $subdirs
2852         do
2853                 echo "dir ${srcdir}/$s" >> .gdbinit
2854         done
2855 fi
2856 echo "source ${srcdir}/gdbinit.in" >> .gdbinit
2857
2858 # If $(exec_prefix) exists and is not the same as $(prefix), then compute an
2859 # absolute path for gcc_tooldir based on inserting the number of up-directory
2860 # movements required to get from $(exec_prefix) to $(prefix) into the basic
2861 # $(libsubdir)/@(unlibsubdir) based path.
2862 # Don't set gcc_tooldir to tooldir since that's only passed in by the toplevel
2863 # make and thus we'd get different behavior depending on where we built the
2864 # sources.
2865 if test x$exec_prefix = xNONE -o x$exec_prefix = x$prefix; then
2866     gcc_tooldir='$(libsubdir)/$(unlibsubdir)/../$(target_alias)'
2867 else
2868 changequote(<<, >>)dnl
2869 # An explanation of the sed strings:
2870 #  -e 's|^\$(prefix)||'   matches and eliminates 'prefix' from 'exec_prefix'
2871 #  -e 's|/$||'            match a trailing forward slash and eliminates it
2872 #  -e 's|^[^/]|/|'        forces the string to start with a forward slash (*)
2873 #  -e 's|/[^/]*|../|g'    replaces each occurrence of /<directory> with ../
2874 #
2875 # (*) Note this pattern overwrites the first character of the string
2876 # with a forward slash if one is not already present.  This is not a
2877 # problem because the exact names of the sub-directories concerned is
2878 # unimportant, just the number of them matters.
2879 #
2880 # The practical upshot of these patterns is like this:
2881 #
2882 #  prefix     exec_prefix        result
2883 #  ------     -----------        ------
2884 #   /foo        /foo/bar          ../
2885 #   /foo/       /foo/bar          ../
2886 #   /foo        /foo/bar/         ../
2887 #   /foo/       /foo/bar/         ../
2888 #   /foo        /foo/bar/ugg      ../../
2889 #
2890     dollar='$$'
2891     gcc_tooldir="\$(libsubdir)/\$(unlibsubdir)/\`echo \$(exec_prefix) | sed -e 's|^\$(prefix)||' -e 's|/\$(dollar)||' -e 's|^[^/]|/|' -e 's|/[^/]*|../|g'\`\$(target_alias)"
2892 changequote([, ])dnl
2893 fi
2894 AC_SUBST(gcc_tooldir)
2895 AC_SUBST(dollar)
2896
2897 # Find a directory in which to install a shared libgcc.
2898
2899 AC_ARG_ENABLE(version-specific-runtime-libs,
2900 [  --enable-version-specific-runtime-libs
2901                           specify that runtime libraries should be
2902                           installed in a compiler-specific directory])
2903
2904 AC_ARG_WITH(slibdir,
2905 [  --with-slibdir=DIR      shared libraries in DIR [LIBDIR]],
2906 slibdir="$with_slibdir",
2907 if test "${enable_version_specific_runtime_libs+set}" = set; then
2908   slibdir='$(libsubdir)'
2909 elif test "$host" != "$target"; then
2910   slibdir='$(build_tooldir)/lib'
2911 else
2912   slibdir='$(libdir)'
2913 fi)
2914 AC_SUBST(slibdir)
2915
2916 objdir=`${PWDCMD-pwd}`
2917 AC_SUBST(objdir)
2918
2919 # Substitute configuration variables
2920 AC_SUBST(subdirs)
2921 AC_SUBST(srcdir)
2922 AC_SUBST(all_boot_languages)
2923 AC_SUBST(all_compilers)
2924 AC_SUBST(all_gtfiles)
2925 AC_SUBST(all_gtfiles_files_langs)
2926 AC_SUBST(all_gtfiles_files_files)
2927 AC_SUBST(all_lang_makefrags)
2928 AC_SUBST(all_lang_makefiles)
2929 AC_SUBST(all_languages)
2930 AC_SUBST(all_stagestuff)
2931 AC_SUBST(build_exeext)
2932 AC_SUBST(build_install_headers_dir)
2933 AC_SUBST(build_xm_file_list)
2934 AC_SUBST(build_xm_include_list)
2935 AC_SUBST(build_xm_defines)
2936 AC_SUBST(check_languages)
2937 AC_SUBST(cc_set_by_configure)
2938 AC_SUBST(quoted_cc_set_by_configure)
2939 AC_SUBST(cpp_install_dir)
2940 AC_SUBST(xmake_file)
2941 AC_SUBST(tmake_file)
2942 AC_SUBST(extra_headers_list)
2943 AC_SUBST(extra_objs)
2944 AC_SUBST(extra_parts)
2945 AC_SUBST(extra_passes)
2946 AC_SUBST(extra_programs)
2947 AC_SUBST(float_h_file)
2948 AC_SUBST(gcc_config_arguments)
2949 AC_SUBST(gcc_gxx_include_dir)
2950 AC_SUBST(libstdcxx_incdir)
2951 AC_SUBST(gcc_version)
2952 AC_SUBST(gcc_version_full)
2953 AC_SUBST(gcc_version_trigger)
2954 AC_SUBST(host_exeext)
2955 AC_SUBST(host_extra_gcc_objs)
2956 AC_SUBST(host_xm_file_list)
2957 AC_SUBST(host_xm_include_list)
2958 AC_SUBST(host_xm_defines)
2959 AC_SUBST(out_host_hook_obj)
2960 AC_SUBST(install)
2961 AC_SUBST(lang_opt_files)
2962 AC_SUBST(lang_specs_files)
2963 AC_SUBST(lang_tree_files)
2964 AC_SUBST(local_prefix)
2965 AC_SUBST(md_file)
2966 AC_SUBST(objc_boehm_gc)
2967 AC_SUBST(out_file)
2968 AC_SUBST(out_object_file)
2969 AC_SUBST(stage_prefix_set_by_configure)
2970 AC_SUBST(quoted_stage_prefix_set_by_configure)
2971 AC_SUBST(symbolic_link)
2972 AC_SUBST(thread_file)
2973 AC_SUBST(tm_file_list)
2974 AC_SUBST(tm_include_list)
2975 AC_SUBST(tm_defines)
2976 AC_SUBST(tm_p_file_list)
2977 AC_SUBST(tm_p_include_list)
2978 AC_SUBST(xm_file_list)
2979 AC_SUBST(xm_include_list)
2980 AC_SUBST(xm_defines)
2981 AC_SUBST(target_alias)
2982 AC_SUBST(c_target_objs)
2983 AC_SUBST(cxx_target_objs)
2984 AC_SUBST(target_cpu_default)
2985
2986 AC_SUBST_FILE(language_hooks)
2987
2988 # Echo that links are built
2989 if test x$host = x$target
2990 then
2991         str1="native "
2992 else
2993         str1="cross-"
2994         str2=" from $host"
2995 fi
2996
2997 if test x$host != x$build
2998 then
2999         str3=" on a $build system"
3000 fi
3001
3002 if test "x$str2" != x || test "x$str3" != x
3003 then
3004         str4=
3005 fi
3006
3007 echo "Links are now set up to build a ${str1}compiler for ${target}$str4" 1>&2
3008
3009 if test "x$str2" != x || test "x$str3" != x
3010 then
3011         echo " ${str2}${str3}." 1>&2
3012 fi
3013
3014 # Configure the subdirectories
3015 # AC_CONFIG_SUBDIRS($subdirs)
3016
3017 # Create the Makefile
3018 # and configure language subdirectories
3019 AC_OUTPUT($all_outputs,
3020 [
3021 case x$CONFIG_HEADERS in
3022 xauto-host.h:config.in)
3023 echo > cstamp-h ;;
3024 esac
3025 # Make sure all the subdirs exist.
3026 for d in $subdirs
3027 do
3028     test -d $d || mkdir $d
3029 done
3030 # If the host supports symlinks, point stage[1234] at ../stage[1234] so
3031 # bootstrapping and the installation procedure can still use
3032 # CC="stage1/xgcc -Bstage1/".  If the host doesn't support symlinks,
3033 # FLAGS_TO_PASS has been modified to solve the problem there.
3034 # This is virtually a duplicate of what happens in configure.lang; we do
3035 # an extra check to make sure this only happens if ln -s can be used.
3036 if test "$symbolic_link" = "ln -s"; then
3037  for d in ${subdirs} fixinc ; do
3038         STARTDIR=`${PWDCMD-pwd}`
3039         cd $d
3040         for t in stage1 stage2 stage3 stage4 stageprofile stagefeedback include
3041         do
3042                 rm -f $t
3043                 $symbolic_link ../$t $t 2>/dev/null
3044         done
3045         cd $STARTDIR
3046  done
3047 else true ; fi
3048 ], 
3049 [subdirs='$subdirs'
3050 symbolic_link='$symbolic_link'
3051 ])