OSDN Git Service

bbcbc7fdcf575689b0b3730c650a56a280383ee5
[pf3gnuchains/gcc-fork.git] / gcc / configure.ac
1 # configure.ac for GCC
2 # Process this file with autoconf to generate a configuration script.
3
4 # Copyright 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2004, 2005, 2006,
5 # 2007, 2008, 2009, 2010 Free Software Foundation, Inc.
6
7 #This file is part of GCC.
8
9 #GCC is free software; you can redistribute it and/or modify it under
10 #the terms of the GNU General Public License as published by the Free
11 #Software Foundation; either version 3, or (at your option) any later
12 #version.
13
14 #GCC is distributed in the hope that it will be useful, but WITHOUT
15 #ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
16 #FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
17 #for more details.
18
19 #You should have received a copy of the GNU General Public License
20 #along with GCC; see the file COPYING3.  If not see
21 #<http://www.gnu.org/licenses/>.
22
23 # --------------------------------
24 # Initialization and sanity checks
25 # --------------------------------
26
27 AC_PREREQ(2.64)
28 AC_INIT
29 AC_CONFIG_SRCDIR(tree.c)
30 AC_CONFIG_HEADER(auto-host.h:config.in)
31
32 gcc_version=`cat $srcdir/BASE-VER`
33
34 # Determine the host, build, and target systems
35 AC_CANONICAL_BUILD
36 AC_CANONICAL_HOST
37 AC_CANONICAL_TARGET
38
39 # Determine the noncanonical target name, for directory use.
40 ACX_NONCANONICAL_TARGET
41
42 # Determine the target- and build-specific subdirectories
43 GCC_TOPLEV_SUBDIRS
44
45 # Set program_transform_name
46 AC_ARG_PROGRAM
47
48 # Check for bogus environment variables.
49 # Test if LIBRARY_PATH contains the notation for the current directory
50 # since this would lead to problems installing/building glibc.
51 # LIBRARY_PATH contains the current directory if one of the following
52 # is true:
53 # - one of the terminals (":" and ";") is the first or last sign
54 # - two terminals occur directly after each other
55 # - the path contains an element with a dot in it
56 AC_MSG_CHECKING(LIBRARY_PATH variable)
57 changequote(,)dnl
58 case ${LIBRARY_PATH} in
59   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
60     library_path_setting="contains current directory"
61     ;;
62   *)
63     library_path_setting="ok"
64     ;;
65 esac
66 changequote([,])dnl
67 AC_MSG_RESULT($library_path_setting)
68 if test "$library_path_setting" != "ok"; then
69 AC_MSG_ERROR([
70 *** LIBRARY_PATH shouldn't contain the current directory when
71 *** building gcc. Please change the environment variable
72 *** and run configure again.])
73 fi
74
75 # Test if GCC_EXEC_PREFIX contains the notation for the current directory
76 # since this would lead to problems installing/building glibc.
77 # GCC_EXEC_PREFIX contains the current directory if one of the following
78 # is true:
79 # - one of the terminals (":" and ";") is the first or last sign
80 # - two terminals occur directly after each other
81 # - the path contains an element with a dot in it
82 AC_MSG_CHECKING(GCC_EXEC_PREFIX variable)
83 changequote(,)dnl
84 case ${GCC_EXEC_PREFIX} in
85   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
86     gcc_exec_prefix_setting="contains current directory"
87     ;;
88   *)
89     gcc_exec_prefix_setting="ok"
90     ;;
91 esac
92 changequote([,])dnl
93 AC_MSG_RESULT($gcc_exec_prefix_setting)
94 if test "$gcc_exec_prefix_setting" != "ok"; then
95 AC_MSG_ERROR([
96 *** GCC_EXEC_PREFIX shouldn't contain the current directory when
97 *** building gcc. Please change the environment variable
98 *** and run configure again.])
99 fi
100
101 # -----------
102 # Directories
103 # -----------
104
105 # Specify the local prefix
106 local_prefix=
107 AC_ARG_WITH(local-prefix,
108 [  --with-local-prefix=DIR specifies directory to put local include],
109 [case "${withval}" in
110 yes)    AC_MSG_ERROR(bad value ${withval} given for local include directory prefix) ;;
111 no)     ;;
112 *)      local_prefix=$with_local_prefix ;;
113 esac])
114
115 # Default local prefix if it is empty
116 if test x$local_prefix = x; then
117         local_prefix=/usr/local
118 fi
119
120 # Don't set gcc_gxx_include_dir to gxx_include_dir since that's only
121 # passed in by the toplevel make and thus we'd get different behavior
122 # depending on where we built the sources.
123 gcc_gxx_include_dir=
124 # Specify the g++ header file directory
125 AC_ARG_WITH(gxx-include-dir,
126 [  --with-gxx-include-dir=DIR
127                           specifies directory to put g++ header files],
128 [case "${withval}" in
129 yes)    AC_MSG_ERROR(bad value ${withval} given for g++ include directory) ;;
130 no)     ;;
131 *)      gcc_gxx_include_dir=$with_gxx_include_dir ;;
132 esac])
133
134 # This logic must match libstdc++-v3/acinclude.m4:GLIBCXX_EXPORT_INSTALL_INFO.
135 if test x${gcc_gxx_include_dir} = x; then
136   if test x${enable_version_specific_runtime_libs} = xyes; then
137     gcc_gxx_include_dir='${libsubdir}/include/c++'
138   else
139     libstdcxx_incdir='include/c++/$(version)'
140     if test x$host != x$target; then
141        libstdcxx_incdir="$target_alias/$libstdcxx_incdir"
142     fi
143     gcc_gxx_include_dir="\$(libsubdir)/\$(libsubdir_to_prefix)$libstdcxx_incdir"
144   fi
145 fi
146
147 AC_ARG_WITH(cpp_install_dir,
148 [  --with-cpp-install-dir=DIR
149                           install the user visible C preprocessor in DIR
150                           (relative to PREFIX) as well as PREFIX/bin],
151 [if test x$withval = xyes; then
152   AC_MSG_ERROR([option --with-cpp-install-dir requires an argument])
153 elif test x$withval != xno; then
154   cpp_install_dir=$withval
155 fi])
156
157 # We would like to our source tree to be readonly.  However when releases or
158 # pre-releases are generated, the flex/bison generated files as well as the 
159 # various formats of manuals need to be included along with the rest of the
160 # sources.  Therefore we have --enable-generated-files-in-srcdir to do 
161 # just that.
162
163 AC_MSG_CHECKING([whether to place generated files in the source directory])
164   dnl generated-files-in-srcdir is disabled by default
165   AC_ARG_ENABLE(generated-files-in-srcdir, 
166 [  --enable-generated-files-in-srcdir
167                           put copies of generated files in source dir
168                           intended for creating source tarballs for users
169                           without texinfo bison or flex.],
170       generated_files_in_srcdir=$enableval,
171       generated_files_in_srcdir=no)
172
173 AC_MSG_RESULT($generated_files_in_srcdir)
174
175 if test "$generated_files_in_srcdir" = "yes"; then
176   GENINSRC=''
177 else
178   GENINSRC='#'
179 fi
180 AC_SUBST(GENINSRC)
181
182 # -------------------
183 # Find default linker
184 # -------------------
185
186 # With GNU ld
187 AC_ARG_WITH(gnu-ld,
188 [  --with-gnu-ld           arrange to work with GNU ld.],
189 gnu_ld_flag="$with_gnu_ld",
190 gnu_ld_flag=no)
191
192 # With pre-defined ld
193 AC_ARG_WITH(ld,
194 [  --with-ld               arrange to use the specified ld (full pathname)],
195 DEFAULT_LINKER="$with_ld")
196 if test x"${DEFAULT_LINKER+set}" = x"set"; then
197   if test ! -x "$DEFAULT_LINKER"; then
198     AC_MSG_ERROR([cannot execute: $DEFAULT_LINKER: check --with-ld or env. var. DEFAULT_LINKER])
199   elif $DEFAULT_LINKER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
200     gnu_ld_flag=yes
201   fi
202   AC_DEFINE_UNQUOTED(DEFAULT_LINKER,"$DEFAULT_LINKER",
203         [Define to enable the use of a default linker.])
204 fi
205
206 gnu_ld=`if test x"$gnu_ld_flag" = x"yes"; then echo 1; else echo 0; fi`
207 AC_DEFINE_UNQUOTED(HAVE_GNU_LD, $gnu_ld, [Define if using GNU ld.])
208
209 AC_MSG_CHECKING([whether a default linker was specified])
210 if test x"${DEFAULT_LINKER+set}" = x"set"; then
211   if test x"$gnu_ld_flag" = x"no"; then
212     AC_MSG_RESULT([yes ($DEFAULT_LINKER)])
213   else
214     AC_MSG_RESULT([yes ($DEFAULT_LINKER - GNU ld)])
215   fi
216 else
217   AC_MSG_RESULT(no)
218 fi
219
220 # With demangler in GNU ld
221 AC_ARG_WITH(demangler-in-ld,
222 [  --with-demangler-in-ld  try to use demangler in GNU ld.],
223 demangler_in_ld="$with_demangler_in_ld",
224 demangler_in_ld=no)
225
226 # ----------------------
227 # Find default assembler
228 # ----------------------
229
230 # With GNU as
231 AC_ARG_WITH(gnu-as,
232 [  --with-gnu-as           arrange to work with GNU as],
233 gas_flag="$with_gnu_as",
234 gas_flag=no)
235
236 AC_ARG_WITH(as,
237 [  --with-as               arrange to use the specified as (full pathname)],
238 DEFAULT_ASSEMBLER="$with_as")
239 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
240   if test ! -x "$DEFAULT_ASSEMBLER"; then
241     AC_MSG_ERROR([cannot execute: $DEFAULT_ASSEMBLER: check --with-as or env. var. DEFAULT_ASSEMBLER])
242   elif $DEFAULT_ASSEMBLER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
243     gas_flag=yes
244   fi
245   AC_DEFINE_UNQUOTED(DEFAULT_ASSEMBLER,"$DEFAULT_ASSEMBLER",
246         [Define to enable the use of a default assembler.])
247 fi
248
249 gnu_as=`if test x"$gas_flag" = x"yes"; then echo 1; else echo 0; fi`
250 AC_DEFINE_UNQUOTED(HAVE_GNU_AS, $gnu_as, [Define if using GNU as.])
251
252 AC_MSG_CHECKING([whether a default assembler was specified])
253 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
254   if test x"$gas_flag" = x"no"; then
255     AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER)])
256   else
257     AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER - GNU as)])
258   fi
259 else
260   AC_MSG_RESULT(no)
261 fi
262
263 # ---------------
264 # Find C compiler
265 # ---------------
266
267 # If a non-executable a.out is present (e.g. created by GNU as above even if
268 # invoked with -v only), the IRIX 6 native ld just overwrites the existing
269 # file, even when creating an executable, so an execution test fails.
270 # Remove possible default executable files to avoid this.
271 #
272 # FIXME: This really belongs into AC_PROG_CC and can be removed once
273 # Autoconf includes it.
274 rm -f a.out a.exe b.out
275
276 # Find the native compiler
277 AC_PROG_CC
278 AM_PROG_CC_C_O
279 AC_PROG_CXX
280 ACX_PROG_GNAT([-I"$srcdir"/ada])
281
282 # autoconf is lame and doesn't give us any substitution variable for this.
283 if eval "test \"`echo '$ac_cv_prog_cc_'${ac_cc}_c_o`\" = no"; then
284   NO_MINUS_C_MINUS_O=yes
285 else
286   OUTPUT_OPTION='-o $@'
287 fi
288 AC_SUBST(NO_MINUS_C_MINUS_O)
289 AC_SUBST(OUTPUT_OPTION)
290
291 # Remove the -O2: for historical reasons, unless bootstrapping we prefer
292 # optimizations to be activated explicitly by the toplevel.
293 case "$CC" in
294   */prev-gcc/xgcc*) ;;
295   *) CFLAGS=`echo $CFLAGS | sed "s/-O[[s0-9]]* *//" ` ;;
296 esac
297 AC_SUBST(CFLAGS)
298
299 # -------------------------
300 # Check C compiler features
301 # -------------------------
302
303 AC_USE_SYSTEM_EXTENSIONS
304 AC_PROG_CPP
305 AC_C_INLINE
306
307 # sizeof(char) is 1 by definition.
308 AC_CHECK_SIZEOF(void *)
309 AC_CHECK_SIZEOF(short)
310 AC_CHECK_SIZEOF(int)
311 AC_CHECK_SIZEOF(long)
312 AC_CHECK_TYPES([long long], [AC_CHECK_SIZEOF(long long)])
313 AC_CHECK_TYPES([__int64], [AC_CHECK_SIZEOF(__int64)])
314 GCC_STDINT_TYPES
315
316 # ---------------------
317 # Warnings and checking
318 # ---------------------
319
320 # Check $CC warning features (if it's GCC).
321 # We want to use -pedantic, but we don't want warnings about
322 # * 'long long'
323 # * variadic macros
324 # * overlong strings
325 # So, we only use -pedantic if we can disable those warnings.
326
327 ACX_PROG_CC_WARNING_OPTS(
328         m4_quote(m4_do([-W -Wall -Wwrite-strings -Wcast-qual])), [loose_warn])
329 ACX_PROG_CC_WARNING_OPTS(
330         m4_quote(m4_do([-Wstrict-prototypes -Wmissing-prototypes])),
331         [c_loose_warn])
332 ACX_PROG_CC_WARNING_OPTS(
333         m4_quote(m4_do([-Wmissing-format-attribute])), [strict_warn])
334 ACX_PROG_CC_WARNING_OPTS(
335         m4_quote(m4_do([-Wold-style-definition -Wc++-compat])), [c_strict_warn])
336 ACX_PROG_CC_WARNING_ALMOST_PEDANTIC(
337         m4_quote(m4_do([-Wno-long-long -Wno-variadic-macros ], 
338                        [-Wno-overlength-strings])), [strict_warn])
339 ACX_PROG_CC_WARNINGS_ARE_ERRORS([manual], [strict_warn])
340
341 # The above macros do nothing if the compiler is not GCC.  However, the
342 # Makefile has more goo to add other flags, so these variables are used
343 # to enable warnings only for GCC.
344 warn_cflags=
345 warn_cxxflags=
346 if test "x$GCC" = "xyes"; then
347   warn_cflags='$(GCC_WARN_CFLAGS)'
348   warn_cxxflags='$(GCC_WARN_CXXFLAGS)'
349 fi
350 AC_SUBST(warn_cflags)
351 AC_SUBST(warn_cxxflags)
352
353 # Enable expensive internal checks
354 is_release=
355 if test x"`cat $srcdir/DEV-PHASE`" != xexperimental; then
356   is_release=yes
357 fi
358
359 AC_ARG_ENABLE(checking,
360 [  --enable-checking[=LIST]
361                           enable expensive run-time checks.  With LIST,
362                           enable only specific categories of checks.
363                           Categories are: yes,no,all,none,release.
364                           Flags are: assert,df,fold,gc,gcac,gimple,misc,
365                           rtlflag,rtl,runtime,tree,valgrind,types.],
366 [ac_checking_flags="${enableval}"],[
367 # Determine the default checks.
368 if test x$is_release = x ; then
369   ac_checking_flags=yes
370 else
371   ac_checking_flags=release
372 fi])
373 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
374 for check in release $ac_checking_flags
375 do
376         case $check in
377         # these set all the flags to specific states
378         yes)            ac_assert_checking=1 ; ac_checking=1 ; ac_df_checking= ;
379                         ac_fold_checking= ; ac_gc_checking=1 ;
380                         ac_gc_always_collect= ; ac_gimple_checking=1 ; ac_rtl_checking= ;
381                         ac_rtlflag_checking=1 ; ac_runtime_checking=1 ;
382                         ac_tree_checking=1 ; ac_valgrind_checking= ;
383                         ac_types_checking=1 ;;
384         no|none)        ac_assert_checking= ; ac_checking= ; ac_df_checking= ;
385                         ac_fold_checking= ; ac_gc_checking= ;
386                         ac_gc_always_collect= ; ac_gimple_checking= ; ac_rtl_checking= ;
387                         ac_rtlflag_checking= ; ac_runtime_checking= ;
388                         ac_tree_checking= ; ac_valgrind_checking= ;
389                         ac_types_checking= ;;
390         all)            ac_assert_checking=1 ; ac_checking=1 ; ac_df_checking=1 ;
391                         ac_fold_checking=1 ; ac_gc_checking=1 ;
392                         ac_gc_always_collect=1 ; ac_gimple_checking=1 ; ac_rtl_checking=1 ;
393                         ac_rtlflag_checking=1 ; ac_runtime_checking=1 ;
394                         ac_tree_checking=1 ; ac_valgrind_checking= ;
395                         ac_types_checking=1 ;;
396         release)        ac_assert_checking=1 ; ac_checking= ; ac_df_checking= ;
397                         ac_fold_checking= ; ac_gc_checking= ;
398                         ac_gc_always_collect= ; ac_gimple_checking= ; ac_rtl_checking= ;
399                         ac_rtlflag_checking= ; ac_runtime_checking=1 ;
400                         ac_tree_checking= ; ac_valgrind_checking= ;
401                         ac_types_checking= ;;
402         # these enable particular checks
403         assert)         ac_assert_checking=1 ;;
404         df)             ac_df_checking=1 ;;
405         fold)           ac_fold_checking=1 ;;
406         gc)             ac_gc_checking=1 ;;
407         gcac)           ac_gc_always_collect=1 ;;
408         gimple)         ac_gimple_checking=1 ;;
409         misc)           ac_checking=1 ;;
410         rtl)            ac_rtl_checking=1 ;;
411         rtlflag)        ac_rtlflag_checking=1 ;;
412         runtime)        ac_runtime_checking=1 ;;
413         tree)           ac_tree_checking=1 ;;
414         types)          ac_types_checking=1 ;;
415         valgrind)       ac_valgrind_checking=1 ;;
416         *)      AC_MSG_ERROR(unknown check category $check) ;;
417         esac
418 done
419 IFS="$ac_save_IFS"
420
421 nocommon_flag=""
422 if test x$ac_checking != x ; then
423   AC_DEFINE(ENABLE_CHECKING, 1,
424 [Define if you want more run-time sanity checks.  This one gets a grab
425    bag of miscellaneous but relatively cheap checks.])
426   nocommon_flag=-fno-common
427 fi
428 AC_SUBST(nocommon_flag)
429 if test x$ac_df_checking != x ; then
430   AC_DEFINE(ENABLE_DF_CHECKING, 1,
431 [Define if you want more run-time sanity checks for dataflow.])
432 fi
433 if test x$ac_assert_checking != x ; then
434   AC_DEFINE(ENABLE_ASSERT_CHECKING, 1,
435 [Define if you want assertions enabled.  This is a cheap check.])
436 fi
437 if test x$ac_gimple_checking != x ; then
438   AC_DEFINE(ENABLE_GIMPLE_CHECKING, 1,
439 [Define if you want operations on GIMPLE (the basic data structure of
440 the high-level optimizers) to be checked for dynamic type safety at
441 runtime.  This is moderately expensive.])
442 fi
443 GCC_TARGET_TEMPLATE(ENABLE_RUNTIME_CHECKING)
444 if test x$ac_runtime_checking != x ; then
445   AC_DEFINE(ENABLE_RUNTIME_CHECKING, 1,
446 [Define if you want runtime assertions enabled.  This is a cheap check.])
447 fi
448 if test x$ac_tree_checking != x ; then
449   AC_DEFINE(ENABLE_TREE_CHECKING, 1,
450 [Define if you want all operations on trees (the basic data
451    structure of the front ends) to be checked for dynamic type safety
452    at runtime.  This is moderately expensive.  The tree browser debugging
453    routines will also be enabled by this option.
454    ])
455   TREEBROWSER=tree-browser.o
456 fi
457 if test x$ac_types_checking != x ; then
458   AC_DEFINE(ENABLE_TYPES_CHECKING, 1,
459 [Define if you want all gimple types to be verified after gimplifiation.
460    This is cheap.
461    ])
462 fi
463 AC_SUBST(TREEBROWSER)
464 if test x$ac_rtl_checking != x ; then
465   AC_DEFINE(ENABLE_RTL_CHECKING, 1,
466 [Define if you want all operations on RTL (the basic data structure
467    of the optimizer and back end) to be checked for dynamic type safety
468    at runtime.  This is quite expensive.])
469 fi
470 if test x$ac_rtlflag_checking != x ; then
471   AC_DEFINE(ENABLE_RTL_FLAG_CHECKING, 1,
472 [Define if you want RTL flag accesses to be checked against the RTL
473    codes that are supported for each access macro.  This is relatively
474    cheap.])
475 fi
476 if test x$ac_gc_checking != x ; then
477   AC_DEFINE(ENABLE_GC_CHECKING, 1,
478 [Define if you want the garbage collector to do object poisoning and
479    other memory allocation checks.  This is quite expensive.])
480 fi
481 if test x$ac_gc_always_collect != x ; then
482   AC_DEFINE(ENABLE_GC_ALWAYS_COLLECT, 1,
483 [Define if you want the garbage collector to operate in maximally
484    paranoid mode, validating the entire heap and collecting garbage at
485    every opportunity.  This is extremely expensive.])
486 fi
487 if test x$ac_fold_checking != x ; then
488   AC_DEFINE(ENABLE_FOLD_CHECKING, 1,
489 [Define if you want fold checked that it never destructs its argument.
490    This is quite expensive.])
491 fi
492 valgrind_path_defines=
493 valgrind_command=
494
495 dnl # This check AC_REQUIREs various stuff, so it *must not* be inside
496 dnl # an if statement.  This was the source of very frustrating bugs
497 dnl # in converting to autoconf 2.5x!
498 AC_CHECK_HEADER(valgrind.h, have_valgrind_h=yes, have_valgrind_h=no)
499
500 if test x$ac_valgrind_checking != x ; then
501   # It is certainly possible that there's valgrind but no valgrind.h.
502   # GCC relies on making annotations so we must have both.
503   AC_MSG_CHECKING(for VALGRIND_DISCARD in <valgrind/memcheck.h>)
504   AC_PREPROC_IFELSE([AC_LANG_SOURCE(
505     [[#include <valgrind/memcheck.h>
506 #ifndef VALGRIND_DISCARD
507 #error VALGRIND_DISCARD not defined
508 #endif]])],
509   [gcc_cv_header_valgrind_memcheck_h=yes],
510   [gcc_cv_header_valgrind_memcheck_h=no])
511   AC_MSG_RESULT($gcc_cv_header_valgrind_memcheck_h)
512   AC_MSG_CHECKING(for VALGRIND_DISCARD in <memcheck.h>)
513   AC_PREPROC_IFELSE([AC_LANG_SOURCE(
514     [[#include <memcheck.h>
515 #ifndef VALGRIND_DISCARD
516 #error VALGRIND_DISCARD not defined
517 #endif]])],
518   [gcc_cv_header_memcheck_h=yes],
519   [gcc_cv_header_memcheck_h=no])
520   AC_MSG_RESULT($gcc_cv_header_memcheck_h)
521   AM_PATH_PROG_WITH_TEST(valgrind_path, valgrind,
522         [$ac_dir/$ac_word --version | grep valgrind- >/dev/null 2>&1])
523   if test "x$valgrind_path" = "x" \
524     || (test $have_valgrind_h = no \
525         && test $gcc_cv_header_memcheck_h = no \
526         && test $gcc_cv_header_valgrind_memcheck_h = no); then
527         AC_MSG_ERROR([*** Can't find both valgrind and valgrind/memcheck.h, memcheck.h or valgrind.h])
528   fi
529   valgrind_path_defines=-DVALGRIND_PATH='\"'$valgrind_path'\"'
530   valgrind_command="$valgrind_path -q"
531   AC_DEFINE(ENABLE_VALGRIND_CHECKING, 1,
532 [Define if you want to run subprograms and generated programs
533    through valgrind (a memory checker).  This is extremely expensive.])
534   if test $gcc_cv_header_valgrind_memcheck_h = yes; then
535     AC_DEFINE(HAVE_VALGRIND_MEMCHECK_H, 1,
536         [Define if valgrind's valgrind/memcheck.h header is installed.])
537   fi
538   if test $gcc_cv_header_memcheck_h = yes; then
539     AC_DEFINE(HAVE_MEMCHECK_H, 1,
540         [Define if valgrind's memcheck.h header is installed.])
541   fi
542 fi
543 AC_SUBST(valgrind_path_defines)
544 AC_SUBST(valgrind_command)
545
546 # Enable code coverage collection
547 AC_ARG_ENABLE(coverage,
548 [  --enable-coverage[=LEVEL]
549                           enable compiler's code coverage collection.
550                           Use to measure compiler performance and locate
551                           unused parts of the compiler. With LEVEL, specify
552                           optimization. Values are opt, noopt,
553                           default is noopt],
554 [case "${enableval}" in
555   yes|noopt)
556     coverage_flags="-fprofile-arcs -ftest-coverage -frandom-seed=\$@ -O0"
557     ;;
558   opt)
559     coverage_flags="-fprofile-arcs -ftest-coverage -frandom-seed=\$@ -O2"
560     ;;
561   no)
562     # a.k.a. --disable-coverage
563     coverage_flags=""
564     ;;
565   *)
566     AC_MSG_ERROR(unknown coverage setting $enableval)
567     ;;
568 esac],
569 [coverage_flags=""])
570 AC_SUBST(coverage_flags)
571
572 AC_ARG_ENABLE(gather-detailed-mem-stats, 
573 [  --enable-gather-detailed-mem-stats         enable detailed memory allocation stats gathering], [],
574 [enable_gather_detailed_mem_stats=no])
575 if test x$enable_gather_detailed_mem_stats = xyes ; then
576   AC_DEFINE(GATHER_STATISTICS, 1,
577         [Define to enable detailed memory allocation stats gathering.])
578 fi
579
580 # -------------------------------
581 # Miscenalleous configure options
582 # -------------------------------
583
584 # See if we are building gcc with C++.
585 AC_ARG_ENABLE(build-with-cxx,
586 [  --enable-build-with-cxx build with C++ compiler instead of C compiler],
587 ENABLE_BUILD_WITH_CXX=$enableval,
588 ENABLE_BUILD_WITH_CXX=no)
589 AC_SUBST(ENABLE_BUILD_WITH_CXX)
590
591 # With stabs
592 AC_ARG_WITH(stabs,
593 [  --with-stabs            arrange to use stabs instead of host debug format],
594 stabs="$with_stabs",
595 stabs=no)
596
597 # Determine whether or not multilibs are enabled.
598 AC_ARG_ENABLE(multilib,
599 [  --enable-multilib       enable library support for multiple ABIs],
600 [], [enable_multilib=yes])
601 AC_SUBST(enable_multilib)
602
603 # Enable __cxa_atexit for C++.
604 AC_ARG_ENABLE(__cxa_atexit,
605 [  --enable-__cxa_atexit   enable __cxa_atexit for C++],
606 [], [])
607
608 # Enable C extension for decimal float if target supports it.
609 GCC_AC_ENABLE_DECIMAL_FLOAT([$target])
610
611 dfp=`if test $enable_decimal_float != no; then echo 1; else echo 0; fi`
612 AC_DEFINE_UNQUOTED(ENABLE_DECIMAL_FLOAT, $dfp,
613 [Define to 1 to enable decimal float extension to C.])
614
615 bid=`if test $enable_decimal_float = bid; then echo 1; else echo 0; fi`
616 AC_DEFINE_UNQUOTED(ENABLE_DECIMAL_BID_FORMAT, $bid,
617 [Define to 1 to specify that we are using the BID decimal floating
618 point format instead of DPD])
619
620 # Enable C extension for fixed-point arithmetic.
621 AC_ARG_ENABLE(fixed-point,
622 [  --enable-fixed-point    enable fixed-point arithmetic extension to C],
623 [
624 ],
625 [
626   case $target in
627     mips*-*-*)
628       case $host in
629         mips*-sgi-irix*)
630           AC_MSG_WARN(fixed-point is not supported on IRIX, ignored)
631           enable_fixed_point=no
632           ;;
633         *)
634           enable_fixed_point=yes
635           ;;
636       esac
637       ;;
638     *)
639       AC_MSG_WARN(fixed-point is not supported for this target, ignored)
640       enable_fixed_point=no
641       ;;
642   esac
643 ])
644 AC_SUBST(enable_fixed_point)
645
646 fixedpoint=`if test $enable_fixed_point = yes; then echo 1; else echo 0; fi`
647 AC_DEFINE_UNQUOTED(ENABLE_FIXED_POINT, $fixedpoint,
648 [Define to 1 to enable fixed-point arithmetic extension to C.])
649
650 # Enable threads
651 # Pass with no value to take the default
652 # Pass with a value to specify a thread package
653 AC_ARG_ENABLE(threads,
654 [  --enable-threads        enable thread usage for target GCC
655   --enable-threads=LIB    use LIB thread package for target GCC],,
656 [enable_threads=''])
657
658 AC_ARG_ENABLE(tls,
659 [  --enable-tls            enable or disable generation of tls code
660                           overriding the assembler check for tls support],
661 [
662   case $enable_tls in
663     yes | no) ;;
664     *) AC_MSG_ERROR(['$enable_tls' is an invalid value for --enable-tls.
665 Valid choices are 'yes' and 'no'.]) ;;
666   esac
667 ], [enable_tls=''])
668
669 AC_ARG_ENABLE(objc-gc,
670 [  --enable-objc-gc       enable the use of Boehm's garbage collector with
671                           the GNU Objective-C runtime],
672 if test x$enable_objc_gc = xno; then
673         objc_boehm_gc=''
674 else
675         objc_boehm_gc=1
676 fi,
677 objc_boehm_gc='')
678
679 AC_ARG_WITH(dwarf2,
680 [  --with-dwarf2           force the default debug format to be DWARF 2],
681 dwarf2="$with_dwarf2",
682 dwarf2=no)
683
684 AC_ARG_ENABLE(shared,
685 [  --disable-shared        don't provide a shared libgcc],
686 [
687   case $enable_shared in
688   yes | no) ;;
689   *)
690     enable_shared=no
691     IFS="${IFS=         }"; ac_save_ifs="$IFS"; IFS="${IFS}:,"
692     for pkg in $enableval; do
693       if test "X$pkg" = "Xgcc" || test "X$pkg" = "Xlibgcc"; then
694         enable_shared=yes
695       fi
696     done
697     IFS="$ac_save_ifs"
698     ;;
699   esac
700 ], [enable_shared=yes])
701 AC_SUBST(enable_shared)
702
703 AC_ARG_WITH(build-sysroot, 
704   [  --with-build-sysroot=sysroot
705                           use sysroot as the system root during the build])
706
707 AC_ARG_WITH(sysroot,
708 [  --with-sysroot[=DIR] Search for usr/lib, usr/include, et al, within DIR.],
709 [
710  case ${with_sysroot} in
711  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_noncanonical}/sys-root' ;;
712  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
713  esac
714    
715  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
716  CROSS_SYSTEM_HEADER_DIR='$(TARGET_SYSTEM_ROOT)$${sysroot_headers_suffix}$(NATIVE_SYSTEM_HEADER_DIR)'
717         
718  if test "x$prefix" = xNONE; then
719   test_prefix=/usr/local
720  else
721   test_prefix=$prefix
722  fi
723  if test "x$exec_prefix" = xNONE; then
724   test_exec_prefix=$test_prefix
725  else
726   test_exec_prefix=$exec_prefix
727  fi
728  case ${TARGET_SYSTEM_ROOT} in
729  "${test_prefix}"|"${test_prefix}/"*|\
730  "${test_exec_prefix}"|"${test_exec_prefix}/"*|\
731  '${prefix}'|'${prefix}/'*|\
732  '${exec_prefix}'|'${exec_prefix}/'*)
733    t="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE"
734    TARGET_SYSTEM_ROOT_DEFINE="$t"
735    ;;
736  esac
737 ], [
738  TARGET_SYSTEM_ROOT=
739  TARGET_SYSTEM_ROOT_DEFINE=
740  CROSS_SYSTEM_HEADER_DIR='$(gcc_tooldir)/sys-include'
741 ])
742 AC_SUBST(TARGET_SYSTEM_ROOT)
743 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
744 AC_SUBST(CROSS_SYSTEM_HEADER_DIR)
745
746 AC_ARG_WITH(specs,
747   [AS_HELP_STRING([--with-specs=SPECS],
748                   [add SPECS to driver command-line processing])],
749   [CONFIGURE_SPECS=$withval],
750   [CONFIGURE_SPECS=]
751 )
752 AC_SUBST(CONFIGURE_SPECS)
753
754 # Build with intermodule optimisations
755 AC_ARG_ENABLE(intermodule,
756 [  --enable-intermodule    build the compiler in one step],
757 [case ${enable_intermodule} in
758   yes) onestep="-onestep";;
759   *) onestep="";;
760 esac],
761 [onestep=""])
762 AC_SUBST(onestep)
763
764 ACX_PKGVERSION([GCC])
765 ACX_BUGURL([http://gcc.gnu.org/bugs.html])
766
767 # Sanity check enable_languages in case someone does not run the toplevel
768 # configure # script.
769 AC_ARG_ENABLE(languages,
770 [  --enable-languages=LIST specify which front-ends to build],
771 [case ,${enable_languages}, in
772        ,,|,yes,)
773                 # go safe -- we cannot be much sure without the toplevel
774                 # configure's
775                 # analysis of which target libs are present and usable
776                 enable_languages=c
777                 ;;
778          *,all,*)
779                 AC_MSG_ERROR([only the toplevel supports --enable-languages=all])
780                 ;;
781         *,c,*)
782                 ;;
783         *)
784                 enable_languages=c,${enable_languages}
785                 ;;
786 esac],
787 [enable_languages=c])
788
789 AC_ARG_WITH(multilib-list,
790 [  --with-multilib-list    Select multilibs (SH only)],
791 :,
792 with_multilib_list=default)
793
794 # -------------------------
795 # Checks for other programs
796 # -------------------------
797
798 AC_PROG_MAKE_SET
799
800 # Find some useful tools
801 AC_PROG_AWK
802 # We need awk to create options.c and options.h.
803 # Bail out if it's missing.
804 case ${AWK} in
805   "") AC_MSG_ERROR([can't build without awk, bailing out]) ;;
806 esac
807
808 gcc_AC_PROG_LN_S
809 ACX_PROG_LN($LN_S)
810 AC_PROG_RANLIB
811 case "${host}" in
812 *-*-darwin*)
813   # By default, the Darwin ranlib will not treat common symbols as
814   # definitions when  building the archive table of contents.  Other 
815   # ranlibs do that; pass an option to the Darwin ranlib that makes
816   # it behave similarly.
817   ranlib_flags="-c" 
818   ;;
819 *)
820   ranlib_flags=""
821 esac
822 AC_SUBST(ranlib_flags)
823      
824 gcc_AC_PROG_INSTALL
825
826 # See if cmp has --ignore-initial.
827 gcc_AC_PROG_CMP_IGNORE_INITIAL
828
829 # See if we have the mktemp command.
830 AC_CHECK_PROG(have_mktemp_command, mktemp, yes, no)
831
832 # See if makeinfo has been installed and is modern enough
833 # that we can use it.
834 ACX_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
835   [GNU texinfo.* \([0-9][0-9.]*\)],
836   [4.[7-9]*|4.[1-9][0-9]*|[5-9]*|[1-9][0-9]*])
837 if test $gcc_cv_prog_makeinfo_modern = no; then
838   AC_MSG_WARN([
839 *** Makeinfo is missing or too old.
840 *** Info documentation will not be built.])
841   BUILD_INFO=
842 else
843   BUILD_INFO=info
844 fi
845 AC_SUBST(BUILD_INFO)
846
847 # Is pod2man recent enough to regenerate manpages?
848 AC_MSG_CHECKING([for recent Pod::Man])
849 if (perl -e 'use 1.10 Pod::Man') >/dev/null 2>&1; then
850   AC_MSG_RESULT(yes)
851   GENERATED_MANPAGES=generated-manpages
852 else
853   AC_MSG_RESULT(no)
854   GENERATED_MANPAGES=
855 fi
856 AC_SUBST(GENERATED_MANPAGES)
857
858 MISSING="${CONFIG_SHELL-/bin/sh} $ac_aux_dir/missing"
859
860 # How about lex?
861 dnl Don't use AC_PROG_LEX; we insist on flex.
862 dnl LEXLIB is not useful in gcc.
863 AC_CHECK_PROGS([FLEX], flex, [$MISSING flex])
864
865 # Bison?
866 AC_CHECK_PROGS([BISON], bison, [$MISSING bison])
867
868 # Binutils are not build modules, unlike bison/flex/makeinfo.  So we
869 # check for build == host before using them.
870
871 # NM
872 if test x${build} = x${host} && test -f $srcdir/../binutils/nm.c \
873   && test -d ../binutils ; then
874   NM='${objdir}/../binutils/nm-new'
875 else
876   AC_CHECK_PROG(NM, nm, nm, ${CONFIG_SHELL-/bin/sh} ${srcdir}/../missing nm)
877 fi
878
879 # AR
880 if test x${build} = x${host} && test -f $srcdir/../binutils/ar.c \
881   && test -d ../binutils ; then
882   AR='${objdir}/../binutils/ar'
883 else
884   AC_CHECK_PROG(AR, ar, ar, ${CONFIG_SHELL-/bin/sh} ${srcdir}/../missing ar)
885 fi
886
887
888 # --------------------
889 # Checks for C headers
890 # --------------------
891
892 # Need to reject headers which give warnings, so that the -Werror bootstrap
893 # works later. *sigh*  This needs to come before all header checks.
894 AC_PROG_CPP_WERROR
895
896 AC_HEADER_STDC
897 AC_HEADER_TIME
898 ACX_HEADER_STRING
899 AC_HEADER_SYS_WAIT
900 AC_CHECK_HEADERS(limits.h stddef.h string.h strings.h stdlib.h time.h iconv.h \
901                  fcntl.h unistd.h sys/file.h sys/time.h sys/mman.h \
902                  sys/resource.h sys/param.h sys/times.h sys/stat.h \
903                  direct.h malloc.h langinfo.h ldfcn.h locale.h wchar.h)
904
905 # Check for thread headers.
906 AC_CHECK_HEADER(thread.h, [have_thread_h=yes], [have_thread_h=])
907 AC_CHECK_HEADER(pthread.h, [have_pthread_h=yes], [have_pthread_h=])
908
909 # These tests can't be done till we know if we have limits.h.
910 gcc_AC_C_CHAR_BIT
911 AC_C_BIGENDIAN
912
913 # --------
914 # UNSORTED
915 # --------
916
917
918 # These libraries may be used by collect2.
919 # We may need a special search path to get them linked.
920 AC_CACHE_CHECK(for collect2 libraries, gcc_cv_collect2_libs,
921 [save_LIBS="$LIBS"
922 for libs in '' -lld -lmld \
923                 '-L/usr/lib/cmplrs/cc2.11 -lmld' \
924                 '-L/usr/lib/cmplrs/cc3.11 -lmld'
925 do
926         LIBS="$libs"
927         AC_TRY_LINK_FUNC(ldopen,
928                 [gcc_cv_collect2_libs="$libs"; break])
929 done
930 LIBS="$save_LIBS"
931 test -z "$gcc_cv_collect2_libs" && gcc_cv_collect2_libs='none required'])
932 case $gcc_cv_collect2_libs in
933         "none required")        ;;
934         *)      COLLECT2_LIBS=$gcc_cv_collect2_libs ;;
935 esac
936 AC_SUBST(COLLECT2_LIBS)
937
938 # When building Ada code on Alpha, we need exc_resume which is usually in
939 # -lexc.  So test for it.
940 save_LIBS="$LIBS"
941 LIBS=
942 AC_SEARCH_LIBS(exc_resume, exc)
943 GNAT_LIBEXC="$LIBS"
944 LIBS="$save_LIBS"
945 AC_SUBST(GNAT_LIBEXC)
946
947 # Some systems put ldexp and frexp in libm instead of libc; assume
948 # they're both in the same place.  jcf-dump needs them.
949 save_LIBS="$LIBS"
950 LIBS=
951 AC_SEARCH_LIBS(ldexp, m)
952 LDEXP_LIB="$LIBS"
953 LIBS="$save_LIBS"
954 AC_SUBST(LDEXP_LIB)
955
956 # Use <inttypes.h> only if it exists,
957 # doesn't clash with <sys/types.h>, and declares intmax_t.
958 AC_MSG_CHECKING(for inttypes.h)
959 AC_CACHE_VAL(gcc_cv_header_inttypes_h,
960 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
961 [[#include <sys/types.h>
962 #include <inttypes.h>]],
963   [[intmax_t i = -1;]])],
964   [gcc_cv_header_inttypes_h=yes],
965   [gcc_cv_header_inttypes_h=no])])
966 AC_MSG_RESULT($gcc_cv_header_inttypes_h)
967 if test $gcc_cv_header_inttypes_h = yes; then
968   AC_DEFINE(HAVE_INTTYPES_H, 1,
969         [Define if you have a working <inttypes.h> header file.])
970 fi
971
972 dnl Disabled until we have a complete test for buggy enum bitfields.
973 dnl gcc_AC_C_ENUM_BF_UNSIGNED
974
975 define(gcc_UNLOCKED_FUNCS, clearerr_unlocked feof_unlocked dnl
976   ferror_unlocked fflush_unlocked fgetc_unlocked fgets_unlocked dnl
977   fileno_unlocked fprintf_unlocked fputc_unlocked fputs_unlocked dnl
978   fread_unlocked fwrite_unlocked getchar_unlocked getc_unlocked dnl
979   putchar_unlocked putc_unlocked)
980 AC_CHECK_FUNCS(times clock kill getrlimit setrlimit atoll atoq \
981         sysconf strsignal getrusage nl_langinfo \
982         gettimeofday mbstowcs wcswidth mmap mincore setlocale \
983         gcc_UNLOCKED_FUNCS)
984
985 save_CPPFLAGS="$CPPFLAGS"
986 save_LIBS="$LIBS"
987 LIBS="$LIBS $LIBELFLIBS"
988 AC_CHECK_FUNCS(elf_getshdrstrndx,,
989   [AC_CHECK_FUNCS(elf_getshstrndx,
990     [AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdlib.h>
991 #include <libelf.h>
992 int main()
993 {
994   return elf_getshstrndx (NULL, 0) == 0;
995 }]])], AC_DEFINE(HAVE_ELF_GETSHSTRNDX_GABI, 1,
996         [Define if elf_getshstrndx has gABI conformant return values.]))])]
997   )
998 LIBS="$save_LIBS"
999 CPPFLAGS="$save_CPPFLAGS"
1000
1001 if test x$ac_cv_func_mbstowcs = xyes; then
1002   AC_CACHE_CHECK(whether mbstowcs works, gcc_cv_func_mbstowcs_works,
1003 [    AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdlib.h>
1004 int main()
1005 {
1006   mbstowcs(0, "", 0);
1007   return 0;
1008 }]])],
1009     [gcc_cv_func_mbstowcs_works=yes],
1010     [gcc_cv_func_mbstowcs_works=no],
1011     [gcc_cv_func_mbstowcs_works=yes])])
1012   if test x$gcc_cv_func_mbstowcs_works = xyes; then
1013     AC_DEFINE(HAVE_WORKING_MBSTOWCS, 1,
1014   [Define this macro if mbstowcs does not crash when its
1015    first argument is NULL.])
1016   fi
1017 fi
1018
1019 AC_CHECK_TYPE(ssize_t, int)
1020 AC_CHECK_TYPE(caddr_t, char *)
1021
1022 gcc_AC_FUNC_MMAP_BLACKLIST
1023
1024 case "${host}" in
1025 *-*-*vms*)
1026   # Under VMS, vfork works very differently than on Unix. The standard test 
1027   # won't work, and it isn't easily adaptable. It makes more sense to
1028   # just force it.
1029   ac_cv_func_vfork_works=yes
1030   ;;
1031 esac
1032 AC_FUNC_FORK
1033
1034 AM_ICONV
1035 # Until we have in-tree GNU iconv:
1036 LIBICONV_DEP=
1037 AC_SUBST(LIBICONV_DEP)
1038
1039 AM_LC_MESSAGES
1040
1041 AM_LANGINFO_CODESET
1042
1043 # We will need to find libiberty.h and ansidecl.h
1044 saved_CFLAGS="$CFLAGS"
1045 CFLAGS="$CFLAGS -I${srcdir} -I${srcdir}/../include"
1046 gcc_AC_CHECK_DECLS(getenv atol asprintf sbrk abort atof getcwd getwd \
1047         strsignal strstr strverscmp \
1048         errno snprintf vsnprintf vasprintf malloc realloc calloc \
1049         free basename getopt clock getpagesize gcc_UNLOCKED_FUNCS, , ,[
1050 #include "ansidecl.h"
1051 #include "system.h"])
1052
1053 gcc_AC_CHECK_DECLS(getrlimit setrlimit getrusage, , ,[
1054 #include "ansidecl.h"
1055 #include "system.h"
1056 #ifdef HAVE_SYS_RESOURCE_H
1057 #include <sys/resource.h>
1058 #endif
1059 ])
1060
1061 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1062 #include "ansidecl.h"
1063 #include "system.h"
1064 #ifdef HAVE_SYS_RESOURCE_H
1065 #include <sys/resource.h>
1066 #endif
1067 ]], [[rlim_t l = 0;]])],[],[AC_DEFINE([rlim_t],[long],
1068 [Define to `long' if <sys/resource.h> doesn't define.])])
1069
1070 # On AIX 5.2, <ldfcn.h> conflicts with <fcntl.h>, as both define incompatible
1071 # FREAD and FWRITE macros.  Fortunately, for GCC's single usage of ldgetname
1072 # in collect2.c, <fcntl.h> isn't visible, but the configure test below needs
1073 # to undef these macros to get the correct value for HAVE_DECL_LDGETNAME.
1074 gcc_AC_CHECK_DECLS(ldgetname, , ,[
1075 #include "ansidecl.h"
1076 #include "system.h"
1077 #ifdef HAVE_LDFCN_H
1078 #undef FREAD
1079 #undef FWRITE
1080 #include <ldfcn.h>
1081 #endif
1082 ])
1083
1084 gcc_AC_CHECK_DECLS(times, , ,[
1085 #include "ansidecl.h"
1086 #include "system.h"
1087 #ifdef HAVE_SYS_TIMES_H
1088 #include <sys/times.h>
1089 #endif
1090 ])
1091
1092 gcc_AC_CHECK_DECLS(sigaltstack, , ,[
1093 #include "ansidecl.h"
1094 #include "system.h"
1095 #include <signal.h>
1096 ])
1097
1098 # More time-related stuff.
1099 AC_CACHE_CHECK(for struct tms, ac_cv_struct_tms, [
1100 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1101 #include "ansidecl.h"
1102 #include "system.h"
1103 #ifdef HAVE_SYS_TIMES_H
1104 #include <sys/times.h>
1105 #endif
1106 ]], [[struct tms tms;]])],[ac_cv_struct_tms=yes],[ac_cv_struct_tms=no])])
1107 if test $ac_cv_struct_tms = yes; then
1108   AC_DEFINE(HAVE_STRUCT_TMS, 1,
1109   [Define if <sys/times.h> defines struct tms.])
1110 fi
1111
1112 # use gcc_cv_* here because this doesn't match the behavior of AC_CHECK_TYPE.
1113 # revisit after autoconf 2.50.
1114 AC_CACHE_CHECK(for clock_t, gcc_cv_type_clock_t, [
1115 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1116 #include "ansidecl.h"
1117 #include "system.h"
1118 ]], [[clock_t x;]])],[gcc_cv_type_clock_t=yes],[gcc_cv_type_clock_t=no])])
1119 if test $gcc_cv_type_clock_t = yes; then
1120   AC_DEFINE(HAVE_CLOCK_T, 1,
1121   [Define if <time.h> defines clock_t.])
1122 fi
1123
1124 # Restore CFLAGS from before the gcc_AC_NEED_DECLARATIONS tests.
1125 CFLAGS="$saved_CFLAGS"
1126
1127 gcc_AC_INITFINI_ARRAY
1128
1129 # mkdir takes a single argument on some systems. 
1130 gcc_AC_FUNC_MKDIR_TAKES_ONE_ARG
1131
1132 # File extensions
1133 manext='.1'
1134 objext='.o'
1135 AC_SUBST(manext)
1136 AC_SUBST(objext)
1137
1138 # With Setjmp/Longjmp based exception handling.
1139 AC_ARG_ENABLE(sjlj-exceptions,
1140 [  --enable-sjlj-exceptions
1141                           arrange to use setjmp/longjmp exception handling],
1142 [case $target in
1143   *-*-hpux10*)
1144     if test $enableval != yes; then
1145       AC_MSG_WARN([dwarf2 exceptions not supported, sjlj exceptions forced])
1146       enableval=yes
1147     fi
1148     ;;
1149 esac
1150 force_sjlj_exceptions=yes],
1151 [case $target in
1152   *-*-hpux10*)
1153     force_sjlj_exceptions=yes
1154     enableval=yes
1155     ;;
1156   *)
1157     force_sjlj_exceptions=no
1158     ;;
1159 esac])
1160 if test $force_sjlj_exceptions = yes; then
1161   sjlj=`if test $enableval = yes; then echo 1; else echo 0; fi`
1162   AC_DEFINE_UNQUOTED(CONFIG_SJLJ_EXCEPTIONS, $sjlj,
1163     [Define 0/1 to force the choice for exception handling model.])
1164 fi
1165
1166 # For platforms with the unwind ABI which includes an unwind library,
1167 # libunwind, we can choose to use the system libunwind.
1168 # config.gcc also contains tests of with_system_libunwind.
1169 GCC_CHECK_UNWIND_GETIPINFO
1170
1171 # --------------------------------------------------------
1172 # Build, host, and target specific configuration fragments
1173 # --------------------------------------------------------
1174
1175 # Collect build-machine-specific information.
1176 . ${srcdir}/config.build
1177
1178 # Collect host-machine-specific information.
1179 . ${srcdir}/config.host
1180
1181 target_gtfiles=
1182
1183 # Collect target-machine-specific information.
1184 . ${srcdir}/config.gcc
1185
1186 extra_objs="${host_extra_objs} ${extra_objs}"
1187 extra_gcc_objs="${host_extra_gcc_objs} ${extra_gcc_objs}"
1188
1189 # Default the target-machine variables that were not explicitly set.
1190 if test x"$tm_file" = x
1191 then tm_file=$cpu_type/$cpu_type.h; fi
1192
1193 if test x"$extra_headers" = x
1194 then extra_headers=; fi
1195
1196 if test x$md_file = x
1197 then md_file=$cpu_type/$cpu_type.md; fi
1198
1199 if test x$out_file = x
1200 then out_file=$cpu_type/$cpu_type.c; fi
1201
1202 if test x"$tmake_file" = x
1203 then tmake_file=$cpu_type/t-$cpu_type
1204 fi
1205
1206 if test x"$dwarf2" = xyes
1207 then tm_file="$tm_file tm-dwarf2.h"
1208 fi
1209
1210 # Say what files are being used for the output code and MD file.
1211 echo "Using \`$srcdir/config/$out_file' for machine-specific logic."
1212 echo "Using \`$srcdir/config/$md_file' as machine description file."
1213
1214 # If any of the xm_file variables contain nonexistent files, warn
1215 # about them and drop them.
1216
1217 bx=
1218 for x in $build_xm_file; do
1219   if    test -f $srcdir/config/$x
1220   then      bx="$bx $x"
1221   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1222   fi
1223 done
1224 build_xm_file="$bx"
1225
1226 hx=
1227 for x in $host_xm_file; do
1228   if    test -f $srcdir/config/$x
1229   then      hx="$hx $x"
1230   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1231   fi
1232 done
1233 host_xm_file="$hx"
1234
1235 tx=
1236 for x in $xm_file; do
1237   if    test -f $srcdir/config/$x
1238   then      tx="$tx $x"
1239   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1240   fi
1241 done
1242 xm_file="$tx"
1243
1244 count=a
1245 for f in $tm_file; do
1246         count=${count}x
1247 done
1248 if test $count = ax; then
1249         echo "Using \`$srcdir/config/$tm_file' as target machine macro file."
1250 else
1251         echo "Using the following target machine macro files:"
1252         for f in $tm_file; do
1253                 echo "  $srcdir/config/$f"
1254         done
1255 fi
1256
1257 if test x$need_64bit_hwint = xyes; then
1258         AC_DEFINE(NEED_64BIT_HOST_WIDE_INT, 1,
1259 [Define to 1 if HOST_WIDE_INT must be 64 bits wide (see hwint.h).])
1260 fi
1261
1262 if test x$use_long_long_for_widest_fast_int = xyes; then
1263         AC_DEFINE(USE_LONG_LONG_FOR_WIDEST_FAST_INT, 1,
1264 [Define to 1 if the 'long long' (or '__int64') is wider than 'long' but still
1265 efficiently supported by the host hardware.])
1266 fi
1267
1268 count=a
1269 for f in $host_xm_file; do
1270         count=${count}x
1271 done
1272 if test $count = a; then
1273         :
1274 elif test $count = ax; then
1275         echo "Using \`$srcdir/config/$host_xm_file' as host machine macro file."
1276 else
1277         echo "Using the following host machine macro files:"
1278         for f in $host_xm_file; do
1279                 echo "  $srcdir/config/$f"
1280         done
1281 fi
1282 echo "Using ${out_host_hook_obj} for host machine hooks."
1283
1284 if test "$host_xm_file" != "$build_xm_file"; then
1285         count=a
1286         for f in $build_xm_file; do
1287                 count=${count}x
1288         done
1289         if test $count = a; then
1290                 :
1291         elif test $count = ax; then
1292                 echo "Using \`$srcdir/config/$build_xm_file' as build machine macro file."
1293         else
1294                 echo "Using the following build machine macro files:"
1295                 for f in $build_xm_file; do
1296                         echo "  $srcdir/config/$f"
1297                 done
1298         fi
1299 fi
1300
1301 case ${host} in
1302   powerpc*-*-darwin*)
1303     AC_CACHE_CHECK([whether mcontext_t fields have underscores],
1304       gcc_cv_mcontext_underscores,
1305       AC_COMPILE_IFELSE([
1306 #include <sys/cdefs.h>
1307 #include <sys/signal.h>
1308 #include <ucontext.h>
1309 int main() { mcontext_t m; if (m->ss.srr0) return 0; return 0; }
1310 ],
1311         gcc_cv_mcontext_underscores=no, gcc_cv_mcontext_underscores=yes))
1312       if test $gcc_cv_mcontext_underscores = yes; then
1313         AC_DEFINE(HAS_MCONTEXT_T_UNDERSCORES,,dnl
1314           [mcontext_t fields start with __])
1315       fi
1316     ;;
1317 esac
1318
1319 # ---------
1320 # Threading
1321 # ---------
1322
1323 # Check if a valid thread package
1324 case ${enable_threads} in
1325   "" | no)
1326     # No threads
1327     target_thread_file='single'
1328     ;;
1329   yes)
1330     # default
1331     target_thread_file='single'
1332     ;;
1333   aix | dce | gnat | irix | posix | posix95 | rtems | \
1334   single | solaris | vxworks | win32 | mipssde)
1335     target_thread_file=${enable_threads}
1336     ;;
1337   *)
1338     echo "${enable_threads} is an unknown thread package" 1>&2
1339     exit 1
1340     ;;
1341 esac
1342
1343 if test x${thread_file} = x; then
1344   # No thread file set by target-specific clauses in config.gcc,
1345   # so use file chosen by default logic above
1346   thread_file=${target_thread_file}
1347 fi
1348
1349 # Make gthr-default.h if we have a thread file.
1350 gthread_flags=
1351 if test $thread_file != single; then
1352   echo "#include \"gthr-${thread_file}.h\"" > gthr-default.h-t
1353   if diff gthr-default.h-t gthr-default.h 2>/dev/null; then
1354     rm -f gthr-default.h-t
1355   else
1356     mv -f gthr-default.h-t gthr-default.h
1357   fi
1358   gthread_flags=-DHAVE_GTHR_DEFAULT
1359 fi
1360 AC_SUBST(gthread_flags)
1361
1362 # --------
1363 # UNSORTED
1364 # --------
1365
1366 use_cxa_atexit=no
1367 if test x$enable___cxa_atexit = xyes || \
1368    test x$enable___cxa_atexit = x -a x$default_use_cxa_atexit = xyes; then
1369   if test x$host = x$target; then
1370     case $host in
1371       # mingw32 doesn't have __cxa_atexit but uses atexit registration
1372       # keyed to flag_use_cxa_atexit
1373       *-*-mingw32*)
1374         use_cxa_atexit=yes
1375         ;;
1376       *)
1377         AC_CHECK_FUNC(__cxa_atexit,[use_cxa_atexit=yes],
1378           [echo "__cxa_atexit can't be enabled on this target"])
1379         ;;
1380     esac
1381   else
1382     # We can't check for __cxa_atexit when building a cross, so assume
1383     # it is available 
1384     use_cxa_atexit=yes
1385   fi
1386   if test x$use_cxa_atexit = xyes; then
1387     AC_DEFINE(DEFAULT_USE_CXA_ATEXIT, 2,
1388       [Define if you want to use __cxa_atexit, rather than atexit, to
1389       register C++ destructors for local statics and global objects.
1390       This is essential for fully standards-compliant handling of
1391       destructors, but requires __cxa_atexit in libc.])
1392   fi
1393 fi
1394
1395 # Look for a file containing extra machine modes.
1396 if test -n "$extra_modes" && test -f $srcdir/config/$extra_modes; then
1397   extra_modes_file='$(srcdir)'/config/${extra_modes}
1398   AC_SUBST(extra_modes_file)
1399   AC_DEFINE_UNQUOTED(EXTRA_MODES_FILE, "config/$extra_modes",
1400   [Define to the name of a file containing a list of extra machine modes
1401    for this architecture.])
1402 fi
1403
1404 # Convert extra_options into a form suitable for Makefile use.
1405 extra_opt_files=
1406 for f in $extra_options; do
1407   extra_opt_files="$extra_opt_files \$(srcdir)/config/$f"
1408 done
1409 AC_SUBST(extra_opt_files)
1410
1411 # auto-host.h is the file containing items generated by autoconf and is
1412 # the first file included by config.h.
1413 # If host=build, it is correct to have bconfig include auto-host.h
1414 # as well.  If host!=build, we are in error and need to do more 
1415 # work to find out the build config parameters.
1416 if test x$host = x$build
1417 then
1418         build_auto=auto-host.h
1419 else
1420         # We create a subdir, then run autoconf in the subdir.
1421         # To prevent recursion we set host and build for the new
1422         # invocation of configure to the build for this invocation
1423         # of configure. 
1424         tempdir=build.$$
1425         rm -rf $tempdir
1426         mkdir $tempdir
1427         cd $tempdir
1428         case ${srcdir} in
1429         /* | [A-Za-z]:[\\/]* ) realsrcdir=${srcdir};;
1430         *) realsrcdir=../${srcdir};;
1431         esac
1432         saved_CFLAGS="${CFLAGS}"
1433         CC="${CC_FOR_BUILD}" CFLAGS="${CFLAGS_FOR_BUILD}" \
1434         LDFLAGS="${LDFLAGS_FOR_BUILD}" \
1435         ${realsrcdir}/configure \
1436                 --enable-languages=${enable_languages-all} \
1437                 --target=$target_alias --host=$build_alias --build=$build_alias
1438         CFLAGS="${saved_CFLAGS}"
1439
1440         # We just finished tests for the build machine, so rename
1441         # the file auto-build.h in the gcc directory.
1442         mv auto-host.h ../auto-build.h
1443         cd ..
1444         rm -rf $tempdir
1445         build_auto=auto-build.h
1446 fi
1447 AC_SUBST(build_subdir)
1448
1449 tm_file="${tm_file} defaults.h"
1450 tm_p_file="${tm_p_file} tm-preds.h"
1451 host_xm_file="auto-host.h ansidecl.h ${host_xm_file}"
1452 build_xm_file="${build_auto} ansidecl.h ${build_xm_file}"
1453 # We don't want ansidecl.h in target files, write code there in ISO/GNU C.
1454 # put this back in temporarily.
1455 xm_file="auto-host.h ansidecl.h ${xm_file}"
1456
1457 # --------
1458 # UNSORTED
1459 # --------
1460
1461 changequote(,)dnl
1462 # Compile in configure arguments.
1463 if test -f configargs.h ; then
1464         # Being re-configured.
1465         gcc_config_arguments=`grep configuration_arguments configargs.h | sed -e 's/.*"\([^"]*\)".*/\1/'`
1466         gcc_config_arguments="$gcc_config_arguments : (reconfigured) $TOPLEVEL_CONFIGURE_ARGUMENTS"
1467 else
1468         gcc_config_arguments="$TOPLEVEL_CONFIGURE_ARGUMENTS"
1469 fi
1470
1471 # Double all backslashes and backslash all quotes to turn
1472 # gcc_config_arguments into a C string.
1473 sed -e 's/\\/\\\\/g; s/"/\\"/g' <<EOF >conftest.out
1474 $gcc_config_arguments
1475 EOF
1476 gcc_config_arguments_str=`cat conftest.out`
1477 rm -f conftest.out
1478
1479 cat > configargs.h <<EOF
1480 /* Generated automatically. */
1481 static const char configuration_arguments[] = "$gcc_config_arguments_str";
1482 static const char thread_model[] = "$thread_file";
1483
1484 static const struct {
1485   const char *name, *value;
1486 } configure_default_options[] = $configure_default_options;
1487 EOF
1488 changequote([,])dnl
1489
1490 changequote(,)dnl
1491 gcc_BASEVER=`cat $srcdir/BASE-VER`
1492 gcc_DEVPHASE=`cat $srcdir/DEV-PHASE`
1493 gcc_DATESTAMP=`cat $srcdir/DATESTAMP`
1494 if test -f $srcdir/REVISION ; then
1495         gcc_REVISION=`cat $srcdir/REVISION`
1496 else
1497         gcc_REVISION=""
1498 fi
1499 cat > plugin-version.h <<EOF
1500 #include "configargs.h"
1501
1502 static char basever[] = "$gcc_BASEVER";
1503 static char datestamp[] = "$gcc_DATESTAMP";
1504 static char devphase[] = "$gcc_DEVPHASE";
1505 static char revision[] = "$gcc_REVISION";
1506
1507 /* FIXME plugins: We should make the version information more precise.
1508    One way to do is to add a checksum. */
1509
1510 static struct plugin_gcc_version gcc_version = {basever, datestamp,
1511                                                 devphase, revision,
1512                                                 configuration_arguments};
1513 EOF
1514 changequote([,])dnl
1515
1516 # Internationalization
1517 ZW_GNU_GETTEXT_SISTER_DIR
1518
1519 # If LIBINTL contains LIBICONV, then clear LIBICONV so we don't get
1520 # -liconv on the link line twice.
1521 case "$LIBINTL" in *$LIBICONV*)
1522         LIBICONV= ;;
1523 esac
1524
1525 AC_ARG_ENABLE(secureplt,
1526 [  --enable-secureplt      enable -msecure-plt by default for PowerPC],
1527 [], [])
1528
1529 AC_ARG_ENABLE(leading-mingw64-underscores,
1530   AS_HELP_STRING([--enable-leading-mingw64-underscores],
1531                  [Enable leading underscores on 64 bit mingw targets]),
1532   [],[])
1533 AS_IF([ test x"$enable_leading_mingw64_underscores" = xyes ],
1534   [AC_DEFINE(USE_MINGW64_LEADING_UNDERSCORES, 1,
1535     [Define if we should use leading underscore on 64 bit mingw targets])])
1536
1537 AC_ARG_ENABLE(cld,
1538 [  --enable-cld            enable -mcld by default for 32bit x86], [],
1539 [enable_cld=no])
1540
1541 AC_ARG_ENABLE(frame-pointer,
1542 [  --enable-frame-pointer  enable -fno-omit-frame-pointer by default for 32bit x86], [],
1543 [
1544 case $target_os in
1545 linux* | darwin[[8912]]*)
1546   # Enable -fomit-frame-pointer by default for Linux and Darwin with
1547   # DWARF2.
1548   enable_frame_pointer=no
1549   ;;
1550 *)
1551   enable_frame_pointer=yes
1552   ;;
1553 esac
1554 ])
1555
1556 # Windows32 Registry support for specifying GCC installation paths.
1557 AC_ARG_ENABLE(win32-registry,
1558 [  --disable-win32-registry
1559                           disable lookup of installation paths in the
1560                           Registry on Windows hosts
1561   --enable-win32-registry enable registry lookup (default)
1562   --enable-win32-registry=KEY
1563                           use KEY instead of GCC version as the last portion
1564                           of the registry key],,)
1565
1566 case $host_os in
1567   win32 | pe | cygwin* | mingw32* | uwin*)
1568     if test "x$enable_win32_registry" != xno; then
1569       AC_SEARCH_LIBS(RegOpenKeyExA, advapi32,, [enable_win32_registry=no])
1570     fi
1571
1572     if test "x$enable_win32_registry" != xno; then
1573       AC_DEFINE(ENABLE_WIN32_REGISTRY, 1,
1574   [Define to 1 if installation paths should be looked up in the Windows
1575    Registry. Ignored on non-Windows hosts.])
1576
1577       if test "x$enable_win32_registry" != xyes \
1578          && test "x$enable_win32_registry" != x; then
1579         AC_DEFINE_UNQUOTED(WIN32_REGISTRY_KEY, "$enable_win32_registry",
1580   [Define to be the last component of the Windows registry key under which
1581    to look for installation paths.  The full key used will be 
1582    HKEY_LOCAL_MACHINE/SOFTWARE/Free Software Foundation/{WIN32_REGISTRY_KEY}.
1583    The default is the GCC version number.])
1584       fi
1585     fi
1586   ;;
1587 esac
1588
1589 # Get an absolute path to the GCC top-level source directory
1590 holddir=`${PWDCMD-pwd}`
1591 cd $srcdir
1592 topdir=`${PWDCMD-pwd}`
1593 cd $holddir
1594
1595 # Conditionalize the makefile for this host machine.
1596 xmake_file=
1597 for f in ${host_xmake_file}
1598 do
1599         if test -f ${srcdir}/config/$f
1600         then
1601                 xmake_file="${xmake_file} \$(srcdir)/config/$f"
1602         fi
1603 done
1604
1605 # Conditionalize the makefile for this target machine.
1606 tmake_file_=
1607 for f in ${tmake_file}
1608 do
1609         if test -f ${srcdir}/config/$f
1610         then
1611                 tmake_file_="${tmake_file_} \$(srcdir)/config/$f"
1612         fi
1613 done
1614 tmake_file="${tmake_file_}"
1615
1616 out_object_file=`basename $out_file .c`.o
1617
1618 tm_file_list="options.h"
1619 tm_include_list="options.h insn-constants.h"
1620 for f in $tm_file; do
1621   case $f in
1622     ./* )
1623        f=`echo $f | sed 's/^..//'`
1624        tm_file_list="${tm_file_list} $f"
1625        tm_include_list="${tm_include_list} $f"
1626        ;;
1627     defaults.h )
1628        tm_file_list="${tm_file_list} \$(srcdir)/$f"
1629        tm_include_list="${tm_include_list} $f"
1630        ;;
1631     * )
1632        tm_file_list="${tm_file_list} \$(srcdir)/config/$f"
1633        tm_include_list="${tm_include_list} config/$f"
1634        ;;
1635   esac
1636 done
1637
1638 tm_p_file_list=
1639 tm_p_include_list=
1640 for f in $tm_p_file; do
1641   case $f in
1642     tm-preds.h )
1643        tm_p_file_list="${tm_p_file_list} $f"
1644        tm_p_include_list="${tm_p_include_list} $f"
1645        ;;
1646     * )
1647        tm_p_file_list="${tm_p_file_list} \$(srcdir)/config/$f"
1648        tm_p_include_list="${tm_p_include_list} config/$f"
1649   esac
1650 done
1651
1652 xm_file_list=
1653 xm_include_list=
1654 for f in $xm_file; do
1655   case $f in
1656     ansidecl.h )
1657        xm_file_list="${xm_file_list} \$(srcdir)/../include/$f"
1658        xm_include_list="${xm_include_list} $f"
1659        ;;
1660     auto-host.h )
1661        xm_file_list="${xm_file_list} $f"
1662        xm_include_list="${xm_include_list} $f"
1663        ;;
1664     * )
1665        xm_file_list="${xm_file_list} \$(srcdir)/config/$f"
1666        xm_include_list="${xm_include_list} config/$f"
1667        ;;
1668   esac
1669 done
1670
1671 host_xm_file_list=
1672 host_xm_include_list=
1673 for f in $host_xm_file; do
1674   case $f in
1675     ansidecl.h )
1676        host_xm_file_list="${host_xm_file_list} \$(srcdir)/../include/$f"
1677        host_xm_include_list="${host_xm_include_list} $f"
1678        ;;
1679     auto-host.h )
1680        host_xm_file_list="${host_xm_file_list} $f"
1681        host_xm_include_list="${host_xm_include_list} $f"
1682        ;;
1683     * )
1684        host_xm_file_list="${host_xm_file_list} \$(srcdir)/config/$f"
1685        host_xm_include_list="${host_xm_include_list} config/$f"
1686        ;;
1687   esac
1688 done
1689
1690 build_xm_file_list=
1691 for f in $build_xm_file; do
1692   case $f in
1693     ansidecl.h )
1694        build_xm_file_list="${build_xm_file_list} \$(srcdir)/../include/$f"
1695        build_xm_include_list="${build_xm_include_list} $f"
1696        ;;
1697     auto-build.h | auto-host.h )
1698        build_xm_file_list="${build_xm_file_list} $f"
1699        build_xm_include_list="${build_xm_include_list} $f"
1700        ;;
1701     * )
1702        build_xm_file_list="${build_xm_file_list} \$(srcdir)/config/$f"
1703        build_xm_include_list="${build_xm_include_list} config/$f"
1704        ;;
1705   esac
1706 done
1707
1708 # Define macro CROSS_DIRECTORY_STRUCTURE in compilation if this is a
1709 # cross-compiler which does not use the native headers and libraries.
1710 # Also use all.cross instead of all.internal and adjust SYSTEM_HEADER_DIR.
1711 CROSS=                                          AC_SUBST(CROSS)
1712 ALL=all.internal                                AC_SUBST(ALL)
1713 SYSTEM_HEADER_DIR='$(NATIVE_SYSTEM_HEADER_DIR)' AC_SUBST(SYSTEM_HEADER_DIR)
1714
1715 if test "x$with_build_sysroot" != x; then
1716   build_system_header_dir=$with_build_sysroot'$${sysroot_headers_suffix}$(NATIVE_SYSTEM_HEADER_DIR)'
1717 else
1718   # This value is used, even on a native system, because 
1719   # CROSS_SYSTEM_HEADER_DIR is just 
1720   # $(TARGET_SYSTEM_ROOT)$(NATIVE_SYSTEM_HEADER_DIR).
1721   build_system_header_dir='$(CROSS_SYSTEM_HEADER_DIR)'
1722 fi
1723
1724 if test x$host != x$target
1725 then
1726         CROSS="-DCROSS_DIRECTORY_STRUCTURE"
1727         ALL=all.cross
1728         SYSTEM_HEADER_DIR=$build_system_header_dir
1729         case "$host","$target" in
1730         # Darwin crosses can use the host system's libraries and headers,
1731         # because of the fat library support.  Of course, it must be the
1732         # same version of Darwin on both sides.  Allow the user to
1733         # just say --target=foo-darwin without a version number to mean
1734         # "the version on this system".
1735             *-*-darwin*,*-*-darwin*)
1736                 hostos=`echo $host | sed 's/.*-darwin/darwin/'`
1737                 targetos=`echo $target | sed 's/.*-darwin/darwin/'`
1738                 if test $hostos = $targetos -o $targetos = darwin ; then
1739                     CROSS=
1740                     SYSTEM_HEADER_DIR='$(NATIVE_SYSTEM_HEADER_DIR)'
1741                     with_headers=yes
1742                 fi
1743                 ;;
1744
1745             i?86-*-*,x86_64-*-* \
1746             | powerpc*-*-*,powerpc64*-*-*)
1747                 CROSS="$CROSS -DNATIVE_CROSS" ;;
1748         esac
1749 elif test "x$TARGET_SYSTEM_ROOT" != x; then
1750         SYSTEM_HEADER_DIR=$build_system_header_dir 
1751 fi
1752
1753 # If this is a cross-compiler that does not
1754 # have its own set of headers then define
1755 # inhibit_libc
1756
1757 # If this is using newlib, without having the headers available now,
1758 # then define inhibit_libc in LIBGCC2_CFLAGS.
1759 # This prevents libgcc2 from containing any code which requires libc
1760 # support.
1761 : ${inhibit_libc=false}
1762 if { { test x$host != x$target && test "x$with_sysroot" = x ; } ||
1763        test x$with_newlib = xyes ; } &&
1764      { test "x$with_headers" = x || test "x$with_headers" = xno ; } ; then
1765        inhibit_libc=true
1766 fi
1767 AC_SUBST(inhibit_libc)
1768
1769 # When building gcc with a cross-compiler, we need to adjust things so
1770 # that the generator programs are still built with the native compiler.
1771 # Also, we cannot run fixincludes.
1772
1773 # These are the normal (build=host) settings:
1774 CC_FOR_BUILD='$(CC)'            AC_SUBST(CC_FOR_BUILD)
1775 BUILD_CFLAGS='$(ALL_CFLAGS)'    AC_SUBST(BUILD_CFLAGS)
1776 BUILD_LDFLAGS='$(LDFLAGS)'      AC_SUBST(BUILD_LDFLAGS)
1777 STMP_FIXINC=stmp-fixinc         AC_SUBST(STMP_FIXINC)
1778
1779 # And these apply if build != host, or we are generating coverage data
1780 if test x$build != x$host || test "x$coverage_flags" != x
1781 then
1782     BUILD_CFLAGS='$(INTERNAL_CFLAGS) $(T_CFLAGS) $(CFLAGS_FOR_BUILD)'
1783     BUILD_LDFLAGS='$(LDFLAGS_FOR_BUILD)'
1784 fi
1785
1786 # Expand extra_headers to include complete path.
1787 # This substitutes for lots of t-* files.
1788 extra_headers_list=
1789 # Prepend $(srcdir)/config/${cpu_type}/ to every entry in extra_headers.
1790 for file in ${extra_headers} ; do
1791   extra_headers_list="${extra_headers_list} \$(srcdir)/config/${cpu_type}/${file}"
1792 done
1793
1794 # If use_gcc_tgmath is set, append ginclude/tgmath.h.
1795 if test x"$use_gcc_tgmath" = xyes
1796 then extra_headers_list="${extra_headers_list} \$(srcdir)/ginclude/tgmath.h"
1797 fi
1798
1799 # Define collect2 in Makefile.
1800 case $host_can_use_collect2 in
1801   no) collect2= ;;
1802   *) collect2='collect2$(exeext)' ;;
1803 esac
1804 AC_SUBST([collect2])
1805
1806 # Add a definition of USE_COLLECT2 if system wants one.
1807 case $use_collect2 in
1808   no) use_collect2= ;;
1809   "") ;;
1810   *) 
1811     host_xm_defines="${host_xm_defines} USE_COLLECT2"
1812     xm_defines="${xm_defines} USE_COLLECT2"
1813     case $host_can_use_collect2 in
1814       no)
1815         AC_MSG_ERROR([collect2 is required but cannot be built on this system])
1816         ;;
1817     esac
1818     ;;
1819 esac
1820
1821 # ---------------------------
1822 # Assembler & linker features
1823 # ---------------------------
1824
1825 # During stage 2, ld is actually gcc/collect-ld, which is a small script to
1826 # discern between when to use prev-ld/ld-new and when to use ld/ld-new.
1827 # However when ld-new is first executed from the build tree, libtool will
1828 # relink it as .libs/lt-ld-new, so that it can give it an RPATH that refers
1829 # to the build tree.  While doing this we need to use the previous-stage
1830 # linker, or we have an infinite loop.  The presence of a shell script as
1831 # ld/ld-new, and the fact that the script *uses ld itself*, is what confuses
1832 # the gcc/collect-ld script.  So we need to know how libtool works, or
1833 # exec-tool will fail.
1834
1835 m4_defun([_LT_CONFIG_COMMANDS], [])
1836 AC_PROG_LIBTOOL
1837 AC_SUBST(objdir)
1838 AC_SUBST(enable_fast_install)
1839
1840 # Identify the assembler which will work hand-in-glove with the newly
1841 # built GCC, so that we can examine its features.  This is the assembler
1842 # which will be driven by the driver program.
1843 #
1844 # If build != host, and we aren't building gas in-tree, we identify a
1845 # build->target assembler and hope that it will have the same features
1846 # as the host->target assembler we'll be using.
1847 gcc_cv_gas_major_version=
1848 gcc_cv_gas_minor_version=
1849 gcc_cv_as_gas_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/gas
1850
1851 m4_pattern_allow([AS_FOR_TARGET])dnl
1852 AS_VAR_SET_IF(gcc_cv_as,, [
1853 if test -x "$DEFAULT_ASSEMBLER"; then
1854         gcc_cv_as="$DEFAULT_ASSEMBLER"
1855 elif test -f $gcc_cv_as_gas_srcdir/configure.in \
1856      && test -f ../gas/Makefile \
1857      && test x$build = x$host; then
1858         gcc_cv_as=../gas/as-new$build_exeext
1859 elif test -x as$build_exeext; then
1860         # Build using assembler in the current directory.
1861         gcc_cv_as=./as$build_exeext
1862 elif test -x $AS_FOR_TARGET; then
1863         gcc_cv_as="$AS_FOR_TARGET"
1864 else
1865         AC_PATH_PROG(gcc_cv_as, $AS_FOR_TARGET)
1866 fi])
1867
1868 ORIGINAL_AS_FOR_TARGET=$gcc_cv_as
1869 AC_SUBST(ORIGINAL_AS_FOR_TARGET)
1870 case "$ORIGINAL_AS_FOR_TARGET" in
1871   ./as | ./as$build_exeext) ;;
1872   *) AC_CONFIG_FILES(as:exec-tool.in, [chmod +x as]) ;;
1873 esac 
1874
1875 AC_MSG_CHECKING(what assembler to use)
1876 if test "$gcc_cv_as" = ../gas/as-new$build_exeext; then
1877   # Single tree build which includes gas.  We want to prefer it
1878   # over whatever linker top-level may have detected, since
1879   # we'll use what we're building after installation anyway.
1880   AC_MSG_RESULT(newly built gas)
1881   in_tree_gas=yes
1882   _gcc_COMPUTE_GAS_VERSION
1883   in_tree_gas_is_elf=no
1884   if grep 'obj_format = elf' ../gas/Makefile > /dev/null \
1885      || (grep 'obj_format = multi' ../gas/Makefile \
1886          && grep 'extra_objects =.* obj-elf' ../gas/Makefile) > /dev/null
1887   then
1888     in_tree_gas_is_elf=yes
1889   fi
1890 else
1891   AC_MSG_RESULT($gcc_cv_as)
1892   in_tree_gas=no
1893 fi
1894
1895 # Identify the linker which will work hand-in-glove with the newly
1896 # built GCC, so that we can examine its features.  This is the linker
1897 # which will be driven by the driver program.
1898 #
1899 # If build != host, and we aren't building gas in-tree, we identify a
1900 # build->target linker and hope that it will have the same features
1901 # as the host->target linker we'll be using.
1902 gcc_cv_gld_major_version=
1903 gcc_cv_gld_minor_version=
1904 gcc_cv_ld_gld_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/ld
1905 gcc_cv_ld_bfd_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/bfd
1906
1907 AS_VAR_SET_IF(gcc_cv_ld,, [
1908 if test -x "$DEFAULT_LINKER"; then
1909         gcc_cv_ld="$DEFAULT_LINKER"
1910 elif test -f $gcc_cv_ld_gld_srcdir/configure.in \
1911      && test -f ../ld/Makefile \
1912      && test x$build = x$host; then
1913         gcc_cv_ld=../ld/ld-new$build_exeext
1914 elif test -x collect-ld$build_exeext; then
1915         # Build using linker in the current directory.
1916         gcc_cv_ld=./collect-ld$build_exeext
1917 elif test -x $LD_FOR_TARGET; then
1918         gcc_cv_ld="$LD_FOR_TARGET"
1919 else
1920         AC_PATH_PROG(gcc_cv_ld, $LD_FOR_TARGET)
1921 fi])
1922
1923 ORIGINAL_PLUGIN_LD_FOR_TARGET=$gcc_cv_ld
1924 PLUGIN_LD=`basename $gcc_cv_ld`
1925 AC_ARG_WITH(plugin-ld,
1926 [  --with-plugin-ld=[[ARG]]  specify the plugin linker],
1927 [if test x"$withval" != x; then
1928    ORIGINAL_PLUGIN_LD_FOR_TARGET="$withval"
1929    PLUGIN_LD="$withval"
1930  fi])
1931 AC_SUBST(ORIGINAL_PLUGIN_LD_FOR_TARGET)
1932 AC_DEFINE_UNQUOTED(PLUGIN_LD, "$PLUGIN_LD", [Specify plugin linker])
1933
1934 # Check to see if we are using gold instead of ld
1935 AC_MSG_CHECKING(whether we are using gold)
1936 ld_is_gold=no
1937 if test x$gcc_cv_ld != x; then
1938   if $gcc_cv_ld --version 2>/dev/null | sed 1q \
1939      | grep "GNU gold" > /dev/null; then
1940     ld_is_gold=yes
1941   fi
1942 fi
1943 AC_MSG_RESULT($ld_is_gold)
1944
1945 ORIGINAL_LD_FOR_TARGET=$gcc_cv_ld
1946 AC_SUBST(ORIGINAL_LD_FOR_TARGET)
1947 case "$ORIGINAL_LD_FOR_TARGET" in
1948   ./collect-ld | ./collect-ld$build_exeext) ;;
1949   *) AC_CONFIG_FILES(collect-ld:exec-tool.in, [chmod +x collect-ld]) ;;
1950 esac 
1951
1952 AC_MSG_CHECKING(what linker to use)
1953 if test "$gcc_cv_ld" = ../ld/ld-new$build_exeext; then
1954         # Single tree build which includes ld.  We want to prefer it
1955         # over whatever linker top-level may have detected, since
1956         # we'll use what we're building after installation anyway.
1957         AC_MSG_RESULT(newly built ld)
1958         in_tree_ld=yes
1959         in_tree_ld_is_elf=no
1960         if (grep 'EMUL = .*elf' ../ld/Makefile \
1961             || grep 'EMUL = .*linux' ../ld/Makefile \
1962             || grep 'EMUL = .*lynx' ../ld/Makefile) > /dev/null; then
1963           in_tree_ld_is_elf=yes
1964         fi
1965         for f in $gcc_cv_ld_bfd_srcdir/configure $gcc_cv_ld_gld_srcdir/configure $gcc_cv_ld_gld_srcdir/configure.in $gcc_cv_ld_gld_srcdir/Makefile.in
1966         do
1967 changequote(,)dnl
1968                 gcc_cv_gld_version=`sed -n -e 's/^[     ]*\(VERSION=[0-9]*\.[0-9]*.*\)/\1/p' < $f`
1969                 if test x$gcc_cv_gld_version != x; then
1970                         break
1971                 fi
1972         done
1973         gcc_cv_gld_major_version=`expr "$gcc_cv_gld_version" : "VERSION=\([0-9]*\)"`
1974         gcc_cv_gld_minor_version=`expr "$gcc_cv_gld_version" : "VERSION=[0-9]*\.\([0-9]*\)"`
1975 changequote([,])dnl
1976 else
1977         AC_MSG_RESULT($gcc_cv_ld)
1978         in_tree_ld=no
1979 fi
1980
1981 # Figure out what nm we will be using.
1982 gcc_cv_binutils_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/binutils
1983 AS_VAR_SET_IF(gcc_cv_nm,, [
1984 if test -f $gcc_cv_binutils_srcdir/configure.in \
1985      && test -f ../binutils/Makefile \
1986      && test x$build = x$host; then
1987         gcc_cv_nm=../binutils/nm-new$build_exeext
1988 elif test -x nm$build_exeext; then
1989         gcc_cv_nm=./nm$build_exeext
1990 elif test -x $NM_FOR_TARGET; then
1991         gcc_cv_nm="$NM_FOR_TARGET"
1992 else
1993         AC_PATH_PROG(gcc_cv_nm, $NM_FOR_TARGET)
1994 fi])
1995
1996 AC_MSG_CHECKING(what nm to use)
1997 if test "$gcc_cv_nm" = ../binutils/nm-new$build_exeext; then
1998         # Single tree build which includes binutils.
1999         AC_MSG_RESULT(newly built nm)
2000         in_tree_nm=yes
2001 else
2002         AC_MSG_RESULT($gcc_cv_nm)
2003         in_tree_nm=no
2004 fi
2005
2006 ORIGINAL_NM_FOR_TARGET=$gcc_cv_nm
2007 AC_SUBST(ORIGINAL_NM_FOR_TARGET)
2008 case "$ORIGINAL_NM_FOR_TARGET" in
2009   ./nm | ./nm$build_exeext) ;;
2010   *) AC_CONFIG_FILES(nm:exec-tool.in, [chmod +x nm]) ;;
2011 esac
2012
2013
2014 # Figure out what objdump we will be using.
2015 AS_VAR_SET_IF(gcc_cv_objdump,, [
2016 if test -f $gcc_cv_binutils_srcdir/configure.in \
2017      && test -f ../binutils/Makefile \
2018      && test x$build = x$host; then
2019         # Single tree build which includes binutils.
2020         gcc_cv_objdump=../binutils/objdump$build_exeext
2021 elif test -x objdump$build_exeext; then
2022         gcc_cv_objdump=./objdump$build_exeext
2023 elif test -x $OBJDUMP_FOR_TARGET; then
2024         gcc_cv_objdump="$OBJDUMP_FOR_TARGET"
2025 else
2026         AC_PATH_PROG(gcc_cv_objdump, $OBJDUMP_FOR_TARGET)
2027 fi])
2028
2029 AC_MSG_CHECKING(what objdump to use)
2030 if test "$gcc_cv_objdump" = ../binutils/objdump$build_exeext; then
2031         # Single tree build which includes binutils.
2032         AC_MSG_RESULT(newly built objdump)
2033 elif test x$gcc_cv_objdump = x; then
2034         AC_MSG_RESULT(not found)
2035 else
2036         AC_MSG_RESULT($gcc_cv_objdump)
2037 fi
2038
2039 # Figure out what readelf we will be using.
2040 AS_VAR_SET_IF(gcc_cv_readelf,, [
2041 if test -f $gcc_cv_binutils_srcdir/configure.in \
2042      && test -f ../binutils/Makefile \
2043      && test x$build = x$host; then
2044         # Single tree build which includes binutils.
2045         gcc_cv_readelf=../binutils/readelf$build_exeext
2046 elif test -x readelf$build_exeext; then
2047         gcc_cv_readelf=./readelf$build_exeext
2048 else
2049         AC_PATH_PROG(gcc_cv_readelf, readelf)
2050 fi])
2051
2052 AC_MSG_CHECKING(what readelf to use)
2053 if test "$gcc_cv_readelf" = ../binutils/readelf$build_exeext; then
2054         # Single tree build which includes binutils.
2055         AC_MSG_RESULT(newly built readelf)
2056 elif test x$gcc_cv_readelf = x; then
2057         AC_MSG_RESULT(not found)
2058 else
2059         AC_MSG_RESULT($gcc_cv_readelf)
2060 fi
2061
2062 # Figure out what assembler alignment features are present.
2063 gcc_GAS_CHECK_FEATURE([.balign and .p2align], gcc_cv_as_balign_and_p2align,
2064  [2,6,0],,
2065 [.balign 4
2066 .p2align 2],,
2067 [AC_DEFINE(HAVE_GAS_BALIGN_AND_P2ALIGN, 1,
2068   [Define if your assembler supports .balign and .p2align.])])
2069
2070 gcc_GAS_CHECK_FEATURE([.p2align with maximum skip], gcc_cv_as_max_skip_p2align,
2071  [2,8,0],,
2072  [.p2align 4,,7],,
2073 [AC_DEFINE(HAVE_GAS_MAX_SKIP_P2ALIGN, 1,
2074   [Define if your assembler supports specifying the maximum number
2075    of bytes to skip when using the GAS .p2align command.])])
2076
2077 gcc_GAS_CHECK_FEATURE([.literal16], gcc_cv_as_literal16,
2078  [2,8,0],,
2079  [.literal16],,
2080 [AC_DEFINE(HAVE_GAS_LITERAL16, 1,
2081   [Define if your assembler supports .literal16.])])
2082
2083 gcc_GAS_CHECK_FEATURE([working .subsection -1], gcc_cv_as_subsection_m1,
2084  [elf,2,9,0],,
2085  [conftest_label1: .word 0
2086 .subsection -1
2087 conftest_label2: .word 0
2088 .previous],
2089  [if test x$gcc_cv_nm != x; then
2090     $gcc_cv_nm conftest.o | grep conftest_label1 > conftest.nm1
2091     $gcc_cv_nm conftest.o | grep conftest_label2 | sed -e 's/label2/label1/' > conftest.nm2
2092     if cmp conftest.nm1 conftest.nm2 > /dev/null 2>&1
2093     then :
2094     else gcc_cv_as_subsection_m1=yes
2095     fi
2096     rm -f conftest.nm1 conftest.nm2
2097   fi],
2098  [AC_DEFINE(HAVE_GAS_SUBSECTION_ORDERING, 1,
2099   [Define if your assembler supports .subsection and .subsection -1 starts
2100    emitting at the beginning of your section.])])
2101
2102 gcc_GAS_CHECK_FEATURE([.weak], gcc_cv_as_weak,
2103  [2,2,0],,
2104  [      .weak foobar],,
2105 [AC_DEFINE(HAVE_GAS_WEAK, 1, [Define if your assembler supports .weak.])])
2106
2107 gcc_GAS_CHECK_FEATURE([.weakref], gcc_cv_as_weakref,
2108  [2,17,0],,
2109  [      .weakref foobar, barfnot],,
2110 [AC_DEFINE(HAVE_GAS_WEAKREF, 1, [Define if your assembler supports .weakref.])])
2111
2112 gcc_GAS_CHECK_FEATURE([.nsubspa comdat], gcc_cv_as_nsubspa_comdat,
2113  [2,15,91],,
2114  [      .SPACE $TEXT$
2115         .NSUBSPA $CODE$,COMDAT],,
2116 [AC_DEFINE(HAVE_GAS_NSUBSPA_COMDAT, 1, [Define if your assembler supports .nsubspa comdat option.])])
2117
2118 # .hidden needs to be supported in both the assembler and the linker,
2119 # because GNU LD versions before 2.12.1 have buggy support for STV_HIDDEN.
2120 # This is irritatingly difficult to feature test for; we have to check the
2121 # date string after the version number.  If we've got an in-tree
2122 # ld, we don't know its patchlevel version, so we set the baseline at 2.13
2123 # to be safe.
2124 # The gcc_GAS_CHECK_FEATURE call just sets a cache variable.
2125 gcc_GAS_CHECK_FEATURE([.hidden], gcc_cv_as_hidden,
2126  [elf,2,13,0],,
2127 [       .hidden foobar
2128 foobar:],[
2129 # Solaris 9/x86 as incorrectly emits an alias for a hidden symbol with
2130 # STV_HIDDEN, so disable .hidden support if so.
2131 case "${target}" in
2132   i?86-*-solaris2*)
2133     if test x$gcc_cv_as != x && test x$gcc_cv_objdump != x; then
2134       cat > conftest.s <<EOF
2135 .globl hidden
2136         .hidden hidden
2137 hidden:
2138 .globl default
2139         .set    default,hidden
2140 EOF
2141       if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1 \
2142         && $gcc_cv_objdump -t conftest.o 2>/dev/null | \
2143         grep '\.hidden default' > /dev/null; then
2144         gcc_cv_as_hidden=no
2145       else
2146         gcc_cv_as_hidden=yes
2147       fi
2148     else
2149       # Assume bug is present if objdump is missing.
2150       gcc_cv_as_hidden=no
2151     fi
2152     ;;
2153   *)
2154     gcc_cv_as_hidden=yes
2155     ;;
2156 esac])
2157
2158 changequote(,)dnl
2159 if test $in_tree_ld != yes ; then
2160   ld_ver=`$gcc_cv_ld --version 2>/dev/null | sed 1q`
2161   if test x"$ld_is_gold" = xyes; then
2162     gcc_cv_ld_hidden=yes
2163   elif echo "$ld_ver" | grep GNU > /dev/null; then
2164     ld_vers=`echo $ld_ver | sed -n \
2165         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*.*\)$,\1,p'`
2166     ld_date=`echo $ld_ver | sed -n 's,^.*\([2-9][0-9][0-9][0-9]\)[-]*\([01][0-9]\)[-]*\([0-3][0-9]\).*$,\1\2\3,p'`
2167     ld_vers_major=`expr "$ld_vers" : '\([0-9]*\)'`
2168     ld_vers_minor=`expr "$ld_vers" : '[0-9]*\.\([0-9]*\)'`
2169     ld_vers_patch=`expr "$ld_vers" : '[0-9]*\.[0-9]*\.\([0-9]*\)'`
2170   else
2171     case "${target}" in
2172       *-*-solaris2*)
2173         #
2174         # Solaris 2 ld -V output looks like this for a regular version:
2175         #
2176         # ld: Software Generation Utilities - Solaris Link Editors: 5.11-1.1699
2177         #
2178         # but test versions add stuff at the end:
2179         #
2180         # ld: Software Generation Utilities - Solaris Link Editors: 5.11-1.1701:onnv-ab196087-6931056-03/25/10
2181         #
2182         ld_ver=`$gcc_cv_ld -V 2>&1`
2183         if echo "$ld_ver" | grep 'Solaris Link Editors' > /dev/null; then
2184           ld_vers=`echo $ld_ver | sed -n \
2185             -e 's,^.*: 5\.[0-9][0-9]*-\([0-9]\.[0-9][0-9]*\).*$,\1,p'`
2186           ld_vers_major=`expr "$ld_vers" : '\([0-9]*\)'`
2187           ld_vers_minor=`expr "$ld_vers" : '[0-9]*\.\([0-9]*\)'`
2188         fi
2189         ;;
2190     esac
2191   fi
2192 fi
2193 changequote([,])dnl
2194
2195 AC_CACHE_CHECK(linker for .hidden support, gcc_cv_ld_hidden,
2196 [[if test $in_tree_ld = yes ; then
2197   gcc_cv_ld_hidden=no
2198   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 13 -o "$gcc_cv_gld_major_version" -gt 2 \
2199      && test $in_tree_ld_is_elf = yes; then
2200      gcc_cv_ld_hidden=yes
2201   fi
2202 else
2203   gcc_cv_ld_hidden=yes
2204   if echo "$ld_ver" | grep GNU > /dev/null; then
2205     if test 0"$ld_date" -lt 20020404; then
2206       if test -n "$ld_date"; then
2207         # If there was date string, but was earlier than 2002-04-04, fail
2208         gcc_cv_ld_hidden=no
2209       elif test -z "$ld_vers"; then
2210         # If there was no date string nor ld version number, something is wrong
2211         gcc_cv_ld_hidden=no
2212       else
2213         test -z "$ld_vers_patch" && ld_vers_patch=0
2214         if test "$ld_vers_major" -lt 2; then
2215           gcc_cv_ld_hidden=no
2216         elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -lt 12; then
2217           gcc_cv_ld_hidden="no"
2218         elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -eq 12 -a "$ld_vers_patch" -eq 0; then
2219           gcc_cv_ld_hidden=no
2220         fi
2221       fi
2222     fi
2223   else
2224     case "${target}" in
2225       hppa64*-*-hpux* | ia64*-*-hpux*)
2226         gcc_cv_ld_hidden=yes
2227         ;;
2228       *-*-solaris2.9* | *-*-solaris2.1[0-9]*)
2229         # Support for .hidden in Sun ld appeared in Solaris 9 FCS, but
2230         # .symbolic was only added in Solaris 9 12/02.
2231         gcc_cv_ld_hidden=yes
2232         ;;
2233       *)
2234         gcc_cv_ld_hidden=no
2235         ;;
2236     esac
2237   fi
2238 fi]])
2239 libgcc_visibility=no
2240 AC_SUBST(libgcc_visibility)
2241 GCC_TARGET_TEMPLATE([HAVE_GAS_HIDDEN])
2242 if test $gcc_cv_as_hidden = yes && test $gcc_cv_ld_hidden = yes; then
2243   libgcc_visibility=yes
2244   AC_DEFINE(HAVE_GAS_HIDDEN, 1,
2245   [Define if your assembler and linker support .hidden.])
2246 fi
2247
2248 AC_MSG_CHECKING(linker read-only and read-write section mixing)
2249 gcc_cv_ld_ro_rw_mix=unknown
2250 if test $in_tree_ld = yes ; then
2251   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 10 -o "$gcc_cv_gld_major_version" -gt 2 \
2252      && test $in_tree_ld_is_elf = yes; then
2253     gcc_cv_ld_ro_rw_mix=read-write
2254   fi
2255 elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x -a x$gcc_cv_objdump != x ; then
2256   echo '.section myfoosect, "a"' > conftest1.s
2257   echo '.section myfoosect, "aw"' > conftest2.s
2258   echo '.byte 1' >> conftest2.s
2259   echo '.section myfoosect, "a"' > conftest3.s
2260   echo '.byte 0' >> conftest3.s
2261   if $gcc_cv_as -o conftest1.o conftest1.s > /dev/null 2>&1 \
2262      && $gcc_cv_as -o conftest2.o conftest2.s > /dev/null 2>&1 \
2263      && $gcc_cv_as -o conftest3.o conftest3.s > /dev/null 2>&1 \
2264      && $gcc_cv_ld -shared -o conftest1.so conftest1.o \
2265         conftest2.o conftest3.o > /dev/null 2>&1; then
2266     gcc_cv_ld_ro_rw_mix=`$gcc_cv_objdump -h conftest1.so \
2267                          | sed -e '/myfoosect/!d' -e N`
2268     if echo "$gcc_cv_ld_ro_rw_mix" | grep CONTENTS > /dev/null; then
2269       if echo "$gcc_cv_ld_ro_rw_mix" | grep READONLY > /dev/null; then
2270         gcc_cv_ld_ro_rw_mix=read-only
2271       else
2272         gcc_cv_ld_ro_rw_mix=read-write
2273       fi
2274     fi
2275   fi
2276 changequote(,)dnl
2277   rm -f conftest.* conftest[123].*
2278 changequote([,])dnl
2279 fi
2280 if test x$gcc_cv_ld_ro_rw_mix = xread-write; then
2281         AC_DEFINE(HAVE_LD_RO_RW_SECTION_MIXING, 1,
2282   [Define if your linker links a mix of read-only
2283    and read-write sections into a read-write section.])
2284 fi
2285 AC_MSG_RESULT($gcc_cv_ld_ro_rw_mix)
2286
2287 # Check if we have .[us]leb128, and support symbol arithmetic with it.
2288 gcc_GAS_CHECK_FEATURE([.sleb128 and .uleb128], gcc_cv_as_leb128,
2289   [elf,2,11,0],,
2290 [       .data
2291         .uleb128 L2 - L1
2292 L1:
2293         .uleb128 1280
2294         .sleb128 -1010
2295 L2:],
2296 [[# GAS versions before 2.11 do not support uleb128,
2297   # despite appearing to.
2298   # ??? There exists an elf-specific test that will crash
2299   # the assembler.  Perhaps it's better to figure out whether
2300   # arbitrary sections are supported and try the test.
2301   as_ver=`$gcc_cv_as --version 2>/dev/null | sed 1q`
2302   if echo "$as_ver" | grep GNU > /dev/null; then
2303     as_vers=`echo $as_ver | sed -n \
2304         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*.*\)$,\1,p'`
2305     as_major=`expr "$as_vers" : '\([0-9]*\)'`
2306     as_minor=`expr "$as_vers" : '[0-9]*\.\([0-9]*\)'`
2307     if test $as_major -eq 2 && test $as_minor -lt 11
2308     then :
2309     else gcc_cv_as_leb128=yes
2310     fi
2311   fi]],
2312   [AC_DEFINE(HAVE_AS_LEB128, 1,
2313     [Define if your assembler supports .sleb128 and .uleb128.])])
2314
2315 # Check if we have assembler support for unwind directives.
2316 gcc_GAS_CHECK_FEATURE([cfi directives], gcc_cv_as_cfi_directive,
2317   ,,
2318 [       .text
2319         .cfi_startproc
2320         .cfi_offset 0, 0
2321         .cfi_same_value 1
2322         .cfi_def_cfa 1, 2
2323         .cfi_escape 1, 2, 3, 4, 5
2324         .cfi_endproc],
2325 [case "$target" in
2326   *-*-solaris*)
2327     # If the linker used on Solaris (like Sun ld) isn't capable of merging
2328     # read-only and read-write sections, we need to make sure that the
2329     # assembler used emits read-write .eh_frame sections.
2330     if test "x$gcc_cv_ld_ro_rw_mix" != xread-write; then
2331       if test "x$gcc_cv_objdump" != x; then
2332         if $gcc_cv_objdump -h conftest.o 2>/dev/null | \
2333                 sed -e /.eh_frame/!d -e N | grep READONLY > /dev/null; then
2334           gcc_cv_as_cfi_directive=no
2335         else
2336           case "$target" in
2337             i?86-*-solaris2.1[[0-9]]*)
2338               # On Solaris/x86, make sure that GCC and gas agree on using
2339               # read-only .eh_frame sections for 64-bit.
2340               if $gcc_cv_as --64 -o conftest.o conftest.s > /dev/null 2>&1 && \
2341                 $gcc_cv_objdump -h conftest.o 2>/dev/null | \
2342                         sed -e /.eh_frame/!d -e N | \
2343                         grep READONLY > /dev/null; then
2344                 gcc_cv_as_cfi_directive=yes
2345               else
2346                 gcc_cv_as_cfi_directive=no
2347               fi
2348               ;;
2349             *)
2350               gcc_cv_as_cfi_directive=yes
2351               ;;
2352           esac 
2353         fi
2354       else
2355         # no objdump, err on the side of caution
2356         gcc_cv_as_cfi_directive=no
2357       fi
2358     else
2359       gcc_cv_as_cfi_directive=yes
2360     fi
2361     ;;
2362   *-*-*)
2363     gcc_cv_as_cfi_directive=yes
2364     ;;
2365 esac])
2366 if test $gcc_cv_as_cfi_directive = yes && test x$gcc_cv_objdump != x; then
2367 gcc_GAS_CHECK_FEATURE([working cfi advance], gcc_cv_as_cfi_advance_working,
2368   ,,
2369 [       .text
2370         .cfi_startproc
2371         .cfi_adjust_cfa_offset 64
2372         .skip 75040, 0
2373         .cfi_adjust_cfa_offset 128
2374         .cfi_endproc],
2375 [[
2376 if $gcc_cv_objdump -Wf conftest.o 2>/dev/null \
2377     | grep 'DW_CFA_advance_loc[24]:[    ][      ]*75040[        ]' >/dev/null; then
2378    gcc_cv_as_cfi_advance_working=yes
2379 fi
2380 ]])
2381 else
2382   # no objdump, err on the side of caution
2383   gcc_cv_as_cfi_advance_working=no
2384 fi
2385 AC_DEFINE_UNQUOTED(HAVE_GAS_CFI_DIRECTIVE,
2386   [`if test $gcc_cv_as_cfi_directive = yes \
2387        && test $gcc_cv_as_cfi_advance_working = yes; then echo 1; else echo 0; fi`],
2388   [Define 0/1 if your assembler supports CFI directives.])
2389
2390 gcc_GAS_CHECK_FEATURE([cfi personality directive],
2391   gcc_cv_as_cfi_personality_directive, ,,
2392 [       .text
2393         .cfi_startproc
2394         .cfi_personality 0, symbol
2395         .cfi_endproc])
2396 AC_DEFINE_UNQUOTED(HAVE_GAS_CFI_PERSONALITY_DIRECTIVE,
2397   [`if test $gcc_cv_as_cfi_personality_directive = yes;
2398     then echo 1; else echo 0; fi`],
2399   [Define 0/1 if your assembler supports .cfi_personality.])
2400
2401 gcc_GAS_CHECK_FEATURE([cfi sections directive],
2402   gcc_cv_as_cfi_sections_directive, ,,
2403 [       .text
2404         .cfi_sections .debug_frame, .eh_frame
2405         .cfi_startproc
2406         .cfi_endproc],
2407 [case $target_os in
2408   win32 | pe | cygwin* | mingw32* | uwin*)
2409     # Need to check that we generated the correct relocation for the
2410     # .debug_frame section.  This was fixed for binutils 2.21.
2411     gcc_cv_as_cfi_sections_directive=no
2412     if test "x$gcc_cv_objdump" != x; then
2413      if $gcc_cv_objdump -j .debug_frame -r conftest.o 2>/dev/null | \
2414         grep secrel > /dev/null; then
2415       gcc_cv_as_cfi_sections_directive=yes
2416      fi
2417     fi
2418     ;;
2419   *)
2420     gcc_cv_as_cfi_sections_directive=yes
2421     ;;
2422 esac])
2423 AC_DEFINE_UNQUOTED(HAVE_GAS_CFI_SECTIONS_DIRECTIVE,
2424   [`if test $gcc_cv_as_cfi_sections_directive = yes;
2425     then echo 1; else echo 0; fi`],
2426   [Define 0/1 if your assembler supports .cfi_sections.])
2427
2428 # GAS versions up to and including 2.11.0 may mis-optimize
2429 # .eh_frame data.
2430 gcc_GAS_CHECK_FEATURE(eh_frame optimization, gcc_cv_as_eh_frame,
2431   [elf,2,12,0],,
2432 [       .text
2433 .LFB1:
2434         .4byte  0
2435 .L1:
2436         .4byte  0
2437 .LFE1:
2438         .section        .eh_frame,"aw",@progbits
2439 __FRAME_BEGIN__:
2440         .4byte  .LECIE1-.LSCIE1
2441 .LSCIE1:
2442         .4byte  0x0
2443         .byte   0x1
2444         .ascii "z\0"
2445         .byte   0x1
2446         .byte   0x78
2447         .byte   0x1a
2448         .byte   0x0
2449         .byte   0x4
2450         .4byte  1
2451         .p2align 1
2452 .LECIE1:
2453 .LSFDE1:
2454         .4byte  .LEFDE1-.LASFDE1
2455 .LASFDE1:
2456         .4byte  .LASFDE1-__FRAME_BEGIN__
2457         .4byte  .LFB1
2458         .4byte  .LFE1-.LFB1
2459         .byte   0x4
2460         .4byte  .LFE1-.LFB1
2461         .byte   0x4
2462         .4byte  .L1-.LFB1
2463 .LEFDE1:],
2464 [  dnl # For autoconf 2.5x, must protect trailing spaces with @&t@.
2465 cat > conftest.lit <<EOF
2466  0000 10000000 00000000 017a0001 781a0004  .........z..x...
2467  0010 01000000 12000000 18000000 00000000  ................
2468  0020 08000000 04080000 0044               .........D      @&t@
2469 EOF
2470 cat > conftest.big <<EOF
2471  0000 00000010 00000000 017a0001 781a0004  .........z..x...
2472  0010 00000001 00000012 00000018 00000000  ................
2473  0020 00000008 04000000 0844               .........D      @&t@
2474 EOF
2475   # If the assembler didn't choke, and we can objdump,
2476   # and we got the correct data, then succeed.
2477   # The text in the here-document typically retains its unix-style line
2478   # endings, while the output of objdump will use host line endings.
2479   # Therefore, use diff -b for the comparisons.
2480   if test x$gcc_cv_objdump != x \
2481   && $gcc_cv_objdump -s -j .eh_frame conftest.o 2>/dev/null \
2482      | tail -3 > conftest.got \
2483   && { diff -b conftest.lit conftest.got > /dev/null 2>&1 \
2484     || diff -b conftest.big conftest.got > /dev/null 2>&1; }
2485   then
2486     gcc_cv_as_eh_frame=yes
2487   elif AC_TRY_COMMAND($gcc_cv_as -o conftest.o --traditional-format /dev/null); then
2488     gcc_cv_as_eh_frame=buggy
2489   else
2490     # Uh oh, what do we do now?
2491     gcc_cv_as_eh_frame=no
2492   fi])
2493
2494 if test $gcc_cv_as_eh_frame = buggy; then
2495   AC_DEFINE(USE_AS_TRADITIONAL_FORMAT, 1,
2496   [Define if your assembler mis-optimizes .eh_frame data.])
2497 fi
2498
2499 gcc_GAS_CHECK_FEATURE(section merging support, gcc_cv_as_shf_merge,
2500  [elf,2,12,0], [--fatal-warnings],
2501  [.section .rodata.str, "aMS", @progbits, 1])
2502 if test $gcc_cv_as_shf_merge = no; then
2503   gcc_GAS_CHECK_FEATURE(section merging support, gcc_cv_as_shf_merge,
2504     [elf,2,12,0], [--fatal-warnings],
2505     [.section .rodata.str, "aMS", %progbits, 1])
2506 fi
2507 AC_DEFINE_UNQUOTED(HAVE_GAS_SHF_MERGE,
2508   [`if test $gcc_cv_as_shf_merge = yes; then echo 1; else echo 0; fi`],
2509 [Define 0/1 if your assembler supports marking sections with SHF_MERGE flag.])
2510
2511 gcc_GAS_CHECK_FEATURE(COMDAT group support, gcc_cv_as_comdat_group,
2512  [elf,2,16,0], [--fatal-warnings],
2513  [.section .text,"axG",@progbits,.foo,comdat])
2514 if test $gcc_cv_as_comdat_group = yes; then
2515   gcc_cv_as_comdat_group_percent=no
2516 else
2517  gcc_GAS_CHECK_FEATURE(COMDAT group support, gcc_cv_as_comdat_group_percent,
2518    [elf,2,16,0], [--fatal-warnings],
2519    [.section .text,"axG",%progbits,.foo,comdat])
2520 fi
2521 if test x"$ld_is_gold" = xyes; then
2522   comdat_group=yes
2523 elif test $in_tree_ld = yes ; then
2524   comdat_group=no
2525   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2 \
2526      && test $in_tree_ld_is_elf = yes; then
2527      comdat_group=yes
2528   fi
2529 elif echo "$ld_ver" | grep GNU > /dev/null; then
2530   comdat_group=yes
2531   if test 0"$ld_date" -lt 20050308; then
2532     if test -n "$ld_date"; then
2533       # If there was date string, but was earlier than 2005-03-08, fail
2534       comdat_group=no
2535     elif test "$ld_vers_major" -lt 2; then
2536       comdat_group=no
2537     elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -lt 16; then
2538       comdat_group=no
2539     fi
2540   fi
2541 else
2542 changequote(,)dnl
2543   case "${target}" in
2544     *-*-solaris2.1[1-9]*)
2545       # Sun ld has COMDAT group support since Solaris 9, but it doesn't
2546       # interoperate with GNU as until Solaris 11 build 130, i.e. ld
2547       # version 1.688.
2548       #
2549       # FIXME: Maybe need to refine later when COMDAT group support with
2550       # Sun as is implemented.
2551       if test "$ld_vers_major" -gt 1 || test "$ld_vers_minor" -ge 1688; then
2552         comdat_group=yes
2553       else
2554         comdat_group=no
2555       fi
2556       ;;
2557     *)
2558       # Assume linkers other than GNU ld don't support COMDAT group.
2559       comdat_group=no
2560       ;;
2561   esac
2562 changequote([,])dnl
2563 fi
2564 # Allow overriding the automatic COMDAT group tests above.
2565 AC_ARG_ENABLE(comdat,
2566   [AS_HELP_STRING([--enable-comdat], [enable COMDAT group support])],
2567   [comdat_group="$enable_comdat"])
2568 if test $comdat_group = no; then
2569   gcc_cv_as_comdat_group=no
2570   gcc_cv_as_comdat_group_percent=no
2571 fi
2572 AC_DEFINE_UNQUOTED(HAVE_COMDAT_GROUP,
2573   [`if test $gcc_cv_as_comdat_group = yes || test $gcc_cv_as_comdat_group_percent = yes; then echo 1; else echo 0; fi`],
2574 [Define 0/1 if your assembler and linker support COMDAT groups.])
2575
2576 gcc_GAS_CHECK_FEATURE([line table discriminator support],
2577  gcc_cv_as_discriminator,
2578  [2,19,51],,
2579 [       .text
2580         .file 1 "conf.c"
2581         .loc 1 1 0 discriminator 1],,
2582 [AC_DEFINE(HAVE_GAS_DISCRIMINATOR, 1,
2583   [Define if your assembler supports the .loc discriminator sub-directive.])])
2584
2585 # Thread-local storage - the check is heavily parameterized.
2586 conftest_s=
2587 tls_first_major=
2588 tls_first_minor=
2589 tls_as_opt=
2590 case "$target" in
2591 changequote(,)dnl
2592   alpha*-*-*)
2593     conftest_s='
2594         .section ".tdata","awT",@progbits
2595 foo:    .long   25
2596         .text
2597         ldq     $27,__tls_get_addr($29)         !literal!1
2598         lda     $16,foo($29)                    !tlsgd!1
2599         jsr     $26,($27),__tls_get_addr        !lituse_tlsgd!1
2600         ldq     $27,__tls_get_addr($29)         !literal!2
2601         lda     $16,foo($29)                    !tlsldm!2
2602         jsr     $26,($27),__tls_get_addr        !lituse_tlsldm!2
2603         ldq     $1,foo($29)                     !gotdtprel
2604         ldah    $2,foo($29)                     !dtprelhi
2605         lda     $3,foo($2)                      !dtprello
2606         lda     $4,foo($29)                     !dtprel
2607         ldq     $1,foo($29)                     !gottprel
2608         ldah    $2,foo($29)                     !tprelhi
2609         lda     $3,foo($2)                      !tprello
2610         lda     $4,foo($29)                     !tprel'
2611         tls_first_major=2
2612         tls_first_minor=13
2613         tls_as_opt=--fatal-warnings
2614         ;;
2615   cris-*-*|crisv32-*-*)
2616     conftest_s='
2617         .section ".tdata","awT",@progbits
2618 x:      .long   25
2619         .text
2620         move.d x:IE,$r10
2621         nop'
2622         tls_first_major=2
2623         tls_first_minor=20
2624         tls_as_opt=--fatal-warnings
2625         ;;
2626   frv*-*-*)
2627     conftest_s='
2628         .section ".tdata","awT",@progbits
2629 x:      .long   25
2630         .text
2631         call    #gettlsoff(x)'
2632         tls_first_major=2
2633         tls_first_minor=14
2634         ;;
2635   hppa*-*-linux*)
2636     conftest_s='
2637 t1:     .reg    %r20
2638 t2:     .reg    %r21
2639 gp:     .reg    %r19
2640         .section ".tdata","awT",@progbits
2641 foo:    .long   25
2642         .text
2643         .align  4
2644         addil LT%foo-$tls_gdidx$,gp
2645         ldo RT%foo-$tls_gdidx$(%r1),%arg0
2646         b __tls_get_addr
2647         nop             
2648         addil LT%foo-$tls_ldidx$,gp
2649         b __tls_get_addr
2650         ldo RT%foo-$tls_ldidx$(%r1),%arg0
2651         addil LR%foo-$tls_dtpoff$,%ret0
2652         ldo RR%foo-$tls_dtpoff$(%r1),%t1
2653         mfctl %cr27,%t1                 
2654         addil LT%foo-$tls_ieoff$,gp
2655         ldw RT%foo-$tls_ieoff$(%r1),%t2
2656         add %t1,%t2,%t3                 
2657         mfctl %cr27,%t1                 
2658         addil LR%foo-$tls_leoff$,%t1
2659         ldo RR%foo-$tls_leoff$(%r1),%t2'
2660         tls_first_major=2
2661         tls_first_minor=15
2662         tls_as_opt=--fatal-warnings
2663         ;;
2664   arm*-*-*)
2665     conftest_s='
2666         .section ".tdata","awT",%progbits
2667 foo:    .long   25
2668         .text
2669 .word foo(gottpoff)
2670 .word foo(tpoff)
2671 .word foo(tlsgd)
2672 .word foo(tlsldm)
2673 .word foo(tlsldo)'
2674         tls_first_major=2
2675         tls_first_minor=17
2676         ;;
2677   i[34567]86-*-*)
2678     case "$target" in
2679       i[34567]86-*-solaris2.*)
2680         on_solaris=yes
2681         tga_func=___tls_get_addr
2682         ;;
2683       *)
2684         on_solaris=no
2685         ;;
2686     esac
2687     if test x$on_solaris = xyes && test x$gas_flag = xno; then
2688       conftest_s='
2689         .section .tdata,"awt",@progbits'
2690       tls_first_major=0
2691       tls_first_minor=0
2692 changequote([,])dnl
2693       AC_DEFINE(TLS_SECTION_ASM_FLAG, 't',
2694 [Define to the flag used to mark TLS sections if the default (`T') doesn't work.])
2695 changequote(,)dnl
2696     else
2697       conftest_s='
2698         .section ".tdata","awT",@progbits'
2699       tls_first_major=2
2700       tls_first_minor=14
2701       tls_as_opt="--fatal-warnings"
2702     fi
2703     conftest_s="$conftest_s
2704 foo:    .long   25
2705         .text
2706         movl    %gs:0, %eax
2707         leal    foo@tlsgd(,%ebx,1), %eax
2708         leal    foo@tlsldm(%ebx), %eax
2709         leal    foo@dtpoff(%eax), %edx
2710         movl    foo@gottpoff(%ebx), %eax
2711         subl    foo@gottpoff(%ebx), %eax
2712         addl    foo@gotntpoff(%ebx), %eax
2713         movl    foo@indntpoff, %eax
2714         movl    \$foo@tpoff, %eax
2715         subl    \$foo@tpoff, %eax
2716         leal    foo@ntpoff(%ecx), %eax"
2717     ;;
2718   x86_64-*-*)
2719     conftest_s='
2720         .section ".tdata","awT",@progbits
2721 foo:    .long   25
2722         .text
2723         movq    %fs:0, %rax
2724         leaq    foo@TLSGD(%rip), %rdi
2725         leaq    foo@TLSLD(%rip), %rdi
2726         leaq    foo@DTPOFF(%rax), %rdx
2727         movq    foo@GOTTPOFF(%rip), %rax
2728         movq    $foo@TPOFF, %rax'
2729         tls_first_major=2
2730         tls_first_minor=14
2731         tls_as_opt=--fatal-warnings
2732         ;;
2733   ia64-*-*)
2734     conftest_s='
2735         .section ".tdata","awT",@progbits
2736 foo:    data8   25
2737         .text
2738         addl    r16 = @ltoff(@dtpmod(foo#)), gp
2739         addl    r17 = @ltoff(@dtprel(foo#)), gp
2740         addl    r18 = @ltoff(@tprel(foo#)), gp
2741         addl    r19 = @dtprel(foo#), gp
2742         adds    r21 = @dtprel(foo#), r13
2743         movl    r23 = @dtprel(foo#)
2744         addl    r20 = @tprel(foo#), gp
2745         adds    r22 = @tprel(foo#), r13
2746         movl    r24 = @tprel(foo#)'
2747         tls_first_major=2
2748         tls_first_minor=13
2749         tls_as_opt=--fatal-warnings
2750         ;;
2751   mips*-*-*)
2752     conftest_s='
2753         .section .tdata,"awT",@progbits
2754 x:
2755         .word 2
2756         .text
2757         addiu $4, $28, %tlsgd(x)
2758         addiu $4, $28, %tlsldm(x)
2759         lui $4, %dtprel_hi(x)
2760         addiu $4, $4, %dtprel_lo(x)
2761         lw $4, %gottprel(x)($28)
2762         lui $4, %tprel_hi(x)
2763         addiu $4, $4, %tprel_lo(x)'
2764         tls_first_major=2
2765         tls_first_minor=16
2766         tls_as_opt='-32 --fatal-warnings'
2767         ;;
2768   m68k-*-*)
2769     conftest_s='
2770         .section .tdata,"awT",@progbits
2771 x:
2772         .word 2
2773         .text
2774 foo:
2775         move.l x@TLSGD(%a5),%a0
2776         move.l x@TLSLDM(%a5),%a0
2777         move.l x@TLSLDO(%a5),%a0
2778         move.l x@TLSIE(%a5),%a0
2779         move.l x@TLSLE(%a5),%a0'
2780         tls_first_major=2
2781         tls_first_minor=19
2782         tls_as_opt='--fatal-warnings'
2783         ;;
2784   powerpc-*-*)
2785     conftest_s='
2786         .section ".tdata","awT",@progbits
2787         .align 2
2788 ld0:    .space 4
2789 ld1:    .space 4
2790 x1:     .space 4
2791 x2:     .space 4
2792 x3:     .space 4
2793         .text
2794         addi 3,31,ld0@got@tlsgd
2795         bl __tls_get_addr
2796         addi 3,31,x1@got@tlsld
2797         bl __tls_get_addr
2798         addi 9,3,x1@dtprel
2799         addis 9,3,x2@dtprel@ha
2800         addi 9,9,x2@dtprel@l
2801         lwz 9,x3@got@tprel(31)
2802         add 9,9,x@tls
2803         addi 9,2,x1@tprel
2804         addis 9,2,x2@tprel@ha
2805         addi 9,9,x2@tprel@l'
2806         tls_first_major=2
2807         tls_first_minor=14
2808         tls_as_opt="-a32 --fatal-warnings"
2809         ;;
2810   powerpc64-*-*)
2811     conftest_s='
2812         .section ".tdata","awT",@progbits
2813         .align 3
2814 ld0:    .space 8
2815 ld1:    .space 8
2816 x1:     .space 8
2817 x2:     .space 8
2818 x3:     .space 8
2819         .text
2820         addi 3,2,ld0@got@tlsgd
2821         bl .__tls_get_addr
2822         nop
2823         addi 3,2,ld1@toc
2824         bl .__tls_get_addr
2825         nop
2826         addi 3,2,x1@got@tlsld
2827         bl .__tls_get_addr
2828         nop
2829         addi 9,3,x1@dtprel
2830         bl .__tls_get_addr
2831         nop
2832         addis 9,3,x2@dtprel@ha
2833         addi 9,9,x2@dtprel@l
2834         bl .__tls_get_addr
2835         nop
2836         ld 9,x3@got@dtprel(2)
2837         add 9,9,3
2838         bl .__tls_get_addr
2839         nop'
2840         tls_first_major=2
2841         tls_first_minor=14
2842         tls_as_opt="-a64 --fatal-warnings"
2843         ;;
2844   s390-*-*)
2845     conftest_s='
2846         .section ".tdata","awT",@progbits
2847 foo:    .long   25
2848         .text
2849         .long   foo@TLSGD
2850         .long   foo@TLSLDM
2851         .long   foo@DTPOFF
2852         .long   foo@NTPOFF
2853         .long   foo@GOTNTPOFF
2854         .long   foo@INDNTPOFF
2855         l       %r1,foo@GOTNTPOFF(%r12)
2856         l       %r1,0(%r1):tls_load:foo
2857         bas     %r14,0(%r1,%r13):tls_gdcall:foo
2858         bas     %r14,0(%r1,%r13):tls_ldcall:foo'
2859         tls_first_major=2
2860         tls_first_minor=14
2861         tls_as_opt="-m31 --fatal-warnings"
2862         ;;
2863   s390x-*-*)
2864     conftest_s='
2865         .section ".tdata","awT",@progbits
2866 foo:    .long   25
2867         .text
2868         .quad   foo@TLSGD
2869         .quad   foo@TLSLDM
2870         .quad   foo@DTPOFF
2871         .quad   foo@NTPOFF
2872         .quad   foo@GOTNTPOFF
2873         lg      %r1,foo@GOTNTPOFF(%r12)
2874         larl    %r1,foo@INDNTPOFF
2875         brasl   %r14,__tls_get_offset@PLT:tls_gdcall:foo
2876         brasl   %r14,__tls_get_offset@PLT:tls_ldcall:foo'
2877         tls_first_major=2
2878         tls_first_minor=14
2879         tls_as_opt="-m64 -Aesame --fatal-warnings"
2880         ;;
2881   sh-*-* | sh[34]-*-*)
2882     conftest_s='
2883         .section ".tdata","awT",@progbits
2884 foo:    .long   25
2885         .text
2886         .long   foo@TLSGD
2887         .long   foo@TLSLDM
2888         .long   foo@DTPOFF
2889         .long   foo@GOTTPOFF
2890         .long   foo@TPOFF'
2891         tls_first_major=2
2892         tls_first_minor=13
2893         tls_as_opt=--fatal-warnings
2894         ;;
2895   sparc*-*-*)
2896     case "$target" in
2897       sparc*-sun-solaris2.*)
2898         on_solaris=yes
2899         tga_func=__tls_get_addr
2900         ;;
2901       *)
2902         on_solaris=no
2903         ;;
2904     esac
2905     if test x$on_solaris = xyes && test x$gas_flag = xno; then
2906       conftest_s='
2907         .section ".tdata",#alloc,#write,#tls'
2908         tls_first_major=0
2909         tls_first_minor=0
2910     else
2911       conftest_s='
2912         .section ".tdata","awT",@progbits'
2913         tls_first_major=2
2914         tls_first_minor=14
2915         tls_as_opt="-32 --fatal-warnings"
2916     fi
2917     conftest_s="$conftest_s
2918 foo:    .long   25
2919         .text
2920         sethi   %tgd_hi22(foo), %o0
2921         add     %o0, %tgd_lo10(foo), %o1
2922         add     %l7, %o1, %o0, %tgd_add(foo)
2923         call    __tls_get_addr, %tgd_call(foo)
2924         sethi   %tldm_hi22(foo), %l1
2925         add     %l1, %tldm_lo10(foo), %l2
2926         add     %l7, %l2, %o0, %tldm_add(foo)
2927         call    __tls_get_addr, %tldm_call(foo)
2928         sethi   %tldo_hix22(foo), %l3
2929         xor     %l3, %tldo_lox10(foo), %l4
2930         add     %o0, %l4, %l5, %tldo_add(foo)
2931         sethi   %tie_hi22(foo), %o3
2932         add     %o3, %tie_lo10(foo), %o3
2933         ld      [%l7 + %o3], %o2, %tie_ld(foo)
2934         add     %g7, %o2, %o4, %tie_add(foo)
2935         sethi   %tle_hix22(foo), %l1
2936         xor     %l1, %tle_lox10(foo), %o5
2937         ld      [%g7 + %o5], %o1"
2938         ;;
2939   xtensa*-*-*)
2940     conftest_s='
2941         .section ".tdata","awT",@progbits
2942 foo:    .long   25
2943         .text
2944         movi    a8, foo@TLSFUNC
2945         movi    a10, foo@TLSARG
2946         callx8.tls a8, foo@TLSCALL'
2947         tls_first_major=2
2948         tls_first_minor=19
2949         ;;
2950 changequote([,])dnl
2951 esac
2952 set_have_as_tls=no
2953 if test "x$enable_tls" = xno ; then
2954   : # TLS explicitly disabled.
2955 elif test "x$enable_tls" = xyes ; then
2956   set_have_as_tls=yes # TLS explicitly enabled.
2957 elif test -z "$tls_first_major"; then
2958   : # If we don't have a check, assume no support.
2959 else
2960   gcc_GAS_CHECK_FEATURE(thread-local storage support, gcc_cv_as_tls,
2961   [$tls_first_major,$tls_first_minor,0], [$tls_as_opt], [$conftest_s],,
2962   [set_have_as_tls=yes])
2963 fi
2964 case "$target" in
2965   # TLS was introduced in the Solaris 9 FCS release and backported to
2966   # Solaris 8 patches.  Support for GNU-style TLS on x86 was only
2967   # introduced in Solaris 9 4/04, replacing the earlier Sun style that Sun
2968   # ld and GCC don't support any longer.
2969   *-*-solaris2.*)
2970     AC_MSG_CHECKING(linker and ld.so.1 TLS support)
2971     ld_tls_support=no
2972     # Check ld and ld.so.1 TLS support.
2973     if echo "$ld_ver" | grep GNU > /dev/null; then
2974       # Assume all interesting versions of GNU ld have TLS support.
2975       # FIXME: still need ld.so.1 support, i.e. ld version checks below.
2976       ld_tls_support=yes
2977     else
2978       case "$target" in
2979         # Solaris 8/x86 ld has GNU style TLS support since version 1.280.
2980         i?86-*-solaris2.8)
2981           min_tls_ld_vers_minor=280
2982           ;;
2983         # Solaris 8/SPARC ld has TLS support since version 1.272.
2984         sparc*-*-solaris2.8)
2985           min_tls_ld_vers_minor=272
2986           ;;
2987         # Solaris 9/x86 ld has GNU style TLS support since version 1.374.
2988         i?86-*-solaris2.9)
2989           min_tls_ld_vers_minor=374
2990           ;;
2991         # Solaris 9/SPARC and Solaris 10+ ld have TLS support since FCS.
2992         sparc*-*-solaris2.9 | *-*-solaris2.1[[0-9]]*)
2993           min_tls_ld_vers_minor=343
2994           ;;
2995       esac
2996       if test "$ls_vers_major" -gt 1 || \
2997         test "$ld_vers_minor" -ge "$min_tls_ld_vers_minor"; then
2998         ld_tls_support=yes
2999       else
3000         set_have_as_tls=no
3001       fi
3002     fi
3003     AC_MSG_RESULT($ld_tls_support)
3004
3005     save_LIBS="$LIBS"
3006     save_LDFLAGS="$LDFLAGS"
3007     LIBS=
3008     LDFLAGS=
3009
3010     AC_MSG_CHECKING(alternate thread library)
3011     case "$target" in
3012       # TLS support was backported to Solaris 8 patches, but only lives in
3013       # the alternate thread library which became the default in Solaris 9. 
3014       # We want to always use that, irrespective of TLS support.
3015       *-*-solaris2.8)
3016         # Take multilib subdir into account.  There's no spec to handle
3017         # this.  The 64 symlink exists since Solaris 8.
3018         lwp_dir=/usr/lib/lwp
3019         lwp_spec="-L$lwp_dir%{m64:/64} -R$lwp_dir%{m64:/64}"
3020         LDFLAGS="-L$lwp_dir -R$lwp_dir"
3021         ;;
3022       *-*-solaris2*)
3023         lwp_dir="none"
3024         lwp_spec=""
3025         ;;
3026     esac    
3027     # Always define LIB_THREAD_LDFLAGS_SPEC, even without TLS support.
3028     AC_DEFINE_UNQUOTED(LIB_THREAD_LDFLAGS_SPEC, "$lwp_spec",
3029         [Define to the linker flags to use for -pthread.])
3030     AC_MSG_RESULT($lwp_dir)
3031
3032     AC_MSG_CHECKING(library containing $tga_func)
3033     # Before Solaris 10, __tls_get_addr (SPARC/x64) resp. ___tls_get_addr
3034     # (32-bit x86) only lived in libthread, so check for that.  Keep
3035     # set_have_as_tls if found, disable if not.
3036     AC_SEARCH_LIBS([$tga_func], [thread],, [set_have_as_tls=no])
3037     # Clear LIBS if we cannot support TLS.
3038     if test $set_have_as_tls = no; then
3039       LIBS=
3040     fi
3041     # Always define LIB_TLS_SPEC, even without TLS support.
3042     AC_DEFINE_UNQUOTED(LIB_TLS_SPEC, "$LIBS",
3043         [Define to the library containing __tls_get_addr/___tls_get_addr.])
3044     AC_MSG_RESULT($LIBS)
3045
3046     LIBS="$save_LIBS"
3047     LDFLAGS="$save_LDFLAGS"
3048     ;;
3049 esac
3050 if test $set_have_as_tls = yes ; then
3051   AC_DEFINE(HAVE_AS_TLS, 1,
3052             [Define if your assembler and linker support thread-local storage.])
3053 fi
3054
3055 # Target-specific assembler checks.
3056
3057 AC_MSG_CHECKING(linker -Bstatic/-Bdynamic option)
3058 gcc_cv_ld_static_dynamic=no
3059 if test $in_tree_ld = yes ; then
3060   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 10 -o "$gcc_cv_gld_major_version" -gt 2; then
3061     gcc_cv_ld_static_dynamic=yes
3062   fi
3063 elif test x$gcc_cv_ld != x; then
3064         # Check if linker supports -Bstatic/-Bdynamic option
3065         if $gcc_cv_ld --help 2>/dev/null | grep -- -Bstatic > /dev/null \
3066           && $gcc_cv_ld --help 2>/dev/null | grep -- -Bdynamic > /dev/null; then
3067                 gcc_cv_ld_static_dynamic=yes
3068         fi
3069 fi
3070 if test x"$gcc_cv_ld_static_dynamic" = xyes; then
3071         AC_DEFINE(HAVE_LD_STATIC_DYNAMIC, 1,
3072 [Define if your linker supports -Bstatic/-Bdynamic option.])
3073 fi
3074 AC_MSG_RESULT($gcc_cv_ld_static_dynamic)
3075
3076 if test x"$demangler_in_ld" = xyes; then
3077   AC_MSG_CHECKING(linker --demangle support)
3078   gcc_cv_ld_demangle=no
3079   if test $in_tree_ld = yes; then
3080     if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 14 -o "$gcc_cv_gld_major_version" -gt 2; then \
3081       gcc_cv_ld_demangle=yes
3082     fi
3083   elif test x$gcc_cv_ld != x -a x"$gnu_ld" = xyes; then
3084     # Check if the GNU linker supports --demangle option
3085     if $gcc_cv_ld --help 2>/dev/null | grep no-demangle > /dev/null; then
3086       gcc_cv_ld_demangle=yes
3087     fi
3088   fi
3089   if test x"$gcc_cv_ld_demangle" = xyes; then
3090     AC_DEFINE(HAVE_LD_DEMANGLE, 1,
3091 [Define if your linker supports --demangle option.])
3092   fi
3093   AC_MSG_RESULT($gcc_cv_ld_demangle)
3094 fi
3095
3096 case "$target" in
3097   # All TARGET_ABI_OSF targets.
3098   alpha*-*-osf* | alpha*-*-linux* | alpha*-*-*bsd*)
3099     gcc_GAS_CHECK_FEATURE([explicit relocation support],
3100         gcc_cv_as_alpha_explicit_relocs, [2,12,0],,
3101 [       .set nomacro
3102         .text
3103         extbl   $3, $2, $3      !lituse_bytoff!1
3104         ldq     $2, a($29)      !literal!1
3105         ldq     $4, b($29)      !literal!2
3106         ldq_u   $3, 0($2)       !lituse_base!1
3107         ldq     $27, f($29)     !literal!5
3108         jsr     $26, ($27), f   !lituse_jsr!5
3109         ldah    $29, 0($26)     !gpdisp!3
3110         lda     $0, c($29)      !gprel
3111         ldah    $1, d($29)      !gprelhigh
3112         lda     $1, d($1)       !gprellow
3113         lda     $29, 0($29)     !gpdisp!3],,
3114     [AC_DEFINE(HAVE_AS_EXPLICIT_RELOCS, 1,
3115   [Define if your assembler supports explicit relocations.])])
3116     gcc_GAS_CHECK_FEATURE([jsrdirect relocation support],
3117         gcc_cv_as_alpha_jsrdirect_relocs, [2,16,90],,
3118 [       .set nomacro
3119         .text
3120         ldq     $27, a($29)     !literal!1
3121         jsr     $26, ($27), a   !lituse_jsrdirect!1],,
3122     [AC_DEFINE(HAVE_AS_JSRDIRECT_RELOCS, 1,
3123   [Define if your assembler supports the lituse_jsrdirect relocation.])])
3124     ;;
3125
3126   cris-*-*)
3127     gcc_GAS_CHECK_FEATURE([-no-mul-bug-abort option],
3128       gcc_cv_as_cris_no_mul_bug,[2,15,91],
3129       [-no-mul-bug-abort], [.text],,
3130       [AC_DEFINE(HAVE_AS_NO_MUL_BUG_ABORT_OPTION, 1,
3131                 [Define if your assembler supports the -no-mul-bug-abort option.])])
3132     ;;
3133
3134   sparc*-*-*)
3135     gcc_GAS_CHECK_FEATURE([.register], gcc_cv_as_sparc_register_op,,,
3136       [.register %g2, #scratch],,
3137       [AC_DEFINE(HAVE_AS_REGISTER_PSEUDO_OP, 1,
3138                 [Define if your assembler supports .register.])])
3139
3140     gcc_GAS_CHECK_FEATURE([-relax option], gcc_cv_as_sparc_relax,,
3141       [-relax], [.text],,
3142       [AC_DEFINE(HAVE_AS_RELAX_OPTION, 1,
3143                 [Define if your assembler supports -relax option.])])
3144
3145     gcc_GAS_CHECK_FEATURE([GOTDATA_OP relocs],
3146       gcc_cv_as_sparc_gotdata_op,,
3147       [-K PIC],
3148 [.text
3149 foo:
3150         nop
3151 bar:
3152         sethi %gdop_hix22(foo), %g1
3153         xor    %g1, %gdop_lox10(foo), %g1
3154         ld    [[%l7 + %g1]], %g2, %gdop(foo)],
3155       [if test x$gcc_cv_ld != x \
3156        && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1; then
3157          if $gcc_cv_ld -v | grep GNU >/dev/null 2>&1; then
3158            if test x$gcc_cv_objdump != x; then
3159              if $gcc_cv_objdump -s -j .text conftest 2> /dev/null \
3160                 | grep ' 03000004 82186004 c405c001'> /dev/null 2>&1; then
3161                gcc_cv_as_sparc_gotdata_op=no
3162              else
3163                gcc_cv_as_sparc_gotdata_op=yes
3164              fi
3165            fi
3166          else
3167            gcc_cv_as_sparc_gotdata_op=yes
3168          fi
3169        fi
3170        rm -f conftest],
3171       [AC_DEFINE(HAVE_AS_SPARC_GOTDATA_OP, 1,
3172                 [Define if your assembler and linker support GOTDATA_OP relocs.])])
3173
3174     gcc_GAS_CHECK_FEATURE([unaligned pcrel relocs],
3175       gcc_cv_as_sparc_ua_pcrel,,
3176       [-K PIC],
3177 [.text
3178 foo:
3179         nop
3180 .data
3181 .align 4
3182 .byte 0
3183 .uaword %r_disp32(foo)],
3184       [if test x$gcc_cv_ld != x \
3185        && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1; then
3186          gcc_cv_as_sparc_ua_pcrel=yes
3187        fi
3188        rm -f conftest],
3189       [AC_DEFINE(HAVE_AS_SPARC_UA_PCREL, 1,
3190                 [Define if your assembler and linker support unaligned PC relative relocs.])
3191
3192       gcc_GAS_CHECK_FEATURE([unaligned pcrel relocs against hidden symbols],
3193         gcc_cv_as_sparc_ua_pcrel_hidden,,
3194         [-K PIC],
3195 [.data
3196 .align 4
3197 .byte 0x31
3198 .uaword %r_disp32(foo)
3199 .byte 0x32, 0x33, 0x34
3200 .global foo
3201 .hidden foo
3202 foo:
3203 .skip 4],
3204         [if test x$gcc_cv_ld != x && test x$gcc_cv_objdump != x \
3205          && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1 \
3206          && $gcc_cv_objdump -s -j .data conftest 2> /dev/null \
3207             | grep ' 31000000 07323334' > /dev/null 2>&1; then
3208             if $gcc_cv_objdump -R conftest 2> /dev/null \
3209                | grep 'DISP32' > /dev/null 2>&1; then
3210                 :
3211             else
3212                 gcc_cv_as_sparc_ua_pcrel_hidden=yes
3213             fi
3214          fi
3215          rm -f conftest],
3216          [AC_DEFINE(HAVE_AS_SPARC_UA_PCREL_HIDDEN, 1,
3217                    [Define if your assembler and linker support unaligned PC relative relocs against hidden symbols.])])
3218     ]) # unaligned pcrel relocs
3219
3220     gcc_GAS_CHECK_FEATURE([offsetable %lo()],
3221       gcc_cv_as_sparc_offsetable_lo10,,
3222       [-xarch=v9],
3223 [.text
3224         or %g1, %lo(ab) + 12, %g1
3225         or %g1, %lo(ab + 12), %g1],
3226       [if test x$gcc_cv_objdump != x \
3227        && $gcc_cv_objdump -s -j .text conftest.o 2> /dev/null \
3228           | grep ' 82106000 82106000' > /dev/null 2>&1; then
3229          gcc_cv_as_sparc_offsetable_lo10=yes
3230        fi],
3231        [AC_DEFINE(HAVE_AS_OFFSETABLE_LO10, 1,
3232                  [Define if your assembler supports offsetable %lo().])])
3233     ;;
3234
3235 changequote(,)dnl
3236   i[34567]86-*-* | x86_64-*-*)
3237 changequote([,])dnl
3238     case $target_os in
3239       cygwin*)
3240         # Full C++ conformance when using a shared libstdc++-v3 requires some
3241         # support from the Cygwin DLL, which in more recent versions exports
3242         # wrappers to aid in interposing and redirecting operators new, delete,
3243         # etc., as per n2800 #17.6.4.6 [replacement.functions].  Check if we
3244         # are configuring for a version of Cygwin that exports the wrappers.
3245         if test x$host = x$target; then
3246           AC_CHECK_FUNC([__wrap__Znaj],[gcc_ac_cygwin_dll_wrappers=yes],[gcc_ac_cygwin_dll_wrappers=no])
3247         else
3248           # Can't check presence of libc functions during cross-compile, so
3249           # we just have to assume we're building for an up-to-date target.
3250           gcc_ac_cygwin_dll_wrappers=yes
3251         fi
3252         AC_DEFINE_UNQUOTED(USE_CYGWIN_LIBSTDCXX_WRAPPERS,
3253           [`if test $gcc_ac_cygwin_dll_wrappers = yes; then echo 1; else echo 0; fi`],
3254           [Define if you want to generate code by default that assumes that the
3255            Cygwin DLL exports wrappers to support libstdc++ function replacement.])
3256     esac
3257     case $target_os in
3258       cygwin* | pe | mingw32*)
3259         # Recent binutils allows the three-operand form of ".comm" on PE.  This
3260         # definition is used unconditionally to initialise the default state of
3261         # the target option variable that governs usage of the feature.
3262         gcc_GAS_CHECK_FEATURE([.comm with alignment], gcc_cv_as_comm_has_align,
3263          [2,19,52],,[.comm foo,1,32])
3264         AC_DEFINE_UNQUOTED(HAVE_GAS_ALIGNED_COMM,
3265           [`if test $gcc_cv_as_comm_has_align = yes; then echo 1; else echo 0; fi`],
3266           [Define if your assembler supports specifying the alignment
3267            of objects allocated using the GAS .comm command.])
3268         # Used for DWARF 2 in PE
3269         gcc_GAS_CHECK_FEATURE([.secrel32 relocs],
3270           gcc_cv_as_ix86_pe_secrel32,
3271           [2,15,91],,
3272 [.text
3273 foo:    nop
3274 .data
3275         .secrel32 foo],
3276           [if test x$gcc_cv_ld != x \
3277            && $gcc_cv_ld -o conftest conftest.o > /dev/null 2>&1; then
3278              gcc_cv_as_ix86_pe_secrel32=yes
3279            fi
3280            rm -f conftest],
3281           [AC_DEFINE(HAVE_GAS_PE_SECREL32_RELOC, 1,
3282             [Define if your assembler and linker support 32-bit section relative relocs via '.secrel32 label'.])])
3283         # Test if the assembler supports the extended form of the .section
3284         # directive that specifies section alignment.  LTO support uses this,
3285         # but normally only after installation, so we warn but don't fail the
3286         # configure if LTO is enabled but the assembler does not support it.
3287         gcc_GAS_CHECK_FEATURE([.section with alignment], gcc_cv_as_section_has_align,
3288           [2,20,1],-fatal-warnings,[.section lto_test,"dr0"])
3289         if test x$gcc_cv_as_section_has_align != xyes; then
3290           case ",$enable_languages," in
3291             *,lto,*)
3292               AC_MSG_WARN([LTO for $target requires binutils >= 2.20.1, but version found appears insufficient; LTO will not work until binutils is upgraded.])
3293               ;;
3294           esac
3295         fi
3296         ;;
3297     esac
3298
3299     gcc_GAS_CHECK_FEATURE([filds and fists mnemonics],
3300        gcc_cv_as_ix86_filds,,,
3301        [filds mem; fists mem],,
3302        [AC_DEFINE(HAVE_AS_IX86_FILDS, 1,
3303          [Define if your assembler uses filds and fists mnemonics.])])
3304
3305     gcc_GAS_CHECK_FEATURE([fildq and fistpq mnemonics],
3306        gcc_cv_as_ix86_fildq,,,
3307        [fildq mem; fistpq mem],,
3308        [AC_DEFINE(HAVE_AS_IX86_FILDQ, 1,
3309          [Define if your assembler uses fildq and fistq mnemonics.])])
3310
3311     gcc_GAS_CHECK_FEATURE([cmov syntax],
3312       gcc_cv_as_ix86_cmov_sun_syntax,,,
3313       [cmovl.l %edx, %eax],,
3314       [AC_DEFINE(HAVE_AS_IX86_CMOV_SUN_SYNTAX, 1,
3315         [Define if your assembler supports the Sun syntax for cmov.])])
3316
3317     gcc_GAS_CHECK_FEATURE([ffreep mnemonic],
3318       gcc_cv_as_ix86_ffreep,,,
3319       [ffreep %st(1)],,
3320       [AC_DEFINE(HAVE_AS_IX86_FFREEP, 1,
3321         [Define if your assembler supports the ffreep mnemonic.])])
3322
3323     gcc_GAS_CHECK_FEATURE([.quad directive],
3324       gcc_cv_as_ix86_quad,,,
3325       [.quad 0],,
3326       [AC_DEFINE(HAVE_AS_IX86_QUAD, 1,
3327         [Define if your assembler supports the .quad directive.])])
3328
3329     gcc_GAS_CHECK_FEATURE([sahf mnemonic],
3330       gcc_cv_as_ix86_sahf,,,
3331       [.code64
3332        sahf],,
3333       [AC_DEFINE(HAVE_AS_IX86_SAHF, 1,
3334         [Define if your assembler supports the sahf mnemonic in 64bit mode.])])
3335
3336     gcc_GAS_CHECK_FEATURE([swap suffix],
3337       gcc_cv_as_ix86_swap,,,
3338       [movl.s %esp, %ebp],,
3339       [AC_DEFINE(HAVE_AS_IX86_SWAP, 1,
3340         [Define if your assembler supports the swap suffix.])])
3341
3342     gcc_GAS_CHECK_FEATURE([different section symbol subtraction],
3343       gcc_cv_as_ix86_diff_sect_delta,,,
3344       [.section .rodata
3345 .L1:
3346         .long .L2-.L1
3347         .long .L3-.L1
3348         .text
3349 .L3:    nop
3350 .L2:    nop],,
3351       [AC_DEFINE(HAVE_AS_IX86_DIFF_SECT_DELTA, 1,
3352         [Define if your assembler supports the subtraction of symbols in different sections.])])
3353
3354     # These two are used unconditionally by i386.[ch]; it is to be defined
3355     # to 1 if the feature is present, 0 otherwise.
3356     gcc_GAS_CHECK_FEATURE([GOTOFF in data],
3357         gcc_cv_as_ix86_gotoff_in_data, [2,11,0],,
3358 [       .text
3359 .L0:
3360         nop
3361         .data
3362         .long .L0@GOTOFF])
3363     AC_DEFINE_UNQUOTED(HAVE_AS_GOTOFF_IN_DATA,
3364       [`if test $gcc_cv_as_ix86_gotoff_in_data = yes; then echo 1; else echo 0; fi`],
3365       [Define true if the assembler supports '.long foo@GOTOFF'.])
3366
3367     gcc_GAS_CHECK_FEATURE([rep and lock prefix],
3368         gcc_cv_as_ix86_rep_lock_prefix,,,
3369         [rep movsl
3370          lock addl %edi, (%eax,%esi)
3371          lock orl $0, (%esp)],,
3372         [AC_DEFINE(HAVE_AS_IX86_REP_LOCK_PREFIX, 1,
3373           [Define if the assembler supports 'rep <insn>, lock <insn>'.])])
3374
3375     ;;
3376
3377   ia64*-*-*)
3378     gcc_GAS_CHECK_FEATURE([ltoffx and ldxmov relocs],
3379         gcc_cv_as_ia64_ltoffx_ldxmov_relocs, [2,14,0],,
3380 [       .text
3381         addl r15 = @ltoffx(x#), gp
3382         ;;
3383         ld8.mov r16 = [[r15]], x#],,
3384     [AC_DEFINE(HAVE_AS_LTOFFX_LDXMOV_RELOCS, 1,
3385           [Define if your assembler supports ltoffx and ldxmov relocations.])])
3386
3387     ;;
3388
3389   powerpc*-*-*)
3390     case $target in
3391       *-*-aix*) conftest_s='    .machine "pwr5"
3392         .csect .text[[PR]]
3393         mfcr 3,128';;
3394       *-*-darwin*)
3395         gcc_GAS_CHECK_FEATURE([.machine directive support],
3396           gcc_cv_as_machine_directive,,,
3397           [     .machine ppc7400])
3398         if test x$gcc_cv_as_machine_directive != xyes; then
3399           echo "*** This target requires an assembler supporting \".machine\"" >&2
3400           echo you can get it from: ftp://gcc.gnu.org/pub/gcc/infrastructure/cctools-528.5.dmg >&2
3401           test x$build = x$target && exit 1
3402         fi
3403         conftest_s='    .text
3404         mfcr r3,128';;
3405       *) conftest_s='   .machine power4
3406         .text
3407         mfcr 3,128';;
3408     esac
3409
3410     gcc_GAS_CHECK_FEATURE([mfcr field support],
3411       gcc_cv_as_powerpc_mfcrf, [2,14,0],,
3412       [$conftest_s],,
3413       [AC_DEFINE(HAVE_AS_MFCRF, 1,
3414           [Define if your assembler supports mfcr field.])])
3415
3416     case $target in
3417       *-*-aix*) conftest_s='    .machine "pwr5"
3418         .csect .text[[PR]]
3419         popcntb 3,3';;
3420       *) conftest_s='   .machine power5
3421         .text
3422         popcntb 3,3';;
3423     esac
3424
3425     gcc_GAS_CHECK_FEATURE([popcntb support],
3426       gcc_cv_as_powerpc_popcntb, [2,17,0],,
3427       [$conftest_s],,
3428       [AC_DEFINE(HAVE_AS_POPCNTB, 1,
3429           [Define if your assembler supports popcntb field.])])
3430
3431     case $target in
3432       *-*-aix*) conftest_s='    .machine "pwr5x"
3433         .csect .text[[PR]]
3434         frin 1,1';;
3435       *) conftest_s='   .machine power5
3436         .text
3437         frin 1,1';;
3438     esac
3439
3440     gcc_GAS_CHECK_FEATURE([fp round support],
3441       gcc_cv_as_powerpc_fprnd, [2,17,0],,
3442       [$conftest_s],,
3443       [AC_DEFINE(HAVE_AS_FPRND, 1,
3444           [Define if your assembler supports fprnd.])])
3445
3446     case $target in
3447       *-*-aix*) conftest_s='    .machine "pwr6"
3448         .csect .text[[PR]]
3449         mffgpr 1,3';;
3450       *) conftest_s='   .machine power6
3451         .text
3452         mffgpr 1,3';;
3453     esac
3454
3455     gcc_GAS_CHECK_FEATURE([move fp gpr support],
3456       gcc_cv_as_powerpc_mfpgpr, [2,19,2],,
3457       [$conftest_s],,
3458       [AC_DEFINE(HAVE_AS_MFPGPR, 1,
3459           [Define if your assembler supports mffgpr and mftgpr.])])
3460
3461     case $target in
3462       *-*-aix*) conftest_s='    .csect .text[[PR]]
3463 LCF..0:
3464         addis 11,30,_GLOBAL_OFFSET_TABLE_-LCF..0@ha';;
3465       *-*-darwin*)
3466         conftest_s='    .text
3467 LCF0:
3468         addis r11,r30,_GLOBAL_OFFSET_TABLE_-LCF0@ha';;
3469       *) conftest_s='   .text
3470 .LCF0:
3471         addis 11,30,_GLOBAL_OFFSET_TABLE_-.LCF0@ha';;
3472     esac
3473
3474     gcc_GAS_CHECK_FEATURE([rel16 relocs],
3475       gcc_cv_as_powerpc_rel16, [2,17,0], -a32,
3476       [$conftest_s],,
3477       [AC_DEFINE(HAVE_AS_REL16, 1,
3478           [Define if your assembler supports R_PPC_REL16 relocs.])])
3479
3480     case $target in
3481       *-*-aix*) conftest_s='    .machine "pwr6"
3482         .csect .text[[PR]]
3483         cmpb 3,4,5';;
3484       *) conftest_s='   .machine power6
3485         .text
3486         cmpb 3,4,5';;
3487     esac
3488
3489     gcc_GAS_CHECK_FEATURE([compare bytes support],
3490       gcc_cv_as_powerpc_cmpb, [2,19,2], -a32,
3491       [$conftest_s],,
3492       [AC_DEFINE(HAVE_AS_CMPB, 1,
3493           [Define if your assembler supports cmpb.])])
3494
3495     case $target in
3496       *-*-aix*) conftest_s='    .machine "pwr6"
3497         .csect .text[[PR]]
3498         dadd 1,2,3';;
3499       *) conftest_s='   .machine power6
3500         .text
3501         dadd 1,2,3';;
3502     esac
3503
3504     gcc_GAS_CHECK_FEATURE([decimal float support],
3505       gcc_cv_as_powerpc_dfp, [2,19,2], -a32,
3506       [$conftest_s],,
3507       [AC_DEFINE(HAVE_AS_DFP, 1,
3508           [Define if your assembler supports DFP instructions.])])
3509
3510     case $target in
3511       *-*-aix*) conftest_s='    .machine "pwr7"
3512         .csect .text[[PR]]
3513         lxvd2x 1,2,3';;
3514       *) conftest_s='   .machine power7
3515         .text
3516         lxvd2x 1,2,3';;
3517     esac
3518
3519     gcc_GAS_CHECK_FEATURE([vector-scalar support],
3520       gcc_cv_as_powerpc_vsx, [2,19,2], -a32,
3521       [$conftest_s],,
3522       [AC_DEFINE(HAVE_AS_VSX, 1,
3523           [Define if your assembler supports VSX instructions.])])
3524
3525     case $target in
3526       *-*-aix*) conftest_s='    .machine "pwr7"
3527         .csect .text[[PR]]
3528         popcntd 3,3';;
3529       *) conftest_s='   .machine power7
3530         .text
3531         popcntd 3,3';;
3532     esac
3533
3534     gcc_GAS_CHECK_FEATURE([popcntd support],
3535       gcc_cv_as_powerpc_popcntd, [2,19,2], -a32,
3536       [$conftest_s],,
3537       [AC_DEFINE(HAVE_AS_POPCNTD, 1,
3538           [Define if your assembler supports POPCNTD instructions.])])
3539
3540     case $target in
3541       *-*-aix*) conftest_s='    .csect .text[[PR]]
3542         lwsync';;
3543       *) conftest_s='   .text
3544         lwsync';;
3545     esac
3546
3547     gcc_GAS_CHECK_FEATURE([lwsync support],
3548       gcc_cv_as_powerpc_lwsync, [2,19,2], -a32,
3549       [$conftest_s],,
3550       [AC_DEFINE(HAVE_AS_LWSYNC, 1,
3551           [Define if your assembler supports LWSYNC instructions.])])
3552
3553     case $target in
3554       *-*-aix*) conftest_s='    .machine "476"
3555         .csect .text[[PR]]
3556         dci 0';;
3557       *) conftest_s='   .machine "476"
3558         .text
3559         dci 0';;
3560     esac
3561
3562     gcc_GAS_CHECK_FEATURE([data cache invalidate support],
3563       gcc_cv_as_powerpc_dci, [9,99,0], -a32,
3564       [$conftest_s],,
3565       [AC_DEFINE(HAVE_AS_DCI, 1,
3566           [Define if your assembler supports the DCI/ICI instructions.])])
3567
3568     gcc_GAS_CHECK_FEATURE([.gnu_attribute support],
3569       gcc_cv_as_powerpc_gnu_attribute, [2,18,0],,
3570       [.gnu_attribute 4,1],,
3571       [AC_DEFINE(HAVE_AS_GNU_ATTRIBUTE, 1,
3572           [Define if your assembler supports .gnu_attribute.])])
3573
3574     gcc_GAS_CHECK_FEATURE([tls marker support],
3575       gcc_cv_as_powerpc_tls_markers, [2,20,0],,
3576       [ bl __tls_get_addr(x@tlsgd)],,
3577       [AC_DEFINE(HAVE_AS_TLS_MARKERS, 1,
3578           [Define if your assembler supports arg info for __tls_get_addr.])])
3579
3580     case $target in
3581       *-*-aix*)
3582         gcc_GAS_CHECK_FEATURE([.ref support],
3583           gcc_cv_as_aix_ref, [2.21.0],,
3584           [     .csect stuff[[rw]]
3585              stuff:
3586                 .long 1
3587                 .extern sym
3588                 .ref sym
3589           ],,
3590           [AC_DEFINE(HAVE_AS_REF, 1,
3591             [Define if your assembler supports .ref])])
3592         ;;
3593     esac
3594     ;;
3595
3596   mips*-*-*)
3597     gcc_GAS_CHECK_FEATURE([explicit relocation support],
3598       gcc_cv_as_mips_explicit_relocs, [2,14,0],,
3599 [       lw $4,%gp_rel(foo)($4)],,
3600       [if test x$target_cpu_default = x
3601        then target_cpu_default=MASK_EXPLICIT_RELOCS
3602        else target_cpu_default="($target_cpu_default)|MASK_EXPLICIT_RELOCS"
3603        fi])
3604     gcc_GAS_CHECK_FEATURE([-mno-shared support],
3605       gcc_cv_as_mips_no_shared, [2,16,0], [-mno-shared], [nop],,
3606       [AC_DEFINE(HAVE_AS_NO_SHARED, 1,
3607                  [Define if the assembler understands -mno-shared.])])
3608
3609     gcc_GAS_CHECK_FEATURE([.gnu_attribute support],
3610       gcc_cv_as_mips_gnu_attribute, [2,18,0],,
3611       [.gnu_attribute 4,1],,
3612       [AC_DEFINE(HAVE_AS_GNU_ATTRIBUTE, 1,
3613           [Define if your assembler supports .gnu_attribute.])])
3614
3615     gcc_GAS_CHECK_FEATURE([.dtprelword support],
3616       gcc_cv_as_mips_dtprelword, [2,18,0],,
3617       [.section .tdata,"awT",@progbits
3618 x:
3619         .word 2
3620         .text
3621         .dtprelword x+0x8000],,
3622       [AC_DEFINE(HAVE_AS_DTPRELWORD, 1,
3623           [Define if your assembler supports .dtprelword.])])
3624
3625     AC_MSG_CHECKING(assembler and linker for explicit JALR relocation)
3626     gcc_cv_as_ld_jalr_reloc=no
3627     if test $gcc_cv_as_mips_explicit_relocs = yes; then
3628       if test $in_tree_ld = yes ; then
3629         if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 20 -o "$gcc_cv_gld_major_version" -gt 2 \
3630            && test $in_tree_ld_is_elf = yes; then
3631           gcc_cv_as_ld_jalr_reloc=yes
3632         fi
3633       elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x -a x$gcc_cv_objdump != x; then
3634         echo '  .ent x' > conftest.s
3635         echo 'x:        ld $2,%got_disp(y)($3)' >> conftest.s
3636         echo '  ld $25,%call16(y)($28)' >> conftest.s
3637         echo '  .reloc  1f,R_MIPS_JALR,y' >> conftest.s
3638         echo '1:        jalr $25' >> conftest.s
3639         echo '  .reloc  1f,R_MIPS_JALR,x' >> conftest.s
3640         echo '1:        jalr $25' >> conftest.s
3641         echo '  .end x' >> conftest.s
3642         if $gcc_cv_as -o conftest.o conftest.s >/dev/null 2>&AS_MESSAGE_LOG_FD \
3643            && $gcc_cv_ld -shared -o conftest.so conftest.o >/dev/null 2>&AS_MESSAGE_LOG_FD; then
3644           if $gcc_cv_objdump -d conftest.so | grep jalr >/dev/null 2>&1 \
3645              && $gcc_cv_objdump -d conftest.so | grep "bal.*<x>" >/dev/null 2>&1; then
3646             gcc_cv_as_ld_jalr_reloc=yes
3647           fi
3648         fi
3649         rm -f conftest.*
3650       fi
3651     fi
3652     if test $gcc_cv_as_ld_jalr_reloc = yes; then
3653       if test x$target_cpu_default = x; then
3654         target_cpu_default=MASK_RELAX_PIC_CALLS
3655       else
3656         target_cpu_default="($target_cpu_default)|MASK_RELAX_PIC_CALLS"
3657       fi
3658     fi
3659     AC_MSG_RESULT($gcc_cv_as_ld_jalr_reloc)
3660
3661     AC_CACHE_CHECK([linker for .eh_frame personality relaxation],
3662       [gcc_cv_ld_mips_personality_relaxation],
3663       [gcc_cv_ld_mips_personality_relaxation=no
3664        if test $in_tree_ld = yes ; then
3665          if test "$gcc_cv_gld_major_version" -eq 2 \
3666                  -a "$gcc_cv_gld_minor_version" -ge 21 \
3667                  -o "$gcc_cv_gld_major_version" -gt 2; then
3668            gcc_cv_ld_mips_personality_relaxation=yes
3669          fi
3670        elif test x$gcc_cv_as != x \
3671                  -a x$gcc_cv_ld != x \
3672                  -a x$gcc_cv_readelf != x ; then
3673          cat > conftest.s <<EOF
3674         .cfi_startproc
3675         .cfi_personality 0x80,indirect_ptr
3676         .ent test
3677 test:
3678         nop
3679         .end test
3680         .cfi_endproc
3681
3682         .section .data,"aw",@progbits
3683 indirect_ptr:
3684         .dc.a personality
3685 EOF
3686          if $gcc_cv_as -KPIC -o conftest.o conftest.s > /dev/null 2>&1 \
3687             && $gcc_cv_ld -o conftest conftest.o -shared > /dev/null 2>&1; then
3688            if $gcc_cv_readelf -d conftest 2>&1 \
3689               | grep TEXTREL > /dev/null 2>&1; then
3690              :
3691            elif $gcc_cv_readelf --relocs conftest 2>&1 \
3692                 | grep 'R_MIPS_REL32 *$' > /dev/null 2>&1; then
3693              :
3694            else
3695              gcc_cv_ld_mips_personality_relaxation=yes
3696            fi
3697          fi
3698        fi
3699        rm -f conftest.s conftest.o conftest])
3700     if test x$gcc_cv_ld_mips_personality_relaxation = xyes; then
3701             AC_DEFINE(HAVE_LD_PERSONALITY_RELAXATION, 1,
3702       [Define if your linker can relax absolute .eh_frame personality
3703 pointers into PC-relative form.])
3704     fi
3705     ;;
3706 esac
3707
3708 # Mips and HP-UX need the GNU assembler.
3709 # Linux on IA64 might be able to use the Intel assembler.
3710
3711 case "$target" in
3712   mips*-*-* | *-*-hpux* )
3713     if test x$gas_flag = xyes \
3714        || test x"$host" != x"$build" \
3715        || test ! -x "$gcc_cv_as" \
3716        || "$gcc_cv_as" -v < /dev/null 2>&1 | grep GNU > /dev/null; then
3717       :
3718     else
3719       echo "*** This configuration requires the GNU assembler" >&2
3720       exit 1
3721     fi
3722     ;;
3723 esac
3724
3725 # ??? Not all targets support dwarf2 debug_line, even within a version
3726 # of gas.  Moreover, we need to emit a valid instruction to trigger any
3727 # info to the output file.  So, as supported targets are added to gas 2.11,
3728 # add some instruction here to (also) show we expect this might work.
3729 # ??? Once 2.11 is released, probably need to add first known working
3730 # version to the per-target configury.
3731 case "$target" in
3732   i?86*-*-* | mips*-*-* | alpha*-*-* | powerpc*-*-* | sparc*-*-* | m68*-*-* \
3733   | x86_64*-*-* | hppa*-*-* | arm*-*-* \
3734   | xstormy16*-*-* | cris-*-* | crisv32-*-* | xtensa*-*-* | bfin-*-* | score*-*-* \
3735   | spu-*-* | fido*-*-* | m32c-*-*)
3736     insn="nop"
3737     ;;
3738   ia64*-*-* | s390*-*-*)
3739     insn="nop 0"
3740     ;;
3741   mmix-*-*)
3742     insn="swym 0"
3743     ;;
3744 esac
3745 if test x"$insn" != x; then
3746  conftest_s="\
3747         .file 1 \"conftest.s\"
3748         .loc 1 3 0
3749         $insn"
3750  gcc_GAS_CHECK_FEATURE([dwarf2 debug_line support],
3751   gcc_cv_as_dwarf2_debug_line,
3752   [elf,2,11,0],, [$conftest_s],
3753   [if test x$gcc_cv_objdump != x \
3754    && $gcc_cv_objdump -h conftest.o 2> /dev/null \
3755       | grep debug_line > /dev/null 2>&1; then
3756      gcc_cv_as_dwarf2_debug_line=yes
3757    fi])
3758
3759 # The .debug_line file table must be in the exact order that
3760 # we specified the files, since these indices are also used
3761 # by DW_AT_decl_file.  Approximate this test by testing if
3762 # the assembler bitches if the same index is assigned twice.
3763  gcc_GAS_CHECK_FEATURE([buggy dwarf2 .file directive],
3764   gcc_cv_as_dwarf2_file_buggy,,,
3765 [       .file 1 "foo.s"
3766         .file 1 "bar.s"])
3767
3768  if test $gcc_cv_as_dwarf2_debug_line = yes \
3769  && test $gcc_cv_as_dwarf2_file_buggy = no; then
3770         AC_DEFINE(HAVE_AS_DWARF2_DEBUG_LINE, 1,
3771   [Define if your assembler supports dwarf2 .file/.loc directives,
3772    and preserves file table indices exactly as given.])
3773  fi
3774
3775  gcc_GAS_CHECK_FEATURE([--gdwarf2 option],
3776   gcc_cv_as_gdwarf2_flag,
3777   [elf,2,11,0], [--gdwarf2], [$insn],,
3778   [AC_DEFINE(HAVE_AS_GDWARF2_DEBUG_FLAG, 1,
3779 [Define if your assembler supports the --gdwarf2 option.])])
3780
3781  gcc_GAS_CHECK_FEATURE([--gstabs option],
3782   gcc_cv_as_gstabs_flag,
3783   [elf,2,11,0], [--gstabs], [$insn],
3784   [# The native Solaris 9/Intel assembler doesn't understand --gstabs
3785    # and warns about it, but still exits successfully.  So check for
3786    # this.
3787    if AC_TRY_COMMAND([$gcc_cv_as --gstabs -o conftest.o conftest.s 2>&1 | grep -i warning > /dev/null])
3788    then :
3789    else gcc_cv_as_gstabs_flag=yes
3790    fi],
3791   [AC_DEFINE(HAVE_AS_GSTABS_DEBUG_FLAG, 1,
3792 [Define if your assembler supports the --gstabs option.])])
3793
3794  gcc_GAS_CHECK_FEATURE([--debug-prefix-map option],
3795   gcc_cv_as_debug_prefix_map_flag,
3796   [2,18,0], [--debug-prefix-map /a=/b], [$insn],,
3797   [AC_DEFINE(HAVE_AS_DEBUG_PREFIX_MAP, 1,
3798 [Define if your assembler supports the --debug-prefix-map option.])])
3799 fi
3800
3801 gcc_GAS_CHECK_FEATURE([.lcomm with alignment], gcc_cv_as_lcomm_with_alignment,
3802  ,,
3803 [.lcomm bar,4,16],,
3804 [AC_DEFINE(HAVE_GAS_LCOMM_WITH_ALIGNMENT, 1,
3805   [Define if your assembler supports .lcomm with an alignment field.])])
3806
3807 AC_ARG_ENABLE(gnu-unique-object,
3808  [  --enable-gnu-unique-object  enable the use of the @gnu_unique_object ELF extension on
3809                                 glibc systems],
3810  [case $enable_gnu_unique_object in
3811     yes | no) ;;
3812     *) AC_MSG_ERROR(['$enable_gnu_unique_object' is an invalid value for --enable-gnu-unique-object.
3813 Valid choices are 'yes' and 'no'.]) ;;
3814   esac],
3815  [gcc_GAS_CHECK_FEATURE([gnu_unique_object], gcc_cv_as_gnu_unique_object,
3816    [elf,2,19,52],,
3817    [.type foo, @gnu_unique_object],,
3818 # Also check for ld.so support, i.e. glibc 2.11 or higher.
3819    [[if test x$host = x$build -a x$host = x$target &&
3820        glibcver=`ldd --version 2>/dev/null | sed 's/.* //;q'`; then
3821       glibcmajor=`expr "$glibcver" : "\([0-9]*\)"`
3822       glibcminor=`expr "$glibcver" : "[2-9]*\.\([0-9]*\)"`
3823       glibcnum=`expr $glibcmajor \* 1000 + $glibcminor`
3824       if test "$glibcnum" -ge 2011 ; then
3825         enable_gnu_unique_object=yes
3826       fi
3827     fi]])])
3828 if test x$enable_gnu_unique_object = xyes; then
3829   AC_DEFINE(HAVE_GAS_GNU_UNIQUE_OBJECT, 1,
3830    [Define if your assembler supports @gnu_unique_object.])
3831 fi
3832
3833 AC_CACHE_CHECK([assembler for tolerance to line number 0],
3834  [gcc_cv_as_line_zero],
3835  [gcc_cv_as_line_zero=no
3836   if test $in_tree_gas = yes; then
3837     gcc_GAS_VERSION_GTE_IFELSE(2, 16, 91, [gcc_cv_as_line_zero=yes])
3838   elif test "x$gcc_cv_as" != x; then
3839     { echo '# 1 "test.s" 1'; echo '# 0 "" 2'; } > conftest.s
3840     if AC_TRY_COMMAND([$gcc_cv_as -o conftest.o conftest.s >&AS_MESSAGE_LOG_FD 2>conftest.out]) &&
3841        test "x`cat conftest.out`" = x
3842     then
3843       gcc_cv_as_line_zero=yes
3844     else
3845       echo "configure: failed program was" >&AS_MESSAGE_LOG_FD
3846       cat conftest.s >&AS_MESSAGE_LOG_FD
3847       echo "configure: error output was" >&AS_MESSAGE_LOG_FD
3848       cat conftest.out >&AS_MESSAGE_LOG_FD
3849     fi
3850     rm -f conftest.o conftest.s conftest.out
3851   fi])
3852 if test "x$gcc_cv_as_line_zero" = xyes; then
3853   AC_DEFINE([HAVE_AS_LINE_ZERO], 1,
3854 [Define if the assembler won't complain about a line such as # 0 "" 2.])
3855 fi
3856
3857 AC_MSG_CHECKING(linker PT_GNU_EH_FRAME support)
3858 gcc_cv_ld_eh_frame_hdr=no
3859 if test $in_tree_ld = yes ; then
3860   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 12 -o "$gcc_cv_gld_major_version" -gt 2 \
3861      && test $in_tree_ld_is_elf = yes; then
3862     gcc_cv_ld_eh_frame_hdr=yes
3863   fi
3864 elif test x$gcc_cv_ld != x; then
3865         # Check if linker supports --eh-frame-hdr option
3866         if $gcc_cv_ld --help 2>/dev/null | grep eh-frame-hdr > /dev/null; then
3867                 gcc_cv_ld_eh_frame_hdr=yes
3868         fi
3869 fi
3870 GCC_TARGET_TEMPLATE([HAVE_LD_EH_FRAME_HDR])
3871 if test x"$gcc_cv_ld_eh_frame_hdr" = xyes; then
3872         AC_DEFINE(HAVE_LD_EH_FRAME_HDR, 1,
3873 [Define if your linker supports --eh-frame-hdr option.])
3874 fi
3875 AC_MSG_RESULT($gcc_cv_ld_eh_frame_hdr)
3876
3877 AC_MSG_CHECKING(linker position independent executable support)
3878 gcc_cv_ld_pie=no
3879 if test $in_tree_ld = yes ; then
3880   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 15 -o "$gcc_cv_gld_major_version" -gt 2 \
3881      && test $in_tree_ld_is_elf = yes; then
3882     gcc_cv_ld_pie=yes
3883   fi
3884 elif test x$gcc_cv_ld != x; then
3885         # Check if linker supports -pie option
3886         if $gcc_cv_ld --help 2>/dev/null | grep -- -pie > /dev/null; then
3887                 gcc_cv_ld_pie=yes
3888         fi
3889 fi
3890 if test x"$gcc_cv_ld_pie" = xyes; then
3891         AC_DEFINE(HAVE_LD_PIE, 1,
3892 [Define if your linker supports -pie option.])
3893 fi
3894 AC_MSG_RESULT($gcc_cv_ld_pie)
3895
3896 AC_MSG_CHECKING(linker EH-compatible garbage collection of sections)
3897 gcc_cv_ld_eh_gc_sections=no
3898 if test $in_tree_ld = yes ; then
3899   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 17 -o "$gcc_cv_gld_major_version" -gt 2 \
3900      && test $in_tree_ld_is_elf = yes; then
3901     gcc_cv_ld_eh_gc_sections=yes
3902   fi
3903 elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x -a x$gcc_cv_objdump != x ; then
3904   cat > conftest.s <<EOF
3905         .section        .text
3906 .globl _start
3907         .type _start, @function
3908 _start:
3909         .long foo
3910         .size _start, .-_start
3911         .section        .text.foo,"ax",@progbits
3912         .type foo, @function
3913 foo:
3914         .long 0
3915         .size foo, .-foo
3916         .section        .gcc_except_table.foo,"a",@progbits
3917 .L0:
3918         .long 0
3919         .section        .eh_frame,"a",@progbits
3920         .long .L0
3921 EOF
3922   if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
3923     if $gcc_cv_ld -o conftest conftest.o --entry=_start --gc-sections 2>&1 \
3924          | grep "gc-sections option ignored" > /dev/null; then
3925       gcc_cv_ld_eh_gc_sections=no
3926     elif $gcc_cv_objdump -h conftest 2> /dev/null \
3927          | grep gcc_except_table > /dev/null; then
3928       gcc_cv_ld_eh_gc_sections=yes
3929       # If no COMDAT groups, the compiler will emit .gnu.linkonce.t. sections.
3930       if test x$gcc_cv_as_comdat_group != xyes; then
3931         gcc_cv_ld_eh_gc_sections=no
3932         cat > conftest.s <<EOF
3933         .section        .text
3934 .globl _start
3935         .type _start, @function
3936 _start:
3937         .long foo
3938         .size _start, .-_start
3939         .section        .gnu.linkonce.t.foo,"ax",@progbits
3940         .type foo, @function
3941 foo:
3942         .long 0
3943         .size foo, .-foo
3944         .section        .gcc_except_table.foo,"a",@progbits
3945 .L0:
3946         .long 0
3947         .section        .eh_frame,"a",@progbits
3948         .long .L0
3949 EOF
3950         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
3951           if $gcc_cv_ld -o conftest conftest.o --entry=_start --gc-sections 2>&1 \
3952                | grep "gc-sections option ignored" > /dev/null; then
3953             gcc_cv_ld_eh_gc_sections=no
3954           elif $gcc_cv_objdump -h conftest 2> /dev/null \
3955                | grep gcc_except_table > /dev/null; then
3956             gcc_cv_ld_eh_gc_sections=yes
3957           fi
3958         fi
3959       fi
3960     fi
3961   fi
3962   rm -f conftest.s conftest.o conftest
3963 fi
3964 case "$target" in
3965   hppa*-*-linux*)
3966     # ??? This apparently exposes a binutils bug with PC-relative relocations.
3967     gcc_cv_ld_eh_gc_sections=no
3968     ;;
3969 esac
3970 if test x$gcc_cv_ld_eh_gc_sections = xyes; then
3971         AC_DEFINE(HAVE_LD_EH_GC_SECTIONS, 1,
3972   [Define if your linker supports garbage collection of
3973    sections in presence of EH frames.])
3974 fi
3975 AC_MSG_RESULT($gcc_cv_ld_eh_gc_sections)
3976
3977 # --------
3978 # UNSORTED
3979 # --------
3980
3981 AC_CACHE_CHECK(linker --as-needed support,
3982 gcc_cv_ld_as_needed,
3983 [gcc_cv_ld_as_needed=no
3984 if test $in_tree_ld = yes ; then
3985   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2 \
3986      && test $in_tree_ld_is_elf = yes; then
3987     gcc_cv_ld_as_needed=yes
3988   fi
3989 elif test x$gcc_cv_ld != x; then
3990         # Check if linker supports --as-needed and --no-as-needed options
3991         if $gcc_cv_ld --help 2>/dev/null | grep as-needed > /dev/null; then
3992                 gcc_cv_ld_as_needed=yes
3993         fi
3994 fi
3995 ])
3996 if test x"$gcc_cv_ld_as_needed" = xyes; then
3997         AC_DEFINE(HAVE_LD_AS_NEEDED, 1,
3998 [Define if your linker supports --as-needed and --no-as-needed options.])
3999 fi
4000
4001 case "$target:$tm_file" in
4002   powerpc64*-*-linux* | powerpc*-*-linux*rs6000/biarch64.h*)
4003     AC_CACHE_CHECK(linker support for omitting dot symbols,
4004     gcc_cv_ld_no_dot_syms,
4005     [gcc_cv_ld_no_dot_syms=no
4006     if test $in_tree_ld = yes ; then
4007       if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2; then
4008         gcc_cv_ld_no_dot_syms=yes
4009       fi
4010     elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x ; then
4011       cat > conftest1.s <<EOF
4012         .text
4013         bl .foo
4014 EOF
4015       cat > conftest2.s <<EOF
4016         .section ".opd","aw"
4017         .align 3
4018         .globl foo
4019         .type foo,@function
4020 foo:
4021         .quad .LEfoo,.TOC.@tocbase,0
4022         .text
4023 .LEfoo:
4024         blr
4025         .size foo,.-.LEfoo
4026 EOF
4027       if $gcc_cv_as -a64 -o conftest1.o conftest1.s > /dev/null 2>&1 \
4028          && $gcc_cv_as -a64 -o conftest2.o conftest2.s > /dev/null 2>&1 \
4029          && $gcc_cv_ld -melf64ppc -o conftest conftest1.o conftest2.o > /dev/null 2>&1; then
4030         gcc_cv_ld_no_dot_syms=yes
4031       fi
4032       rm -f conftest conftest1.o conftest2.o conftest1.s conftest2.s
4033     fi
4034     ])
4035     if test x"$gcc_cv_ld_no_dot_syms" = xyes; then
4036       AC_DEFINE(HAVE_LD_NO_DOT_SYMS, 1,
4037     [Define if your PowerPC64 linker only needs function descriptor syms.])
4038     fi
4039
4040     AC_CACHE_CHECK(linker large toc support,
4041     gcc_cv_ld_large_toc,
4042     [gcc_cv_ld_large_toc=no
4043     if test $in_tree_ld = yes ; then
4044       if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 21 -o "$gcc_cv_gld_major_version" -gt 2; then
4045         gcc_cv_ld_large_toc=yes
4046       fi
4047     elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x ; then
4048       cat > conftest.s <<EOF
4049         .section ".tbss","awT",@nobits
4050         .align 3
4051 ie0:    .space 8
4052         .global _start
4053         .text
4054 _start:
4055         addis 9,13,ie0@got@tprel@ha
4056         ld 9,ie0@got@tprel@l(9)
4057 EOF
4058       if $gcc_cv_as -a64 -o conftest.o conftest.s > /dev/null 2>&1 \
4059          && $gcc_cv_ld -melf64ppc --no-toc-sort -o conftest conftest.o > /dev/null 2>&1; then
4060         gcc_cv_ld_large_toc=yes
4061       fi
4062       rm -f conftest conftest.o conftest.s
4063     fi
4064     ])
4065     if test x"$gcc_cv_ld_large_toc" = xyes; then
4066       AC_DEFINE(HAVE_LD_LARGE_TOC, 1,
4067     [Define if your PowerPC64 linker supports a large TOC.])
4068     fi
4069     ;;
4070 esac
4071
4072 AC_CACHE_CHECK(linker --build-id support,
4073   gcc_cv_ld_buildid,
4074   [gcc_cv_ld_buildid=no
4075   if test $in_tree_ld = yes ; then
4076     if test "$gcc_cv_gld_major_version" -eq 2 -a \
4077        "$gcc_cv_gld_minor_version" -ge 18 -o \
4078        "$gcc_cv_gld_major_version" -gt 2 \
4079        && test $in_tree_ld_is_elf = yes; then
4080       gcc_cv_ld_buildid=yes
4081     fi
4082   elif test x$gcc_cv_ld != x; then
4083     if $gcc_cv_ld --help 2>/dev/null | grep build-id > /dev/null; then
4084       gcc_cv_ld_buildid=yes
4085     fi
4086   fi])
4087 if test x"$gcc_cv_ld_buildid" = xyes; then
4088   AC_DEFINE(HAVE_LD_BUILDID, 1,
4089   [Define if your linker supports --build-id.])
4090 fi
4091
4092 AC_ARG_ENABLE(linker-build-id,
4093 [  --enable-linker-build-id
4094                           compiler will always pass --build-id to linker],
4095 [],
4096 enable_linker_build_id=no)
4097
4098 if test x"$enable_linker_build_id" = xyes; then
4099   if test x"$gcc_cv_ld_buildid" = xyes; then
4100     AC_DEFINE(ENABLE_LD_BUILDID, 1,
4101     [Define if gcc should always pass --build-id to linker.])
4102   else
4103     AC_MSG_WARN(--build-id is not supported by your linker; --enable-linker-build-id ignored)
4104   fi
4105 fi
4106
4107 # In binutils 2.21, GNU ld gained support for new emulations fully
4108 # supporting the Solaris 2 ABI.  Detect their presence in the linker used.
4109 AC_CACHE_CHECK(linker *_sol2 emulation support,
4110   gcc_cv_ld_sol2_emulation,
4111   [gcc_cv_ld_sol2_emulation=no
4112   if test $in_tree_ld = yes ; then
4113     if test "$gcc_cv_gld_major_version" -eq 2 -a \
4114        "$gcc_cv_gld_minor_version" -ge 21 -o \
4115        "$gcc_cv_gld_major_version" -gt 2 \
4116        && test $in_tree_ld_is_elf = yes; then
4117       gcc_cv_ld_sol2_emulation=yes
4118     fi
4119   elif test x$gcc_cv_ld != x; then
4120     if $gcc_cv_ld -V 2>/dev/null | sed -e '1,/Supported emulations/d;q' | \
4121        grep _sol2 > /dev/null; then
4122       gcc_cv_ld_sol2_emulation=yes
4123     fi
4124   fi])
4125 if test x"$gcc_cv_ld_sol2_emulation" = xyes; then
4126   AC_DEFINE(HAVE_LD_SOL2_EMULATION, 1,
4127   [Define if your linker supports the *_sol2 emulations.])
4128 fi
4129
4130 AC_CACHE_CHECK(linker --sysroot support,
4131   gcc_cv_ld_sysroot,
4132   [gcc_cv_ld_sysroot=no
4133   if test $in_tree_ld = yes ; then
4134       if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2 ; then
4135         gcc_cv_ld_sysroot=yes
4136       fi
4137   elif test x$gcc_cv_ld != x; then 
4138     if $gcc_cv_ld --help 2>/dev/null | grep sysroot > /dev/null; then
4139       gcc_cv_ld_sysroot=yes
4140     fi
4141   fi])
4142 if test x"$gcc_cv_ld_sysroot" = xyes; then
4143   AC_DEFINE(HAVE_LD_SYSROOT, 1,
4144   [Define if your linker supports --sysroot.])
4145 fi        
4146
4147 if test x$with_sysroot = x && test x$host = x$target \
4148    && test "$prefix" != "/usr" && test "x$prefix" != "x$local_prefix" \
4149    && test "$prefix" != "NONE"; then
4150   AC_DEFINE_UNQUOTED(PREFIX_INCLUDE_DIR, "$prefix/include",
4151 [Define to PREFIX/include if cpp should also search that directory.])
4152 fi
4153
4154 # Test for stack protector support in target C library.
4155 AC_CACHE_CHECK(__stack_chk_fail in target C library,
4156       gcc_cv_libc_provides_ssp,
4157       [gcc_cv_libc_provides_ssp=no
4158     case "$target" in
4159        *-*-linux* | *-*-kfreebsd*-gnu | *-*-knetbsd*-gnu)
4160       if test x$host != x$target || test "x$TARGET_SYSTEM_ROOT" != x; then
4161         if test "x$with_headers" != x; then
4162           glibc_header_dir=$with_headers
4163         elif test "x$with_sysroot" = x; then
4164           glibc_header_dir="${exec_prefix}/${target_noncanonical}/sys-include"
4165         elif test "x$with_build_sysroot" != "x"; then
4166           glibc_header_dir="${with_build_sysroot}/usr/include"
4167         elif test "x$with_sysroot" = xyes; then
4168           glibc_header_dir="${exec_prefix}/${target_noncanonical}/sys-root/usr/include"
4169         else
4170           glibc_header_dir="${with_sysroot}/usr/include"
4171         fi
4172       else
4173         glibc_header_dir=/usr/include
4174       fi
4175       [# glibc 2.4 and later provides __stack_chk_fail and
4176       # either __stack_chk_guard, or TLS access to stack guard canary.
4177       if test -f $glibc_header_dir/features.h \
4178          && $EGREP '^[  ]*#[    ]*define[       ]+__GNU_LIBRARY__[      ]+([1-9][0-9]|[6-9])' \
4179             $glibc_header_dir/features.h > /dev/null; then
4180         if $EGREP '^[   ]*#[    ]*define[       ]+__GLIBC__[    ]+([1-9][0-9]|[3-9])' \
4181            $glibc_header_dir/features.h > /dev/null; then
4182           gcc_cv_libc_provides_ssp=yes
4183         elif $EGREP '^[         ]*#[    ]*define[       ]+__GLIBC__[    ]+2' \
4184              $glibc_header_dir/features.h > /dev/null \
4185              && $EGREP '^[      ]*#[    ]*define[       ]+__GLIBC_MINOR__[      ]+([1-9][0-9]|[4-9])' \
4186              $glibc_header_dir/features.h > /dev/null; then
4187           gcc_cv_libc_provides_ssp=yes
4188         elif $EGREP '^[         ]*#[    ]*define[       ]+__UCLIBC__[   ]+1' \
4189              $glibc_header_dir/features.h > /dev/null && \
4190              test -f $glibc_header_dir/bits/uClibc_config.h && \
4191              $EGREP '^[         ]*#[    ]*define[       ]+__UCLIBC_HAS_SSP__[   ]+1' \
4192              $glibc_header_dir/bits/uClibc_config.h > /dev/null; then
4193           gcc_cv_libc_provides_ssp=yes
4194         fi
4195       fi]
4196         ;;
4197        *-*-gnu*)
4198          # Avoid complicated tests (see
4199          # <http://gcc.gnu.org/ml/gcc/2008-10/msg00130.html>) and for now
4200          # simply assert that glibc does provide this, which is true for all
4201          # realistically usable GNU/Hurd configurations.
4202          gcc_cv_libc_provides_ssp=yes;;
4203        *-*-darwin* | *-*-freebsd*)
4204          AC_CHECK_FUNC(__stack_chk_fail,[gcc_cv_libc_provides_ssp=yes],
4205            [echo "no __stack_chk_fail on this target"])
4206         ;;
4207   *) gcc_cv_libc_provides_ssp=no ;;
4208     esac])
4209
4210 if test x$gcc_cv_libc_provides_ssp = xyes; then
4211   AC_DEFINE(TARGET_LIBC_PROVIDES_SSP, 1,
4212             [Define if your target C library provides stack protector support])
4213 fi
4214
4215 # Check if TFmode long double should be used by default or not.
4216 # Some glibc targets used DFmode long double, but with glibc 2.4
4217 # and later they can use TFmode.
4218 case "$target" in
4219   powerpc*-*-linux* | \
4220   powerpc*-*-gnu* | \
4221   sparc*-*-linux* | \
4222   s390*-*-linux* | \
4223   alpha*-*-linux*)
4224     AC_ARG_WITH(long-double-128,
4225 [  --with-long-double-128  Use 128-bit long double by default.],
4226       gcc_cv_target_ldbl128="$with_long_double_128",
4227       [[gcc_cv_target_ldbl128=no
4228       if test x$host != x$target || test "x$TARGET_SYSTEM_ROOT" != x; then
4229         if test "x$with_sysroot" = x; then
4230           glibc_header_dir="${exec_prefix}/${target_noncanonical}/sys-include"
4231         elif test "x$with_build_sysroot" != "x"; then
4232           glibc_header_dir="${with_build_sysroot}/usr/include"
4233         elif test "x$with_sysroot" = xyes; then
4234           glibc_header_dir="${exec_prefix}/${target_noncanonical}/sys-root/usr/include"
4235         else
4236           glibc_header_dir="${with_sysroot}/usr/include"
4237         fi
4238       else
4239         glibc_header_dir=/usr/include
4240       fi
4241       grep '^[  ]*#[    ]*define[       ][      ]*__LONG_DOUBLE_MATH_OPTIONAL' \
4242         $glibc_header_dir/bits/wordsize.h > /dev/null 2>&1 \
4243       && gcc_cv_target_ldbl128=yes
4244       ]])
4245     ;;
4246 esac
4247 if test x$gcc_cv_target_ldbl128 = xyes; then
4248   AC_DEFINE(TARGET_DEFAULT_LONG_DOUBLE_128, 1,
4249             [Define if TFmode long double should be the default])
4250 fi
4251
4252 # Find out what GC implementation we want, or may, use.
4253 AC_ARG_WITH(gc,
4254 [  --with-gc={page,zone}   choose the garbage collection mechanism to use
4255                           with the compiler],
4256 [case "$withval" in