gcc/configure.ac

   1 # configure.ac for GCC
   2 # Process this file with autoconf to generate a configuration script.
   3
   4 # Copyright 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2004
   5 # Free Software Foundation, Inc.
   6
   7 #This file is part of GCC.
   8
   9 #GCC is free software; you can redistribute it and/or modify it under
  10 #the terms of the GNU General Public License as published by the Free
  11 #Software Foundation; either version 2, or (at your option) any later
  12 #version.
  13
  14 #GCC is distributed in the hope that it will be useful, but WITHOUT
  15 #ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  16 #FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  17 #for more details.
  18
  19 #You should have received a copy of the GNU General Public License
  20 #along with GCC; see the file COPYING.  If not, write to the Free
  21 #Software Foundation, 51 Franklin Street, Fifth Floor, Boston, MA
  22 #02110-1301, USA.
  23
  24 # --------------------------------
  25 # Initialization and sanity checks
  26 # --------------------------------
  27
  28 AC_PREREQ(2.59)
  29 AC_INIT
  30 AC_CONFIG_SRCDIR(tree.c)
  31 AC_CONFIG_HEADER(auto-host.h:config.in)
  32
  33 gcc_version=`cat $srcdir/BASE-VER`
  34
  35 # Determine the host, build, and target systems
  36 AC_CANONICAL_BUILD
  37 AC_CANONICAL_HOST
  38 AC_CANONICAL_TARGET
  39
  40 # Determine the noncanonical target name, for directory use.
  41 ACX_NONCANONICAL_TARGET
  42
  43 # Determine the target- and build-specific subdirectories
  44 GCC_TOPLEV_SUBDIRS
  45
  46 # Set program_transform_name
  47 AC_ARG_PROGRAM
  48
  49 # Check for bogus environment variables.
  50 # Test if LIBRARY_PATH contains the notation for the current directory
  51 # since this would lead to problems installing/building glibc.
  52 # LIBRARY_PATH contains the current directory if one of the following
  53 # is true:
  54 # - one of the terminals (":" and ";") is the first or last sign
  55 # - two terminals occur directly after each other
  56 # - the path contains an element with a dot in it
  57 AC_MSG_CHECKING(LIBRARY_PATH variable)
  58 changequote(,)dnl
  59 case ${LIBRARY_PATH} in
  60   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
  61     library_path_setting="contains current directory"
  62     ;;
  63   *)
  64     library_path_setting="ok"
  65     ;;
  66 esac
  67 changequote([,])dnl
  68 AC_MSG_RESULT($library_path_setting)
  69 if test "$library_path_setting" != "ok"; then
  70 AC_MSG_ERROR([
  71 *** LIBRARY_PATH shouldn't contain the current directory when
  72 *** building gcc. Please change the environment variable
  73 *** and run configure again.])
  74 fi
  75
  76 # Test if GCC_EXEC_PREFIX contains the notation for the current directory
  77 # since this would lead to problems installing/building glibc.
  78 # GCC_EXEC_PREFIX contains the current directory if one of the following
  79 # is true:
  80 # - one of the terminals (":" and ";") is the first or last sign
  81 # - two terminals occur directly after each other
  82 # - the path contains an element with a dot in it
  83 AC_MSG_CHECKING(GCC_EXEC_PREFIX variable)
  84 changequote(,)dnl
  85 case ${GCC_EXEC_PREFIX} in
  86   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
  87     gcc_exec_prefix_setting="contains current directory"
  88     ;;
  89   *)
  90     gcc_exec_prefix_setting="ok"
  91     ;;
  92 esac
  93 changequote([,])dnl
  94 AC_MSG_RESULT($gcc_exec_prefix_setting)
  95 if test "$gcc_exec_prefix_setting" != "ok"; then
  96 AC_MSG_ERROR([
  97 *** GCC_EXEC_PREFIX shouldn't contain the current directory when
  98 *** building gcc. Please change the environment variable
  99 *** and run configure again.])
 100 fi
 101
 102 # -----------
 103 # Directories
 104 # -----------
 105
 106 # Specify the local prefix
 107 local_prefix=
 108 AC_ARG_WITH(local-prefix,
 109 [  --with-local-prefix=DIR specifies directory to put local include],
 110 [case "${withval}" in
 111 yes)    AC_MSG_ERROR(bad value ${withval} given for local include directory prefix) ;;
 112 no)     ;;
 113 *)      local_prefix=$with_local_prefix ;;
 114 esac])
 115
 116 # Default local prefix if it is empty
 117 if test x$local_prefix = x; then
 118         local_prefix=/usr/local
 119 fi
 120
 121 # Don't set gcc_gxx_include_dir to gxx_include_dir since that's only
 122 # passed in by the toplevel make and thus we'd get different behavior
 123 # depending on where we built the sources.
 124 gcc_gxx_include_dir=
 125 # Specify the g++ header file directory
 126 AC_ARG_WITH(gxx-include-dir,
 127 [  --with-gxx-include-dir=DIR
 128                           specifies directory to put g++ header files],
 129 [case "${withval}" in
 130 yes)    AC_MSG_ERROR(bad value ${withval} given for g++ include directory) ;;
 131 no)     ;;
 132 *)      gcc_gxx_include_dir=$with_gxx_include_dir ;;
 133 esac])
 134
 135 if test x${gcc_gxx_include_dir} = x; then
 136   if test x${enable_version_specific_runtime_libs} = xyes; then
 137     gcc_gxx_include_dir='${libsubdir}/include/c++'
 138   else
 139     libstdcxx_incdir='c++/$(version)'
 140 changequote(<<, >>)dnl
 141     gcc_gxx_include_dir="\$(libsubdir)/\$(unlibsubdir)/..\`echo \$(exec_prefix) | sed -e 's|^\$(prefix)||' -e 's|/[^/]*|/..|g'\`/include/"${libstdcxx_incdir}
 142 changequote([, ])dnl
 143   fi
 144 fi
 145
 146 AC_ARG_WITH(cpp_install_dir,
 147 [  --with-cpp-install-dir=DIR
 148                           install the user visible C preprocessor in DIR
 149                           (relative to PREFIX) as well as PREFIX/bin],
 150 [if test x$withval = xyes; then
 151   AC_MSG_ERROR([option --with-cpp-install-dir requires an argument])
 152 elif test x$withval != xno; then
 153   cpp_install_dir=$withval
 154 fi])
 155
 156 # We would like to our source tree to be readonly.  However when releases or
 157 # pre-releases are generated, the flex/bison generated files as well as the
 158 # various formats of manuals need to be included along with the rest of the
 159 # sources.  Therefore we have --enable-generated-files-in-srcdir to do
 160 # just that.
 161
 162 AC_MSG_CHECKING([whether to place generated files in the source directory])
 163   dnl generated-files-in-srcdir is disabled by default
 164   AC_ARG_ENABLE(generated-files-in-srcdir,
 165 [  --enable-generated-files-in-srcdir
 166                           put copies of generated files in source dir
 167                           intended for creating source tarballs for users
 168                           without texinfo bison or flex.],
 169       generated_files_in_srcdir=$enableval,
 170       generated_files_in_srcdir=no)
 171
 172 AC_MSG_RESULT($generated_files_in_srcdir)
 173
 174 if test "$generated_files_in_srcdir" = "yes"; then
 175   GENINSRC=''
 176 else
 177   GENINSRC='#'
 178 fi
 179 AC_SUBST(GENINSRC)
 180
 181 # -------------------
 182 # Find default linker
 183 # -------------------
 184
 185 # With GNU ld
 186 AC_ARG_WITH(gnu-ld,
 187 [  --with-gnu-ld           arrange to work with GNU ld.],
 188 gnu_ld_flag="$with_gnu_ld",
 189 gnu_ld_flag=no)
 190
 191 # With pre-defined ld
 192 AC_ARG_WITH(ld,
 193 [  --with-ld               arrange to use the specified ld (full pathname)],
 194 DEFAULT_LINKER="$with_ld")
 195 if test x"${DEFAULT_LINKER+set}" = x"set"; then
 196   if test ! -x "$DEFAULT_LINKER"; then
 197     AC_MSG_ERROR([cannot execute: $DEFAULT_LINKER: check --with-ld or env. var. DEFAULT_LINKER])
 198   elif $DEFAULT_LINKER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
 199     gnu_ld_flag=yes
 200   fi
 201   AC_DEFINE_UNQUOTED(DEFAULT_LINKER,"$DEFAULT_LINKER",
 202         [Define to enable the use of a default linker.])
 203 fi
 204
 205 AC_MSG_CHECKING([whether a default linker was specified])
 206 if test x"${DEFAULT_LINKER+set}" = x"set"; then
 207   if test x"$gnu_ld_flag" = x"no"; then
 208     AC_MSG_RESULT([yes ($DEFAULT_LINKER)])
 209   else
 210     AC_MSG_RESULT([yes ($DEFAULT_LINKER - GNU ld)])
 211   fi
 212 else
 213   AC_MSG_RESULT(no)
 214 fi
 215
 216 # With demangler in GNU ld
 217 AC_ARG_WITH(demangler-in-ld,
 218 [  --with-demangler-in-ld  try to use demangler in GNU ld.],
 219 demangler_in_ld="$with_demangler_in_ld",
 220 demangler_in_ld=no)
 221
 222 # ----------------------
 223 # Find default assembler
 224 # ----------------------
 225
 226 # With GNU as
 227 AC_ARG_WITH(gnu-as,
 228 [  --with-gnu-as           arrange to work with GNU as],
 229 gas_flag="$with_gnu_as",
 230 gas_flag=no)
 231
 232 AC_ARG_WITH(as,
 233 [  --with-as               arrange to use the specified as (full pathname)],
 234 DEFAULT_ASSEMBLER="$with_as")
 235 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
 236   if test ! -x "$DEFAULT_ASSEMBLER"; then
 237     AC_MSG_ERROR([cannot execute: $DEFAULT_ASSEMBLER: check --with-as or env. var. DEFAULT_ASSEMBLER])
 238   elif $DEFAULT_ASSEMBLER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
 239     gas_flag=yes
 240   fi
 241   AC_DEFINE_UNQUOTED(DEFAULT_ASSEMBLER,"$DEFAULT_ASSEMBLER",
 242         [Define to enable the use of a default assembler.])
 243 fi
 244
 245 AC_MSG_CHECKING([whether a default assembler was specified])
 246 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
 247   if test x"$gas_flag" = x"no"; then
 248     AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER)])
 249   else
 250     AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER - GNU as)])
 251   fi
 252 else
 253   AC_MSG_RESULT(no)
 254 fi
 255
 256 # ---------------
 257 # Find C compiler
 258 # ---------------
 259
 260 # If a non-executable a.out is present (e.g. created by GNU as above even if
 261 # invoked with -v only), the IRIX 6 native ld just overwrites the existing
 262 # file, even when creating an executable, so an execution test fails.
 263 # Remove possible default executable files to avoid this.
 264 #
 265 # FIXME: This really belongs into AC_PROG_CC and can be removed once
 266 # Autoconf includes it.
 267 rm -f a.out a.exe b.out
 268
 269 # Find the native compiler
 270 AC_PROG_CC
 271 AM_PROG_CC_C_O
 272 # autoconf is lame and doesn't give us any substitution variable for this.
 273 if eval "test \"`echo '$ac_cv_prog_cc_'${ac_cc}_c_o`\" = no"; then
 274   NO_MINUS_C_MINUS_O=yes
 275 else
 276   OUTPUT_OPTION='-o $@'
 277 fi
 278 AC_SUBST(NO_MINUS_C_MINUS_O)
 279 AC_SUBST(OUTPUT_OPTION)
 280
 281 # -------------------------
 282 # Check C compiler features
 283 # -------------------------
 284
 285 AC_PROG_CPP
 286 AC_C_INLINE
 287
 288 # sizeof(char) is 1 by definition.
 289 AC_CHECK_SIZEOF(void *)
 290 AC_CHECK_SIZEOF(short)
 291 AC_CHECK_SIZEOF(int)
 292 AC_CHECK_SIZEOF(long)
 293 AC_CHECK_TYPES([long long], [AC_CHECK_SIZEOF(long long)])
 294 AC_CHECK_TYPES([__int64], [AC_CHECK_SIZEOF(__int64)])
 295
 296 # ---------------------
 297 # Warnings and checking
 298 # ---------------------
 299
 300 # Check $CC warning features (if it's GCC).
 301 # We want to use -pedantic, but we don't want warnings about
 302 # * 'long long'
 303 # * variadic macros
 304 # So, we only use -pedantic if we can disable those warnings.
 305
 306 AC_CACHE_CHECK(
 307   [whether ${CC} accepts -Wno-long-long],
 308   [ac_cv_prog_cc_w_no_long_long],
 309   [save_CFLAGS="$CFLAGS"
 310   CFLAGS="-Wno-long-long"
 311   AC_COMPILE_IFELSE([AC_LANG_SOURCE([[]])],
 312                     [ac_cv_prog_cc_w_no_long_long=yes],
 313                     [ac_cv_prog_cc_w_no_long_long=no])
 314   CFLAGS="$save_CFLAGS"
 315   ])
 316
 317 AC_CACHE_CHECK(
 318   [whether ${CC} accepts -Wno-variadic-macros],
 319   [ac_cv_prog_cc_w_no_variadic_macros],
 320   [save_CFLAGS="$CFLAGS"
 321   CFLAGS="-Wno-variadic-macros"
 322   AC_COMPILE_IFELSE([AC_LANG_SOURCE([[]])],
 323                     [ac_cv_prog_cc_w_no_variadic_macros=yes],
 324                     [ac_cv_prog_cc_w_no_variadic_macros=no])
 325   CFLAGS="$save_CFLAGS"
 326   ])
 327
 328 strict1_warn=
 329 if test $ac_cv_prog_cc_w_no_long_long = yes \
 330    && test $ac_cv_prog_cc_w_no_variadic_macros = yes ; then
 331   strict1_warn="-pedantic -Wno-long-long -Wno-variadic-macros"
 332 fi
 333 AC_SUBST(strict1_warn)
 334
 335 # Add -Wold-style-definition if it's accepted
 336 AC_CACHE_CHECK(
 337   [whether ${CC} accepts -Wold-style-definition],
 338   [ac_cv_prog_cc_w_old_style_definition],
 339   [save_CFLAGS="$CFLAGS"
 340   CFLAGS="-Wold-style-definition"
 341   AC_COMPILE_IFELSE([AC_LANG_SOURCE([[]])],
 342                     [ac_cv_prog_cc_w_old_style_definition=yes],
 343                     [ac_cv_prog_cc_w_old_style_definition=no])
 344   CFLAGS="$save_CFLAGS"
 345   ])
 346 if test $ac_cv_prog_cc_w_old_style_definition = yes ; then
 347   strict1_warn="${strict1_warn} -Wold-style-definition"
 348 fi
 349
 350 # Enable -Werror, period.
 351 AC_ARG_ENABLE(werror_always,
 352 [  --enable-werror-always         enable -Werror always], [],
 353 [enable_werror_always=no])
 354 if test x${enable_werror_always} = xyes ; then
 355   strict1_warn="${strict1_warn} -Werror"
 356   WERROR=-Werror
 357 fi
 358
 359 # If the native compiler is GCC, we can enable warnings even in stage1.
 360 # That's useful for people building cross-compilers, or just running a
 361 # quick `make'.
 362 warn_cflags=
 363 if test "x$GCC" = "xyes"; then
 364   warn_cflags='$(GCC_WARN_CFLAGS)'
 365 fi
 366 AC_SUBST(warn_cflags)
 367
 368 # Enable -Werror in bootstrap stage2 and later.
 369 is_release=
 370 if test x"`cat $srcdir/DEV-PHASE`" != xexperimental; then
 371   is_release=yes
 372 fi
 373 AC_ARG_ENABLE(werror,
 374 [  --enable-werror         enable -Werror in bootstrap stage2 and later], [],
 375 [if test x$is_release = x ; then
 376   # Default to "yes" on development branches.
 377   enable_werror=yes
 378 else
 379   # Default to "no" on release branches.
 380   enable_werror=no
 381 fi])
 382 if test x$enable_werror = xyes ; then
 383   WERROR=-Werror
 384 fi
 385 AC_SUBST(WERROR)
 386
 387 # Enable expensive internal checks
 388 AC_ARG_ENABLE(checking,
 389 [  --enable-checking[=LIST]
 390                           enable expensive run-time checks.  With LIST,
 391                           enable only specific categories of checks.
 392                           Categories are: yes,no,all,none,release.
 393                           Flags are: assert,fold,gc,gcac,misc,
 394                           rtlflag,rtl,runtime,tree,valgrind.],
 395 [ac_checking_flags="${enableval}"],[
 396 # Determine the default checks.
 397 if test x$is_release = x ; then
 398   ac_checking_flags=yes
 399 else
 400   ac_checking_flags=release
 401 fi])
 402 ac_assert_checking=1
 403 ac_checking=
 404 ac_fold_checking=
 405 ac_gc_checking=
 406 ac_gc_always_collect=
 407 ac_rtl_checking=
 408 ac_rtlflag_checking=
 409 ac_runtime_checking=1
 410 ac_tree_checking=
 411 ac_valgrind_checking=
 412 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 413 for check in $ac_checking_flags
 414 do
 415         case $check in
 416         # these set all the flags to specific states
 417         yes)            ac_assert_checking=1 ; ac_checking=1 ;
 418                         ac_fold_checking= ; ac_gc_checking=1 ;
 419                         ac_gc_always_collect= ; ac_rtl_checking= ;
 420                         ac_rtlflag_checking=1 ; ac_runtime_checking=1 ;
 421                         ac_tree_checking=1 ; ac_valgrind_checking= ;;
 422         no|none)        ac_assert_checking= ; ac_checking= ;
 423                         ac_fold_checking= ; ac_gc_checking= ;
 424                         ac_gc_always_collect= ; ac_rtl_checking= ;
 425                         ac_rtlflag_checking= ; ac_runtime_checking= ;
 426                         ac_tree_checking= ; ac_valgrind_checking= ;;
 427         all)            ac_assert_checking=1 ; ac_checking=1 ;
 428                         ac_fold_checking=1 ; ac_gc_checking=1 ;
 429                         ac_gc_always_collect=1 ; ac_rtl_checking=1 ;
 430                         ac_rtlflag_checking=1 ; ac_runtime_checking=1 ;
 431                         ac_tree_checking=1 ; ac_valgrind_checking= ;;
 432         release)        ac_assert_checking=1 ; ac_checking= ;
 433                         ac_fold_checking= ; ac_gc_checking= ;
 434                         ac_gc_always_collect= ; ac_rtl_checking= ;
 435                         ac_rtlflag_checking= ; ac_runtime_checking=1 ;
 436                         ac_tree_checking= ; ac_valgrind_checking= ;;
 437         # these enable particular checks
 438         assert)         ac_assert_checking=1 ;;
 439         fold)           ac_fold_checking=1 ;;
 440         gc)             ac_gc_checking=1 ;;
 441         gcac)           ac_gc_always_collect=1 ;;
 442         misc)           ac_checking=1 ;;
 443         rtl)            ac_rtl_checking=1 ;;
 444         rtlflag)        ac_rtlflag_checking=1 ;;
 445         runtime)        ac_runtime_checking=1 ;;
 446         tree)           ac_tree_checking=1 ;;
 447         valgrind)       ac_valgrind_checking=1 ;;
 448         *)      AC_MSG_ERROR(unknown check category $check) ;;
 449         esac
 450 done
 451 IFS="$ac_save_IFS"
 452
 453 nocommon_flag=""
 454 if test x$ac_checking != x ; then
 455   AC_DEFINE(ENABLE_CHECKING, 1,
 456 [Define if you want more run-time sanity checks.  This one gets a grab
 457    bag of miscellaneous but relatively cheap checks.])
 458   nocommon_flag=-fno-common
 459 fi
 460 AC_SUBST(nocommon_flag)
 461 if test x$ac_assert_checking != x ; then
 462   AC_DEFINE(ENABLE_ASSERT_CHECKING, 1,
 463 [Define if you want assertions enabled.  This is a cheap check.])
 464 fi
 465 GCC_TARGET_TEMPLATE(ENABLE_RUNTIME_CHECKING)
 466 if test x$ac_runtime_checking != x ; then
 467   AC_DEFINE(ENABLE_RUNTIME_CHECKING, 1,
 468 [Define if you want runtime assertions enabled.  This is a cheap check.])
 469 fi
 470 if test x$ac_tree_checking != x ; then
 471   AC_DEFINE(ENABLE_TREE_CHECKING, 1,
 472 [Define if you want all operations on trees (the basic data
 473    structure of the front ends) to be checked for dynamic type safety
 474    at runtime.  This is moderately expensive.  The tree browser debugging
 475    routines will also be enabled by this option.
 476    ])
 477   TREEBROWSER=tree-browser.o
 478 fi
 479 AC_SUBST(TREEBROWSER)
 480 if test x$ac_rtl_checking != x ; then
 481   AC_DEFINE(ENABLE_RTL_CHECKING, 1,
 482 [Define if you want all operations on RTL (the basic data structure
 483    of the optimizer and back end) to be checked for dynamic type safety
 484    at runtime.  This is quite expensive.])
 485 fi
 486 if test x$ac_rtlflag_checking != x ; then
 487   AC_DEFINE(ENABLE_RTL_FLAG_CHECKING, 1,
 488 [Define if you want RTL flag accesses to be checked against the RTL
 489    codes that are supported for each access macro.  This is relatively
 490    cheap.])
 491 fi
 492 if test x$ac_gc_checking != x ; then
 493   AC_DEFINE(ENABLE_GC_CHECKING, 1,
 494 [Define if you want the garbage collector to do object poisoning and
 495    other memory allocation checks.  This is quite expensive.])
 496 fi
 497 if test x$ac_gc_always_collect != x ; then
 498   AC_DEFINE(ENABLE_GC_ALWAYS_COLLECT, 1,
 499 [Define if you want the garbage collector to operate in maximally
 500    paranoid mode, validating the entire heap and collecting garbage at
 501    every opportunity.  This is extremely expensive.])
 502 fi
 503 if test x$ac_fold_checking != x ; then
 504   AC_DEFINE(ENABLE_FOLD_CHECKING, 1,
 505 [Define if you want fold checked that it never destructs its argument.
 506    This is quite expensive.])
 507 fi
 508 valgrind_path_defines=
 509 valgrind_command=
 510
 511 dnl # This check AC_REQUIREs various stuff, so it *must not* be inside
 512 dnl # an if statement.  This was the source of very frustrating bugs
 513 dnl # in converting to autoconf 2.5x!
 514 AC_CHECK_HEADER(valgrind.h, have_valgrind_h=yes, have_valgrind_h=no)
 515
 516 if test x$ac_valgrind_checking != x ; then
 517   # It is certainly possible that there's valgrind but no valgrind.h.
 518   # GCC relies on making annotations so we must have both.
 519   AC_MSG_CHECKING(for VALGRIND_DISCARD in <valgrind/memcheck.h>)
 520   AC_TRY_CPP(
 521     [#include <valgrind/memcheck.h>
 522 #ifndef VALGRIND_DISCARD
 523 #error VALGRIND_DISCARD not defined
 524 #endif],
 525   [gcc_cv_header_valgrind_memcheck_h=yes],
 526   [gcc_cv_header_valgrind_memcheck_h=no])
 527   AC_MSG_RESULT($gcc_cv_header_valgrind_memcheck_h)
 528   AC_MSG_CHECKING(for VALGRIND_DISCARD in <memcheck.h>)
 529   AC_TRY_CPP(
 530     [#include <memcheck.h>
 531 #ifndef VALGRIND_DISCARD
 532 #error VALGRIND_DISCARD not defined
 533 #endif],
 534   [gcc_cv_header_memcheck_h=yes],
 535   gcc_cv_header_memcheck_h=no)
 536   AC_MSG_RESULT($gcc_cv_header_memcheck_h)
 537   AM_PATH_PROG_WITH_TEST(valgrind_path, valgrind,
 538         [$ac_dir/$ac_word --version | grep valgrind- >/dev/null 2>&1])
 539   if test "x$valgrind_path" = "x" \
 540     || (test $have_valgrind_h = no \
 541         && test $gcc_cv_header_memcheck_h = no \
 542         && test $gcc_cv_header_valgrind_memcheck_h = no); then
 543         AC_MSG_ERROR([*** Can't find both valgrind and valgrind/memcheck.h, memcheck.h or valgrind.h])
 544   fi
 545   valgrind_path_defines=-DVALGRIND_PATH='\"'$valgrind_path'\"'
 546   valgrind_command="$valgrind_path -q"
 547   AC_DEFINE(ENABLE_VALGRIND_CHECKING, 1,
 548 [Define if you want to run subprograms and generated programs
 549    through valgrind (a memory checker).  This is extremely expensive.])
 550   if test $gcc_cv_header_valgrind_memcheck_h = yes; then
 551     AC_DEFINE(HAVE_VALGRIND_MEMCHECK_H, 1,
 552         [Define if valgrind's valgrind/memcheck.h header is installed.])
 553   fi
 554   if test $gcc_cv_header_memcheck_h = yes; then
 555     AC_DEFINE(HAVE_MEMCHECK_H, 1,
 556         [Define if valgrind's memcheck.h header is installed.])
 557   fi
 558 fi
 559 AC_SUBST(valgrind_path_defines)
 560 AC_SUBST(valgrind_command)
 561
 562 AC_ARG_ENABLE(mapped-location,
 563 [  --enable-mapped-location   location_t is fileline integer cookie],,
 564 enable_mapped_location=no)
 565
 566 if test "$enable_mapped_location" = yes ; then
 567   AC_DEFINE(USE_MAPPED_LOCATION, 1,
 568 [Define if location_t is fileline integer cookie.])
 569 fi
 570
 571 # Enable code coverage collection
 572 AC_ARG_ENABLE(coverage,
 573 [  --enable-coverage[=LEVEL]
 574                           enable compiler's code coverage collection.
 575                           Use to measure compiler performance and locate
 576                           unused parts of the compiler. With LEVEL, specify
 577                           optimization. Values are opt, noopt,
 578                           default is noopt],
 579 [case "${enableval}" in
 580   yes|noopt)
 581     coverage_flags="-fprofile-arcs -ftest-coverage -frandom-seed=\$@ -O0"
 582     ;;
 583   opt)
 584     coverage_flags="-fprofile-arcs -ftest-coverage -frandom-seed=\$@ -O2"
 585     ;;
 586   no)
 587     # a.k.a. --disable-coverage
 588     coverage_flags=""
 589     ;;
 590   *)
 591     AC_MSG_ERROR(unknown coverage setting $enableval)
 592     ;;
 593 esac],
 594 [coverage_flags=""])
 595 AC_SUBST(coverage_flags)
 596
 597 AC_ARG_ENABLE(gather-detailed-mem-stats,
 598 [  --enable-gather-detailed-mem-stats         enable detailed memory allocation stats gathering], [],
 599 [enable_gather_detailed_mem_stats=no])
 600 if test x$enable_gather_detailed_mem_stats = xyes ; then
 601   AC_DEFINE(GATHER_STATISTICS, 1,
 602         [Define to enable detailed memory allocation stats gathering.])
 603 fi
 604
 605 # -------------------------------
 606 # Miscenalleous configure options
 607 # -------------------------------
 608
 609 # With stabs
 610 AC_ARG_WITH(stabs,
 611 [  --with-stabs            arrange to use stabs instead of host debug format],
 612 stabs="$with_stabs",
 613 stabs=no)
 614
 615 # Determine whether or not multilibs are enabled.
 616 AC_ARG_ENABLE(multilib,
 617 [  --enable-multilib       enable library support for multiple ABIs],
 618 [], [enable_multilib=yes])
 619 AC_SUBST(enable_multilib)
 620
 621 # Enable __cxa_atexit for C++.
 622 AC_ARG_ENABLE(__cxa_atexit,
 623 [  --enable-__cxa_atexit   enable __cxa_atexit for C++],
 624 [], [])
 625
 626 # Enable threads
 627 # Pass with no value to take the default
 628 # Pass with a value to specify a thread package
 629 AC_ARG_ENABLE(threads,
 630 [  --enable-threads        enable thread usage for target GCC
 631   --enable-threads=LIB    use LIB thread package for target GCC],,
 632 [enable_threads=''])
 633
 634 AC_ARG_ENABLE(objc-gc,
 635 [  --enable-objc-gc       enable the use of Boehm's garbage collector with
 636                           the GNU Objective-C runtime],
 637 if test x$enable_objc_gc = xno; then
 638         objc_boehm_gc=''
 639 else
 640         objc_boehm_gc=1
 641 fi,
 642 objc_boehm_gc='')
 643
 644 AC_ARG_WITH(dwarf2,
 645 [  --with-dwarf2           force the default debug format to be DWARF 2],
 646 dwarf2="$with_dwarf2",
 647 dwarf2=no)
 648
 649 AC_ARG_ENABLE(shared,
 650 [  --disable-shared        don't provide a shared libgcc],
 651 [
 652   case $enable_shared in
 653   yes | no) ;;
 654   *)
 655     enable_shared=no
 656     IFS="${IFS=         }"; ac_save_ifs="$IFS"; IFS="${IFS}:,"
 657     for pkg in $enableval; do
 658       if test "X$pkg" = "Xgcc" || test "X$pkg" = "Xlibgcc"; then
 659         enable_shared=yes
 660       fi
 661     done
 662     IFS="$ac_save_ifs"
 663     ;;
 664   esac
 665 ], [enable_shared=yes])
 666 AC_SUBST(enable_shared)
 667
 668 AC_ARG_WITH(sysroot,
 669 [  --with-sysroot[=DIR] Search for usr/lib, usr/include, et al, within DIR.],
 670 [
 671  case ${with_sysroot} in
 672  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_noncanonical}/sys-root' ;;
 673  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
 674  esac
 675
 676  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
 677  CROSS_SYSTEM_HEADER_DIR='$(TARGET_SYSTEM_ROOT)$(NATIVE_SYSTEM_HEADER_DIR)'
 678
 679  if test "x$exec_prefix" = xNONE; then
 680   if test "x$prefix" = xNONE; then
 681    test_prefix=/usr/local
 682   else
 683    test_prefix=$prefix
 684   fi
 685  else
 686   test_prefix=$exec_prefix
 687  fi
 688  case ${TARGET_SYSTEM_ROOT} in
 689  "${test_prefix}"|"${test_prefix}/"*|\
 690  '${exec_prefix}'|'${exec_prefix}/'*)
 691    t="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE"
 692    TARGET_SYSTEM_ROOT_DEFINE="$t"
 693    ;;
 694  esac
 695 ], [
 696  TARGET_SYSTEM_ROOT=
 697  TARGET_SYSTEM_ROOT_DEFINE=
 698  CROSS_SYSTEM_HEADER_DIR='$(gcc_tooldir)/sys-include'
 699 ])
 700 AC_SUBST(TARGET_SYSTEM_ROOT)
 701 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
 702 AC_SUBST(CROSS_SYSTEM_HEADER_DIR)
 703
 704 # Build with intermodule optimisations
 705 AC_ARG_ENABLE(intermodule,
 706 [  --enable-intermodule    build the compiler in one step],
 707 [case ${enable_intermodule} in
 708   yes) onestep="-onestep";;
 709   *) onestep="";;
 710 esac],
 711 [onestep=""])
 712 AC_SUBST(onestep)
 713
 714 # Sanity check enable_languages in case someone does not run the toplevel
 715 # configure # script.
 716 AC_ARG_ENABLE(languages,
 717 [  --enable-languages=LIST specify which front-ends to build],
 718 [case ,${enable_languages}, in
 719        ,,|,yes,)
 720                 # go safe -- we cannot be much sure without the toplevel
 721                 # configure's
 722                 # analysis of which target libs are present and usable
 723                 enable_languages=c
 724                 ;;
 725          *,all,*)
 726                 AC_MSG_ERROR([only the toplevel supports --enable-languages=all])
 727                 ;;
 728         *,c,*)
 729                 ;;
 730         *)
 731                 enable_languages=c,${enable_languages}
 732                 ;;
 733 esac],
 734 [enable_languages=c])
 735
 736 subdirs=
 737 for lang in ${srcdir}/*/config-lang.in
 738 do
 739         case $lang in
 740         # The odd quoting in the next line works around
 741         # an apparent bug in bash 1.12 on linux.
 742 changequote(,)dnl
 743         ${srcdir}/[*]/config-lang.in) ;;
 744         *)
 745           lang_alias=`sed -n -e 's,^language=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^language=\([^   ]*\).*$,\1,p' $lang`
 746           if test "x$lang_alias" = x
 747           then
 748                 echo "$lang doesn't set \$language." 1>&2
 749                 exit 1
 750           fi
 751           case ",$enable_languages," in
 752           *,$lang_alias,*)
 753             subdirs="$subdirs `echo $lang | sed -e 's,^.*/\([^/]*\)/config-lang.in$,\1,'`" ;;
 754           esac
 755           ;;
 756 changequote([,])dnl
 757         esac
 758 done
 759
 760
 761 # -------------------------
 762 # Checks for other programs
 763 # -------------------------
 764
 765 AC_PROG_MAKE_SET
 766
 767 # Find some useful tools
 768 AC_PROG_AWK
 769 # We need awk to create options.c and options.h.
 770 # Bail out if it's missing.
 771 case ${AWK} in
 772   "") AC_MSG_ERROR([can't build without awk, bailing out]) ;;
 773 esac
 774
 775 gcc_AC_PROG_LN_S
 776 ACX_PROG_LN($LN_S)
 777 AC_PROG_RANLIB
 778 case "${host}" in
 779 *-*-darwin*)
 780   # By default, the Darwin ranlib will not treat common symbols as
 781   # definitions when  building the archive table of contents.  Other
 782   # ranlibs do that; pass an option to the Darwin ranlib that makes
 783   # it behave similarly.
 784   ranlib_flags="-c"
 785   ;;
 786 *)
 787   ranlib_flags=""
 788 esac
 789 AC_SUBST(ranlib_flags)
 790
 791 gcc_AC_PROG_INSTALL
 792
 793 # See if cmp has --ignore-initial.
 794 gcc_AC_PROG_CMP_IGNORE_INITIAL
 795
 796 # See if we have the mktemp command.
 797 AC_CHECK_PROG(have_mktemp_command, mktemp, yes, no)
 798
 799 MISSING="${CONFIG_SHELL-/bin/sh} $srcdir/../missing"
 800
 801 # See if makeinfo has been installed and is modern enough
 802 # that we can use it.
 803 gcc_AC_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
 804   [GNU texinfo.* \([0-9][0-9.]*\)],
 805   [4.[2-9]*])
 806 if test $gcc_cv_prog_makeinfo_modern = no; then
 807   MAKEINFO="$MISSING makeinfo"
 808   AC_MSG_WARN([
 809 *** Makeinfo is missing or too old.
 810 *** Info documentation will not be built.])
 811   BUILD_INFO=
 812 else
 813   BUILD_INFO=info
 814 fi
 815 AC_SUBST(BUILD_INFO)
 816
 817 # Is pod2man recent enough to regenerate manpages?
 818 AC_MSG_CHECKING([for recent Pod::Man])
 819 if (perl -e 'use 1.10 Pod::Man') >/dev/null 2>&1; then
 820   AC_MSG_RESULT(yes)
 821   GENERATED_MANPAGES=generated-manpages
 822 else
 823   AC_MSG_RESULT(no)
 824   GENERATED_MANPAGES=
 825 fi
 826 AC_SUBST(GENERATED_MANPAGES)
 827
 828 # How about lex?
 829 dnl Don't use AC_PROG_LEX; we insist on flex.
 830 dnl LEXLIB is not useful in gcc.
 831 AC_CHECK_PROGS([FLEX], flex, [$MISSING flex])
 832
 833 # Bison?
 834 AC_CHECK_PROGS([BISON], bison, [$MISSING bison])
 835
 836 # Binutils are not build modules, unlike bison/flex/makeinfo.  So we
 837 # check for build == host before using them.
 838
 839 # NM
 840 if test x${build} = x${host} && test -f $srcdir/../binutils/nm.c \
 841   && test -d ../binutils ; then
 842   NM='$(objdir)/../binutils/nm-new'
 843 else
 844   AC_CHECK_PROG(NM, nm, nm, ${CONFIG_SHELL-/bin/sh} ${srcdir}/../missing nm)
 845 fi
 846
 847 # AR
 848 if test x${build} = x${host} && test -f $srcdir/../binutils/ar.c \
 849   && test -d ../binutils ; then
 850   AR='$(objdir)/../binutils/ar'
 851 else
 852   AC_CHECK_PROG(AR, ar, ar, ${CONFIG_SHELL-/bin/sh} ${srcdir}/../missing ar)
 853 fi
 854
 855
 856 # --------------------
 857 # Checks for C headers
 858 # --------------------
 859
 860 AC_MSG_CHECKING(for GNU C library)
 861 AC_CACHE_VAL(gcc_cv_glibc,
 862 [AC_TRY_COMPILE(
 863   [#include <features.h>],[
 864 #if ! (defined __GLIBC__ || defined __GNU_LIBRARY__)
 865 #error Not a GNU C library system
 866 #endif],
 867   [gcc_cv_glibc=yes],
 868   gcc_cv_glibc=no)])
 869 AC_MSG_RESULT($gcc_cv_glibc)
 870 if test $gcc_cv_glibc = yes; then
 871   AC_DEFINE(_GNU_SOURCE, 1, [Always define this when using the GNU C Library])
 872 fi
 873
 874 # Need to reject headers which give warnings, so that the -Werror bootstrap
 875 # works later. *sigh*  This needs to come before all header checks.
 876 AC_PROG_CPP_WERROR
 877
 878 AC_HEADER_STDC
 879 AC_HEADER_TIME
 880 ACX_HEADER_STRING
 881 AC_HEADER_SYS_WAIT
 882 AC_CHECK_HEADERS(limits.h stddef.h string.h strings.h stdlib.h time.h iconv.h \
 883                  fcntl.h unistd.h sys/file.h sys/time.h sys/mman.h \
 884                  sys/resource.h sys/param.h sys/times.h sys/stat.h \
 885                  direct.h malloc.h langinfo.h ldfcn.h locale.h wchar.h)
 886
 887 # Check for thread headers.
 888 AC_CHECK_HEADER(thread.h, [have_thread_h=yes], [have_thread_h=])
 889 AC_CHECK_HEADER(pthread.h, [have_pthread_h=yes], [have_pthread_h=])
 890
 891 # These tests can't be done till we know if we have limits.h.
 892 gcc_AC_C_CHAR_BIT
 893 AC_C_BIGENDIAN
 894
 895 # --------
 896 # UNSORTED
 897 # --------
 898
 899 # Stage specific cflags for build.
 900 stage1_cflags=
 901 case $build in
 902 vax-*-*)
 903   if test x$GCC = xyes
 904   then
 905     stage1_cflags="-Wa,-J"
 906   else
 907     stage1_cflags="-J"
 908   fi
 909   ;;
 910 powerpc-*-darwin*)
 911   # The spiffy cpp-precomp chokes on some legitimate constructs in GCC
 912   # sources; use -no-cpp-precomp to get to GNU cpp.
 913   # Apple's GCC has bugs in designated initializer handling, so disable
 914   # that too.
 915   stage1_cflags="-no-cpp-precomp -DHAVE_DESIGNATED_INITIALIZERS=0"
 916   ;;
 917 esac
 918 AC_SUBST(stage1_cflags)
 919
 920 # These libraries may be used by collect2.
 921 # We may need a special search path to get them linked.
 922 AC_CACHE_CHECK(for collect2 libraries, gcc_cv_collect2_libs,
 923 [save_LIBS="$LIBS"
 924 for libs in '' -lld -lmld \
 925                 '-L/usr/lib/cmplrs/cc2.11 -lmld' \
 926                 '-L/usr/lib/cmplrs/cc3.11 -lmld'
 927 do
 928         LIBS="$libs"
 929         AC_TRY_LINK_FUNC(ldopen,
 930                 [gcc_cv_collect2_libs="$libs"; break])
 931 done
 932 LIBS="$save_LIBS"
 933 test -z "$gcc_cv_collect2_libs" && gcc_cv_collect2_libs='none required'])
 934 case $gcc_cv_collect2_libs in
 935         "none required")        ;;
 936         *)      COLLECT2_LIBS=$gcc_cv_collect2_libs ;;
 937 esac
 938 AC_SUBST(COLLECT2_LIBS)
 939
 940 # When building Ada code on Alpha, we need exc_resume which is usually in
 941 # -lexc.  So test for it.
 942 save_LIBS="$LIBS"
 943 LIBS=
 944 AC_SEARCH_LIBS(exc_resume, exc)
 945 GNAT_LIBEXC="$LIBS"
 946 LIBS="$save_LIBS"
 947 AC_SUBST(GNAT_LIBEXC)
 948
 949 # Some systems put ldexp and frexp in libm instead of libc; assume
 950 # they're both in the same place.  jcf-dump needs them.
 951 save_LIBS="$LIBS"
 952 LIBS=
 953 AC_SEARCH_LIBS(ldexp, m)
 954 LDEXP_LIB="$LIBS"
 955 LIBS="$save_LIBS"
 956 AC_SUBST(LDEXP_LIB)
 957
 958 # Use <inttypes.h> only if it exists,
 959 # doesn't clash with <sys/types.h>, and declares intmax_t.
 960 AC_MSG_CHECKING(for inttypes.h)
 961 AC_CACHE_VAL(gcc_cv_header_inttypes_h,
 962 [AC_TRY_COMPILE(
 963   [#include <sys/types.h>
 964 #include <inttypes.h>],
 965   [intmax_t i = -1;],
 966   [gcc_cv_header_inttypes_h=yes],
 967   gcc_cv_header_inttypes_h=no)])
 968 AC_MSG_RESULT($gcc_cv_header_inttypes_h)
 969 if test $gcc_cv_header_inttypes_h = yes; then
 970   AC_DEFINE(HAVE_INTTYPES_H, 1,
 971         [Define if you have a working <inttypes.h> header file.])
 972 fi
 973
 974 dnl Disabled until we have a complete test for buggy enum bitfields.
 975 dnl gcc_AC_C_ENUM_BF_UNSIGNED
 976
 977 define(gcc_UNLOCKED_FUNCS, clearerr_unlocked feof_unlocked dnl
 978   ferror_unlocked fflush_unlocked fgetc_unlocked fgets_unlocked dnl
 979   fileno_unlocked fprintf_unlocked fputc_unlocked fputs_unlocked dnl
 980   fread_unlocked fwrite_unlocked getchar_unlocked getc_unlocked dnl
 981   putchar_unlocked putc_unlocked)
 982 AC_CHECK_FUNCS(times clock dup2 kill getrlimit setrlimit atoll atoq \
 983         sysconf strsignal getrusage nl_langinfo scandir alphasort \
 984         gettimeofday mbstowcs wcswidth mmap mincore setlocale \
 985         gcc_UNLOCKED_FUNCS)
 986
 987 if test x$ac_cv_func_mbstowcs = xyes; then
 988   AC_CACHE_CHECK(whether mbstowcs works, gcc_cv_func_mbstowcs_works,
 989 [    AC_TRY_RUN([#include <stdlib.h>
 990 int main()
 991 {
 992   mbstowcs(0, "", 0);
 993   return 0;
 994 }],
 995     gcc_cv_func_mbstowcs_works=yes,
 996     gcc_cv_func_mbstowcs_works=no,
 997     gcc_cv_func_mbstowcs_works=yes)])
 998   if test x$gcc_cv_func_mbstowcs_works = xyes; then
 999     AC_DEFINE(HAVE_WORKING_MBSTOWCS, 1,
1000   [Define this macro if mbstowcs does not crash when its
1001    first argument is NULL.])
1002   fi
1003 fi
1004
1005 AC_CHECK_TYPE(ssize_t, int)
1006
1007 # Try to determine the array type of the second argument of getgroups
1008 # for the target system (int or gid_t).
1009 AC_TYPE_GETGROUPS
1010 if test "${target}" = "${build}"; then
1011   TARGET_GETGROUPS_T=$ac_cv_type_getgroups
1012 else
1013   case "${target}" in
1014         # This condition may need some tweaking.  It should include all
1015         # targets where the array type of the second argument of getgroups
1016         # is int and the type of gid_t is not equivalent to int.
1017         *-*-sunos* | *-*-ultrix*)
1018                 TARGET_GETGROUPS_T=int
1019                 ;;
1020         *)
1021                 TARGET_GETGROUPS_T=gid_t
1022                 ;;
1023   esac
1024 fi
1025 AC_SUBST(TARGET_GETGROUPS_T)
1026
1027 gcc_AC_FUNC_PRINTF_PTR
1028 gcc_AC_FUNC_MMAP_BLACKLIST
1029
1030 case "${host}" in
1031 *-*-*vms*)
1032   # Under VMS, vfork works very differently than on Unix. The standard test
1033   # won't work, and it isn't easily adaptable. It makes more sense to
1034   # just force it.
1035   ac_cv_func_vfork_works=yes
1036   ;;
1037 esac
1038 AC_FUNC_VFORK
1039
1040 AM_ICONV
1041 # Until we have in-tree GNU iconv:
1042 LIBICONV_DEP=
1043 AC_SUBST(LIBICONV_DEP)
1044
1045 AM_LC_MESSAGES
1046
1047 AM_LANGINFO_CODESET
1048
1049 # We will need to find libiberty.h and ansidecl.h
1050 saved_CFLAGS="$CFLAGS"
1051 CFLAGS="$CFLAGS -I${srcdir} -I${srcdir}/../include"
1052 gcc_AC_CHECK_DECLS(getenv atol asprintf sbrk abort atof getcwd getwd strsignal \
1053         strstr errno snprintf vsnprintf vasprintf malloc realloc calloc \
1054         free basename getopt clock getpagesize gcc_UNLOCKED_FUNCS, , ,[
1055 #include "ansidecl.h"
1056 #include "system.h"])
1057
1058 gcc_AC_CHECK_DECLS(getrlimit setrlimit getrusage, , ,[
1059 #include "ansidecl.h"
1060 #include "system.h"
1061 #ifdef HAVE_SYS_RESOURCE_H
1062 #include <sys/resource.h>
1063 #endif
1064 ])
1065
1066 AC_TRY_COMPILE([
1067 #include "ansidecl.h"
1068 #include "system.h"
1069 #ifdef HAVE_SYS_RESOURCE_H
1070 #include <sys/resource.h>
1071 #endif
1072 ],[rlim_t l = 0;],,[AC_DEFINE([rlim_t],[long],
1073 [Define to \`long' if <sys/resource.h> doesn't define.])])
1074
1075 # On AIX 5.2, <ldfcn.h> conflicts with <fcntl.h>, as both define incompatible
1076 # FREAD and FWRITE macros.  Fortunately, for GCC's single usage of ldgetname
1077 # in collect2.c, <fcntl.h> isn't visible, but the configure test below needs
1078 # to undef these macros to get the correct value for HAVE_DECL_LDGETNAME.
1079 gcc_AC_CHECK_DECLS(ldgetname, , ,[
1080 #include "ansidecl.h"
1081 #include "system.h"
1082 #ifdef HAVE_LDFCN_H
1083 #undef FREAD
1084 #undef FWRITE
1085 #include <ldfcn.h>
1086 #endif
1087 ])
1088
1089 gcc_AC_CHECK_DECLS(times, , ,[
1090 #include "ansidecl.h"
1091 #include "system.h"
1092 #ifdef HAVE_SYS_TIMES_H
1093 #include <sys/times.h>
1094 #endif
1095 ])
1096
1097 # More time-related stuff.
1098 AC_CACHE_CHECK(for struct tms, ac_cv_struct_tms, [
1099 AC_TRY_COMPILE([
1100 #include "ansidecl.h"
1101 #include "system.h"
1102 #ifdef HAVE_SYS_TIMES_H
1103 #include <sys/times.h>
1104 #endif
1105 ], [struct tms tms;], ac_cv_struct_tms=yes, ac_cv_struct_tms=no)])
1106 if test $ac_cv_struct_tms = yes; then
1107   AC_DEFINE(HAVE_STRUCT_TMS, 1,
1108   [Define if <sys/times.h> defines struct tms.])
1109 fi
1110
1111 # use gcc_cv_* here because this doesn't match the behavior of AC_CHECK_TYPE.
1112 # revisit after autoconf 2.50.
1113 AC_CACHE_CHECK(for clock_t, gcc_cv_type_clock_t, [
1114 AC_TRY_COMPILE([
1115 #include "ansidecl.h"
1116 #include "system.h"
1117 ], [clock_t x;], gcc_cv_type_clock_t=yes, gcc_cv_type_clock_t=no)])
1118 if test $gcc_cv_type_clock_t = yes; then
1119   AC_DEFINE(HAVE_CLOCK_T, 1,
1120   [Define if <time.h> defines clock_t.])
1121 fi
1122
1123 # Restore CFLAGS from before the gcc_AC_NEED_DECLARATIONS tests.
1124 CFLAGS="$saved_CFLAGS"
1125
1126 gcc_AC_INITFINI_ARRAY
1127
1128 # mkdir takes a single argument on some systems.
1129 gcc_AC_FUNC_MKDIR_TAKES_ONE_ARG
1130
1131 # File extensions
1132 manext='.1'
1133 objext='.o'
1134 AC_SUBST(manext)
1135 AC_SUBST(objext)
1136
1137 # With Setjmp/Longjmp based exception handling.
1138 AC_ARG_ENABLE(sjlj-exceptions,
1139 [  --enable-sjlj-exceptions
1140                           arrange to use setjmp/longjmp exception handling],
1141 [sjlj=`if test $enableval = yes; then echo 1; else echo 0; fi`
1142 AC_DEFINE_UNQUOTED(CONFIG_SJLJ_EXCEPTIONS, $sjlj,
1143   [Define 0/1 to force the choice for exception handling model.])])
1144
1145 # For platforms with the unwind ABI which includes an unwind library,
1146 # libunwind, we can choose to use the system libunwind.
1147 AC_ARG_WITH(system-libunwind,
1148 [  --with-system-libunwind use installed libunwind])
1149
1150 # --------------------------------------------------------
1151 # Build, host, and target specific configuration fragments
1152 # --------------------------------------------------------
1153
1154 # Collect build-machine-specific information.
1155 . ${srcdir}/config.build
1156
1157 # Collect host-machine-specific information.
1158 . ${srcdir}/config.host
1159
1160 target_gtfiles=
1161
1162 # Collect target-machine-specific information.
1163 . ${srcdir}/config.gcc
1164
1165 extra_objs="${host_extra_objs} ${extra_objs}"
1166 extra_gcc_objs="${host_extra_gcc_objs} ${extra_gcc_objs}"
1167
1168 # Default the target-machine variables that were not explicitly set.
1169 if test x"$tm_file" = x
1170 then tm_file=$cpu_type/$cpu_type.h; fi
1171
1172 if test x"$extra_headers" = x
1173 then extra_headers=; fi
1174
1175 if test x$md_file = x
1176 then md_file=$cpu_type/$cpu_type.md; fi
1177
1178 if test x$out_file = x
1179 then out_file=$cpu_type/$cpu_type.c; fi
1180
1181 if test x"$tmake_file" = x
1182 then tmake_file=$cpu_type/t-$cpu_type
1183 fi
1184
1185 if test x"$dwarf2" = xyes
1186 then tm_file="$tm_file tm-dwarf2.h"
1187 fi
1188
1189 # Say what files are being used for the output code and MD file.
1190 echo "Using \`$srcdir/config/$out_file' for machine-specific logic."
1191 echo "Using \`$srcdir/config/$md_file' as machine description file."
1192
1193 # If any of the xm_file variables contain nonexistent files, warn
1194 # about them and drop them.
1195
1196 bx=
1197 for x in $build_xm_file; do
1198   if    test -f $srcdir/config/$x
1199   then      bx="$bx $x"
1200   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1201   fi
1202 done
1203 build_xm_file="$bx"
1204
1205 hx=
1206 for x in $host_xm_file; do
1207   if    test -f $srcdir/config/$x
1208   then      hx="$hx $x"
1209   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1210   fi
1211 done
1212 host_xm_file="$hx"
1213
1214 tx=
1215 for x in $xm_file; do
1216   if    test -f $srcdir/config/$x
1217   then      tx="$tx $x"
1218   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1219   fi
1220 done
1221 xm_file="$tx"
1222
1223 count=a
1224 for f in $tm_file; do
1225         count=${count}x
1226 done
1227 if test $count = ax; then
1228         echo "Using \`$srcdir/config/$tm_file' as target machine macro file."
1229 else
1230         echo "Using the following target machine macro files:"
1231         for f in $tm_file; do
1232                 echo "  $srcdir/config/$f"
1233         done
1234 fi
1235
1236 if test x$need_64bit_hwint = xyes; then
1237         AC_DEFINE(NEED_64BIT_HOST_WIDE_INT, 1,
1238 [Define to 1 if HOST_WIDE_INT must be 64 bits wide (see hwint.h).])
1239 fi
1240
1241 if test x$use_long_long_for_widest_fast_int = xyes; then
1242         AC_DEFINE(USE_LONG_LONG_FOR_WIDEST_FAST_INT, 1,
1243 [Define to 1 if the 'long long' (or '__int64') is wider than 'long' but still
1244 efficiently supported by the host hardware.])
1245 fi
1246
1247 count=a
1248 for f in $host_xm_file; do
1249         count=${count}x
1250 done
1251 if test $count = a; then
1252         :
1253 elif test $count = ax; then
1254         echo "Using \`$srcdir/config/$host_xm_file' as host machine macro file."
1255 else
1256         echo "Using the following host machine macro files:"
1257         for f in $host_xm_file; do
1258                 echo "  $srcdir/config/$f"
1259         done
1260 fi
1261 echo "Using ${out_host_hook_obj} for host machine hooks."
1262
1263 if test "$host_xm_file" != "$build_xm_file"; then
1264         count=a
1265         for f in $build_xm_file; do
1266                 count=${count}x
1267         done
1268         if test $count = a; then
1269                 :
1270         elif test $count = ax; then
1271                 echo "Using \`$srcdir/config/$build_xm_file' as build machine macro file."
1272         else
1273                 echo "Using the following build machine macro files:"
1274                 for f in $build_xm_file; do
1275                         echo "  $srcdir/config/$f"
1276                 done
1277         fi
1278 fi
1279
1280 # ---------
1281 # Threading
1282 # ---------
1283
1284 # Check if a valid thread package
1285 case ${enable_threads} in
1286   "" | no)
1287     # No threads
1288     target_thread_file='single'
1289     ;;
1290   yes)
1291     # default
1292     target_thread_file='single'
1293     ;;
1294   aix | dce | gnat | irix | posix | posix95 | rtems | \
1295   single | solaris | vxworks | win32 )
1296     target_thread_file=${enable_threads}
1297     ;;
1298   *)
1299     echo "${enable_threads} is an unknown thread package" 1>&2
1300     exit 1
1301     ;;
1302 esac
1303
1304 if test x${thread_file} = x; then
1305   # No thread file set by target-specific clauses in config.gcc,
1306   # so use file chosen by default logic above
1307   thread_file=${target_thread_file}
1308 fi
1309
1310 # Make gthr-default.h if we have a thread file.
1311 gthread_flags=
1312 if test $thread_file != single; then
1313   rm -f gthr-default.h
1314   echo "#include \"gthr-${thread_file}.h\"" > gthr-default.h
1315   gthread_flags=-DHAVE_GTHR_DEFAULT
1316 fi
1317 AC_SUBST(gthread_flags)
1318
1319 # --------
1320 # UNSORTED
1321 # --------
1322
1323 use_cxa_atexit=no
1324 if test x$enable___cxa_atexit = xyes || \
1325    test x$enable___cxa_atexit = x -a x$default_use_cxa_atexit = xyes; then
1326   if test x$host = x$target; then
1327     AC_CHECK_FUNC(__cxa_atexit,[use_cxa_atexit=yes],
1328         [echo "__cxa_atexit can't be enabled on this target"])
1329   else
1330     # We can't check for __cxa_atexit when building a cross, so assume
1331     # it is available
1332     use_cxa_atexit=yes
1333   fi
1334   if test x$use_cxa_atexit = xyes; then
1335     AC_DEFINE(DEFAULT_USE_CXA_ATEXIT, 1,
1336       [Define if you want to use __cxa_atexit, rather than atexit, to
1337       register C++ destructors for local statics and global objects.
1338       This is essential for fully standards-compliant handling of
1339       destructors, but requires __cxa_atexit in libc.])
1340   fi
1341 fi
1342
1343 # Look for a file containing extra machine modes.
1344 if test -n "$extra_modes" && test -f $srcdir/config/$extra_modes; then
1345   extra_modes_file='$(srcdir)'/config/${extra_modes}
1346   AC_SUBST(extra_modes_file)
1347   AC_DEFINE_UNQUOTED(EXTRA_MODES_FILE, "config/$extra_modes",
1348   [Define to the name of a file containing a list of extra machine modes
1349    for this architecture.])
1350 fi
1351
1352 # Convert extra_options into a form suitable for Makefile use.
1353 extra_opt_files=
1354 for f in $extra_options; do
1355   extra_opt_files="$extra_opt_files \$(srcdir)/config/$f"
1356 done
1357 AC_SUBST(extra_opt_files)
1358
1359 # auto-host.h is the file containing items generated by autoconf and is
1360 # the first file included by config.h.
1361 # If host=build, it is correct to have bconfig include auto-host.h
1362 # as well.  If host!=build, we are in error and need to do more
1363 # work to find out the build config parameters.
1364 if test x$host = x$build
1365 then
1366         build_auto=auto-host.h
1367 else
1368         # We create a subdir, then run autoconf in the subdir.
1369         # To prevent recursion we set host and build for the new
1370         # invocation of configure to the build for this invocation
1371         # of configure.
1372         tempdir=build.$$
1373         rm -rf $tempdir
1374         mkdir $tempdir
1375         cd $tempdir
1376         case ${srcdir} in
1377         /* | [A-Za-z]:[\\/]* ) realsrcdir=${srcdir};;
1378         *) realsrcdir=../${srcdir};;
1379         esac
1380         saved_CFLAGS="${CFLAGS}"
1381         CC="${CC_FOR_BUILD}" CFLAGS="${CFLAGS_FOR_BUILD}" \
1382         ${realsrcdir}/configure \
1383                 --enable-languages=${enable_languages-all} \
1384                 --target=$target_alias --host=$build_alias --build=$build_alias
1385         CFLAGS="${saved_CFLAGS}"
1386
1387         # We just finished tests for the build machine, so rename
1388         # the file auto-build.h in the gcc directory.
1389         mv auto-host.h ../auto-build.h
1390         cd ..
1391         rm -rf $tempdir
1392         build_auto=auto-build.h
1393 fi
1394 AC_SUBST(build_subdir)
1395
1396 tm_file="${tm_file} defaults.h"
1397 tm_p_file="${tm_p_file} tm-preds.h"
1398 host_xm_file="auto-host.h ansidecl.h ${host_xm_file}"
1399 build_xm_file="${build_auto} ansidecl.h ${build_xm_file}"
1400 # We don't want ansidecl.h in target files, write code there in ISO/GNU C.
1401 # put this back in temporarily.
1402 xm_file="auto-host.h ansidecl.h ${xm_file}"
1403
1404 # --------
1405 # UNSORTED
1406 # --------
1407
1408 changequote(,)dnl
1409 # Compile in configure arguments.
1410 if test -f configargs.h ; then
1411         # Being re-configured.
1412         gcc_config_arguments=`grep configuration_arguments configargs.h | sed -e 's/.*"\([^"]*\)".*/\1/'`
1413         gcc_config_arguments="$gcc_config_arguments : (reconfigured) $TOPLEVEL_CONFIGURE_ARGUMENTS"
1414 else
1415         gcc_config_arguments="$TOPLEVEL_CONFIGURE_ARGUMENTS"
1416 fi
1417
1418 # Double all backslashes and backslash all quotes to turn
1419 # gcc_config_arguments into a C string.
1420 sed -e 's/\\/\\\\/g; s/"/\\"/g' <<EOF >conftest.out
1421 $gcc_config_arguments
1422 EOF
1423 gcc_config_arguments_str=`cat conftest.out`
1424 rm -f conftest.out
1425
1426 cat > configargs.h <<EOF
1427 /* Generated automatically. */
1428 static const char configuration_arguments[] = "$gcc_config_arguments_str";
1429 static const char thread_model[] = "$thread_file";
1430
1431 static const struct {
1432   const char *name, *value;
1433 } configure_default_options[] = $configure_default_options;
1434 EOF
1435 changequote([,])dnl
1436
1437 # Internationalization
1438 ZW_GNU_GETTEXT_SISTER_DIR
1439
1440 # If LIBINTL contains LIBICONV, then clear LIBICONV so we don't get
1441 # -liconv on the link line twice.
1442 case "$LIBINTL" in *$LIBICONV*)
1443         LIBICONV= ;;
1444 esac
1445
1446 AC_ARG_ENABLE(secureplt,
1447 [  --enable-secureplt      enable -msecure-plt by default for PowerPC],
1448 [], [])
1449
1450 # Windows32 Registry support for specifying GCC installation paths.
1451 AC_ARG_ENABLE(win32-registry,
1452 [  --disable-win32-registry
1453                           disable lookup of installation paths in the
1454                           Registry on Windows hosts
1455   --enable-win32-registry enable registry lookup (default)
1456   --enable-win32-registry=KEY
1457                           use KEY instead of GCC version as the last portion
1458                           of the registry key],,)
1459
1460 case $host_os in
1461   win32 | pe | cygwin* | mingw32* | uwin*)
1462     if test "x$enable_win32_registry" != xno; then
1463       AC_SEARCH_LIBS(RegOpenKeyExA, advapi32,, [enable_win32_registry=no])
1464     fi
1465
1466     if test "x$enable_win32_registry" != xno; then
1467       AC_DEFINE(ENABLE_WIN32_REGISTRY, 1,
1468   [Define to 1 if installation paths should be looked up in the Windows
1469    Registry. Ignored on non-Windows hosts.])
1470
1471       if test "x$enable_win32_registry" != xyes \
1472          && test "x$enable_win32_registry" != x; then
1473         AC_DEFINE_UNQUOTED(WIN32_REGISTRY_KEY, "$enable_win32_registry",
1474   [Define to be the last component of the Windows registry key under which
1475    to look for installation paths.  The full key used will be
1476    HKEY_LOCAL_MACHINE/SOFTWARE/Free Software Foundation/{WIN32_REGISTRY_KEY}.
1477    The default is the GCC version number.])
1478       fi
1479     fi
1480   ;;
1481 esac
1482
1483 # Get an absolute path to the GCC top-level source directory
1484 holddir=`${PWDCMD-pwd}`
1485 cd $srcdir
1486 topdir=`${PWDCMD-pwd}`
1487 cd $holddir
1488
1489 # Conditionalize the makefile for this host machine.
1490 xmake_file=
1491 for f in ${host_xmake_file}
1492 do
1493         if test -f ${srcdir}/config/$f
1494         then
1495                 xmake_file="${xmake_file} \$(srcdir)/config/$f"
1496         fi
1497 done
1498
1499 # Conditionalize the makefile for this target machine.
1500 tmake_file_=
1501 for f in ${tmake_file}
1502 do
1503         if test -f ${srcdir}/config/$f
1504         then
1505                 tmake_file_="${tmake_file_} \$(srcdir)/config/$f"
1506         fi
1507 done
1508 tmake_file="${tmake_file_}"
1509
1510 # If the host doesn't support symlinks, modify CC in
1511 # FLAGS_TO_PASS so CC="stage1/xgcc -Bstage1/" works.
1512 # Otherwise, we can use "CC=$(CC)".
1513 rm -f symtest.tem
1514 case "$LN_S" in
1515         *-s*)
1516                 cc_set_by_configure="\$(CC)"
1517                 quoted_cc_set_by_configure="\$(CC)"
1518                 stage_prefix_set_by_configure="\$(STAGE_PREFIX)"
1519                 quoted_stage_prefix_set_by_configure="\$(STAGE_PREFIX)"
1520                 ;;
1521         *)
1522                 cc_set_by_configure="\`case '\$(CC)' in stage*) echo '\$(CC)' | sed -e 's|stage|../stage|g';; *) echo '\$(CC)';; esac\`"
1523                 quoted_cc_set_by_configure="\\\`case '\\\$(CC)' in stage*) echo '\\\$(CC)' | sed -e 's|stage|../stage|g';; *) echo '\\\$(CC)';; esac\\\`"
1524                 stage_prefix_set_by_configure="\`case '\$(STAGE_PREFIX)' in stage*) echo '\$(STAGE_PREFIX)' | sed -e 's|stage|../stage|g';; *) echo '\$(STAGE_PREFIX)';; esac\`"
1525                 quoted_stage_prefix_set_by_configure="\\\`case '\\\$(STAGE_PREFIX)' in stage*) echo '\\\$(STAGE_PREFIX)' | sed -e 's|stage|../stage|g';; *) echo '\\\$(STAGE_PREFIX)';; esac\\\`"
1526                 ;;
1527 esac
1528
1529 # This is a terrible hack which will go away some day.
1530 host_cc_for_libada=${CC}
1531 AC_SUBST(host_cc_for_libada)
1532
1533 out_object_file=`basename $out_file .c`.o
1534
1535 tm_file_list="options.h"
1536 tm_include_list="options.h"
1537 for f in $tm_file; do
1538   case $f in
1539     defaults.h )
1540        tm_file_list="${tm_file_list} \$(srcdir)/$f"
1541        tm_include_list="${tm_include_list} $f"
1542        ;;
1543     * )
1544        tm_file_list="${tm_file_list} \$(srcdir)/config/$f"
1545        tm_include_list="${tm_include_list} config/$f"
1546        ;;
1547   esac
1548 done
1549
1550 tm_p_file_list=
1551 tm_p_include_list=
1552 for f in $tm_p_file; do
1553   case $f in
1554     tm-preds.h )
1555        tm_p_file_list="${tm_p_file_list} $f"
1556        tm_p_include_list="${tm_p_include_list} $f"
1557        ;;
1558     * )
1559        tm_p_file_list="${tm_p_file_list} \$(srcdir)/config/$f"
1560        tm_p_include_list="${tm_p_include_list} config/$f"
1561   esac
1562 done
1563
1564 xm_file_list=
1565 xm_include_list=
1566 for f in $xm_file; do
1567   case $f in
1568     ansidecl.h )
1569        xm_file_list="${xm_file_list} \$(srcdir)/../include/$f"
1570        xm_include_list="${xm_include_list} $f"
1571        ;;
1572     auto-host.h )
1573        xm_file_list="${xm_file_list} $f"
1574        xm_include_list="${xm_include_list} $f"
1575        ;;
1576     * )
1577        xm_file_list="${xm_file_list} \$(srcdir)/config/$f"
1578        xm_include_list="${xm_include_list} config/$f"
1579        ;;
1580   esac
1581 done
1582
1583 host_xm_file_list=
1584 host_xm_include_list=
1585 for f in $host_xm_file; do
1586   case $f in
1587     ansidecl.h )
1588        host_xm_file_list="${host_xm_file_list} \$(srcdir)/../include/$f"
1589        host_xm_include_list="${host_xm_include_list} $f"
1590        ;;
1591     auto-host.h )
1592        host_xm_file_list="${host_xm_file_list} $f"
1593        host_xm_include_list="${host_xm_include_list} $f"
1594        ;;
1595     * )
1596        host_xm_file_list="${host_xm_file_list} \$(srcdir)/config/$f"
1597        host_xm_include_list="${host_xm_include_list} config/$f"
1598        ;;
1599   esac
1600 done
1601
1602 build_xm_file_list=
1603 for f in $build_xm_file; do
1604   case $f in
1605     ansidecl.h )
1606        build_xm_file_list="${build_xm_file_list} \$(srcdir)/../include/$f"
1607        build_xm_include_list="${build_xm_include_list} $f"
1608        ;;
1609     auto-build.h | auto-host.h )
1610        build_xm_file_list="${build_xm_file_list} $f"
1611        build_xm_include_list="${build_xm_include_list} $f"
1612        ;;
1613     * )
1614        build_xm_file_list="${build_xm_file_list} \$(srcdir)/config/$f"
1615        build_xm_include_list="${build_xm_include_list} config/$f"
1616        ;;
1617   esac
1618 done
1619
1620 # Define macro CROSS_COMPILE in compilation if this is a cross-compiler.
1621 # Also use all.cross instead of all.internal and adjust SYSTEM_HEADER_DIR.
1622 CROSS=                                          AC_SUBST(CROSS)
1623 ALL=all.internal                                AC_SUBST(ALL)
1624 SYSTEM_HEADER_DIR='$(NATIVE_SYSTEM_HEADER_DIR)' AC_SUBST(SYSTEM_HEADER_DIR)
1625 if test x$host != x$target
1626 then
1627         CROSS="-DCROSS_COMPILE"
1628         ALL=all.cross
1629         SYSTEM_HEADER_DIR='$(CROSS_SYSTEM_HEADER_DIR)'
1630         case "$host","$target" in
1631         # Darwin crosses can use the host system's libraries and headers,
1632         # because of the fat library support.  Of course, it must be the
1633         # same version of Darwin on both sides.  Allow the user to
1634         # just say --target=foo-darwin without a version number to mean
1635         # "the version on this system".
1636             *-*-darwin*,*-*-darwin*)
1637                 hostos=`echo $host | sed 's/.*-darwin/darwin/'`
1638                 targetos=`echo $target | sed 's/.*-darwin/darwin/'`
1639                 if test $hostos = $targetos -o $targetos = darwin ; then
1640                     CROSS=
1641                     SYSTEM_HEADER_DIR='$(NATIVE_SYSTEM_HEADER_DIR)'
1642                     with_headers=yes
1643                 fi
1644                 ;;
1645
1646             i?86-*-*,x86_64-*-* \
1647             | powerpc*-*-*,powerpc64*-*-*)
1648                 CROSS="$CROSS -DNATIVE_CROSS" ;;
1649         esac
1650 elif test "x$TARGET_SYSTEM_ROOT" != x; then
1651         # This is just $(TARGET_SYSTEM_ROOT)$(NATIVE_SYSTEM_HEADER_DIR)
1652         SYSTEM_HEADER_DIR='$(CROSS_SYSTEM_HEADER_DIR)'
1653 fi
1654
1655 # If this is a cross-compiler that does not
1656 # have its own set of headers then define
1657 # inhibit_libc
1658
1659 # If this is using newlib, without having the headers available now,
1660 # then define inhibit_libc in LIBGCC2_CFLAGS.
1661 # This prevents libgcc2 from containing any code which requires libc
1662 # support.
1663 inhibit_libc=
1664 if { { test x$host != x$target && test "x$with_sysroot" = x ; } ||
1665        test x$with_newlib = xyes ; } &&
1666      { test "x$with_headers" = x || test "x$with_headers" = xno ; } ; then
1667        inhibit_libc=-Dinhibit_libc
1668 fi
1669 AC_SUBST(inhibit_libc)
1670
1671 # When building gcc with a cross-compiler, we need to adjust things so
1672 # that the generator programs are still built with the native compiler.
1673 # Also, we cannot run fixincludes or fix-header.
1674
1675 # These are the normal (build=host) settings:
1676 CC_FOR_BUILD='$(CC)'            AC_SUBST(CC_FOR_BUILD)
1677 BUILD_CFLAGS='$(ALL_CFLAGS)'    AC_SUBST(BUILD_CFLAGS)
1678 STMP_FIXINC=stmp-fixinc         AC_SUBST(STMP_FIXINC)
1679
1680 # Possibly disable fixproto, on a per-target basis.
1681 case ${use_fixproto} in
1682   no)
1683     STMP_FIXPROTO=
1684     ;;
1685   yes)
1686     STMP_FIXPROTO=stmp-fixproto
1687     ;;
1688 esac
1689 AC_SUBST(STMP_FIXPROTO)
1690
1691 # And these apply if build != host, or we are generating coverage data
1692 if test x$build != x$host || test "x$coverage_flags" != x
1693 then
1694     BUILD_CFLAGS='$(INTERNAL_CFLAGS) $(T_CFLAGS) $(CFLAGS_FOR_BUILD)'
1695
1696     if test "x$TARGET_SYSTEM_ROOT" = x; then
1697         if test "x$STMP_FIXPROTO" != x; then
1698           STMP_FIXPROTO=stmp-install-fixproto
1699         fi
1700     fi
1701 fi
1702
1703 # Expand extra_headers to include complete path.
1704 # This substitutes for lots of t-* files.
1705 extra_headers_list=
1706 # Prepend $(srcdir)/config/${cpu_type}/ to every entry in extra_headers.
1707 for file in ${extra_headers} ; do
1708   extra_headers_list="${extra_headers_list} \$(srcdir)/config/${cpu_type}/${file}"
1709 done
1710
1711 # Define collect2 in Makefile.
1712 case $host_can_use_collect2 in
1713   no) collect2= ;;
1714   *) collect2='collect2$(exeext)' ;;
1715 esac
1716 AC_SUBST([collect2])
1717
1718 # Add a definition of USE_COLLECT2 if system wants one.
1719 case $use_collect2 in
1720   no) use_collect2= ;;
1721   "") ;;
1722   *)
1723     host_xm_defines="${host_xm_defines} USE_COLLECT2"
1724     xm_defines="${xm_defines} USE_COLLECT2"
1725     case $host_can_use_collect2 in
1726       no)
1727         AC_MSG_ERROR([collect2 is required but cannot be built on this system])
1728         ;;
1729     esac
1730     ;;
1731 esac
1732
1733 # ---------------------------
1734 # Assembler & linker features
1735 # ---------------------------
1736
1737 # Identify the assembler which will work hand-in-glove with the newly
1738 # built GCC, so that we can examine its features.  This is the assembler
1739 # which will be driven by the driver program.
1740 #
1741 # If build != host, and we aren't building gas in-tree, we identify a
1742 # build->target assembler and hope that it will have the same features
1743 # as the host->target assembler we'll be using.
1744 in_tree_gas=no
1745 gcc_cv_as=
1746 gcc_cv_gas_major_version=
1747 gcc_cv_gas_minor_version=
1748 gcc_cv_as_gas_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/gas
1749 if test -x "$DEFAULT_ASSEMBLER"; then
1750         gcc_cv_as="$DEFAULT_ASSEMBLER"
1751 elif test -f $gcc_cv_as_gas_srcdir/configure.in \
1752      && test -f ../gas/Makefile \
1753      && test x$build = x$host; then
1754   # Single tree build which includes gas.  We want to prefer it
1755   # over whatever linker top-level may have detected, since
1756   # we'll use what we're building after installation anyway.
1757   in_tree_gas=yes
1758   _gcc_COMPUTE_GAS_VERSION
1759   gcc_cv_as=../gas/as-new$build_exeext
1760   in_tree_gas_is_elf=no
1761   if grep 'obj_format = elf' ../gas/Makefile > /dev/null \
1762      || (grep 'obj_format = multi' ../gas/Makefile \
1763          && grep 'extra_objects =.* obj-elf' ../gas/Makefile) > /dev/null
1764   then
1765     in_tree_gas_is_elf=yes
1766   fi
1767 m4_pattern_allow([AS_FOR_TARGET])dnl
1768 elif test -x as$build_exeext; then
1769         # Build using assembler in the current directory.
1770         gcc_cv_as=./as$build_exeext
1771 elif test -x "$AS_FOR_TARGET"; then
1772         gcc_cv_as="$AS_FOR_TARGET"
1773 elif test -x "$AS" && test x$host = x$target; then
1774         gcc_cv_as="$AS"
1775 fi
1776
1777 gcc_AC_CHECK_TOOL(gcc_cv_as, as, ORIGINAL_AS_FOR_TARGET)
1778 AC_MSG_CHECKING(what assembler to use)
1779 case $in_tree_gas in
1780   yes)
1781     AC_MSG_RESULT("newly built gas")
1782     ;;
1783   no)
1784     AC_MSG_RESULT($gcc_cv_as)
1785     ;;
1786 esac
1787
1788 # Identify the linker which will work hand-in-glove with the newly
1789 # built GCC, so that we can examine its features.  This is the linker
1790 # which will be driven by the driver program.
1791 #
1792 # If build != host, and we aren't building gas in-tree, we identify a
1793 # build->target linker and hope that it will have the same features
1794 # as the host->target linker we'll be using.
1795 in_tree_ld=no
1796 gcc_cv_ld=
1797 gcc_cv_gld_major_version=
1798 gcc_cv_gld_minor_version=
1799 gcc_cv_ld_gld_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/ld
1800 gcc_cv_ld_bfd_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/bfd
1801 if test -x "$DEFAULT_LINKER"; then
1802         gcc_cv_ld="$DEFAULT_LINKER"
1803 elif test -f $gcc_cv_ld_gld_srcdir/configure.in \
1804      && test -f ../ld/Makefile \
1805      && test x$build = x$host; then
1806         # Single tree build which includes ld.  We want to prefer it
1807         # over whatever linker top-level may have detected, since
1808         # we'll use what we're building after installation anyway.
1809         in_tree_ld=yes
1810         in_tree_ld_is_elf=no
1811         if (grep 'EMUL = .*elf' ../ld/Makefile \
1812             || grep 'EMUL = .*linux' ../ld/Makefile \
1813             || grep 'EMUL = .*lynx' ../ld/Makefile) > /dev/null; then
1814           in_tree_ld_is_elf=yes
1815         fi
1816         for f in $gcc_cv_ld_bfd_srcdir/configure $gcc_cv_ld_gld_srcdir/configure $gcc_cv_ld_gld_srcdir/configure.in $gcc_cv_ld_gld_srcdir/Makefile.in
1817         do
1818 changequote(,)dnl
1819                 gcc_cv_gld_version=`sed -n -e 's/^[     ]*\(VERSION=[0-9]*\.[0-9]*.*\)/\1/p' < $f`
1820 changequote([,])dnl
1821                 if test x$gcc_cv_gld_version != x; then
1822                         break
1823                 fi
1824         done
1825 changequote(,)dnl
1826         gcc_cv_gld_major_version=`expr "$gcc_cv_gld_version" : "VERSION=\([0-9]*\)"`
1827         gcc_cv_gld_minor_version=`expr "$gcc_cv_gld_version" : "VERSION=[0-9]*\.\([0-9]*\)"`
1828 changequote([,])dnl
1829         gcc_cv_ld=../ld/ld-new$build_exeext
1830 elif test -x collect-ld$build_exeext; then
1831         # Build using linker in the current directory.
1832         gcc_cv_ld=./collect-ld$build_exeext
1833 elif test -x "$LD_FOR_TARGET"; then
1834         gcc_cv_ld="$LD_FOR_TARGET"
1835 elif test -x "$LD" && test x$host = x$target; then
1836         gcc_cv_ld="$LD"
1837 fi
1838
1839 gcc_AC_CHECK_TOOL(gcc_cv_ld, ld, ORIGINAL_LD_FOR_TARGET)
1840 AC_MSG_CHECKING(what linker to use)
1841 case $in_tree_ld in
1842   yes)
1843     AC_MSG_RESULT("newly built ld")
1844     ;;
1845   no)
1846     AC_MSG_RESULT($gcc_cv_ld)
1847     ;;
1848 esac
1849
1850 # Figure out what nm we will be using.
1851 gcc_cv_binutils_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/binutils
1852 in_tree_nm=no
1853 gcc_cv_nm=
1854 if test -f $gcc_cv_binutils_srcdir/configure.in \
1855      && test -f ../binutils/Makefile; then
1856         # Single tree build which includes binutils.
1857         in_tree_nm=yes
1858         gcc_cv_nm=../binutils/nm-new$build_exeext
1859 elif test -x nm$build_exeext; then
1860         gcc_cv_nm=./nm$build_exeext
1861 fi
1862
1863 gcc_AC_CHECK_TOOL(gcc_cv_nm, nm, ORIGINAL_NM_FOR_TARGET)
1864 AC_MSG_CHECKING(what nm to use)
1865 case $in_tree_nm in
1866   yes) AC_MSG_RESULT("newly built nm") ;;
1867   no)  AC_MSG_RESULT($gcc_cv_nm) ;;
1868 esac
1869
1870 # Figure out what objdump we will be using.
1871 AC_MSG_CHECKING(what objdump to use)
1872 in_tree_objdump=no
1873 if test -x objdump$build_exeext; then
1874         gcc_cv_objdump=./objdump$build_exeext
1875 elif test -f $gcc_cv_binutils_srcdir/configure.in \
1876      && test -f ../binutils/Makefile; then
1877         # Single tree build which includes binutils.
1878         in_tree_objdump=yes
1879         gcc_cv_objdump=../binutils/objdump$build_exeext
1880 elif test "x$program_prefix" != xNONE; then
1881         gcc_cv_objdump=${program_prefix}objdump$build_exeext
1882 elif test x$build != x$host && test x$build != x$target; then
1883         gcc_cv_objdump=${target_noncanonical}-objdump$build_exeext
1884 else
1885         gcc_cv_objdump=`echo objdump | \
1886                 sed "${program_transform_name}"`$build_exeext
1887 fi
1888 case $in_tree_objdump in
1889   yes) AC_MSG_RESULT("newly built objdump") ;;
1890   no)  AC_MSG_RESULT($gcc_cv_objdump) ;;
1891 esac
1892
1893 # Figure out what assembler alignment features are present.
1894 gcc_GAS_CHECK_FEATURE([.balign and .p2align], gcc_cv_as_balign_and_p2align,
1895  [2,6,0],,
1896 [.balign 4
1897 .p2align 2],,
1898 [AC_DEFINE(HAVE_GAS_BALIGN_AND_P2ALIGN, 1,
1899   [Define if your assembler supports .balign and .p2align.])])
1900
1901 gcc_GAS_CHECK_FEATURE([.p2align with maximum skip], gcc_cv_as_max_skip_p2align,
1902  [2,8,0],,
1903  [.p2align 4,,7],,
1904 [AC_DEFINE(HAVE_GAS_MAX_SKIP_P2ALIGN, 1,
1905   [Define if your assembler supports specifying the maximum number
1906    of bytes to skip when using the GAS .p2align command.])])
1907
1908 gcc_GAS_CHECK_FEATURE([working .subsection -1], gcc_cv_as_subsection_m1,
1909  [elf,2,9,0],,
1910  [conftest_label1: .word 0
1911 .subsection -1
1912 conftest_label2: .word 0
1913 .previous],
1914  [if test x$gcc_cv_nm != x; then
1915     $gcc_cv_nm conftest.o | grep conftest_label1 > conftest.nm1
1916     $gcc_cv_nm conftest.o | grep conftest_label2 | sed -e 's/label2/label1/' > conftest.nm2
1917     if cmp conftest.nm1 conftest.nm2 > /dev/null 2>&1
1918     then :
1919     else gcc_cv_as_subsection_m1=yes
1920     fi
1921     rm -f conftest.nm1 conftest.nm2
1922   fi],
1923  [AC_DEFINE(HAVE_GAS_SUBSECTION_ORDERING, 1,
1924   [Define if your assembler supports .subsection and .subsection -1 starts
1925    emitting at the beginning of your section.])])
1926
1927 gcc_GAS_CHECK_FEATURE([.weak], gcc_cv_as_weak,
1928  [2,2,0],,
1929  [      .weak foobar],,
1930 [AC_DEFINE(HAVE_GAS_WEAK, 1, [Define if your assembler supports .weak.])])
1931
1932 gcc_GAS_CHECK_FEATURE([.nsubspa comdat], gcc_cv_as_nsubspa_comdat,
1933  [2,15,91],,
1934  [      .SPACE $TEXT$
1935         .NSUBSPA $CODE$,COMDAT],,
1936 [AC_DEFINE(HAVE_GAS_NSUBSPA_COMDAT, 1, [Define if your assembler supports .nsubspa comdat option.])])
1937
1938 # .hidden needs to be supported in both the assembler and the linker,
1939 # because GNU LD versions before 2.12.1 have buggy support for STV_HIDDEN.
1940 # This is irritatingly difficult to feature test for; we have to check the
1941 # date string after the version number.  If we've got an in-tree
1942 # ld, we don't know its patchlevel version, so we set the baseline at 2.13
1943 # to be safe.
1944 # The gcc_GAS_CHECK_FEATURE call just sets a cache variable.
1945 gcc_GAS_CHECK_FEATURE([.hidden], gcc_cv_as_hidden,
1946  [elf,2,13,0],,
1947 [       .hidden foobar
1948 foobar:])
1949
1950 AC_CACHE_CHECK(linker for .hidden support, gcc_cv_ld_hidden,
1951 [if test $in_tree_ld = yes ; then
1952   gcc_cv_ld_hidden=no
1953   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 13 -o "$gcc_cv_gld_major_version" -gt 2 \
1954      && test $in_tree_ld_is_elf = yes; then
1955      gcc_cv_ld_hidden=yes
1956   fi
1957 else
1958   gcc_cv_ld_hidden=yes
1959   ld_ver=`$gcc_cv_ld --version 2>/dev/null | sed 1q`
1960   if echo "$ld_ver" | grep GNU > /dev/null; then
1961 changequote(,)dnl
1962     ld_vers=`echo $ld_ver | sed -n \
1963         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\)$,\1,p' \
1964         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\)$,\1,p' \
1965         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\)$,\1,p' \
1966         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\)[  ].*$,\1,p' \
1967         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\)[     ].*$,\1,p' \
1968         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\)[       ].*$,\1,p' \
1969         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\)[   ].*$,\1,p'`
1970     ld_date=`echo $ld_ver | sed -n 's,^.*\([2-9][0-9][0-9][0-9]\)[-]*\([01][0-9]\)[-]*\([0-3][0-9]\).*$,\1\2\3,p'`
1971     ld_vers_major=`expr "$ld_vers" : '\([0-9]*\)'`
1972     ld_vers_minor=`expr "$ld_vers" : '[0-9]*\.\([0-9]*\)'`
1973     ld_vers_patch=`expr "$ld_vers" : '[0-9]*\.[0-9]*\.\([0-9]*\)'`
1974     if test 0"$ld_date" -lt 20020404; then
1975       if test -n "$ld_date"; then
1976         # If there was date string, but was earlier than 2002-04-04, fail
1977         gcc_cv_ld_hidden=no
1978       elif test -z "$ld_vers"; then
1979         # If there was no date string nor ld version number, something is wrong
1980         gcc_cv_ld_hidden=no
1981       else
1982         test -z "$ld_vers_patch" && ld_vers_patch=0
1983         if test "$ld_vers_major" -lt 2; then
1984           gcc_cv_ld_hidden=no
1985         elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -lt 12; then
1986           gcc_cv_ld_hidden="no"
1987         elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -eq 12 -a "$ld_vers_patch" -eq 0; then
1988           gcc_cv_ld_hidden=no
1989         fi
1990       fi
1991 changequote([,])dnl
1992     fi
1993   else
1994     case "${target}" in
1995       hppa64*-*-hpux* | ia64*-*-hpux*)
1996         gcc_cv_ld_hidden=yes
1997         ;;
1998       *)
1999         gcc_cv_ld_hidden=no
2000         ;;
2001     esac
2002   fi
2003 fi])
2004 libgcc_visibility=no
2005 AC_SUBST(libgcc_visibility)
2006 GCC_TARGET_TEMPLATE([HAVE_GAS_HIDDEN])
2007 if test $gcc_cv_as_hidden = yes && test $gcc_cv_ld_hidden = yes; then
2008   libgcc_visibility=yes
2009   AC_DEFINE(HAVE_GAS_HIDDEN, 1,
2010   [Define if your assembler and linker support .hidden.])
2011 fi
2012
2013 # Check if we have .[us]leb128, and support symbol arithmetic with it.
2014 gcc_GAS_CHECK_FEATURE([.sleb128 and .uleb128], gcc_cv_as_leb128,
2015   [elf,2,11,0],,
2016 [       .data
2017         .uleb128 L2 - L1
2018 L1:
2019         .uleb128 1280
2020         .sleb128 -1010
2021 L2:],
2022  [# GAS versions before 2.11 do not support uleb128,
2023   # despite appearing to.
2024   # ??? There exists an elf-specific test that will crash
2025   # the assembler.  Perhaps it's better to figure out whether
2026   # arbitrary sections are supported and try the test.
2027   as_ver=`$gcc_cv_as --version 2>/dev/null | sed 1q`
2028   if echo "$as_ver" | grep GNU > /dev/null; then
2029 changequote(,)dnl
2030     as_ver=`echo $as_ver | sed -e 's/GNU assembler \([0-9.][0-9.]*\).*/\1/'`
2031     as_major=`echo $as_ver | sed 's/\..*//'`
2032     as_minor=`echo $as_ver | sed 's/[^.]*\.\([0-9]*\).*/\1/'`
2033 changequote([,])dnl
2034     if test $as_major -eq 2 && test $as_minor -lt 11
2035     then :
2036     else gcc_cv_as_leb128=yes
2037     fi
2038   fi],
2039   [AC_DEFINE(HAVE_AS_LEB128, 1,
2040     [Define if your assembler supports .sleb128 and .uleb128.])])
2041
2042 # GAS versions up to and including 2.11.0 may mis-optimize
2043 # .eh_frame data.
2044 gcc_GAS_CHECK_FEATURE(eh_frame optimization, gcc_cv_as_eh_frame,
2045   [elf,2,12,0],,
2046 [       .text
2047 .LFB1:
2048         .4byte  0
2049 .L1:
2050         .4byte  0
2051 .LFE1:
2052         .section        .eh_frame,"aw",@progbits
2053 __FRAME_BEGIN__:
2054         .4byte  .LECIE1-.LSCIE1
2055 .LSCIE1:
2056         .4byte  0x0
2057         .byte   0x1
2058         .ascii "z\0"
2059         .byte   0x1
2060         .byte   0x78
2061         .byte   0x1a
2062         .byte   0x0
2063         .byte   0x4
2064         .4byte  1
2065         .p2align 1
2066 .LECIE1:
2067 .LSFDE1:
2068         .4byte  .LEFDE1-.LASFDE1
2069 .LASFDE1:
2070         .4byte  .LASFDE1-__FRAME_BEGIN__
2071         .4byte  .LFB1
2072         .4byte  .LFE1-.LFB1
2073         .byte   0x4
2074         .4byte  .LFE1-.LFB1
2075         .byte   0x4
2076         .4byte  .L1-.LFB1
2077 .LEFDE1:],
2078 [  dnl # For autoconf 2.5x, must protect trailing spaces with @&t@.
2079 cat > conftest.lit <<EOF
2080  0000 10000000 00000000 017a0001 781a0004  .........z..x...
2081  0010 01000000 12000000 18000000 00000000  ................
2082  0020 08000000 04080000 0044               .........D      @&t@
2083 EOF
2084 cat > conftest.big <<EOF
2085  0000 00000010 00000000 017a0001 781a0004  .........z..x...
2086  0010 00000001 00000012 00000018 00000000  ................
2087  0020 00000008 04000000 0844               .........D      @&t@
2088 EOF
2089   # If the assembler didn't choke, and we can objdump,
2090   # and we got the correct data, then succeed.
2091   if test x$gcc_cv_objdump != x \
2092   && $gcc_cv_objdump -s -j .eh_frame conftest.o 2>/dev/null \
2093      | tail -3 > conftest.got \
2094   && { cmp conftest.lit conftest.got > /dev/null 2>&1 \
2095     || cmp conftest.big conftest.got > /dev/null 2>&1; }
2096   then
2097     gcc_cv_as_eh_frame=yes
2098   elif AC_TRY_COMMAND($gcc_cv_as -o conftest.o --traditional-format /dev/null); then
2099     gcc_cv_as_eh_frame=buggy
2100   else
2101     # Uh oh, what do we do now?
2102     gcc_cv_as_eh_frame=no
2103   fi])
2104
2105 if test $gcc_cv_as_eh_frame = buggy; then
2106   AC_DEFINE(USE_AS_TRADITIONAL_FORMAT, 1,
2107   [Define if your assembler mis-optimizes .eh_frame data.])
2108 fi
2109
2110 gcc_GAS_CHECK_FEATURE(section merging support, gcc_cv_as_shf_merge,
2111  [elf,2,12,0], [--fatal-warnings],
2112  [.section .rodata.str, "aMS", @progbits, 1])
2113 if test $gcc_cv_as_shf_merge = no; then
2114   gcc_GAS_CHECK_FEATURE(section merging support, gcc_cv_as_shf_merge,
2115     [elf,2,12,0], [--fatal-warnings],
2116     [.section .rodata.str, "aMS", %progbits, 1])
2117 fi
2118 AC_DEFINE_UNQUOTED(HAVE_GAS_SHF_MERGE,
2119   [`if test $gcc_cv_as_shf_merge = yes; then echo 1; else echo 0; fi`],
2120 [Define 0/1 if your assembler supports marking sections with SHF_MERGE flag.])
2121
2122 gcc_GAS_CHECK_FEATURE(COMDAT group support, gcc_cv_as_comdat_group,
2123  [elf,2,16,0], [--fatal-warnings],
2124  [.section .text,"axG",@progbits,.foo,comdat])
2125 if test $gcc_cv_as_comdat_group = yes; then
2126   gcc_cv_as_comdat_group_percent=no
2127 else
2128  gcc_GAS_CHECK_FEATURE(COMDAT group support, gcc_cv_as_comdat_group_percent,
2129    [elf,2,16,0], [--fatal-warnings],
2130    [.section .text,"axG",%progbits,.foo,comdat])
2131 fi
2132 if test $in_tree_ld != yes && test x"$ld_vers" != x; then
2133   comdat_group=yes
2134   if test 0"$ld_date" -lt 20050308; then
2135     if test -n "$ld_date"; then
2136       # If there was date string, but was earlier than 2005-03-08, fail
2137       comdat_group=no
2138     elif test "$ld_vers_major" -lt 2; then
2139       comdat_group=no
2140     elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -lt 16; then
2141       comdat_group=no
2142     fi
2143   fi
2144   if test $comdat_group = no; then
2145     gcc_cv_as_comdat_group=no
2146     gcc_cv_as_comdat_group_percent=no
2147   fi
2148 fi
2149 AC_DEFINE_UNQUOTED(HAVE_COMDAT_GROUP,
2150   [`if test $gcc_cv_as_comdat_group = yes || test $gcc_cv_as_comdat_group_percent = yes; then echo 1; else echo 0; fi`],
2151 [Define 0/1 if your assembler and linker support COMDAT groups.])
2152
2153 # Thread-local storage - the check is heavily parametrized.
2154 conftest_s=
2155 tls_first_major=
2156 tls_first_minor=
2157 tls_as_opt=
2158 case "$target" in
2159 changequote(,)dnl
2160   alpha*-*-*)
2161     conftest_s='
2162         .section ".tdata","awT",@progbits
2163 foo:    .long   25
2164         .text
2165         ldq     $27,__tls_get_addr($29)         !literal!1
2166         lda     $16,foo($29)                    !tlsgd!1
2167         jsr     $26,($27),__tls_get_addr        !lituse_tlsgd!1
2168         ldq     $27,__tls_get_addr($29)         !literal!2
2169         lda     $16,foo($29)                    !tlsldm!2
2170         jsr     $26,($27),__tls_get_addr        !lituse_tlsldm!2
2171         ldq     $1,foo($29)                     !gotdtprel
2172         ldah    $2,foo($29)                     !dtprelhi
2173         lda     $3,foo($2)                      !dtprello
2174         lda     $4,foo($29)                     !dtprel
2175         ldq     $1,foo($29)                     !gottprel
2176         ldah    $2,foo($29)                     !tprelhi
2177         lda     $3,foo($2)                      !tprello
2178         lda     $4,foo($29)                     !tprel'
2179         tls_first_major=2
2180         tls_first_minor=13
2181         tls_as_opt=--fatal-warnings
2182         ;;
2183   frv*-*-*)
2184     conftest_s='
2185         .section ".tdata","awT",@progbits
2186 x:      .long   25
2187         .text
2188         call    #gettlsoff(x)'
2189         tls_first_major=2
2190         tls_first_minor=14
2191         ;;
2192   i[34567]86-*-*)
2193     conftest_s='
2194         .section ".tdata","awT",@progbits
2195 foo:    .long   25
2196         .text
2197         movl    %gs:0, %eax
2198         leal    foo@TLSGD(,%ebx,1), %eax
2199         leal    foo@TLSLDM(%ebx), %eax
2200         leal    foo@DTPOFF(%eax), %edx
2201         movl    foo@GOTTPOFF(%ebx), %eax
2202         subl    foo@GOTTPOFF(%ebx), %eax
2203         addl    foo@GOTNTPOFF(%ebx), %eax
2204         movl    foo@INDNTPOFF, %eax
2205         movl    $foo@TPOFF, %eax
2206         subl    $foo@TPOFF, %eax
2207         leal    foo@NTPOFF(%ecx), %eax'
2208         tls_first_major=2
2209         tls_first_minor=14
2210         tls_as_opt=--fatal-warnings
2211         ;;
2212   x86_64-*-*)
2213     conftest_s='
2214         .section ".tdata","awT",@progbits
2215 foo:    .long   25
2216         .text
2217         movq    %fs:0, %rax
2218         leaq    foo@TLSGD(%rip), %rdi
2219         leaq    foo@TLSLD(%rip), %rdi
2220         leaq    foo@DTPOFF(%rax), %rdx
2221         movq    foo@GOTTPOFF(%rip), %rax
2222         movq    $foo@TPOFF, %rax'
2223         tls_first_major=2
2224         tls_first_minor=14
2225         tls_as_opt=--fatal-warnings
2226         ;;
2227   ia64-*-*)
2228     conftest_s='
2229         .section ".tdata","awT",@progbits
2230 foo:    data8   25
2231         .text
2232         addl    r16 = @ltoff(@dtpmod(foo#)), gp
2233         addl    r17 = @ltoff(@dtprel(foo#)), gp
2234         addl    r18 = @ltoff(@tprel(foo#)), gp
2235         addl    r19 = @dtprel(foo#), gp
2236         adds    r21 = @dtprel(foo#), r13
2237         movl    r23 = @dtprel(foo#)
2238         addl    r20 = @tprel(foo#), gp
2239         adds    r22 = @tprel(foo#), r13
2240         movl    r24 = @tprel(foo#)'
2241         tls_first_major=2
2242         tls_first_minor=13
2243         tls_as_opt=--fatal-warnings
2244         ;;
2245   mips*-*-*)
2246     conftest_s='
2247         .section .tdata,"awT",@progbits
2248 x:
2249         .word 2
2250         .text
2251         addiu $4, $28, %tlsgd(x)
2252         addiu $4, $28, %tlsldm(x)
2253         lui $4, %dtprel_hi(x)
2254         addiu $4, $4, %dtprel_lo(x)
2255         lw $4, %gottprel(x)($28)
2256         lui $4, %tprel_hi(x)
2257         addiu $4, $4, %tprel_lo(x)'
2258         tls_first_major=2
2259         tls_first_minor=16
2260         tls_as_opt='-32 --fatal-warnings'
2261         ;;
2262   powerpc-*-*)
2263     conftest_s='
2264         .section ".tdata","awT",@progbits
2265         .align 2
2266 ld0:    .space 4
2267 ld1:    .space 4
2268 x1:     .space 4
2269 x2:     .space 4
2270 x3:     .space 4
2271         .text
2272         addi 3,31,ld0@got@tlsgd
2273         bl __tls_get_addr
2274         addi 3,31,x1@got@tlsld
2275         bl __tls_get_addr
2276         addi 9,3,x1@dtprel
2277         addis 9,3,x2@dtprel@ha
2278         addi 9,9,x2@dtprel@l
2279         lwz 9,x3@got@tprel(31)
2280         add 9,9,x@tls
2281         addi 9,2,x1@tprel
2282         addis 9,2,x2@tprel@ha
2283         addi 9,9,x2@tprel@l'
2284         tls_first_major=2
2285         tls_first_minor=14
2286         tls_as_opt="-a32 --fatal-warnings"
2287         ;;
2288   powerpc64-*-*)
2289     conftest_s='
2290         .section ".tdata","awT",@progbits
2291         .align 3
2292 ld0:    .space 8
2293 ld1:    .space 8
2294 x1:     .space 8
2295 x2:     .space 8
2296 x3:     .space 8
2297         .text
2298         addi 3,2,ld0@got@tlsgd
2299         bl .__tls_get_addr
2300         nop
2301         addi 3,2,ld1@toc
2302         bl .__tls_get_addr
2303         nop
2304         addi 3,2,x1@got@tlsld
2305         bl .__tls_get_addr
2306         nop
2307         addi 9,3,x1@dtprel
2308         bl .__tls_get_addr
2309         nop
2310         addis 9,3,x2@dtprel@ha
2311         addi 9,9,x2@dtprel@l
2312         bl .__tls_get_addr
2313         nop
2314         ld 9,x3@got@dtprel(2)
2315         add 9,9,3
2316         bl .__tls_get_addr
2317         nop'
2318         tls_first_major=2
2319         tls_first_minor=14
2320         tls_as_opt="-a64 --fatal-warnings"
2321         ;;
2322   s390-*-*)
2323     conftest_s='
2324         .section ".tdata","awT",@progbits
2325 foo:    .long   25
2326         .text
2327         .long   foo@TLSGD
2328         .long   foo@TLSLDM
2329         .long   foo@DTPOFF
2330         .long   foo@NTPOFF
2331         .long   foo@GOTNTPOFF
2332         .long   foo@INDNTPOFF
2333         l       %r1,foo@GOTNTPOFF(%r12)
2334         l       %r1,0(%r1):tls_load:foo
2335         bas     %r14,0(%r1,%r13):tls_gdcall:foo
2336         bas     %r14,0(%r1,%r13):tls_ldcall:foo'
2337         tls_first_major=2
2338         tls_first_minor=14
2339         tls_as_opt="-m31 --fatal-warnings"
2340         ;;
2341   s390x-*-*)
2342     conftest_s='
2343         .section ".tdata","awT",@progbits
2344 foo:    .long   25
2345         .text
2346         .quad   foo@TLSGD
2347         .quad   foo@TLSLDM
2348         .quad   foo@DTPOFF
2349         .quad   foo@NTPOFF
2350         .quad   foo@GOTNTPOFF
2351         lg      %r1,foo@GOTNTPOFF(%r12)
2352         larl    %r1,foo@INDNTPOFF
2353         brasl   %r14,__tls_get_offset@PLT:tls_gdcall:foo
2354         brasl   %r14,__tls_get_offset@PLT:tls_ldcall:foo'
2355         tls_first_major=2
2356         tls_first_minor=14
2357         tls_as_opt="-m64 -Aesame --fatal-warnings"
2358         ;;
2359   sh-*-* | sh[34]-*-*)
2360     conftest_s='
2361         .section ".tdata","awT",@progbits
2362 foo:    .long   25
2363         .text
2364         .long   foo@TLSGD
2365         .long   foo@TLSLDM
2366         .long   foo@DTPOFF
2367         .long   foo@GOTTPOFF
2368         .long   foo@TPOFF'
2369         tls_first_major=2
2370         tls_first_minor=13
2371         tls_as_opt=--fatal-warnings
2372         ;;
2373   sparc*-*-*)
2374     case "$target" in
2375       sparc*-sun-solaris2.*)
2376         on_solaris=yes
2377         ;;
2378       *)
2379         on_solaris=no
2380         ;;
2381     esac
2382     if test x$on_solaris = xyes && test x$gas_flag = xno; then
2383       conftest_s='
2384         .section ".tdata",#alloc,#write,#tls
2385 foo:    .long   25
2386         .text
2387         sethi   %tgd_hi22(foo), %o0
2388         add     %o0, %tgd_lo10(foo), %o1
2389         add     %l7, %o1, %o0, %tgd_add(foo)
2390         call    __tls_get_addr, %tgd_call(foo)
2391         sethi   %tldm_hi22(foo), %l1
2392         add     %l1, %tldm_lo10(foo), %l2
2393         add     %l7, %l2, %o0, %tldm_add(foo)
2394         call    __tls_get_addr, %tldm_call(foo)
2395         sethi   %tldo_hix22(foo), %l3
2396         xor     %l3, %tldo_lox10(foo), %l4
2397         add     %o0, %l4, %l5, %tldo_add(foo)
2398         sethi   %tie_hi22(foo), %o3
2399         add     %o3, %tie_lo10(foo), %o3
2400         ld      [%l7 + %o3], %o2, %tie_ld(foo)
2401         add     %g7, %o2, %o4, %tie_add(foo)
2402         sethi   %tle_hix22(foo), %l1
2403         xor     %l1, %tle_lox10(foo), %o5
2404         ld      [%g7 + %o5], %o1'
2405         tls_first_major=0
2406         tls_first_minor=0
2407     else
2408       conftest_s='
2409         .section ".tdata","awT",@progbits
2410 foo:    .long   25
2411         .text
2412         sethi   %tgd_hi22(foo), %o0
2413         add     %o0, %tgd_lo10(foo), %o1
2414         add     %l7, %o1, %o0, %tgd_add(foo)
2415         call    __tls_get_addr, %tgd_call(foo)
2416         sethi   %tldm_hi22(foo), %l1
2417         add     %l1, %tldm_lo10(foo), %l2
2418         add     %l7, %l2, %o0, %tldm_add(foo)
2419         call    __tls_get_addr, %tldm_call(foo)
2420         sethi   %tldo_hix22(foo), %l3
2421         xor     %l3, %tldo_lox10(foo), %l4
2422         add     %o0, %l4, %l5, %tldo_add(foo)
2423         sethi   %tie_hi22(foo), %o3
2424         add     %o3, %tie_lo10(foo), %o3
2425         ld      [%l7 + %o3], %o2, %tie_ld(foo)
2426         add     %g7, %o2, %o4, %tie_add(foo)
2427         sethi   %tle_hix22(foo), %l1
2428         xor     %l1, %tle_lox10(foo), %o5
2429         ld      [%g7 + %o5], %o1'
2430         tls_first_major=2
2431         tls_first_minor=14
2432         tls_as_opt="-32 --fatal-warnings"
2433       fi
2434         ;;
2435 changequote([,])dnl
2436 esac
2437 if test -z "$tls_first_major"; then
2438   : # If we don't have a check, assume no support.
2439 else
2440   gcc_GAS_CHECK_FEATURE(thread-local storage support, gcc_cv_as_tls,
2441   [$tls_first_major,$tls_first_minor,0], [$tls_as_opt], [$conftest_s],,
2442   [AC_DEFINE(HAVE_AS_TLS, 1,
2443             [Define if your assembler supports thread-local storage.])])
2444 fi
2445
2446 # Target-specific assembler checks.
2447
2448 AC_MSG_CHECKING(linker -Bstatic/-Bdynamic option)
2449 gcc_cv_ld_static_dynamic=no
2450 if test $in_tree_ld = yes ; then
2451   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 10; then
2452     gcc_cv_ld_static_dynamic=yes
2453   fi
2454 elif test x$gcc_cv_ld != x; then
2455         # Check if linker supports -Bstatic/-Bdynamic option
2456         if $gcc_cv_ld --help 2>/dev/null | grep -- -Bstatic > /dev/null \
2457           && $gcc_cv_ld --help 2>/dev/null | grep -- -Bdynamic > /dev/null; then
2458                 gcc_cv_ld_static_dynamic=yes
2459         fi
2460 fi
2461 if test x"$gcc_cv_ld_static_dynamic" = xyes; then
2462         AC_DEFINE(HAVE_LD_STATIC_DYNAMIC, 1,
2463 [Define if your linker supports -Bstatic/-Bdynamic option.])
2464 fi
2465 AC_MSG_RESULT($gcc_cv_ld_static_dynamic)
2466
2467 if test x"$demangler_in_ld" = xyes; then
2468   AC_MSG_CHECKING(linker --demangle support)
2469   gcc_cv_ld_demangle=no
2470   if test $in_tree_ld = yes; then
2471     if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 14 -o "$gcc_cv_gld_major_version" -gt 2; then \
2472       gcc_cv_ld_demangle=yes
2473     fi
2474   elif test x$gcc_cv_ld != x -a x"$gnu_ld" = xyes; then
2475     # Check if the GNU linker supports --demangle option
2476     if $gcc_cv_ld --help 2>/dev/null | grep no-demangle > /dev/null; then
2477       gcc_cv_ld_demangle=yes
2478     fi
2479   fi
2480   if test x"$gcc_cv_ld_demangle" = xyes; then
2481     AC_DEFINE(HAVE_LD_DEMANGLE, 1,
2482 [Define if your linker supports --demangle option.])
2483   fi
2484   AC_MSG_RESULT($gcc_cv_ld_demangle)
2485 fi
2486
2487 case "$target" in
2488   # All TARGET_ABI_OSF targets.
2489   alpha*-*-osf* | alpha*-*-linux* | alpha*-*-*bsd*)
2490     gcc_GAS_CHECK_FEATURE([explicit relocation support],
2491         gcc_cv_as_alpha_explicit_relocs, [2,12,0],,
2492 [       .set nomacro
2493         .text
2494         extbl   $3, $2, $3      !lituse_bytoff!1
2495         ldq     $2, a($29)      !literal!1
2496         ldq     $4, b($29)      !literal!2
2497         ldq_u   $3, 0($2)       !lituse_base!1
2498         ldq     $27, f($29)     !literal!5
2499         jsr     $26, ($27), f   !lituse_jsr!5
2500         ldah    $29, 0($26)     !gpdisp!3
2501         lda     $0, c($29)      !gprel
2502         ldah    $1, d($29)      !gprelhigh
2503         lda     $1, d($1)       !gprellow
2504         lda     $29, 0($29)     !gpdisp!3],,
2505     [AC_DEFINE(HAVE_AS_EXPLICIT_RELOCS, 1,
2506   [Define if your assembler supports explicit relocations.])])
2507     gcc_GAS_CHECK_FEATURE([jsrdirect relocation support],
2508         gcc_cv_as_alpha_jsrdirect_relocs, [2,16,90],,
2509 [       .set nomacro
2510         .text
2511         ldq     $27, a($29)     !literal!1
2512         jsr     $26, ($27), a   !lituse_jsrdirect!1],,
2513     [AC_DEFINE(HAVE_AS_JSRDIRECT_RELOCS, 1,
2514   [Define if your assembler supports the lituse_jsrdirect relocation.])])
2515     ;;
2516
2517   cris-*-*)
2518     gcc_GAS_CHECK_FEATURE([-no-mul-bug-abort option],
2519       gcc_cv_as_cris_no_mul_bug,[2,15,91],
2520       [-no-mul-bug-abort], [.text],,
2521       [AC_DEFINE(HAVE_AS_NO_MUL_BUG_ABORT_OPTION, 1,
2522                 [Define if your assembler supports the -no-mul-bug-abort option.])])
2523     ;;
2524
2525   sparc*-*-*)
2526     gcc_GAS_CHECK_FEATURE([.register], gcc_cv_as_sparc_register_op,,,
2527       [.register %g2, #scratch],,
2528       [AC_DEFINE(HAVE_AS_REGISTER_PSEUDO_OP, 1,
2529                 [Define if your assembler supports .register.])])
2530
2531     gcc_GAS_CHECK_FEATURE([-relax option], gcc_cv_as_sparc_relax,,
2532       [-relax], [.text],,
2533       [AC_DEFINE(HAVE_AS_RELAX_OPTION, 1,
2534                 [Define if your assembler supports -relax option.])])
2535
2536     gcc_GAS_CHECK_FEATURE([unaligned pcrel relocs],
2537       gcc_cv_as_sparc_ua_pcrel,,
2538       [-K PIC],
2539 [.text
2540 foo:
2541         nop
2542 .data
2543 .align 4
2544 .byte 0
2545 .uaword %r_disp32(foo)],
2546       [if test x$gcc_cv_ld != x \
2547        && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1; then
2548          gcc_cv_as_sparc_ua_pcrel=yes
2549        fi
2550        rm -f conftest],
2551       [AC_DEFINE(HAVE_AS_SPARC_UA_PCREL, 1,
2552                 [Define if your assembler and linker support unaligned PC relative relocs.])
2553
2554       gcc_GAS_CHECK_FEATURE([unaligned pcrel relocs against hidden symbols],
2555         gcc_cv_as_sparc_ua_pcrel_hidden,,
2556         [-K PIC],
2557 [.data
2558 .align 4
2559 .byte 0x31
2560 .uaword %r_disp32(foo)
2561 .byte 0x32, 0x33, 0x34
2562 .global foo
2563 .hidden foo
2564 foo:
2565 .skip 4],
2566         [if test x$gcc_cv_ld != x && test x$gcc_cv_objdump != x \
2567          && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1 \
2568          && $gcc_cv_objdump -s -j .data conftest 2> /dev/null \
2569             | grep ' 31000000 07323334' > /dev/null 2>&1; then
2570             if $gcc_cv_objdump -R conftest 2> /dev/null \
2571                | grep 'DISP32' > /dev/null 2>&1; then
2572                 :
2573             else
2574                 gcc_cv_as_sparc_ua_pcrel_hidden=yes
2575             fi
2576          fi
2577          rm -f conftest],
2578          [AC_DEFINE(HAVE_AS_SPARC_UA_PCREL_HIDDEN, 1,
2579                    [Define if your assembler and linker support unaligned PC relative relocs against hidden symbols.])])
2580     ]) # unaligned pcrel relocs
2581
2582     gcc_GAS_CHECK_FEATURE([offsetable %lo()],
2583       gcc_cv_as_sparc_offsetable_lo10,,
2584       [-xarch=v9],
2585 [.text
2586         or %g1, %lo(ab) + 12, %g1
2587         or %g1, %lo(ab + 12), %g1],
2588       [if test x$gcc_cv_objdump != x \
2589        && $gcc_cv_objdump -s -j .text conftest.o 2> /dev/null \
2590           | grep ' 82106000 82106000' > /dev/null 2>&1; then
2591          gcc_cv_as_sparc_offsetable_lo10=yes
2592        fi],
2593        [AC_DEFINE(HAVE_AS_OFFSETABLE_LO10, 1,
2594                  [Define if your assembler supports offsetable %lo().])])
2595     ;;
2596
2597 changequote(,)dnl
2598   i[34567]86-*-* | x86_64-*-*)
2599 changequote([,])dnl
2600     case $target_os in
2601       cygwin* | pe | mingw32*)
2602         # Used for DWARF 2 in PE
2603         gcc_GAS_CHECK_FEATURE([.secrel32 relocs],
2604           gcc_cv_as_ix86_pe_secrel32,
2605           [2,15,91],,
2606 [.text
2607 foo:    nop
2608 .data
2609         .secrel32 foo],
2610           [if test x$gcc_cv_ld != x \
2611            && $gcc_cv_ld -o conftest conftest.o > /dev/null 2>&1; then
2612              gcc_cv_as_ix86_pe_secrel32=yes
2613            fi
2614            rm -f conftest],
2615           [AC_DEFINE(HAVE_GAS_PE_SECREL32_RELOC, 1,
2616             [Define if your assembler and linker support 32-bit section relative relocs via '.secrel32 label'.])])
2617         ;;
2618     esac
2619
2620     gcc_GAS_CHECK_FEATURE([filds and fists mnemonics],
2621        gcc_cv_as_ix86_filds_fists,
2622       [2,9,0],, [filds mem; fists mem],,
2623       [AC_DEFINE(HAVE_GAS_FILDS_FISTS, 1,
2624         [Define if your assembler uses the new HImode fild and fist notation.])])
2625
2626     gcc_GAS_CHECK_FEATURE([cmov syntax],
2627       gcc_cv_as_ix86_cmov_sun_syntax,,,
2628       [cmovl.l %edx, %eax],,
2629       [AC_DEFINE(HAVE_AS_IX86_CMOV_SUN_SYNTAX, 1,
2630         [Define if your assembler supports the Sun syntax for cmov.])])
2631
2632     # This one is used unconditionally by i386.[ch]; it is to be defined
2633     # to 1 if the feature is present, 0 otherwise.
2634     gcc_GAS_CHECK_FEATURE([GOTOFF in data],
2635         gcc_cv_as_ix86_gotoff_in_data, [2,11,0],,
2636 [       .text
2637 .L0:
2638         nop
2639         .data
2640         .long .L0@GOTOFF])
2641     AC_DEFINE_UNQUOTED(HAVE_AS_GOTOFF_IN_DATA,
2642       [`if test $gcc_cv_as_ix86_gotoff_in_data = yes; then echo 1; else echo 0; fi`],
2643       [Define true if the assembler supports '.long foo@GOTOFF'.])
2644     ;;
2645
2646   ia64*-*-*)
2647     gcc_GAS_CHECK_FEATURE([ltoffx and ldxmov relocs],
2648         gcc_cv_as_ia64_ltoffx_ldxmov_relocs, [2,14,0],,
2649 [       .text
2650         addl r15 = @ltoffx(x#), gp
2651         ;;
2652         ld8.mov r16 = [[r15]], x#],,
2653     [AC_DEFINE(HAVE_AS_LTOFFX_LDXMOV_RELOCS, 1,
2654           [Define if your assembler supports ltoffx and ldxmov relocations.])])
2655
2656     ;;
2657
2658   powerpc*-*-*)
2659     case $target in
2660       *-*-aix*) conftest_s='    .machine "pwr5"
2661         .csect .text[[PR]]
2662         mfcr 3,128';;
2663       *-*-darwin*)
2664         gcc_GAS_CHECK_FEATURE([.machine directive support],
2665           gcc_cv_as_machine_directive,,,
2666           [     .machine ppc7400])
2667         if test x$gcc_cv_as_machine_directive != xyes; then
2668           echo "*** This target requires an assembler supporting \".machine\"" >&2
2669           echo you can get it from: ftp://gcc.gnu.org/pub/gcc/infrastructure/cctools-528.5.dmg >&2
2670           test x$build = x$target && exit 1
2671         fi
2672         conftest_s='    .text
2673         mfcr r3,128';;
2674       *) conftest_s='   .machine power4
2675         .text
2676         mfcr 3,128';;
2677     esac
2678
2679     gcc_GAS_CHECK_FEATURE([mfcr field support],
2680       gcc_cv_as_powerpc_mfcrf, [2,14,0],,
2681       [$conftest_s],,
2682       [AC_DEFINE(HAVE_AS_MFCRF, 1,
2683           [Define if your assembler supports mfcr field.])])
2684
2685     case $target in
2686       *-*-aix*) conftest_s='    .machine "pwr5"
2687         .csect .text[[PR]]
2688         popcntb 3,3';;
2689       *) conftest_s='   .machine power5
2690         .text
2691         popcntb 3,3';;
2692     esac
2693
2694     gcc_GAS_CHECK_FEATURE([popcntb support],
2695       gcc_cv_as_powerpc_popcntb, [2,17,0],,
2696       [$conftest_s],,
2697       [AC_DEFINE(HAVE_AS_POPCNTB, 1,
2698           [Define if your assembler supports popcntb field.])])
2699
2700     case $target in
2701       *-*-aix*) conftest_s='    .csect .text[[PR]]
2702 LCF..0:
2703         addis 11,30,_GLOBAL_OFFSET_TABLE_-LCF..0@ha';;
2704       *-*-darwin*)
2705         conftest_s='    .text
2706 LCF0:
2707         addis r11,r30,_GLOBAL_OFFSET_TABLE_-LCF0@ha';;
2708       *) conftest_s='   .text
2709 .LCF0:
2710         addis 11,30,_GLOBAL_OFFSET_TABLE_-.LCF0@ha';;
2711     esac
2712
2713     gcc_GAS_CHECK_FEATURE([rel16 relocs],
2714       gcc_cv_as_powerpc_rel16, [2,17,0], -a32,
2715       [$conftest_s],,
2716       [AC_DEFINE(HAVE_AS_REL16, 1,
2717           [Define if your assembler supports R_PPC_REL16 relocs.])])
2718     ;;
2719
2720   mips*-*-*)
2721     gcc_GAS_CHECK_FEATURE([explicit relocation support],
2722       gcc_cv_as_mips_explicit_relocs, [2,14,0],,
2723 [       lw $4,%gp_rel(foo)($4)],,
2724       [if test x$target_cpu_default = x
2725        then target_cpu_default=MASK_EXPLICIT_RELOCS
2726        else target_cpu_default="($target_cpu_default)|MASK_EXPLICIT_RELOCS"
2727        fi])
2728
2729     if test x$gas_flag = xyes \
2730        || test x"$host" != x"$build" \
2731        || test ! -x "$gcc_cv_as" \
2732        || "$gcc_cv_as" -v < /dev/null 2>&1 | grep GNU > /dev/null; then
2733       :
2734     else
2735       echo "*** This configuration requires the GNU assembler" >&2
2736       exit 1
2737     fi
2738     ;;
2739 esac
2740 # ??? Not all targets support dwarf2 debug_line, even within a version
2741 # of gas.  Moreover, we need to emit a valid instruction to trigger any
2742 # info to the output file.  So, as supported targets are added to gas 2.11,
2743 # add some instruction here to (also) show we expect this might work.
2744 # ??? Once 2.11 is released, probably need to add first known working
2745 # version to the per-target configury.
2746 case "$target" in
2747   i?86*-*-* | mips*-*-* | alpha*-*-* | powerpc*-*-* | sparc*-*-* | m68*-*-* \
2748   | x86_64*-*-* | hppa*-*-* | arm*-*-* | strongarm*-*-* | xscale*-*-* \
2749   | xstormy16*-*-* | cris-*-* | xtensa-*-*)
2750     insn="nop"
2751     ;;
2752   ia64*-*-* | s390*-*-*)
2753     insn="nop 0"
2754     ;;
2755   mmix-*-*)
2756     insn="swym 0"
2757     ;;
2758 esac
2759 if test x"$insn" != x; then
2760  conftest_s="\
2761         .file 1 \"conftest.s\"
2762         .loc 1 3 0
2763         $insn"
2764  gcc_GAS_CHECK_FEATURE([dwarf2 debug_line support],
2765   gcc_cv_as_dwarf2_debug_line,
2766   [elf,2,11,0],, [$conftest_s],
2767   [if test x$gcc_cv_objdump != x \
2768    && $gcc_cv_objdump -h conftest.o 2> /dev/null \
2769       | grep debug_line > /dev/null 2>&1; then
2770      gcc_cv_as_dwarf2_debug_line=yes
2771    fi])
2772
2773 # The .debug_line file table must be in the exact order that
2774 # we specified the files, since these indices are also used
2775 # by DW_AT_decl_file.  Approximate this test by testing if
2776 # the assembler bitches if the same index is assigned twice.
2777  gcc_GAS_CHECK_FEATURE([buggy dwarf2 .file directive],
2778   gcc_cv_as_dwarf2_file_buggy,,,
2779 [       .file 1 "foo.s"
2780         .file 1 "bar.s"])
2781
2782  if test $gcc_cv_as_dwarf2_debug_line = yes \
2783  && test $gcc_cv_as_dwarf2_file_buggy = no; then
2784         AC_DEFINE(HAVE_AS_DWARF2_DEBUG_LINE, 1,
2785   [Define if your assembler supports dwarf2 .file/.loc directives,
2786    and preserves file table indices exactly as given.])
2787  fi
2788
2789  gcc_GAS_CHECK_FEATURE([--gdwarf2 option],
2790   gcc_cv_as_gdwarf2_flag,
2791   [elf,2,11,0], [--gdwarf2], [$insn],,
2792   [AC_DEFINE(HAVE_AS_GDWARF2_DEBUG_FLAG, 1,
2793 [Define if your assembler supports the --gdwarf2 option.])])
2794
2795  gcc_GAS_CHECK_FEATURE([--gstabs option],
2796   gcc_cv_as_gstabs_flag,
2797   [elf,2,11,0], [--gstabs], [$insn],
2798   [# The native Solaris 9/Intel assembler doesn't understand --gstabs
2799    # and warns about it, but still exits successfully.  So check for
2800    # this.
2801    if AC_TRY_COMMAND([$gcc_cv_as --gstabs -o conftest.o conftest.s 2>&1 | grep -i warning > /dev/null])
2802    then :
2803    else gcc_cv_as_gstabs_flag=yes
2804    fi],
2805   [AC_DEFINE(HAVE_AS_GSTABS_DEBUG_FLAG, 1,
2806 [Define if your assembler supports the --gstabs option.])])
2807 fi
2808
2809 AC_MSG_CHECKING(linker read-only and read-write section mixing)
2810 gcc_cv_ld_ro_rw_mix=unknown
2811 if test $in_tree_ld = yes ; then
2812   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 10 -o "$gcc_cv_gld_major_version" -gt 2 \
2813      && test $in_tree_ld_is_elf = yes; then
2814     gcc_cv_ld_ro_rw_mix=read-write
2815   fi
2816 elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x -a x$gcc_cv_objdump != x ; then
2817   echo '.section myfoosect, "a"' > conftest1.s
2818   echo '.section myfoosect, "aw"' > conftest2.s
2819   echo '.byte 1' >> conftest2.s
2820   echo '.section myfoosect, "a"' > conftest3.s
2821   echo '.byte 0' >> conftest3.s
2822   if $gcc_cv_as -o conftest1.o conftest1.s > /dev/null 2>&1 \
2823      && $gcc_cv_as -o conftest2.o conftest2.s > /dev/null 2>&1 \
2824      && $gcc_cv_as -o conftest3.o conftest3.s > /dev/null 2>&1 \
2825      && $gcc_cv_ld -shared -o conftest1.so conftest1.o \
2826         conftest2.o conftest3.o > /dev/null 2>&1; then
2827     gcc_cv_ld_ro_rw_mix=`$gcc_cv_objdump -h conftest1.so \
2828                          | sed -e '/myfoosect/!d' -e N`
2829     if echo "$gcc_cv_ld_ro_rw_mix" | grep CONTENTS > /dev/null; then
2830       if echo "$gcc_cv_ld_ro_rw_mix" | grep READONLY > /dev/null; then
2831         gcc_cv_ld_ro_rw_mix=read-only
2832       else
2833         gcc_cv_ld_ro_rw_mix=read-write
2834       fi
2835     fi
2836   fi
2837 changequote(,)dnl
2838   rm -f conftest.* conftest[123].*
2839 changequote([,])dnl
2840 fi
2841 if test x$gcc_cv_ld_ro_rw_mix = xread-write; then
2842         AC_DEFINE(HAVE_LD_RO_RW_SECTION_MIXING, 1,
2843   [Define if your linker links a mix of read-only
2844    and read-write sections into a read-write section.])
2845 fi
2846 AC_MSG_RESULT($gcc_cv_ld_ro_rw_mix)
2847
2848 AC_MSG_CHECKING(linker PT_GNU_EH_FRAME support)
2849 gcc_cv_ld_eh_frame_hdr=no
2850 if test $in_tree_ld = yes ; then
2851   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 12 -o "$gcc_cv_gld_major_version" -gt 2 \
2852      && test $in_tree_ld_is_elf = yes; then
2853     gcc_cv_ld_eh_frame_hdr=yes
2854   fi
2855 elif test x$gcc_cv_ld != x; then
2856         # Check if linker supports --eh-frame-hdr option
2857         if $gcc_cv_ld --help 2>/dev/null | grep eh-frame-hdr > /dev/null; then
2858                 gcc_cv_ld_eh_frame_hdr=yes
2859         fi
2860 fi
2861 GCC_TARGET_TEMPLATE([HAVE_LD_EH_FRAME_HDR])
2862 if test x"$gcc_cv_ld_eh_frame_hdr" = xyes; then
2863         AC_DEFINE(HAVE_LD_EH_FRAME_HDR, 1,
2864 [Define if your linker supports --eh-frame-hdr option.])
2865 fi
2866 AC_MSG_RESULT($gcc_cv_ld_eh_frame_hdr)
2867
2868 AC_MSG_CHECKING(linker position independent executable support)
2869 gcc_cv_ld_pie=no
2870 if test $in_tree_ld = yes ; then
2871   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 15 -o "$gcc_cv_gld_major_version" -gt 2 \
2872      && test $in_tree_ld_is_elf = yes; then
2873     gcc_cv_ld_pie=yes
2874   fi
2875 elif test x$gcc_cv_ld != x; then
2876         # Check if linker supports -pie option
2877         if $gcc_cv_ld --help 2>/dev/null | grep -- -pie > /dev/null; then
2878                 gcc_cv_ld_pie=yes
2879         fi
2880 fi
2881 if test x"$gcc_cv_ld_pie" = xyes; then
2882         AC_DEFINE(HAVE_LD_PIE, 1,
2883 [Define if your linker supports -pie option.])
2884 fi
2885 AC_MSG_RESULT($gcc_cv_ld_pie)
2886
2887 # --------
2888 # UNSORTED
2889 # --------
2890
2891 AC_CACHE_CHECK(linker --as-needed support,
2892 gcc_cv_ld_as_needed,
2893 [gcc_cv_ld_as_needed=no
2894 if test $in_tree_ld = yes ; then
2895   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2 \
2896      && test $in_tree_ld_is_elf = yes; then
2897     gcc_cv_ld_as_needed=yes
2898   fi
2899 elif test x$gcc_cv_ld != x; then
2900         # Check if linker supports --as-needed and --no-as-needed options
2901         if $gcc_cv_ld --help 2>/dev/null | grep as-needed > /dev/null; then
2902                 gcc_cv_ld_as_needed=yes
2903         fi
2904 fi
2905 ])
2906 if test x"$gcc_cv_ld_as_needed" = xyes; then
2907         AC_DEFINE(HAVE_LD_AS_NEEDED, 1,
2908 [Define if your linker supports --as-needed and --no-as-needed options.])
2909 fi
2910
2911 case "$target" in
2912   powerpc64*-*-linux*)
2913     AC_CACHE_CHECK(linker support for omitting dot symbols,
2914     gcc_cv_ld_no_dot_syms,
2915     [gcc_cv_ld_no_dot_syms=no
2916     if test $in_tree_ld = yes ; then
2917       if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2; then
2918         gcc_cv_ld_no_dot_syms=yes
2919       fi
2920     elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x ; then
2921       cat > conftest1.s <<EOF
2922         .text
2923         bl .foo
2924 EOF
2925       cat > conftest2.s <<EOF
2926         .section ".opd","aw"
2927         .align 3
2928         .globl foo
2929         .type foo,@function
2930 foo:
2931         .quad .LEfoo,.TOC.@tocbase,0
2932         .text
2933 .LEfoo:
2934         blr
2935         .size foo,.-.LEfoo
2936 EOF
2937       if $gcc_cv_as -a64 -o conftest1.o conftest1.s > /dev/null 2>&1 \
2938          && $gcc_cv_as -a64 -o conftest2.o conftest2.s > /dev/null 2>&1 \
2939          && $gcc_cv_ld -melf64ppc -o conftest conftest1.o conftest2.o > /dev/null 2>&1; then
2940         gcc_cv_ld_no_dot_syms=yes
2941       fi
2942       rm -f conftest conftest1.o conftest2.o conftest1.s conftest2.s
2943     fi
2944     ])
2945     if test x"$gcc_cv_ld_no_dot_syms" = xyes; then
2946       AC_DEFINE(HAVE_LD_NO_DOT_SYMS, 1,
2947     [Define if your PowerPC64 linker only needs function descriptor syms.])
2948     fi
2949     ;;
2950 esac
2951
2952 AC_CACHE_CHECK(linker --sysroot support,
2953   gcc_cv_ld_sysroot,
2954   [gcc_cv_ld_sysroot=no
2955   if test $in_tree_ld = yes ; then
2956       if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2 ; then
2957         gcc_cv_ld_sysroot=yes
2958       fi
2959   elif test x$gcc_cv_ld != x; then
2960     if $gcc_cv_ld --help 2>/dev/null | grep sysroot > /dev/null; then
2961       gcc_cv_ld_sysroot=yes
2962     fi
2963   fi])
2964 if test x"$gcc_cv_ld_sysroot" = xyes; then
2965   AC_DEFINE(HAVE_LD_SYSROOT, 1,
2966   [Define if your linker supports --sysroot.])
2967 fi
2968
2969 if test x$with_sysroot = x && test x$host = x$target \
2970    && test "$prefix" != "/usr" && test "x$prefix" != "x$local_prefix" ; then
2971   AC_DEFINE_UNQUOTED(PREFIX_INCLUDE_DIR, "$prefix/include",
2972 [Define to PREFIX/include if cpp should also search that directory.])
2973 fi
2974
2975 # Find out what GC implementation we want, or may, use.
2976 AC_ARG_WITH(gc,
2977 [  --with-gc={page,zone}   choose the garbage collection mechanism to use
2978                           with the compiler],
2979 [case "$withval" in
2980   page)
2981     GGC=ggc-$withval
2982     ;;
2983   zone)
2984     GGC=ggc-$withval
2985     AC_DEFINE(GGC_ZONE, 1, [Define if the zone collector is in use])
2986     ;;
2987   *)
2988     AC_MSG_ERROR([$withval is an invalid option to --with-gc])
2989     ;;
2990 esac],
2991 [GGC=ggc-page])
2992 AC_SUBST(GGC)
2993 echo "Using $GGC for garbage collection."
2994
2995 # Use the system's zlib library.
2996 zlibdir=-L../zlib
2997 zlibinc="-I\$(srcdir)/../zlib"
2998 AC_ARG_WITH(system-zlib,
2999 [  --with-system-zlib      use installed libz],
3000 zlibdir=
3001 zlibinc=
3002 )
3003 AC_SUBST(zlibdir)
3004 AC_SUBST(zlibinc)
3005
3006 dnl Very limited version of automake's enable-maintainer-mode
3007
3008 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
3009   dnl maintainer-mode is disabled by default
3010   AC_ARG_ENABLE(maintainer-mode,
3011 [  --enable-maintainer-mode
3012                           enable make rules and dependencies not useful
3013                           (and sometimes confusing) to the casual installer],
3014       maintainer_mode=$enableval,
3015       maintainer_mode=no)
3016
3017 AC_MSG_RESULT($maintainer_mode)
3018
3019 if test "$maintainer_mode" = "yes"; then
3020   MAINT=''
3021 else
3022   MAINT='#'
3023 fi
3024 AC_SUBST(MAINT)dnl
3025
3026 # --------------
3027 # Language hooks
3028 # --------------
3029
3030 # Make empty files to contain the specs and options for each language.
3031 # Then add #include lines to for a compiler that has specs and/or options.
3032
3033 lang_opt_files=
3034 lang_specs_files=
3035 lang_tree_files=
3036 for subdir in . $subdirs
3037 do
3038         if test -f $srcdir/$subdir/lang.opt; then
3039             lang_opt_files="$lang_opt_files $srcdir/$subdir/lang.opt"
3040         fi
3041         if test -f $srcdir/$subdir/lang-specs.h; then
3042             lang_specs_files="$lang_specs_files $srcdir/$subdir/lang-specs.h"
3043         fi
3044         if test -f $srcdir/$subdir/$subdir-tree.def; then
3045             lang_tree_files="$lang_tree_files $srcdir/$subdir/$subdir-tree.def"
3046         fi
3047 done
3048
3049 # These (without "all_") are set in each config-lang.in.
3050 # `language' must be a single word so is spelled singularly.
3051 all_languages=
3052 all_boot_languages=
3053 all_compilers=
3054 all_stagestuff=
3055 all_outputs='Makefile gccbug mklibgcc libada-mk'
3056 # List of language makefile fragments.
3057 all_lang_makefrags=
3058 # List of language subdirectory makefiles.  Deprecated.
3059 all_lang_makefiles=
3060 # Files for gengtype
3061 all_gtfiles="$target_gtfiles"
3062 # Files for gengtype with language
3063 all_gtfiles_files_langs=
3064 all_gtfiles_files_files=
3065
3066 # Add the language fragments.
3067 # Languages are added via two mechanisms.  Some information must be
3068 # recorded in makefile variables, these are defined in config-lang.in.
3069 # We accumulate them and plug them into the main Makefile.
3070 # The other mechanism is a set of hooks for each of the main targets
3071 # like `clean', `install', etc.
3072
3073 language_hooks="Make-hooks"
3074
3075 for s in $subdirs
3076 do
3077                 language=
3078                 boot_language=
3079                 compilers=
3080                 stagestuff=
3081                 outputs=
3082                 gtfiles=
3083                 . ${srcdir}/$s/config-lang.in
3084                 if test "x$language" = x
3085                 then
3086                         echo "${srcdir}/$s/config-lang.in doesn't set \$language." 1>&2
3087                         exit 1
3088                 fi
3089                 all_lang_makefrags="$all_lang_makefrags \$(srcdir)/$s/Make-lang.in"
3090                 if test -f ${srcdir}/$s/Makefile.in
3091                 then all_lang_makefiles="$s/Makefile"
3092                 fi
3093                 all_languages="$all_languages $language"
3094                 if test "x$boot_language" = xyes
3095                 then
3096                         all_boot_languages="$all_boot_languages $language"
3097                 fi
3098                 all_compilers="$all_compilers $compilers"
3099                 all_stagestuff="$all_stagestuff $stagestuff"
3100                 all_outputs="$all_outputs $outputs"
3101                 all_gtfiles="$all_gtfiles $gtfiles"
3102                 for f in $gtfiles
3103                 do
3104                          all_gtfiles_files_langs="$all_gtfiles_files_langs ${s} "
3105                          all_gtfiles_files_files="$all_gtfiles_files_files ${f} "
3106                 done
3107 done
3108
3109 # Pick up gtfiles for c
3110 gtfiles=
3111 s="c"
3112 . ${srcdir}/c-config-lang.in
3113 all_gtfiles="$all_gtfiles $gtfiles"
3114 for f in $gtfiles
3115 do
3116         all_gtfiles_files_langs="$all_gtfiles_files_langs ${s} "
3117         all_gtfiles_files_files="$all_gtfiles_files_files ${f} "
3118 done
3119
3120 check_languages=
3121 for language in $all_languages
3122 do
3123                 check_languages="$check_languages check-$language"
3124 done
3125
3126 # We link each language in with a set of hooks, reached indirectly via
3127 # lang.${target}.
3128
3129 rm -f Make-hooks
3130 touch Make-hooks
3131 target_list="all.build all.cross start.encap rest.encap tags \
3132         install-normal install-common install-man \
3133         uninstall info man srcextra srcman srcinfo \
3134         mostlyclean clean distclean maintainer-clean \
3135         stage1 stage2 stage3 stage4 stageprofile stagefeedback"
3136 for t in $target_list
3137 do
3138         x=
3139         for lang in $all_languages
3140         do
3141                         x="$x $lang.$t"
3142         done
3143         echo "lang.$t: $x" >> Make-hooks
3144 done
3145
3146 # --------
3147 # UNSORTED
3148 # --------
3149
3150 # Create .gdbinit.
3151
3152 echo "dir ." > .gdbinit
3153 echo "dir ${srcdir}" >> .gdbinit
3154 if test x$gdb_needs_out_file_path = xyes
3155 then
3156         echo "dir ${srcdir}/config/"`dirname ${out_file}` >> .gdbinit
3157 fi
3158 if test "x$subdirs" != x; then
3159         for s in $subdirs
3160         do
3161                 echo "dir ${srcdir}/$s" >> .gdbinit
3162         done
3163 fi
3164 echo "source ${srcdir}/gdbinit.in" >> .gdbinit
3165
3166 # If $(exec_prefix) exists and is not the same as $(prefix), then compute an
3167 # absolute path for gcc_tooldir based on inserting the number of up-directory
3168 # movements required to get from $(exec_prefix) to $(prefix) into the basic
3169 # $(libsubdir)/@(unlibsubdir) based path.
3170 # Don't set gcc_tooldir to tooldir since that's only passed in by the toplevel
3171 # make and thus we'd get different behavior depending on where we built the
3172 # sources.
3173 if test x$exec_prefix = xNONE -o x$exec_prefix = x$prefix; then
3174     gcc_tooldir='$(libsubdir)/$(unlibsubdir)/../$(target_noncanonical)'
3175 else
3176 changequote(<<, >>)dnl
3177 # An explanation of the sed strings:
3178 #  -e 's|^\$(prefix)||'   matches and eliminates 'prefix' from 'exec_prefix'
3179 #  -e 's|/$||'            match a trailing forward slash and eliminates it
3180 #  -e 's|^[^/]|/|'        forces the string to start with a forward slash (*)
3181 #  -e 's|/[^/]*|../|g'    replaces each occurrence of /<directory> with ../
3182 #
3183 # (*) Note this pattern overwrites the first character of the string
3184 # with a forward slash if one is not already present.  This is not a
3185 # problem because the exact names of the sub-directories concerned is
3186 # unimportant, just the number of them matters.
3187 #
3188 # The practical upshot of these patterns is like this:
3189 #
3190 #  prefix     exec_prefix        result
3191 #  ------     -----------        ------
3192 #   /foo        /foo/bar          ../
3193 #   /foo/       /foo/bar          ../
3194 #   /foo        /foo/bar/         ../
3195 #   /foo/       /foo/bar/         ../
3196 #   /foo        /foo/bar/ugg      ../../
3197 #
3198     dollar='$$'
3199     gcc_tooldir="\$(libsubdir)/\$(unlibsubdir)/\`echo \$(exec_prefix) | sed -e 's|^\$(prefix)||' -e 's|/\$(dollar)||' -e 's|^[^/]|/|' -e 's|/[^/]*|../|g'\`\$(target_noncanonical)"
3200 changequote([, ])dnl
3201 fi
3202 AC_SUBST(gcc_tooldir)
3203 AC_SUBST(dollar)
3204
3205 # Find a directory in which to install a shared libgcc.
3206
3207 AC_ARG_ENABLE(version-specific-runtime-libs,
3208 [  --enable-version-specific-runtime-libs
3209                           specify that runtime libraries should be
3210                           installed in a compiler-specific directory])
3211
3212 AC_ARG_WITH(slibdir,
3213 [  --with-slibdir=DIR      shared libraries in DIR [LIBDIR]],
3214 slibdir="$with_slibdir",
3215 if test "${enable_version_specific_runtime_libs+set}" = set; then
3216   slibdir='$(libsubdir)'
3217 elif test "$host" != "$target"; then
3218   slibdir='$(build_tooldir)/lib'
3219 else
3220   slibdir='$(libdir)'
3221 fi)
3222 AC_SUBST(slibdir)
3223
3224 objdir=`${PWDCMD-pwd}`
3225 AC_SUBST(objdir)
3226
3227 # Substitute configuration variables
3228 AC_SUBST(subdirs)
3229 AC_SUBST(srcdir)
3230 AC_SUBST(all_boot_languages)
3231 AC_SUBST(all_compilers)
3232 AC_SUBST(all_gtfiles)
3233 AC_SUBST(all_gtfiles_files_langs)
3234 AC_SUBST(all_gtfiles_files_files)
3235 AC_SUBST(all_lang_makefrags)
3236 AC_SUBST(all_lang_makefiles)
3237 AC_SUBST(all_languages)
3238 AC_SUBST(all_stagestuff)
3239 AC_SUBST(build_exeext)
3240 AC_SUBST(build_install_headers_dir)
3241 AC_SUBST(build_xm_file_list)
3242 AC_SUBST(build_xm_include_list)
3243 AC_SUBST(build_xm_defines)
3244 AC_SUBST(check_languages)
3245 AC_SUBST(cc_set_by_configure)
3246 AC_SUBST(quoted_cc_set_by_configure)
3247 AC_SUBST(cpp_install_dir)
3248 AC_SUBST(xmake_file)
3249 AC_SUBST(tmake_file)
3250 AC_SUBST(extra_gcc_objs)
3251 AC_SUBST(extra_headers_list)
3252 AC_SUBST(extra_objs)
3253 AC_SUBST(extra_parts)
3254 AC_SUBST(extra_passes)
3255 AC_SUBST(extra_programs)
3256 AC_SUBST(float_h_file)
3257 AC_SUBST(gcc_config_arguments)
3258 AC_SUBST(gcc_gxx_include_dir)
3259 AC_SUBST(libstdcxx_incdir)
3260 AC_SUBST(host_exeext)
3261 AC_SUBST(host_xm_file_list)
3262 AC_SUBST(host_xm_include_list)
3263 AC_SUBST(host_xm_defines)
3264 AC_SUBST(out_host_hook_obj)
3265 AC_SUBST(install)
3266 AC_SUBST(lang_opt_files)
3267 AC_SUBST(lang_specs_files)
3268 AC_SUBST(lang_tree_files)
3269 AC_SUBST(local_prefix)
3270 AC_SUBST(md_file)
3271 AC_SUBST(objc_boehm_gc)
3272 AC_SUBST(out_file)
3273 AC_SUBST(out_object_file)
3274 AC_SUBST(stage_prefix_set_by_configure)
3275 AC_SUBST(quoted_stage_prefix_set_by_configure)
3276 AC_SUBST(thread_file)
3277 AC_SUBST(tm_file_list)
3278 AC_SUBST(tm_include_list)
3279 AC_SUBST(tm_defines)
3280 AC_SUBST(tm_p_file_list)
3281 AC_SUBST(tm_p_include_list)
3282 AC_SUBST(xm_file_list)
3283 AC_SUBST(xm_include_list)
3284 AC_SUBST(xm_defines)
3285 AC_SUBST(c_target_objs)
3286 AC_SUBST(cxx_target_objs)
3287 AC_SUBST(target_cpu_default)
3288
3289 AC_SUBST_FILE(language_hooks)
3290
3291 # Echo link setup.
3292 if test x${build} = x${host} ; then
3293   if test x${host} = x${target} ; then
3294     echo "Links are now set up to build a native compiler for ${target}." 1>&2
3295   else
3296     echo "Links are now set up to build a cross-compiler" 1>&2
3297     echo " from ${host} to ${target}." 1>&2
3298   fi
3299 else
3300   if test x${host} = x${target} ; then
3301     echo "Links are now set up to build (on ${build}) a native compiler" 1>&2
3302     echo " for ${target}." 1>&2
3303   else
3304     echo "Links are now set up to build (on ${build}) a cross-compiler" 1>&2
3305     echo " from ${host} to ${target}." 1>&2
3306   fi
3307 fi
3308
3309 AC_ARG_VAR(GMPLIBS,[How to link GMP])
3310 AC_ARG_VAR(GMPINC,[How to find GMP include files])
3311
3312 # Configure the subdirectories
3313 # AC_CONFIG_SUBDIRS($subdirs)
3314
3315 # Create the Makefile
3316 # and configure language subdirectories
3317 AC_CONFIG_FILES($all_outputs)
3318
3319 AC_CONFIG_COMMANDS([default],
3320 [
3321 case ${CONFIG_HEADERS} in
3322   *auto-host.h:config.in*)
3323   echo > cstamp-h ;;
3324 esac
3325 # Make sure all the subdirs exist.
3326 for d in $subdirs doc build
3327 do
3328     test -d $d || mkdir $d
3329 done
3330 # If the host supports symlinks, point stage[1234] at ../stage[1234] so
3331 # bootstrapping and the installation procedure can still use
3332 # CC="stage1/xgcc -Bstage1/".  If the host doesn't support symlinks,
3333 # FLAGS_TO_PASS has been modified to solve the problem there.
3334 # This is virtually a duplicate of what happens in configure.lang; we do
3335 # an extra check to make sure this only happens if ln -s can be used.
3336 case "$LN_S" in
3337   *-s*)
3338     for d in ${subdirs} ; do
3339         STARTDIR=`${PWDCMD-pwd}`
3340         cd $d
3341         for t in stage1 stage2 stage3 stage4 stageprofile stagefeedback include
3342         do
3343                 rm -f $t
3344                 $LN_S ../$t $t 2>/dev/null
3345         done
3346         cd $STARTDIR
3347     done
3348   ;;
3349 esac
3350 ],
3351 [subdirs='$subdirs'])
3352 AC_OUTPUT