gcc/configure.ac

   1 # configure.ac for GCC
   2 # Process this file with autoconf to generate a configuration script.
   3
   4 # Copyright 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2004, 2005
   5 # Free Software Foundation, Inc.
   6
   7 #This file is part of GCC.
   8
   9 #GCC is free software; you can redistribute it and/or modify it under
  10 #the terms of the GNU General Public License as published by the Free
  11 #Software Foundation; either version 2, or (at your option) any later
  12 #version.
  13
  14 #GCC is distributed in the hope that it will be useful, but WITHOUT
  15 #ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  16 #FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  17 #for more details.
  18
  19 #You should have received a copy of the GNU General Public License
  20 #along with GCC; see the file COPYING.  If not, write to the Free
  21 #Software Foundation, 51 Franklin Street, Fifth Floor, Boston, MA
  22 #02110-1301, USA.
  23
  24 # --------------------------------
  25 # Initialization and sanity checks
  26 # --------------------------------
  27
  28 AC_PREREQ(2.59)
  29 AC_INIT
  30 AC_CONFIG_SRCDIR(tree.c)
  31 AC_CONFIG_HEADER(auto-host.h:config.in)
  32
  33 gcc_version=`cat $srcdir/BASE-VER`
  34
  35 # Determine the host, build, and target systems
  36 AC_CANONICAL_BUILD
  37 AC_CANONICAL_HOST
  38 AC_CANONICAL_TARGET
  39
  40 # Determine the noncanonical target name, for directory use.
  41 ACX_NONCANONICAL_TARGET
  42
  43 # Determine the target- and build-specific subdirectories
  44 GCC_TOPLEV_SUBDIRS
  45
  46 # Set program_transform_name
  47 AC_ARG_PROGRAM
  48
  49 # Check for bogus environment variables.
  50 # Test if LIBRARY_PATH contains the notation for the current directory
  51 # since this would lead to problems installing/building glibc.
  52 # LIBRARY_PATH contains the current directory if one of the following
  53 # is true:
  54 # - one of the terminals (":" and ";") is the first or last sign
  55 # - two terminals occur directly after each other
  56 # - the path contains an element with a dot in it
  57 AC_MSG_CHECKING(LIBRARY_PATH variable)
  58 changequote(,)dnl
  59 case ${LIBRARY_PATH} in
  60   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
  61     library_path_setting="contains current directory"
  62     ;;
  63   *)
  64     library_path_setting="ok"
  65     ;;
  66 esac
  67 changequote([,])dnl
  68 AC_MSG_RESULT($library_path_setting)
  69 if test "$library_path_setting" != "ok"; then
  70 AC_MSG_ERROR([
  71 *** LIBRARY_PATH shouldn't contain the current directory when
  72 *** building gcc. Please change the environment variable
  73 *** and run configure again.])
  74 fi
  75
  76 # Test if GCC_EXEC_PREFIX contains the notation for the current directory
  77 # since this would lead to problems installing/building glibc.
  78 # GCC_EXEC_PREFIX contains the current directory if one of the following
  79 # is true:
  80 # - one of the terminals (":" and ";") is the first or last sign
  81 # - two terminals occur directly after each other
  82 # - the path contains an element with a dot in it
  83 AC_MSG_CHECKING(GCC_EXEC_PREFIX variable)
  84 changequote(,)dnl
  85 case ${GCC_EXEC_PREFIX} in
  86   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
  87     gcc_exec_prefix_setting="contains current directory"
  88     ;;
  89   *)
  90     gcc_exec_prefix_setting="ok"
  91     ;;
  92 esac
  93 changequote([,])dnl
  94 AC_MSG_RESULT($gcc_exec_prefix_setting)
  95 if test "$gcc_exec_prefix_setting" != "ok"; then
  96 AC_MSG_ERROR([
  97 *** GCC_EXEC_PREFIX shouldn't contain the current directory when
  98 *** building gcc. Please change the environment variable
  99 *** and run configure again.])
 100 fi
 101
 102 # -----------
 103 # Directories
 104 # -----------
 105
 106 # Specify the local prefix
 107 local_prefix=
 108 AC_ARG_WITH(local-prefix,
 109 [  --with-local-prefix=DIR specifies directory to put local include],
 110 [case "${withval}" in
 111 yes)    AC_MSG_ERROR(bad value ${withval} given for local include directory prefix) ;;
 112 no)     ;;
 113 *)      local_prefix=$with_local_prefix ;;
 114 esac])
 115
 116 # Default local prefix if it is empty
 117 if test x$local_prefix = x; then
 118         local_prefix=/usr/local
 119 fi
 120
 121 # Don't set gcc_gxx_include_dir to gxx_include_dir since that's only
 122 # passed in by the toplevel make and thus we'd get different behavior
 123 # depending on where we built the sources.
 124 gcc_gxx_include_dir=
 125 # Specify the g++ header file directory
 126 AC_ARG_WITH(gxx-include-dir,
 127 [  --with-gxx-include-dir=DIR
 128                           specifies directory to put g++ header files],
 129 [case "${withval}" in
 130 yes)    AC_MSG_ERROR(bad value ${withval} given for g++ include directory) ;;
 131 no)     ;;
 132 *)      gcc_gxx_include_dir=$with_gxx_include_dir ;;
 133 esac])
 134
 135 # This logic must match libstdc++-v3/acinclude.m4:GLIBCXX_EXPORT_INSTALL_INFO.
 136 if test x${gcc_gxx_include_dir} = x; then
 137   if test x${enable_version_specific_runtime_libs} = xyes; then
 138     gcc_gxx_include_dir='${libsubdir}/include/c++'
 139   else
 140     libstdcxx_incdir='include/c++/$(version)'
 141     if test x$host != x$target; then
 142        libstdcxx_incdir="$target_alias/$libstdcxx_incdir"
 143     fi
 144 changequote(<<, >>)dnl
 145     gcc_gxx_include_dir="\$(libsubdir)/\$(unlibsubdir)/..\`echo \$(exec_prefix) | sed -e 's|^\$(prefix)||' -e 's|/[^/]*|/..|g'\`/$libstdcxx_incdir"
 146 changequote([, ])dnl
 147   fi
 148 fi
 149
 150 AC_ARG_WITH(cpp_install_dir,
 151 [  --with-cpp-install-dir=DIR
 152                           install the user visible C preprocessor in DIR
 153                           (relative to PREFIX) as well as PREFIX/bin],
 154 [if test x$withval = xyes; then
 155   AC_MSG_ERROR([option --with-cpp-install-dir requires an argument])
 156 elif test x$withval != xno; then
 157   cpp_install_dir=$withval
 158 fi])
 159
 160 # We would like to our source tree to be readonly.  However when releases or
 161 # pre-releases are generated, the flex/bison generated files as well as the
 162 # various formats of manuals need to be included along with the rest of the
 163 # sources.  Therefore we have --enable-generated-files-in-srcdir to do
 164 # just that.
 165
 166 AC_MSG_CHECKING([whether to place generated files in the source directory])
 167   dnl generated-files-in-srcdir is disabled by default
 168   AC_ARG_ENABLE(generated-files-in-srcdir,
 169 [  --enable-generated-files-in-srcdir
 170                           put copies of generated files in source dir
 171                           intended for creating source tarballs for users
 172                           without texinfo bison or flex.],
 173       generated_files_in_srcdir=$enableval,
 174       generated_files_in_srcdir=no)
 175
 176 AC_MSG_RESULT($generated_files_in_srcdir)
 177
 178 if test "$generated_files_in_srcdir" = "yes"; then
 179   GENINSRC=''
 180 else
 181   GENINSRC='#'
 182 fi
 183 AC_SUBST(GENINSRC)
 184
 185 # -------------------
 186 # Find default linker
 187 # -------------------
 188
 189 # With GNU ld
 190 AC_ARG_WITH(gnu-ld,
 191 [  --with-gnu-ld           arrange to work with GNU ld.],
 192 gnu_ld_flag="$with_gnu_ld",
 193 gnu_ld_flag=no)
 194
 195 # With pre-defined ld
 196 AC_ARG_WITH(ld,
 197 [  --with-ld               arrange to use the specified ld (full pathname)],
 198 DEFAULT_LINKER="$with_ld")
 199 if test x"${DEFAULT_LINKER+set}" = x"set"; then
 200   if test ! -x "$DEFAULT_LINKER"; then
 201     AC_MSG_ERROR([cannot execute: $DEFAULT_LINKER: check --with-ld or env. var. DEFAULT_LINKER])
 202   elif $DEFAULT_LINKER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
 203     gnu_ld_flag=yes
 204   fi
 205   AC_DEFINE_UNQUOTED(DEFAULT_LINKER,"$DEFAULT_LINKER",
 206         [Define to enable the use of a default linker.])
 207 fi
 208
 209 AC_MSG_CHECKING([whether a default linker was specified])
 210 if test x"${DEFAULT_LINKER+set}" = x"set"; then
 211   if test x"$gnu_ld_flag" = x"no"; then
 212     AC_MSG_RESULT([yes ($DEFAULT_LINKER)])
 213   else
 214     AC_MSG_RESULT([yes ($DEFAULT_LINKER - GNU ld)])
 215   fi
 216 else
 217   AC_MSG_RESULT(no)
 218 fi
 219
 220 # With demangler in GNU ld
 221 AC_ARG_WITH(demangler-in-ld,
 222 [  --with-demangler-in-ld  try to use demangler in GNU ld.],
 223 demangler_in_ld="$with_demangler_in_ld",
 224 demangler_in_ld=no)
 225
 226 # ----------------------
 227 # Find default assembler
 228 # ----------------------
 229
 230 # With GNU as
 231 AC_ARG_WITH(gnu-as,
 232 [  --with-gnu-as           arrange to work with GNU as],
 233 gas_flag="$with_gnu_as",
 234 gas_flag=no)
 235
 236 AC_ARG_WITH(as,
 237 [  --with-as               arrange to use the specified as (full pathname)],
 238 DEFAULT_ASSEMBLER="$with_as")
 239 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
 240   if test ! -x "$DEFAULT_ASSEMBLER"; then
 241     AC_MSG_ERROR([cannot execute: $DEFAULT_ASSEMBLER: check --with-as or env. var. DEFAULT_ASSEMBLER])
 242   elif $DEFAULT_ASSEMBLER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
 243     gas_flag=yes
 244   fi
 245   AC_DEFINE_UNQUOTED(DEFAULT_ASSEMBLER,"$DEFAULT_ASSEMBLER",
 246         [Define to enable the use of a default assembler.])
 247 fi
 248
 249 AC_MSG_CHECKING([whether a default assembler was specified])
 250 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
 251   if test x"$gas_flag" = x"no"; then
 252     AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER)])
 253   else
 254     AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER - GNU as)])
 255   fi
 256 else
 257   AC_MSG_RESULT(no)
 258 fi
 259
 260 # ---------------
 261 # Find C compiler
 262 # ---------------
 263
 264 # If a non-executable a.out is present (e.g. created by GNU as above even if
 265 # invoked with -v only), the IRIX 6 native ld just overwrites the existing
 266 # file, even when creating an executable, so an execution test fails.
 267 # Remove possible default executable files to avoid this.
 268 #
 269 # FIXME: This really belongs into AC_PROG_CC and can be removed once
 270 # Autoconf includes it.
 271 rm -f a.out a.exe b.out
 272
 273 # Find the native compiler
 274 AC_PROG_CC
 275 AM_PROG_CC_C_O
 276 # autoconf is lame and doesn't give us any substitution variable for this.
 277 if eval "test \"`echo '$ac_cv_prog_cc_'${ac_cc}_c_o`\" = no"; then
 278   NO_MINUS_C_MINUS_O=yes
 279 else
 280   OUTPUT_OPTION='-o $@'
 281 fi
 282 AC_SUBST(NO_MINUS_C_MINUS_O)
 283 AC_SUBST(OUTPUT_OPTION)
 284
 285 # Remove the -O2: for historical reasons, unless bootstrapping we prefer
 286 # optimizations to be activated explicitly by the toplevel.
 287 case "$CC" in
 288   */prev-gcc/xgcc*) ;;
 289   *) CFLAGS=`echo $CFLAGS | sed "s/-O[[s0-9]]* *//" ` ;;
 290 esac
 291 AC_SUBST(CFLAGS)
 292
 293 # -------------------------
 294 # Check C compiler features
 295 # -------------------------
 296
 297 AC_PROG_CPP
 298 AC_C_INLINE
 299
 300 # sizeof(char) is 1 by definition.
 301 AC_CHECK_SIZEOF(void *)
 302 AC_CHECK_SIZEOF(short)
 303 AC_CHECK_SIZEOF(int)
 304 AC_CHECK_SIZEOF(long)
 305 AC_CHECK_TYPES([long long], [AC_CHECK_SIZEOF(long long)])
 306 AC_CHECK_TYPES([__int64], [AC_CHECK_SIZEOF(__int64)])
 307
 308 # ---------------------
 309 # Warnings and checking
 310 # ---------------------
 311
 312 # Check $CC warning features (if it's GCC).
 313 # We want to use -pedantic, but we don't want warnings about
 314 # * 'long long'
 315 # * variadic macros
 316 # * overlong strings
 317 # So, we only use -pedantic if we can disable those warnings.
 318
 319 AC_CACHE_CHECK(
 320   [whether ${CC} accepts -Wno-long-long],
 321   [ac_cv_prog_cc_w_no_long_long],
 322   [save_CFLAGS="$CFLAGS"
 323   CFLAGS="-Wno-long-long"
 324   AC_COMPILE_IFELSE([AC_LANG_SOURCE([[]])],
 325                     [ac_cv_prog_cc_w_no_long_long=yes],
 326                     [ac_cv_prog_cc_w_no_long_long=no])
 327   CFLAGS="$save_CFLAGS"
 328   ])
 329
 330 AC_CACHE_CHECK(
 331   [whether ${CC} accepts -Wno-variadic-macros],
 332   [ac_cv_prog_cc_w_no_variadic_macros],
 333   [save_CFLAGS="$CFLAGS"
 334   CFLAGS="-Wno-variadic-macros"
 335   AC_COMPILE_IFELSE([AC_LANG_SOURCE([[]])],
 336                     [ac_cv_prog_cc_w_no_variadic_macros=yes],
 337                     [ac_cv_prog_cc_w_no_variadic_macros=no])
 338   CFLAGS="$save_CFLAGS"
 339   ])
 340
 341 AC_CACHE_CHECK(
 342   [whether ${CC} accepts -Wno-overlength-strings],
 343   [ac_cv_prog_cc_w_no_overlength_strings],
 344   [save_CFLAGS="$CFLAGS"
 345   CFLAGS="-Wno-overlength-strings"
 346   AC_COMPILE_IFELSE([AC_LANG_SOURCE([[]])],
 347                     [ac_cv_prog_cc_w_no_overlength_strings=yes],
 348                     [ac_cv_prog_cc_w_no_overlength_strings=no])
 349   CFLAGS="$save_CFLAGS"
 350   ])
 351
 352 strict1_warn=
 353 if test $ac_cv_prog_cc_w_no_long_long = yes \
 354    && test $ac_cv_prog_cc_w_no_variadic_macros = yes \
 355    && test $ac_cv_prog_cc_w_no_overlength_strings = yes ; then
 356   strict1_warn="-pedantic -Wno-long-long -Wno-variadic-macros -Wno-overlength-strings"
 357 fi
 358
 359 # Add -Wold-style-definition if it's accepted
 360 AC_CACHE_CHECK(
 361   [whether ${CC} accepts -Wold-style-definition],
 362   [ac_cv_prog_cc_w_old_style_definition],
 363   [save_CFLAGS="$CFLAGS"
 364   CFLAGS="-Wold-style-definition"
 365   AC_COMPILE_IFELSE([AC_LANG_SOURCE([[]])],
 366                     [ac_cv_prog_cc_w_old_style_definition=yes],
 367                     [ac_cv_prog_cc_w_old_style_definition=no])
 368   CFLAGS="$save_CFLAGS"
 369   ])
 370 if test $ac_cv_prog_cc_w_old_style_definition = yes ; then
 371   strict1_warn="${strict1_warn} -Wold-style-definition"
 372 fi
 373
 374 # Add -Wmissing-format-attribute if it's accepted
 375 AC_CACHE_CHECK(
 376   [whether ${CC} accepts -Wmissing-format-attribute],
 377   [ac_cv_prog_cc_w_missing_format_attribute],
 378   [save_CFLAGS="$CFLAGS"
 379   CFLAGS="-Wmissing-format-attribute"
 380   AC_COMPILE_IFELSE([AC_LANG_SOURCE([[]])],
 381                     [ac_cv_prog_cc_w_missing_format_attribute=yes],
 382                     [ac_cv_prog_cc_w_missing_format_attribute=no])
 383   CFLAGS="$save_CFLAGS"
 384   ])
 385 if test $ac_cv_prog_cc_w_missing_format_attribute = yes ; then
 386   strict1_warn="${strict1_warn} -Wmissing-format-attribute"
 387 fi
 388
 389 # Enable -Werror, period.
 390 AC_ARG_ENABLE(werror_always,
 391 [  --enable-werror-always         enable -Werror always], [],
 392 [enable_werror_always=no])
 393 if test x${enable_werror_always} = xyes ; then
 394   strict1_warn="${strict1_warn} -Werror"
 395   WERROR=-Werror
 396 fi
 397
 398 AC_SUBST(strict1_warn)
 399
 400 # Get C++ compatibility warning flag, if supported.
 401 AC_CACHE_CHECK(
 402   [whether ${CC} accepts -Wc++-compat],
 403   [ac_cv_prog_cc_w_cxx_compat],
 404   [save_CFLAGS="$CFLAGS"
 405   CFLAGS="-Wc++-compat"
 406   AC_COMPILE_IFELSE([AC_LANG_SOURCE([[]])],
 407                     [ac_cv_prog_cc_w_cxx_compat=yes],
 408                     [ac_cv_prog_cc_w_cxx_compat=no])
 409   CFLAGS="$save_CFLAGS"
 410   ])
 411 if test x${ac_cv_prog_cc_w_cxx_compat} = xyes; then
 412   cxx_compat_warn="-Wc++-compat"
 413 fi
 414 AC_SUBST(cxx_compat_warn)
 415
 416
 417 # If the native compiler is GCC, we can enable warnings even in stage1.
 418 # That's useful for people building cross-compilers, or just running a
 419 # quick `make'.
 420 warn_cflags=
 421 if test "x$GCC" = "xyes"; then
 422   warn_cflags='$(GCC_WARN_CFLAGS)'
 423 fi
 424 AC_SUBST(warn_cflags)
 425
 426 # Enable -Werror in bootstrap stage2 and later.
 427 is_release=
 428 if test x"`cat $srcdir/DEV-PHASE`" != xexperimental; then
 429   is_release=yes
 430 fi
 431 AC_ARG_ENABLE(werror,
 432 [  --enable-werror         enable -Werror in bootstrap stage2 and later], [],
 433 [if test x$is_release = x ; then
 434   # Default to "yes" on development branches.
 435   enable_werror=yes
 436 else
 437   # Default to "no" on release branches.
 438   enable_werror=no
 439 fi])
 440 if test x$enable_werror = xyes ; then
 441   WERROR=-Werror
 442 fi
 443 AC_SUBST(WERROR)
 444
 445 # Enable expensive internal checks
 446 AC_ARG_ENABLE(checking,
 447 [  --enable-checking[=LIST]
 448                           enable expensive run-time checks.  With LIST,
 449                           enable only specific categories of checks.
 450                           Categories are: yes,no,all,none,release.
 451                           Flags are: assert,fold,gc,gcac,misc,
 452                           rtlflag,rtl,runtime,tree,valgrind.],
 453 [ac_checking_flags="${enableval}"],[
 454 # Determine the default checks.
 455 if test x$is_release = x ; then
 456   ac_checking_flags=yes
 457 else
 458   ac_checking_flags=release
 459 fi])
 460 ac_assert_checking=1
 461 ac_checking=
 462 ac_fold_checking=
 463 ac_gc_checking=
 464 ac_gc_always_collect=
 465 ac_rtl_checking=
 466 ac_rtlflag_checking=
 467 ac_runtime_checking=1
 468 ac_tree_checking=
 469 ac_valgrind_checking=
 470 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 471 for check in $ac_checking_flags
 472 do
 473         case $check in
 474         # these set all the flags to specific states
 475         yes)            ac_assert_checking=1 ; ac_checking=1 ;
 476                         ac_fold_checking= ; ac_gc_checking=1 ;
 477                         ac_gc_always_collect= ; ac_rtl_checking= ;
 478                         ac_rtlflag_checking=1 ; ac_runtime_checking=1 ;
 479                         ac_tree_checking=1 ; ac_valgrind_checking= ;;
 480         no|none)        ac_assert_checking= ; ac_checking= ;
 481                         ac_fold_checking= ; ac_gc_checking= ;
 482                         ac_gc_always_collect= ; ac_rtl_checking= ;
 483                         ac_rtlflag_checking= ; ac_runtime_checking= ;
 484                         ac_tree_checking= ; ac_valgrind_checking= ;;
 485         all)            ac_assert_checking=1 ; ac_checking=1 ;
 486                         ac_fold_checking=1 ; ac_gc_checking=1 ;
 487                         ac_gc_always_collect=1 ; ac_rtl_checking=1 ;
 488                         ac_rtlflag_checking=1 ; ac_runtime_checking=1 ;
 489                         ac_tree_checking=1 ; ac_valgrind_checking= ;;
 490         release)        ac_assert_checking=1 ; ac_checking= ;
 491                         ac_fold_checking= ; ac_gc_checking= ;
 492                         ac_gc_always_collect= ; ac_rtl_checking= ;
 493                         ac_rtlflag_checking= ; ac_runtime_checking=1 ;
 494                         ac_tree_checking= ; ac_valgrind_checking= ;;
 495         # these enable particular checks
 496         assert)         ac_assert_checking=1 ;;
 497         fold)           ac_fold_checking=1 ;;
 498         gc)             ac_gc_checking=1 ;;
 499         gcac)           ac_gc_always_collect=1 ;;
 500         misc)           ac_checking=1 ;;
 501         rtl)            ac_rtl_checking=1 ;;
 502         rtlflag)        ac_rtlflag_checking=1 ;;
 503         runtime)        ac_runtime_checking=1 ;;
 504         tree)           ac_tree_checking=1 ;;
 505         valgrind)       ac_valgrind_checking=1 ;;
 506         *)      AC_MSG_ERROR(unknown check category $check) ;;
 507         esac
 508 done
 509 IFS="$ac_save_IFS"
 510
 511 nocommon_flag=""
 512 if test x$ac_checking != x ; then
 513   AC_DEFINE(ENABLE_CHECKING, 1,
 514 [Define if you want more run-time sanity checks.  This one gets a grab
 515    bag of miscellaneous but relatively cheap checks.])
 516   nocommon_flag=-fno-common
 517 fi
 518 AC_SUBST(nocommon_flag)
 519 if test x$ac_assert_checking != x ; then
 520   AC_DEFINE(ENABLE_ASSERT_CHECKING, 1,
 521 [Define if you want assertions enabled.  This is a cheap check.])
 522 fi
 523 GCC_TARGET_TEMPLATE(ENABLE_RUNTIME_CHECKING)
 524 if test x$ac_runtime_checking != x ; then
 525   AC_DEFINE(ENABLE_RUNTIME_CHECKING, 1,
 526 [Define if you want runtime assertions enabled.  This is a cheap check.])
 527 fi
 528 if test x$ac_tree_checking != x ; then
 529   AC_DEFINE(ENABLE_TREE_CHECKING, 1,
 530 [Define if you want all operations on trees (the basic data
 531    structure of the front ends) to be checked for dynamic type safety
 532    at runtime.  This is moderately expensive.  The tree browser debugging
 533    routines will also be enabled by this option.
 534    ])
 535   TREEBROWSER=tree-browser.o
 536 fi
 537 AC_SUBST(TREEBROWSER)
 538 if test x$ac_rtl_checking != x ; then
 539   AC_DEFINE(ENABLE_RTL_CHECKING, 1,
 540 [Define if you want all operations on RTL (the basic data structure
 541    of the optimizer and back end) to be checked for dynamic type safety
 542    at runtime.  This is quite expensive.])
 543 fi
 544 if test x$ac_rtlflag_checking != x ; then
 545   AC_DEFINE(ENABLE_RTL_FLAG_CHECKING, 1,
 546 [Define if you want RTL flag accesses to be checked against the RTL
 547    codes that are supported for each access macro.  This is relatively
 548    cheap.])
 549 fi
 550 if test x$ac_gc_checking != x ; then
 551   AC_DEFINE(ENABLE_GC_CHECKING, 1,
 552 [Define if you want the garbage collector to do object poisoning and
 553    other memory allocation checks.  This is quite expensive.])
 554 fi
 555 if test x$ac_gc_always_collect != x ; then
 556   AC_DEFINE(ENABLE_GC_ALWAYS_COLLECT, 1,
 557 [Define if you want the garbage collector to operate in maximally
 558    paranoid mode, validating the entire heap and collecting garbage at
 559    every opportunity.  This is extremely expensive.])
 560 fi
 561 if test x$ac_fold_checking != x ; then
 562   AC_DEFINE(ENABLE_FOLD_CHECKING, 1,
 563 [Define if you want fold checked that it never destructs its argument.
 564    This is quite expensive.])
 565 fi
 566 valgrind_path_defines=
 567 valgrind_command=
 568
 569 dnl # This check AC_REQUIREs various stuff, so it *must not* be inside
 570 dnl # an if statement.  This was the source of very frustrating bugs
 571 dnl # in converting to autoconf 2.5x!
 572 AC_CHECK_HEADER(valgrind.h, have_valgrind_h=yes, have_valgrind_h=no)
 573
 574 if test x$ac_valgrind_checking != x ; then
 575   # It is certainly possible that there's valgrind but no valgrind.h.
 576   # GCC relies on making annotations so we must have both.
 577   AC_MSG_CHECKING(for VALGRIND_DISCARD in <valgrind/memcheck.h>)
 578   AC_PREPROC_IFELSE([AC_LANG_SOURCE(
 579     [[#include <valgrind/memcheck.h>
 580 #ifndef VALGRIND_DISCARD
 581 #error VALGRIND_DISCARD not defined
 582 #endif]])],
 583   [gcc_cv_header_valgrind_memcheck_h=yes],
 584   [gcc_cv_header_valgrind_memcheck_h=no])
 585   AC_MSG_RESULT($gcc_cv_header_valgrind_memcheck_h)
 586   AC_MSG_CHECKING(for VALGRIND_DISCARD in <memcheck.h>)
 587   AC_PREPROC_IFELSE([AC_LANG_SOURCE(
 588     [[#include <memcheck.h>
 589 #ifndef VALGRIND_DISCARD
 590 #error VALGRIND_DISCARD not defined
 591 #endif]])],
 592   [gcc_cv_header_memcheck_h=yes],
 593   [gcc_cv_header_memcheck_h=no])
 594   AC_MSG_RESULT($gcc_cv_header_memcheck_h)
 595   AM_PATH_PROG_WITH_TEST(valgrind_path, valgrind,
 596         [$ac_dir/$ac_word --version | grep valgrind- >/dev/null 2>&1])
 597   if test "x$valgrind_path" = "x" \
 598     || (test $have_valgrind_h = no \
 599         && test $gcc_cv_header_memcheck_h = no \
 600         && test $gcc_cv_header_valgrind_memcheck_h = no); then
 601         AC_MSG_ERROR([*** Can't find both valgrind and valgrind/memcheck.h, memcheck.h or valgrind.h])
 602   fi
 603   valgrind_path_defines=-DVALGRIND_PATH='\"'$valgrind_path'\"'
 604   valgrind_command="$valgrind_path -q"
 605   AC_DEFINE(ENABLE_VALGRIND_CHECKING, 1,
 606 [Define if you want to run subprograms and generated programs
 607    through valgrind (a memory checker).  This is extremely expensive.])
 608   if test $gcc_cv_header_valgrind_memcheck_h = yes; then
 609     AC_DEFINE(HAVE_VALGRIND_MEMCHECK_H, 1,
 610         [Define if valgrind's valgrind/memcheck.h header is installed.])
 611   fi
 612   if test $gcc_cv_header_memcheck_h = yes; then
 613     AC_DEFINE(HAVE_MEMCHECK_H, 1,
 614         [Define if valgrind's memcheck.h header is installed.])
 615   fi
 616 fi
 617 AC_SUBST(valgrind_path_defines)
 618 AC_SUBST(valgrind_command)
 619
 620 AC_ARG_ENABLE(mapped-location,
 621 [  --enable-mapped-location   location_t is fileline integer cookie],,
 622 enable_mapped_location=no)
 623
 624 if test "$enable_mapped_location" = yes ; then
 625   AC_DEFINE(USE_MAPPED_LOCATION, 1,
 626 [Define if location_t is fileline integer cookie.])
 627 fi
 628
 629 # Enable code coverage collection
 630 AC_ARG_ENABLE(coverage,
 631 [  --enable-coverage[=LEVEL]
 632                           enable compiler's code coverage collection.
 633                           Use to measure compiler performance and locate
 634                           unused parts of the compiler. With LEVEL, specify
 635                           optimization. Values are opt, noopt,
 636                           default is noopt],
 637 [case "${enableval}" in
 638   yes|noopt)
 639     coverage_flags="-fprofile-arcs -ftest-coverage -frandom-seed=\$@ -O0"
 640     ;;
 641   opt)
 642     coverage_flags="-fprofile-arcs -ftest-coverage -frandom-seed=\$@ -O2"
 643     ;;
 644   no)
 645     # a.k.a. --disable-coverage
 646     coverage_flags=""
 647     ;;
 648   *)
 649     AC_MSG_ERROR(unknown coverage setting $enableval)
 650     ;;
 651 esac],
 652 [coverage_flags=""])
 653 AC_SUBST(coverage_flags)
 654
 655 AC_ARG_ENABLE(gather-detailed-mem-stats,
 656 [  --enable-gather-detailed-mem-stats         enable detailed memory allocation stats gathering], [],
 657 [enable_gather_detailed_mem_stats=no])
 658 if test x$enable_gather_detailed_mem_stats = xyes ; then
 659   AC_DEFINE(GATHER_STATISTICS, 1,
 660         [Define to enable detailed memory allocation stats gathering.])
 661 fi
 662
 663 # -------------------------------
 664 # Miscenalleous configure options
 665 # -------------------------------
 666
 667 # With stabs
 668 AC_ARG_WITH(stabs,
 669 [  --with-stabs            arrange to use stabs instead of host debug format],
 670 stabs="$with_stabs",
 671 stabs=no)
 672
 673 # Determine whether or not multilibs are enabled.
 674 AC_ARG_ENABLE(multilib,
 675 [  --enable-multilib       enable library support for multiple ABIs],
 676 [], [enable_multilib=yes])
 677 AC_SUBST(enable_multilib)
 678
 679 # Enable __cxa_atexit for C++.
 680 AC_ARG_ENABLE(__cxa_atexit,
 681 [  --enable-__cxa_atexit   enable __cxa_atexit for C++],
 682 [], [])
 683
 684 # Enable C extension for decimal float if target supports it.
 685 AC_ARG_ENABLE(decimal-float,
 686 [  --enable-decimal-float  enable decimal float extension to C],
 687 [
 688   if test x$enablevar = xyes ; then
 689     case $target in
 690     powerpc*-*-linux* | i?86*-*-linux*)
 691       enable_decimal_float=yes
 692       ;;
 693     *)
 694       AC_MSG_WARN(decimal float is not supported for this target, ignored)
 695       enable_decimal_float=no
 696       ;;
 697     esac
 698   fi
 699 ], [enable_decimal_float=no])
 700
 701 AC_SUBST(enable_decimal_float)
 702
 703 dfp=`if test $enable_decimal_float = yes; then echo 1; else echo 0; fi`
 704 AC_DEFINE_UNQUOTED(ENABLE_DECIMAL_FLOAT, $dfp,
 705 [Define to 1 to enable decimal float extension to C.])
 706
 707 # Enable threads
 708 # Pass with no value to take the default
 709 # Pass with a value to specify a thread package
 710 AC_ARG_ENABLE(threads,
 711 [  --enable-threads        enable thread usage for target GCC
 712   --enable-threads=LIB    use LIB thread package for target GCC],,
 713 [enable_threads=''])
 714
 715 AC_ARG_ENABLE(tls,
 716 [  --enable-tls            enable or disable generation of tls code
 717                           overriding the assembler check for tls support],
 718 [
 719   case $enable_tls in
 720     yes | no) ;;
 721     *) AC_MSG_ERROR(['$enable_tls' is an invalid value for --enable-tls.
 722 Valid choices are 'yes' and 'no'.]) ;;
 723   esac
 724 ], [enable_tls=''])
 725
 726 AC_ARG_ENABLE(objc-gc,
 727 [  --enable-objc-gc       enable the use of Boehm's garbage collector with
 728                           the GNU Objective-C runtime],
 729 if test x$enable_objc_gc = xno; then
 730         objc_boehm_gc=''
 731 else
 732         objc_boehm_gc=1
 733 fi,
 734 objc_boehm_gc='')
 735
 736 AC_ARG_WITH(dwarf2,
 737 [  --with-dwarf2           force the default debug format to be DWARF 2],
 738 dwarf2="$with_dwarf2",
 739 dwarf2=no)
 740
 741 AC_ARG_ENABLE(shared,
 742 [  --disable-shared        don't provide a shared libgcc],
 743 [
 744   case $enable_shared in
 745   yes | no) ;;
 746   *)
 747     enable_shared=no
 748     IFS="${IFS=         }"; ac_save_ifs="$IFS"; IFS="${IFS}:,"
 749     for pkg in $enableval; do
 750       if test "X$pkg" = "Xgcc" || test "X$pkg" = "Xlibgcc"; then
 751         enable_shared=yes
 752       fi
 753     done
 754     IFS="$ac_save_ifs"
 755     ;;
 756   esac
 757 ], [enable_shared=yes])
 758 AC_SUBST(enable_shared)
 759
 760 AC_ARG_WITH(build-sysroot,
 761   [  --with-build-sysroot=sysroot
 762                           use sysroot as the system root during the build])
 763
 764 AC_ARG_WITH(sysroot,
 765 [  --with-sysroot[=DIR] Search for usr/lib, usr/include, et al, within DIR.],
 766 [
 767  case ${with_sysroot} in
 768  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_noncanonical}/sys-root' ;;
 769  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
 770  esac
 771
 772  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
 773  CROSS_SYSTEM_HEADER_DIR='$(TARGET_SYSTEM_ROOT)$(NATIVE_SYSTEM_HEADER_DIR)'
 774
 775  if test "x$exec_prefix" = xNONE; then
 776   if test "x$prefix" = xNONE; then
 777    test_prefix=/usr/local
 778   else
 779    test_prefix=$prefix
 780   fi
 781  else
 782   test_prefix=$exec_prefix
 783  fi
 784  case ${TARGET_SYSTEM_ROOT} in
 785  "${test_prefix}"|"${test_prefix}/"*|\
 786  '${exec_prefix}'|'${exec_prefix}/'*)
 787    t="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE"
 788    TARGET_SYSTEM_ROOT_DEFINE="$t"
 789    ;;
 790  esac
 791 ], [
 792  TARGET_SYSTEM_ROOT=
 793  TARGET_SYSTEM_ROOT_DEFINE=
 794  CROSS_SYSTEM_HEADER_DIR='$(gcc_tooldir)/sys-include'
 795 ])
 796 AC_SUBST(TARGET_SYSTEM_ROOT)
 797 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
 798 AC_SUBST(CROSS_SYSTEM_HEADER_DIR)
 799
 800 # Build with intermodule optimisations
 801 AC_ARG_ENABLE(intermodule,
 802 [  --enable-intermodule    build the compiler in one step],
 803 [case ${enable_intermodule} in
 804   yes) onestep="-onestep";;
 805   *) onestep="";;
 806 esac],
 807 [onestep=""])
 808 AC_SUBST(onestep)
 809
 810 # Sanity check enable_languages in case someone does not run the toplevel
 811 # configure # script.
 812 AC_ARG_ENABLE(languages,
 813 [  --enable-languages=LIST specify which front-ends to build],
 814 [case ,${enable_languages}, in
 815        ,,|,yes,)
 816                 # go safe -- we cannot be much sure without the toplevel
 817                 # configure's
 818                 # analysis of which target libs are present and usable
 819                 enable_languages=c
 820                 ;;
 821          *,all,*)
 822                 AC_MSG_ERROR([only the toplevel supports --enable-languages=all])
 823                 ;;
 824         *,c,*)
 825                 ;;
 826         *)
 827                 enable_languages=c,${enable_languages}
 828                 ;;
 829 esac],
 830 [enable_languages=c])
 831
 832 # Used by documentation targets
 833 AC_SUBST(datarootdir)
 834 AC_SUBST(docdir)
 835 AC_SUBST(htmldir)
 836
 837 # -------------------------
 838 # Checks for other programs
 839 # -------------------------
 840
 841 AC_PROG_MAKE_SET
 842
 843 # Find some useful tools
 844 AC_PROG_AWK
 845 # We need awk to create options.c and options.h.
 846 # Bail out if it's missing.
 847 case ${AWK} in
 848   "") AC_MSG_ERROR([can't build without awk, bailing out]) ;;
 849 esac
 850
 851 gcc_AC_PROG_LN_S
 852 ACX_PROG_LN($LN_S)
 853 AC_PROG_RANLIB
 854 case "${host}" in
 855 *-*-darwin*)
 856   # By default, the Darwin ranlib will not treat common symbols as
 857   # definitions when  building the archive table of contents.  Other
 858   # ranlibs do that; pass an option to the Darwin ranlib that makes
 859   # it behave similarly.
 860   ranlib_flags="-c"
 861   ;;
 862 *)
 863   ranlib_flags=""
 864 esac
 865 AC_SUBST(ranlib_flags)
 866
 867 gcc_AC_PROG_INSTALL
 868
 869 # See if cmp has --ignore-initial.
 870 gcc_AC_PROG_CMP_IGNORE_INITIAL
 871
 872 # See if we have the mktemp command.
 873 AC_CHECK_PROG(have_mktemp_command, mktemp, yes, no)
 874
 875 MISSING="${CONFIG_SHELL-/bin/sh} $srcdir/../missing"
 876
 877 # See if makeinfo has been installed and is modern enough
 878 # that we can use it.
 879 gcc_AC_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
 880   [GNU texinfo.* \([0-9][0-9.]*\)],
 881   [4.[4-9]*])
 882 if test $gcc_cv_prog_makeinfo_modern = no; then
 883   MAKEINFO="$MISSING makeinfo"
 884   AC_MSG_WARN([
 885 *** Makeinfo is missing or too old.
 886 *** Info documentation will not be built.])
 887   BUILD_INFO=
 888 else
 889   BUILD_INFO=info
 890 fi
 891 AC_SUBST(BUILD_INFO)
 892
 893 # Is pod2man recent enough to regenerate manpages?
 894 AC_MSG_CHECKING([for recent Pod::Man])
 895 if (perl -e 'use 1.10 Pod::Man') >/dev/null 2>&1; then
 896   AC_MSG_RESULT(yes)
 897   GENERATED_MANPAGES=generated-manpages
 898 else
 899   AC_MSG_RESULT(no)
 900   GENERATED_MANPAGES=
 901 fi
 902 AC_SUBST(GENERATED_MANPAGES)
 903
 904 # How about lex?
 905 dnl Don't use AC_PROG_LEX; we insist on flex.
 906 dnl LEXLIB is not useful in gcc.
 907 AC_CHECK_PROGS([FLEX], flex, [$MISSING flex])
 908
 909 # Bison?
 910 AC_CHECK_PROGS([BISON], bison, [$MISSING bison])
 911
 912 # Binutils are not build modules, unlike bison/flex/makeinfo.  So we
 913 # check for build == host before using them.
 914
 915 # NM
 916 if test x${build} = x${host} && test -f $srcdir/../binutils/nm.c \
 917   && test -d ../binutils ; then
 918   NM='$(objdir)/../binutils/nm-new'
 919 else
 920   AC_CHECK_PROG(NM, nm, nm, ${CONFIG_SHELL-/bin/sh} ${srcdir}/../missing nm)
 921 fi
 922
 923 # AR
 924 if test x${build} = x${host} && test -f $srcdir/../binutils/ar.c \
 925   && test -d ../binutils ; then
 926   AR='$(objdir)/../binutils/ar'
 927 else
 928   AC_CHECK_PROG(AR, ar, ar, ${CONFIG_SHELL-/bin/sh} ${srcdir}/../missing ar)
 929 fi
 930
 931
 932 # --------------------
 933 # Checks for C headers
 934 # --------------------
 935
 936 AC_MSG_CHECKING(for GNU C library)
 937 AC_CACHE_VAL(gcc_cv_glibc,
 938 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 939   [[#include <features.h>]], [[
 940 #if ! (defined __GLIBC__ || defined __GNU_LIBRARY__)
 941 #error Not a GNU C library system
 942 #endif]])],
 943   [gcc_cv_glibc=yes],
 944   [gcc_cv_glibc=no])])
 945 AC_MSG_RESULT($gcc_cv_glibc)
 946 if test $gcc_cv_glibc = yes; then
 947   AC_DEFINE(_GNU_SOURCE, 1, [Always define this when using the GNU C Library])
 948 fi
 949
 950 # Need to reject headers which give warnings, so that the -Werror bootstrap
 951 # works later. *sigh*  This needs to come before all header checks.
 952 AC_PROG_CPP_WERROR
 953
 954 AC_HEADER_STDC
 955 AC_HEADER_TIME
 956 ACX_HEADER_STRING
 957 AC_HEADER_SYS_WAIT
 958 AC_CHECK_HEADERS(limits.h stddef.h string.h strings.h stdlib.h time.h iconv.h \
 959                  fcntl.h unistd.h sys/file.h sys/time.h sys/mman.h \
 960                  sys/resource.h sys/param.h sys/times.h sys/stat.h \
 961                  direct.h malloc.h langinfo.h ldfcn.h locale.h wchar.h)
 962
 963 # Check for thread headers.
 964 AC_CHECK_HEADER(thread.h, [have_thread_h=yes], [have_thread_h=])
 965 AC_CHECK_HEADER(pthread.h, [have_pthread_h=yes], [have_pthread_h=])
 966
 967 # These tests can't be done till we know if we have limits.h.
 968 gcc_AC_C_CHAR_BIT
 969 AC_C_BIGENDIAN
 970
 971 # --------
 972 # UNSORTED
 973 # --------
 974
 975 # Stage specific cflags for build.
 976 stage1_cflags=
 977 case $build in
 978 vax-*-*)
 979   if test x$GCC = xyes
 980   then
 981     stage1_cflags="-Wa,-J"
 982   else
 983     stage1_cflags="-J"
 984   fi
 985   ;;
 986 powerpc-*-darwin*)
 987   # The spiffy cpp-precomp chokes on some legitimate constructs in GCC
 988   # sources; use -no-cpp-precomp to get to GNU cpp.
 989   # Apple's GCC has bugs in designated initializer handling, so disable
 990   # that too.
 991   stage1_cflags="-no-cpp-precomp -DHAVE_DESIGNATED_INITIALIZERS=0"
 992   ;;
 993 esac
 994 AC_SUBST(stage1_cflags)
 995
 996 # These libraries may be used by collect2.
 997 # We may need a special search path to get them linked.
 998 AC_CACHE_CHECK(for collect2 libraries, gcc_cv_collect2_libs,
 999 [save_LIBS="$LIBS"
1000 for libs in '' -lld -lmld \
1001                 '-L/usr/lib/cmplrs/cc2.11 -lmld' \
1002                 '-L/usr/lib/cmplrs/cc3.11 -lmld'
1003 do
1004         LIBS="$libs"
1005         AC_TRY_LINK_FUNC(ldopen,
1006                 [gcc_cv_collect2_libs="$libs"; break])
1007 done
1008 LIBS="$save_LIBS"
1009 test -z "$gcc_cv_collect2_libs" && gcc_cv_collect2_libs='none required'])
1010 case $gcc_cv_collect2_libs in
1011         "none required")        ;;
1012         *)      COLLECT2_LIBS=$gcc_cv_collect2_libs ;;
1013 esac
1014 AC_SUBST(COLLECT2_LIBS)
1015
1016 # When building Ada code on Alpha, we need exc_resume which is usually in
1017 # -lexc.  So test for it.
1018 save_LIBS="$LIBS"
1019 LIBS=
1020 AC_SEARCH_LIBS(exc_resume, exc)
1021 GNAT_LIBEXC="$LIBS"
1022 LIBS="$save_LIBS"
1023 AC_SUBST(GNAT_LIBEXC)
1024
1025 # Some systems put ldexp and frexp in libm instead of libc; assume
1026 # they're both in the same place.  jcf-dump needs them.
1027 save_LIBS="$LIBS"
1028 LIBS=
1029 AC_SEARCH_LIBS(ldexp, m)
1030 LDEXP_LIB="$LIBS"
1031 LIBS="$save_LIBS"
1032 AC_SUBST(LDEXP_LIB)
1033
1034 # Use <inttypes.h> only if it exists,
1035 # doesn't clash with <sys/types.h>, and declares intmax_t.
1036 AC_MSG_CHECKING(for inttypes.h)
1037 AC_CACHE_VAL(gcc_cv_header_inttypes_h,
1038 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
1039 [[#include <sys/types.h>
1040 #include <inttypes.h>]],
1041   [[intmax_t i = -1;]])],
1042   [gcc_cv_header_inttypes_h=yes],
1043   [gcc_cv_header_inttypes_h=no])])
1044 AC_MSG_RESULT($gcc_cv_header_inttypes_h)
1045 if test $gcc_cv_header_inttypes_h = yes; then
1046   AC_DEFINE(HAVE_INTTYPES_H, 1,
1047         [Define if you have a working <inttypes.h> header file.])
1048 fi
1049
1050 dnl Disabled until we have a complete test for buggy enum bitfields.
1051 dnl gcc_AC_C_ENUM_BF_UNSIGNED
1052
1053 define(gcc_UNLOCKED_FUNCS, clearerr_unlocked feof_unlocked dnl
1054   ferror_unlocked fflush_unlocked fgetc_unlocked fgets_unlocked dnl
1055   fileno_unlocked fprintf_unlocked fputc_unlocked fputs_unlocked dnl
1056   fread_unlocked fwrite_unlocked getchar_unlocked getc_unlocked dnl
1057   putchar_unlocked putc_unlocked)
1058 AC_CHECK_FUNCS(times clock kill getrlimit setrlimit atoll atoq \
1059         sysconf strsignal getrusage nl_langinfo scandir alphasort \
1060         gettimeofday mbstowcs wcswidth mmap mincore setlocale \
1061         gcc_UNLOCKED_FUNCS)
1062
1063 if test x$ac_cv_func_mbstowcs = xyes; then
1064   AC_CACHE_CHECK(whether mbstowcs works, gcc_cv_func_mbstowcs_works,
1065 [    AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdlib.h>
1066 int main()
1067 {
1068   mbstowcs(0, "", 0);
1069   return 0;
1070 }]])],
1071     [gcc_cv_func_mbstowcs_works=yes],
1072     [gcc_cv_func_mbstowcs_works=no],
1073     [gcc_cv_func_mbstowcs_works=yes])])
1074   if test x$gcc_cv_func_mbstowcs_works = xyes; then
1075     AC_DEFINE(HAVE_WORKING_MBSTOWCS, 1,
1076   [Define this macro if mbstowcs does not crash when its
1077    first argument is NULL.])
1078   fi
1079 fi
1080
1081 AC_CHECK_TYPE(ssize_t, int)
1082
1083 # Try to determine the array type of the second argument of getgroups
1084 # for the target system (int or gid_t).
1085 AC_TYPE_GETGROUPS
1086 if test "${target}" = "${build}"; then
1087   TARGET_GETGROUPS_T=$ac_cv_type_getgroups
1088 else
1089   case "${target}" in
1090         # This condition may need some tweaking.  It should include all
1091         # targets where the array type of the second argument of getgroups
1092         # is int and the type of gid_t is not equivalent to int.
1093         *-*-sunos* | *-*-ultrix*)
1094                 TARGET_GETGROUPS_T=int
1095                 ;;
1096         *)
1097                 TARGET_GETGROUPS_T=gid_t
1098                 ;;
1099   esac
1100 fi
1101 AC_SUBST(TARGET_GETGROUPS_T)
1102
1103 gcc_AC_FUNC_MMAP_BLACKLIST
1104
1105 case "${host}" in
1106 *-*-*vms*)
1107   # Under VMS, vfork works very differently than on Unix. The standard test
1108   # won't work, and it isn't easily adaptable. It makes more sense to
1109   # just force it.
1110   ac_cv_func_vfork_works=yes
1111   ;;
1112 esac
1113 AC_FUNC_FORK
1114
1115 AM_ICONV
1116 # Until we have in-tree GNU iconv:
1117 LIBICONV_DEP=
1118 AC_SUBST(LIBICONV_DEP)
1119
1120 AM_LC_MESSAGES
1121
1122 AM_LANGINFO_CODESET
1123
1124 # We will need to find libiberty.h and ansidecl.h
1125 saved_CFLAGS="$CFLAGS"
1126 CFLAGS="$CFLAGS -I${srcdir} -I${srcdir}/../include"
1127 gcc_AC_CHECK_DECLS(getenv atol asprintf sbrk abort atof getcwd getwd \
1128         strsignal strstr strverscmp \
1129         errno snprintf vsnprintf vasprintf malloc realloc calloc \
1130         free basename getopt clock getpagesize gcc_UNLOCKED_FUNCS, , ,[
1131 #include "ansidecl.h"
1132 #include "system.h"])
1133
1134 gcc_AC_CHECK_DECLS(getrlimit setrlimit getrusage, , ,[
1135 #include "ansidecl.h"
1136 #include "system.h"
1137 #ifdef HAVE_SYS_RESOURCE_H
1138 #include <sys/resource.h>
1139 #endif
1140 ])
1141
1142 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1143 #include "ansidecl.h"
1144 #include "system.h"
1145 #ifdef HAVE_SYS_RESOURCE_H
1146 #include <sys/resource.h>
1147 #endif
1148 ]], [[rlim_t l = 0;]])],[],[AC_DEFINE([rlim_t],[long],
1149 [Define to \`long' if <sys/resource.h> doesn't define.])])
1150
1151 # On AIX 5.2, <ldfcn.h> conflicts with <fcntl.h>, as both define incompatible
1152 # FREAD and FWRITE macros.  Fortunately, for GCC's single usage of ldgetname
1153 # in collect2.c, <fcntl.h> isn't visible, but the configure test below needs
1154 # to undef these macros to get the correct value for HAVE_DECL_LDGETNAME.
1155 gcc_AC_CHECK_DECLS(ldgetname, , ,[
1156 #include "ansidecl.h"
1157 #include "system.h"
1158 #ifdef HAVE_LDFCN_H
1159 #undef FREAD
1160 #undef FWRITE
1161 #include <ldfcn.h>
1162 #endif
1163 ])
1164
1165 gcc_AC_CHECK_DECLS(times, , ,[
1166 #include "ansidecl.h"
1167 #include "system.h"
1168 #ifdef HAVE_SYS_TIMES_H
1169 #include <sys/times.h>
1170 #endif
1171 ])
1172
1173 gcc_AC_CHECK_DECLS(sigaltstack, , ,[
1174 #include "ansidecl.h"
1175 #include "system.h"
1176 #include <signal.h>
1177 ])
1178
1179 # More time-related stuff.
1180 AC_CACHE_CHECK(for struct tms, ac_cv_struct_tms, [
1181 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1182 #include "ansidecl.h"
1183 #include "system.h"
1184 #ifdef HAVE_SYS_TIMES_H
1185 #include <sys/times.h>
1186 #endif
1187 ]], [[struct tms tms;]])],[ac_cv_struct_tms=yes],[ac_cv_struct_tms=no])])
1188 if test $ac_cv_struct_tms = yes; then
1189   AC_DEFINE(HAVE_STRUCT_TMS, 1,
1190   [Define if <sys/times.h> defines struct tms.])
1191 fi
1192
1193 # use gcc_cv_* here because this doesn't match the behavior of AC_CHECK_TYPE.
1194 # revisit after autoconf 2.50.
1195 AC_CACHE_CHECK(for clock_t, gcc_cv_type_clock_t, [
1196 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1197 #include "ansidecl.h"
1198 #include "system.h"
1199 ]], [[clock_t x;]])],[gcc_cv_type_clock_t=yes],[gcc_cv_type_clock_t=no])])
1200 if test $gcc_cv_type_clock_t = yes; then
1201   AC_DEFINE(HAVE_CLOCK_T, 1,
1202   [Define if <time.h> defines clock_t.])
1203 fi
1204
1205 # Restore CFLAGS from before the gcc_AC_NEED_DECLARATIONS tests.
1206 CFLAGS="$saved_CFLAGS"
1207
1208 gcc_AC_INITFINI_ARRAY
1209
1210 # mkdir takes a single argument on some systems.
1211 gcc_AC_FUNC_MKDIR_TAKES_ONE_ARG
1212
1213 # File extensions
1214 manext='.1'
1215 objext='.o'
1216 AC_SUBST(manext)
1217 AC_SUBST(objext)
1218
1219 # With Setjmp/Longjmp based exception handling.
1220 AC_ARG_ENABLE(sjlj-exceptions,
1221 [  --enable-sjlj-exceptions
1222                           arrange to use setjmp/longjmp exception handling],
1223 [sjlj=`if test $enableval = yes; then echo 1; else echo 0; fi`
1224 AC_DEFINE_UNQUOTED(CONFIG_SJLJ_EXCEPTIONS, $sjlj,
1225   [Define 0/1 to force the choice for exception handling model.])])
1226
1227 # For platforms with the unwind ABI which includes an unwind library,
1228 # libunwind, we can choose to use the system libunwind.
1229 AC_ARG_WITH(system-libunwind,
1230 [  --with-system-libunwind use installed libunwind])
1231
1232 # --------------------------------------------------------
1233 # Build, host, and target specific configuration fragments
1234 # --------------------------------------------------------
1235
1236 # Collect build-machine-specific information.
1237 . ${srcdir}/config.build
1238
1239 # Collect host-machine-specific information.
1240 . ${srcdir}/config.host
1241
1242 target_gtfiles=
1243
1244 # Collect target-machine-specific information.
1245 . ${srcdir}/config.gcc
1246
1247 extra_objs="${host_extra_objs} ${extra_objs}"
1248 extra_gcc_objs="${host_extra_gcc_objs} ${extra_gcc_objs}"
1249
1250 # Default the target-machine variables that were not explicitly set.
1251 if test x"$tm_file" = x
1252 then tm_file=$cpu_type/$cpu_type.h; fi
1253
1254 if test x"$extra_headers" = x
1255 then extra_headers=; fi
1256
1257 if test x$md_file = x
1258 then md_file=$cpu_type/$cpu_type.md; fi
1259
1260 if test x$out_file = x
1261 then out_file=$cpu_type/$cpu_type.c; fi
1262
1263 if test x"$tmake_file" = x
1264 then tmake_file=$cpu_type/t-$cpu_type
1265 fi
1266
1267 if test x"$dwarf2" = xyes
1268 then tm_file="$tm_file tm-dwarf2.h"
1269 fi
1270
1271 # Say what files are being used for the output code and MD file.
1272 echo "Using \`$srcdir/config/$out_file' for machine-specific logic."
1273 echo "Using \`$srcdir/config/$md_file' as machine description file."
1274
1275 # If any of the xm_file variables contain nonexistent files, warn
1276 # about them and drop them.
1277
1278 bx=
1279 for x in $build_xm_file; do
1280   if    test -f $srcdir/config/$x
1281   then      bx="$bx $x"
1282   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1283   fi
1284 done
1285 build_xm_file="$bx"
1286
1287 hx=
1288 for x in $host_xm_file; do
1289   if    test -f $srcdir/config/$x
1290   then      hx="$hx $x"
1291   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1292   fi
1293 done
1294 host_xm_file="$hx"
1295
1296 tx=
1297 for x in $xm_file; do
1298   if    test -f $srcdir/config/$x
1299   then      tx="$tx $x"
1300   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1301   fi
1302 done
1303 xm_file="$tx"
1304
1305 count=a
1306 for f in $tm_file; do
1307         count=${count}x
1308 done
1309 if test $count = ax; then
1310         echo "Using \`$srcdir/config/$tm_file' as target machine macro file."
1311 else
1312         echo "Using the following target machine macro files:"
1313         for f in $tm_file; do
1314                 echo "  $srcdir/config/$f"
1315         done
1316 fi
1317
1318 if test x$need_64bit_hwint = xyes; then
1319         AC_DEFINE(NEED_64BIT_HOST_WIDE_INT, 1,
1320 [Define to 1 if HOST_WIDE_INT must be 64 bits wide (see hwint.h).])
1321 fi
1322
1323 if test x$use_long_long_for_widest_fast_int = xyes; then
1324         AC_DEFINE(USE_LONG_LONG_FOR_WIDEST_FAST_INT, 1,
1325 [Define to 1 if the 'long long' (or '__int64') is wider than 'long' but still
1326 efficiently supported by the host hardware.])
1327 fi
1328
1329 count=a
1330 for f in $host_xm_file; do
1331         count=${count}x
1332 done
1333 if test $count = a; then
1334         :
1335 elif test $count = ax; then
1336         echo "Using \`$srcdir/config/$host_xm_file' as host machine macro file."
1337 else
1338         echo "Using the following host machine macro files:"
1339         for f in $host_xm_file; do
1340                 echo "  $srcdir/config/$f"
1341         done
1342 fi
1343 echo "Using ${out_host_hook_obj} for host machine hooks."
1344
1345 if test "$host_xm_file" != "$build_xm_file"; then
1346         count=a
1347         for f in $build_xm_file; do
1348                 count=${count}x
1349         done
1350         if test $count = a; then
1351                 :
1352         elif test $count = ax; then
1353                 echo "Using \`$srcdir/config/$build_xm_file' as build machine macro file."
1354         else
1355                 echo "Using the following build machine macro files:"
1356                 for f in $build_xm_file; do
1357                         echo "  $srcdir/config/$f"
1358                 done
1359         fi
1360 fi
1361
1362 case ${host} in
1363   powerpc-*-darwin*)
1364     AC_CACHE_CHECK([whether mcontext_t fields have underscores],
1365       gcc_cv_mcontext_underscores,
1366       AC_COMPILE_IFELSE([
1367 #include <sys/signal.h>
1368 #include <ucontext.h>
1369 int main() { mcontext_t m; if (m->ss.srr0) return 0; return 0; }
1370 ],
1371         gcc_cv_mcontext_underscores=no, gcc_cv_mcontext_underscores=yes))
1372       if test $gcc_cv_mcontext_underscores = yes; then
1373         AC_DEFINE(HAS_MCONTEXT_T_UNDERSCORES,,dnl
1374           [mcontext_t fields start with __])
1375       fi
1376     ;;
1377 esac
1378
1379 # ---------
1380 # Threading
1381 # ---------
1382
1383 # Check if a valid thread package
1384 case ${enable_threads} in
1385   "" | no)
1386     # No threads
1387     target_thread_file='single'
1388     ;;
1389   yes)
1390     # default
1391     target_thread_file='single'
1392     ;;
1393   aix | dce | gnat | irix | posix | posix95 | rtems | \
1394   single | solaris | vxworks | win32 )
1395     target_thread_file=${enable_threads}
1396     ;;
1397   *)
1398     echo "${enable_threads} is an unknown thread package" 1>&2
1399     exit 1
1400     ;;
1401 esac
1402
1403 if test x${thread_file} = x; then
1404   # No thread file set by target-specific clauses in config.gcc,
1405   # so use file chosen by default logic above
1406   thread_file=${target_thread_file}
1407 fi
1408
1409 # Make gthr-default.h if we have a thread file.
1410 gthread_flags=
1411 if test $thread_file != single; then
1412   rm -f gthr-default.h
1413   echo "#include \"gthr-${thread_file}.h\"" > gthr-default.h
1414   gthread_flags=-DHAVE_GTHR_DEFAULT
1415 fi
1416 AC_SUBST(gthread_flags)
1417
1418 # --------
1419 # UNSORTED
1420 # --------
1421
1422 use_cxa_atexit=no
1423 if test x$enable___cxa_atexit = xyes || \
1424    test x$enable___cxa_atexit = x -a x$default_use_cxa_atexit = xyes; then
1425   if test x$host = x$target; then
1426     AC_CHECK_FUNC(__cxa_atexit,[use_cxa_atexit=yes],
1427         [echo "__cxa_atexit can't be enabled on this target"])
1428   else
1429     # We can't check for __cxa_atexit when building a cross, so assume
1430     # it is available
1431     use_cxa_atexit=yes
1432   fi
1433   if test x$use_cxa_atexit = xyes; then
1434     AC_DEFINE(DEFAULT_USE_CXA_ATEXIT, 2,
1435       [Define if you want to use __cxa_atexit, rather than atexit, to
1436       register C++ destructors for local statics and global objects.
1437       This is essential for fully standards-compliant handling of
1438       destructors, but requires __cxa_atexit in libc.])
1439   fi
1440 fi
1441
1442 # Look for a file containing extra machine modes.
1443 if test -n "$extra_modes" && test -f $srcdir/config/$extra_modes; then
1444   extra_modes_file='$(srcdir)'/config/${extra_modes}
1445   AC_SUBST(extra_modes_file)
1446   AC_DEFINE_UNQUOTED(EXTRA_MODES_FILE, "config/$extra_modes",
1447   [Define to the name of a file containing a list of extra machine modes
1448    for this architecture.])
1449 fi
1450
1451 # Convert extra_options into a form suitable for Makefile use.
1452 extra_opt_files=
1453 for f in $extra_options; do
1454   extra_opt_files="$extra_opt_files \$(srcdir)/config/$f"
1455 done
1456 AC_SUBST(extra_opt_files)
1457
1458 # auto-host.h is the file containing items generated by autoconf and is
1459 # the first file included by config.h.
1460 # If host=build, it is correct to have bconfig include auto-host.h
1461 # as well.  If host!=build, we are in error and need to do more
1462 # work to find out the build config parameters.
1463 if test x$host = x$build
1464 then
1465         build_auto=auto-host.h
1466 else
1467         # We create a subdir, then run autoconf in the subdir.
1468         # To prevent recursion we set host and build for the new
1469         # invocation of configure to the build for this invocation
1470         # of configure.
1471         tempdir=build.$$
1472         rm -rf $tempdir
1473         mkdir $tempdir
1474         cd $tempdir
1475         case ${srcdir} in
1476         /* | [A-Za-z]:[\\/]* ) realsrcdir=${srcdir};;
1477         *) realsrcdir=../${srcdir};;
1478         esac
1479         saved_CFLAGS="${CFLAGS}"
1480         CC="${CC_FOR_BUILD}" CFLAGS="${CFLAGS_FOR_BUILD}" \
1481         ${realsrcdir}/configure \
1482                 --enable-languages=${enable_languages-all} \
1483                 --target=$target_alias --host=$build_alias --build=$build_alias
1484         CFLAGS="${saved_CFLAGS}"
1485
1486         # We just finished tests for the build machine, so rename
1487         # the file auto-build.h in the gcc directory.
1488         mv auto-host.h ../auto-build.h
1489         cd ..
1490         rm -rf $tempdir
1491         build_auto=auto-build.h
1492 fi
1493 AC_SUBST(build_subdir)
1494
1495 tm_file="${tm_file} defaults.h"
1496 tm_p_file="${tm_p_file} tm-preds.h"
1497 host_xm_file="auto-host.h ansidecl.h ${host_xm_file}"
1498 build_xm_file="${build_auto} ansidecl.h ${build_xm_file}"
1499 # We don't want ansidecl.h in target files, write code there in ISO/GNU C.
1500 # put this back in temporarily.
1501 xm_file="auto-host.h ansidecl.h ${xm_file}"
1502
1503 # --------
1504 # UNSORTED
1505 # --------
1506
1507 changequote(,)dnl
1508 # Compile in configure arguments.
1509 if test -f configargs.h ; then
1510         # Being re-configured.
1511         gcc_config_arguments=`grep configuration_arguments configargs.h | sed -e 's/.*"\([^"]*\)".*/\1/'`
1512         gcc_config_arguments="$gcc_config_arguments : (reconfigured) $TOPLEVEL_CONFIGURE_ARGUMENTS"
1513 else
1514         gcc_config_arguments="$TOPLEVEL_CONFIGURE_ARGUMENTS"
1515 fi
1516
1517 # Double all backslashes and backslash all quotes to turn
1518 # gcc_config_arguments into a C string.
1519 sed -e 's/\\/\\\\/g; s/"/\\"/g' <<EOF >conftest.out
1520 $gcc_config_arguments
1521 EOF
1522 gcc_config_arguments_str=`cat conftest.out`
1523 rm -f conftest.out
1524
1525 cat > configargs.h <<EOF
1526 /* Generated automatically. */
1527 static const char configuration_arguments[] = "$gcc_config_arguments_str";
1528 static const char thread_model[] = "$thread_file";
1529
1530 static const struct {
1531   const char *name, *value;
1532 } configure_default_options[] = $configure_default_options;
1533 EOF
1534 changequote([,])dnl
1535
1536 # Internationalization
1537 ZW_GNU_GETTEXT_SISTER_DIR
1538
1539 # If LIBINTL contains LIBICONV, then clear LIBICONV so we don't get
1540 # -liconv on the link line twice.
1541 case "$LIBINTL" in *$LIBICONV*)
1542         LIBICONV= ;;
1543 esac
1544
1545 AC_ARG_ENABLE(secureplt,
1546 [  --enable-secureplt      enable -msecure-plt by default for PowerPC],
1547 [], [])
1548
1549 # Windows32 Registry support for specifying GCC installation paths.
1550 AC_ARG_ENABLE(win32-registry,
1551 [  --disable-win32-registry
1552                           disable lookup of installation paths in the
1553                           Registry on Windows hosts
1554   --enable-win32-registry enable registry lookup (default)
1555   --enable-win32-registry=KEY
1556                           use KEY instead of GCC version as the last portion
1557                           of the registry key],,)
1558
1559 case $host_os in
1560   win32 | pe | cygwin* | mingw32* | uwin*)
1561     if test "x$enable_win32_registry" != xno; then
1562       AC_SEARCH_LIBS(RegOpenKeyExA, advapi32,, [enable_win32_registry=no])
1563     fi
1564
1565     if test "x$enable_win32_registry" != xno; then
1566       AC_DEFINE(ENABLE_WIN32_REGISTRY, 1,
1567   [Define to 1 if installation paths should be looked up in the Windows
1568    Registry. Ignored on non-Windows hosts.])
1569
1570       if test "x$enable_win32_registry" != xyes \
1571          && test "x$enable_win32_registry" != x; then
1572         AC_DEFINE_UNQUOTED(WIN32_REGISTRY_KEY, "$enable_win32_registry",
1573   [Define to be the last component of the Windows registry key under which
1574    to look for installation paths.  The full key used will be
1575    HKEY_LOCAL_MACHINE/SOFTWARE/Free Software Foundation/{WIN32_REGISTRY_KEY}.
1576    The default is the GCC version number.])
1577       fi
1578     fi
1579   ;;
1580 esac
1581
1582 # Get an absolute path to the GCC top-level source directory
1583 holddir=`${PWDCMD-pwd}`
1584 cd $srcdir
1585 topdir=`${PWDCMD-pwd}`
1586 cd $holddir
1587
1588 # Conditionalize the makefile for this host machine.
1589 xmake_file=
1590 for f in ${host_xmake_file}
1591 do
1592         if test -f ${srcdir}/config/$f
1593         then
1594                 xmake_file="${xmake_file} \$(srcdir)/config/$f"
1595         fi
1596 done
1597
1598 # Conditionalize the makefile for this target machine.
1599 tmake_file_=
1600 for f in ${tmake_file}
1601 do
1602         if test -f ${srcdir}/config/$f
1603         then
1604                 tmake_file_="${tmake_file_} \$(srcdir)/config/$f"
1605         fi
1606 done
1607 tmake_file="${tmake_file_}"
1608
1609 # If the host doesn't support symlinks, modify CC in
1610 # FLAGS_TO_PASS so CC="stage1/xgcc -Bstage1/" works.
1611 # Otherwise, we can use "CC=$(CC)".
1612 rm -f symtest.tem
1613 case "$LN_S" in
1614         *-s*)
1615                 cc_set_by_configure="\$(CC)"
1616                 quoted_cc_set_by_configure="\$(CC)"
1617                 stage_prefix_set_by_configure="\$(STAGE_PREFIX)"
1618                 quoted_stage_prefix_set_by_configure="\$(STAGE_PREFIX)"
1619                 ;;
1620         *)
1621                 cc_set_by_configure="\`case '\$(CC)' in stage*) echo '\$(CC)' | sed -e 's|stage|../stage|g';; *) echo '\$(CC)';; esac\`"
1622                 quoted_cc_set_by_configure="\\\`case '\\\$(CC)' in stage*) echo '\\\$(CC)' | sed -e 's|stage|../stage|g';; *) echo '\\\$(CC)';; esac\\\`"
1623                 stage_prefix_set_by_configure="\`case '\$(STAGE_PREFIX)' in stage*) echo '\$(STAGE_PREFIX)' | sed -e 's|stage|../stage|g';; *) echo '\$(STAGE_PREFIX)';; esac\`"
1624                 quoted_stage_prefix_set_by_configure="\\\`case '\\\$(STAGE_PREFIX)' in stage*) echo '\\\$(STAGE_PREFIX)' | sed -e 's|stage|../stage|g';; *) echo '\\\$(STAGE_PREFIX)';; esac\\\`"
1625                 ;;
1626 esac
1627
1628 # This is a terrible hack which will go away some day.
1629 host_cc_for_libada=${CC}
1630 AC_SUBST(host_cc_for_libada)
1631
1632 out_object_file=`basename $out_file .c`.o
1633
1634 tm_file_list="options.h"
1635 tm_include_list="options.h"
1636 for f in $tm_file; do
1637   case $f in
1638     defaults.h )
1639        tm_file_list="${tm_file_list} \$(srcdir)/$f"
1640        tm_include_list="${tm_include_list} $f"
1641        ;;
1642     * )
1643        tm_file_list="${tm_file_list} \$(srcdir)/config/$f"
1644        tm_include_list="${tm_include_list} config/$f"
1645        ;;
1646   esac
1647 done
1648
1649 tm_p_file_list=
1650 tm_p_include_list=
1651 for f in $tm_p_file; do
1652   case $f in
1653     tm-preds.h )
1654        tm_p_file_list="${tm_p_file_list} $f"
1655        tm_p_include_list="${tm_p_include_list} $f"
1656        ;;
1657     * )
1658        tm_p_file_list="${tm_p_file_list} \$(srcdir)/config/$f"
1659        tm_p_include_list="${tm_p_include_list} config/$f"
1660   esac
1661 done
1662
1663 xm_file_list=
1664 xm_include_list=
1665 for f in $xm_file; do
1666   case $f in
1667     ansidecl.h )
1668        xm_file_list="${xm_file_list} \$(srcdir)/../include/$f"
1669        xm_include_list="${xm_include_list} $f"
1670        ;;
1671     auto-host.h )
1672        xm_file_list="${xm_file_list} $f"
1673        xm_include_list="${xm_include_list} $f"
1674        ;;
1675     * )
1676        xm_file_list="${xm_file_list} \$(srcdir)/config/$f"
1677        xm_include_list="${xm_include_list} config/$f"
1678        ;;
1679   esac
1680 done
1681
1682 host_xm_file_list=
1683 host_xm_include_list=
1684 for f in $host_xm_file; do
1685   case $f in
1686     ansidecl.h )
1687        host_xm_file_list="${host_xm_file_list} \$(srcdir)/../include/$f"
1688        host_xm_include_list="${host_xm_include_list} $f"
1689        ;;
1690     auto-host.h )
1691        host_xm_file_list="${host_xm_file_list} $f"
1692        host_xm_include_list="${host_xm_include_list} $f"
1693        ;;
1694     * )
1695        host_xm_file_list="${host_xm_file_list} \$(srcdir)/config/$f"
1696        host_xm_include_list="${host_xm_include_list} config/$f"
1697        ;;
1698   esac
1699 done
1700
1701 build_xm_file_list=
1702 for f in $build_xm_file; do
1703   case $f in
1704     ansidecl.h )
1705        build_xm_file_list="${build_xm_file_list} \$(srcdir)/../include/$f"
1706        build_xm_include_list="${build_xm_include_list} $f"
1707        ;;
1708     auto-build.h | auto-host.h )
1709        build_xm_file_list="${build_xm_file_list} $f"
1710        build_xm_include_list="${build_xm_include_list} $f"
1711        ;;
1712     * )
1713        build_xm_file_list="${build_xm_file_list} \$(srcdir)/config/$f"
1714        build_xm_include_list="${build_xm_include_list} config/$f"
1715        ;;
1716   esac
1717 done
1718
1719 # Define macro CROSS_COMPILE in compilation if this is a cross-compiler.
1720 # Also use all.cross instead of all.internal and adjust SYSTEM_HEADER_DIR.
1721 CROSS=                                          AC_SUBST(CROSS)
1722 ALL=all.internal                                AC_SUBST(ALL)
1723 SYSTEM_HEADER_DIR='$(NATIVE_SYSTEM_HEADER_DIR)' AC_SUBST(SYSTEM_HEADER_DIR)
1724
1725 if test "x$with_build_sysroot" != x; then
1726   build_system_header_dir=$with_build_sysroot'$(NATIVE_SYSTEM_HEADER_DIR)'
1727 else
1728   # This value is used, even on a native system, because
1729   # CROSS_SYSTEM_HEADER_DIR is just
1730   # $(TARGET_SYSTEM_ROOT)$(NATIVE_SYSTEM_HEADER_DIR).
1731   build_system_header_dir='$(CROSS_SYSTEM_HEADER_DIR)'
1732 fi
1733
1734 if test x$host != x$target
1735 then
1736         CROSS="-DCROSS_COMPILE"
1737         ALL=all.cross
1738         SYSTEM_HEADER_DIR=$build_system_header_dir
1739         case "$host","$target" in
1740         # Darwin crosses can use the host system's libraries and headers,
1741         # because of the fat library support.  Of course, it must be the
1742         # same version of Darwin on both sides.  Allow the user to
1743         # just say --target=foo-darwin without a version number to mean
1744         # "the version on this system".
1745             *-*-darwin*,*-*-darwin*)
1746                 hostos=`echo $host | sed 's/.*-darwin/darwin/'`
1747                 targetos=`echo $target | sed 's/.*-darwin/darwin/'`
1748                 if test $hostos = $targetos -o $targetos = darwin ; then
1749                     CROSS=
1750                     SYSTEM_HEADER_DIR='$(NATIVE_SYSTEM_HEADER_DIR)'
1751                     with_headers=yes
1752                 fi
1753                 ;;
1754
1755             i?86-*-*,x86_64-*-* \
1756             | powerpc*-*-*,powerpc64*-*-*)
1757                 CROSS="$CROSS -DNATIVE_CROSS" ;;
1758         esac
1759 elif test "x$TARGET_SYSTEM_ROOT" != x; then
1760         SYSTEM_HEADER_DIR=$build_system_header_dir
1761 fi
1762
1763 # If this is a cross-compiler that does not
1764 # have its own set of headers then define
1765 # inhibit_libc
1766
1767 # If this is using newlib, without having the headers available now,
1768 # then define inhibit_libc in LIBGCC2_CFLAGS.
1769 # This prevents libgcc2 from containing any code which requires libc
1770 # support.
1771 inhibit_libc=false
1772 if { { test x$host != x$target && test "x$with_sysroot" = x ; } ||
1773        test x$with_newlib = xyes ; } &&
1774      { test "x$with_headers" = x || test "x$with_headers" = xno ; } ; then
1775        inhibit_libc=true
1776 fi
1777 AC_SUBST(inhibit_libc)
1778
1779 # When building gcc with a cross-compiler, we need to adjust things so
1780 # that the generator programs are still built with the native compiler.
1781 # Also, we cannot run fixincludes or fix-header.
1782
1783 # These are the normal (build=host) settings:
1784 CC_FOR_BUILD='$(CC)'            AC_SUBST(CC_FOR_BUILD)
1785 BUILD_CFLAGS='$(ALL_CFLAGS)'    AC_SUBST(BUILD_CFLAGS)
1786 STMP_FIXINC=stmp-fixinc         AC_SUBST(STMP_FIXINC)
1787
1788 # Possibly disable fixproto, on a per-target basis.
1789 case ${use_fixproto} in
1790   no)
1791     STMP_FIXPROTO=
1792     ;;
1793   yes)
1794     STMP_FIXPROTO=stmp-fixproto
1795     ;;
1796 esac
1797 AC_SUBST(STMP_FIXPROTO)
1798
1799 # And these apply if build != host, or we are generating coverage data
1800 if test x$build != x$host || test "x$coverage_flags" != x
1801 then
1802     BUILD_CFLAGS='$(INTERNAL_CFLAGS) $(T_CFLAGS) $(CFLAGS_FOR_BUILD)'
1803
1804     if test "x$TARGET_SYSTEM_ROOT" = x; then
1805         if test "x$STMP_FIXPROTO" != x; then
1806           STMP_FIXPROTO=stmp-install-fixproto
1807         fi
1808     fi
1809 fi
1810
1811 # Expand extra_headers to include complete path.
1812 # This substitutes for lots of t-* files.
1813 extra_headers_list=
1814 # Prepend $(srcdir)/config/${cpu_type}/ to every entry in extra_headers.
1815 for file in ${extra_headers} ; do
1816   extra_headers_list="${extra_headers_list} \$(srcdir)/config/${cpu_type}/${file}"
1817 done
1818
1819 # Define collect2 in Makefile.
1820 case $host_can_use_collect2 in
1821   no) collect2= ;;
1822   *) collect2='collect2$(exeext)' ;;
1823 esac
1824 AC_SUBST([collect2])
1825
1826 # Add a definition of USE_COLLECT2 if system wants one.
1827 case $use_collect2 in
1828   no) use_collect2= ;;
1829   "") ;;
1830   *)
1831     host_xm_defines="${host_xm_defines} USE_COLLECT2"
1832     xm_defines="${xm_defines} USE_COLLECT2"
1833     case $host_can_use_collect2 in
1834       no)
1835         AC_MSG_ERROR([collect2 is required but cannot be built on this system])
1836         ;;
1837     esac
1838     ;;
1839 esac
1840
1841 # ---------------------------
1842 # Assembler & linker features
1843 # ---------------------------
1844
1845 # Identify the assembler which will work hand-in-glove with the newly
1846 # built GCC, so that we can examine its features.  This is the assembler
1847 # which will be driven by the driver program.
1848 #
1849 # If build != host, and we aren't building gas in-tree, we identify a
1850 # build->target assembler and hope that it will have the same features
1851 # as the host->target assembler we'll be using.
1852 gcc_cv_gas_major_version=
1853 gcc_cv_gas_minor_version=
1854 gcc_cv_as_gas_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/gas
1855
1856 m4_pattern_allow([AS_FOR_TARGET])dnl
1857 AS_VAR_SET_IF(gcc_cv_as,, [
1858 if test -x "$DEFAULT_ASSEMBLER"; then
1859         gcc_cv_as="$DEFAULT_ASSEMBLER"
1860 elif test -f $gcc_cv_as_gas_srcdir/configure.in \
1861      && test -f ../gas/Makefile \
1862      && test x$build = x$host; then
1863         gcc_cv_as=../gas/as-new$build_exeext
1864 elif test -x as$build_exeext; then
1865         # Build using assembler in the current directory.
1866         gcc_cv_as=./as$build_exeext
1867 elif test -x $AS_FOR_TARGET; then
1868         gcc_cv_as="$AS_FOR_TARGET"
1869 else
1870         AC_PATH_PROG(gcc_cv_as, $AS_FOR_TARGET)
1871 fi])
1872
1873 ORIGINAL_AS_FOR_TARGET=$gcc_cv_as
1874 AC_SUBST(ORIGINAL_AS_FOR_TARGET)
1875
1876 AC_MSG_CHECKING(what assembler to use)
1877 if test "$gcc_cv_as" = ../gas/as-new$build_exeext; then
1878   # Single tree build which includes gas.  We want to prefer it
1879   # over whatever linker top-level may have detected, since
1880   # we'll use what we're building after installation anyway.
1881   AC_MSG_RESULT(newly built gas)
1882   in_tree_gas=yes
1883   _gcc_COMPUTE_GAS_VERSION
1884   in_tree_gas_is_elf=no
1885   if grep 'obj_format = elf' ../gas/Makefile > /dev/null \
1886      || (grep 'obj_format = multi' ../gas/Makefile \
1887          && grep 'extra_objects =.* obj-elf' ../gas/Makefile) > /dev/null
1888   then
1889     in_tree_gas_is_elf=yes
1890   fi
1891 else
1892   AC_MSG_RESULT($gcc_cv_as)
1893   in_tree_gas=no
1894 fi
1895
1896 # Identify the linker which will work hand-in-glove with the newly
1897 # built GCC, so that we can examine its features.  This is the linker
1898 # which will be driven by the driver program.
1899 #
1900 # If build != host, and we aren't building gas in-tree, we identify a
1901 # build->target linker and hope that it will have the same features
1902 # as the host->target linker we'll be using.
1903 gcc_cv_gld_major_version=
1904 gcc_cv_gld_minor_version=
1905 gcc_cv_ld_gld_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/ld
1906 gcc_cv_ld_bfd_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/bfd
1907
1908 AS_VAR_SET_IF(gcc_cv_ld,, [
1909 if test -x "$DEFAULT_LINKER"; then
1910         gcc_cv_ld="$DEFAULT_LINKER"
1911 elif test -f $gcc_cv_ld_gld_srcdir/configure.in \
1912      && test -f ../ld/Makefile \
1913      && test x$build = x$host; then
1914         gcc_cv_ld=../ld/ld-new$build_exeext
1915 elif test -x collect-ld$build_exeext; then
1916         # Build using linker in the current directory.
1917         gcc_cv_ld=./collect-ld$build_exeext
1918 elif test -x $LD_FOR_TARGET; then
1919         gcc_cv_ld="$LD_FOR_TARGET"
1920 else
1921         AC_PATH_PROG(gcc_cv_ld, $LD_FOR_TARGET)
1922 fi])
1923
1924 ORIGINAL_LD_FOR_TARGET=$gcc_cv_ld
1925 AC_SUBST(ORIGINAL_LD_FOR_TARGET)
1926
1927 AC_MSG_CHECKING(what linker to use)
1928 if test "$gcc_cv_ld" = ../ld/ld-new$build_exeext; then
1929         # Single tree build which includes ld.  We want to prefer it
1930         # over whatever linker top-level may have detected, since
1931         # we'll use what we're building after installation anyway.
1932         AC_MSG_RESULT(newly built ld)
1933         in_tree_ld=yes
1934         in_tree_ld_is_elf=no
1935         if (grep 'EMUL = .*elf' ../ld/Makefile \
1936             || grep 'EMUL = .*linux' ../ld/Makefile \
1937             || grep 'EMUL = .*lynx' ../ld/Makefile) > /dev/null; then
1938           in_tree_ld_is_elf=yes
1939         fi
1940         for f in $gcc_cv_ld_bfd_srcdir/configure $gcc_cv_ld_gld_srcdir/configure $gcc_cv_ld_gld_srcdir/configure.in $gcc_cv_ld_gld_srcdir/Makefile.in
1941         do
1942 changequote(,)dnl
1943                 gcc_cv_gld_version=`sed -n -e 's/^[     ]*\(VERSION=[0-9]*\.[0-9]*.*\)/\1/p' < $f`
1944                 if test x$gcc_cv_gld_version != x; then
1945                         break
1946                 fi
1947         done
1948         gcc_cv_gld_major_version=`expr "$gcc_cv_gld_version" : "VERSION=\([0-9]*\)"`
1949         gcc_cv_gld_minor_version=`expr "$gcc_cv_gld_version" : "VERSION=[0-9]*\.\([0-9]*\)"`
1950 changequote([,])dnl
1951 else
1952         AC_MSG_RESULT($gcc_cv_ld)
1953         in_tree_ld=no
1954 fi
1955
1956 # Figure out what nm we will be using.
1957 gcc_cv_binutils_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/binutils
1958 AS_VAR_SET_IF(gcc_cv_nm,, [
1959 if test -f $gcc_cv_binutils_srcdir/configure.in \
1960      && test -f ../binutils/Makefile \
1961      && test x$build = x$host; then
1962         gcc_cv_nm=../binutils/nm-new$build_exeext
1963 elif test -x nm$build_exeext; then
1964         gcc_cv_nm=./nm$build_exeext
1965 elif test -x $NM_FOR_TARGET; then
1966         gcc_cv_nm="$NM_FOR_TARGET"
1967 else
1968         AC_PATH_PROG(gcc_cv_nm, $NM_FOR_TARGET)
1969 fi])
1970
1971 AC_MSG_CHECKING(what nm to use)
1972 if test "$gcc_cv_nm" = ../binutils/nm-new$build_exeext; then
1973         # Single tree build which includes binutils.
1974         AC_MSG_RESULT(newly built nm)
1975         in_tree_nm=yes
1976 else
1977         AC_MSG_RESULT($gcc_cv_nm)
1978         in_tree_nm=no
1979 fi
1980
1981 ORIGINAL_NM_FOR_TARGET=$gcc_cv_nm
1982 AC_SUBST(ORIGINAL_NM_FOR_TARGET)
1983
1984 # Figure out what objdump we will be using.
1985 AS_VAR_SET_IF(gcc_cv_objdump,, [
1986 if test -f $gcc_cv_binutils_srcdir/configure.in \
1987      && test -f ../binutils/Makefile \
1988      && test x$build = x$host; then
1989         # Single tree build which includes binutils.
1990         gcc_cv_objdump=../binutils/objdump$build_exeext
1991 elif test -x objdump$build_exeext; then
1992         gcc_cv_objdump=./objdump$build_exeext
1993 elif test -x $OBJDUMP_FOR_TARGET; then
1994         gcc_cv_objdump="$OBJDUMP_FOR_TARGET"
1995 else
1996         AC_PATH_PROG(gcc_cv_objdump, $OBJDUMP_FOR_TARGET)
1997 fi])
1998
1999 AC_MSG_CHECKING(what objdump to use)
2000 if test "$gcc_cv_objdump" = ../binutils/objdump$build_exeext; then
2001         # Single tree build which includes binutils.
2002         AC_MSG_RESULT(newly built objdump)
2003 elif test x$gcc_cv_objdump = x; then
2004         AC_MSG_RESULT(not found)
2005 else
2006         AC_MSG_RESULT($gcc_cv_objdump)
2007 fi
2008
2009 # Figure out what assembler alignment features are present.
2010 gcc_GAS_CHECK_FEATURE([.balign and .p2align], gcc_cv_as_balign_and_p2align,
2011  [2,6,0],,
2012 [.balign 4
2013 .p2align 2],,
2014 [AC_DEFINE(HAVE_GAS_BALIGN_AND_P2ALIGN, 1,
2015   [Define if your assembler supports .balign and .p2align.])])
2016
2017 gcc_GAS_CHECK_FEATURE([.p2align with maximum skip], gcc_cv_as_max_skip_p2align,
2018  [2,8,0],,
2019  [.p2align 4,,7],,
2020 [AC_DEFINE(HAVE_GAS_MAX_SKIP_P2ALIGN, 1,
2021   [Define if your assembler supports specifying the maximum number
2022    of bytes to skip when using the GAS .p2align command.])])
2023
2024 gcc_GAS_CHECK_FEATURE([working .subsection -1], gcc_cv_as_subsection_m1,
2025  [elf,2,9,0],,
2026  [conftest_label1: .word 0
2027 .subsection -1
2028 conftest_label2: .word 0
2029 .previous],
2030  [if test x$gcc_cv_nm != x; then
2031     $gcc_cv_nm conftest.o | grep conftest_label1 > conftest.nm1
2032     $gcc_cv_nm conftest.o | grep conftest_label2 | sed -e 's/label2/label1/' > conftest.nm2
2033     if cmp conftest.nm1 conftest.nm2 > /dev/null 2>&1
2034     then :
2035     else gcc_cv_as_subsection_m1=yes
2036     fi
2037     rm -f conftest.nm1 conftest.nm2
2038   fi],
2039  [AC_DEFINE(HAVE_GAS_SUBSECTION_ORDERING, 1,
2040   [Define if your assembler supports .subsection and .subsection -1 starts
2041    emitting at the beginning of your section.])])
2042
2043 gcc_GAS_CHECK_FEATURE([.weak], gcc_cv_as_weak,
2044  [2,2,0],,
2045  [      .weak foobar],,
2046 [AC_DEFINE(HAVE_GAS_WEAK, 1, [Define if your assembler supports .weak.])])
2047
2048 gcc_GAS_CHECK_FEATURE([.weakref], gcc_cv_as_weakref,
2049  [2,17,0],,
2050  [      .weakref foobar, barfnot],,
2051 [AC_DEFINE(HAVE_GAS_WEAKREF, 1, [Define if your assembler supports .weakref.])])
2052
2053 gcc_GAS_CHECK_FEATURE([.nsubspa comdat], gcc_cv_as_nsubspa_comdat,
2054  [2,15,91],,
2055  [      .SPACE $TEXT$
2056         .NSUBSPA $CODE$,COMDAT],,
2057 [AC_DEFINE(HAVE_GAS_NSUBSPA_COMDAT, 1, [Define if your assembler supports .nsubspa comdat option.])])
2058
2059 # .hidden needs to be supported in both the assembler and the linker,
2060 # because GNU LD versions before 2.12.1 have buggy support for STV_HIDDEN.
2061 # This is irritatingly difficult to feature test for; we have to check the
2062 # date string after the version number.  If we've got an in-tree
2063 # ld, we don't know its patchlevel version, so we set the baseline at 2.13
2064 # to be safe.
2065 # The gcc_GAS_CHECK_FEATURE call just sets a cache variable.
2066 gcc_GAS_CHECK_FEATURE([.hidden], gcc_cv_as_hidden,
2067  [elf,2,13,0],,
2068 [       .hidden foobar
2069 foobar:])
2070
2071 AC_CACHE_CHECK(linker for .hidden support, gcc_cv_ld_hidden,
2072 [if test $in_tree_ld = yes ; then
2073   gcc_cv_ld_hidden=no
2074   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 13 -o "$gcc_cv_gld_major_version" -gt 2 \
2075      && test $in_tree_ld_is_elf = yes; then
2076      gcc_cv_ld_hidden=yes
2077   fi
2078 else
2079   gcc_cv_ld_hidden=yes
2080   ld_ver=`$gcc_cv_ld --version 2>/dev/null | sed 1q`
2081   if echo "$ld_ver" | grep GNU > /dev/null; then
2082 changequote(,)dnl
2083     ld_vers=`echo $ld_ver | sed -n \
2084         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\)$,\1,p' \
2085         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\)$,\1,p' \
2086         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\)$,\1,p' \
2087         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\)[  ].*$,\1,p' \
2088         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\)[     ].*$,\1,p' \
2089         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\)[       ].*$,\1,p' \
2090         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\)[   ].*$,\1,p'`
2091     ld_date=`echo $ld_ver | sed -n 's,^.*\([2-9][0-9][0-9][0-9]\)[-]*\([01][0-9]\)[-]*\([0-3][0-9]\).*$,\1\2\3,p'`
2092     ld_vers_major=`expr "$ld_vers" : '\([0-9]*\)'`
2093     ld_vers_minor=`expr "$ld_vers" : '[0-9]*\.\([0-9]*\)'`
2094     ld_vers_patch=`expr "$ld_vers" : '[0-9]*\.[0-9]*\.\([0-9]*\)'`
2095     if test 0"$ld_date" -lt 20020404; then
2096       if test -n "$ld_date"; then
2097         # If there was date string, but was earlier than 2002-04-04, fail
2098         gcc_cv_ld_hidden=no
2099       elif test -z "$ld_vers"; then
2100         # If there was no date string nor ld version number, something is wrong
2101         gcc_cv_ld_hidden=no
2102       else
2103         test -z "$ld_vers_patch" && ld_vers_patch=0
2104         if test "$ld_vers_major" -lt 2; then
2105           gcc_cv_ld_hidden=no
2106         elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -lt 12; then
2107           gcc_cv_ld_hidden="no"
2108         elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -eq 12 -a "$ld_vers_patch" -eq 0; then
2109           gcc_cv_ld_hidden=no
2110         fi
2111       fi
2112 changequote([,])dnl
2113     fi
2114   else
2115     case "${target}" in
2116       hppa64*-*-hpux* | ia64*-*-hpux*)
2117         gcc_cv_ld_hidden=yes
2118         ;;
2119       *)
2120         gcc_cv_ld_hidden=no
2121         ;;
2122     esac
2123   fi
2124 fi])
2125 libgcc_visibility=no
2126 AC_SUBST(libgcc_visibility)
2127 GCC_TARGET_TEMPLATE([HAVE_GAS_HIDDEN])
2128 if test $gcc_cv_as_hidden = yes && test $gcc_cv_ld_hidden = yes; then
2129   libgcc_visibility=yes
2130   AC_DEFINE(HAVE_GAS_HIDDEN, 1,
2131   [Define if your assembler and linker support .hidden.])
2132 fi
2133
2134 # Check if we have .[us]leb128, and support symbol arithmetic with it.
2135 gcc_GAS_CHECK_FEATURE([.sleb128 and .uleb128], gcc_cv_as_leb128,
2136   [elf,2,11,0],,
2137 [       .data
2138         .uleb128 L2 - L1
2139 L1:
2140         .uleb128 1280
2141         .sleb128 -1010
2142 L2:],
2143  [# GAS versions before 2.11 do not support uleb128,
2144   # despite appearing to.
2145   # ??? There exists an elf-specific test that will crash
2146   # the assembler.  Perhaps it's better to figure out whether
2147   # arbitrary sections are supported and try the test.
2148   as_ver=`$gcc_cv_as --version 2>/dev/null | sed 1q`
2149   if echo "$as_ver" | grep GNU > /dev/null; then
2150 changequote(,)dnl
2151     as_ver=`echo $as_ver | sed -e 's/GNU assembler \([0-9.][0-9.]*\).*/\1/'`
2152     as_major=`echo $as_ver | sed 's/\..*//'`
2153     as_minor=`echo $as_ver | sed 's/[^.]*\.\([0-9]*\).*/\1/'`
2154 changequote([,])dnl
2155     if test $as_major -eq 2 && test $as_minor -lt 11
2156     then :
2157     else gcc_cv_as_leb128=yes
2158     fi
2159   fi],
2160   [AC_DEFINE(HAVE_AS_LEB128, 1,
2161     [Define if your assembler supports .sleb128 and .uleb128.])])
2162
2163 # GAS versions up to and including 2.11.0 may mis-optimize
2164 # .eh_frame data.
2165 gcc_GAS_CHECK_FEATURE(eh_frame optimization, gcc_cv_as_eh_frame,
2166   [elf,2,12,0],,
2167 [       .text
2168 .LFB1:
2169         .4byte  0
2170 .L1:
2171         .4byte  0
2172 .LFE1:
2173         .section        .eh_frame,"aw",@progbits
2174 __FRAME_BEGIN__:
2175         .4byte  .LECIE1-.LSCIE1
2176 .LSCIE1:
2177         .4byte  0x0
2178         .byte   0x1
2179         .ascii "z\0"
2180         .byte   0x1
2181         .byte   0x78
2182         .byte   0x1a
2183         .byte   0x0
2184         .byte   0x4
2185         .4byte  1
2186         .p2align 1
2187 .LECIE1:
2188 .LSFDE1:
2189         .4byte  .LEFDE1-.LASFDE1
2190 .LASFDE1:
2191         .4byte  .LASFDE1-__FRAME_BEGIN__
2192         .4byte  .LFB1
2193         .4byte  .LFE1-.LFB1
2194         .byte   0x4
2195         .4byte  .LFE1-.LFB1
2196         .byte   0x4
2197         .4byte  .L1-.LFB1
2198 .LEFDE1:],
2199 [  dnl # For autoconf 2.5x, must protect trailing spaces with @&t@.
2200 cat > conftest.lit <<EOF
2201  0000 10000000 00000000 017a0001 781a0004  .........z..x...
2202  0010 01000000 12000000 18000000 00000000  ................
2203  0020 08000000 04080000 0044               .........D      @&t@
2204 EOF
2205 cat > conftest.big <<EOF
2206  0000 00000010 00000000 017a0001 781a0004  .........z..x...
2207  0010 00000001 00000012 00000018 00000000  ................
2208  0020 00000008 04000000 0844               .........D      @&t@
2209 EOF
2210   # If the assembler didn't choke, and we can objdump,
2211   # and we got the correct data, then succeed.
2212   if test x$gcc_cv_objdump != x \
2213   && $gcc_cv_objdump -s -j .eh_frame conftest.o 2>/dev/null \
2214      | tail -3 > conftest.got \
2215   && { cmp conftest.lit conftest.got > /dev/null 2>&1 \
2216     || cmp conftest.big conftest.got > /dev/null 2>&1; }
2217   then
2218     gcc_cv_as_eh_frame=yes
2219   elif AC_TRY_COMMAND($gcc_cv_as -o conftest.o --traditional-format /dev/null); then
2220     gcc_cv_as_eh_frame=buggy
2221   else
2222     # Uh oh, what do we do now?
2223     gcc_cv_as_eh_frame=no
2224   fi])
2225
2226 if test $gcc_cv_as_eh_frame = buggy; then
2227   AC_DEFINE(USE_AS_TRADITIONAL_FORMAT, 1,
2228   [Define if your assembler mis-optimizes .eh_frame data.])
2229 fi
2230
2231 gcc_GAS_CHECK_FEATURE(section merging support, gcc_cv_as_shf_merge,
2232  [elf,2,12,0], [--fatal-warnings],
2233  [.section .rodata.str, "aMS", @progbits, 1])
2234 if test $gcc_cv_as_shf_merge = no; then
2235   gcc_GAS_CHECK_FEATURE(section merging support, gcc_cv_as_shf_merge,
2236     [elf,2,12,0], [--fatal-warnings],
2237     [.section .rodata.str, "aMS", %progbits, 1])
2238 fi
2239 AC_DEFINE_UNQUOTED(HAVE_GAS_SHF_MERGE,
2240   [`if test $gcc_cv_as_shf_merge = yes; then echo 1; else echo 0; fi`],
2241 [Define 0/1 if your assembler supports marking sections with SHF_MERGE flag.])
2242
2243 gcc_GAS_CHECK_FEATURE(COMDAT group support, gcc_cv_as_comdat_group,
2244  [elf,2,16,0], [--fatal-warnings],
2245  [.section .text,"axG",@progbits,.foo,comdat])
2246 if test $gcc_cv_as_comdat_group = yes; then
2247   gcc_cv_as_comdat_group_percent=no
2248 else
2249  gcc_GAS_CHECK_FEATURE(COMDAT group support, gcc_cv_as_comdat_group_percent,
2250    [elf,2,16,0], [--fatal-warnings],
2251    [.section .text,"axG",%progbits,.foo,comdat])
2252 fi
2253 if test $in_tree_ld != yes && test x"$ld_vers" != x; then
2254   comdat_group=yes
2255   if test 0"$ld_date" -lt 20050308; then
2256     if test -n "$ld_date"; then
2257       # If there was date string, but was earlier than 2005-03-08, fail
2258       comdat_group=no
2259     elif test "$ld_vers_major" -lt 2; then
2260       comdat_group=no
2261     elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -lt 16; then
2262       comdat_group=no
2263     fi
2264   fi
2265 else
2266   # assume linkers other than GNU ld don't support COMDAT group
2267   comdat_group=no
2268 fi
2269 if test $comdat_group = no; then
2270   gcc_cv_as_comdat_group=no
2271   gcc_cv_as_comdat_group_percent=no
2272 fi
2273 AC_DEFINE_UNQUOTED(HAVE_COMDAT_GROUP,
2274   [`if test $gcc_cv_as_comdat_group = yes || test $gcc_cv_as_comdat_group_percent = yes; then echo 1; else echo 0; fi`],
2275 [Define 0/1 if your assembler and linker support COMDAT groups.])
2276
2277 # Thread-local storage - the check is heavily parametrized.
2278 conftest_s=
2279 tls_first_major=
2280 tls_first_minor=
2281 tls_as_opt=
2282 case "$target" in
2283 changequote(,)dnl
2284   alpha*-*-*)
2285     conftest_s='
2286         .section ".tdata","awT",@progbits
2287 foo:    .long   25
2288         .text
2289         ldq     $27,__tls_get_addr($29)         !literal!1
2290         lda     $16,foo($29)                    !tlsgd!1
2291         jsr     $26,($27),__tls_get_addr        !lituse_tlsgd!1
2292         ldq     $27,__tls_get_addr($29)         !literal!2
2293         lda     $16,foo($29)                    !tlsldm!2
2294         jsr     $26,($27),__tls_get_addr        !lituse_tlsldm!2
2295         ldq     $1,foo($29)                     !gotdtprel
2296         ldah    $2,foo($29)                     !dtprelhi
2297         lda     $3,foo($2)                      !dtprello
2298         lda     $4,foo($29)                     !dtprel
2299         ldq     $1,foo($29)                     !gottprel
2300         ldah    $2,foo($29)                     !tprelhi
2301         lda     $3,foo($2)                      !tprello
2302         lda     $4,foo($29)                     !tprel'
2303         tls_first_major=2
2304         tls_first_minor=13
2305         tls_as_opt=--fatal-warnings
2306         ;;
2307   frv*-*-*)
2308     conftest_s='
2309         .section ".tdata","awT",@progbits
2310 x:      .long   25
2311         .text
2312         call    #gettlsoff(x)'
2313         tls_first_major=2
2314         tls_first_minor=14
2315         ;;
2316   hppa*-*-linux*)
2317     conftest_s='
2318 t1:     .reg    %r20
2319 t2:     .reg    %r21
2320 gp:     .reg    %r19
2321         .section ".tdata","awT",@progbits
2322 foo:    .long   25
2323         .text
2324         .align  4
2325         addil LT%foo-$tls_gdidx$,gp
2326         ldo RT%foo-$tls_gdidx$(%r1),%arg0
2327         b __tls_get_addr
2328         nop
2329         addil LT%foo-$tls_ldidx$,gp
2330         b __tls_get_addr
2331         ldo RT%foo-$tls_ldidx$(%r1),%arg0
2332         addil LR%foo-$tls_dtpoff$,%ret0
2333         ldo RR%foo-$tls_dtpoff$(%r1),%t1
2334         mfctl %cr27,%t1
2335         addil LT%foo-$tls_ieoff$,gp
2336         ldw RT%foo-$tls_ieoff$(%r1),%t2
2337         add %t1,%t2,%t3
2338         mfctl %cr27,%t1
2339         addil LR%foo-$tls_leoff$,%t1
2340         ldo RR%foo-$tls_leoff$(%r1),%t2'
2341         tls_first_major=2
2342         tls_first_minor=15
2343         tls_as_opt=--fatal-warnings
2344         ;;
2345   arm*-*-*)
2346     conftest_s='
2347         .section ".tdata","awT",%progbits
2348 foo:    .long   25
2349         .text
2350 .word foo(gottpoff)
2351 .word foo(tpoff)
2352 .word foo(tlsgd)
2353 .word foo(tlsldm)
2354 .word foo(tlsldo)'
2355         tls_first_major=2
2356         tls_first_minor=17
2357         ;;
2358   i[34567]86-*-*)
2359     conftest_s='
2360         .section ".tdata","awT",@progbits
2361 foo:    .long   25
2362         .text
2363         movl    %gs:0, %eax
2364         leal    foo@TLSGD(,%ebx,1), %eax
2365         leal    foo@TLSLDM(%ebx), %eax
2366         leal    foo@DTPOFF(%eax), %edx
2367         movl    foo@GOTTPOFF(%ebx), %eax
2368         subl    foo@GOTTPOFF(%ebx), %eax
2369         addl    foo@GOTNTPOFF(%ebx), %eax
2370         movl    foo@INDNTPOFF, %eax
2371         movl    $foo@TPOFF, %eax
2372         subl    $foo@TPOFF, %eax
2373         leal    foo@NTPOFF(%ecx), %eax'
2374         tls_first_major=2
2375         tls_first_minor=14
2376         tls_as_opt=--fatal-warnings
2377         ;;
2378   x86_64-*-*)
2379     conftest_s='
2380         .section ".tdata","awT",@progbits
2381 foo:    .long   25
2382         .text
2383         movq    %fs:0, %rax
2384         leaq    foo@TLSGD(%rip), %rdi
2385         leaq    foo@TLSLD(%rip), %rdi
2386         leaq    foo@DTPOFF(%rax), %rdx
2387         movq    foo@GOTTPOFF(%rip), %rax
2388         movq    $foo@TPOFF, %rax'
2389         tls_first_major=2
2390         tls_first_minor=14
2391         tls_as_opt=--fatal-warnings
2392         ;;
2393   ia64-*-*)
2394     conftest_s='
2395         .section ".tdata","awT",@progbits
2396 foo:    data8   25
2397         .text
2398         addl    r16 = @ltoff(@dtpmod(foo#)), gp
2399         addl    r17 = @ltoff(@dtprel(foo#)), gp
2400         addl    r18 = @ltoff(@tprel(foo#)), gp
2401         addl    r19 = @dtprel(foo#), gp
2402         adds    r21 = @dtprel(foo#), r13
2403         movl    r23 = @dtprel(foo#)
2404         addl    r20 = @tprel(foo#), gp
2405         adds    r22 = @tprel(foo#), r13
2406         movl    r24 = @tprel(foo#)'
2407         tls_first_major=2
2408         tls_first_minor=13
2409         tls_as_opt=--fatal-warnings
2410         ;;
2411   mips*-*-*)
2412     conftest_s='
2413         .section .tdata,"awT",@progbits
2414 x:
2415         .word 2
2416         .text
2417         addiu $4, $28, %tlsgd(x)
2418         addiu $4, $28, %tlsldm(x)
2419         lui $4, %dtprel_hi(x)
2420         addiu $4, $4, %dtprel_lo(x)
2421         lw $4, %gottprel(x)($28)
2422         lui $4, %tprel_hi(x)
2423         addiu $4, $4, %tprel_lo(x)'
2424         tls_first_major=2
2425         tls_first_minor=16
2426         tls_as_opt='-32 --fatal-warnings'
2427         ;;
2428   powerpc-*-*)
2429     conftest_s='
2430         .section ".tdata","awT",@progbits
2431         .align 2
2432 ld0:    .space 4
2433 ld1:    .space 4
2434 x1:     .space 4
2435 x2:     .space 4
2436 x3:     .space 4
2437         .text
2438         addi 3,31,ld0@got@tlsgd
2439         bl __tls_get_addr
2440         addi 3,31,x1@got@tlsld
2441         bl __tls_get_addr
2442         addi 9,3,x1@dtprel
2443         addis 9,3,x2@dtprel@ha
2444         addi 9,9,x2@dtprel@l
2445         lwz 9,x3@got@tprel(31)
2446         add 9,9,x@tls
2447         addi 9,2,x1@tprel
2448         addis 9,2,x2@tprel@ha
2449         addi 9,9,x2@tprel@l'
2450         tls_first_major=2
2451         tls_first_minor=14
2452         tls_as_opt="-a32 --fatal-warnings"
2453         ;;
2454   powerpc64-*-*)
2455     conftest_s='
2456         .section ".tdata","awT",@progbits
2457         .align 3
2458 ld0:    .space 8
2459 ld1:    .space 8
2460 x1:     .space 8
2461 x2:     .space 8
2462 x3:     .space 8
2463         .text
2464         addi 3,2,ld0@got@tlsgd
2465         bl .__tls_get_addr
2466         nop
2467         addi 3,2,ld1@toc
2468         bl .__tls_get_addr
2469         nop
2470         addi 3,2,x1@got@tlsld
2471         bl .__tls_get_addr
2472         nop
2473         addi 9,3,x1@dtprel
2474         bl .__tls_get_addr
2475         nop
2476         addis 9,3,x2@dtprel@ha
2477         addi 9,9,x2@dtprel@l
2478         bl .__tls_get_addr
2479         nop
2480         ld 9,x3@got@dtprel(2)
2481         add 9,9,3
2482         bl .__tls_get_addr
2483         nop'
2484         tls_first_major=2
2485         tls_first_minor=14
2486         tls_as_opt="-a64 --fatal-warnings"
2487         ;;
2488   s390-*-*)
2489     conftest_s='
2490         .section ".tdata","awT",@progbits
2491 foo:    .long   25
2492         .text
2493         .long   foo@TLSGD
2494         .long   foo@TLSLDM
2495         .long   foo@DTPOFF
2496         .long   foo@NTPOFF
2497         .long   foo@GOTNTPOFF
2498         .long   foo@INDNTPOFF
2499         l       %r1,foo@GOTNTPOFF(%r12)
2500         l       %r1,0(%r1):tls_load:foo
2501         bas     %r14,0(%r1,%r13):tls_gdcall:foo
2502         bas     %r14,0(%r1,%r13):tls_ldcall:foo'
2503         tls_first_major=2
2504         tls_first_minor=14
2505         tls_as_opt="-m31 --fatal-warnings"
2506         ;;
2507   s390x-*-*)
2508     conftest_s='
2509         .section ".tdata","awT",@progbits
2510 foo:    .long   25
2511         .text
2512         .quad   foo@TLSGD
2513         .quad   foo@TLSLDM
2514         .quad   foo@DTPOFF
2515         .quad   foo@NTPOFF
2516         .quad   foo@GOTNTPOFF
2517         lg      %r1,foo@GOTNTPOFF(%r12)
2518         larl    %r1,foo@INDNTPOFF
2519         brasl   %r14,__tls_get_offset@PLT:tls_gdcall:foo
2520         brasl   %r14,__tls_get_offset@PLT:tls_ldcall:foo'
2521         tls_first_major=2
2522         tls_first_minor=14
2523         tls_as_opt="-m64 -Aesame --fatal-warnings"
2524         ;;
2525   sh-*-* | sh[34]-*-*)
2526     conftest_s='
2527         .section ".tdata","awT",@progbits
2528 foo:    .long   25
2529         .text
2530         .long   foo@TLSGD
2531         .long   foo@TLSLDM
2532         .long   foo@DTPOFF
2533         .long   foo@GOTTPOFF
2534         .long   foo@TPOFF'
2535         tls_first_major=2
2536         tls_first_minor=13
2537         tls_as_opt=--fatal-warnings
2538         ;;
2539   sparc*-*-*)
2540     case "$target" in
2541       sparc*-sun-solaris2.[56789]*)
2542         # TLS was introduced in the Solaris 9 4/04 release but
2543         # we do not enable it by default on Solaris 9 either.
2544         if test "x$enable_tls" = xyes ; then
2545           on_solaris=yes
2546         else
2547           enable_tls=no;
2548         fi
2549         ;;
2550       sparc*-sun-solaris2.*)
2551         on_solaris=yes
2552         ;;
2553       *)
2554         on_solaris=no
2555         ;;
2556     esac
2557     if test x$on_solaris = xyes && test x$gas_flag = xno; then
2558       conftest_s='
2559         .section ".tdata",#alloc,#write,#tls
2560 foo:    .long   25
2561         .text
2562         sethi   %tgd_hi22(foo), %o0
2563         add     %o0, %tgd_lo10(foo), %o1
2564         add     %l7, %o1, %o0, %tgd_add(foo)
2565         call    __tls_get_addr, %tgd_call(foo)
2566         sethi   %tldm_hi22(foo), %l1
2567         add     %l1, %tldm_lo10(foo), %l2
2568         add     %l7, %l2, %o0, %tldm_add(foo)
2569         call    __tls_get_addr, %tldm_call(foo)
2570         sethi   %tldo_hix22(foo), %l3
2571         xor     %l3, %tldo_lox10(foo), %l4
2572         add     %o0, %l4, %l5, %tldo_add(foo)
2573         sethi   %tie_hi22(foo), %o3
2574         add     %o3, %tie_lo10(foo), %o3
2575         ld      [%l7 + %o3], %o2, %tie_ld(foo)
2576         add     %g7, %o2, %o4, %tie_add(foo)
2577         sethi   %tle_hix22(foo), %l1
2578         xor     %l1, %tle_lox10(foo), %o5
2579         ld      [%g7 + %o5], %o1'
2580         tls_first_major=0
2581         tls_first_minor=0
2582     else
2583       conftest_s='
2584         .section ".tdata","awT",@progbits
2585 foo:    .long   25
2586         .text
2587         sethi   %tgd_hi22(foo), %o0
2588         add     %o0, %tgd_lo10(foo), %o1
2589         add     %l7, %o1, %o0, %tgd_add(foo)
2590         call    __tls_get_addr, %tgd_call(foo)
2591         sethi   %tldm_hi22(foo), %l1
2592         add     %l1, %tldm_lo10(foo), %l2
2593         add     %l7, %l2, %o0, %tldm_add(foo)
2594         call    __tls_get_addr, %tldm_call(foo)
2595         sethi   %tldo_hix22(foo), %l3
2596         xor     %l3, %tldo_lox10(foo), %l4
2597         add     %o0, %l4, %l5, %tldo_add(foo)
2598         sethi   %tie_hi22(foo), %o3
2599         add     %o3, %tie_lo10(foo), %o3
2600         ld      [%l7 + %o3], %o2, %tie_ld(foo)
2601         add     %g7, %o2, %o4, %tie_add(foo)
2602         sethi   %tle_hix22(foo), %l1
2603         xor     %l1, %tle_lox10(foo), %o5
2604         ld      [%g7 + %o5], %o1'
2605         tls_first_major=2
2606         tls_first_minor=14
2607         tls_as_opt="-32 --fatal-warnings"
2608       fi
2609         ;;
2610 changequote([,])dnl
2611 esac
2612 set_have_as_tls=no
2613 if test "x$enable_tls" = xno ; then
2614   : # TLS explicitly disabled.
2615 elif test "x$enable_tls" = xyes ; then
2616   set_have_as_tls=yes # TLS explicitly enabled.
2617 elif test -z "$tls_first_major"; then
2618   : # If we don't have a check, assume no support.
2619 else
2620   gcc_GAS_CHECK_FEATURE(thread-local storage support, gcc_cv_as_tls,
2621   [$tls_first_major,$tls_first_minor,0], [$tls_as_opt], [$conftest_s],,
2622   [set_have_as_tls=yes])
2623 fi
2624 if test $set_have_as_tls = yes ; then
2625   AC_DEFINE(HAVE_AS_TLS, 1,
2626             [Define if your assembler supports thread-local storage.])
2627 fi
2628
2629 # Target-specific assembler checks.
2630
2631 AC_MSG_CHECKING(linker -Bstatic/-Bdynamic option)
2632 gcc_cv_ld_static_dynamic=no
2633 if test $in_tree_ld = yes ; then
2634   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 10; then
2635     gcc_cv_ld_static_dynamic=yes
2636   fi
2637 elif test x$gcc_cv_ld != x; then
2638         # Check if linker supports -Bstatic/-Bdynamic option
2639         if $gcc_cv_ld --help 2>/dev/null | grep -- -Bstatic > /dev/null \
2640           && $gcc_cv_ld --help 2>/dev/null | grep -- -Bdynamic > /dev/null; then
2641                 gcc_cv_ld_static_dynamic=yes
2642         fi
2643 fi
2644 if test x"$gcc_cv_ld_static_dynamic" = xyes; then
2645         AC_DEFINE(HAVE_LD_STATIC_DYNAMIC, 1,
2646 [Define if your linker supports -Bstatic/-Bdynamic option.])
2647 fi
2648 AC_MSG_RESULT($gcc_cv_ld_static_dynamic)
2649
2650 if test x"$demangler_in_ld" = xyes; then
2651   AC_MSG_CHECKING(linker --demangle support)
2652   gcc_cv_ld_demangle=no
2653   if test $in_tree_ld = yes; then
2654     if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 14 -o "$gcc_cv_gld_major_version" -gt 2; then \
2655       gcc_cv_ld_demangle=yes
2656     fi
2657   elif test x$gcc_cv_ld != x -a x"$gnu_ld" = xyes; then
2658     # Check if the GNU linker supports --demangle option
2659     if $gcc_cv_ld --help 2>/dev/null | grep no-demangle > /dev/null; then
2660       gcc_cv_ld_demangle=yes
2661     fi
2662   fi
2663   if test x"$gcc_cv_ld_demangle" = xyes; then
2664     AC_DEFINE(HAVE_LD_DEMANGLE, 1,
2665 [Define if your linker supports --demangle option.])
2666   fi
2667   AC_MSG_RESULT($gcc_cv_ld_demangle)
2668 fi
2669
2670 case "$target" in
2671   # All TARGET_ABI_OSF targets.
2672   alpha*-*-osf* | alpha*-*-linux* | alpha*-*-*bsd*)
2673     gcc_GAS_CHECK_FEATURE([explicit relocation support],
2674         gcc_cv_as_alpha_explicit_relocs, [2,12,0],,
2675 [       .set nomacro
2676         .text
2677         extbl   $3, $2, $3      !lituse_bytoff!1
2678         ldq     $2, a($29)      !literal!1
2679         ldq     $4, b($29)      !literal!2
2680         ldq_u   $3, 0($2)       !lituse_base!1
2681         ldq     $27, f($29)     !literal!5
2682         jsr     $26, ($27), f   !lituse_jsr!5
2683         ldah    $29, 0($26)     !gpdisp!3
2684         lda     $0, c($29)      !gprel
2685         ldah    $1, d($29)      !gprelhigh
2686         lda     $1, d($1)       !gprellow
2687         lda     $29, 0($29)     !gpdisp!3],,
2688     [AC_DEFINE(HAVE_AS_EXPLICIT_RELOCS, 1,
2689   [Define if your assembler supports explicit relocations.])])
2690     gcc_GAS_CHECK_FEATURE([jsrdirect relocation support],
2691         gcc_cv_as_alpha_jsrdirect_relocs, [2,16,90],,
2692 [       .set nomacro
2693         .text
2694         ldq     $27, a($29)     !literal!1
2695         jsr     $26, ($27), a   !lituse_jsrdirect!1],,
2696     [AC_DEFINE(HAVE_AS_JSRDIRECT_RELOCS, 1,
2697   [Define if your assembler supports the lituse_jsrdirect relocation.])])
2698     ;;
2699
2700   cris-*-*)
2701     gcc_GAS_CHECK_FEATURE([-no-mul-bug-abort option],
2702       gcc_cv_as_cris_no_mul_bug,[2,15,91],
2703       [-no-mul-bug-abort], [.text],,
2704       [AC_DEFINE(HAVE_AS_NO_MUL_BUG_ABORT_OPTION, 1,
2705                 [Define if your assembler supports the -no-mul-bug-abort option.])])
2706     ;;
2707
2708   sparc*-*-*)
2709     gcc_GAS_CHECK_FEATURE([.register], gcc_cv_as_sparc_register_op,,,
2710       [.register %g2, #scratch],,
2711       [AC_DEFINE(HAVE_AS_REGISTER_PSEUDO_OP, 1,
2712                 [Define if your assembler supports .register.])])
2713
2714     gcc_GAS_CHECK_FEATURE([-relax option], gcc_cv_as_sparc_relax,,
2715       [-relax], [.text],,
2716       [AC_DEFINE(HAVE_AS_RELAX_OPTION, 1,
2717                 [Define if your assembler supports -relax option.])])
2718
2719     gcc_GAS_CHECK_FEATURE([unaligned pcrel relocs],
2720       gcc_cv_as_sparc_ua_pcrel,,
2721       [-K PIC],
2722 [.text
2723 foo:
2724         nop
2725 .data
2726 .align 4
2727 .byte 0
2728 .uaword %r_disp32(foo)],
2729       [if test x$gcc_cv_ld != x \
2730        && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1; then
2731          gcc_cv_as_sparc_ua_pcrel=yes
2732        fi
2733        rm -f conftest],
2734       [AC_DEFINE(HAVE_AS_SPARC_UA_PCREL, 1,
2735                 [Define if your assembler and linker support unaligned PC relative relocs.])
2736
2737       gcc_GAS_CHECK_FEATURE([unaligned pcrel relocs against hidden symbols],
2738         gcc_cv_as_sparc_ua_pcrel_hidden,,
2739         [-K PIC],
2740 [.data
2741 .align 4
2742 .byte 0x31
2743 .uaword %r_disp32(foo)
2744 .byte 0x32, 0x33, 0x34
2745 .global foo
2746 .hidden foo
2747 foo:
2748 .skip 4],
2749         [if test x$gcc_cv_ld != x && test x$gcc_cv_objdump != x \
2750          && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1 \
2751          && $gcc_cv_objdump -s -j .data conftest 2> /dev/null \
2752             | grep ' 31000000 07323334' > /dev/null 2>&1; then
2753             if $gcc_cv_objdump -R conftest 2> /dev/null \
2754                | grep 'DISP32' > /dev/null 2>&1; then
2755                 :
2756             else
2757                 gcc_cv_as_sparc_ua_pcrel_hidden=yes
2758             fi
2759          fi
2760          rm -f conftest],
2761          [AC_DEFINE(HAVE_AS_SPARC_UA_PCREL_HIDDEN, 1,
2762                    [Define if your assembler and linker support unaligned PC relative relocs against hidden symbols.])])
2763     ]) # unaligned pcrel relocs
2764
2765     gcc_GAS_CHECK_FEATURE([offsetable %lo()],
2766       gcc_cv_as_sparc_offsetable_lo10,,
2767       [-xarch=v9],
2768 [.text
2769         or %g1, %lo(ab) + 12, %g1
2770         or %g1, %lo(ab + 12), %g1],
2771       [if test x$gcc_cv_objdump != x \
2772        && $gcc_cv_objdump -s -j .text conftest.o 2> /dev/null \
2773           | grep ' 82106000 82106000' > /dev/null 2>&1; then
2774          gcc_cv_as_sparc_offsetable_lo10=yes
2775        fi],
2776        [AC_DEFINE(HAVE_AS_OFFSETABLE_LO10, 1,
2777                  [Define if your assembler supports offsetable %lo().])])
2778     ;;
2779
2780 changequote(,)dnl
2781   i[34567]86-*-* | x86_64-*-*)
2782 changequote([,])dnl
2783     case $target_os in
2784       cygwin* | pe | mingw32*)
2785         # Used for DWARF 2 in PE
2786         gcc_GAS_CHECK_FEATURE([.secrel32 relocs],
2787           gcc_cv_as_ix86_pe_secrel32,
2788           [2,15,91],,
2789 [.text
2790 foo:    nop
2791 .data
2792         .secrel32 foo],
2793           [if test x$gcc_cv_ld != x \
2794            && $gcc_cv_ld -o conftest conftest.o > /dev/null 2>&1; then
2795              gcc_cv_as_ix86_pe_secrel32=yes
2796            fi
2797            rm -f conftest],
2798           [AC_DEFINE(HAVE_GAS_PE_SECREL32_RELOC, 1,
2799             [Define if your assembler and linker support 32-bit section relative relocs via '.secrel32 label'.])])
2800         ;;
2801     esac
2802
2803     gcc_GAS_CHECK_FEATURE([filds and fists mnemonics],
2804        gcc_cv_as_ix86_filds_fists,
2805       [2,9,0],, [filds mem; fists mem],,
2806       [AC_DEFINE(HAVE_GAS_FILDS_FISTS, 1,
2807         [Define if your assembler uses the new HImode fild and fist notation.])])
2808
2809     gcc_GAS_CHECK_FEATURE([cmov syntax],
2810       gcc_cv_as_ix86_cmov_sun_syntax,,,
2811       [cmovl.l %edx, %eax],,
2812       [AC_DEFINE(HAVE_AS_IX86_CMOV_SUN_SYNTAX, 1,
2813         [Define if your assembler supports the Sun syntax for cmov.])])
2814
2815     # This one is used unconditionally by i386.[ch]; it is to be defined
2816     # to 1 if the feature is present, 0 otherwise.
2817     gcc_GAS_CHECK_FEATURE([GOTOFF in data],
2818         gcc_cv_as_ix86_gotoff_in_data, [2,11,0],,
2819 [       .text
2820 .L0:
2821         nop
2822         .data
2823         .long .L0@GOTOFF])
2824     AC_DEFINE_UNQUOTED(HAVE_AS_GOTOFF_IN_DATA,
2825       [`if test $gcc_cv_as_ix86_gotoff_in_data = yes; then echo 1; else echo 0; fi`],
2826       [Define true if the assembler supports '.long foo@GOTOFF'.])
2827     ;;
2828
2829   ia64*-*-*)
2830     gcc_GAS_CHECK_FEATURE([ltoffx and ldxmov relocs],
2831         gcc_cv_as_ia64_ltoffx_ldxmov_relocs, [2,14,0],,
2832 [       .text
2833         addl r15 = @ltoffx(x#), gp
2834         ;;
2835         ld8.mov r16 = [[r15]], x#],,
2836     [AC_DEFINE(HAVE_AS_LTOFFX_LDXMOV_RELOCS, 1,
2837           [Define if your assembler supports ltoffx and ldxmov relocations.])])
2838
2839     ;;
2840
2841   powerpc*-*-*)
2842     case $target in
2843       *-*-aix*) conftest_s='    .machine "pwr5"
2844         .csect .text[[PR]]
2845         mfcr 3,128';;
2846       *-*-darwin*)
2847         gcc_GAS_CHECK_FEATURE([.machine directive support],
2848           gcc_cv_as_machine_directive,,,
2849           [     .machine ppc7400])
2850         if test x$gcc_cv_as_machine_directive != xyes; then
2851           echo "*** This target requires an assembler supporting \".machine\"" >&2
2852           echo you can get it from: ftp://gcc.gnu.org/pub/gcc/infrastructure/cctools-528.5.dmg >&2
2853           test x$build = x$target && exit 1
2854         fi
2855         conftest_s='    .text
2856         mfcr r3,128';;
2857       *) conftest_s='   .machine power4
2858         .text
2859         mfcr 3,128';;
2860     esac
2861
2862     gcc_GAS_CHECK_FEATURE([mfcr field support],
2863       gcc_cv_as_powerpc_mfcrf, [2,14,0],,
2864       [$conftest_s],,
2865       [AC_DEFINE(HAVE_AS_MFCRF, 1,
2866           [Define if your assembler supports mfcr field.])])
2867
2868     case $target in
2869       *-*-aix*) conftest_s='    .machine "pwr5"
2870         .csect .text[[PR]]
2871         popcntb 3,3';;
2872       *) conftest_s='   .machine power5
2873         .text
2874         popcntb 3,3';;
2875     esac
2876
2877     gcc_GAS_CHECK_FEATURE([popcntb support],
2878       gcc_cv_as_powerpc_popcntb, [2,17,0],,
2879       [$conftest_s],,
2880       [AC_DEFINE(HAVE_AS_POPCNTB, 1,
2881           [Define if your assembler supports popcntb field.])])
2882
2883     case $target in
2884       *-*-aix*) conftest_s='    .machine "pwr5x"
2885         .csect .text[[PR]]
2886         frin 1,1';;
2887       *) conftest_s='   .machine power5
2888         .text
2889         frin 1,1';;
2890     esac
2891
2892     gcc_GAS_CHECK_FEATURE([fp round support],
2893       gcc_cv_as_powerpc_fprnd, [2,17,0],,
2894       [$conftest_s],,
2895       [AC_DEFINE(HAVE_AS_FPRND, 1,
2896           [Define if your assembler supports fprnd.])])
2897
2898     case $target in
2899       *-*-aix*) conftest_s='    .csect .text[[PR]]
2900 LCF..0:
2901         addis 11,30,_GLOBAL_OFFSET_TABLE_-LCF..0@ha';;
2902       *-*-darwin*)
2903         conftest_s='    .text
2904 LCF0:
2905         addis r11,r30,_GLOBAL_OFFSET_TABLE_-LCF0@ha';;
2906       *) conftest_s='   .text
2907 .LCF0:
2908         addis 11,30,_GLOBAL_OFFSET_TABLE_-.LCF0@ha';;
2909     esac
2910
2911     gcc_GAS_CHECK_FEATURE([rel16 relocs],
2912       gcc_cv_as_powerpc_rel16, [2,17,0], -a32,
2913       [$conftest_s],,
2914       [AC_DEFINE(HAVE_AS_REL16, 1,
2915           [Define if your assembler supports R_PPC_REL16 relocs.])])
2916     ;;
2917
2918   mips*-*-*)
2919     gcc_GAS_CHECK_FEATURE([explicit relocation support],
2920       gcc_cv_as_mips_explicit_relocs, [2,14,0],,
2921 [       lw $4,%gp_rel(foo)($4)],,
2922       [if test x$target_cpu_default = x
2923        then target_cpu_default=MASK_EXPLICIT_RELOCS
2924        else target_cpu_default="($target_cpu_default)|MASK_EXPLICIT_RELOCS"
2925        fi])
2926     ;;
2927 esac
2928
2929 # Mips and HP-UX need the GNU assembler.
2930 # Linux on IA64 might be able to use the Intel assembler.
2931
2932 case "$target" in
2933   mips*-*-* | *-*-hpux* )
2934     if test x$gas_flag = xyes \
2935        || test x"$host" != x"$build" \
2936        || test ! -x "$gcc_cv_as" \
2937        || "$gcc_cv_as" -v < /dev/null 2>&1 | grep GNU > /dev/null; then
2938       :
2939     else
2940       echo "*** This configuration requires the GNU assembler" >&2
2941       exit 1
2942     fi
2943     ;;
2944 esac
2945
2946 # ??? Not all targets support dwarf2 debug_line, even within a version
2947 # of gas.  Moreover, we need to emit a valid instruction to trigger any
2948 # info to the output file.  So, as supported targets are added to gas 2.11,
2949 # add some instruction here to (also) show we expect this might work.
2950 # ??? Once 2.11 is released, probably need to add first known working
2951 # version to the per-target configury.
2952 case "$target" in
2953   i?86*-*-* | mips*-*-* | alpha*-*-* | powerpc*-*-* | sparc*-*-* | m68*-*-* \
2954   | x86_64*-*-* | hppa*-*-* | arm*-*-* | strongarm*-*-* | xscale*-*-* \
2955   | xstormy16*-*-* | cris-*-* | xtensa-*-* | bfin-*-*)
2956     insn="nop"
2957     ;;
2958   ia64*-*-* | s390*-*-*)
2959     insn="nop 0"
2960     ;;
2961   mmix-*-*)
2962     insn="swym 0"
2963     ;;
2964 esac
2965 if test x"$insn" != x; then
2966  conftest_s="\
2967         .file 1 \"conftest.s\"
2968         .loc 1 3 0
2969         $insn"
2970  gcc_GAS_CHECK_FEATURE([dwarf2 debug_line support],
2971   gcc_cv_as_dwarf2_debug_line,
2972   [elf,2,11,0],, [$conftest_s],
2973   [if test x$gcc_cv_objdump != x \
2974    && $gcc_cv_objdump -h conftest.o 2> /dev/null \
2975       | grep debug_line > /dev/null 2>&1; then
2976      gcc_cv_as_dwarf2_debug_line=yes
2977    fi])
2978
2979 # The .debug_line file table must be in the exact order that
2980 # we specified the files, since these indices are also used
2981 # by DW_AT_decl_file.  Approximate this test by testing if
2982 # the assembler bitches if the same index is assigned twice.
2983  gcc_GAS_CHECK_FEATURE([buggy dwarf2 .file directive],
2984   gcc_cv_as_dwarf2_file_buggy,,,
2985 [       .file 1 "foo.s"
2986         .file 1 "bar.s"])
2987
2988  if test $gcc_cv_as_dwarf2_debug_line = yes \
2989  && test $gcc_cv_as_dwarf2_file_buggy = no; then
2990         AC_DEFINE(HAVE_AS_DWARF2_DEBUG_LINE, 1,
2991   [Define if your assembler supports dwarf2 .file/.loc directives,
2992    and preserves file table indices exactly as given.])
2993  fi
2994
2995  gcc_GAS_CHECK_FEATURE([--gdwarf2 option],
2996   gcc_cv_as_gdwarf2_flag,
2997   [elf,2,11,0], [--gdwarf2], [$insn],,
2998   [AC_DEFINE(HAVE_AS_GDWARF2_DEBUG_FLAG, 1,
2999 [Define if your assembler supports the --gdwarf2 option.])])
3000
3001  gcc_GAS_CHECK_FEATURE([--gstabs option],
3002   gcc_cv_as_gstabs_flag,
3003   [elf,2,11,0], [--gstabs], [$insn],
3004   [# The native Solaris 9/Intel assembler doesn't understand --gstabs
3005    # and warns about it, but still exits successfully.  So check for
3006    # this.
3007    if AC_TRY_COMMAND([$gcc_cv_as --gstabs -o conftest.o conftest.s 2>&1 | grep -i warning > /dev/null])
3008    then :
3009    else gcc_cv_as_gstabs_flag=yes
3010    fi],
3011   [AC_DEFINE(HAVE_AS_GSTABS_DEBUG_FLAG, 1,
3012 [Define if your assembler supports the --gstabs option.])])
3013 fi
3014
3015 AC_MSG_CHECKING(linker read-only and read-write section mixing)
3016 gcc_cv_ld_ro_rw_mix=unknown
3017 if test $in_tree_ld = yes ; then
3018   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 10 -o "$gcc_cv_gld_major_version" -gt 2 \
3019      && test $in_tree_ld_is_elf = yes; then
3020     gcc_cv_ld_ro_rw_mix=read-write
3021   fi
3022 elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x -a x$gcc_cv_objdump != x ; then
3023   echo '.section myfoosect, "a"' > conftest1.s
3024   echo '.section myfoosect, "aw"' > conftest2.s
3025   echo '.byte 1' >> conftest2.s
3026   echo '.section myfoosect, "a"' > conftest3.s
3027   echo '.byte 0' >> conftest3.s
3028   if $gcc_cv_as -o conftest1.o conftest1.s > /dev/null 2>&1 \
3029      && $gcc_cv_as -o conftest2.o conftest2.s > /dev/null 2>&1 \
3030      && $gcc_cv_as -o conftest3.o conftest3.s > /dev/null 2>&1 \
3031      && $gcc_cv_ld -shared -o conftest1.so conftest1.o \
3032         conftest2.o conftest3.o > /dev/null 2>&1; then
3033     gcc_cv_ld_ro_rw_mix=`$gcc_cv_objdump -h conftest1.so \
3034                          | sed -e '/myfoosect/!d' -e N`
3035     if echo "$gcc_cv_ld_ro_rw_mix" | grep CONTENTS > /dev/null; then
3036       if echo "$gcc_cv_ld_ro_rw_mix" | grep READONLY > /dev/null; then
3037         gcc_cv_ld_ro_rw_mix=read-only
3038       else
3039         gcc_cv_ld_ro_rw_mix=read-write
3040       fi
3041     fi
3042   fi
3043 changequote(,)dnl
3044   rm -f conftest.* conftest[123].*
3045 changequote([,])dnl
3046 fi
3047 if test x$gcc_cv_ld_ro_rw_mix = xread-write; then
3048         AC_DEFINE(HAVE_LD_RO_RW_SECTION_MIXING, 1,
3049   [Define if your linker links a mix of read-only
3050    and read-write sections into a read-write section.])
3051 fi
3052 AC_MSG_RESULT($gcc_cv_ld_ro_rw_mix)
3053
3054 AC_MSG_CHECKING(linker PT_GNU_EH_FRAME support)
3055 gcc_cv_ld_eh_frame_hdr=no
3056 if test $in_tree_ld = yes ; then
3057   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 12 -o "$gcc_cv_gld_major_version" -gt 2 \
3058      && test $in_tree_ld_is_elf = yes; then
3059     gcc_cv_ld_eh_frame_hdr=yes
3060   fi
3061 elif test x$gcc_cv_ld != x; then
3062         # Check if linker supports --eh-frame-hdr option
3063         if $gcc_cv_ld --help 2>/dev/null | grep eh-frame-hdr > /dev/null; then
3064                 gcc_cv_ld_eh_frame_hdr=yes
3065         fi
3066 fi
3067 GCC_TARGET_TEMPLATE([HAVE_LD_EH_FRAME_HDR])
3068 if test x"$gcc_cv_ld_eh_frame_hdr" = xyes; then
3069         AC_DEFINE(HAVE_LD_EH_FRAME_HDR, 1,
3070 [Define if your linker supports --eh-frame-hdr option.])
3071 fi
3072 AC_MSG_RESULT($gcc_cv_ld_eh_frame_hdr)
3073
3074 AC_MSG_CHECKING(linker position independent executable support)
3075 gcc_cv_ld_pie=no
3076 if test $in_tree_ld = yes ; then
3077   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 15 -o "$gcc_cv_gld_major_version" -gt 2 \
3078      && test $in_tree_ld_is_elf = yes; then
3079     gcc_cv_ld_pie=yes
3080   fi
3081 elif test x$gcc_cv_ld != x; then
3082         # Check if linker supports -pie option
3083         if $gcc_cv_ld --help 2>/dev/null | grep -- -pie > /dev/null; then
3084                 gcc_cv_ld_pie=yes
3085         fi
3086 fi
3087 if test x"$gcc_cv_ld_pie" = xyes; then
3088         AC_DEFINE(HAVE_LD_PIE, 1,
3089 [Define if your linker supports -pie option.])
3090 fi
3091 AC_MSG_RESULT($gcc_cv_ld_pie)
3092
3093 # --------
3094 # UNSORTED
3095 # --------
3096
3097 AC_CACHE_CHECK(linker --as-needed support,
3098 gcc_cv_ld_as_needed,
3099 [gcc_cv_ld_as_needed=no
3100 if test $in_tree_ld = yes ; then
3101   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2 \
3102      && test $in_tree_ld_is_elf = yes; then
3103     gcc_cv_ld_as_needed=yes
3104   fi
3105 elif test x$gcc_cv_ld != x; then
3106         # Check if linker supports --as-needed and --no-as-needed options
3107         if $gcc_cv_ld --help 2>/dev/null | grep as-needed > /dev/null; then
3108                 gcc_cv_ld_as_needed=yes
3109         fi
3110 fi
3111 ])
3112 if test x"$gcc_cv_ld_as_needed" = xyes; then
3113         AC_DEFINE(HAVE_LD_AS_NEEDED, 1,
3114 [Define if your linker supports --as-needed and --no-as-needed options.])
3115 fi
3116
3117 case "$target:$tm_file" in
3118   powerpc64*-*-linux* | powerpc*-*-linux*rs6000/biarch64.h*)
3119     AC_CACHE_CHECK(linker support for omitting dot symbols,
3120     gcc_cv_ld_no_dot_syms,
3121     [gcc_cv_ld_no_dot_syms=no
3122     if test $in_tree_ld = yes ; then
3123       if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2; then
3124         gcc_cv_ld_no_dot_syms=yes
3125       fi
3126     elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x ; then
3127       cat > conftest1.s <<EOF
3128         .text
3129         bl .foo
3130 EOF
3131       cat > conftest2.s <<EOF
3132         .section ".opd","aw"
3133         .align 3
3134         .globl foo
3135         .type foo,@function
3136 foo:
3137         .quad .LEfoo,.TOC.@tocbase,0
3138         .text
3139 .LEfoo:
3140         blr
3141         .size foo,.-.LEfoo
3142 EOF
3143       if $gcc_cv_as -a64 -o conftest1.o conftest1.s > /dev/null 2>&1 \
3144          && $gcc_cv_as -a64 -o conftest2.o conftest2.s > /dev/null 2>&1 \
3145          && $gcc_cv_ld -melf64ppc -o conftest conftest1.o conftest2.o > /dev/null 2>&1; then
3146         gcc_cv_ld_no_dot_syms=yes
3147       fi
3148       rm -f conftest conftest1.o conftest2.o conftest1.s conftest2.s
3149     fi
3150     ])
3151     if test x"$gcc_cv_ld_no_dot_syms" = xyes; then
3152       AC_DEFINE(HAVE_LD_NO_DOT_SYMS, 1,
3153     [Define if your PowerPC64 linker only needs function descriptor syms.])
3154     fi
3155     ;;
3156 esac
3157
3158 AC_CACHE_CHECK(linker --sysroot support,
3159   gcc_cv_ld_sysroot,
3160   [gcc_cv_ld_sysroot=no
3161   if test $in_tree_ld = yes ; then
3162       if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2 ; then
3163         gcc_cv_ld_sysroot=yes
3164       fi
3165   elif test x$gcc_cv_ld != x; then
3166     if $gcc_cv_ld --help 2>/dev/null | grep sysroot > /dev/null; then
3167       gcc_cv_ld_sysroot=yes
3168     fi
3169   fi])
3170 if test x"$gcc_cv_ld_sysroot" = xyes; then
3171   AC_DEFINE(HAVE_LD_SYSROOT, 1,
3172   [Define if your linker supports --sysroot.])
3173 fi
3174
3175 if test x$with_sysroot = x && test x$host = x$target \
3176    && test "$prefix" != "/usr" && test "x$prefix" != "x$local_prefix" ; then
3177   AC_DEFINE_UNQUOTED(PREFIX_INCLUDE_DIR, "$prefix/include",
3178 [Define to PREFIX/include if cpp should also search that directory.])
3179 fi
3180
3181 # Test for stack protector support in target C library.
3182 case "$target" in
3183   *-*-linux*)
3184     AC_CACHE_CHECK(__stack_chk_fail in target GNU C library,
3185       gcc_cv_libc_provides_ssp,
3186       [gcc_cv_libc_provides_ssp=no
3187       if test x$host != x$target || test "x$TARGET_SYSTEM_ROOT" != x; then
3188         if test "x$with_sysroot" = x; then
3189           glibc_header_dir="${exec_prefix}/${target_noncanonical}/sys-include"
3190         elif test "x$with_sysroot" = xyes; then
3191           glibc_header_dir="${exec_prefix}/${target_noncanonical}/sys-root/usr/include"
3192         else
3193           glibc_header_dir="${with_sysroot}/usr/include"
3194         fi
3195       else
3196         glibc_header_dir=/usr/include
3197       fi
3198       # glibc 2.4 and later provides __stack_chk_fail and
3199       # either __stack_chk_guard, or TLS access to stack guard canary.
3200       if test -f $glibc_header_dir/features.h \
3201          && $EGREP '^@<:@       @:>@*#[         ]*define[       ]+__GNU_LIBRARY__[      ]+([1-9][0-9]|[6-9])' \
3202             $glibc_header_dir/features.h > /dev/null; then
3203         if $EGREP '^@<:@        @:>@*#[         ]*define[       ]+__GLIBC__[    ]+([1-9][0-9]|[3-9])' \
3204            $glibc_header_dir/features.h > /dev/null; then
3205           gcc_cv_libc_provides_ssp=yes
3206         elif $EGREP '^@<:@      @:>@*#[         ]*define[       ]+__GLIBC__[    ]+2' \
3207              $glibc_header_dir/features.h > /dev/null \
3208              && $EGREP '^@<:@   @:>@*#[         ]*define[       ]+__GLIBC_MINOR__[      ]+([1-9][0-9]|[4-9])' \
3209              $glibc_header_dir/features.h > /dev/null; then
3210           gcc_cv_libc_provides_ssp=yes
3211         fi
3212       fi]) ;;
3213   *) gcc_cv_libc_provides_ssp=no ;;
3214 esac
3215 if test x$gcc_cv_libc_provides_ssp = xyes; then
3216   AC_DEFINE(TARGET_LIBC_PROVIDES_SSP, 1,
3217             [Define if your target C library provides stack protector support])
3218 fi
3219
3220 # Check if TFmode long double should be used by default or not.
3221 # Some glibc targets used DFmode long double, but with glibc 2.4
3222 # and later they can use TFmode.
3223 case "$target" in
3224   powerpc*-*-*gnu* | \
3225   sparc*-*-linux* | \
3226   s390*-*-linux* | \
3227   alpha*-*-linux*)
3228     AC_ARG_WITH(long-double-128,
3229 [  --with-long-double-128  Use 128-bit long double by default.],
3230       gcc_cv_target_ldbl128="$with_long_double_128",
3231       [gcc_cv_target_ldbl128=no
3232       if test x$host != x$target || test "x$TARGET_SYSTEM_ROOT" != x; then
3233         if test "x$with_sysroot" = x; then
3234           glibc_header_dir="${exec_prefix}/${target_noncanonical}/sys-include"
3235         elif test "x$with_sysroot" = xyes; then
3236           glibc_header_dir="${exec_prefix}/${target_noncanonical}/sys-root/usr/include"
3237         else
3238           glibc_header_dir="${with_sysroot}/usr/include"
3239         fi
3240       else
3241         glibc_header_dir=/usr/include
3242       fi
3243       grep '^[  ]*#[    ]*define[       ][      ]*__LONG_DOUBLE_MATH_OPTIONAL' \
3244         $glibc_header_dir/bits/wordsize.h > /dev/null 2>&1 \
3245       && gcc_cv_target_ldbl128=yes])
3246     ;;
3247 esac
3248 if test x$gcc_cv_target_ldbl128 = xyes; then
3249   AC_DEFINE(TARGET_DEFAULT_LONG_DOUBLE_128, 1,
3250             [Define if TFmode long double should be the default])
3251 fi
3252
3253 # Find out what GC implementation we want, or may, use.
3254 AC_ARG_WITH(gc,
3255 [  --with-gc={page,zone}   choose the garbage collection mechanism to use
3256                           with the compiler],
3257 [case "$withval" in
3258   page)
3259     GGC=ggc-$withval
3260     ;;
3261   zone)
3262     GGC=ggc-$withval
3263     AC_DEFINE(GGC_ZONE, 1, [Define if the zone collector is in use])
3264     ;;
3265   *)
3266     AC_MSG_ERROR([$withval is an invalid option to --with-gc])
3267     ;;
3268 esac],
3269 [GGC=ggc-page])
3270 AC_SUBST(GGC)
3271 echo "Using $GGC for garbage collection."
3272
3273 # Use the system's zlib library.
3274 zlibdir=-L../zlib
3275 zlibinc="-I\$(srcdir)/../zlib"
3276 AC_ARG_WITH(system-zlib,
3277 [  --with-system-zlib      use installed libz],
3278 zlibdir=
3279 zlibinc=
3280 )
3281 AC_SUBST(zlibdir)
3282 AC_SUBST(zlibinc)
3283
3284 dnl Very limited version of automake's enable-maintainer-mode
3285
3286 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
3287   dnl maintainer-mode is disabled by default
3288   AC_ARG_ENABLE(maintainer-mode,
3289 [  --enable-maintainer-mode
3290                           enable make rules and dependencies not useful
3291                           (and sometimes confusing) to the casual installer],
3292       maintainer_mode=$enableval,
3293       maintainer_mode=no)
3294
3295 AC_MSG_RESULT($maintainer_mode)
3296
3297 if test "$maintainer_mode" = "yes"; then
3298   MAINT=''
3299 else
3300   MAINT='#'
3301 fi
3302 AC_SUBST(MAINT)dnl
3303
3304 # --------------
3305 # Language hooks
3306 # --------------
3307
3308 # Make empty files to contain the specs and options for each language.
3309 # Then add #include lines to for a compiler that has specs and/or options.
3310
3311 subdirs=
3312 lang_opt_files=
3313 lang_specs_files=
3314 lang_tree_files=
3315 # These (without "all_") are set in each config-lang.in.
3316 # `language' must be a single word so is spelled singularly.
3317 all_languages=
3318 all_boot_languages=
3319 all_compilers=
3320 all_stagestuff=
3321 all_outputs='Makefile gccbug mklibgcc libada-mk'
3322 # List of language makefile fragments.
3323 all_lang_makefrags=
3324 # List of language subdirectory makefiles.  Deprecated.
3325 all_lang_makefiles=
3326 # Files for gengtype
3327 all_gtfiles="$target_gtfiles"
3328 # Files for gengtype with language
3329 all_gtfiles_files_langs=
3330 all_gtfiles_files_files=
3331
3332 # These are the languages that are set in --enable-languages,
3333 # and are available in the GCC tree.
3334 all_selected_languages=
3335
3336 # Add the language fragments.
3337 # Languages are added via two mechanisms.  Some information must be
3338 # recorded in makefile variables, these are defined in config-lang.in.
3339 # We accumulate them and plug them into the main Makefile.
3340 # The other mechanism is a set of hooks for each of the main targets
3341 # like `clean', `install', etc.
3342
3343 language_hooks="Make-hooks"
3344
3345 for lang in ${srcdir}/*/config-lang.in
3346 do
3347     case $lang in
3348     # The odd quoting in the next line works around
3349     # an apparent bug in bash 1.12 on linux.
3350 changequote(,)dnl
3351     ${srcdir}/[*]/config-lang.in)
3352         continue ;;
3353     *)
3354         lang_alias=`sed -n -e 's,^language=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^language=\([^   ]*\).*$,\1,p' $lang`
3355         if test "x$lang_alias" = x
3356         then
3357               echo "$lang doesn't set \$language." 1>&2
3358               exit 1
3359         fi
3360         subdir="`echo $lang | sed -e 's,^.*/\([^/]*\)/config-lang.in$,\1,'`"
3361         subdirs="$subdirs $subdir"
3362         case ",$enable_languages," in
3363         *,$lang_alias,*)
3364             all_selected_languages="$all_selected_languages $lang_alias"
3365             if test -f $srcdir/$subdir/lang-specs.h; then
3366                 lang_specs_files="$lang_specs_files $srcdir/$subdir/lang-specs.h"
3367             fi
3368             ;;
3369         esac
3370 changequote([,])dnl
3371
3372         if test -f $srcdir/$subdir/lang.opt; then
3373             lang_opt_files="$lang_opt_files $srcdir/$subdir/lang.opt"
3374         fi
3375         if test -f $srcdir/$subdir/$subdir-tree.def; then
3376             lang_tree_files="$lang_tree_files $srcdir/$subdir/$subdir-tree.def"
3377         fi
3378
3379         language=
3380         boot_language=
3381         compilers=
3382         stagestuff=
3383         outputs=
3384         gtfiles=
3385         . ${srcdir}/$subdir/config-lang.in
3386         if test "x$language" = x
3387         then
3388                 echo "${srcdir}/$subdir/config-lang.in doesn't set \$language." 1>&2
3389                 exit 1
3390         fi
3391         all_lang_makefrags="$all_lang_makefrags \$(srcdir)/$subdir/Make-lang.in"
3392         if test -f ${srcdir}/$subdir/Makefile.in
3393                 then all_lang_makefiles="$subdir/Makefile"
3394         fi
3395         all_languages="$all_languages $language"
3396         if test "x$boot_language" = xyes
3397         then
3398                 all_boot_languages="$all_boot_languages $language"
3399         fi
3400         all_compilers="$all_compilers $compilers"
3401         all_stagestuff="$all_stagestuff $stagestuff"
3402         all_outputs="$all_outputs $outputs"
3403         all_gtfiles="$all_gtfiles $gtfiles"
3404         for f in $gtfiles
3405         do
3406                  all_gtfiles_files_langs="$all_gtfiles_files_langs ${subdir} "
3407                  all_gtfiles_files_files="$all_gtfiles_files_files ${f} "
3408         done
3409         ;;
3410     esac
3411 done
3412
3413 # Pick up gtfiles for c
3414 gtfiles=
3415 subdir="c"
3416 . ${srcdir}/c-config-lang.in
3417 all_gtfiles="$all_gtfiles $gtfiles"
3418 for f in $gtfiles
3419 do
3420         all_gtfiles_files_langs="$all_gtfiles_files_langs ${subdir} "
3421         all_gtfiles_files_files="$all_gtfiles_files_files ${f} "
3422 done
3423
3424 check_languages=
3425 for language in $all_selected_languages
3426 do
3427         check_languages="$check_languages check-$language"
3428 done
3429
3430 # We link each language in with a set of hooks, reached indirectly via
3431 # lang.${target}.  Only do so for selected languages.
3432
3433 rm -f Make-hooks
3434 touch Make-hooks
3435 target_list="all.cross start.encap rest.encap tags \
3436         install-common install-man install-info dvi html \
3437         uninstall info man srcextra srcman srcinfo \
3438         mostlyclean clean distclean maintainer-clean \
3439         stage1 stage2 stage3 stage4 stageprofile stagefeedback"
3440
3441 for t in $target_list
3442 do
3443         x=
3444         for lang in $all_selected_languages
3445         do
3446                 x="$x $lang.$t"
3447         done
3448         echo "lang.$t: $x" >> Make-hooks
3449 done
3450
3451 # --------
3452 # UNSORTED
3453 # --------
3454
3455 # Create .gdbinit.
3456
3457 echo "dir ." > .gdbinit
3458 echo "dir ${srcdir}" >> .gdbinit
3459 if test x$gdb_needs_out_file_path = xyes
3460 then
3461         echo "dir ${srcdir}/config/"`dirname ${out_file}` >> .gdbinit
3462 fi
3463 if test "x$subdirs" != x; then
3464         for s in $subdirs
3465         do
3466                 echo "dir ${srcdir}/$s" >> .gdbinit
3467         done
3468 fi
3469 echo "source ${srcdir}/gdbinit.in" >> .gdbinit
3470
3471 # If $(exec_prefix) exists and is not the same as $(prefix), then compute an
3472 # absolute path for gcc_tooldir based on inserting the number of up-directory
3473 # movements required to get from $(exec_prefix) to $(prefix) into the basic
3474 # $(libsubdir)/@(unlibsubdir) based path.
3475 # Don't set gcc_tooldir to tooldir since that's only passed in by the toplevel
3476 # make and thus we'd get different behavior depending on where we built the
3477 # sources.
3478 if test x$exec_prefix = xNONE -o x$exec_prefix = x$prefix; then
3479     gcc_tooldir='$(libsubdir)/$(unlibsubdir)/../$(target_noncanonical)'
3480 else
3481 changequote(<<, >>)dnl
3482 # An explanation of the sed strings:
3483 #  -e 's|^\$(prefix)||'   matches and eliminates 'prefix' from 'exec_prefix'
3484 #  -e 's|/$||'            match a trailing forward slash and eliminates it
3485 #  -e 's|^[^/]|/|'        forces the string to start with a forward slash (*)
3486 #  -e 's|/[^/]*|../|g'    replaces each occurrence of /<directory> with ../
3487 #
3488 # (*) Note this pattern overwrites the first character of the string
3489 # with a forward slash if one is not already present.  This is not a
3490 # problem because the exact names of the sub-directories concerned is
3491 # unimportant, just the number of them matters.
3492 #
3493 # The practical upshot of these patterns is like this:
3494 #
3495 #  prefix     exec_prefix        result
3496 #  ------     -----------        ------
3497 #   /foo        /foo/bar          ../
3498 #   /foo/       /foo/bar          ../
3499 #   /foo        /foo/bar/         ../
3500 #   /foo/       /foo/bar/         ../
3501 #   /foo        /foo/bar/ugg      ../../
3502 #
3503     dollar='$$'
3504     gcc_tooldir="\$(libsubdir)/\$(unlibsubdir)/\`echo \$(exec_prefix) | sed -e 's|^\$(prefix)||' -e 's|/\$(dollar)||' -e 's|^[^/]|/|' -e 's|/[^/]*|../|g'\`\$(target_noncanonical)"
3505 changequote([, ])dnl
3506 fi
3507 AC_SUBST(gcc_tooldir)
3508 AC_SUBST(dollar)
3509
3510 # Find a directory in which to install a shared libgcc.
3511
3512 AC_ARG_ENABLE(version-specific-runtime-libs,
3513 [  --enable-version-specific-runtime-libs
3514                           specify that runtime libraries should be
3515                           installed in a compiler-specific directory])
3516
3517 AC_ARG_WITH(slibdir,
3518 [  --with-slibdir=DIR      shared libraries in DIR [[LIBDIR]]],
3519 slibdir="$with_slibdir",
3520 if test "${enable_version_specific_runtime_libs+set}" = set; then
3521   slibdir='$(libsubdir)'
3522 elif test "$host" != "$target"; then
3523   slibdir='$(build_tooldir)/lib'
3524 else
3525   slibdir='$(libdir)'
3526 fi)
3527 AC_SUBST(slibdir)
3528
3529 objdir=`${PWDCMD-pwd}`
3530 AC_SUBST(objdir)
3531
3532 AC_ARG_WITH(datarootdir,
3533 [  --with-datarootdir=DIR  Use DIR as the data root [[PREFIX/share]]],
3534 datarootdir="\${prefix}/$with_datarootdir",
3535 datarootdir='$(prefix)/share')
3536 AC_SUBST(datarootdir)
3537
3538 AC_ARG_WITH(docdir,
3539 [  --with-docdir=DIR       Install documentation in DIR [[DATAROOTDIR]]],
3540 docdir="\${prefix}/$with_docdir",
3541 docdir='$(datarootdir)')
3542 AC_SUBST(docdir)
3543
3544 AC_ARG_WITH(htmldir,
3545 [  --with-htmldir=DIR      html documentation in in DIR [[DOCDIR]]],
3546 htmldir="\${prefix}/$with_htmldir",
3547 htmldir='$(docdir)')
3548 AC_SUBST(htmldir)
3549
3550 # Substitute configuration variables
3551 AC_SUBST(subdirs)
3552 AC_SUBST(srcdir)
3553 AC_SUBST(all_boot_languages)
3554 AC_SUBST(all_compilers)
3555 AC_SUBST(all_gtfiles)
3556 AC_SUBST(all_gtfiles_files_langs)
3557 AC_SUBST(all_gtfiles_files_files)
3558 AC_SUBST(all_lang_makefrags)
3559 AC_SUBST(all_lang_makefiles)
3560 AC_SUBST(all_languages)
3561 AC_SUBST(all_selected_languages)
3562 AC_SUBST(all_stagestuff)
3563 AC_SUBST(build_exeext)
3564 AC_SUBST(build_install_headers_dir)
3565 AC_SUBST(build_xm_file_list)
3566 AC_SUBST(build_xm_include_list)
3567 AC_SUBST(build_xm_defines)
3568 AC_SUBST(check_languages)
3569 AC_SUBST(cc_set_by_configure)
3570 AC_SUBST(quoted_cc_set_by_configure)
3571 AC_SUBST(cpp_install_dir)
3572 AC_SUBST(xmake_file)
3573 AC_SUBST(tmake_file)
3574 AC_SUBST(extra_gcc_objs)
3575 AC_SUBST(extra_headers_list)
3576 AC_SUBST(extra_objs)
3577 AC_SUBST(extra_parts)
3578 AC_SUBST(extra_passes)
3579 AC_SUBST(extra_programs)
3580 AC_SUBST(float_h_file)
3581 AC_SUBST(gcc_config_arguments)
3582 AC_SUBST(gcc_gxx_include_dir)
3583 AC_SUBST(host_exeext)
3584 AC_SUBST(host_xm_file_list)
3585 AC_SUBST(host_xm_include_list)
3586 AC_SUBST(host_xm_defines)
3587 AC_SUBST(out_host_hook_obj)
3588 AC_SUBST(install)
3589 AC_SUBST(lang_opt_files)
3590 AC_SUBST(lang_specs_files)
3591 AC_SUBST(lang_tree_files)
3592 AC_SUBST(local_prefix)
3593 AC_SUBST(md_file)
3594 AC_SUBST(objc_boehm_gc)
3595 AC_SUBST(out_file)
3596 AC_SUBST(out_object_file)
3597 AC_SUBST(stage_prefix_set_by_configure)
3598 AC_SUBST(quoted_stage_prefix_set_by_configure)
3599 AC_SUBST(thread_file)
3600 AC_SUBST(tm_file_list)
3601 AC_SUBST(tm_include_list)
3602 AC_SUBST(tm_defines)
3603 AC_SUBST(tm_p_file_list)
3604 AC_SUBST(tm_p_include_list)
3605 AC_SUBST(xm_file_list)
3606 AC_SUBST(xm_include_list)
3607 AC_SUBST(xm_defines)
3608 AC_SUBST(c_target_objs)
3609 AC_SUBST(cxx_target_objs)
3610 AC_SUBST(target_cpu_default)
3611
3612 AC_SUBST_FILE(language_hooks)
3613
3614 # Echo link setup.
3615 if test x${build} = x${host} ; then
3616   if test x${host} = x${target} ; then
3617     echo "Links are now set up to build a native compiler for ${target}." 1>&2
3618   else
3619     echo "Links are now set up to build a cross-compiler" 1>&2
3620     echo " from ${host} to ${target}." 1>&2
3621   fi
3622 else
3623   if test x${host} = x${target} ; then
3624     echo "Links are now set up to build (on ${build}) a native compiler" 1>&2
3625     echo " for ${target}." 1>&2
3626   else
3627     echo "Links are now set up to build (on ${build}) a cross-compiler" 1>&2
3628     echo " from ${host} to ${target}." 1>&2
3629   fi
3630 fi
3631
3632 AC_ARG_VAR(GMPLIBS,[How to link GMP])
3633 AC_ARG_VAR(GMPINC,[How to find GMP include files])
3634
3635 # Configure the subdirectories
3636 # AC_CONFIG_SUBDIRS($subdirs)
3637
3638 # Create the Makefile
3639 # and configure language subdirectories
3640 AC_CONFIG_FILES($all_outputs)
3641
3642 AC_CONFIG_COMMANDS([default],
3643 [
3644 case ${CONFIG_HEADERS} in
3645   *auto-host.h:config.in*)
3646   echo > cstamp-h ;;
3647 esac
3648 # Make sure all the subdirs exist.
3649 for d in $subdirs doc build
3650 do
3651     test -d $d || mkdir $d
3652 done
3653 # If the host supports symlinks, point stage[1234] at ../stage[1234] so
3654 # bootstrapping and the installation procedure can still use
3655 # CC="stage1/xgcc -Bstage1/".  If the host doesn't support symlinks,
3656 # FLAGS_TO_PASS has been modified to solve the problem there.
3657 # This is virtually a duplicate of what happens in configure.lang; we do
3658 # an extra check to make sure this only happens if ln -s can be used.
3659 case "$LN_S" in
3660   *-s*)
3661     for d in ${subdirs} ; do
3662         STARTDIR=`${PWDCMD-pwd}`
3663         cd $d
3664         for t in stage1 stage2 stage3 stage4 stageprofile stagefeedback include
3665         do
3666                 rm -f $t
3667                 $LN_S ../$t $t 2>/dev/null
3668         done
3669         cd $STARTDIR
3670     done
3671   ;;
3672 esac
3673 ],
3674 [subdirs='$subdirs'])
3675 AC_OUTPUT