OSDN Git Service

* configure.frag: Delete file.
[pf3gnuchains/gcc-fork.git] / gcc / configure.in
1 # configure.in for GCC
2 # Process this file with autoconf to generate a configuration script.
3
4 # Copyright 1997, 1998, 1999, 2000, 2001, 2002, 2003
5 # Free Software Foundation, Inc.
6
7 #This file is part of GCC.
8
9 #GCC is free software; you can redistribute it and/or modify it under
10 #the terms of the GNU General Public License as published by the Free
11 #Software Foundation; either version 2, or (at your option) any later
12 #version.
13
14 #GCC is distributed in the hope that it will be useful, but WITHOUT
15 #ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
16 #FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
17 #for more details.
18
19 #You should have received a copy of the GNU General Public License
20 #along with GCC; see the file COPYING.  If not, write to the Free
21 #Software Foundation, 59 Temple Place - Suite 330, Boston, MA
22 #02111-1307, USA.
23
24 # --------------------------------
25 # Initialization and sanity checks
26 # --------------------------------
27
28 AC_PREREQ(2.13)
29 AC_INIT(tree.c)
30 AC_CONFIG_HEADER(auto-host.h:config.in)
31
32 # Determine the host, build, and target systems
33 AC_CANONICAL_SYSTEM
34
35 # Determine the target- and build-specific subdirectories
36 GCC_TOPLEV_SUBDIRS
37
38 # Set program_transform_name
39 AC_ARG_PROGRAM
40
41 # Check for bogus environment variables.
42 # Test if LIBRARY_PATH contains the notation for the current directory
43 # since this would lead to problems installing/building glibc.
44 # LIBRARY_PATH contains the current directory if one of the following
45 # is true:
46 # - one of the terminals (":" and ";") is the first or last sign
47 # - two terminals occur directly after each other
48 # - the path contains an element with a dot in it
49 AC_MSG_CHECKING(LIBRARY_PATH variable)
50 changequote(,)dnl
51 case ${LIBRARY_PATH} in
52   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
53     library_path_setting="contains current directory"
54     ;;
55   *)
56     library_path_setting="ok"
57     ;;
58 esac
59 changequote([,])dnl
60 AC_MSG_RESULT($library_path_setting)
61 if test "$library_path_setting" != "ok"; then
62 AC_MSG_ERROR([
63 *** LIBRARY_PATH shouldn't contain the current directory when
64 *** building gcc. Please change the environment variable
65 *** and run configure again.])
66 fi
67
68 # Test if GCC_EXEC_PREFIX contains the notation for the current directory
69 # since this would lead to problems installing/building glibc.
70 # GCC_EXEC_PREFIX contains the current directory if one of the following
71 # is true:
72 # - one of the terminals (":" and ";") is the first or last sign
73 # - two terminals occur directly after each other
74 # - the path contains an element with a dot in it
75 AC_MSG_CHECKING(GCC_EXEC_PREFIX variable)
76 changequote(,)dnl
77 case ${GCC_EXEC_PREFIX} in
78   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
79     gcc_exec_prefix_setting="contains current directory"
80     ;;
81   *)
82     gcc_exec_prefix_setting="ok"
83     ;;
84 esac
85 changequote([,])dnl
86 AC_MSG_RESULT($gcc_exec_prefix_setting)
87 if test "$gcc_exec_prefix_setting" != "ok"; then
88 AC_MSG_ERROR([
89 *** GCC_EXEC_PREFIX shouldn't contain the current directory when
90 *** building gcc. Please change the environment variable
91 *** and run configure again.])
92 fi
93
94 # -----------
95 # Directories
96 # -----------
97
98 # Specify the local prefix
99 local_prefix=
100 AC_ARG_WITH(local-prefix,
101 [  --with-local-prefix=DIR specifies directory to put local include],
102 [case "${withval}" in
103 yes)    AC_MSG_ERROR(bad value ${withval} given for local include directory prefix) ;;
104 no)     ;;
105 *)      local_prefix=$with_local_prefix ;;
106 esac])
107
108 # Default local prefix if it is empty
109 if test x$local_prefix = x; then
110         local_prefix=/usr/local
111 fi
112
113 # Don't set gcc_gxx_include_dir to gxx_include_dir since that's only
114 # passed in by the toplevel make and thus we'd get different behavior
115 # depending on where we built the sources.
116 gcc_gxx_include_dir=
117 # Specify the g++ header file directory
118 AC_ARG_WITH(gxx-include-dir,
119 [  --with-gxx-include-dir=DIR
120                           specifies directory to put g++ header files],
121 [case "${withval}" in
122 yes)    AC_MSG_ERROR(bad value ${withval} given for g++ include directory) ;;
123 no)     ;;
124 *)      gcc_gxx_include_dir=$with_gxx_include_dir ;;
125 esac])
126
127 if test x${gcc_gxx_include_dir} = x; then
128   if test x${enable_version_specific_runtime_libs} = xyes; then
129     gcc_gxx_include_dir='${libsubdir}/include/c++'
130   else
131     topsrcdir=${srcdir}/.. . ${srcdir}/../config.if
132 changequote(<<, >>)dnl
133     gcc_gxx_include_dir="\$(libsubdir)/\$(unlibsubdir)/..\`echo \$(exec_prefix) | sed -e 's|^\$(prefix)||' -e 's|/[^/]*|/..|g'\`/include/"${libstdcxx_incdir}
134 changequote([, ])dnl
135   fi
136 fi
137
138 AC_ARG_WITH(cpp_install_dir,
139 [  --with-cpp-install-dir=DIR
140                           install the user visible C preprocessor in DIR
141                           (relative to PREFIX) as well as PREFIX/bin],
142 [if test x$withval = xyes; then
143   AC_MSG_ERROR([option --with-cpp-install-dir requires an argument])
144 elif test x$withval != xno; then
145   cpp_install_dir=$withval
146 fi])
147
148 # -------------------
149 # Find default linker
150 # -------------------
151
152 # With GNU ld
153 AC_ARG_WITH(gnu-ld,
154 [  --with-gnu-ld           arrange to work with GNU ld.],
155 gnu_ld_flag="$with_gnu_ld",
156 gnu_ld_flag=no)
157
158 # With pre-defined ld
159 AC_ARG_WITH(ld,
160 [  --with-ld               arrange to use the specified ld (full pathname)],
161 DEFAULT_LINKER="$with_ld")
162 if test x"${DEFAULT_LINKER+set}" = x"set"; then
163   if test ! -x "$DEFAULT_LINKER"; then
164     AC_MSG_WARN([cannot execute: $DEFAULT_LINKER: check --with-ld or env. var. DEFAULT_LINKER])
165   elif $DEFAULT_LINKER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
166     gnu_ld_flag=yes
167   fi
168   AC_DEFINE_UNQUOTED(DEFAULT_LINKER,"$DEFAULT_LINKER",
169         [Define to enable the use of a default linker.])
170 fi
171
172 AC_MSG_CHECKING([whether a default linker was specified])
173 if test x"${DEFAULT_LINKER+set}" = x"set"; then
174   if test x"$gnu_ld_flag" = x"no"; then
175     AC_MSG_RESULT([yes ($DEFAULT_LINKER)])
176   else
177     AC_MSG_RESULT([yes ($DEFAULT_LINKER - GNU ld)])
178   fi
179 else
180   AC_MSG_RESULT(no)
181 fi
182
183 # ----------------------
184 # Find default assembler
185 # ----------------------
186
187 # With GNU as
188 AC_ARG_WITH(gnu-as,
189 [  --with-gnu-as           arrange to work with GNU as],
190 gas_flag="$with_gnu_as",
191 gas_flag=no)
192
193 AC_ARG_WITH(as,
194 [  --with-as               arrange to use the specified as (full pathname)],
195 DEFAULT_ASSEMBLER="$with_as")
196 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
197   if test ! -x "$DEFAULT_ASSEMBLER"; then
198     AC_MSG_WARN([cannot execute: $DEFAULT_ASSEMBLER: check --with-as or env. var. DEFAULT_ASSEMBLER])
199   elif $DEFAULT_ASSEMBLER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
200     gas_flag=yes
201   fi
202   AC_DEFINE_UNQUOTED(DEFAULT_ASSEMBLER,"$DEFAULT_ASSEMBLER",
203         [Define to enable the use of a default assembler.])
204 fi
205
206 AC_MSG_CHECKING([whether a default assembler was specified])
207 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
208   if test x"$gas_flag" = x"no"; then
209     AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER)])
210   else
211     AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER - GNU as)])
212   fi
213 else
214   AC_MSG_RESULT(no)
215 fi
216
217 # ---------------
218 # Find C compiler
219 # ---------------
220
221 # Find the native compiler
222 AC_PROG_CC
223 AC_PROG_CC_C_O
224 # autoconf is lame and doesn't give us any substitution variable for this.
225 if eval "test \"`echo '$ac_cv_prog_cc_'${ac_cc}_c_o`\" = no"; then
226   NO_MINUS_C_MINUS_O=yes
227 else
228   OUTPUT_OPTION='-o $@'
229 fi
230 AC_SUBST(NO_MINUS_C_MINUS_O)
231 AC_SUBST(OUTPUT_OPTION)
232
233 # -------------------------
234 # Check C compiler features
235 # -------------------------
236
237 AC_CACHE_CHECK(whether ${CC-cc} accepts -Wno-long-long,
238 ac_cv_prog_cc_no_long_long,
239 [save_CFLAGS="$CFLAGS"
240 CFLAGS="-Wno-long-long"
241 AC_TRY_COMPILE(,,ac_cv_prog_cc_no_long_long=yes,
242                ac_cv_prog_cc_no_long_long=no)
243 CFLAGS="$save_CFLAGS"])
244
245 AC_PROG_CPP
246 AC_C_INLINE
247
248 gcc_AC_C_LONG_LONG
249 gcc_AC_C__BOOL
250
251 # sizeof(char) is 1 by definition.
252 AC_COMPILE_CHECK_SIZEOF(void *)
253 AC_COMPILE_CHECK_SIZEOF(short)
254 AC_COMPILE_CHECK_SIZEOF(int)
255 AC_COMPILE_CHECK_SIZEOF(long)
256 if test $ac_cv_c_long_long = yes; then
257   AC_COMPILE_CHECK_SIZEOF(long long)
258 fi
259 if test $ac_cv_c___int64 = yes; then
260   AC_COMPILE_CHECK_SIZEOF(__int64)
261 fi
262
263 # -----------------
264 # Find Ada compiler
265 # -----------------
266
267 # See if GNAT has been installed
268 gcc_AC_PROG_GNAT
269
270 if test x$have_gnat != xno ; then 
271 AC_CACHE_CHECK(whether ${ADAC} accepts -Wno-long-long,
272 ac_cv_prog_adac_no_long_long,
273 [cat >conftest.adb <<EOF
274 procedure conftest is begin null; end conftest;
275 EOF
276 if $ADAC -Wno-long-long -c conftest.adb 1>&5 2>&5 ; then
277   ac_cv_prog_adac_no_long_long=yes
278 else
279   ac_cv_prog_adac_no_long_long=no
280 fi
281 rm -f conftest*])
282 else
283   ac_cv_prog_adac_no_long_long=yes
284 fi
285
286 # ---------------------
287 # Warnings and checking
288 # ---------------------
289
290 strict1_warn=
291 if test $ac_cv_prog_cc_no_long_long = yes && \
292     test $ac_cv_prog_adac_no_long_long = yes ; then
293   strict1_warn="-pedantic -Wno-long-long"
294 fi
295 AC_SUBST(strict1_warn)
296
297 # If the native compiler is GCC, we can enable warnings even in stage1.  
298 # That's useful for people building cross-compilers, or just running a
299 # quick `make'.
300 warn_cflags=
301 if test "x$GCC" = "xyes"; then
302   warn_cflags='$(GCC_WARN_CFLAGS)'
303 fi
304 AC_SUBST(warn_cflags)
305
306 # Enable -Werror in bootstrap stage2 and later.
307 # Change the default to "no" on release branches.
308 AC_ARG_ENABLE(werror, 
309 [  --enable-werror         enable -Werror in bootstrap stage2 and later], [],
310 [enable_werror=yes])
311 if test x$enable_werror = xyes ; then
312   WERROR=-Werror
313 fi
314 AC_SUBST(WERROR)
315
316 # Enable expensive internal checks
317 AC_ARG_ENABLE(checking,
318 [  --enable-checking[=LIST]
319                           enable expensive run-time checks.  With LIST,
320                           enable only specific categories of checks.
321                           Categories are: misc,tree,rtl,rtlflag,gc,gcac,fold;
322                           default is misc,tree,gc,rtlflag],
323 [ac_checking=
324 ac_tree_checking=
325 ac_rtl_checking=
326 ac_rtlflag_checking=
327 ac_gc_checking=
328 ac_gc_always_collect=
329 ac_fold_checking=
330 case "${enableval}" in
331 yes)    ac_checking=1 ; ac_tree_checking=1 ; ac_gc_checking=1 ;
332         ac_rtlflag_checking=1 ;;
333 no)     ;;
334 *)      IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
335         set fnord $enableval; shift
336         IFS="$ac_save_IFS"
337         for check
338         do
339                 case $check in
340                 misc)   ac_checking=1 ;;
341                 tree)   ac_tree_checking=1 ;;
342                 rtlflag)        ac_rtlflag_checking=1 ;;
343                 rtl)    ac_rtl_checking=1 ;;
344                 gc)     ac_gc_checking=1 ;;
345                 gcac)   ac_gc_always_collect=1 ;;
346                 fold)   ac_fold_checking=1 ;;
347                 valgrind)       ac_checking_valgrind=1 ;;
348                 *)      AC_MSG_ERROR(unknown check category $check) ;;
349                 esac
350         done
351         ;;
352 esac
353 ], 
354 # Enable some checks by default for development versions of GCC
355 [ac_checking=1; ac_tree_checking=1; ac_gc_checking=1; ac_rtlflag_checking=1;])
356 nocommon_flag=""
357 if test x$ac_checking != x ; then
358   AC_DEFINE(ENABLE_CHECKING, 1,
359 [Define if you want more run-time sanity checks.  This one gets a grab
360    bag of miscellaneous but relatively cheap checks.])
361   nocommon_flag=-fno-common
362 fi
363 AC_SUBST(nocommon_flag)
364 if test x$ac_tree_checking != x ; then
365   AC_DEFINE(ENABLE_TREE_CHECKING, 1,
366 [Define if you want all operations on trees (the basic data
367    structure of the front ends) to be checked for dynamic type safety
368    at runtime.  This is moderately expensive.])
369 fi
370 if test x$ac_rtl_checking != x ; then
371   AC_DEFINE(ENABLE_RTL_CHECKING, 1,
372 [Define if you want all operations on RTL (the basic data structure
373    of the optimizer and back end) to be checked for dynamic type safety
374    at runtime.  This is quite expensive.])
375 fi
376 if test x$ac_rtlflag_checking != x ; then
377   AC_DEFINE(ENABLE_RTL_FLAG_CHECKING, 1,
378 [Define if you want RTL flag accesses to be checked against the RTL
379    codes that are supported for each access macro.  This is relatively
380    cheap.])
381 fi
382 if test x$ac_gc_checking != x ; then
383   AC_DEFINE(ENABLE_GC_CHECKING, 1,
384 [Define if you want the garbage collector to do object poisoning and
385    other memory allocation checks.  This is quite expensive.])
386 fi
387 if test x$ac_gc_always_collect != x ; then
388   AC_DEFINE(ENABLE_GC_ALWAYS_COLLECT, 1,
389 [Define if you want the garbage collector to operate in maximally
390    paranoid mode, validating the entire heap and collecting garbage at
391    every opportunity.  This is extremely expensive.])
392 fi
393 if test x$ac_fold_checking != x ; then
394   AC_DEFINE(ENABLE_FOLD_CHECKING, 1,
395 [Define if you want fold checked that it never destructs its argument.
396    This is quite expensive.])
397 fi
398 valgrind_path_defines=
399 valgrind_command=
400 if test x$ac_checking_valgrind != x ; then
401   # It is certainly possible that there's valgrind but no valgrind.h.
402   # GCC relies on making annotations so we must have both.
403   AC_MSG_CHECKING(for VALGRIND_DISCARD in <memcheck.h>)
404   AC_TRY_CPP(
405     [#include <memcheck.h>
406 #ifndef VALGRIND_DISCARD
407 #error VALGRIND_DISCARD not defined
408 #endif],
409   [gcc_cv_header_memcheck_h=yes], 
410   gcc_cv_header_memcheck_h=no)
411   AC_MSG_RESULT($gcc_cv_header_memcheck_h)
412   AC_CHECK_HEADER(valgrind.h, have_valgrind_h=yes, have_valgrind_h=no)
413   AM_PATH_PROG_WITH_TEST(valgrind_path, valgrind,
414         [$ac_dir/$ac_word --version | grep valgrind- >/dev/null 2>&1])
415   if test "x$valgrind_path" = "x" || (test $have_valgrind_h = no && test $gcc_cv_header_memcheck_h = no); then
416         AC_MSG_ERROR([*** Can't find both valgrind and valgrind.h/memcheck.h])
417   fi
418   valgrind_path_defines=-DVALGRIND_PATH='\"'$valgrind_path'\"'
419   valgrind_command="$valgrind_path -q"
420   AC_DEFINE(ENABLE_VALGRIND_CHECKING, 1,
421 [Define if you want to run subprograms and generated programs
422    through valgrind (a memory checker).  This is extremely expensive.])
423   if test $gcc_cv_header_memcheck_h = yes; then
424     AC_DEFINE(HAVE_MEMCHECK_H, 1,
425         [Define if valgrind's memcheck.h header is installed.])
426   fi
427 fi
428 AC_SUBST(valgrind_path_defines)
429 AC_SUBST(valgrind_command)
430
431 # Enable code coverage collection
432 AC_ARG_ENABLE(coverage,
433 [  --enable-coverage[=LEVEL]
434                           enable compiler\'s code coverage collection.
435                           Use to measure compiler performance and locate
436                           unused parts of the compiler. With LEVEL, specify
437                           optimization. Values are opt, noopt,
438                           default is noopt],
439 [case "${enableval}" in
440 yes|noopt)
441         coverage_flags="-fprofile-arcs -ftest-coverage -frandom-seed=\$@ -O0"
442         ;;
443 opt)
444         coverage_flags="-fprofile-arcs -ftest-coverage -frandom-seed=\$@ -O2"
445         ;;
446 *)
447         AC_MSG_ERROR(unknown coverage setting $enableval)
448         ;;
449 esac],
450 [coverage_flags=""])
451 AC_SUBST(coverage_flags)
452
453 # -------------------------------
454 # Miscenalleous configure options
455 # -------------------------------
456
457 # With stabs
458 AC_ARG_WITH(stabs,
459 [  --with-stabs            arrange to use stabs instead of host debug format],
460 stabs="$with_stabs",
461 stabs=no)
462
463 # With ELF
464 AC_ARG_WITH(elf,
465 [  --with-elf              arrange to use ELF instead of host debug format],
466 elf="$with_elf",
467 elf=no)
468
469 # Determine whether or not multilibs are enabled.
470 AC_ARG_ENABLE(multilib,
471 [  --enable-multilib       enable library support for multiple ABIs],
472 [], [enable_multilib=yes])
473 AC_SUBST(enable_multilib)
474
475 # Enable __cxa_atexit for C++.
476 AC_ARG_ENABLE(__cxa_atexit,
477 [  --enable-__cxa_atexit   enable __cxa_atexit for C++],
478 [], [])
479
480 # Enable threads
481 # Pass with no value to take the default
482 # Pass with a value to specify a thread package
483 AC_ARG_ENABLE(threads,
484 [  --enable-threads        enable thread usage for target GCC
485   --enable-threads=LIB    use LIB thread package for target GCC],,
486 enable_threads='')
487
488 enable_threads_flag=$enable_threads
489 # Check if a valid thread package
490 case x${enable_threads_flag} in
491         x | xno)
492                 # No threads
493                 target_thread_file='single'
494                 ;;
495         xyes)
496                 # default
497                 target_thread_file=''
498                 ;;
499         xdecosf1 | xirix | xmach | xos2 | xposix | xpthreads | xsingle | \
500         xsolaris | xwin32 | xdce | xrtems| xvxworks | xaix | xgnat)
501                 target_thread_file=$enable_threads_flag
502                 ;;
503         *)
504                 echo "$enable_threads is an unknown thread package" 1>&2
505                 exit 1
506                 ;;
507 esac
508
509 AC_ARG_ENABLE(objc-gc,
510 [  --enable-objc-gc       enable the use of Boehm's garbage collector with
511                           the GNU Objective-C runtime],
512 if test x$enable_objc_gc = xno; then
513         objc_boehm_gc=''
514 else
515         objc_boehm_gc=1
516 fi,
517 objc_boehm_gc='')
518
519 AC_ARG_WITH(dwarf2,
520 [  --with-dwarf2           force the default debug format to be DWARF 2],
521 dwarf2="$with_dwarf2",
522 dwarf2=no)
523
524 AC_ARG_ENABLE(shared,
525 [  --disable-shared        don't provide a shared libgcc],
526 [
527   case $enable_shared in
528   yes | no) ;;
529   *)
530     enable_shared=no
531     IFS="${IFS=         }"; ac_save_ifs="$IFS"; IFS="${IFS}:,"
532     for pkg in $enableval; do
533       if test "X$pkg" = "Xgcc" || test "X$pkg" = "Xlibgcc"; then
534         enable_shared=yes
535       fi
536     done
537     IFS="$ac_save_ifs"
538     ;;
539   esac
540 ], [enable_shared=yes])
541 AC_SUBST(enable_shared)
542
543 AC_ARG_WITH(sysroot,
544 [  --with-sysroot[=DIR] Search for usr/lib, usr/include, et al, within DIR.],
545 [
546  case ${with_sysroot} in
547  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_alias}/sys-root' ;;
548  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
549  esac
550    
551  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
552  CROSS_SYSTEM_HEADER_DIR='$(TARGET_SYSTEM_ROOT)$(NATIVE_SYSTEM_HEADER_DIR)'
553
554  if test "x$exec_prefix" = xNONE; then
555   if test "x$prefix" = xNONE; then
556    test_prefix=/usr/local
557   else
558    test_prefix=$prefix
559   fi
560  else
561   test_prefix=$exec_prefix
562  fi
563  case ${TARGET_SYSTEM_ROOT} in
564  "${test_prefix}"|"${test_prefix}/"*|\
565  '${exec_prefix}'|'${exec_prefix}/'*)
566    t="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE"
567    TARGET_SYSTEM_ROOT_DEFINE="$t"
568    ;;
569  esac
570 ], [
571  TARGET_SYSTEM_ROOT=
572  TARGET_SYSTEM_ROOT_DEFINE=
573  CROSS_SYSTEM_HEADER_DIR='$(gcc_tooldir)/sys-include'
574 ])
575 AC_SUBST(TARGET_SYSTEM_ROOT)
576 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
577 AC_SUBST(CROSS_SYSTEM_HEADER_DIR)
578
579 # Build with intermodule optimisations
580 AC_ARG_ENABLE(intermodule,
581 [  --enable-intermodule    build the compiler in one step],
582 [case ${enable_intermodule} in
583   yes) onestep="-onestep";;
584   *) onestep="";;
585 esac],
586 [onestep=""])
587 AC_SUBST(onestep)
588
589 # -------------------------
590 # Checks for other programs
591 # -------------------------
592
593 AC_PROG_MAKE_SET
594
595 # Find some useful tools
596 AC_PROG_AWK
597 gcc_AC_PROG_LN
598 gcc_AC_PROG_LN_S
599 AC_PROG_RANLIB
600 gcc_AC_PROG_INSTALL
601
602 # See if cmp has --ignore-initial.
603 gcc_AC_PROG_CMP_IGNORE_INITIAL
604
605 # See if we have the mktemp command.
606 AC_CHECK_PROG(have_mktemp_command, mktemp, yes, no)
607
608 # Do we have a single-tree copy of texinfo?
609 if test -f $srcdir/../texinfo/Makefile.in; then
610   MAKEINFO='$(objdir)/../texinfo/makeinfo/makeinfo'
611   gcc_cv_prog_makeinfo_modern=yes
612   AC_MSG_RESULT([Using makeinfo from the unified source tree.])
613 else
614   # See if makeinfo has been installed and is modern enough
615   # that we can use it.
616   gcc_AC_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
617   [GNU texinfo.* \([0-9][0-9.]*\)],
618   [4.[2-9]*])
619 fi
620
621 if test $gcc_cv_prog_makeinfo_modern = no; then
622   AC_MSG_WARN([
623 *** Makeinfo is missing or too old.
624 *** Info documentation will not be built.])
625   BUILD_INFO=
626 else
627   BUILD_INFO=info               AC_SUBST(BUILD_INFO)
628 fi
629
630 # Is pod2man recent enough to regenerate manpages?
631 AC_MSG_CHECKING([for recent Pod::Man])
632 if (perl -e 'use 1.10 Pod::Man') >/dev/null 2>&1; then
633   AC_MSG_RESULT(yes)
634   GENERATED_MANPAGES=generated-manpages         AC_SUBST(GENERATED_MANPAGES)
635 else
636   AC_MSG_RESULT(no)
637   GENERATED_MANPAGES=
638 fi
639
640 # How about lex?
641 dnl Don't use AC_PROG_LEX; we insist on flex.
642 dnl LEXLIB is not useful in gcc.
643 if test -f $srcdir/../flex/skel.c; then
644   FLEX='$(objdir)/../flex/flex'
645 else
646   AC_CHECK_PROG(FLEX, flex, flex, ${CONFIG_SHELL-/bin/sh} ${srcdir}/../missing flex)
647 fi
648
649 # Bison?
650 # The -L switch is so bison can find its skeleton file.
651 if test -f $srcdir/../bison/bison.simple; then
652   BISON='$(objdir)/../bison/bison -L $(srcdir)/../bison/'
653 else
654   AC_CHECK_PROG(BISON, bison, bison, ${CONFIG_SHELL-/bin/sh} ${srcdir}/../missing bison)
655 fi
656
657 # --------------------
658 # Checks for C headers
659 # --------------------
660
661 AC_MSG_CHECKING(for GNU C library)
662 AC_CACHE_VAL(gcc_cv_glibc,
663 [AC_TRY_COMPILE(
664   [#include <features.h>],[
665 #if ! (defined __GLIBC__ || defined __GNU_LIBRARY__)
666 #error Not a GNU C library system
667 #endif], 
668   [gcc_cv_glibc=yes], 
669   gcc_cv_glibc=no)])
670 AC_MSG_RESULT($gcc_cv_glibc)
671 if test $gcc_cv_glibc = yes; then
672   AC_DEFINE(_GNU_SOURCE, 1, [Always define this when using the GNU C Library])
673 fi
674
675 AC_HEADER_STDC
676 AC_HEADER_TIME
677 gcc_AC_HEADER_STDBOOL
678 gcc_AC_HEADER_STRING
679 AC_HEADER_SYS_WAIT
680 AC_CHECK_HEADERS(limits.h stddef.h string.h strings.h stdlib.h time.h \
681                  fcntl.h unistd.h sys/file.h sys/time.h sys/mman.h \
682                  sys/resource.h sys/param.h sys/times.h sys/stat.h \
683                  direct.h malloc.h langinfo.h ldfcn.h locale.h wchar.h)
684
685 # Check for thread headers.
686 AC_CHECK_HEADER(thread.h, [have_thread_h=yes], [have_thread_h=])
687 AC_CHECK_HEADER(pthread.h, [have_pthread_h=yes], [have_pthread_h=])
688
689 # These tests can't be done till we know if we have limits.h.
690 gcc_AC_C_CHAR_BIT
691 AC_C_BIGENDIAN_CROSS
692
693 # --------
694 # UNSORTED
695 # --------
696
697 # Stage specific cflags for build.
698 stage1_cflags=
699 case $build in
700 vax-*-*)
701   if test x$GCC = xyes
702   then
703     stage1_cflags="-Wa,-J"
704   else
705     stage1_cflags="-J"
706   fi
707   ;;
708 powerpc-*-darwin*)
709   # The spiffy cpp-precomp chokes on some legitimate constructs in GCC
710   # sources; use -no-cpp-precomp to get to GNU cpp.
711   # Apple's GCC has bugs in designated initializer handling, so disable
712   # that too.
713   stage1_cflags="-no-cpp-precomp -DHAVE_DESIGNATED_INITIALIZERS=0"
714   ;;
715 esac
716 AC_SUBST(stage1_cflags)
717
718 # These libraries may be used by collect2.
719 # We may need a special search path to get them linked.
720 AC_CACHE_CHECK(for collect2 libraries, gcc_cv_collect2_libs,
721 [save_LIBS="$LIBS"
722 for libs in '' -lld -lmld \
723                 '-L/usr/lib/cmplrs/cc2.11 -lmld' \
724                 '-L/usr/lib/cmplrs/cc3.11 -lmld'
725 do
726         LIBS="$libs"
727         AC_TRY_LINK_FUNC(ldopen,
728                 [gcc_cv_collect2_libs="$libs"; break])
729 done
730 LIBS="$save_LIBS"
731 test -z "$gcc_cv_collect2_libs" && gcc_cv_collect2_libs='none required'])
732 case $gcc_cv_collect2_libs in
733         "none required")        ;;
734         *)      COLLECT2_LIBS=$gcc_cv_collect2_libs ;;
735 esac
736 AC_SUBST(COLLECT2_LIBS)
737
738 # When building Ada code on Alpha, we need exc_resume which is usually in
739 # -lexc.  So test for it.
740 save_LIBS="$LIBS"
741 LIBS=
742 AC_SEARCH_LIBS(exc_resume, exc)
743 GNAT_LIBEXC="$LIBS"
744 LIBS="$save_LIBS"
745 AC_SUBST(GNAT_LIBEXC)
746
747 # Some systems put ldexp and frexp in libm instead of libc; assume
748 # they're both in the same place.  jcf-dump needs them.
749 save_LIBS="$LIBS"
750 LIBS=
751 AC_SEARCH_LIBS(ldexp, m)
752 LDEXP_LIB="$LIBS"
753 LIBS="$save_LIBS"
754 AC_SUBST(LDEXP_LIB)
755
756 # Use <inttypes.h> only if it exists,
757 # doesn't clash with <sys/types.h>, and declares intmax_t.
758 AC_MSG_CHECKING(for inttypes.h)
759 AC_CACHE_VAL(gcc_cv_header_inttypes_h,
760 [AC_TRY_COMPILE(
761   [#include <sys/types.h>
762 #include <inttypes.h>],
763   [intmax_t i = -1;],
764   [gcc_cv_header_inttypes_h=yes],
765   gcc_cv_header_inttypes_h=no)])
766 AC_MSG_RESULT($gcc_cv_header_inttypes_h)
767 if test $gcc_cv_header_inttypes_h = yes; then
768   AC_DEFINE(HAVE_INTTYPES_H, 1,
769         [Define if you have a working <inttypes.h> header file.])
770 fi
771
772 dnl Disabled until we have a complete test for buggy enum bitfields.
773 dnl gcc_AC_C_ENUM_BF_UNSIGNED
774
775 AC_CHECK_FUNCS(times clock dup2 kill getrlimit setrlimit atoll atoq \
776         sysconf strsignal putc_unlocked fputc_unlocked fputs_unlocked \
777         fwrite_unlocked fprintf_unlocked getrusage nl_langinfo \
778         scandir alphasort gettimeofday mbstowcs wcswidth mmap mincore \
779         setlocale)
780
781 if test x$ac_cv_func_mbstowcs = xyes; then
782   AC_CACHE_CHECK(whether mbstowcs works, gcc_cv_func_mbstowcs_works,
783 [    AC_TRY_RUN([#include <stdlib.h>
784 int main()
785 {
786   mbstowcs(0, "", 0);
787   return 0;
788 }],
789     gcc_cv_func_mbstowcs_works=yes,
790     gcc_cv_func_mbstowcs_works=no,
791     gcc_cv_func_mbstowcs_works=yes)])
792   if test x$gcc_cv_func_mbstowcs_works = xyes; then
793     AC_DEFINE(HAVE_WORKING_MBSTOWCS, 1,
794   [Define this macro if mbstowcs does not crash when its
795    first argument is NULL.])
796   fi
797 fi
798
799 gcc_AC_CHECK_TYPE(ssize_t, int)
800
801 # Try to determine the array type of the second argument of getgroups
802 # for the target system (int or gid_t).
803 AC_TYPE_GETGROUPS
804 if test "${target}" = "${build}"; then
805   TARGET_GETGROUPS_T=$ac_cv_type_getgroups
806 else
807   case "${target}" in
808         # This condition may need some tweaking.  It should include all
809         # targets where the array type of the second argument of getgroups
810         # is int and the type of gid_t is not equivalent to int.
811         *-*-sunos* | *-*-ultrix*)
812                 TARGET_GETGROUPS_T=int
813                 ;;
814         *)
815                 TARGET_GETGROUPS_T=gid_t
816                 ;;
817   esac
818 fi
819 AC_SUBST(TARGET_GETGROUPS_T)
820
821 gcc_AC_FUNC_PRINTF_PTR
822 gcc_AC_FUNC_MMAP_BLACKLIST
823
824 case "${host}" in
825 *-*-uwin*)
826   AC_MSG_ERROR([
827 *** UWIN may not be used as a host platform because
828 *** linking with posix.dll is not allowed by the GNU GPL])
829   ;;
830 *-*-*vms*)
831   # Under VMS, vfork works very different than on Unix. The standard test 
832   # won't work, and it isn't easily adaptable. It makes more sense to
833   # just force it.
834   ac_cv_func_vfork_works=yes
835   ;;
836 esac
837 AC_FUNC_VFORK
838
839 AM_ICONV
840 # Until we have in-tree GNU iconv:
841 LIBICONV_DEP=
842 AC_SUBST(LIBICONV_DEP)
843
844 AM_LC_MESSAGES
845
846 # We will need to find libiberty.h and ansidecl.h
847 saved_CFLAGS="$CFLAGS"
848 CFLAGS="$CFLAGS -I${srcdir} -I${srcdir}/../include"
849 gcc_AC_CHECK_DECLS(getenv atol sbrk abort atof getcwd getwd \
850         strsignal putc_unlocked fputs_unlocked fwrite_unlocked \
851         fprintf_unlocked strstr errno vasprintf \
852         malloc realloc calloc free basename getopt clock, , ,[
853 #include "ansidecl.h"
854 #include "system.h"])
855
856 gcc_AC_CHECK_DECLS(getrlimit setrlimit getrusage, , ,[
857 #include "ansidecl.h"
858 #include "system.h"
859 #ifdef HAVE_SYS_RESOURCE_H
860 #include <sys/resource.h>
861 #endif
862 ])
863
864 AC_TRY_COMPILE([
865 #include "ansidecl.h"
866 #include "system.h"
867 #ifdef HAVE_SYS_RESOURCE_H
868 #include <sys/resource.h>
869 #endif
870 ],[rlim_t l = 0;],,[AC_DEFINE([rlim_t],[long],
871 [Define to \`long' if <sys/resource.h> doesn't define.])])
872
873 gcc_AC_CHECK_DECLS(ldgetname, , ,[
874 #include "ansidecl.h"
875 #include "system.h"
876 #ifdef HAVE_LDFCN_H
877 #include <ldfcn.h>
878 #endif
879 ])
880
881 gcc_AC_CHECK_DECLS(times, , ,[
882 #include "ansidecl.h"
883 #include "system.h"
884 #ifdef HAVE_SYS_TIMES_H
885 #include <sys/times.h>
886 #endif
887 ])
888
889 # More time-related stuff.
890 AC_CACHE_CHECK(for struct tms, ac_cv_struct_tms, [
891 AC_TRY_COMPILE([
892 #include "ansidecl.h"
893 #include "system.h"
894 #ifdef HAVE_SYS_TIMES_H
895 #include <sys/times.h>
896 #endif
897 ], [struct tms tms;], ac_cv_struct_tms=yes, ac_cv_struct_tms=no)])
898 if test $ac_cv_struct_tms = yes; then
899   AC_DEFINE(HAVE_STRUCT_TMS, 1,
900   [Define if <sys/times.h> defines struct tms.])
901 fi
902
903 # use gcc_cv_* here because this doesn't match the behavior of AC_CHECK_TYPE.
904 # revisit after autoconf 2.50.
905 AC_CACHE_CHECK(for clock_t, gcc_cv_type_clock_t, [
906 AC_TRY_COMPILE([
907 #include "ansidecl.h"
908 #include "system.h"
909 ], [clock_t x;], gcc_cv_type_clock_t=yes, gcc_cv_type_clock_t=no)])
910 if test $gcc_cv_type_clock_t = yes; then
911   AC_DEFINE(HAVE_CLOCK_T, 1,
912   [Define if <time.h> defines clock_t.])
913 fi
914
915 AC_CACHE_CHECK(for uchar, gcc_cv_type_uchar,
916 [AC_TRY_COMPILE([
917 #include "ansidecl.h"
918 #include "system.h"
919 ], 
920 [if ((uchar *)0) return 0;
921  if (sizeof(uchar)) return 0;],
922 ac_cv_type_uchar=yes, ac_cv_type_uchar=no)])
923 if test $ac_cv_type_uchar = yes; then
924   AC_DEFINE(HAVE_UCHAR, 1,
925   [Define if <sys/types.h> defines \`uchar'.])
926 fi
927
928 # Restore CFLAGS from before the gcc_AC_NEED_DECLARATIONS tests.
929 CFLAGS="$saved_CFLAGS"
930
931 gcc_AC_INITFINI_ARRAY
932
933 # mkdir takes a single argument on some systems. 
934 gcc_AC_FUNC_MKDIR_TAKES_ONE_ARG
935
936 # File extensions
937 manext='.1'
938 objext='.o'
939 AC_SUBST(manext)
940 AC_SUBST(objext)
941
942 # With Setjmp/Longjmp based exception handling.
943 AC_ARG_ENABLE(sjlj-exceptions,
944 [  --enable-sjlj-exceptions
945                           arrange to use setjmp/longjmp exception handling],
946 [sjlj=`if test $enableval = yes; then echo 1; else echo 0; fi`
947 AC_DEFINE_UNQUOTED(CONFIG_SJLJ_EXCEPTIONS, $sjlj,
948   [Define 0/1 to force the choice for exception handling model.])])
949
950 AC_CHECK_LIB(unwind, main, use_libunwind_default=yes, use_libunwind_default=no)
951 # Use libunwind based exception handling.
952 AC_ARG_ENABLE(libunwind-exceptions,
953 [  --enable-libunwind-exceptions  force use libunwind for exceptions],
954 use_libunwind_exceptions=$enableval,
955 use_libunwind_exceptions=$use_libunwind_default)
956 if test x"$use_libunwind_exceptions" = xyes; then
957    AC_DEFINE(USE_LIBUNWIND_EXCEPTIONS, 1,
958         [Define if gcc should use -lunwind.])
959 fi
960
961 # --------------------------------------------------------
962 # Build, host, and target specific configuration fragments
963 # --------------------------------------------------------
964
965 target_gtfiles=
966 build_xm_file=
967 build_xm_defines=
968 build_install_headers_dir=install-headers-tar
969 build_exeext=
970 host_xm_file=
971 host_xm_defines=
972 host_xmake_file=
973 host_exeext=
974
975 # Decode the host machine, then the target machine.
976 # For the host machine, we save the xm_file variable as host_xm_file;
977 # then we decode the target machine and forget everything else
978 # that came from the host machine.
979 for machine in $build $host $target; do
980         . ${srcdir}/config.gcc
981 done
982
983 extra_objs="${host_extra_objs} ${extra_objs}"
984
985 # Default the target-machine variables that were not explicitly set.
986 if test x"$tm_file" = x
987 then tm_file=$cpu_type/$cpu_type.h; fi
988
989 if test x"$extra_headers" = x
990 then extra_headers=; fi
991
992 if test x$md_file = x
993 then md_file=$cpu_type/$cpu_type.md; fi
994
995 if test x$out_file = x
996 then out_file=$cpu_type/$cpu_type.c; fi
997
998 if test x"$tmake_file" = x
999 then tmake_file=$cpu_type/t-$cpu_type
1000 fi
1001
1002 if test x"$dwarf2" = xyes
1003 then tm_file="$tm_file tm-dwarf2.h"
1004 fi
1005
1006 # Say what files are being used for the output code and MD file.
1007 echo "Using \`$srcdir/config/$out_file' for machine-specific logic."
1008 echo "Using \`$srcdir/config/$md_file' as machine description file."
1009
1010 # If any of the xm_file variables contain nonexistent files, warn
1011 # about them and drop them.
1012
1013 bx=
1014 for x in $build_xm_file; do
1015   if    test -f $srcdir/config/$x
1016   then      bx="$bx $x"
1017   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1018   fi
1019 done
1020 build_xm_file="$bx"
1021
1022 hx=
1023 for x in $host_xm_file; do
1024   if    test -f $srcdir/config/$x
1025   then      hx="$hx $x"
1026   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1027   fi
1028 done
1029 host_xm_file="$hx"
1030
1031 tx=
1032 for x in $xm_file; do
1033   if    test -f $srcdir/config/$x
1034   then      tx="$tx $x"
1035   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1036   fi
1037 done
1038 xm_file="$tx"
1039
1040 count=a
1041 for f in $tm_file; do
1042         count=${count}x
1043 done
1044 if test $count = ax; then
1045         echo "Using \`$srcdir/config/$tm_file' as target machine macro file."
1046 else
1047         echo "Using the following target machine macro files:"
1048         for f in $tm_file; do
1049                 echo "  $srcdir/config/$f"
1050         done
1051 fi
1052
1053 if test x$need_64bit_hwint = xyes; then
1054         AC_DEFINE(NEED_64BIT_HOST_WIDE_INT, 1,
1055 [Define to 1 if HOST_WIDE_INT must be 64 bits wide (see hwint.h).])
1056 fi
1057
1058 count=a
1059 for f in $host_xm_file; do
1060         count=${count}x
1061 done
1062 if test $count = a; then
1063         :
1064 elif test $count = ax; then
1065         echo "Using \`$srcdir/config/$host_xm_file' as host machine macro file."
1066 else
1067         echo "Using the following host machine macro files:"
1068         for f in $host_xm_file; do
1069                 echo "  $srcdir/config/$f"
1070         done
1071 fi
1072 echo "Using ${out_host_hook_obj} for host machine hooks."
1073
1074 if test "$host_xm_file" != "$build_xm_file"; then
1075         count=a
1076         for f in $build_xm_file; do
1077                 count=${count}x
1078         done
1079         if test $count = a; then
1080                 :
1081         elif test $count = ax; then
1082                 echo "Using \`$srcdir/config/$build_xm_file' as build machine macro file."
1083         else
1084                 echo "Using the following build machine macro files:"
1085                 for f in $build_xm_file; do
1086                         echo "  $srcdir/config/$f"
1087                 done
1088         fi
1089 fi
1090
1091 if test x$thread_file = x; then
1092         if test x$target_thread_file != x; then
1093                 thread_file=$target_thread_file
1094         else
1095                 thread_file='single'
1096         fi
1097 fi
1098
1099 if test x$enable___cxa_atexit = xyes || \
1100    test x$enable___cxa_atexit = x -a x$default_use_cxa_atexit = xyes; then
1101   AC_DEFINE(DEFAULT_USE_CXA_ATEXIT, 1,
1102   [Define if you want to use __cxa_atexit, rather than atexit, to
1103    register C++ destructors for local statics and global objects.
1104    This is essential for fully standards-compliant handling of
1105    destructors, but requires __cxa_atexit in libc.])
1106 fi
1107
1108 # Look for a file containing extra machine modes.
1109 if test -n "$extra_modes" && test -f $srcdir/config/$extra_modes; then
1110   extra_modes_file='$(srcdir)'/config/${extra_modes}
1111   AC_SUBST(extra_modes_file)
1112   AC_DEFINE_UNQUOTED(EXTRA_MODES_FILE, "config/$extra_modes",
1113   [Define to the name of a file containing a list of extra machine modes
1114    for this architecture.])
1115   AC_DEFINE(EXTRA_CC_MODES, 1,
1116   [Define if the target architecture needs extra machine modes to represent
1117    the results of comparisons.])
1118 fi
1119
1120 # auto-host.h is the file containing items generated by autoconf and is
1121 # the first file included by config.h.
1122 # If host=build, it is correct to have bconfig include auto-host.h
1123 # as well.  If host!=build, we are in error and need to do more 
1124 # work to find out the build config parameters.
1125 if test x$host = x$build
1126 then
1127         build_auto=auto-host.h
1128         FORBUILD=..
1129 else
1130         # We create a subdir, then run autoconf in the subdir.
1131         # To prevent recursion we set host and build for the new
1132         # invocation of configure to the build for this invocation
1133         # of configure. 
1134         tempdir=build.$$
1135         rm -rf $tempdir
1136         mkdir $tempdir
1137         cd $tempdir
1138         case ${srcdir} in
1139         /* | [A-Za-z]:[\\/]* ) realsrcdir=${srcdir};;
1140         *) realsrcdir=../${srcdir};;
1141         esac
1142         saved_CFLAGS="${CFLAGS}"
1143         CC="${CC_FOR_BUILD}" CFLAGS="${CFLAGS_FOR_BUILD}" \
1144         ${realsrcdir}/configure \
1145                 --target=$target_alias --host=$build_alias --build=$build_alias
1146         CFLAGS="${saved_CFLAGS}"
1147
1148         # We just finished tests for the build machine, so rename
1149         # the file auto-build.h in the gcc directory.
1150         mv auto-host.h ../auto-build.h
1151         cd ..
1152         rm -rf $tempdir
1153         build_auto=auto-build.h
1154         FORBUILD=../${build_subdir}
1155 fi
1156 AC_SUBST(FORBUILD)
1157
1158 tm_file="${tm_file} defaults.h"
1159 tm_p_file="${tm_p_file} tm-preds.h"
1160 host_xm_file="auto-host.h ansidecl.h ${host_xm_file}"
1161 build_xm_file="${build_auto} ansidecl.h ${build_xm_file}"
1162 # We don't want ansidecl.h in target files, write code there in ISO/GNU C.
1163 # put this back in temporarily.
1164 xm_file="ansidecl.h ${xm_file}"
1165
1166 # --------
1167 # UNSORTED
1168 # --------
1169
1170 # Get the version trigger filename from the toplevel
1171 if test "${with_gcc_version_trigger+set}" = set; then
1172         gcc_version_trigger=$with_gcc_version_trigger
1173 else
1174         gcc_version_trigger=${srcdir}/version.c
1175 fi
1176 changequote(,)dnl
1177 gcc_version_full=`grep version_string ${gcc_version_trigger} | sed -e 's/.*"\([^"]*\)".*/\1/'`
1178 gcc_version=`echo ${gcc_version_full} | sed -e 's/\([^ ]*\) .*/\1/'`
1179
1180 # Compile in configure arguments.
1181 if test -f configargs.h ; then
1182         # Being re-configured.
1183         gcc_config_arguments=`grep configuration_arguments configargs.h | sed -e 's/.*"\([^"]*\)".*/\1/'`
1184         gcc_config_arguments="$gcc_config_arguments : (reconfigured) $TOPLEVEL_CONFIGURE_ARGUMENTS"
1185 else
1186         gcc_config_arguments="$TOPLEVEL_CONFIGURE_ARGUMENTS"
1187 fi
1188 cat > configargs.h <<EOF
1189 /* Generated automatically. */
1190 static const char configuration_arguments[] = "$gcc_config_arguments";
1191 static const char thread_model[] = "$thread_file";
1192
1193 static const struct {
1194   const char *name, *value;
1195 } configure_default_options[] = $configure_default_options;
1196 EOF
1197 changequote([,])dnl
1198
1199 # Internationalization
1200 PACKAGE=gcc
1201 VERSION="$gcc_version"
1202 AC_SUBST(PACKAGE)
1203 AC_SUBST(VERSION)
1204
1205 ZW_GNU_GETTEXT_SISTER_DIR
1206
1207 # If LIBINTL contains LIBICONV, then clear LIBICONV so we don't get
1208 # -liconv on the link line twice.
1209 case "$LIBINTL" in *$LIBICONV*)
1210         LIBICONV= ;;
1211 esac
1212
1213 # Windows32 Registry support for specifying GCC installation paths.
1214 AC_ARG_ENABLE(win32-registry,
1215 [  --disable-win32-registry
1216                           disable lookup of installation paths in the
1217                           Registry on Windows hosts
1218   --enable-win32-registry enable registry lookup (default)
1219   --enable-win32-registry=KEY
1220                           use KEY instead of GCC version as the last portion
1221                           of the registry key],,)
1222 case $host_os in
1223         win32 | pe | cygwin* | mingw32* | uwin*)
1224 AC_MSG_CHECKING(whether windows registry support is requested)
1225 if test "x$enable_win32_registry" != xno; then
1226   AC_DEFINE(ENABLE_WIN32_REGISTRY, 1,
1227 [Define to 1 if installation paths should be looked up in Windows32
1228    Registry. Ignored on non windows32 hosts.])
1229   AC_MSG_RESULT(yes)
1230   AC_SEARCH_LIBS(RegOpenKeyExA, advapi32)
1231 else
1232   AC_MSG_RESULT(no)
1233 fi
1234
1235 # Check if user specified a different registry key.
1236 case "x${enable_win32_registry}" in
1237 x | xyes)
1238   # default.
1239   gcc_cv_win32_registry_key="$VERSION"
1240   ;;
1241 xno)
1242   # no registry lookup.
1243   gcc_cv_win32_registry_key=''
1244   ;;
1245 *)
1246   # user-specified key.
1247   gcc_cv_win32_registry_key="$enable_win32_registry"
1248   ;;
1249 esac
1250
1251 if test "x$enable_win32_registry" != xno; then
1252   AC_MSG_CHECKING(registry key on windows hosts)
1253   AC_DEFINE_UNQUOTED(WIN32_REGISTRY_KEY, "$gcc_cv_win32_registry_key",
1254         [Define to be the last portion of registry key on windows hosts.])
1255   AC_MSG_RESULT($gcc_cv_win32_registry_key)
1256 fi
1257 ;;
1258 esac
1259
1260 # Get an absolute path to the GCC top-level source directory
1261 holddir=`${PWDCMD-pwd}`
1262 cd $srcdir
1263 topdir=`${PWDCMD-pwd}`
1264 cd $holddir
1265
1266 # Conditionalize the makefile for this host machine.
1267 xmake_file=
1268 for f in .. ${host_xmake_file}
1269 do
1270         if test -f ${srcdir}/config/$f
1271         then
1272                 xmake_file="${xmake_file} \$(srcdir)/config/$f"
1273         fi
1274 done
1275
1276 # Conditionalize the makefile for this target machine.
1277 tmake_file_=
1278 for f in .. ${tmake_file}
1279 do
1280         if test -f ${srcdir}/config/$f
1281         then
1282                 tmake_file_="${tmake_file_} \$(srcdir)/config/$f"
1283         fi
1284 done
1285 tmake_file="${tmake_file_}"
1286
1287 symbolic_link='ln -s'
1288
1289 # If the host doesn't support symlinks, modify CC in
1290 # FLAGS_TO_PASS so CC="stage1/xgcc -Bstage1/" works.
1291 # Otherwise, we can use "CC=$(CC)".
1292 rm -f symtest.tem
1293 if $symbolic_link $srcdir/gcc.c symtest.tem 2>/dev/null
1294 then
1295         cc_set_by_configure="\$(CC)"
1296         quoted_cc_set_by_configure="\$(CC)"
1297         stage_prefix_set_by_configure="\$(STAGE_PREFIX)"
1298         quoted_stage_prefix_set_by_configure="\$(STAGE_PREFIX)"
1299 else
1300         rm -f symtest.tem
1301         if cp -p $srcdir/gcc.c symtest.tem 2>/dev/null
1302         then
1303                 symbolic_link="cp -p"
1304         else
1305                 symbolic_link="cp"
1306         fi
1307         cc_set_by_configure="\`case '\$(CC)' in stage*) echo '\$(CC)' | sed -e 's|stage|../stage|g';; *) echo '\$(CC)';; esac\`"
1308         quoted_cc_set_by_configure="\\\`case '\\\$(CC)' in stage*) echo '\\\$(CC)' | sed -e 's|stage|../stage|g';; *) echo '\\\$(CC)';; esac\\\`"
1309         stage_prefix_set_by_configure="\`case '\$(STAGE_PREFIX)' in stage*) echo '\$(STAGE_PREFIX)' | sed -e 's|stage|../stage|g';; *) echo '\$(STAGE_PREFIX)';; esac\`"
1310         quoted_stage_prefix_set_by_configure="\\\`case '\\\$(STAGE_PREFIX)' in stage*) echo '\\\$(STAGE_PREFIX)' | sed -e 's|stage|../stage|g';; *) echo '\\\$(STAGE_PREFIX)';; esac\\\`"
1311 fi
1312 rm -f symtest.tem
1313
1314 out_object_file=`basename $out_file .c`.o
1315
1316 tm_file_list=
1317 tm_include_list=
1318 for f in $tm_file; do
1319   case $f in
1320     defaults.h )
1321        tm_file_list="${tm_file_list} \$(srcdir)/$f"
1322        tm_include_list="${tm_include_list} $f"
1323        ;;
1324     * )
1325        tm_file_list="${tm_file_list} \$(srcdir)/config/$f"
1326        tm_include_list="${tm_include_list} config/$f"
1327        ;;
1328   esac
1329 done
1330
1331 tm_p_file_list=
1332 tm_p_include_list=
1333 for f in $tm_p_file; do
1334   case $f in
1335     tm-preds.h )
1336        tm_p_file_list="${tm_p_file_list} $f"
1337        tm_p_include_list="${tm_p_include_list} $f"
1338        ;;
1339     * )
1340        tm_p_file_list="${tm_p_file_list} \$(srcdir)/config/$f"
1341        tm_p_include_list="${tm_p_include_list} config/$f"
1342   esac
1343 done
1344
1345 xm_file_list=
1346 xm_include_list=
1347 for f in $xm_file; do
1348   case $f in
1349     ansidecl.h )
1350        xm_file_list="${xm_file_list} \$(srcdir)/../include/$f"
1351        xm_include_list="${xm_include_list} $f"
1352        ;;
1353     auto-host.h )
1354        xm_file_list="${xm_file_list} $f"
1355        xm_include_list="${xm_include_list} $f"
1356        ;;
1357     * )
1358        xm_file_list="${xm_file_list} \$(srcdir)/config/$f"
1359        xm_include_list="${xm_include_list} config/$f"
1360        ;;
1361   esac
1362 done
1363
1364 host_xm_file_list=
1365 host_xm_include_list=
1366 for f in $host_xm_file; do
1367   case $f in
1368     ansidecl.h )
1369        host_xm_file_list="${host_xm_file_list} \$(srcdir)/../include/$f"
1370        host_xm_include_list="${host_xm_include_list} $f"
1371        ;;
1372     auto-host.h )
1373        host_xm_file_list="${host_xm_file_list} $f"
1374        host_xm_include_list="${host_xm_include_list} $f"
1375        ;;
1376     * )
1377        host_xm_file_list="${host_xm_file_list} \$(srcdir)/config/$f"
1378        host_xm_include_list="${host_xm_include_list} config/$f"
1379        ;;
1380   esac
1381 done
1382
1383 build_xm_file_list=
1384 for f in $build_xm_file; do
1385   case $f in
1386     ansidecl.h )
1387        build_xm_file_list="${build_xm_file_list} \$(srcdir)/../include/$f"
1388        build_xm_include_list="${build_xm_include_list} $f"
1389        ;;
1390     auto-build.h | auto-host.h )
1391        build_xm_file_list="${build_xm_file_list} $f"
1392        build_xm_include_list="${build_xm_include_list} $f"
1393        ;;
1394     * )
1395        build_xm_file_list="${build_xm_file_list} \$(srcdir)/config/$f"
1396        build_xm_include_list="${build_xm_include_list} config/$f"
1397        ;;
1398   esac
1399 done
1400
1401 # Define macro CROSS_COMPILE in compilation if this is a cross-compiler.
1402 # Also use all.cross instead of all.internal and adjust SYSTEM_HEADER_DIR.
1403 CROSS=                                          AC_SUBST(CROSS)
1404 ALL=all.internal                                AC_SUBST(ALL)
1405 SYSTEM_HEADER_DIR='$(NATIVE_SYSTEM_HEADER_DIR)' AC_SUBST(SYSTEM_HEADER_DIR)
1406 if test x$host != x$target
1407 then
1408         CROSS="-DCROSS_COMPILE"
1409         ALL=all.cross
1410         SYSTEM_HEADER_DIR='$(CROSS_SYSTEM_HEADER_DIR)'
1411         case "$host","$target" in
1412         # Darwin crosses can use the host system's libraries and headers,
1413         # because of the fat library support.  Of course, it must be the
1414         # same version of Darwin on both sides.  Allow the user to
1415         # just say --target=foo-darwin without a version number to mean
1416         # "the version on this system".
1417             *-*-darwin*,*-*-darwin*)
1418                 hostos=`echo $host | sed 's/.*-darwin/darwin/'`
1419                 targetos=`echo $target | sed 's/.*-darwin/darwin/'`
1420                 if test $hostos = $targetos -o $targetos = darwin ; then
1421                     CROSS=
1422                     SYSTEM_HEADER_DIR='$(NATIVE_SYSTEM_HEADER_DIR)'
1423                     with_headers=yes
1424                 fi
1425                 ;;
1426
1427             i?86-*-*,x86_64-*-* \
1428             | powerpc*-*-*,powerpc64*-*-*)
1429                 CROSS="$CROSS -DNATIVE_CROSS" ;;
1430         esac
1431 elif test "x$TARGET_SYSTEM_ROOT" != x; then
1432         # This is just $(TARGET_SYSTEM_ROOT)$(NATIVE_SYSTEM_HEADER_DIR)
1433         SYSTEM_HEADER_DIR='$(CROSS_SYSTEM_HEADER_DIR)'
1434 fi
1435
1436 # If this is a cross-compiler that does not
1437 # have its own set of headers then define
1438 # inhibit_libc
1439
1440 # If this is using newlib, without having the headers available now,
1441 # then define inhibit_libc in LIBGCC2_CFLAGS.
1442 # This prevents libgcc2 from containing any code which requires libc
1443 # support.
1444 inhibit_libc=
1445 if { { test x$host != x$target && test "x$with_sysroot" = x ; } ||
1446        test x$with_newlib = xyes ; } &&
1447      { test "x$with_headers" = x || test "x$with_headers" = xno ; } ; then
1448        inhibit_libc=-Dinhibit_libc
1449 fi
1450 AC_SUBST(inhibit_libc)
1451
1452 # When building gcc with a cross-compiler, we need to adjust things so
1453 # that the generator programs are still built with the native compiler.
1454 # Also, we cannot run fixincludes or fix-header.
1455
1456 # These are the normal (build=host) settings:
1457 BUILD_PREFIX=                   AC_SUBST(BUILD_PREFIX)
1458 BUILD_PREFIX_1=ignore-          AC_SUBST(BUILD_PREFIX_1)
1459 CC_FOR_BUILD='$(CC)'            AC_SUBST(CC_FOR_BUILD)
1460 BUILD_CFLAGS='$(ALL_CFLAGS)'    AC_SUBST(BUILD_CFLAGS)
1461
1462 STMP_FIXINC=stmp-fixinc         AC_SUBST(STMP_FIXINC)
1463 STMP_FIXPROTO=stmp-fixproto     AC_SUBST(STMP_FIXPROTO)
1464
1465 # And these apply if build != host, or we are generating coverage data
1466 if test x$build != x$host || test "x$coverage_flags" != x
1467 then
1468     BUILD_PREFIX=build-
1469     BUILD_PREFIX_1=build-
1470     BUILD_CFLAGS='$(INTERNAL_CFLAGS) $(T_CFLAGS) $(CFLAGS_FOR_BUILD)'
1471
1472     if test "x$TARGET_SYSTEM_ROOT" = x; then
1473         STMP_FIXINC=
1474         STMP_FIXPROTO=
1475     fi
1476 fi
1477
1478 # Expand extra_headers to include complete path.
1479 # This substitutes for lots of t-* files.
1480 extra_headers_list=
1481 if test "x$extra_headers" = x
1482 then true
1483 else
1484         # Prepend ${srcdir}/config/${cpu_type}/ to every entry in extra_headers.
1485         for file in $extra_headers;
1486         do
1487                 extra_headers_list="${extra_headers_list} \$(srcdir)/config/${cpu_type}/${file}"
1488         done
1489 fi
1490
1491 # Add a definition of USE_COLLECT2 if system wants one.
1492 case $use_collect2 in
1493   no) use_collect2= ;;
1494   "") ;;
1495   *) 
1496     host_xm_defines="${host_xm_defines} USE_COLLECT2"
1497     xm_defines="${xm_defines} USE_COLLECT2"
1498     ;;
1499 esac
1500
1501 # Identify the assembler which will work hand-in-glove with the newly
1502 # built GCC, so that we can examine its features.  This is the assembler
1503 # which will be driven by the driver program.
1504 #
1505 # If build != host, and we aren't building gas in-tree, we identify a
1506 # build->target assembler and hope that it will have the same features
1507 # as the host->target assembler we'll be using.
1508 AC_MSG_CHECKING(what assembler to use)
1509 in_tree_gas=no
1510 gcc_cv_as=
1511 gcc_cv_gas_major_version=
1512 gcc_cv_gas_minor_version=
1513 gcc_cv_as_gas_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/gas
1514 if test -x "$DEFAULT_ASSEMBLER"; then
1515         gcc_cv_as="$DEFAULT_ASSEMBLER"
1516 elif test -x "$AS"; then
1517         gcc_cv_as="$AS"
1518 elif test -x as$host_exeext; then
1519         # Build using assembler in the current directory.
1520         gcc_cv_as=./as$host_exeext
1521 elif test -f $gcc_cv_as_gas_srcdir/configure.in \
1522      && test -f ../gas/Makefile; then
1523   # Single tree build which includes gas.
1524   in_tree_gas=yes
1525   _gcc_COMPUTE_GAS_VERSION
1526   rm -f as$host_exeext
1527   $symbolic_link ../gas/as-new$host_exeext as$host_exeext 2>/dev/null
1528   in_tree_gas_is_elf=no
1529   if grep 'obj_format = elf' ../gas/Makefile > /dev/null \
1530      || (grep 'obj_format = multi' ../gas/Makefile \
1531          && grep 'extra_objects =.* obj-elf' ../gas/Makefile) > /dev/null
1532   then
1533     in_tree_gas_is_elf=yes
1534   fi
1535 fi
1536
1537 if test "x$gcc_cv_as" = x; then
1538         # Search the same directories that the installed compiler will
1539         # search.  Else we may find the wrong assembler and lose.  If we
1540         # do not find a suitable assembler binary, then try the user's
1541         # path.
1542         #
1543         # Also note we have to check MD_EXEC_PREFIX before checking the
1544         # user's path.  Unfortunately, there is no good way to get at the
1545         # value of MD_EXEC_PREFIX here.  So we do a brute force search
1546         # through all the known MD_EXEC_PREFIX values.  Ugh.  This needs
1547         # to be fixed as part of the make/configure rewrite too.
1548
1549         if test "x$exec_prefix" = xNONE; then
1550                 if test "x$prefix" = xNONE; then
1551                         test_prefix=/usr/local
1552                 else
1553                         test_prefix=$prefix
1554                 fi
1555         else
1556                 test_prefix=$exec_prefix
1557         fi
1558
1559         # If the loop below does not find an assembler, then use whatever
1560         # one we can find in the users's path.
1561         # user's path.
1562         if test "x$program_prefix" != xNONE; then
1563                 gcc_cv_as=${program_prefix}as$host_exeext
1564         else
1565                 gcc_cv_as=`echo as | sed ${program_transform_name}`$host_exeext
1566         fi
1567
1568         test_dirs="$test_prefix/lib/gcc-lib/$target_alias/$gcc_version \
1569                    $test_prefix/lib/gcc-lib/$target_alias \
1570                    /usr/lib/gcc/$target_alias/$gcc_version \
1571                    /usr/lib/gcc/$target_alias \
1572                    $test_prefix/$target_alias/bin/$target_alias/$gcc_version \
1573                    $test_prefix/$target_alias/bin"
1574
1575         if test x$host = x$target; then
1576             test_dirs="$test_dirs \
1577                    /usr/libexec \
1578                    /usr/ccs/gcc \
1579                    /usr/ccs/bin \
1580                    /udk/usr/ccs/bin \
1581                    /bsd43/usr/lib/cmplrs/cc \
1582                    /usr/cross64/usr/bin \
1583                    /usr/lib/cmplrs/cc \
1584                    /sysv/usr/lib/cmplrs/cc \
1585                    /svr4/usr/lib/cmplrs/cc \
1586                    /usr/bin"
1587         fi
1588
1589         for dir in $test_dirs; do
1590                 if test -x $dir/as$host_exeext; then
1591                         gcc_cv_as=$dir/as$host_exeext
1592                         break;
1593                 fi
1594         done
1595 fi
1596 case $in_tree_gas in
1597   yes)
1598     AC_MSG_RESULT("newly built gas")
1599     ;;
1600   no)
1601     AC_MSG_RESULT($gcc_cv_as)
1602     ;;
1603 esac
1604
1605 # Identify the linker which will work hand-in-glove with the newly
1606 # built GCC, so that we can examine its features.  This is the linker
1607 # which will be driven by the driver program.
1608 #
1609 # If build != host, and we aren't building gas in-tree, we identify a
1610 # build->target linker and hope that it will have the same features
1611 # as the host->target linker we'll be using.
1612 AC_MSG_CHECKING(what linker to use)
1613 in_tree_ld=no
1614 gcc_cv_ld=
1615 gcc_cv_gld_major_version=
1616 gcc_cv_gld_minor_version=
1617 gcc_cv_ld_gld_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/ld
1618 gcc_cv_ld_bfd_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/bfd
1619 if test -x "$DEFAULT_LINKER"; then
1620         gcc_cv_ld="$DEFAULT_LINKER"
1621 elif test -x "$LD"; then
1622         gcc_cv_ld="$LD"
1623 elif test -x collect-ld$host_exeext; then
1624         # Build using linker in the current directory.
1625         gcc_cv_ld=./collect-ld$host_exeext
1626 elif test -f $gcc_cv_ld_gld_srcdir/configure.in \
1627      && test -f ../ld/Makefile; then
1628         # Single tree build which includes ld.
1629         in_tree_ld=yes
1630         in_tree_ld_is_elf=no
1631         if (grep 'EMUL = .*elf' ../ld/Makefile \
1632             || grep 'EMUL = .*linux' ../ld/Makefile) > /dev/null; then
1633           in_tree_ld_is_elf=yes
1634         fi
1635         for f in $gcc_cv_ld_bfd_srcdir/configure $gcc_cv_ld_gld_srcdir/configure $gcc_cv_ld_gld_srcdir/configure.in $gcc_cv_ld_gld_srcdir/Makefile.in
1636         do
1637 changequote(,)dnl
1638                 gcc_cv_gld_version=`grep '^VERSION=[0-9]*\.[0-9]*' $f`
1639 changequote([,])dnl
1640                 if test x$gcc_cv_gld_version != x; then
1641                         break
1642                 fi
1643         done
1644 changequote(,)dnl
1645         gcc_cv_gld_major_version=`expr "$gcc_cv_gld_version" : "VERSION=\([0-9]*\)"`
1646         gcc_cv_gld_minor_version=`expr "$gcc_cv_gld_version" : "VERSION=[0-9]*\.\([0-9]*\)"`
1647 changequote([,])dnl
1648         rm -f collect-ld$host_exeext
1649         $symbolic_link ../ld/ld-new$host_exeext collect-ld$host_exeext \
1650                 2>/dev/null
1651 fi
1652
1653 if test "x$gcc_cv_ld" = x; then
1654         # Search the same directories that the installed compiler will
1655         # search.  Else we may find the wrong linker and lose.  If we
1656         # do not find a suitable linker binary, then try the user's
1657         # path.
1658         #
1659         # Also note we have to check MD_EXEC_PREFIX before checking the
1660         # user's path.  Unfortunately, there is no good way to get at the
1661         # value of MD_EXEC_PREFIX here.  So we do a brute force search
1662         # through all the known MD_EXEC_PREFIX values.  Ugh.  This needs
1663         # to be fixed as part of the make/configure rewrite too.
1664
1665         if test "x$exec_prefix" = xNONE; then
1666                 if test "x$prefix" = xNONE; then
1667                         test_prefix=/usr/local
1668                 else
1669                         test_prefix=$prefix
1670                 fi
1671         else
1672                 test_prefix=$exec_prefix
1673         fi
1674
1675         # If the loop below does not find an linker, then use whatever
1676         # one we can find in the users's path.
1677         # user's path.
1678         if test "x$program_prefix" != xNONE; then
1679                 gcc_cv_ld=${program_prefix}ld$host_exeext
1680         else
1681                 gcc_cv_ld=`echo ld | sed ${program_transform_name}`$host_exeext
1682         fi
1683
1684         test_dirs="$test_prefix/lib/gcc-lib/$target_alias/$gcc_version \
1685                    $test_prefix/lib/gcc-lib/$target_alias \
1686                    /usr/lib/gcc/$target_alias/$gcc_version \
1687                    /usr/lib/gcc/$target_alias \
1688                    $test_prefix/$target_alias/bin/$target_alias/$gcc_version \
1689                    $test_prefix/$target_alias/bin"
1690
1691         if test x$host = x$target; then
1692             test_dirs="$test_dirs \
1693                    /usr/libexec \
1694                    /usr/ccs/gcc \
1695                    /usr/ccs/bin \
1696                    /udk/usr/ccs/bin \
1697                    /bsd43/usr/lib/cmplrs/cc \
1698                    /usr/cross64/usr/bin \
1699                    /usr/lib/cmplrs/cc \
1700                    /sysv/usr/lib/cmplrs/cc \
1701                    /svr4/usr/lib/cmplrs/cc \
1702                    /usr/bin"
1703         fi
1704
1705         for dir in $test_dirs; do
1706                 if test -x $dir/ld$host_exeext; then
1707                         gcc_cv_ld=$dir/ld$host_exeext
1708                         break;
1709                 fi
1710         done
1711 fi
1712 case $in_tree_ld in
1713   yes)
1714     AC_MSG_RESULT("newly built ld")
1715     ;;
1716   no)
1717     AC_MSG_RESULT($gcc_cv_ld)
1718     ;;
1719 esac
1720
1721 # Figure out what nm we will be using.
1722 gcc_cv_binutils_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/binutils
1723 AC_MSG_CHECKING(what nm to use)
1724 in_tree_nm=no
1725 if test -x nm$host_exeext; then
1726         gcc_cv_nm=./nm$host_exeext
1727 elif test -f $gcc_cv_binutils_srcdir/configure.in \
1728      && test -f ../binutils/Makefile; then
1729         # Single tree build which includes binutils.
1730         in_tree_nm=yes
1731         gcc_cv_nm=./nm$host_exeext
1732         rm -f nm$host_exeext
1733         $symbolic_link ../binutils/nm-new$host_exeext nm$host_exeext 2>/dev/null
1734 elif test "x$program_prefix" != xNONE; then
1735         gcc_cv_nm=${program_prefix}nm$host_exeext
1736 else
1737         gcc_cv_nm=`echo nm | sed ${program_transform_name}`$host_exeext
1738 fi
1739 case $in_tree_nm in
1740   yes) AC_MSG_RESULT("newly built nm") ;;
1741   no)  AC_MSG_RESULT($gcc_cv_nm) ;;
1742 esac
1743
1744 # Figure out what objdump we will be using.
1745 AC_MSG_CHECKING(what objdump to use)
1746 in_tree_objdump=no
1747 if test -x objdump$host_exeext; then
1748         gcc_cv_objdump=./objdump$host_exeext
1749 elif test -f $gcc_cv_binutils_srcdir/configure.in \
1750      && test -f ../binutils/Makefile; then
1751         # Single tree build which includes binutils.
1752         in_tree_objdump=yes
1753         gcc_cv_objdump=./objdump$host_exeext
1754         rm -f objdump$host_exeext
1755         $symbolic_link ../binutils/objdump$host_exeext \
1756                 objdump$host_exeext 2>/dev/null
1757 elif test "x$program_prefix" != xNONE; then
1758         gcc_cv_objdump=${program_prefix}objdump$host_exeext
1759 else
1760         gcc_cv_objdump=`echo objdump | \
1761                 sed ${program_transform_name}`$host_exeext
1762 fi
1763 case $in_tree_objdump in
1764   yes) AC_MSG_RESULT("newly built objdump") ;;
1765   no)  AC_MSG_RESULT($gcc_cv_objdump) ;;
1766 esac
1767
1768 # Figure out what assembler alignment features are present.
1769 gcc_GAS_CHECK_FEATURE([.balign and .p2align], gcc_cv_as_balign_and_p2align,
1770  [2,6,0],,
1771 [.balign 4
1772 .p2align 2],,
1773 [AC_DEFINE(HAVE_GAS_BALIGN_AND_P2ALIGN, 1,
1774   [Define if your assembler supports .balign and .p2align.])])
1775
1776 gcc_GAS_CHECK_FEATURE([.p2align with maximum skip], gcc_cv_as_max_skip_p2align,
1777  [2,8,0],,
1778  [.p2align 4,,7],,
1779 [AC_DEFINE(HAVE_GAS_MAX_SKIP_P2ALIGN, 1,
1780   [Define if your assembler supports specifying the maximum number
1781    of bytes to skip when using the GAS .p2align command.])])
1782
1783 gcc_GAS_CHECK_FEATURE([working .subsection -1], gcc_cv_as_subsection_m1,
1784  [elf,2,9,0],,
1785  [conftest_label1: .word 0
1786 .subsection -1
1787 conftest_label2: .word 0
1788 .previous],
1789  [if test x$gcc_cv_nm != x; then
1790     $gcc_cv_nm conftest.o | grep conftest_label1 > conftest.nm1
1791     $gcc_cv_nm conftest.o | grep conftest_label2 | sed -e 's/label2/label1/' > conftest.nm2
1792     if cmp conftest.nm1 conftest.nm2 > /dev/null 2>&1
1793     then :
1794     else gcc_cv_as_subsection_m1=yes
1795     fi
1796     rm -f conftest.nm1 conftest.nm2
1797   fi],
1798  [AC_DEFINE(HAVE_GAS_SUBSECTION_ORDERING, 1,
1799   [Define if your assembler supports .subsection and .subsection -1 starts
1800    emitting at the beginning of your section.])])
1801
1802 gcc_GAS_CHECK_FEATURE([.weak], gcc_cv_as_weak,
1803  [2,2,0],,
1804  [      .weak foobar],,
1805 [AC_DEFINE(HAVE_GAS_WEAK, 1, [Define if your assembler supports .weak.])])
1806
1807 # .hidden needs to be supported in both the assembler and the linker,
1808 # because GNU LD versions before 2.12.1 have buggy support for STV_HIDDEN.
1809 # This is irritatingly difficult to feature test for; we have to check the
1810 # date string after the version number.  If we've got an in-tree
1811 # ld, we don't know its patchlevel version, so we set the baseline at 2.13
1812 # to be safe.
1813 # The gcc_GAS_CHECK_FEATURE call just sets a cache variable.
1814 gcc_GAS_CHECK_FEATURE([.hidden], gcc_cv_as_hidden,
1815  [elf,2,13,0],,
1816 [       .hidden foobar
1817 foobar:])
1818
1819 AC_CACHE_CHECK(linker for .hidden support, gcc_cv_ld_hidden,
1820 [if test $in_tree_ld = yes ; then
1821   gcc_cv_ld_hidden=no
1822   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 13 -o "$gcc_cv_gld_major_version" -gt 2 \
1823      && test $in_tree_ld_is_elf = yes; then
1824      gcc_cv_ld_hidden=yes
1825   fi
1826 else
1827   gcc_cv_ld_hidden=yes
1828   ld_ver=`$gcc_cv_ld --version 2>/dev/null | head -1`
1829   if echo "$ld_ver" | grep GNU > /dev/null; then
1830 changequote(,)dnl
1831     ld_vers=`echo $ld_ver | sed -n \
1832         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\)$,\1,p' \
1833         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\)$,\1,p' \
1834         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\)$,\1,p' \
1835         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\)[  ].*$,\1,p' \
1836         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\)[     ].*$,\1,p' \
1837         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\)[        ].*$,\1,p'`
1838     ld_date=`echo $ld_ver | sed -n 's,^.*\([2-9][0-9][0-9][0-9]\)[-]*\([01][0-9]\)[-]*\([0-3][0-9]\).*$,\1\2\3,p'`
1839     if test 0"$ld_date" -lt 20020404; then
1840       if test -n "$ld_date"; then
1841         # If there was date string, but was earlier than 2002-04-04, fail
1842         gcc_cv_ld_hidden=no
1843       elif test -z "$ld_vers"; then
1844         # If there was no date string nor ld version number, something is wrong
1845         gcc_cv_ld_hidden=no
1846       else
1847         ld_vers_major=`expr "$ld_vers" : '\([0-9]*\)'`
1848         ld_vers_minor=`expr "$ld_vers" : '[0-9]*\.\([0-9]*\)'`
1849         ld_vers_patch=`expr "$ld_vers" : '[0-9]*\.[0-9]*\.\([0-9]*\)'`
1850         test -z "$ld_vers_patch" && ld_vers_patch=0
1851         if test "$ld_vers_major" -lt 2; then
1852           gcc_cv_ld_hidden=no
1853         elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -lt 12; then
1854           gcc_cv_ld_hidden="no"
1855         elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -eq 12 -a "$ld_vers_patch" -eq 0; then
1856           gcc_cv_ld_hidden=no
1857         fi
1858       fi
1859 changequote([,])dnl
1860     fi
1861   else
1862     case "$target" in
1863       mips-sgi-irix[[56]]*)
1864         if test x"$gnu_ld_flag" = x"no"; then
1865           # Even if using gas with .hidden support, the resulting object files
1866           # cannot be linked with the IRIX 5 and IRIX 6 O32 linkers.  With
1867           # the IRIX 6 N32 and N64 linkers, the problem is that the linker
1868           # refuses to accept -call_shared (passed by default to the
1869           # linker) and -r (used to link the object file generated without
1870           # .hidden directives with one that hides symbols), so we also lose.
1871           gcc_cv_ld_hidden=no
1872         fi
1873      ;;
1874     esac
1875   fi
1876 fi])
1877 libgcc_visibility=no
1878 AC_SUBST(libgcc_visibility)
1879 if test $gcc_cv_as_hidden = yes && test $gcc_cv_ld_hidden = yes; then
1880   libgcc_visibility=yes
1881   AC_DEFINE(HAVE_GAS_HIDDEN, 1,
1882   [Define if your assembler and linker support .hidden.])
1883 fi
1884
1885 # Check if we have .[us]leb128, and support symbol arithmetic with it.
1886 gcc_GAS_CHECK_FEATURE([.sleb128 and .uleb128], gcc_cv_as_leb128,
1887   [elf,2,11,0],,
1888 [       .data
1889         .uleb128 L2 - L1
1890 L1:
1891         .uleb128 1280
1892         .sleb128 -1010
1893 L2:],
1894  [# GAS versions before 2.11 do not support uleb128,
1895   # despite appearing to.
1896   # ??? There exists an elf-specific test that will crash
1897   # the assembler.  Perhaps it's better to figure out whether
1898   # arbitrary sections are supported and try the test.
1899   as_ver=`$gcc_cv_as --version 2>/dev/null | head -1`
1900   if echo "$as_ver" | grep GNU > /dev/null; then
1901 changequote(,)dnl
1902     as_ver=`echo $as_ver | sed -e 's/GNU assembler \([0-9.][0-9.]*\).*/\1/'`
1903     as_major=`echo $as_ver | sed 's/\..*//'`
1904     as_minor=`echo $as_ver | sed 's/[^.]*\.\([0-9]*\).*/\1/'`
1905 changequote([,])dnl
1906     if test $as_major -eq 2 && test $as_minor -lt 11
1907     then :
1908     else gcc_cv_as_leb128=yes
1909     fi
1910   fi],
1911   [AC_DEFINE(HAVE_AS_LEB128, 1,
1912     [Define if your assembler supports .sleb128 and .uleb128.])])
1913
1914 # GAS versions up to and including 2.11.0 may mis-optimize
1915 # .eh_frame data.
1916 gcc_GAS_CHECK_FEATURE(eh_frame optimization, gcc_cv_as_eh_frame,
1917   [elf,2,12,0],,
1918 [       .text
1919 .LFB1:
1920         .4byte  0
1921 .L1:
1922         .4byte  0
1923 .LFE1:
1924         .section        .eh_frame,"aw",@progbits
1925 __FRAME_BEGIN__:
1926         .4byte  .LECIE1-.LSCIE1
1927 .LSCIE1:
1928         .4byte  0x0
1929         .byte   0x1
1930         .ascii "z\0"
1931         .byte   0x1
1932         .byte   0x78
1933         .byte   0x1a
1934         .byte   0x0
1935         .byte   0x4
1936         .4byte  1
1937         .p2align 1
1938 .LECIE1:
1939 .LSFDE1:
1940         .4byte  .LEFDE1-.LASFDE1
1941 .LASFDE1:
1942         .4byte  .LASFDE1-__FRAME_BEGIN__
1943         .4byte  .LFB1
1944         .4byte  .LFE1-.LFB1
1945         .byte   0x4
1946         .4byte  .LFE1-.LFB1
1947         .byte   0x4
1948         .4byte  .L1-.LFB1
1949 .LEFDE1:],
1950 [  cat > conftest.lit <<EOF
1951  0000 10000000 00000000 017a0001 781a0004  .........z..x...
1952  0010 01000000 12000000 18000000 00000000  ................
1953  0020 08000000 04080000 0044               .........D      
1954 EOF
1955   cat > conftest.big <<EOF
1956  0000 00000010 00000000 017a0001 781a0004  .........z..x...
1957  0010 00000001 00000012 00000018 00000000  ................
1958  0020 00000008 04000000 0844               .........D      
1959 EOF
1960   # If the assembler didn't choke, and we can objdump,
1961   # and we got the correct data, then succeed.
1962   if test x$gcc_cv_objdump != x \
1963   && $gcc_cv_objdump -s -j .eh_frame conftest.o 2>/dev/null \
1964      | tail -3 > conftest.got \
1965   && { cmp conftest.lit conftest.got > /dev/null 2>&1 \
1966     || cmp conftest.big conftest.got > /dev/null 2>&1; }
1967   then
1968     gcc_cv_as_eh_frame=yes
1969   elif AC_TRY_COMMAND($gcc_cv_as -o conftest.o --traditional-format /dev/null); then
1970     gcc_cv_as_eh_frame=buggy
1971   else
1972     # Uh oh, what do we do now?
1973     gcc_cv_as_eh_frame=no
1974   fi])
1975
1976 if test $gcc_cv_as_eh_frame = buggy; then
1977   AC_DEFINE(USE_AS_TRADITIONAL_FORMAT, 1,
1978   [Define if your assembler mis-optimizes .eh_frame data.])
1979 fi
1980
1981 gcc_GAS_CHECK_FEATURE(section merging support, gcc_cv_as_shf_merge,
1982  [elf,2,12,0], [--fatal-warnings],
1983  [.section .rodata.str, "aMS", @progbits, 1],,
1984  [AC_DEFINE(HAVE_GAS_SHF_MERGE, 1,
1985 [Define if your assembler supports marking sections with SHF_MERGE flag.])])
1986
1987 # Thread-local storage - the check is heavily parametrized.
1988 conftest_s=
1989 tls_first_major=
1990 tls_first_minor=
1991 tls_as_opt=
1992 case "$target" in
1993 changequote(,)dnl
1994   alpha*-*-*)
1995     conftest_s='
1996         .section ".tdata","awT",@progbits
1997 foo:    .long   25
1998         .text
1999         ldq     $27,__tls_get_addr($29)         !literal!1
2000         lda     $16,foo($29)                    !tlsgd!1
2001         jsr     $26,($27),__tls_get_addr        !lituse_tlsgd!1
2002         ldq     $27,__tls_get_addr($29)         !literal!2
2003         lda     $16,foo($29)                    !tlsldm!2
2004         jsr     $26,($27),__tls_get_addr        !lituse_tlsldm!2
2005         ldq     $1,foo($29)                     !gotdtprel
2006         ldah    $2,foo($29)                     !dtprelhi
2007         lda     $3,foo($2)                      !dtprello
2008         lda     $4,foo($29)                     !dtprel
2009         ldq     $1,foo($29)                     !gottprel
2010         ldah    $2,foo($29)                     !tprelhi
2011         lda     $3,foo($2)                      !tprello
2012         lda     $4,foo($29)                     !tprel'
2013         tls_first_major=2
2014         tls_first_minor=13
2015         ;;
2016   i[34567]86-*-*)
2017 changequote([,])dnl
2018     conftest_s='
2019         .section ".tdata","awT",@progbits
2020 foo:    .long   25
2021         .text
2022         movl    %gs:0, %eax
2023         leal    foo@TLSGD(,%ebx,1), %eax
2024         leal    foo@TLSLDM(%ebx), %eax
2025         leal    foo@DTPOFF(%eax), %edx
2026         movl    foo@GOTTPOFF(%ebx), %eax
2027         subl    foo@GOTTPOFF(%ebx), %eax
2028         addl    foo@GOTNTPOFF(%ebx), %eax
2029         movl    foo@INDNTPOFF, %eax
2030         movl    $foo@TPOFF, %eax
2031         subl    $foo@TPOFF, %eax
2032         leal    foo@NTPOFF(%ecx), %eax'
2033         tls_first_major=2
2034         tls_first_minor=14
2035         ;;
2036   x86_64-*-*)
2037     conftest_s='
2038         .section ".tdata","awT",@progbits
2039 foo:    .long   25
2040         .text
2041         movq    %fs:0, %rax
2042         leaq    foo@TLSGD(%rip), %rdi
2043         leaq    foo@TLSLD(%rip), %rdi
2044         leaq    foo@DTPOFF(%rax), %rdx
2045         movq    foo@GOTTPOFF(%rip), %rax
2046         movq    $foo@TPOFF, %rax'
2047         tls_first_major=2
2048         tls_first_minor=14
2049         ;;
2050   ia64-*-*)
2051     conftest_s='
2052         .section ".tdata","awT",@progbits
2053 foo:    data8   25
2054         .text
2055         addl    r16 = @ltoff(@dtpmod(foo#)), gp
2056         addl    r17 = @ltoff(@dtprel(foo#)), gp
2057         addl    r18 = @ltoff(@tprel(foo#)), gp
2058         addl    r19 = @dtprel(foo#), gp
2059         adds    r21 = @dtprel(foo#), r13
2060         movl    r23 = @dtprel(foo#)
2061         addl    r20 = @tprel(foo#), gp
2062         adds    r22 = @tprel(foo#), r13
2063         movl    r24 = @tprel(foo#)'
2064         tls_first_major=2
2065         tls_first_minor=13
2066         ;;
2067   powerpc-*-*)
2068     conftest_s='
2069         .section ".tdata","awT",@progbits
2070         .align 2
2071 ld0:    .space 4
2072 ld1:    .space 4
2073 x1:     .space 4
2074 x2:     .space 4
2075 x3:     .space 4
2076         .text
2077         addi 3,31,ld0@got@tlsgd
2078         bl __tls_get_addr
2079         addi 3,31,x1@got@tlsld
2080         bl __tls_get_addr
2081         addi 9,3,x1@dtprel
2082         addis 9,3,x2@dtprel@ha
2083         addi 9,9,x2@dtprel@l
2084         lwz 9,x3@got@tprel(31)
2085         add 9,9,x@tls
2086         addi 9,2,x1@tprel
2087         addis 9,2,x2@tprel@ha
2088         addi 9,9,x2@tprel@l'
2089         tls_first_major=2
2090         tls_first_minor=14
2091         tls_as_opt=-a32
2092         ;;
2093   powerpc64-*-*)
2094     conftest_s='
2095         .section ".tdata","awT",@progbits
2096         .align 3
2097 ld0:    .space 8
2098 ld1:    .space 8
2099 x1:     .space 8
2100 x2:     .space 8
2101 x3:     .space 8
2102         .text
2103         addi 3,2,ld0@got@tlsgd
2104         bl .__tls_get_addr
2105         nop
2106         addi 3,2,ld1@toc
2107         bl .__tls_get_addr
2108         nop
2109         addi 3,2,x1@got@tlsld
2110         bl .__tls_get_addr
2111         nop
2112         addi 9,3,x1@dtprel
2113         bl .__tls_get_addr
2114         nop
2115         addis 9,3,x2@dtprel@ha
2116         addi 9,9,x2@dtprel@l
2117         bl .__tls_get_addr
2118         nop
2119         ld 9,x3@got@dtprel(2)
2120         add 9,9,3
2121         bl .__tls_get_addr
2122         nop'
2123         tls_first_major=2
2124         tls_first_minor=14
2125         tls_as_opt=-a64
2126         ;;
2127   s390-*-*)
2128     conftest_s='
2129         .section ".tdata","awT",@progbits
2130 foo:    .long   25
2131         .text
2132         .long   foo@TLSGD
2133         .long   foo@TLSLDM
2134         .long   foo@DTPOFF
2135         .long   foo@NTPOFF
2136         .long   foo@GOTNTPOFF
2137         .long   foo@INDNTPOFF
2138         l       %r1,foo@GOTNTPOFF(%r12)
2139         l       %r1,0(%r1):tls_load:foo
2140         bas     %r14,0(%r1,%r13):tls_gdcall:foo
2141         bas     %r14,0(%r1,%r13):tls_ldcall:foo'
2142         tls_first_major=2
2143         tls_first_minor=14
2144         tls_as_opt=-m31
2145         ;;
2146   s390x-*-*)
2147     conftest_s='
2148         .section ".tdata","awT",@progbits
2149 foo:    .long   25
2150         .text
2151         .quad   foo@TLSGD
2152         .quad   foo@TLSLDM
2153         .quad   foo@DTPOFF
2154         .quad   foo@NTPOFF
2155         .quad   foo@GOTNTPOFF
2156         lg      %r1,foo@GOTNTPOFF(%r12)
2157         larl    %r1,foo@INDNTPOFF
2158         brasl   %r14,__tls_get_offset@PLT:tls_gdcall:foo
2159         brasl   %r14,__tls_get_offset@PLT:tls_ldcall:foo'
2160         tls_first_major=2
2161         tls_first_minor=14
2162         tls_as_opt="-m64 -Aesame"
2163         ;;
2164 esac
2165 if test -z "$tls_first_major"; then
2166   : # If we don't have a check, assume no support.
2167 else
2168   gcc_GAS_CHECK_FEATURE(thread-local storage support, gcc_cv_as_tls,
2169   [$tls_first_major,$tls_first_minor,0], [$tls_as_opt --fatal-warnings],
2170   [$conftest_s],,
2171   [AC_DEFINE(HAVE_AS_TLS, 1,
2172             [Define if your assembler supports thread-local storage.])])
2173 fi
2174
2175 # Target-specific assembler checks.
2176
2177 case "$target" in
2178   # All TARGET_ABI_OSF targets.
2179   alpha*-*-osf* | alpha*-*-linux* | alpha*-*-*bsd*)
2180     gcc_GAS_CHECK_FEATURE([explicit relocation support],
2181         gcc_cv_as_alpha_explicit_relocs, [2,12,0],,
2182 [       .set nomacro
2183         .text
2184         extbl   $3, $2, $3      !lituse_bytoff!1
2185         ldq     $2, a($29)      !literal!1
2186         ldq     $4, b($29)      !literal!2
2187         ldq_u   $3, 0($2)       !lituse_base!1
2188         ldq     $27, f($29)     !literal!5
2189         jsr     $26, ($27), f   !lituse_jsr!5
2190         ldah    $29, 0($26)     !gpdisp!3
2191         lda     $0, c($29)      !gprel
2192         ldah    $1, d($29)      !gprelhigh
2193         lda     $1, d($1)       !gprellow
2194         lda     $29, 0($29)     !gpdisp!3],,
2195     [AC_DEFINE(HAVE_AS_EXPLICIT_RELOCS, 1,
2196   [Define if your assembler supports explicit relocations.])])
2197     ;;
2198
2199   sparc*-*-*)
2200     gcc_GAS_CHECK_FEATURE([.register], gcc_cv_as_sparc_register_op,,,
2201       [.register %g2, #scratch],,
2202       [AC_DEFINE(HAVE_AS_REGISTER_PSEUDO_OP, 1,
2203                 [Define if your assembler supports .register.])])
2204
2205     gcc_GAS_CHECK_FEATURE([-relax option], gcc_cv_as_sparc_relax,,
2206       [-relax], [.text],,
2207       [AC_DEFINE(HAVE_AS_RELAX_OPTION, 1,
2208                 [Define if your assembler supports -relax option.])])
2209
2210     gcc_GAS_CHECK_FEATURE([unaligned pcrel relocs],
2211       gcc_cv_as_sparc_ua_pcrel,,
2212       [-K PIC],
2213 [.text
2214 foo:
2215         nop
2216 .data
2217 .align 4
2218 .byte 0
2219 .uaword %r_disp32(foo)],
2220       [if test x$gcc_cv_ld != x \
2221        && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1; then
2222          gcc_cv_as_sparc_ua_pcrel=yes
2223        fi
2224        rm -f conftest],
2225       [AC_DEFINE(HAVE_AS_SPARC_UA_PCREL, 1,
2226                 [Define if your assembler and linker support unaligned PC relative relocs.])
2227
2228       gcc_GAS_CHECK_FEATURE([unaligned pcrel relocs against hidden symbols],
2229         gcc_cv_as_sparc_ua_pcrel_hidden,,
2230         [-K PIC],
2231 [.data
2232 .align 4
2233 .byte 0x31
2234 .uaword %r_disp32(foo)
2235 .byte 0x32, 0x33, 0x34
2236 .global foo
2237 .hidden foo
2238 foo:
2239 .skip 4],
2240         [if test x$gcc_cv_ld != x && test x$gcc_cv_objdump != x \
2241          && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1 \
2242          && $gcc_cv_objdump -s -j .data conftest 2> /dev/null \
2243             | grep ' 31000000 07323334' > /dev/null 2>&1; then
2244             if $gcc_cv_objdump -R conftest 2> /dev/null \
2245                | grep 'DISP32' > /dev/null 2>&1; then
2246                 :
2247             else
2248                 gcc_cv_as_sparc_ua_pcrel_hidden=yes
2249             fi
2250          fi
2251          rm -f conftest],
2252          [AC_DEFINE(HAVE_AS_SPARC_UA_PCREL_HIDDEN, 1,
2253                    [Define if your assembler and linker support unaligned PC relative relocs against hidden symbols.])])
2254     ]) # unaligned pcrel relocs
2255
2256     gcc_GAS_CHECK_FEATURE([offsetable %lo()],
2257       gcc_cv_as_sparc_offsetable_lo10,,
2258       [-xarch=v9],
2259 [.text
2260         or %g1, %lo(ab) + 12, %g1
2261         or %g1, %lo(ab + 12), %g1],
2262       [if test x$gcc_cv_objdump != x \
2263        && %gcc_cv_objdump -s -j .text conftest.o 2> /dev/null \
2264           | grep ' 82106000 82106000' > /dev/null 2>&1; then
2265          gcc_cv_as_offsetable_lo10=yes
2266        fi],
2267        [AC_DEFINE(HAVE_AS_OFFSETABLE_LO10, 1,
2268                  [Define if your assembler supports offsetable %lo().])])
2269     ;;
2270
2271 changequote(,)dnl
2272   i[34567]86-*-* | x86_64-*-*)
2273 changequote([,])dnl
2274     gcc_GAS_CHECK_FEATURE([filds and fists mnemonics],
2275        gcc_cv_as_ix86_filds_fists,
2276       [2,9,0],, [filds mem; fists mem],,
2277       [AC_DEFINE(HAVE_GAS_FILDS_FISTS, 1,
2278         [Define if your assembler uses the new HImode fild and fist notation.])])
2279
2280     # This one is used unconditionally by i386.[ch]; it is to be defined
2281     # to 1 if the feature is present, 0 otherwise.
2282     gcc_GAS_CHECK_FEATURE([GOTOFF in data],
2283         gcc_cv_as_ix86_gotoff_in_data, [2,11,0],,
2284 [       .text
2285 .L0:
2286         nop
2287         .data
2288         .long .L0@GOTOFF])
2289     AC_DEFINE_UNQUOTED(HAVE_AS_GOTOFF_IN_DATA,
2290       [`if test $gcc_cv_as_ix86_gotoff_in_data = yes; then echo 1; else echo 0; fi`],
2291       [Define true if the assembler supports '.long foo@GOTOFF'.])
2292     ;;
2293
2294   ia64*-*-*)
2295     gcc_GAS_CHECK_FEATURE([ltoffx and ldxmov relocs],
2296         gcc_cv_as_ia64_ltoffx_ldxmov_relocs, [2,14,0],,
2297 [       .text
2298         addl r15 = @ltoffx(x#), gp
2299         ;;
2300         ld8.mov r16 = [[r15]], x#],,
2301     [AC_DEFINE(HAVE_AS_LTOFFX_LDXMOV_RELOCS, 1,
2302           [Define if your assembler supports ltoffx and ldxmov relocations.])])
2303
2304     ;;
2305
2306   powerpc*-*-*)
2307     case $target in
2308       *-*-aix) conftest_s='     .csect .text[PR]';;
2309       *)       conftest_s='     .text';;
2310     esac
2311     conftest_s="$conftest_s
2312         mfcr 3,128"
2313
2314     gcc_GAS_CHECK_FEATURE([mfcr field support],
2315       gcc_cv_as_powerpc_mfcrf, [2,14,0],,
2316       [$conftest_s],,
2317       [AC_DEFINE(HAVE_AS_MFCRF, 1,
2318           [Define if your assembler supports mfcr field.])])
2319     ;;
2320
2321   mips*-*-*)
2322     gcc_GAS_CHECK_FEATURE([explicit relocation support],
2323       gcc_cv_as_mips_explicit_relocs, [2,14,0],,
2324 [       lw $4,%gp_rel(foo)($4)],,
2325       [if test x$target_cpu_default = x
2326        then target_cpu_default=MASK_EXPLICIT_RELOCS
2327        else target_cpu_default="($target_cpu_default)|MASK_EXPLICIT_RELOCS"
2328        fi])
2329
2330     ;;
2331 esac
2332 # ??? Not all targets support dwarf2 debug_line, even within a version
2333 # of gas.  Moreover, we need to emit a valid instruction to trigger any
2334 # info to the output file.  So, as supported targets are added to gas 2.11,
2335 # add some instruction here to (also) show we expect this might work.
2336 # ??? Once 2.11 is released, probably need to add first known working
2337 # version to the per-target configury.
2338 case "$target" in
2339   i?86*-*-* | mips*-*-* | alpha*-*-* | powerpc*-*-* | sparc*-*-* | m68*-*-* \
2340   | x86_64*-*-* | hppa*-*-* | arm*-*-* | strongarm*-*-* | xscale*-*-* \
2341   | xstormy16*-*-* | cris-*-*)
2342     insn="nop"
2343     ;;
2344   ia64*-*-*)
2345     insn="nop 0"
2346     ;;
2347   mmix-*-*)
2348     insn="swym 0"
2349     ;;
2350 esac
2351 if test x"$insn" != x; then
2352  conftest_s="\
2353         .file 1 \"conftest.s\"
2354         .loc 1 3 0
2355         $insn"
2356  gcc_GAS_CHECK_FEATURE([dwarf2 debug_line support],
2357   gcc_cv_as_dwarf2_debug_line,
2358   [elf,2,11,0],, [$conftest_s],
2359   [# ??? This fails with non-gnu grep.  Maybe use objdump?
2360    if grep debug_line conftest.o > /dev/null 2>&1; then
2361      gcc_cv_as_dwarf2_debug_line=yes
2362    fi])
2363
2364 # The .debug_line file table must be in the exact order that
2365 # we specified the files, since these indices are also used
2366 # by DW_AT_decl_file.  Approximate this test by testing if
2367 # the assembler bitches if the same index is assigned twice.
2368  gcc_GAS_CHECK_FEATURE([buggy dwarf2 .file directive],
2369   gcc_cv_as_dwarf2_file_buggy,,,
2370 [       .file 1 "foo.s"
2371         .file 1 "bar.s"])
2372
2373  if test $gcc_cv_as_dwarf2_debug_line = yes \
2374  && test $gcc_cv_as_dwarf2_file_buggy = no; then
2375         AC_DEFINE(HAVE_AS_DWARF2_DEBUG_LINE, 1,
2376   [Define if your assembler supports dwarf2 .file/.loc directives,
2377    and preserves file table indices exactly as given.])
2378  fi
2379
2380  gcc_GAS_CHECK_FEATURE([--gdwarf2 option],
2381   gcc_cv_as_gdwarf2_flag,
2382   [elf,2,11,0], [--gdwarf2], [$insn],,
2383   [AC_DEFINE(HAVE_AS_GDWARF2_DEBUG_FLAG, 1,
2384 [Define if your assembler supports the --gdwarf2 option.])])
2385
2386  gcc_GAS_CHECK_FEATURE([--gstabs option],
2387   gcc_cv_as_gstabs_flag,
2388   [elf,2,11,0], [--gstabs], [$insn],
2389   [# The native Solaris 9/Intel assembler doesn't understand --gstabs
2390    # and warns about it, but still exits successfully.  So check for
2391    # this.
2392    if AC_TRY_COMMAND([$gcc_cv_as --gstabs -o conftest.o conftest.s 2>&1 | grep -i warning > /dev/null])
2393    then :
2394    else gcc_cv_as_gstabs_flag=yes
2395    fi],
2396   [AC_DEFINE(HAVE_AS_GSTABS_DEBUG_FLAG, 1,
2397 [Define if your assembler supports the --gstabs option.])])
2398 fi
2399
2400 AC_MSG_CHECKING(linker read-only and read-write section mixing)
2401 gcc_cv_ld_ro_rw_mix=unknown
2402 if test $in_tree_ld = yes ; then
2403   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 10 -o "$gcc_cv_gld_major_version" -gt 2 \
2404      && test $in_tree_ld_is_elf = yes; then
2405     gcc_cv_ld_ro_rw_mix=read-write
2406   fi
2407 elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x -a x$gcc_cv_objdump != x ; then
2408   echo '.section myfoosect, "a"' > conftest1.s
2409   echo '.section myfoosect, "aw"' > conftest2.s
2410   echo '.byte 1' >> conftest2.s
2411   echo '.section myfoosect, "a"' > conftest3.s
2412   echo '.byte 0' >> conftest3.s
2413   if $gcc_cv_as -o conftest1.o conftest1.s > /dev/null 2>&1 \
2414      && $gcc_cv_as -o conftest2.o conftest2.s > /dev/null 2>&1 \
2415      && $gcc_cv_as -o conftest3.o conftest3.s > /dev/null 2>&1 \
2416      && $gcc_cv_ld -shared -o conftest1.so conftest1.o \
2417         conftest2.o conftest3.o > /dev/null 2>&1; then
2418     gcc_cv_ld_ro_rw_mix=`$gcc_cv_objdump -h conftest1.so \
2419                          | sed -e '/myfoosect/!d' -e N`
2420     if echo "$gcc_cv_ld_ro_rw_mix" | grep CONTENTS > /dev/null; then
2421       if echo "$gcc_cv_ld_ro_rw_mix" | grep READONLY > /dev/null; then
2422         gcc_cv_ld_ro_rw_mix=read-only
2423       else
2424         gcc_cv_ld_ro_rw_mix=read-write
2425       fi
2426     fi
2427   fi
2428 changequote(,)dnl
2429   rm -f conftest.* conftest[123].*
2430 changequote([,])dnl
2431 fi
2432 if test x$gcc_cv_ld_ro_rw_mix = xread-write; then
2433         AC_DEFINE(HAVE_LD_RO_RW_SECTION_MIXING, 1,
2434   [Define if your linker links a mix of read-only
2435    and read-write sections into a read-write section.])
2436 fi
2437 AC_MSG_RESULT($gcc_cv_ld_ro_rw_mix)
2438
2439 AC_MSG_CHECKING(linker PT_GNU_EH_FRAME support)
2440 gcc_cv_ld_eh_frame_hdr=no
2441 if test $in_tree_ld = yes ; then
2442   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 12 -o "$gcc_cv_gld_major_version" -gt 2 \
2443      && test $in_tree_ld_is_elf = yes; then
2444     gcc_cv_ld_eh_frame_hdr=yes
2445   fi
2446 elif test x$gcc_cv_ld != x; then
2447         # Check if linker supports --eh-frame-hdr option
2448         if $gcc_cv_ld --help 2>/dev/null | grep eh-frame-hdr > /dev/null; then
2449                 gcc_cv_ld_eh_frame_hdr=yes
2450         fi
2451 fi
2452 if test x"$gcc_cv_ld_eh_frame_hdr" = xyes; then
2453         AC_DEFINE(HAVE_LD_EH_FRAME_HDR, 1,
2454 [Define if your linker supports --eh-frame-hdr option.])
2455 fi
2456 AC_MSG_RESULT($gcc_cv_ld_eh_frame_hdr)
2457
2458 AC_MSG_CHECKING(linker position independent executable support)
2459 gcc_cv_ld_pie=no
2460 if test $in_tree_ld = yes ; then
2461   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 15 -o "$gcc_cv_gld_major_version" -gt 2 \
2462      && test $in_tree_ld_is_elf = yes; then
2463     gcc_cv_ld_pie=yes
2464   fi
2465 elif test x$gcc_cv_ld != x; then
2466         # Check if linker supports -pie option
2467         if $gcc_cv_ld --help 2>/dev/null | grep -- -pie > /dev/null; then
2468                 gcc_cv_ld_pie=yes
2469         fi
2470 fi
2471 if test x"$gcc_cv_ld_pie" = xyes; then
2472         AC_DEFINE(HAVE_LD_PIE, 1,
2473 [Define if your linker supports -pie option.])
2474 fi
2475 AC_MSG_RESULT($gcc_cv_ld_pie)
2476
2477 # Miscellaneous target-specific checks.
2478 case "$target" in
2479   mips*-*-*)
2480     AC_MSG_CHECKING(whether libgloss uses STARTUP directives consistently)
2481     gcc_cv_mips_libgloss_startup=no
2482     gcc_cv_libgloss_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/libgloss
2483     if test "x$exec_prefix" = xNONE; then
2484       if test "x$prefix" = xNONE; then
2485         test_prefix=/usr/local
2486       else
2487         test_prefix=$prefix
2488       fi
2489     else
2490       test_prefix=$exec_prefix
2491     fi
2492     for f in $gcc_cv_libgloss_srcdir/mips/idt.ld $test_prefix/$target_alias/lib/idt.ld
2493     do
2494       if grep '^STARTUP' $f > /dev/null 2>&1; then
2495         gcc_cv_mips_libgloss_startup=yes
2496         break
2497       fi
2498     done
2499     if test x"$gcc_cv_mips_libgloss_startup" = xyes; then
2500       AC_DEFINE(HAVE_MIPS_LIBGLOSS_STARTUP_DIRECTIVES, 1,
2501         [Define if your MIPS libgloss linker scripts consistently include STARTUP directives.])
2502     fi
2503     AC_MSG_RESULT($gcc_cv_mips_libgloss_startup)
2504     ;;
2505 esac
2506
2507 if test x$with_sysroot = x && test x$host = x$target \
2508    && test "$prefix" != "/usr" && test "x$prefix" != "x$local_prefix" ; then
2509   AC_DEFINE_UNQUOTED(PREFIX_INCLUDE_DIR, "$prefix/include",
2510 [Define to PREFIX/include if cpp should also search that directory.])
2511 fi
2512
2513 # Figure out what language subdirectories are present.
2514 # Look if the user specified --enable-languages="..."; if not, use
2515 # the environment variable $LANGUAGES if defined. $LANGUAGES might
2516 # go away some day.
2517 # NB:  embedded tabs in this IF block -- do not untabify
2518 if test x"${enable_languages+set}" != xset; then
2519         if test x"${LANGUAGES+set}" = xset; then
2520                 enable_languages="${LANGUAGES}"
2521                 AC_MSG_WARN([setting LANGUAGES is deprecated, use --enable-languages instead])
2522
2523         else
2524                 enable_languages=all
2525         fi
2526 else
2527         if test x"${enable_languages}" = x \
2528         || test x"${enable_languages}" = xyes;
2529         then
2530                 AC_MSG_ERROR([--enable-languages needs at least one language argument])
2531         fi
2532 fi
2533 enable_languages=`echo "${enable_languages}" | sed -e 's/[[     ,]][[   ,]]*/,/g' -e 's/,$//'`
2534
2535 # First scan to see if an enabled language requires some other language.
2536 # We assume that a given config-lang.in will list all the language
2537 # front ends it requires, even if some are required indirectly.
2538 for lang in ${srcdir}/*/config-lang.in ..
2539 do
2540    case $lang in
2541     ..)
2542        ;;
2543     # The odd quoting in the next line works around
2544     # an apparent bug in bash 1.12 on linux.
2545 changequote(,)dnl
2546     ${srcdir}/[*]/config-lang.in)
2547        ;;
2548     *)
2549        lang_alias=`sed -n -e 's,^language=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^language=\([^      ]*\).*$,\1,p' $lang`
2550        this_lang_requires=`sed -n -e 's,^lang_requires=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^lang_requires=\([^    ]*\).*$,\1,p' $lang`
2551        for other in $this_lang_requires
2552        do
2553           case ,${enable_languages}, in
2554            *,$other,*)
2555               ;;
2556            *,all,*)
2557               ;;
2558            *,$lang_alias,*)
2559               enable_languages="$enable_languages,$other"
2560               ;;
2561           esac
2562        done
2563        ;;
2564 changequote([,])dnl
2565    esac
2566 done
2567
2568 expected_languages=`echo ,${enable_languages}, | sed -e 's:,: :g' -e 's:  *: :g' -e 's:  *: :g' -e 's:^ ::' -e 's: $::'`
2569 found_languages=
2570 subdirs=
2571 for lang in ${srcdir}/*/config-lang.in ..
2572 do
2573         case $lang in
2574         ..) ;;
2575         # The odd quoting in the next line works around
2576         # an apparent bug in bash 1.12 on linux.
2577 changequote(,)dnl
2578         ${srcdir}/[*]/config-lang.in) ;;
2579         *)
2580           lang_alias=`sed -n -e 's,^language=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^language=\([^   ]*\).*$,\1,p' $lang`
2581           this_lang_libs=`sed -n -e 's,^target_libs=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^target_libs=\([^         ]*\).*$,\1,p' $lang`
2582           build_by_default=`sed -n -e 's,^build_by_default=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^build_by_default=\([^     ]*\).*$,\1,p' $lang`
2583           if test "x$lang_alias" = x
2584           then
2585                 echo "$lang doesn't set \$language." 1>&2
2586                 exit 1
2587           fi
2588           case ${build_by_default},${enable_languages}, in
2589           *,$lang_alias,*) add_this_lang=yes ;;
2590           no,*) add_this_lang=no ;;
2591           *,all,*) add_this_lang=yes ;;
2592           *) add_this_lang=no ;;
2593           esac
2594           found_languages="${found_languages} ${lang_alias}"
2595           if test x"${add_this_lang}" = xyes; then
2596                 case $lang in
2597                     ${srcdir}/ada/config-lang.in)
2598                         if test x$have_gnat = xyes ; then
2599                                 subdirs="$subdirs `echo $lang | sed -e 's,^.*/\([^/]*\)/config-lang.in$,\1,'`"
2600                         fi
2601                         ;;
2602                     *)
2603                         subdirs="$subdirs `echo $lang | sed -e 's,^.*/\([^/]*\)/config-lang.in$,\1,'`"
2604                         ;;
2605                 esac
2606           fi
2607           ;;
2608 changequote([,])dnl
2609         esac
2610 done
2611
2612 missing_languages=
2613 for expected_language in ${expected_languages} ..
2614 do 
2615     if test "${expected_language}" != ..; then
2616         missing_language="${expected_language}"
2617         if test "${expected_language}" = "c" \
2618            || test "${expected_language}" = "all"; then
2619                 missing_language=
2620         fi
2621         for found_language in ${found_languages} ..
2622         do 
2623             if test "${found_language}" != ..; then
2624                 if test "${expected_language}" = "${found_language}"; then
2625                     missing_language=
2626                 fi
2627             fi
2628         done
2629         if test "x${missing_language}" != x; then
2630            missing_languages="${missing_languages} ${missing_language}"
2631         fi
2632     fi
2633 done
2634
2635 if test "x$missing_languages" != x; then
2636   AC_MSG_ERROR([
2637 The following requested languages were not found:${missing_languages}
2638 The following languages were available: c${found_languages}])
2639 fi
2640
2641 # Make gthr-default.h if we have a thread file.
2642 gthread_flags=
2643 if test $thread_file != single; then
2644     rm -f gthr-default.h
2645     echo "#include \"gthr-${thread_file}.h\"" > gthr-default.h
2646     gthread_flags=-DHAVE_GTHR_DEFAULT
2647 fi
2648 AC_SUBST(gthread_flags)
2649
2650 # Find out what GC implementation we want, or may, use.
2651 AC_ARG_WITH(gc,
2652 [  --with-gc={simple,page} choose the garbage collection mechanism to use
2653                           with the compiler],
2654 [case "$withval" in
2655   simple | page)
2656     GGC=ggc-$withval
2657     ;;
2658   *)
2659     AC_MSG_ERROR([$withval is an invalid option to --with-gc])
2660     ;;
2661 esac],
2662 [GGC=ggc-page])
2663 AC_SUBST(GGC)
2664 echo "Using $GGC for garbage collection."
2665
2666 # Use the system's zlib library.
2667 zlibdir=-L../zlib
2668 zlibinc="-I\$(srcdir)/../zlib"
2669 AC_ARG_WITH(system-zlib,
2670 [  --with-system-zlib      use installed libz],
2671 zlibdir=
2672 zlibinc=
2673 )
2674 AC_SUBST(zlibdir)
2675 AC_SUBST(zlibinc)
2676
2677 dnl Very limited version of automake's enable-maintainer-mode
2678
2679 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
2680   dnl maintainer-mode is disabled by default
2681   AC_ARG_ENABLE(maintainer-mode,
2682 [  --enable-maintainer-mode
2683                           enable make rules and dependencies not useful
2684                           (and sometimes confusing) to the casual installer],
2685       maintainer_mode=$enableval,
2686       maintainer_mode=no)
2687
2688 AC_MSG_RESULT($maintainer_mode)
2689
2690 if test "$maintainer_mode" = "yes"; then
2691   MAINT=''
2692 else
2693   MAINT='#'
2694 fi
2695 AC_SUBST(MAINT)dnl
2696
2697 # Make empty files to contain the specs and options for each language.
2698 # Then add #include lines to for a compiler that has specs and/or options.
2699
2700 lang_opt_files=
2701 lang_specs_files=
2702 lang_tree_files=
2703 for subdir in . $subdirs
2704 do
2705         if test -f $srcdir/$subdir/lang.opt; then
2706             lang_opt_files="$lang_opt_files $srcdir/$subdir/lang.opt"
2707         fi
2708         if test -f $srcdir/$subdir/lang-specs.h; then
2709             lang_specs_files="$lang_specs_files $srcdir/$subdir/lang-specs.h"
2710         fi
2711         if test -f $srcdir/$subdir/$subdir-tree.def; then
2712             lang_tree_files="$lang_tree_files $srcdir/$subdir/$subdir-tree.def"
2713         fi
2714 done
2715
2716 # These (without "all_") are set in each config-lang.in.
2717 # `language' must be a single word so is spelled singularly.
2718 all_languages=
2719 all_boot_languages=
2720 all_compilers=
2721 all_stagestuff=
2722 all_outputs='Makefile fixinc/Makefile gccbug mklibgcc mkheaders'
2723 # List of language makefile fragments.
2724 all_lang_makefrags=
2725 # List of language subdirectory makefiles.  Deprecated.
2726 all_lang_makefiles=
2727 # Files for gengtype
2728 all_gtfiles="$target_gtfiles"
2729 # Files for gengtype with language
2730 all_gtfiles_files_langs=
2731 all_gtfiles_files_files=
2732
2733 # Add the language fragments.
2734 # Languages are added via two mechanisms.  Some information must be
2735 # recorded in makefile variables, these are defined in config-lang.in.
2736 # We accumulate them and plug them into the main Makefile.
2737 # The other mechanism is a set of hooks for each of the main targets
2738 # like `clean', `install', etc.
2739
2740 language_hooks="Make-hooks"
2741
2742 for s in .. $subdirs
2743 do
2744         if test $s != ".."
2745         then
2746                 language=
2747                 boot_language=
2748                 compilers=
2749                 stagestuff=
2750                 outputs=
2751                 gtfiles=
2752                 . ${srcdir}/$s/config-lang.in
2753                 if test "x$language" = x
2754                 then
2755                         echo "${srcdir}/$s/config-lang.in doesn't set \$language." 1>&2
2756                         exit 1
2757                 fi
2758                 all_lang_makefrags="$all_lang_makefrags \$(srcdir)/$s/Make-lang.in"
2759                 if test -f ${srcdir}/$s/Makefile.in
2760                 then all_lang_makefiles="$s/Makefile"
2761                 fi
2762                 all_languages="$all_languages $language"
2763                 if test "x$boot_language" = xyes
2764                 then
2765                         all_boot_languages="$all_boot_languages $language"
2766                 fi
2767                 all_compilers="$all_compilers $compilers"
2768                 all_stagestuff="$all_stagestuff $stagestuff"
2769                 all_outputs="$all_outputs $outputs"
2770                 all_gtfiles="$all_gtfiles $gtfiles"
2771                 for f in .. $gtfiles
2772                 do
2773                      if test $f != ".."
2774                      then
2775                          all_gtfiles_files_langs="$all_gtfiles_files_langs ${s} "
2776                          all_gtfiles_files_files="$all_gtfiles_files_files ${f} "
2777                      fi
2778                 done
2779         fi
2780 done
2781
2782 # Pick up gtfiles for c
2783 gtfiles=
2784 s="c"
2785 . ${srcdir}/c-config-lang.in
2786 all_gtfiles="$all_gtfiles $gtfiles"
2787 for f in .. $gtfiles
2788 do
2789      if test $f != ".."
2790      then
2791         all_gtfiles_files_langs="$all_gtfiles_files_langs ${s} "
2792         all_gtfiles_files_files="$all_gtfiles_files_files ${f} "
2793      fi
2794 done
2795
2796 check_languages=
2797 for language in .. $all_languages
2798 do
2799         if test $language != ".."
2800         then
2801                 check_languages="$check_languages check-$language"
2802         fi
2803 done
2804
2805 # Since we can't use `::' targets, we link each language in
2806 # with a set of hooks, reached indirectly via lang.${target}.
2807
2808 rm -f Make-hooks
2809 touch Make-hooks
2810 target_list="all.build all.cross start.encap rest.encap tags \
2811         info dvi generated-manpages \
2812         install-normal install-common install-info install-man \
2813         uninstall \
2814         mostlyclean clean distclean extraclean maintainer-clean \
2815         stage1 stage2 stage3 stage4 stageprofile stagefeedback"
2816 for t in $target_list
2817 do
2818         x=
2819         for lang in .. $all_languages
2820         do
2821                 if test $lang != ".."; then
2822                         x="$x $lang.$t"
2823                 fi
2824         done
2825         echo "lang.$t: $x" >> Make-hooks
2826 done
2827
2828 # Create .gdbinit.
2829
2830 echo "dir ." > .gdbinit
2831 echo "dir ${srcdir}" >> .gdbinit
2832 if test x$gdb_needs_out_file_path = xyes
2833 then
2834         echo "dir ${srcdir}/config/"`dirname ${out_file}` >> .gdbinit
2835 fi
2836 if test "x$subdirs" != x; then
2837         for s in $subdirs
2838         do
2839                 echo "dir ${srcdir}/$s" >> .gdbinit
2840         done
2841 fi
2842 echo "source ${srcdir}/gdbinit.in" >> .gdbinit
2843
2844 # If $(exec_prefix) exists and is not the same as $(prefix), then compute an
2845 # absolute path for gcc_tooldir based on inserting the number of up-directory
2846 # movements required to get from $(exec_prefix) to $(prefix) into the basic
2847 # $(libsubdir)/@(unlibsubdir) based path.
2848 # Don't set gcc_tooldir to tooldir since that's only passed in by the toplevel
2849 # make and thus we'd get different behavior depending on where we built the
2850 # sources.
2851 if test x$exec_prefix = xNONE -o x$exec_prefix = x$prefix; then
2852     gcc_tooldir='$(libsubdir)/$(unlibsubdir)/../$(target_alias)'
2853 else
2854 changequote(<<, >>)dnl
2855 # An explanation of the sed strings:
2856 #  -e 's|^\$(prefix)||'   matches and eliminates 'prefix' from 'exec_prefix'
2857 #  -e 's|/$||'            match a trailing forward slash and eliminates it
2858 #  -e 's|^[^/]|/|'        forces the string to start with a forward slash (*)
2859 #  -e 's|/[^/]*|../|g'    replaces each occurrence of /<directory> with ../
2860 #
2861 # (*) Note this pattern overwrites the first character of the string
2862 # with a forward slash if one is not already present.  This is not a
2863 # problem because the exact names of the sub-directories concerned is
2864 # unimportant, just the number of them matters.
2865 #
2866 # The practical upshot of these patterns is like this:
2867 #
2868 #  prefix     exec_prefix        result
2869 #  ------     -----------        ------
2870 #   /foo        /foo/bar          ../
2871 #   /foo/       /foo/bar          ../
2872 #   /foo        /foo/bar/         ../
2873 #   /foo/       /foo/bar/         ../
2874 #   /foo        /foo/bar/ugg      ../../
2875 #
2876     dollar='$$'
2877     gcc_tooldir="\$(libsubdir)/\$(unlibsubdir)/\`echo \$(exec_prefix) | sed -e 's|^\$(prefix)||' -e 's|/\$(dollar)||' -e 's|^[^/]|/|' -e 's|/[^/]*|../|g'\`\$(target_alias)"
2878 changequote([, ])dnl
2879 fi
2880 AC_SUBST(gcc_tooldir)
2881 AC_SUBST(dollar)
2882
2883 # Find a directory in which to install a shared libgcc.
2884
2885 AC_ARG_ENABLE(version-specific-runtime-libs,
2886 [  --enable-version-specific-runtime-libs
2887                           specify that runtime libraries should be
2888                           installed in a compiler-specific directory])
2889
2890 AC_ARG_WITH(slibdir,
2891 [  --with-slibdir=DIR      shared libraries in DIR [LIBDIR]],
2892 slibdir="$with_slibdir",
2893 if test "${enable_version_specific_runtime_libs+set}" = set; then
2894   slibdir='$(libsubdir)'
2895 elif test "$host" != "$target"; then
2896   slibdir='$(build_tooldir)/lib'
2897 else
2898   slibdir='$(libdir)'
2899 fi)
2900 AC_SUBST(slibdir)
2901
2902 objdir=`${PWDCMD-pwd}`
2903 AC_SUBST(objdir)
2904
2905 # Substitute configuration variables
2906 AC_SUBST(subdirs)
2907 AC_SUBST(srcdir)
2908 AC_SUBST(all_boot_languages)
2909 AC_SUBST(all_compilers)
2910 AC_SUBST(all_gtfiles)
2911 AC_SUBST(all_gtfiles_files_langs)
2912 AC_SUBST(all_gtfiles_files_files)
2913 AC_SUBST(all_lang_makefrags)
2914 AC_SUBST(all_lang_makefiles)
2915 AC_SUBST(all_languages)
2916 AC_SUBST(all_stagestuff)
2917 AC_SUBST(build_exeext)
2918 AC_SUBST(build_install_headers_dir)
2919 AC_SUBST(build_xm_file_list)
2920 AC_SUBST(build_xm_include_list)
2921 AC_SUBST(build_xm_defines)
2922 AC_SUBST(check_languages)
2923 AC_SUBST(cc_set_by_configure)
2924 AC_SUBST(quoted_cc_set_by_configure)
2925 AC_SUBST(cpp_install_dir)
2926 AC_SUBST(xmake_file)
2927 AC_SUBST(tmake_file)
2928 AC_SUBST(extra_headers_list)
2929 AC_SUBST(extra_objs)
2930 AC_SUBST(extra_parts)
2931 AC_SUBST(extra_passes)
2932 AC_SUBST(extra_programs)
2933 AC_SUBST(float_h_file)
2934 AC_SUBST(gcc_config_arguments)
2935 AC_SUBST(gcc_gxx_include_dir)
2936 AC_SUBST(libstdcxx_incdir)
2937 AC_SUBST(gcc_version)
2938 AC_SUBST(gcc_version_full)
2939 AC_SUBST(gcc_version_trigger)
2940 AC_SUBST(host_exeext)
2941 AC_SUBST(host_extra_gcc_objs)
2942 AC_SUBST(host_xm_file_list)
2943 AC_SUBST(host_xm_include_list)
2944 AC_SUBST(host_xm_defines)
2945 AC_SUBST(out_host_hook_obj)
2946 AC_SUBST(install)
2947 AC_SUBST(lang_opt_files)
2948 AC_SUBST(lang_specs_files)
2949 AC_SUBST(lang_tree_files)
2950 AC_SUBST(local_prefix)
2951 AC_SUBST(md_file)
2952 AC_SUBST(objc_boehm_gc)
2953 AC_SUBST(out_file)
2954 AC_SUBST(out_object_file)
2955 AC_SUBST(stage_prefix_set_by_configure)
2956 AC_SUBST(quoted_stage_prefix_set_by_configure)
2957 AC_SUBST(symbolic_link)
2958 AC_SUBST(thread_file)
2959 AC_SUBST(tm_file_list)
2960 AC_SUBST(tm_include_list)
2961 AC_SUBST(tm_defines)
2962 AC_SUBST(tm_p_file_list)
2963 AC_SUBST(tm_p_include_list)
2964 AC_SUBST(xm_file_list)
2965 AC_SUBST(xm_include_list)
2966 AC_SUBST(xm_defines)
2967 AC_SUBST(target_alias)
2968 AC_SUBST(c_target_objs)
2969 AC_SUBST(cxx_target_objs)
2970 AC_SUBST(target_cpu_default)
2971
2972 AC_SUBST_FILE(language_hooks)
2973
2974 # Echo that links are built
2975 if test x$host = x$target
2976 then
2977         str1="native "
2978 else
2979         str1="cross-"
2980         str2=" from $host"
2981 fi
2982
2983 if test x$host != x$build
2984 then
2985         str3=" on a $build system"
2986 fi
2987
2988 if test "x$str2" != x || test "x$str3" != x
2989 then
2990         str4=
2991 fi
2992
2993 echo "Links are now set up to build a ${str1}compiler for ${target}$str4" 1>&2
2994
2995 if test "x$str2" != x || test "x$str3" != x
2996 then
2997         echo " ${str2}${str3}." 1>&2
2998 fi
2999
3000 # Configure the subdirectories
3001 # AC_CONFIG_SUBDIRS($subdirs)
3002
3003 # Create the Makefile
3004 # and configure language subdirectories
3005 AC_OUTPUT($all_outputs,
3006 [
3007 case x$CONFIG_HEADERS in
3008 xauto-host.h:config.in)
3009 echo > cstamp-h ;;
3010 esac
3011 # Make sure all the subdirs exist.
3012 for d in .. $subdirs
3013 do
3014   if test $d != ..; then
3015     test -d $d || mkdir $d
3016   fi
3017 done
3018 # If the host supports symlinks, point stage[1234] at ../stage[1234] so
3019 # bootstrapping and the installation procedure can still use
3020 # CC="stage1/xgcc -Bstage1/".  If the host doesn't support symlinks,
3021 # FLAGS_TO_PASS has been modified to solve the problem there.
3022 # This is virtually a duplicate of what happens in configure.lang; we do
3023 # an extra check to make sure this only happens if ln -s can be used.
3024 if test "$symbolic_link" = "ln -s"; then
3025  for d in .. ${subdirs} fixinc ; do
3026    if test $d != ..; then
3027         STARTDIR=`${PWDCMD-pwd}`
3028         cd $d
3029         for t in stage1 stage2 stage3 stage4 stageprofile stagefeedback include
3030         do
3031                 rm -f $t
3032                 $symbolic_link ../$t $t 2>/dev/null
3033         done
3034         cd $STARTDIR
3035    fi
3036  done
3037 else true ; fi
3038 ], 
3039 [subdirs='$subdirs'
3040 symbolic_link='$symbolic_link'
3041 ])