gcc/configure.ac

   1 # configure.ac for GCC
   2 # Process this file with autoconf to generate a configuration script.
   3
   4 # Copyright 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2004, 2005, 2006,
   5 # 2007, 2008, 2009, 2010, 2011 Free Software Foundation, Inc.
   6
   7 #This file is part of GCC.
   8
   9 #GCC is free software; you can redistribute it and/or modify it under
  10 #the terms of the GNU General Public License as published by the Free
  11 #Software Foundation; either version 3, or (at your option) any later
  12 #version.
  13
  14 #GCC is distributed in the hope that it will be useful, but WITHOUT
  15 #ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  16 #FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  17 #for more details.
  18
  19 #You should have received a copy of the GNU General Public License
  20 #along with GCC; see the file COPYING3.  If not see
  21 #<http://www.gnu.org/licenses/>.
  22
  23 # --------------------------------
  24 # Initialization and sanity checks
  25 # --------------------------------
  26
  27 AC_PREREQ(2.64)
  28 AC_INIT
  29 AC_CONFIG_SRCDIR(tree.c)
  30 AC_CONFIG_HEADER(auto-host.h:config.in)
  31
  32 gcc_version=`cat $srcdir/BASE-VER`
  33
  34 # Determine the host, build, and target systems
  35 AC_CANONICAL_BUILD
  36 AC_CANONICAL_HOST
  37 AC_CANONICAL_TARGET
  38
  39 # Determine the noncanonical target name, for directory use.
  40 ACX_NONCANONICAL_TARGET
  41
  42 # Determine the target- and build-specific subdirectories
  43 GCC_TOPLEV_SUBDIRS
  44
  45 # Set program_transform_name
  46 AC_ARG_PROGRAM
  47
  48 # Check for bogus environment variables.
  49 # Test if LIBRARY_PATH contains the notation for the current directory
  50 # since this would lead to problems installing/building glibc.
  51 # LIBRARY_PATH contains the current directory if one of the following
  52 # is true:
  53 # - one of the terminals (":" and ";") is the first or last sign
  54 # - two terminals occur directly after each other
  55 # - the path contains an element with a dot in it
  56 AC_MSG_CHECKING(LIBRARY_PATH variable)
  57 changequote(,)dnl
  58 case ${LIBRARY_PATH} in
  59   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
  60     library_path_setting="contains current directory"
  61     ;;
  62   *)
  63     library_path_setting="ok"
  64     ;;
  65 esac
  66 changequote([,])dnl
  67 AC_MSG_RESULT($library_path_setting)
  68 if test "$library_path_setting" != "ok"; then
  69 AC_MSG_ERROR([
  70 *** LIBRARY_PATH shouldn't contain the current directory when
  71 *** building gcc. Please change the environment variable
  72 *** and run configure again.])
  73 fi
  74
  75 # Test if GCC_EXEC_PREFIX contains the notation for the current directory
  76 # since this would lead to problems installing/building glibc.
  77 # GCC_EXEC_PREFIX contains the current directory if one of the following
  78 # is true:
  79 # - one of the terminals (":" and ";") is the first or last sign
  80 # - two terminals occur directly after each other
  81 # - the path contains an element with a dot in it
  82 AC_MSG_CHECKING(GCC_EXEC_PREFIX variable)
  83 changequote(,)dnl
  84 case ${GCC_EXEC_PREFIX} in
  85   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
  86     gcc_exec_prefix_setting="contains current directory"
  87     ;;
  88   *)
  89     gcc_exec_prefix_setting="ok"
  90     ;;
  91 esac
  92 changequote([,])dnl
  93 AC_MSG_RESULT($gcc_exec_prefix_setting)
  94 if test "$gcc_exec_prefix_setting" != "ok"; then
  95 AC_MSG_ERROR([
  96 *** GCC_EXEC_PREFIX shouldn't contain the current directory when
  97 *** building gcc. Please change the environment variable
  98 *** and run configure again.])
  99 fi
 100
 101 # -----------
 102 # Directories
 103 # -----------
 104
 105 # Specify the local prefix
 106 local_prefix=
 107 AC_ARG_WITH(local-prefix,
 108 [  --with-local-prefix=DIR specifies directory to put local include],
 109 [case "${withval}" in
 110 yes)    AC_MSG_ERROR(bad value ${withval} given for local include directory prefix) ;;
 111 no)     ;;
 112 *)      local_prefix=$with_local_prefix ;;
 113 esac])
 114
 115 # Default local prefix if it is empty
 116 if test x$local_prefix = x; then
 117         local_prefix=/usr/local
 118 fi
 119
 120 # Don't set gcc_gxx_include_dir to gxx_include_dir since that's only
 121 # passed in by the toplevel make and thus we'd get different behavior
 122 # depending on where we built the sources.
 123 gcc_gxx_include_dir=
 124 # Specify the g++ header file directory
 125 AC_ARG_WITH(gxx-include-dir,
 126 [  --with-gxx-include-dir=DIR
 127                           specifies directory to put g++ header files],
 128 [case "${withval}" in
 129 yes)    AC_MSG_ERROR(bad value ${withval} given for g++ include directory) ;;
 130 no)     ;;
 131 *)      gcc_gxx_include_dir=$with_gxx_include_dir ;;
 132 esac])
 133
 134 # This logic must match libstdc++-v3/acinclude.m4:GLIBCXX_EXPORT_INSTALL_INFO.
 135 if test x${gcc_gxx_include_dir} = x; then
 136   if test x${enable_version_specific_runtime_libs} = xyes; then
 137     gcc_gxx_include_dir='${libsubdir}/include/c++'
 138   else
 139     libstdcxx_incdir='include/c++/$(version)'
 140     if test x$host != x$target; then
 141        libstdcxx_incdir="$target_alias/$libstdcxx_incdir"
 142     fi
 143     gcc_gxx_include_dir="\$(libsubdir)/\$(libsubdir_to_prefix)$libstdcxx_incdir"
 144   fi
 145 fi
 146
 147 AC_ARG_WITH(cpp_install_dir,
 148 [  --with-cpp-install-dir=DIR
 149                           install the user visible C preprocessor in DIR
 150                           (relative to PREFIX) as well as PREFIX/bin],
 151 [if test x$withval = xyes; then
 152   AC_MSG_ERROR([option --with-cpp-install-dir requires an argument])
 153 elif test x$withval != xno; then
 154   cpp_install_dir=$withval
 155 fi])
 156
 157 # We would like to our source tree to be readonly.  However when releases or
 158 # pre-releases are generated, the flex/bison generated files as well as the
 159 # various formats of manuals need to be included along with the rest of the
 160 # sources.  Therefore we have --enable-generated-files-in-srcdir to do
 161 # just that.
 162
 163 AC_MSG_CHECKING([whether to place generated files in the source directory])
 164   dnl generated-files-in-srcdir is disabled by default
 165   AC_ARG_ENABLE(generated-files-in-srcdir,
 166 [  --enable-generated-files-in-srcdir
 167                           put copies of generated files in source dir
 168                           intended for creating source tarballs for users
 169                           without texinfo bison or flex.],
 170       generated_files_in_srcdir=$enableval,
 171       generated_files_in_srcdir=no)
 172
 173 AC_MSG_RESULT($generated_files_in_srcdir)
 174
 175 if test "$generated_files_in_srcdir" = "yes"; then
 176   GENINSRC=''
 177 else
 178   GENINSRC='#'
 179 fi
 180 AC_SUBST(GENINSRC)
 181
 182 # -------------------
 183 # Find default linker
 184 # -------------------
 185
 186 # With GNU ld
 187 AC_ARG_WITH(gnu-ld,
 188 [  --with-gnu-ld           arrange to work with GNU ld.],
 189 gnu_ld_flag="$with_gnu_ld",
 190 gnu_ld_flag=no)
 191
 192 # With pre-defined ld
 193 AC_ARG_WITH(ld,
 194 [  --with-ld               arrange to use the specified ld (full pathname)],
 195 DEFAULT_LINKER="$with_ld")
 196 if test x"${DEFAULT_LINKER+set}" = x"set"; then
 197   if test ! -x "$DEFAULT_LINKER"; then
 198     AC_MSG_ERROR([cannot execute: $DEFAULT_LINKER: check --with-ld or env. var. DEFAULT_LINKER])
 199   elif $DEFAULT_LINKER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
 200     gnu_ld_flag=yes
 201   fi
 202   AC_DEFINE_UNQUOTED(DEFAULT_LINKER,"$DEFAULT_LINKER",
 203         [Define to enable the use of a default linker.])
 204 fi
 205
 206 gnu_ld=`if test x"$gnu_ld_flag" = x"yes"; then echo 1; else echo 0; fi`
 207 AC_DEFINE_UNQUOTED(HAVE_GNU_LD, $gnu_ld, [Define if using GNU ld.])
 208
 209 AC_MSG_CHECKING([whether a default linker was specified])
 210 if test x"${DEFAULT_LINKER+set}" = x"set"; then
 211   if test x"$gnu_ld_flag" = x"no"; then
 212     AC_MSG_RESULT([yes ($DEFAULT_LINKER)])
 213   else
 214     AC_MSG_RESULT([yes ($DEFAULT_LINKER - GNU ld)])
 215   fi
 216 else
 217   AC_MSG_RESULT(no)
 218 fi
 219
 220 # With demangler in GNU ld
 221 AC_ARG_WITH(demangler-in-ld,
 222 [  --with-demangler-in-ld  try to use demangler in GNU ld.],
 223 demangler_in_ld="$with_demangler_in_ld",
 224 demangler_in_ld=no)
 225
 226 # ----------------------
 227 # Find default assembler
 228 # ----------------------
 229
 230 # With GNU as
 231 AC_ARG_WITH(gnu-as,
 232 [  --with-gnu-as           arrange to work with GNU as],
 233 gas_flag="$with_gnu_as",
 234 gas_flag=no)
 235
 236 AC_ARG_WITH(as,
 237 [  --with-as               arrange to use the specified as (full pathname)],
 238 DEFAULT_ASSEMBLER="$with_as")
 239 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
 240   if test ! -x "$DEFAULT_ASSEMBLER"; then
 241     AC_MSG_ERROR([cannot execute: $DEFAULT_ASSEMBLER: check --with-as or env. var. DEFAULT_ASSEMBLER])
 242   elif $DEFAULT_ASSEMBLER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
 243     gas_flag=yes
 244   fi
 245   AC_DEFINE_UNQUOTED(DEFAULT_ASSEMBLER,"$DEFAULT_ASSEMBLER",
 246         [Define to enable the use of a default assembler.])
 247 fi
 248
 249 gnu_as=`if test x"$gas_flag" = x"yes"; then echo 1; else echo 0; fi`
 250 AC_DEFINE_UNQUOTED(HAVE_GNU_AS, $gnu_as, [Define if using GNU as.])
 251
 252 AC_MSG_CHECKING([whether a default assembler was specified])
 253 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
 254   if test x"$gas_flag" = x"no"; then
 255     AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER)])
 256   else
 257     AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER - GNU as)])
 258   fi
 259 else
 260   AC_MSG_RESULT(no)
 261 fi
 262
 263 # ---------------
 264 # Find C compiler
 265 # ---------------
 266
 267 # If a non-executable a.out is present (e.g. created by GNU as above even if
 268 # invoked with -v only), the IRIX 6 native ld just overwrites the existing
 269 # file, even when creating an executable, so an execution test fails.
 270 # Remove possible default executable files to avoid this.
 271 #
 272 # FIXME: This really belongs into AC_PROG_CC and can be removed once
 273 # Autoconf includes it.
 274 rm -f a.out a.exe b.out
 275
 276 # Find the native compiler
 277 AC_PROG_CC
 278 AM_PROG_CC_C_O
 279 AC_PROG_CXX
 280 ACX_PROG_GNAT([-I"$srcdir"/ada])
 281
 282 # autoconf is lame and doesn't give us any substitution variable for this.
 283 if eval "test \"`echo '$ac_cv_prog_cc_'${ac_cc}_c_o`\" = no"; then
 284   NO_MINUS_C_MINUS_O=yes
 285 else
 286   OUTPUT_OPTION='-o $@'
 287 fi
 288 AC_SUBST(NO_MINUS_C_MINUS_O)
 289 AC_SUBST(OUTPUT_OPTION)
 290
 291 # Remove the -O2: for historical reasons, unless bootstrapping we prefer
 292 # optimizations to be activated explicitly by the toplevel.
 293 case "$CC" in
 294   */prev-gcc/xgcc*) ;;
 295   *) CFLAGS=`echo $CFLAGS | sed "s/-O[[s0-9]]* *//" ` ;;
 296 esac
 297 AC_SUBST(CFLAGS)
 298
 299 # -------------------------
 300 # Check C compiler features
 301 # -------------------------
 302
 303 AC_USE_SYSTEM_EXTENSIONS
 304 AC_PROG_CPP
 305 AC_C_INLINE
 306
 307 AC_SYS_LARGEFILE
 308
 309 # sizeof(char) is 1 by definition.
 310 AC_CHECK_SIZEOF(void *)
 311 AC_CHECK_SIZEOF(short)
 312 AC_CHECK_SIZEOF(int)
 313 AC_CHECK_SIZEOF(long)
 314 AC_CHECK_TYPES([long long], [AC_CHECK_SIZEOF(long long)])
 315 AC_CHECK_TYPES([__int64], [AC_CHECK_SIZEOF(__int64)])
 316 GCC_STDINT_TYPES
 317
 318 # ---------------------
 319 # Warnings and checking
 320 # ---------------------
 321
 322 # Check $CC warning features (if it's GCC).
 323 # We want to use -pedantic, but we don't want warnings about
 324 # * 'long long'
 325 # * variadic macros
 326 # * overlong strings
 327 # So, we only use -pedantic if we can disable those warnings.
 328
 329 ACX_PROG_CC_WARNING_OPTS(
 330         m4_quote(m4_do([-W -Wall -Wwrite-strings -Wcast-qual])), [loose_warn])
 331 ACX_PROG_CC_WARNING_OPTS(
 332         m4_quote(m4_do([-Wstrict-prototypes -Wmissing-prototypes])),
 333         [c_loose_warn])
 334 ACX_PROG_CC_WARNING_OPTS(
 335         m4_quote(m4_do([-Wmissing-format-attribute])), [strict_warn])
 336 ACX_PROG_CC_WARNING_OPTS(
 337         m4_quote(m4_do([-Wold-style-definition -Wc++-compat])), [c_strict_warn])
 338 ACX_PROG_CC_WARNING_ALMOST_PEDANTIC(
 339         m4_quote(m4_do([-Wno-long-long -Wno-variadic-macros ],
 340                        [-Wno-overlength-strings])), [strict_warn])
 341 ACX_PROG_CC_WARNINGS_ARE_ERRORS([manual], [strict_warn])
 342
 343 # The above macros do nothing if the compiler is not GCC.  However, the
 344 # Makefile has more goo to add other flags, so these variables are used
 345 # to enable warnings only for GCC.
 346 warn_cflags=
 347 warn_cxxflags=
 348 if test "x$GCC" = "xyes"; then
 349   warn_cflags='$(GCC_WARN_CFLAGS)'
 350   warn_cxxflags='$(GCC_WARN_CXXFLAGS)'
 351 fi
 352 AC_SUBST(warn_cflags)
 353 AC_SUBST(warn_cxxflags)
 354
 355 # Enable expensive internal checks
 356 is_release=
 357 if test x"`cat $srcdir/DEV-PHASE`" != xexperimental; then
 358   is_release=yes
 359 fi
 360
 361 AC_ARG_ENABLE(checking,
 362 [  --enable-checking[=LIST]
 363                           enable expensive run-time checks.  With LIST,
 364                           enable only specific categories of checks.
 365                           Categories are: yes,no,all,none,release.
 366                           Flags are: assert,df,fold,gc,gcac,gimple,misc,
 367                           rtlflag,rtl,runtime,tree,valgrind,types.],
 368 [ac_checking_flags="${enableval}"],[
 369 # Determine the default checks.
 370 if test x$is_release = x ; then
 371   ac_checking_flags=yes
 372 else
 373   ac_checking_flags=release
 374 fi])
 375 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 376 for check in release $ac_checking_flags
 377 do
 378         case $check in
 379         # these set all the flags to specific states
 380         yes)            ac_assert_checking=1 ; ac_checking=1 ; ac_df_checking= ;
 381                         ac_fold_checking= ; ac_gc_checking=1 ;
 382                         ac_gc_always_collect= ; ac_gimple_checking=1 ; ac_rtl_checking= ;
 383                         ac_rtlflag_checking=1 ; ac_runtime_checking=1 ;
 384                         ac_tree_checking=1 ; ac_valgrind_checking= ;
 385                         ac_types_checking=1 ;;
 386         no|none)        ac_assert_checking= ; ac_checking= ; ac_df_checking= ;
 387                         ac_fold_checking= ; ac_gc_checking= ;
 388                         ac_gc_always_collect= ; ac_gimple_checking= ; ac_rtl_checking= ;
 389                         ac_rtlflag_checking= ; ac_runtime_checking= ;
 390                         ac_tree_checking= ; ac_valgrind_checking= ;
 391                         ac_types_checking= ;;
 392         all)            ac_assert_checking=1 ; ac_checking=1 ; ac_df_checking=1 ;
 393                         ac_fold_checking=1 ; ac_gc_checking=1 ;
 394                         ac_gc_always_collect=1 ; ac_gimple_checking=1 ; ac_rtl_checking=1 ;
 395                         ac_rtlflag_checking=1 ; ac_runtime_checking=1 ;
 396                         ac_tree_checking=1 ; ac_valgrind_checking= ;
 397                         ac_types_checking=1 ;;
 398         release)        ac_assert_checking=1 ; ac_checking= ; ac_df_checking= ;
 399                         ac_fold_checking= ; ac_gc_checking= ;
 400                         ac_gc_always_collect= ; ac_gimple_checking= ; ac_rtl_checking= ;
 401                         ac_rtlflag_checking= ; ac_runtime_checking=1 ;
 402                         ac_tree_checking= ; ac_valgrind_checking= ;
 403                         ac_types_checking= ;;
 404         # these enable particular checks
 405         assert)         ac_assert_checking=1 ;;
 406         df)             ac_df_checking=1 ;;
 407         fold)           ac_fold_checking=1 ;;
 408         gc)             ac_gc_checking=1 ;;
 409         gcac)           ac_gc_always_collect=1 ;;
 410         gimple)         ac_gimple_checking=1 ;;
 411         misc)           ac_checking=1 ;;
 412         rtl)            ac_rtl_checking=1 ;;
 413         rtlflag)        ac_rtlflag_checking=1 ;;
 414         runtime)        ac_runtime_checking=1 ;;
 415         tree)           ac_tree_checking=1 ;;
 416         types)          ac_types_checking=1 ;;
 417         valgrind)       ac_valgrind_checking=1 ;;
 418         *)      AC_MSG_ERROR(unknown check category $check) ;;
 419         esac
 420 done
 421 IFS="$ac_save_IFS"
 422
 423 nocommon_flag=""
 424 if test x$ac_checking != x ; then
 425   AC_DEFINE(ENABLE_CHECKING, 1,
 426 [Define if you want more run-time sanity checks.  This one gets a grab
 427    bag of miscellaneous but relatively cheap checks.])
 428   nocommon_flag=-fno-common
 429 fi
 430 AC_SUBST(nocommon_flag)
 431 if test x$ac_df_checking != x ; then
 432   AC_DEFINE(ENABLE_DF_CHECKING, 1,
 433 [Define if you want more run-time sanity checks for dataflow.])
 434 fi
 435 if test x$ac_assert_checking != x ; then
 436   AC_DEFINE(ENABLE_ASSERT_CHECKING, 1,
 437 [Define if you want assertions enabled.  This is a cheap check.])
 438 fi
 439 if test x$ac_gimple_checking != x ; then
 440   AC_DEFINE(ENABLE_GIMPLE_CHECKING, 1,
 441 [Define if you want operations on GIMPLE (the basic data structure of
 442 the high-level optimizers) to be checked for dynamic type safety at
 443 runtime.  This is moderately expensive.])
 444 fi
 445 GCC_TARGET_TEMPLATE(ENABLE_RUNTIME_CHECKING)
 446 if test x$ac_runtime_checking != x ; then
 447   AC_DEFINE(ENABLE_RUNTIME_CHECKING, 1,
 448 [Define if you want runtime assertions enabled.  This is a cheap check.])
 449 fi
 450 if test x$ac_tree_checking != x ; then
 451   AC_DEFINE(ENABLE_TREE_CHECKING, 1,
 452 [Define if you want all operations on trees (the basic data
 453    structure of the front ends) to be checked for dynamic type safety
 454    at runtime.  This is moderately expensive.  The tree browser debugging
 455    routines will also be enabled by this option.
 456    ])
 457   TREEBROWSER=tree-browser.o
 458 fi
 459 if test x$ac_types_checking != x ; then
 460   AC_DEFINE(ENABLE_TYPES_CHECKING, 1,
 461 [Define if you want all gimple types to be verified after gimplifiation.
 462    This is cheap.
 463    ])
 464 fi
 465 AC_SUBST(TREEBROWSER)
 466 if test x$ac_rtl_checking != x ; then
 467   AC_DEFINE(ENABLE_RTL_CHECKING, 1,
 468 [Define if you want all operations on RTL (the basic data structure
 469    of the optimizer and back end) to be checked for dynamic type safety
 470    at runtime.  This is quite expensive.])
 471 fi
 472 if test x$ac_rtlflag_checking != x ; then
 473   AC_DEFINE(ENABLE_RTL_FLAG_CHECKING, 1,
 474 [Define if you want RTL flag accesses to be checked against the RTL
 475    codes that are supported for each access macro.  This is relatively
 476    cheap.])
 477 fi
 478 if test x$ac_gc_checking != x ; then
 479   AC_DEFINE(ENABLE_GC_CHECKING, 1,
 480 [Define if you want the garbage collector to do object poisoning and
 481    other memory allocation checks.  This is quite expensive.])
 482 fi
 483 if test x$ac_gc_always_collect != x ; then
 484   AC_DEFINE(ENABLE_GC_ALWAYS_COLLECT, 1,
 485 [Define if you want the garbage collector to operate in maximally
 486    paranoid mode, validating the entire heap and collecting garbage at
 487    every opportunity.  This is extremely expensive.])
 488 fi
 489 if test x$ac_fold_checking != x ; then
 490   AC_DEFINE(ENABLE_FOLD_CHECKING, 1,
 491 [Define if you want fold checked that it never destructs its argument.
 492    This is quite expensive.])
 493 fi
 494 valgrind_path_defines=
 495 valgrind_command=
 496
 497 dnl # This check AC_REQUIREs various stuff, so it *must not* be inside
 498 dnl # an if statement.  This was the source of very frustrating bugs
 499 dnl # in converting to autoconf 2.5x!
 500 AC_CHECK_HEADER(valgrind.h, have_valgrind_h=yes, have_valgrind_h=no)
 501
 502 if test x$ac_valgrind_checking != x ; then
 503   # It is certainly possible that there's valgrind but no valgrind.h.
 504   # GCC relies on making annotations so we must have both.
 505   AC_MSG_CHECKING(for VALGRIND_DISCARD in <valgrind/memcheck.h>)
 506   AC_PREPROC_IFELSE([AC_LANG_SOURCE(
 507     [[#include <valgrind/memcheck.h>
 508 #ifndef VALGRIND_DISCARD
 509 #error VALGRIND_DISCARD not defined
 510 #endif]])],
 511   [gcc_cv_header_valgrind_memcheck_h=yes],
 512   [gcc_cv_header_valgrind_memcheck_h=no])
 513   AC_MSG_RESULT($gcc_cv_header_valgrind_memcheck_h)
 514   AC_MSG_CHECKING(for VALGRIND_DISCARD in <memcheck.h>)
 515   AC_PREPROC_IFELSE([AC_LANG_SOURCE(
 516     [[#include <memcheck.h>
 517 #ifndef VALGRIND_DISCARD
 518 #error VALGRIND_DISCARD not defined
 519 #endif]])],
 520   [gcc_cv_header_memcheck_h=yes],
 521   [gcc_cv_header_memcheck_h=no])
 522   AC_MSG_RESULT($gcc_cv_header_memcheck_h)
 523   AM_PATH_PROG_WITH_TEST(valgrind_path, valgrind,
 524         [$ac_dir/$ac_word --version | grep valgrind- >/dev/null 2>&1])
 525   if test "x$valgrind_path" = "x" \
 526     || (test $have_valgrind_h = no \
 527         && test $gcc_cv_header_memcheck_h = no \
 528         && test $gcc_cv_header_valgrind_memcheck_h = no); then
 529         AC_MSG_ERROR([*** Can't find both valgrind and valgrind/memcheck.h, memcheck.h or valgrind.h])
 530   fi
 531   valgrind_path_defines=-DVALGRIND_PATH='\"'$valgrind_path'\"'
 532   valgrind_command="$valgrind_path -q"
 533   AC_DEFINE(ENABLE_VALGRIND_CHECKING, 1,
 534 [Define if you want to run subprograms and generated programs
 535    through valgrind (a memory checker).  This is extremely expensive.])
 536   if test $gcc_cv_header_valgrind_memcheck_h = yes; then
 537     AC_DEFINE(HAVE_VALGRIND_MEMCHECK_H, 1,
 538         [Define if valgrind's valgrind/memcheck.h header is installed.])
 539   fi
 540   if test $gcc_cv_header_memcheck_h = yes; then
 541     AC_DEFINE(HAVE_MEMCHECK_H, 1,
 542         [Define if valgrind's memcheck.h header is installed.])
 543   fi
 544 fi
 545 AC_SUBST(valgrind_path_defines)
 546 AC_SUBST(valgrind_command)
 547
 548 # Enable code coverage collection
 549 AC_ARG_ENABLE(coverage,
 550 [  --enable-coverage[=LEVEL]
 551                           enable compiler's code coverage collection.
 552                           Use to measure compiler performance and locate
 553                           unused parts of the compiler. With LEVEL, specify
 554                           optimization. Values are opt, noopt,
 555                           default is noopt],
 556 [case "${enableval}" in
 557   yes|noopt)
 558     coverage_flags="-fprofile-arcs -ftest-coverage -frandom-seed=\$@ -O0"
 559     ;;
 560   opt)
 561     coverage_flags="-fprofile-arcs -ftest-coverage -frandom-seed=\$@ -O2"
 562     ;;
 563   no)
 564     # a.k.a. --disable-coverage
 565     coverage_flags=""
 566     ;;
 567   *)
 568     AC_MSG_ERROR(unknown coverage setting $enableval)
 569     ;;
 570 esac],
 571 [coverage_flags=""])
 572 AC_SUBST(coverage_flags)
 573
 574 AC_ARG_ENABLE(gather-detailed-mem-stats,
 575 [  --enable-gather-detailed-mem-stats         enable detailed memory allocation stats gathering], [],
 576 [enable_gather_detailed_mem_stats=no])
 577 if test x$enable_gather_detailed_mem_stats = xyes ; then
 578   AC_DEFINE(GATHER_STATISTICS, 1,
 579         [Define to enable detailed memory allocation stats gathering.])
 580 fi
 581
 582 # -------------------------------
 583 # Miscenalleous configure options
 584 # -------------------------------
 585
 586 # See if we are building gcc with C++.
 587 AC_ARG_ENABLE(build-with-cxx,
 588 [  --enable-build-with-cxx build with C++ compiler instead of C compiler],
 589 ENABLE_BUILD_WITH_CXX=$enableval,
 590 ENABLE_BUILD_WITH_CXX=no)
 591 AC_SUBST(ENABLE_BUILD_WITH_CXX)
 592 if test "$ENABLE_BUILD_WITH_CXX" = "yes"; then
 593   AC_DEFINE(ENABLE_BUILD_WITH_CXX, 1,
 594             [Define if building with C++.])
 595 fi
 596
 597 # With stabs
 598 AC_ARG_WITH(stabs,
 599 [  --with-stabs            arrange to use stabs instead of host debug format],
 600 stabs="$with_stabs",
 601 stabs=no)
 602
 603 # Determine whether or not multilibs are enabled.
 604 AC_ARG_ENABLE(multilib,
 605 [  --enable-multilib       enable library support for multiple ABIs],
 606 [], [enable_multilib=yes])
 607 AC_SUBST(enable_multilib)
 608
 609 # Enable __cxa_atexit for C++.
 610 AC_ARG_ENABLE(__cxa_atexit,
 611 [  --enable-__cxa_atexit   enable __cxa_atexit for C++],
 612 [], [])
 613
 614 # Enable C extension for decimal float if target supports it.
 615 GCC_AC_ENABLE_DECIMAL_FLOAT([$target])
 616
 617 dfp=`if test $enable_decimal_float != no; then echo 1; else echo 0; fi`
 618 AC_DEFINE_UNQUOTED(ENABLE_DECIMAL_FLOAT, $dfp,
 619 [Define to 1 to enable decimal float extension to C.])
 620
 621 # Use default_decimal_float for dependency.
 622 enable_decimal_float=$default_decimal_float
 623
 624 bid=`if test $enable_decimal_float = bid; then echo 1; else echo 0; fi`
 625 AC_DEFINE_UNQUOTED(ENABLE_DECIMAL_BID_FORMAT, $bid,
 626 [Define to 1 to specify that we are using the BID decimal floating
 627 point format instead of DPD])
 628
 629 # Enable C extension for fixed-point arithmetic.
 630 AC_ARG_ENABLE(fixed-point,
 631 [  --enable-fixed-point    enable fixed-point arithmetic extension to C],
 632 [
 633 ],
 634 [
 635   case $target in
 636     mips*-*-*)
 637       case $host in
 638         mips*-sgi-irix*)
 639           AC_MSG_WARN([fixed-point is not supported on IRIX, ignored])
 640           enable_fixed_point=no
 641           ;;
 642         *)
 643           enable_fixed_point=yes
 644           ;;
 645       esac
 646       ;;
 647     *)
 648       AC_MSG_WARN([fixed-point is not supported for this target, ignored])
 649       enable_fixed_point=no
 650       ;;
 651   esac
 652 ])
 653 AC_SUBST(enable_fixed_point)
 654
 655 fixedpoint=`if test $enable_fixed_point = yes; then echo 1; else echo 0; fi`
 656 AC_DEFINE_UNQUOTED(ENABLE_FIXED_POINT, $fixedpoint,
 657 [Define to 1 to enable fixed-point arithmetic extension to C.])
 658
 659 # Enable threads
 660 # Pass with no value to take the default
 661 # Pass with a value to specify a thread package
 662 AC_ARG_ENABLE(threads,
 663 [  --enable-threads        enable thread usage for target GCC
 664   --enable-threads=LIB    use LIB thread package for target GCC],,
 665 [enable_threads=''])
 666
 667 AC_ARG_ENABLE(tls,
 668 [  --enable-tls            enable or disable generation of tls code
 669                           overriding the assembler check for tls support],
 670 [
 671   case $enable_tls in
 672     yes | no) ;;
 673     *) AC_MSG_ERROR(['$enable_tls' is an invalid value for --enable-tls.
 674 Valid choices are 'yes' and 'no'.]) ;;
 675   esac
 676 ], [enable_tls=''])
 677
 678 AC_ARG_ENABLE(objc-gc,
 679 [  --enable-objc-gc       enable the use of Boehm's garbage collector with
 680                           the GNU Objective-C runtime],
 681 if test x$enable_objc_gc = xno; then
 682         objc_boehm_gc=''
 683 else
 684         objc_boehm_gc=1
 685 fi,
 686 objc_boehm_gc='')
 687
 688 AC_ARG_WITH(dwarf2,
 689 [  --with-dwarf2           force the default debug format to be DWARF 2],
 690 dwarf2="$with_dwarf2",
 691 dwarf2=no)
 692
 693 AC_ARG_ENABLE(shared,
 694 [  --disable-shared        don't provide a shared libgcc],
 695 [
 696   case $enable_shared in
 697   yes | no) ;;
 698   *)
 699     enable_shared=no
 700     IFS="${IFS=         }"; ac_save_ifs="$IFS"; IFS="${IFS}:,"
 701     for pkg in $enableval; do
 702       if test "X$pkg" = "Xgcc" || test "X$pkg" = "Xlibgcc"; then
 703         enable_shared=yes
 704       fi
 705     done
 706     IFS="$ac_save_ifs"
 707     ;;
 708   esac
 709 ], [enable_shared=yes])
 710 AC_SUBST(enable_shared)
 711
 712 AC_ARG_WITH(build-sysroot,
 713   [  --with-build-sysroot=sysroot
 714                           use sysroot as the system root during the build])
 715
 716 AC_ARG_WITH(sysroot,
 717 [  --with-sysroot[=DIR] Search for usr/lib, usr/include, et al, within DIR.],
 718 [
 719  case ${with_sysroot} in
 720  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_noncanonical}/sys-root' ;;
 721  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
 722  esac
 723
 724  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
 725  CROSS_SYSTEM_HEADER_DIR='$(TARGET_SYSTEM_ROOT)$${sysroot_headers_suffix}$(NATIVE_SYSTEM_HEADER_DIR)'
 726
 727  if test "x$prefix" = xNONE; then
 728   test_prefix=/usr/local
 729  else
 730   test_prefix=$prefix
 731  fi
 732  if test "x$exec_prefix" = xNONE; then
 733   test_exec_prefix=$test_prefix
 734  else
 735   test_exec_prefix=$exec_prefix
 736  fi
 737  case ${TARGET_SYSTEM_ROOT} in
 738  "${test_prefix}"|"${test_prefix}/"*|\
 739  "${test_exec_prefix}"|"${test_exec_prefix}/"*|\
 740  '${prefix}'|'${prefix}/'*|\
 741  '${exec_prefix}'|'${exec_prefix}/'*)
 742    t="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE"
 743    TARGET_SYSTEM_ROOT_DEFINE="$t"
 744    ;;
 745  esac
 746 ], [
 747  TARGET_SYSTEM_ROOT=
 748  TARGET_SYSTEM_ROOT_DEFINE=
 749  CROSS_SYSTEM_HEADER_DIR='$(gcc_tooldir)/sys-include'
 750 ])
 751 AC_SUBST(TARGET_SYSTEM_ROOT)
 752 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
 753 AC_SUBST(CROSS_SYSTEM_HEADER_DIR)
 754
 755 AC_ARG_WITH(specs,
 756   [AS_HELP_STRING([--with-specs=SPECS],
 757                   [add SPECS to driver command-line processing])],
 758   [CONFIGURE_SPECS=$withval],
 759   [CONFIGURE_SPECS=]
 760 )
 761 AC_SUBST(CONFIGURE_SPECS)
 762
 763 ACX_PKGVERSION([GCC])
 764 ACX_BUGURL([http://gcc.gnu.org/bugs.html])
 765
 766 # Sanity check enable_languages in case someone does not run the toplevel
 767 # configure # script.
 768 AC_ARG_ENABLE(languages,
 769 [  --enable-languages=LIST specify which front-ends to build],
 770 [case ,${enable_languages}, in
 771        ,,|,yes,)
 772                 # go safe -- we cannot be much sure without the toplevel
 773                 # configure's
 774                 # analysis of which target libs are present and usable
 775                 enable_languages=c
 776                 ;;
 777          *,all,*)
 778                 AC_MSG_ERROR([only the toplevel supports --enable-languages=all])
 779                 ;;
 780         *,c,*)
 781                 ;;
 782         *)
 783                 enable_languages=c,${enable_languages}
 784                 ;;
 785 esac],
 786 [enable_languages=c])
 787
 788 AC_ARG_WITH(multilib-list,
 789 [  --with-multilib-list    Select multilibs (SH only)],
 790 :,
 791 with_multilib_list=default)
 792
 793 # -------------------------
 794 # Checks for other programs
 795 # -------------------------
 796
 797 AC_PROG_MAKE_SET
 798
 799 # Find some useful tools
 800 AC_PROG_AWK
 801 # We need awk to create options.c and options.h.
 802 # Bail out if it's missing.
 803 case ${AWK} in
 804   "") AC_MSG_ERROR([can't build without awk, bailing out]) ;;
 805 esac
 806
 807 gcc_AC_PROG_LN_S
 808 ACX_PROG_LN($LN_S)
 809 AC_PROG_RANLIB
 810 case "${host}" in
 811 *-*-darwin*)
 812   # By default, the Darwin ranlib will not treat common symbols as
 813   # definitions when  building the archive table of contents.  Other
 814   # ranlibs do that; pass an option to the Darwin ranlib that makes
 815   # it behave similarly.
 816   ranlib_flags="-c"
 817   ;;
 818 *)
 819   ranlib_flags=""
 820 esac
 821 AC_SUBST(ranlib_flags)
 822
 823 gcc_AC_PROG_INSTALL
 824
 825 # See if cmp has --ignore-initial.
 826 gcc_AC_PROG_CMP_IGNORE_INITIAL
 827
 828 # See if we have the mktemp command.
 829 AC_CHECK_PROG(have_mktemp_command, mktemp, yes, no)
 830
 831 # See if makeinfo has been installed and is modern enough
 832 # that we can use it.
 833 ACX_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
 834   [GNU texinfo.* \([0-9][0-9.]*\)],
 835   [4.[7-9]*|4.[1-9][0-9]*|[5-9]*|[1-9][0-9]*])
 836 if test $gcc_cv_prog_makeinfo_modern = no; then
 837   AC_MSG_WARN([
 838 *** Makeinfo is missing or too old.
 839 *** Info documentation will not be built.])
 840   BUILD_INFO=
 841 else
 842   BUILD_INFO=info
 843 fi
 844 AC_SUBST(BUILD_INFO)
 845
 846 # Is pod2man recent enough to regenerate manpages?
 847 AC_MSG_CHECKING([for recent Pod::Man])
 848 if (perl -e 'use 1.10 Pod::Man') >/dev/null 2>&1; then
 849   AC_MSG_RESULT(yes)
 850   GENERATED_MANPAGES=generated-manpages
 851 else
 852   AC_MSG_RESULT(no)
 853   GENERATED_MANPAGES=
 854 fi
 855 AC_SUBST(GENERATED_MANPAGES)
 856
 857 MISSING="${CONFIG_SHELL-/bin/sh} $ac_aux_dir/missing"
 858
 859 # How about lex?
 860 dnl Don't use AC_PROG_LEX; we insist on flex.
 861 dnl LEXLIB is not useful in gcc.
 862 AC_CHECK_PROGS([FLEX], flex, [$MISSING flex])
 863
 864 # Bison?
 865 AC_CHECK_PROGS([BISON], bison, [$MISSING bison])
 866
 867 # Binutils are not build modules, unlike bison/flex/makeinfo.  So we
 868 # check for build == host before using them.
 869
 870 # NM
 871 if test x${build} = x${host} && test -f $srcdir/../binutils/nm.c \
 872   && test -d ../binutils ; then
 873   NM='${objdir}/../binutils/nm-new'
 874 else
 875   AC_CHECK_PROG(NM, nm, nm, ${CONFIG_SHELL-/bin/sh} ${srcdir}/../missing nm)
 876 fi
 877
 878 # AR
 879 if test x${build} = x${host} && test -f $srcdir/../binutils/ar.c \
 880   && test -d ../binutils ; then
 881   AR='${objdir}/../binutils/ar'
 882 else
 883   AC_CHECK_PROG(AR, ar, ar, ${CONFIG_SHELL-/bin/sh} ${srcdir}/../missing ar)
 884 fi
 885
 886
 887 # --------------------
 888 # Checks for C headers
 889 # --------------------
 890
 891 # Need to reject headers which give warnings, so that the -Werror bootstrap
 892 # works later. *sigh*  This needs to come before all header checks.
 893 AC_PROG_CPP_WERROR
 894
 895 AC_HEADER_STDC
 896 AC_HEADER_TIME
 897 ACX_HEADER_STRING
 898 AC_HEADER_SYS_WAIT
 899 AC_CHECK_HEADERS(limits.h stddef.h string.h strings.h stdlib.h time.h iconv.h \
 900                  fcntl.h unistd.h sys/file.h sys/time.h sys/mman.h \
 901                  sys/resource.h sys/param.h sys/times.h sys/stat.h \
 902                  direct.h malloc.h langinfo.h ldfcn.h locale.h wchar.h)
 903
 904 # Check for thread headers.
 905 AC_CHECK_HEADER(thread.h, [have_thread_h=yes], [have_thread_h=])
 906 AC_CHECK_HEADER(pthread.h, [have_pthread_h=yes], [have_pthread_h=])
 907
 908 # These tests can't be done till we know if we have limits.h.
 909 gcc_AC_C_CHAR_BIT
 910 AC_C_BIGENDIAN
 911
 912 # ----------------------
 913 # Checks for C++ headers
 914 # ----------------------
 915
 916 dnl Autoconf will give an error in the configure script if there is no
 917 dnl C++ preprocessor.  Hack to prevent that.
 918 m4_pushdef([AC_MSG_ERROR], m4_defn([AC_MSG_WARN]))[]dnl
 919 AC_PROG_CXXCPP
 920 m4_popdef([AC_MSG_ERROR])[]dnl
 921
 922 AC_LANG_PUSH(C++)
 923
 924 AC_CHECK_HEADERS(unordered_map)
 925 AC_CHECK_HEADERS(tr1/unordered_map)
 926 AC_CHECK_HEADERS(ext/hash_map)
 927
 928 AC_LANG_POP(C++)
 929
 930 # --------
 931 # UNSORTED
 932 # --------
 933
 934
 935 # These libraries may be used by collect2.
 936 # We may need a special search path to get them linked.
 937 AC_CACHE_CHECK(for collect2 libraries, gcc_cv_collect2_libs,
 938 [save_LIBS="$LIBS"
 939 for libs in '' -lld -lmld \
 940                 '-L/usr/lib/cmplrs/cc2.11 -lmld' \
 941                 '-L/usr/lib/cmplrs/cc3.11 -lmld'
 942 do
 943         LIBS="$libs"
 944         AC_TRY_LINK_FUNC(ldopen,
 945                 [gcc_cv_collect2_libs="$libs"; break])
 946 done
 947 LIBS="$save_LIBS"
 948 test -z "$gcc_cv_collect2_libs" && gcc_cv_collect2_libs='none required'])
 949 case $gcc_cv_collect2_libs in
 950         "none required")        ;;
 951         *)      COLLECT2_LIBS=$gcc_cv_collect2_libs ;;
 952 esac
 953 AC_SUBST(COLLECT2_LIBS)
 954
 955 # When building Ada code on Alpha, we need exc_resume which is usually in
 956 # -lexc.  So test for it.
 957 save_LIBS="$LIBS"
 958 LIBS=
 959 AC_SEARCH_LIBS(exc_resume, exc)
 960 GNAT_LIBEXC="$LIBS"
 961 LIBS="$save_LIBS"
 962 AC_SUBST(GNAT_LIBEXC)
 963
 964 # Some systems put ldexp and frexp in libm instead of libc; assume
 965 # they're both in the same place.  jcf-dump needs them.
 966 save_LIBS="$LIBS"
 967 LIBS=
 968 AC_SEARCH_LIBS(ldexp, m)
 969 LDEXP_LIB="$LIBS"
 970 LIBS="$save_LIBS"
 971 AC_SUBST(LDEXP_LIB)
 972
 973 # Use <inttypes.h> only if it exists,
 974 # doesn't clash with <sys/types.h>, and declares intmax_t.
 975 AC_MSG_CHECKING(for inttypes.h)
 976 AC_CACHE_VAL(gcc_cv_header_inttypes_h,
 977 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 978 [[#include <sys/types.h>
 979 #include <inttypes.h>]],
 980   [[intmax_t i = -1;]])],
 981   [gcc_cv_header_inttypes_h=yes],
 982   [gcc_cv_header_inttypes_h=no])])
 983 AC_MSG_RESULT($gcc_cv_header_inttypes_h)
 984 if test $gcc_cv_header_inttypes_h = yes; then
 985   AC_DEFINE(HAVE_INTTYPES_H, 1,
 986         [Define if you have a working <inttypes.h> header file.])
 987 fi
 988
 989 dnl Disabled until we have a complete test for buggy enum bitfields.
 990 dnl gcc_AC_C_ENUM_BF_UNSIGNED
 991
 992 define(gcc_UNLOCKED_FUNCS, clearerr_unlocked feof_unlocked dnl
 993   ferror_unlocked fflush_unlocked fgetc_unlocked fgets_unlocked dnl
 994   fileno_unlocked fprintf_unlocked fputc_unlocked fputs_unlocked dnl
 995   fread_unlocked fwrite_unlocked getchar_unlocked getc_unlocked dnl
 996   putchar_unlocked putc_unlocked)
 997 AC_CHECK_FUNCS(times clock kill getrlimit setrlimit atoll atoq \
 998         sysconf strsignal getrusage nl_langinfo \
 999         gettimeofday mbstowcs wcswidth mmap setlocale \
1000         gcc_UNLOCKED_FUNCS)
1001
1002 if test x$ac_cv_func_mbstowcs = xyes; then
1003   AC_CACHE_CHECK(whether mbstowcs works, gcc_cv_func_mbstowcs_works,
1004 [    AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdlib.h>
1005 int main()
1006 {
1007   mbstowcs(0, "", 0);
1008   return 0;
1009 }]])],
1010     [gcc_cv_func_mbstowcs_works=yes],
1011     [gcc_cv_func_mbstowcs_works=no],
1012     [gcc_cv_func_mbstowcs_works=yes])])
1013   if test x$gcc_cv_func_mbstowcs_works = xyes; then
1014     AC_DEFINE(HAVE_WORKING_MBSTOWCS, 1,
1015   [Define this macro if mbstowcs does not crash when its
1016    first argument is NULL.])
1017   fi
1018 fi
1019
1020 AC_CHECK_TYPE(ssize_t, int)
1021 AC_CHECK_TYPE(caddr_t, char *)
1022
1023 gcc_AC_FUNC_MMAP_BLACKLIST
1024
1025 case "${host}" in
1026 *-*-*vms*)
1027   # Under VMS, vfork works very differently than on Unix. The standard test
1028   # won't work, and it isn't easily adaptable. It makes more sense to
1029   # just force it.
1030   ac_cv_func_vfork_works=yes
1031   ;;
1032 esac
1033 AC_FUNC_FORK
1034
1035 AM_ICONV
1036 # Until we have in-tree GNU iconv:
1037 LIBICONV_DEP=
1038 AC_SUBST(LIBICONV_DEP)
1039
1040 AM_LC_MESSAGES
1041
1042 AM_LANGINFO_CODESET
1043
1044 # We will need to find libiberty.h and ansidecl.h
1045 saved_CFLAGS="$CFLAGS"
1046 CFLAGS="$CFLAGS -I${srcdir} -I${srcdir}/../include"
1047 gcc_AC_CHECK_DECLS(getenv atol asprintf sbrk abort atof getcwd getwd \
1048         strsignal strstr strverscmp \
1049         errno snprintf vsnprintf vasprintf malloc realloc calloc \
1050         free basename getopt clock getpagesize gcc_UNLOCKED_FUNCS, , ,[
1051 #include "ansidecl.h"
1052 #include "system.h"])
1053
1054 gcc_AC_CHECK_DECLS(getrlimit setrlimit getrusage, , ,[
1055 #include "ansidecl.h"
1056 #include "system.h"
1057 #ifdef HAVE_SYS_RESOURCE_H
1058 #include <sys/resource.h>
1059 #endif
1060 ])
1061
1062 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1063 #include "ansidecl.h"
1064 #include "system.h"
1065 #ifdef HAVE_SYS_RESOURCE_H
1066 #include <sys/resource.h>
1067 #endif
1068 ]], [[rlim_t l = 0;]])],[],[AC_DEFINE([rlim_t],[long],
1069 [Define to `long' if <sys/resource.h> doesn't define.])])
1070
1071 # On AIX 5.2, <ldfcn.h> conflicts with <fcntl.h>, as both define incompatible
1072 # FREAD and FWRITE macros.  Fortunately, for GCC's single usage of ldgetname
1073 # in collect2.c, <fcntl.h> isn't visible, but the configure test below needs
1074 # to undef these macros to get the correct value for HAVE_DECL_LDGETNAME.
1075 gcc_AC_CHECK_DECLS(ldgetname, , ,[
1076 #include "ansidecl.h"
1077 #include "system.h"
1078 #ifdef HAVE_LDFCN_H
1079 #undef FREAD
1080 #undef FWRITE
1081 #include <ldfcn.h>
1082 #endif
1083 ])
1084
1085 gcc_AC_CHECK_DECLS(times, , ,[
1086 #include "ansidecl.h"
1087 #include "system.h"
1088 #ifdef HAVE_SYS_TIMES_H
1089 #include <sys/times.h>
1090 #endif
1091 ])
1092
1093 gcc_AC_CHECK_DECLS(sigaltstack, , ,[
1094 #include "ansidecl.h"
1095 #include "system.h"
1096 #include <signal.h>
1097 ])
1098
1099 # More time-related stuff.
1100 AC_CACHE_CHECK(for struct tms, ac_cv_struct_tms, [
1101 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1102 #include "ansidecl.h"
1103 #include "system.h"
1104 #ifdef HAVE_SYS_TIMES_H
1105 #include <sys/times.h>
1106 #endif
1107 ]], [[struct tms tms;]])],[ac_cv_struct_tms=yes],[ac_cv_struct_tms=no])])
1108 if test $ac_cv_struct_tms = yes; then
1109   AC_DEFINE(HAVE_STRUCT_TMS, 1,
1110   [Define if <sys/times.h> defines struct tms.])
1111 fi
1112
1113 # use gcc_cv_* here because this doesn't match the behavior of AC_CHECK_TYPE.
1114 # revisit after autoconf 2.50.
1115 AC_CACHE_CHECK(for clock_t, gcc_cv_type_clock_t, [
1116 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1117 #include "ansidecl.h"
1118 #include "system.h"
1119 ]], [[clock_t x;]])],[gcc_cv_type_clock_t=yes],[gcc_cv_type_clock_t=no])])
1120 if test $gcc_cv_type_clock_t = yes; then
1121   AC_DEFINE(HAVE_CLOCK_T, 1,
1122   [Define if <time.h> defines clock_t.])
1123 fi
1124
1125 # Restore CFLAGS from before the gcc_AC_NEED_DECLARATIONS tests.
1126 CFLAGS="$saved_CFLAGS"
1127
1128 gcc_AC_INITFINI_ARRAY
1129
1130 # mkdir takes a single argument on some systems.
1131 gcc_AC_FUNC_MKDIR_TAKES_ONE_ARG
1132
1133 # File extensions
1134 manext='.1'
1135 objext='.o'
1136 AC_SUBST(manext)
1137 AC_SUBST(objext)
1138
1139 # With Setjmp/Longjmp based exception handling.
1140 AC_ARG_ENABLE(sjlj-exceptions,
1141 [  --enable-sjlj-exceptions
1142                           arrange to use setjmp/longjmp exception handling],
1143 [case $target in
1144   *-*-hpux10*)
1145     if test $enableval != yes; then
1146       AC_MSG_WARN([dwarf2 exceptions not supported, sjlj exceptions forced])
1147       enableval=yes
1148     fi
1149     ;;
1150 esac
1151 force_sjlj_exceptions=yes],
1152 [case $target in
1153   *-*-hpux10*)
1154     force_sjlj_exceptions=yes
1155     enableval=yes
1156     ;;
1157   *)
1158     force_sjlj_exceptions=no
1159     ;;
1160 esac])
1161 if test $force_sjlj_exceptions = yes; then
1162   sjlj=`if test $enableval = yes; then echo 1; else echo 0; fi`
1163   AC_DEFINE_UNQUOTED(CONFIG_SJLJ_EXCEPTIONS, $sjlj,
1164     [Define 0/1 to force the choice for exception handling model.])
1165 fi
1166
1167 # For platforms with the unwind ABI which includes an unwind library,
1168 # libunwind, we can choose to use the system libunwind.
1169 # config.gcc also contains tests of with_system_libunwind.
1170 GCC_CHECK_UNWIND_GETIPINFO
1171
1172 # --------------------------------------------------------
1173 # Build, host, and target specific configuration fragments
1174 # --------------------------------------------------------
1175
1176 # Collect build-machine-specific information.
1177 . ${srcdir}/config.build
1178
1179 # Collect host-machine-specific information.
1180 . ${srcdir}/config.host
1181
1182 target_gtfiles=
1183
1184 # Collect target-machine-specific information.
1185 . ${srcdir}/config.gcc
1186
1187 extra_objs="${host_extra_objs} ${extra_objs}"
1188 extra_gcc_objs="${host_extra_gcc_objs} ${extra_gcc_objs}"
1189
1190 # Default the target-machine variables that were not explicitly set.
1191 if test x"$tm_file" = x
1192 then tm_file=$cpu_type/$cpu_type.h; fi
1193
1194 if test x"$extra_headers" = x
1195 then extra_headers=; fi
1196
1197 if test x$md_file = x
1198 then md_file=$cpu_type/$cpu_type.md; fi
1199
1200 if test x$out_file = x
1201 then out_file=$cpu_type/$cpu_type.c; fi
1202
1203 if test x"$tmake_file" = x
1204 then tmake_file=$cpu_type/t-$cpu_type
1205 fi
1206
1207 if test x"$dwarf2" = xyes
1208 then tm_file="$tm_file tm-dwarf2.h"
1209 fi
1210
1211 # Say what files are being used for the output code and MD file.
1212 echo "Using \`$srcdir/config/$out_file' for machine-specific logic."
1213 echo "Using \`$srcdir/config/$md_file' as machine description file."
1214
1215 # If any of the xm_file variables contain nonexistent files, warn
1216 # about them and drop them.
1217
1218 bx=
1219 for x in $build_xm_file; do
1220   if    test -f $srcdir/config/$x
1221   then      bx="$bx $x"
1222   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1223   fi
1224 done
1225 build_xm_file="$bx"
1226
1227 hx=
1228 for x in $host_xm_file; do
1229   if    test -f $srcdir/config/$x
1230   then      hx="$hx $x"
1231   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1232   fi
1233 done
1234 host_xm_file="$hx"
1235
1236 tx=
1237 for x in $xm_file; do
1238   if    test -f $srcdir/config/$x
1239   then      tx="$tx $x"
1240   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1241   fi
1242 done
1243 xm_file="$tx"
1244
1245 count=a
1246 for f in $tm_file; do
1247         count=${count}x
1248 done
1249 if test $count = ax; then
1250         echo "Using \`$srcdir/config/$tm_file' as target machine macro file."
1251 else
1252         echo "Using the following target machine macro files:"
1253         for f in $tm_file; do
1254                 echo "  $srcdir/config/$f"
1255         done
1256 fi
1257
1258 if test x$need_64bit_hwint = xyes; then
1259         AC_DEFINE(NEED_64BIT_HOST_WIDE_INT, 1,
1260 [Define to 1 if HOST_WIDE_INT must be 64 bits wide (see hwint.h).])
1261 fi
1262
1263 if test x$use_long_long_for_widest_fast_int = xyes; then
1264         AC_DEFINE(USE_LONG_LONG_FOR_WIDEST_FAST_INT, 1,
1265 [Define to 1 if the 'long long' (or '__int64') is wider than 'long' but still
1266 efficiently supported by the host hardware.])
1267 fi
1268
1269 count=a
1270 for f in $host_xm_file; do
1271         count=${count}x
1272 done
1273 if test $count = a; then
1274         :
1275 elif test $count = ax; then
1276         echo "Using \`$srcdir/config/$host_xm_file' as host machine macro file."
1277 else
1278         echo "Using the following host machine macro files:"
1279         for f in $host_xm_file; do
1280                 echo "  $srcdir/config/$f"
1281         done
1282 fi
1283 echo "Using ${out_host_hook_obj} for host machine hooks."
1284
1285 if test "$host_xm_file" != "$build_xm_file"; then
1286         count=a
1287         for f in $build_xm_file; do
1288                 count=${count}x
1289         done
1290         if test $count = a; then
1291                 :
1292         elif test $count = ax; then
1293                 echo "Using \`$srcdir/config/$build_xm_file' as build machine macro file."
1294         else
1295                 echo "Using the following build machine macro files:"
1296                 for f in $build_xm_file; do
1297                         echo "  $srcdir/config/$f"
1298                 done
1299         fi
1300 fi
1301
1302 case ${host} in
1303   powerpc*-*-darwin*)
1304     AC_CACHE_CHECK([whether mcontext_t fields have underscores],
1305       gcc_cv_mcontext_underscores,
1306       AC_COMPILE_IFELSE([
1307 #include <sys/cdefs.h>
1308 #include <sys/signal.h>
1309 #include <ucontext.h>
1310 int main() { mcontext_t m; if (m->ss.srr0) return 0; return 0; }
1311 ],
1312         gcc_cv_mcontext_underscores=no, gcc_cv_mcontext_underscores=yes))
1313       if test $gcc_cv_mcontext_underscores = yes; then
1314         AC_DEFINE(HAS_MCONTEXT_T_UNDERSCORES,,dnl
1315           [mcontext_t fields start with __])
1316       fi
1317     ;;
1318 esac
1319
1320 # ---------
1321 # Threading
1322 # ---------
1323
1324 # Check if a valid thread package
1325 case ${enable_threads} in
1326   "" | no)
1327     # No threads
1328     target_thread_file='single'
1329     ;;
1330   yes)
1331     # default
1332     target_thread_file='single'
1333     ;;
1334   aix | dce | gnat | irix | posix | posix95 | rtems | \
1335   single | vxworks | win32 | mipssde)
1336     target_thread_file=${enable_threads}
1337     ;;
1338   *)
1339     echo "${enable_threads} is an unknown thread package" 1>&2
1340     exit 1
1341     ;;
1342 esac
1343
1344 if test x${thread_file} = x; then
1345   # No thread file set by target-specific clauses in config.gcc,
1346   # so use file chosen by default logic above
1347   thread_file=${target_thread_file}
1348 fi
1349
1350 # Make gthr-default.h if we have a thread file.
1351 gthread_flags=
1352 if test $thread_file != single; then
1353   echo "#include \"gthr-${thread_file}.h\"" > gthr-default.h-t
1354   if diff gthr-default.h-t gthr-default.h 2>/dev/null; then
1355     rm -f gthr-default.h-t
1356   else
1357     mv -f gthr-default.h-t gthr-default.h
1358   fi
1359   gthread_flags=-DHAVE_GTHR_DEFAULT
1360 fi
1361 AC_SUBST(gthread_flags)
1362
1363 # --------
1364 # UNSORTED
1365 # --------
1366
1367 use_cxa_atexit=no
1368 if test x$enable___cxa_atexit = xyes || \
1369    test x$enable___cxa_atexit = x -a x$default_use_cxa_atexit = xyes; then
1370   if test x$host = x$target; then
1371     case $host in
1372       # mingw32 doesn't have __cxa_atexit but uses atexit registration
1373       # keyed to flag_use_cxa_atexit
1374       *-*-mingw32*)
1375         use_cxa_atexit=yes
1376         ;;
1377       *)
1378         AC_CHECK_FUNC(__cxa_atexit,[use_cxa_atexit=yes],
1379           [echo "__cxa_atexit can't be enabled on this target"])
1380         ;;
1381     esac
1382   else
1383     # We can't check for __cxa_atexit when building a cross, so assume
1384     # it is available
1385     use_cxa_atexit=yes
1386   fi
1387   if test x$use_cxa_atexit = xyes; then
1388     AC_DEFINE(DEFAULT_USE_CXA_ATEXIT, 2,
1389       [Define if you want to use __cxa_atexit, rather than atexit, to
1390       register C++ destructors for local statics and global objects.
1391       This is essential for fully standards-compliant handling of
1392       destructors, but requires __cxa_atexit in libc.])
1393   fi
1394 fi
1395
1396 # Look for a file containing extra machine modes.
1397 if test -n "$extra_modes" && test -f $srcdir/config/$extra_modes; then
1398   extra_modes_file='$(srcdir)'/config/${extra_modes}
1399   AC_SUBST(extra_modes_file)
1400   AC_DEFINE_UNQUOTED(EXTRA_MODES_FILE, "config/$extra_modes",
1401   [Define to the name of a file containing a list of extra machine modes
1402    for this architecture.])
1403 fi
1404
1405 # Convert extra_options into a form suitable for Makefile use.
1406 extra_opt_files=
1407 all_opt_files=
1408 for f in $extra_options; do
1409   extra_opt_files="$extra_opt_files \$(srcdir)/config/$f"
1410   all_opt_files="$all_opt_files $srcdir/config/$f"
1411 done
1412 AC_SUBST(extra_opt_files)
1413
1414 # auto-host.h is the file containing items generated by autoconf and is
1415 # the first file included by config.h.
1416 # If host=build, it is correct to have bconfig include auto-host.h
1417 # as well.  If host!=build, we are in error and need to do more
1418 # work to find out the build config parameters.
1419 if test x$host = x$build
1420 then
1421         build_auto=auto-host.h
1422 else
1423         # We create a subdir, then run autoconf in the subdir.
1424         # To prevent recursion we set host and build for the new
1425         # invocation of configure to the build for this invocation
1426         # of configure.
1427         tempdir=build.$$
1428         rm -rf $tempdir
1429         mkdir $tempdir
1430         cd $tempdir
1431         case ${srcdir} in
1432         /* | [A-Za-z]:[\\/]* ) realsrcdir=${srcdir};;
1433         *) realsrcdir=../${srcdir};;
1434         esac
1435         saved_CFLAGS="${CFLAGS}"
1436         CC="${CC_FOR_BUILD}" CFLAGS="${CFLAGS_FOR_BUILD}" \
1437         LDFLAGS="${LDFLAGS_FOR_BUILD}" \
1438         ${realsrcdir}/configure \
1439                 --enable-languages=${enable_languages-all} \
1440                 --target=$target_alias --host=$build_alias --build=$build_alias
1441         CFLAGS="${saved_CFLAGS}"
1442
1443         # We just finished tests for the build machine, so rename
1444         # the file auto-build.h in the gcc directory.
1445         mv auto-host.h ../auto-build.h
1446         cd ..
1447         rm -rf $tempdir
1448         build_auto=auto-build.h
1449 fi
1450 AC_SUBST(build_subdir)
1451
1452 tm_file="${tm_file} defaults.h"
1453 tm_p_file="${tm_p_file} tm-preds.h"
1454 host_xm_file="auto-host.h ansidecl.h ${host_xm_file}"
1455 build_xm_file="${build_auto} ansidecl.h ${build_xm_file}"
1456 # We don't want ansidecl.h in target files, write code there in ISO/GNU C.
1457 # put this back in temporarily.
1458 xm_file="auto-host.h ansidecl.h ${xm_file}"
1459
1460 # --------
1461 # UNSORTED
1462 # --------
1463
1464 changequote(,)dnl
1465 # Compile in configure arguments.
1466 if test -f configargs.h ; then
1467         # Being re-configured.
1468         gcc_config_arguments=`grep configuration_arguments configargs.h | sed -e 's/.*"\([^"]*\)".*/\1/'`
1469         gcc_config_arguments="$gcc_config_arguments : (reconfigured) $TOPLEVEL_CONFIGURE_ARGUMENTS"
1470 else
1471         gcc_config_arguments="$TOPLEVEL_CONFIGURE_ARGUMENTS"
1472 fi
1473
1474 # Double all backslashes and backslash all quotes to turn
1475 # gcc_config_arguments into a C string.
1476 sed -e 's/\\/\\\\/g; s/"/\\"/g' <<EOF >conftest.out
1477 $gcc_config_arguments
1478 EOF
1479 gcc_config_arguments_str=`cat conftest.out`
1480 rm -f conftest.out
1481
1482 cat > configargs.h <<EOF
1483 /* Generated automatically. */
1484 static const char configuration_arguments[] = "$gcc_config_arguments_str";
1485 static const char thread_model[] = "$thread_file";
1486
1487 static const struct {
1488   const char *name, *value;
1489 } configure_default_options[] = $configure_default_options;
1490 EOF
1491 changequote([,])dnl
1492
1493 changequote(,)dnl
1494 gcc_BASEVER=`cat $srcdir/BASE-VER`
1495 gcc_DEVPHASE=`cat $srcdir/DEV-PHASE`
1496 gcc_DATESTAMP=`cat $srcdir/DATESTAMP`
1497 if test -f $srcdir/REVISION ; then
1498         gcc_REVISION=`cat $srcdir/REVISION`
1499 else
1500         gcc_REVISION=""
1501 fi
1502 cat > plugin-version.h <<EOF
1503 #include "configargs.h"
1504
1505 static char basever[] = "$gcc_BASEVER";
1506 static char datestamp[] = "$gcc_DATESTAMP";
1507 static char devphase[] = "$gcc_DEVPHASE";
1508 static char revision[] = "$gcc_REVISION";
1509
1510 /* FIXME plugins: We should make the version information more precise.
1511    One way to do is to add a checksum. */
1512
1513 static struct plugin_gcc_version gcc_version = {basever, datestamp,
1514                                                 devphase, revision,
1515                                                 configuration_arguments};
1516 EOF
1517 changequote([,])dnl
1518
1519 # Internationalization
1520 ZW_GNU_GETTEXT_SISTER_DIR
1521
1522 # If LIBINTL contains LIBICONV, then clear LIBICONV so we don't get
1523 # -liconv on the link line twice.
1524 case "$LIBINTL" in *$LIBICONV*)
1525         LIBICONV= ;;
1526 esac
1527
1528 AC_ARG_ENABLE(secureplt,
1529 [  --enable-secureplt      enable -msecure-plt by default for PowerPC],
1530 [], [])
1531
1532 AC_ARG_ENABLE(leading-mingw64-underscores,
1533   AS_HELP_STRING([--enable-leading-mingw64-underscores],
1534                  [Enable leading underscores on 64 bit mingw targets]),
1535   [],[])
1536 AS_IF([ test x"$enable_leading_mingw64_underscores" = xyes ],
1537   [AC_DEFINE(USE_MINGW64_LEADING_UNDERSCORES, 1,
1538     [Define if we should use leading underscore on 64 bit mingw targets])])
1539
1540 AC_ARG_ENABLE(cld,
1541 [  --enable-cld            enable -mcld by default for 32bit x86], [],
1542 [enable_cld=no])
1543
1544 AC_ARG_ENABLE(frame-pointer,
1545 [  --enable-frame-pointer  enable -fno-omit-frame-pointer by default for 32bit x86], [],
1546 [
1547 case $target_os in
1548 linux* | darwin[[8912]]*)
1549   # Enable -fomit-frame-pointer by default for Linux and Darwin with
1550   # DWARF2.
1551   enable_frame_pointer=no
1552   ;;
1553 *)
1554   enable_frame_pointer=yes
1555   ;;
1556 esac
1557 ])
1558
1559 # Windows32 Registry support for specifying GCC installation paths.
1560 AC_ARG_ENABLE(win32-registry,
1561 [  --disable-win32-registry
1562                           disable lookup of installation paths in the
1563                           Registry on Windows hosts
1564   --enable-win32-registry enable registry lookup (default)
1565   --enable-win32-registry=KEY
1566                           use KEY instead of GCC version as the last portion
1567                           of the registry key],,)
1568
1569 case $host_os in
1570   win32 | pe | cygwin* | mingw32* | uwin*)
1571     if test "x$enable_win32_registry" != xno; then
1572       AC_SEARCH_LIBS(RegOpenKeyExA, advapi32,, [enable_win32_registry=no])
1573     fi
1574
1575     if test "x$enable_win32_registry" != xno; then
1576       AC_DEFINE(ENABLE_WIN32_REGISTRY, 1,
1577   [Define to 1 if installation paths should be looked up in the Windows
1578    Registry. Ignored on non-Windows hosts.])
1579
1580       if test "x$enable_win32_registry" != xyes \
1581          && test "x$enable_win32_registry" != x; then
1582         AC_DEFINE_UNQUOTED(WIN32_REGISTRY_KEY, "$enable_win32_registry",
1583   [Define to be the last component of the Windows registry key under which
1584    to look for installation paths.  The full key used will be
1585    HKEY_LOCAL_MACHINE/SOFTWARE/Free Software Foundation/{WIN32_REGISTRY_KEY}.
1586    The default is the GCC version number.])
1587       fi
1588     fi
1589   ;;
1590 esac
1591
1592 # Get an absolute path to the GCC top-level source directory
1593 holddir=`${PWDCMD-pwd}`
1594 cd $srcdir
1595 topdir=`${PWDCMD-pwd}`
1596 cd $holddir
1597
1598 # Conditionalize the makefile for this host machine.
1599 xmake_file=
1600 for f in ${host_xmake_file}
1601 do
1602         if test -f ${srcdir}/config/$f
1603         then
1604                 xmake_file="${xmake_file} \$(srcdir)/config/$f"
1605         fi
1606 done
1607
1608 # Conditionalize the makefile for this target machine.
1609 tmake_file_=
1610 for f in ${tmake_file}
1611 do
1612         if test -f ${srcdir}/config/$f
1613         then
1614                 tmake_file_="${tmake_file_} \$(srcdir)/config/$f"
1615         fi
1616 done
1617 tmake_file="${tmake_file_}"
1618
1619 out_object_file=`basename $out_file .c`.o
1620
1621 tm_file_list="options.h"
1622 tm_include_list="options.h insn-constants.h"
1623 for f in $tm_file; do
1624   case $f in
1625     ./* )
1626        f=`echo $f | sed 's/^..//'`
1627        tm_file_list="${tm_file_list} $f"
1628        tm_include_list="${tm_include_list} $f"
1629        ;;
1630     defaults.h )
1631        tm_file_list="${tm_file_list} \$(srcdir)/$f"
1632        tm_include_list="${tm_include_list} $f"
1633        ;;
1634     * )
1635        tm_file_list="${tm_file_list} \$(srcdir)/config/$f"
1636        tm_include_list="${tm_include_list} config/$f"
1637        ;;
1638   esac
1639 done
1640
1641 libgcc_tm_file_list=
1642 libgcc_tm_include_list=
1643 for f in $libgcc_tm_file; do
1644   libgcc_tm_file_list="${libgcc_tm_file_list} \$(srcdir)/../libgcc/config/$f"
1645   libgcc_tm_include_list="${libgcc_tm_include_list} ../libgcc/config/$f"
1646 done
1647
1648 tm_p_file_list=
1649 tm_p_include_list=
1650 for f in $tm_p_file; do
1651   case $f in
1652     tm-preds.h )
1653        tm_p_file_list="${tm_p_file_list} $f"
1654        tm_p_include_list="${tm_p_include_list} $f"
1655        ;;
1656     * )
1657        tm_p_file_list="${tm_p_file_list} \$(srcdir)/config/$f"
1658        tm_p_include_list="${tm_p_include_list} config/$f"
1659   esac
1660 done
1661
1662 xm_file_list=
1663 xm_include_list=
1664 for f in $xm_file; do
1665   case $f in
1666     ansidecl.h )
1667        xm_file_list="${xm_file_list} \$(srcdir)/../include/$f"
1668        xm_include_list="${xm_include_list} $f"
1669        ;;
1670     auto-host.h )
1671        xm_file_list="${xm_file_list} $f"
1672        xm_include_list="${xm_include_list} $f"
1673        ;;
1674     * )
1675        xm_file_list="${xm_file_list} \$(srcdir)/config/$f"
1676        xm_include_list="${xm_include_list} config/$f"
1677        ;;
1678   esac
1679 done
1680
1681 host_xm_file_list=
1682 host_xm_include_list=
1683 for f in $host_xm_file; do
1684   case $f in
1685     ansidecl.h )
1686        host_xm_file_list="${host_xm_file_list} \$(srcdir)/../include/$f"
1687        host_xm_include_list="${host_xm_include_list} $f"
1688        ;;
1689     auto-host.h )
1690        host_xm_file_list="${host_xm_file_list} $f"
1691        host_xm_include_list="${host_xm_include_list} $f"
1692        ;;
1693     * )
1694        host_xm_file_list="${host_xm_file_list} \$(srcdir)/config/$f"
1695        host_xm_include_list="${host_xm_include_list} config/$f"
1696        ;;
1697   esac
1698 done
1699
1700 build_xm_file_list=
1701 for f in $build_xm_file; do
1702   case $f in
1703     ansidecl.h )
1704        build_xm_file_list="${build_xm_file_list} \$(srcdir)/../include/$f"
1705        build_xm_include_list="${build_xm_include_list} $f"
1706        ;;
1707     auto-build.h | auto-host.h )
1708        build_xm_file_list="${build_xm_file_list} $f"
1709        build_xm_include_list="${build_xm_include_list} $f"
1710        ;;
1711     * )
1712        build_xm_file_list="${build_xm_file_list} \$(srcdir)/config/$f"
1713        build_xm_include_list="${build_xm_include_list} config/$f"
1714        ;;
1715   esac
1716 done
1717
1718 # Define macro CROSS_DIRECTORY_STRUCTURE in compilation if this is a
1719 # cross-compiler which does not use the native headers and libraries.
1720 # Also use all.cross instead of all.internal and adjust SYSTEM_HEADER_DIR.
1721 CROSS=                                          AC_SUBST(CROSS)
1722 ALL=all.internal                                AC_SUBST(ALL)
1723 SYSTEM_HEADER_DIR='$(NATIVE_SYSTEM_HEADER_DIR)' AC_SUBST(SYSTEM_HEADER_DIR)
1724
1725 if test "x$with_build_sysroot" != x; then
1726   build_system_header_dir=$with_build_sysroot'$${sysroot_headers_suffix}$(NATIVE_SYSTEM_HEADER_DIR)'
1727 else
1728   # This value is used, even on a native system, because
1729   # CROSS_SYSTEM_HEADER_DIR is just
1730   # $(TARGET_SYSTEM_ROOT)$(NATIVE_SYSTEM_HEADER_DIR).
1731   build_system_header_dir='$(CROSS_SYSTEM_HEADER_DIR)'
1732 fi
1733
1734 if test x$host != x$target
1735 then
1736         CROSS="-DCROSS_DIRECTORY_STRUCTURE"
1737         ALL=all.cross
1738         SYSTEM_HEADER_DIR=$build_system_header_dir
1739         case "$host","$target" in
1740         # Darwin crosses can use the host system's libraries and headers,
1741         # because of the fat library support.  Of course, it must be the
1742         # same version of Darwin on both sides.  Allow the user to
1743         # just say --target=foo-darwin without a version number to mean
1744         # "the version on this system".
1745             *-*-darwin*,*-*-darwin*)
1746                 hostos=`echo $host | sed 's/.*-darwin/darwin/'`
1747                 targetos=`echo $target | sed 's/.*-darwin/darwin/'`
1748                 if test $hostos = $targetos -o $targetos = darwin ; then
1749                     CROSS=
1750                     SYSTEM_HEADER_DIR='$(NATIVE_SYSTEM_HEADER_DIR)'
1751                     with_headers=yes
1752                 fi
1753                 ;;
1754
1755             i?86-*-*,x86_64-*-* \
1756             | powerpc*-*-*,powerpc64*-*-*)
1757                 CROSS="$CROSS -DNATIVE_CROSS" ;;
1758         esac
1759
1760         case $target in
1761                 *-*-mingw*)
1762                         if test "x$with_headers" = x; then
1763                                 with_headers=yes
1764                         fi
1765                         ;;
1766                 *)
1767                         ;;
1768         esac
1769 elif test "x$TARGET_SYSTEM_ROOT" != x; then
1770         SYSTEM_HEADER_DIR=$build_system_header_dir
1771 fi
1772
1773 # If this is a cross-compiler that does not
1774 # have its own set of headers then define
1775 # inhibit_libc
1776
1777 # If this is using newlib, without having the headers available now,
1778 # then define inhibit_libc in LIBGCC2_CFLAGS.
1779 # This prevents libgcc2 from containing any code which requires libc
1780 # support.
1781 : ${inhibit_libc=false}
1782 if { { test x$host != x$target && test "x$with_sysroot" = x ; } ||
1783        test x$with_newlib = xyes ; } &&
1784      { test "x$with_headers" = x || test "x$with_headers" = xno ; } ; then
1785        inhibit_libc=true
1786 fi
1787 AC_SUBST(inhibit_libc)
1788
1789 # When building gcc with a cross-compiler, we need to adjust things so
1790 # that the generator programs are still built with the native compiler.
1791 # Also, we cannot run fixincludes.
1792
1793 # These are the normal (build=host) settings:
1794 CC_FOR_BUILD='$(CC)'            AC_SUBST(CC_FOR_BUILD)
1795 BUILD_CFLAGS='$(ALL_CFLAGS)'    AC_SUBST(BUILD_CFLAGS)
1796 BUILD_LDFLAGS='$(LDFLAGS)'      AC_SUBST(BUILD_LDFLAGS)
1797 STMP_FIXINC=stmp-fixinc         AC_SUBST(STMP_FIXINC)
1798
1799 # And these apply if build != host, or we are generating coverage data
1800 if test x$build != x$host || test "x$coverage_flags" != x
1801 then
1802     BUILD_CFLAGS='$(INTERNAL_CFLAGS) $(T_CFLAGS) $(CFLAGS_FOR_BUILD)'
1803     BUILD_LDFLAGS='$(LDFLAGS_FOR_BUILD)'
1804 fi
1805
1806 # Expand extra_headers to include complete path.
1807 # This substitutes for lots of t-* files.
1808 extra_headers_list=
1809 # Prepend $(srcdir)/config/${cpu_type}/ to every entry in extra_headers.
1810 for file in ${extra_headers} ; do
1811   extra_headers_list="${extra_headers_list} \$(srcdir)/config/${cpu_type}/${file}"
1812 done
1813
1814 # If use_gcc_tgmath is set, append ginclude/tgmath.h.
1815 if test x"$use_gcc_tgmath" = xyes
1816 then extra_headers_list="${extra_headers_list} \$(srcdir)/ginclude/tgmath.h"
1817 fi
1818
1819 # Define collect2 in Makefile.
1820 case $host_can_use_collect2 in
1821   no) collect2= ;;
1822   *) collect2='collect2$(exeext)' ;;
1823 esac
1824 AC_SUBST([collect2])
1825
1826 # Add a definition of USE_COLLECT2 if system wants one.
1827 case $use_collect2 in
1828   no) use_collect2= ;;
1829   "") ;;
1830   *)
1831     host_xm_defines="${host_xm_defines} USE_COLLECT2"
1832     xm_defines="${xm_defines} USE_COLLECT2"
1833     case $host_can_use_collect2 in
1834       no)
1835         AC_MSG_ERROR([collect2 is required but cannot be built on this system])
1836         ;;
1837     esac
1838     ;;
1839 esac
1840
1841 AC_DEFINE_UNQUOTED(LTOPLUGINSONAME,"${host_lto_plugin_soname}",
1842 [Define to the name of the LTO plugin DSO that must be
1843   passed to the linker's -plugin=LIB option.])
1844
1845 # ---------------------------
1846 # Assembler & linker features
1847 # ---------------------------
1848
1849 # During stage 2, ld is actually gcc/collect-ld, which is a small script to
1850 # discern between when to use prev-ld/ld-new and when to use ld/ld-new.
1851 # However when ld-new is first executed from the build tree, libtool will
1852 # relink it as .libs/lt-ld-new, so that it can give it an RPATH that refers
1853 # to the build tree.  While doing this we need to use the previous-stage
1854 # linker, or we have an infinite loop.  The presence of a shell script as
1855 # ld/ld-new, and the fact that the script *uses ld itself*, is what confuses
1856 # the gcc/collect-ld script.  So we need to know how libtool works, or
1857 # exec-tool will fail.
1858
1859 m4_defun([_LT_CONFIG_COMMANDS], [])
1860 AC_PROG_LIBTOOL
1861 AC_SUBST(objdir)
1862 AC_SUBST(enable_fast_install)
1863
1864 # Identify the assembler which will work hand-in-glove with the newly
1865 # built GCC, so that we can examine its features.  This is the assembler
1866 # which will be driven by the driver program.
1867 #
1868 # If build != host, and we aren't building gas in-tree, we identify a
1869 # build->target assembler and hope that it will have the same features
1870 # as the host->target assembler we'll be using.
1871 gcc_cv_gas_major_version=
1872 gcc_cv_gas_minor_version=
1873 gcc_cv_as_gas_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/gas
1874
1875 m4_pattern_allow([AS_FOR_TARGET])dnl
1876 AS_VAR_SET_IF(gcc_cv_as,, [
1877 if test -x "$DEFAULT_ASSEMBLER"; then
1878         gcc_cv_as="$DEFAULT_ASSEMBLER"
1879 elif test -f $gcc_cv_as_gas_srcdir/configure.in \
1880      && test -f ../gas/Makefile \
1881      && test x$build = x$host; then
1882         gcc_cv_as=../gas/as-new$build_exeext
1883 elif test -x as$build_exeext; then
1884         # Build using assembler in the current directory.
1885         gcc_cv_as=./as$build_exeext
1886 elif ( set dummy $AS_FOR_TARGET; test -x $[2] ); then
1887         gcc_cv_as="$AS_FOR_TARGET"
1888 else
1889         AC_PATH_PROG(gcc_cv_as, $AS_FOR_TARGET)
1890 fi])
1891
1892 ORIGINAL_AS_FOR_TARGET=$gcc_cv_as
1893 AC_SUBST(ORIGINAL_AS_FOR_TARGET)
1894 case "$ORIGINAL_AS_FOR_TARGET" in
1895   ./as | ./as$build_exeext) ;;
1896   *) AC_CONFIG_FILES(as:exec-tool.in, [chmod +x as]) ;;
1897 esac
1898
1899 AC_MSG_CHECKING(what assembler to use)
1900 if test "$gcc_cv_as" = ../gas/as-new$build_exeext; then
1901   # Single tree build which includes gas.  We want to prefer it
1902   # over whatever linker top-level may have detected, since
1903   # we'll use what we're building after installation anyway.
1904   AC_MSG_RESULT(newly built gas)
1905   in_tree_gas=yes
1906   _gcc_COMPUTE_GAS_VERSION
1907   in_tree_gas_is_elf=no
1908   if grep 'obj_format = elf' ../gas/Makefile > /dev/null \
1909      || (grep 'obj_format = multi' ../gas/Makefile \
1910          && grep 'extra_objects =.* obj-elf' ../gas/Makefile) > /dev/null
1911   then
1912     in_tree_gas_is_elf=yes
1913   fi
1914 else
1915   AC_MSG_RESULT($gcc_cv_as)
1916   in_tree_gas=no
1917 fi
1918
1919 # Identify the linker which will work hand-in-glove with the newly
1920 # built GCC, so that we can examine its features.  This is the linker
1921 # which will be driven by the driver program.
1922 #
1923 # If build != host, and we aren't building gas in-tree, we identify a
1924 # build->target linker and hope that it will have the same features
1925 # as the host->target linker we'll be using.
1926 gcc_cv_gld_major_version=
1927 gcc_cv_gld_minor_version=
1928 gcc_cv_ld_gld_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/ld
1929 gcc_cv_ld_bfd_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/bfd
1930
1931 AS_VAR_SET_IF(gcc_cv_ld,, [
1932 if test -x "$DEFAULT_LINKER"; then
1933         gcc_cv_ld="$DEFAULT_LINKER"
1934 elif test -f $gcc_cv_ld_gld_srcdir/configure.in \
1935      && test -f ../ld/Makefile \
1936      && test x$build = x$host; then
1937         gcc_cv_ld=../ld/ld-new$build_exeext
1938 elif test -x collect-ld$build_exeext; then
1939         # Build using linker in the current directory.
1940         gcc_cv_ld=./collect-ld$build_exeext
1941 elif ( set dummy $LD_FOR_TARGET; test -x $[2] ); then
1942         gcc_cv_ld="$LD_FOR_TARGET"
1943 else
1944         AC_PATH_PROG(gcc_cv_ld, $LD_FOR_TARGET)
1945 fi])
1946
1947 ORIGINAL_PLUGIN_LD_FOR_TARGET=$gcc_cv_ld
1948 PLUGIN_LD=`basename $gcc_cv_ld`
1949 AC_ARG_WITH(plugin-ld,
1950 [  --with-plugin-ld=[[ARG]]  specify the plugin linker],
1951 [if test x"$withval" != x; then
1952    ORIGINAL_PLUGIN_LD_FOR_TARGET="$withval"
1953    PLUGIN_LD="$withval"
1954  fi])
1955 AC_SUBST(ORIGINAL_PLUGIN_LD_FOR_TARGET)
1956 AC_DEFINE_UNQUOTED(PLUGIN_LD, "$PLUGIN_LD", [Specify plugin linker])
1957
1958 # Check to see if we are using gold instead of ld
1959 AC_MSG_CHECKING(whether we are using gold)
1960 ld_is_gold=no
1961 if test x$gcc_cv_ld != x; then
1962   if $gcc_cv_ld --version 2>/dev/null | sed 1q \
1963      | grep "GNU gold" > /dev/null; then
1964     ld_is_gold=yes
1965   fi
1966 fi
1967 AC_MSG_RESULT($ld_is_gold)
1968
1969 ORIGINAL_LD_FOR_TARGET=$gcc_cv_ld
1970 AC_SUBST(ORIGINAL_LD_FOR_TARGET)
1971 case "$ORIGINAL_LD_FOR_TARGET" in
1972   ./collect-ld | ./collect-ld$build_exeext) ;;
1973   *) AC_CONFIG_FILES(collect-ld:exec-tool.in, [chmod +x collect-ld]) ;;
1974 esac
1975
1976 AC_MSG_CHECKING(what linker to use)
1977 if test "$gcc_cv_ld" = ../ld/ld-new$build_exeext \
1978    || test "$gcc_cv_ld" = ../gold/ld-new$build_exeext; then
1979         # Single tree build which includes ld.  We want to prefer it
1980         # over whatever linker top-level may have detected, since
1981         # we'll use what we're building after installation anyway.
1982         AC_MSG_RESULT(newly built ld)
1983         in_tree_ld=yes
1984         in_tree_ld_is_elf=no
1985         if (grep 'EMUL = .*elf' ../ld/Makefile \
1986             || grep 'EMUL = .*linux' ../ld/Makefile \
1987             || grep 'EMUL = .*lynx' ../ld/Makefile) > /dev/null; then
1988           in_tree_ld_is_elf=yes
1989         elif test "$ld_is_gold" = yes; then
1990           in_tree_ld_is_elf=yes
1991         fi
1992         for f in $gcc_cv_ld_bfd_srcdir/configure $gcc_cv_ld_gld_srcdir/configure $gcc_cv_ld_gld_srcdir/configure.in $gcc_cv_ld_gld_srcdir/Makefile.in
1993         do
1994 changequote(,)dnl
1995                 gcc_cv_gld_version=`sed -n -e 's/^[     ]*\(VERSION=[0-9]*\.[0-9]*.*\)/\1/p' < $f`
1996                 if test x$gcc_cv_gld_version != x; then
1997                         break
1998                 fi
1999         done
2000         gcc_cv_gld_major_version=`expr "$gcc_cv_gld_version" : "VERSION=\([0-9]*\)"`
2001         gcc_cv_gld_minor_version=`expr "$gcc_cv_gld_version" : "VERSION=[0-9]*\.\([0-9]*\)"`
2002 changequote([,])dnl
2003 else
2004         AC_MSG_RESULT($gcc_cv_ld)
2005         in_tree_ld=no
2006 fi
2007
2008 # Figure out what nm we will be using.
2009 gcc_cv_binutils_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/binutils
2010 AS_VAR_SET_IF(gcc_cv_nm,, [
2011 if test -f $gcc_cv_binutils_srcdir/configure.in \
2012      && test -f ../binutils/Makefile \
2013      && test x$build = x$host; then
2014         gcc_cv_nm=../binutils/nm-new$build_exeext
2015 elif test -x nm$build_exeext; then
2016         gcc_cv_nm=./nm$build_exeext
2017 elif ( set dummy $NM_FOR_TARGET; test -x $[2] ); then
2018         gcc_cv_nm="$NM_FOR_TARGET"
2019 else
2020         AC_PATH_PROG(gcc_cv_nm, $NM_FOR_TARGET)
2021 fi])
2022
2023 AC_MSG_CHECKING(what nm to use)
2024 if test "$gcc_cv_nm" = ../binutils/nm-new$build_exeext; then
2025         # Single tree build which includes binutils.
2026         AC_MSG_RESULT(newly built nm)
2027         in_tree_nm=yes
2028 else
2029         AC_MSG_RESULT($gcc_cv_nm)
2030         in_tree_nm=no
2031 fi
2032
2033 ORIGINAL_NM_FOR_TARGET=$gcc_cv_nm
2034 AC_SUBST(ORIGINAL_NM_FOR_TARGET)
2035 case "$ORIGINAL_NM_FOR_TARGET" in
2036   ./nm | ./nm$build_exeext) ;;
2037   *) AC_CONFIG_FILES(nm:exec-tool.in, [chmod +x nm]) ;;
2038 esac
2039
2040
2041 # Figure out what objdump we will be using.
2042 AS_VAR_SET_IF(gcc_cv_objdump,, [
2043 if test -f $gcc_cv_binutils_srcdir/configure.in \
2044      && test -f ../binutils/Makefile \
2045      && test x$build = x$host; then
2046         # Single tree build which includes binutils.
2047         gcc_cv_objdump=../binutils/objdump$build_exeext
2048 elif test -x objdump$build_exeext; then
2049         gcc_cv_objdump=./objdump$build_exeext
2050 elif ( set dummy $OBJDUMP_FOR_TARGET; test -x $[2] ); then
2051         gcc_cv_objdump="$OBJDUMP_FOR_TARGET"
2052 else
2053         AC_PATH_PROG(gcc_cv_objdump, $OBJDUMP_FOR_TARGET)
2054 fi])
2055
2056 AC_MSG_CHECKING(what objdump to use)
2057 if test "$gcc_cv_objdump" = ../binutils/objdump$build_exeext; then
2058         # Single tree build which includes binutils.
2059         AC_MSG_RESULT(newly built objdump)
2060 elif test x$gcc_cv_objdump = x; then
2061         AC_MSG_RESULT(not found)
2062 else
2063         AC_MSG_RESULT($gcc_cv_objdump)
2064 fi
2065
2066 # Figure out what readelf we will be using.
2067 AS_VAR_SET_IF(gcc_cv_readelf,, [
2068 if test -f $gcc_cv_binutils_srcdir/configure.in \
2069      && test -f ../binutils/Makefile \
2070      && test x$build = x$host; then
2071         # Single tree build which includes binutils.
2072         gcc_cv_readelf=../binutils/readelf$build_exeext
2073 elif test -x readelf$build_exeext; then
2074         gcc_cv_readelf=./readelf$build_exeext
2075 else
2076         AC_PATH_PROG(gcc_cv_readelf, readelf)
2077 fi])
2078
2079 AC_MSG_CHECKING(what readelf to use)
2080 if test "$gcc_cv_readelf" = ../binutils/readelf$build_exeext; then
2081         # Single tree build which includes binutils.
2082         AC_MSG_RESULT(newly built readelf)
2083 elif test x$gcc_cv_readelf = x; then
2084         AC_MSG_RESULT(not found)
2085 else
2086         AC_MSG_RESULT($gcc_cv_readelf)
2087 fi
2088
2089 # Figure out what assembler alignment features are present.
2090 gcc_GAS_CHECK_FEATURE([.balign and .p2align], gcc_cv_as_balign_and_p2align,
2091  [2,6,0],,
2092 [.balign 4
2093 .p2align 2],,
2094 [AC_DEFINE(HAVE_GAS_BALIGN_AND_P2ALIGN, 1,
2095   [Define if your assembler supports .balign and .p2align.])])
2096
2097 gcc_GAS_CHECK_FEATURE([.p2align with maximum skip], gcc_cv_as_max_skip_p2align,
2098  [2,8,0],,
2099  [.p2align 4,,7],,
2100 [AC_DEFINE(HAVE_GAS_MAX_SKIP_P2ALIGN, 1,
2101   [Define if your assembler supports specifying the maximum number
2102    of bytes to skip when using the GAS .p2align command.])])
2103
2104 gcc_GAS_CHECK_FEATURE([.literal16], gcc_cv_as_literal16,
2105  [2,8,0],,
2106  [.literal16],,
2107 [AC_DEFINE(HAVE_GAS_LITERAL16, 1,
2108   [Define if your assembler supports .literal16.])])
2109
2110 gcc_GAS_CHECK_FEATURE([working .subsection -1], gcc_cv_as_subsection_m1,
2111  [elf,2,9,0],,
2112  [conftest_label1: .word 0
2113 .subsection -1
2114 conftest_label2: .word 0
2115 .previous],
2116  [if test x$gcc_cv_nm != x; then
2117     $gcc_cv_nm conftest.o | grep conftest_label1 > conftest.nm1
2118     $gcc_cv_nm conftest.o | grep conftest_label2 | sed -e 's/label2/label1/' > conftest.nm2
2119     if cmp conftest.nm1 conftest.nm2 > /dev/null 2>&1
2120     then :
2121     else gcc_cv_as_subsection_m1=yes
2122     fi
2123     rm -f conftest.nm1 conftest.nm2
2124   fi],
2125  [AC_DEFINE(HAVE_GAS_SUBSECTION_ORDERING, 1,
2126   [Define if your assembler supports .subsection and .subsection -1 starts
2127    emitting at the beginning of your section.])])
2128
2129 gcc_GAS_CHECK_FEATURE([.weak], gcc_cv_as_weak,
2130  [2,2,0],,
2131  [      .weak foobar],,
2132 [AC_DEFINE(HAVE_GAS_WEAK, 1, [Define if your assembler supports .weak.])])
2133
2134 gcc_GAS_CHECK_FEATURE([.weakref], gcc_cv_as_weakref,
2135  [2,17,0],,
2136  [      .weakref foobar, barfnot],,
2137 [AC_DEFINE(HAVE_GAS_WEAKREF, 1, [Define if your assembler supports .weakref.])])
2138
2139 gcc_GAS_CHECK_FEATURE([.nsubspa comdat], gcc_cv_as_nsubspa_comdat,
2140  [2,15,91],,
2141  [      .SPACE $TEXT$
2142         .NSUBSPA $CODE$,COMDAT],,
2143 [AC_DEFINE(HAVE_GAS_NSUBSPA_COMDAT, 1, [Define if your assembler supports .nsubspa comdat option.])])
2144
2145 # .hidden needs to be supported in both the assembler and the linker,
2146 # because GNU LD versions before 2.12.1 have buggy support for STV_HIDDEN.
2147 # This is irritatingly difficult to feature test for; we have to check the
2148 # date string after the version number.  If we've got an in-tree
2149 # ld, we don't know its patchlevel version, so we set the baseline at 2.13
2150 # to be safe.
2151 # The gcc_GAS_CHECK_FEATURE call just sets a cache variable.
2152 gcc_GAS_CHECK_FEATURE([.hidden], gcc_cv_as_hidden,
2153  [elf,2,13,0],,
2154 [       .hidden foobar
2155 foobar:],[
2156 # Solaris 9/x86 as incorrectly emits an alias for a hidden symbol with
2157 # STV_HIDDEN, so disable .hidden support if so.
2158 case "${target}" in
2159   i?86-*-solaris2*)
2160     if test x$gcc_cv_as != x && test x$gcc_cv_objdump != x; then
2161       cat > conftest.s <<EOF
2162 .globl hidden
2163         .hidden hidden
2164 hidden:
2165 .globl default
2166         .set    default,hidden
2167 EOF
2168       if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1 \
2169         && $gcc_cv_objdump -t conftest.o 2>/dev/null | \
2170         grep '\.hidden default' > /dev/null; then
2171         gcc_cv_as_hidden=no
2172       else
2173         gcc_cv_as_hidden=yes
2174       fi
2175     else
2176       # Assume bug is present if objdump is missing.
2177       gcc_cv_as_hidden=no
2178     fi
2179     ;;
2180   *)
2181     gcc_cv_as_hidden=yes
2182     ;;
2183 esac])
2184
2185 # gnu_indirect_function type is an extension proposed at
2186 # http://groups.google/com/group/generic-abi/files. It allows dynamic runtime
2187 # selection of function implementation
2188 AC_ARG_ENABLE(gnu-indirect-function,
2189  [AS_HELP_STRING([--enable-gnu-indirect-function],
2190                  [enable the use of the @gnu_indirect_function to glibc systems])],
2191  [case $enable_gnu_indirect_function in
2192     yes | no) ;;
2193     *) AC_MSG_ERROR(['$enable_gnu_indirect_function' is an invalid value for --enable-gnu-indirect-function.
2194 Valid choices are 'yes' and 'no'.]) ;;
2195   esac],
2196  [enable_gnu_indirect_function="$default_gnu_indirect_function"])
2197 if test x$enable_gnu_indirect_function = xyes; then
2198   AC_DEFINE(HAVE_GNU_INDIRECT_FUNCTION, 1,
2199    [Define if your system supports gnu indirect functions.])
2200 fi
2201
2202 changequote(,)dnl
2203 if test $in_tree_ld != yes ; then
2204   ld_ver=`$gcc_cv_ld --version 2>/dev/null | sed 1q`
2205   if echo "$ld_ver" | grep GNU > /dev/null; then
2206     if test x"$ld_is_gold" = xyes; then
2207       # GNU gold --version looks like this:
2208       #
2209       # GNU gold (GNU Binutils 2.21.51.20110225) 1.11
2210       #
2211       # We extract the binutils version which is more familiar and specific
2212       # than the gold version.
2213       ld_vers=`echo $ld_ver | sed -n \
2214           -e 's,^[^)]*[  ]\([0-9][0-9]*\.[0-9][0-9]*[^)]*\)) .*$,\1,p'`
2215     else
2216       # GNU ld --version looks like this:
2217       #
2218       # GNU ld (GNU Binutils) 2.21.51.20110225
2219       ld_vers=`echo $ld_ver | sed -n \
2220           -e 's,^.*[     ]\([0-9][0-9]*\.[0-9][0-9]*.*\)$,\1,p'`
2221     fi
2222     ld_date=`echo $ld_ver | sed -n 's,^.*\([2-9][0-9][0-9][0-9]\)[-]*\([01][0-9]\)[-]*\([0-3][0-9]\).*$,\1\2\3,p'`
2223     ld_vers_major=`expr "$ld_vers" : '\([0-9]*\)'`
2224     ld_vers_minor=`expr "$ld_vers" : '[0-9]*\.\([0-9]*\)'`
2225     ld_vers_patch=`expr "$ld_vers" : '[0-9]*\.[0-9]*\.\([0-9]*\)'`
2226   else
2227     case "${target}" in
2228       *-*-solaris2*)
2229         #
2230         # Solaris 2 ld -V output looks like this for a regular version:
2231         #
2232         # ld: Software Generation Utilities - Solaris Link Editors: 5.11-1.1699
2233         #
2234         # but test versions add stuff at the end:
2235         #
2236         # ld: Software Generation Utilities - Solaris Link Editors: 5.11-1.1701:onnv-ab196087-6931056-03/25/10
2237         #
2238         ld_ver=`$gcc_cv_ld -V 2>&1`
2239         if echo "$ld_ver" | grep 'Solaris Link Editors' > /dev/null; then
2240           ld_vers=`echo $ld_ver | sed -n \
2241             -e 's,^.*: 5\.[0-9][0-9]*-\([0-9]\.[0-9][0-9]*\).*$,\1,p'`
2242           ld_vers_major=`expr "$ld_vers" : '\([0-9]*\)'`
2243           ld_vers_minor=`expr "$ld_vers" : '[0-9]*\.\([0-9]*\)'`
2244         fi
2245         ;;
2246     esac
2247   fi
2248 fi
2249 changequote([,])dnl
2250
2251 AC_CACHE_CHECK(linker for .hidden support, gcc_cv_ld_hidden,
2252 [[if test $in_tree_ld = yes ; then
2253   gcc_cv_ld_hidden=no
2254   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 13 -o "$gcc_cv_gld_major_version" -gt 2 \
2255      && test $in_tree_ld_is_elf = yes; then
2256      gcc_cv_ld_hidden=yes
2257   fi
2258 else
2259   gcc_cv_ld_hidden=yes
2260   if test x"$ld_is_gold" = xyes; then
2261     :
2262   elif echo "$ld_ver" | grep GNU > /dev/null; then
2263     if test 0"$ld_date" -lt 20020404; then
2264       if test -n "$ld_date"; then
2265         # If there was date string, but was earlier than 2002-04-04, fail
2266         gcc_cv_ld_hidden=no
2267       elif test -z "$ld_vers"; then
2268         # If there was no date string nor ld version number, something is wrong
2269         gcc_cv_ld_hidden=no
2270       else
2271         test -z "$ld_vers_patch" && ld_vers_patch=0
2272         if test "$ld_vers_major" -lt 2; then
2273           gcc_cv_ld_hidden=no
2274         elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -lt 12; then
2275           gcc_cv_ld_hidden="no"
2276         elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -eq 12 -a "$ld_vers_patch" -eq 0; then
2277           gcc_cv_ld_hidden=no
2278         fi
2279       fi
2280     fi
2281   else
2282     case "${target}" in
2283       hppa64*-*-hpux* | ia64*-*-hpux*)
2284         gcc_cv_ld_hidden=yes
2285         ;;
2286       *-*-solaris2.8*)
2287         # .hidden support was backported to Solaris 8, starting with ld
2288         # version 1.276.
2289         if test "$ld_vers_minor" -ge 276; then
2290           gcc_cv_ld_hidden=yes
2291         else
2292           gcc_cv_ld_hidden=no
2293         fi
2294         ;;
2295       *-*-solaris2.9* | *-*-solaris2.1[0-9]*)
2296         # Support for .hidden in Sun ld appeared in Solaris 9 FCS, but
2297         # .symbolic was only added in Solaris 9 12/02.
2298         gcc_cv_ld_hidden=yes
2299         ;;
2300       *)
2301         gcc_cv_ld_hidden=no
2302         ;;
2303     esac
2304   fi
2305 fi]])
2306 libgcc_visibility=no
2307 AC_SUBST(libgcc_visibility)
2308 GCC_TARGET_TEMPLATE([HAVE_GAS_HIDDEN])
2309 if test $gcc_cv_as_hidden = yes && test $gcc_cv_ld_hidden = yes; then
2310   libgcc_visibility=yes
2311   AC_DEFINE(HAVE_GAS_HIDDEN, 1,
2312   [Define if your assembler and linker support .hidden.])
2313 fi
2314
2315 AC_MSG_CHECKING(linker read-only and read-write section mixing)
2316 gcc_cv_ld_ro_rw_mix=unknown
2317 if test $in_tree_ld = yes ; then
2318   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 10 -o "$gcc_cv_gld_major_version" -gt 2 \
2319      && test $in_tree_ld_is_elf = yes; then
2320     gcc_cv_ld_ro_rw_mix=read-write
2321   fi
2322 elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x -a x$gcc_cv_objdump != x ; then
2323   echo '.section myfoosect, "a"' > conftest1.s
2324   echo '.section myfoosect, "aw"' > conftest2.s
2325   echo '.byte 1' >> conftest2.s
2326   echo '.section myfoosect, "a"' > conftest3.s
2327   echo '.byte 0' >> conftest3.s
2328   if $gcc_cv_as -o conftest1.o conftest1.s > /dev/null 2>&1 \
2329      && $gcc_cv_as -o conftest2.o conftest2.s > /dev/null 2>&1 \
2330      && $gcc_cv_as -o conftest3.o conftest3.s > /dev/null 2>&1 \
2331      && $gcc_cv_ld -shared -o conftest1.so conftest1.o \
2332         conftest2.o conftest3.o > /dev/null 2>&1; then
2333     gcc_cv_ld_ro_rw_mix=`$gcc_cv_objdump -h conftest1.so \
2334                          | sed -e '/myfoosect/!d' -e N`
2335     if echo "$gcc_cv_ld_ro_rw_mix" | grep CONTENTS > /dev/null; then
2336       if echo "$gcc_cv_ld_ro_rw_mix" | grep READONLY > /dev/null; then
2337         gcc_cv_ld_ro_rw_mix=read-only
2338       else
2339         gcc_cv_ld_ro_rw_mix=read-write
2340       fi
2341     fi
2342   fi
2343 changequote(,)dnl
2344   rm -f conftest.* conftest[123].*
2345 changequote([,])dnl
2346 fi
2347 if test x$gcc_cv_ld_ro_rw_mix = xread-write; then
2348         AC_DEFINE(HAVE_LD_RO_RW_SECTION_MIXING, 1,
2349   [Define if your linker links a mix of read-only
2350    and read-write sections into a read-write section.])
2351 fi
2352 AC_MSG_RESULT($gcc_cv_ld_ro_rw_mix)
2353
2354 # Check if we have .[us]leb128, and support symbol arithmetic with it.
2355 gcc_GAS_CHECK_FEATURE([.sleb128 and .uleb128], gcc_cv_as_leb128,
2356   [elf,2,11,0],,
2357 [       .data
2358         .uleb128 L2 - L1
2359 L1:
2360         .uleb128 1280
2361         .sleb128 -1010
2362 L2:],
2363 [[# GAS versions before 2.11 do not support uleb128,
2364   # despite appearing to.
2365   # ??? There exists an elf-specific test that will crash
2366   # the assembler.  Perhaps it's better to figure out whether
2367   # arbitrary sections are supported and try the test.
2368   as_ver=`$gcc_cv_as --version 2>/dev/null | sed 1q`
2369   if echo "$as_ver" | grep GNU > /dev/null; then
2370     as_vers=`echo $as_ver | sed -n \
2371         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*.*\)$,\1,p'`
2372     as_major=`expr "$as_vers" : '\([0-9]*\)'`
2373     as_minor=`expr "$as_vers" : '[0-9]*\.\([0-9]*\)'`
2374     if test $as_major -eq 2 && test $as_minor -lt 11
2375     then :
2376     else gcc_cv_as_leb128=yes
2377     fi
2378   fi]],
2379   [AC_DEFINE(HAVE_AS_LEB128, 1,
2380     [Define if your assembler supports .sleb128 and .uleb128.])])
2381
2382 # Check if we have assembler support for unwind directives.
2383 gcc_GAS_CHECK_FEATURE([cfi directives], gcc_cv_as_cfi_directive,
2384   ,,
2385 [       .text
2386         .cfi_startproc
2387         .cfi_offset 0, 0
2388         .cfi_same_value 1
2389         .cfi_def_cfa 1, 2
2390         .cfi_escape 1, 2, 3, 4, 5
2391         .cfi_endproc],
2392 [case "$target" in
2393   *-*-solaris*)
2394     # If the linker used on Solaris (like Sun ld) isn't capable of merging
2395     # read-only and read-write sections, we need to make sure that the
2396     # assembler used emits read-write .eh_frame sections.
2397     if test "x$gcc_cv_ld_ro_rw_mix" != xread-write; then
2398       if test "x$gcc_cv_objdump" != x; then
2399         if $gcc_cv_objdump -h conftest.o 2>/dev/null | \
2400                 sed -e /.eh_frame/!d -e N | grep READONLY > /dev/null; then
2401           gcc_cv_as_cfi_directive=no
2402         else
2403           case "$target" in
2404             i?86-*-solaris2.1[[0-9]]*)
2405               # On Solaris/x86, make sure that GCC and gas agree on using
2406               # read-only .eh_frame sections for 64-bit.
2407               if $gcc_cv_as --64 -o conftest.o conftest.s > /dev/null 2>&1 && \
2408                 $gcc_cv_objdump -h conftest.o 2>/dev/null | \
2409                         sed -e /.eh_frame/!d -e N | \
2410                         grep READONLY > /dev/null; then
2411                 gcc_cv_as_cfi_directive=yes
2412               else
2413                 gcc_cv_as_cfi_directive=no
2414               fi
2415               ;;
2416             *)
2417               gcc_cv_as_cfi_directive=yes
2418               ;;
2419           esac
2420         fi
2421       else
2422         # no objdump, err on the side of caution
2423         gcc_cv_as_cfi_directive=no
2424       fi
2425     else
2426       gcc_cv_as_cfi_directive=yes
2427     fi
2428     ;;
2429   *-*-*)
2430     gcc_cv_as_cfi_directive=yes
2431     ;;
2432 esac])
2433 if test $gcc_cv_as_cfi_directive = yes && test x$gcc_cv_objdump != x; then
2434 gcc_GAS_CHECK_FEATURE([working cfi advance], gcc_cv_as_cfi_advance_working,
2435   ,,
2436 [       .text
2437         .cfi_startproc
2438         .cfi_adjust_cfa_offset 64
2439         .skip 75040, 0
2440         .cfi_adjust_cfa_offset 128
2441         .cfi_endproc],
2442 [[
2443 if $gcc_cv_objdump -Wf conftest.o 2>/dev/null \
2444     | grep 'DW_CFA_advance_loc[24]:[    ][      ]*75040[        ]' >/dev/null; then
2445    gcc_cv_as_cfi_advance_working=yes
2446 fi
2447 ]])
2448 else
2449   # no objdump, err on the side of caution
2450   gcc_cv_as_cfi_advance_working=no
2451 fi
2452 GCC_TARGET_TEMPLATE(HAVE_GAS_CFI_DIRECTIVE)
2453 AC_DEFINE_UNQUOTED(HAVE_GAS_CFI_DIRECTIVE,
2454   [`if test $gcc_cv_as_cfi_directive = yes \
2455        && test $gcc_cv_as_cfi_advance_working = yes; then echo 1; else echo 0; fi`],
2456   [Define 0/1 if your assembler supports CFI directives.])
2457
2458 GCC_TARGET_TEMPLATE(HAVE_GAS_CFI_PERSONALITY_DIRECTIVE)
2459 gcc_GAS_CHECK_FEATURE([cfi personality directive],
2460   gcc_cv_as_cfi_personality_directive, ,,
2461 [       .text
2462         .cfi_startproc
2463         .cfi_personality 0, symbol
2464         .cfi_endproc])
2465 AC_DEFINE_UNQUOTED(HAVE_GAS_CFI_PERSONALITY_DIRECTIVE,
2466   [`if test $gcc_cv_as_cfi_personality_directive = yes;
2467     then echo 1; else echo 0; fi`],
2468   [Define 0/1 if your assembler supports .cfi_personality.])
2469
2470 gcc_GAS_CHECK_FEATURE([cfi sections directive],
2471   gcc_cv_as_cfi_sections_directive, ,,
2472 [       .text
2473         .cfi_sections .debug_frame, .eh_frame
2474         .cfi_startproc
2475         .cfi_endproc],
2476 [case $target_os in
2477   win32 | pe | cygwin* | mingw32* | uwin*)
2478     # Need to check that we generated the correct relocation for the
2479     # .debug_frame section.  This was fixed for binutils 2.21.
2480     gcc_cv_as_cfi_sections_directive=no
2481     if test "x$gcc_cv_objdump" != x; then
2482      if $gcc_cv_objdump -j .debug_frame -r conftest.o 2>/dev/null | \
2483         grep secrel > /dev/null; then
2484       gcc_cv_as_cfi_sections_directive=yes
2485      fi
2486     fi
2487     ;;
2488   *)
2489     gcc_cv_as_cfi_sections_directive=yes
2490     ;;
2491 esac])
2492 GCC_TARGET_TEMPLATE(HAVE_GAS_CFI_SECTIONS_DIRECTIVE)
2493 AC_DEFINE_UNQUOTED(HAVE_GAS_CFI_SECTIONS_DIRECTIVE,
2494   [`if test $gcc_cv_as_cfi_sections_directive = yes;
2495     then echo 1; else echo 0; fi`],
2496   [Define 0/1 if your assembler supports .cfi_sections.])
2497
2498 # GAS versions up to and including 2.11.0 may mis-optimize
2499 # .eh_frame data.
2500 gcc_GAS_CHECK_FEATURE(eh_frame optimization, gcc_cv_as_eh_frame,
2501   [elf,2,12,0],,
2502 [       .text
2503 .LFB1:
2504         .4byte  0
2505 .L1:
2506         .4byte  0
2507 .LFE1:
2508         .section        .eh_frame,"aw",@progbits
2509 __FRAME_BEGIN__:
2510         .4byte  .LECIE1-.LSCIE1
2511 .LSCIE1:
2512         .4byte  0x0
2513         .byte   0x1
2514         .ascii "z\0"
2515         .byte   0x1
2516         .byte   0x78
2517         .byte   0x1a
2518         .byte   0x0
2519         .byte   0x4
2520         .4byte  1
2521         .p2align 1
2522 .LECIE1:
2523 .LSFDE1:
2524         .4byte  .LEFDE1-.LASFDE1
2525 .LASFDE1:
2526         .4byte  .LASFDE1-__FRAME_BEGIN__
2527         .4byte  .LFB1
2528         .4byte  .LFE1-.LFB1
2529         .byte   0x4
2530         .4byte  .LFE1-.LFB1
2531         .byte   0x4
2532         .4byte  .L1-.LFB1
2533 .LEFDE1:],
2534 [  dnl # For autoconf 2.5x, must protect trailing spaces with @&t@.
2535 cat > conftest.lit <<EOF
2536  0000 10000000 00000000 017a0001 781a0004  .........z..x...
2537  0010 01000000 12000000 18000000 00000000  ................
2538  0020 08000000 04080000 0044               .........D      @&t@
2539 EOF
2540 cat > conftest.big <<EOF
2541  0000 00000010 00000000 017a0001 781a0004  .........z..x...
2542  0010 00000001 00000012 00000018 00000000  ................
2543  0020 00000008 04000000 0844               .........D      @&t@
2544 EOF
2545   # If the assembler didn't choke, and we can objdump,
2546   # and we got the correct data, then succeed.
2547   # The text in the here-document typically retains its unix-style line
2548   # endings, while the output of objdump will use host line endings.
2549   # Therefore, use diff -b for the comparisons.
2550   if test x$gcc_cv_objdump != x \
2551   && $gcc_cv_objdump -s -j .eh_frame conftest.o 2>/dev/null \
2552      | tail -3 > conftest.got \
2553   && { diff -b conftest.lit conftest.got > /dev/null 2>&1 \
2554     || diff -b conftest.big conftest.got > /dev/null 2>&1; }
2555   then
2556     gcc_cv_as_eh_frame=yes
2557   elif AC_TRY_COMMAND($gcc_cv_as -o conftest.o --traditional-format /dev/null); then
2558     gcc_cv_as_eh_frame=buggy
2559   else
2560     # Uh oh, what do we do now?
2561     gcc_cv_as_eh_frame=no
2562   fi])
2563
2564 if test $gcc_cv_as_eh_frame = buggy; then
2565   AC_DEFINE(USE_AS_TRADITIONAL_FORMAT, 1,
2566   [Define if your assembler mis-optimizes .eh_frame data.])
2567 fi
2568
2569 gcc_GAS_CHECK_FEATURE(section merging support, gcc_cv_as_shf_merge,
2570  [elf,2,12,0], [--fatal-warnings],
2571  [.section .rodata.str, "aMS", @progbits, 1])
2572 if test $gcc_cv_as_shf_merge = no; then
2573   gcc_GAS_CHECK_FEATURE(section merging support, gcc_cv_as_shf_merge,
2574     [elf,2,12,0], [--fatal-warnings],
2575     [.section .rodata.str, "aMS", %progbits, 1])
2576 fi
2577 AC_DEFINE_UNQUOTED(HAVE_GAS_SHF_MERGE,
2578   [`if test $gcc_cv_as_shf_merge = yes; then echo 1; else echo 0; fi`],
2579 [Define 0/1 if your assembler supports marking sections with SHF_MERGE flag.])
2580
2581 gcc_GAS_CHECK_FEATURE(COMDAT group support, gcc_cv_as_comdat_group,
2582  [elf,2,16,0], [--fatal-warnings],
2583  [.section .text,"axG",@progbits,.foo,comdat])
2584 if test $gcc_cv_as_comdat_group = yes; then
2585   gcc_cv_as_comdat_group_percent=no
2586 else
2587  gcc_GAS_CHECK_FEATURE(COMDAT group support, gcc_cv_as_comdat_group_percent,
2588    [elf,2,16,0], [--fatal-warnings],
2589    [.section .text,"axG",%progbits,.foo,comdat])
2590 fi
2591 if test x"$ld_is_gold" = xyes; then
2592   comdat_group=yes
2593 elif test $in_tree_ld = yes ; then
2594   comdat_group=no
2595   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2 \
2596      && test $in_tree_ld_is_elf = yes; then
2597      comdat_group=yes
2598   fi
2599 elif echo "$ld_ver" | grep GNU > /dev/null; then
2600   comdat_group=yes
2601   if test 0"$ld_date" -lt 20050308; then
2602     if test -n "$ld_date"; then
2603       # If there was date string, but was earlier than 2005-03-08, fail
2604       comdat_group=no
2605     elif test "$ld_vers_major" -lt 2; then
2606       comdat_group=no
2607     elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -lt 16; then
2608       comdat_group=no
2609     fi
2610   fi
2611 else
2612 changequote(,)dnl
2613   case "${target}" in
2614     *-*-solaris2.1[1-9]*)
2615       # Sun ld has COMDAT group support since Solaris 9, but it doesn't
2616       # interoperate with GNU as until Solaris 11 build 130, i.e. ld
2617       # version 1.688.
2618       #
2619       # FIXME: Maybe need to refine later when COMDAT group support with
2620       # Sun as is implemented.
2621       if test "$ld_vers_major" -gt 1 || test "$ld_vers_minor" -ge 1688; then
2622         comdat_group=yes
2623       else
2624         comdat_group=no
2625       fi
2626       ;;
2627     *)
2628       # Assume linkers other than GNU ld don't support COMDAT group.
2629       comdat_group=no
2630       ;;
2631   esac
2632 changequote([,])dnl
2633 fi
2634 # Allow overriding the automatic COMDAT group tests above.
2635 AC_ARG_ENABLE(comdat,
2636   [AS_HELP_STRING([--enable-comdat], [enable COMDAT group support])],
2637   [comdat_group="$enable_comdat"])
2638 if test $comdat_group = no; then
2639   gcc_cv_as_comdat_group=no
2640   gcc_cv_as_comdat_group_percent=no
2641 fi
2642 AC_DEFINE_UNQUOTED(HAVE_COMDAT_GROUP,
2643   [`if test $gcc_cv_as_comdat_group = yes || test $gcc_cv_as_comdat_group_percent = yes; then echo 1; else echo 0; fi`],
2644 [Define 0/1 if your assembler and linker support COMDAT groups.])
2645
2646 gcc_GAS_CHECK_FEATURE([line table discriminator support],
2647  gcc_cv_as_discriminator,
2648  [2,19,51],,
2649 [       .text
2650         .file 1 "conf.c"
2651         .loc 1 1 0 discriminator 1],,
2652 [AC_DEFINE(HAVE_GAS_DISCRIMINATOR, 1,
2653   [Define if your assembler supports the .loc discriminator sub-directive.])])
2654
2655 # Thread-local storage - the check is heavily parameterized.
2656 conftest_s=
2657 tls_first_major=
2658 tls_first_minor=
2659 tls_as_opt=
2660 case "$target" in
2661 changequote(,)dnl
2662   alpha*-*-*)
2663     conftest_s='
2664         .section ".tdata","awT",@progbits
2665 foo:    .long   25
2666         .text
2667         ldq     $27,__tls_get_addr($29)         !literal!1
2668         lda     $16,foo($29)                    !tlsgd!1
2669         jsr     $26,($27),__tls_get_addr        !lituse_tlsgd!1
2670         ldq     $27,__tls_get_addr($29)         !literal!2
2671         lda     $16,foo($29)                    !tlsldm!2
2672         jsr     $26,($27),__tls_get_addr        !lituse_tlsldm!2
2673         ldq     $1,foo($29)                     !gotdtprel
2674         ldah    $2,foo($29)                     !dtprelhi
2675         lda     $3,foo($2)                      !dtprello
2676         lda     $4,foo($29)                     !dtprel
2677         ldq     $1,foo($29)                     !gottprel
2678         ldah    $2,foo($29)                     !tprelhi
2679         lda     $3,foo($2)                      !tprello
2680         lda     $4,foo($29)                     !tprel'
2681         tls_first_major=2
2682         tls_first_minor=13
2683         tls_as_opt=--fatal-warnings
2684         ;;
2685   cris-*-*|crisv32-*-*)
2686     conftest_s='
2687         .section ".tdata","awT",@progbits
2688 x:      .long   25
2689         .text
2690         move.d x:IE,$r10
2691         nop'
2692         tls_first_major=2
2693         tls_first_minor=20
2694         tls_as_opt=--fatal-warnings
2695         ;;
2696   frv*-*-*)
2697     conftest_s='
2698         .section ".tdata","awT",@progbits
2699 x:      .long   25
2700         .text
2701         call    #gettlsoff(x)'
2702         tls_first_major=2
2703         tls_first_minor=14
2704         ;;
2705   hppa*-*-linux*)
2706     conftest_s='
2707 t1:     .reg    %r20
2708 t2:     .reg    %r21
2709 gp:     .reg    %r19
2710         .section ".tdata","awT",@progbits
2711 foo:    .long   25
2712         .text
2713         .align  4
2714         addil LT%foo-$tls_gdidx$,gp
2715         ldo RT%foo-$tls_gdidx$(%r1),%arg0
2716         b __tls_get_addr
2717         nop
2718         addil LT%foo-$tls_ldidx$,gp
2719         b __tls_get_addr
2720         ldo RT%foo-$tls_ldidx$(%r1),%arg0
2721         addil LR%foo-$tls_dtpoff$,%ret0
2722         ldo RR%foo-$tls_dtpoff$(%r1),%t1
2723         mfctl %cr27,%t1
2724         addil LT%foo-$tls_ieoff$,gp
2725         ldw RT%foo-$tls_ieoff$(%r1),%t2
2726         add %t1,%t2,%t3
2727         mfctl %cr27,%t1
2728         addil LR%foo-$tls_leoff$,%t1
2729         ldo RR%foo-$tls_leoff$(%r1),%t2'
2730         tls_first_major=2
2731         tls_first_minor=15
2732         tls_as_opt=--fatal-warnings
2733         ;;
2734   arm*-*-*)
2735     conftest_s='
2736         .section ".tdata","awT",%progbits
2737 foo:    .long   25
2738         .text
2739 .word foo(gottpoff)
2740 .word foo(tpoff)
2741 .word foo(tlsgd)
2742 .word foo(tlsldm)
2743 .word foo(tlsldo)'
2744         tls_first_major=2
2745         tls_first_minor=17
2746         ;;
2747   i[34567]86-*-*)
2748     case "$target" in
2749       i[34567]86-*-solaris2.*)
2750         on_solaris=yes
2751         tga_func=___tls_get_addr
2752         ;;
2753       *)
2754         on_solaris=no
2755         ;;
2756     esac
2757     if test x$on_solaris = xyes && test x$gas_flag = xno; then
2758       conftest_s='
2759         .section .tdata,"awt",@progbits'
2760       tls_first_major=0
2761       tls_first_minor=0
2762 changequote([,])dnl
2763       AC_DEFINE(TLS_SECTION_ASM_FLAG, 't',
2764 [Define to the flag used to mark TLS sections if the default (`T') doesn't work.])
2765 changequote(,)dnl
2766     else
2767       conftest_s='
2768         .section ".tdata","awT",@progbits'
2769       tls_first_major=2
2770       tls_first_minor=14
2771       tls_as_opt="--fatal-warnings"
2772     fi
2773     conftest_s="$conftest_s
2774 foo:    .long   25
2775         .text
2776         movl    %gs:0, %eax
2777         leal    foo@tlsgd(,%ebx,1), %eax
2778         leal    foo@tlsldm(%ebx), %eax
2779         leal    foo@dtpoff(%eax), %edx
2780         movl    foo@gottpoff(%ebx), %eax
2781         subl    foo@gottpoff(%ebx), %eax
2782         addl    foo@gotntpoff(%ebx), %eax
2783         movl    foo@indntpoff, %eax
2784         movl    \$foo@tpoff, %eax
2785         subl    \$foo@tpoff, %eax
2786         leal    foo@ntpoff(%ecx), %eax"
2787     ;;
2788   x86_64-*-*)
2789     conftest_s='
2790         .section ".tdata","awT",@progbits
2791 foo:    .long   25
2792         .text
2793         movq    %fs:0, %rax
2794         leaq    foo@TLSGD(%rip), %rdi
2795         leaq    foo@TLSLD(%rip), %rdi
2796         leaq    foo@DTPOFF(%rax), %rdx
2797         movq    foo@GOTTPOFF(%rip), %rax
2798         movq    $foo@TPOFF, %rax'
2799         tls_first_major=2
2800         tls_first_minor=14
2801         tls_as_opt=--fatal-warnings
2802         ;;
2803   ia64-*-*)
2804     conftest_s='
2805         .section ".tdata","awT",@progbits
2806 foo:    data8   25
2807         .text
2808         addl    r16 = @ltoff(@dtpmod(foo#)), gp
2809         addl    r17 = @ltoff(@dtprel(foo#)), gp
2810         addl    r18 = @ltoff(@tprel(foo#)), gp
2811         addl    r19 = @dtprel(foo#), gp
2812         adds    r21 = @dtprel(foo#), r13
2813         movl    r23 = @dtprel(foo#)
2814         addl    r20 = @tprel(foo#), gp
2815         adds    r22 = @tprel(foo#), r13
2816         movl    r24 = @tprel(foo#)'
2817         tls_first_major=2
2818         tls_first_minor=13
2819         tls_as_opt=--fatal-warnings
2820         ;;
2821   mips*-*-*)
2822     conftest_s='
2823         .section .tdata,"awT",@progbits
2824 x:
2825         .word 2
2826         .text
2827         addiu $4, $28, %tlsgd(x)
2828         addiu $4, $28, %tlsldm(x)
2829         lui $4, %dtprel_hi(x)
2830         addiu $4, $4, %dtprel_lo(x)
2831         lw $4, %gottprel(x)($28)
2832         lui $4, %tprel_hi(x)
2833         addiu $4, $4, %tprel_lo(x)'
2834         tls_first_major=2
2835         tls_first_minor=16
2836         tls_as_opt='-32 --fatal-warnings'
2837         ;;
2838   m68k-*-*)
2839     conftest_s='
2840         .section .tdata,"awT",@progbits
2841 x:
2842         .word 2
2843         .text
2844 foo:
2845         move.l x@TLSGD(%a5),%a0
2846         move.l x@TLSLDM(%a5),%a0
2847         move.l x@TLSLDO(%a5),%a0
2848         move.l x@TLSIE(%a5),%a0
2849         move.l x@TLSLE(%a5),%a0'
2850         tls_first_major=2
2851         tls_first_minor=19
2852         tls_as_opt='--fatal-warnings'
2853         ;;
2854   powerpc-*-*)
2855     conftest_s='
2856         .section ".tdata","awT",@progbits
2857         .align 2
2858 ld0:    .space 4
2859 ld1:    .space 4
2860 x1:     .space 4
2861 x2:     .space 4
2862 x3:     .space 4
2863         .text
2864         addi 3,31,ld0@got@tlsgd
2865         bl __tls_get_addr
2866         addi 3,31,x1@got@tlsld
2867         bl __tls_get_addr
2868         addi 9,3,x1@dtprel
2869         addis 9,3,x2@dtprel@ha
2870         addi 9,9,x2@dtprel@l
2871         lwz 9,x3@got@tprel(31)
2872         add 9,9,x@tls
2873         addi 9,2,x1@tprel
2874         addis 9,2,x2@tprel@ha
2875         addi 9,9,x2@tprel@l'
2876         tls_first_major=2
2877         tls_first_minor=14
2878         tls_as_opt="-a32 --fatal-warnings"
2879         ;;
2880   powerpc64-*-*)
2881     conftest_s='
2882         .section ".tdata","awT",@progbits
2883         .align 3
2884 ld0:    .space 8
2885 ld1:    .space 8
2886 x1:     .space 8
2887 x2:     .space 8
2888 x3:     .space 8
2889         .text
2890         addi 3,2,ld0@got@tlsgd
2891         bl .__tls_get_addr
2892         nop
2893         addi 3,2,ld1@toc
2894         bl .__tls_get_addr
2895         nop
2896         addi 3,2,x1@got@tlsld
2897         bl .__tls_get_addr
2898         nop
2899         addi 9,3,x1@dtprel
2900         bl .__tls_get_addr
2901         nop
2902         addis 9,3,x2@dtprel@ha
2903         addi 9,9,x2@dtprel@l
2904         bl .__tls_get_addr
2905         nop
2906         ld 9,x3@got@dtprel(2)
2907         add 9,9,3
2908         bl .__tls_get_addr
2909         nop'
2910         tls_first_major=2
2911         tls_first_minor=14
2912         tls_as_opt="-a64 --fatal-warnings"
2913         ;;
2914   s390-*-*)
2915     conftest_s='
2916         .section ".tdata","awT",@progbits
2917 foo:    .long   25
2918         .text
2919         .long   foo@TLSGD
2920         .long   foo@TLSLDM
2921         .long   foo@DTPOFF
2922         .long   foo@NTPOFF
2923         .long   foo@GOTNTPOFF
2924         .long   foo@INDNTPOFF
2925         l       %r1,foo@GOTNTPOFF(%r12)
2926         l       %r1,0(%r1):tls_load:foo
2927         bas     %r14,0(%r1,%r13):tls_gdcall:foo
2928         bas     %r14,0(%r1,%r13):tls_ldcall:foo'
2929         tls_first_major=2
2930         tls_first_minor=14
2931         tls_as_opt="-m31 --fatal-warnings"
2932         ;;
2933   s390x-*-*)
2934     conftest_s='
2935         .section ".tdata","awT",@progbits
2936 foo:    .long   25
2937         .text
2938         .quad   foo@TLSGD
2939         .quad   foo@TLSLDM
2940         .quad   foo@DTPOFF
2941         .quad   foo@NTPOFF
2942         .quad   foo@GOTNTPOFF
2943         lg      %r1,foo@GOTNTPOFF(%r12)
2944         larl    %r1,foo@INDNTPOFF
2945         brasl   %r14,__tls_get_offset@PLT:tls_gdcall:foo
2946         brasl   %r14,__tls_get_offset@PLT:tls_ldcall:foo'
2947         tls_first_major=2
2948         tls_first_minor=14
2949         tls_as_opt="-m64 -Aesame --fatal-warnings"
2950         ;;
2951   sh-*-* | sh[34]-*-*)
2952     conftest_s='
2953         .section ".tdata","awT",@progbits
2954 foo:    .long   25
2955         .text
2956         .long   foo@TLSGD
2957         .long   foo@TLSLDM
2958         .long   foo@DTPOFF
2959         .long   foo@GOTTPOFF
2960         .long   foo@TPOFF'
2961         tls_first_major=2
2962         tls_first_minor=13
2963         tls_as_opt=--fatal-warnings
2964         ;;
2965   sparc*-*-*)
2966     case "$target" in
2967       sparc*-sun-solaris2.*)
2968         on_solaris=yes
2969         tga_func=__tls_get_addr
2970         ;;
2971       *)
2972         on_solaris=no
2973         ;;
2974     esac
2975     if test x$on_solaris = xyes && test x$gas_flag = xno; then
2976       conftest_s='
2977         .section ".tdata",#alloc,#write,#tls'
2978         tls_first_major=0
2979         tls_first_minor=0
2980     else
2981       conftest_s='
2982         .section ".tdata","awT",@progbits'
2983         tls_first_major=2
2984         tls_first_minor=14
2985         tls_as_opt="-32 --fatal-warnings"
2986     fi
2987     conftest_s="$conftest_s
2988 foo:    .long   25
2989         .text
2990         sethi   %tgd_hi22(foo), %o0
2991         add     %o0, %tgd_lo10(foo), %o1
2992         add     %l7, %o1, %o0, %tgd_add(foo)
2993         call    __tls_get_addr, %tgd_call(foo)
2994         sethi   %tldm_hi22(foo), %l1
2995         add     %l1, %tldm_lo10(foo), %l2
2996         add     %l7, %l2, %o0, %tldm_add(foo)
2997         call    __tls_get_addr, %tldm_call(foo)
2998         sethi   %tldo_hix22(foo), %l3
2999         xor     %l3, %tldo_lox10(foo), %l4
3000         add     %o0, %l4, %l5, %tldo_add(foo)
3001         sethi   %tie_hi22(foo), %o3
3002         add     %o3, %tie_lo10(foo), %o3
3003         ld      [%l7 + %o3], %o2, %tie_ld(foo)
3004         add     %g7, %o2, %o4, %tie_add(foo)
3005         sethi   %tle_hix22(foo), %l1
3006         xor     %l1, %tle_lox10(foo), %o5
3007         ld      [%g7 + %o5], %o1"
3008         ;;
3009   xtensa*-*-*)
3010     conftest_s='
3011         .section ".tdata","awT",@progbits
3012 foo:    .long   25
3013         .text
3014         movi    a8, foo@TLSFUNC
3015         movi    a10, foo@TLSARG
3016         callx8.tls a8, foo@TLSCALL'
3017         tls_first_major=2
3018         tls_first_minor=19
3019         ;;
3020 changequote([,])dnl
3021 esac
3022 set_have_as_tls=no
3023 if test "x$enable_tls" = xno ; then
3024   : # TLS explicitly disabled.
3025 elif test "x$enable_tls" = xyes ; then
3026   set_have_as_tls=yes # TLS explicitly enabled.
3027 elif test -z "$tls_first_major"; then
3028   : # If we don't have a check, assume no support.
3029 else
3030   gcc_GAS_CHECK_FEATURE(thread-local storage support, gcc_cv_as_tls,
3031   [$tls_first_major,$tls_first_minor,0], [$tls_as_opt], [$conftest_s],,
3032   [set_have_as_tls=yes])
3033 fi
3034 case "$target" in
3035   *-*-irix6*)
3036     # IRIX 6.5 rld and libc.so lack TLS support, so even if gas and gld
3037     # with TLS support are in use, native TLS cannot work.
3038     set_have_as_tls=no
3039     ;;
3040   *-*-osf*)
3041     # Tru64 UNIX loader and libc.so lack TLS support, so even if gas and
3042     # gld with TLS support are in use, native TLS cannot work.
3043     set_have_as_tls=no
3044     ;;
3045   # TLS was introduced in the Solaris 9 FCS release and backported to
3046   # Solaris 8 patches.  Support for GNU-style TLS on x86 was only
3047   # introduced in Solaris 9 4/04, replacing the earlier Sun style that Sun
3048   # ld and GCC don't support any longer.
3049   *-*-solaris2.*)
3050     AC_MSG_CHECKING(linker and ld.so.1 TLS support)
3051     ld_tls_support=no
3052     # Check ld and ld.so.1 TLS support.
3053     if echo "$ld_ver" | grep GNU > /dev/null; then
3054       # Assume all interesting versions of GNU ld have TLS support.
3055       # FIXME: still need ld.so.1 support, i.e. ld version checks below.
3056       ld_tls_support=yes
3057     else
3058       case "$target" in
3059         # Solaris 8/x86 ld has GNU style TLS support since version 1.280.
3060         i?86-*-solaris2.8)
3061           min_tls_ld_vers_minor=280
3062           ;;
3063         # Solaris 8/SPARC ld has TLS support since version 1.272.
3064         sparc*-*-solaris2.8)
3065           min_tls_ld_vers_minor=272
3066           ;;
3067         # Solaris 9/x86 ld has GNU style TLS support since version 1.374.
3068         i?86-*-solaris2.9)
3069           min_tls_ld_vers_minor=374
3070           ;;
3071         # Solaris 9/SPARC and Solaris 10+ ld have TLS support since FCS.
3072         sparc*-*-solaris2.9 | *-*-solaris2.1[[0-9]]*)
3073           min_tls_ld_vers_minor=343
3074           ;;
3075       esac
3076       if test "$ld_vers_major" -gt 1 || \
3077         test "$ld_vers_minor" -ge "$min_tls_ld_vers_minor"; then
3078         ld_tls_support=yes
3079       else
3080         set_have_as_tls=no
3081       fi
3082     fi
3083     AC_MSG_RESULT($ld_tls_support)
3084
3085     save_LIBS="$LIBS"
3086     save_LDFLAGS="$LDFLAGS"
3087     LIBS=
3088     LDFLAGS=
3089
3090     AC_MSG_CHECKING(alternate thread library)
3091     case "$target" in
3092       # TLS support was backported to Solaris 8 patches, but only lives in
3093       # the alternate thread library which became the default in Solaris 9.
3094       # We want to always use that, irrespective of TLS support.
3095       *-*-solaris2.8)
3096         # Take multilib subdir into account.  There's no spec to handle
3097         # this.  The 64 symlink exists since Solaris 8.
3098         lwp_dir=/usr/lib/lwp
3099         lwp_spec="-L$lwp_dir%{m64:/64} -R$lwp_dir%{m64:/64}"
3100         LDFLAGS="-L$lwp_dir -R$lwp_dir"
3101         ;;
3102       *-*-solaris2*)
3103         lwp_dir="none"
3104         lwp_spec=""
3105         ;;
3106     esac
3107     # Always define LIB_THREAD_LDFLAGS_SPEC, even without TLS support.
3108     AC_DEFINE_UNQUOTED(LIB_THREAD_LDFLAGS_SPEC, "$lwp_spec",
3109         [Define to the linker flags to use for -pthread.])
3110     AC_MSG_RESULT($lwp_dir)
3111
3112     AC_MSG_CHECKING(library containing $tga_func)
3113     # Before Solaris 10, __tls_get_addr (SPARC/x64) resp. ___tls_get_addr
3114     # (32-bit x86) only lived in libthread, so check for that.  Keep
3115     # set_have_as_tls if found, disable if not.
3116     AC_SEARCH_LIBS([$tga_func], [thread],, [set_have_as_tls=no])
3117     # Clear LIBS if we cannot support TLS.
3118     if test $set_have_as_tls = no; then
3119       LIBS=
3120     fi
3121     # Always define LIB_TLS_SPEC, even without TLS support.
3122     AC_DEFINE_UNQUOTED(LIB_TLS_SPEC, "$LIBS",
3123         [Define to the library containing __tls_get_addr/___tls_get_addr.])
3124     AC_MSG_RESULT($LIBS)
3125
3126     LIBS="$save_LIBS"
3127     LDFLAGS="$save_LDFLAGS"
3128     ;;
3129 esac
3130 if test $set_have_as_tls = yes ; then
3131   AC_DEFINE(HAVE_AS_TLS, 1,
3132             [Define if your assembler and linker support thread-local storage.])
3133 fi
3134
3135 # Target-specific assembler checks.
3136
3137 AC_MSG_CHECKING(linker -Bstatic/-Bdynamic option)
3138 gcc_cv_ld_static_dynamic=no
3139 gcc_cv_ld_static_option='-Bstatic'
3140 gcc_cv_ld_dynamic_option='-Bdynamic'
3141 if test $in_tree_ld = yes ; then
3142   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 10 -o "$gcc_cv_gld_major_version" -gt 2; then
3143     gcc_cv_ld_static_dynamic=yes
3144   fi
3145 elif test x$gcc_cv_ld != x; then
3146   # Check if linker supports -Bstatic/-Bdynamic option
3147   if $gcc_cv_ld --help 2>/dev/null | grep -- -Bstatic > /dev/null \
3148      && $gcc_cv_ld --help 2>/dev/null | grep -- -Bdynamic > /dev/null; then
3149       gcc_cv_ld_static_dynamic=yes
3150   else
3151     case "$target" in
3152       # Tru64 UNIX support -noso/-so_archive instead of -Bstatic/-Bdynamic.
3153       alpha*-dec-osf*)
3154         gcc_cv_ld_static_dynamic=yes
3155         gcc_cv_ld_static_option="-noso"
3156         gcc_cv_ld_dynamic_option="-so_archive"
3157         ;;
3158       # IRIX 6 ld supports -Bstatic/-Bdynamic.
3159       mips-sgi-irix6*)
3160         gcc_cv_ld_static_dynamic=yes
3161         ;;
3162       # Solaris 2 ld always supports -Bstatic/-Bdynamic.
3163       *-*-solaris2*)
3164         gcc_cv_ld_static_dynamic=yes
3165         ;;
3166     esac
3167   fi
3168 fi
3169 if test x"$gcc_cv_ld_static_dynamic" = xyes; then
3170         AC_DEFINE(HAVE_LD_STATIC_DYNAMIC, 1,
3171 [Define if your linker supports -Bstatic/-Bdynamic or equivalent options.])
3172         AC_DEFINE_UNQUOTED(LD_STATIC_OPTION, "$gcc_cv_ld_static_option",
3173 [Define to the linker option to disable use of shared objects.])
3174         AC_DEFINE_UNQUOTED(LD_DYNAMIC_OPTION, "$gcc_cv_ld_dynamic_option",
3175 [Define to the linker option to enable use of shared objects.])
3176 fi
3177 AC_MSG_RESULT($gcc_cv_ld_static_dynamic)
3178
3179 if test x"$demangler_in_ld" = xyes; then
3180   AC_MSG_CHECKING(linker --demangle support)
3181   gcc_cv_ld_demangle=no
3182   if test $in_tree_ld = yes; then
3183     if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 14 -o "$gcc_cv_gld_major_version" -gt 2; then \
3184       gcc_cv_ld_demangle=yes
3185     fi
3186   elif test x$gcc_cv_ld != x -a x"$gnu_ld" = xyes; then
3187     # Check if the GNU linker supports --demangle option
3188     if $gcc_cv_ld --help 2>/dev/null | grep no-demangle > /dev/null; then
3189       gcc_cv_ld_demangle=yes
3190     fi
3191   fi
3192   if test x"$gcc_cv_ld_demangle" = xyes; then
3193     AC_DEFINE(HAVE_LD_DEMANGLE, 1,
3194 [Define if your linker supports --demangle option.])
3195   fi
3196   AC_MSG_RESULT($gcc_cv_ld_demangle)
3197 fi
3198
3199 AC_MSG_CHECKING(linker plugin support)
3200 gcc_cv_lto_plugin=0
3201 if test -f liblto_plugin.la; then
3202   if test $in_tree_ld = yes -a x"$ORIGINAL_PLUGIN_LD_FOR_TARGET" = x"$gcc_cv_ld"; then
3203     if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 21 -o "$gcc_cv_gld_major_version" -gt 2; then
3204       gcc_cv_lto_plugin=2
3205     elif test "$ld_is_gold" = yes -a "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -eq 20; then
3206       gcc_cv_lto_plugin=1
3207
3208     fi
3209   elif test x"$ORIGINAL_PLUGIN_LD_FOR_TARGET" = x"$gcc_cv_ld" && echo "$ld_ver" | grep GNU > /dev/null; then
3210     # Require GNU ld or gold 2.21+ for plugin support by default.
3211     if test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -ge 21; then
3212       gcc_cv_lto_plugin=2
3213     # Allow -fuse-linker-plugin to enable plugin support in GNU gold 2.20.
3214     elif test "$ld_is_gold" = yes -a "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -eq 20; then
3215       gcc_cv_lto_plugin=1
3216     fi
3217   elif test x"$ORIGINAL_PLUGIN_LD_FOR_TARGET" != x"$gcc_cv_ld"; then
3218     # Allow -fuse-linker-plugin if plugin linker differs from
3219     # default/specified linker.
3220     gcc_cv_lto_plugin=1
3221   fi
3222 fi
3223 AC_DEFINE_UNQUOTED(HAVE_LTO_PLUGIN, $gcc_cv_lto_plugin,
3224   [Define to the level of your linker's plugin support.])
3225 AC_MSG_RESULT($gcc_cv_lto_plugin)
3226
3227 case "$target" in
3228   # All TARGET_ABI_OSF targets.
3229   alpha*-*-osf* | alpha*-*-linux* | alpha*-*-*bsd*)
3230     gcc_GAS_CHECK_FEATURE([explicit relocation support],
3231         gcc_cv_as_alpha_explicit_relocs, [2,12,0],,
3232 [       .set nomacro
3233         .text
3234         extbl   $3, $2, $3      !lituse_bytoff!1
3235         ldq     $2, a($29)      !literal!1
3236         ldq     $4, b($29)      !literal!2
3237         ldq_u   $3, 0($2)       !lituse_base!1
3238         ldq     $27, f($29)     !literal!5
3239         jsr     $26, ($27), f   !lituse_jsr!5
3240         ldah    $29, 0($26)     !gpdisp!3
3241         lda     $0, c($29)      !gprel
3242         ldah    $1, d($29)      !gprelhigh
3243         lda     $1, d($1)       !gprellow
3244         lda     $29, 0($29)     !gpdisp!3],,
3245     [AC_DEFINE(HAVE_AS_EXPLICIT_RELOCS, 1,
3246   [Define if your assembler supports explicit relocations.])])
3247     gcc_GAS_CHECK_FEATURE([jsrdirect relocation support],
3248         gcc_cv_as_alpha_jsrdirect_relocs, [2,16,90],,
3249 [       .set nomacro
3250         .text
3251         ldq     $27, a($29)     !literal!1
3252         jsr     $26, ($27), a   !lituse_jsrdirect!1],,
3253     [AC_DEFINE(HAVE_AS_JSRDIRECT_RELOCS, 1,
3254   [Define if your assembler supports the lituse_jsrdirect relocation.])])
3255     ;;
3256
3257   cris-*-*)
3258     gcc_GAS_CHECK_FEATURE([-no-mul-bug-abort option],
3259       gcc_cv_as_cris_no_mul_bug,[2,15,91],
3260       [-no-mul-bug-abort], [.text],,
3261       [AC_DEFINE(HAVE_AS_NO_MUL_BUG_ABORT_OPTION, 1,
3262                 [Define if your assembler supports the -no-mul-bug-abort option.])])
3263     ;;
3264
3265   sparc*-*-*)
3266     gcc_GAS_CHECK_FEATURE([.register], gcc_cv_as_sparc_register_op,,,
3267       [.register %g2, #scratch],,
3268       [AC_DEFINE(HAVE_AS_REGISTER_PSEUDO_OP, 1,
3269                 [Define if your assembler supports .register.])])
3270
3271     gcc_GAS_CHECK_FEATURE([-relax option], gcc_cv_as_sparc_relax,,
3272       [-relax], [.text],,
3273       [AC_DEFINE(HAVE_AS_RELAX_OPTION, 1,
3274                 [Define if your assembler supports -relax option.])])
3275
3276     gcc_GAS_CHECK_FEATURE([GOTDATA_OP relocs],
3277       gcc_cv_as_sparc_gotdata_op,,
3278       [-K PIC],
3279 [.text
3280 .align 4
3281 foo:
3282         nop
3283 bar:
3284         sethi %gdop_hix22(foo), %g1
3285         xor    %g1, %gdop_lox10(foo), %g1
3286         ld    [[%l7 + %g1]], %g2, %gdop(foo)],
3287       [if test x$gcc_cv_ld != x \
3288        && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1; then
3289          if test x$gcc_cv_objdump != x; then
3290            if $gcc_cv_objdump -s -j .text conftest 2> /dev/null \
3291               | grep ' 03000004 82186004 c405c001'> /dev/null 2>&1; then
3292                gcc_cv_as_sparc_gotdata_op=no
3293            else
3294                gcc_cv_as_sparc_gotdata_op=yes
3295            fi
3296          fi
3297        fi
3298        rm -f conftest],
3299       [AC_DEFINE(HAVE_AS_SPARC_GOTDATA_OP, 1,
3300                 [Define if your assembler and linker support GOTDATA_OP relocs.])])
3301
3302     gcc_GAS_CHECK_FEATURE([unaligned pcrel relocs],
3303       gcc_cv_as_sparc_ua_pcrel,,
3304       [-K PIC],
3305 [.text
3306 foo:
3307         nop
3308 .data
3309 .align 4
3310 .byte 0
3311 .uaword %r_disp32(foo)],
3312       [if test x$gcc_cv_ld != x \
3313        && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1; then
3314          gcc_cv_as_sparc_ua_pcrel=yes
3315        fi
3316        rm -f conftest],
3317       [AC_DEFINE(HAVE_AS_SPARC_UA_PCREL, 1,
3318                 [Define if your assembler and linker support unaligned PC relative relocs.])
3319
3320       gcc_GAS_CHECK_FEATURE([unaligned pcrel relocs against hidden symbols],
3321         gcc_cv_as_sparc_ua_pcrel_hidden,,
3322         [-K PIC],
3323 [.data
3324 .align 4
3325 .byte 0x31
3326 .uaword %r_disp32(foo)
3327 .byte 0x32, 0x33, 0x34
3328 .global foo
3329 .hidden foo
3330 foo:
3331 .skip 4],
3332         [if test x$gcc_cv_ld != x && test x$gcc_cv_objdump != x \
3333          && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1 \
3334          && $gcc_cv_objdump -s -j .data conftest 2> /dev/null \
3335             | grep ' 31000000 07323334' > /dev/null 2>&1; then
3336             if $gcc_cv_objdump -R conftest 2> /dev/null \
3337                | grep 'DISP32' > /dev/null 2>&1; then
3338                 :
3339             else
3340                 gcc_cv_as_sparc_ua_pcrel_hidden=yes
3341             fi
3342          fi
3343          rm -f conftest],
3344          [AC_DEFINE(HAVE_AS_SPARC_UA_PCREL_HIDDEN, 1,
3345                    [Define if your assembler and linker support unaligned PC relative relocs against hidden symbols.])])
3346     ]) # unaligned pcrel relocs
3347
3348     gcc_GAS_CHECK_FEATURE([offsetable %lo()],
3349       gcc_cv_as_sparc_offsetable_lo10,,
3350       [-xarch=v9],
3351 [.text
3352         or %g1, %lo(ab) + 12, %g1
3353         or %g1, %lo(ab + 12), %g1],
3354       [if test x$gcc_cv_objdump != x \
3355        && $gcc_cv_objdump -s -j .text conftest.o 2> /dev/null \
3356           | grep ' 82106000 82106000' > /dev/null 2>&1; then
3357          gcc_cv_as_sparc_offsetable_lo10=yes
3358        fi],
3359        [AC_DEFINE(HAVE_AS_OFFSETABLE_LO10, 1,
3360                  [Define if your assembler supports offsetable %lo().])])
3361     ;;
3362
3363 changequote(,)dnl
3364   i[34567]86-*-* | x86_64-*-*)
3365 changequote([,])dnl
3366     case $target_os in
3367       cygwin*)
3368         # Full C++ conformance when using a shared libstdc++-v3 requires some
3369         # support from the Cygwin DLL, which in more recent versions exports
3370         # wrappers to aid in interposing and redirecting operators new, delete,
3371         # etc., as per n2800 #17.6.4.6 [replacement.functions].  Check if we
3372         # are configuring for a version of Cygwin that exports the wrappers.
3373         if test x$host = x$target; then
3374           AC_CHECK_FUNC([__wrap__Znaj],[gcc_ac_cygwin_dll_wrappers=yes],[gcc_ac_cygwin_dll_wrappers=no])
3375         else
3376           # Can't check presence of libc functions during cross-compile, so
3377           # we just have to assume we're building for an up-to-date target.
3378           gcc_ac_cygwin_dll_wrappers=yes
3379         fi
3380         AC_DEFINE_UNQUOTED(USE_CYGWIN_LIBSTDCXX_WRAPPERS,
3381           [`if test $gcc_ac_cygwin_dll_wrappers = yes; then echo 1; else echo 0; fi`],
3382           [Define if you want to generate code by default that assumes that the
3383            Cygwin DLL exports wrappers to support libstdc++ function replacement.])
3384     esac
3385     case $target_os in
3386       cygwin* | pe | mingw32*)
3387         # Recent binutils allows the three-operand form of ".comm" on PE.  This
3388         # definition is used unconditionally to initialise the default state of
3389         # the target option variable that governs usage of the feature.
3390         gcc_GAS_CHECK_FEATURE([.comm with alignment], gcc_cv_as_comm_has_align,
3391          [2,19,52],,[.comm foo,1,32])
3392         AC_DEFINE_UNQUOTED(HAVE_GAS_ALIGNED_COMM,
3393           [`if test $gcc_cv_as_comm_has_align = yes; then echo 1; else echo 0; fi`],
3394           [Define if your assembler supports specifying the alignment
3395            of objects allocated using the GAS .comm command.])
3396         # Used for DWARF 2 in PE
3397         gcc_GAS_CHECK_FEATURE([.secrel32 relocs],
3398           gcc_cv_as_ix86_pe_secrel32,
3399           [2,15,91],,
3400 [.text
3401 foo:    nop
3402 .data
3403         .secrel32 foo],
3404           [if test x$gcc_cv_ld != x \
3405            && $gcc_cv_ld -o conftest conftest.o > /dev/null 2>&1; then
3406              gcc_cv_as_ix86_pe_secrel32=yes
3407            fi
3408            rm -f conftest],
3409           [AC_DEFINE(HAVE_GAS_PE_SECREL32_RELOC, 1,
3410             [Define if your assembler and linker support 32-bit section relative relocs via '.secrel32 label'.])])
3411         # Test if the assembler supports the extended form of the .section
3412         # directive that specifies section alignment.  LTO support uses this,
3413         # but normally only after installation, so we warn but don't fail the
3414         # configure if LTO is enabled but the assembler does not support it.
3415         gcc_GAS_CHECK_FEATURE([.section with alignment], gcc_cv_as_section_has_align,
3416           [2,20,1],-fatal-warnings,[.section lto_test,"dr0"])
3417         if test x$gcc_cv_as_section_has_align != xyes; then
3418           case ",$enable_languages," in
3419             *,lto,*)
3420               AC_MSG_WARN([LTO for $target requires binutils >= 2.20.1, but version found appears insufficient; LTO will not work until binutils is upgraded.])
3421               ;;
3422           esac
3423         fi
3424         ;;
3425     esac
3426
3427     gcc_GAS_CHECK_FEATURE([filds and fists mnemonics],
3428        gcc_cv_as_ix86_filds,,,
3429        [filds mem; fists mem],,
3430        [AC_DEFINE(HAVE_AS_IX86_FILDS, 1,
3431          [Define if your assembler uses filds and fists mnemonics.])])
3432
3433     gcc_GAS_CHECK_FEATURE([fildq and fistpq mnemonics],
3434        gcc_cv_as_ix86_fildq,,,
3435        [fildq mem; fistpq mem],,
3436        [AC_DEFINE(HAVE_AS_IX86_FILDQ, 1,
3437          [Define if your assembler uses fildq and fistq mnemonics.])])
3438
3439     gcc_GAS_CHECK_FEATURE([cmov syntax],
3440       gcc_cv_as_ix86_cmov_sun_syntax,,,
3441       [cmovl.l %edx, %eax],,
3442       [AC_DEFINE(HAVE_AS_IX86_CMOV_SUN_SYNTAX, 1,
3443         [Define if your assembler supports the Sun syntax for cmov.])])
3444
3445     gcc_GAS_CHECK_FEATURE([ffreep mnemonic],
3446       gcc_cv_as_ix86_ffreep,,,
3447       [ffreep %st(1)],,
3448       [AC_DEFINE(HAVE_AS_IX86_FFREEP, 1,
3449         [Define if your assembler supports the ffreep mnemonic.])])
3450
3451     gcc_GAS_CHECK_FEATURE([.quad directive],
3452       gcc_cv_as_ix86_quad,,,
3453       [.quad 0],,
3454       [AC_DEFINE(HAVE_AS_IX86_QUAD, 1,
3455         [Define if your assembler supports the .quad directive.])])
3456
3457     gcc_GAS_CHECK_FEATURE([sahf mnemonic],
3458       gcc_cv_as_ix86_sahf,,,
3459       [.code64
3460        sahf],,
3461       [AC_DEFINE(HAVE_AS_IX86_SAHF, 1,
3462         [Define if your assembler supports the sahf mnemonic in 64bit mode.])])
3463
3464     gcc_GAS_CHECK_FEATURE([swap suffix],
3465       gcc_cv_as_ix86_swap,,,
3466       [movl.s %esp, %ebp],,
3467       [AC_DEFINE(HAVE_AS_IX86_SWAP, 1,
3468         [Define if your assembler supports the swap suffix.])])
3469
3470     gcc_GAS_CHECK_FEATURE([different section symbol subtraction],
3471       gcc_cv_as_ix86_diff_sect_delta,,,
3472       [.section .rodata
3473 .L1:
3474         .long .L2-.L1
3475         .long .L3-.L1
3476         .text
3477 .L3:    nop
3478 .L2:    nop],,
3479       [AC_DEFINE(HAVE_AS_IX86_DIFF_SECT_DELTA, 1,
3480         [Define if your assembler supports the subtraction of symbols in different sections.])])
3481
3482     # These two are used unconditionally by i386.[ch]; it is to be defined
3483     # to 1 if the feature is present, 0 otherwise.
3484     gcc_GAS_CHECK_FEATURE([GOTOFF in data],
3485         gcc_cv_as_ix86_gotoff_in_data, [2,11,0],,
3486 [       .text
3487 .L0:
3488         nop
3489         .data
3490         .long .L0@GOTOFF])
3491     AC_DEFINE_UNQUOTED(HAVE_AS_GOTOFF_IN_DATA,
3492       [`if test $gcc_cv_as_ix86_gotoff_in_data = yes; then echo 1; else echo 0; fi`],
3493       [Define true if the assembler supports '.long foo@GOTOFF'.])
3494
3495     gcc_GAS_CHECK_FEATURE([rep and lock prefix],
3496         gcc_cv_as_ix86_rep_lock_prefix,,,
3497         [rep movsl
3498          lock addl %edi, (%eax,%esi)
3499          lock orl $0, (%esp)],,
3500         [AC_DEFINE(HAVE_AS_IX86_REP_LOCK_PREFIX, 1,
3501           [Define if the assembler supports 'rep <insn>, lock <insn>'.])])
3502
3503     ;;
3504
3505   ia64*-*-*)
3506     gcc_GAS_CHECK_FEATURE([ltoffx and ldxmov relocs],
3507         gcc_cv_as_ia64_ltoffx_ldxmov_relocs, [2,14,0],,
3508 [       .text
3509         addl r15 = @ltoffx(x#), gp
3510         ;;
3511         ld8.mov r16 = [[r15]], x#],,
3512     [AC_DEFINE(HAVE_AS_LTOFFX_LDXMOV_RELOCS, 1,
3513           [Define if your assembler supports ltoffx and ldxmov relocations.])])
3514
3515     ;;
3516
3517   powerpc*-*-*)
3518     case $target in
3519       *-*-aix*) conftest_s='    .machine "pwr5"
3520         .csect .text[[PR]]
3521         mfcr 3,128';;
3522       *-*-darwin*)
3523         gcc_GAS_CHECK_FEATURE([.machine directive support],
3524           gcc_cv_as_machine_directive,,,
3525           [     .machine ppc7400])
3526         if test x$gcc_cv_as_machine_directive != xyes; then
3527           echo "*** This target requires an assembler supporting \".machine\"" >&2
3528           echo you can get it from: ftp://gcc.gnu.org/pub/gcc/infrastructure/cctools-528.5.dmg >&2
3529           test x$build = x$target && exit 1
3530         fi
3531         conftest_s='    .text
3532         mfcr r3,128';;
3533       *) conftest_s='   .machine power4
3534         .text
3535         mfcr 3,128';;
3536     esac
3537
3538     gcc_GAS_CHECK_FEATURE([mfcr field support],
3539       gcc_cv_as_powerpc_mfcrf, [2,14,0],,
3540       [$conftest_s],,
3541       [AC_DEFINE(HAVE_AS_MFCRF, 1,
3542           [Define if your assembler supports mfcr field.])])
3543
3544     case $target in
3545       *-*-aix*) conftest_s='    .machine "pwr5"
3546         .csect .text[[PR]]
3547         popcntb 3,3';;
3548       *) conftest_s='   .machine power5
3549         .text
3550         popcntb 3,3';;
3551     esac
3552
3553     gcc_GAS_CHECK_FEATURE([popcntb support],
3554       gcc_cv_as_powerpc_popcntb, [2,17,0],,
3555       [$conftest_s],,
3556       [AC_DEFINE(HAVE_AS_POPCNTB, 1,
3557           [Define if your assembler supports popcntb field.])])
3558
3559     case $target in
3560       *-*-aix*) conftest_s='    .machine "pwr5x"
3561         .csect .text[[PR]]
3562         frin 1,1';;
3563       *) conftest_s='   .machine power5
3564         .text
3565         frin 1,1';;
3566     esac
3567
3568     gcc_GAS_CHECK_FEATURE([fp round support],
3569       gcc_cv_as_powerpc_fprnd, [2,17,0],,
3570       [$conftest_s],,
3571       [AC_DEFINE(HAVE_AS_FPRND, 1,
3572           [Define if your assembler supports fprnd.])])
3573
3574     case $target in
3575       *-*-aix*) conftest_s='    .machine "pwr6"
3576         .csect .text[[PR]]
3577         mffgpr 1,3';;
3578       *) conftest_s='   .machine power6
3579         .text
3580         mffgpr 1,3';;
3581     esac
3582
3583     gcc_GAS_CHECK_FEATURE([move fp gpr support],
3584       gcc_cv_as_powerpc_mfpgpr, [2,19,2],,
3585       [$conftest_s],,
3586       [AC_DEFINE(HAVE_AS_MFPGPR, 1,
3587           [Define if your assembler supports mffgpr and mftgpr.])])
3588
3589     case $target in
3590       *-*-aix*) conftest_s='    .csect .text[[PR]]
3591 LCF..0:
3592         addis 11,30,_GLOBAL_OFFSET_TABLE_-LCF..0@ha';;
3593       *-*-darwin*)
3594         conftest_s='    .text
3595 LCF0:
3596         addis r11,r30,_GLOBAL_OFFSET_TABLE_-LCF0@ha';;
3597       *) conftest_s='   .text
3598 .LCF0:
3599         addis 11,30,_GLOBAL_OFFSET_TABLE_-.LCF0@ha';;
3600     esac
3601
3602     gcc_GAS_CHECK_FEATURE([rel16 relocs],
3603       gcc_cv_as_powerpc_rel16, [2,17,0], -a32,
3604       [$conftest_s],,
3605       [AC_DEFINE(HAVE_AS_REL16, 1,
3606           [Define if your assembler supports R_PPC_REL16 relocs.])])
3607
3608     case $target in
3609       *-*-aix*) conftest_s='    .machine "pwr6"
3610         .csect .text[[PR]]
3611         cmpb 3,4,5';;
3612       *) conftest_s='   .machine power6
3613         .text
3614         cmpb 3,4,5';;
3615     esac
3616
3617     gcc_GAS_CHECK_FEATURE([compare bytes support],
3618       gcc_cv_as_powerpc_cmpb, [2,19,2], -a32,
3619       [$conftest_s],,
3620       [AC_DEFINE(HAVE_AS_CMPB, 1,
3621           [Define if your assembler supports cmpb.])])
3622
3623     case $target in
3624       *-*-aix*) conftest_s='    .machine "pwr6"
3625         .csect .text[[PR]]
3626         dadd 1,2,3';;
3627       *) conftest_s='   .machine power6
3628         .text
3629         dadd 1,2,3';;
3630     esac
3631
3632     gcc_GAS_CHECK_FEATURE([decimal float support],
3633       gcc_cv_as_powerpc_dfp, [2,19,2], -a32,
3634       [$conftest_s],,
3635       [AC_DEFINE(HAVE_AS_DFP, 1,
3636           [Define if your assembler supports DFP instructions.])])
3637
3638     case $target in
3639       *-*-aix*) conftest_s='    .machine "pwr7"
3640         .csect .text[[PR]]
3641         lxvd2x 1,2,3';;
3642       *) conftest_s='   .machine power7
3643         .text
3644         lxvd2x 1,2,3';;
3645     esac
3646
3647     gcc_GAS_CHECK_FEATURE([vector-scalar support],
3648       gcc_cv_as_powerpc_vsx, [2,19,2], -a32,
3649       [$conftest_s],,
3650       [AC_DEFINE(HAVE_AS_VSX, 1,
3651           [Define if your assembler supports VSX instructions.])])
3652
3653     case $target in
3654       *-*-aix*) conftest_s='    .machine "pwr7"
3655         .csect .text[[PR]]
3656         popcntd 3,3';;
3657       *) conftest_s='   .machine power7
3658         .text
3659         popcntd 3,3';;
3660     esac
3661
3662     gcc_GAS_CHECK_FEATURE([popcntd support],
3663       gcc_cv_as_powerpc_popcntd, [2,19,2], -a32,
3664       [$conftest_s],,
3665       [AC_DEFINE(HAVE_AS_POPCNTD, 1,
3666           [Define if your assembler supports POPCNTD instructions.])])
3667
3668     case $target in
3669       *-*-aix*) conftest_s='    .csect .text[[PR]]
3670         lwsync';;
3671       *) conftest_s='   .text
3672         lwsync';;
3673     esac
3674
3675     gcc_GAS_CHECK_FEATURE([lwsync support],
3676       gcc_cv_as_powerpc_lwsync, [2,19,2], -a32,
3677       [$conftest_s],,
3678       [AC_DEFINE(HAVE_AS_LWSYNC, 1,
3679           [Define if your assembler supports LWSYNC instructions.])])
3680
3681     case $target in
3682       *-*-aix*) conftest_s='    .machine "476"
3683         .csect .text[[PR]]
3684         dci 0';;
3685       *) conftest_s='   .machine "476"
3686         .text
3687         dci 0';;
3688     esac
3689
3690     gcc_GAS_CHECK_FEATURE([data cache invalidate support],
3691       gcc_cv_as_powerpc_dci, [9,99,0], -a32,
3692       [$conftest_s],,
3693       [AC_DEFINE(HAVE_AS_DCI, 1,
3694           [Define if your assembler supports the DCI/ICI instructions.])])
3695
3696     gcc_GAS_CHECK_FEATURE([.gnu_attribute support],
3697       gcc_cv_as_powerpc_gnu_attribute, [2,18,0],,
3698       [.gnu_attribute 4,1],,
3699       [AC_DEFINE(HAVE_AS_GNU_ATTRIBUTE, 1,
3700           [Define if your assembler supports .gnu_attribute.])])
3701
3702     gcc_GAS_CHECK_FEATURE([tls marker support],
3703       gcc_cv_as_powerpc_tls_markers, [2,20,0],,
3704       [ bl __tls_get_addr(x@tlsgd)],,
3705       [AC_DEFINE(HAVE_AS_TLS_MARKERS, 1,
3706           [Define if your assembler supports arg info for __tls_get_addr.])])
3707
3708     case $target in
3709       *-*-aix*)
3710         gcc_GAS_CHECK_FEATURE([.ref support],
3711           gcc_cv_as_aix_ref, [2.21.0],,
3712           [     .csect stuff[[rw]]
3713              stuff:
3714                 .long 1
3715                 .extern sym
3716                 .ref sym
3717           ],,
3718           [AC_DEFINE(HAVE_AS_REF, 1,
3719             [Define if your assembler supports .ref])])
3720         ;;
3721     esac
3722     ;;
3723
3724   mips*-*-*)
3725     gcc_GAS_CHECK_FEATURE([explicit relocation support],
3726       gcc_cv_as_mips_explicit_relocs, [2,14,0],,
3727 [       lw $4,%gp_rel(foo)($4)],,
3728       [if test x$target_cpu_default = x
3729        then target_cpu_default=MASK_EXPLICIT_RELOCS
3730        else target_cpu_default="($target_cpu_default)|MASK_EXPLICIT_RELOCS"
3731        fi])
3732     gcc_GAS_CHECK_FEATURE([-mno-shared support],
3733       gcc_cv_as_mips_no_shared, [2,16,0], [-mno-shared], [nop],,
3734       [AC_DEFINE(HAVE_AS_NO_SHARED, 1,
3735                  [Define if the assembler understands -mno-shared.])])
3736
3737     gcc_GAS_CHECK_FEATURE([.gnu_attribute support],
3738       gcc_cv_as_mips_gnu_attribute, [2,18,0],,
3739       [.gnu_attribute 4,1],,
3740       [AC_DEFINE(HAVE_AS_GNU_ATTRIBUTE, 1,
3741           [Define if your assembler supports .gnu_attribute.])])
3742
3743     gcc_GAS_CHECK_FEATURE([.dtprelword support],
3744       gcc_cv_as_mips_dtprelword, [2,18,0],,
3745       [.section .tdata,"awT",@progbits
3746 x:
3747         .word 2
3748         .text
3749         .dtprelword x+0x8000],,
3750       [AC_DEFINE(HAVE_AS_DTPRELWORD, 1,
3751           [Define if your assembler supports .dtprelword.])])
3752
3753     gcc_GAS_CHECK_FEATURE([DSPR1 mult with four accumulators support],
3754       gcc_cv_as_mips_dspr1_mult,,,
3755 [       .set    mips32r2
3756         .set    nodspr2
3757         .set    dsp
3758         madd    $ac3,$4,$5
3759         maddu   $ac3,$4,$5
3760         msub    $ac3,$4,$5
3761         msubu   $ac3,$4,$5
3762         mult    $ac3,$4,$5
3763         multu   $ac3,$4,$5],,
3764       [AC_DEFINE(HAVE_AS_DSPR1_MULT, 1,
3765           [Define if your assembler supports DSPR1 mult.])])
3766
3767     AC_MSG_CHECKING(assembler and linker for explicit JALR relocation)
3768     gcc_cv_as_ld_jalr_reloc=no
3769     if test $gcc_cv_as_mips_explicit_relocs = yes; then
3770       if test $in_tree_ld = yes ; then
3771         if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 20 -o "$gcc_cv_gld_major_version" -gt 2 \
3772            && test $in_tree_ld_is_elf = yes; then
3773           gcc_cv_as_ld_jalr_reloc=yes
3774         fi
3775       elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x -a x$gcc_cv_objdump != x; then
3776         echo '  .ent x' > conftest.s
3777         echo 'x:        ld $2,%got_disp(y)($3)' >> conftest.s
3778         echo '  ld $25,%call16(y)($28)' >> conftest.s
3779         echo '  .reloc  1f,R_MIPS_JALR,y' >> conftest.s
3780         echo '1:        jalr $25' >> conftest.s
3781         echo '  .reloc  1f,R_MIPS_JALR,x' >> conftest.s
3782         echo '1:        jalr $25' >> conftest.s
3783         echo '  .end x' >> conftest.s
3784         if $gcc_cv_as -o conftest.o conftest.s >/dev/null 2>&AS_MESSAGE_LOG_FD \
3785            && $gcc_cv_ld -shared -o conftest.so conftest.o >/dev/null 2>&AS_MESSAGE_LOG_FD; then
3786           if $gcc_cv_objdump -d conftest.so | grep jalr >/dev/null 2>&1 \
3787              && $gcc_cv_objdump -d conftest.so | grep "bal.*<x>" >/dev/null 2>&1; then
3788             gcc_cv_as_ld_jalr_reloc=yes
3789           fi
3790         fi
3791         rm -f conftest.*
3792       fi
3793     fi
3794     if test $gcc_cv_as_ld_jalr_reloc = yes; then
3795       if test x$target_cpu_default = x; then
3796         target_cpu_default=MASK_RELAX_PIC_CALLS
3797       else
3798         target_cpu_default="($target_cpu_default)|MASK_RELAX_PIC_CALLS"
3799       fi
3800     fi
3801     AC_MSG_RESULT($gcc_cv_as_ld_jalr_reloc)
3802
3803     AC_CACHE_CHECK([linker for .eh_frame personality relaxation],
3804       [gcc_cv_ld_mips_personality_relaxation],
3805       [gcc_cv_ld_mips_personality_relaxation=no
3806        if test $in_tree_ld = yes ; then
3807          if test "$gcc_cv_gld_major_version" -eq 2 \
3808                  -a "$gcc_cv_gld_minor_version" -ge 21 \
3809                  -o "$gcc_cv_gld_major_version" -gt 2; then
3810            gcc_cv_ld_mips_personality_relaxation=yes
3811          fi
3812        elif test x$gcc_cv_as != x \
3813                  -a x$gcc_cv_ld != x \
3814                  -a x$gcc_cv_readelf != x ; then
3815          cat > conftest.s <<EOF
3816         .cfi_startproc
3817         .cfi_personality 0x80,indirect_ptr
3818         .ent test
3819 test:
3820         nop
3821         .end test
3822         .cfi_endproc
3823
3824         .section .data,"aw",@progbits
3825 indirect_ptr:
3826         .dc.a personality
3827 EOF
3828          if $gcc_cv_as -KPIC -o conftest.o conftest.s > /dev/null 2>&1 \
3829             && $gcc_cv_ld -o conftest conftest.o -shared > /dev/null 2>&1; then
3830            if $gcc_cv_readelf -d conftest 2>&1 \
3831               | grep TEXTREL > /dev/null 2>&1; then
3832              :
3833            elif $gcc_cv_readelf --relocs conftest 2>&1 \
3834                 | grep 'R_MIPS_REL32 *$' > /dev/null 2>&1; then
3835              :
3836            else
3837              gcc_cv_ld_mips_personality_relaxation=yes
3838            fi
3839          fi
3840        fi
3841        rm -f conftest.s conftest.o conftest])
3842     if test x$gcc_cv_ld_mips_personality_relaxation = xyes; then
3843             AC_DEFINE(HAVE_LD_PERSONALITY_RELAXATION, 1,
3844       [Define if your linker can relax absolute .eh_frame personality
3845 pointers into PC-relative form.])
3846     fi
3847     ;;
3848 esac
3849
3850 # Mips and HP-UX need the GNU assembler.
3851 # Linux on IA64 might be able to use the Intel assembler.
3852
3853 case "$target" in
3854   mips*-*-* | *-*-hpux* )
3855     if test x$gas_flag = xyes \
3856        || test x"$host" != x"$build" \
3857        || test ! -x "$gcc_cv_as" \
3858        || "$gcc_cv_as" -v < /dev/null 2>&1 | grep GNU > /dev/null; then
3859       :
3860     else
3861       echo "*** This configuration requires the GNU assembler" >&2
3862       exit 1
3863     fi
3864     ;;
3865 esac
3866
3867 # ??? Not all targets support dwarf2 debug_line, even within a version
3868 # of gas.  Moreover, we need to emit a valid instruction to trigger any
3869 # info to the output file.  So, as supported targets are added to gas 2.11,
3870 # add some instruction here to (also) show we expect this might work.
3871 # ??? Once 2.11 is released, probably need to add first known working
3872 # version to the per-target configury.
3873 case "$cpu_type" in
3874   alpha | arm | avr | bfin | cris | i386 | m32c | m68k | microblaze | mips \
3875   | pa | rs6000 | score | sparc | spu | xstormy16 | xtensa)
3876     insn="nop"
3877     ;;
3878   ia64 | s390)
3879     insn="nop 0"
3880     ;;
3881   mmix)
3882     insn="swym 0"
3883     ;;
3884 esac
3885 if test x"$insn" != x; then
3886  conftest_s="\
3887         .file 1 \"conftest.s\"
3888         .loc 1 3 0
3889         $insn"
3890  gcc_GAS_CHECK_FEATURE([dwarf2 debug_line support],
3891   gcc_cv_as_dwarf2_debug_line,
3892   [elf,2,11,0],, [$conftest_s],
3893   [if test x$gcc_cv_objdump != x \
3894    && $gcc_cv_objdump -h conftest.o 2> /dev/null \
3895       | grep debug_line > /dev/null 2>&1; then
3896      gcc_cv_as_dwarf2_debug_line=yes
3897    fi])
3898
3899 # The .debug_line file table must be in the exact order that
3900 # we specified the files, since these indices are also used
3901 # by DW_AT_decl_file.  Approximate this test by testing if
3902 # the assembler bitches if the same index is assigned twice.
3903  gcc_GAS_CHECK_FEATURE([buggy dwarf2 .file directive],
3904   gcc_cv_as_dwarf2_file_buggy,,,
3905 [       .file 1 "foo.s"
3906         .file 1 "bar.s"])
3907
3908  if test $gcc_cv_as_dwarf2_debug_line = yes \
3909  && test $gcc_cv_as_dwarf2_file_buggy = no; then
3910         AC_DEFINE(HAVE_AS_DWARF2_DEBUG_LINE, 1,
3911   [Define if your assembler supports dwarf2 .file/.loc directives,
3912    and preserves file table indices exactly as given.])
3913  fi
3914
3915  gcc_GAS_CHECK_FEATURE([--gdwarf2 option],
3916   gcc_cv_as_gdwarf2_flag,
3917   [elf,2,11,0], [--gdwarf2], [$insn],,
3918   [AC_DEFINE(HAVE_AS_GDWARF2_DEBUG_FLAG, 1,
3919 [Define if your assembler supports the --gdwarf2 option.])])
3920
3921  gcc_GAS_CHECK_FEATURE([--gstabs option],
3922   gcc_cv_as_gstabs_flag,
3923   [elf,2,11,0], [--gstabs], [$insn],
3924   [# The native Solaris 9/Intel assembler doesn't understand --gstabs
3925    # and warns about it, but still exits successfully.  So check for
3926    # this.
3927    if AC_TRY_COMMAND([$gcc_cv_as --gstabs -o conftest.o conftest.s 2>&1 | grep -i warning > /dev/null])
3928    then :
3929    else gcc_cv_as_gstabs_flag=yes
3930    fi],
3931   [AC_DEFINE(HAVE_AS_GSTABS_DEBUG_FLAG, 1,
3932 [Define if your assembler supports the --gstabs option.])])
3933
3934  gcc_GAS_CHECK_FEATURE([--debug-prefix-map option],
3935   gcc_cv_as_debug_prefix_map_flag,
3936   [2,18,0], [--debug-prefix-map /a=/b], [$insn],,
3937   [AC_DEFINE(HAVE_AS_DEBUG_PREFIX_MAP, 1,
3938 [Define if your assembler supports the --debug-prefix-map option.])])
3939 fi
3940
3941 gcc_GAS_CHECK_FEATURE([.lcomm with alignment], gcc_cv_as_lcomm_with_alignment,
3942  ,,
3943 [.lcomm bar,4,16],,
3944 [AC_DEFINE(HAVE_GAS_LCOMM_WITH_ALIGNMENT, 1,
3945   [Define if your assembler supports .lcomm with an alignment field.])])
3946
3947 AC_ARG_ENABLE(gnu-unique-object,
3948  [AS_HELP_STRING([--enable-gnu-unique-object],
3949    [enable the use of the @gnu_unique_object ELF extension on glibc systems])],
3950  [case $enable_gnu_unique_object in
3951     yes | no) ;;
3952     *) AC_MSG_ERROR(['$enable_gnu_unique_object' is an invalid value for --enable-gnu-unique-object.
3953 Valid choices are 'yes' and 'no'.]) ;;
3954   esac],
3955  [gcc_GAS_CHECK_FEATURE([gnu_unique_object], gcc_cv_as_gnu_unique_object,
3956    [elf,2,19,52],,
3957    [.type foo, @gnu_unique_object],,
3958 # Also check for ld.so support, i.e. glibc 2.11 or higher.
3959    [[if test x$host = x$build -a x$host = x$target &&
3960        ldd --version 2>/dev/null &&
3961        glibcver=`ldd --version 2>/dev/null | sed 's/.* //;q'`; then
3962       glibcmajor=`expr "$glibcver" : "\([0-9]*\)"`
3963       glibcminor=`expr "$glibcver" : "[2-9]*\.\([0-9]*\)"`
3964       glibcnum=`expr $glibcmajor \* 1000 + $glibcminor`
3965       if test "$glibcnum" -ge 2011 ; then
3966         enable_gnu_unique_object=yes
3967       fi
3968     fi]])])
3969 if test x$enable_gnu_unique_object = xyes; then
3970   AC_DEFINE(HAVE_GAS_GNU_UNIQUE_OBJECT, 1,
3971    [Define if your assembler supports @gnu_unique_object.])
3972 fi
3973
3974 AC_CACHE_CHECK([assembler for tolerance to line number 0],
3975  [gcc_cv_as_line_zero],
3976  [gcc_cv_as_line_zero=no
3977   if test $in_tree_gas = yes; then
3978     gcc_GAS_VERSION_GTE_IFELSE(2, 16, 91, [gcc_cv_as_line_zero=yes])
3979   elif test "x$gcc_cv_as" != x; then
3980     { echo '# 1 "test.s" 1'; echo '# 0 "" 2'; } > conftest.s
3981     if AC_TRY_COMMAND([$gcc_cv_as -o conftest.o conftest.s >&AS_MESSAGE_LOG_FD 2>conftest.out]) &&
3982        test "x`cat conftest.out`" = x
3983     then
3984       gcc_cv_as_line_zero=yes
3985     else
3986       echo "configure: failed program was" >&AS_MESSAGE_LOG_FD
3987       cat conftest.s >&AS_MESSAGE_LOG_FD
3988       echo "configure: error output was" >&AS_MESSAGE_LOG_FD
3989       cat conftest.out >&AS_MESSAGE_LOG_FD
3990     fi
3991     rm -f conftest.o conftest.s conftest.out
3992   fi])
3993 if test "x$gcc_cv_as_line_zero" = xyes; then
3994   AC_DEFINE([HAVE_AS_LINE_ZERO], 1,
3995 [Define if the assembler won't complain about a line such as # 0 "" 2.])
3996 fi
3997
3998 AC_MSG_CHECKING(linker PT_GNU_EH_FRAME support)
3999 gcc_cv_ld_eh_frame_hdr=no
4000 if test $in_tree_ld = yes ; then
4001   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 12 -o "$gcc_cv_gld_major_version" -gt 2 \
4002      && test $in_tree_ld_is_elf = yes; then
4003     gcc_cv_ld_eh_frame_hdr=yes
4004   fi
4005 elif test x$gcc_cv_ld != x; then
4006   if echo "$ld_ver" | grep GNU > /dev/null; then
4007     # Check if linker supports --eh-frame-hdr option
4008     if $gcc_cv_ld --help 2>/dev/null | grep eh-frame-hdr > /dev/null; then
4009       gcc_cv_ld_eh_frame_hdr=yes
4010     fi
4011   else
4012     case "$target" in
4013       *-*-solaris2*)
4014         # Sun ld has various bugs in .eh_frame_hdr support before version 1.2251.
4015         if test "$ld_vers_major" -gt 1 || test "$ld_vers_minor" -ge 2251; then
4016           gcc_cv_ld_eh_frame_hdr=yes
4017         fi
4018         ;;
4019     esac
4020   fi
4021 fi
4022 GCC_TARGET_TEMPLATE([HAVE_LD_EH_FRAME_HDR])
4023 if test x"$gcc_cv_ld_eh_frame_hdr" = xyes; then
4024         AC_DEFINE(HAVE_LD_EH_FRAME_HDR, 1,
4025 [Define if your linker supports .eh_frame_hdr.])
4026 fi
4027 AC_MSG_RESULT($gcc_cv_ld_eh_frame_hdr)
4028
4029 AC_MSG_CHECKING(linker position independent executable support)
4030 gcc_cv_ld_pie=no
4031 if test $in_tree_ld = yes ; then
4032   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 15 -o "$gcc_cv_gld_major_version" -gt 2 \
4033      && test $in_tree_ld_is_elf = yes; then
4034     gcc_cv_ld_pie=yes
4035   fi
4036 elif test x$gcc_cv_ld != x; then
4037         # Check if linker supports -pie option
4038         if $gcc_cv_ld --help 2>/dev/null | grep -- -pie > /dev/null; then
4039                 gcc_cv_ld_pie=yes
4040         fi
4041 fi
4042 if test x"$gcc_cv_ld_pie" = xyes; then
4043         AC_DEFINE(HAVE_LD_PIE, 1,
4044 [Define if your linker supports -pie option.])
4045 fi
4046 AC_MSG_RESULT($gcc_cv_ld_pie)
4047
4048 AC_MSG_CHECKING(linker EH-compatible garbage collection of sections)
4049 gcc_cv_ld_eh_gc_sections=no
4050 if test $in_tree_ld = yes ; then
4051   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 17 -o "$gcc_cv_gld_major_version" -gt 2 \
4052      && test $in_tree_ld_is_elf = yes; then
4053     gcc_cv_ld_eh_gc_sections=yes
4054   fi
4055 elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x -a x$gcc_cv_objdump != x ; then
4056   cat > conftest.s <<EOF
4057         .section        .text
4058 .globl _start
4059         .type _start, @function
4060 _start:
4061         .long foo
4062         .size _start, .-_start
4063         .section        .text.foo,"ax",@progbits
4064         .type foo, @function
4065 foo:
4066         .long 0
4067         .size foo, .-foo
4068         .section        .gcc_except_table.foo,"a",@progbits
4069 .L0:
4070         .long 0
4071         .section        .eh_frame,"a",@progbits
4072         .long .L0
4073 EOF
4074   if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
4075     if $gcc_cv_ld -o conftest conftest.o --entry=_start --gc-sections 2>&1 \
4076          | grep "gc-sections option ignored" > /dev/null; then
4077       gcc_cv_ld_eh_gc_sections=no
4078     elif $gcc_cv_objdump -h conftest 2> /dev/null \
4079          | grep gcc_except_table > /dev/null; then
4080       gcc_cv_ld_eh_gc_sections=yes
4081       # If no COMDAT groups, the compiler will emit .gnu.linkonce.t. sections.
4082       if test x$gcc_cv_as_comdat_group != xyes; then
4083         gcc_cv_ld_eh_gc_sections=no
4084         cat > conftest.s <<EOF
4085         .section        .text
4086 .globl _start
4087         .type _start, @function
4088 _start:
4089         .long foo
4090         .size _start, .-_start
4091         .section        .gnu.linkonce.t.foo,"ax",@progbits
4092         .type foo, @function
4093 foo:
4094         .long 0
4095         .size foo, .-foo
4096         .section        .gcc_except_table.foo,"a",@progbits
4097 .L0:
4098         .long 0
4099         .section        .eh_frame,"a",@progbits
4100         .long .L0
4101 EOF
4102         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
4103           if $gcc_cv_ld -o conftest conftest.o --entry=_start --gc-sections 2>&1 \
4104                | grep "gc-sections option ignored" > /dev/null; then
4105             gcc_cv_ld_eh_gc_sections=no
4106           elif $gcc_cv_objdump -h conftest 2> /dev/null \
4107                | grep gcc_except_table > /dev/null; then
4108             gcc_cv_ld_eh_gc_sections=yes
4109           fi
4110         fi
4111       fi
4112     fi
4113   fi
4114   rm -f conftest.s conftest.o conftest
4115 fi
4116 case "$target" in
4117   hppa*-*-linux*)
4118     # ??? This apparently exposes a binutils bug with PC-relative relocations.
4119     gcc_cv_ld_eh_gc_sections=no
4120     ;;
4121 esac
4122 if test x$gcc_cv_ld_eh_gc_sections = xyes; then
4123         AC_DEFINE(HAVE_LD_EH_GC_SECTIONS, 1,
4124   [Define if your linker supports garbage collection of
4125    sections in presence of EH frames.])
4126 fi
4127 AC_MSG_RESULT($gcc_cv_ld_eh_gc_sections)
4128
4129 AC_MSG_CHECKING(linker EH garbage collection of sections bug)
4130 gcc_cv_ld_eh_gc_sections_bug=no
4131 if test $in_tree_ld = yes ; then
4132   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -lt 19 -o "$gcc_cv_gld_major_version" -lt 2 \
4133      && test $in_tree_ld_is_elf = yes; then
4134     gcc_cv_ld_eh_gc_sections_bug=yes
4135   fi
4136 elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x -a x$gcc_cv_objdump != x -a x$gcc_cv_as_comdat_group = xyes; then
4137   gcc_cv_ld_eh_gc_sections_bug=yes
4138   cat > conftest.s <<EOF
4139         .section        .text
4140 .globl _start
4141         .type _start, @function
4142 _start:
4143         .long foo
4144         .size _start, .-_start
4145         .section        .text.startup.foo,"ax",@progbits
4146         .type foo, @function
4147 foo:
4148         .long 0
4149         .size foo, .-foo
4150         .section        .gcc_except_table.foo,"a",@progbits
4151 .L0:
4152         .long 0
4153         .section        .eh_frame,"a",@progbits
4154         .long .L0
4155 EOF
4156   if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
4157     if $gcc_cv_ld -o conftest conftest.o --entry=_start --gc-sections 2>&1 \
4158          | grep "gc-sections option ignored" > /dev/null; then
4159       :
4160     elif $gcc_cv_objdump -h conftest 2> /dev/null \
4161          | grep gcc_except_table > /dev/null; then
4162       gcc_cv_ld_eh_gc_sections_bug=no
4163     fi
4164   fi
4165   rm -f conftest.s conftest.o conftest
4166 fi
4167 if test x$gcc_cv_ld_eh_gc_sections_bug = xyes; then
4168         AC_DEFINE(HAVE_LD_EH_GC_SECTIONS_BUG, 1,
4169   [Define if your linker has buggy garbage collection of
4170    sections support when .text.startup.foo like sections are used.])
4171 fi
4172 AC_MSG_RESULT($gcc_cv_ld_eh_gc_sections_bug)
4173
4174 # --------
4175 # UNSORTED
4176 # --------
4177
4178 AC_CACHE_CHECK(linker --as-needed support,
4179 gcc_cv_ld_as_needed,
4180 [gcc_cv_ld_as_needed=no
4181 if test $in_tree_ld = yes ; then
4182   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2 \
4183      && test $in_tree_ld_is_elf = yes; then
4184     gcc_cv_ld_as_needed=yes
4185   fi
4186 elif test x$gcc_cv_ld != x; then
4187         # Check if linker supports --as-needed and --no-as-needed options
4188         if $gcc_cv_ld --help 2>/dev/null | grep as-needed > /dev/null; then
4189                 gcc_cv_ld_as_needed=yes
4190         fi
4191 fi
4192 ])
4193 if test x"$gcc_cv_ld_as_needed" = xyes; then
4194         AC_DEFINE(HAVE_LD_AS_NEEDED, 1,
4195 [Define if your linker supports --as-needed and --no-as-needed options.])
4196 fi
4197
4198 case "$target:$tm_file" in
4199   powerpc64*-*-linux* | powerpc*-*-linux*rs6000/biarch64.h*)
4200     AC_CACHE_CHECK(linker support for omitting dot symbols,
4201     gcc_cv_ld_no_dot_syms,
4202     [gcc_cv_ld_no_dot_syms=no
4203     if test $in_tree_ld = yes ; then
4204       if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2; then
4205         gcc_cv_ld_no_dot_syms=yes
4206       fi
4207     elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x ; then
4208       cat > conftest1.s <<EOF
4209         .text
4210         bl .foo
4211 EOF
4212       cat > conftest2.s <<EOF
4213         .section ".opd","aw"
4214         .align 3
4215         .globl foo
4216         .type foo,@function
4217 foo:
4218         .quad .LEfoo,.TOC.@tocbase,0
4219         .text
4220 .LEfoo:
4221         blr
4222         .size foo,.-.LEfoo
4223 EOF
4224       if $gcc_cv_as -a64 -o conftest1.o conftest1.s > /dev/null 2>&1 \
4225          && $gcc_cv_as -a64 -o conftest2.o conftest2.s > /dev/null 2>&1 \
4226          && $gcc_cv_ld -melf64ppc -o conftest conftest1.o conftest2.o > /dev/null 2>&1; then
4227         gcc_cv_ld_no_dot_syms=yes
4228       fi
4229       rm -f conftest conftest1.o conftest2.o conftest1.s conftest2.s
4230     fi
4231     ])
4232     if test x"$gcc_cv_ld_no_dot_syms" = xyes; then
4233       AC_DEFINE(HAVE_LD_NO_DOT_SYMS, 1,
4234     [Define if your PowerPC64 linker only needs function descriptor syms.])
4235     fi
4236
4237     AC_CACHE_CHECK(linker large toc support,
4238     gcc_cv_ld_large_toc,
4239     [gcc_cv_ld_large_toc=no
4240     if test $in_tree_ld = yes ; then
4241       if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 21 -o "$gcc_cv_gld_major_version" -gt 2; then
4242         gcc_cv_ld_large_toc=yes
4243       fi
4244     elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x ; then
4245       cat > conftest.s <<EOF
4246         .section ".tbss","awT",@nobits
4247         .align 3
4248 ie0:    .space 8
4249         .global _start
4250         .text
4251 _start:
4252         addis 9,13,ie0@got@tprel@ha
4253         ld 9,ie0@got@tprel@l(9)
4254 EOF
4255       if $gcc_cv_as -a64 -o conftest.o conftest.s > /dev/null 2>&1 \
4256          && $gcc_cv_ld -melf64ppc --no-toc-sort -o conftest conftest.o > /dev/null 2>&1; then
4257         gcc_cv_ld_large_toc=yes
4258       fi
4259       rm -f conftest conftest.o conftest.s
4260     fi
4261     ])
4262     if test x"$gcc_cv_ld_large_toc" = xyes; then
4263       AC_DEFINE(HAVE_LD_LARGE_TOC, 1,
4264     [Define if your PowerPC64 linker supports a large TOC.])
4265     fi
4266     ;;
4267 esac
4268
4269 AC_CACHE_CHECK(linker --build-id support,
4270   gcc_cv_ld_buildid,
4271   [gcc_cv_ld_buildid=no
4272   if test $in_tree_ld = yes ; then
4273     if test "$gcc_cv_gld_major_version" -eq 2 -a \
4274        "$gcc_cv_gld_minor_version" -ge 18 -o \
4275        "$gcc_cv_gld_major_version" -gt 2 \
4276        && test $in_tree_ld_is_elf = yes; then
4277       gcc_cv_ld_buildid=yes
4278     fi
4279   elif test x$gcc_cv_ld != x; then
4280     if $gcc_cv_ld --help 2>/dev/null | grep build-id > /dev/null; then
4281       gcc_cv_ld_buildid=yes
4282     fi
4283   fi])
4284 if test x"$gcc_cv_ld_buildid" = xyes; then
4285   AC_DEFINE(HAVE_LD_BUILDID, 1,
4286   [Define if your linker supports --build-id.])
4287 fi
4288
4289 AC_ARG_ENABLE(linker-build-id,
4290 [  --enable-linker-build-id
4291                           compiler will always pass --build-id to linker],
4292 [],
4293 enable_linker_build_id=no)
4294
4295 if test x"$enable_linker_build_id" = xyes; then
4296   if test x"$gcc_cv_ld_buildid" = xyes; then
4297     AC_DEFINE(ENABLE_LD_BUILDID, 1,
4298     [Define if gcc should always pass --build-id to linker.])
4299   else
4300     AC_MSG_WARN(--build-id is not supported by your linker; --enable-linker-build-id ignored)
4301   fi
4302 fi
4303
4304 # In binutils 2.21, GNU ld gained support for new emulations fully
4305 # supporting the Solaris 2 ABI.  Detect their presence in the linker used.
4306 AC_CACHE_CHECK(linker *_sol2 emulation support,
4307   gcc_cv_ld_sol2_emulation,
4308   [gcc_cv_ld_sol2_emulation=no
4309   if test $in_tree_ld = yes ; then
4310     if test "$gcc_cv_gld_major_version" -eq 2 -a \
4311        "$gcc_cv_gld_minor_version" -ge 21 -o \
4312        "$gcc_cv_gld_major_version" -gt 2 \
4313        && test $in_tree_ld_is_elf = yes; then
4314       gcc_cv_ld_sol2_emulation=yes
4315     fi
4316   elif test x$gcc_cv_ld != x; then
4317     if $gcc_cv_ld -V 2>/dev/null | sed -e '1,/Supported emulations/d;q' | \
4318        grep _sol2 > /dev/null; then
4319       gcc_cv_ld_sol2_emulation=yes
4320     fi
4321   fi])
4322 if test x"$gcc_cv_ld_sol2_emulation" = xyes; then
4323   AC_DEFINE(HAVE_LD_SOL2_EMULATION, 1,
4324   [Define if your linker supports the *_sol2 emulations.])
4325 fi
4326
4327 AC_CACHE_CHECK(linker --sysroot support,
4328   gcc_cv_ld_sysroot,
4329   [gcc_cv_ld_sysroot=no
4330   if test $in_tree_ld = yes ; then
4331       if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2 ; then
4332         gcc_cv_ld_sysroot=yes
4333       fi
4334   elif test x$gcc_cv_ld != x; then
4335     if $gcc_cv_ld --help 2>/dev/null | grep sysroot > /dev/null; then
4336       gcc_cv_ld_sysroot=yes
4337     fi
4338   fi])
4339 if test x"$gcc_cv_ld_sysroot" = xyes; then
4340   AC_DEFINE(HAVE_LD_SYSROOT, 1,
4341   [Define if your linker supports --sysroot.])
4342 fi
4343
4344 if test x$with_sysroot = x && test x$host = x$target \
4345    && test "$prefix" != "/usr" && test "x$prefix" != "x$local_prefix" \
4346    && test "$prefix" != "NONE"; then
4347   AC_DEFINE_UNQUOTED(PREFIX_INCLUDE_DIR, "$prefix/include",
4348 [Define to PREFIX/include if cpp should also search that directory.])
4349 fi
4350
4351 if test x$host != x$target || test "x$TARGET_SYSTEM_ROOT" != x; then
4352   if test "x$with_headers" != x; then
4353     target_header_dir=$with_headers
4354   elif test "x$with_sysroot" = x; then
4355     target_header_dir="${exec_prefix}/${target_noncanonical}/sys-include"
4356   elif test "x$with_build_sysroot" != "x"; then
4357     target_header_dir="${with_build_sysroot}/usr/include"
4358   elif test "x$with_sysroot" = xyes; then
4359     target_header_dir="${exec_prefix}/${target_noncanonical}/sys-root/usr/include"
4360   else
4361     target_header_dir="${with_sysroot}/usr/include"
4362   fi
4363 else
4364   target_header_dir=/usr/include
4365 fi
4366
4367 # Test for stack protector support in target C library.
4368 AC_CACHE_CHECK(__stack_chk_fail in target C library,
4369       gcc_cv_libc_provides_ssp,
4370       [gcc_cv_libc_provides_ssp=no
4371     case "$target" in
4372        *-*-linux* | *-*-kfreebsd*-gnu | *-*-knetbsd*-gnu)
4373       [# glibc 2.4 and later provides __stack_chk_fail and
4374       # either __stack_chk_guard, or TLS access to stack guard canary.
4375       if test -f $target_header_dir/features.h \
4376          && $EGREP '^[  ]*#[    ]*define[       ]+__GNU_LIBRARY__[      ]+([1-9][0-9]|[6-9])' \
4377             $target_header_dir/features.h > /dev/null; then
4378         if $EGREP '^[   ]*#[    ]*define[       ]+__GLIBC__[    ]+([1-9][0-9]|[3-9])' \
4379            $target_header_dir/features.h > /dev/null; then
4380           gcc_cv_libc_provides_ssp=yes
4381         elif $EGREP '^[         ]*#[    ]*define[       ]+__GLIBC__[    ]+2' \
4382              $target_header_dir/features.h > /dev/null \
4383              && $EGREP '^[      ]*#[    ]*define[       ]+__GLIBC_MINOR__[      ]+([1-9][0-9]|[4-9])' \
4384              $target_header_dir/features.h > /dev/null; then
4385           gcc_cv_libc_provides_ssp=yes
4386         elif $EGREP '^[         ]*#[    ]*define[       ]+__UCLIBC__[   ]+1' \
4387              $target_header_dir/features.h > /dev/null && \
4388              test -f $target_header_dir/bits/uClibc_config.h && \
4389              $EGREP '^[         ]*#[    ]*define[       ]+__UCLIBC_HAS_SSP__[   ]+1' \
4390              $target_header_dir/bits/uClibc_config.h > /dev/null; then
4391           gcc_cv_libc_provides_ssp=yes
4392         fi
4393       fi]
4394         ;;
4395        *-*-gnu*)
4396          # Avoid complicated tests (see
4397          # <http://gcc.gnu.org/ml/gcc/2008-10/msg00130.html>) and for now
4398          # simply assert that glibc does provide this, which is true for all
4399          # realistically usable GNU/Hurd configurations.
4400          gcc_cv_libc_provides_ssp=yes;;
4401        *-*-darwin* | *-*-freebsd*)
4402          AC_CHECK_FUNC(__stack_chk_fail,[gcc_cv_libc_provides_ssp=yes],
4403            [echo "no __stack_chk_fail on this target"])
4404         ;;
4405   *) gcc_cv_libc_provides_ssp=no ;;
4406     esac])
4407
4408 if test x$gcc_cv_libc_provides_ssp = xyes; then
4409   AC_DEFINE(TARGET_LIBC_PROVIDES_SSP, 1,
4410             [Define if your target C library provides stack protector support])
4411 fi
4412
4413 # Test for <sys/sdt.h> on the target.
4414 GCC_TARGET_TEMPLATE([HAVE_SYS_SDT_H])
4415 AC_MSG_CHECKING(sys/sdt.h in the target C library)
4416 have_sys_sdt_h=no
4417 if test -f $target_header_dir/sys/sdt.h; then
4418   AC_DEFINE(HAVE_SYS_SDT_H, 1,
4419             [Define if your target C library provides sys/sdt.h])
4420 fi
4421 AC_MSG_RESULT($have_sys_sdt_h)
4422
4423 # Check if TFmode long double should be used by default or not.
4424 # Some glibc targets used DFmode long double, but with glibc 2.4
4425 # and later they can use TFmode.
4426 case "$target" in
4427   powerpc*-*-linux* | \
4428   sparc*-*-linux* | \
4429   s390*-*-linux* | \
4430   alpha*-*-linux*)
4431     AC_ARG_WITH(long-double-128,
4432 [  --with-long-double-128  Use 128-bit long double by default.],
4433       gcc_cv_target_ldbl128="$with_long_double_128",
4434       [[gcc_cv_target_ldbl128=no
4435       grep '^[  ]*#[    ]*define[       ][      ]*__LONG_DOUBLE_MATH_OPTIONAL' \
4436         $target_header_dir/bits/wordsize.h > /dev/null 2>&1 \
4437       && gcc_cv_target_ldbl128=yes
4438       ]])
4439     ;;
4440 esac
4441 if test x$gcc_cv_target_ldbl128 = xyes; then
4442   AC_DEFINE(TARGET_DEFAULT_LONG_DOUBLE_128, 1,
4443             [Define if TFmode long double should be the default])
4444 fi
4445
4446 AC_MSG_CHECKING(dl_iterate_phdr in target C library)
4447 gcc_cv_target_dl_iterate_phdr=unknown
4448 case "$target" in
4449   *-*-solaris2*)
4450     # <link.h> needs both a dl_iterate_phdr declaration and support for
4451     # compilation with largefile support.
4452     if grep dl_iterate_phdr $target_header_dir/link.h > /dev/null 2>&1 \
4453       && grep 'large file capable' $target_header_dir/link.h > /dev/null 2>&1; then
4454       gcc_cv_target_dl_iterate_phdr=yes
4455     else
4456       gcc_cv_target_dl_iterate_phdr=no
4457     fi
4458     ;;
4459 esac
4460 GCC_TARGET_TEMPLATE([TARGET_DL_ITERATE_PHDR])
4461 if test x$gcc_cv_target_dl_iterate_phdr = xyes; then
4462    AC_DEFINE(TARGET_DL_ITERATE_PHDR, 1,
4463 [Define if your target C library provides the `dl_iterate_phdr' function.])
4464 fi
4465 AC_MSG_RESULT($gcc_cv_target_dl_iterate_phdr)
4466
4467 # Find out what GC implementation we want, or may, use.
4468 AC_ARG_WITH(gc,
4469 [  --with-gc={page,zone}   choose the garbage collection mechanism to use
4470                           with the compiler],
4471 [case "$withval" in
4472   page)
4473     GGC=ggc-$withval
4474     ;;
4475   zone)
4476     GGC=ggc-$withval
4477     AC_DEFINE(GGC_ZONE, 1, [Define if the zone collector is in use])
4478     ;;
4479   *)
4480     AC_MSG_ERROR([$withval is an invalid option to --with-gc])
4481     ;;
4482 esac],
4483 [GGC=ggc-page])
4484 AC_SUBST(GGC)
4485 echo "Using $GGC for garbage collection."
4486
4487 # Libraries to use on the host.  This will normally be set by the top
4488 # level Makefile.  Here we simply capture the value for our Makefile.
4489 if test -z "${HOST_LIBS+set}"; then
4490   HOST_LIBS=
4491 fi
4492 AC_SUBST(HOST_LIBS)
4493
4494 # Use the system's zlib library.
4495 zlibdir=-L../zlib
4496 zlibinc="-I\$(srcdir)/../zlib"
4497 AC_ARG_WITH(system-zlib,
4498 [  --with-system-zlib      use installed libz],
4499 zlibdir=
4500 zlibinc=
4501 )
4502 AC_SUBST(zlibdir)
4503 AC_SUBST(zlibinc)
4504
4505 dnl Very limited version of automake's enable-maintainer-mode
4506
4507 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
4508   dnl maintainer-mode is disabled by default
4509   AC_ARG_ENABLE(maintainer-mode,
4510 [  --enable-maintainer-mode
4511                           enable make rules and dependencies not useful
4512                           (and sometimes confusing) to the casual installer],
4513       maintainer_mode=$enableval,
4514       maintainer_mode=no)
4515
4516 AC_MSG_RESULT($maintainer_mode)
4517
4518 if test "$maintainer_mode" = "yes"; then
4519   MAINT=''
4520 else
4521   MAINT='#'
4522 fi
4523 AC_SUBST(MAINT)dnl
4524
4525 # --------------
4526 # Language hooks
4527 # --------------
4528
4529 # Make empty files to contain the specs and options for each language.
4530 # Then add #include lines to for a compiler that has specs and/or options.
4531
4532 subdirs=
4533 lang_opt_files=
4534 lang_specs_files=
4535 lang_tree_files=
4536 # These (without "all_") are set in each config-lang.in.
4537 # `language' must be a single word so is spelled singularly.
4538 all_languages=
4539 all_compilers=
4540 all_outputs='Makefile'
4541 # List of language makefile fragments.
4542 all_lang_makefrags=
4543 # Additional files for gengtype
4544 all_gtfiles="$target_gtfiles"
4545
4546 # These are the languages that are set in --enable-languages,
4547 # and are available in the GCC tree.
4548 all_selected_languages=
4549
4550 # Add the language fragments.
4551 # Languages are added via two mechanisms.  Some information must be
4552 # recorded in makefile variables, these are defined in config-lang.in.
4553 # We accumulate them and plug them into the main Makefile.
4554 # The other mechanism is a set of hooks for each of the main targets
4555 # like `clean', `install', etc.
4556
4557 language_hooks="Make-hooks"
4558
4559 for lang in ${srcdir}/*/config-lang.in
4560 do
4561 changequote(,)dnl
4562         test "$lang" = "${srcdir}/*/config-lang.in" && continue
4563
4564         lang_alias=`sed -n -e 's,^language=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^language=\([^   ]*\).*$,\1,p' $lang`
4565         if test "x$lang_alias" = x
4566         then
4567               echo "$lang doesn't set \$language." 1>&2
4568               exit 1
4569         fi
4570         subdir="`echo $lang | sed -e 's,^.*/\([^/]*\)/config-lang.in$,\1,'`"
4571         subdirs="$subdirs $subdir"
4572
4573         # $gcc_subdir is where the gcc integration files are to be found
4574         # for a language, both for internal compiler purposes (compiler
4575         # sources implementing front-end to GCC tree converters), and for
4576         # build infrastructure purposes (Make-lang.in, etc.)
4577         #
4578         # This will be <subdir> (relative to $srcdir) if a line like
4579         # gcc_subdir="<subdir>" or gcc_subdir=<subdir>
4580         # is found in <langdir>/config-lang.in, and will remain <langdir>
4581         # otherwise.
4582         #
4583         # Except for the language alias (fetched above), the regular
4584         # "config-lang.in" contents are always retrieved from $gcc_subdir,
4585         # so a <langdir>/config-lang.in setting gcc_subdir typically sets
4586         # only this and the language alias.
4587
4588         gcc_subdir=`sed -n -e 's,^gcc_subdir=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^gcc_subdir=\([^   ]*\).*$,\1,p' $lang`
4589         if [ "$gcc_subdir" = "" ]; then
4590            gcc_subdir="$subdir"
4591         fi
4592
4593         case ",$enable_languages," in
4594         *,$lang_alias,*)
4595             all_selected_languages="$all_selected_languages $lang_alias"
4596             if test -f $srcdir/$gcc_subdir/lang-specs.h; then
4597                 lang_specs_files="$lang_specs_files $srcdir/$gcc_subdir/lang-specs.h"
4598             fi
4599             ;;
4600         esac
4601 changequote([,])dnl
4602
4603         language=
4604         boot_language=
4605         compilers=
4606         outputs=
4607         gtfiles=
4608         subdir_requires=
4609         . ${srcdir}/$gcc_subdir/config-lang.in
4610         if test "x$language" = x
4611         then
4612                 echo "${srcdir}/$gcc_subdir/config-lang.in doesn't set \$language." 1>&2
4613                 exit 1
4614         fi
4615
4616         ok=:
4617         case ",$enable_languages," in
4618                 *,$lang_alias,*) ;;
4619                 *)
4620                         for i in $subdir_requires; do
4621                                 test -f "${srcdir}/$i/config-lang.in" && continue
4622                                 ok=false
4623                                 break
4624                         done
4625                 ;;
4626         esac
4627         $ok || continue
4628
4629         all_lang_makefrags="$all_lang_makefrags \$(srcdir)/$gcc_subdir/Make-lang.in"
4630         if test -f $srcdir/$gcc_subdir/lang.opt; then
4631             lang_opt_files="$lang_opt_files $srcdir/$gcc_subdir/lang.opt"
4632             all_opt_files="$all_opt_files $srcdir/$gcc_subdir/lang.opt"
4633         fi
4634         if test -f $srcdir/$gcc_subdir/$subdir-tree.def; then
4635             lang_tree_files="$lang_tree_files $srcdir/$gcc_subdir/$subdir-tree.def"
4636         fi
4637         all_languages="$all_languages $language"
4638         all_compilers="$all_compilers $compilers"
4639         all_outputs="$all_outputs $outputs"
4640         all_gtfiles="$all_gtfiles [[$subdir]] $gtfiles"
4641         case ",$enable_languages," in
4642                 *,lto,*)
4643                     AC_DEFINE(ENABLE_LTO, 1, [Define to enable LTO support.])
4644                     enable_lto=yes
4645                     AC_SUBST(enable_lto)
4646                     ;;
4647                 *) ;;
4648         esac
4649 done
4650
4651 # Pick up gtfiles for c
4652 gtfiles=
4653 . ${srcdir}/c-config-lang.in
4654 all_gtfiles="$all_gtfiles [[c]] $gtfiles"
4655
4656 check_languages=
4657 for language in $all_selected_languages
4658 do
4659         check_languages="$check_languages check-$language"
4660 done
4661
4662 # We link each language in with a set of hooks, reached indirectly via
4663 # lang.${target}.  Only do so for selected languages.
4664
4665 rm -f Make-hooks
4666 touch Make-hooks
4667 target_list="all.cross start.encap rest.encap tags \
4668         install-common install-man install-info install-pdf install-html dvi \
4669         pdf html uninstall info man srcextra srcman srcinfo \
4670         mostlyclean clean distclean maintainer-clean install-plugin"
4671
4672 for t in $target_list
4673 do
4674         x=
4675         for lang in $all_selected_languages
4676         do
4677                 x="$x $lang.$t"
4678         done
4679         echo "lang.$t: $x" >> Make-hooks
4680 done
4681
4682 # --------
4683 # Option include files
4684 # --------
4685
4686 ${AWK} -f $srcdir/opt-include.awk $all_opt_files > option-includes.mk
4687 option_includes="option-includes.mk"
4688 AC_SUBST_FILE(option_includes)
4689
4690 # --------
4691 # UNSORTED
4692 # --------
4693
4694 # Create .gdbinit.
4695
4696 echo "dir ." > .gdbinit
4697 echo "dir ${srcdir}" >> .gdbinit
4698 if test x$gdb_needs_out_file_path = xyes
4699 then
4700         echo "dir ${srcdir}/config/"`dirname ${out_file}` >> .gdbinit
4701 fi
4702 if test "x$subdirs" != x; then
4703         for s in $subdirs
4704         do
4705                 echo "dir ${srcdir}/$s" >> .gdbinit
4706         done
4707 fi
4708 echo "source ${srcdir}/gdbinit.in" >> .gdbinit
4709
4710 gcc_tooldir='$(libsubdir)/$(libsubdir_to_prefix)$(target_noncanonical)'
4711 AC_SUBST(gcc_tooldir)
4712 AC_SUBST(dollar)
4713
4714 # Find a directory in which to install a shared libgcc.
4715
4716 AC_ARG_ENABLE(version-specific-runtime-libs,
4717 [  --enable-version-specific-runtime-libs
4718                           specify that runtime libraries should be
4719                           installed in a compiler-specific directory])
4720
4721 AC_ARG_WITH(slibdir,
4722 [  --with-slibdir=DIR      shared libraries in DIR [[LIBDIR]]],
4723 slibdir="$with_slibdir",
4724 if test "${enable_version_specific_runtime_libs+set}" = set; then
4725   slibdir='$(libsubdir)'
4726 elif test "$host" != "$target"; then
4727   slibdir='$(build_tooldir)/lib'
4728 else
4729   slibdir='$(libdir)'
4730 fi)
4731 AC_SUBST(slibdir)
4732
4733 # Substitute configuration variables
4734 AC_SUBST(subdirs)
4735 AC_SUBST(srcdir)
4736 AC_SUBST(all_compilers)
4737 AC_SUBST(all_gtfiles)
4738 AC_SUBST(all_lang_makefrags)
4739 AC_SUBST(all_languages)
4740 AC_SUBST(all_selected_languages)
4741 AC_SUBST(build_exeext)
4742 AC_SUBST(build_install_headers_dir)
4743 AC_SUBST(build_xm_file_list)
4744 AC_SUBST(build_xm_include_list)
4745 AC_SUBST(build_xm_defines)
4746 AC_SUBST(build_file_translate)
4747 AC_SUBST(check_languages)
4748 AC_SUBST(cpp_install_dir)
4749 AC_SUBST(xmake_file)
4750 AC_SUBST(tmake_file)
4751 AC_SUBST(TM_ENDIAN_CONFIG)
4752 AC_SUBST(TM_MULTILIB_CONFIG)
4753 AC_SUBST(TM_MULTILIB_EXCEPTIONS_CONFIG)
4754 AC_SUBST(extra_gcc_objs)
4755 AC_SUBST(user_headers_inc_next_pre)
4756 AC_SUBST(user_headers_inc_next_post)
4757 AC_SUBST(extra_headers_list)
4758 AC_SUBST(extra_objs)
4759 AC_SUBST(extra_parts)
4760 AC_SUBST(extra_passes)
4761 AC_SUBST(extra_programs)
4762 AC_SUBST(float_h_file)
4763 AC_SUBST(gcc_config_arguments)
4764 AC_SUBST(gcc_gxx_include_dir)
4765 AC_SUBST(host_exeext)
4766 AC_SUBST(host_xm_file_list)
4767 AC_SUBST(host_xm_include_list)
4768 AC_SUBST(host_xm_defines)
4769 AC_SUBST(out_host_hook_obj)
4770 AC_SUBST(install)
4771 AC_SUBST(lang_opt_files)
4772 AC_SUBST(lang_specs_files)
4773 AC_SUBST(lang_tree_files)
4774 AC_SUBST(local_prefix)
4775 AC_SUBST(md_file)
4776 AC_SUBST(objc_boehm_gc)
4777 AC_SUBST(out_file)
4778 AC_SUBST(out_object_file)
4779 AC_SUBST(thread_file)
4780 AC_SUBST(tm_file_list)
4781 AC_SUBST(tm_include_list)
4782 AC_SUBST(tm_defines)
4783 AC_SUBST(libgcc_tm_file_list)
4784 AC_SUBST(libgcc_tm_include_list)
4785 AC_SUBST(tm_p_file_list)
4786 AC_SUBST(tm_p_include_list)
4787 AC_SUBST(xm_file_list)
4788 AC_SUBST(xm_include_list)
4789 AC_SUBST(xm_defines)
4790 AC_SUBST(use_gcc_stdint)
4791 AC_SUBST(c_target_objs)
4792 AC_SUBST(cxx_target_objs)
4793 AC_SUBST(fortran_target_objs)
4794 AC_SUBST(target_cpu_default)
4795
4796 AC_SUBST_FILE(language_hooks)
4797
4798 # Echo link setup.
4799 if test x${build} = x${host} ; then
4800   if test x${host} = x${target} ; then
4801     echo "Links are now set up to build a native compiler for ${target}." 1>&2
4802   else
4803     echo "Links are now set up to build a cross-compiler" 1>&2
4804     echo " from ${host} to ${target}." 1>&2
4805   fi
4806 else
4807   if test x${host} = x${target} ; then
4808     echo "Links are now set up to build (on ${build}) a native compiler" 1>&2
4809     echo " for ${target}." 1>&2
4810   else
4811     echo "Links are now set up to build (on ${build}) a cross-compiler" 1>&2
4812     echo " from ${host} to ${target}." 1>&2
4813   fi
4814 fi
4815
4816 AC_ARG_VAR(GMPLIBS,[How to link GMP])
4817 AC_ARG_VAR(GMPINC,[How to find GMP include files])
4818
4819 AC_ARG_VAR(PPLLIBS,[How to link PPL])
4820 AC_ARG_VAR(PPLINC,[How to find PPL include files])
4821
4822 AC_ARG_VAR(CLOOGLIBS,[How to link CLOOG])
4823 AC_ARG_VAR(CLOOGINC,[How to find CLOOG include files])
4824 if test "x${CLOOGLIBS}" != "x" ; then
4825    AC_DEFINE(HAVE_cloog, 1, [Define if cloog is in use.])
4826 fi
4827
4828 # Check for plugin support
4829 AC_ARG_ENABLE(plugin,
4830 [  --enable-plugin         enable plugin support],
4831 enable_plugin=$enableval,
4832 enable_plugin=yes; default_plugin=yes)
4833
4834 pluginlibs=
4835
4836 case "${host}" in
4837   *-*-darwin*)
4838     if test x$build = x$host; then
4839       export_sym_check="nm${exeext} -g"
4840     elif test x$host = x$target; then
4841       export_sym_check="$gcc_cv_nm -g"
4842     else
4843       export_sym_check=
4844     fi
4845   ;;
4846   *)
4847     if test x$build = x$host; then
4848       export_sym_check="objdump${exeext} -T"
4849     elif test x$host = x$target; then
4850       export_sym_check="$gcc_cv_objdump -T"
4851     else
4852       export_sym_check=
4853     fi
4854   ;;
4855 esac
4856
4857 if test x"$enable_plugin" = x"yes"; then
4858
4859   AC_MSG_CHECKING([for exported symbols])
4860   if test "x$export_sym_check" != x; then
4861     echo "int main() {return 0;} int foobar() {return 0;}" > conftest.c
4862     ${CC} ${CFLAGS} ${LDFLAGS} conftest.c -o conftest > /dev/null 2>&1
4863     if $export_sym_check conftest | grep foobar > /dev/null; then
4864       : # No need to use a flag
4865       AC_MSG_RESULT([yes])
4866     else
4867       AC_MSG_RESULT([yes])
4868       AC_MSG_CHECKING([for -rdynamic])
4869       ${CC} ${CFLAGS} ${LDFLAGS} -rdynamic conftest.c -o conftest > /dev/null 2>&1
4870       if $export_sym_check conftest | grep foobar > /dev/null; then
4871         plugin_rdynamic=yes
4872         pluginlibs="-rdynamic"
4873       else
4874         plugin_rdynamic=no
4875         enable_plugin=no
4876       fi
4877       AC_MSG_RESULT([$plugin_rdynamic])
4878     fi
4879   else
4880     AC_MSG_RESULT([unable to check])
4881   fi
4882
4883   # Check -ldl
4884   saved_LIBS="$LIBS"
4885   AC_SEARCH_LIBS([dlopen], [dl])
4886   if test x"$ac_cv_search_dlopen" = x"-ldl"; then
4887     pluginlibs="$pluginlibs -ldl"
4888   fi
4889   LIBS="$saved_LIBS"
4890
4891   # Check that we can build shared objects with -fPIC -shared
4892   saved_LDFLAGS="$LDFLAGS"
4893   saved_CFLAGS="$CFLAGS"
4894   case "${host}" in
4895     *-*-darwin*)
4896       CFLAGS=`echo $CFLAGS | sed s/-mdynamic-no-pic//g`
4897       CFLAGS="$CFLAGS -fPIC"
4898       LDFLAGS="$LDFLAGS -shared -undefined dynamic_lookup"
4899     ;;
4900     *)
4901       CFLAGS="$CFLAGS -fPIC"
4902       LDFLAGS="$LDFLAGS -fPIC -shared"
4903     ;;
4904   esac
4905   AC_MSG_CHECKING([for -fPIC -shared])
4906   AC_TRY_LINK(
4907     [extern int X;],[return X == 0;],
4908     [AC_MSG_RESULT([yes]); have_pic_shared=yes],
4909     [AC_MSG_RESULT([no]); have_pic_shared=no])
4910   if test x"$have_pic_shared" != x"yes" -o x"$ac_cv_search_dlopen" = x"no"; then
4911     pluginlibs=
4912     enable_plugin=no
4913   fi
4914   LDFLAGS="$saved_LDFLAGS"
4915   CFLAGS="$saved_CFLAGS"
4916
4917   # If plugin support had been requested but not available, fail.
4918   if test x"$enable_plugin" = x"no" ; then
4919     if test x"$default_plugin" != x"yes"; then
4920       AC_MSG_ERROR([
4921 Building GCC with plugin support requires a host that supports
4922 -fPIC, -shared, -ldl and -rdynamic.])
4923     fi
4924   fi
4925 fi
4926
4927 AC_SUBST(pluginlibs)
4928 AC_SUBST(enable_plugin)
4929 if test x"$enable_plugin" = x"yes"; then
4930   AC_DEFINE(ENABLE_PLUGIN, 1, [Define to enable plugin support.])
4931 fi
4932
4933
4934 AC_ARG_ENABLE(libquadmath-support,
4935 [AS_HELP_STRING([--disable-libquadmath-support],
4936   [disable libquadmath support for Fortran])],
4937 ENABLE_LIBQUADMATH_SUPPORT=$enableval,
4938 ENABLE_LIBQUADMATH_SUPPORT=yes)
4939 if test "${ENABLE_LIBQUADMATH_SUPPORT}" != "no" ; then
4940   AC_DEFINE(ENABLE_LIBQUADMATH_SUPPORT, 1,
4941             [Define to 1 to enable libquadmath support])
4942 fi
4943
4944
4945 # Specify what hash style to use by default.
4946 AC_ARG_WITH([linker-hash-style],
4947 [AC_HELP_STRING([--with-linker-hash-style={sysv,gnu,both}],
4948                 [specify the linker hash style])],
4949 [case x"$withval" in
4950    xsysv)
4951      LINKER_HASH_STYLE=sysv
4952      ;;
4953    xgnu)
4954      LINKER_HASH_STYLE=gnu
4955      ;;
4956    xboth)
4957      LINKER_HASH_STYLE=both
4958      ;;
4959    *)
4960      AC_MSG_ERROR([$withval is an invalid option to --with-linker-hash-style])
4961      ;;
4962  esac],
4963 [LINKER_HASH_STYLE=''])
4964 if test x"${LINKER_HASH_STYLE}" != x; then
4965   AC_DEFINE_UNQUOTED(LINKER_HASH_STYLE, "$LINKER_HASH_STYLE",
4966                                          [The linker hash style])
4967 fi
4968
4969 # Configure the subdirectories
4970 # AC_CONFIG_SUBDIRS($subdirs)
4971
4972 # Create the Makefile
4973 # and configure language subdirectories
4974 AC_CONFIG_FILES($all_outputs)
4975
4976 AC_CONFIG_COMMANDS([default],
4977 [
4978 case ${CONFIG_HEADERS} in
4979   *auto-host.h:config.in*)
4980   echo > cstamp-h ;;
4981 esac
4982 # Make sure all the subdirs exist.
4983 for d in $subdirs doc build c-family
4984 do
4985     test -d $d || mkdir $d
4986 done
4987 ],
4988 [subdirs='$subdirs'])
4989 AC_OUTPUT
4990