gcc/configure.ac

   1 # configure.ac for GCC
   2 # Process this file with autoconf to generate a configuration script.
   3
   4 # Copyright 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2004, 2005, 2006,
   5 # 2007, 2008 Free Software Foundation, Inc.
   6
   7 #This file is part of GCC.
   8
   9 #GCC is free software; you can redistribute it and/or modify it under
  10 #the terms of the GNU General Public License as published by the Free
  11 #Software Foundation; either version 3, or (at your option) any later
  12 #version.
  13
  14 #GCC is distributed in the hope that it will be useful, but WITHOUT
  15 #ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  16 #FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  17 #for more details.
  18
  19 #You should have received a copy of the GNU General Public License
  20 #along with GCC; see the file COPYING3.  If not see
  21 #<http://www.gnu.org/licenses/>.
  22
  23 # --------------------------------
  24 # Initialization and sanity checks
  25 # --------------------------------
  26
  27 AC_PREREQ(2.59)
  28 AC_INIT
  29 AC_CONFIG_SRCDIR(tree.c)
  30 AC_CONFIG_HEADER(auto-host.h:config.in)
  31
  32 gcc_version=`cat $srcdir/BASE-VER`
  33
  34 # Determine the host, build, and target systems
  35 AC_CANONICAL_BUILD
  36 AC_CANONICAL_HOST
  37 AC_CANONICAL_TARGET
  38
  39 # Determine the noncanonical target name, for directory use.
  40 ACX_NONCANONICAL_TARGET
  41
  42 # Determine the target- and build-specific subdirectories
  43 GCC_TOPLEV_SUBDIRS
  44
  45 # Set program_transform_name
  46 AC_ARG_PROGRAM
  47
  48 # Check for bogus environment variables.
  49 # Test if LIBRARY_PATH contains the notation for the current directory
  50 # since this would lead to problems installing/building glibc.
  51 # LIBRARY_PATH contains the current directory if one of the following
  52 # is true:
  53 # - one of the terminals (":" and ";") is the first or last sign
  54 # - two terminals occur directly after each other
  55 # - the path contains an element with a dot in it
  56 AC_MSG_CHECKING(LIBRARY_PATH variable)
  57 changequote(,)dnl
  58 case ${LIBRARY_PATH} in
  59   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
  60     library_path_setting="contains current directory"
  61     ;;
  62   *)
  63     library_path_setting="ok"
  64     ;;
  65 esac
  66 changequote([,])dnl
  67 AC_MSG_RESULT($library_path_setting)
  68 if test "$library_path_setting" != "ok"; then
  69 AC_MSG_ERROR([
  70 *** LIBRARY_PATH shouldn't contain the current directory when
  71 *** building gcc. Please change the environment variable
  72 *** and run configure again.])
  73 fi
  74
  75 # Test if GCC_EXEC_PREFIX contains the notation for the current directory
  76 # since this would lead to problems installing/building glibc.
  77 # GCC_EXEC_PREFIX contains the current directory if one of the following
  78 # is true:
  79 # - one of the terminals (":" and ";") is the first or last sign
  80 # - two terminals occur directly after each other
  81 # - the path contains an element with a dot in it
  82 AC_MSG_CHECKING(GCC_EXEC_PREFIX variable)
  83 changequote(,)dnl
  84 case ${GCC_EXEC_PREFIX} in
  85   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
  86     gcc_exec_prefix_setting="contains current directory"
  87     ;;
  88   *)
  89     gcc_exec_prefix_setting="ok"
  90     ;;
  91 esac
  92 changequote([,])dnl
  93 AC_MSG_RESULT($gcc_exec_prefix_setting)
  94 if test "$gcc_exec_prefix_setting" != "ok"; then
  95 AC_MSG_ERROR([
  96 *** GCC_EXEC_PREFIX shouldn't contain the current directory when
  97 *** building gcc. Please change the environment variable
  98 *** and run configure again.])
  99 fi
 100
 101 # -----------
 102 # Directories
 103 # -----------
 104
 105 # Specify the local prefix
 106 local_prefix=
 107 AC_ARG_WITH(local-prefix,
 108 [  --with-local-prefix=DIR specifies directory to put local include],
 109 [case "${withval}" in
 110 yes)    AC_MSG_ERROR(bad value ${withval} given for local include directory prefix) ;;
 111 no)     ;;
 112 *)      local_prefix=$with_local_prefix ;;
 113 esac])
 114
 115 # Default local prefix if it is empty
 116 if test x$local_prefix = x; then
 117         local_prefix=/usr/local
 118 fi
 119
 120 # Don't set gcc_gxx_include_dir to gxx_include_dir since that's only
 121 # passed in by the toplevel make and thus we'd get different behavior
 122 # depending on where we built the sources.
 123 gcc_gxx_include_dir=
 124 # Specify the g++ header file directory
 125 AC_ARG_WITH(gxx-include-dir,
 126 [  --with-gxx-include-dir=DIR
 127                           specifies directory to put g++ header files],
 128 [case "${withval}" in
 129 yes)    AC_MSG_ERROR(bad value ${withval} given for g++ include directory) ;;
 130 no)     ;;
 131 *)      gcc_gxx_include_dir=$with_gxx_include_dir ;;
 132 esac])
 133
 134 # This logic must match libstdc++-v3/acinclude.m4:GLIBCXX_EXPORT_INSTALL_INFO.
 135 if test x${gcc_gxx_include_dir} = x; then
 136   if test x${enable_version_specific_runtime_libs} = xyes; then
 137     gcc_gxx_include_dir='${libsubdir}/include/c++'
 138   else
 139     libstdcxx_incdir='include/c++/$(version)'
 140     if test x$host != x$target; then
 141        libstdcxx_incdir="$target_alias/$libstdcxx_incdir"
 142     fi
 143     gcc_gxx_include_dir="\$(libsubdir)/\$(libsubdir_to_prefix)$libstdcxx_incdir"
 144   fi
 145 fi
 146
 147 AC_ARG_WITH(cpp_install_dir,
 148 [  --with-cpp-install-dir=DIR
 149                           install the user visible C preprocessor in DIR
 150                           (relative to PREFIX) as well as PREFIX/bin],
 151 [if test x$withval = xyes; then
 152   AC_MSG_ERROR([option --with-cpp-install-dir requires an argument])
 153 elif test x$withval != xno; then
 154   cpp_install_dir=$withval
 155 fi])
 156
 157 # We would like to our source tree to be readonly.  However when releases or
 158 # pre-releases are generated, the flex/bison generated files as well as the
 159 # various formats of manuals need to be included along with the rest of the
 160 # sources.  Therefore we have --enable-generated-files-in-srcdir to do
 161 # just that.
 162
 163 AC_MSG_CHECKING([whether to place generated files in the source directory])
 164   dnl generated-files-in-srcdir is disabled by default
 165   AC_ARG_ENABLE(generated-files-in-srcdir,
 166 [  --enable-generated-files-in-srcdir
 167                           put copies of generated files in source dir
 168                           intended for creating source tarballs for users
 169                           without texinfo bison or flex.],
 170       generated_files_in_srcdir=$enableval,
 171       generated_files_in_srcdir=no)
 172
 173 AC_MSG_RESULT($generated_files_in_srcdir)
 174
 175 if test "$generated_files_in_srcdir" = "yes"; then
 176   GENINSRC=''
 177 else
 178   GENINSRC='#'
 179 fi
 180 AC_SUBST(GENINSRC)
 181
 182 # -------------------
 183 # Find default linker
 184 # -------------------
 185
 186 # With GNU ld
 187 AC_ARG_WITH(gnu-ld,
 188 [  --with-gnu-ld           arrange to work with GNU ld.],
 189 gnu_ld_flag="$with_gnu_ld",
 190 gnu_ld_flag=no)
 191
 192 # With pre-defined ld
 193 AC_ARG_WITH(ld,
 194 [  --with-ld               arrange to use the specified ld (full pathname)],
 195 DEFAULT_LINKER="$with_ld")
 196 if test x"${DEFAULT_LINKER+set}" = x"set"; then
 197   if test ! -x "$DEFAULT_LINKER"; then
 198     AC_MSG_ERROR([cannot execute: $DEFAULT_LINKER: check --with-ld or env. var. DEFAULT_LINKER])
 199   elif $DEFAULT_LINKER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
 200     gnu_ld_flag=yes
 201   fi
 202   AC_DEFINE_UNQUOTED(DEFAULT_LINKER,"$DEFAULT_LINKER",
 203         [Define to enable the use of a default linker.])
 204 fi
 205
 206 gnu_ld=`if test x"$gnu_ld_flag" = x"yes"; then echo 1; else echo 0; fi`
 207 AC_DEFINE_UNQUOTED(HAVE_GNU_LD, $gnu_ld, [Define if using GNU ld.])
 208
 209 AC_MSG_CHECKING([whether a default linker was specified])
 210 if test x"${DEFAULT_LINKER+set}" = x"set"; then
 211   if test x"$gnu_ld_flag" = x"no"; then
 212     AC_MSG_RESULT([yes ($DEFAULT_LINKER)])
 213   else
 214     AC_MSG_RESULT([yes ($DEFAULT_LINKER - GNU ld)])
 215   fi
 216 else
 217   AC_MSG_RESULT(no)
 218 fi
 219
 220 # With demangler in GNU ld
 221 AC_ARG_WITH(demangler-in-ld,
 222 [  --with-demangler-in-ld  try to use demangler in GNU ld.],
 223 demangler_in_ld="$with_demangler_in_ld",
 224 demangler_in_ld=no)
 225
 226 # ----------------------
 227 # Find default assembler
 228 # ----------------------
 229
 230 # With GNU as
 231 AC_ARG_WITH(gnu-as,
 232 [  --with-gnu-as           arrange to work with GNU as],
 233 gas_flag="$with_gnu_as",
 234 gas_flag=no)
 235
 236 AC_ARG_WITH(as,
 237 [  --with-as               arrange to use the specified as (full pathname)],
 238 DEFAULT_ASSEMBLER="$with_as")
 239 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
 240   if test ! -x "$DEFAULT_ASSEMBLER"; then
 241     AC_MSG_ERROR([cannot execute: $DEFAULT_ASSEMBLER: check --with-as or env. var. DEFAULT_ASSEMBLER])
 242   elif $DEFAULT_ASSEMBLER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
 243     gas_flag=yes
 244   fi
 245   AC_DEFINE_UNQUOTED(DEFAULT_ASSEMBLER,"$DEFAULT_ASSEMBLER",
 246         [Define to enable the use of a default assembler.])
 247 fi
 248
 249 gnu_as=`if test x"$gas_flag" = x"yes"; then echo 1; else echo 0; fi`
 250 AC_DEFINE_UNQUOTED(HAVE_GNU_AS, $gnu_as, [Define if using GNU as.])
 251
 252 AC_MSG_CHECKING([whether a default assembler was specified])
 253 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
 254   if test x"$gas_flag" = x"no"; then
 255     AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER)])
 256   else
 257     AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER - GNU as)])
 258   fi
 259 else
 260   AC_MSG_RESULT(no)
 261 fi
 262
 263 # ---------------
 264 # Find C compiler
 265 # ---------------
 266
 267 # If a non-executable a.out is present (e.g. created by GNU as above even if
 268 # invoked with -v only), the IRIX 6 native ld just overwrites the existing
 269 # file, even when creating an executable, so an execution test fails.
 270 # Remove possible default executable files to avoid this.
 271 #
 272 # FIXME: This really belongs into AC_PROG_CC and can be removed once
 273 # Autoconf includes it.
 274 rm -f a.out a.exe b.out
 275
 276 # Find the native compiler
 277 AC_PROG_CC
 278 AM_PROG_CC_C_O
 279 ACX_PROG_GNAT([-I"$srcdir"/ada])
 280
 281 # autoconf is lame and doesn't give us any substitution variable for this.
 282 if eval "test \"`echo '$ac_cv_prog_cc_'${ac_cc}_c_o`\" = no"; then
 283   NO_MINUS_C_MINUS_O=yes
 284 else
 285   OUTPUT_OPTION='-o $@'
 286 fi
 287 AC_SUBST(NO_MINUS_C_MINUS_O)
 288 AC_SUBST(OUTPUT_OPTION)
 289
 290 # Remove the -O2: for historical reasons, unless bootstrapping we prefer
 291 # optimizations to be activated explicitly by the toplevel.
 292 case "$CC" in
 293   */prev-gcc/xgcc*) ;;
 294   *) CFLAGS=`echo $CFLAGS | sed "s/-O[[s0-9]]* *//" ` ;;
 295 esac
 296 AC_SUBST(CFLAGS)
 297
 298 # -------------------------
 299 # Check C compiler features
 300 # -------------------------
 301
 302 AC_USE_SYSTEM_EXTENSIONS
 303 AC_PROG_CPP
 304 AC_C_INLINE
 305
 306 # sizeof(char) is 1 by definition.
 307 AC_CHECK_SIZEOF(void *)
 308 AC_CHECK_SIZEOF(short)
 309 AC_CHECK_SIZEOF(int)
 310 AC_CHECK_SIZEOF(long)
 311 AC_CHECK_TYPES([long long], [AC_CHECK_SIZEOF(long long)])
 312 AC_CHECK_TYPES([__int64], [AC_CHECK_SIZEOF(__int64)])
 313
 314 # ---------------------
 315 # Warnings and checking
 316 # ---------------------
 317
 318 # Check $CC warning features (if it's GCC).
 319 # We want to use -pedantic, but we don't want warnings about
 320 # * 'long long'
 321 # * variadic macros
 322 # * overlong strings
 323 # So, we only use -pedantic if we can disable those warnings.
 324
 325 ACX_PROG_CC_WARNING_OPTS(
 326         m4_quote(m4_do([-W -Wall -Wwrite-strings -Wstrict-prototypes ],
 327                        [-Wmissing-prototypes -Wcast-qual])), [loose_warn])
 328 ACX_PROG_CC_WARNING_OPTS(
 329         m4_quote(m4_do([-Wold-style-definition -Wc++-compat ],
 330                        [-Wmissing-format-attribute])), [strict_warn])
 331 ACX_PROG_CC_WARNING_ALMOST_PEDANTIC(
 332         m4_quote(m4_do([-Wno-long-long -Wno-variadic-macros ],
 333                        [-Wno-overlength-strings])), [strict_warn])
 334 ACX_PROG_CC_WARNINGS_ARE_ERRORS([manual], [strict_warn])
 335
 336 # The above macros do nothing if the compiler is not GCC.  However, the
 337 # Makefile has more goo to add other flags, so this variabl is used to
 338 # enables warnings only for GCC.
 339 warn_cflags=
 340 if test "x$GCC" = "xyes"; then
 341   warn_cflags='$(GCC_WARN_CFLAGS)'
 342 fi
 343 AC_SUBST(warn_cflags)
 344
 345 # Enable expensive internal checks
 346 is_release=
 347 if test x"`cat $srcdir/DEV-PHASE`" != xexperimental; then
 348   is_release=yes
 349 fi
 350
 351 AC_ARG_ENABLE(checking,
 352 [  --enable-checking[=LIST]
 353                           enable expensive run-time checks.  With LIST,
 354                           enable only specific categories of checks.
 355                           Categories are: yes,no,all,none,release.
 356                           Flags are: assert,df,fold,gc,gcac,gimple,misc,
 357                           rtlflag,rtl,runtime,tree,valgrind,types.],
 358 [ac_checking_flags="${enableval}"],[
 359 # Determine the default checks.
 360 if test x$is_release = x ; then
 361   ac_checking_flags=yes
 362 else
 363   ac_checking_flags=release
 364 fi])
 365 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 366 for check in release $ac_checking_flags
 367 do
 368         case $check in
 369         # these set all the flags to specific states
 370         yes)            ac_assert_checking=1 ; ac_checking=1 ; ac_df_checking= ;
 371                         ac_fold_checking= ; ac_gc_checking=1 ;
 372                         ac_gc_always_collect= ; ac_gimple_checking=1 ; ac_rtl_checking= ;
 373                         ac_rtlflag_checking=1 ; ac_runtime_checking=1 ;
 374                         ac_tree_checking=1 ; ac_valgrind_checking= ;
 375                         ac_types_checking=1 ;;
 376         no|none)        ac_assert_checking= ; ac_checking= ; ac_df_checking= ;
 377                         ac_fold_checking= ; ac_gc_checking= ;
 378                         ac_gc_always_collect= ; ac_gimple_checking= ; ac_rtl_checking= ;
 379                         ac_rtlflag_checking= ; ac_runtime_checking= ;
 380                         ac_tree_checking= ; ac_valgrind_checking= ;
 381                         ac_types_checking= ;;
 382         all)            ac_assert_checking=1 ; ac_checking=1 ; ac_df_checking=1 ;
 383                         ac_fold_checking=1 ; ac_gc_checking=1 ;
 384                         ac_gc_always_collect=1 ; ac_gimple_checking=1 ; ac_rtl_checking=1 ;
 385                         ac_rtlflag_checking=1 ; ac_runtime_checking=1 ;
 386                         ac_tree_checking=1 ; ac_valgrind_checking= ;
 387                         ac_types_checking=1 ;;
 388         release)        ac_assert_checking=1 ; ac_checking= ; ac_df_checking= ;
 389                         ac_fold_checking= ; ac_gc_checking= ;
 390                         ac_gc_always_collect= ; ac_gimple_checking= ; ac_rtl_checking= ;
 391                         ac_rtlflag_checking= ; ac_runtime_checking=1 ;
 392                         ac_tree_checking= ; ac_valgrind_checking= ;
 393                         ac_types_checking= ;;
 394         # these enable particular checks
 395         assert)         ac_assert_checking=1 ;;
 396         df)             ac_df_checking=1 ;;
 397         fold)           ac_fold_checking=1 ;;
 398         gc)             ac_gc_checking=1 ;;
 399         gcac)           ac_gc_always_collect=1 ;;
 400         gimple)         ac_gimple_checking=1 ;;
 401         misc)           ac_checking=1 ;;
 402         rtl)            ac_rtl_checking=1 ;;
 403         rtlflag)        ac_rtlflag_checking=1 ;;
 404         runtime)        ac_runtime_checking=1 ;;
 405         tree)           ac_tree_checking=1 ;;
 406         types)          ac_types_checking=1 ;;
 407         valgrind)       ac_valgrind_checking=1 ;;
 408         *)      AC_MSG_ERROR(unknown check category $check) ;;
 409         esac
 410 done
 411 IFS="$ac_save_IFS"
 412
 413 nocommon_flag=""
 414 if test x$ac_checking != x ; then
 415   AC_DEFINE(ENABLE_CHECKING, 1,
 416 [Define if you want more run-time sanity checks.  This one gets a grab
 417    bag of miscellaneous but relatively cheap checks.])
 418   nocommon_flag=-fno-common
 419 fi
 420 AC_SUBST(nocommon_flag)
 421 if test x$ac_df_checking != x ; then
 422   AC_DEFINE(ENABLE_DF_CHECKING, 1,
 423 [Define if you want more run-time sanity checks for dataflow.])
 424 fi
 425 if test x$ac_assert_checking != x ; then
 426   AC_DEFINE(ENABLE_ASSERT_CHECKING, 1,
 427 [Define if you want assertions enabled.  This is a cheap check.])
 428 fi
 429 if test x$ac_gimple_checking != x ; then
 430   AC_DEFINE(ENABLE_GIMPLE_CHECKING, 1,
 431 [Define if you want operations on GIMPLE (the basic data structure of
 432 the high-level optimizers) to be checked for dynamic type safety at
 433 runtime.  This is moderately expensive.])
 434 fi
 435 GCC_TARGET_TEMPLATE(ENABLE_RUNTIME_CHECKING)
 436 if test x$ac_runtime_checking != x ; then
 437   AC_DEFINE(ENABLE_RUNTIME_CHECKING, 1,
 438 [Define if you want runtime assertions enabled.  This is a cheap check.])
 439 fi
 440 if test x$ac_tree_checking != x ; then
 441   AC_DEFINE(ENABLE_TREE_CHECKING, 1,
 442 [Define if you want all operations on trees (the basic data
 443    structure of the front ends) to be checked for dynamic type safety
 444    at runtime.  This is moderately expensive.  The tree browser debugging
 445    routines will also be enabled by this option.
 446    ])
 447   TREEBROWSER=tree-browser.o
 448 fi
 449 if test x$ac_types_checking != x ; then
 450   AC_DEFINE(ENABLE_TYPES_CHECKING, 1,
 451 [Define if you want all gimple types to be verified after gimplifiation.
 452    This is cheap.
 453    ])
 454 fi
 455 AC_SUBST(TREEBROWSER)
 456 if test x$ac_rtl_checking != x ; then
 457   AC_DEFINE(ENABLE_RTL_CHECKING, 1,
 458 [Define if you want all operations on RTL (the basic data structure
 459    of the optimizer and back end) to be checked for dynamic type safety
 460    at runtime.  This is quite expensive.])
 461 fi
 462 if test x$ac_rtlflag_checking != x ; then
 463   AC_DEFINE(ENABLE_RTL_FLAG_CHECKING, 1,
 464 [Define if you want RTL flag accesses to be checked against the RTL
 465    codes that are supported for each access macro.  This is relatively
 466    cheap.])
 467 fi
 468 if test x$ac_gc_checking != x ; then
 469   AC_DEFINE(ENABLE_GC_CHECKING, 1,
 470 [Define if you want the garbage collector to do object poisoning and
 471    other memory allocation checks.  This is quite expensive.])
 472 fi
 473 if test x$ac_gc_always_collect != x ; then
 474   AC_DEFINE(ENABLE_GC_ALWAYS_COLLECT, 1,
 475 [Define if you want the garbage collector to operate in maximally
 476    paranoid mode, validating the entire heap and collecting garbage at
 477    every opportunity.  This is extremely expensive.])
 478 fi
 479 if test x$ac_fold_checking != x ; then
 480   AC_DEFINE(ENABLE_FOLD_CHECKING, 1,
 481 [Define if you want fold checked that it never destructs its argument.
 482    This is quite expensive.])
 483 fi
 484 valgrind_path_defines=
 485 valgrind_command=
 486
 487 dnl # This check AC_REQUIREs various stuff, so it *must not* be inside
 488 dnl # an if statement.  This was the source of very frustrating bugs
 489 dnl # in converting to autoconf 2.5x!
 490 AC_CHECK_HEADER(valgrind.h, have_valgrind_h=yes, have_valgrind_h=no)
 491
 492 if test x$ac_valgrind_checking != x ; then
 493   # It is certainly possible that there's valgrind but no valgrind.h.
 494   # GCC relies on making annotations so we must have both.
 495   AC_MSG_CHECKING(for VALGRIND_DISCARD in <valgrind/memcheck.h>)
 496   AC_PREPROC_IFELSE([AC_LANG_SOURCE(
 497     [[#include <valgrind/memcheck.h>
 498 #ifndef VALGRIND_DISCARD
 499 #error VALGRIND_DISCARD not defined
 500 #endif]])],
 501   [gcc_cv_header_valgrind_memcheck_h=yes],
 502   [gcc_cv_header_valgrind_memcheck_h=no])
 503   AC_MSG_RESULT($gcc_cv_header_valgrind_memcheck_h)
 504   AC_MSG_CHECKING(for VALGRIND_DISCARD in <memcheck.h>)
 505   AC_PREPROC_IFELSE([AC_LANG_SOURCE(
 506     [[#include <memcheck.h>
 507 #ifndef VALGRIND_DISCARD
 508 #error VALGRIND_DISCARD not defined
 509 #endif]])],
 510   [gcc_cv_header_memcheck_h=yes],
 511   [gcc_cv_header_memcheck_h=no])
 512   AC_MSG_RESULT($gcc_cv_header_memcheck_h)
 513   AM_PATH_PROG_WITH_TEST(valgrind_path, valgrind,
 514         [$ac_dir/$ac_word --version | grep valgrind- >/dev/null 2>&1])
 515   if test "x$valgrind_path" = "x" \
 516     || (test $have_valgrind_h = no \
 517         && test $gcc_cv_header_memcheck_h = no \
 518         && test $gcc_cv_header_valgrind_memcheck_h = no); then
 519         AC_MSG_ERROR([*** Can't find both valgrind and valgrind/memcheck.h, memcheck.h or valgrind.h])
 520   fi
 521   valgrind_path_defines=-DVALGRIND_PATH='\"'$valgrind_path'\"'
 522   valgrind_command="$valgrind_path -q"
 523   AC_DEFINE(ENABLE_VALGRIND_CHECKING, 1,
 524 [Define if you want to run subprograms and generated programs
 525    through valgrind (a memory checker).  This is extremely expensive.])
 526   if test $gcc_cv_header_valgrind_memcheck_h = yes; then
 527     AC_DEFINE(HAVE_VALGRIND_MEMCHECK_H, 1,
 528         [Define if valgrind's valgrind/memcheck.h header is installed.])
 529   fi
 530   if test $gcc_cv_header_memcheck_h = yes; then
 531     AC_DEFINE(HAVE_MEMCHECK_H, 1,
 532         [Define if valgrind's memcheck.h header is installed.])
 533   fi
 534 fi
 535 AC_SUBST(valgrind_path_defines)
 536 AC_SUBST(valgrind_command)
 537
 538 # Enable code coverage collection
 539 AC_ARG_ENABLE(coverage,
 540 [  --enable-coverage[=LEVEL]
 541                           enable compiler's code coverage collection.
 542                           Use to measure compiler performance and locate
 543                           unused parts of the compiler. With LEVEL, specify
 544                           optimization. Values are opt, noopt,
 545                           default is noopt],
 546 [case "${enableval}" in
 547   yes|noopt)
 548     coverage_flags="-fprofile-arcs -ftest-coverage -frandom-seed=\$@ -O0"
 549     ;;
 550   opt)
 551     coverage_flags="-fprofile-arcs -ftest-coverage -frandom-seed=\$@ -O2"
 552     ;;
 553   no)
 554     # a.k.a. --disable-coverage
 555     coverage_flags=""
 556     ;;
 557   *)
 558     AC_MSG_ERROR(unknown coverage setting $enableval)
 559     ;;
 560 esac],
 561 [coverage_flags=""])
 562 AC_SUBST(coverage_flags)
 563
 564 AC_ARG_ENABLE(gather-detailed-mem-stats,
 565 [  --enable-gather-detailed-mem-stats         enable detailed memory allocation stats gathering], [],
 566 [enable_gather_detailed_mem_stats=no])
 567 if test x$enable_gather_detailed_mem_stats = xyes ; then
 568   AC_DEFINE(GATHER_STATISTICS, 1,
 569         [Define to enable detailed memory allocation stats gathering.])
 570 fi
 571
 572 # -------------------------------
 573 # Miscenalleous configure options
 574 # -------------------------------
 575
 576 # With stabs
 577 AC_ARG_WITH(stabs,
 578 [  --with-stabs            arrange to use stabs instead of host debug format],
 579 stabs="$with_stabs",
 580 stabs=no)
 581
 582 # Determine whether or not multilibs are enabled.
 583 AC_ARG_ENABLE(multilib,
 584 [  --enable-multilib       enable library support for multiple ABIs],
 585 [], [enable_multilib=yes])
 586 AC_SUBST(enable_multilib)
 587
 588 # Enable __cxa_atexit for C++.
 589 AC_ARG_ENABLE(__cxa_atexit,
 590 [  --enable-__cxa_atexit   enable __cxa_atexit for C++],
 591 [], [])
 592
 593 # Enable C extension for decimal float if target supports it.
 594 AC_ARG_ENABLE(decimal-float,
 595 [  --enable-decimal-float={no,yes,bid,dpd}
 596                         enable decimal float extension to C.  Selecting 'bid'
 597                         or 'dpd' choses which decimal floating point format
 598                         to use],
 599 [
 600   case $enable_decimal_float in
 601     yes | no | bid | dpd) ;;
 602     *) AC_MSG_ERROR(['$enable_decimal_float' is an invalid value for --enable-decimal-float.
 603 Valid choices are 'yes', 'bid', 'dpd', and 'no'.]) ;;
 604   esac
 605 ],
 606 [
 607   case $target in
 608     powerpc*-*-linux* | i?86*-*-linux* | x86_64*-*-linux*)
 609       enable_decimal_float=yes
 610       ;;
 611     *)
 612       AC_MSG_WARN(decimal float is not supported for this target, ignored)
 613       enable_decimal_float=no
 614       ;;
 615   esac
 616 ])
 617
 618 dfp=`if test $enable_decimal_float != no; then echo 1; else echo 0; fi`
 619 AC_DEFINE_UNQUOTED(ENABLE_DECIMAL_FLOAT, $dfp,
 620 [Define to 1 to enable decimal float extension to C.])
 621
 622 # x86's use BID format instead of DPD
 623 case x$enable_decimal_float in
 624   xyes)
 625     case $target in
 626       i?86*-*-linux* | x86_64*-*-linux*)
 627         enable_decimal_float=bid
 628         ;;
 629       *)
 630         enable_decimal_float=dpd
 631         ;;
 632     esac
 633     ;;
 634   xno)
 635     # ENABLE_DECIMAL_FLOAT is set to 0. But we have to have proper
 636     # dependency on libdecnumber.
 637     enable_decimal_float=dpd
 638     ;;
 639 esac
 640 AC_SUBST(enable_decimal_float)
 641
 642 bid=`if test $enable_decimal_float = bid; then echo 1; else echo 0; fi`
 643 AC_DEFINE_UNQUOTED(ENABLE_DECIMAL_BID_FORMAT, $bid,
 644 [Define to 1 to specify that we are using the BID decimal floating
 645 point format instead of DPD])
 646
 647 # Enable C extension for fixed-point arithmetic.
 648 AC_ARG_ENABLE(fixed-point,
 649 [  --enable-fixed-point    enable fixed-point arithmetic extension to C],
 650 [
 651 ],
 652 [
 653   case $target in
 654     mips*-*-*)
 655       case $host in
 656         mips*-sgi-irix*)
 657           AC_MSG_WARN(fixed-point is not supported on IRIX, ignored)
 658           enable_fixed_point=no
 659           ;;
 660         *)
 661           enable_fixed_point=yes
 662           ;;
 663       esac
 664       ;;
 665     *)
 666       AC_MSG_WARN(fixed-point is not supported for this target, ignored)
 667       enable_fixed_point=no
 668       ;;
 669   esac
 670 ])
 671 AC_SUBST(enable_fixed_point)
 672
 673 fixedpoint=`if test $enable_fixed_point = yes; then echo 1; else echo 0; fi`
 674 AC_DEFINE_UNQUOTED(ENABLE_FIXED_POINT, $fixedpoint,
 675 [Define to 1 to enable fixed-point arithmetic extension to C.])
 676
 677 # Enable threads
 678 # Pass with no value to take the default
 679 # Pass with a value to specify a thread package
 680 AC_ARG_ENABLE(threads,
 681 [  --enable-threads        enable thread usage for target GCC
 682   --enable-threads=LIB    use LIB thread package for target GCC],,
 683 [enable_threads=''])
 684
 685 AC_ARG_ENABLE(tls,
 686 [  --enable-tls            enable or disable generation of tls code
 687                           overriding the assembler check for tls support],
 688 [
 689   case $enable_tls in
 690     yes | no) ;;
 691     *) AC_MSG_ERROR(['$enable_tls' is an invalid value for --enable-tls.
 692 Valid choices are 'yes' and 'no'.]) ;;
 693   esac
 694 ], [enable_tls=''])
 695
 696 AC_ARG_ENABLE(objc-gc,
 697 [  --enable-objc-gc       enable the use of Boehm's garbage collector with
 698                           the GNU Objective-C runtime],
 699 if test x$enable_objc_gc = xno; then
 700         objc_boehm_gc=''
 701 else
 702         objc_boehm_gc=1
 703 fi,
 704 objc_boehm_gc='')
 705
 706 AC_ARG_WITH(dwarf2,
 707 [  --with-dwarf2           force the default debug format to be DWARF 2],
 708 dwarf2="$with_dwarf2",
 709 dwarf2=no)
 710
 711 AC_ARG_ENABLE(shared,
 712 [  --disable-shared        don't provide a shared libgcc],
 713 [
 714   case $enable_shared in
 715   yes | no) ;;
 716   *)
 717     enable_shared=no
 718     IFS="${IFS=         }"; ac_save_ifs="$IFS"; IFS="${IFS}:,"
 719     for pkg in $enableval; do
 720       if test "X$pkg" = "Xgcc" || test "X$pkg" = "Xlibgcc"; then
 721         enable_shared=yes
 722       fi
 723     done
 724     IFS="$ac_save_ifs"
 725     ;;
 726   esac
 727 ], [enable_shared=yes])
 728 AC_SUBST(enable_shared)
 729
 730 AC_ARG_WITH(build-sysroot,
 731   [  --with-build-sysroot=sysroot
 732                           use sysroot as the system root during the build])
 733
 734 AC_ARG_WITH(sysroot,
 735 [  --with-sysroot[=DIR] Search for usr/lib, usr/include, et al, within DIR.],
 736 [
 737  case ${with_sysroot} in
 738  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_noncanonical}/sys-root' ;;
 739  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
 740  esac
 741
 742  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
 743  CROSS_SYSTEM_HEADER_DIR='$(TARGET_SYSTEM_ROOT)$${sysroot_headers_suffix}$(NATIVE_SYSTEM_HEADER_DIR)'
 744
 745  if test "x$prefix" = xNONE; then
 746   test_prefix=/usr/local
 747  else
 748   test_prefix=$prefix
 749  fi
 750  if test "x$exec_prefix" = xNONE; then
 751   test_exec_prefix=$test_prefix
 752  else
 753   test_exec_prefix=$exec_prefix
 754  fi
 755  case ${TARGET_SYSTEM_ROOT} in
 756  "${test_prefix}"|"${test_prefix}/"*|\
 757  "${test_exec_prefix}"|"${test_exec_prefix}/"*|\
 758  '${prefix}'|'${prefix}/'*|\
 759  '${exec_prefix}'|'${exec_prefix}/'*)
 760    t="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE"
 761    TARGET_SYSTEM_ROOT_DEFINE="$t"
 762    ;;
 763  esac
 764 ], [
 765  TARGET_SYSTEM_ROOT=
 766  TARGET_SYSTEM_ROOT_DEFINE=
 767  CROSS_SYSTEM_HEADER_DIR='$(gcc_tooldir)/sys-include'
 768 ])
 769 AC_SUBST(TARGET_SYSTEM_ROOT)
 770 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
 771 AC_SUBST(CROSS_SYSTEM_HEADER_DIR)
 772
 773 # Build with intermodule optimisations
 774 AC_ARG_ENABLE(intermodule,
 775 [  --enable-intermodule    build the compiler in one step],
 776 [case ${enable_intermodule} in
 777   yes) onestep="-onestep";;
 778   *) onestep="";;
 779 esac],
 780 [onestep=""])
 781 AC_SUBST(onestep)
 782
 783 ACX_PKGVERSION([GCC])
 784 ACX_BUGURL([http://gcc.gnu.org/bugs.html])
 785
 786 # Sanity check enable_languages in case someone does not run the toplevel
 787 # configure # script.
 788 AC_ARG_ENABLE(languages,
 789 [  --enable-languages=LIST specify which front-ends to build],
 790 [case ,${enable_languages}, in
 791        ,,|,yes,)
 792                 # go safe -- we cannot be much sure without the toplevel
 793                 # configure's
 794                 # analysis of which target libs are present and usable
 795                 enable_languages=c
 796                 ;;
 797          *,all,*)
 798                 AC_MSG_ERROR([only the toplevel supports --enable-languages=all])
 799                 ;;
 800         *,c,*)
 801                 ;;
 802         *)
 803                 enable_languages=c,${enable_languages}
 804                 ;;
 805 esac],
 806 [enable_languages=c])
 807
 808 # Used by documentation targets
 809 AC_SUBST(datarootdir)
 810 AC_SUBST(docdir)
 811 AC_SUBST(htmldir)
 812
 813 # -------------------------
 814 # Checks for other programs
 815 # -------------------------
 816
 817 AC_PROG_MAKE_SET
 818
 819 # Find some useful tools
 820 AC_PROG_AWK
 821 # We need awk to create options.c and options.h.
 822 # Bail out if it's missing.
 823 case ${AWK} in
 824   "") AC_MSG_ERROR([can't build without awk, bailing out]) ;;
 825 esac
 826
 827 gcc_AC_PROG_LN_S
 828 ACX_PROG_LN($LN_S)
 829 AC_PROG_RANLIB
 830 case "${host}" in
 831 *-*-darwin*)
 832   # By default, the Darwin ranlib will not treat common symbols as
 833   # definitions when  building the archive table of contents.  Other
 834   # ranlibs do that; pass an option to the Darwin ranlib that makes
 835   # it behave similarly.
 836   ranlib_flags="-c"
 837   ;;
 838 *)
 839   ranlib_flags=""
 840 esac
 841 AC_SUBST(ranlib_flags)
 842
 843 gcc_AC_PROG_INSTALL
 844
 845 # See if cmp has --ignore-initial.
 846 gcc_AC_PROG_CMP_IGNORE_INITIAL
 847
 848 # See if we have the mktemp command.
 849 AC_CHECK_PROG(have_mktemp_command, mktemp, yes, no)
 850
 851 # See if makeinfo has been installed and is modern enough
 852 # that we can use it.
 853 ACX_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
 854   [GNU texinfo.* \([0-9][0-9.]*\)],
 855   [4.[7-9]*|4.[1-9][0-9]*|[5-9]*|[1-9][0-9]*])
 856 if test $gcc_cv_prog_makeinfo_modern = no; then
 857   AC_MSG_WARN([
 858 *** Makeinfo is missing or too old.
 859 *** Info documentation will not be built.])
 860   BUILD_INFO=
 861 else
 862   BUILD_INFO=info
 863 fi
 864 AC_SUBST(BUILD_INFO)
 865
 866 # Is pod2man recent enough to regenerate manpages?
 867 AC_MSG_CHECKING([for recent Pod::Man])
 868 if (perl -e 'use 1.10 Pod::Man') >/dev/null 2>&1; then
 869   AC_MSG_RESULT(yes)
 870   GENERATED_MANPAGES=generated-manpages
 871 else
 872   AC_MSG_RESULT(no)
 873   GENERATED_MANPAGES=
 874 fi
 875 AC_SUBST(GENERATED_MANPAGES)
 876
 877 MISSING="${CONFIG_SHELL-/bin/sh} $ac_aux_dir/missing"
 878
 879 # How about lex?
 880 dnl Don't use AC_PROG_LEX; we insist on flex.
 881 dnl LEXLIB is not useful in gcc.
 882 AC_CHECK_PROGS([FLEX], flex, [$MISSING flex])
 883
 884 # Bison?
 885 AC_CHECK_PROGS([BISON], bison, [$MISSING bison])
 886
 887 # Binutils are not build modules, unlike bison/flex/makeinfo.  So we
 888 # check for build == host before using them.
 889
 890 # NM
 891 if test x${build} = x${host} && test -f $srcdir/../binutils/nm.c \
 892   && test -d ../binutils ; then
 893   NM='$(objdir)/../binutils/nm-new'
 894 else
 895   AC_CHECK_PROG(NM, nm, nm, ${CONFIG_SHELL-/bin/sh} ${srcdir}/../missing nm)
 896 fi
 897
 898 # AR
 899 if test x${build} = x${host} && test -f $srcdir/../binutils/ar.c \
 900   && test -d ../binutils ; then
 901   AR='$(objdir)/../binutils/ar'
 902 else
 903   AC_CHECK_PROG(AR, ar, ar, ${CONFIG_SHELL-/bin/sh} ${srcdir}/../missing ar)
 904 fi
 905
 906
 907 # --------------------
 908 # Checks for C headers
 909 # --------------------
 910
 911 # Need to reject headers which give warnings, so that the -Werror bootstrap
 912 # works later. *sigh*  This needs to come before all header checks.
 913 AC_PROG_CPP_WERROR
 914
 915 AC_HEADER_STDC
 916 AC_HEADER_TIME
 917 ACX_HEADER_STRING
 918 AC_HEADER_SYS_WAIT
 919 AC_CHECK_HEADERS(limits.h stddef.h string.h strings.h stdlib.h time.h iconv.h \
 920                  fcntl.h unistd.h sys/file.h sys/time.h sys/mman.h \
 921                  sys/resource.h sys/param.h sys/times.h sys/stat.h \
 922                  direct.h malloc.h langinfo.h ldfcn.h locale.h wchar.h)
 923
 924 # Check for thread headers.
 925 AC_CHECK_HEADER(thread.h, [have_thread_h=yes], [have_thread_h=])
 926 AC_CHECK_HEADER(pthread.h, [have_pthread_h=yes], [have_pthread_h=])
 927
 928 # These tests can't be done till we know if we have limits.h.
 929 gcc_AC_C_CHAR_BIT
 930 AC_C_BIGENDIAN
 931
 932 # --------
 933 # UNSORTED
 934 # --------
 935
 936
 937 # These libraries may be used by collect2.
 938 # We may need a special search path to get them linked.
 939 AC_CACHE_CHECK(for collect2 libraries, gcc_cv_collect2_libs,
 940 [save_LIBS="$LIBS"
 941 for libs in '' -lld -lmld \
 942                 '-L/usr/lib/cmplrs/cc2.11 -lmld' \
 943                 '-L/usr/lib/cmplrs/cc3.11 -lmld'
 944 do
 945         LIBS="$libs"
 946         AC_TRY_LINK_FUNC(ldopen,
 947                 [gcc_cv_collect2_libs="$libs"; break])
 948 done
 949 LIBS="$save_LIBS"
 950 test -z "$gcc_cv_collect2_libs" && gcc_cv_collect2_libs='none required'])
 951 case $gcc_cv_collect2_libs in
 952         "none required")        ;;
 953         *)      COLLECT2_LIBS=$gcc_cv_collect2_libs ;;
 954 esac
 955 AC_SUBST(COLLECT2_LIBS)
 956
 957 # When building Ada code on Alpha, we need exc_resume which is usually in
 958 # -lexc.  So test for it.
 959 save_LIBS="$LIBS"
 960 LIBS=
 961 AC_SEARCH_LIBS(exc_resume, exc)
 962 GNAT_LIBEXC="$LIBS"
 963 LIBS="$save_LIBS"
 964 AC_SUBST(GNAT_LIBEXC)
 965
 966 # Some systems put ldexp and frexp in libm instead of libc; assume
 967 # they're both in the same place.  jcf-dump needs them.
 968 save_LIBS="$LIBS"
 969 LIBS=
 970 AC_SEARCH_LIBS(ldexp, m)
 971 LDEXP_LIB="$LIBS"
 972 LIBS="$save_LIBS"
 973 AC_SUBST(LDEXP_LIB)
 974
 975 # Use <inttypes.h> only if it exists,
 976 # doesn't clash with <sys/types.h>, and declares intmax_t.
 977 AC_MSG_CHECKING(for inttypes.h)
 978 AC_CACHE_VAL(gcc_cv_header_inttypes_h,
 979 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 980 [[#include <sys/types.h>
 981 #include <inttypes.h>]],
 982   [[intmax_t i = -1;]])],
 983   [gcc_cv_header_inttypes_h=yes],
 984   [gcc_cv_header_inttypes_h=no])])
 985 AC_MSG_RESULT($gcc_cv_header_inttypes_h)
 986 if test $gcc_cv_header_inttypes_h = yes; then
 987   AC_DEFINE(HAVE_INTTYPES_H, 1,
 988         [Define if you have a working <inttypes.h> header file.])
 989 fi
 990
 991 dnl Disabled until we have a complete test for buggy enum bitfields.
 992 dnl gcc_AC_C_ENUM_BF_UNSIGNED
 993
 994 define(gcc_UNLOCKED_FUNCS, clearerr_unlocked feof_unlocked dnl
 995   ferror_unlocked fflush_unlocked fgetc_unlocked fgets_unlocked dnl
 996   fileno_unlocked fprintf_unlocked fputc_unlocked fputs_unlocked dnl
 997   fread_unlocked fwrite_unlocked getchar_unlocked getc_unlocked dnl
 998   putchar_unlocked putc_unlocked)
 999 AC_CHECK_FUNCS(times clock kill getrlimit setrlimit atoll atoq \
1000         sysconf strsignal getrusage nl_langinfo \
1001         gettimeofday mbstowcs wcswidth mmap mincore setlocale \
1002         gcc_UNLOCKED_FUNCS)
1003
1004 if test x$ac_cv_func_mbstowcs = xyes; then
1005   AC_CACHE_CHECK(whether mbstowcs works, gcc_cv_func_mbstowcs_works,
1006 [    AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdlib.h>
1007 int main()
1008 {
1009   mbstowcs(0, "", 0);
1010   return 0;
1011 }]])],
1012     [gcc_cv_func_mbstowcs_works=yes],
1013     [gcc_cv_func_mbstowcs_works=no],
1014     [gcc_cv_func_mbstowcs_works=yes])])
1015   if test x$gcc_cv_func_mbstowcs_works = xyes; then
1016     AC_DEFINE(HAVE_WORKING_MBSTOWCS, 1,
1017   [Define this macro if mbstowcs does not crash when its
1018    first argument is NULL.])
1019   fi
1020 fi
1021
1022 AC_CHECK_TYPE(ssize_t, int)
1023 AC_CHECK_TYPE(caddr_t, char *)
1024
1025 # Try to determine the array type of the second argument of getgroups
1026 # for the target system (int or gid_t).
1027 AC_TYPE_GETGROUPS
1028 if test "${target}" = "${build}"; then
1029   TARGET_GETGROUPS_T=$ac_cv_type_getgroups
1030 else
1031   case "${target}" in
1032         # This condition may need some tweaking.  It should include all
1033         # targets where the array type of the second argument of getgroups
1034         # is int and the type of gid_t is not equivalent to int.
1035         *-*-sunos* | *-*-ultrix*)
1036                 TARGET_GETGROUPS_T=int
1037                 ;;
1038         *)
1039                 TARGET_GETGROUPS_T=gid_t
1040                 ;;
1041   esac
1042 fi
1043 AC_SUBST(TARGET_GETGROUPS_T)
1044
1045 gcc_AC_FUNC_MMAP_BLACKLIST
1046
1047 case "${host}" in
1048 *-*-*vms*)
1049   # Under VMS, vfork works very differently than on Unix. The standard test
1050   # won't work, and it isn't easily adaptable. It makes more sense to
1051   # just force it.
1052   ac_cv_func_vfork_works=yes
1053   ;;
1054 esac
1055 AC_FUNC_FORK
1056
1057 AM_ICONV
1058 # Until we have in-tree GNU iconv:
1059 LIBICONV_DEP=
1060 AC_SUBST(LIBICONV_DEP)
1061
1062 AM_LC_MESSAGES
1063
1064 AM_LANGINFO_CODESET
1065
1066 # We will need to find libiberty.h and ansidecl.h
1067 saved_CFLAGS="$CFLAGS"
1068 CFLAGS="$CFLAGS -I${srcdir} -I${srcdir}/../include"
1069 gcc_AC_CHECK_DECLS(getenv atol asprintf sbrk abort atof getcwd getwd \
1070         strsignal strstr strverscmp \
1071         errno snprintf vsnprintf vasprintf malloc realloc calloc \
1072         free basename getopt clock getpagesize gcc_UNLOCKED_FUNCS, , ,[
1073 #include "ansidecl.h"
1074 #include "system.h"])
1075
1076 gcc_AC_CHECK_DECLS(getrlimit setrlimit getrusage, , ,[
1077 #include "ansidecl.h"
1078 #include "system.h"
1079 #ifdef HAVE_SYS_RESOURCE_H
1080 #include <sys/resource.h>
1081 #endif
1082 ])
1083
1084 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1085 #include "ansidecl.h"
1086 #include "system.h"
1087 #ifdef HAVE_SYS_RESOURCE_H
1088 #include <sys/resource.h>
1089 #endif
1090 ]], [[rlim_t l = 0;]])],[],[AC_DEFINE([rlim_t],[long],
1091 [Define to `long' if <sys/resource.h> doesn't define.])])
1092
1093 # On AIX 5.2, <ldfcn.h> conflicts with <fcntl.h>, as both define incompatible
1094 # FREAD and FWRITE macros.  Fortunately, for GCC's single usage of ldgetname
1095 # in collect2.c, <fcntl.h> isn't visible, but the configure test below needs
1096 # to undef these macros to get the correct value for HAVE_DECL_LDGETNAME.
1097 gcc_AC_CHECK_DECLS(ldgetname, , ,[
1098 #include "ansidecl.h"
1099 #include "system.h"
1100 #ifdef HAVE_LDFCN_H
1101 #undef FREAD
1102 #undef FWRITE
1103 #include <ldfcn.h>
1104 #endif
1105 ])
1106
1107 gcc_AC_CHECK_DECLS(times, , ,[
1108 #include "ansidecl.h"
1109 #include "system.h"
1110 #ifdef HAVE_SYS_TIMES_H
1111 #include <sys/times.h>
1112 #endif
1113 ])
1114
1115 gcc_AC_CHECK_DECLS(sigaltstack, , ,[
1116 #include "ansidecl.h"
1117 #include "system.h"
1118 #include <signal.h>
1119 ])
1120
1121 # More time-related stuff.
1122 AC_CACHE_CHECK(for struct tms, ac_cv_struct_tms, [
1123 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1124 #include "ansidecl.h"
1125 #include "system.h"
1126 #ifdef HAVE_SYS_TIMES_H
1127 #include <sys/times.h>
1128 #endif
1129 ]], [[struct tms tms;]])],[ac_cv_struct_tms=yes],[ac_cv_struct_tms=no])])
1130 if test $ac_cv_struct_tms = yes; then
1131   AC_DEFINE(HAVE_STRUCT_TMS, 1,
1132   [Define if <sys/times.h> defines struct tms.])
1133 fi
1134
1135 # use gcc_cv_* here because this doesn't match the behavior of AC_CHECK_TYPE.
1136 # revisit after autoconf 2.50.
1137 AC_CACHE_CHECK(for clock_t, gcc_cv_type_clock_t, [
1138 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1139 #include "ansidecl.h"
1140 #include "system.h"
1141 ]], [[clock_t x;]])],[gcc_cv_type_clock_t=yes],[gcc_cv_type_clock_t=no])])
1142 if test $gcc_cv_type_clock_t = yes; then
1143   AC_DEFINE(HAVE_CLOCK_T, 1,
1144   [Define if <time.h> defines clock_t.])
1145 fi
1146
1147 # Restore CFLAGS from before the gcc_AC_NEED_DECLARATIONS tests.
1148 CFLAGS="$saved_CFLAGS"
1149
1150 gcc_AC_INITFINI_ARRAY
1151
1152 # mkdir takes a single argument on some systems.
1153 gcc_AC_FUNC_MKDIR_TAKES_ONE_ARG
1154
1155 # File extensions
1156 manext='.1'
1157 objext='.o'
1158 AC_SUBST(manext)
1159 AC_SUBST(objext)
1160
1161 # With Setjmp/Longjmp based exception handling.
1162 AC_ARG_ENABLE(sjlj-exceptions,
1163 [  --enable-sjlj-exceptions
1164                           arrange to use setjmp/longjmp exception handling],
1165 [case $target in
1166   *-*-hpux10*)
1167     if test $enableval != yes; then
1168       AC_MSG_WARN([dwarf2 exceptions not supported, sjlj exceptions forced])
1169       enableval=yes
1170     fi
1171     ;;
1172 esac
1173 force_sjlj_exceptions=yes],
1174 [case $target in
1175   *-*-hpux10*)
1176     force_sjlj_exceptions=yes
1177     enableval=yes
1178     ;;
1179   *)
1180     force_sjlj_exceptions=no
1181     ;;
1182 esac])
1183 if test $force_sjlj_exceptions = yes; then
1184   sjlj=`if test $enableval = yes; then echo 1; else echo 0; fi`
1185   AC_DEFINE_UNQUOTED(CONFIG_SJLJ_EXCEPTIONS, $sjlj,
1186     [Define 0/1 to force the choice for exception handling model.])
1187 fi
1188
1189 # For platforms with the unwind ABI which includes an unwind library,
1190 # libunwind, we can choose to use the system libunwind.
1191 # config.gcc also contains tests of with_system_libunwind.
1192 GCC_CHECK_UNWIND_GETIPINFO
1193
1194 # --------------------------------------------------------
1195 # Build, host, and target specific configuration fragments
1196 # --------------------------------------------------------
1197
1198 # Collect build-machine-specific information.
1199 . ${srcdir}/config.build
1200
1201 # Collect host-machine-specific information.
1202 . ${srcdir}/config.host
1203
1204 target_gtfiles=
1205
1206 # Collect target-machine-specific information.
1207 . ${srcdir}/config.gcc
1208
1209 extra_objs="${host_extra_objs} ${extra_objs}"
1210 extra_gcc_objs="${host_extra_gcc_objs} ${extra_gcc_objs}"
1211
1212 # Default the target-machine variables that were not explicitly set.
1213 if test x"$tm_file" = x
1214 then tm_file=$cpu_type/$cpu_type.h; fi
1215
1216 if test x"$extra_headers" = x
1217 then extra_headers=; fi
1218
1219 if test x$md_file = x
1220 then md_file=$cpu_type/$cpu_type.md; fi
1221
1222 if test x$out_file = x
1223 then out_file=$cpu_type/$cpu_type.c; fi
1224
1225 if test x"$tmake_file" = x
1226 then tmake_file=$cpu_type/t-$cpu_type
1227 fi
1228
1229 if test x"$dwarf2" = xyes
1230 then tm_file="$tm_file tm-dwarf2.h"
1231 fi
1232
1233 # Say what files are being used for the output code and MD file.
1234 echo "Using \`$srcdir/config/$out_file' for machine-specific logic."
1235 echo "Using \`$srcdir/config/$md_file' as machine description file."
1236
1237 # If any of the xm_file variables contain nonexistent files, warn
1238 # about them and drop them.
1239
1240 bx=
1241 for x in $build_xm_file; do
1242   if    test -f $srcdir/config/$x
1243   then      bx="$bx $x"
1244   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1245   fi
1246 done
1247 build_xm_file="$bx"
1248
1249 hx=
1250 for x in $host_xm_file; do
1251   if    test -f $srcdir/config/$x
1252   then      hx="$hx $x"
1253   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1254   fi
1255 done
1256 host_xm_file="$hx"
1257
1258 tx=
1259 for x in $xm_file; do
1260   if    test -f $srcdir/config/$x
1261   then      tx="$tx $x"
1262   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1263   fi
1264 done
1265 xm_file="$tx"
1266
1267 count=a
1268 for f in $tm_file; do
1269         count=${count}x
1270 done
1271 if test $count = ax; then
1272         echo "Using \`$srcdir/config/$tm_file' as target machine macro file."
1273 else
1274         echo "Using the following target machine macro files:"
1275         for f in $tm_file; do
1276                 echo "  $srcdir/config/$f"
1277         done
1278 fi
1279
1280 if test x$need_64bit_hwint = xyes; then
1281         AC_DEFINE(NEED_64BIT_HOST_WIDE_INT, 1,
1282 [Define to 1 if HOST_WIDE_INT must be 64 bits wide (see hwint.h).])
1283 fi
1284
1285 if test x$use_long_long_for_widest_fast_int = xyes; then
1286         AC_DEFINE(USE_LONG_LONG_FOR_WIDEST_FAST_INT, 1,
1287 [Define to 1 if the 'long long' (or '__int64') is wider than 'long' but still
1288 efficiently supported by the host hardware.])
1289 fi
1290
1291 count=a
1292 for f in $host_xm_file; do
1293         count=${count}x
1294 done
1295 if test $count = a; then
1296         :
1297 elif test $count = ax; then
1298         echo "Using \`$srcdir/config/$host_xm_file' as host machine macro file."
1299 else
1300         echo "Using the following host machine macro files:"
1301         for f in $host_xm_file; do
1302                 echo "  $srcdir/config/$f"
1303         done
1304 fi
1305 echo "Using ${out_host_hook_obj} for host machine hooks."
1306
1307 if test "$host_xm_file" != "$build_xm_file"; then
1308         count=a
1309         for f in $build_xm_file; do
1310                 count=${count}x
1311         done
1312         if test $count = a; then
1313                 :
1314         elif test $count = ax; then
1315                 echo "Using \`$srcdir/config/$build_xm_file' as build machine macro file."
1316         else
1317                 echo "Using the following build machine macro files:"
1318                 for f in $build_xm_file; do
1319                         echo "  $srcdir/config/$f"
1320                 done
1321         fi
1322 fi
1323
1324 case ${host} in
1325   powerpc*-*-darwin*)
1326     AC_CACHE_CHECK([whether mcontext_t fields have underscores],
1327       gcc_cv_mcontext_underscores,
1328       AC_COMPILE_IFELSE([
1329 #include <sys/cdefs.h>
1330 #include <sys/signal.h>
1331 #include <ucontext.h>
1332 int main() { mcontext_t m; if (m->ss.srr0) return 0; return 0; }
1333 ],
1334         gcc_cv_mcontext_underscores=no, gcc_cv_mcontext_underscores=yes))
1335       if test $gcc_cv_mcontext_underscores = yes; then
1336         AC_DEFINE(HAS_MCONTEXT_T_UNDERSCORES,,dnl
1337           [mcontext_t fields start with __])
1338       fi
1339     ;;
1340 esac
1341
1342 # ---------
1343 # Threading
1344 # ---------
1345
1346 # Check if a valid thread package
1347 case ${enable_threads} in
1348   "" | no)
1349     # No threads
1350     target_thread_file='single'
1351     ;;
1352   yes)
1353     # default
1354     target_thread_file='single'
1355     ;;
1356   aix | dce | gnat | irix | posix | posix95 | rtems | \
1357   single | solaris | vxworks | win32 | mipssde)
1358     target_thread_file=${enable_threads}
1359     ;;
1360   *)
1361     echo "${enable_threads} is an unknown thread package" 1>&2
1362     exit 1
1363     ;;
1364 esac
1365
1366 if test x${thread_file} = x; then
1367   # No thread file set by target-specific clauses in config.gcc,
1368   # so use file chosen by default logic above
1369   thread_file=${target_thread_file}
1370 fi
1371
1372 # Make gthr-default.h if we have a thread file.
1373 gthread_flags=
1374 if test $thread_file != single; then
1375   echo "#include \"gthr-${thread_file}.h\"" > gthr-default.h-t
1376   if diff gthr-default.h-t gthr-default.h 2>/dev/null; then
1377     rm -f gthr-default.h-t
1378   else
1379     mv -f gthr-default.h-t gthr-default.h
1380   fi
1381   gthread_flags=-DHAVE_GTHR_DEFAULT
1382 fi
1383 AC_SUBST(gthread_flags)
1384
1385 # --------
1386 # UNSORTED
1387 # --------
1388
1389 use_cxa_atexit=no
1390 if test x$enable___cxa_atexit = xyes || \
1391    test x$enable___cxa_atexit = x -a x$default_use_cxa_atexit = xyes; then
1392   if test x$host = x$target; then
1393     case $host in
1394       # mingw32 doesn't have __cxa_atexit but uses atexit registration
1395       # keyed to flag_use_cxa_atexit
1396       *-*-mingw32*)
1397         use_cxa_atexit=yes
1398         ;;
1399       *)
1400         AC_CHECK_FUNC(__cxa_atexit,[use_cxa_atexit=yes],
1401           [echo "__cxa_atexit can't be enabled on this target"])
1402         ;;
1403     esac
1404   else
1405     # We can't check for __cxa_atexit when building a cross, so assume
1406     # it is available
1407     use_cxa_atexit=yes
1408   fi
1409   if test x$use_cxa_atexit = xyes; then
1410     AC_DEFINE(DEFAULT_USE_CXA_ATEXIT, 2,
1411       [Define if you want to use __cxa_atexit, rather than atexit, to
1412       register C++ destructors for local statics and global objects.
1413       This is essential for fully standards-compliant handling of
1414       destructors, but requires __cxa_atexit in libc.])
1415   fi
1416 fi
1417
1418 # Look for a file containing extra machine modes.
1419 if test -n "$extra_modes" && test -f $srcdir/config/$extra_modes; then
1420   extra_modes_file='$(srcdir)'/config/${extra_modes}
1421   AC_SUBST(extra_modes_file)
1422   AC_DEFINE_UNQUOTED(EXTRA_MODES_FILE, "config/$extra_modes",
1423   [Define to the name of a file containing a list of extra machine modes
1424    for this architecture.])
1425 fi
1426
1427 # Convert extra_options into a form suitable for Makefile use.
1428 extra_opt_files=
1429 for f in $extra_options; do
1430   extra_opt_files="$extra_opt_files \$(srcdir)/config/$f"
1431 done
1432 AC_SUBST(extra_opt_files)
1433
1434 # auto-host.h is the file containing items generated by autoconf and is
1435 # the first file included by config.h.
1436 # If host=build, it is correct to have bconfig include auto-host.h
1437 # as well.  If host!=build, we are in error and need to do more
1438 # work to find out the build config parameters.
1439 if test x$host = x$build
1440 then
1441         build_auto=auto-host.h
1442 else
1443         # We create a subdir, then run autoconf in the subdir.
1444         # To prevent recursion we set host and build for the new
1445         # invocation of configure to the build for this invocation
1446         # of configure.
1447         tempdir=build.$$
1448         rm -rf $tempdir
1449         mkdir $tempdir
1450         cd $tempdir
1451         case ${srcdir} in
1452         /* | [A-Za-z]:[\\/]* ) realsrcdir=${srcdir};;
1453         *) realsrcdir=../${srcdir};;
1454         esac
1455         saved_CFLAGS="${CFLAGS}"
1456         CC="${CC_FOR_BUILD}" CFLAGS="${CFLAGS_FOR_BUILD}" \
1457         LDFLAGS="${LDFLAGS_FOR_BUILD}" \
1458         ${realsrcdir}/configure \
1459                 --enable-languages=${enable_languages-all} \
1460                 --target=$target_alias --host=$build_alias --build=$build_alias
1461         CFLAGS="${saved_CFLAGS}"
1462
1463         # We just finished tests for the build machine, so rename
1464         # the file auto-build.h in the gcc directory.
1465         mv auto-host.h ../auto-build.h
1466         cd ..
1467         rm -rf $tempdir
1468         build_auto=auto-build.h
1469 fi
1470 AC_SUBST(build_subdir)
1471
1472 tm_file="${tm_file} defaults.h"
1473 tm_p_file="${tm_p_file} tm-preds.h"
1474 host_xm_file="auto-host.h ansidecl.h ${host_xm_file}"
1475 build_xm_file="${build_auto} ansidecl.h ${build_xm_file}"
1476 # We don't want ansidecl.h in target files, write code there in ISO/GNU C.
1477 # put this back in temporarily.
1478 xm_file="auto-host.h ansidecl.h ${xm_file}"
1479
1480 # --------
1481 # UNSORTED
1482 # --------
1483
1484 changequote(,)dnl
1485 # Compile in configure arguments.
1486 if test -f configargs.h ; then
1487         # Being re-configured.
1488         gcc_config_arguments=`grep configuration_arguments configargs.h | sed -e 's/.*"\([^"]*\)".*/\1/'`
1489         gcc_config_arguments="$gcc_config_arguments : (reconfigured) $TOPLEVEL_CONFIGURE_ARGUMENTS"
1490 else
1491         gcc_config_arguments="$TOPLEVEL_CONFIGURE_ARGUMENTS"
1492 fi
1493
1494 # Double all backslashes and backslash all quotes to turn
1495 # gcc_config_arguments into a C string.
1496 sed -e 's/\\/\\\\/g; s/"/\\"/g' <<EOF >conftest.out
1497 $gcc_config_arguments
1498 EOF
1499 gcc_config_arguments_str=`cat conftest.out`
1500 rm -f conftest.out
1501
1502 cat > configargs.h <<EOF
1503 /* Generated automatically. */
1504 static const char configuration_arguments[] = "$gcc_config_arguments_str";
1505 static const char thread_model[] = "$thread_file";
1506
1507 static const struct {
1508   const char *name, *value;
1509 } configure_default_options[] = $configure_default_options;
1510 EOF
1511 changequote([,])dnl
1512
1513 # Internationalization
1514 ZW_GNU_GETTEXT_SISTER_DIR
1515
1516 # If LIBINTL contains LIBICONV, then clear LIBICONV so we don't get
1517 # -liconv on the link line twice.
1518 case "$LIBINTL" in *$LIBICONV*)
1519         LIBICONV= ;;
1520 esac
1521
1522 AC_ARG_ENABLE(secureplt,
1523 [  --enable-secureplt      enable -msecure-plt by default for PowerPC],
1524 [], [])
1525
1526 AC_ARG_ENABLE(cld,
1527 [  --enable-cld            enable -mcld by default for 32bit x86], [],
1528 [enable_cld=no])
1529
1530 # Windows32 Registry support for specifying GCC installation paths.
1531 AC_ARG_ENABLE(win32-registry,
1532 [  --disable-win32-registry
1533                           disable lookup of installation paths in the
1534                           Registry on Windows hosts
1535   --enable-win32-registry enable registry lookup (default)
1536   --enable-win32-registry=KEY
1537                           use KEY instead of GCC version as the last portion
1538                           of the registry key],,)
1539
1540 case $host_os in
1541   win32 | pe | cygwin* | mingw32* | uwin*)
1542     if test "x$enable_win32_registry" != xno; then
1543       AC_SEARCH_LIBS(RegOpenKeyExA, advapi32,, [enable_win32_registry=no])
1544     fi
1545
1546     if test "x$enable_win32_registry" != xno; then
1547       AC_DEFINE(ENABLE_WIN32_REGISTRY, 1,
1548   [Define to 1 if installation paths should be looked up in the Windows
1549    Registry. Ignored on non-Windows hosts.])
1550
1551       if test "x$enable_win32_registry" != xyes \
1552          && test "x$enable_win32_registry" != x; then
1553         AC_DEFINE_UNQUOTED(WIN32_REGISTRY_KEY, "$enable_win32_registry",
1554   [Define to be the last component of the Windows registry key under which
1555    to look for installation paths.  The full key used will be
1556    HKEY_LOCAL_MACHINE/SOFTWARE/Free Software Foundation/{WIN32_REGISTRY_KEY}.
1557    The default is the GCC version number.])
1558       fi
1559     fi
1560   ;;
1561 esac
1562
1563 # Get an absolute path to the GCC top-level source directory
1564 holddir=`${PWDCMD-pwd}`
1565 cd $srcdir
1566 topdir=`${PWDCMD-pwd}`
1567 cd $holddir
1568
1569 # Conditionalize the makefile for this host machine.
1570 xmake_file=
1571 for f in ${host_xmake_file}
1572 do
1573         if test -f ${srcdir}/config/$f
1574         then
1575                 xmake_file="${xmake_file} \$(srcdir)/config/$f"
1576         fi
1577 done
1578
1579 # Conditionalize the makefile for this target machine.
1580 tmake_file_=
1581 for f in ${tmake_file}
1582 do
1583         if test -f ${srcdir}/config/$f
1584         then
1585                 tmake_file_="${tmake_file_} \$(srcdir)/config/$f"
1586         fi
1587 done
1588 tmake_file="${tmake_file_}"
1589
1590 out_object_file=`basename $out_file .c`.o
1591
1592 tm_file_list="options.h"
1593 tm_include_list="options.h"
1594 for f in $tm_file; do
1595   case $f in
1596     ./* )
1597        f=`echo $f | sed 's/^..//'`
1598        tm_file_list="${tm_file_list} $f"
1599        tm_include_list="${tm_include_list} $f"
1600        ;;
1601     defaults.h )
1602        tm_file_list="${tm_file_list} \$(srcdir)/$f"
1603        tm_include_list="${tm_include_list} $f"
1604        ;;
1605     * )
1606        tm_file_list="${tm_file_list} \$(srcdir)/config/$f"
1607        tm_include_list="${tm_include_list} config/$f"
1608        ;;
1609   esac
1610 done
1611
1612 tm_p_file_list=
1613 tm_p_include_list=
1614 for f in $tm_p_file; do
1615   case $f in
1616     tm-preds.h )
1617        tm_p_file_list="${tm_p_file_list} $f"
1618        tm_p_include_list="${tm_p_include_list} $f"
1619        ;;
1620     * )
1621        tm_p_file_list="${tm_p_file_list} \$(srcdir)/config/$f"
1622        tm_p_include_list="${tm_p_include_list} config/$f"
1623   esac
1624 done
1625
1626 xm_file_list=
1627 xm_include_list=
1628 for f in $xm_file; do
1629   case $f in
1630     ansidecl.h )
1631        xm_file_list="${xm_file_list} \$(srcdir)/../include/$f"
1632        xm_include_list="${xm_include_list} $f"
1633        ;;
1634     auto-host.h )
1635        xm_file_list="${xm_file_list} $f"
1636        xm_include_list="${xm_include_list} $f"
1637        ;;
1638     * )
1639        xm_file_list="${xm_file_list} \$(srcdir)/config/$f"
1640        xm_include_list="${xm_include_list} config/$f"
1641        ;;
1642   esac
1643 done
1644
1645 host_xm_file_list=
1646 host_xm_include_list=
1647 for f in $host_xm_file; do
1648   case $f in
1649     ansidecl.h )
1650        host_xm_file_list="${host_xm_file_list} \$(srcdir)/../include/$f"
1651        host_xm_include_list="${host_xm_include_list} $f"
1652        ;;
1653     auto-host.h )
1654        host_xm_file_list="${host_xm_file_list} $f"
1655        host_xm_include_list="${host_xm_include_list} $f"
1656        ;;
1657     * )
1658        host_xm_file_list="${host_xm_file_list} \$(srcdir)/config/$f"
1659        host_xm_include_list="${host_xm_include_list} config/$f"
1660        ;;
1661   esac
1662 done
1663
1664 build_xm_file_list=
1665 for f in $build_xm_file; do
1666   case $f in
1667     ansidecl.h )
1668        build_xm_file_list="${build_xm_file_list} \$(srcdir)/../include/$f"
1669        build_xm_include_list="${build_xm_include_list} $f"
1670        ;;
1671     auto-build.h | auto-host.h )
1672        build_xm_file_list="${build_xm_file_list} $f"
1673        build_xm_include_list="${build_xm_include_list} $f"
1674        ;;
1675     * )
1676        build_xm_file_list="${build_xm_file_list} \$(srcdir)/config/$f"
1677        build_xm_include_list="${build_xm_include_list} config/$f"
1678        ;;
1679   esac
1680 done
1681
1682 # Define macro CROSS_DIRECTORY_STRUCTURE in compilation if this is a
1683 # cross-compiler which does not use the native headers and libraries.
1684 # Also use all.cross instead of all.internal and adjust SYSTEM_HEADER_DIR.
1685 CROSS=                                          AC_SUBST(CROSS)
1686 ALL=all.internal                                AC_SUBST(ALL)
1687 SYSTEM_HEADER_DIR='$(NATIVE_SYSTEM_HEADER_DIR)' AC_SUBST(SYSTEM_HEADER_DIR)
1688
1689 if test "x$with_build_sysroot" != x; then
1690   build_system_header_dir=$with_build_sysroot'$${sysroot_headers_suffix}$(NATIVE_SYSTEM_HEADER_DIR)'
1691 else
1692   # This value is used, even on a native system, because
1693   # CROSS_SYSTEM_HEADER_DIR is just
1694   # $(TARGET_SYSTEM_ROOT)$(NATIVE_SYSTEM_HEADER_DIR).
1695   build_system_header_dir='$(CROSS_SYSTEM_HEADER_DIR)'
1696 fi
1697
1698 if test x$host != x$target
1699 then
1700         CROSS="-DCROSS_DIRECTORY_STRUCTURE"
1701         ALL=all.cross
1702         SYSTEM_HEADER_DIR=$build_system_header_dir
1703         case "$host","$target" in
1704         # Darwin crosses can use the host system's libraries and headers,
1705         # because of the fat library support.  Of course, it must be the
1706         # same version of Darwin on both sides.  Allow the user to
1707         # just say --target=foo-darwin without a version number to mean
1708         # "the version on this system".
1709             *-*-darwin*,*-*-darwin*)
1710                 hostos=`echo $host | sed 's/.*-darwin/darwin/'`
1711                 targetos=`echo $target | sed 's/.*-darwin/darwin/'`
1712                 if test $hostos = $targetos -o $targetos = darwin ; then
1713                     CROSS=
1714                     SYSTEM_HEADER_DIR='$(NATIVE_SYSTEM_HEADER_DIR)'
1715                     with_headers=yes
1716                 fi
1717                 ;;
1718
1719             i?86-*-*,x86_64-*-* \
1720             | powerpc*-*-*,powerpc64*-*-*)
1721                 CROSS="$CROSS -DNATIVE_CROSS" ;;
1722         esac
1723 elif test "x$TARGET_SYSTEM_ROOT" != x; then
1724         SYSTEM_HEADER_DIR=$build_system_header_dir
1725 fi
1726
1727 # If this is a cross-compiler that does not
1728 # have its own set of headers then define
1729 # inhibit_libc
1730
1731 # If this is using newlib, without having the headers available now,
1732 # then define inhibit_libc in LIBGCC2_CFLAGS.
1733 # This prevents libgcc2 from containing any code which requires libc
1734 # support.
1735 : ${inhibit_libc=false}
1736 if { { test x$host != x$target && test "x$with_sysroot" = x ; } ||
1737        test x$with_newlib = xyes ; } &&
1738      { test "x$with_headers" = x || test "x$with_headers" = xno ; } ; then
1739        inhibit_libc=true
1740 fi
1741 AC_SUBST(inhibit_libc)
1742
1743 # When building gcc with a cross-compiler, we need to adjust things so
1744 # that the generator programs are still built with the native compiler.
1745 # Also, we cannot run fixincludes or fix-header.
1746
1747 # These are the normal (build=host) settings:
1748 CC_FOR_BUILD='$(CC)'            AC_SUBST(CC_FOR_BUILD)
1749 BUILD_CFLAGS='$(ALL_CFLAGS)'    AC_SUBST(BUILD_CFLAGS)
1750 BUILD_LDFLAGS='$(LDFLAGS)'      AC_SUBST(BUILD_LDFLAGS)
1751 STMP_FIXINC=stmp-fixinc         AC_SUBST(STMP_FIXINC)
1752
1753 # Possibly disable fixproto, on a per-target basis.
1754 case ${use_fixproto} in
1755   no)
1756     STMP_FIXPROTO=
1757     ;;
1758   yes)
1759     STMP_FIXPROTO=stmp-fixproto
1760     ;;
1761 esac
1762 AC_SUBST(STMP_FIXPROTO)
1763
1764 # And these apply if build != host, or we are generating coverage data
1765 if test x$build != x$host || test "x$coverage_flags" != x
1766 then
1767     BUILD_CFLAGS='$(INTERNAL_CFLAGS) $(T_CFLAGS) $(CFLAGS_FOR_BUILD)'
1768     BUILD_LDFLAGS='$(LDFLAGS_FOR_BUILD)'
1769
1770     if test "x$TARGET_SYSTEM_ROOT" = x; then
1771         if test "x$STMP_FIXPROTO" != x; then
1772           STMP_FIXPROTO=stmp-install-fixproto
1773         fi
1774     fi
1775 fi
1776
1777 # Expand extra_headers to include complete path.
1778 # This substitutes for lots of t-* files.
1779 extra_headers_list=
1780 # Prepend $(srcdir)/config/${cpu_type}/ to every entry in extra_headers.
1781 for file in ${extra_headers} ; do
1782   extra_headers_list="${extra_headers_list} \$(srcdir)/config/${cpu_type}/${file}"
1783 done
1784
1785 # If use_gcc_tgmath is set, append ginclude/tgmath.h.
1786 if test x"$use_gcc_tgmath" = xyes
1787 then extra_headers_list="${extra_headers_list} \$(srcdir)/ginclude/tgmath.h"
1788 fi
1789
1790 # Define collect2 in Makefile.
1791 case $host_can_use_collect2 in
1792   no) collect2= ;;
1793   *) collect2='collect2$(exeext)' ;;
1794 esac
1795 AC_SUBST([collect2])
1796
1797 # Add a definition of USE_COLLECT2 if system wants one.
1798 case $use_collect2 in
1799   no) use_collect2= ;;
1800   "") ;;
1801   *)
1802     host_xm_defines="${host_xm_defines} USE_COLLECT2"
1803     xm_defines="${xm_defines} USE_COLLECT2"
1804     case $host_can_use_collect2 in
1805       no)
1806         AC_MSG_ERROR([collect2 is required but cannot be built on this system])
1807         ;;
1808     esac
1809     ;;
1810 esac
1811
1812 # ---------------------------
1813 # Assembler & linker features
1814 # ---------------------------
1815
1816 # During stage 2, ld is actually gcc/collect-ld, which is a small script to
1817 # discern between when to use prev-ld/ld-new and when to use ld/ld-new.
1818 # However when ld-new is first executed from the build tree, libtool will
1819 # relink it as .libs/lt-ld-new, so that it can give it an RPATH that refers
1820 # to the build tree.  While doing this we need to use the previous-stage
1821 # linker, or we have an infinite loop.  The presence of a shell script as
1822 # ld/ld-new, and the fact that the script *uses ld itself*, is what confuses
1823 # the gcc/collect-ld script.  So we need to know how libtool works, or
1824 # exec-tool will fail.
1825
1826 m4_defun([_LT_CONFIG_COMMANDS], [])
1827 AC_PROG_LIBTOOL
1828 AC_SUBST(objdir)
1829 AC_SUBST(enable_fast_install)
1830
1831 # Identify the assembler which will work hand-in-glove with the newly
1832 # built GCC, so that we can examine its features.  This is the assembler
1833 # which will be driven by the driver program.
1834 #
1835 # If build != host, and we aren't building gas in-tree, we identify a
1836 # build->target assembler and hope that it will have the same features
1837 # as the host->target assembler we'll be using.
1838 gcc_cv_gas_major_version=
1839 gcc_cv_gas_minor_version=
1840 gcc_cv_as_gas_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/gas
1841
1842 m4_pattern_allow([AS_FOR_TARGET])dnl
1843 AS_VAR_SET_IF(gcc_cv_as,, [
1844 if test -x "$DEFAULT_ASSEMBLER"; then
1845         gcc_cv_as="$DEFAULT_ASSEMBLER"
1846 elif test -f $gcc_cv_as_gas_srcdir/configure.in \
1847      && test -f ../gas/Makefile \
1848      && test x$build = x$host; then
1849         gcc_cv_as=../gas/as-new$build_exeext
1850 elif test -x as$build_exeext; then
1851         # Build using assembler in the current directory.
1852         gcc_cv_as=./as$build_exeext
1853 elif test -x $AS_FOR_TARGET; then
1854         gcc_cv_as="$AS_FOR_TARGET"
1855 else
1856         AC_PATH_PROG(gcc_cv_as, $AS_FOR_TARGET)
1857 fi])
1858
1859 ORIGINAL_AS_FOR_TARGET=$gcc_cv_as
1860 AC_SUBST(ORIGINAL_AS_FOR_TARGET)
1861 case "$ORIGINAL_AS_FOR_TARGET" in
1862   ./as | ./as$build_exeext) ;;
1863   *) AC_CONFIG_FILES(as:exec-tool.in, [chmod +x as]) ;;
1864 esac
1865
1866 AC_MSG_CHECKING(what assembler to use)
1867 if test "$gcc_cv_as" = ../gas/as-new$build_exeext; then
1868   # Single tree build which includes gas.  We want to prefer it
1869   # over whatever linker top-level may have detected, since
1870   # we'll use what we're building after installation anyway.
1871   AC_MSG_RESULT(newly built gas)
1872   in_tree_gas=yes
1873   _gcc_COMPUTE_GAS_VERSION
1874   in_tree_gas_is_elf=no
1875   if grep 'obj_format = elf' ../gas/Makefile > /dev/null \
1876      || (grep 'obj_format = multi' ../gas/Makefile \
1877          && grep 'extra_objects =.* obj-elf' ../gas/Makefile) > /dev/null
1878   then
1879     in_tree_gas_is_elf=yes
1880   fi
1881 else
1882   AC_MSG_RESULT($gcc_cv_as)
1883   in_tree_gas=no
1884 fi
1885
1886 # Identify the linker which will work hand-in-glove with the newly
1887 # built GCC, so that we can examine its features.  This is the linker
1888 # which will be driven by the driver program.
1889 #
1890 # If build != host, and we aren't building gas in-tree, we identify a
1891 # build->target linker and hope that it will have the same features
1892 # as the host->target linker we'll be using.
1893 gcc_cv_gld_major_version=
1894 gcc_cv_gld_minor_version=
1895 gcc_cv_ld_gld_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/ld
1896 gcc_cv_ld_bfd_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/bfd
1897
1898 AS_VAR_SET_IF(gcc_cv_ld,, [
1899 if test -x "$DEFAULT_LINKER"; then
1900         gcc_cv_ld="$DEFAULT_LINKER"
1901 elif test -f $gcc_cv_ld_gld_srcdir/configure.in \
1902      && test -f ../ld/Makefile \
1903      && test x$build = x$host; then
1904         gcc_cv_ld=../ld/ld-new$build_exeext
1905 elif test -x collect-ld$build_exeext; then
1906         # Build using linker in the current directory.
1907         gcc_cv_ld=./collect-ld$build_exeext
1908 elif test -x $LD_FOR_TARGET; then
1909         gcc_cv_ld="$LD_FOR_TARGET"
1910 else
1911         AC_PATH_PROG(gcc_cv_ld, $LD_FOR_TARGET)
1912 fi])
1913
1914 ORIGINAL_LD_FOR_TARGET=$gcc_cv_ld
1915 AC_SUBST(ORIGINAL_LD_FOR_TARGET)
1916 case "$ORIGINAL_LD_FOR_TARGET" in
1917   ./collect-ld | ./collect-ld$build_exeext) ;;
1918   *) AC_CONFIG_FILES(collect-ld:exec-tool.in, [chmod +x collect-ld]) ;;
1919 esac
1920
1921 AC_MSG_CHECKING(what linker to use)
1922 if test "$gcc_cv_ld" = ../ld/ld-new$build_exeext; then
1923         # Single tree build which includes ld.  We want to prefer it
1924         # over whatever linker top-level may have detected, since
1925         # we'll use what we're building after installation anyway.
1926         AC_MSG_RESULT(newly built ld)
1927         in_tree_ld=yes
1928         in_tree_ld_is_elf=no
1929         if (grep 'EMUL = .*elf' ../ld/Makefile \
1930             || grep 'EMUL = .*linux' ../ld/Makefile \
1931             || grep 'EMUL = .*lynx' ../ld/Makefile) > /dev/null; then
1932           in_tree_ld_is_elf=yes
1933         fi
1934         for f in $gcc_cv_ld_bfd_srcdir/configure $gcc_cv_ld_gld_srcdir/configure $gcc_cv_ld_gld_srcdir/configure.in $gcc_cv_ld_gld_srcdir/Makefile.in
1935         do
1936 changequote(,)dnl
1937                 gcc_cv_gld_version=`sed -n -e 's/^[     ]*\(VERSION=[0-9]*\.[0-9]*.*\)/\1/p' < $f`
1938                 if test x$gcc_cv_gld_version != x; then
1939                         break
1940                 fi
1941         done
1942         gcc_cv_gld_major_version=`expr "$gcc_cv_gld_version" : "VERSION=\([0-9]*\)"`
1943         gcc_cv_gld_minor_version=`expr "$gcc_cv_gld_version" : "VERSION=[0-9]*\.\([0-9]*\)"`
1944 changequote([,])dnl
1945 else
1946         AC_MSG_RESULT($gcc_cv_ld)
1947         in_tree_ld=no
1948 fi
1949
1950 # Figure out what nm we will be using.
1951 gcc_cv_binutils_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/binutils
1952 AS_VAR_SET_IF(gcc_cv_nm,, [
1953 if test -f $gcc_cv_binutils_srcdir/configure.in \
1954      && test -f ../binutils/Makefile \
1955      && test x$build = x$host; then
1956         gcc_cv_nm=../binutils/nm-new$build_exeext
1957 elif test -x nm$build_exeext; then
1958         gcc_cv_nm=./nm$build_exeext
1959 elif test -x $NM_FOR_TARGET; then
1960         gcc_cv_nm="$NM_FOR_TARGET"
1961 else
1962         AC_PATH_PROG(gcc_cv_nm, $NM_FOR_TARGET)
1963 fi])
1964
1965 AC_MSG_CHECKING(what nm to use)
1966 if test "$gcc_cv_nm" = ../binutils/nm-new$build_exeext; then
1967         # Single tree build which includes binutils.
1968         AC_MSG_RESULT(newly built nm)
1969         in_tree_nm=yes
1970 else
1971         AC_MSG_RESULT($gcc_cv_nm)
1972         in_tree_nm=no
1973 fi
1974
1975 ORIGINAL_NM_FOR_TARGET=$gcc_cv_nm
1976 AC_SUBST(ORIGINAL_NM_FOR_TARGET)
1977 case "$ORIGINAL_NM_FOR_TARGET" in
1978   ./nm | ./nm$build_exeext) ;;
1979   *) AC_CONFIG_FILES(nm:exec-tool.in, [chmod +x nm]) ;;
1980 esac
1981
1982
1983 # Figure out what objdump we will be using.
1984 AS_VAR_SET_IF(gcc_cv_objdump,, [
1985 if test -f $gcc_cv_binutils_srcdir/configure.in \
1986      && test -f ../binutils/Makefile \
1987      && test x$build = x$host; then
1988         # Single tree build which includes binutils.
1989         gcc_cv_objdump=../binutils/objdump$build_exeext
1990 elif test -x objdump$build_exeext; then
1991         gcc_cv_objdump=./objdump$build_exeext
1992 elif test -x $OBJDUMP_FOR_TARGET; then
1993         gcc_cv_objdump="$OBJDUMP_FOR_TARGET"
1994 else
1995         AC_PATH_PROG(gcc_cv_objdump, $OBJDUMP_FOR_TARGET)
1996 fi])
1997
1998 AC_MSG_CHECKING(what objdump to use)
1999 if test "$gcc_cv_objdump" = ../binutils/objdump$build_exeext; then
2000         # Single tree build which includes binutils.
2001         AC_MSG_RESULT(newly built objdump)
2002 elif test x$gcc_cv_objdump = x; then
2003         AC_MSG_RESULT(not found)
2004 else
2005         AC_MSG_RESULT($gcc_cv_objdump)
2006 fi
2007
2008 # Figure out what readelf we will be using.
2009 AS_VAR_SET_IF(gcc_cv_readelf,, [
2010 if test -f $gcc_cv_binutils_srcdir/configure.in \
2011      && test -f ../binutils/Makefile \
2012      && test x$build = x$host; then
2013         # Single tree build which includes binutils.
2014         gcc_cv_readelf=../binutils/readelf$build_exeext
2015 elif test -x readelf$build_exeext; then
2016         gcc_cv_readelf=./readelf$build_exeext
2017 else
2018         AC_PATH_PROG(gcc_cv_readelf, readelf)
2019 fi])
2020
2021 AC_MSG_CHECKING(what readelf to use)
2022 if test "$gcc_cv_readelf" = ../binutils/readelf$build_exeext; then
2023         # Single tree build which includes binutils.
2024         AC_MSG_RESULT(newly built readelf)
2025 elif test x$gcc_cv_readelf = x; then
2026         AC_MSG_RESULT(not found)
2027 else
2028         AC_MSG_RESULT($gcc_cv_readelf)
2029 fi
2030
2031 # Figure out what assembler alignment features are present.
2032 gcc_GAS_CHECK_FEATURE([.balign and .p2align], gcc_cv_as_balign_and_p2align,
2033  [2,6,0],,
2034 [.balign 4
2035 .p2align 2],,
2036 [AC_DEFINE(HAVE_GAS_BALIGN_AND_P2ALIGN, 1,
2037   [Define if your assembler supports .balign and .p2align.])])
2038
2039 gcc_GAS_CHECK_FEATURE([.p2align with maximum skip], gcc_cv_as_max_skip_p2align,
2040  [2,8,0],,
2041  [.p2align 4,,7],,
2042 [AC_DEFINE(HAVE_GAS_MAX_SKIP_P2ALIGN, 1,
2043   [Define if your assembler supports specifying the maximum number
2044    of bytes to skip when using the GAS .p2align command.])])
2045
2046 gcc_GAS_CHECK_FEATURE([.literal16], gcc_cv_as_literal16,
2047  [2,8,0],,
2048  [.literal16],,
2049 [AC_DEFINE(HAVE_GAS_LITERAL16, 1,
2050   [Define if your assembler supports .literal16.])])
2051
2052 gcc_GAS_CHECK_FEATURE([working .subsection -1], gcc_cv_as_subsection_m1,
2053  [elf,2,9,0],,
2054  [conftest_label1: .word 0
2055 .subsection -1
2056 conftest_label2: .word 0
2057 .previous],
2058  [if test x$gcc_cv_nm != x; then
2059     $gcc_cv_nm conftest.o | grep conftest_label1 > conftest.nm1
2060     $gcc_cv_nm conftest.o | grep conftest_label2 | sed -e 's/label2/label1/' > conftest.nm2
2061     if cmp conftest.nm1 conftest.nm2 > /dev/null 2>&1
2062     then :
2063     else gcc_cv_as_subsection_m1=yes
2064     fi
2065     rm -f conftest.nm1 conftest.nm2
2066   fi],
2067  [AC_DEFINE(HAVE_GAS_SUBSECTION_ORDERING, 1,
2068   [Define if your assembler supports .subsection and .subsection -1 starts
2069    emitting at the beginning of your section.])])
2070
2071 gcc_GAS_CHECK_FEATURE([.weak], gcc_cv_as_weak,
2072  [2,2,0],,
2073  [      .weak foobar],,
2074 [AC_DEFINE(HAVE_GAS_WEAK, 1, [Define if your assembler supports .weak.])])
2075
2076 gcc_GAS_CHECK_FEATURE([.weakref], gcc_cv_as_weakref,
2077  [2,17,0],,
2078  [      .weakref foobar, barfnot],,
2079 [AC_DEFINE(HAVE_GAS_WEAKREF, 1, [Define if your assembler supports .weakref.])])
2080
2081 gcc_GAS_CHECK_FEATURE([.nsubspa comdat], gcc_cv_as_nsubspa_comdat,
2082  [2,15,91],,
2083  [      .SPACE $TEXT$
2084         .NSUBSPA $CODE$,COMDAT],,
2085 [AC_DEFINE(HAVE_GAS_NSUBSPA_COMDAT, 1, [Define if your assembler supports .nsubspa comdat option.])])
2086
2087 # .hidden needs to be supported in both the assembler and the linker,
2088 # because GNU LD versions before 2.12.1 have buggy support for STV_HIDDEN.
2089 # This is irritatingly difficult to feature test for; we have to check the
2090 # date string after the version number.  If we've got an in-tree
2091 # ld, we don't know its patchlevel version, so we set the baseline at 2.13
2092 # to be safe.
2093 # The gcc_GAS_CHECK_FEATURE call just sets a cache variable.
2094 gcc_GAS_CHECK_FEATURE([.hidden], gcc_cv_as_hidden,
2095  [elf,2,13,0],,
2096 [       .hidden foobar
2097 foobar:])
2098
2099 AC_CACHE_CHECK(linker for .hidden support, gcc_cv_ld_hidden,
2100 [if test $in_tree_ld = yes ; then
2101   gcc_cv_ld_hidden=no
2102   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 13 -o "$gcc_cv_gld_major_version" -gt 2 \
2103      && test $in_tree_ld_is_elf = yes; then
2104      gcc_cv_ld_hidden=yes
2105   fi
2106 else
2107 changequote(,)dnl
2108   gcc_cv_ld_hidden=yes
2109   ld_ver=`$gcc_cv_ld --version 2>/dev/null | sed 1q`
2110   if echo "$ld_ver" | grep GNU > /dev/null; then
2111     ld_vers=`echo $ld_ver | sed -n \
2112         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*.*\)$,\1,p'`
2113     ld_date=`echo $ld_ver | sed -n 's,^.*\([2-9][0-9][0-9][0-9]\)[-]*\([01][0-9]\)[-]*\([0-3][0-9]\).*$,\1\2\3,p'`
2114     ld_vers_major=`expr "$ld_vers" : '\([0-9]*\)'`
2115     ld_vers_minor=`expr "$ld_vers" : '[0-9]*\.\([0-9]*\)'`
2116     ld_vers_patch=`expr "$ld_vers" : '[0-9]*\.[0-9]*\.\([0-9]*\)'`
2117     if test 0"$ld_date" -lt 20020404; then
2118       if test -n "$ld_date"; then
2119         # If there was date string, but was earlier than 2002-04-04, fail
2120         gcc_cv_ld_hidden=no
2121       elif test -z "$ld_vers"; then
2122         # If there was no date string nor ld version number, something is wrong
2123         gcc_cv_ld_hidden=no
2124       else
2125         test -z "$ld_vers_patch" && ld_vers_patch=0
2126         if test "$ld_vers_major" -lt 2; then
2127           gcc_cv_ld_hidden=no
2128         elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -lt 12; then
2129           gcc_cv_ld_hidden="no"
2130         elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -eq 12 -a "$ld_vers_patch" -eq 0; then
2131           gcc_cv_ld_hidden=no
2132         fi
2133       fi
2134     fi
2135   else
2136     case "${target}" in
2137       hppa64*-*-hpux* | ia64*-*-hpux*)
2138         gcc_cv_ld_hidden=yes
2139         ;;
2140       *-*-solaris2.9* | *-*-solaris2.1[0-9]*)
2141         gcc_cv_ld_hidden=yes
2142         ;;
2143       *)
2144         gcc_cv_ld_hidden=no
2145         ;;
2146     esac
2147   fi
2148 changequote([,])dnl
2149 fi])
2150 libgcc_visibility=no
2151 AC_SUBST(libgcc_visibility)
2152 GCC_TARGET_TEMPLATE([HAVE_GAS_HIDDEN])
2153 if test $gcc_cv_as_hidden = yes && test $gcc_cv_ld_hidden = yes; then
2154   libgcc_visibility=yes
2155   AC_DEFINE(HAVE_GAS_HIDDEN, 1,
2156   [Define if your assembler and linker support .hidden.])
2157 fi
2158
2159 AC_MSG_CHECKING(linker read-only and read-write section mixing)
2160 gcc_cv_ld_ro_rw_mix=unknown
2161 if test $in_tree_ld = yes ; then
2162   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 10 -o "$gcc_cv_gld_major_version" -gt 2 \
2163      && test $in_tree_ld_is_elf = yes; then
2164     gcc_cv_ld_ro_rw_mix=read-write
2165   fi
2166 elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x -a x$gcc_cv_objdump != x ; then
2167   echo '.section myfoosect, "a"' > conftest1.s
2168   echo '.section myfoosect, "aw"' > conftest2.s
2169   echo '.byte 1' >> conftest2.s
2170   echo '.section myfoosect, "a"' > conftest3.s
2171   echo '.byte 0' >> conftest3.s
2172   if $gcc_cv_as -o conftest1.o conftest1.s > /dev/null 2>&1 \
2173      && $gcc_cv_as -o conftest2.o conftest2.s > /dev/null 2>&1 \
2174      && $gcc_cv_as -o conftest3.o conftest3.s > /dev/null 2>&1 \
2175      && $gcc_cv_ld -shared -o conftest1.so conftest1.o \
2176         conftest2.o conftest3.o > /dev/null 2>&1; then
2177     gcc_cv_ld_ro_rw_mix=`$gcc_cv_objdump -h conftest1.so \
2178                          | sed -e '/myfoosect/!d' -e N`
2179     if echo "$gcc_cv_ld_ro_rw_mix" | grep CONTENTS > /dev/null; then
2180       if echo "$gcc_cv_ld_ro_rw_mix" | grep READONLY > /dev/null; then
2181         gcc_cv_ld_ro_rw_mix=read-only
2182       else
2183         gcc_cv_ld_ro_rw_mix=read-write
2184       fi
2185     fi
2186   fi
2187 changequote(,)dnl
2188   rm -f conftest.* conftest[123].*
2189 changequote([,])dnl
2190 fi
2191 if test x$gcc_cv_ld_ro_rw_mix = xread-write; then
2192         AC_DEFINE(HAVE_LD_RO_RW_SECTION_MIXING, 1,
2193   [Define if your linker links a mix of read-only
2194    and read-write sections into a read-write section.])
2195 fi
2196 AC_MSG_RESULT($gcc_cv_ld_ro_rw_mix)
2197
2198 # Check if we have .[us]leb128, and support symbol arithmetic with it.
2199 gcc_GAS_CHECK_FEATURE([.sleb128 and .uleb128], gcc_cv_as_leb128,
2200   [elf,2,11,0],,
2201 [       .data
2202         .uleb128 L2 - L1
2203 L1:
2204         .uleb128 1280
2205         .sleb128 -1010
2206 L2:],
2207  [# GAS versions before 2.11 do not support uleb128,
2208   # despite appearing to.
2209   # ??? There exists an elf-specific test that will crash
2210   # the assembler.  Perhaps it's better to figure out whether
2211   # arbitrary sections are supported and try the test.
2212   as_ver=`$gcc_cv_as --version 2>/dev/null | sed 1q`
2213   if echo "$as_ver" | grep GNU > /dev/null; then
2214 changequote(,)dnl
2215     as_vers=`echo $as_ver | sed -n \
2216         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*.*\)$,\1,p'`
2217     as_major=`expr "$as_vers" : '\([0-9]*\)'`
2218     as_minor=`expr "$as_vers" : '[0-9]*\.\([0-9]*\)'`
2219 changequote([,])dnl
2220     if test $as_major -eq 2 && test $as_minor -lt 11
2221     then :
2222     else gcc_cv_as_leb128=yes
2223     fi
2224   fi],
2225   [AC_DEFINE(HAVE_AS_LEB128, 1,
2226     [Define if your assembler supports .sleb128 and .uleb128.])])
2227
2228 # Check if we have assembler support for unwind directives.
2229 gcc_GAS_CHECK_FEATURE([cfi directives], gcc_cv_as_cfi_directive,
2230   ,,
2231 [       .text
2232         .cfi_startproc
2233         .cfi_offset 0, 0
2234         .cfi_same_value 1
2235         .cfi_def_cfa 1, 2
2236         .cfi_escape 1, 2, 3, 4, 5
2237         .cfi_endproc],
2238 [case "$target" in
2239   *-*-solaris*)
2240     # If the linker used on Solaris (like Sun ld) isn't capable of merging
2241     # read-only and read-write sections, we need to make sure that the
2242     # assembler used emits read-write .eh_frame sections.
2243     if test "x$gcc_cv_ld_ro_rw_mix" != xread-write; then
2244       if test "x$gcc_cv_objdump" != x; then
2245         if $gcc_cv_objdump -h conftest.o 2>/dev/null | \
2246                 sed -e /.eh_frame/!d -e N | grep READONLY > /dev/null; then
2247           gcc_cv_as_cfi_directive=no
2248         else
2249           gcc_cv_as_cfi_directive=yes
2250         fi
2251       else
2252         # no objdump, err on the side of caution
2253         gcc_cv_as_cfi_directive=no
2254       fi
2255     else
2256       gcc_cv_as_cfi_directive=yes
2257     fi
2258     ;;
2259   *-*-*)
2260     gcc_cv_as_cfi_directive=yes
2261     ;;
2262 esac])
2263 if test $gcc_cv_as_cfi_directive = yes && test x$gcc_cv_readelf != x; then
2264 gcc_GAS_CHECK_FEATURE([working cfi advance], gcc_cv_as_cfi_advance_working,
2265   ,,
2266 [       .text
2267         .cfi_startproc
2268         .cfi_adjust_cfa_offset 64
2269         .skip 512, 0
2270         .cfi_adjust_cfa_offset 128
2271         .cfi_endproc],
2272 [
2273 changequote(,)dnl
2274 if $gcc_cv_readelf -wf conftest.o 2>/dev/null \
2275     | grep 'DW_CFA_advance_loc[12]:[    ][      ]*512[  ]' >/dev/null; then
2276    gcc_cv_as_cfi_advance_working=yes
2277 fi
2278 changequote([,])dnl
2279 ])
2280 else
2281   gcc_cv_as_cfi_advance_working=yes
2282 fi
2283 AC_DEFINE_UNQUOTED(HAVE_GAS_CFI_DIRECTIVE,
2284   [`if test $gcc_cv_as_cfi_directive = yes \
2285        && test $gcc_cv_as_cfi_advance_working = yes; then echo 1; else echo 0; fi`],
2286   [Define 0/1 if your assembler supports CFI directives.])
2287
2288 gcc_GAS_CHECK_FEATURE([cfi personality directive],
2289   gcc_cv_as_cfi_personality_directive, ,,
2290 [       .text
2291         .cfi_startproc
2292         .cfi_personality 0, symbol
2293         .cfi_endproc])
2294 AC_DEFINE_UNQUOTED(HAVE_GAS_CFI_PERSONALITY_DIRECTIVE,
2295   [`if test $gcc_cv_as_cfi_personality_directive = yes;
2296     then echo 1; else echo 0; fi`],
2297   [Define 0/1 if your assembler supports .cfi_personality.])
2298
2299 # GAS versions up to and including 2.11.0 may mis-optimize
2300 # .eh_frame data.
2301 gcc_GAS_CHECK_FEATURE(eh_frame optimization, gcc_cv_as_eh_frame,
2302   [elf,2,12,0],,
2303 [       .text
2304 .LFB1:
2305         .4byte  0
2306 .L1:
2307         .4byte  0
2308 .LFE1:
2309         .section        .eh_frame,"aw",@progbits
2310 __FRAME_BEGIN__:
2311         .4byte  .LECIE1-.LSCIE1
2312 .LSCIE1:
2313         .4byte  0x0
2314         .byte   0x1
2315         .ascii "z\0"
2316         .byte   0x1
2317         .byte   0x78
2318         .byte   0x1a
2319         .byte   0x0
2320         .byte   0x4
2321         .4byte  1
2322         .p2align 1
2323 .LECIE1:
2324 .LSFDE1:
2325         .4byte  .LEFDE1-.LASFDE1
2326 .LASFDE1:
2327         .4byte  .LASFDE1-__FRAME_BEGIN__
2328         .4byte  .LFB1
2329         .4byte  .LFE1-.LFB1
2330         .byte   0x4
2331         .4byte  .LFE1-.LFB1
2332         .byte   0x4
2333         .4byte  .L1-.LFB1
2334 .LEFDE1:],
2335 [  dnl # For autoconf 2.5x, must protect trailing spaces with @&t@.
2336 cat > conftest.lit <<EOF
2337  0000 10000000 00000000 017a0001 781a0004  .........z..x...
2338  0010 01000000 12000000 18000000 00000000  ................
2339  0020 08000000 04080000 0044               .........D      @&t@
2340 EOF
2341 cat > conftest.big <<EOF
2342  0000 00000010 00000000 017a0001 781a0004  .........z..x...
2343  0010 00000001 00000012 00000018 00000000  ................
2344  0020 00000008 04000000 0844               .........D      @&t@
2345 EOF
2346   # If the assembler didn't choke, and we can objdump,
2347   # and we got the correct data, then succeed.
2348   # The text in the here-document typically retains its unix-style line
2349   # endings, while the output of objdump will use host line endings.
2350   # Therefore, use diff -b for the comparisons.
2351   if test x$gcc_cv_objdump != x \
2352   && $gcc_cv_objdump -s -j .eh_frame conftest.o 2>/dev/null \
2353      | tail -3 > conftest.got \
2354   && { diff -b conftest.lit conftest.got > /dev/null 2>&1 \
2355     || diff -b conftest.big conftest.got > /dev/null 2>&1; }
2356   then
2357     gcc_cv_as_eh_frame=yes
2358   elif AC_TRY_COMMAND($gcc_cv_as -o conftest.o --traditional-format /dev/null); then
2359     gcc_cv_as_eh_frame=buggy
2360   else
2361     # Uh oh, what do we do now?
2362     gcc_cv_as_eh_frame=no
2363   fi])
2364
2365 if test $gcc_cv_as_eh_frame = buggy; then
2366   AC_DEFINE(USE_AS_TRADITIONAL_FORMAT, 1,
2367   [Define if your assembler mis-optimizes .eh_frame data.])
2368 fi
2369
2370 gcc_GAS_CHECK_FEATURE(section merging support, gcc_cv_as_shf_merge,
2371  [elf,2,12,0], [--fatal-warnings],
2372  [.section .rodata.str, "aMS", @progbits, 1])
2373 if test $gcc_cv_as_shf_merge = no; then
2374   gcc_GAS_CHECK_FEATURE(section merging support, gcc_cv_as_shf_merge,
2375     [elf,2,12,0], [--fatal-warnings],
2376     [.section .rodata.str, "aMS", %progbits, 1])
2377 fi
2378 AC_DEFINE_UNQUOTED(HAVE_GAS_SHF_MERGE,
2379   [`if test $gcc_cv_as_shf_merge = yes; then echo 1; else echo 0; fi`],
2380 [Define 0/1 if your assembler supports marking sections with SHF_MERGE flag.])
2381
2382 gcc_GAS_CHECK_FEATURE(COMDAT group support, gcc_cv_as_comdat_group,
2383  [elf,2,16,0], [--fatal-warnings],
2384  [.section .text,"axG",@progbits,.foo,comdat])
2385 if test $gcc_cv_as_comdat_group = yes; then
2386   gcc_cv_as_comdat_group_percent=no
2387 else
2388  gcc_GAS_CHECK_FEATURE(COMDAT group support, gcc_cv_as_comdat_group_percent,
2389    [elf,2,16,0], [--fatal-warnings],
2390    [.section .text,"axG",%progbits,.foo,comdat])
2391 fi
2392 if test $in_tree_ld != yes && test x"$ld_vers" != x; then
2393   comdat_group=yes
2394   if test 0"$ld_date" -lt 20050308; then
2395     if test -n "$ld_date"; then
2396       # If there was date string, but was earlier than 2005-03-08, fail
2397       comdat_group=no
2398     elif test "$ld_vers_major" -lt 2; then
2399       comdat_group=no
2400     elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -lt 16; then
2401       comdat_group=no
2402     fi
2403   fi
2404 else
2405   # assume linkers other than GNU ld don't support COMDAT group
2406   comdat_group=no
2407 fi
2408 if test $comdat_group = no; then
2409   gcc_cv_as_comdat_group=no
2410   gcc_cv_as_comdat_group_percent=no
2411 fi
2412 AC_DEFINE_UNQUOTED(HAVE_COMDAT_GROUP,
2413   [`if test $gcc_cv_as_comdat_group = yes || test $gcc_cv_as_comdat_group_percent = yes; then echo 1; else echo 0; fi`],
2414 [Define 0/1 if your assembler and linker support COMDAT groups.])
2415
2416 # Thread-local storage - the check is heavily parameterized.
2417 conftest_s=
2418 tls_first_major=
2419 tls_first_minor=
2420 tls_as_opt=
2421 case "$target" in
2422 changequote(,)dnl
2423   alpha*-*-*)
2424     conftest_s='
2425         .section ".tdata","awT",@progbits
2426 foo:    .long   25
2427         .text
2428         ldq     $27,__tls_get_addr($29)         !literal!1
2429         lda     $16,foo($29)                    !tlsgd!1
2430         jsr     $26,($27),__tls_get_addr        !lituse_tlsgd!1
2431         ldq     $27,__tls_get_addr($29)         !literal!2
2432         lda     $16,foo($29)                    !tlsldm!2
2433         jsr     $26,($27),__tls_get_addr        !lituse_tlsldm!2
2434         ldq     $1,foo($29)                     !gotdtprel
2435         ldah    $2,foo($29)                     !dtprelhi
2436         lda     $3,foo($2)                      !dtprello
2437         lda     $4,foo($29)                     !dtprel
2438         ldq     $1,foo($29)                     !gottprel
2439         ldah    $2,foo($29)                     !tprelhi
2440         lda     $3,foo($2)                      !tprello
2441         lda     $4,foo($29)                     !tprel'
2442         tls_first_major=2
2443         tls_first_minor=13
2444         tls_as_opt=--fatal-warnings
2445         ;;
2446   frv*-*-*)
2447     conftest_s='
2448         .section ".tdata","awT",@progbits
2449 x:      .long   25
2450         .text
2451         call    #gettlsoff(x)'
2452         tls_first_major=2
2453         tls_first_minor=14
2454         ;;
2455   hppa*-*-linux*)
2456     conftest_s='
2457 t1:     .reg    %r20
2458 t2:     .reg    %r21
2459 gp:     .reg    %r19
2460         .section ".tdata","awT",@progbits
2461 foo:    .long   25
2462         .text
2463         .align  4
2464         addil LT%foo-$tls_gdidx$,gp
2465         ldo RT%foo-$tls_gdidx$(%r1),%arg0
2466         b __tls_get_addr
2467         nop
2468         addil LT%foo-$tls_ldidx$,gp
2469         b __tls_get_addr
2470         ldo RT%foo-$tls_ldidx$(%r1),%arg0
2471         addil LR%foo-$tls_dtpoff$,%ret0
2472         ldo RR%foo-$tls_dtpoff$(%r1),%t1
2473         mfctl %cr27,%t1
2474         addil LT%foo-$tls_ieoff$,gp
2475         ldw RT%foo-$tls_ieoff$(%r1),%t2
2476         add %t1,%t2,%t3
2477         mfctl %cr27,%t1
2478         addil LR%foo-$tls_leoff$,%t1
2479         ldo RR%foo-$tls_leoff$(%r1),%t2'
2480         tls_first_major=2
2481         tls_first_minor=15
2482         tls_as_opt=--fatal-warnings
2483         ;;
2484   arm*-*-*)
2485     conftest_s='
2486         .section ".tdata","awT",%progbits
2487 foo:    .long   25
2488         .text
2489 .word foo(gottpoff)
2490 .word foo(tpoff)
2491 .word foo(tlsgd)
2492 .word foo(tlsldm)
2493 .word foo(tlsldo)'
2494         tls_first_major=2
2495         tls_first_minor=17
2496         ;;
2497   i[34567]86-*-*)
2498     conftest_s='
2499         .section ".tdata","awT",@progbits
2500 foo:    .long   25
2501         .text
2502         movl    %gs:0, %eax
2503         leal    foo@TLSGD(,%ebx,1), %eax
2504         leal    foo@TLSLDM(%ebx), %eax
2505         leal    foo@DTPOFF(%eax), %edx
2506         movl    foo@GOTTPOFF(%ebx), %eax
2507         subl    foo@GOTTPOFF(%ebx), %eax
2508         addl    foo@GOTNTPOFF(%ebx), %eax
2509         movl    foo@INDNTPOFF, %eax
2510         movl    $foo@TPOFF, %eax
2511         subl    $foo@TPOFF, %eax
2512         leal    foo@NTPOFF(%ecx), %eax'
2513         tls_first_major=2
2514         tls_first_minor=14
2515         tls_as_opt=--fatal-warnings
2516         ;;
2517   x86_64-*-*)
2518     conftest_s='
2519         .section ".tdata","awT",@progbits
2520 foo:    .long   25
2521         .text
2522         movq    %fs:0, %rax
2523         leaq    foo@TLSGD(%rip), %rdi
2524         leaq    foo@TLSLD(%rip), %rdi
2525         leaq    foo@DTPOFF(%rax), %rdx
2526         movq    foo@GOTTPOFF(%rip), %rax
2527         movq    $foo@TPOFF, %rax'
2528         tls_first_major=2
2529         tls_first_minor=14
2530         tls_as_opt=--fatal-warnings
2531         ;;
2532   ia64-*-*)
2533     conftest_s='
2534         .section ".tdata","awT",@progbits
2535 foo:    data8   25
2536         .text
2537         addl    r16 = @ltoff(@dtpmod(foo#)), gp
2538         addl    r17 = @ltoff(@dtprel(foo#)), gp
2539         addl    r18 = @ltoff(@tprel(foo#)), gp
2540         addl    r19 = @dtprel(foo#), gp
2541         adds    r21 = @dtprel(foo#), r13
2542         movl    r23 = @dtprel(foo#)
2543         addl    r20 = @tprel(foo#), gp
2544         adds    r22 = @tprel(foo#), r13
2545         movl    r24 = @tprel(foo#)'
2546         tls_first_major=2
2547         tls_first_minor=13
2548         tls_as_opt=--fatal-warnings
2549         ;;
2550   mips*-*-*)
2551     conftest_s='
2552         .section .tdata,"awT",@progbits
2553 x:
2554         .word 2
2555         .text
2556         addiu $4, $28, %tlsgd(x)
2557         addiu $4, $28, %tlsldm(x)
2558         lui $4, %dtprel_hi(x)
2559         addiu $4, $4, %dtprel_lo(x)
2560         lw $4, %gottprel(x)($28)
2561         lui $4, %tprel_hi(x)
2562         addiu $4, $4, %tprel_lo(x)'
2563         tls_first_major=2
2564         tls_first_minor=16
2565         tls_as_opt='-32 --fatal-warnings'
2566         ;;
2567   powerpc-*-*)
2568     conftest_s='
2569         .section ".tdata","awT",@progbits
2570         .align 2
2571 ld0:    .space 4
2572 ld1:    .space 4
2573 x1:     .space 4
2574 x2:     .space 4
2575 x3:     .space 4
2576         .text
2577         addi 3,31,ld0@got@tlsgd
2578         bl __tls_get_addr
2579         addi 3,31,x1@got@tlsld
2580         bl __tls_get_addr
2581         addi 9,3,x1@dtprel
2582         addis 9,3,x2@dtprel@ha
2583         addi 9,9,x2@dtprel@l
2584         lwz 9,x3@got@tprel(31)
2585         add 9,9,x@tls
2586         addi 9,2,x1@tprel
2587         addis 9,2,x2@tprel@ha
2588         addi 9,9,x2@tprel@l'
2589         tls_first_major=2
2590         tls_first_minor=14
2591         tls_as_opt="-a32 --fatal-warnings"
2592         ;;
2593   powerpc64-*-*)
2594     conftest_s='
2595         .section ".tdata","awT",@progbits
2596         .align 3
2597 ld0:    .space 8
2598 ld1:    .space 8
2599 x1:     .space 8
2600 x2:     .space 8
2601 x3:     .space 8
2602         .text
2603         addi 3,2,ld0@got@tlsgd
2604         bl .__tls_get_addr
2605         nop
2606         addi 3,2,ld1@toc
2607         bl .__tls_get_addr
2608         nop
2609         addi 3,2,x1@got@tlsld
2610         bl .__tls_get_addr
2611         nop
2612         addi 9,3,x1@dtprel
2613         bl .__tls_get_addr
2614         nop
2615         addis 9,3,x2@dtprel@ha
2616         addi 9,9,x2@dtprel@l
2617         bl .__tls_get_addr
2618         nop
2619         ld 9,x3@got@dtprel(2)
2620         add 9,9,3
2621         bl .__tls_get_addr
2622         nop'
2623         tls_first_major=2
2624         tls_first_minor=14
2625         tls_as_opt="-a64 --fatal-warnings"
2626         ;;
2627   s390-*-*)
2628     conftest_s='
2629         .section ".tdata","awT",@progbits
2630 foo:    .long   25
2631         .text
2632         .long   foo@TLSGD
2633         .long   foo@TLSLDM
2634         .long   foo@DTPOFF
2635         .long   foo@NTPOFF
2636         .long   foo@GOTNTPOFF
2637         .long   foo@INDNTPOFF
2638         l       %r1,foo@GOTNTPOFF(%r12)
2639         l       %r1,0(%r1):tls_load:foo
2640         bas     %r14,0(%r1,%r13):tls_gdcall:foo
2641         bas     %r14,0(%r1,%r13):tls_ldcall:foo'
2642         tls_first_major=2
2643         tls_first_minor=14
2644         tls_as_opt="-m31 --fatal-warnings"
2645         ;;
2646   s390x-*-*)
2647     conftest_s='
2648         .section ".tdata","awT",@progbits
2649 foo:    .long   25
2650         .text
2651         .quad   foo@TLSGD
2652         .quad   foo@TLSLDM
2653         .quad   foo@DTPOFF
2654         .quad   foo@NTPOFF
2655         .quad   foo@GOTNTPOFF
2656         lg      %r1,foo@GOTNTPOFF(%r12)
2657         larl    %r1,foo@INDNTPOFF
2658         brasl   %r14,__tls_get_offset@PLT:tls_gdcall:foo
2659         brasl   %r14,__tls_get_offset@PLT:tls_ldcall:foo'
2660         tls_first_major=2
2661         tls_first_minor=14
2662         tls_as_opt="-m64 -Aesame --fatal-warnings"
2663         ;;
2664   sh-*-* | sh[34]-*-*)
2665     conftest_s='
2666         .section ".tdata","awT",@progbits
2667 foo:    .long   25
2668         .text
2669         .long   foo@TLSGD
2670         .long   foo@TLSLDM
2671         .long   foo@DTPOFF
2672         .long   foo@GOTTPOFF
2673         .long   foo@TPOFF'
2674         tls_first_major=2
2675         tls_first_minor=13
2676         tls_as_opt=--fatal-warnings
2677         ;;
2678   sparc*-*-*)
2679     case "$target" in
2680       sparc*-sun-solaris2.[56789]*)
2681         # TLS was introduced in the Solaris 9 4/04 release but
2682         # we do not enable it by default on Solaris 9 either.
2683         if test "x$enable_tls" = xyes ; then
2684           on_solaris=yes
2685         else
2686           enable_tls=no;
2687         fi
2688         ;;
2689       sparc*-sun-solaris2.*)
2690         on_solaris=yes
2691         ;;
2692       *)
2693         on_solaris=no
2694         ;;
2695     esac
2696     if test x$on_solaris = xyes && test x$gas_flag = xno; then
2697       conftest_s='
2698         .section ".tdata",#alloc,#write,#tls
2699 foo:    .long   25
2700         .text
2701         sethi   %tgd_hi22(foo), %o0
2702         add     %o0, %tgd_lo10(foo), %o1
2703         add     %l7, %o1, %o0, %tgd_add(foo)
2704         call    __tls_get_addr, %tgd_call(foo)
2705         sethi   %tldm_hi22(foo), %l1
2706         add     %l1, %tldm_lo10(foo), %l2
2707         add     %l7, %l2, %o0, %tldm_add(foo)
2708         call    __tls_get_addr, %tldm_call(foo)
2709         sethi   %tldo_hix22(foo), %l3
2710         xor     %l3, %tldo_lox10(foo), %l4
2711         add     %o0, %l4, %l5, %tldo_add(foo)
2712         sethi   %tie_hi22(foo), %o3
2713         add     %o3, %tie_lo10(foo), %o3
2714         ld      [%l7 + %o3], %o2, %tie_ld(foo)
2715         add     %g7, %o2, %o4, %tie_add(foo)
2716         sethi   %tle_hix22(foo), %l1
2717         xor     %l1, %tle_lox10(foo), %o5
2718         ld      [%g7 + %o5], %o1'
2719         tls_first_major=0
2720         tls_first_minor=0
2721     else
2722       conftest_s='
2723         .section ".tdata","awT",@progbits
2724 foo:    .long   25
2725         .text
2726         sethi   %tgd_hi22(foo), %o0
2727         add     %o0, %tgd_lo10(foo), %o1
2728         add     %l7, %o1, %o0, %tgd_add(foo)
2729         call    __tls_get_addr, %tgd_call(foo)
2730         sethi   %tldm_hi22(foo), %l1
2731         add     %l1, %tldm_lo10(foo), %l2
2732         add     %l7, %l2, %o0, %tldm_add(foo)
2733         call    __tls_get_addr, %tldm_call(foo)
2734         sethi   %tldo_hix22(foo), %l3
2735         xor     %l3, %tldo_lox10(foo), %l4
2736         add     %o0, %l4, %l5, %tldo_add(foo)
2737         sethi   %tie_hi22(foo), %o3
2738         add     %o3, %tie_lo10(foo), %o3
2739         ld      [%l7 + %o3], %o2, %tie_ld(foo)
2740         add     %g7, %o2, %o4, %tie_add(foo)
2741         sethi   %tle_hix22(foo), %l1
2742         xor     %l1, %tle_lox10(foo), %o5
2743         ld      [%g7 + %o5], %o1'
2744         tls_first_major=2
2745         tls_first_minor=14
2746         tls_as_opt="-32 --fatal-warnings"
2747       fi
2748         ;;
2749   xtensa*-*-*)
2750     conftest_s='
2751         .section ".tdata","awT",@progbits
2752 foo:    .long   25
2753         .text
2754         movi    a8, foo@TLSFUNC
2755         movi    a10, foo@TLSARG
2756         callx8.tls a8, foo@TLSCALL'
2757         tls_first_major=2
2758         tls_first_minor=19
2759         ;;
2760 changequote([,])dnl
2761 esac
2762 set_have_as_tls=no
2763 if test "x$enable_tls" = xno ; then
2764   : # TLS explicitly disabled.
2765 elif test "x$enable_tls" = xyes ; then
2766   set_have_as_tls=yes # TLS explicitly enabled.
2767 elif test -z "$tls_first_major"; then
2768   : # If we don't have a check, assume no support.
2769 else
2770   gcc_GAS_CHECK_FEATURE(thread-local storage support, gcc_cv_as_tls,
2771   [$tls_first_major,$tls_first_minor,0], [$tls_as_opt], [$conftest_s],,
2772   [set_have_as_tls=yes])
2773 fi
2774 if test $set_have_as_tls = yes ; then
2775   AC_DEFINE(HAVE_AS_TLS, 1,
2776             [Define if your assembler supports thread-local storage.])
2777 fi
2778
2779 # Target-specific assembler checks.
2780
2781 AC_MSG_CHECKING(linker -Bstatic/-Bdynamic option)
2782 gcc_cv_ld_static_dynamic=no
2783 if test $in_tree_ld = yes ; then
2784   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 10; then
2785     gcc_cv_ld_static_dynamic=yes
2786   fi
2787 elif test x$gcc_cv_ld != x; then
2788         # Check if linker supports -Bstatic/-Bdynamic option
2789         if $gcc_cv_ld --help 2>/dev/null | grep -- -Bstatic > /dev/null \
2790           && $gcc_cv_ld --help 2>/dev/null | grep -- -Bdynamic > /dev/null; then
2791                 gcc_cv_ld_static_dynamic=yes
2792         fi
2793 fi
2794 if test x"$gcc_cv_ld_static_dynamic" = xyes; then
2795         AC_DEFINE(HAVE_LD_STATIC_DYNAMIC, 1,
2796 [Define if your linker supports -Bstatic/-Bdynamic option.])
2797 fi
2798 AC_MSG_RESULT($gcc_cv_ld_static_dynamic)
2799
2800 if test x"$demangler_in_ld" = xyes; then
2801   AC_MSG_CHECKING(linker --demangle support)
2802   gcc_cv_ld_demangle=no
2803   if test $in_tree_ld = yes; then
2804     if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 14 -o "$gcc_cv_gld_major_version" -gt 2; then \
2805       gcc_cv_ld_demangle=yes
2806     fi
2807   elif test x$gcc_cv_ld != x -a x"$gnu_ld" = xyes; then
2808     # Check if the GNU linker supports --demangle option
2809     if $gcc_cv_ld --help 2>/dev/null | grep no-demangle > /dev/null; then
2810       gcc_cv_ld_demangle=yes
2811     fi
2812   fi
2813   if test x"$gcc_cv_ld_demangle" = xyes; then
2814     AC_DEFINE(HAVE_LD_DEMANGLE, 1,
2815 [Define if your linker supports --demangle option.])
2816   fi
2817   AC_MSG_RESULT($gcc_cv_ld_demangle)
2818 fi
2819
2820 case "$target" in
2821   # All TARGET_ABI_OSF targets.
2822   alpha*-*-osf* | alpha*-*-linux* | alpha*-*-*bsd*)
2823     gcc_GAS_CHECK_FEATURE([explicit relocation support],
2824         gcc_cv_as_alpha_explicit_relocs, [2,12,0],,
2825 [       .set nomacro
2826         .text
2827         extbl   $3, $2, $3      !lituse_bytoff!1
2828         ldq     $2, a($29)      !literal!1
2829         ldq     $4, b($29)      !literal!2
2830         ldq_u   $3, 0($2)       !lituse_base!1
2831         ldq     $27, f($29)     !literal!5
2832         jsr     $26, ($27), f   !lituse_jsr!5
2833         ldah    $29, 0($26)     !gpdisp!3
2834         lda     $0, c($29)      !gprel
2835         ldah    $1, d($29)      !gprelhigh
2836         lda     $1, d($1)       !gprellow
2837         lda     $29, 0($29)     !gpdisp!3],,
2838     [AC_DEFINE(HAVE_AS_EXPLICIT_RELOCS, 1,
2839   [Define if your assembler supports explicit relocations.])])
2840     gcc_GAS_CHECK_FEATURE([jsrdirect relocation support],
2841         gcc_cv_as_alpha_jsrdirect_relocs, [2,16,90],,
2842 [       .set nomacro
2843         .text
2844         ldq     $27, a($29)     !literal!1
2845         jsr     $26, ($27), a   !lituse_jsrdirect!1],,
2846     [AC_DEFINE(HAVE_AS_JSRDIRECT_RELOCS, 1,
2847   [Define if your assembler supports the lituse_jsrdirect relocation.])])
2848     ;;
2849
2850   cris-*-*)
2851     gcc_GAS_CHECK_FEATURE([-no-mul-bug-abort option],
2852       gcc_cv_as_cris_no_mul_bug,[2,15,91],
2853       [-no-mul-bug-abort], [.text],,
2854       [AC_DEFINE(HAVE_AS_NO_MUL_BUG_ABORT_OPTION, 1,
2855                 [Define if your assembler supports the -no-mul-bug-abort option.])])
2856     ;;
2857
2858   sparc*-*-*)
2859     gcc_GAS_CHECK_FEATURE([.register], gcc_cv_as_sparc_register_op,,,
2860       [.register %g2, #scratch],,
2861       [AC_DEFINE(HAVE_AS_REGISTER_PSEUDO_OP, 1,
2862                 [Define if your assembler supports .register.])])
2863
2864     gcc_GAS_CHECK_FEATURE([-relax option], gcc_cv_as_sparc_relax,,
2865       [-relax], [.text],,
2866       [AC_DEFINE(HAVE_AS_RELAX_OPTION, 1,
2867                 [Define if your assembler supports -relax option.])])
2868
2869     gcc_GAS_CHECK_FEATURE([unaligned pcrel relocs],
2870       gcc_cv_as_sparc_ua_pcrel,,
2871       [-K PIC],
2872 [.text
2873 foo:
2874         nop
2875 .data
2876 .align 4
2877 .byte 0
2878 .uaword %r_disp32(foo)],
2879       [if test x$gcc_cv_ld != x \
2880        && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1; then
2881          gcc_cv_as_sparc_ua_pcrel=yes
2882        fi
2883        rm -f conftest],
2884       [AC_DEFINE(HAVE_AS_SPARC_UA_PCREL, 1,
2885                 [Define if your assembler and linker support unaligned PC relative relocs.])
2886
2887       gcc_GAS_CHECK_FEATURE([unaligned pcrel relocs against hidden symbols],
2888         gcc_cv_as_sparc_ua_pcrel_hidden,,
2889         [-K PIC],
2890 [.data
2891 .align 4
2892 .byte 0x31
2893 .uaword %r_disp32(foo)
2894 .byte 0x32, 0x33, 0x34
2895 .global foo
2896 .hidden foo
2897 foo:
2898 .skip 4],
2899         [if test x$gcc_cv_ld != x && test x$gcc_cv_objdump != x \
2900          && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1 \
2901          && $gcc_cv_objdump -s -j .data conftest 2> /dev/null \
2902             | grep ' 31000000 07323334' > /dev/null 2>&1; then
2903             if $gcc_cv_objdump -R conftest 2> /dev/null \
2904                | grep 'DISP32' > /dev/null 2>&1; then
2905                 :
2906             else
2907                 gcc_cv_as_sparc_ua_pcrel_hidden=yes
2908             fi
2909          fi
2910          rm -f conftest],
2911          [AC_DEFINE(HAVE_AS_SPARC_UA_PCREL_HIDDEN, 1,
2912                    [Define if your assembler and linker support unaligned PC relative relocs against hidden symbols.])])
2913     ]) # unaligned pcrel relocs
2914
2915     gcc_GAS_CHECK_FEATURE([offsetable %lo()],
2916       gcc_cv_as_sparc_offsetable_lo10,,
2917       [-xarch=v9],
2918 [.text
2919         or %g1, %lo(ab) + 12, %g1
2920         or %g1, %lo(ab + 12), %g1],
2921       [if test x$gcc_cv_objdump != x \
2922        && $gcc_cv_objdump -s -j .text conftest.o 2> /dev/null \
2923           | grep ' 82106000 82106000' > /dev/null 2>&1; then
2924          gcc_cv_as_sparc_offsetable_lo10=yes
2925        fi],
2926        [AC_DEFINE(HAVE_AS_OFFSETABLE_LO10, 1,
2927                  [Define if your assembler supports offsetable %lo().])])
2928     ;;
2929
2930 changequote(,)dnl
2931   i[34567]86-*-* | x86_64-*-*)
2932 changequote([,])dnl
2933     case $target_os in
2934       cygwin* | pe | mingw32*)
2935         # Used for DWARF 2 in PE
2936         gcc_GAS_CHECK_FEATURE([.secrel32 relocs],
2937           gcc_cv_as_ix86_pe_secrel32,
2938           [2,15,91],,
2939 [.text
2940 foo:    nop
2941 .data
2942         .secrel32 foo],
2943           [if test x$gcc_cv_ld != x \
2944            && $gcc_cv_ld -o conftest conftest.o > /dev/null 2>&1; then
2945              gcc_cv_as_ix86_pe_secrel32=yes
2946            fi
2947            rm -f conftest],
2948           [AC_DEFINE(HAVE_GAS_PE_SECREL32_RELOC, 1,
2949             [Define if your assembler and linker support 32-bit section relative relocs via '.secrel32 label'.])])
2950         ;;
2951     esac
2952
2953     gcc_GAS_CHECK_FEATURE([filds and fists mnemonics],
2954        gcc_cv_as_ix86_filds_fists,
2955       [2,9,0],, [filds mem; fists mem],,
2956       [AC_DEFINE(HAVE_GAS_FILDS_FISTS, 1,
2957         [Define if your assembler uses the new HImode fild and fist notation.])])
2958
2959     gcc_GAS_CHECK_FEATURE([cmov syntax],
2960       gcc_cv_as_ix86_cmov_sun_syntax,,,
2961       [cmovl.l %edx, %eax],,
2962       [AC_DEFINE(HAVE_AS_IX86_CMOV_SUN_SYNTAX, 1,
2963         [Define if your assembler supports the Sun syntax for cmov.])])
2964
2965     gcc_GAS_CHECK_FEATURE([ffreep mnemonic],
2966       gcc_cv_as_ix86_ffreep,,,
2967       [ffreep %st(1)],,
2968       [AC_DEFINE(HAVE_AS_IX86_FFREEP, 1,
2969         [Define if your assembler supports the ffreep mnemonic.])])
2970
2971     gcc_GAS_CHECK_FEATURE([sahf mnemonic],
2972       gcc_cv_as_ix86_sahf,,,
2973       [sahf],,
2974       [AC_DEFINE(HAVE_AS_IX86_SAHF, 1,
2975         [Define if your assembler supports the sahf mnemonic.])])
2976
2977     gcc_GAS_CHECK_FEATURE([different section symbol subtraction],
2978       gcc_cv_as_ix86_diff_sect_delta,,,
2979       [.section .rodata
2980 .L1:
2981         .long .L2-.L1
2982         .long .L3-.L1
2983         .text
2984 .L3:    nop
2985 .L2:    nop],,
2986       [AC_DEFINE(HAVE_AS_IX86_DIFF_SECT_DELTA, 1,
2987         [Define if your assembler supports the subtraction of symbols in different sections.])])
2988
2989     # This one is used unconditionally by i386.[ch]; it is to be defined
2990     # to 1 if the feature is present, 0 otherwise.
2991     gcc_GAS_CHECK_FEATURE([GOTOFF in data],
2992         gcc_cv_as_ix86_gotoff_in_data, [2,11,0],,
2993 [       .text
2994 .L0:
2995         nop
2996         .data
2997         .long .L0@GOTOFF])
2998     AC_DEFINE_UNQUOTED(HAVE_AS_GOTOFF_IN_DATA,
2999       [`if test $gcc_cv_as_ix86_gotoff_in_data = yes; then echo 1; else echo 0; fi`],
3000       [Define true if the assembler supports '.long foo@GOTOFF'.])
3001     ;;
3002
3003   ia64*-*-*)
3004     gcc_GAS_CHECK_FEATURE([ltoffx and ldxmov relocs],
3005         gcc_cv_as_ia64_ltoffx_ldxmov_relocs, [2,14,0],,
3006 [       .text
3007         addl r15 = @ltoffx(x#), gp
3008         ;;
3009         ld8.mov r16 = [[r15]], x#],,
3010     [AC_DEFINE(HAVE_AS_LTOFFX_LDXMOV_RELOCS, 1,
3011           [Define if your assembler supports ltoffx and ldxmov relocations.])])
3012
3013     ;;
3014
3015   powerpc*-*-*)
3016     case $target in
3017       *-*-aix*) conftest_s='    .machine "pwr5"
3018         .csect .text[[PR]]
3019         mfcr 3,128';;
3020       *-*-darwin*)
3021         gcc_GAS_CHECK_FEATURE([.machine directive support],
3022           gcc_cv_as_machine_directive,,,
3023           [     .machine ppc7400])
3024         if test x$gcc_cv_as_machine_directive != xyes; then
3025           echo "*** This target requires an assembler supporting \".machine\"" >&2
3026           echo you can get it from: ftp://gcc.gnu.org/pub/gcc/infrastructure/cctools-528.5.dmg >&2
3027           test x$build = x$target && exit 1
3028         fi
3029         conftest_s='    .text
3030         mfcr r3,128';;
3031       *) conftest_s='   .machine power4
3032         .text
3033         mfcr 3,128';;
3034     esac
3035
3036     gcc_GAS_CHECK_FEATURE([mfcr field support],
3037       gcc_cv_as_powerpc_mfcrf, [2,14,0],,
3038       [$conftest_s],,
3039       [AC_DEFINE(HAVE_AS_MFCRF, 1,
3040           [Define if your assembler supports mfcr field.])])
3041
3042     case $target in
3043       *-*-aix*) conftest_s='    .machine "pwr5"
3044         .csect .text[[PR]]
3045         popcntb 3,3';;
3046       *) conftest_s='   .machine power5
3047         .text
3048         popcntb 3,3';;
3049     esac
3050
3051     gcc_GAS_CHECK_FEATURE([popcntb support],
3052       gcc_cv_as_powerpc_popcntb, [2,17,0],,
3053       [$conftest_s],,
3054       [AC_DEFINE(HAVE_AS_POPCNTB, 1,
3055           [Define if your assembler supports popcntb field.])])
3056
3057     case $target in
3058       *-*-aix*) conftest_s='    .machine "pwr5x"
3059         .csect .text[[PR]]
3060         frin 1,1';;
3061       *) conftest_s='   .machine power5
3062         .text
3063         frin 1,1';;
3064     esac
3065
3066     gcc_GAS_CHECK_FEATURE([fp round support],
3067       gcc_cv_as_powerpc_fprnd, [2,17,0],,
3068       [$conftest_s],,
3069       [AC_DEFINE(HAVE_AS_FPRND, 1,
3070           [Define if your assembler supports fprnd.])])
3071
3072     case $target in
3073       *-*-aix*) conftest_s='    .machine "pwr6"
3074         .csect .text[[PR]]
3075         mffgpr 1,3';;
3076       *) conftest_s='   .machine power6
3077         .text
3078         mffgpr 1,3';;
3079     esac
3080
3081     gcc_GAS_CHECK_FEATURE([move fp gpr support],
3082       gcc_cv_as_powerpc_mfpgpr, [9,99,0],,
3083       [$conftest_s],,
3084       [AC_DEFINE(HAVE_AS_MFPGPR, 1,
3085           [Define if your assembler supports mffgpr and mftgpr.])])
3086
3087     case $target in
3088       *-*-aix*) conftest_s='    .csect .text[[PR]]
3089 LCF..0:
3090         addis 11,30,_GLOBAL_OFFSET_TABLE_-LCF..0@ha';;
3091       *-*-darwin*)
3092         conftest_s='    .text
3093 LCF0:
3094         addis r11,r30,_GLOBAL_OFFSET_TABLE_-LCF0@ha';;
3095       *) conftest_s='   .text
3096 .LCF0:
3097         addis 11,30,_GLOBAL_OFFSET_TABLE_-.LCF0@ha';;
3098     esac
3099
3100     gcc_GAS_CHECK_FEATURE([rel16 relocs],
3101       gcc_cv_as_powerpc_rel16, [2,17,0], -a32,
3102       [$conftest_s],,
3103       [AC_DEFINE(HAVE_AS_REL16, 1,
3104           [Define if your assembler supports R_PPC_REL16 relocs.])])
3105
3106     case $target in
3107       *-*-aix*) conftest_s='    .machine "pwr6"
3108         .csect .text[[PR]]
3109         cmpb 3,4,5';;
3110       *) conftest_s='   .machine power6
3111         .text
3112         cmpb 3,4,5';;
3113     esac
3114
3115     gcc_GAS_CHECK_FEATURE([compare bytes support],
3116       gcc_cv_as_powerpc_cmpb, [9,99,0], -a32,
3117       [$conftest_s],,
3118       [AC_DEFINE(HAVE_AS_CMPB, 1,
3119           [Define if your assembler supports cmpb.])])
3120
3121     case $target in
3122       *-*-aix*) conftest_s='    .machine "pwr6"
3123         .csect .text[[PR]]
3124         dadd 1,2,3';;
3125       *) conftest_s='   .machine power6
3126         .text
3127         dadd 1,2,3';;
3128     esac
3129
3130     gcc_GAS_CHECK_FEATURE([decimal float support],
3131       gcc_cv_as_powerpc_dfp, [9,99,0], -a32,
3132       [$conftest_s],,
3133       [AC_DEFINE(HAVE_AS_DFP, 1,
3134           [Define if your assembler supports DFP instructions.])])
3135
3136     case $target in
3137       *-*-aix*) conftest_s='    .machine "pwr7"
3138         .csect .text[[PR]]
3139         lxvd2x 1,2,3';;
3140       *) conftest_s='   .machine power7
3141         .text
3142         lxvd2x 1,2,3';;
3143     esac
3144
3145     gcc_GAS_CHECK_FEATURE([vector-scalar support],
3146       gcc_cv_as_powerpc_vsx, [9,99,0], -a32,
3147       [$conftest_s],,
3148       [AC_DEFINE(HAVE_AS_VSX, 1,
3149           [Define if your assembler supports VSX instructions.])])
3150
3151     gcc_GAS_CHECK_FEATURE([.gnu_attribute support],
3152       gcc_cv_as_powerpc_gnu_attribute, [2,18,0],,
3153       [.gnu_attribute 4,1],,
3154       [AC_DEFINE(HAVE_AS_GNU_ATTRIBUTE, 1,
3155           [Define if your assembler supports .gnu_attribute.])])
3156     ;;
3157
3158   mips*-*-*)
3159     gcc_GAS_CHECK_FEATURE([explicit relocation support],
3160       gcc_cv_as_mips_explicit_relocs, [2,14,0],,
3161 [       lw $4,%gp_rel(foo)($4)],,
3162       [if test x$target_cpu_default = x
3163        then target_cpu_default=MASK_EXPLICIT_RELOCS
3164        else target_cpu_default="($target_cpu_default)|MASK_EXPLICIT_RELOCS"
3165        fi])
3166     gcc_GAS_CHECK_FEATURE([-mno-shared support],
3167       gcc_cv_as_mips_no_shared, [2,16,0], [-mno-shared], [nop],,
3168       [AC_DEFINE(HAVE_AS_NO_SHARED, 1,
3169                  [Define if the assembler understands -mno-shared.])])
3170
3171     gcc_GAS_CHECK_FEATURE([.gnu_attribute support],
3172       gcc_cv_as_mips_gnu_attribute, [2,18,0],,
3173       [.gnu_attribute 4,1],,
3174       [AC_DEFINE(HAVE_AS_GNU_ATTRIBUTE, 1,
3175           [Define if your assembler supports .gnu_attribute.])])
3176
3177     gcc_GAS_CHECK_FEATURE([.dtprelword support],
3178       gcc_cv_as_mips_dtprelword, [2,18,0],,
3179       [.section .tdata,"awT",@progbits
3180 x:
3181         .word 2
3182         .text
3183         .dtprelword x+0x8000],,
3184       [AC_DEFINE(HAVE_AS_DTPRELWORD, 1,
3185           [Define if your assembler supports .dtprelword.])])
3186     ;;
3187 esac
3188
3189 # Mips and HP-UX need the GNU assembler.
3190 # Linux on IA64 might be able to use the Intel assembler.
3191
3192 case "$target" in
3193   mips*-*-* | *-*-hpux* )
3194     if test x$gas_flag = xyes \
3195        || test x"$host" != x"$build" \
3196        || test ! -x "$gcc_cv_as" \
3197        || "$gcc_cv_as" -v < /dev/null 2>&1 | grep GNU > /dev/null; then
3198       :
3199     else
3200       echo "*** This configuration requires the GNU assembler" >&2
3201       exit 1
3202     fi
3203     ;;
3204 esac
3205
3206 # ??? Not all targets support dwarf2 debug_line, even within a version
3207 # of gas.  Moreover, we need to emit a valid instruction to trigger any
3208 # info to the output file.  So, as supported targets are added to gas 2.11,
3209 # add some instruction here to (also) show we expect this might work.
3210 # ??? Once 2.11 is released, probably need to add first known working
3211 # version to the per-target configury.
3212 case "$target" in
3213   i?86*-*-* | mips*-*-* | alpha*-*-* | powerpc*-*-* | sparc*-*-* | m68*-*-* \
3214   | x86_64*-*-* | hppa*-*-* | arm*-*-* \
3215   | xstormy16*-*-* | cris-*-* | xtensa*-*-* | bfin-*-* | score*-*-* \
3216   | spu-*-* | fido*-*-* | m32c-*-*)
3217     insn="nop"
3218     ;;
3219   ia64*-*-* | s390*-*-*)
3220     insn="nop 0"
3221     ;;
3222   mmix-*-*)
3223     insn="swym 0"
3224     ;;
3225 esac
3226 if test x"$insn" != x; then
3227  conftest_s="\
3228         .file 1 \"conftest.s\"
3229         .loc 1 3 0
3230         $insn"
3231  gcc_GAS_CHECK_FEATURE([dwarf2 debug_line support],
3232   gcc_cv_as_dwarf2_debug_line,
3233   [elf,2,11,0],, [$conftest_s],
3234   [if test x$gcc_cv_objdump != x \
3235    && $gcc_cv_objdump -h conftest.o 2> /dev/null \
3236       | grep debug_line > /dev/null 2>&1; then
3237      gcc_cv_as_dwarf2_debug_line=yes
3238    fi])
3239
3240 # The .debug_line file table must be in the exact order that
3241 # we specified the files, since these indices are also used
3242 # by DW_AT_decl_file.  Approximate this test by testing if
3243 # the assembler bitches if the same index is assigned twice.
3244  gcc_GAS_CHECK_FEATURE([buggy dwarf2 .file directive],
3245   gcc_cv_as_dwarf2_file_buggy,,,
3246 [       .file 1 "foo.s"
3247         .file 1 "bar.s"])
3248
3249  if test $gcc_cv_as_dwarf2_debug_line = yes \
3250  && test $gcc_cv_as_dwarf2_file_buggy = no; then
3251         AC_DEFINE(HAVE_AS_DWARF2_DEBUG_LINE, 1,
3252   [Define if your assembler supports dwarf2 .file/.loc directives,
3253    and preserves file table indices exactly as given.])
3254  fi
3255
3256  gcc_GAS_CHECK_FEATURE([--gdwarf2 option],
3257   gcc_cv_as_gdwarf2_flag,
3258   [elf,2,11,0], [--gdwarf2], [$insn],,
3259   [AC_DEFINE(HAVE_AS_GDWARF2_DEBUG_FLAG, 1,
3260 [Define if your assembler supports the --gdwarf2 option.])])
3261
3262  gcc_GAS_CHECK_FEATURE([--gstabs option],
3263   gcc_cv_as_gstabs_flag,
3264   [elf,2,11,0], [--gstabs], [$insn],
3265   [# The native Solaris 9/Intel assembler doesn't understand --gstabs
3266    # and warns about it, but still exits successfully.  So check for
3267    # this.
3268    if AC_TRY_COMMAND([$gcc_cv_as --gstabs -o conftest.o conftest.s 2>&1 | grep -i warning > /dev/null])
3269    then :
3270    else gcc_cv_as_gstabs_flag=yes
3271    fi],
3272   [AC_DEFINE(HAVE_AS_GSTABS_DEBUG_FLAG, 1,
3273 [Define if your assembler supports the --gstabs option.])])
3274
3275  gcc_GAS_CHECK_FEATURE([--debug-prefix-map option],
3276   gcc_cv_as_debug_prefix_map_flag,
3277   [2,18,0], [--debug-prefix-map /a=/b], [$insn],,
3278   [AC_DEFINE(HAVE_AS_DEBUG_PREFIX_MAP, 1,
3279 [Define if your assembler supports the --debug-prefix-map option.])])
3280 fi
3281
3282 gcc_GAS_CHECK_FEATURE([.lcomm with alignment], gcc_cv_as_lcomm_with_alignment,
3283  ,,
3284 [.lcomm bar,4,16],,
3285 [AC_DEFINE(HAVE_GAS_LCOMM_WITH_ALIGNMENT, 1,
3286   [Define if your assembler supports .lcomm with an alignment field.])])
3287
3288 AC_CACHE_CHECK([assembler for tolerance to line number 0],
3289  [gcc_cv_as_line_zero],
3290  [gcc_cv_as_line_zero=no
3291   if test $in_tree_gas = yes; then
3292     gcc_GAS_VERSION_GTE_IFELSE(2, 16, 91, [gcc_cv_as_line_zero=yes])
3293   elif test "x$gcc_cv_as" != x; then
3294     { echo '# 1 "test.s" 1'; echo '# 0 "" 2'; } > conftest.s
3295     if AC_TRY_COMMAND([$gcc_cv_as -o conftest.o conftest.s >&AS_MESSAGE_LOG_FD 2>conftest.out]) &&
3296        test "x`cat conftest.out`" = x
3297     then
3298       gcc_cv_as_line_zero=yes
3299     else
3300       echo "configure: failed program was" >&AS_MESSAGE_LOG_FD
3301       cat conftest.s >&AS_MESSAGE_LOG_FD
3302       echo "configure: error output was" >&AS_MESSAGE_LOG_FD
3303       cat conftest.out >&AS_MESSAGE_LOG_FD
3304     fi
3305     rm -f conftest.o conftest.s conftest.out
3306   fi])
3307 if test "x$gcc_cv_as_line_zero" = xyes; then
3308   AC_DEFINE([HAVE_AS_LINE_ZERO], 1,
3309 [Define if the assembler won't complain about a line such as # 0 "" 2.])
3310 fi
3311
3312 AC_MSG_CHECKING(linker PT_GNU_EH_FRAME support)
3313 gcc_cv_ld_eh_frame_hdr=no
3314 if test $in_tree_ld = yes ; then
3315   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 12 -o "$gcc_cv_gld_major_version" -gt 2 \
3316      && test $in_tree_ld_is_elf = yes; then
3317     gcc_cv_ld_eh_frame_hdr=yes
3318   fi
3319 elif test x$gcc_cv_ld != x; then
3320         # Check if linker supports --eh-frame-hdr option
3321         if $gcc_cv_ld --help 2>/dev/null | grep eh-frame-hdr > /dev/null; then
3322                 gcc_cv_ld_eh_frame_hdr=yes
3323         fi
3324 fi
3325 GCC_TARGET_TEMPLATE([HAVE_LD_EH_FRAME_HDR])
3326 if test x"$gcc_cv_ld_eh_frame_hdr" = xyes; then
3327         AC_DEFINE(HAVE_LD_EH_FRAME_HDR, 1,
3328 [Define if your linker supports --eh-frame-hdr option.])
3329 fi
3330 AC_MSG_RESULT($gcc_cv_ld_eh_frame_hdr)
3331
3332 AC_MSG_CHECKING(linker position independent executable support)
3333 gcc_cv_ld_pie=no
3334 if test $in_tree_ld = yes ; then
3335   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 15 -o "$gcc_cv_gld_major_version" -gt 2 \
3336      && test $in_tree_ld_is_elf = yes; then
3337     gcc_cv_ld_pie=yes
3338   fi
3339 elif test x$gcc_cv_ld != x; then
3340         # Check if linker supports -pie option
3341         if $gcc_cv_ld --help 2>/dev/null | grep -- -pie > /dev/null; then
3342                 gcc_cv_ld_pie=yes
3343         fi
3344 fi
3345 if test x"$gcc_cv_ld_pie" = xyes; then
3346         AC_DEFINE(HAVE_LD_PIE, 1,
3347 [Define if your linker supports -pie option.])
3348 fi
3349 AC_MSG_RESULT($gcc_cv_ld_pie)
3350
3351 AC_MSG_CHECKING(linker EH-compatible garbage collection of sections)
3352 gcc_cv_ld_eh_gc_sections=no
3353 if test $in_tree_ld = yes ; then
3354   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 17 -o "$gcc_cv_gld_major_version" -gt 2 \
3355      && test $in_tree_ld_is_elf = yes; then
3356     gcc_cv_ld_eh_gc_sections=yes
3357   fi
3358 elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x -a x$gcc_cv_objdump != x ; then
3359   cat > conftest.s <<EOF
3360         .section        .text
3361 .globl _start
3362         .type _start, @function
3363 _start:
3364         .long foo
3365         .size _start, .-_start
3366         .section        .text.foo,"ax",@progbits
3367         .type foo, @function
3368 foo:
3369         .long 0
3370         .size foo, .-foo
3371         .section        .gcc_except_table.foo,"a",@progbits
3372 .L0:
3373         .long 0
3374         .section        .eh_frame,"a",@progbits
3375         .long .L0
3376 EOF
3377   if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
3378     if $gcc_cv_ld -o conftest conftest.o --entry=_start --gc-sections 2>&1 \
3379          | grep "gc-sections option ignored" > /dev/null; then
3380       gcc_cv_ld_eh_gc_sections=no
3381     elif $gcc_cv_objdump -h conftest | grep gcc_except_table > /dev/null; then
3382       gcc_cv_ld_eh_gc_sections=yes
3383       # If no COMDAT groups, the compiler will emit .gnu.linkonce.t. sections.
3384       if test x$gcc_cv_as_comdat_group != xyes; then
3385         gcc_cv_ld_eh_gc_sections=no
3386         cat > conftest.s <<EOF
3387         .section        .text
3388 .globl _start
3389         .type _start, @function
3390 _start:
3391         .long foo
3392         .size _start, .-_start
3393         .section        .gnu.linkonce.t.foo,"ax",@progbits
3394         .type foo, @function
3395 foo:
3396         .long 0
3397         .size foo, .-foo
3398         .section        .gcc_except_table.foo,"a",@progbits
3399 .L0:
3400         .long 0
3401         .section        .eh_frame,"a",@progbits
3402         .long .L0
3403 EOF
3404         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
3405           if $gcc_cv_ld -o conftest conftest.o --entry=_start --gc-sections 2>&1 \
3406                | grep "gc-sections option ignored" > /dev/null; then
3407             gcc_cv_ld_eh_gc_sections=no
3408           elif $gcc_cv_objdump -h conftest | grep gcc_except_table > /dev/null; then
3409             gcc_cv_ld_eh_gc_sections=yes
3410           fi
3411         fi
3412       fi
3413     fi
3414   fi
3415   rm -f conftest.s conftest.o conftest
3416 fi
3417 case "$target" in
3418   hppa*-*-linux*)
3419     # ??? This apparently exposes a binutils bug with PC-relative relocations.
3420     gcc_cv_ld_eh_gc_sections=no
3421     ;;
3422 esac
3423 if test x$gcc_cv_ld_eh_gc_sections = xyes; then
3424         AC_DEFINE(HAVE_LD_EH_GC_SECTIONS, 1,
3425   [Define if your linker supports garbage collection of
3426    sections in presence of EH frames.])
3427 fi
3428 AC_MSG_RESULT($gcc_cv_ld_eh_gc_sections)
3429
3430 # --------
3431 # UNSORTED
3432 # --------
3433
3434 AC_CACHE_CHECK(linker --as-needed support,
3435 gcc_cv_ld_as_needed,
3436 [gcc_cv_ld_as_needed=no
3437 if test $in_tree_ld = yes ; then
3438   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2 \
3439      && test $in_tree_ld_is_elf = yes; then
3440     gcc_cv_ld_as_needed=yes
3441   fi
3442 elif test x$gcc_cv_ld != x; then
3443         # Check if linker supports --as-needed and --no-as-needed options
3444         if $gcc_cv_ld --help 2>/dev/null | grep as-needed > /dev/null; then
3445                 gcc_cv_ld_as_needed=yes
3446         fi
3447 fi
3448 ])
3449 if test x"$gcc_cv_ld_as_needed" = xyes; then
3450         AC_DEFINE(HAVE_LD_AS_NEEDED, 1,
3451 [Define if your linker supports --as-needed and --no-as-needed options.])
3452 fi
3453
3454 case "$target:$tm_file" in
3455   powerpc64*-*-linux* | powerpc*-*-linux*rs6000/biarch64.h*)
3456     AC_CACHE_CHECK(linker support for omitting dot symbols,
3457     gcc_cv_ld_no_dot_syms,
3458     [gcc_cv_ld_no_dot_syms=no
3459     if test $in_tree_ld = yes ; then
3460       if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2; then
3461         gcc_cv_ld_no_dot_syms=yes
3462       fi
3463     elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x ; then
3464       cat > conftest1.s <<EOF
3465         .text
3466         bl .foo
3467 EOF
3468       cat > conftest2.s <<EOF
3469         .section ".opd","aw"
3470         .align 3
3471         .globl foo
3472         .type foo,@function
3473 foo:
3474         .quad .LEfoo,.TOC.@tocbase,0
3475         .text
3476 .LEfoo:
3477         blr
3478         .size foo,.-.LEfoo
3479 EOF
3480       if $gcc_cv_as -a64 -o conftest1.o conftest1.s > /dev/null 2>&1 \
3481          && $gcc_cv_as -a64 -o conftest2.o conftest2.s > /dev/null 2>&1 \
3482          && $gcc_cv_ld -melf64ppc -o conftest conftest1.o conftest2.o > /dev/null 2>&1; then
3483         gcc_cv_ld_no_dot_syms=yes
3484       fi
3485       rm -f conftest conftest1.o conftest2.o conftest1.s conftest2.s
3486     fi
3487     ])
3488     if test x"$gcc_cv_ld_no_dot_syms" = xyes; then
3489       AC_DEFINE(HAVE_LD_NO_DOT_SYMS, 1,
3490     [Define if your PowerPC64 linker only needs function descriptor syms.])
3491     fi
3492     ;;
3493 esac
3494
3495 AC_CACHE_CHECK(linker --sysroot support,
3496   gcc_cv_ld_sysroot,
3497   [gcc_cv_ld_sysroot=no
3498   if test $in_tree_ld = yes ; then
3499       if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2 ; then
3500         gcc_cv_ld_sysroot=yes
3501       fi
3502   elif test x$gcc_cv_ld != x; then
3503     if $gcc_cv_ld --help 2>/dev/null | grep sysroot > /dev/null; then
3504       gcc_cv_ld_sysroot=yes
3505     fi
3506   fi])
3507 if test x"$gcc_cv_ld_sysroot" = xyes; then
3508   AC_DEFINE(HAVE_LD_SYSROOT, 1,
3509   [Define if your linker supports --sysroot.])
3510 fi
3511
3512 if test x$with_sysroot = x && test x$host = x$target \
3513    && test "$prefix" != "/usr" && test "x$prefix" != "x$local_prefix" \
3514    && test "$prefix" != "NONE"; then
3515   AC_DEFINE_UNQUOTED(PREFIX_INCLUDE_DIR, "$prefix/include",
3516 [Define to PREFIX/include if cpp should also search that directory.])
3517 fi
3518
3519 # Test for stack protector support in target C library.
3520 AC_CACHE_CHECK(__stack_chk_fail in target C library,
3521       gcc_cv_libc_provides_ssp,
3522       [gcc_cv_libc_provides_ssp=no
3523     case "$target" in
3524        *-*-linux* | *-*-kfreebsd*-gnu | *-*-knetbsd*-gnu)
3525       if test x$host != x$target || test "x$TARGET_SYSTEM_ROOT" != x; then
3526         if test "x$with_sysroot" = x; then
3527           glibc_header_dir="${exec_prefix}/${target_noncanonical}/sys-include"
3528         elif test "x$with_build_sysroot" != "x"; then
3529           glibc_header_dir="${with_build_sysroot}/usr/include"
3530         elif test "x$with_sysroot" = xyes; then
3531           glibc_header_dir="${exec_prefix}/${target_noncanonical}/sys-root/usr/include"
3532         else
3533           glibc_header_dir="${with_sysroot}/usr/include"
3534         fi
3535       else
3536         glibc_header_dir=/usr/include
3537       fi
3538       # glibc 2.4 and later provides __stack_chk_fail and
3539       # either __stack_chk_guard, or TLS access to stack guard canary.
3540       if test -f $glibc_header_dir/features.h \
3541          && $EGREP '^@<:@       @:>@*#[         ]*define[       ]+__GNU_LIBRARY__[      ]+([1-9][0-9]|[6-9])' \
3542             $glibc_header_dir/features.h > /dev/null; then
3543         if $EGREP '^@<:@        @:>@*#[         ]*define[       ]+__GLIBC__[    ]+([1-9][0-9]|[3-9])' \
3544            $glibc_header_dir/features.h > /dev/null; then
3545           gcc_cv_libc_provides_ssp=yes
3546         elif $EGREP '^@<:@      @:>@*#[         ]*define[       ]+__GLIBC__[    ]+2' \
3547              $glibc_header_dir/features.h > /dev/null \
3548              && $EGREP '^@<:@   @:>@*#[         ]*define[       ]+__GLIBC_MINOR__[      ]+([1-9][0-9]|[4-9])' \
3549              $glibc_header_dir/features.h > /dev/null; then
3550           gcc_cv_libc_provides_ssp=yes
3551         elif $EGREP '^@<:@      @:>@*#[         ]*define[       ]+__UCLIBC__[   ]+1' \
3552              $glibc_header_dir/features.h > /dev/null && \
3553              test -f $glibc_header_dir/bits/uClibc_config.h && \
3554              $EGREP '^@<:@      @:>@*#[         ]*define[       ]+__UCLIBC_HAS_SSP__[   ]+1' \
3555              $glibc_header_dir/bits/uClibc_config.h > /dev/null; then
3556           gcc_cv_libc_provides_ssp=yes
3557         fi
3558       fi
3559         ;;
3560        *-*-gnu*)
3561          # Avoid complicated tests (see
3562          # <http://gcc.gnu.org/ml/gcc/2008-10/msg00130.html>) and for now
3563          # simply assert that glibc does provide this, which is true for all
3564          # realistically usable GNU/Hurd configurations.
3565          gcc_cv_libc_provides_ssp=yes;;
3566        *-*-darwin*)
3567          AC_CHECK_FUNC(__stack_chk_fail,[gcc_cv_libc_provides_ssp=yes],
3568            [echo "no __stack_chk_fail on this target"])
3569         ;;
3570   *) gcc_cv_libc_provides_ssp=no ;;
3571     esac])
3572
3573 if test x$gcc_cv_libc_provides_ssp = xyes; then
3574   AC_DEFINE(TARGET_LIBC_PROVIDES_SSP, 1,
3575             [Define if your target C library provides stack protector support])
3576 fi
3577
3578 # Check if TFmode long double should be used by default or not.
3579 # Some glibc targets used DFmode long double, but with glibc 2.4
3580 # and later they can use TFmode.
3581 case "$target" in
3582   powerpc*-*-linux* | \
3583   powerpc*-*-gnu* | \
3584   sparc*-*-linux* | \
3585   s390*-*-linux* | \
3586   alpha*-*-linux*)
3587     AC_ARG_WITH(long-double-128,
3588 [  --with-long-double-128  Use 128-bit long double by default.],
3589       gcc_cv_target_ldbl128="$with_long_double_128",
3590       [gcc_cv_target_ldbl128=no
3591       if test x$host != x$target || test "x$TARGET_SYSTEM_ROOT" != x; then
3592         if test "x$with_sysroot" = x; then
3593           glibc_header_dir="${exec_prefix}/${target_noncanonical}/sys-include"
3594         elif test "x$with_build_sysroot" != "x"; then
3595           glibc_header_dir="${with_build_sysroot}/usr/include"
3596         elif test "x$with_sysroot" = xyes; then
3597           glibc_header_dir="${exec_prefix}/${target_noncanonical}/sys-root/usr/include"
3598         else
3599           glibc_header_dir="${with_sysroot}/usr/include"
3600         fi
3601       else
3602         glibc_header_dir=/usr/include
3603       fi
3604 changequote(,)dnl
3605       grep '^[  ]*#[    ]*define[       ][      ]*__LONG_DOUBLE_MATH_OPTIONAL' \
3606         $glibc_header_dir/bits/wordsize.h > /dev/null 2>&1 \
3607       && gcc_cv_target_ldbl128=yes
3608 changequote([,])dnl
3609       ])
3610     ;;
3611 esac
3612 if test x$gcc_cv_target_ldbl128 = xyes; then
3613   AC_DEFINE(TARGET_DEFAULT_LONG_DOUBLE_128, 1,
3614             [Define if TFmode long double should be the default])
3615 fi
3616
3617 # Find out what GC implementation we want, or may, use.
3618 AC_ARG_WITH(gc,
3619 [  --with-gc={page,zone}   choose the garbage collection mechanism to use
3620                           with the compiler],
3621 [case "$withval" in
3622   page)
3623     GGC=ggc-$withval
3624     ;;
3625   zone)
3626     GGC=ggc-$withval
3627     AC_DEFINE(GGC_ZONE, 1, [Define if the zone collector is in use])
3628     ;;
3629   *)
3630     AC_MSG_ERROR([$withval is an invalid option to --with-gc])
3631     ;;
3632 esac],
3633 [GGC=ggc-page])
3634 AC_SUBST(GGC)
3635 echo "Using $GGC for garbage collection."
3636
3637 # Use the system's zlib library.
3638 zlibdir=-L../zlib
3639 zlibinc="-I\$(srcdir)/../zlib"
3640 AC_ARG_WITH(system-zlib,
3641 [  --with-system-zlib      use installed libz],
3642 zlibdir=
3643 zlibinc=
3644 )
3645 AC_SUBST(zlibdir)
3646 AC_SUBST(zlibinc)
3647
3648 dnl Very limited version of automake's enable-maintainer-mode
3649
3650 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
3651   dnl maintainer-mode is disabled by default
3652   AC_ARG_ENABLE(maintainer-mode,
3653 [  --enable-maintainer-mode
3654                           enable make rules and dependencies not useful
3655                           (and sometimes confusing) to the casual installer],
3656       maintainer_mode=$enableval,
3657       maintainer_mode=no)
3658
3659 AC_MSG_RESULT($maintainer_mode)
3660
3661 if test "$maintainer_mode" = "yes"; then
3662   MAINT=''
3663 else
3664   MAINT='#'
3665 fi
3666 AC_SUBST(MAINT)dnl
3667
3668 # --------------
3669 # Language hooks
3670 # --------------
3671
3672 # Make empty files to contain the specs and options for each language.
3673 # Then add #include lines to for a compiler that has specs and/or options.
3674
3675 subdirs=
3676 lang_opt_files=
3677 lang_specs_files=
3678 lang_tree_files=
3679 # These (without "all_") are set in each config-lang.in.
3680 # `language' must be a single word so is spelled singularly.
3681 all_languages=
3682 all_compilers=
3683 all_outputs='Makefile gccbug'
3684 # List of language makefile fragments.
3685 all_lang_makefrags=
3686 # List of language subdirectory makefiles.  Deprecated.
3687 all_lang_makefiles=
3688 # Additional files for gengtype
3689 all_gtfiles="$target_gtfiles"
3690
3691 # These are the languages that are set in --enable-languages,
3692 # and are available in the GCC tree.
3693 all_selected_languages=
3694
3695 # Add the language fragments.
3696 # Languages are added via two mechanisms.  Some information must be
3697 # recorded in makefile variables, these are defined in config-lang.in.
3698 # We accumulate them and plug them into the main Makefile.
3699 # The other mechanism is a set of hooks for each of the main targets
3700 # like `clean', `install', etc.
3701
3702 language_hooks="Make-hooks"
3703
3704 for lang in ${srcdir}/*/config-lang.in
3705 do
3706 changequote(,)dnl
3707         test "$lang" = "${srcdir}/*/config-lang.in" && continue
3708
3709         lang_alias=`sed -n -e 's,^language=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^language=\([^   ]*\).*$,\1,p' $lang`
3710         if test "x$lang_alias" = x
3711         then
3712               echo "$lang doesn't set \$language." 1>&2
3713               exit 1
3714         fi
3715         subdir="`echo $lang | sed -e 's,^.*/\([^/]*\)/config-lang.in$,\1,'`"
3716         subdirs="$subdirs $subdir"
3717
3718         # $gcc_subdir is where the gcc integration files are to be found
3719         # for a language, both for internal compiler purposes (compiler
3720         # sources implementing front-end to GCC tree converters), and for
3721         # build infrastructure purposes (Make-lang.in, etc.)
3722         #
3723         # This will be <subdir> (relative to $srcdir) if a line like
3724         # gcc_subdir="<subdir>" or gcc_subdir=<subdir>
3725         # is found in <langdir>/config-lang.in, and will remain <langdir>
3726         # otherwise.
3727         #
3728         # Except for the language alias (fetched above), the regular
3729         # "config-lang.in" contents are always retrieved from $gcc_subdir,
3730         # so a <langdir>/config-lang.in setting gcc_subdir typically sets
3731         # only this and the language alias.
3732
3733         gcc_subdir=`sed -n -e 's,^gcc_subdir=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^gcc_subdir=\([^   ]*\).*$,\1,p' $lang`
3734         if [ "$gcc_subdir" = "" ]; then
3735            gcc_subdir="$subdir"
3736         fi
3737
3738         case ",$enable_languages," in
3739         *,$lang_alias,*)
3740             all_selected_languages="$all_selected_languages $lang_alias"
3741             if test -f $srcdir/$gcc_subdir/lang-specs.h; then
3742                 lang_specs_files="$lang_specs_files $srcdir/$gcc_subdir/lang-specs.h"
3743             fi
3744             ;;
3745         esac
3746 changequote([,])dnl
3747
3748         language=
3749         boot_language=
3750         compilers=
3751         outputs=
3752         gtfiles=
3753         subdir_requires=
3754         . ${srcdir}/$gcc_subdir/config-lang.in
3755         if test "x$language" = x
3756         then
3757                 echo "${srcdir}/$gcc_subdir/config-lang.in doesn't set \$language." 1>&2
3758                 exit 1
3759         fi
3760
3761         ok=:
3762         case ",$enable_languages," in
3763                 *,$lang_alias,*) ;;
3764                 *)
3765                         for i in $subdir_requires; do
3766                                 test -f "${srcdir}/$i/config-lang.in" && continue
3767                                 ok=false
3768                                 break
3769                         done
3770                 ;;
3771         esac
3772         $ok || continue
3773
3774         all_lang_makefrags="$all_lang_makefrags \$(srcdir)/$gcc_subdir/Make-lang.in"
3775         if test -f $srcdir/$gcc_subdir/lang.opt; then
3776             lang_opt_files="$lang_opt_files $srcdir/$gcc_subdir/lang.opt"
3777         fi
3778         if test -f $srcdir/$gcc_subdir/$subdir-tree.def; then
3779             lang_tree_files="$lang_tree_files $srcdir/$gcc_subdir/$subdir-tree.def"
3780         fi
3781         if test -f ${srcdir}/$gcc_subdir/Makefile.in
3782                 then all_lang_makefiles="$gcc_subdir/Makefile"
3783         fi
3784         all_languages="$all_languages $language"
3785         all_compilers="$all_compilers $compilers"
3786         all_outputs="$all_outputs $outputs"
3787         all_gtfiles="$all_gtfiles [[$subdir]] $gtfiles"
3788 done
3789
3790 # Pick up gtfiles for c
3791 gtfiles=
3792 . ${srcdir}/c-config-lang.in
3793 all_gtfiles="$all_gtfiles [[c]] $gtfiles"
3794
3795 check_languages=
3796 for language in $all_selected_languages
3797 do
3798         check_languages="$check_languages check-$language"
3799 done
3800
3801 # We link each language in with a set of hooks, reached indirectly via
3802 # lang.${target}.  Only do so for selected languages.
3803
3804 rm -f Make-hooks
3805 touch Make-hooks
3806 target_list="all.cross start.encap rest.encap tags \
3807         install-common install-man install-info install-pdf dvi pdf \
3808         html uninstall info man srcextra srcman srcinfo \
3809         mostlyclean clean distclean maintainer-clean"
3810
3811 for t in $target_list
3812 do
3813         x=
3814         for lang in $all_selected_languages
3815         do
3816                 x="$x $lang.$t"
3817         done
3818         echo "lang.$t: $x" >> Make-hooks
3819 done
3820
3821 # --------
3822 # UNSORTED
3823 # --------
3824
3825 # Create .gdbinit.
3826
3827 echo "dir ." > .gdbinit
3828 echo "dir ${srcdir}" >> .gdbinit
3829 if test x$gdb_needs_out_file_path = xyes
3830 then
3831         echo "dir ${srcdir}/config/"`dirname ${out_file}` >> .gdbinit
3832 fi
3833 if test "x$subdirs" != x; then
3834         for s in $subdirs
3835         do
3836                 echo "dir ${srcdir}/$s" >> .gdbinit
3837         done
3838 fi
3839 echo "source ${srcdir}/gdbinit.in" >> .gdbinit
3840
3841 gcc_tooldir='$(libsubdir)/$(libsubdir_to_prefix)$(target_noncanonical)'
3842 AC_SUBST(gcc_tooldir)
3843 AC_SUBST(dollar)
3844
3845 # Find a directory in which to install a shared libgcc.
3846
3847 AC_ARG_ENABLE(version-specific-runtime-libs,
3848 [  --enable-version-specific-runtime-libs
3849                           specify that runtime libraries should be
3850                           installed in a compiler-specific directory])
3851
3852 AC_ARG_WITH(slibdir,
3853 [  --with-slibdir=DIR      shared libraries in DIR [[LIBDIR]]],
3854 slibdir="$with_slibdir",
3855 if test "${enable_version_specific_runtime_libs+set}" = set; then
3856   slibdir='$(libsubdir)'
3857 elif test "$host" != "$target"; then
3858   slibdir='$(build_tooldir)/lib'
3859 else
3860   slibdir='$(libdir)'
3861 fi)
3862 AC_SUBST(slibdir)
3863
3864 AC_ARG_WITH(datarootdir,
3865 [  --with-datarootdir=DIR  Use DIR as the data root [[PREFIX/share]]],
3866 datarootdir="\${prefix}/$with_datarootdir",
3867 datarootdir='$(prefix)/share')
3868 AC_SUBST(datarootdir)
3869
3870 AC_ARG_WITH(docdir,
3871 [  --with-docdir=DIR       Install documentation in DIR [[DATAROOTDIR]]],
3872 docdir="\${prefix}/$with_docdir",
3873 docdir='$(datarootdir)')
3874 AC_SUBST(docdir)
3875
3876 AC_ARG_WITH(htmldir,
3877 [  --with-htmldir=DIR      html documentation in in DIR [[DOCDIR]]],
3878 htmldir="\${prefix}/$with_htmldir",
3879 htmldir='$(docdir)')
3880 AC_SUBST(htmldir)
3881
3882 # Substitute configuration variables
3883 AC_SUBST(subdirs)
3884 AC_SUBST(srcdir)
3885 AC_SUBST(all_compilers)
3886 AC_SUBST(all_gtfiles)
3887 AC_SUBST(all_lang_makefrags)
3888 AC_SUBST(all_lang_makefiles)
3889 AC_SUBST(all_languages)
3890 AC_SUBST(all_selected_languages)
3891 AC_SUBST(build_exeext)
3892 AC_SUBST(build_install_headers_dir)
3893 AC_SUBST(build_xm_file_list)
3894 AC_SUBST(build_xm_include_list)
3895 AC_SUBST(build_xm_defines)
3896 AC_SUBST(build_file_translate)
3897 AC_SUBST(check_languages)
3898 AC_SUBST(cpp_install_dir)
3899 AC_SUBST(xmake_file)
3900 AC_SUBST(tmake_file)
3901 AC_SUBST(extra_gcc_objs)
3902 AC_SUBST(extra_headers_list)
3903 AC_SUBST(extra_objs)
3904 AC_SUBST(extra_parts)
3905 AC_SUBST(extra_passes)
3906 AC_SUBST(extra_programs)
3907 AC_SUBST(float_h_file)
3908 AC_SUBST(gcc_config_arguments)
3909 AC_SUBST(gcc_gxx_include_dir)
3910 AC_SUBST(host_exeext)
3911 AC_SUBST(host_xm_file_list)
3912 AC_SUBST(host_xm_include_list)
3913 AC_SUBST(host_xm_defines)
3914 AC_SUBST(out_host_hook_obj)
3915 AC_SUBST(install)
3916 AC_SUBST(lang_opt_files)
3917 AC_SUBST(lang_specs_files)
3918 AC_SUBST(lang_tree_files)
3919 AC_SUBST(local_prefix)
3920 AC_SUBST(md_file)
3921 AC_SUBST(objc_boehm_gc)
3922 AC_SUBST(out_file)
3923 AC_SUBST(out_object_file)
3924 AC_SUBST(thread_file)
3925 AC_SUBST(tm_file_list)
3926 AC_SUBST(tm_include_list)
3927 AC_SUBST(tm_defines)
3928 AC_SUBST(tm_p_file_list)
3929 AC_SUBST(tm_p_include_list)
3930 AC_SUBST(xm_file_list)
3931 AC_SUBST(xm_include_list)
3932 AC_SUBST(xm_defines)
3933 AC_SUBST(c_target_objs)
3934 AC_SUBST(cxx_target_objs)
3935 AC_SUBST(fortran_target_objs)
3936 AC_SUBST(target_cpu_default)
3937
3938 AC_SUBST_FILE(language_hooks)
3939
3940 # Echo link setup.
3941 if test x${build} = x${host} ; then
3942   if test x${host} = x${target} ; then
3943     echo "Links are now set up to build a native compiler for ${target}." 1>&2
3944   else
3945     echo "Links are now set up to build a cross-compiler" 1>&2
3946     echo " from ${host} to ${target}." 1>&2
3947   fi
3948 else
3949   if test x${host} = x${target} ; then
3950     echo "Links are now set up to build (on ${build}) a native compiler" 1>&2
3951     echo " for ${target}." 1>&2
3952   else
3953     echo "Links are now set up to build (on ${build}) a cross-compiler" 1>&2
3954     echo " from ${host} to ${target}." 1>&2
3955   fi
3956 fi
3957
3958 AC_ARG_VAR(GMPLIBS,[How to link GMP])
3959 AC_ARG_VAR(GMPINC,[How to find GMP include files])
3960
3961 AC_ARG_VAR(PPLLIBS,[How to link PPL])
3962 AC_ARG_VAR(PPLINC,[How to find PPL include files])
3963
3964 AC_ARG_VAR(CLOOGLIBS,[How to link CLOOG])
3965 AC_ARG_VAR(CLOOGINC,[How to find CLOOG include files])
3966 if test "x${CLOOGLIBS}" != "x" ; then
3967    AC_DEFINE(HAVE_cloog, 1, [Define if cloog is in use.])
3968 fi
3969
3970 # Configure the subdirectories
3971 # AC_CONFIG_SUBDIRS($subdirs)
3972
3973 # Create the Makefile
3974 # and configure language subdirectories
3975 AC_CONFIG_FILES($all_outputs)
3976
3977 AC_CONFIG_COMMANDS([default],
3978 [
3979 case ${CONFIG_HEADERS} in
3980   *auto-host.h:config.in*)
3981   echo > cstamp-h ;;
3982 esac
3983 # Make sure all the subdirs exist.
3984 for d in $subdirs doc build
3985 do
3986     test -d $d || mkdir $d
3987 done
3988 ],
3989 [subdirs='$subdirs'])
3990 AC_OUTPUT