OSDN Git Service

M68K TLS support.
[pf3gnuchains/gcc-fork.git] / gcc / configure.ac
1 # configure.ac for GCC
2 # Process this file with autoconf to generate a configuration script.
3
4 # Copyright 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2004, 2005, 2006,
5 # 2007, 2008, 2009 Free Software Foundation, Inc.
6
7 #This file is part of GCC.
8
9 #GCC is free software; you can redistribute it and/or modify it under
10 #the terms of the GNU General Public License as published by the Free
11 #Software Foundation; either version 3, or (at your option) any later
12 #version.
13
14 #GCC is distributed in the hope that it will be useful, but WITHOUT
15 #ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
16 #FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
17 #for more details.
18
19 #You should have received a copy of the GNU General Public License
20 #along with GCC; see the file COPYING3.  If not see
21 #<http://www.gnu.org/licenses/>.
22
23 # --------------------------------
24 # Initialization and sanity checks
25 # --------------------------------
26
27 AC_PREREQ(2.59)
28 AC_INIT
29 AC_CONFIG_SRCDIR(tree.c)
30 AC_CONFIG_HEADER(auto-host.h:config.in)
31
32 gcc_version=`cat $srcdir/BASE-VER`
33
34 # Determine the host, build, and target systems
35 AC_CANONICAL_BUILD
36 AC_CANONICAL_HOST
37 AC_CANONICAL_TARGET
38
39 # Determine the noncanonical target name, for directory use.
40 ACX_NONCANONICAL_TARGET
41
42 # Determine the target- and build-specific subdirectories
43 GCC_TOPLEV_SUBDIRS
44
45 # Set program_transform_name
46 AC_ARG_PROGRAM
47
48 # Check for bogus environment variables.
49 # Test if LIBRARY_PATH contains the notation for the current directory
50 # since this would lead to problems installing/building glibc.
51 # LIBRARY_PATH contains the current directory if one of the following
52 # is true:
53 # - one of the terminals (":" and ";") is the first or last sign
54 # - two terminals occur directly after each other
55 # - the path contains an element with a dot in it
56 AC_MSG_CHECKING(LIBRARY_PATH variable)
57 changequote(,)dnl
58 case ${LIBRARY_PATH} in
59   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
60     library_path_setting="contains current directory"
61     ;;
62   *)
63     library_path_setting="ok"
64     ;;
65 esac
66 changequote([,])dnl
67 AC_MSG_RESULT($library_path_setting)
68 if test "$library_path_setting" != "ok"; then
69 AC_MSG_ERROR([
70 *** LIBRARY_PATH shouldn't contain the current directory when
71 *** building gcc. Please change the environment variable
72 *** and run configure again.])
73 fi
74
75 # Test if GCC_EXEC_PREFIX contains the notation for the current directory
76 # since this would lead to problems installing/building glibc.
77 # GCC_EXEC_PREFIX contains the current directory if one of the following
78 # is true:
79 # - one of the terminals (":" and ";") is the first or last sign
80 # - two terminals occur directly after each other
81 # - the path contains an element with a dot in it
82 AC_MSG_CHECKING(GCC_EXEC_PREFIX variable)
83 changequote(,)dnl
84 case ${GCC_EXEC_PREFIX} in
85   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
86     gcc_exec_prefix_setting="contains current directory"
87     ;;
88   *)
89     gcc_exec_prefix_setting="ok"
90     ;;
91 esac
92 changequote([,])dnl
93 AC_MSG_RESULT($gcc_exec_prefix_setting)
94 if test "$gcc_exec_prefix_setting" != "ok"; then
95 AC_MSG_ERROR([
96 *** GCC_EXEC_PREFIX shouldn't contain the current directory when
97 *** building gcc. Please change the environment variable
98 *** and run configure again.])
99 fi
100
101 # -----------
102 # Directories
103 # -----------
104
105 # Specify the local prefix
106 local_prefix=
107 AC_ARG_WITH(local-prefix,
108 [  --with-local-prefix=DIR specifies directory to put local include],
109 [case "${withval}" in
110 yes)    AC_MSG_ERROR(bad value ${withval} given for local include directory prefix) ;;
111 no)     ;;
112 *)      local_prefix=$with_local_prefix ;;
113 esac])
114
115 # Default local prefix if it is empty
116 if test x$local_prefix = x; then
117         local_prefix=/usr/local
118 fi
119
120 # Don't set gcc_gxx_include_dir to gxx_include_dir since that's only
121 # passed in by the toplevel make and thus we'd get different behavior
122 # depending on where we built the sources.
123 gcc_gxx_include_dir=
124 # Specify the g++ header file directory
125 AC_ARG_WITH(gxx-include-dir,
126 [  --with-gxx-include-dir=DIR
127                           specifies directory to put g++ header files],
128 [case "${withval}" in
129 yes)    AC_MSG_ERROR(bad value ${withval} given for g++ include directory) ;;
130 no)     ;;
131 *)      gcc_gxx_include_dir=$with_gxx_include_dir ;;
132 esac])
133
134 # This logic must match libstdc++-v3/acinclude.m4:GLIBCXX_EXPORT_INSTALL_INFO.
135 if test x${gcc_gxx_include_dir} = x; then
136   if test x${enable_version_specific_runtime_libs} = xyes; then
137     gcc_gxx_include_dir='${libsubdir}/include/c++'
138   else
139     libstdcxx_incdir='include/c++/$(version)'
140     if test x$host != x$target; then
141        libstdcxx_incdir="$target_alias/$libstdcxx_incdir"
142     fi
143     gcc_gxx_include_dir="\$(libsubdir)/\$(libsubdir_to_prefix)$libstdcxx_incdir"
144   fi
145 fi
146
147 AC_ARG_WITH(cpp_install_dir,
148 [  --with-cpp-install-dir=DIR
149                           install the user visible C preprocessor in DIR
150                           (relative to PREFIX) as well as PREFIX/bin],
151 [if test x$withval = xyes; then
152   AC_MSG_ERROR([option --with-cpp-install-dir requires an argument])
153 elif test x$withval != xno; then
154   cpp_install_dir=$withval
155 fi])
156
157 # We would like to our source tree to be readonly.  However when releases or
158 # pre-releases are generated, the flex/bison generated files as well as the 
159 # various formats of manuals need to be included along with the rest of the
160 # sources.  Therefore we have --enable-generated-files-in-srcdir to do 
161 # just that.
162
163 AC_MSG_CHECKING([whether to place generated files in the source directory])
164   dnl generated-files-in-srcdir is disabled by default
165   AC_ARG_ENABLE(generated-files-in-srcdir, 
166 [  --enable-generated-files-in-srcdir
167                           put copies of generated files in source dir
168                           intended for creating source tarballs for users
169                           without texinfo bison or flex.],
170       generated_files_in_srcdir=$enableval,
171       generated_files_in_srcdir=no)
172
173 AC_MSG_RESULT($generated_files_in_srcdir)
174
175 if test "$generated_files_in_srcdir" = "yes"; then
176   GENINSRC=''
177 else
178   GENINSRC='#'
179 fi
180 AC_SUBST(GENINSRC)
181
182 # -------------------
183 # Find default linker
184 # -------------------
185
186 # With GNU ld
187 AC_ARG_WITH(gnu-ld,
188 [  --with-gnu-ld           arrange to work with GNU ld.],
189 gnu_ld_flag="$with_gnu_ld",
190 gnu_ld_flag=no)
191
192 # With pre-defined ld
193 AC_ARG_WITH(ld,
194 [  --with-ld               arrange to use the specified ld (full pathname)],
195 DEFAULT_LINKER="$with_ld")
196 if test x"${DEFAULT_LINKER+set}" = x"set"; then
197   if test ! -x "$DEFAULT_LINKER"; then
198     AC_MSG_ERROR([cannot execute: $DEFAULT_LINKER: check --with-ld or env. var. DEFAULT_LINKER])
199   elif $DEFAULT_LINKER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
200     gnu_ld_flag=yes
201   fi
202   AC_DEFINE_UNQUOTED(DEFAULT_LINKER,"$DEFAULT_LINKER",
203         [Define to enable the use of a default linker.])
204 fi
205
206 gnu_ld=`if test x"$gnu_ld_flag" = x"yes"; then echo 1; else echo 0; fi`
207 AC_DEFINE_UNQUOTED(HAVE_GNU_LD, $gnu_ld, [Define if using GNU ld.])
208
209 AC_MSG_CHECKING([whether a default linker was specified])
210 if test x"${DEFAULT_LINKER+set}" = x"set"; then
211   if test x"$gnu_ld_flag" = x"no"; then
212     AC_MSG_RESULT([yes ($DEFAULT_LINKER)])
213   else
214     AC_MSG_RESULT([yes ($DEFAULT_LINKER - GNU ld)])
215   fi
216 else
217   AC_MSG_RESULT(no)
218 fi
219
220 # With demangler in GNU ld
221 AC_ARG_WITH(demangler-in-ld,
222 [  --with-demangler-in-ld  try to use demangler in GNU ld.],
223 demangler_in_ld="$with_demangler_in_ld",
224 demangler_in_ld=no)
225
226 # ----------------------
227 # Find default assembler
228 # ----------------------
229
230 # With GNU as
231 AC_ARG_WITH(gnu-as,
232 [  --with-gnu-as           arrange to work with GNU as],
233 gas_flag="$with_gnu_as",
234 gas_flag=no)
235
236 AC_ARG_WITH(as,
237 [  --with-as               arrange to use the specified as (full pathname)],
238 DEFAULT_ASSEMBLER="$with_as")
239 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
240   if test ! -x "$DEFAULT_ASSEMBLER"; then
241     AC_MSG_ERROR([cannot execute: $DEFAULT_ASSEMBLER: check --with-as or env. var. DEFAULT_ASSEMBLER])
242   elif $DEFAULT_ASSEMBLER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
243     gas_flag=yes
244   fi
245   AC_DEFINE_UNQUOTED(DEFAULT_ASSEMBLER,"$DEFAULT_ASSEMBLER",
246         [Define to enable the use of a default assembler.])
247 fi
248
249 gnu_as=`if test x"$gas_flag" = x"yes"; then echo 1; else echo 0; fi`
250 AC_DEFINE_UNQUOTED(HAVE_GNU_AS, $gnu_as, [Define if using GNU as.])
251
252 AC_MSG_CHECKING([whether a default assembler was specified])
253 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
254   if test x"$gas_flag" = x"no"; then
255     AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER)])
256   else
257     AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER - GNU as)])
258   fi
259 else
260   AC_MSG_RESULT(no)
261 fi
262
263 # ---------------
264 # Find C compiler
265 # ---------------
266
267 # If a non-executable a.out is present (e.g. created by GNU as above even if
268 # invoked with -v only), the IRIX 6 native ld just overwrites the existing
269 # file, even when creating an executable, so an execution test fails.
270 # Remove possible default executable files to avoid this.
271 #
272 # FIXME: This really belongs into AC_PROG_CC and can be removed once
273 # Autoconf includes it.
274 rm -f a.out a.exe b.out
275
276 # Find the native compiler
277 AC_PROG_CC
278 AM_PROG_CC_C_O
279 ACX_PROG_GNAT([-I"$srcdir"/ada])
280
281 # autoconf is lame and doesn't give us any substitution variable for this.
282 if eval "test \"`echo '$ac_cv_prog_cc_'${ac_cc}_c_o`\" = no"; then
283   NO_MINUS_C_MINUS_O=yes
284 else
285   OUTPUT_OPTION='-o $@'
286 fi
287 AC_SUBST(NO_MINUS_C_MINUS_O)
288 AC_SUBST(OUTPUT_OPTION)
289
290 # Remove the -O2: for historical reasons, unless bootstrapping we prefer
291 # optimizations to be activated explicitly by the toplevel.
292 case "$CC" in
293   */prev-gcc/xgcc*) ;;
294   *) CFLAGS=`echo $CFLAGS | sed "s/-O[[s0-9]]* *//" ` ;;
295 esac
296 AC_SUBST(CFLAGS)
297
298 # -------------------------
299 # Check C compiler features
300 # -------------------------
301
302 AC_USE_SYSTEM_EXTENSIONS
303 AC_PROG_CPP
304 AC_C_INLINE
305
306 # sizeof(char) is 1 by definition.
307 AC_CHECK_SIZEOF(void *)
308 AC_CHECK_SIZEOF(short)
309 AC_CHECK_SIZEOF(int)
310 AC_CHECK_SIZEOF(long)
311 AC_CHECK_TYPES([long long], [AC_CHECK_SIZEOF(long long)])
312 AC_CHECK_TYPES([__int64], [AC_CHECK_SIZEOF(__int64)])
313
314 # ---------------------
315 # Warnings and checking
316 # ---------------------
317
318 # Check $CC warning features (if it's GCC).
319 # We want to use -pedantic, but we don't want warnings about
320 # * 'long long'
321 # * variadic macros
322 # * overlong strings
323 # So, we only use -pedantic if we can disable those warnings.
324
325 ACX_PROG_CC_WARNING_OPTS(
326         m4_quote(m4_do([-W -Wall -Wwrite-strings -Wstrict-prototypes ],
327                        [-Wmissing-prototypes -Wcast-qual])), [loose_warn])
328 ACX_PROG_CC_WARNING_OPTS(
329         m4_quote(m4_do([-Wold-style-definition -Wc++-compat ], 
330                        [-Wmissing-format-attribute])), [strict_warn])
331 ACX_PROG_CC_WARNING_ALMOST_PEDANTIC(
332         m4_quote(m4_do([-Wno-long-long -Wno-variadic-macros ], 
333                        [-Wno-overlength-strings])), [strict_warn])
334 ACX_PROG_CC_WARNINGS_ARE_ERRORS([manual], [strict_warn])
335
336 # The above macros do nothing if the compiler is not GCC.  However, the
337 # Makefile has more goo to add other flags, so this variabl is used to
338 # enables warnings only for GCC.
339 warn_cflags=
340 if test "x$GCC" = "xyes"; then
341   warn_cflags='$(GCC_WARN_CFLAGS)'
342 fi
343 AC_SUBST(warn_cflags)
344
345 # Enable expensive internal checks
346 is_release=
347 if test x"`cat $srcdir/DEV-PHASE`" != xexperimental; then
348   is_release=yes
349 fi
350
351 AC_ARG_ENABLE(checking,
352 [  --enable-checking[=LIST]
353                           enable expensive run-time checks.  With LIST,
354                           enable only specific categories of checks.
355                           Categories are: yes,no,all,none,release.
356                           Flags are: assert,df,fold,gc,gcac,gimple,misc,
357                           rtlflag,rtl,runtime,tree,valgrind,types.],
358 [ac_checking_flags="${enableval}"],[
359 # Determine the default checks.
360 if test x$is_release = x ; then
361   ac_checking_flags=yes
362 else
363   ac_checking_flags=release
364 fi])
365 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
366 for check in release $ac_checking_flags
367 do
368         case $check in
369         # these set all the flags to specific states
370         yes)            ac_assert_checking=1 ; ac_checking=1 ; ac_df_checking= ;
371                         ac_fold_checking= ; ac_gc_checking=1 ;
372                         ac_gc_always_collect= ; ac_gimple_checking=1 ; ac_rtl_checking= ;
373                         ac_rtlflag_checking=1 ; ac_runtime_checking=1 ;
374                         ac_tree_checking=1 ; ac_valgrind_checking= ;
375                         ac_types_checking=1 ;;
376         no|none)        ac_assert_checking= ; ac_checking= ; ac_df_checking= ;
377                         ac_fold_checking= ; ac_gc_checking= ;
378                         ac_gc_always_collect= ; ac_gimple_checking= ; ac_rtl_checking= ;
379                         ac_rtlflag_checking= ; ac_runtime_checking= ;
380                         ac_tree_checking= ; ac_valgrind_checking= ;
381                         ac_types_checking= ;;
382         all)            ac_assert_checking=1 ; ac_checking=1 ; ac_df_checking=1 ;
383                         ac_fold_checking=1 ; ac_gc_checking=1 ;
384                         ac_gc_always_collect=1 ; ac_gimple_checking=1 ; ac_rtl_checking=1 ;
385                         ac_rtlflag_checking=1 ; ac_runtime_checking=1 ;
386                         ac_tree_checking=1 ; ac_valgrind_checking= ;
387                         ac_types_checking=1 ;;
388         release)        ac_assert_checking=1 ; ac_checking= ; ac_df_checking= ;
389                         ac_fold_checking= ; ac_gc_checking= ;
390                         ac_gc_always_collect= ; ac_gimple_checking= ; ac_rtl_checking= ;
391                         ac_rtlflag_checking= ; ac_runtime_checking=1 ;
392                         ac_tree_checking= ; ac_valgrind_checking= ;
393                         ac_types_checking= ;;
394         # these enable particular checks
395         assert)         ac_assert_checking=1 ;;
396         df)             ac_df_checking=1 ;;
397         fold)           ac_fold_checking=1 ;;
398         gc)             ac_gc_checking=1 ;;
399         gcac)           ac_gc_always_collect=1 ;;
400         gimple)         ac_gimple_checking=1 ;;
401         misc)           ac_checking=1 ;;
402         rtl)            ac_rtl_checking=1 ;;
403         rtlflag)        ac_rtlflag_checking=1 ;;
404         runtime)        ac_runtime_checking=1 ;;
405         tree)           ac_tree_checking=1 ;;
406         types)          ac_types_checking=1 ;;
407         valgrind)       ac_valgrind_checking=1 ;;
408         *)      AC_MSG_ERROR(unknown check category $check) ;;
409         esac
410 done
411 IFS="$ac_save_IFS"
412
413 nocommon_flag=""
414 if test x$ac_checking != x ; then
415   AC_DEFINE(ENABLE_CHECKING, 1,
416 [Define if you want more run-time sanity checks.  This one gets a grab
417    bag of miscellaneous but relatively cheap checks.])
418   nocommon_flag=-fno-common
419 fi
420 AC_SUBST(nocommon_flag)
421 if test x$ac_df_checking != x ; then
422   AC_DEFINE(ENABLE_DF_CHECKING, 1,
423 [Define if you want more run-time sanity checks for dataflow.])
424 fi
425 if test x$ac_assert_checking != x ; then
426   AC_DEFINE(ENABLE_ASSERT_CHECKING, 1,
427 [Define if you want assertions enabled.  This is a cheap check.])
428 fi
429 if test x$ac_gimple_checking != x ; then
430   AC_DEFINE(ENABLE_GIMPLE_CHECKING, 1,
431 [Define if you want operations on GIMPLE (the basic data structure of
432 the high-level optimizers) to be checked for dynamic type safety at
433 runtime.  This is moderately expensive.])
434 fi
435 GCC_TARGET_TEMPLATE(ENABLE_RUNTIME_CHECKING)
436 if test x$ac_runtime_checking != x ; then
437   AC_DEFINE(ENABLE_RUNTIME_CHECKING, 1,
438 [Define if you want runtime assertions enabled.  This is a cheap check.])
439 fi
440 if test x$ac_tree_checking != x ; then
441   AC_DEFINE(ENABLE_TREE_CHECKING, 1,
442 [Define if you want all operations on trees (the basic data
443    structure of the front ends) to be checked for dynamic type safety
444    at runtime.  This is moderately expensive.  The tree browser debugging
445    routines will also be enabled by this option.
446    ])
447   TREEBROWSER=tree-browser.o
448 fi
449 if test x$ac_types_checking != x ; then
450   AC_DEFINE(ENABLE_TYPES_CHECKING, 1,
451 [Define if you want all gimple types to be verified after gimplifiation.
452    This is cheap.
453    ])
454 fi
455 AC_SUBST(TREEBROWSER)
456 if test x$ac_rtl_checking != x ; then
457   AC_DEFINE(ENABLE_RTL_CHECKING, 1,
458 [Define if you want all operations on RTL (the basic data structure
459    of the optimizer and back end) to be checked for dynamic type safety
460    at runtime.  This is quite expensive.])
461 fi
462 if test x$ac_rtlflag_checking != x ; then
463   AC_DEFINE(ENABLE_RTL_FLAG_CHECKING, 1,
464 [Define if you want RTL flag accesses to be checked against the RTL
465    codes that are supported for each access macro.  This is relatively
466    cheap.])
467 fi
468 if test x$ac_gc_checking != x ; then
469   AC_DEFINE(ENABLE_GC_CHECKING, 1,
470 [Define if you want the garbage collector to do object poisoning and
471    other memory allocation checks.  This is quite expensive.])
472 fi
473 if test x$ac_gc_always_collect != x ; then
474   AC_DEFINE(ENABLE_GC_ALWAYS_COLLECT, 1,
475 [Define if you want the garbage collector to operate in maximally
476    paranoid mode, validating the entire heap and collecting garbage at
477    every opportunity.  This is extremely expensive.])
478 fi
479 if test x$ac_fold_checking != x ; then
480   AC_DEFINE(ENABLE_FOLD_CHECKING, 1,
481 [Define if you want fold checked that it never destructs its argument.
482    This is quite expensive.])
483 fi
484 valgrind_path_defines=
485 valgrind_command=
486
487 dnl # This check AC_REQUIREs various stuff, so it *must not* be inside
488 dnl # an if statement.  This was the source of very frustrating bugs
489 dnl # in converting to autoconf 2.5x!
490 AC_CHECK_HEADER(valgrind.h, have_valgrind_h=yes, have_valgrind_h=no)
491
492 if test x$ac_valgrind_checking != x ; then
493   # It is certainly possible that there's valgrind but no valgrind.h.
494   # GCC relies on making annotations so we must have both.
495   AC_MSG_CHECKING(for VALGRIND_DISCARD in <valgrind/memcheck.h>)
496   AC_PREPROC_IFELSE([AC_LANG_SOURCE(
497     [[#include <valgrind/memcheck.h>
498 #ifndef VALGRIND_DISCARD
499 #error VALGRIND_DISCARD not defined
500 #endif]])],
501   [gcc_cv_header_valgrind_memcheck_h=yes],
502   [gcc_cv_header_valgrind_memcheck_h=no])
503   AC_MSG_RESULT($gcc_cv_header_valgrind_memcheck_h)
504   AC_MSG_CHECKING(for VALGRIND_DISCARD in <memcheck.h>)
505   AC_PREPROC_IFELSE([AC_LANG_SOURCE(
506     [[#include <memcheck.h>
507 #ifndef VALGRIND_DISCARD
508 #error VALGRIND_DISCARD not defined
509 #endif]])],
510   [gcc_cv_header_memcheck_h=yes],
511   [gcc_cv_header_memcheck_h=no])
512   AC_MSG_RESULT($gcc_cv_header_memcheck_h)
513   AM_PATH_PROG_WITH_TEST(valgrind_path, valgrind,
514         [$ac_dir/$ac_word --version | grep valgrind- >/dev/null 2>&1])
515   if test "x$valgrind_path" = "x" \
516     || (test $have_valgrind_h = no \
517         && test $gcc_cv_header_memcheck_h = no \
518         && test $gcc_cv_header_valgrind_memcheck_h = no); then
519         AC_MSG_ERROR([*** Can't find both valgrind and valgrind/memcheck.h, memcheck.h or valgrind.h])
520   fi
521   valgrind_path_defines=-DVALGRIND_PATH='\"'$valgrind_path'\"'
522   valgrind_command="$valgrind_path -q"
523   AC_DEFINE(ENABLE_VALGRIND_CHECKING, 1,
524 [Define if you want to run subprograms and generated programs
525    through valgrind (a memory checker).  This is extremely expensive.])
526   if test $gcc_cv_header_valgrind_memcheck_h = yes; then
527     AC_DEFINE(HAVE_VALGRIND_MEMCHECK_H, 1,
528         [Define if valgrind's valgrind/memcheck.h header is installed.])
529   fi
530   if test $gcc_cv_header_memcheck_h = yes; then
531     AC_DEFINE(HAVE_MEMCHECK_H, 1,
532         [Define if valgrind's memcheck.h header is installed.])
533   fi
534 fi
535 AC_SUBST(valgrind_path_defines)
536 AC_SUBST(valgrind_command)
537
538 # Enable code coverage collection
539 AC_ARG_ENABLE(coverage,
540 [  --enable-coverage[=LEVEL]
541                           enable compiler's code coverage collection.
542                           Use to measure compiler performance and locate
543                           unused parts of the compiler. With LEVEL, specify
544                           optimization. Values are opt, noopt,
545                           default is noopt],
546 [case "${enableval}" in
547   yes|noopt)
548     coverage_flags="-fprofile-arcs -ftest-coverage -frandom-seed=\$@ -O0"
549     ;;
550   opt)
551     coverage_flags="-fprofile-arcs -ftest-coverage -frandom-seed=\$@ -O2"
552     ;;
553   no)
554     # a.k.a. --disable-coverage
555     coverage_flags=""
556     ;;
557   *)
558     AC_MSG_ERROR(unknown coverage setting $enableval)
559     ;;
560 esac],
561 [coverage_flags=""])
562 AC_SUBST(coverage_flags)
563
564 AC_ARG_ENABLE(gather-detailed-mem-stats, 
565 [  --enable-gather-detailed-mem-stats         enable detailed memory allocation stats gathering], [],
566 [enable_gather_detailed_mem_stats=no])
567 if test x$enable_gather_detailed_mem_stats = xyes ; then
568   AC_DEFINE(GATHER_STATISTICS, 1,
569         [Define to enable detailed memory allocation stats gathering.])
570 fi
571
572 # -------------------------------
573 # Miscenalleous configure options
574 # -------------------------------
575
576 # With stabs
577 AC_ARG_WITH(stabs,
578 [  --with-stabs            arrange to use stabs instead of host debug format],
579 stabs="$with_stabs",
580 stabs=no)
581
582 # Determine whether or not multilibs are enabled.
583 AC_ARG_ENABLE(multilib,
584 [  --enable-multilib       enable library support for multiple ABIs],
585 [], [enable_multilib=yes])
586 AC_SUBST(enable_multilib)
587
588 # Enable __cxa_atexit for C++.
589 AC_ARG_ENABLE(__cxa_atexit,
590 [  --enable-__cxa_atexit   enable __cxa_atexit for C++],
591 [], [])
592
593 # Enable C extension for decimal float if target supports it.
594 AC_ARG_ENABLE(decimal-float,
595 [  --enable-decimal-float={no,yes,bid,dpd}
596                         enable decimal float extension to C.  Selecting 'bid'
597                         or 'dpd' choses which decimal floating point format
598                         to use],
599 [
600   case $enable_decimal_float in
601     yes | no | bid | dpd) ;;
602     *) AC_MSG_ERROR(['$enable_decimal_float' is an invalid value for --enable-decimal-float.
603 Valid choices are 'yes', 'bid', 'dpd', and 'no'.]) ;;
604   esac
605 ],
606 [
607   case $target in
608     powerpc*-*-linux* | i?86*-*-linux* | x86_64*-*-linux*)
609       enable_decimal_float=yes
610       ;;
611     *)
612       AC_MSG_WARN(decimal float is not supported for this target, ignored)
613       enable_decimal_float=no
614       ;;
615   esac
616 ])
617
618 dfp=`if test $enable_decimal_float != no; then echo 1; else echo 0; fi`
619 AC_DEFINE_UNQUOTED(ENABLE_DECIMAL_FLOAT, $dfp,
620 [Define to 1 to enable decimal float extension to C.])
621
622 # x86's use BID format instead of DPD
623 case x$enable_decimal_float in
624   xyes)
625     case $target in
626       i?86*-*-linux* | x86_64*-*-linux*)
627         enable_decimal_float=bid
628         ;;
629       *)
630         enable_decimal_float=dpd
631         ;;
632     esac
633     ;;
634   xno)
635     # ENABLE_DECIMAL_FLOAT is set to 0. But we have to have proper
636     # dependency on libdecnumber.
637     enable_decimal_float=dpd
638     ;;
639 esac
640 AC_SUBST(enable_decimal_float)
641
642 bid=`if test $enable_decimal_float = bid; then echo 1; else echo 0; fi`
643 AC_DEFINE_UNQUOTED(ENABLE_DECIMAL_BID_FORMAT, $bid,
644 [Define to 1 to specify that we are using the BID decimal floating
645 point format instead of DPD])
646
647 # Enable C extension for fixed-point arithmetic.
648 AC_ARG_ENABLE(fixed-point,
649 [  --enable-fixed-point    enable fixed-point arithmetic extension to C],
650 [
651 ],
652 [
653   case $target in
654     mips*-*-*)
655       case $host in
656         mips*-sgi-irix*)
657           AC_MSG_WARN(fixed-point is not supported on IRIX, ignored)
658           enable_fixed_point=no
659           ;;
660         *)
661           enable_fixed_point=yes
662           ;;
663       esac
664       ;;
665     *)
666       AC_MSG_WARN(fixed-point is not supported for this target, ignored)
667       enable_fixed_point=no
668       ;;
669   esac
670 ])
671 AC_SUBST(enable_fixed_point)
672
673 fixedpoint=`if test $enable_fixed_point = yes; then echo 1; else echo 0; fi`
674 AC_DEFINE_UNQUOTED(ENABLE_FIXED_POINT, $fixedpoint,
675 [Define to 1 to enable fixed-point arithmetic extension to C.])
676
677 # Enable threads
678 # Pass with no value to take the default
679 # Pass with a value to specify a thread package
680 AC_ARG_ENABLE(threads,
681 [  --enable-threads        enable thread usage for target GCC
682   --enable-threads=LIB    use LIB thread package for target GCC],,
683 [enable_threads=''])
684
685 AC_ARG_ENABLE(tls,
686 [  --enable-tls            enable or disable generation of tls code
687                           overriding the assembler check for tls support],
688 [
689   case $enable_tls in
690     yes | no) ;;
691     *) AC_MSG_ERROR(['$enable_tls' is an invalid value for --enable-tls.
692 Valid choices are 'yes' and 'no'.]) ;;
693   esac
694 ], [enable_tls=''])
695
696 AC_ARG_ENABLE(objc-gc,
697 [  --enable-objc-gc       enable the use of Boehm's garbage collector with
698                           the GNU Objective-C runtime],
699 if test x$enable_objc_gc = xno; then
700         objc_boehm_gc=''
701 else
702         objc_boehm_gc=1
703 fi,
704 objc_boehm_gc='')
705
706 AC_ARG_WITH(dwarf2,
707 [  --with-dwarf2           force the default debug format to be DWARF 2],
708 dwarf2="$with_dwarf2",
709 dwarf2=no)
710
711 AC_ARG_ENABLE(shared,
712 [  --disable-shared        don't provide a shared libgcc],
713 [
714   case $enable_shared in
715   yes | no) ;;
716   *)
717     enable_shared=no
718     IFS="${IFS=         }"; ac_save_ifs="$IFS"; IFS="${IFS}:,"
719     for pkg in $enableval; do
720       if test "X$pkg" = "Xgcc" || test "X$pkg" = "Xlibgcc"; then
721         enable_shared=yes
722       fi
723     done
724     IFS="$ac_save_ifs"
725     ;;
726   esac
727 ], [enable_shared=yes])
728 AC_SUBST(enable_shared)
729
730 AC_ARG_WITH(build-sysroot, 
731   [  --with-build-sysroot=sysroot
732                           use sysroot as the system root during the build])
733
734 AC_ARG_WITH(sysroot,
735 [  --with-sysroot[=DIR] Search for usr/lib, usr/include, et al, within DIR.],
736 [
737  case ${with_sysroot} in
738  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_noncanonical}/sys-root' ;;
739  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
740  esac
741    
742  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
743  CROSS_SYSTEM_HEADER_DIR='$(TARGET_SYSTEM_ROOT)$${sysroot_headers_suffix}$(NATIVE_SYSTEM_HEADER_DIR)'
744         
745  if test "x$prefix" = xNONE; then
746   test_prefix=/usr/local
747  else
748   test_prefix=$prefix
749  fi
750  if test "x$exec_prefix" = xNONE; then
751   test_exec_prefix=$test_prefix
752  else
753   test_exec_prefix=$exec_prefix
754  fi
755  case ${TARGET_SYSTEM_ROOT} in
756  "${test_prefix}"|"${test_prefix}/"*|\
757  "${test_exec_prefix}"|"${test_exec_prefix}/"*|\
758  '${prefix}'|'${prefix}/'*|\
759  '${exec_prefix}'|'${exec_prefix}/'*)
760    t="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE"
761    TARGET_SYSTEM_ROOT_DEFINE="$t"
762    ;;
763  esac
764 ], [
765  TARGET_SYSTEM_ROOT=
766  TARGET_SYSTEM_ROOT_DEFINE=
767  CROSS_SYSTEM_HEADER_DIR='$(gcc_tooldir)/sys-include'
768 ])
769 AC_SUBST(TARGET_SYSTEM_ROOT)
770 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
771 AC_SUBST(CROSS_SYSTEM_HEADER_DIR)
772
773 # Build with intermodule optimisations
774 AC_ARG_ENABLE(intermodule,
775 [  --enable-intermodule    build the compiler in one step],
776 [case ${enable_intermodule} in
777   yes) onestep="-onestep";;
778   *) onestep="";;
779 esac],
780 [onestep=""])
781 AC_SUBST(onestep)
782
783 ACX_PKGVERSION([GCC])
784 ACX_BUGURL([http://gcc.gnu.org/bugs.html])
785
786 # Sanity check enable_languages in case someone does not run the toplevel
787 # configure # script.
788 AC_ARG_ENABLE(languages,
789 [  --enable-languages=LIST specify which front-ends to build],
790 [case ,${enable_languages}, in
791        ,,|,yes,)
792                 # go safe -- we cannot be much sure without the toplevel
793                 # configure's
794                 # analysis of which target libs are present and usable
795                 enable_languages=c
796                 ;;
797          *,all,*)
798                 AC_MSG_ERROR([only the toplevel supports --enable-languages=all])
799                 ;;
800         *,c,*)
801                 ;;
802         *)
803                 enable_languages=c,${enable_languages}
804                 ;;
805 esac],
806 [enable_languages=c])
807
808 # Used by documentation targets
809 AC_SUBST(datarootdir)
810 AC_SUBST(docdir)
811 AC_SUBST(htmldir)
812
813 AC_ARG_WITH(multilib-list,
814 [  --with-multilib-list    Select multilibs (SH only)],
815 :,
816 with_multilib_list=default)
817
818 # -------------------------
819 # Checks for other programs
820 # -------------------------
821
822 AC_PROG_MAKE_SET
823
824 # Find some useful tools
825 AC_PROG_AWK
826 # We need awk to create options.c and options.h.
827 # Bail out if it's missing.
828 case ${AWK} in
829   "") AC_MSG_ERROR([can't build without awk, bailing out]) ;;
830 esac
831
832 gcc_AC_PROG_LN_S
833 ACX_PROG_LN($LN_S)
834 AC_PROG_RANLIB
835 case "${host}" in
836 *-*-darwin*)
837   # By default, the Darwin ranlib will not treat common symbols as
838   # definitions when  building the archive table of contents.  Other 
839   # ranlibs do that; pass an option to the Darwin ranlib that makes
840   # it behave similarly.
841   ranlib_flags="-c" 
842   ;;
843 *)
844   ranlib_flags=""
845 esac
846 AC_SUBST(ranlib_flags)
847      
848 gcc_AC_PROG_INSTALL
849
850 # See if cmp has --ignore-initial.
851 gcc_AC_PROG_CMP_IGNORE_INITIAL
852
853 # See if we have the mktemp command.
854 AC_CHECK_PROG(have_mktemp_command, mktemp, yes, no)
855
856 # See if makeinfo has been installed and is modern enough
857 # that we can use it.
858 ACX_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
859   [GNU texinfo.* \([0-9][0-9.]*\)],
860   [4.[7-9]*|4.[1-9][0-9]*|[5-9]*|[1-9][0-9]*])
861 if test $gcc_cv_prog_makeinfo_modern = no; then
862   AC_MSG_WARN([
863 *** Makeinfo is missing or too old.
864 *** Info documentation will not be built.])
865   BUILD_INFO=
866 else
867   BUILD_INFO=info
868 fi
869 AC_SUBST(BUILD_INFO)
870
871 # Is pod2man recent enough to regenerate manpages?
872 AC_MSG_CHECKING([for recent Pod::Man])
873 if (perl -e 'use 1.10 Pod::Man') >/dev/null 2>&1; then
874   AC_MSG_RESULT(yes)
875   GENERATED_MANPAGES=generated-manpages
876 else
877   AC_MSG_RESULT(no)
878   GENERATED_MANPAGES=
879 fi
880 AC_SUBST(GENERATED_MANPAGES)
881
882 MISSING="${CONFIG_SHELL-/bin/sh} $ac_aux_dir/missing"
883
884 # How about lex?
885 dnl Don't use AC_PROG_LEX; we insist on flex.
886 dnl LEXLIB is not useful in gcc.
887 AC_CHECK_PROGS([FLEX], flex, [$MISSING flex])
888
889 # Bison?
890 AC_CHECK_PROGS([BISON], bison, [$MISSING bison])
891
892 # Binutils are not build modules, unlike bison/flex/makeinfo.  So we
893 # check for build == host before using them.
894
895 # NM
896 if test x${build} = x${host} && test -f $srcdir/../binutils/nm.c \
897   && test -d ../binutils ; then
898   NM='$(objdir)/../binutils/nm-new'
899 else
900   AC_CHECK_PROG(NM, nm, nm, ${CONFIG_SHELL-/bin/sh} ${srcdir}/../missing nm)
901 fi
902
903 # AR
904 if test x${build} = x${host} && test -f $srcdir/../binutils/ar.c \
905   && test -d ../binutils ; then
906   AR='$(objdir)/../binutils/ar'
907 else
908   AC_CHECK_PROG(AR, ar, ar, ${CONFIG_SHELL-/bin/sh} ${srcdir}/../missing ar)
909 fi
910
911
912 # --------------------
913 # Checks for C headers
914 # --------------------
915
916 # Need to reject headers which give warnings, so that the -Werror bootstrap
917 # works later. *sigh*  This needs to come before all header checks.
918 AC_PROG_CPP_WERROR
919
920 AC_HEADER_STDC
921 AC_HEADER_TIME
922 ACX_HEADER_STRING
923 AC_HEADER_SYS_WAIT
924 AC_CHECK_HEADERS(limits.h stddef.h string.h strings.h stdlib.h time.h iconv.h \
925                  fcntl.h unistd.h sys/file.h sys/time.h sys/mman.h \
926                  sys/resource.h sys/param.h sys/times.h sys/stat.h \
927                  direct.h malloc.h langinfo.h ldfcn.h locale.h wchar.h)
928
929 # Check for thread headers.
930 AC_CHECK_HEADER(thread.h, [have_thread_h=yes], [have_thread_h=])
931 AC_CHECK_HEADER(pthread.h, [have_pthread_h=yes], [have_pthread_h=])
932
933 # These tests can't be done till we know if we have limits.h.
934 gcc_AC_C_CHAR_BIT
935 AC_C_BIGENDIAN
936
937 # --------
938 # UNSORTED
939 # --------
940
941
942 # These libraries may be used by collect2.
943 # We may need a special search path to get them linked.
944 AC_CACHE_CHECK(for collect2 libraries, gcc_cv_collect2_libs,
945 [save_LIBS="$LIBS"
946 for libs in '' -lld -lmld \
947                 '-L/usr/lib/cmplrs/cc2.11 -lmld' \
948                 '-L/usr/lib/cmplrs/cc3.11 -lmld'
949 do
950         LIBS="$libs"
951         AC_TRY_LINK_FUNC(ldopen,
952                 [gcc_cv_collect2_libs="$libs"; break])
953 done
954 LIBS="$save_LIBS"
955 test -z "$gcc_cv_collect2_libs" && gcc_cv_collect2_libs='none required'])
956 case $gcc_cv_collect2_libs in
957         "none required")        ;;
958         *)      COLLECT2_LIBS=$gcc_cv_collect2_libs ;;
959 esac
960 AC_SUBST(COLLECT2_LIBS)
961
962 # When building Ada code on Alpha, we need exc_resume which is usually in
963 # -lexc.  So test for it.
964 save_LIBS="$LIBS"
965 LIBS=
966 AC_SEARCH_LIBS(exc_resume, exc)
967 GNAT_LIBEXC="$LIBS"
968 LIBS="$save_LIBS"
969 AC_SUBST(GNAT_LIBEXC)
970
971 # Some systems put ldexp and frexp in libm instead of libc; assume
972 # they're both in the same place.  jcf-dump needs them.
973 save_LIBS="$LIBS"
974 LIBS=
975 AC_SEARCH_LIBS(ldexp, m)
976 LDEXP_LIB="$LIBS"
977 LIBS="$save_LIBS"
978 AC_SUBST(LDEXP_LIB)
979
980 # Use <inttypes.h> only if it exists,
981 # doesn't clash with <sys/types.h>, and declares intmax_t.
982 AC_MSG_CHECKING(for inttypes.h)
983 AC_CACHE_VAL(gcc_cv_header_inttypes_h,
984 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
985 [[#include <sys/types.h>
986 #include <inttypes.h>]],
987   [[intmax_t i = -1;]])],
988   [gcc_cv_header_inttypes_h=yes],
989   [gcc_cv_header_inttypes_h=no])])
990 AC_MSG_RESULT($gcc_cv_header_inttypes_h)
991 if test $gcc_cv_header_inttypes_h = yes; then
992   AC_DEFINE(HAVE_INTTYPES_H, 1,
993         [Define if you have a working <inttypes.h> header file.])
994 fi
995
996 dnl Disabled until we have a complete test for buggy enum bitfields.
997 dnl gcc_AC_C_ENUM_BF_UNSIGNED
998
999 define(gcc_UNLOCKED_FUNCS, clearerr_unlocked feof_unlocked dnl
1000   ferror_unlocked fflush_unlocked fgetc_unlocked fgets_unlocked dnl
1001   fileno_unlocked fprintf_unlocked fputc_unlocked fputs_unlocked dnl
1002   fread_unlocked fwrite_unlocked getchar_unlocked getc_unlocked dnl
1003   putchar_unlocked putc_unlocked)
1004 AC_CHECK_FUNCS(times clock kill getrlimit setrlimit atoll atoq \
1005         sysconf strsignal getrusage nl_langinfo \
1006         gettimeofday mbstowcs wcswidth mmap mincore setlocale \
1007         gcc_UNLOCKED_FUNCS)
1008
1009 if test x$ac_cv_func_mbstowcs = xyes; then
1010   AC_CACHE_CHECK(whether mbstowcs works, gcc_cv_func_mbstowcs_works,
1011 [    AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdlib.h>
1012 int main()
1013 {
1014   mbstowcs(0, "", 0);
1015   return 0;
1016 }]])],
1017     [gcc_cv_func_mbstowcs_works=yes],
1018     [gcc_cv_func_mbstowcs_works=no],
1019     [gcc_cv_func_mbstowcs_works=yes])])
1020   if test x$gcc_cv_func_mbstowcs_works = xyes; then
1021     AC_DEFINE(HAVE_WORKING_MBSTOWCS, 1,
1022   [Define this macro if mbstowcs does not crash when its
1023    first argument is NULL.])
1024   fi
1025 fi
1026
1027 AC_CHECK_TYPE(ssize_t, int)
1028 AC_CHECK_TYPE(caddr_t, char *)
1029
1030 gcc_AC_FUNC_MMAP_BLACKLIST
1031
1032 case "${host}" in
1033 *-*-*vms*)
1034   # Under VMS, vfork works very differently than on Unix. The standard test 
1035   # won't work, and it isn't easily adaptable. It makes more sense to
1036   # just force it.
1037   ac_cv_func_vfork_works=yes
1038   ;;
1039 esac
1040 AC_FUNC_FORK
1041
1042 AM_ICONV
1043 # Until we have in-tree GNU iconv:
1044 LIBICONV_DEP=
1045 AC_SUBST(LIBICONV_DEP)
1046
1047 AM_LC_MESSAGES
1048
1049 AM_LANGINFO_CODESET
1050
1051 # We will need to find libiberty.h and ansidecl.h
1052 saved_CFLAGS="$CFLAGS"
1053 CFLAGS="$CFLAGS -I${srcdir} -I${srcdir}/../include"
1054 gcc_AC_CHECK_DECLS(getenv atol asprintf sbrk abort atof getcwd getwd \
1055         strsignal strstr strverscmp \
1056         errno snprintf vsnprintf vasprintf malloc realloc calloc \
1057         free basename getopt clock getpagesize gcc_UNLOCKED_FUNCS, , ,[
1058 #include "ansidecl.h"
1059 #include "system.h"])
1060
1061 gcc_AC_CHECK_DECLS(getrlimit setrlimit getrusage, , ,[
1062 #include "ansidecl.h"
1063 #include "system.h"
1064 #ifdef HAVE_SYS_RESOURCE_H
1065 #include <sys/resource.h>
1066 #endif
1067 ])
1068
1069 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1070 #include "ansidecl.h"
1071 #include "system.h"
1072 #ifdef HAVE_SYS_RESOURCE_H
1073 #include <sys/resource.h>
1074 #endif
1075 ]], [[rlim_t l = 0;]])],[],[AC_DEFINE([rlim_t],[long],
1076 [Define to `long' if <sys/resource.h> doesn't define.])])
1077
1078 # On AIX 5.2, <ldfcn.h> conflicts with <fcntl.h>, as both define incompatible
1079 # FREAD and FWRITE macros.  Fortunately, for GCC's single usage of ldgetname
1080 # in collect2.c, <fcntl.h> isn't visible, but the configure test below needs
1081 # to undef these macros to get the correct value for HAVE_DECL_LDGETNAME.
1082 gcc_AC_CHECK_DECLS(ldgetname, , ,[
1083 #include "ansidecl.h"
1084 #include "system.h"
1085 #ifdef HAVE_LDFCN_H
1086 #undef FREAD
1087 #undef FWRITE
1088 #include <ldfcn.h>
1089 #endif
1090 ])
1091
1092 gcc_AC_CHECK_DECLS(times, , ,[
1093 #include "ansidecl.h"
1094 #include "system.h"
1095 #ifdef HAVE_SYS_TIMES_H
1096 #include <sys/times.h>
1097 #endif
1098 ])
1099
1100 gcc_AC_CHECK_DECLS(sigaltstack, , ,[
1101 #include "ansidecl.h"
1102 #include "system.h"
1103 #include <signal.h>
1104 ])
1105
1106 # More time-related stuff.
1107 AC_CACHE_CHECK(for struct tms, ac_cv_struct_tms, [
1108 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1109 #include "ansidecl.h"
1110 #include "system.h"
1111 #ifdef HAVE_SYS_TIMES_H
1112 #include <sys/times.h>
1113 #endif
1114 ]], [[struct tms tms;]])],[ac_cv_struct_tms=yes],[ac_cv_struct_tms=no])])
1115 if test $ac_cv_struct_tms = yes; then
1116   AC_DEFINE(HAVE_STRUCT_TMS, 1,
1117   [Define if <sys/times.h> defines struct tms.])
1118 fi
1119
1120 # use gcc_cv_* here because this doesn't match the behavior of AC_CHECK_TYPE.
1121 # revisit after autoconf 2.50.
1122 AC_CACHE_CHECK(for clock_t, gcc_cv_type_clock_t, [
1123 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1124 #include "ansidecl.h"
1125 #include "system.h"
1126 ]], [[clock_t x;]])],[gcc_cv_type_clock_t=yes],[gcc_cv_type_clock_t=no])])
1127 if test $gcc_cv_type_clock_t = yes; then
1128   AC_DEFINE(HAVE_CLOCK_T, 1,
1129   [Define if <time.h> defines clock_t.])
1130 fi
1131
1132 # Restore CFLAGS from before the gcc_AC_NEED_DECLARATIONS tests.
1133 CFLAGS="$saved_CFLAGS"
1134
1135 gcc_AC_INITFINI_ARRAY
1136
1137 # mkdir takes a single argument on some systems. 
1138 gcc_AC_FUNC_MKDIR_TAKES_ONE_ARG
1139
1140 # File extensions
1141 manext='.1'
1142 objext='.o'
1143 AC_SUBST(manext)
1144 AC_SUBST(objext)
1145
1146 # With Setjmp/Longjmp based exception handling.
1147 AC_ARG_ENABLE(sjlj-exceptions,
1148 [  --enable-sjlj-exceptions
1149                           arrange to use setjmp/longjmp exception handling],
1150 [case $target in
1151   *-*-hpux10*)
1152     if test $enableval != yes; then
1153       AC_MSG_WARN([dwarf2 exceptions not supported, sjlj exceptions forced])
1154       enableval=yes
1155     fi
1156     ;;
1157 esac
1158 force_sjlj_exceptions=yes],
1159 [case $target in
1160   *-*-hpux10*)
1161     force_sjlj_exceptions=yes
1162     enableval=yes
1163     ;;
1164   *)
1165     force_sjlj_exceptions=no
1166     ;;
1167 esac])
1168 if test $force_sjlj_exceptions = yes; then
1169   sjlj=`if test $enableval = yes; then echo 1; else echo 0; fi`
1170   AC_DEFINE_UNQUOTED(CONFIG_SJLJ_EXCEPTIONS, $sjlj,
1171     [Define 0/1 to force the choice for exception handling model.])
1172 fi
1173
1174 # For platforms with the unwind ABI which includes an unwind library,
1175 # libunwind, we can choose to use the system libunwind.
1176 # config.gcc also contains tests of with_system_libunwind.
1177 GCC_CHECK_UNWIND_GETIPINFO
1178
1179 # --------------------------------------------------------
1180 # Build, host, and target specific configuration fragments
1181 # --------------------------------------------------------
1182
1183 # Collect build-machine-specific information.
1184 . ${srcdir}/config.build
1185
1186 # Collect host-machine-specific information.
1187 . ${srcdir}/config.host
1188
1189 target_gtfiles=
1190
1191 # Collect target-machine-specific information.
1192 . ${srcdir}/config.gcc
1193
1194 extra_objs="${host_extra_objs} ${extra_objs}"
1195 extra_gcc_objs="${host_extra_gcc_objs} ${extra_gcc_objs}"
1196
1197 # Default the target-machine variables that were not explicitly set.
1198 if test x"$tm_file" = x
1199 then tm_file=$cpu_type/$cpu_type.h; fi
1200
1201 if test x"$extra_headers" = x
1202 then extra_headers=; fi
1203
1204 if test x$md_file = x
1205 then md_file=$cpu_type/$cpu_type.md; fi
1206
1207 if test x$out_file = x
1208 then out_file=$cpu_type/$cpu_type.c; fi
1209
1210 if test x"$tmake_file" = x
1211 then tmake_file=$cpu_type/t-$cpu_type
1212 fi
1213
1214 if test x"$dwarf2" = xyes
1215 then tm_file="$tm_file tm-dwarf2.h"
1216 fi
1217
1218 # Say what files are being used for the output code and MD file.
1219 echo "Using \`$srcdir/config/$out_file' for machine-specific logic."
1220 echo "Using \`$srcdir/config/$md_file' as machine description file."
1221
1222 # If any of the xm_file variables contain nonexistent files, warn
1223 # about them and drop them.
1224
1225 bx=
1226 for x in $build_xm_file; do
1227   if    test -f $srcdir/config/$x
1228   then      bx="$bx $x"
1229   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1230   fi
1231 done
1232 build_xm_file="$bx"
1233
1234 hx=
1235 for x in $host_xm_file; do
1236   if    test -f $srcdir/config/$x
1237   then      hx="$hx $x"
1238   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1239   fi
1240 done
1241 host_xm_file="$hx"
1242
1243 tx=
1244 for x in $xm_file; do
1245   if    test -f $srcdir/config/$x
1246   then      tx="$tx $x"
1247   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1248   fi
1249 done
1250 xm_file="$tx"
1251
1252 count=a
1253 for f in $tm_file; do
1254         count=${count}x
1255 done
1256 if test $count = ax; then
1257         echo "Using \`$srcdir/config/$tm_file' as target machine macro file."
1258 else
1259         echo "Using the following target machine macro files:"
1260         for f in $tm_file; do
1261                 echo "  $srcdir/config/$f"
1262         done
1263 fi
1264
1265 if test x$need_64bit_hwint = xyes; then
1266         AC_DEFINE(NEED_64BIT_HOST_WIDE_INT, 1,
1267 [Define to 1 if HOST_WIDE_INT must be 64 bits wide (see hwint.h).])
1268 fi
1269
1270 if test x$use_long_long_for_widest_fast_int = xyes; then
1271         AC_DEFINE(USE_LONG_LONG_FOR_WIDEST_FAST_INT, 1,
1272 [Define to 1 if the 'long long' (or '__int64') is wider than 'long' but still
1273 efficiently supported by the host hardware.])
1274 fi
1275
1276 count=a
1277 for f in $host_xm_file; do
1278         count=${count}x
1279 done
1280 if test $count = a; then
1281         :
1282 elif test $count = ax; then
1283         echo "Using \`$srcdir/config/$host_xm_file' as host machine macro file."
1284 else
1285         echo "Using the following host machine macro files:"
1286         for f in $host_xm_file; do
1287                 echo "  $srcdir/config/$f"
1288         done
1289 fi
1290 echo "Using ${out_host_hook_obj} for host machine hooks."
1291
1292 if test "$host_xm_file" != "$build_xm_file"; then
1293         count=a
1294         for f in $build_xm_file; do
1295                 count=${count}x
1296         done
1297         if test $count = a; then
1298                 :
1299         elif test $count = ax; then
1300                 echo "Using \`$srcdir/config/$build_xm_file' as build machine macro file."
1301         else
1302                 echo "Using the following build machine macro files:"
1303                 for f in $build_xm_file; do
1304                         echo "  $srcdir/config/$f"
1305                 done
1306         fi
1307 fi
1308
1309 case ${host} in
1310   powerpc*-*-darwin*)
1311     AC_CACHE_CHECK([whether mcontext_t fields have underscores],
1312       gcc_cv_mcontext_underscores,
1313       AC_COMPILE_IFELSE([
1314 #include <sys/cdefs.h>
1315 #include <sys/signal.h>
1316 #include <ucontext.h>
1317 int main() { mcontext_t m; if (m->ss.srr0) return 0; return 0; }
1318 ],
1319         gcc_cv_mcontext_underscores=no, gcc_cv_mcontext_underscores=yes))
1320       if test $gcc_cv_mcontext_underscores = yes; then
1321         AC_DEFINE(HAS_MCONTEXT_T_UNDERSCORES,,dnl
1322           [mcontext_t fields start with __])
1323       fi
1324     ;;
1325 esac
1326
1327 # ---------
1328 # Threading
1329 # ---------
1330
1331 # Check if a valid thread package
1332 case ${enable_threads} in
1333   "" | no)
1334     # No threads
1335     target_thread_file='single'
1336     ;;
1337   yes)
1338     # default
1339     target_thread_file='single'
1340     ;;
1341   aix | dce | gnat | irix | posix | posix95 | rtems | \
1342   single | solaris | vxworks | win32 | mipssde)
1343     target_thread_file=${enable_threads}
1344     ;;
1345   *)
1346     echo "${enable_threads} is an unknown thread package" 1>&2
1347     exit 1
1348     ;;
1349 esac
1350
1351 if test x${thread_file} = x; then
1352   # No thread file set by target-specific clauses in config.gcc,
1353   # so use file chosen by default logic above
1354   thread_file=${target_thread_file}
1355 fi
1356
1357 # Make gthr-default.h if we have a thread file.
1358 gthread_flags=
1359 if test $thread_file != single; then
1360   echo "#include \"gthr-${thread_file}.h\"" > gthr-default.h-t
1361   if diff gthr-default.h-t gthr-default.h 2>/dev/null; then
1362     rm -f gthr-default.h-t
1363   else
1364     mv -f gthr-default.h-t gthr-default.h
1365   fi
1366   gthread_flags=-DHAVE_GTHR_DEFAULT
1367 fi
1368 AC_SUBST(gthread_flags)
1369
1370 # --------
1371 # UNSORTED
1372 # --------
1373
1374 use_cxa_atexit=no
1375 if test x$enable___cxa_atexit = xyes || \
1376    test x$enable___cxa_atexit = x -a x$default_use_cxa_atexit = xyes; then
1377   if test x$host = x$target; then
1378     case $host in
1379       # mingw32 doesn't have __cxa_atexit but uses atexit registration
1380       # keyed to flag_use_cxa_atexit
1381       *-*-mingw32*)
1382         use_cxa_atexit=yes
1383         ;;
1384       *)
1385         AC_CHECK_FUNC(__cxa_atexit,[use_cxa_atexit=yes],
1386           [echo "__cxa_atexit can't be enabled on this target"])
1387         ;;
1388     esac
1389   else
1390     # We can't check for __cxa_atexit when building a cross, so assume
1391     # it is available 
1392     use_cxa_atexit=yes
1393   fi
1394   if test x$use_cxa_atexit = xyes; then
1395     AC_DEFINE(DEFAULT_USE_CXA_ATEXIT, 2,
1396       [Define if you want to use __cxa_atexit, rather than atexit, to
1397       register C++ destructors for local statics and global objects.
1398       This is essential for fully standards-compliant handling of
1399       destructors, but requires __cxa_atexit in libc.])
1400   fi
1401 fi
1402
1403 # Look for a file containing extra machine modes.
1404 if test -n "$extra_modes" && test -f $srcdir/config/$extra_modes; then
1405   extra_modes_file='$(srcdir)'/config/${extra_modes}
1406   AC_SUBST(extra_modes_file)
1407   AC_DEFINE_UNQUOTED(EXTRA_MODES_FILE, "config/$extra_modes",
1408   [Define to the name of a file containing a list of extra machine modes
1409    for this architecture.])
1410 fi
1411
1412 # Convert extra_options into a form suitable for Makefile use.
1413 extra_opt_files=
1414 for f in $extra_options; do
1415   extra_opt_files="$extra_opt_files \$(srcdir)/config/$f"
1416 done
1417 AC_SUBST(extra_opt_files)
1418
1419 # auto-host.h is the file containing items generated by autoconf and is
1420 # the first file included by config.h.
1421 # If host=build, it is correct to have bconfig include auto-host.h
1422 # as well.  If host!=build, we are in error and need to do more 
1423 # work to find out the build config parameters.
1424 if test x$host = x$build
1425 then
1426         build_auto=auto-host.h
1427 else
1428         # We create a subdir, then run autoconf in the subdir.
1429         # To prevent recursion we set host and build for the new
1430         # invocation of configure to the build for this invocation
1431         # of configure. 
1432         tempdir=build.$$
1433         rm -rf $tempdir
1434         mkdir $tempdir
1435         cd $tempdir
1436         case ${srcdir} in
1437         /* | [A-Za-z]:[\\/]* ) realsrcdir=${srcdir};;
1438         *) realsrcdir=../${srcdir};;
1439         esac
1440         saved_CFLAGS="${CFLAGS}"
1441         CC="${CC_FOR_BUILD}" CFLAGS="${CFLAGS_FOR_BUILD}" \
1442         LDFLAGS="${LDFLAGS_FOR_BUILD}" \
1443         ${realsrcdir}/configure \
1444                 --enable-languages=${enable_languages-all} \
1445                 --target=$target_alias --host=$build_alias --build=$build_alias
1446         CFLAGS="${saved_CFLAGS}"
1447
1448         # We just finished tests for the build machine, so rename
1449         # the file auto-build.h in the gcc directory.
1450         mv auto-host.h ../auto-build.h
1451         cd ..
1452         rm -rf $tempdir
1453         build_auto=auto-build.h
1454 fi
1455 AC_SUBST(build_subdir)
1456
1457 tm_file="${tm_file} defaults.h"
1458 tm_p_file="${tm_p_file} tm-preds.h"
1459 host_xm_file="auto-host.h ansidecl.h ${host_xm_file}"
1460 build_xm_file="${build_auto} ansidecl.h ${build_xm_file}"
1461 # We don't want ansidecl.h in target files, write code there in ISO/GNU C.
1462 # put this back in temporarily.
1463 xm_file="auto-host.h ansidecl.h ${xm_file}"
1464
1465 # --------
1466 # UNSORTED
1467 # --------
1468
1469 changequote(,)dnl
1470 # Compile in configure arguments.
1471 if test -f configargs.h ; then
1472         # Being re-configured.
1473         gcc_config_arguments=`grep configuration_arguments configargs.h | sed -e 's/.*"\([^"]*\)".*/\1/'`
1474         gcc_config_arguments="$gcc_config_arguments : (reconfigured) $TOPLEVEL_CONFIGURE_ARGUMENTS"
1475 else
1476         gcc_config_arguments="$TOPLEVEL_CONFIGURE_ARGUMENTS"
1477 fi
1478
1479 # Double all backslashes and backslash all quotes to turn
1480 # gcc_config_arguments into a C string.
1481 sed -e 's/\\/\\\\/g; s/"/\\"/g' <<EOF >conftest.out
1482 $gcc_config_arguments
1483 EOF
1484 gcc_config_arguments_str=`cat conftest.out`
1485 rm -f conftest.out
1486
1487 cat > configargs.h <<EOF
1488 /* Generated automatically. */
1489 static const char configuration_arguments[] = "$gcc_config_arguments_str";
1490 static const char thread_model[] = "$thread_file";
1491
1492 static const struct {
1493   const char *name, *value;
1494 } configure_default_options[] = $configure_default_options;
1495 EOF
1496 changequote([,])dnl
1497
1498 changequote(,)dnl
1499 gcc_BASEVER=`cat $srcdir/BASE-VER`
1500 gcc_DEVPHASE=`cat $srcdir/DEV-PHASE`
1501 gcc_DATESTAMP=`cat $srcdir/DATESTAMP`
1502 if test -f $srcdir/REVISION ; then
1503         gcc_REVISION=`cat $srcdir/REVISION`
1504 else
1505         gcc_REVISION=""
1506 fi
1507 cat > plugin-version.h <<EOF
1508 #include "configargs.h"
1509
1510 static char basever[] = "$gcc_BASEVER";
1511 static char datestamp[] = "$gcc_DATESTAMP";
1512 static char devphase[] = "$gcc_DEVPHASE";
1513 static char revision[] = "$gcc_REVISION";
1514
1515 /* FIXME plugins: We should make the version information more precise.
1516    One way to do is to add a checksum. */
1517
1518 static struct plugin_gcc_version gcc_version = {basever, datestamp,
1519                                                 devphase, revision,
1520                                                 configuration_arguments};
1521 EOF
1522 changequote([,])dnl
1523
1524 # Internationalization
1525 ZW_GNU_GETTEXT_SISTER_DIR
1526
1527 # If LIBINTL contains LIBICONV, then clear LIBICONV so we don't get
1528 # -liconv on the link line twice.
1529 case "$LIBINTL" in *$LIBICONV*)
1530         LIBICONV= ;;
1531 esac
1532
1533 AC_ARG_ENABLE(secureplt,
1534 [  --enable-secureplt      enable -msecure-plt by default for PowerPC],
1535 [], [])
1536
1537 AC_ARG_ENABLE(cld,
1538 [  --enable-cld            enable -mcld by default for 32bit x86], [],
1539 [enable_cld=no])
1540
1541 # Windows32 Registry support for specifying GCC installation paths.
1542 AC_ARG_ENABLE(win32-registry,
1543 [  --disable-win32-registry
1544                           disable lookup of installation paths in the
1545                           Registry on Windows hosts
1546   --enable-win32-registry enable registry lookup (default)
1547   --enable-win32-registry=KEY
1548                           use KEY instead of GCC version as the last portion
1549                           of the registry key],,)
1550
1551 case $host_os in
1552   win32 | pe | cygwin* | mingw32* | uwin*)
1553     if test "x$enable_win32_registry" != xno; then
1554       AC_SEARCH_LIBS(RegOpenKeyExA, advapi32,, [enable_win32_registry=no])
1555     fi
1556
1557     if test "x$enable_win32_registry" != xno; then
1558       AC_DEFINE(ENABLE_WIN32_REGISTRY, 1,
1559   [Define to 1 if installation paths should be looked up in the Windows
1560    Registry. Ignored on non-Windows hosts.])
1561
1562       if test "x$enable_win32_registry" != xyes \
1563          && test "x$enable_win32_registry" != x; then
1564         AC_DEFINE_UNQUOTED(WIN32_REGISTRY_KEY, "$enable_win32_registry",
1565   [Define to be the last component of the Windows registry key under which
1566    to look for installation paths.  The full key used will be 
1567    HKEY_LOCAL_MACHINE/SOFTWARE/Free Software Foundation/{WIN32_REGISTRY_KEY}.
1568    The default is the GCC version number.])
1569       fi
1570     fi
1571   ;;
1572 esac
1573
1574 # Get an absolute path to the GCC top-level source directory
1575 holddir=`${PWDCMD-pwd}`
1576 cd $srcdir
1577 topdir=`${PWDCMD-pwd}`
1578 cd $holddir
1579
1580 # Conditionalize the makefile for this host machine.
1581 xmake_file=
1582 for f in ${host_xmake_file}
1583 do
1584         if test -f ${srcdir}/config/$f
1585         then
1586                 xmake_file="${xmake_file} \$(srcdir)/config/$f"
1587         fi
1588 done
1589
1590 # Conditionalize the makefile for this target machine.
1591 tmake_file_=
1592 for f in ${tmake_file}
1593 do
1594         if test -f ${srcdir}/config/$f
1595         then
1596                 tmake_file_="${tmake_file_} \$(srcdir)/config/$f"
1597         fi
1598 done
1599 tmake_file="${tmake_file_}"
1600
1601 out_object_file=`basename $out_file .c`.o
1602
1603 tm_file_list="options.h"
1604 tm_include_list="options.h"
1605 for f in $tm_file; do
1606   case $f in
1607     ./* )
1608        f=`echo $f | sed 's/^..//'`
1609        tm_file_list="${tm_file_list} $f"
1610        tm_include_list="${tm_include_list} $f"
1611        ;;
1612     defaults.h )
1613        tm_file_list="${tm_file_list} \$(srcdir)/$f"
1614        tm_include_list="${tm_include_list} $f"
1615        ;;
1616     * )
1617        tm_file_list="${tm_file_list} \$(srcdir)/config/$f"
1618        tm_include_list="${tm_include_list} config/$f"
1619        ;;
1620   esac
1621 done
1622
1623 tm_p_file_list=
1624 tm_p_include_list=
1625 for f in $tm_p_file; do
1626   case $f in
1627     tm-preds.h )
1628        tm_p_file_list="${tm_p_file_list} $f"
1629        tm_p_include_list="${tm_p_include_list} $f"
1630        ;;
1631     * )
1632        tm_p_file_list="${tm_p_file_list} \$(srcdir)/config/$f"
1633        tm_p_include_list="${tm_p_include_list} config/$f"
1634   esac
1635 done
1636
1637 xm_file_list=
1638 xm_include_list=
1639 for f in $xm_file; do
1640   case $f in
1641     ansidecl.h )
1642        xm_file_list="${xm_file_list} \$(srcdir)/../include/$f"
1643        xm_include_list="${xm_include_list} $f"
1644        ;;
1645     auto-host.h )
1646        xm_file_list="${xm_file_list} $f"
1647        xm_include_list="${xm_include_list} $f"
1648        ;;
1649     * )
1650        xm_file_list="${xm_file_list} \$(srcdir)/config/$f"
1651        xm_include_list="${xm_include_list} config/$f"
1652        ;;
1653   esac
1654 done
1655
1656 host_xm_file_list=
1657 host_xm_include_list=
1658 for f in $host_xm_file; do
1659   case $f in
1660     ansidecl.h )
1661        host_xm_file_list="${host_xm_file_list} \$(srcdir)/../include/$f"
1662        host_xm_include_list="${host_xm_include_list} $f"
1663        ;;
1664     auto-host.h )
1665        host_xm_file_list="${host_xm_file_list} $f"
1666        host_xm_include_list="${host_xm_include_list} $f"
1667        ;;
1668     * )
1669        host_xm_file_list="${host_xm_file_list} \$(srcdir)/config/$f"
1670        host_xm_include_list="${host_xm_include_list} config/$f"
1671        ;;
1672   esac
1673 done
1674
1675 build_xm_file_list=
1676 for f in $build_xm_file; do
1677   case $f in
1678     ansidecl.h )
1679        build_xm_file_list="${build_xm_file_list} \$(srcdir)/../include/$f"
1680        build_xm_include_list="${build_xm_include_list} $f"
1681        ;;
1682     auto-build.h | auto-host.h )
1683        build_xm_file_list="${build_xm_file_list} $f"
1684        build_xm_include_list="${build_xm_include_list} $f"
1685        ;;
1686     * )
1687        build_xm_file_list="${build_xm_file_list} \$(srcdir)/config/$f"
1688        build_xm_include_list="${build_xm_include_list} config/$f"
1689        ;;
1690   esac
1691 done
1692
1693 # Define macro CROSS_DIRECTORY_STRUCTURE in compilation if this is a
1694 # cross-compiler which does not use the native headers and libraries.
1695 # Also use all.cross instead of all.internal and adjust SYSTEM_HEADER_DIR.
1696 CROSS=                                          AC_SUBST(CROSS)
1697 ALL=all.internal                                AC_SUBST(ALL)
1698 SYSTEM_HEADER_DIR='$(NATIVE_SYSTEM_HEADER_DIR)' AC_SUBST(SYSTEM_HEADER_DIR)
1699
1700 if test "x$with_build_sysroot" != x; then
1701   build_system_header_dir=$with_build_sysroot'$${sysroot_headers_suffix}$(NATIVE_SYSTEM_HEADER_DIR)'
1702 else
1703   # This value is used, even on a native system, because 
1704   # CROSS_SYSTEM_HEADER_DIR is just 
1705   # $(TARGET_SYSTEM_ROOT)$(NATIVE_SYSTEM_HEADER_DIR).
1706   build_system_header_dir='$(CROSS_SYSTEM_HEADER_DIR)'
1707 fi
1708
1709 if test x$host != x$target
1710 then
1711         CROSS="-DCROSS_DIRECTORY_STRUCTURE"
1712         ALL=all.cross
1713         SYSTEM_HEADER_DIR=$build_system_header_dir
1714         case "$host","$target" in
1715         # Darwin crosses can use the host system's libraries and headers,
1716         # because of the fat library support.  Of course, it must be the
1717         # same version of Darwin on both sides.  Allow the user to
1718         # just say --target=foo-darwin without a version number to mean
1719         # "the version on this system".
1720             *-*-darwin*,*-*-darwin*)
1721                 hostos=`echo $host | sed 's/.*-darwin/darwin/'`
1722                 targetos=`echo $target | sed 's/.*-darwin/darwin/'`
1723                 if test $hostos = $targetos -o $targetos = darwin ; then
1724                     CROSS=
1725                     SYSTEM_HEADER_DIR='$(NATIVE_SYSTEM_HEADER_DIR)'
1726                     with_headers=yes
1727                 fi
1728                 ;;
1729
1730             i?86-*-*,x86_64-*-* \
1731             | powerpc*-*-*,powerpc64*-*-*)
1732                 CROSS="$CROSS -DNATIVE_CROSS" ;;
1733         esac
1734 elif test "x$TARGET_SYSTEM_ROOT" != x; then
1735         SYSTEM_HEADER_DIR=$build_system_header_dir 
1736 fi
1737
1738 # If this is a cross-compiler that does not
1739 # have its own set of headers then define
1740 # inhibit_libc
1741
1742 # If this is using newlib, without having the headers available now,
1743 # then define inhibit_libc in LIBGCC2_CFLAGS.
1744 # This prevents libgcc2 from containing any code which requires libc
1745 # support.
1746 : ${inhibit_libc=false}
1747 if { { test x$host != x$target && test "x$with_sysroot" = x ; } ||
1748        test x$with_newlib = xyes ; } &&
1749      { test "x$with_headers" = x || test "x$with_headers" = xno ; } ; then
1750        inhibit_libc=true
1751 fi
1752 AC_SUBST(inhibit_libc)
1753
1754 # When building gcc with a cross-compiler, we need to adjust things so
1755 # that the generator programs are still built with the native compiler.
1756 # Also, we cannot run fixincludes.
1757
1758 # These are the normal (build=host) settings:
1759 CC_FOR_BUILD='$(CC)'            AC_SUBST(CC_FOR_BUILD)
1760 BUILD_CFLAGS='$(ALL_CFLAGS)'    AC_SUBST(BUILD_CFLAGS)
1761 BUILD_LDFLAGS='$(LDFLAGS)'      AC_SUBST(BUILD_LDFLAGS)
1762 STMP_FIXINC=stmp-fixinc         AC_SUBST(STMP_FIXINC)
1763
1764 # And these apply if build != host, or we are generating coverage data
1765 if test x$build != x$host || test "x$coverage_flags" != x
1766 then
1767     BUILD_CFLAGS='$(INTERNAL_CFLAGS) $(T_CFLAGS) $(CFLAGS_FOR_BUILD)'
1768     BUILD_LDFLAGS='$(LDFLAGS_FOR_BUILD)'
1769 fi
1770
1771 # Expand extra_headers to include complete path.
1772 # This substitutes for lots of t-* files.
1773 extra_headers_list=
1774 # Prepend $(srcdir)/config/${cpu_type}/ to every entry in extra_headers.
1775 for file in ${extra_headers} ; do
1776   extra_headers_list="${extra_headers_list} \$(srcdir)/config/${cpu_type}/${file}"
1777 done
1778
1779 # If use_gcc_tgmath is set, append ginclude/tgmath.h.
1780 if test x"$use_gcc_tgmath" = xyes
1781 then extra_headers_list="${extra_headers_list} \$(srcdir)/ginclude/tgmath.h"
1782 fi
1783
1784 # Define collect2 in Makefile.
1785 case $host_can_use_collect2 in
1786   no) collect2= ;;
1787   *) collect2='collect2$(exeext)' ;;
1788 esac
1789 AC_SUBST([collect2])
1790
1791 # Add a definition of USE_COLLECT2 if system wants one.
1792 case $use_collect2 in
1793   no) use_collect2= ;;
1794   "") ;;
1795   *) 
1796     host_xm_defines="${host_xm_defines} USE_COLLECT2"
1797     xm_defines="${xm_defines} USE_COLLECT2"
1798     case $host_can_use_collect2 in
1799       no)
1800         AC_MSG_ERROR([collect2 is required but cannot be built on this system])
1801         ;;
1802     esac
1803     ;;
1804 esac
1805
1806 # ---------------------------
1807 # Assembler & linker features
1808 # ---------------------------
1809
1810 # During stage 2, ld is actually gcc/collect-ld, which is a small script to
1811 # discern between when to use prev-ld/ld-new and when to use ld/ld-new.
1812 # However when ld-new is first executed from the build tree, libtool will
1813 # relink it as .libs/lt-ld-new, so that it can give it an RPATH that refers
1814 # to the build tree.  While doing this we need to use the previous-stage
1815 # linker, or we have an infinite loop.  The presence of a shell script as
1816 # ld/ld-new, and the fact that the script *uses ld itself*, is what confuses
1817 # the gcc/collect-ld script.  So we need to know how libtool works, or
1818 # exec-tool will fail.
1819
1820 m4_defun([_LT_CONFIG_COMMANDS], [])
1821 AC_PROG_LIBTOOL
1822 AC_SUBST(objdir)
1823 AC_SUBST(enable_fast_install)
1824
1825 # Identify the assembler which will work hand-in-glove with the newly
1826 # built GCC, so that we can examine its features.  This is the assembler
1827 # which will be driven by the driver program.
1828 #
1829 # If build != host, and we aren't building gas in-tree, we identify a
1830 # build->target assembler and hope that it will have the same features
1831 # as the host->target assembler we'll be using.
1832 gcc_cv_gas_major_version=
1833 gcc_cv_gas_minor_version=
1834 gcc_cv_as_gas_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/gas
1835
1836 m4_pattern_allow([AS_FOR_TARGET])dnl
1837 AS_VAR_SET_IF(gcc_cv_as,, [
1838 if test -x "$DEFAULT_ASSEMBLER"; then
1839         gcc_cv_as="$DEFAULT_ASSEMBLER"
1840 elif test -f $gcc_cv_as_gas_srcdir/configure.in \
1841      && test -f ../gas/Makefile \
1842      && test x$build = x$host; then
1843         gcc_cv_as=../gas/as-new$build_exeext
1844 elif test -x as$build_exeext; then
1845         # Build using assembler in the current directory.
1846         gcc_cv_as=./as$build_exeext
1847 elif test -x $AS_FOR_TARGET; then
1848         gcc_cv_as="$AS_FOR_TARGET"
1849 else
1850         AC_PATH_PROG(gcc_cv_as, $AS_FOR_TARGET)
1851 fi])
1852
1853 ORIGINAL_AS_FOR_TARGET=$gcc_cv_as
1854 AC_SUBST(ORIGINAL_AS_FOR_TARGET)
1855 case "$ORIGINAL_AS_FOR_TARGET" in
1856   ./as | ./as$build_exeext) ;;
1857   *) AC_CONFIG_FILES(as:exec-tool.in, [chmod +x as]) ;;
1858 esac 
1859
1860 AC_MSG_CHECKING(what assembler to use)
1861 if test "$gcc_cv_as" = ../gas/as-new$build_exeext; then
1862   # Single tree build which includes gas.  We want to prefer it
1863   # over whatever linker top-level may have detected, since
1864   # we'll use what we're building after installation anyway.
1865   AC_MSG_RESULT(newly built gas)
1866   in_tree_gas=yes
1867   _gcc_COMPUTE_GAS_VERSION
1868   in_tree_gas_is_elf=no
1869   if grep 'obj_format = elf' ../gas/Makefile > /dev/null \
1870      || (grep 'obj_format = multi' ../gas/Makefile \
1871          && grep 'extra_objects =.* obj-elf' ../gas/Makefile) > /dev/null
1872   then
1873     in_tree_gas_is_elf=yes
1874   fi
1875 else
1876   AC_MSG_RESULT($gcc_cv_as)
1877   in_tree_gas=no
1878 fi
1879
1880 # Identify the linker which will work hand-in-glove with the newly
1881 # built GCC, so that we can examine its features.  This is the linker
1882 # which will be driven by the driver program.
1883 #
1884 # If build != host, and we aren't building gas in-tree, we identify a
1885 # build->target linker and hope that it will have the same features
1886 # as the host->target linker we'll be using.
1887 gcc_cv_gld_major_version=
1888 gcc_cv_gld_minor_version=
1889 gcc_cv_ld_gld_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/ld
1890 gcc_cv_ld_bfd_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/bfd
1891
1892 AS_VAR_SET_IF(gcc_cv_ld,, [
1893 if test -x "$DEFAULT_LINKER"; then
1894         gcc_cv_ld="$DEFAULT_LINKER"
1895 elif test -f $gcc_cv_ld_gld_srcdir/configure.in \
1896      && test -f ../ld/Makefile \
1897      && test x$build = x$host; then
1898         gcc_cv_ld=../ld/ld-new$build_exeext
1899 elif test -x collect-ld$build_exeext; then
1900         # Build using linker in the current directory.
1901         gcc_cv_ld=./collect-ld$build_exeext
1902 elif test -x $LD_FOR_TARGET; then
1903         gcc_cv_ld="$LD_FOR_TARGET"
1904 else
1905         AC_PATH_PROG(gcc_cv_ld, $LD_FOR_TARGET)
1906 fi])
1907
1908 ORIGINAL_LD_FOR_TARGET=$gcc_cv_ld
1909 AC_SUBST(ORIGINAL_LD_FOR_TARGET)
1910 case "$ORIGINAL_LD_FOR_TARGET" in
1911   ./collect-ld | ./collect-ld$build_exeext) ;;
1912   *) AC_CONFIG_FILES(collect-ld:exec-tool.in, [chmod +x collect-ld]) ;;
1913 esac 
1914
1915 AC_MSG_CHECKING(what linker to use)
1916 if test "$gcc_cv_ld" = ../ld/ld-new$build_exeext; then
1917         # Single tree build which includes ld.  We want to prefer it
1918         # over whatever linker top-level may have detected, since
1919         # we'll use what we're building after installation anyway.
1920         AC_MSG_RESULT(newly built ld)
1921         in_tree_ld=yes
1922         in_tree_ld_is_elf=no
1923         if (grep 'EMUL = .*elf' ../ld/Makefile \
1924             || grep 'EMUL = .*linux' ../ld/Makefile \
1925             || grep 'EMUL = .*lynx' ../ld/Makefile) > /dev/null; then
1926           in_tree_ld_is_elf=yes
1927         fi
1928         for f in $gcc_cv_ld_bfd_srcdir/configure $gcc_cv_ld_gld_srcdir/configure $gcc_cv_ld_gld_srcdir/configure.in $gcc_cv_ld_gld_srcdir/Makefile.in
1929         do
1930 changequote(,)dnl
1931                 gcc_cv_gld_version=`sed -n -e 's/^[     ]*\(VERSION=[0-9]*\.[0-9]*.*\)/\1/p' < $f`
1932                 if test x$gcc_cv_gld_version != x; then
1933                         break
1934                 fi
1935         done
1936         gcc_cv_gld_major_version=`expr "$gcc_cv_gld_version" : "VERSION=\([0-9]*\)"`
1937         gcc_cv_gld_minor_version=`expr "$gcc_cv_gld_version" : "VERSION=[0-9]*\.\([0-9]*\)"`
1938 changequote([,])dnl
1939 else
1940         AC_MSG_RESULT($gcc_cv_ld)
1941         in_tree_ld=no
1942 fi
1943
1944 # Figure out what nm we will be using.
1945 gcc_cv_binutils_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/binutils
1946 AS_VAR_SET_IF(gcc_cv_nm,, [
1947 if test -f $gcc_cv_binutils_srcdir/configure.in \
1948      && test -f ../binutils/Makefile \
1949      && test x$build = x$host; then
1950         gcc_cv_nm=../binutils/nm-new$build_exeext
1951 elif test -x nm$build_exeext; then
1952         gcc_cv_nm=./nm$build_exeext
1953 elif test -x $NM_FOR_TARGET; then
1954         gcc_cv_nm="$NM_FOR_TARGET"
1955 else
1956         AC_PATH_PROG(gcc_cv_nm, $NM_FOR_TARGET)
1957 fi])
1958
1959 AC_MSG_CHECKING(what nm to use)
1960 if test "$gcc_cv_nm" = ../binutils/nm-new$build_exeext; then
1961         # Single tree build which includes binutils.
1962         AC_MSG_RESULT(newly built nm)
1963         in_tree_nm=yes
1964 else
1965         AC_MSG_RESULT($gcc_cv_nm)
1966         in_tree_nm=no
1967 fi
1968
1969 ORIGINAL_NM_FOR_TARGET=$gcc_cv_nm
1970 AC_SUBST(ORIGINAL_NM_FOR_TARGET)
1971 case "$ORIGINAL_NM_FOR_TARGET" in
1972   ./nm | ./nm$build_exeext) ;;
1973   *) AC_CONFIG_FILES(nm:exec-tool.in, [chmod +x nm]) ;;
1974 esac
1975
1976
1977 # Figure out what objdump we will be using.
1978 AS_VAR_SET_IF(gcc_cv_objdump,, [
1979 if test -f $gcc_cv_binutils_srcdir/configure.in \
1980      && test -f ../binutils/Makefile \
1981      && test x$build = x$host; then
1982         # Single tree build which includes binutils.
1983         gcc_cv_objdump=../binutils/objdump$build_exeext
1984 elif test -x objdump$build_exeext; then
1985         gcc_cv_objdump=./objdump$build_exeext
1986 elif test -x $OBJDUMP_FOR_TARGET; then
1987         gcc_cv_objdump="$OBJDUMP_FOR_TARGET"
1988 else
1989         AC_PATH_PROG(gcc_cv_objdump, $OBJDUMP_FOR_TARGET)
1990 fi])
1991
1992 AC_MSG_CHECKING(what objdump to use)
1993 if test "$gcc_cv_objdump" = ../binutils/objdump$build_exeext; then
1994         # Single tree build which includes binutils.
1995         AC_MSG_RESULT(newly built objdump)
1996 elif test x$gcc_cv_objdump = x; then
1997         AC_MSG_RESULT(not found)
1998 else
1999         AC_MSG_RESULT($gcc_cv_objdump)
2000 fi
2001
2002 # Figure out what readelf we will be using.
2003 AS_VAR_SET_IF(gcc_cv_readelf,, [
2004 if test -f $gcc_cv_binutils_srcdir/configure.in \
2005      && test -f ../binutils/Makefile \
2006      && test x$build = x$host; then
2007         # Single tree build which includes binutils.
2008         gcc_cv_readelf=../binutils/readelf$build_exeext
2009 elif test -x readelf$build_exeext; then
2010         gcc_cv_readelf=./readelf$build_exeext
2011 else
2012         AC_PATH_PROG(gcc_cv_readelf, readelf)
2013 fi])
2014
2015 AC_MSG_CHECKING(what readelf to use)
2016 if test "$gcc_cv_readelf" = ../binutils/readelf$build_exeext; then
2017         # Single tree build which includes binutils.
2018         AC_MSG_RESULT(newly built readelf)
2019 elif test x$gcc_cv_readelf = x; then
2020         AC_MSG_RESULT(not found)
2021 else
2022         AC_MSG_RESULT($gcc_cv_readelf)
2023 fi
2024
2025 # Figure out what assembler alignment features are present.
2026 gcc_GAS_CHECK_FEATURE([.balign and .p2align], gcc_cv_as_balign_and_p2align,
2027  [2,6,0],,
2028 [.balign 4
2029 .p2align 2],,
2030 [AC_DEFINE(HAVE_GAS_BALIGN_AND_P2ALIGN, 1,
2031   [Define if your assembler supports .balign and .p2align.])])
2032
2033 gcc_GAS_CHECK_FEATURE([.p2align with maximum skip], gcc_cv_as_max_skip_p2align,
2034  [2,8,0],,
2035  [.p2align 4,,7],,
2036 [AC_DEFINE(HAVE_GAS_MAX_SKIP_P2ALIGN, 1,
2037   [Define if your assembler supports specifying the maximum number
2038    of bytes to skip when using the GAS .p2align command.])])
2039
2040 gcc_GAS_CHECK_FEATURE([.literal16], gcc_cv_as_literal16,
2041  [2,8,0],,
2042  [.literal16],,
2043 [AC_DEFINE(HAVE_GAS_LITERAL16, 1,
2044   [Define if your assembler supports .literal16.])])
2045
2046 gcc_GAS_CHECK_FEATURE([working .subsection -1], gcc_cv_as_subsection_m1,
2047  [elf,2,9,0],,
2048  [conftest_label1: .word 0
2049 .subsection -1
2050 conftest_label2: .word 0
2051 .previous],
2052  [if test x$gcc_cv_nm != x; then
2053     $gcc_cv_nm conftest.o | grep conftest_label1 > conftest.nm1
2054     $gcc_cv_nm conftest.o | grep conftest_label2 | sed -e 's/label2/label1/' > conftest.nm2
2055     if cmp conftest.nm1 conftest.nm2 > /dev/null 2>&1
2056     then :
2057     else gcc_cv_as_subsection_m1=yes
2058     fi
2059     rm -f conftest.nm1 conftest.nm2
2060   fi],
2061  [AC_DEFINE(HAVE_GAS_SUBSECTION_ORDERING, 1,
2062   [Define if your assembler supports .subsection and .subsection -1 starts
2063    emitting at the beginning of your section.])])
2064
2065 gcc_GAS_CHECK_FEATURE([.weak], gcc_cv_as_weak,
2066  [2,2,0],,
2067  [      .weak foobar],,
2068 [AC_DEFINE(HAVE_GAS_WEAK, 1, [Define if your assembler supports .weak.])])
2069
2070 gcc_GAS_CHECK_FEATURE([.weakref], gcc_cv_as_weakref,
2071  [2,17,0],,
2072  [      .weakref foobar, barfnot],,
2073 [AC_DEFINE(HAVE_GAS_WEAKREF, 1, [Define if your assembler supports .weakref.])])
2074
2075 gcc_GAS_CHECK_FEATURE([.nsubspa comdat], gcc_cv_as_nsubspa_comdat,
2076  [2,15,91],,
2077  [      .SPACE $TEXT$
2078         .NSUBSPA $CODE$,COMDAT],,
2079 [AC_DEFINE(HAVE_GAS_NSUBSPA_COMDAT, 1, [Define if your assembler supports .nsubspa comdat option.])])
2080
2081 # .hidden needs to be supported in both the assembler and the linker,
2082 # because GNU LD versions before 2.12.1 have buggy support for STV_HIDDEN.
2083 # This is irritatingly difficult to feature test for; we have to check the
2084 # date string after the version number.  If we've got an in-tree
2085 # ld, we don't know its patchlevel version, so we set the baseline at 2.13
2086 # to be safe.
2087 # The gcc_GAS_CHECK_FEATURE call just sets a cache variable.
2088 gcc_GAS_CHECK_FEATURE([.hidden], gcc_cv_as_hidden,
2089  [elf,2,13,0],,
2090 [       .hidden foobar
2091 foobar:])
2092
2093 AC_CACHE_CHECK(linker for .hidden support, gcc_cv_ld_hidden,
2094 [if test $in_tree_ld = yes ; then
2095   gcc_cv_ld_hidden=no
2096   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 13 -o "$gcc_cv_gld_major_version" -gt 2 \
2097      && test $in_tree_ld_is_elf = yes; then
2098      gcc_cv_ld_hidden=yes
2099   fi
2100 else
2101 changequote(,)dnl
2102   gcc_cv_ld_hidden=yes
2103   ld_ver=`$gcc_cv_ld --version 2>/dev/null | sed 1q`
2104   if echo "$ld_ver" | grep GNU > /dev/null; then
2105     ld_vers=`echo $ld_ver | sed -n \
2106         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*.*\)$,\1,p'`
2107     ld_date=`echo $ld_ver | sed -n 's,^.*\([2-9][0-9][0-9][0-9]\)[-]*\([01][0-9]\)[-]*\([0-3][0-9]\).*$,\1\2\3,p'`
2108     ld_vers_major=`expr "$ld_vers" : '\([0-9]*\)'`
2109     ld_vers_minor=`expr "$ld_vers" : '[0-9]*\.\([0-9]*\)'`
2110     ld_vers_patch=`expr "$ld_vers" : '[0-9]*\.[0-9]*\.\([0-9]*\)'`
2111     if test 0"$ld_date" -lt 20020404; then
2112       if test -n "$ld_date"; then
2113         # If there was date string, but was earlier than 2002-04-04, fail
2114         gcc_cv_ld_hidden=no
2115       elif test -z "$ld_vers"; then
2116         # If there was no date string nor ld version number, something is wrong
2117         gcc_cv_ld_hidden=no
2118       else
2119         test -z "$ld_vers_patch" && ld_vers_patch=0
2120         if test "$ld_vers_major" -lt 2; then
2121           gcc_cv_ld_hidden=no
2122         elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -lt 12; then
2123           gcc_cv_ld_hidden="no"
2124         elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -eq 12 -a "$ld_vers_patch" -eq 0; then
2125           gcc_cv_ld_hidden=no
2126         fi
2127       fi
2128     fi
2129   else
2130     case "${target}" in
2131       hppa64*-*-hpux* | ia64*-*-hpux*)
2132         gcc_cv_ld_hidden=yes
2133         ;;
2134       *-*-solaris2.9* | *-*-solaris2.1[0-9]*)
2135         gcc_cv_ld_hidden=yes
2136         ;;
2137       *)
2138         gcc_cv_ld_hidden=no
2139         ;;
2140     esac
2141   fi
2142 changequote([,])dnl
2143 fi])
2144 libgcc_visibility=no
2145 AC_SUBST(libgcc_visibility)
2146 GCC_TARGET_TEMPLATE([HAVE_GAS_HIDDEN])
2147 if test $gcc_cv_as_hidden = yes && test $gcc_cv_ld_hidden = yes; then
2148   libgcc_visibility=yes
2149   AC_DEFINE(HAVE_GAS_HIDDEN, 1,
2150   [Define if your assembler and linker support .hidden.])
2151 fi
2152
2153 AC_MSG_CHECKING(linker read-only and read-write section mixing)
2154 gcc_cv_ld_ro_rw_mix=unknown
2155 if test $in_tree_ld = yes ; then
2156   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 10 -o "$gcc_cv_gld_major_version" -gt 2 \
2157      && test $in_tree_ld_is_elf = yes; then
2158     gcc_cv_ld_ro_rw_mix=read-write
2159   fi
2160 elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x -a x$gcc_cv_objdump != x ; then
2161   echo '.section myfoosect, "a"' > conftest1.s
2162   echo '.section myfoosect, "aw"' > conftest2.s
2163   echo '.byte 1' >> conftest2.s
2164   echo '.section myfoosect, "a"' > conftest3.s
2165   echo '.byte 0' >> conftest3.s
2166   if $gcc_cv_as -o conftest1.o conftest1.s > /dev/null 2>&1 \
2167      && $gcc_cv_as -o conftest2.o conftest2.s > /dev/null 2>&1 \
2168      && $gcc_cv_as -o conftest3.o conftest3.s > /dev/null 2>&1 \
2169      && $gcc_cv_ld -shared -o conftest1.so conftest1.o \
2170         conftest2.o conftest3.o > /dev/null 2>&1; then
2171     gcc_cv_ld_ro_rw_mix=`$gcc_cv_objdump -h conftest1.so \
2172                          | sed -e '/myfoosect/!d' -e N`
2173     if echo "$gcc_cv_ld_ro_rw_mix" | grep CONTENTS > /dev/null; then
2174       if echo "$gcc_cv_ld_ro_rw_mix" | grep READONLY > /dev/null; then
2175         gcc_cv_ld_ro_rw_mix=read-only
2176       else
2177         gcc_cv_ld_ro_rw_mix=read-write
2178       fi
2179     fi
2180   fi
2181 changequote(,)dnl
2182   rm -f conftest.* conftest[123].*
2183 changequote([,])dnl
2184 fi
2185 if test x$gcc_cv_ld_ro_rw_mix = xread-write; then
2186         AC_DEFINE(HAVE_LD_RO_RW_SECTION_MIXING, 1,
2187   [Define if your linker links a mix of read-only
2188    and read-write sections into a read-write section.])
2189 fi
2190 AC_MSG_RESULT($gcc_cv_ld_ro_rw_mix)
2191
2192 # Check if we have .[us]leb128, and support symbol arithmetic with it.
2193 gcc_GAS_CHECK_FEATURE([.sleb128 and .uleb128], gcc_cv_as_leb128,
2194   [elf,2,11,0],,
2195 [       .data
2196         .uleb128 L2 - L1
2197 L1:
2198         .uleb128 1280
2199         .sleb128 -1010
2200 L2:],
2201  [# GAS versions before 2.11 do not support uleb128,
2202   # despite appearing to.
2203   # ??? There exists an elf-specific test that will crash
2204   # the assembler.  Perhaps it's better to figure out whether
2205   # arbitrary sections are supported and try the test.
2206   as_ver=`$gcc_cv_as --version 2>/dev/null | sed 1q`
2207   if echo "$as_ver" | grep GNU > /dev/null; then
2208 changequote(,)dnl
2209     as_vers=`echo $as_ver | sed -n \
2210         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*.*\)$,\1,p'`
2211     as_major=`expr "$as_vers" : '\([0-9]*\)'`
2212     as_minor=`expr "$as_vers" : '[0-9]*\.\([0-9]*\)'`
2213 changequote([,])dnl
2214     if test $as_major -eq 2 && test $as_minor -lt 11
2215     then :
2216     else gcc_cv_as_leb128=yes
2217     fi
2218   fi],
2219   [AC_DEFINE(HAVE_AS_LEB128, 1,
2220     [Define if your assembler supports .sleb128 and .uleb128.])])
2221
2222 # Check if we have assembler support for unwind directives.
2223 gcc_GAS_CHECK_FEATURE([cfi directives], gcc_cv_as_cfi_directive,
2224   ,,
2225 [       .text
2226         .cfi_startproc
2227         .cfi_offset 0, 0
2228         .cfi_same_value 1
2229         .cfi_def_cfa 1, 2
2230         .cfi_escape 1, 2, 3, 4, 5
2231         .cfi_endproc],
2232 [case "$target" in
2233   *-*-solaris*)
2234     # If the linker used on Solaris (like Sun ld) isn't capable of merging
2235     # read-only and read-write sections, we need to make sure that the
2236     # assembler used emits read-write .eh_frame sections.
2237     if test "x$gcc_cv_ld_ro_rw_mix" != xread-write; then
2238       if test "x$gcc_cv_objdump" != x; then
2239         if $gcc_cv_objdump -h conftest.o 2>/dev/null | \
2240                 sed -e /.eh_frame/!d -e N | grep READONLY > /dev/null; then
2241           gcc_cv_as_cfi_directive=no
2242         else
2243           gcc_cv_as_cfi_directive=yes
2244         fi
2245       else
2246         # no objdump, err on the side of caution
2247         gcc_cv_as_cfi_directive=no
2248       fi
2249     else
2250       gcc_cv_as_cfi_directive=yes
2251     fi
2252     ;;
2253   *-*-*)
2254     gcc_cv_as_cfi_directive=yes
2255     ;;
2256 esac])
2257 if test $gcc_cv_as_cfi_directive = yes && test x$gcc_cv_readelf != x; then
2258 gcc_GAS_CHECK_FEATURE([working cfi advance], gcc_cv_as_cfi_advance_working,
2259   ,,
2260 [       .text
2261         .cfi_startproc
2262         .cfi_adjust_cfa_offset 64
2263         .skip 512, 0
2264         .cfi_adjust_cfa_offset 128
2265         .cfi_endproc],
2266 [
2267 changequote(,)dnl
2268 if $gcc_cv_readelf -wf conftest.o 2>/dev/null \
2269     | grep 'DW_CFA_advance_loc[12]:[    ][      ]*512[  ]' >/dev/null; then
2270    gcc_cv_as_cfi_advance_working=yes
2271 fi
2272 changequote([,])dnl
2273 ])
2274 else
2275   # no readelf, err on the side of caution
2276   gcc_cv_as_cfi_advance_working=no
2277 fi
2278 AC_DEFINE_UNQUOTED(HAVE_GAS_CFI_DIRECTIVE,
2279   [`if test $gcc_cv_as_cfi_directive = yes \
2280        && test $gcc_cv_as_cfi_advance_working = yes; then echo 1; else echo 0; fi`],
2281   [Define 0/1 if your assembler supports CFI directives.])
2282
2283 gcc_GAS_CHECK_FEATURE([cfi personality directive],
2284   gcc_cv_as_cfi_personality_directive, ,,
2285 [       .text
2286         .cfi_startproc
2287         .cfi_personality 0, symbol
2288         .cfi_endproc])
2289 AC_DEFINE_UNQUOTED(HAVE_GAS_CFI_PERSONALITY_DIRECTIVE,
2290   [`if test $gcc_cv_as_cfi_personality_directive = yes;
2291     then echo 1; else echo 0; fi`],
2292   [Define 0/1 if your assembler supports .cfi_personality.])
2293
2294 # GAS versions up to and including 2.11.0 may mis-optimize
2295 # .eh_frame data.
2296 gcc_GAS_CHECK_FEATURE(eh_frame optimization, gcc_cv_as_eh_frame,
2297   [elf,2,12,0],,
2298 [       .text
2299 .LFB1:
2300         .4byte  0
2301 .L1:
2302         .4byte  0
2303 .LFE1:
2304         .section        .eh_frame,"aw",@progbits
2305 __FRAME_BEGIN__:
2306         .4byte  .LECIE1-.LSCIE1
2307 .LSCIE1:
2308         .4byte  0x0
2309         .byte   0x1
2310         .ascii "z\0"
2311         .byte   0x1
2312         .byte   0x78
2313         .byte   0x1a
2314         .byte   0x0
2315         .byte   0x4
2316         .4byte  1
2317         .p2align 1
2318 .LECIE1:
2319 .LSFDE1:
2320         .4byte  .LEFDE1-.LASFDE1
2321 .LASFDE1:
2322         .4byte  .LASFDE1-__FRAME_BEGIN__
2323         .4byte  .LFB1
2324         .4byte  .LFE1-.LFB1
2325         .byte   0x4
2326         .4byte  .LFE1-.LFB1
2327         .byte   0x4
2328         .4byte  .L1-.LFB1
2329 .LEFDE1:],
2330 [  dnl # For autoconf 2.5x, must protect trailing spaces with @&t@.
2331 cat > conftest.lit <<EOF
2332  0000 10000000 00000000 017a0001 781a0004  .........z..x...
2333  0010 01000000 12000000 18000000 00000000  ................
2334  0020 08000000 04080000 0044               .........D      @&t@
2335 EOF
2336 cat > conftest.big <<EOF
2337  0000 00000010 00000000 017a0001 781a0004  .........z..x...
2338  0010 00000001 00000012 00000018 00000000  ................
2339  0020 00000008 04000000 0844               .........D      @&t@
2340 EOF
2341   # If the assembler didn't choke, and we can objdump,
2342   # and we got the correct data, then succeed.
2343   # The text in the here-document typically retains its unix-style line
2344   # endings, while the output of objdump will use host line endings.
2345   # Therefore, use diff -b for the comparisons.
2346   if test x$gcc_cv_objdump != x \
2347   && $gcc_cv_objdump -s -j .eh_frame conftest.o 2>/dev/null \
2348      | tail -3 > conftest.got \
2349   && { diff -b conftest.lit conftest.got > /dev/null 2>&1 \
2350     || diff -b conftest.big conftest.got > /dev/null 2>&1; }
2351   then
2352     gcc_cv_as_eh_frame=yes
2353   elif AC_TRY_COMMAND($gcc_cv_as -o conftest.o --traditional-format /dev/null); then
2354     gcc_cv_as_eh_frame=buggy
2355   else
2356     # Uh oh, what do we do now?
2357     gcc_cv_as_eh_frame=no
2358   fi])
2359
2360 if test $gcc_cv_as_eh_frame = buggy; then
2361   AC_DEFINE(USE_AS_TRADITIONAL_FORMAT, 1,
2362   [Define if your assembler mis-optimizes .eh_frame data.])
2363 fi
2364
2365 gcc_GAS_CHECK_FEATURE(section merging support, gcc_cv_as_shf_merge,
2366  [elf,2,12,0], [--fatal-warnings],
2367  [.section .rodata.str, "aMS", @progbits, 1])
2368 if test $gcc_cv_as_shf_merge = no; then
2369   gcc_GAS_CHECK_FEATURE(section merging support, gcc_cv_as_shf_merge,
2370     [elf,2,12,0], [--fatal-warnings],
2371     [.section .rodata.str, "aMS", %progbits, 1])
2372 fi
2373 AC_DEFINE_UNQUOTED(HAVE_GAS_SHF_MERGE,
2374   [`if test $gcc_cv_as_shf_merge = yes; then echo 1; else echo 0; fi`],
2375 [Define 0/1 if your assembler supports marking sections with SHF_MERGE flag.])
2376
2377 gcc_GAS_CHECK_FEATURE(COMDAT group support, gcc_cv_as_comdat_group,
2378  [elf,2,16,0], [--fatal-warnings],
2379  [.section .text,"axG",@progbits,.foo,comdat])
2380 if test $gcc_cv_as_comdat_group = yes; then
2381   gcc_cv_as_comdat_group_percent=no
2382 else
2383  gcc_GAS_CHECK_FEATURE(COMDAT group support, gcc_cv_as_comdat_group_percent,
2384    [elf,2,16,0], [--fatal-warnings],
2385    [.section .text,"axG",%progbits,.foo,comdat])
2386 fi
2387 if test $in_tree_ld != yes && test x"$ld_vers" != x; then
2388   comdat_group=yes
2389   if test 0"$ld_date" -lt 20050308; then
2390     if test -n "$ld_date"; then
2391       # If there was date string, but was earlier than 2005-03-08, fail
2392       comdat_group=no
2393     elif test "$ld_vers_major" -lt 2; then
2394       comdat_group=no
2395     elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -lt 16; then
2396       comdat_group=no
2397     fi
2398   fi
2399 else
2400   # assume linkers other than GNU ld don't support COMDAT group
2401   comdat_group=no
2402 fi
2403 if test $comdat_group = no; then
2404   gcc_cv_as_comdat_group=no
2405   gcc_cv_as_comdat_group_percent=no
2406 fi
2407 AC_DEFINE_UNQUOTED(HAVE_COMDAT_GROUP,
2408   [`if test $gcc_cv_as_comdat_group = yes || test $gcc_cv_as_comdat_group_percent = yes; then echo 1; else echo 0; fi`],
2409 [Define 0/1 if your assembler and linker support COMDAT groups.])
2410
2411 # Thread-local storage - the check is heavily parameterized.
2412 conftest_s=
2413 tls_first_major=
2414 tls_first_minor=
2415 tls_as_opt=
2416 case "$target" in
2417 changequote(,)dnl
2418   alpha*-*-*)
2419     conftest_s='
2420         .section ".tdata","awT",@progbits
2421 foo:    .long   25
2422         .text
2423         ldq     $27,__tls_get_addr($29)         !literal!1
2424         lda     $16,foo($29)                    !tlsgd!1
2425         jsr     $26,($27),__tls_get_addr        !lituse_tlsgd!1
2426         ldq     $27,__tls_get_addr($29)         !literal!2
2427         lda     $16,foo($29)                    !tlsldm!2
2428         jsr     $26,($27),__tls_get_addr        !lituse_tlsldm!2
2429         ldq     $1,foo($29)                     !gotdtprel
2430         ldah    $2,foo($29)                     !dtprelhi
2431         lda     $3,foo($2)                      !dtprello
2432         lda     $4,foo($29)                     !dtprel
2433         ldq     $1,foo($29)                     !gottprel
2434         ldah    $2,foo($29)                     !tprelhi
2435         lda     $3,foo($2)                      !tprello
2436         lda     $4,foo($29)                     !tprel'
2437         tls_first_major=2
2438         tls_first_minor=13
2439         tls_as_opt=--fatal-warnings
2440         ;;
2441   cris-*-*|crisv32-*-*)
2442     conftest_s='
2443         .section ".tdata","awT",@progbits
2444 x:      .long   25
2445         .text
2446         move.d x:IE,$r10
2447         nop'
2448         tls_first_major=2
2449         tls_first_minor=20
2450         tls_as_opt=--fatal-warnings
2451         ;;
2452   frv*-*-*)
2453     conftest_s='
2454         .section ".tdata","awT",@progbits
2455 x:      .long   25
2456         .text
2457         call    #gettlsoff(x)'
2458         tls_first_major=2
2459         tls_first_minor=14
2460         ;;
2461   hppa*-*-linux*)
2462     conftest_s='
2463 t1:     .reg    %r20
2464 t2:     .reg    %r21
2465 gp:     .reg    %r19
2466         .section ".tdata","awT",@progbits
2467 foo:    .long   25
2468         .text
2469         .align  4
2470         addil LT%foo-$tls_gdidx$,gp
2471         ldo RT%foo-$tls_gdidx$(%r1),%arg0
2472         b __tls_get_addr
2473         nop             
2474         addil LT%foo-$tls_ldidx$,gp
2475         b __tls_get_addr
2476         ldo RT%foo-$tls_ldidx$(%r1),%arg0
2477         addil LR%foo-$tls_dtpoff$,%ret0
2478         ldo RR%foo-$tls_dtpoff$(%r1),%t1
2479         mfctl %cr27,%t1                 
2480         addil LT%foo-$tls_ieoff$,gp
2481         ldw RT%foo-$tls_ieoff$(%r1),%t2
2482         add %t1,%t2,%t3                 
2483         mfctl %cr27,%t1                 
2484         addil LR%foo-$tls_leoff$,%t1
2485         ldo RR%foo-$tls_leoff$(%r1),%t2'
2486         tls_first_major=2
2487         tls_first_minor=15
2488         tls_as_opt=--fatal-warnings
2489         ;;
2490   arm*-*-*)
2491     conftest_s='
2492         .section ".tdata","awT",%progbits
2493 foo:    .long   25
2494         .text
2495 .word foo(gottpoff)
2496 .word foo(tpoff)
2497 .word foo(tlsgd)
2498 .word foo(tlsldm)
2499 .word foo(tlsldo)'
2500         tls_first_major=2
2501         tls_first_minor=17
2502         ;;
2503   i[34567]86-*-*)
2504     conftest_s='
2505         .section ".tdata","awT",@progbits
2506 foo:    .long   25
2507         .text
2508         movl    %gs:0, %eax
2509         leal    foo@TLSGD(,%ebx,1), %eax
2510         leal    foo@TLSLDM(%ebx), %eax
2511         leal    foo@DTPOFF(%eax), %edx
2512         movl    foo@GOTTPOFF(%ebx), %eax
2513         subl    foo@GOTTPOFF(%ebx), %eax
2514         addl    foo@GOTNTPOFF(%ebx), %eax
2515         movl    foo@INDNTPOFF, %eax
2516         movl    $foo@TPOFF, %eax
2517         subl    $foo@TPOFF, %eax
2518         leal    foo@NTPOFF(%ecx), %eax'
2519         tls_first_major=2
2520         tls_first_minor=14
2521         tls_as_opt=--fatal-warnings
2522         ;;
2523   x86_64-*-*)
2524     conftest_s='
2525         .section ".tdata","awT",@progbits
2526 foo:    .long   25
2527         .text
2528         movq    %fs:0, %rax
2529         leaq    foo@TLSGD(%rip), %rdi
2530         leaq    foo@TLSLD(%rip), %rdi
2531         leaq    foo@DTPOFF(%rax), %rdx
2532         movq    foo@GOTTPOFF(%rip), %rax
2533         movq    $foo@TPOFF, %rax'
2534         tls_first_major=2
2535         tls_first_minor=14
2536         tls_as_opt=--fatal-warnings
2537         ;;
2538   ia64-*-*)
2539     conftest_s='
2540         .section ".tdata","awT",@progbits
2541 foo:    data8   25
2542         .text
2543         addl    r16 = @ltoff(@dtpmod(foo#)), gp
2544         addl    r17 = @ltoff(@dtprel(foo#)), gp
2545         addl    r18 = @ltoff(@tprel(foo#)), gp
2546         addl    r19 = @dtprel(foo#), gp
2547         adds    r21 = @dtprel(foo#), r13
2548         movl    r23 = @dtprel(foo#)
2549         addl    r20 = @tprel(foo#), gp
2550         adds    r22 = @tprel(foo#), r13
2551         movl    r24 = @tprel(foo#)'
2552         tls_first_major=2
2553         tls_first_minor=13
2554         tls_as_opt=--fatal-warnings
2555         ;;
2556   mips*-*-*)
2557     conftest_s='
2558         .section .tdata,"awT",@progbits
2559 x:
2560         .word 2
2561         .text
2562         addiu $4, $28, %tlsgd(x)
2563         addiu $4, $28, %tlsldm(x)
2564         lui $4, %dtprel_hi(x)
2565         addiu $4, $4, %dtprel_lo(x)
2566         lw $4, %gottprel(x)($28)
2567         lui $4, %tprel_hi(x)
2568         addiu $4, $4, %tprel_lo(x)'
2569         tls_first_major=2
2570         tls_first_minor=16
2571         tls_as_opt='-32 --fatal-warnings'
2572         ;;
2573   m68k-*-*)
2574     conftest_s='
2575         .section .tdata,"awT",@progbits
2576 x:
2577         .word 2
2578         .text
2579 foo:
2580         move.l x@TLSGD(%a5),%a0
2581         move.l x@TLSLDM(%a5),%a0
2582         move.l x@TLSLDO(%a5),%a0
2583         move.l x@TLSIE(%a5),%a0
2584         move.l x@TLSLE(%a5),%a0'
2585         tls_first_major=2
2586         tls_first_minor=19
2587         tls_as_opt='--fatal-warnings'
2588         ;;
2589   powerpc-*-*)
2590     conftest_s='
2591         .section ".tdata","awT",@progbits
2592         .align 2
2593 ld0:    .space 4
2594 ld1:    .space 4
2595 x1:     .space 4
2596 x2:     .space 4
2597 x3:     .space 4
2598         .text
2599         addi 3,31,ld0@got@tlsgd
2600         bl __tls_get_addr
2601         addi 3,31,x1@got@tlsld
2602         bl __tls_get_addr
2603         addi 9,3,x1@dtprel
2604         addis 9,3,x2@dtprel@ha
2605         addi 9,9,x2@dtprel@l
2606         lwz 9,x3@got@tprel(31)
2607         add 9,9,x@tls
2608         addi 9,2,x1@tprel
2609         addis 9,2,x2@tprel@ha
2610         addi 9,9,x2@tprel@l'
2611         tls_first_major=2
2612         tls_first_minor=14
2613         tls_as_opt="-a32 --fatal-warnings"
2614         ;;
2615   powerpc64-*-*)
2616     conftest_s='
2617         .section ".tdata","awT",@progbits
2618         .align 3
2619 ld0:    .space 8
2620 ld1:    .space 8
2621 x1:     .space 8
2622 x2:     .space 8
2623 x3:     .space 8
2624         .text
2625         addi 3,2,ld0@got@tlsgd
2626         bl .__tls_get_addr
2627         nop
2628         addi 3,2,ld1@toc
2629         bl .__tls_get_addr
2630         nop
2631         addi 3,2,x1@got@tlsld
2632         bl .__tls_get_addr
2633         nop
2634         addi 9,3,x1@dtprel
2635         bl .__tls_get_addr
2636         nop
2637         addis 9,3,x2@dtprel@ha
2638         addi 9,9,x2@dtprel@l
2639         bl .__tls_get_addr
2640         nop
2641         ld 9,x3@got@dtprel(2)
2642         add 9,9,3
2643         bl .__tls_get_addr
2644         nop'
2645         tls_first_major=2
2646         tls_first_minor=14
2647         tls_as_opt="-a64 --fatal-warnings"
2648         ;;
2649   s390-*-*)
2650     conftest_s='
2651         .section ".tdata","awT",@progbits
2652 foo:    .long   25
2653         .text
2654         .long   foo@TLSGD
2655         .long   foo@TLSLDM
2656         .long   foo@DTPOFF
2657         .long   foo@NTPOFF
2658         .long   foo@GOTNTPOFF
2659         .long   foo@INDNTPOFF
2660         l       %r1,foo@GOTNTPOFF(%r12)
2661         l       %r1,0(%r1):tls_load:foo
2662         bas     %r14,0(%r1,%r13):tls_gdcall:foo
2663         bas     %r14,0(%r1,%r13):tls_ldcall:foo'
2664         tls_first_major=2
2665         tls_first_minor=14
2666         tls_as_opt="-m31 --fatal-warnings"
2667         ;;
2668   s390x-*-*)
2669     conftest_s='
2670         .section ".tdata","awT",@progbits
2671 foo:    .long   25
2672         .text
2673         .quad   foo@TLSGD
2674         .quad   foo@TLSLDM
2675         .quad   foo@DTPOFF
2676         .quad   foo@NTPOFF
2677         .quad   foo@GOTNTPOFF
2678         lg      %r1,foo@GOTNTPOFF(%r12)
2679         larl    %r1,foo@INDNTPOFF
2680         brasl   %r14,__tls_get_offset@PLT:tls_gdcall:foo
2681         brasl   %r14,__tls_get_offset@PLT:tls_ldcall:foo'
2682         tls_first_major=2
2683         tls_first_minor=14
2684         tls_as_opt="-m64 -Aesame --fatal-warnings"
2685         ;;
2686   sh-*-* | sh[34]-*-*)
2687     conftest_s='
2688         .section ".tdata","awT",@progbits
2689 foo:    .long   25
2690         .text
2691         .long   foo@TLSGD
2692         .long   foo@TLSLDM
2693         .long   foo@DTPOFF
2694         .long   foo@GOTTPOFF
2695         .long   foo@TPOFF'
2696         tls_first_major=2
2697         tls_first_minor=13
2698         tls_as_opt=--fatal-warnings
2699         ;;
2700   sparc*-*-*)
2701     case "$target" in
2702       sparc*-sun-solaris2.[56789]*)
2703         # TLS was introduced in the Solaris 9 4/04 release but
2704         # we do not enable it by default on Solaris 9 either.
2705         if test "x$enable_tls" = xyes ; then
2706           on_solaris=yes
2707         else
2708           enable_tls=no;
2709         fi
2710         ;;
2711       sparc*-sun-solaris2.*)
2712         on_solaris=yes
2713         ;;
2714       *)
2715         on_solaris=no
2716         ;;
2717     esac
2718     if test x$on_solaris = xyes && test x$gas_flag = xno; then
2719       conftest_s='
2720         .section ".tdata",#alloc,#write,#tls
2721 foo:    .long   25
2722         .text
2723         sethi   %tgd_hi22(foo), %o0
2724         add     %o0, %tgd_lo10(foo), %o1
2725         add     %l7, %o1, %o0, %tgd_add(foo)
2726         call    __tls_get_addr, %tgd_call(foo)
2727         sethi   %tldm_hi22(foo), %l1
2728         add     %l1, %tldm_lo10(foo), %l2
2729         add     %l7, %l2, %o0, %tldm_add(foo)
2730         call    __tls_get_addr, %tldm_call(foo)
2731         sethi   %tldo_hix22(foo), %l3
2732         xor     %l3, %tldo_lox10(foo), %l4
2733         add     %o0, %l4, %l5, %tldo_add(foo)
2734         sethi   %tie_hi22(foo), %o3
2735         add     %o3, %tie_lo10(foo), %o3
2736         ld      [%l7 + %o3], %o2, %tie_ld(foo)
2737         add     %g7, %o2, %o4, %tie_add(foo)
2738         sethi   %tle_hix22(foo), %l1
2739         xor     %l1, %tle_lox10(foo), %o5
2740         ld      [%g7 + %o5], %o1'
2741         tls_first_major=0
2742         tls_first_minor=0
2743     else
2744       conftest_s='
2745         .section ".tdata","awT",@progbits
2746 foo:    .long   25
2747         .text
2748         sethi   %tgd_hi22(foo), %o0
2749         add     %o0, %tgd_lo10(foo), %o1
2750         add     %l7, %o1, %o0, %tgd_add(foo)
2751         call    __tls_get_addr, %tgd_call(foo)
2752         sethi   %tldm_hi22(foo), %l1
2753         add     %l1, %tldm_lo10(foo), %l2
2754         add     %l7, %l2, %o0, %tldm_add(foo)
2755         call    __tls_get_addr, %tldm_call(foo)
2756         sethi   %tldo_hix22(foo), %l3
2757         xor     %l3, %tldo_lox10(foo), %l4
2758         add     %o0, %l4, %l5, %tldo_add(foo)
2759         sethi   %tie_hi22(foo), %o3
2760         add     %o3, %tie_lo10(foo), %o3
2761         ld      [%l7 + %o3], %o2, %tie_ld(foo)
2762         add     %g7, %o2, %o4, %tie_add(foo)
2763         sethi   %tle_hix22(foo), %l1
2764         xor     %l1, %tle_lox10(foo), %o5
2765         ld      [%g7 + %o5], %o1'
2766         tls_first_major=2
2767         tls_first_minor=14
2768         tls_as_opt="-32 --fatal-warnings"
2769       fi
2770         ;;
2771   xtensa*-*-*)
2772     conftest_s='
2773         .section ".tdata","awT",@progbits
2774 foo:    .long   25
2775         .text
2776         movi    a8, foo@TLSFUNC
2777         movi    a10, foo@TLSARG
2778         callx8.tls a8, foo@TLSCALL'
2779         tls_first_major=2
2780         tls_first_minor=19
2781         ;;
2782 changequote([,])dnl
2783 esac
2784 set_have_as_tls=no
2785 if test "x$enable_tls" = xno ; then
2786   : # TLS explicitly disabled.
2787 elif test "x$enable_tls" = xyes ; then
2788   set_have_as_tls=yes # TLS explicitly enabled.
2789 elif test -z "$tls_first_major"; then
2790   : # If we don't have a check, assume no support.
2791 else
2792   gcc_GAS_CHECK_FEATURE(thread-local storage support, gcc_cv_as_tls,
2793   [$tls_first_major,$tls_first_minor,0], [$tls_as_opt], [$conftest_s],,
2794   [set_have_as_tls=yes])
2795 fi
2796 if test $set_have_as_tls = yes ; then
2797   AC_DEFINE(HAVE_AS_TLS, 1,
2798             [Define if your assembler supports thread-local storage.])
2799 fi
2800
2801 # Target-specific assembler checks.
2802
2803 AC_MSG_CHECKING(linker -Bstatic/-Bdynamic option)
2804 gcc_cv_ld_static_dynamic=no
2805 if test $in_tree_ld = yes ; then
2806   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 10 -o "$gcc_cv_gld_major_version" -gt 2; then
2807     gcc_cv_ld_static_dynamic=yes
2808   fi
2809 elif test x$gcc_cv_ld != x; then
2810         # Check if linker supports -Bstatic/-Bdynamic option
2811         if $gcc_cv_ld --help 2>/dev/null | grep -- -Bstatic > /dev/null \
2812           && $gcc_cv_ld --help 2>/dev/null | grep -- -Bdynamic > /dev/null; then
2813                 gcc_cv_ld_static_dynamic=yes
2814         fi
2815 fi
2816 if test x"$gcc_cv_ld_static_dynamic" = xyes; then
2817         AC_DEFINE(HAVE_LD_STATIC_DYNAMIC, 1,
2818 [Define if your linker supports -Bstatic/-Bdynamic option.])
2819 fi
2820 AC_MSG_RESULT($gcc_cv_ld_static_dynamic)
2821
2822 if test x"$demangler_in_ld" = xyes; then
2823   AC_MSG_CHECKING(linker --demangle support)
2824   gcc_cv_ld_demangle=no
2825   if test $in_tree_ld = yes; then
2826     if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 14 -o "$gcc_cv_gld_major_version" -gt 2; then \
2827       gcc_cv_ld_demangle=yes
2828     fi
2829   elif test x$gcc_cv_ld != x -a x"$gnu_ld" = xyes; then
2830     # Check if the GNU linker supports --demangle option
2831     if $gcc_cv_ld --help 2>/dev/null | grep no-demangle > /dev/null; then
2832       gcc_cv_ld_demangle=yes
2833     fi
2834   fi
2835   if test x"$gcc_cv_ld_demangle" = xyes; then
2836     AC_DEFINE(HAVE_LD_DEMANGLE, 1,
2837 [Define if your linker supports --demangle option.])
2838   fi
2839   AC_MSG_RESULT($gcc_cv_ld_demangle)
2840 fi
2841
2842 case "$target" in
2843   # All TARGET_ABI_OSF targets.
2844   alpha*-*-osf* | alpha*-*-linux* | alpha*-*-*bsd*)
2845     gcc_GAS_CHECK_FEATURE([explicit relocation support],
2846         gcc_cv_as_alpha_explicit_relocs, [2,12,0],,
2847 [       .set nomacro
2848         .text
2849         extbl   $3, $2, $3      !lituse_bytoff!1
2850         ldq     $2, a($29)      !literal!1
2851         ldq     $4, b($29)      !literal!2
2852         ldq_u   $3, 0($2)       !lituse_base!1
2853         ldq     $27, f($29)     !literal!5
2854         jsr     $26, ($27), f   !lituse_jsr!5
2855         ldah    $29, 0($26)     !gpdisp!3
2856         lda     $0, c($29)      !gprel
2857         ldah    $1, d($29)      !gprelhigh
2858         lda     $1, d($1)       !gprellow
2859         lda     $29, 0($29)     !gpdisp!3],,
2860     [AC_DEFINE(HAVE_AS_EXPLICIT_RELOCS, 1,
2861   [Define if your assembler supports explicit relocations.])])
2862     gcc_GAS_CHECK_FEATURE([jsrdirect relocation support],
2863         gcc_cv_as_alpha_jsrdirect_relocs, [2,16,90],,
2864 [       .set nomacro
2865         .text
2866         ldq     $27, a($29)     !literal!1
2867         jsr     $26, ($27), a   !lituse_jsrdirect!1],,
2868     [AC_DEFINE(HAVE_AS_JSRDIRECT_RELOCS, 1,
2869   [Define if your assembler supports the lituse_jsrdirect relocation.])])
2870     ;;
2871
2872   cris-*-*)
2873     gcc_GAS_CHECK_FEATURE([-no-mul-bug-abort option],
2874       gcc_cv_as_cris_no_mul_bug,[2,15,91],
2875       [-no-mul-bug-abort], [.text],,
2876       [AC_DEFINE(HAVE_AS_NO_MUL_BUG_ABORT_OPTION, 1,
2877                 [Define if your assembler supports the -no-mul-bug-abort option.])])
2878     ;;
2879
2880   sparc*-*-*)
2881     gcc_GAS_CHECK_FEATURE([.register], gcc_cv_as_sparc_register_op,,,
2882       [.register %g2, #scratch],,
2883       [AC_DEFINE(HAVE_AS_REGISTER_PSEUDO_OP, 1,
2884                 [Define if your assembler supports .register.])])
2885
2886     gcc_GAS_CHECK_FEATURE([-relax option], gcc_cv_as_sparc_relax,,
2887       [-relax], [.text],,
2888       [AC_DEFINE(HAVE_AS_RELAX_OPTION, 1,
2889                 [Define if your assembler supports -relax option.])])
2890
2891     gcc_GAS_CHECK_FEATURE([unaligned pcrel relocs],
2892       gcc_cv_as_sparc_ua_pcrel,,
2893       [-K PIC],
2894 [.text
2895 foo:
2896         nop
2897 .data
2898 .align 4
2899 .byte 0
2900 .uaword %r_disp32(foo)],
2901       [if test x$gcc_cv_ld != x \
2902        && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1; then
2903          gcc_cv_as_sparc_ua_pcrel=yes
2904        fi
2905        rm -f conftest],
2906       [AC_DEFINE(HAVE_AS_SPARC_UA_PCREL, 1,
2907                 [Define if your assembler and linker support unaligned PC relative relocs.])
2908
2909       gcc_GAS_CHECK_FEATURE([unaligned pcrel relocs against hidden symbols],
2910         gcc_cv_as_sparc_ua_pcrel_hidden,,
2911         [-K PIC],
2912 [.data
2913 .align 4
2914 .byte 0x31
2915 .uaword %r_disp32(foo)
2916 .byte 0x32, 0x33, 0x34
2917 .global foo
2918 .hidden foo
2919 foo:
2920 .skip 4],
2921         [if test x$gcc_cv_ld != x && test x$gcc_cv_objdump != x \
2922          && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1 \
2923          && $gcc_cv_objdump -s -j .data conftest 2> /dev/null \
2924             | grep ' 31000000 07323334' > /dev/null 2>&1; then
2925             if $gcc_cv_objdump -R conftest 2> /dev/null \
2926                | grep 'DISP32' > /dev/null 2>&1; then
2927                 :
2928             else
2929                 gcc_cv_as_sparc_ua_pcrel_hidden=yes
2930             fi
2931          fi
2932          rm -f conftest],
2933          [AC_DEFINE(HAVE_AS_SPARC_UA_PCREL_HIDDEN, 1,
2934                    [Define if your assembler and linker support unaligned PC relative relocs against hidden symbols.])])
2935     ]) # unaligned pcrel relocs
2936
2937     gcc_GAS_CHECK_FEATURE([offsetable %lo()],
2938       gcc_cv_as_sparc_offsetable_lo10,,
2939       [-xarch=v9],
2940 [.text
2941         or %g1, %lo(ab) + 12, %g1
2942         or %g1, %lo(ab + 12), %g1],
2943       [if test x$gcc_cv_objdump != x \
2944        && $gcc_cv_objdump -s -j .text conftest.o 2> /dev/null \
2945           | grep ' 82106000 82106000' > /dev/null 2>&1; then
2946          gcc_cv_as_sparc_offsetable_lo10=yes
2947        fi],
2948        [AC_DEFINE(HAVE_AS_OFFSETABLE_LO10, 1,
2949                  [Define if your assembler supports offsetable %lo().])])
2950     ;;
2951
2952 changequote(,)dnl
2953   i[34567]86-*-* | x86_64-*-*)
2954 changequote([,])dnl
2955     case $target_os in
2956       cygwin* | pe | mingw32*)
2957         # Used for DWARF 2 in PE
2958         gcc_GAS_CHECK_FEATURE([.secrel32 relocs],
2959           gcc_cv_as_ix86_pe_secrel32,
2960           [2,15,91],,
2961 [.text
2962 foo:    nop
2963 .data
2964         .secrel32 foo],
2965           [if test x$gcc_cv_ld != x \
2966            && $gcc_cv_ld -o conftest conftest.o > /dev/null 2>&1; then
2967              gcc_cv_as_ix86_pe_secrel32=yes
2968            fi
2969            rm -f conftest],
2970           [AC_DEFINE(HAVE_GAS_PE_SECREL32_RELOC, 1,
2971             [Define if your assembler and linker support 32-bit section relative relocs via '.secrel32 label'.])])
2972         ;;
2973     esac
2974
2975     gcc_GAS_CHECK_FEATURE([filds and fists mnemonics],
2976        gcc_cv_as_ix86_filds,,,
2977        [filds mem; fists mem],,
2978        [AC_DEFINE(HAVE_AS_IX86_FILDS, 1,
2979          [Define if your assembler uses filds and fists mnemonics.])])
2980
2981     gcc_GAS_CHECK_FEATURE([fildq and fistpq mnemonics],
2982        gcc_cv_as_ix86_fildq,,,
2983        [fildq mem; fistpq mem],,
2984        [AC_DEFINE(HAVE_AS_IX86_FILDQ, 1,
2985          [Define if your assembler uses fildq and fistq mnemonics.])])
2986
2987     gcc_GAS_CHECK_FEATURE([cmov syntax],
2988       gcc_cv_as_ix86_cmov_sun_syntax,,,
2989       [cmovl.l %edx, %eax],,
2990       [AC_DEFINE(HAVE_AS_IX86_CMOV_SUN_SYNTAX, 1,
2991         [Define if your assembler supports the Sun syntax for cmov.])])
2992
2993     gcc_GAS_CHECK_FEATURE([ffreep mnemonic],
2994       gcc_cv_as_ix86_ffreep,,,
2995       [ffreep %st(1)],,
2996       [AC_DEFINE(HAVE_AS_IX86_FFREEP, 1,
2997         [Define if your assembler supports the ffreep mnemonic.])])
2998
2999     gcc_GAS_CHECK_FEATURE([sahf mnemonic],
3000       gcc_cv_as_ix86_sahf,,,
3001       [sahf],,
3002       [AC_DEFINE(HAVE_AS_IX86_SAHF, 1,
3003         [Define if your assembler supports the sahf mnemonic.])])
3004
3005     gcc_GAS_CHECK_FEATURE([different section symbol subtraction],
3006       gcc_cv_as_ix86_diff_sect_delta,,,
3007       [.section .rodata
3008 .L1:
3009         .long .L2-.L1
3010         .long .L3-.L1
3011         .text
3012 .L3:    nop
3013 .L2:    nop],,
3014       [AC_DEFINE(HAVE_AS_IX86_DIFF_SECT_DELTA, 1,
3015         [Define if your assembler supports the subtraction of symbols in different sections.])])
3016
3017     # This one is used unconditionally by i386.[ch]; it is to be defined
3018     # to 1 if the feature is present, 0 otherwise.
3019     gcc_GAS_CHECK_FEATURE([GOTOFF in data],
3020         gcc_cv_as_ix86_gotoff_in_data, [2,11,0],,
3021 [       .text
3022 .L0:
3023         nop
3024         .data
3025         .long .L0@GOTOFF])
3026     AC_DEFINE_UNQUOTED(HAVE_AS_GOTOFF_IN_DATA,
3027       [`if test $gcc_cv_as_ix86_gotoff_in_data = yes; then echo 1; else echo 0; fi`],
3028       [Define true if the assembler supports '.long foo@GOTOFF'.])
3029     ;;
3030
3031   ia64*-*-*)
3032     gcc_GAS_CHECK_FEATURE([ltoffx and ldxmov relocs],
3033         gcc_cv_as_ia64_ltoffx_ldxmov_relocs, [2,14,0],,
3034 [       .text
3035         addl r15 = @ltoffx(x#), gp
3036         ;;
3037         ld8.mov r16 = [[r15]], x#],,
3038     [AC_DEFINE(HAVE_AS_LTOFFX_LDXMOV_RELOCS, 1,
3039           [Define if your assembler supports ltoffx and ldxmov relocations.])])
3040
3041     ;;
3042
3043   powerpc*-*-*)
3044     case $target in
3045       *-*-aix*) conftest_s='    .machine "pwr5"
3046         .csect .text[[PR]]
3047         mfcr 3,128';;
3048       *-*-darwin*)
3049         gcc_GAS_CHECK_FEATURE([.machine directive support],
3050           gcc_cv_as_machine_directive,,,
3051           [     .machine ppc7400])
3052         if test x$gcc_cv_as_machine_directive != xyes; then
3053           echo "*** This target requires an assembler supporting \".machine\"" >&2
3054           echo you can get it from: ftp://gcc.gnu.org/pub/gcc/infrastructure/cctools-528.5.dmg >&2
3055           test x$build = x$target && exit 1
3056         fi
3057         conftest_s='    .text
3058         mfcr r3,128';;
3059       *) conftest_s='   .machine power4
3060         .text
3061         mfcr 3,128';;
3062     esac
3063
3064     gcc_GAS_CHECK_FEATURE([mfcr field support],
3065       gcc_cv_as_powerpc_mfcrf, [2,14,0],,
3066       [$conftest_s],,
3067       [AC_DEFINE(HAVE_AS_MFCRF, 1,
3068           [Define if your assembler supports mfcr field.])])
3069
3070     case $target in
3071       *-*-aix*) conftest_s='    .machine "pwr5"
3072         .csect .text[[PR]]
3073         popcntb 3,3';;
3074       *) conftest_s='   .machine power5
3075         .text
3076         popcntb 3,3';;
3077     esac
3078
3079     gcc_GAS_CHECK_FEATURE([popcntb support],
3080       gcc_cv_as_powerpc_popcntb, [2,17,0],,
3081       [$conftest_s],,
3082       [AC_DEFINE(HAVE_AS_POPCNTB, 1,
3083           [Define if your assembler supports popcntb field.])])
3084
3085     case $target in
3086       *-*-aix*) conftest_s='    .machine "pwr5x"
3087         .csect .text[[PR]]
3088         frin 1,1';;
3089       *) conftest_s='   .machine power5
3090         .text
3091         frin 1,1';;
3092     esac
3093
3094     gcc_GAS_CHECK_FEATURE([fp round support],
3095       gcc_cv_as_powerpc_fprnd, [2,17,0],,
3096       [$conftest_s],,
3097       [AC_DEFINE(HAVE_AS_FPRND, 1,
3098           [Define if your assembler supports fprnd.])])
3099
3100     case $target in
3101       *-*-aix*) conftest_s='    .machine "pwr6"
3102         .csect .text[[PR]]
3103         mffgpr 1,3';;
3104       *) conftest_s='   .machine power6
3105         .text
3106         mffgpr 1,3';;
3107     esac
3108
3109     gcc_GAS_CHECK_FEATURE([move fp gpr support],
3110       gcc_cv_as_powerpc_mfpgpr, [9,99,0],,
3111       [$conftest_s],,
3112       [AC_DEFINE(HAVE_AS_MFPGPR, 1,
3113           [Define if your assembler supports mffgpr and mftgpr.])])
3114
3115     case $target in
3116       *-*-aix*) conftest_s='    .csect .text[[PR]]
3117 LCF..0:
3118         addis 11,30,_GLOBAL_OFFSET_TABLE_-LCF..0@ha';;
3119       *-*-darwin*)
3120         conftest_s='    .text
3121 LCF0:
3122         addis r11,r30,_GLOBAL_OFFSET_TABLE_-LCF0@ha';;
3123       *) conftest_s='   .text
3124 .LCF0:
3125         addis 11,30,_GLOBAL_OFFSET_TABLE_-.LCF0@ha';;
3126     esac
3127
3128     gcc_GAS_CHECK_FEATURE([rel16 relocs],
3129       gcc_cv_as_powerpc_rel16, [2,17,0], -a32,
3130       [$conftest_s],,
3131       [AC_DEFINE(HAVE_AS_REL16, 1,
3132           [Define if your assembler supports R_PPC_REL16 relocs.])])
3133
3134     case $target in
3135       *-*-aix*) conftest_s='    .machine "pwr6"
3136         .csect .text[[PR]]
3137         cmpb 3,4,5';;
3138       *) conftest_s='   .machine power6
3139         .text
3140         cmpb 3,4,5';;
3141     esac
3142
3143     gcc_GAS_CHECK_FEATURE([compare bytes support],
3144       gcc_cv_as_powerpc_cmpb, [9,99,0], -a32,
3145       [$conftest_s],,
3146       [AC_DEFINE(HAVE_AS_CMPB, 1,
3147           [Define if your assembler supports cmpb.])])
3148
3149     case $target in
3150       *-*-aix*) conftest_s='    .machine "pwr6"
3151         .csect .text[[PR]]
3152         dadd 1,2,3';;
3153       *) conftest_s='   .machine power6
3154         .text
3155         dadd 1,2,3';;
3156     esac
3157
3158     gcc_GAS_CHECK_FEATURE([decimal float support],
3159       gcc_cv_as_powerpc_dfp, [9,99,0], -a32,
3160       [$conftest_s],,
3161       [AC_DEFINE(HAVE_AS_DFP, 1,
3162           [Define if your assembler supports DFP instructions.])])
3163
3164     case $target in
3165       *-*-aix*) conftest_s='    .machine "pwr7"
3166         .csect .text[[PR]]
3167         lxvd2x 1,2,3';;
3168       *) conftest_s='   .machine power7
3169         .text
3170         lxvd2x 1,2,3';;
3171     esac
3172
3173     gcc_GAS_CHECK_FEATURE([vector-scalar support],
3174       gcc_cv_as_powerpc_vsx, [9,99,0], -a32,
3175       [$conftest_s],,
3176       [AC_DEFINE(HAVE_AS_VSX, 1,
3177           [Define if your assembler supports VSX instructions.])])
3178
3179     gcc_GAS_CHECK_FEATURE([.gnu_attribute support],
3180       gcc_cv_as_powerpc_gnu_attribute, [2,18,0],,
3181       [.gnu_attribute 4,1],,
3182       [AC_DEFINE(HAVE_AS_GNU_ATTRIBUTE, 1,
3183           [Define if your assembler supports .gnu_attribute.])])
3184
3185     gcc_GAS_CHECK_FEATURE([tls marker support],
3186       gcc_cv_as_powerpc_tls_markers, [2,20,0],,
3187       [ bl __tls_get_addr(x@tlsgd)],,
3188       [AC_DEFINE(HAVE_AS_TLS_MARKERS, 1,
3189           [Define if your assembler supports arg info for __tls_get_addr.])])
3190     ;;
3191
3192   mips*-*-*)
3193     gcc_GAS_CHECK_FEATURE([explicit relocation support],
3194       gcc_cv_as_mips_explicit_relocs, [2,14,0],,
3195 [       lw $4,%gp_rel(foo)($4)],,
3196       [if test x$target_cpu_default = x
3197        then target_cpu_default=MASK_EXPLICIT_RELOCS
3198        else target_cpu_default="($target_cpu_default)|MASK_EXPLICIT_RELOCS"
3199        fi])
3200     gcc_GAS_CHECK_FEATURE([-mno-shared support],
3201       gcc_cv_as_mips_no_shared, [2,16,0], [-mno-shared], [nop],,
3202       [AC_DEFINE(HAVE_AS_NO_SHARED, 1,
3203                  [Define if the assembler understands -mno-shared.])])
3204
3205     gcc_GAS_CHECK_FEATURE([.gnu_attribute support],
3206       gcc_cv_as_mips_gnu_attribute, [2,18,0],,
3207       [.gnu_attribute 4,1],,
3208       [AC_DEFINE(HAVE_AS_GNU_ATTRIBUTE, 1,
3209           [Define if your assembler supports .gnu_attribute.])])
3210
3211     gcc_GAS_CHECK_FEATURE([.dtprelword support],
3212       gcc_cv_as_mips_dtprelword, [2,18,0],,
3213       [.section .tdata,"awT",@progbits
3214 x:
3215         .word 2
3216         .text
3217         .dtprelword x+0x8000],,
3218       [AC_DEFINE(HAVE_AS_DTPRELWORD, 1,
3219           [Define if your assembler supports .dtprelword.])])
3220     ;;
3221 esac
3222
3223 # Mips and HP-UX need the GNU assembler.
3224 # Linux on IA64 might be able to use the Intel assembler.
3225
3226 case "$target" in
3227   mips*-*-* | *-*-hpux* )
3228     if test x$gas_flag = xyes \
3229        || test x"$host" != x"$build" \
3230        || test ! -x "$gcc_cv_as" \
3231        || "$gcc_cv_as" -v < /dev/null 2>&1 | grep GNU > /dev/null; then
3232       :
3233     else
3234       echo "*** This configuration requires the GNU assembler" >&2
3235       exit 1
3236     fi
3237     ;;
3238 esac
3239
3240 # ??? Not all targets support dwarf2 debug_line, even within a version
3241 # of gas.  Moreover, we need to emit a valid instruction to trigger any
3242 # info to the output file.  So, as supported targets are added to gas 2.11,
3243 # add some instruction here to (also) show we expect this might work.
3244 # ??? Once 2.11 is released, probably need to add first known working
3245 # version to the per-target configury.
3246 case "$target" in
3247   i?86*-*-* | mips*-*-* | alpha*-*-* | powerpc*-*-* | sparc*-*-* | m68*-*-* \
3248   | x86_64*-*-* | hppa*-*-* | arm*-*-* \
3249   | xstormy16*-*-* | cris-*-* | crisv32-*-* | xtensa*-*-* | bfin-*-* | score*-*-* \
3250   | spu-*-* | fido*-*-* | m32c-*-*)
3251     insn="nop"
3252     ;;
3253   ia64*-*-* | s390*-*-*)
3254     insn="nop 0"
3255     ;;
3256   mmix-*-*)
3257     insn="swym 0"
3258     ;;
3259 esac
3260 if test x"$insn" != x; then
3261  conftest_s="\
3262         .file 1 \"conftest.s\"
3263         .loc 1 3 0
3264         $insn"
3265  gcc_GAS_CHECK_FEATURE([dwarf2 debug_line support],
3266   gcc_cv_as_dwarf2_debug_line,
3267   [elf,2,11,0],, [$conftest_s],
3268   [if test x$gcc_cv_objdump != x \
3269    && $gcc_cv_objdump -h conftest.o 2> /dev/null \
3270       | grep debug_line > /dev/null 2>&1; then
3271      gcc_cv_as_dwarf2_debug_line=yes
3272    fi])
3273
3274 # The .debug_line file table must be in the exact order that
3275 # we specified the files, since these indices are also used
3276 # by DW_AT_decl_file.  Approximate this test by testing if
3277 # the assembler bitches if the same index is assigned twice.
3278  gcc_GAS_CHECK_FEATURE([buggy dwarf2 .file directive],
3279   gcc_cv_as_dwarf2_file_buggy,,,
3280 [       .file 1 "foo.s"
3281         .file 1 "bar.s"])
3282
3283  if test $gcc_cv_as_dwarf2_debug_line = yes \
3284  && test $gcc_cv_as_dwarf2_file_buggy = no; then
3285         AC_DEFINE(HAVE_AS_DWARF2_DEBUG_LINE, 1,
3286   [Define if your assembler supports dwarf2 .file/.loc directives,
3287    and preserves file table indices exactly as given.])
3288  fi
3289
3290  gcc_GAS_CHECK_FEATURE([--gdwarf2 option],
3291   gcc_cv_as_gdwarf2_flag,
3292   [elf,2,11,0], [--gdwarf2], [$insn],,
3293   [AC_DEFINE(HAVE_AS_GDWARF2_DEBUG_FLAG, 1,
3294 [Define if your assembler supports the --gdwarf2 option.])])
3295
3296  gcc_GAS_CHECK_FEATURE([--gstabs option],
3297   gcc_cv_as_gstabs_flag,
3298   [elf,2,11,0], [--gstabs], [$insn],
3299   [# The native Solaris 9/Intel assembler doesn't understand --gstabs
3300    # and warns about it, but still exits successfully.  So check for
3301    # this.
3302    if AC_TRY_COMMAND([$gcc_cv_as --gstabs -o conftest.o conftest.s 2>&1 | grep -i warning > /dev/null])
3303    then :
3304    else gcc_cv_as_gstabs_flag=yes
3305    fi],
3306   [AC_DEFINE(HAVE_AS_GSTABS_DEBUG_FLAG, 1,
3307 [Define if your assembler supports the --gstabs option.])])
3308
3309  gcc_GAS_CHECK_FEATURE([--debug-prefix-map option],
3310   gcc_cv_as_debug_prefix_map_flag,
3311   [2,18,0], [--debug-prefix-map /a=/b], [$insn],,
3312   [AC_DEFINE(HAVE_AS_DEBUG_PREFIX_MAP, 1,
3313 [Define if your assembler supports the --debug-prefix-map option.])])
3314 fi
3315
3316 gcc_GAS_CHECK_FEATURE([.lcomm with alignment], gcc_cv_as_lcomm_with_alignment,
3317  ,,
3318 [.lcomm bar,4,16],,
3319 [AC_DEFINE(HAVE_GAS_LCOMM_WITH_ALIGNMENT, 1,
3320   [Define if your assembler supports .lcomm with an alignment field.])])
3321
3322 AC_CACHE_CHECK([assembler for tolerance to line number 0],
3323  [gcc_cv_as_line_zero],
3324  [gcc_cv_as_line_zero=no
3325   if test $in_tree_gas = yes; then
3326     gcc_GAS_VERSION_GTE_IFELSE(2, 16, 91, [gcc_cv_as_line_zero=yes])
3327   elif test "x$gcc_cv_as" != x; then
3328     { echo '# 1 "test.s" 1'; echo '# 0 "" 2'; } > conftest.s
3329     if AC_TRY_COMMAND([$gcc_cv_as -o conftest.o conftest.s >&AS_MESSAGE_LOG_FD 2>conftest.out]) &&
3330        test "x`cat conftest.out`" = x
3331     then
3332       gcc_cv_as_line_zero=yes
3333     else
3334       echo "configure: failed program was" >&AS_MESSAGE_LOG_FD
3335       cat conftest.s >&AS_MESSAGE_LOG_FD
3336       echo "configure: error output was" >&AS_MESSAGE_LOG_FD
3337       cat conftest.out >&AS_MESSAGE_LOG_FD
3338     fi
3339     rm -f conftest.o conftest.s conftest.out
3340   fi])
3341 if test "x$gcc_cv_as_line_zero" = xyes; then
3342   AC_DEFINE([HAVE_AS_LINE_ZERO], 1,
3343 [Define if the assembler won't complain about a line such as # 0 "" 2.])
3344 fi
3345
3346 AC_MSG_CHECKING(linker PT_GNU_EH_FRAME support)
3347 gcc_cv_ld_eh_frame_hdr=no
3348 if test $in_tree_ld = yes ; then
3349   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 12 -o "$gcc_cv_gld_major_version" -gt 2 \
3350      && test $in_tree_ld_is_elf = yes; then
3351     gcc_cv_ld_eh_frame_hdr=yes
3352   fi
3353 elif test x$gcc_cv_ld != x; then
3354         # Check if linker supports --eh-frame-hdr option
3355         if $gcc_cv_ld --help 2>/dev/null | grep eh-frame-hdr > /dev/null; then
3356                 gcc_cv_ld_eh_frame_hdr=yes
3357         fi
3358 fi
3359 GCC_TARGET_TEMPLATE([HAVE_LD_EH_FRAME_HDR])
3360 if test x"$gcc_cv_ld_eh_frame_hdr" = xyes; then
3361         AC_DEFINE(HAVE_LD_EH_FRAME_HDR, 1,
3362 [Define if your linker supports --eh-frame-hdr option.])
3363 fi
3364 AC_MSG_RESULT($gcc_cv_ld_eh_frame_hdr)
3365
3366 AC_MSG_CHECKING(linker position independent executable support)
3367 gcc_cv_ld_pie=no
3368 if test $in_tree_ld = yes ; then
3369   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 15 -o "$gcc_cv_gld_major_version" -gt 2 \
3370      && test $in_tree_ld_is_elf = yes; then
3371     gcc_cv_ld_pie=yes
3372   fi
3373 elif test x$gcc_cv_ld != x; then
3374         # Check if linker supports -pie option
3375         if $gcc_cv_ld --help 2>/dev/null | grep -- -pie > /dev/null; then
3376                 gcc_cv_ld_pie=yes
3377         fi
3378 fi
3379 if test x"$gcc_cv_ld_pie" = xyes; then
3380         AC_DEFINE(HAVE_LD_PIE, 1,
3381 [Define if your linker supports -pie option.])
3382 fi
3383 AC_MSG_RESULT($gcc_cv_ld_pie)
3384
3385 AC_MSG_CHECKING(linker EH-compatible garbage collection of sections)
3386 gcc_cv_ld_eh_gc_sections=no
3387 if test $in_tree_ld = yes ; then
3388   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 17 -o "$gcc_cv_gld_major_version" -gt 2 \
3389      && test $in_tree_ld_is_elf = yes; then
3390     gcc_cv_ld_eh_gc_sections=yes
3391   fi
3392 elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x -a x$gcc_cv_objdump != x ; then
3393   cat > conftest.s <<EOF
3394         .section        .text
3395 .globl _start
3396         .type _start, @function
3397 _start:
3398         .long foo
3399         .size _start, .-_start
3400         .section        .text.foo,"ax",@progbits
3401         .type foo, @function
3402 foo:
3403         .long 0
3404         .size foo, .-foo
3405         .section        .gcc_except_table.foo,"a",@progbits
3406 .L0:
3407         .long 0
3408         .section        .eh_frame,"a",@progbits
3409         .long .L0
3410 EOF
3411   if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
3412     if $gcc_cv_ld -o conftest conftest.o --entry=_start --gc-sections 2>&1 \
3413          | grep "gc-sections option ignored" > /dev/null; then
3414       gcc_cv_ld_eh_gc_sections=no
3415     elif $gcc_cv_objdump -h conftest | grep gcc_except_table > /dev/null; then
3416       gcc_cv_ld_eh_gc_sections=yes
3417       # If no COMDAT groups, the compiler will emit .gnu.linkonce.t. sections.
3418       if test x$gcc_cv_as_comdat_group != xyes; then
3419         gcc_cv_ld_eh_gc_sections=no
3420         cat > conftest.s <<EOF
3421         .section        .text
3422 .globl _start
3423         .type _start, @function
3424 _start:
3425         .long foo
3426         .size _start, .-_start
3427         .section        .gnu.linkonce.t.foo,"ax",@progbits
3428         .type foo, @function
3429 foo:
3430         .long 0
3431         .size foo, .-foo
3432         .section        .gcc_except_table.foo,"a",@progbits
3433 .L0:
3434         .long 0
3435         .section        .eh_frame,"a",@progbits
3436         .long .L0
3437 EOF
3438         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
3439           if $gcc_cv_ld -o conftest conftest.o --entry=_start --gc-sections 2>&1 \
3440                | grep "gc-sections option ignored" > /dev/null; then
3441             gcc_cv_ld_eh_gc_sections=no
3442           elif $gcc_cv_objdump -h conftest | grep gcc_except_table > /dev/null; then
3443             gcc_cv_ld_eh_gc_sections=yes
3444           fi
3445         fi
3446       fi
3447     fi
3448   fi
3449   rm -f conftest.s conftest.o conftest
3450 fi
3451 case "$target" in
3452   hppa*-*-linux*)
3453     # ??? This apparently exposes a binutils bug with PC-relative relocations.
3454     gcc_cv_ld_eh_gc_sections=no
3455     ;;
3456 esac
3457 if test x$gcc_cv_ld_eh_gc_sections = xyes; then
3458         AC_DEFINE(HAVE_LD_EH_GC_SECTIONS, 1,
3459   [Define if your linker supports garbage collection of
3460    sections in presence of EH frames.])
3461 fi
3462 AC_MSG_RESULT($gcc_cv_ld_eh_gc_sections)
3463
3464 # --------
3465 # UNSORTED
3466 # --------
3467
3468 AC_CACHE_CHECK(linker --as-needed support,
3469 gcc_cv_ld_as_needed,
3470 [gcc_cv_ld_as_needed=no
3471 if test $in_tree_ld = yes ; then
3472   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2 \
3473      && test $in_tree_ld_is_elf = yes; then
3474     gcc_cv_ld_as_needed=yes
3475   fi
3476 elif test x$gcc_cv_ld != x; then
3477         # Check if linker supports --as-needed and --no-as-needed options
3478         if $gcc_cv_ld --help 2>/dev/null | grep as-needed > /dev/null; then
3479                 gcc_cv_ld_as_needed=yes
3480         fi
3481 fi
3482 ])
3483 if test x"$gcc_cv_ld_as_needed" = xyes; then
3484         AC_DEFINE(HAVE_LD_AS_NEEDED, 1,
3485 [Define if your linker supports --as-needed and --no-as-needed options.])
3486 fi
3487
3488 case "$target:$tm_file" in
3489   powerpc64*-*-linux* | powerpc*-*-linux*rs6000/biarch64.h*)
3490     AC_CACHE_CHECK(linker support for omitting dot symbols,
3491     gcc_cv_ld_no_dot_syms,
3492     [gcc_cv_ld_no_dot_syms=no
3493     if test $in_tree_ld = yes ; then
3494       if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2; then
3495         gcc_cv_ld_no_dot_syms=yes
3496       fi
3497     elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x ; then
3498       cat > conftest1.s <<EOF
3499         .text
3500         bl .foo
3501 EOF
3502       cat > conftest2.s <<EOF
3503         .section ".opd","aw"
3504         .align 3
3505         .globl foo
3506         .type foo,@function
3507 foo:
3508         .quad .LEfoo,.TOC.@tocbase,0
3509         .text
3510 .LEfoo:
3511         blr
3512         .size foo,.-.LEfoo
3513 EOF
3514       if $gcc_cv_as -a64 -o conftest1.o conftest1.s > /dev/null 2>&1 \
3515          && $gcc_cv_as -a64 -o conftest2.o conftest2.s > /dev/null 2>&1 \
3516          && $gcc_cv_ld -melf64ppc -o conftest conftest1.o conftest2.o > /dev/null 2>&1; then
3517         gcc_cv_ld_no_dot_syms=yes
3518       fi
3519       rm -f conftest conftest1.o conftest2.o conftest1.s conftest2.s
3520     fi
3521     ])
3522     if test x"$gcc_cv_ld_no_dot_syms" = xyes; then
3523       AC_DEFINE(HAVE_LD_NO_DOT_SYMS, 1,
3524     [Define if your PowerPC64 linker only needs function descriptor syms.])
3525     fi
3526     ;;
3527 esac
3528
3529 AC_CACHE_CHECK(linker --build-id support,
3530   gcc_cv_ld_buildid,
3531   [gcc_cv_ld_buildid=no
3532   if test $in_tree_ld = yes ; then
3533     if test "$gcc_cv_gld_major_version" -eq 2 -a \
3534        "$gcc_cv_gld_minor_version" -ge 18 -o \
3535        "$gcc_cv_gld_major_version" -gt 2 \
3536        && test $in_tree_ld_is_elf = yes; then
3537       gcc_cv_ld_buildid=yes
3538     fi
3539   elif test x$gcc_cv_ld != x; then
3540     if $gcc_cv_ld --help 2>/dev/null | grep build-id > /dev/null; then
3541       gcc_cv_ld_buildid=yes
3542     fi
3543   fi])
3544 if test x"$gcc_cv_ld_buildid" = xyes; then
3545   AC_DEFINE(HAVE_LD_BUILDID, 1,
3546   [Define if your linker supports --build-id.])
3547 fi
3548
3549 AC_ARG_ENABLE(linker-build-id,
3550 [  --enable-linker-build-id
3551                           compiler will always pass --build-id to linker],
3552 [],
3553 enable_linker_build_id=no)
3554
3555 if test x"$enable_linker_build_id" = xyes; then
3556   if test x"$gcc_cv_ld_buildid" = xyes; then
3557     AC_DEFINE(ENABLE_LD_BUILDID, 1,
3558     [Define if gcc should always pass --build-id to linker.])
3559   else
3560     AC_MSG_WARN(--build-id is not supported by your linker; --enable-linker-build-id ignored)
3561   fi
3562 fi
3563
3564 AC_CACHE_CHECK(linker --sysroot support,
3565   gcc_cv_ld_sysroot,
3566   [gcc_cv_ld_sysroot=no
3567   if test $in_tree_ld = yes ; then
3568       if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2 ; then
3569         gcc_cv_ld_sysroot=yes
3570       fi
3571   elif test x$gcc_cv_ld != x; then 
3572     if $gcc_cv_ld --help 2>/dev/null | grep sysroot > /dev/null; then
3573       gcc_cv_ld_sysroot=yes
3574     fi
3575   fi])
3576 if test x"$gcc_cv_ld_sysroot" = xyes; then
3577   AC_DEFINE(HAVE_LD_SYSROOT, 1,
3578   [Define if your linker supports --sysroot.])
3579 fi        
3580
3581 if test x$with_sysroot = x && test x$host = x$target \
3582    && test "$prefix" != "/usr" && test "x$prefix" != "x$local_prefix" \
3583    && test "$prefix" != "NONE"; then
3584   AC_DEFINE_UNQUOTED(PREFIX_INCLUDE_DIR, "$prefix/include",
3585 [Define to PREFIX/include if cpp should also search that directory.])
3586 fi
3587
3588 # Test for stack protector support in target C library.
3589 AC_CACHE_CHECK(__stack_chk_fail in target C library,
3590       gcc_cv_libc_provides_ssp,
3591       [gcc_cv_libc_provides_ssp=no
3592     case "$target" in
3593        *-*-linux* | *-*-kfreebsd*-gnu | *-*-knetbsd*-gnu)
3594       if test x$host != x$target || test "x$TARGET_SYSTEM_ROOT" != x; then
3595         if test "x$with_sysroot" = x; then
3596           glibc_header_dir="${exec_prefix}/${target_noncanonical}/sys-include"
3597         elif test "x$with_build_sysroot" != "x"; then
3598           glibc_header_dir="${with_build_sysroot}/usr/include"
3599         elif test "x$with_sysroot" = xyes; then
3600           glibc_header_dir="${exec_prefix}/${target_noncanonical}/sys-root/usr/include"
3601         else
3602           glibc_header_dir="${with_sysroot}/usr/include"
3603         fi
3604       else
3605         glibc_header_dir=/usr/include
3606       fi
3607       # glibc 2.4 and later provides __stack_chk_fail and
3608       # either __stack_chk_guard, or TLS access to stack guard canary.
3609       if test -f $glibc_header_dir/features.h \
3610          && $EGREP '^@<:@       @:>@*#[         ]*define[       ]+__GNU_LIBRARY__[      ]+([1-9][0-9]|[6-9])' \
3611             $glibc_header_dir/features.h > /dev/null; then
3612         if $EGREP '^@<:@        @:>@*#[         ]*define[       ]+__GLIBC__[    ]+([1-9][0-9]|[3-9])' \
3613            $glibc_header_dir/features.h > /dev/null; then
3614           gcc_cv_libc_provides_ssp=yes
3615         elif $EGREP '^@<:@      @:>@*#[         ]*define[       ]+__GLIBC__[    ]+2' \
3616              $glibc_header_dir/features.h > /dev/null \
3617              && $EGREP '^@<:@   @:>@*#[         ]*define[       ]+__GLIBC_MINOR__[      ]+([1-9][0-9]|[4-9])' \
3618              $glibc_header_dir/features.h > /dev/null; then
3619           gcc_cv_libc_provides_ssp=yes
3620         elif $EGREP '^@<:@      @:>@*#[         ]*define[       ]+__UCLIBC__[   ]+1' \
3621              $glibc_header_dir/features.h > /dev/null && \
3622              test -f $glibc_header_dir/bits/uClibc_config.h && \
3623              $EGREP '^@<:@      @:>@*#[         ]*define[       ]+__UCLIBC_HAS_SSP__[   ]+1' \
3624              $glibc_header_dir/bits/uClibc_config.h > /dev/null; then
3625           gcc_cv_libc_provides_ssp=yes
3626         fi
3627       fi
3628         ;;
3629        *-*-gnu*)
3630          # Avoid complicated tests (see
3631          # <http://gcc.gnu.org/ml/gcc/2008-10/msg00130.html>) and for now