OSDN Git Service

2008-09-02 Sebastian Pop <sebastian.pop@amd.com>
[pf3gnuchains/gcc-fork.git] / gcc / configure.ac
1 # configure.ac for GCC
2 # Process this file with autoconf to generate a configuration script.
3
4 # Copyright 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2004, 2005, 2006,
5 # 2007, 2008 Free Software Foundation, Inc.
6
7 #This file is part of GCC.
8
9 #GCC is free software; you can redistribute it and/or modify it under
10 #the terms of the GNU General Public License as published by the Free
11 #Software Foundation; either version 3, or (at your option) any later
12 #version.
13
14 #GCC is distributed in the hope that it will be useful, but WITHOUT
15 #ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
16 #FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
17 #for more details.
18
19 #You should have received a copy of the GNU General Public License
20 #along with GCC; see the file COPYING3.  If not see
21 #<http://www.gnu.org/licenses/>.
22
23 # --------------------------------
24 # Initialization and sanity checks
25 # --------------------------------
26
27 AC_PREREQ(2.59)
28 AC_INIT
29 AC_CONFIG_SRCDIR(tree.c)
30 AC_CONFIG_HEADER(auto-host.h:config.in)
31
32 gcc_version=`cat $srcdir/BASE-VER`
33
34 # Determine the host, build, and target systems
35 AC_CANONICAL_BUILD
36 AC_CANONICAL_HOST
37 AC_CANONICAL_TARGET
38
39 # Determine the noncanonical target name, for directory use.
40 ACX_NONCANONICAL_TARGET
41
42 # Determine the target- and build-specific subdirectories
43 GCC_TOPLEV_SUBDIRS
44
45 # Set program_transform_name
46 AC_ARG_PROGRAM
47
48 # Check for bogus environment variables.
49 # Test if LIBRARY_PATH contains the notation for the current directory
50 # since this would lead to problems installing/building glibc.
51 # LIBRARY_PATH contains the current directory if one of the following
52 # is true:
53 # - one of the terminals (":" and ";") is the first or last sign
54 # - two terminals occur directly after each other
55 # - the path contains an element with a dot in it
56 AC_MSG_CHECKING(LIBRARY_PATH variable)
57 changequote(,)dnl
58 case ${LIBRARY_PATH} in
59   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
60     library_path_setting="contains current directory"
61     ;;
62   *)
63     library_path_setting="ok"
64     ;;
65 esac
66 changequote([,])dnl
67 AC_MSG_RESULT($library_path_setting)
68 if test "$library_path_setting" != "ok"; then
69 AC_MSG_ERROR([
70 *** LIBRARY_PATH shouldn't contain the current directory when
71 *** building gcc. Please change the environment variable
72 *** and run configure again.])
73 fi
74
75 # Test if GCC_EXEC_PREFIX contains the notation for the current directory
76 # since this would lead to problems installing/building glibc.
77 # GCC_EXEC_PREFIX contains the current directory if one of the following
78 # is true:
79 # - one of the terminals (":" and ";") is the first or last sign
80 # - two terminals occur directly after each other
81 # - the path contains an element with a dot in it
82 AC_MSG_CHECKING(GCC_EXEC_PREFIX variable)
83 changequote(,)dnl
84 case ${GCC_EXEC_PREFIX} in
85   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
86     gcc_exec_prefix_setting="contains current directory"
87     ;;
88   *)
89     gcc_exec_prefix_setting="ok"
90     ;;
91 esac
92 changequote([,])dnl
93 AC_MSG_RESULT($gcc_exec_prefix_setting)
94 if test "$gcc_exec_prefix_setting" != "ok"; then
95 AC_MSG_ERROR([
96 *** GCC_EXEC_PREFIX shouldn't contain the current directory when
97 *** building gcc. Please change the environment variable
98 *** and run configure again.])
99 fi
100
101 # -----------
102 # Directories
103 # -----------
104
105 # Specify the local prefix
106 local_prefix=
107 AC_ARG_WITH(local-prefix,
108 [  --with-local-prefix=DIR specifies directory to put local include],
109 [case "${withval}" in
110 yes)    AC_MSG_ERROR(bad value ${withval} given for local include directory prefix) ;;
111 no)     ;;
112 *)      local_prefix=$with_local_prefix ;;
113 esac])
114
115 # Default local prefix if it is empty
116 if test x$local_prefix = x; then
117         local_prefix=/usr/local
118 fi
119
120 # Don't set gcc_gxx_include_dir to gxx_include_dir since that's only
121 # passed in by the toplevel make and thus we'd get different behavior
122 # depending on where we built the sources.
123 gcc_gxx_include_dir=
124 # Specify the g++ header file directory
125 AC_ARG_WITH(gxx-include-dir,
126 [  --with-gxx-include-dir=DIR
127                           specifies directory to put g++ header files],
128 [case "${withval}" in
129 yes)    AC_MSG_ERROR(bad value ${withval} given for g++ include directory) ;;
130 no)     ;;
131 *)      gcc_gxx_include_dir=$with_gxx_include_dir ;;
132 esac])
133
134 # This logic must match libstdc++-v3/acinclude.m4:GLIBCXX_EXPORT_INSTALL_INFO.
135 if test x${gcc_gxx_include_dir} = x; then
136   if test x${enable_version_specific_runtime_libs} = xyes; then
137     gcc_gxx_include_dir='${libsubdir}/include/c++'
138   else
139     libstdcxx_incdir='include/c++/$(version)'
140     if test x$host != x$target; then
141        libstdcxx_incdir="$target_alias/$libstdcxx_incdir"
142     fi
143     gcc_gxx_include_dir="\$(libsubdir)/\$(libsubdir_to_prefix)$libstdcxx_incdir"
144   fi
145 fi
146
147 AC_ARG_WITH(cpp_install_dir,
148 [  --with-cpp-install-dir=DIR
149                           install the user visible C preprocessor in DIR
150                           (relative to PREFIX) as well as PREFIX/bin],
151 [if test x$withval = xyes; then
152   AC_MSG_ERROR([option --with-cpp-install-dir requires an argument])
153 elif test x$withval != xno; then
154   cpp_install_dir=$withval
155 fi])
156
157 # We would like to our source tree to be readonly.  However when releases or
158 # pre-releases are generated, the flex/bison generated files as well as the 
159 # various formats of manuals need to be included along with the rest of the
160 # sources.  Therefore we have --enable-generated-files-in-srcdir to do 
161 # just that.
162
163 AC_MSG_CHECKING([whether to place generated files in the source directory])
164   dnl generated-files-in-srcdir is disabled by default
165   AC_ARG_ENABLE(generated-files-in-srcdir, 
166 [  --enable-generated-files-in-srcdir
167                           put copies of generated files in source dir
168                           intended for creating source tarballs for users
169                           without texinfo bison or flex.],
170       generated_files_in_srcdir=$enableval,
171       generated_files_in_srcdir=no)
172
173 AC_MSG_RESULT($generated_files_in_srcdir)
174
175 if test "$generated_files_in_srcdir" = "yes"; then
176   GENINSRC=''
177 else
178   GENINSRC='#'
179 fi
180 AC_SUBST(GENINSRC)
181
182 # -------------------
183 # Find default linker
184 # -------------------
185
186 # With GNU ld
187 AC_ARG_WITH(gnu-ld,
188 [  --with-gnu-ld           arrange to work with GNU ld.],
189 gnu_ld_flag="$with_gnu_ld",
190 gnu_ld_flag=no)
191
192 # With pre-defined ld
193 AC_ARG_WITH(ld,
194 [  --with-ld               arrange to use the specified ld (full pathname)],
195 DEFAULT_LINKER="$with_ld")
196 if test x"${DEFAULT_LINKER+set}" = x"set"; then
197   if test ! -x "$DEFAULT_LINKER"; then
198     AC_MSG_ERROR([cannot execute: $DEFAULT_LINKER: check --with-ld or env. var. DEFAULT_LINKER])
199   elif $DEFAULT_LINKER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
200     gnu_ld_flag=yes
201   fi
202   AC_DEFINE_UNQUOTED(DEFAULT_LINKER,"$DEFAULT_LINKER",
203         [Define to enable the use of a default linker.])
204 fi
205
206 gnu_ld=`if test x"$gnu_ld_flag" = x"yes"; then echo 1; else echo 0; fi`
207 AC_DEFINE_UNQUOTED(HAVE_GNU_LD, $gnu_ld, [Define if using GNU ld.])
208
209 AC_MSG_CHECKING([whether a default linker was specified])
210 if test x"${DEFAULT_LINKER+set}" = x"set"; then
211   if test x"$gnu_ld_flag" = x"no"; then
212     AC_MSG_RESULT([yes ($DEFAULT_LINKER)])
213   else
214     AC_MSG_RESULT([yes ($DEFAULT_LINKER - GNU ld)])
215   fi
216 else
217   AC_MSG_RESULT(no)
218 fi
219
220 # With demangler in GNU ld
221 AC_ARG_WITH(demangler-in-ld,
222 [  --with-demangler-in-ld  try to use demangler in GNU ld.],
223 demangler_in_ld="$with_demangler_in_ld",
224 demangler_in_ld=no)
225
226 # ----------------------
227 # Find default assembler
228 # ----------------------
229
230 # With GNU as
231 AC_ARG_WITH(gnu-as,
232 [  --with-gnu-as           arrange to work with GNU as],
233 gas_flag="$with_gnu_as",
234 gas_flag=no)
235
236 AC_ARG_WITH(as,
237 [  --with-as               arrange to use the specified as (full pathname)],
238 DEFAULT_ASSEMBLER="$with_as")
239 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
240   if test ! -x "$DEFAULT_ASSEMBLER"; then
241     AC_MSG_ERROR([cannot execute: $DEFAULT_ASSEMBLER: check --with-as or env. var. DEFAULT_ASSEMBLER])
242   elif $DEFAULT_ASSEMBLER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
243     gas_flag=yes
244   fi
245   AC_DEFINE_UNQUOTED(DEFAULT_ASSEMBLER,"$DEFAULT_ASSEMBLER",
246         [Define to enable the use of a default assembler.])
247 fi
248
249 gnu_as=`if test x"$gas_flag" = x"yes"; then echo 1; else echo 0; fi`
250 AC_DEFINE_UNQUOTED(HAVE_GNU_AS, $gnu_as, [Define if using GNU as.])
251
252 AC_MSG_CHECKING([whether a default assembler was specified])
253 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
254   if test x"$gas_flag" = x"no"; then
255     AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER)])
256   else
257     AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER - GNU as)])
258   fi
259 else
260   AC_MSG_RESULT(no)
261 fi
262
263 # ---------------
264 # Find C compiler
265 # ---------------
266
267 # If a non-executable a.out is present (e.g. created by GNU as above even if
268 # invoked with -v only), the IRIX 6 native ld just overwrites the existing
269 # file, even when creating an executable, so an execution test fails.
270 # Remove possible default executable files to avoid this.
271 #
272 # FIXME: This really belongs into AC_PROG_CC and can be removed once
273 # Autoconf includes it.
274 rm -f a.out a.exe b.out
275
276 # Find the native compiler
277 AC_PROG_CC
278 AM_PROG_CC_C_O
279 ACX_PROG_GNAT([-I"$srcdir"/ada])
280
281 # autoconf is lame and doesn't give us any substitution variable for this.
282 if eval "test \"`echo '$ac_cv_prog_cc_'${ac_cc}_c_o`\" = no"; then
283   NO_MINUS_C_MINUS_O=yes
284 else
285   OUTPUT_OPTION='-o $@'
286 fi
287 AC_SUBST(NO_MINUS_C_MINUS_O)
288 AC_SUBST(OUTPUT_OPTION)
289
290 # Remove the -O2: for historical reasons, unless bootstrapping we prefer
291 # optimizations to be activated explicitly by the toplevel.
292 case "$CC" in
293   */prev-gcc/xgcc*) ;;
294   *) CFLAGS=`echo $CFLAGS | sed "s/-O[[s0-9]]* *//" ` ;;
295 esac
296 AC_SUBST(CFLAGS)
297
298 # -------------------------
299 # Check C compiler features
300 # -------------------------
301
302 AC_USE_SYSTEM_EXTENSIONS
303 AC_PROG_CPP
304 AC_C_INLINE
305
306 # sizeof(char) is 1 by definition.
307 AC_CHECK_SIZEOF(void *)
308 AC_CHECK_SIZEOF(short)
309 AC_CHECK_SIZEOF(int)
310 AC_CHECK_SIZEOF(long)
311 AC_CHECK_TYPES([long long], [AC_CHECK_SIZEOF(long long)])
312 AC_CHECK_TYPES([__int64], [AC_CHECK_SIZEOF(__int64)])
313
314 # ---------------------
315 # Warnings and checking
316 # ---------------------
317
318 # Check $CC warning features (if it's GCC).
319 # We want to use -pedantic, but we don't want warnings about
320 # * 'long long'
321 # * variadic macros
322 # * overlong strings
323 # So, we only use -pedantic if we can disable those warnings.
324
325 ACX_PROG_CC_WARNING_OPTS(
326         [m4_do([-W -Wall -Wwrite-strings -Wstrict-prototypes ],
327                [-Wmissing-prototypes -Wcast-qual])], [loose_warn])
328 ACX_PROG_CC_WARNING_OPTS(
329         [m4_do([-Wold-style-definition -Wc++-compat ], 
330                [-Wmissing-format-attribute])], [strict_warn])
331 ACX_PROG_CC_WARNING_ALMOST_PEDANTIC(
332         [m4_do([-Wno-long-long -Wno-variadic-macros ], 
333                [-Wno-overlength-strings])], [strict_warn])
334 ACX_PROG_CC_WARNINGS_ARE_ERRORS([manual], [strict_warn])
335
336 # The above macros do nothing if the compiler is not GCC.  However, the
337 # Makefile has more goo to add other flags, so this variabl is used to
338 # enables warnings only for GCC.
339 warn_cflags=
340 if test "x$GCC" = "xyes"; then
341   warn_cflags='$(GCC_WARN_CFLAGS)'
342 fi
343 AC_SUBST(warn_cflags)
344
345 # Enable expensive internal checks
346 is_release=
347 if test x"`cat $srcdir/DEV-PHASE`" != xexperimental; then
348   is_release=yes
349 fi
350
351 AC_ARG_ENABLE(checking,
352 [  --enable-checking[=LIST]
353                           enable expensive run-time checks.  With LIST,
354                           enable only specific categories of checks.
355                           Categories are: yes,no,all,none,release.
356                           Flags are: assert,df,fold,gc,gcac,gimple,misc,
357                           rtlflag,rtl,runtime,tree,valgrind,types.],
358 [ac_checking_flags="${enableval}"],[
359 # Determine the default checks.
360 if test x$is_release = x ; then
361   ac_checking_flags=yes
362 else
363   ac_checking_flags=release
364 fi])
365 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
366 for check in release $ac_checking_flags
367 do
368         case $check in
369         # these set all the flags to specific states
370         yes)            ac_assert_checking=1 ; ac_checking=1 ; ac_df_checking= ;
371                         ac_fold_checking= ; ac_gc_checking=1 ;
372                         ac_gc_always_collect= ; ac_gimple_checking=1 ; ac_rtl_checking= ;
373                         ac_rtlflag_checking=1 ; ac_runtime_checking=1 ;
374                         ac_tree_checking=1 ; ac_valgrind_checking= ;
375                         ac_types_checking=1 ;;
376         no|none)        ac_assert_checking= ; ac_checking= ; ac_df_checking= ;
377                         ac_fold_checking= ; ac_gc_checking= ;
378                         ac_gc_always_collect= ; ac_gimple_checking= ; ac_rtl_checking= ;
379                         ac_rtlflag_checking= ; ac_runtime_checking= ;
380                         ac_tree_checking= ; ac_valgrind_checking= ;
381                         ac_types_checking= ;;
382         all)            ac_assert_checking=1 ; ac_checking=1 ; ac_df_checking=1 ;
383                         ac_fold_checking=1 ; ac_gc_checking=1 ;
384                         ac_gc_always_collect=1 ; ac_gimple_checking=1 ; ac_rtl_checking=1 ;
385                         ac_rtlflag_checking=1 ; ac_runtime_checking=1 ;
386                         ac_tree_checking=1 ; ac_valgrind_checking= ;
387                         ac_types_checking=1 ;;
388         release)        ac_assert_checking=1 ; ac_checking= ; ac_df_checking= ;
389                         ac_fold_checking= ; ac_gc_checking= ;
390                         ac_gc_always_collect= ; ac_gimple_checking= ; ac_rtl_checking= ;
391                         ac_rtlflag_checking= ; ac_runtime_checking=1 ;
392                         ac_tree_checking= ; ac_valgrind_checking= ;
393                         ac_types_checking= ;;
394         # these enable particular checks
395         assert)         ac_assert_checking=1 ;;
396         df)             ac_df_checking=1 ;;
397         fold)           ac_fold_checking=1 ;;
398         gc)             ac_gc_checking=1 ;;
399         gcac)           ac_gc_always_collect=1 ;;
400         gimple)         ac_gimple_checking=1 ;;
401         misc)           ac_checking=1 ;;
402         rtl)            ac_rtl_checking=1 ;;
403         rtlflag)        ac_rtlflag_checking=1 ;;
404         runtime)        ac_runtime_checking=1 ;;
405         tree)           ac_tree_checking=1 ;;
406         types)          ac_types_checking=1 ;;
407         valgrind)       ac_valgrind_checking=1 ;;
408         *)      AC_MSG_ERROR(unknown check category $check) ;;
409         esac
410 done
411 IFS="$ac_save_IFS"
412
413 nocommon_flag=""
414 if test x$ac_checking != x ; then
415   AC_DEFINE(ENABLE_CHECKING, 1,
416 [Define if you want more run-time sanity checks.  This one gets a grab
417    bag of miscellaneous but relatively cheap checks.])
418   nocommon_flag=-fno-common
419 fi
420 AC_SUBST(nocommon_flag)
421 if test x$ac_df_checking != x ; then
422   AC_DEFINE(ENABLE_DF_CHECKING, 1,
423 [Define if you want more run-time sanity checks for dataflow.])
424 fi
425 if test x$ac_assert_checking != x ; then
426   AC_DEFINE(ENABLE_ASSERT_CHECKING, 1,
427 [Define if you want assertions enabled.  This is a cheap check.])
428 fi
429 if test x$ac_gimple_checking != x ; then
430   AC_DEFINE(ENABLE_GIMPLE_CHECKING, 1,
431 [Define if you want operations on GIMPLE (the basic data structure of
432 the high-level optimizers) to be checked for dynamic type safety at
433 runtime.  This is moderately expensive.])
434 fi
435 GCC_TARGET_TEMPLATE(ENABLE_RUNTIME_CHECKING)
436 if test x$ac_runtime_checking != x ; then
437   AC_DEFINE(ENABLE_RUNTIME_CHECKING, 1,
438 [Define if you want runtime assertions enabled.  This is a cheap check.])
439 fi
440 if test x$ac_tree_checking != x ; then
441   AC_DEFINE(ENABLE_TREE_CHECKING, 1,
442 [Define if you want all operations on trees (the basic data
443    structure of the front ends) to be checked for dynamic type safety
444    at runtime.  This is moderately expensive.  The tree browser debugging
445    routines will also be enabled by this option.
446    ])
447   TREEBROWSER=tree-browser.o
448 fi
449 if test x$ac_types_checking != x ; then
450   AC_DEFINE(ENABLE_TYPES_CHECKING, 1,
451 [Define if you want all gimple types to be verified after gimplifiation.
452    This is cheap.
453    ])
454 fi
455 AC_SUBST(TREEBROWSER)
456 if test x$ac_rtl_checking != x ; then
457   AC_DEFINE(ENABLE_RTL_CHECKING, 1,
458 [Define if you want all operations on RTL (the basic data structure
459    of the optimizer and back end) to be checked for dynamic type safety
460    at runtime.  This is quite expensive.])
461 fi
462 if test x$ac_rtlflag_checking != x ; then
463   AC_DEFINE(ENABLE_RTL_FLAG_CHECKING, 1,
464 [Define if you want RTL flag accesses to be checked against the RTL
465    codes that are supported for each access macro.  This is relatively
466    cheap.])
467 fi
468 if test x$ac_gc_checking != x ; then
469   AC_DEFINE(ENABLE_GC_CHECKING, 1,
470 [Define if you want the garbage collector to do object poisoning and
471    other memory allocation checks.  This is quite expensive.])
472 fi
473 if test x$ac_gc_always_collect != x ; then
474   AC_DEFINE(ENABLE_GC_ALWAYS_COLLECT, 1,
475 [Define if you want the garbage collector to operate in maximally
476    paranoid mode, validating the entire heap and collecting garbage at
477    every opportunity.  This is extremely expensive.])
478 fi
479 if test x$ac_fold_checking != x ; then
480   AC_DEFINE(ENABLE_FOLD_CHECKING, 1,
481 [Define if you want fold checked that it never destructs its argument.
482    This is quite expensive.])
483 fi
484 valgrind_path_defines=
485 valgrind_command=
486
487 dnl # This check AC_REQUIREs various stuff, so it *must not* be inside
488 dnl # an if statement.  This was the source of very frustrating bugs
489 dnl # in converting to autoconf 2.5x!
490 AC_CHECK_HEADER(valgrind.h, have_valgrind_h=yes, have_valgrind_h=no)
491
492 if test x$ac_valgrind_checking != x ; then
493   # It is certainly possible that there's valgrind but no valgrind.h.
494   # GCC relies on making annotations so we must have both.
495   AC_MSG_CHECKING(for VALGRIND_DISCARD in <valgrind/memcheck.h>)
496   AC_PREPROC_IFELSE([AC_LANG_SOURCE(
497     [[#include <valgrind/memcheck.h>
498 #ifndef VALGRIND_DISCARD
499 #error VALGRIND_DISCARD not defined
500 #endif]])],
501   [gcc_cv_header_valgrind_memcheck_h=yes],
502   [gcc_cv_header_valgrind_memcheck_h=no])
503   AC_MSG_RESULT($gcc_cv_header_valgrind_memcheck_h)
504   AC_MSG_CHECKING(for VALGRIND_DISCARD in <memcheck.h>)
505   AC_PREPROC_IFELSE([AC_LANG_SOURCE(
506     [[#include <memcheck.h>
507 #ifndef VALGRIND_DISCARD
508 #error VALGRIND_DISCARD not defined
509 #endif]])],
510   [gcc_cv_header_memcheck_h=yes],
511   [gcc_cv_header_memcheck_h=no])
512   AC_MSG_RESULT($gcc_cv_header_memcheck_h)
513   AM_PATH_PROG_WITH_TEST(valgrind_path, valgrind,
514         [$ac_dir/$ac_word --version | grep valgrind- >/dev/null 2>&1])
515   if test "x$valgrind_path" = "x" \
516     || (test $have_valgrind_h = no \
517         && test $gcc_cv_header_memcheck_h = no \
518         && test $gcc_cv_header_valgrind_memcheck_h = no); then
519         AC_MSG_ERROR([*** Can't find both valgrind and valgrind/memcheck.h, memcheck.h or valgrind.h])
520   fi
521   valgrind_path_defines=-DVALGRIND_PATH='\"'$valgrind_path'\"'
522   valgrind_command="$valgrind_path -q"
523   AC_DEFINE(ENABLE_VALGRIND_CHECKING, 1,
524 [Define if you want to run subprograms and generated programs
525    through valgrind (a memory checker).  This is extremely expensive.])
526   if test $gcc_cv_header_valgrind_memcheck_h = yes; then
527     AC_DEFINE(HAVE_VALGRIND_MEMCHECK_H, 1,
528         [Define if valgrind's valgrind/memcheck.h header is installed.])
529   fi
530   if test $gcc_cv_header_memcheck_h = yes; then
531     AC_DEFINE(HAVE_MEMCHECK_H, 1,
532         [Define if valgrind's memcheck.h header is installed.])
533   fi
534 fi
535 AC_SUBST(valgrind_path_defines)
536 AC_SUBST(valgrind_command)
537
538 # Enable code coverage collection
539 AC_ARG_ENABLE(coverage,
540 [  --enable-coverage[=LEVEL]
541                           enable compiler's code coverage collection.
542                           Use to measure compiler performance and locate
543                           unused parts of the compiler. With LEVEL, specify
544                           optimization. Values are opt, noopt,
545                           default is noopt],
546 [case "${enableval}" in
547   yes|noopt)
548     coverage_flags="-fprofile-arcs -ftest-coverage -frandom-seed=\$@ -O0"
549     ;;
550   opt)
551     coverage_flags="-fprofile-arcs -ftest-coverage -frandom-seed=\$@ -O2"
552     ;;
553   no)
554     # a.k.a. --disable-coverage
555     coverage_flags=""
556     ;;
557   *)
558     AC_MSG_ERROR(unknown coverage setting $enableval)
559     ;;
560 esac],
561 [coverage_flags=""])
562 AC_SUBST(coverage_flags)
563
564 AC_ARG_ENABLE(gather-detailed-mem-stats, 
565 [  --enable-gather-detailed-mem-stats         enable detailed memory allocation stats gathering], [],
566 [enable_gather_detailed_mem_stats=no])
567 if test x$enable_gather_detailed_mem_stats = xyes ; then
568   AC_DEFINE(GATHER_STATISTICS, 1,
569         [Define to enable detailed memory allocation stats gathering.])
570 fi
571
572 # -------------------------------
573 # Miscenalleous configure options
574 # -------------------------------
575
576 # With stabs
577 AC_ARG_WITH(stabs,
578 [  --with-stabs            arrange to use stabs instead of host debug format],
579 stabs="$with_stabs",
580 stabs=no)
581
582 # Determine whether or not multilibs are enabled.
583 AC_ARG_ENABLE(multilib,
584 [  --enable-multilib       enable library support for multiple ABIs],
585 [], [enable_multilib=yes])
586 AC_SUBST(enable_multilib)
587
588 # Enable __cxa_atexit for C++.
589 AC_ARG_ENABLE(__cxa_atexit,
590 [  --enable-__cxa_atexit   enable __cxa_atexit for C++],
591 [], [])
592
593 # Enable C extension for decimal float if target supports it.
594 AC_ARG_ENABLE(decimal-float,
595 [  --enable-decimal-float={no,yes,bid,dpd}
596                         enable decimal float extension to C.  Selecting 'bid'
597                         or 'dpd' choses which decimal floating point format
598                         to use],
599 [
600   case $enable_decimal_float in
601     yes | no | bid | dpd) ;;
602     *) AC_MSG_ERROR(['$enable_decimal_float' is an invalid value for --enable-decimal-float.
603 Valid choices are 'yes', 'bid', 'dpd', and 'no'.]) ;;
604   esac
605 ],
606 [
607   case $target in
608     powerpc*-*-linux* | i?86*-*-linux* | x86_64*-*-linux*)
609       enable_decimal_float=yes
610       ;;
611     *)
612       AC_MSG_WARN(decimal float is not supported for this target, ignored)
613       enable_decimal_float=no
614       ;;
615   esac
616 ])
617
618 dfp=`if test $enable_decimal_float != no; then echo 1; else echo 0; fi`
619 AC_DEFINE_UNQUOTED(ENABLE_DECIMAL_FLOAT, $dfp,
620 [Define to 1 to enable decimal float extension to C.])
621
622 # x86's use BID format instead of DPD
623 case x$enable_decimal_float in
624   xyes)
625     case $target in
626       i?86*-*-linux* | x86_64*-*-linux*)
627         enable_decimal_float=bid
628         ;;
629       *)
630         enable_decimal_float=dpd
631         ;;
632     esac
633     ;;
634   xno)
635     # ENABLE_DECIMAL_FLOAT is set to 0. But we have to have proper
636     # dependency on libdecnumber.
637     enable_decimal_float=dpd
638     ;;
639 esac
640 AC_SUBST(enable_decimal_float)
641
642 bid=`if test $enable_decimal_float = bid; then echo 1; else echo 0; fi`
643 AC_DEFINE_UNQUOTED(ENABLE_DECIMAL_BID_FORMAT, $bid,
644 [Define to 1 to specify that we are using the BID decimal floating
645 point format instead of DPD])
646
647 # Enable C extension for fixed-point arithmetic.
648 AC_ARG_ENABLE(fixed-point,
649 [  --enable-fixed-point    enable fixed-point arithmetic extension to C],
650 [
651 ],
652 [
653   case $target in
654     mips*-*-*)
655       case $host in
656         mips*-sgi-irix*)
657           AC_MSG_WARN(fixed-point is not supported on IRIX, ignored)
658           enable_fixed_point=no
659           ;;
660         *)
661           enable_fixed_point=yes
662           ;;
663       esac
664       ;;
665     *)
666       AC_MSG_WARN(fixed-point is not supported for this target, ignored)
667       enable_fixed_point=no
668       ;;
669   esac
670 ])
671 AC_SUBST(enable_fixed_point)
672
673 fixedpoint=`if test $enable_fixed_point = yes; then echo 1; else echo 0; fi`
674 AC_DEFINE_UNQUOTED(ENABLE_FIXED_POINT, $fixedpoint,
675 [Define to 1 to enable fixed-point arithmetic extension to C.])
676
677 # Enable threads
678 # Pass with no value to take the default
679 # Pass with a value to specify a thread package
680 AC_ARG_ENABLE(threads,
681 [  --enable-threads        enable thread usage for target GCC
682   --enable-threads=LIB    use LIB thread package for target GCC],,
683 [enable_threads=''])
684
685 AC_ARG_ENABLE(tls,
686 [  --enable-tls            enable or disable generation of tls code
687                           overriding the assembler check for tls support],
688 [
689   case $enable_tls in
690     yes | no) ;;
691     *) AC_MSG_ERROR(['$enable_tls' is an invalid value for --enable-tls.
692 Valid choices are 'yes' and 'no'.]) ;;
693   esac
694 ], [enable_tls=''])
695
696 AC_ARG_ENABLE(objc-gc,
697 [  --enable-objc-gc       enable the use of Boehm's garbage collector with
698                           the GNU Objective-C runtime],
699 if test x$enable_objc_gc = xno; then
700         objc_boehm_gc=''
701 else
702         objc_boehm_gc=1
703 fi,
704 objc_boehm_gc='')
705
706 AC_ARG_WITH(dwarf2,
707 [  --with-dwarf2           force the default debug format to be DWARF 2],
708 dwarf2="$with_dwarf2",
709 dwarf2=no)
710
711 AC_ARG_ENABLE(shared,
712 [  --disable-shared        don't provide a shared libgcc],
713 [
714   case $enable_shared in
715   yes | no) ;;
716   *)
717     enable_shared=no
718     IFS="${IFS=         }"; ac_save_ifs="$IFS"; IFS="${IFS}:,"
719     for pkg in $enableval; do
720       if test "X$pkg" = "Xgcc" || test "X$pkg" = "Xlibgcc"; then
721         enable_shared=yes
722       fi
723     done
724     IFS="$ac_save_ifs"
725     ;;
726   esac
727 ], [enable_shared=yes])
728 AC_SUBST(enable_shared)
729
730 AC_ARG_WITH(build-sysroot, 
731   [  --with-build-sysroot=sysroot
732                           use sysroot as the system root during the build])
733
734 AC_ARG_WITH(sysroot,
735 [  --with-sysroot[=DIR] Search for usr/lib, usr/include, et al, within DIR.],
736 [
737  case ${with_sysroot} in
738  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_noncanonical}/sys-root' ;;
739  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
740  esac
741    
742  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
743  CROSS_SYSTEM_HEADER_DIR='$(TARGET_SYSTEM_ROOT)$${sysroot_headers_suffix}$(NATIVE_SYSTEM_HEADER_DIR)'
744         
745  if test "x$prefix" = xNONE; then
746   test_prefix=/usr/local
747  else
748   test_prefix=$prefix
749  fi
750  if test "x$exec_prefix" = xNONE; then
751   test_exec_prefix=$test_prefix
752  else
753   test_exec_prefix=$exec_prefix
754  fi
755  case ${TARGET_SYSTEM_ROOT} in
756  "${test_prefix}"|"${test_prefix}/"*|\
757  "${test_exec_prefix}"|"${test_exec_prefix}/"*|\
758  '${prefix}'|'${prefix}/'*|\
759  '${exec_prefix}'|'${exec_prefix}/'*)
760    t="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE"
761    TARGET_SYSTEM_ROOT_DEFINE="$t"
762    ;;
763  esac
764 ], [
765  TARGET_SYSTEM_ROOT=
766  TARGET_SYSTEM_ROOT_DEFINE=
767  CROSS_SYSTEM_HEADER_DIR='$(gcc_tooldir)/sys-include'
768 ])
769 AC_SUBST(TARGET_SYSTEM_ROOT)
770 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
771 AC_SUBST(CROSS_SYSTEM_HEADER_DIR)
772
773 # Build with intermodule optimisations
774 AC_ARG_ENABLE(intermodule,
775 [  --enable-intermodule    build the compiler in one step],
776 [case ${enable_intermodule} in
777   yes) onestep="-onestep";;
778   *) onestep="";;
779 esac],
780 [onestep=""])
781 AC_SUBST(onestep)
782
783 ACX_PKGVERSION([GCC])
784 ACX_BUGURL([http://gcc.gnu.org/bugs.html])
785
786 # Sanity check enable_languages in case someone does not run the toplevel
787 # configure # script.
788 AC_ARG_ENABLE(languages,
789 [  --enable-languages=LIST specify which front-ends to build],
790 [case ,${enable_languages}, in
791        ,,|,yes,)
792                 # go safe -- we cannot be much sure without the toplevel
793                 # configure's
794                 # analysis of which target libs are present and usable
795                 enable_languages=c
796                 ;;
797          *,all,*)
798                 AC_MSG_ERROR([only the toplevel supports --enable-languages=all])
799                 ;;
800         *,c,*)
801                 ;;
802         *)
803                 enable_languages=c,${enable_languages}
804                 ;;
805 esac],
806 [enable_languages=c])
807
808 # Used by documentation targets
809 AC_SUBST(datarootdir)
810 AC_SUBST(docdir)
811 AC_SUBST(htmldir)
812
813 # -------------------------
814 # Checks for other programs
815 # -------------------------
816
817 AC_PROG_MAKE_SET
818
819 # Find some useful tools
820 AC_PROG_AWK
821 # We need awk to create options.c and options.h.
822 # Bail out if it's missing.
823 case ${AWK} in
824   "") AC_MSG_ERROR([can't build without awk, bailing out]) ;;
825 esac
826
827 gcc_AC_PROG_LN_S
828 ACX_PROG_LN($LN_S)
829 AC_PROG_RANLIB
830 case "${host}" in
831 *-*-darwin*)
832   # By default, the Darwin ranlib will not treat common symbols as
833   # definitions when  building the archive table of contents.  Other 
834   # ranlibs do that; pass an option to the Darwin ranlib that makes
835   # it behave similarly.
836   ranlib_flags="-c" 
837   ;;
838 *)
839   ranlib_flags=""
840 esac
841 AC_SUBST(ranlib_flags)
842      
843 gcc_AC_PROG_INSTALL
844
845 # See if cmp has --ignore-initial.
846 gcc_AC_PROG_CMP_IGNORE_INITIAL
847
848 # See if we have the mktemp command.
849 AC_CHECK_PROG(have_mktemp_command, mktemp, yes, no)
850
851 # See if makeinfo has been installed and is modern enough
852 # that we can use it.
853 ACX_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
854   [GNU texinfo.* \([0-9][0-9.]*\)],
855   [4.[7-9]*|4.[1-9][0-9]*|[5-9]*|[1-9][0-9]*])
856 if test $gcc_cv_prog_makeinfo_modern = no; then
857   AC_MSG_WARN([
858 *** Makeinfo is missing or too old.
859 *** Info documentation will not be built.])
860   BUILD_INFO=
861 else
862   BUILD_INFO=info
863 fi
864 AC_SUBST(BUILD_INFO)
865
866 # Is pod2man recent enough to regenerate manpages?
867 AC_MSG_CHECKING([for recent Pod::Man])
868 if (perl -e 'use 1.10 Pod::Man') >/dev/null 2>&1; then
869   AC_MSG_RESULT(yes)
870   GENERATED_MANPAGES=generated-manpages
871 else
872   AC_MSG_RESULT(no)
873   GENERATED_MANPAGES=
874 fi
875 AC_SUBST(GENERATED_MANPAGES)
876
877 MISSING="${CONFIG_SHELL-/bin/sh} $ac_aux_dir/missing"
878
879 # How about lex?
880 dnl Don't use AC_PROG_LEX; we insist on flex.
881 dnl LEXLIB is not useful in gcc.
882 AC_CHECK_PROGS([FLEX], flex, [$MISSING flex])
883
884 # Bison?
885 AC_CHECK_PROGS([BISON], bison, [$MISSING bison])
886
887 # Binutils are not build modules, unlike bison/flex/makeinfo.  So we
888 # check for build == host before using them.
889
890 # NM
891 if test x${build} = x${host} && test -f $srcdir/../binutils/nm.c \
892   && test -d ../binutils ; then
893   NM='$(objdir)/../binutils/nm-new'
894 else
895   AC_CHECK_PROG(NM, nm, nm, ${CONFIG_SHELL-/bin/sh} ${srcdir}/../missing nm)
896 fi
897
898 # AR
899 if test x${build} = x${host} && test -f $srcdir/../binutils/ar.c \
900   && test -d ../binutils ; then
901   AR='$(objdir)/../binutils/ar'
902 else
903   AC_CHECK_PROG(AR, ar, ar, ${CONFIG_SHELL-/bin/sh} ${srcdir}/../missing ar)
904 fi
905
906
907 # --------------------
908 # Checks for C headers
909 # --------------------
910
911 # Need to reject headers which give warnings, so that the -Werror bootstrap
912 # works later. *sigh*  This needs to come before all header checks.
913 AC_PROG_CPP_WERROR
914
915 AC_HEADER_STDC
916 AC_HEADER_TIME
917 ACX_HEADER_STRING
918 AC_HEADER_SYS_WAIT
919 AC_CHECK_HEADERS(limits.h stddef.h string.h strings.h stdlib.h time.h iconv.h \
920                  fcntl.h unistd.h sys/file.h sys/time.h sys/mman.h \
921                  sys/resource.h sys/param.h sys/times.h sys/stat.h \
922                  direct.h malloc.h langinfo.h ldfcn.h locale.h wchar.h)
923
924 # Check for thread headers.
925 AC_CHECK_HEADER(thread.h, [have_thread_h=yes], [have_thread_h=])
926 AC_CHECK_HEADER(pthread.h, [have_pthread_h=yes], [have_pthread_h=])
927
928 # These tests can't be done till we know if we have limits.h.
929 gcc_AC_C_CHAR_BIT
930 AC_C_BIGENDIAN
931
932 # --------
933 # UNSORTED
934 # --------
935
936
937 # These libraries may be used by collect2.
938 # We may need a special search path to get them linked.
939 AC_CACHE_CHECK(for collect2 libraries, gcc_cv_collect2_libs,
940 [save_LIBS="$LIBS"
941 for libs in '' -lld -lmld \
942                 '-L/usr/lib/cmplrs/cc2.11 -lmld' \
943                 '-L/usr/lib/cmplrs/cc3.11 -lmld'
944 do
945         LIBS="$libs"
946         AC_TRY_LINK_FUNC(ldopen,
947                 [gcc_cv_collect2_libs="$libs"; break])
948 done
949 LIBS="$save_LIBS"
950 test -z "$gcc_cv_collect2_libs" && gcc_cv_collect2_libs='none required'])
951 case $gcc_cv_collect2_libs in
952         "none required")        ;;
953         *)      COLLECT2_LIBS=$gcc_cv_collect2_libs ;;
954 esac
955 AC_SUBST(COLLECT2_LIBS)
956
957 # When building Ada code on Alpha, we need exc_resume which is usually in
958 # -lexc.  So test for it.
959 save_LIBS="$LIBS"
960 LIBS=
961 AC_SEARCH_LIBS(exc_resume, exc)
962 GNAT_LIBEXC="$LIBS"
963 LIBS="$save_LIBS"
964 AC_SUBST(GNAT_LIBEXC)
965
966 # Some systems put ldexp and frexp in libm instead of libc; assume
967 # they're both in the same place.  jcf-dump needs them.
968 save_LIBS="$LIBS"
969 LIBS=
970 AC_SEARCH_LIBS(ldexp, m)
971 LDEXP_LIB="$LIBS"
972 LIBS="$save_LIBS"
973 AC_SUBST(LDEXP_LIB)
974
975 # Use <inttypes.h> only if it exists,
976 # doesn't clash with <sys/types.h>, and declares intmax_t.
977 AC_MSG_CHECKING(for inttypes.h)
978 AC_CACHE_VAL(gcc_cv_header_inttypes_h,
979 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
980 [[#include <sys/types.h>
981 #include <inttypes.h>]],
982   [[intmax_t i = -1;]])],
983   [gcc_cv_header_inttypes_h=yes],
984   [gcc_cv_header_inttypes_h=no])])
985 AC_MSG_RESULT($gcc_cv_header_inttypes_h)
986 if test $gcc_cv_header_inttypes_h = yes; then
987   AC_DEFINE(HAVE_INTTYPES_H, 1,
988         [Define if you have a working <inttypes.h> header file.])
989 fi
990
991 dnl Disabled until we have a complete test for buggy enum bitfields.
992 dnl gcc_AC_C_ENUM_BF_UNSIGNED
993
994 define(gcc_UNLOCKED_FUNCS, clearerr_unlocked feof_unlocked dnl
995   ferror_unlocked fflush_unlocked fgetc_unlocked fgets_unlocked dnl
996   fileno_unlocked fprintf_unlocked fputc_unlocked fputs_unlocked dnl
997   fread_unlocked fwrite_unlocked getchar_unlocked getc_unlocked dnl
998   putchar_unlocked putc_unlocked)
999 AC_CHECK_FUNCS(times clock kill getrlimit setrlimit atoll atoq \
1000         sysconf strsignal getrusage nl_langinfo \
1001         gettimeofday mbstowcs wcswidth mmap mincore setlocale \
1002         gcc_UNLOCKED_FUNCS)
1003
1004 if test x$ac_cv_func_mbstowcs = xyes; then
1005   AC_CACHE_CHECK(whether mbstowcs works, gcc_cv_func_mbstowcs_works,
1006 [    AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdlib.h>
1007 int main()
1008 {
1009   mbstowcs(0, "", 0);
1010   return 0;
1011 }]])],
1012     [gcc_cv_func_mbstowcs_works=yes],
1013     [gcc_cv_func_mbstowcs_works=no],
1014     [gcc_cv_func_mbstowcs_works=yes])])
1015   if test x$gcc_cv_func_mbstowcs_works = xyes; then
1016     AC_DEFINE(HAVE_WORKING_MBSTOWCS, 1,
1017   [Define this macro if mbstowcs does not crash when its
1018    first argument is NULL.])
1019   fi
1020 fi
1021
1022 AC_CHECK_TYPE(ssize_t, int)
1023 AC_CHECK_TYPE(caddr_t, char *)
1024
1025 # Try to determine the array type of the second argument of getgroups
1026 # for the target system (int or gid_t).
1027 AC_TYPE_GETGROUPS
1028 if test "${target}" = "${build}"; then
1029   TARGET_GETGROUPS_T=$ac_cv_type_getgroups
1030 else
1031   case "${target}" in
1032         # This condition may need some tweaking.  It should include all
1033         # targets where the array type of the second argument of getgroups
1034         # is int and the type of gid_t is not equivalent to int.
1035         *-*-sunos* | *-*-ultrix*)
1036                 TARGET_GETGROUPS_T=int
1037                 ;;
1038         *)
1039                 TARGET_GETGROUPS_T=gid_t
1040                 ;;
1041   esac
1042 fi
1043 AC_SUBST(TARGET_GETGROUPS_T)
1044
1045 gcc_AC_FUNC_MMAP_BLACKLIST
1046
1047 case "${host}" in
1048 *-*-*vms*)
1049   # Under VMS, vfork works very differently than on Unix. The standard test 
1050   # won't work, and it isn't easily adaptable. It makes more sense to
1051   # just force it.
1052   ac_cv_func_vfork_works=yes
1053   ;;
1054 esac
1055 AC_FUNC_FORK
1056
1057 AM_ICONV
1058 # Until we have in-tree GNU iconv:
1059 LIBICONV_DEP=
1060 AC_SUBST(LIBICONV_DEP)
1061
1062 AM_LC_MESSAGES
1063
1064 AM_LANGINFO_CODESET
1065
1066 # We will need to find libiberty.h and ansidecl.h
1067 saved_CFLAGS="$CFLAGS"
1068 CFLAGS="$CFLAGS -I${srcdir} -I${srcdir}/../include"
1069 gcc_AC_CHECK_DECLS(getenv atol asprintf sbrk abort atof getcwd getwd \
1070         strsignal strstr strverscmp \
1071         errno snprintf vsnprintf vasprintf malloc realloc calloc \
1072         free basename getopt clock getpagesize gcc_UNLOCKED_FUNCS, , ,[
1073 #include "ansidecl.h"
1074 #include "system.h"])
1075
1076 gcc_AC_CHECK_DECLS(getrlimit setrlimit getrusage, , ,[
1077 #include "ansidecl.h"
1078 #include "system.h"
1079 #ifdef HAVE_SYS_RESOURCE_H
1080 #include <sys/resource.h>
1081 #endif
1082 ])
1083
1084 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1085 #include "ansidecl.h"
1086 #include "system.h"
1087 #ifdef HAVE_SYS_RESOURCE_H
1088 #include <sys/resource.h>
1089 #endif
1090 ]], [[rlim_t l = 0;]])],[],[AC_DEFINE([rlim_t],[long],
1091 [Define to `long' if <sys/resource.h> doesn't define.])])
1092
1093 # On AIX 5.2, <ldfcn.h> conflicts with <fcntl.h>, as both define incompatible
1094 # FREAD and FWRITE macros.  Fortunately, for GCC's single usage of ldgetname
1095 # in collect2.c, <fcntl.h> isn't visible, but the configure test below needs
1096 # to undef these macros to get the correct value for HAVE_DECL_LDGETNAME.
1097 gcc_AC_CHECK_DECLS(ldgetname, , ,[
1098 #include "ansidecl.h"
1099 #include "system.h"
1100 #ifdef HAVE_LDFCN_H
1101 #undef FREAD
1102 #undef FWRITE
1103 #include <ldfcn.h>
1104 #endif
1105 ])
1106
1107 gcc_AC_CHECK_DECLS(times, , ,[
1108 #include "ansidecl.h"
1109 #include "system.h"
1110 #ifdef HAVE_SYS_TIMES_H
1111 #include <sys/times.h>
1112 #endif
1113 ])
1114
1115 gcc_AC_CHECK_DECLS(sigaltstack, , ,[
1116 #include "ansidecl.h"
1117 #include "system.h"
1118 #include <signal.h>
1119 ])
1120
1121 # More time-related stuff.
1122 AC_CACHE_CHECK(for struct tms, ac_cv_struct_tms, [
1123 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1124 #include "ansidecl.h"
1125 #include "system.h"
1126 #ifdef HAVE_SYS_TIMES_H
1127 #include <sys/times.h>
1128 #endif
1129 ]], [[struct tms tms;]])],[ac_cv_struct_tms=yes],[ac_cv_struct_tms=no])])
1130 if test $ac_cv_struct_tms = yes; then
1131   AC_DEFINE(HAVE_STRUCT_TMS, 1,
1132   [Define if <sys/times.h> defines struct tms.])
1133 fi
1134
1135 # use gcc_cv_* here because this doesn't match the behavior of AC_CHECK_TYPE.
1136 # revisit after autoconf 2.50.
1137 AC_CACHE_CHECK(for clock_t, gcc_cv_type_clock_t, [
1138 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1139 #include "ansidecl.h"
1140 #include "system.h"
1141 ]], [[clock_t x;]])],[gcc_cv_type_clock_t=yes],[gcc_cv_type_clock_t=no])])
1142 if test $gcc_cv_type_clock_t = yes; then
1143   AC_DEFINE(HAVE_CLOCK_T, 1,
1144   [Define if <time.h> defines clock_t.])
1145 fi
1146
1147 # Restore CFLAGS from before the gcc_AC_NEED_DECLARATIONS tests.
1148 CFLAGS="$saved_CFLAGS"
1149
1150 gcc_AC_INITFINI_ARRAY
1151
1152 # mkdir takes a single argument on some systems. 
1153 gcc_AC_FUNC_MKDIR_TAKES_ONE_ARG
1154
1155 # File extensions
1156 manext='.1'
1157 objext='.o'
1158 AC_SUBST(manext)
1159 AC_SUBST(objext)
1160
1161 # With Setjmp/Longjmp based exception handling.
1162 AC_ARG_ENABLE(sjlj-exceptions,
1163 [  --enable-sjlj-exceptions
1164                           arrange to use setjmp/longjmp exception handling],
1165 [case $target in
1166   *-*-hpux10*)
1167     if test $enableval != yes; then
1168       AC_MSG_WARN([dwarf2 exceptions not supported, sjlj exceptions forced])
1169       enableval=yes
1170     fi
1171     ;;
1172 esac
1173 force_sjlj_exceptions=yes],
1174 [case $target in
1175   *-*-hpux10*)
1176     force_sjlj_exceptions=yes
1177     enableval=yes
1178     ;;
1179   *)
1180     force_sjlj_exceptions=no
1181     ;;
1182 esac])
1183 if test $force_sjlj_exceptions = yes; then
1184   sjlj=`if test $enableval = yes; then echo 1; else echo 0; fi`
1185   AC_DEFINE_UNQUOTED(CONFIG_SJLJ_EXCEPTIONS, $sjlj,
1186     [Define 0/1 to force the choice for exception handling model.])
1187 fi
1188
1189 # For platforms with the unwind ABI which includes an unwind library,
1190 # libunwind, we can choose to use the system libunwind.
1191 AC_ARG_WITH(system-libunwind,
1192 [  --with-system-libunwind use installed libunwind])
1193
1194 # config.gcc also contains tests of with_system_libunwind.
1195 if test x$with_system_libunwind = xyes; then
1196         AC_DEFINE(HAVE_GETIPINFO, 1,
1197 [Define to 1 if system unwind library has _Unwind_GetIPInfo.])
1198 fi
1199
1200 # --------------------------------------------------------
1201 # Build, host, and target specific configuration fragments
1202 # --------------------------------------------------------
1203
1204 # Collect build-machine-specific information.
1205 . ${srcdir}/config.build
1206
1207 # Collect host-machine-specific information.
1208 . ${srcdir}/config.host
1209
1210 target_gtfiles=
1211
1212 # Collect target-machine-specific information.
1213 . ${srcdir}/config.gcc
1214
1215 extra_objs="${host_extra_objs} ${extra_objs}"
1216 extra_gcc_objs="${host_extra_gcc_objs} ${extra_gcc_objs}"
1217
1218 # Default the target-machine variables that were not explicitly set.
1219 if test x"$tm_file" = x
1220 then tm_file=$cpu_type/$cpu_type.h; fi
1221
1222 if test x"$extra_headers" = x
1223 then extra_headers=; fi
1224
1225 if test x$md_file = x
1226 then md_file=$cpu_type/$cpu_type.md; fi
1227
1228 if test x$out_file = x
1229 then out_file=$cpu_type/$cpu_type.c; fi
1230
1231 if test x"$tmake_file" = x
1232 then tmake_file=$cpu_type/t-$cpu_type
1233 fi
1234
1235 if test x"$dwarf2" = xyes
1236 then tm_file="$tm_file tm-dwarf2.h"
1237 fi
1238
1239 # Say what files are being used for the output code and MD file.
1240 echo "Using \`$srcdir/config/$out_file' for machine-specific logic."
1241 echo "Using \`$srcdir/config/$md_file' as machine description file."
1242
1243 # If any of the xm_file variables contain nonexistent files, warn
1244 # about them and drop them.
1245
1246 bx=
1247 for x in $build_xm_file; do
1248   if    test -f $srcdir/config/$x
1249   then      bx="$bx $x"
1250   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1251   fi
1252 done
1253 build_xm_file="$bx"
1254
1255 hx=
1256 for x in $host_xm_file; do
1257   if    test -f $srcdir/config/$x
1258   then      hx="$hx $x"
1259   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1260   fi
1261 done
1262 host_xm_file="$hx"
1263
1264 tx=
1265 for x in $xm_file; do
1266   if    test -f $srcdir/config/$x
1267   then      tx="$tx $x"
1268   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1269   fi
1270 done
1271 xm_file="$tx"
1272
1273 count=a
1274 for f in $tm_file; do
1275         count=${count}x
1276 done
1277 if test $count = ax; then
1278         echo "Using \`$srcdir/config/$tm_file' as target machine macro file."
1279 else
1280         echo "Using the following target machine macro files:"
1281         for f in $tm_file; do
1282                 echo "  $srcdir/config/$f"
1283         done
1284 fi
1285
1286 if test x$need_64bit_hwint = xyes; then
1287         AC_DEFINE(NEED_64BIT_HOST_WIDE_INT, 1,
1288 [Define to 1 if HOST_WIDE_INT must be 64 bits wide (see hwint.h).])
1289 fi
1290
1291 if test x$use_long_long_for_widest_fast_int = xyes; then
1292         AC_DEFINE(USE_LONG_LONG_FOR_WIDEST_FAST_INT, 1,
1293 [Define to 1 if the 'long long' (or '__int64') is wider than 'long' but still
1294 efficiently supported by the host hardware.])
1295 fi
1296
1297 count=a
1298 for f in $host_xm_file; do
1299         count=${count}x
1300 done
1301 if test $count = a; then
1302         :
1303 elif test $count = ax; then
1304         echo "Using \`$srcdir/config/$host_xm_file' as host machine macro file."
1305 else
1306         echo "Using the following host machine macro files:"
1307         for f in $host_xm_file; do
1308                 echo "  $srcdir/config/$f"
1309         done
1310 fi
1311 echo "Using ${out_host_hook_obj} for host machine hooks."
1312
1313 if test "$host_xm_file" != "$build_xm_file"; then
1314         count=a
1315         for f in $build_xm_file; do
1316                 count=${count}x
1317         done
1318         if test $count = a; then
1319                 :
1320         elif test $count = ax; then
1321                 echo "Using \`$srcdir/config/$build_xm_file' as build machine macro file."
1322         else
1323                 echo "Using the following build machine macro files:"
1324                 for f in $build_xm_file; do
1325                         echo "  $srcdir/config/$f"
1326                 done
1327         fi
1328 fi
1329
1330 case ${host} in
1331   powerpc*-*-darwin*)
1332     AC_CACHE_CHECK([whether mcontext_t fields have underscores],
1333       gcc_cv_mcontext_underscores,
1334       AC_COMPILE_IFELSE([
1335 #include <sys/cdefs.h>
1336 #include <sys/signal.h>
1337 #include <ucontext.h>
1338 int main() { mcontext_t m; if (m->ss.srr0) return 0; return 0; }
1339 ],
1340         gcc_cv_mcontext_underscores=no, gcc_cv_mcontext_underscores=yes))
1341       if test $gcc_cv_mcontext_underscores = yes; then
1342         AC_DEFINE(HAS_MCONTEXT_T_UNDERSCORES,,dnl
1343           [mcontext_t fields start with __])
1344       fi
1345     ;;
1346 esac
1347
1348 # ---------
1349 # Threading
1350 # ---------
1351
1352 # Check if a valid thread package
1353 case ${enable_threads} in
1354   "" | no)
1355     # No threads
1356     target_thread_file='single'
1357     ;;
1358   yes)
1359     # default
1360     target_thread_file='single'
1361     ;;
1362   aix | dce | gnat | irix | posix | posix95 | rtems | \
1363   single | solaris | vxworks | win32 | mipssde)
1364     target_thread_file=${enable_threads}
1365     ;;
1366   *)
1367     echo "${enable_threads} is an unknown thread package" 1>&2
1368     exit 1
1369     ;;
1370 esac
1371
1372 if test x${thread_file} = x; then
1373   # No thread file set by target-specific clauses in config.gcc,
1374   # so use file chosen by default logic above
1375   thread_file=${target_thread_file}
1376 fi
1377
1378 # Make gthr-default.h if we have a thread file.
1379 gthread_flags=
1380 if test $thread_file != single; then
1381   echo "#include \"gthr-${thread_file}.h\"" > gthr-default.h-t
1382   if diff gthr-default.h-t gthr-default.h 2>/dev/null; then
1383     rm -f gthr-default.h-t
1384   else
1385     mv -f gthr-default.h-t gthr-default.h
1386   fi
1387   gthread_flags=-DHAVE_GTHR_DEFAULT
1388 fi
1389 AC_SUBST(gthread_flags)
1390
1391 # --------
1392 # UNSORTED
1393 # --------
1394
1395 use_cxa_atexit=no
1396 if test x$enable___cxa_atexit = xyes || \
1397    test x$enable___cxa_atexit = x -a x$default_use_cxa_atexit = xyes; then
1398   if test x$host = x$target; then
1399     case $host in
1400       # mingw32 doesn't have __cxa_atexit but uses atexit registration
1401       # keyed to flag_use_cxa_atexit
1402       *-*-mingw32*)
1403         use_cxa_atexit=yes
1404         ;;
1405       *)
1406         AC_CHECK_FUNC(__cxa_atexit,[use_cxa_atexit=yes],
1407           [echo "__cxa_atexit can't be enabled on this target"])
1408         ;;
1409     esac
1410   else
1411     # We can't check for __cxa_atexit when building a cross, so assume
1412     # it is available 
1413     use_cxa_atexit=yes
1414   fi
1415   if test x$use_cxa_atexit = xyes; then
1416     AC_DEFINE(DEFAULT_USE_CXA_ATEXIT, 2,
1417       [Define if you want to use __cxa_atexit, rather than atexit, to
1418       register C++ destructors for local statics and global objects.
1419       This is essential for fully standards-compliant handling of
1420       destructors, but requires __cxa_atexit in libc.])
1421   fi
1422 fi
1423
1424 use_getipinfo=yes
1425 if test x$with_system_libunwind = xyes; then
1426    if test x$host = x$target; then
1427      AC_SEARCH_LIBS(_Unwind_GetIPInfo, unwind,, [use_getipinfo=no])
1428    fi
1429 fi
1430 GCC_TARGET_TEMPLATE(HAVE_GETIPINFO)
1431 if test x$use_getipinfo = xyes; then
1432    AC_DEFINE(HAVE_GETIPINFO, 1,
1433         [Define to 1 if system unwind library has _Unwind_GetIPInfo.])
1434 else
1435    echo "The system unwind library does not support _Unwind_GetIPInfo."
1436 fi
1437
1438 # Look for a file containing extra machine modes.
1439 if test -n "$extra_modes" && test -f $srcdir/config/$extra_modes; then
1440   extra_modes_file='$(srcdir)'/config/${extra_modes}
1441   AC_SUBST(extra_modes_file)
1442   AC_DEFINE_UNQUOTED(EXTRA_MODES_FILE, "config/$extra_modes",
1443   [Define to the name of a file containing a list of extra machine modes
1444    for this architecture.])
1445 fi
1446
1447 # Convert extra_options into a form suitable for Makefile use.
1448 extra_opt_files=
1449 for f in $extra_options; do
1450   extra_opt_files="$extra_opt_files \$(srcdir)/config/$f"
1451 done
1452 AC_SUBST(extra_opt_files)
1453
1454 # auto-host.h is the file containing items generated by autoconf and is
1455 # the first file included by config.h.
1456 # If host=build, it is correct to have bconfig include auto-host.h
1457 # as well.  If host!=build, we are in error and need to do more 
1458 # work to find out the build config parameters.
1459 if test x$host = x$build
1460 then
1461         build_auto=auto-host.h
1462 else
1463         # We create a subdir, then run autoconf in the subdir.
1464         # To prevent recursion we set host and build for the new
1465         # invocation of configure to the build for this invocation
1466         # of configure. 
1467         tempdir=build.$$
1468         rm -rf $tempdir
1469         mkdir $tempdir
1470         cd $tempdir
1471         case ${srcdir} in
1472         /* | [A-Za-z]:[\\/]* ) realsrcdir=${srcdir};;
1473         *) realsrcdir=../${srcdir};;
1474         esac
1475         saved_CFLAGS="${CFLAGS}"
1476         CC="${CC_FOR_BUILD}" CFLAGS="${CFLAGS_FOR_BUILD}" \
1477         LDFLAGS="${LDFLAGS_FOR_BUILD}" \
1478         ${realsrcdir}/configure \
1479                 --enable-languages=${enable_languages-all} \
1480                 --target=$target_alias --host=$build_alias --build=$build_alias
1481         CFLAGS="${saved_CFLAGS}"
1482
1483         # We just finished tests for the build machine, so rename
1484         # the file auto-build.h in the gcc directory.
1485         mv auto-host.h ../auto-build.h
1486         cd ..
1487         rm -rf $tempdir
1488         build_auto=auto-build.h
1489 fi
1490 AC_SUBST(build_subdir)
1491
1492 tm_file="${tm_file} defaults.h"
1493 tm_p_file="${tm_p_file} tm-preds.h"
1494 host_xm_file="auto-host.h ansidecl.h ${host_xm_file}"
1495 build_xm_file="${build_auto} ansidecl.h ${build_xm_file}"
1496 # We don't want ansidecl.h in target files, write code there in ISO/GNU C.
1497 # put this back in temporarily.
1498 xm_file="auto-host.h ansidecl.h ${xm_file}"
1499
1500 # --------
1501 # UNSORTED
1502 # --------
1503
1504 changequote(,)dnl
1505 # Compile in configure arguments.
1506 if test -f configargs.h ; then
1507         # Being re-configured.
1508         gcc_config_arguments=`grep configuration_arguments configargs.h | sed -e 's/.*"\([^"]*\)".*/\1/'`
1509         gcc_config_arguments="$gcc_config_arguments : (reconfigured) $TOPLEVEL_CONFIGURE_ARGUMENTS"
1510 else
1511         gcc_config_arguments="$TOPLEVEL_CONFIGURE_ARGUMENTS"
1512 fi
1513
1514 # Double all backslashes and backslash all quotes to turn
1515 # gcc_config_arguments into a C string.
1516 sed -e 's/\\/\\\\/g; s/"/\\"/g' <<EOF >conftest.out
1517 $gcc_config_arguments
1518 EOF
1519 gcc_config_arguments_str=`cat conftest.out`
1520 rm -f conftest.out
1521
1522 cat > configargs.h <<EOF
1523 /* Generated automatically. */
1524 static const char configuration_arguments[] = "$gcc_config_arguments_str";
1525 static const char thread_model[] = "$thread_file";
1526
1527 static const struct {
1528   const char *name, *value;
1529 } configure_default_options[] = $configure_default_options;
1530 EOF
1531 changequote([,])dnl
1532
1533 # Internationalization
1534 ZW_GNU_GETTEXT_SISTER_DIR
1535
1536 # If LIBINTL contains LIBICONV, then clear LIBICONV so we don't get
1537 # -liconv on the link line twice.
1538 case "$LIBINTL" in *$LIBICONV*)
1539         LIBICONV= ;;
1540 esac
1541
1542 AC_ARG_ENABLE(secureplt,
1543 [  --enable-secureplt      enable -msecure-plt by default for PowerPC],
1544 [], [])
1545
1546 AC_ARG_ENABLE(cld,
1547 [  --enable-cld            enable -mcld by default for 32bit x86], [],
1548 [enable_cld=no])
1549
1550 # Windows32 Registry support for specifying GCC installation paths.
1551 AC_ARG_ENABLE(win32-registry,
1552 [  --disable-win32-registry
1553                           disable lookup of installation paths in the
1554                           Registry on Windows hosts
1555   --enable-win32-registry enable registry lookup (default)
1556   --enable-win32-registry=KEY
1557                           use KEY instead of GCC version as the last portion
1558                           of the registry key],,)
1559
1560 case $host_os in
1561   win32 | pe | cygwin* | mingw32* | uwin*)
1562     if test "x$enable_win32_registry" != xno; then
1563       AC_SEARCH_LIBS(RegOpenKeyExA, advapi32,, [enable_win32_registry=no])
1564     fi
1565
1566     if test "x$enable_win32_registry" != xno; then
1567       AC_DEFINE(ENABLE_WIN32_REGISTRY, 1,
1568   [Define to 1 if installation paths should be looked up in the Windows
1569    Registry. Ignored on non-Windows hosts.])
1570
1571       if test "x$enable_win32_registry" != xyes \
1572          && test "x$enable_win32_registry" != x; then
1573         AC_DEFINE_UNQUOTED(WIN32_REGISTRY_KEY, "$enable_win32_registry",
1574   [Define to be the last component of the Windows registry key under which
1575    to look for installation paths.  The full key used will be 
1576    HKEY_LOCAL_MACHINE/SOFTWARE/Free Software Foundation/{WIN32_REGISTRY_KEY}.
1577    The default is the GCC version number.])
1578       fi
1579     fi
1580   ;;
1581 esac
1582
1583 # Get an absolute path to the GCC top-level source directory
1584 holddir=`${PWDCMD-pwd}`
1585 cd $srcdir
1586 topdir=`${PWDCMD-pwd}`
1587 cd $holddir
1588
1589 # Conditionalize the makefile for this host machine.
1590 xmake_file=
1591 for f in ${host_xmake_file}
1592 do
1593         if test -f ${srcdir}/config/$f
1594         then
1595                 xmake_file="${xmake_file} \$(srcdir)/config/$f"
1596         fi
1597 done
1598
1599 # Conditionalize the makefile for this target machine.
1600 tmake_file_=
1601 for f in ${tmake_file}
1602 do
1603         if test -f ${srcdir}/config/$f
1604         then
1605                 tmake_file_="${tmake_file_} \$(srcdir)/config/$f"
1606         fi
1607 done
1608 tmake_file="${tmake_file_}"
1609
1610 out_object_file=`basename $out_file .c`.o
1611
1612 tm_file_list="options.h"
1613 tm_include_list="options.h"
1614 for f in $tm_file; do
1615   case $f in
1616     ./* )
1617        f=`echo $f | sed 's/^..//'`
1618        tm_file_list="${tm_file_list} $f"
1619        tm_include_list="${tm_include_list} $f"
1620        ;;
1621     defaults.h )
1622        tm_file_list="${tm_file_list} \$(srcdir)/$f"
1623        tm_include_list="${tm_include_list} $f"
1624        ;;
1625     * )
1626        tm_file_list="${tm_file_list} \$(srcdir)/config/$f"
1627        tm_include_list="${tm_include_list} config/$f"
1628        ;;
1629   esac
1630 done
1631
1632 tm_p_file_list=
1633 tm_p_include_list=
1634 for f in $tm_p_file; do
1635   case $f in
1636     tm-preds.h )
1637        tm_p_file_list="${tm_p_file_list} $f"
1638        tm_p_include_list="${tm_p_include_list} $f"
1639        ;;
1640     * )
1641        tm_p_file_list="${tm_p_file_list} \$(srcdir)/config/$f"
1642        tm_p_include_list="${tm_p_include_list} config/$f"
1643   esac
1644 done
1645
1646 xm_file_list=
1647 xm_include_list=
1648 for f in $xm_file; do
1649   case $f in
1650     ansidecl.h )
1651        xm_file_list="${xm_file_list} \$(srcdir)/../include/$f"
1652        xm_include_list="${xm_include_list} $f"
1653        ;;
1654     auto-host.h )
1655        xm_file_list="${xm_file_list} $f"
1656        xm_include_list="${xm_include_list} $f"
1657        ;;
1658     * )
1659        xm_file_list="${xm_file_list} \$(srcdir)/config/$f"
1660        xm_include_list="${xm_include_list} config/$f"
1661        ;;
1662   esac
1663 done
1664
1665 host_xm_file_list=
1666 host_xm_include_list=
1667 for f in $host_xm_file; do
1668   case $f in
1669     ansidecl.h )
1670        host_xm_file_list="${host_xm_file_list} \$(srcdir)/../include/$f"
1671        host_xm_include_list="${host_xm_include_list} $f"
1672        ;;
1673     auto-host.h )
1674        host_xm_file_list="${host_xm_file_list} $f"
1675        host_xm_include_list="${host_xm_include_list} $f"
1676        ;;
1677     * )
1678        host_xm_file_list="${host_xm_file_list} \$(srcdir)/config/$f"
1679        host_xm_include_list="${host_xm_include_list} config/$f"
1680        ;;
1681   esac
1682 done
1683
1684 build_xm_file_list=
1685 for f in $build_xm_file; do
1686   case $f in
1687     ansidecl.h )
1688        build_xm_file_list="${build_xm_file_list} \$(srcdir)/../include/$f"
1689        build_xm_include_list="${build_xm_include_list} $f"
1690        ;;
1691     auto-build.h | auto-host.h )
1692        build_xm_file_list="${build_xm_file_list} $f"
1693        build_xm_include_list="${build_xm_include_list} $f"
1694        ;;
1695     * )
1696        build_xm_file_list="${build_xm_file_list} \$(srcdir)/config/$f"
1697        build_xm_include_list="${build_xm_include_list} config/$f"
1698        ;;
1699   esac
1700 done
1701
1702 # Define macro CROSS_DIRECTORY_STRUCTURE in compilation if this is a
1703 # cross-compiler which does not use the native headers and libraries.
1704 # Also use all.cross instead of all.internal and adjust SYSTEM_HEADER_DIR.
1705 CROSS=                                          AC_SUBST(CROSS)
1706 ALL=all.internal                                AC_SUBST(ALL)
1707 SYSTEM_HEADER_DIR='$(NATIVE_SYSTEM_HEADER_DIR)' AC_SUBST(SYSTEM_HEADER_DIR)
1708
1709 if test "x$with_build_sysroot" != x; then
1710   build_system_header_dir=$with_build_sysroot'$${sysroot_headers_suffix}$(NATIVE_SYSTEM_HEADER_DIR)'
1711 else
1712   # This value is used, even on a native system, because 
1713   # CROSS_SYSTEM_HEADER_DIR is just 
1714   # $(TARGET_SYSTEM_ROOT)$(NATIVE_SYSTEM_HEADER_DIR).
1715   build_system_header_dir='$(CROSS_SYSTEM_HEADER_DIR)'
1716 fi
1717
1718 if test x$host != x$target
1719 then
1720         CROSS="-DCROSS_DIRECTORY_STRUCTURE"
1721         ALL=all.cross
1722         SYSTEM_HEADER_DIR=$build_system_header_dir
1723         case "$host","$target" in
1724         # Darwin crosses can use the host system's libraries and headers,
1725         # because of the fat library support.  Of course, it must be the
1726         # same version of Darwin on both sides.  Allow the user to
1727         # just say --target=foo-darwin without a version number to mean
1728         # "the version on this system".
1729             *-*-darwin*,*-*-darwin*)
1730                 hostos=`echo $host | sed 's/.*-darwin/darwin/'`
1731                 targetos=`echo $target | sed 's/.*-darwin/darwin/'`
1732                 if test $hostos = $targetos -o $targetos = darwin ; then
1733                     CROSS=
1734                     SYSTEM_HEADER_DIR='$(NATIVE_SYSTEM_HEADER_DIR)'
1735                     with_headers=yes
1736                 fi
1737                 ;;
1738
1739             i?86-*-*,x86_64-*-* \
1740             | powerpc*-*-*,powerpc64*-*-*)
1741                 CROSS="$CROSS -DNATIVE_CROSS" ;;
1742         esac
1743 elif test "x$TARGET_SYSTEM_ROOT" != x; then
1744         SYSTEM_HEADER_DIR=$build_system_header_dir 
1745 fi
1746
1747 # If this is a cross-compiler that does not
1748 # have its own set of headers then define
1749 # inhibit_libc
1750
1751 # If this is using newlib, without having the headers available now,
1752 # then define inhibit_libc in LIBGCC2_CFLAGS.
1753 # This prevents libgcc2 from containing any code which requires libc
1754 # support.
1755 : ${inhibit_libc=false}
1756 if { { test x$host != x$target && test "x$with_sysroot" = x ; } ||
1757        test x$with_newlib = xyes ; } &&
1758      { test "x$with_headers" = x || test "x$with_headers" = xno ; } ; then
1759        inhibit_libc=true
1760 fi
1761 AC_SUBST(inhibit_libc)
1762
1763 # When building gcc with a cross-compiler, we need to adjust things so
1764 # that the generator programs are still built with the native compiler.
1765 # Also, we cannot run fixincludes or fix-header.
1766
1767 # These are the normal (build=host) settings:
1768 CC_FOR_BUILD='$(CC)'            AC_SUBST(CC_FOR_BUILD)
1769 BUILD_CFLAGS='$(ALL_CFLAGS)'    AC_SUBST(BUILD_CFLAGS)
1770 BUILD_LDFLAGS='$(LDFLAGS)'      AC_SUBST(BUILD_LDFLAGS)
1771 STMP_FIXINC=stmp-fixinc         AC_SUBST(STMP_FIXINC)
1772
1773 # Possibly disable fixproto, on a per-target basis.
1774 case ${use_fixproto} in
1775   no)
1776     STMP_FIXPROTO=
1777     ;;
1778   yes)
1779     STMP_FIXPROTO=stmp-fixproto
1780     ;;
1781 esac
1782 AC_SUBST(STMP_FIXPROTO)
1783
1784 # And these apply if build != host, or we are generating coverage data
1785 if test x$build != x$host || test "x$coverage_flags" != x
1786 then
1787     BUILD_CFLAGS='$(INTERNAL_CFLAGS) $(T_CFLAGS) $(CFLAGS_FOR_BUILD)'
1788     BUILD_LDFLAGS='$(LDFLAGS_FOR_BUILD)'
1789
1790     if test "x$TARGET_SYSTEM_ROOT" = x; then
1791         if test "x$STMP_FIXPROTO" != x; then
1792           STMP_FIXPROTO=stmp-install-fixproto
1793         fi
1794     fi
1795 fi
1796
1797 # Expand extra_headers to include complete path.
1798 # This substitutes for lots of t-* files.
1799 extra_headers_list=
1800 # Prepend $(srcdir)/config/${cpu_type}/ to every entry in extra_headers.
1801 for file in ${extra_headers} ; do
1802   extra_headers_list="${extra_headers_list} \$(srcdir)/config/${cpu_type}/${file}"
1803 done
1804
1805 # If use_gcc_tgmath is set, append ginclude/tgmath.h.
1806 if test x"$use_gcc_tgmath" = xyes
1807 then extra_headers_list="${extra_headers_list} \$(srcdir)/ginclude/tgmath.h"
1808 fi
1809
1810 # Define collect2 in Makefile.
1811 case $host_can_use_collect2 in
1812   no) collect2= ;;
1813   *) collect2='collect2$(exeext)' ;;
1814 esac
1815 AC_SUBST([collect2])
1816
1817 # Add a definition of USE_COLLECT2 if system wants one.
1818 case $use_collect2 in
1819   no) use_collect2= ;;
1820   "") ;;
1821   *) 
1822     host_xm_defines="${host_xm_defines} USE_COLLECT2"
1823     xm_defines="${xm_defines} USE_COLLECT2"
1824     case $host_can_use_collect2 in
1825       no)
1826         AC_MSG_ERROR([collect2 is required but cannot be built on this system])
1827         ;;
1828     esac
1829     ;;
1830 esac
1831
1832 # ---------------------------
1833 # Assembler & linker features
1834 # ---------------------------
1835
1836 # During stage 2, ld is actually gcc/collect-ld, which is a small script to
1837 # discern between when to use prev-ld/ld-new and when to use ld/ld-new.
1838 # However when ld-new is first executed from the build tree, libtool will
1839 # relink it as .libs/lt-ld-new, so that it can give it an RPATH that refers
1840 # to the build tree.  While doing this we need to use the previous-stage
1841 # linker, or we have an infinite loop.  The presence of a shell script as
1842 # ld/ld-new, and the fact that the script *uses ld itself*, is what confuses
1843 # the gcc/collect-ld script.  So we need to know how libtool works, or
1844 # exec-tool will fail.
1845
1846 m4_defun([_LT_CONFIG_COMMANDS], [])
1847 AC_PROG_LIBTOOL
1848 AC_SUBST(objdir)
1849 AC_SUBST(enable_fast_install)
1850
1851 # Identify the assembler which will work hand-in-glove with the newly
1852 # built GCC, so that we can examine its features.  This is the assembler
1853 # which will be driven by the driver program.
1854 #
1855 # If build != host, and we aren't building gas in-tree, we identify a
1856 # build->target assembler and hope that it will have the same features
1857 # as the host->target assembler we'll be using.
1858 gcc_cv_gas_major_version=
1859 gcc_cv_gas_minor_version=
1860 gcc_cv_as_gas_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/gas
1861
1862 m4_pattern_allow([AS_FOR_TARGET])dnl
1863 AS_VAR_SET_IF(gcc_cv_as,, [
1864 if test -x "$DEFAULT_ASSEMBLER"; then
1865         gcc_cv_as="$DEFAULT_ASSEMBLER"
1866 elif test -f $gcc_cv_as_gas_srcdir/configure.in \
1867      && test -f ../gas/Makefile \
1868      && test x$build = x$host; then
1869         gcc_cv_as=../gas/as-new$build_exeext
1870 elif test -x as$build_exeext; then
1871         # Build using assembler in the current directory.
1872         gcc_cv_as=./as$build_exeext
1873 elif test -x $AS_FOR_TARGET; then
1874         gcc_cv_as="$AS_FOR_TARGET"
1875 else
1876         AC_PATH_PROG(gcc_cv_as, $AS_FOR_TARGET)
1877 fi])
1878
1879 ORIGINAL_AS_FOR_TARGET=$gcc_cv_as
1880 AC_SUBST(ORIGINAL_AS_FOR_TARGET)
1881 case "$ORIGINAL_AS_FOR_TARGET" in
1882   ./as | ./as$build_exeext) ;;
1883   *) AC_CONFIG_FILES(as:exec-tool.in, [chmod +x as]) ;;
1884 esac 
1885
1886 AC_MSG_CHECKING(what assembler to use)
1887 if test "$gcc_cv_as" = ../gas/as-new$build_exeext; then
1888   # Single tree build which includes gas.  We want to prefer it
1889   # over whatever linker top-level may have detected, since
1890   # we'll use what we're building after installation anyway.
1891   AC_MSG_RESULT(newly built gas)
1892   in_tree_gas=yes
1893   _gcc_COMPUTE_GAS_VERSION
1894   in_tree_gas_is_elf=no
1895   if grep 'obj_format = elf' ../gas/Makefile > /dev/null \
1896      || (grep 'obj_format = multi' ../gas/Makefile \
1897          && grep 'extra_objects =.* obj-elf' ../gas/Makefile) > /dev/null
1898   then
1899     in_tree_gas_is_elf=yes
1900   fi
1901 else
1902   AC_MSG_RESULT($gcc_cv_as)
1903   in_tree_gas=no
1904 fi
1905
1906 # Identify the linker which will work hand-in-glove with the newly
1907 # built GCC, so that we can examine its features.  This is the linker
1908 # which will be driven by the driver program.
1909 #
1910 # If build != host, and we aren't building gas in-tree, we identify a
1911 # build->target linker and hope that it will have the same features
1912 # as the host->target linker we'll be using.
1913 gcc_cv_gld_major_version=
1914 gcc_cv_gld_minor_version=
1915 gcc_cv_ld_gld_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/ld
1916 gcc_cv_ld_bfd_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/bfd
1917
1918 AS_VAR_SET_IF(gcc_cv_ld,, [
1919 if test -x "$DEFAULT_LINKER"; then
1920         gcc_cv_ld="$DEFAULT_LINKER"
1921 elif test -f $gcc_cv_ld_gld_srcdir/configure.in \
1922      && test -f ../ld/Makefile \
1923      && test x$build = x$host; then
1924         gcc_cv_ld=../ld/ld-new$build_exeext
1925 elif test -x collect-ld$build_exeext; then
1926         # Build using linker in the current directory.
1927         gcc_cv_ld=./collect-ld$build_exeext
1928 elif test -x $LD_FOR_TARGET; then
1929         gcc_cv_ld="$LD_FOR_TARGET"
1930 else
1931         AC_PATH_PROG(gcc_cv_ld, $LD_FOR_TARGET)
1932 fi])
1933
1934 ORIGINAL_LD_FOR_TARGET=$gcc_cv_ld
1935 AC_SUBST(ORIGINAL_LD_FOR_TARGET)
1936 case "$ORIGINAL_LD_FOR_TARGET" in
1937   ./collect-ld | ./collect-ld$build_exeext) ;;
1938   *) AC_CONFIG_FILES(collect-ld:exec-tool.in, [chmod +x collect-ld]) ;;
1939 esac 
1940
1941 AC_MSG_CHECKING(what linker to use)
1942 if test "$gcc_cv_ld" = ../ld/ld-new$build_exeext; then
1943         # Single tree build which includes ld.  We want to prefer it
1944         # over whatever linker top-level may have detected, since
1945         # we'll use what we're building after installation anyway.
1946         AC_MSG_RESULT(newly built ld)
1947         in_tree_ld=yes
1948         in_tree_ld_is_elf=no
1949         if (grep 'EMUL = .*elf' ../ld/Makefile \
1950             || grep 'EMUL = .*linux' ../ld/Makefile \
1951             || grep 'EMUL = .*lynx' ../ld/Makefile) > /dev/null; then
1952           in_tree_ld_is_elf=yes
1953         fi
1954         for f in $gcc_cv_ld_bfd_srcdir/configure $gcc_cv_ld_gld_srcdir/configure $gcc_cv_ld_gld_srcdir/configure.in $gcc_cv_ld_gld_srcdir/Makefile.in
1955         do
1956 changequote(,)dnl
1957                 gcc_cv_gld_version=`sed -n -e 's/^[     ]*\(VERSION=[0-9]*\.[0-9]*.*\)/\1/p' < $f`
1958                 if test x$gcc_cv_gld_version != x; then
1959                         break
1960                 fi
1961         done
1962         gcc_cv_gld_major_version=`expr "$gcc_cv_gld_version" : "VERSION=\([0-9]*\)"`
1963         gcc_cv_gld_minor_version=`expr "$gcc_cv_gld_version" : "VERSION=[0-9]*\.\([0-9]*\)"`
1964 changequote([,])dnl
1965 else
1966         AC_MSG_RESULT($gcc_cv_ld)
1967         in_tree_ld=no
1968 fi
1969
1970 # Figure out what nm we will be using.
1971 gcc_cv_binutils_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/binutils
1972 AS_VAR_SET_IF(gcc_cv_nm,, [
1973 if test -f $gcc_cv_binutils_srcdir/configure.in \
1974      && test -f ../binutils/Makefile \
1975      && test x$build = x$host; then
1976         gcc_cv_nm=../binutils/nm-new$build_exeext
1977 elif test -x nm$build_exeext; then
1978         gcc_cv_nm=./nm$build_exeext
1979 elif test -x $NM_FOR_TARGET; then
1980         gcc_cv_nm="$NM_FOR_TARGET"
1981 else
1982         AC_PATH_PROG(gcc_cv_nm, $NM_FOR_TARGET)
1983 fi])
1984
1985 AC_MSG_CHECKING(what nm to use)
1986 if test "$gcc_cv_nm" = ../binutils/nm-new$build_exeext; then
1987         # Single tree build which includes binutils.
1988         AC_MSG_RESULT(newly built nm)
1989         in_tree_nm=yes
1990 else
1991         AC_MSG_RESULT($gcc_cv_nm)
1992         in_tree_nm=no
1993 fi
1994
1995 ORIGINAL_NM_FOR_TARGET=$gcc_cv_nm
1996 AC_SUBST(ORIGINAL_NM_FOR_TARGET)
1997 case "$ORIGINAL_NM_FOR_TARGET" in
1998   ./nm | ./nm$build_exeext) ;;
1999   *) AC_CONFIG_FILES(nm:exec-tool.in, [chmod +x nm]) ;;
2000 esac
2001
2002
2003 # Figure out what objdump we will be using.
2004 AS_VAR_SET_IF(gcc_cv_objdump,, [
2005 if test -f $gcc_cv_binutils_srcdir/configure.in \
2006      && test -f ../binutils/Makefile \
2007      && test x$build = x$host; then
2008         # Single tree build which includes binutils.
2009         gcc_cv_objdump=../binutils/objdump$build_exeext
2010 elif test -x objdump$build_exeext; then
2011         gcc_cv_objdump=./objdump$build_exeext
2012 elif test -x $OBJDUMP_FOR_TARGET; then
2013         gcc_cv_objdump="$OBJDUMP_FOR_TARGET"
2014 else
2015         AC_PATH_PROG(gcc_cv_objdump, $OBJDUMP_FOR_TARGET)
2016 fi])
2017
2018 AC_MSG_CHECKING(what objdump to use)
2019 if test "$gcc_cv_objdump" = ../binutils/objdump$build_exeext; then
2020         # Single tree build which includes binutils.
2021         AC_MSG_RESULT(newly built objdump)
2022 elif test x$gcc_cv_objdump = x; then
2023         AC_MSG_RESULT(not found)
2024 else
2025         AC_MSG_RESULT($gcc_cv_objdump)
2026 fi
2027
2028 # Figure out what assembler alignment features are present.
2029 gcc_GAS_CHECK_FEATURE([.balign and .p2align], gcc_cv_as_balign_and_p2align,
2030  [2,6,0],,
2031 [.balign 4
2032 .p2align 2],,
2033 [AC_DEFINE(HAVE_GAS_BALIGN_AND_P2ALIGN, 1,
2034   [Define if your assembler supports .balign and .p2align.])])
2035
2036 gcc_GAS_CHECK_FEATURE([.p2align with maximum skip], gcc_cv_as_max_skip_p2align,
2037  [2,8,0],,
2038  [.p2align 4,,7],,
2039 [AC_DEFINE(HAVE_GAS_MAX_SKIP_P2ALIGN, 1,
2040   [Define if your assembler supports specifying the maximum number
2041    of bytes to skip when using the GAS .p2align command.])])
2042
2043 gcc_GAS_CHECK_FEATURE([.literal16], gcc_cv_as_literal16,
2044  [2,8,0],,
2045  [.literal16],,
2046 [AC_DEFINE(HAVE_GAS_LITERAL16, 1,
2047   [Define if your assembler supports .literal16.])])
2048
2049 gcc_GAS_CHECK_FEATURE([working .subsection -1], gcc_cv_as_subsection_m1,
2050  [elf,2,9,0],,
2051  [conftest_label1: .word 0
2052 .subsection -1
2053 conftest_label2: .word 0
2054 .previous],
2055  [if test x$gcc_cv_nm != x; then
2056     $gcc_cv_nm conftest.o | grep conftest_label1 > conftest.nm1
2057     $gcc_cv_nm conftest.o | grep conftest_label2 | sed -e 's/label2/label1/' > conftest.nm2
2058     if cmp conftest.nm1 conftest.nm2 > /dev/null 2>&1
2059     then :
2060     else gcc_cv_as_subsection_m1=yes
2061     fi
2062     rm -f conftest.nm1 conftest.nm2
2063   fi],
2064  [AC_DEFINE(HAVE_GAS_SUBSECTION_ORDERING, 1,
2065   [Define if your assembler supports .subsection and .subsection -1 starts
2066    emitting at the beginning of your section.])])
2067
2068 gcc_GAS_CHECK_FEATURE([.weak], gcc_cv_as_weak,
2069  [2,2,0],,
2070  [      .weak foobar],,
2071 [AC_DEFINE(HAVE_GAS_WEAK, 1, [Define if your assembler supports .weak.])])
2072
2073 gcc_GAS_CHECK_FEATURE([.weakref], gcc_cv_as_weakref,
2074  [2,17,0],,
2075  [      .weakref foobar, barfnot],,
2076 [AC_DEFINE(HAVE_GAS_WEAKREF, 1, [Define if your assembler supports .weakref.])])
2077
2078 gcc_GAS_CHECK_FEATURE([.nsubspa comdat], gcc_cv_as_nsubspa_comdat,
2079  [2,15,91],,
2080  [      .SPACE $TEXT$
2081         .NSUBSPA $CODE$,COMDAT],,
2082 [AC_DEFINE(HAVE_GAS_NSUBSPA_COMDAT, 1, [Define if your assembler supports .nsubspa comdat option.])])
2083
2084 # .hidden needs to be supported in both the assembler and the linker,
2085 # because GNU LD versions before 2.12.1 have buggy support for STV_HIDDEN.
2086 # This is irritatingly difficult to feature test for; we have to check the
2087 # date string after the version number.  If we've got an in-tree
2088 # ld, we don't know its patchlevel version, so we set the baseline at 2.13
2089 # to be safe.
2090 # The gcc_GAS_CHECK_FEATURE call just sets a cache variable.
2091 gcc_GAS_CHECK_FEATURE([.hidden], gcc_cv_as_hidden,
2092  [elf,2,13,0],,
2093 [       .hidden foobar
2094 foobar:])
2095
2096 AC_CACHE_CHECK(linker for .hidden support, gcc_cv_ld_hidden,
2097 [if test $in_tree_ld = yes ; then
2098   gcc_cv_ld_hidden=no
2099   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 13 -o "$gcc_cv_gld_major_version" -gt 2 \
2100      && test $in_tree_ld_is_elf = yes; then
2101      gcc_cv_ld_hidden=yes
2102   fi
2103 else
2104   gcc_cv_ld_hidden=yes
2105   ld_ver=`$gcc_cv_ld --version 2>/dev/null | sed 1q`
2106   if echo "$ld_ver" | grep GNU > /dev/null; then
2107 changequote(,)dnl
2108     ld_vers=`echo $ld_ver | sed -n \
2109         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*.*\)$,\1,p'`
2110     ld_date=`echo $ld_ver | sed -n 's,^.*\([2-9][0-9][0-9][0-9]\)[-]*\([01][0-9]\)[-]*\([0-3][0-9]\).*$,\1\2\3,p'`
2111     ld_vers_major=`expr "$ld_vers" : '\([0-9]*\)'`
2112     ld_vers_minor=`expr "$ld_vers" : '[0-9]*\.\([0-9]*\)'`
2113     ld_vers_patch=`expr "$ld_vers" : '[0-9]*\.[0-9]*\.\([0-9]*\)'`
2114     if test 0"$ld_date" -lt 20020404; then
2115       if test -n "$ld_date"; then
2116         # If there was date string, but was earlier than 2002-04-04, fail
2117         gcc_cv_ld_hidden=no
2118       elif test -z "$ld_vers"; then
2119         # If there was no date string nor ld version number, something is wrong
2120         gcc_cv_ld_hidden=no
2121       else
2122         test -z "$ld_vers_patch" && ld_vers_patch=0
2123         if test "$ld_vers_major" -lt 2; then
2124           gcc_cv_ld_hidden=no
2125         elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -lt 12; then
2126           gcc_cv_ld_hidden="no"
2127         elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -eq 12 -a "$ld_vers_patch" -eq 0; then
2128           gcc_cv_ld_hidden=no
2129         fi
2130       fi
2131 changequote([,])dnl
2132     fi
2133   else
2134     case "${target}" in
2135       hppa64*-*-hpux* | ia64*-*-hpux*)
2136         gcc_cv_ld_hidden=yes
2137         ;;
2138       *)
2139         gcc_cv_ld_hidden=no
2140         ;;
2141     esac
2142   fi
2143 fi])
2144 libgcc_visibility=no
2145 AC_SUBST(libgcc_visibility)
2146 GCC_TARGET_TEMPLATE([HAVE_GAS_HIDDEN])
2147 if test $gcc_cv_as_hidden = yes && test $gcc_cv_ld_hidden = yes; then
2148   libgcc_visibility=yes
2149   AC_DEFINE(HAVE_GAS_HIDDEN, 1,
2150   [Define if your assembler and linker support .hidden.])
2151 fi
2152
2153 # Check if we have .[us]leb128, and support symbol arithmetic with it.
2154 gcc_GAS_CHECK_FEATURE([.sleb128 and .uleb128], gcc_cv_as_leb128,
2155   [elf,2,11,0],,
2156 [       .data
2157         .uleb128 L2 - L1
2158 L1:
2159         .uleb128 1280
2160         .sleb128 -1010
2161 L2:],
2162  [# GAS versions before 2.11 do not support uleb128,
2163   # despite appearing to.
2164   # ??? There exists an elf-specific test that will crash
2165   # the assembler.  Perhaps it's better to figure out whether
2166   # arbitrary sections are supported and try the test.
2167   as_ver=`$gcc_cv_as --version 2>/dev/null | sed 1q`
2168   if echo "$as_ver" | grep GNU > /dev/null; then
2169 changequote(,)dnl
2170     as_vers=`echo $as_ver | sed -n \
2171         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*.*\)$,\1,p'`
2172     as_major=`expr "$as_vers" : '\([0-9]*\)'`
2173     as_minor=`expr "$as_vers" : '[0-9]*\.\([0-9]*\)'`
2174 changequote([,])dnl
2175     if test $as_major -eq 2 && test $as_minor -lt 11
2176     then :
2177     else gcc_cv_as_leb128=yes
2178     fi
2179   fi],
2180   [AC_DEFINE(HAVE_AS_LEB128, 1,
2181     [Define if your assembler supports .sleb128 and .uleb128.])])
2182
2183 # Check if we have assembler support for unwind directives.
2184 gcc_GAS_CHECK_FEATURE([cfi directives], gcc_cv_as_cfi_directive,
2185   ,,
2186 [       .text
2187         .cfi_startproc
2188         .cfi_offset 0, 0
2189         .cfi_same_value 1
2190         .cfi_def_cfa 1, 2
2191         .cfi_escape 1, 2, 3, 4, 5
2192         .cfi_endproc])
2193 AC_DEFINE_UNQUOTED(HAVE_GAS_CFI_DIRECTIVE,
2194   [`if test $gcc_cv_as_cfi_directive = yes; then echo 1; else echo 0; fi`],
2195   [Define 0/1 if your assembler supports CFI directives.])
2196
2197 gcc_GAS_CHECK_FEATURE([cfi personality directive],
2198   gcc_cv_as_cfi_personality_directive, ,,
2199 [       .text
2200         .cfi_startproc
2201         .cfi_personality 0, symbol
2202         .cfi_endproc])
2203 AC_DEFINE_UNQUOTED(HAVE_GAS_CFI_PERSONALITY_DIRECTIVE,
2204   [`if test $gcc_cv_as_cfi_personality_directive = yes;
2205     then echo 1; else echo 0; fi`],
2206   [Define 0/1 if your assembler supports .cfi_personality.])
2207
2208 # GAS versions up to and including 2.11.0 may mis-optimize
2209 # .eh_frame data.
2210 gcc_GAS_CHECK_FEATURE(eh_frame optimization, gcc_cv_as_eh_frame,
2211   [elf,2,12,0],,
2212 [       .text
2213 .LFB1:
2214         .4byte  0
2215 .L1:
2216         .4byte  0
2217 .LFE1:
2218         .section        .eh_frame,"aw",@progbits
2219 __FRAME_BEGIN__:
2220         .4byte  .LECIE1-.LSCIE1
2221 .LSCIE1:
2222         .4byte  0x0
2223         .byte   0x1
2224         .ascii "z\0"
2225         .byte   0x1
2226         .byte   0x78
2227         .byte   0x1a
2228         .byte   0x0
2229         .byte   0x4
2230         .4byte  1
2231         .p2align 1
2232 .LECIE1:
2233 .LSFDE1:
2234         .4byte  .LEFDE1-.LASFDE1
2235 .LASFDE1:
2236         .4byte  .LASFDE1-__FRAME_BEGIN__
2237         .4byte  .LFB1
2238         .4byte  .LFE1-.LFB1
2239         .byte   0x4
2240         .4byte  .LFE1-.LFB1
2241         .byte   0x4
2242         .4byte  .L1-.LFB1
2243 .LEFDE1:],
2244 [  dnl # For autoconf 2.5x, must protect trailing spaces with @&t@.
2245 cat > conftest.lit <<EOF
2246  0000 10000000 00000000 017a0001 781a0004  .........z..x...
2247  0010 01000000 12000000 18000000 00000000  ................
2248  0020 08000000 04080000 0044               .........D      @&t@
2249 EOF
2250 cat > conftest.big <<EOF
2251  0000 00000010 00000000 017a0001 781a0004  .........z..x...
2252  0010 00000001 00000012 00000018 00000000  ................
2253  0020 00000008 04000000 0844               .........D      @&t@
2254 EOF
2255   # If the assembler didn't choke, and we can objdump,
2256   # and we got the correct data, then succeed.
2257   # The text in the here-document typically retains its unix-style line
2258   # endings, while the output of objdump will use host line endings.
2259   # Therefore, use diff -b for the comparisons.
2260   if test x$gcc_cv_objdump != x \
2261   && $gcc_cv_objdump -s -j .eh_frame conftest.o 2>/dev/null \
2262      | tail -3 > conftest.got \
2263   && { diff -b conftest.lit conftest.got > /dev/null 2>&1 \
2264     || diff -b conftest.big conftest.got > /dev/null 2>&1; }
2265   then
2266     gcc_cv_as_eh_frame=yes
2267   elif AC_TRY_COMMAND($gcc_cv_as -o conftest.o --traditional-format /dev/null); then
2268     gcc_cv_as_eh_frame=buggy
2269   else
2270     # Uh oh, what do we do now?
2271     gcc_cv_as_eh_frame=no
2272   fi])
2273
2274 if test $gcc_cv_as_eh_frame = buggy; then
2275   AC_DEFINE(USE_AS_TRADITIONAL_FORMAT, 1,
2276   [Define if your assembler mis-optimizes .eh_frame data.])
2277 fi
2278
2279 gcc_GAS_CHECK_FEATURE(section merging support, gcc_cv_as_shf_merge,
2280  [elf,2,12,0], [--fatal-warnings],
2281  [.section .rodata.str, "aMS", @progbits, 1])
2282 if test $gcc_cv_as_shf_merge = no; then
2283   gcc_GAS_CHECK_FEATURE(section merging support, gcc_cv_as_shf_merge,
2284     [elf,2,12,0], [--fatal-warnings],
2285     [.section .rodata.str, "aMS", %progbits, 1])
2286 fi
2287 AC_DEFINE_UNQUOTED(HAVE_GAS_SHF_MERGE,
2288   [`if test $gcc_cv_as_shf_merge = yes; then echo 1; else echo 0; fi`],
2289 [Define 0/1 if your assembler supports marking sections with SHF_MERGE flag.])
2290
2291 gcc_GAS_CHECK_FEATURE(COMDAT group support, gcc_cv_as_comdat_group,
2292  [elf,2,16,0], [--fatal-warnings],
2293  [.section .text,"axG",@progbits,.foo,comdat])
2294 if test $gcc_cv_as_comdat_group = yes; then
2295   gcc_cv_as_comdat_group_percent=no
2296 else
2297  gcc_GAS_CHECK_FEATURE(COMDAT group support, gcc_cv_as_comdat_group_percent,
2298    [elf,2,16,0], [--fatal-warnings],
2299    [.section .text,"axG",%progbits,.foo,comdat])
2300 fi
2301 if test $in_tree_ld != yes && test x"$ld_vers" != x; then
2302   comdat_group=yes
2303   if test 0"$ld_date" -lt 20050308; then
2304     if test -n "$ld_date"; then
2305       # If there was date string, but was earlier than 2005-03-08, fail
2306       comdat_group=no
2307     elif test "$ld_vers_major" -lt 2; then
2308       comdat_group=no
2309     elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -lt 16; then
2310       comdat_group=no
2311     fi
2312   fi
2313 else
2314   # assume linkers other than GNU ld don't support COMDAT group
2315   comdat_group=no
2316 fi
2317 if test $comdat_group = no; then
2318   gcc_cv_as_comdat_group=no
2319   gcc_cv_as_comdat_group_percent=no
2320 fi
2321 AC_DEFINE_UNQUOTED(HAVE_COMDAT_GROUP,
2322   [`if test $gcc_cv_as_comdat_group = yes || test $gcc_cv_as_comdat_group_percent = yes; then echo 1; else echo 0; fi`],
2323 [Define 0/1 if your assembler and linker support COMDAT groups.])
2324
2325 # Thread-local storage - the check is heavily parametrized.
2326 conftest_s=
2327 tls_first_major=
2328 tls_first_minor=
2329 tls_as_opt=
2330 case "$target" in
2331 changequote(,)dnl
2332   alpha*-*-*)
2333     conftest_s='
2334         .section ".tdata","awT",@progbits
2335 foo:    .long   25
2336         .text
2337         ldq     $27,__tls_get_addr($29)         !literal!1
2338         lda     $16,foo($29)                    !tlsgd!1
2339         jsr     $26,($27),__tls_get_addr        !lituse_tlsgd!1
2340         ldq     $27,__tls_get_addr($29)         !literal!2
2341         lda     $16,foo($29)                    !tlsldm!2
2342         jsr     $26,($27),__tls_get_addr        !lituse_tlsldm!2
2343         ldq     $1,foo($29)                     !gotdtprel
2344         ldah    $2,foo($29)                     !dtprelhi
2345         lda     $3,foo($2)                      !dtprello
2346         lda     $4,foo($29)                     !dtprel
2347         ldq     $1,foo($29)                     !gottprel
2348         ldah    $2,foo($29)                     !tprelhi
2349         lda     $3,foo($2)                      !tprello
2350         lda     $4,foo($29)                     !tprel'
2351         tls_first_major=2
2352         tls_first_minor=13
2353         tls_as_opt=--fatal-warnings
2354         ;;
2355   frv*-*-*)
2356     conftest_s='
2357         .section ".tdata","awT",@progbits
2358 x:      .long   25
2359         .text
2360         call    #gettlsoff(x)'
2361         tls_first_major=2
2362         tls_first_minor=14
2363         ;;
2364   hppa*-*-linux*)
2365     conftest_s='
2366 t1:     .reg    %r20
2367 t2:     .reg    %r21
2368 gp:     .reg    %r19
2369         .section ".tdata","awT",@progbits
2370 foo:    .long   25
2371         .text
2372         .align  4
2373         addil LT%foo-$tls_gdidx$,gp
2374         ldo RT%foo-$tls_gdidx$(%r1),%arg0
2375         b __tls_get_addr
2376         nop             
2377         addil LT%foo-$tls_ldidx$,gp
2378         b __tls_get_addr
2379         ldo RT%foo-$tls_ldidx$(%r1),%arg0
2380         addil LR%foo-$tls_dtpoff$,%ret0
2381         ldo RR%foo-$tls_dtpoff$(%r1),%t1
2382         mfctl %cr27,%t1                 
2383         addil LT%foo-$tls_ieoff$,gp
2384         ldw RT%foo-$tls_ieoff$(%r1),%t2
2385         add %t1,%t2,%t3                 
2386         mfctl %cr27,%t1                 
2387         addil LR%foo-$tls_leoff$,%t1
2388         ldo RR%foo-$tls_leoff$(%r1),%t2'
2389         tls_first_major=2
2390         tls_first_minor=15
2391         tls_as_opt=--fatal-warnings
2392         ;;
2393   arm*-*-*)
2394     conftest_s='
2395         .section ".tdata","awT",%progbits
2396 foo:    .long   25
2397         .text
2398 .word foo(gottpoff)
2399 .word foo(tpoff)
2400 .word foo(tlsgd)
2401 .word foo(tlsldm)
2402 .word foo(tlsldo)'
2403         tls_first_major=2
2404         tls_first_minor=17
2405         ;;
2406   i[34567]86-*-*)
2407     conftest_s='
2408         .section ".tdata","awT",@progbits
2409 foo:    .long   25
2410         .text
2411         movl    %gs:0, %eax
2412         leal    foo@TLSGD(,%ebx,1), %eax
2413         leal    foo@TLSLDM(%ebx), %eax
2414         leal    foo@DTPOFF(%eax), %edx
2415         movl    foo@GOTTPOFF(%ebx), %eax
2416         subl    foo@GOTTPOFF(%ebx), %eax
2417         addl    foo@GOTNTPOFF(%ebx), %eax
2418         movl    foo@INDNTPOFF, %eax
2419         movl    $foo@TPOFF, %eax
2420         subl    $foo@TPOFF, %eax
2421         leal    foo@NTPOFF(%ecx), %eax'
2422         tls_first_major=2
2423         tls_first_minor=14
2424         tls_as_opt=--fatal-warnings
2425         ;;
2426   x86_64-*-*)
2427     conftest_s='
2428         .section ".tdata","awT",@progbits
2429 foo:    .long   25
2430         .text
2431         movq    %fs:0, %rax
2432         leaq    foo@TLSGD(%rip), %rdi
2433         leaq    foo@TLSLD(%rip), %rdi
2434         leaq    foo@DTPOFF(%rax), %rdx
2435         movq    foo@GOTTPOFF(%rip), %rax
2436         movq    $foo@TPOFF, %rax'
2437         tls_first_major=2
2438         tls_first_minor=14
2439         tls_as_opt=--fatal-warnings
2440         ;;
2441   ia64-*-*)
2442     conftest_s='
2443         .section ".tdata","awT",@progbits
2444 foo:    data8   25
2445         .text
2446         addl    r16 = @ltoff(@dtpmod(foo#)), gp
2447         addl    r17 = @ltoff(@dtprel(foo#)), gp
2448         addl    r18 = @ltoff(@tprel(foo#)), gp
2449         addl    r19 = @dtprel(foo#), gp
2450         adds    r21 = @dtprel(foo#), r13
2451         movl    r23 = @dtprel(foo#)
2452         addl    r20 = @tprel(foo#), gp
2453         adds    r22 = @tprel(foo#), r13
2454         movl    r24 = @tprel(foo#)'
2455         tls_first_major=2
2456         tls_first_minor=13
2457         tls_as_opt=--fatal-warnings
2458         ;;
2459   mips*-*-*)
2460     conftest_s='
2461         .section .tdata,"awT",@progbits
2462 x:
2463         .word 2
2464         .text
2465         addiu $4, $28, %tlsgd(x)
2466         addiu $4, $28, %tlsldm(x)
2467         lui $4, %dtprel_hi(x)
2468         addiu $4, $4, %dtprel_lo(x)
2469         lw $4, %gottprel(x)($28)
2470         lui $4, %tprel_hi(x)
2471         addiu $4, $4, %tprel_lo(x)'
2472         tls_first_major=2
2473         tls_first_minor=16
2474         tls_as_opt='-32 --fatal-warnings'
2475         ;;
2476   powerpc-*-*)
2477     conftest_s='
2478         .section ".tdata","awT",@progbits
2479         .align 2
2480 ld0:    .space 4
2481 ld1:    .space 4
2482 x1:     .space 4
2483 x2:     .space 4
2484 x3:     .space 4
2485         .text
2486         addi 3,31,ld0@got@tlsgd
2487         bl __tls_get_addr
2488         addi 3,31,x1@got@tlsld
2489         bl __tls_get_addr
2490         addi 9,3,x1@dtprel
2491         addis 9,3,x2@dtprel@ha
2492         addi 9,9,x2@dtprel@l
2493         lwz 9,x3@got@tprel(31)
2494         add 9,9,x@tls
2495         addi 9,2,x1@tprel
2496         addis 9,2,x2@tprel@ha
2497         addi 9,9,x2@tprel@l'
2498         tls_first_major=2
2499         tls_first_minor=14
2500         tls_as_opt="-a32 --fatal-warnings"
2501         ;;
2502   powerpc64-*-*)
2503     conftest_s='
2504         .section ".tdata","awT",@progbits
2505         .align 3
2506 ld0:    .space 8
2507 ld1:    .space 8
2508 x1:     .space 8
2509 x2:     .space 8
2510 x3:     .space 8
2511         .text
2512         addi 3,2,ld0@got@tlsgd
2513         bl .__tls_get_addr
2514         nop
2515         addi 3,2,ld1@toc
2516         bl .__tls_get_addr
2517         nop
2518         addi 3,2,x1@got@tlsld
2519         bl .__tls_get_addr
2520         nop
2521         addi 9,3,x1@dtprel
2522         bl .__tls_get_addr
2523         nop
2524         addis 9,3,x2@dtprel@ha
2525         addi 9,9,x2@dtprel@l
2526         bl .__tls_get_addr
2527         nop
2528         ld 9,x3@got@dtprel(2)
2529         add 9,9,3
2530         bl .__tls_get_addr
2531         nop'
2532         tls_first_major=2
2533         tls_first_minor=14
2534         tls_as_opt="-a64 --fatal-warnings"
2535         ;;
2536   s390-*-*)
2537     conftest_s='
2538         .section ".tdata","awT",@progbits
2539 foo:    .long   25
2540         .text
2541         .long   foo@TLSGD
2542         .long   foo@TLSLDM
2543         .long   foo@DTPOFF
2544         .long   foo@NTPOFF
2545         .long   foo@GOTNTPOFF
2546         .long   foo@INDNTPOFF
2547         l       %r1,foo@GOTNTPOFF(%r12)
2548         l       %r1,0(%r1):tls_load:foo
2549         bas     %r14,0(%r1,%r13):tls_gdcall:foo
2550         bas     %r14,0(%r1,%r13):tls_ldcall:foo'
2551         tls_first_major=2
2552         tls_first_minor=14
2553         tls_as_opt="-m31 --fatal-warnings"
2554         ;;
2555   s390x-*-*)
2556     conftest_s='
2557         .section ".tdata","awT",@progbits
2558 foo:    .long   25
2559         .text
2560         .quad   foo@TLSGD
2561         .quad   foo@TLSLDM
2562         .quad   foo@DTPOFF
2563         .quad   foo@NTPOFF
2564         .quad   foo@GOTNTPOFF
2565         lg      %r1,foo@GOTNTPOFF(%r12)
2566         larl    %r1,foo@INDNTPOFF
2567         brasl   %r14,__tls_get_offset@PLT:tls_gdcall:foo
2568         brasl   %r14,__tls_get_offset@PLT:tls_ldcall:foo'
2569         tls_first_major=2
2570         tls_first_minor=14
2571         tls_as_opt="-m64 -Aesame --fatal-warnings"
2572         ;;
2573   sh-*-* | sh[34]-*-*)
2574     conftest_s='
2575         .section ".tdata","awT",@progbits
2576 foo:    .long   25
2577         .text
2578         .long   foo@TLSGD
2579         .long   foo@TLSLDM
2580         .long   foo@DTPOFF
2581         .long   foo@GOTTPOFF
2582         .long   foo@TPOFF'
2583         tls_first_major=2
2584         tls_first_minor=13
2585         tls_as_opt=--fatal-warnings
2586         ;;
2587   sparc*-*-*)
2588     case "$target" in
2589       sparc*-sun-solaris2.[56789]*)
2590         # TLS was introduced in the Solaris 9 4/04 release but
2591         # we do not enable it by default on Solaris 9 either.
2592         if test "x$enable_tls" = xyes ; then
2593           on_solaris=yes
2594         else
2595           enable_tls=no;
2596         fi
2597         ;;
2598       sparc*-sun-solaris2.*)
2599         on_solaris=yes
2600         ;;
2601       *)
2602         on_solaris=no
2603         ;;
2604     esac
2605     if test x$on_solaris = xyes && test x$gas_flag = xno; then
2606       conftest_s='
2607         .section ".tdata",#alloc,#write,#tls
2608 foo:    .long   25
2609         .text
2610         sethi   %tgd_hi22(foo), %o0
2611         add     %o0, %tgd_lo10(foo), %o1
2612         add     %l7, %o1, %o0, %tgd_add(foo)
2613         call    __tls_get_addr, %tgd_call(foo)
2614         sethi   %tldm_hi22(foo), %l1
2615         add     %l1, %tldm_lo10(foo), %l2
2616         add     %l7, %l2, %o0, %tldm_add(foo)
2617         call    __tls_get_addr, %tldm_call(foo)
2618         sethi   %tldo_hix22(foo), %l3
2619         xor     %l3, %tldo_lox10(foo), %l4
2620         add     %o0, %l4, %l5, %tldo_add(foo)
2621         sethi   %tie_hi22(foo), %o3
2622         add     %o3, %tie_lo10(foo), %o3
2623         ld      [%l7 + %o3], %o2, %tie_ld(foo)
2624         add     %g7, %o2, %o4, %tie_add(foo)
2625         sethi   %tle_hix22(foo), %l1
2626         xor     %l1, %tle_lox10(foo), %o5
2627         ld      [%g7 + %o5], %o1'
2628         tls_first_major=0
2629         tls_first_minor=0
2630     else
2631       conftest_s='
2632         .section ".tdata","awT",@progbits
2633 foo:    .long   25
2634         .text
2635         sethi   %tgd_hi22(foo), %o0
2636         add     %o0, %tgd_lo10(foo), %o1
2637         add     %l7, %o1, %o0, %tgd_add(foo)
2638         call    __tls_get_addr, %tgd_call(foo)
2639         sethi   %tldm_hi22(foo), %l1
2640         add     %l1, %tldm_lo10(foo), %l2
2641         add     %l7, %l2, %o0, %tldm_add(foo)
2642         call    __tls_get_addr, %tldm_call(foo)
2643         sethi   %tldo_hix22(foo), %l3
2644         xor     %l3, %tldo_lox10(foo), %l4
2645         add     %o0, %l4, %l5, %tldo_add(foo)
2646         sethi   %tie_hi22(foo), %o3
2647         add     %o3, %tie_lo10(foo), %o3
2648         ld      [%l7 + %o3], %o2, %tie_ld(foo)
2649         add     %g7, %o2, %o4, %tie_add(foo)
2650         sethi   %tle_hix22(foo), %l1
2651         xor     %l1, %tle_lox10(foo), %o5
2652         ld      [%g7 + %o5], %o1'
2653         tls_first_major=2
2654         tls_first_minor=14
2655         tls_as_opt="-32 --fatal-warnings"
2656       fi
2657         ;;
2658 changequote([,])dnl
2659 esac
2660 set_have_as_tls=no
2661 if test "x$enable_tls" = xno ; then
2662   : # TLS explicitly disabled.
2663 elif test "x$enable_tls" = xyes ; then
2664   set_have_as_tls=yes # TLS explicitly enabled.
2665 elif test -z "$tls_first_major"; then
2666   : # If we don't have a check, assume no support.
2667 else
2668   gcc_GAS_CHECK_FEATURE(thread-local storage support, gcc_cv_as_tls,
2669   [$tls_first_major,$tls_first_minor,0], [$tls_as_opt], [$conftest_s],,
2670   [set_have_as_tls=yes])
2671 fi
2672 if test $set_have_as_tls = yes ; then
2673   AC_DEFINE(HAVE_AS_TLS, 1,
2674             [Define if your assembler supports thread-local storage.])
2675 fi
2676
2677 # Target-specific assembler checks.
2678
2679 AC_MSG_CHECKING(linker -Bstatic/-Bdynamic option)
2680 gcc_cv_ld_static_dynamic=no
2681 if test $in_tree_ld = yes ; then
2682   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 10; then
2683     gcc_cv_ld_static_dynamic=yes
2684   fi
2685 elif test x$gcc_cv_ld != x; then
2686         # Check if linker supports -Bstatic/-Bdynamic option
2687         if $gcc_cv_ld --help 2>/dev/null | grep -- -Bstatic > /dev/null \
2688           && $gcc_cv_ld --help 2>/dev/null | grep -- -Bdynamic > /dev/null; then
2689                 gcc_cv_ld_static_dynamic=yes
2690         fi
2691 fi
2692 if test x"$gcc_cv_ld_static_dynamic" = xyes; then
2693         AC_DEFINE(HAVE_LD_STATIC_DYNAMIC, 1,
2694 [Define if your linker supports -Bstatic/-Bdynamic option.])
2695 fi
2696 AC_MSG_RESULT($gcc_cv_ld_static_dynamic)
2697
2698 if test x"$demangler_in_ld" = xyes; then
2699   AC_MSG_CHECKING(linker --demangle support)
2700   gcc_cv_ld_demangle=no
2701   if test $in_tree_ld = yes; then
2702     if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 14 -o "$gcc_cv_gld_major_version" -gt 2; then \
2703       gcc_cv_ld_demangle=yes
2704     fi
2705   elif test x$gcc_cv_ld != x -a x"$gnu_ld" = xyes; then
2706     # Check if the GNU linker supports --demangle option
2707     if $gcc_cv_ld --help 2>/dev/null | grep no-demangle > /dev/null; then
2708       gcc_cv_ld_demangle=yes
2709     fi
2710   fi
2711   if test x"$gcc_cv_ld_demangle" = xyes; then
2712     AC_DEFINE(HAVE_LD_DEMANGLE, 1,
2713 [Define if your linker supports --demangle option.])
2714   fi
2715   AC_MSG_RESULT($gcc_cv_ld_demangle)
2716 fi
2717
2718 case "$target" in
2719   # All TARGET_ABI_OSF targets.
2720   alpha*-*-osf* | alpha*-*-linux* | alpha*-*-*bsd*)
2721     gcc_GAS_CHECK_FEATURE([explicit relocation support],
2722         gcc_cv_as_alpha_explicit_relocs, [2,12,0],,
2723 [       .set nomacro
2724         .text
2725         extbl   $3, $2, $3      !lituse_bytoff!1
2726         ldq     $2, a($29)      !literal!1
2727         ldq     $4, b($29)      !literal!2
2728         ldq_u   $3, 0($2)       !lituse_base!1
2729         ldq     $27, f($29)     !literal!5
2730         jsr     $26, ($27), f   !lituse_jsr!5
2731         ldah    $29, 0($26)     !gpdisp!3
2732         lda     $0, c($29)      !gprel
2733         ldah    $1, d($29)      !gprelhigh
2734         lda     $1, d($1)       !gprellow
2735         lda     $29, 0($29)     !gpdisp!3],,
2736     [AC_DEFINE(HAVE_AS_EXPLICIT_RELOCS, 1,
2737   [Define if your assembler supports explicit relocations.])])
2738     gcc_GAS_CHECK_FEATURE([jsrdirect relocation support],
2739         gcc_cv_as_alpha_jsrdirect_relocs, [2,16,90],,
2740 [       .set nomacro
2741         .text
2742         ldq     $27, a($29)     !literal!1
2743         jsr     $26, ($27), a   !lituse_jsrdirect!1],,
2744     [AC_DEFINE(HAVE_AS_JSRDIRECT_RELOCS, 1,
2745   [Define if your assembler supports the lituse_jsrdirect relocation.])])
2746     ;;
2747
2748   cris-*-*)
2749     gcc_GAS_CHECK_FEATURE([-no-mul-bug-abort option],
2750       gcc_cv_as_cris_no_mul_bug,[2,15,91],
2751       [-no-mul-bug-abort], [.text],,
2752       [AC_DEFINE(HAVE_AS_NO_MUL_BUG_ABORT_OPTION, 1,
2753                 [Define if your assembler supports the -no-mul-bug-abort option.])])
2754     ;;
2755
2756   sparc*-*-*)
2757     gcc_GAS_CHECK_FEATURE([.register], gcc_cv_as_sparc_register_op,,,
2758       [.register %g2, #scratch],,
2759       [AC_DEFINE(HAVE_AS_REGISTER_PSEUDO_OP, 1,
2760                 [Define if your assembler supports .register.])])
2761
2762     gcc_GAS_CHECK_FEATURE([-relax option], gcc_cv_as_sparc_relax,,
2763       [-relax], [.text],,
2764       [AC_DEFINE(HAVE_AS_RELAX_OPTION, 1,
2765                 [Define if your assembler supports -relax option.])])
2766
2767     gcc_GAS_CHECK_FEATURE([unaligned pcrel relocs],
2768       gcc_cv_as_sparc_ua_pcrel,,
2769       [-K PIC],
2770 [.text
2771 foo:
2772         nop
2773 .data
2774 .align 4
2775 .byte 0
2776 .uaword %r_disp32(foo)],
2777       [if test x$gcc_cv_ld != x \
2778        && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1; then
2779          gcc_cv_as_sparc_ua_pcrel=yes
2780        fi
2781        rm -f conftest],
2782       [AC_DEFINE(HAVE_AS_SPARC_UA_PCREL, 1,
2783                 [Define if your assembler and linker support unaligned PC relative relocs.])
2784
2785       gcc_GAS_CHECK_FEATURE([unaligned pcrel relocs against hidden symbols],
2786         gcc_cv_as_sparc_ua_pcrel_hidden,,
2787         [-K PIC],
2788 [.data
2789 .align 4
2790 .byte 0x31
2791 .uaword %r_disp32(foo)
2792 .byte 0x32, 0x33, 0x34
2793 .global foo
2794 .hidden foo
2795 foo:
2796 .skip 4],
2797         [if test x$gcc_cv_ld != x && test x$gcc_cv_objdump != x \
2798          && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1 \
2799          && $gcc_cv_objdump -s -j .data conftest 2> /dev/null \
2800             | grep ' 31000000 07323334' > /dev/null 2>&1; then
2801             if $gcc_cv_objdump -R conftest 2> /dev/null \
2802                | grep 'DISP32' > /dev/null 2>&1; then
2803                 :
2804             else
2805                 gcc_cv_as_sparc_ua_pcrel_hidden=yes
2806             fi
2807          fi
2808          rm -f conftest],
2809          [AC_DEFINE(HAVE_AS_SPARC_UA_PCREL_HIDDEN, 1,
2810                    [Define if your assembler and linker support unaligned PC relative relocs against hidden symbols.])])
2811     ]) # unaligned pcrel relocs
2812
2813     gcc_GAS_CHECK_FEATURE([offsetable %lo()],
2814       gcc_cv_as_sparc_offsetable_lo10,,
2815       [-xarch=v9],
2816 [.text
2817         or %g1, %lo(ab) + 12, %g1
2818         or %g1, %lo(ab + 12), %g1],
2819       [if test x$gcc_cv_objdump != x \
2820        && $gcc_cv_objdump -s -j .text conftest.o 2> /dev/null \
2821           | grep ' 82106000 82106000' > /dev/null 2>&1; then
2822          gcc_cv_as_sparc_offsetable_lo10=yes
2823        fi],
2824        [AC_DEFINE(HAVE_AS_OFFSETABLE_LO10, 1,
2825                  [Define if your assembler supports offsetable %lo().])])
2826     ;;
2827
2828 changequote(,)dnl
2829   i[34567]86-*-* | x86_64-*-*)
2830 changequote([,])dnl
2831     case $target_os in
2832       cygwin* | pe | mingw32*)
2833         # Used for DWARF 2 in PE
2834         gcc_GAS_CHECK_FEATURE([.secrel32 relocs],
2835           gcc_cv_as_ix86_pe_secrel32,
2836           [2,15,91],,
2837 [.text
2838 foo:    nop
2839 .data
2840         .secrel32 foo],
2841           [if test x$gcc_cv_ld != x \
2842            && $gcc_cv_ld -o conftest conftest.o > /dev/null 2>&1; then
2843              gcc_cv_as_ix86_pe_secrel32=yes
2844            fi
2845            rm -f conftest],
2846           [AC_DEFINE(HAVE_GAS_PE_SECREL32_RELOC, 1,
2847             [Define if your assembler and linker support 32-bit section relative relocs via '.secrel32 label'.])])
2848         ;;
2849     esac
2850
2851     gcc_GAS_CHECK_FEATURE([filds and fists mnemonics],
2852        gcc_cv_as_ix86_filds_fists,
2853       [2,9,0],, [filds mem; fists mem],,
2854       [AC_DEFINE(HAVE_GAS_FILDS_FISTS, 1,
2855         [Define if your assembler uses the new HImode fild and fist notation.])])
2856
2857     gcc_GAS_CHECK_FEATURE([cmov syntax],
2858       gcc_cv_as_ix86_cmov_sun_syntax,,,
2859       [cmovl.l %edx, %eax],,
2860       [AC_DEFINE(HAVE_AS_IX86_CMOV_SUN_SYNTAX, 1,
2861         [Define if your assembler supports the Sun syntax for cmov.])])
2862
2863     gcc_GAS_CHECK_FEATURE([ffreep mnemonic],
2864       gcc_cv_as_ix86_ffreep,,,
2865       [ffreep %st(1)],,
2866       [AC_DEFINE(HAVE_AS_IX86_FFREEP, 1,
2867         [Define if your assembler supports the ffreep mnemonic.])])
2868
2869     gcc_GAS_CHECK_FEATURE([sahf mnemonic],
2870       gcc_cv_as_ix86_sahf,,,
2871       [sahf],,
2872       [AC_DEFINE(HAVE_AS_IX86_SAHF, 1,
2873         [Define if your assembler supports the sahf mnemonic.])])
2874
2875     gcc_GAS_CHECK_FEATURE([different section symbol subtraction],
2876       gcc_cv_as_ix86_diff_sect_delta,,,
2877       [.section .rodata
2878 .L1:
2879         .long .L2-.L1
2880         .long .L3-.L1
2881         .text
2882 .L3:    nop
2883 .L2:    nop],,
2884       [AC_DEFINE(HAVE_AS_IX86_DIFF_SECT_DELTA, 1,
2885         [Define if your assembler supports the subtraction of symbols in different sections.])])
2886
2887     # This one is used unconditionally by i386.[ch]; it is to be defined
2888     # to 1 if the feature is present, 0 otherwise.
2889     gcc_GAS_CHECK_FEATURE([GOTOFF in data],
2890         gcc_cv_as_ix86_gotoff_in_data, [2,11,0],,
2891 [       .text
2892 .L0:
2893         nop
2894         .data
2895         .long .L0@GOTOFF])
2896     AC_DEFINE_UNQUOTED(HAVE_AS_GOTOFF_IN_DATA,
2897       [`if test $gcc_cv_as_ix86_gotoff_in_data = yes; then echo 1; else echo 0; fi`],
2898       [Define true if the assembler supports '.long foo@GOTOFF'.])
2899     ;;
2900
2901   ia64*-*-*)
2902     gcc_GAS_CHECK_FEATURE([ltoffx and ldxmov relocs],
2903         gcc_cv_as_ia64_ltoffx_ldxmov_relocs, [2,14,0],,
2904 [       .text
2905         addl r15 = @ltoffx(x#), gp
2906         ;;
2907         ld8.mov r16 = [[r15]], x#],,
2908     [AC_DEFINE(HAVE_AS_LTOFFX_LDXMOV_RELOCS, 1,
2909           [Define if your assembler supports ltoffx and ldxmov relocations.])])
2910
2911     ;;
2912
2913   powerpc*-*-*)
2914     case $target in
2915       *-*-aix*) conftest_s='    .machine "pwr5"
2916         .csect .text[[PR]]
2917         mfcr 3,128';;
2918       *-*-darwin*)
2919         gcc_GAS_CHECK_FEATURE([.machine directive support],
2920           gcc_cv_as_machine_directive,,,
2921           [     .machine ppc7400])
2922         if test x$gcc_cv_as_machine_directive != xyes; then
2923           echo "*** This target requires an assembler supporting \".machine\"" >&2
2924           echo you can get it from: ftp://gcc.gnu.org/pub/gcc/infrastructure/cctools-528.5.dmg >&2
2925           test x$build = x$target && exit 1
2926         fi
2927         conftest_s='    .text
2928         mfcr r3,128';;
2929       *) conftest_s='   .machine power4
2930         .text
2931         mfcr 3,128';;
2932     esac
2933
2934     gcc_GAS_CHECK_FEATURE([mfcr field support],
2935       gcc_cv_as_powerpc_mfcrf, [2,14,0],,
2936       [$conftest_s],,
2937       [AC_DEFINE(HAVE_AS_MFCRF, 1,
2938           [Define if your assembler supports mfcr field.])])
2939
2940     case $target in
2941       *-*-aix*) conftest_s='    .machine "pwr5"
2942         .csect .text[[PR]]
2943         popcntb 3,3';;
2944       *) conftest_s='   .machine power5
2945         .text
2946         popcntb 3,3';;
2947     esac
2948
2949     gcc_GAS_CHECK_FEATURE([popcntb support],
2950       gcc_cv_as_powerpc_popcntb, [2,17,0],,
2951       [$conftest_s],,
2952       [AC_DEFINE(HAVE_AS_POPCNTB, 1,
2953           [Define if your assembler supports popcntb field.])])
2954
2955     case $target in
2956       *-*-aix*) conftest_s='    .machine "pwr5x"
2957         .csect .text[[PR]]
2958         frin 1,1';;
2959       *) conftest_s='   .machine power5
2960         .text
2961         frin 1,1';;
2962     esac
2963
2964     gcc_GAS_CHECK_FEATURE([fp round support],
2965       gcc_cv_as_powerpc_fprnd, [2,17,0],,
2966       [$conftest_s],,
2967       [AC_DEFINE(HAVE_AS_FPRND, 1,
2968           [Define if your assembler supports fprnd.])])
2969
2970     case $target in
2971       *-*-aix*) conftest_s='    .machine "pwr6"
2972         .csect .text[[PR]]
2973         mffgpr 1,3';;
2974       *) conftest_s='   .machine power6
2975         .text
2976         mffgpr 1,3';;
2977     esac
2978
2979     gcc_GAS_CHECK_FEATURE([move fp gpr support],
2980       gcc_cv_as_powerpc_mfpgpr, [9,99,0],,
2981       [$conftest_s],,
2982       [AC_DEFINE(HAVE_AS_MFPGPR, 1,
2983           [Define if your assembler supports mffgpr and mftgpr.])])
2984
2985     case $target in
2986       *-*-aix*) conftest_s='    .csect .text[[PR]]
2987 LCF..0:
2988         addis 11,30,_GLOBAL_OFFSET_TABLE_-LCF..0@ha';;
2989       *-*-darwin*)
2990         conftest_s='    .text
2991 LCF0:
2992         addis r11,r30,_GLOBAL_OFFSET_TABLE_-LCF0@ha';;
2993       *) conftest_s='   .text
2994 .LCF0:
2995         addis 11,30,_GLOBAL_OFFSET_TABLE_-.LCF0@ha';;
2996     esac
2997
2998     gcc_GAS_CHECK_FEATURE([rel16 relocs],
2999       gcc_cv_as_powerpc_rel16, [2,17,0], -a32,
3000       [$conftest_s],,
3001       [AC_DEFINE(HAVE_AS_REL16, 1,
3002           [Define if your assembler supports R_PPC_REL16 relocs.])])
3003
3004     case $target in
3005       *-*-aix*) conftest_s='    .machine "pwr6"
3006         .csect .text[[PR]]
3007         cmpb 3,4,5';;
3008       *) conftest_s='   .machine power6
3009         .text
3010         cmpb 3,4,5';;
3011     esac
3012
3013     gcc_GAS_CHECK_FEATURE([compare bytes support],
3014       gcc_cv_as_powerpc_cmpb, [9,99,0], -a32,
3015       [$conftest_s],,
3016       [AC_DEFINE(HAVE_AS_CMPB, 1,
3017           [Define if your assembler supports cmpb.])])
3018
3019     case $target in
3020       *-*-aix*) conftest_s='    .machine "pwr6"
3021         .csect .text[[PR]]
3022         dadd 1,2,3';;
3023       *) conftest_s='   .machine power6
3024         .text
3025         dadd 1,2,3';;
3026     esac
3027
3028     gcc_GAS_CHECK_FEATURE([decimal float support],
3029       gcc_cv_as_powerpc_dfp, [9,99,0], -a32,
3030       [$conftest_s],,
3031       [AC_DEFINE(HAVE_AS_DFP, 1,
3032           [Define if your assembler supports DFP instructions.])])
3033
3034     case $target in
3035       *-*-aix*) conftest_s='    .machine "pwr7"
3036         .csect .text[[PR]]
3037         lxvd2x 1,2,3';;
3038       *) conftest_s='   .machine power7
3039         .text
3040         lxvd2x 1,2,3';;
3041     esac
3042
3043     gcc_GAS_CHECK_FEATURE([vector-scalar support],
3044       gcc_cv_as_powerpc_vsx, [9,99,0], -a32,
3045       [$conftest_s],,
3046       [AC_DEFINE(HAVE_AS_VSX, 1,
3047           [Define if your assembler supports VSX instructions.])])
3048
3049     gcc_GAS_CHECK_FEATURE([.gnu_attribute support],
3050       gcc_cv_as_powerpc_gnu_attribute, [2,18,0],,
3051       [.gnu_attribute 4,1],,
3052       [AC_DEFINE(HAVE_AS_GNU_ATTRIBUTE, 1,
3053           [Define if your assembler supports .gnu_attribute.])])
3054     ;;
3055
3056   mips*-*-*)
3057     gcc_GAS_CHECK_FEATURE([explicit relocation support],
3058       gcc_cv_as_mips_explicit_relocs, [2,14,0],,
3059 [       lw $4,%gp_rel(foo)($4)],,
3060       [if test x$target_cpu_default = x
3061        then target_cpu_default=MASK_EXPLICIT_RELOCS
3062        else target_cpu_default="($target_cpu_default)|MASK_EXPLICIT_RELOCS"
3063        fi])
3064     gcc_GAS_CHECK_FEATURE([-mno-shared support],
3065       gcc_cv_as_mips_no_shared, [2,16,0], [-mno-shared], [nop],,
3066       [AC_DEFINE(HAVE_AS_NO_SHARED, 1,
3067                  [Define if the assembler understands -mno-shared.])])
3068
3069     gcc_GAS_CHECK_FEATURE([.gnu_attribute support],
3070       gcc_cv_as_mips_gnu_attribute, [2,18,0],,
3071       [.gnu_attribute 4,1],,
3072       [AC_DEFINE(HAVE_AS_GNU_ATTRIBUTE, 1,
3073           [Define if your assembler supports .gnu_attribute.])])
3074
3075     gcc_GAS_CHECK_FEATURE([.dtprelword support],
3076       gcc_cv_as_mips_dtprelword, [2,18,0],,
3077       [.section .tdata,"awT",@progbits
3078 x:
3079         .word 2
3080         .text
3081         .dtprelword x+0x8000],,
3082       [AC_DEFINE(HAVE_AS_DTPRELWORD, 1,
3083           [Define if your assembler supports .dtprelword.])])
3084     ;;
3085 esac
3086
3087 # Mips and HP-UX need the GNU assembler.
3088 # Linux on IA64 might be able to use the Intel assembler.
3089
3090 case "$target" in
3091   mips*-*-* | *-*-hpux* )
3092     if test x$gas_flag = xyes \
3093        || test x"$host" != x"$build" \
3094        || test ! -x "$gcc_cv_as" \
3095        || "$gcc_cv_as" -v < /dev/null 2>&1 | grep GNU > /dev/null; then
3096       :
3097     else
3098       echo "*** This configuration requires the GNU assembler" >&2
3099       exit 1
3100     fi
3101     ;;
3102 esac
3103
3104 # ??? Not all targets support dwarf2 debug_line, even within a version
3105 # of gas.  Moreover, we need to emit a valid instruction to trigger any
3106 # info to the output file.  So, as supported targets are added to gas 2.11,
3107 # add some instruction here to (also) show we expect this might work.
3108 # ??? Once 2.11 is released, probably need to add first known working
3109 # version to the per-target configury.
3110 case "$target" in
3111   i?86*-*-* | mips*-*-* | alpha*-*-* | powerpc*-*-* | sparc*-*-* | m68*-*-* \
3112   | x86_64*-*-* | hppa*-*-* | arm*-*-* \
3113   | xstormy16*-*-* | cris-*-* | xtensa*-*-* | bfin-*-* | score*-*-* \
3114   | spu-*-* | fido*-*-*)
3115     insn="nop"
3116     ;;
3117   ia64*-*-* | s390*-*-*)
3118     insn="nop 0"
3119     ;;
3120   mmix-*-*)
3121     insn="swym 0"
3122     ;;
3123 esac
3124 if test x"$insn" != x; then
3125  conftest_s="\
3126         .file 1 \"conftest.s\"
3127         .loc 1 3 0
3128         $insn"
3129  gcc_GAS_CHECK_FEATURE([dwarf2 debug_line support],
3130   gcc_cv_as_dwarf2_debug_line,
3131   [elf,2,11,0],, [$conftest_s],
3132   [if test x$gcc_cv_objdump != x \
3133    && $gcc_cv_objdump -h conftest.o 2> /dev/null \
3134       | grep debug_line > /dev/null 2>&1; then
3135      gcc_cv_as_dwarf2_debug_line=yes
3136    fi])
3137
3138 # The .debug_line file table must be in the exact order that
3139 # we specified the files, since these indices are also used
3140 # by DW_AT_decl_file.  Approximate this test by testing if
3141 # the assembler bitches if the same index is assigned twice.
3142  gcc_GAS_CHECK_FEATURE([buggy dwarf2 .file directive],
3143   gcc_cv_as_dwarf2_file_buggy,,,
3144 [       .file 1 "foo.s"
3145         .file 1 "bar.s"])
3146
3147  if test $gcc_cv_as_dwarf2_debug_line = yes \
3148  && test $gcc_cv_as_dwarf2_file_buggy = no; then
3149         AC_DEFINE(HAVE_AS_DWARF2_DEBUG_LINE, 1,
3150   [Define if your assembler supports dwarf2 .file/.loc directives,
3151    and preserves file table indices exactly as given.])
3152  fi
3153
3154  gcc_GAS_CHECK_FEATURE([--gdwarf2 option],
3155   gcc_cv_as_gdwarf2_flag,
3156   [elf,2,11,0], [--gdwarf2], [$insn],,
3157   [AC_DEFINE(HAVE_AS_GDWARF2_DEBUG_FLAG, 1,
3158 [Define if your assembler supports the --gdwarf2 option.])])
3159
3160  gcc_GAS_CHECK_FEATURE([--gstabs option],
3161   gcc_cv_as_gstabs_flag,
3162   [elf,2,11,0], [--gstabs], [$insn],
3163   [# The native Solaris 9/Intel assembler doesn't understand --gstabs
3164    # and warns about it, but still exits successfully.  So check for
3165    # this.
3166    if AC_TRY_COMMAND([$gcc_cv_as --gstabs -o conftest.o conftest.s 2>&1 | grep -i warning > /dev/null])
3167    then :
3168    else gcc_cv_as_gstabs_flag=yes
3169    fi],
3170   [AC_DEFINE(HAVE_AS_GSTABS_DEBUG_FLAG, 1,
3171 [Define if your assembler supports the --gstabs option.])])
3172
3173  gcc_GAS_CHECK_FEATURE([--debug-prefix-map option],
3174   gcc_cv_as_debug_prefix_map_flag,
3175   [2,18,0], [--debug-prefix-map /a=/b], [$insn],,
3176   [AC_DEFINE(HAVE_AS_DEBUG_PREFIX_MAP, 1,
3177 [Define if your assembler supports the --debug-prefix-map option.])])
3178 fi
3179
3180 AC_CACHE_CHECK([assembler for tolerance to line number 0],
3181  [gcc_cv_as_line_zero],
3182  [gcc_cv_as_line_zero=no
3183   if test $in_tree_gas = yes; then
3184     gcc_GAS_VERSION_GTE_IFELSE(2, 16, 91, [gcc_cv_as_line_zero=yes])
3185   elif test "x$gcc_cv_as" != x; then
3186     { echo '# 1 "test.s" 1'; echo '# 0 "" 2'; } > conftest.s
3187     if AC_TRY_COMMAND([$gcc_cv_as -o conftest.o conftest.s >&AS_MESSAGE_LOG_FD 2>conftest.out]) &&
3188        test "x`cat conftest.out`" = x
3189     then
3190       gcc_cv_as_line_zero=yes
3191     else
3192       echo "configure: failed program was" >&AS_MESSAGE_LOG_FD
3193       cat conftest.s >&AS_MESSAGE_LOG_FD
3194       echo "configure: error output was" >&AS_MESSAGE_LOG_FD
3195       cat conftest.out >&AS_MESSAGE_LOG_FD
3196     fi
3197     rm -f conftest.o conftest.s conftest.out
3198   fi])
3199 if test "x$gcc_cv_as_line_zero" = xyes; then
3200   AC_DEFINE([HAVE_AS_LINE_ZERO], 1,
3201 [Define if the assembler won't complain about a line such as # 0 "" 2.])
3202 fi
3203
3204 AC_MSG_CHECKING(linker read-only and read-write section mixing)
3205 gcc_cv_ld_ro_rw_mix=unknown
3206 if test $in_tree_ld = yes ; then
3207   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 10 -o "$gcc_cv_gld_major_version" -gt 2 \
3208      && test $in_tree_ld_is_elf = yes; then
3209     gcc_cv_ld_ro_rw_mix=read-write
3210   fi
3211 elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x -a x$gcc_cv_objdump != x ; then
3212   echo '.section myfoosect, "a"' > conftest1.s
3213   echo '.section myfoosect, "aw"' > conftest2.s
3214   echo '.byte 1' >> conftest2.s
3215   echo '.section myfoosect, "a"' > conftest3.s
3216   echo '.byte 0' >> conftest3.s
3217   if $gcc_cv_as -o conftest1.o conftest1.s > /dev/null 2>&1 \
3218      && $gcc_cv_as -o conftest2.o conftest2.s > /dev/null 2>&1 \
3219      && $gcc_cv_as -o conftest3.o conftest3.s > /dev/null 2>&1 \
3220      && $gcc_cv_ld -shared -o conftest1.so conftest1.o \
3221         conftest2.o conftest3.o > /dev/null 2>&1; then
3222     gcc_cv_ld_ro_rw_mix=`$gcc_cv_objdump -h conftest1.so \
3223                          | sed -e '/myfoosect/!d' -e N`
3224     if echo "$gcc_cv_ld_ro_rw_mix" | grep CONTENTS > /dev/null; then
3225       if echo "$gcc_cv_ld_ro_rw_mix" | grep READONLY > /dev/null; then
3226         gcc_cv_ld_ro_rw_mix=read-only
3227       else
3228         gcc_cv_ld_ro_rw_mix=read-write
3229       fi
3230     fi
3231   fi
3232 changequote(,)dnl
3233   rm -f conftest.* conftest[123].*
3234 changequote([,])dnl
3235 fi
3236 if test x$gcc_cv_ld_ro_rw_mix = xread-write; then
3237         AC_DEFINE(HAVE_LD_RO_RW_SECTION_MIXING, 1,
3238   [Define if your linker links a mix of read-only
3239    and read-write sections into a read-write section.])
3240 fi
3241 AC_MSG_RESULT($gcc_cv_ld_ro_rw_mix)
3242
3243 AC_MSG_CHECKING(linker PT_GNU_EH_FRAME support)
3244 gcc_cv_ld_eh_frame_hdr=no
3245 if test $in_tree_ld = yes ; then
3246   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 12 -o "$gcc_cv_gld_major_version" -gt 2 \
3247      && test $in_tree_ld_is_elf = yes; then
3248     gcc_cv_ld_eh_frame_hdr=yes
3249   fi
3250 elif test x$gcc_cv_ld != x; then
3251         # Check if linker supports --eh-frame-hdr option
3252         if $gcc_cv_ld --help 2>/dev/null | grep eh-frame-hdr > /dev/null; then
3253                 gcc_cv_ld_eh_frame_hdr=yes
3254         fi
3255 fi
3256 GCC_TARGET_TEMPLATE([HAVE_LD_EH_FRAME_HDR])
3257 if test x"$gcc_cv_ld_eh_frame_hdr" = xyes; then
3258         AC_DEFINE(HAVE_LD_EH_FRAME_HDR, 1,
3259 [Define if your linker supports --eh-frame-hdr option.])
3260 fi
3261 AC_MSG_RESULT($gcc_cv_ld_eh_frame_hdr)
3262
3263 AC_MSG_CHECKING(linker position independent executable support)
3264 gcc_cv_ld_pie=no
3265 if test $in_tree_ld = yes ; then
3266   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 15 -o "$gcc_cv_gld_major_version" -gt 2 \
3267      && test $in_tree_ld_is_elf = yes; then
3268     gcc_cv_ld_pie=yes
3269   fi
3270 elif test x$gcc_cv_ld != x; then
3271         # Check if linker supports -pie option
3272         if $gcc_cv_ld --help 2>/dev/null | grep -- -pie > /dev/null; then
3273                 gcc_cv_ld_pie=yes
3274         fi
3275 fi
3276 if test x"$gcc_cv_ld_pie" = xyes; then
3277         AC_DEFINE(HAVE_LD_PIE, 1,
3278 [Define if your linker supports -pie option.])
3279 fi
3280 AC_MSG_RESULT($gcc_cv_ld_pie)
3281
3282 AC_MSG_CHECKING(linker EH-compatible garbage collection of sections)
3283 gcc_cv_ld_eh_gc_sections=no
3284 if test $in_tree_ld = yes ; then
3285   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 17 -o "$gcc_cv_gld_major_version" -gt 2 \
3286      && test $in_tree_ld_is_elf = yes; then
3287     gcc_cv_ld_eh_gc_sections=yes
3288   fi
3289 elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x -a x$gcc_cv_objdump != x ; then
3290   cat > conftest.s <<EOF
3291         .section        .text
3292 .globl _start
3293         .type _start, @function
3294 _start:
3295         .long foo
3296         .size _start, .-_start
3297         .section        .text.foo,"ax",@progbits
3298         .type foo, @function
3299 foo:
3300         .long 0
3301         .size foo, .-foo
3302         .section        .gcc_except_table.foo,"a",@progbits
3303 .L0:
3304         .long 0
3305         .section        .eh_frame,"a",@progbits
3306         .long .L0
3307 EOF
3308   if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
3309     if $gcc_cv_ld -o conftest conftest.o --entry=_start --gc-sections 2>&1 \
3310          | grep "gc-sections option ignored" > /dev/null; then
3311       gcc_cv_ld_eh_gc_sections=no
3312     elif $gcc_cv_objdump -h conftest | grep gcc_except_table > /dev/null; then
3313       gcc_cv_ld_eh_gc_sections=yes
3314       # If no COMDAT groups, the compiler will emit .gnu.linkonce.t. sections.
3315       if test x$gcc_cv_as_comdat_group != xyes; then
3316         gcc_cv_ld_eh_gc_sections=no
3317         cat > conftest.s <<EOF
3318         .section        .text
3319 .globl _start
3320         .type _start, @function
3321 _start:
3322         .long foo
3323         .size _start, .-_start
3324         .section        .gnu.linkonce.t.foo,"ax",@progbits
3325         .type foo, @function
3326 foo:
3327         .long 0
3328         .size foo, .-foo
3329         .section        .gcc_except_table.foo,"a",@progbits
3330 .L0:
3331         .long 0
3332         .section        .eh_frame,"a",@progbits
3333         .long .L0
3334 EOF
3335         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
3336           if $gcc_cv_ld -o conftest conftest.o --entry=_start --gc-sections 2>&1 \
3337                | grep "gc-sections option ignored" > /dev/null; then
3338             gcc_cv_ld_eh_gc_sections=no
3339           elif $gcc_cv_objdump -h conftest | grep gcc_except_table > /dev/null; then
3340             gcc_cv_ld_eh_gc_sections=yes
3341           fi
3342         fi
3343       fi
3344     fi
3345   fi
3346   rm -f conftest.s conftest.o conftest
3347 fi
3348 case "$target" in
3349   hppa*-*-linux*)
3350     # ??? This apparently exposes a binutils bug with PC-relative relocations.
3351     gcc_cv_ld_eh_gc_sections=no
3352     ;;
3353 esac
3354 if test x$gcc_cv_ld_eh_gc_sections = xyes; then
3355         AC_DEFINE(HAVE_LD_EH_GC_SECTIONS, 1,
3356   [Define if your linker supports garbage collection of
3357    sections in presence of EH frames.])
3358 fi
3359 AC_MSG_RESULT($gcc_cv_ld_eh_gc_sections)
3360
3361 # --------
3362 # UNSORTED
3363 # --------
3364
3365 AC_CACHE_CHECK(linker --as-needed support,
3366 gcc_cv_ld_as_needed,
3367 [gcc_cv_ld_as_needed=no
3368 if test $in_tree_ld = yes ; then
3369   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2 \
3370      && test $in_tree_ld_is_elf = yes; then
3371     gcc_cv_ld_as_needed=yes
3372   fi
3373 elif test x$gcc_cv_ld != x; then
3374         # Check if linker supports --as-needed and --no-as-needed options
3375         if $gcc_cv_ld --help 2>/dev/null | grep as-needed > /dev/null; then
3376                 gcc_cv_ld_as_needed=yes
3377         fi
3378 fi
3379 ])
3380 if test x"$gcc_cv_ld_as_needed" = xyes; then
3381         AC_DEFINE(HAVE_LD_AS_NEEDED, 1,
3382 [Define if your linker supports --as-needed and --no-as-needed options.])
3383 fi
3384
3385 case "$target:$tm_file" in
3386   powerpc64*-*-linux* | powerpc*-*-linux*rs6000/biarch64.h*)
3387     AC_CACHE_CHECK(linker support for omitting dot symbols,
3388     gcc_cv_ld_no_dot_syms,
3389     [gcc_cv_ld_no_dot_syms=no
3390     if test $in_tree_ld = yes ; then
3391       if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2; then
3392         gcc_cv_ld_no_dot_syms=yes
3393       fi
3394     elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x ; then
3395       cat > conftest1.s <<EOF
3396         .text
3397         bl .foo
3398 EOF
3399       cat > conftest2.s <<EOF
3400         .section ".opd","aw"
3401         .align 3
3402         .globl foo
3403         .type foo,@function
3404 foo:
3405         .quad .LEfoo,.TOC.@tocbase,0
3406         .text
3407 .LEfoo:
3408         blr
3409         .size foo,.-.LEfoo
3410 EOF
3411       if $gcc_cv_as -a64 -o conftest1.o conftest1.s > /dev/null 2>&1 \
3412          && $gcc_cv_as -a64 -o conftest2.o conftest2.s > /dev/null 2>&1 \
3413          && $gcc_cv_ld -melf64ppc -o conftest conftest1.o conftest2.o > /dev/null 2>&1; then
3414         gcc_cv_ld_no_dot_syms=yes
3415       fi
3416       rm -f conftest conftest1.o conftest2.o conftest1.s conftest2.s
3417     fi
3418     ])
3419     if test x"$gcc_cv_ld_no_dot_syms" = xyes; then
3420       AC_DEFINE(HAVE_LD_NO_DOT_SYMS, 1,
3421     [Define if your PowerPC64 linker only needs function descriptor syms.])
3422     fi
3423     ;;
3424 esac
3425
3426 AC_CACHE_CHECK(linker --sysroot support,
3427   gcc_cv_ld_sysroot,
3428   [gcc_cv_ld_sysroot=no
3429   if test $in_tree_ld = yes ; then
3430       if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2 ; then
3431         gcc_cv_ld_sysroot=yes
3432       fi
3433   elif test x$gcc_cv_ld != x; then 
3434     if $gcc_cv_ld --help 2>/dev/null | grep sysroot > /dev/null; then
3435       gcc_cv_ld_sysroot=yes
3436     fi
3437   fi])
3438 if test x"$gcc_cv_ld_sysroot" = xyes; then
3439   AC_DEFINE(HAVE_LD_SYSROOT, 1,
3440   [Define if your linker supports --sysroot.])
3441 fi        
3442
3443 if test x$with_sysroot = x && test x$host = x$target \
3444    && test "$prefix" != "/usr" && test "x$prefix" != "x$local_prefix" \
3445    && test "$prefix" != "NONE"; then
3446   AC_DEFINE_UNQUOTED(PREFIX_INCLUDE_DIR, "$prefix/include",
3447 [Define to PREFIX/include if cpp should also search that directory.])
3448 fi
3449
3450 # Test for stack protector support in target C library.
3451 AC_CACHE_CHECK(__stack_chk_fail in target C library,
3452       gcc_cv_libc_provides_ssp,
3453       [gcc_cv_libc_provides_ssp=no
3454     case "$target" in
3455        *-*-linux*)
3456       if test x$host != x$target || test "x$TARGET_SYSTEM_ROOT" != x; then
3457         if test "x$with_sysroot" = x; then
3458           glibc_header_dir="${exec_prefix}/${target_noncanonical}/sys-include"
3459         elif test "x$with_build_sysroot" != "x"; then
3460           glibc_header_dir="${with_build_sysroot}/usr/include"
3461         elif test "x$with_sysroot" = xyes; then
3462           glibc_header_dir="${exec_prefix}/${target_noncanonical}/sys-root/usr/include"
3463         else
3464           glibc_header_dir="${with_sysroot}/usr/include"
3465         fi
3466       else
3467         glibc_header_dir=/usr/include
3468       fi
3469       # glibc 2.4 and later provides __stack_chk_fail and
3470       # either __stack_chk_guard, or TLS access to stack guard canary.
3471       if test -f $glibc_header_dir/features.h \
3472          && $EGREP '^@<:@       @:>@*#[         ]*define[       ]+__GNU_LIBRARY__[      ]+([1-9][0-9]|[6-9])' \
3473             $glibc_header_dir/features.h > /dev/null; then
3474         if $EGREP '^@<:@        @:>@*#[         ]*define[       ]+__GLIBC__[    ]+([1-9][0-9]|[3-9])' \
3475            $glibc_header_dir/features.h > /dev/null; then
3476           gcc_cv_libc_provides_ssp=yes
3477         elif $EGREP '^@<:@      @:>@*#[         ]*define[       ]+__GLIBC__[    ]+2' \
3478              $glibc_header_dir/features.h > /dev/null \
3479              && $EGREP '^@<:@   @:>@*#[         ]*define[       ]+__GLIBC_MINOR__[      ]+([1-9][0-9]|[4-9])' \
3480              $glibc_header_dir/features.h > /dev/null; then
3481           gcc_cv_libc_provides_ssp=yes
3482         elif $EGREP '^@<:@      @:>@*#[         ]*define[       ]+__UCLIBC__[   ]+1' \
3483              $glibc_header_dir/features.h > /dev/null && \
3484              test -f $glibc_header_dir/bits/uClibc_config.h && \
3485              $EGREP '^@<:@      @:>@*#[         ]*define[       ]+__UCLIBC_HAS_SSP__[   ]+1' \
3486              $glibc_header_dir/bits/uClibc_config.h > /dev/null; then
3487           gcc_cv_libc_provides_ssp=yes
3488         fi
3489       fi
3490         ;;
3491        *-*-darwin*)
3492          AC_CHECK_FUNC(__stack_chk_fail,[gcc_cv_libc_provides_ssp=yes],
3493            [echo "no __stack_chk_fail on this target"])
3494         ;;
3495   *) gcc_cv_libc_provides_ssp=no ;;
3496     esac])
3497
3498 if test x$gcc_cv_libc_provides_ssp = xyes; then
3499   AC_DEFINE(TARGET_LIBC_PROVIDES_SSP, 1,
3500             [Define if your target C library provides stack protector support])
3501 fi
3502
3503 # Check if TFmode long double should be used by default or not.
3504 # Some glibc targets used DFmode long double, but with glibc 2.4
3505 # and later they can use TFmode.
3506 case "$target" in
3507   powerpc*-*-linux* | \
3508   powerpc*-*-gnu* | \
3509   sparc*-*-linux* | \
3510   s390*-*-linux* | \
3511   alpha*-*-linux*)
3512     AC_ARG_WITH(long-double-128,
3513 [  --with-long-double-128  Use 128-bit long double by default.],
3514       gcc_cv_target_ldbl128="$with_long_double_128",
3515       [gcc_cv_target_ldbl128=no
3516       if test x$host != x$target || test "x$TARGET_SYSTEM_ROOT" != x; then
3517         if test "x$with_sysroot" = x; then
3518           glibc_header_dir="${exec_prefix}/${target_noncanonical}/sys-include"
3519         elif test "x$with_build_sysroot" != "x"; then
3520           glibc_header_dir="${with_build_sysroot}/usr/include"
3521         elif test "x$with_sysroot" = xyes; then
3522           glibc_header_dir="${exec_prefix}/${target_noncanonical}/sys-root/usr/include"
3523         else
3524           glibc_header_dir="${with_sysroot}/usr/include"
3525         fi
3526       else
3527         glibc_header_dir=/usr/include
3528       fi
3529 changequote(,)dnl
3530       grep '^[  ]*#[    ]*define[       ][      ]*__LONG_DOUBLE_MATH_OPTIONAL' \
3531         $glibc_header_dir/bits/wordsize.h > /dev/null 2>&1 \
3532       && gcc_cv_target_ldbl128=yes
3533 changequote([,])dnl
3534       ])
3535     ;;
3536 esac
3537 if test x$gcc_cv_target_ldbl128 = xyes; then
3538   AC_DEFINE(TARGET_DEFAULT_LONG_DOUBLE_128, 1,
3539             [Define if TFmode long double should be the default])
3540 fi
3541
3542 # Find out what GC implementation we want, or may, use.
3543 AC_ARG_WITH(gc,
3544 [  --with-gc={page,zone}   choose the garbage collection mechanism to use
3545                           with the compiler],
3546 [case "$withval" in
3547   page)
3548     GGC=ggc-$withval
3549     ;;
3550   zone)
3551     GGC=ggc-$withval
3552     AC_DEFINE(GGC_ZONE, 1, [Define if the zone collector is in use])
3553     ;;
3554   *)
3555     AC_MSG_ERROR([$withval is an invalid option to --with-gc])
3556     ;;
3557 esac],
3558 [GGC=ggc-page])
3559 AC_SUBST(GGC)
3560 echo "Using $GGC for garbage collection."
3561
3562 # Use the system's zlib library.
3563 zlibdir=-L../zlib
3564 zlibinc="-I\$(srcdir)/../zlib"
3565 AC_ARG_WITH(system-zlib,
3566 [  --with-system-zlib      use installed libz],
3567 zlibdir=
3568 zlibinc=
3569 )
3570 AC_SUBST(zlibdir)
3571 AC_SUBST(zlibinc)
3572
3573 dnl Very limited version of automake's enable-maintainer-mode
3574
3575 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
3576   dnl maintainer-mode is disabled by default
3577   AC_ARG_ENABLE(maintainer-mode,
3578 [  --enable-maintainer-mode
3579                           enable make rules and dependencies not useful
3580                           (and sometimes confusing) to the casual installer],
3581       maintainer_mode=$enableval,
3582       maintainer_mode=no)
3583
3584 AC_MSG_RESULT($maintainer_mode)
3585
3586 if test "$maintainer_mode" = "yes"; then
3587   MAINT=''
3588 else
3589   MAINT='#'
3590 fi
3591 AC_SUBST(MAINT)dnl
3592
3593 # --------------
3594 # Language hooks
3595 # --------------
3596
3597 # Make empty files to contain the specs and options for each language.
3598 # Then add #include lines to for a compiler that has specs and/or options.
3599
3600 subdirs=
3601 lang_opt_files=
3602 lang_specs_files=
3603 lang_tree_files=
3604 # These (without "all_") are set in each config-lang.in.
3605 # `language' must be a single word so is spelled singularly.
3606 all_languages=
3607 all_compilers=
3608 all_outputs='Makefile gccbug'
3609 # List of language makefile fragments.
3610 all_lang_makefrags=
3611 # List of language subdirectory makefiles.  Deprecated.
3612 all_lang_makefiles=
3613 # Additional files for gengtype
3614 all_gtfiles="$target_gtfiles"
3615
3616 # These are the languages that are set in --enable-languages,
3617 # and are available in the GCC tree.
3618 all_selected_languages=
3619
3620 # Add the language fragments.
3621 # Languages are added via two mechanisms.  Some information must be
3622 # recorded in makefile variables, these are defined in config-lang.in.
3623 # We accumulate them and plug them into the main Makefile.
3624 # The other mechanism is a set of hooks for each of the main targets
3625 # like `clean', `install', etc.
3626
3627 language_hooks="Make-hooks"
3628
3629 for lang in ${srcdir}/*/config-lang.in
3630 do
3631 changequote(,)dnl
3632         test "$lang" = "${srcdir}/*/config-lang.in" && continue
3633
3634         lang_alias=`sed -n -e 's,^language=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^language=\([^   ]*\).*$,\1,p' $lang`
3635         if test "x$lang_alias" = x
3636         then
3637               echo "$lang doesn't set \$language." 1>&2
3638               exit 1
3639         fi
3640         subdir="`echo $lang | sed -e 's,^.*/\([^/]*\)/config-lang.in$,\1,'`"
3641         subdirs="$subdirs $subdir"
3642
3643         # $gcc_subdir is where the gcc integration files are to be found
3644         # for a language, both for internal compiler purposes (compiler
3645         # sources implementing front-end to GCC tree converters), and for
3646         # build infrastructure purposes (Make-lang.in, etc.)
3647         #
3648         # This will be <subdir> (relative to $srcdir) if a line like 
3649         # gcc_subdir="<subdir>" or gcc_subdir=<subdir>
3650         # is found in <langdir>/config-lang.in, and will remain <langdir>
3651         # otherwise.
3652         #
3653         # Except for the language alias (fetched above), the regular
3654         # "config-lang.in" contents are always retrieved from $gcc_subdir,
3655         # so a <langdir>/config-lang.in setting gcc_subdir typically sets
3656         # only this and the language alias.
3657
3658         gcc_subdir=`sed -n -e 's,^gcc_subdir=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^gcc_subdir=\([^   ]*\).*$,\1,p' $lang`
3659         if [ "$gcc_subdir" = "" ]; then
3660            gcc_subdir="$subdir"
3661         fi
3662
3663         case ",$enable_languages," in
3664         *,$lang_alias,*)
3665             all_selected_languages="$all_selected_languages $lang_alias"
3666             if test -f $srcdir/$gcc_subdir/lang-specs.h; then
3667                 lang_specs_files="$lang_specs_files $srcdir/$gcc_subdir/lang-specs.h"
3668             fi
3669             ;;
3670         esac
3671 changequote([,])dnl
3672
3673         language=
3674         boot_language=
3675         compilers=
3676         outputs=
3677         gtfiles=
3678         subdir_requires=
3679         . ${srcdir}/$gcc_subdir/config-lang.in
3680         if test "x$language" = x
3681         then
3682                 echo "${srcdir}/$gcc_subdir/config-lang.in doesn't set \$language." 1>&2
3683                 exit 1
3684         fi
3685
3686         ok=:
3687         case ",$enable_languages," in
3688                 *,$lang_alias,*) ;;
3689                 *)
3690                         for i in $subdir_requires; do
3691                                 test -f "${srcdir}/$i/config-lang.in" && continue
3692                                 ok=false
3693                                 break
3694                         done
3695                 ;;
3696         esac
3697         $ok || continue
3698
3699         all_lang_makefrags="$all_lang_makefrags \$(srcdir)/$gcc_subdir/Make-lang.in"
3700         if test -f $srcdir/$gcc_subdir/lang.opt; then
3701             lang_opt_files="$lang_opt_files $srcdir/$gcc_subdir/lang.opt"
3702         fi
3703         if test -f $srcdir/$gcc_subdir/$subdir-tree.def; then
3704             lang_tree_files="$lang_tree_files $srcdir/$gcc_subdir/$subdir-tree.def"
3705         fi
3706         if test -f ${srcdir}/$gcc_subdir/Makefile.in
3707                 then all_lang_makefiles="$gcc_subdir/Makefile"
3708         fi
3709         all_languages="$all_languages $language"
3710         all_compilers="$all_compilers $compilers"
3711         all_outputs="$all_outputs $outputs"
3712         all_gtfiles="$all_gtfiles [[$subdir]] $gtfiles"
3713 done
3714
3715 # Pick up gtfiles for c
3716 gtfiles=
3717 . ${srcdir}/c-config-lang.in
3718 all_gtfiles="$all_gtfiles [[c]] $gtfiles"
3719
3720 check_languages=
3721 for language in $all_selected_languages
3722 do
3723         check_languages="$check_languages check-$language"
3724 done
3725
3726 # We link each language in with a set of hooks, reached indirectly via
3727 # lang.${target}.  Only do so for selected languages.
3728
3729 rm -f Make-hooks
3730 touch Make-hooks
3731 target_list="all.cross start.encap rest.encap tags \
3732         install-common install-man install-info install-pdf dvi pdf \
3733         html uninstall info man srcextra srcman srcinfo \
3734         mostlyclean clean distclean maintainer-clean"
3735
3736 for t in $target_list
3737 do
3738         x=
3739         for lang in $all_selected_languages
3740         do
3741                 x="$x $lang.$t"
3742         done
3743         echo "lang.$t: $x" >> Make-hooks
3744 done
3745
3746 # --------
3747 # UNSORTED
3748 # --------
3749
3750 # Create .gdbinit.
3751
3752 echo "dir ." > .gdbinit
3753 echo "dir ${srcdir}" >> .gdbinit
3754 if test x$gdb_needs_out_file_path = xyes
3755 then
3756         echo "dir ${srcdir}/config/"`dirname ${out_file}` >> .gdbinit
3757 fi
3758 if test "x$subdirs" != x; then
3759         for s in $subdirs
3760         do
3761                 echo "dir ${srcdir}/$s" >> .gdbinit
3762         done
3763 fi
3764 echo "source ${srcdir}/gdbinit.in" >> .gdbinit
3765
3766 gcc_tooldir='$(libsubdir)/$(libsubdir_to_prefix)$(target_noncanonical)'
3767 AC_SUBST(gcc_tooldir)
3768 AC_SUBST(dollar)
3769
3770 # Find a directory in which to install a shared libgcc.
3771
3772 AC_ARG_ENABLE(version-specific-runtime-libs,
3773 [  --enable-version-specific-runtime-libs
3774                           specify that runtime libraries should be
3775                           installed in a compiler-specific directory])
3776
3777 AC_ARG_WITH(slibdir,
3778 [  --with-slibdir=DIR      shared libraries in DIR [[LIBDIR]]],
3779 slibdir="$with_slibdir",
3780 if test "${enable_version_specific_runtime_libs+set}" = set; then
3781   slibdir='$(libsubdir)'
3782 elif test "$host" != "$target"; then
3783   slibdir='$(build_tooldir)/lib'
3784 else
3785   slibdir='$(libdir)'
3786 fi)
3787 AC_SUBST(slibdir)
3788
3789 AC_ARG_WITH(datarootdir,
3790 [  --with-datarootdir=DIR  Use DIR as the data root [[PREFIX/share]]],
3791 datarootdir="\${prefix}/$with_datarootdir",
3792 datarootdir='$(prefix)/share')
3793 AC_SUBST(datarootdir)
3794
3795 AC_ARG_WITH(docdir,
3796 [  --with-docdir=DIR       Install documentation in DIR [[DATAROOTDIR]]],
3797 docdir="\${prefix}/$with_docdir",
3798 docdir='$(datarootdir)')
3799 AC_SUBST(docdir)
3800
3801 AC_ARG_WITH(htmldir,
3802 [  --with-htmldir=DIR      html documentation in in DIR [[DOCDIR]]],
3803 htmldir="\${prefix}/$with_htmldir",
3804 htmldir='$(docdir)')
3805 AC_SUBST(htmldir)
3806
3807 # Substitute configuration variables
3808 AC_SUBST(subdirs)
3809 AC_SUBST(srcdir)
3810 AC_SUBST(all_compilers)
3811 AC_SUBST(all_gtfiles)
3812 AC_SUBST(all_lang_makefrags)
3813 AC_SUBST(all_lang_makefiles)
3814 AC_SUBST(all_languages)
3815 AC_SUBST(all_selected_languages)
3816 AC_SUBST(build_exeext)
3817 AC_SUBST(build_install_headers_dir)
3818 AC_SUBST(build_xm_file_list)
3819 AC_SUBST(build_xm_include_list)
3820 AC_SUBST(build_xm_defines)
3821 AC_SUBST(build_file_translate)
3822 AC_SUBST(check_languages)
3823 AC_SUBST(cpp_install_dir)
3824 AC_SUBST(xmake_file)
3825 AC_SUBST(tmake_file)
3826 AC_SUBST(extra_gcc_objs)
3827 AC_SUBST(extra_headers_list)
3828 AC_SUBST(extra_objs)
3829 AC_SUBST(extra_parts)
3830 AC_SUBST(extra_passes)
3831 AC_SUBST(extra_programs)
3832 AC_SUBST(float_h_file)
3833 AC_SUBST(gcc_config_arguments)
3834 AC_SUBST(gcc_gxx_include_dir)
3835 AC_SUBST(host_exeext)
3836 AC_SUBST(host_xm_file_list)
3837 AC_SUBST(host_xm_include_list)
3838 AC_SUBST(host_xm_defines)
3839 AC_SUBST(out_host_hook_obj)
3840 AC_SUBST(install)
3841 AC_SUBST(lang_opt_files)
3842 AC_SUBST(lang_specs_files)
3843 AC_SUBST(lang_tree_files)
3844 AC_SUBST(local_prefix)
3845 AC_SUBST(md_file)
3846 AC_SUBST(objc_boehm_gc)
3847 AC_SUBST(out_file)
3848 AC_SUBST(out_object_file)
3849 AC_SUBST(thread_file)
3850 AC_SUBST(tm_file_list)
3851 AC_SUBST(tm_include_list)
3852 AC_SUBST(tm_defines)
3853 AC_SUBST(tm_p_file_list)
3854 AC_SUBST(tm_p_include_list)
3855 AC_SUBST(xm_file_list)
3856 AC_SUBST(xm_include_list)
3857 AC_SUBST(xm_defines)
3858 AC_SUBST(c_target_objs)
3859 AC_SUBST(cxx_target_objs)
3860 AC_SUBST(fortran_target_objs)
3861 AC_SUBST(target_cpu_default)
3862
3863 AC_SUBST_FILE(language_hooks)
3864
3865 # Echo link setup.
3866 if test x${build} = x${host} ; then
3867   if test x${host} = x${target} ; then
3868     echo "Links are now set up to build a native compiler for ${target}." 1>&2
3869   else
3870     echo "Links are now set up to build a cross-compiler" 1>&2
3871     echo " from ${host} to ${target}." 1>&2
3872   fi
3873 else
3874   if test x${host} = x${target} ; then
3875     echo "Links are now set up to build (on ${build}) a native compiler" 1>&2
3876     echo " for ${target}." 1>&2
3877   else
3878     echo "Links are now set up to build (on ${build}) a cross-compiler" 1>&2
3879     echo " from ${host} to ${target}." 1>&2
3880   fi
3881 fi
3882
3883 AC_ARG_VAR(GMPLIBS,[How to link GMP])
3884 AC_ARG_VAR(GMPINC,[How to find GMP include files])
3885
3886 AC_ARG_VAR(PPLLIBS,[How to link PPL])
3887 AC_ARG_VAR(PPLINC,[How to find PPL include files])
3888
3889 AC_ARG_VAR(CLOOGLIBS,[How to link CLOOG])
3890 AC_ARG_VAR(CLOOGINC,[How to find CLOOG include files])
3891 if test "x${CLOOGLIBS}" != "x" ; then 
3892    AC_DEFINE(HAVE_cloog, 1, [Define if cloog is in use.])
3893 fi
3894
3895 # Configure the subdirectories
3896 # AC_CONFIG_SUBDIRS($subdirs)
3897
3898 # Create the Makefile
3899 # and configure language subdirectories
3900 AC_CONFIG_FILES($all_outputs)
3901
3902 AC_CONFIG_COMMANDS([default],
3903 [
3904 case ${CONFIG_HEADERS} in
3905   *auto-host.h:config.in*)
3906   echo > cstamp-h ;;
3907 esac
3908 # Make sure all the subdirs exist.
3909 for d in $subdirs doc build
3910 do
3911     test -d $d || mkdir $d
3912 done
3913 ], 
3914 [subdirs='$subdirs'])
3915 AC_OUTPUT