gcc/configure.ac

   1 # configure.ac for GCC
   2 # Process this file with autoconf to generate a configuration script.
   3
   4 # Copyright 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2004
   5 # Free Software Foundation, Inc.
   6
   7 #This file is part of GCC.
   8
   9 #GCC is free software; you can redistribute it and/or modify it under
  10 #the terms of the GNU General Public License as published by the Free
  11 #Software Foundation; either version 2, or (at your option) any later
  12 #version.
  13
  14 #GCC is distributed in the hope that it will be useful, but WITHOUT
  15 #ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  16 #FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  17 #for more details.
  18
  19 #You should have received a copy of the GNU General Public License
  20 #along with GCC; see the file COPYING.  If not, write to the Free
  21 #Software Foundation, 59 Temple Place - Suite 330, Boston, MA
  22 #02111-1307, USA.
  23
  24 # --------------------------------
  25 # Initialization and sanity checks
  26 # --------------------------------
  27
  28 AC_PREREQ(2.59)
  29 AC_INIT
  30 AC_CONFIG_SRCDIR(tree.c)
  31 AC_CONFIG_HEADER(auto-host.h:config.in)
  32
  33 #Set to 1 on a release branch
  34 is_release=
  35
  36 # Determine the host, build, and target systems
  37 AC_CANONICAL_BUILD
  38 AC_CANONICAL_HOST
  39 AC_CANONICAL_TARGET
  40
  41 # Determine the noncanonical target name, for directory use.
  42 ACX_NONCANONICAL_TARGET
  43
  44 # Determine the target- and build-specific subdirectories
  45 GCC_TOPLEV_SUBDIRS
  46
  47 # Set program_transform_name
  48 AC_ARG_PROGRAM
  49
  50 # Check for bogus environment variables.
  51 # Test if LIBRARY_PATH contains the notation for the current directory
  52 # since this would lead to problems installing/building glibc.
  53 # LIBRARY_PATH contains the current directory if one of the following
  54 # is true:
  55 # - one of the terminals (":" and ";") is the first or last sign
  56 # - two terminals occur directly after each other
  57 # - the path contains an element with a dot in it
  58 AC_MSG_CHECKING(LIBRARY_PATH variable)
  59 changequote(,)dnl
  60 case ${LIBRARY_PATH} in
  61   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
  62     library_path_setting="contains current directory"
  63     ;;
  64   *)
  65     library_path_setting="ok"
  66     ;;
  67 esac
  68 changequote([,])dnl
  69 AC_MSG_RESULT($library_path_setting)
  70 if test "$library_path_setting" != "ok"; then
  71 AC_MSG_ERROR([
  72 *** LIBRARY_PATH shouldn't contain the current directory when
  73 *** building gcc. Please change the environment variable
  74 *** and run configure again.])
  75 fi
  76
  77 # Test if GCC_EXEC_PREFIX contains the notation for the current directory
  78 # since this would lead to problems installing/building glibc.
  79 # GCC_EXEC_PREFIX contains the current directory if one of the following
  80 # is true:
  81 # - one of the terminals (":" and ";") is the first or last sign
  82 # - two terminals occur directly after each other
  83 # - the path contains an element with a dot in it
  84 AC_MSG_CHECKING(GCC_EXEC_PREFIX variable)
  85 changequote(,)dnl
  86 case ${GCC_EXEC_PREFIX} in
  87   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
  88     gcc_exec_prefix_setting="contains current directory"
  89     ;;
  90   *)
  91     gcc_exec_prefix_setting="ok"
  92     ;;
  93 esac
  94 changequote([,])dnl
  95 AC_MSG_RESULT($gcc_exec_prefix_setting)
  96 if test "$gcc_exec_prefix_setting" != "ok"; then
  97 AC_MSG_ERROR([
  98 *** GCC_EXEC_PREFIX shouldn't contain the current directory when
  99 *** building gcc. Please change the environment variable
 100 *** and run configure again.])
 101 fi
 102
 103 # -----------
 104 # Directories
 105 # -----------
 106
 107 # Specify the local prefix
 108 local_prefix=
 109 AC_ARG_WITH(local-prefix,
 110 [  --with-local-prefix=DIR specifies directory to put local include],
 111 [case "${withval}" in
 112 yes)    AC_MSG_ERROR(bad value ${withval} given for local include directory prefix) ;;
 113 no)     ;;
 114 *)      local_prefix=$with_local_prefix ;;
 115 esac])
 116
 117 # Default local prefix if it is empty
 118 if test x$local_prefix = x; then
 119         local_prefix=/usr/local
 120 fi
 121
 122 # Don't set gcc_gxx_include_dir to gxx_include_dir since that's only
 123 # passed in by the toplevel make and thus we'd get different behavior
 124 # depending on where we built the sources.
 125 gcc_gxx_include_dir=
 126 # Specify the g++ header file directory
 127 AC_ARG_WITH(gxx-include-dir,
 128 [  --with-gxx-include-dir=DIR
 129                           specifies directory to put g++ header files],
 130 [case "${withval}" in
 131 yes)    AC_MSG_ERROR(bad value ${withval} given for g++ include directory) ;;
 132 no)     ;;
 133 *)      gcc_gxx_include_dir=$with_gxx_include_dir ;;
 134 esac])
 135
 136 if test x${gcc_gxx_include_dir} = x; then
 137   if test x${enable_version_specific_runtime_libs} = xyes; then
 138     gcc_gxx_include_dir='${libsubdir}/include/c++'
 139   else
 140     topsrcdir=${srcdir}/.. . ${srcdir}/../config.if
 141 changequote(<<, >>)dnl
 142     gcc_gxx_include_dir="\$(libsubdir)/\$(unlibsubdir)/..\`echo \$(exec_prefix) | sed -e 's|^\$(prefix)||' -e 's|/[^/]*|/..|g'\`/include/"${libstdcxx_incdir}
 143 changequote([, ])dnl
 144   fi
 145 fi
 146
 147 AC_ARG_WITH(cpp_install_dir,
 148 [  --with-cpp-install-dir=DIR
 149                           install the user visible C preprocessor in DIR
 150                           (relative to PREFIX) as well as PREFIX/bin],
 151 [if test x$withval = xyes; then
 152   AC_MSG_ERROR([option --with-cpp-install-dir requires an argument])
 153 elif test x$withval != xno; then
 154   cpp_install_dir=$withval
 155 fi])
 156
 157 # We would like to our source tree to be readonly.  However when releases or
 158 # pre-releases are generated, the flex/bison generated files as well as the
 159 # various formats of manuals need to be included along with the rest of the
 160 # sources.  Therefore we have --enable-generated-files-in-srcdir to do
 161 # just that.
 162
 163 AC_MSG_CHECKING([whether to place generated files in the source directory])
 164   dnl generated-files-in-srcdir is disabled by default
 165   AC_ARG_ENABLE(generated-files-in-srcdir,
 166 [  --enable-generated-files-in-srcdir
 167                           put copies of generated files in source dir
 168                           intended for creating source tarballs for users
 169                           without texinfo bison or flex.],
 170       generated_files_in_srcdir=$enableval,
 171       generated_files_in_srcdir=no)
 172
 173 AC_MSG_RESULT($generated_files_in_srcdir)
 174
 175 if test "$generated_files_in_srcdir" = "yes"; then
 176   GENINSRC=''
 177 else
 178   GENINSRC='#'
 179 fi
 180 AC_SUBST(GENINSRC)
 181
 182 # -------------------
 183 # Find default linker
 184 # -------------------
 185
 186 # With GNU ld
 187 AC_ARG_WITH(gnu-ld,
 188 [  --with-gnu-ld           arrange to work with GNU ld.],
 189 gnu_ld_flag="$with_gnu_ld",
 190 gnu_ld_flag=no)
 191
 192 # With pre-defined ld
 193 AC_ARG_WITH(ld,
 194 [  --with-ld               arrange to use the specified ld (full pathname)],
 195 DEFAULT_LINKER="$with_ld")
 196 if test x"${DEFAULT_LINKER+set}" = x"set"; then
 197   if test ! -x "$DEFAULT_LINKER"; then
 198     AC_MSG_ERROR([cannot execute: $DEFAULT_LINKER: check --with-ld or env. var. DEFAULT_LINKER])
 199   elif $DEFAULT_LINKER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
 200     gnu_ld_flag=yes
 201   fi
 202   AC_DEFINE_UNQUOTED(DEFAULT_LINKER,"$DEFAULT_LINKER",
 203         [Define to enable the use of a default linker.])
 204 fi
 205
 206 AC_MSG_CHECKING([whether a default linker was specified])
 207 if test x"${DEFAULT_LINKER+set}" = x"set"; then
 208   if test x"$gnu_ld_flag" = x"no"; then
 209     AC_MSG_RESULT([yes ($DEFAULT_LINKER)])
 210   else
 211     AC_MSG_RESULT([yes ($DEFAULT_LINKER - GNU ld)])
 212   fi
 213 else
 214   AC_MSG_RESULT(no)
 215 fi
 216
 217 # With demangler in GNU ld
 218 AC_ARG_WITH(demangler-in-ld,
 219 [  --with-demangler-in-ld  try to use demangler in GNU ld.],
 220 demangler_in_ld="$with_demangler_in_ld",
 221 demangler_in_ld=no)
 222
 223 # ----------------------
 224 # Find default assembler
 225 # ----------------------
 226
 227 # With GNU as
 228 AC_ARG_WITH(gnu-as,
 229 [  --with-gnu-as           arrange to work with GNU as],
 230 gas_flag="$with_gnu_as",
 231 gas_flag=no)
 232
 233 AC_ARG_WITH(as,
 234 [  --with-as               arrange to use the specified as (full pathname)],
 235 DEFAULT_ASSEMBLER="$with_as")
 236 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
 237   if test ! -x "$DEFAULT_ASSEMBLER"; then
 238     AC_MSG_ERROR([cannot execute: $DEFAULT_ASSEMBLER: check --with-as or env. var. DEFAULT_ASSEMBLER])
 239   elif $DEFAULT_ASSEMBLER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
 240     gas_flag=yes
 241   fi
 242   AC_DEFINE_UNQUOTED(DEFAULT_ASSEMBLER,"$DEFAULT_ASSEMBLER",
 243         [Define to enable the use of a default assembler.])
 244 fi
 245
 246 AC_MSG_CHECKING([whether a default assembler was specified])
 247 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
 248   if test x"$gas_flag" = x"no"; then
 249     AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER)])
 250   else
 251     AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER - GNU as)])
 252   fi
 253 else
 254   AC_MSG_RESULT(no)
 255 fi
 256
 257 # ---------------
 258 # Find C compiler
 259 # ---------------
 260
 261 # If a non-executable a.out is present (e.g. created by GNU as above even if
 262 # invoked with -v only), the IRIX 6 native ld just overwrites the existing
 263 # file, even when creating an executable, so an execution test fails.
 264 # Remove possible default executable files to avoid this.
 265 #
 266 # FIXME: This really belongs into AC_PROG_CC and can be removed once
 267 # Autoconf includes it.
 268 rm -f a.out a.exe b.out
 269
 270 # Find the native compiler
 271 AC_PROG_CC
 272 AM_PROG_CC_C_O
 273 # autoconf is lame and doesn't give us any substitution variable for this.
 274 if eval "test \"`echo '$ac_cv_prog_cc_'${ac_cc}_c_o`\" = no"; then
 275   NO_MINUS_C_MINUS_O=yes
 276 else
 277   OUTPUT_OPTION='-o $@'
 278 fi
 279 AC_SUBST(NO_MINUS_C_MINUS_O)
 280 AC_SUBST(OUTPUT_OPTION)
 281
 282 # -------------------------
 283 # Check C compiler features
 284 # -------------------------
 285
 286 AC_PROG_CPP
 287 AC_C_INLINE
 288
 289 gcc_AC_C_LONG_LONG
 290
 291 # sizeof(char) is 1 by definition.
 292 AC_CHECK_SIZEOF(void *)
 293 AC_CHECK_SIZEOF(short)
 294 AC_CHECK_SIZEOF(int)
 295 AC_CHECK_SIZEOF(long)
 296 if test $ac_cv_c_long_long = yes; then
 297   AC_CHECK_SIZEOF(long long)
 298 fi
 299 if test $ac_cv_c___int64 = yes; then
 300   AC_CHECK_SIZEOF(__int64)
 301 fi
 302
 303 # ---------------------
 304 # Warnings and checking
 305 # ---------------------
 306
 307 # Check $CC warning features (if it's GCC).
 308 # We want to use -pedantic, but we don't want warnings about
 309 # * 'long long'
 310 # * variadic macros
 311 # So, we only use -pedantic if we can disable those warnings.
 312
 313 AC_CACHE_CHECK(
 314   [whether ${CC} accepts -Wno-long-long],
 315   [ac_cv_prog_cc_w_no_long_long],
 316   [save_CFLAGS="$CFLAGS"
 317   CFLAGS="-Wno-long-long"
 318   AC_COMPILE_IFELSE([AC_LANG_SOURCE([[]])],
 319                     [ac_cv_prog_cc_w_no_long_long=yes],
 320                     [ac_cv_prog_cc_w_no_long_long=no])
 321   CFLAGS="$save_CFLAGS"
 322   ])
 323
 324 AC_CACHE_CHECK(
 325   [whether ${CC} accepts -Wno-variadic-macros],
 326   [ac_cv_prog_cc_w_no_variadic_macros],
 327   [save_CFLAGS="$CFLAGS"
 328   CFLAGS="-Wno-variadic-macros"
 329   AC_COMPILE_IFELSE([AC_LANG_SOURCE([[]])],
 330                     [ac_cv_prog_cc_w_no_variadic_macros=yes],
 331                     [ac_cv_prog_cc_w_no_variadic_macros=no])
 332   CFLAGS="$save_CFLAGS"
 333   ])
 334
 335 strict1_warn=
 336 if test $ac_cv_prog_cc_w_no_long_long = yes \
 337    && test $ac_cv_prog_cc_w_no_variadic_macros = yes ; then
 338   strict1_warn="-pedantic -Wno-long-long -Wno-variadic-macros"
 339 fi
 340 AC_SUBST(strict1_warn)
 341
 342 # Add -Wold-style-definition if it's accepted
 343 AC_CACHE_CHECK(
 344   [whether ${CC} accepts -Wold-style-definition],
 345   [ac_cv_prog_cc_w_old_style_definition],
 346   [save_CFLAGS="$CFLAGS"
 347   CFLAGS="-Wold-style-definition"
 348   AC_COMPILE_IFELSE([AC_LANG_SOURCE([[]])],
 349                     [ac_cv_prog_cc_w_old_style_definition=yes],
 350                     [ac_cv_prog_cc_w_old_style_definition=no])
 351   CFLAGS="$save_CFLAGS"
 352   ])
 353 if test $ac_cv_prog_cc_w_old_style_definition = yes ; then
 354   strict1_warn="${strict1_warn} -Wold-style-definition"
 355 fi
 356
 357 # Enable -Werror, period.
 358 AC_ARG_ENABLE(werror_always,
 359 [  --enable-werror-always         enable -Werror always], [],
 360 [enable_werror_always=no])
 361 if test x${enable_werror_always} = xyes ; then
 362   strict1_warn="${strict1_warn} -Werror"
 363   WERROR=-Werror
 364 fi
 365
 366 # If the native compiler is GCC, we can enable warnings even in stage1.
 367 # That's useful for people building cross-compilers, or just running a
 368 # quick `make'.
 369 warn_cflags=
 370 if test "x$GCC" = "xyes"; then
 371   warn_cflags='$(GCC_WARN_CFLAGS)'
 372 fi
 373 AC_SUBST(warn_cflags)
 374
 375 # Enable -Werror in bootstrap stage2 and later.
 376 AC_ARG_ENABLE(werror,
 377 [  --enable-werror         enable -Werror in bootstrap stage2 and later], [],
 378 [if test x$is_release = x ; then
 379   # Default to "yes" on development branches.
 380   enable_werror=yes
 381 else
 382   # Default to "no" on release branches.
 383   enable_werror=no
 384 fi])
 385 if test x$enable_werror = xyes ; then
 386   WERROR=-Werror
 387 fi
 388 AC_SUBST(WERROR)
 389
 390 # Enable expensive internal checks
 391 AC_ARG_ENABLE(checking,
 392 [  --enable-checking[=LIST]
 393                           enable expensive run-time checks.  With LIST,
 394                           enable only specific categories of checks.
 395                           Categories are: assert,fold,gc,gcac,misc,
 396                           rtlflag,rtl,tree,valgrind,release,yes,all;],
 397 [ac_checking_flags="${enableval}"],[
 398 # Determine the default checks.
 399 if test x$is_release = x ; then
 400   ac_checking_flags=yes
 401 else
 402   ac_checking_flags=release
 403 fi])
 404 ac_assert_checking=1
 405 ac_checking=
 406 ac_tree_checking=
 407 ac_rtl_checking=
 408 ac_rtlflag_checking=
 409 ac_gc_checking=
 410 ac_gc_always_collect=
 411 ac_fold_checking=
 412 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 413 for check in $ac_checking_flags
 414 do
 415         case $check in
 416         yes)            ac_assert_checking=1 ; ac_checking=1 ;
 417                         ac_tree_checking=1 ; ac_gc_checking=1 ;
 418                         ac_rtlflag_checking=1 ;;
 419         no)             ac_assert_checking= ; ac_checking= ;
 420                         ac_tree_checking= ; ac_rtl_checking= ;
 421                         ac_rtlflag_checking= ; ac_gc_checking= ;
 422                         ac_gc_always_collect= ; ac_fold_checking= ;;
 423         all)            ac_assert_checking=1 ; ac_checking=1 ;
 424                         ac_tree_checking=1 ; ac_rtl_checking=1 ;
 425                         ac_rtlflag_checking=1 ; ac_gc_checking=1 ;
 426                         ac_gc_always_collect=1 ; ac_fold_checking=1 ;;
 427         release)        ac_assert_checking=1 ;;
 428         assert)         ac_assert_checking=1 ;;
 429         fold)           ac_fold_checking=1 ;;
 430         gc)             ac_gc_checking=1 ;;
 431         gcac)           ac_gc_always_collect=1 ;;
 432         misc)           ac_checking=1 ;;
 433         rtlflag)        ac_rtlflag_checking=1 ;;
 434         rtl)            ac_rtl_checking=1 ;;
 435         tree)           ac_tree_checking=1 ;;
 436         valgrind)       ac_checking_valgrind=1 ;;
 437         *)      AC_MSG_ERROR(unknown check category $check) ;;
 438         esac
 439 done
 440 IFS="$ac_save_IFS"
 441
 442 nocommon_flag=""
 443 if test x$ac_checking != x ; then
 444   AC_DEFINE(ENABLE_CHECKING, 1,
 445 [Define if you want more run-time sanity checks.  This one gets a grab
 446    bag of miscellaneous but relatively cheap checks.])
 447   nocommon_flag=-fno-common
 448 fi
 449 AC_SUBST(nocommon_flag)
 450 if test x$ac_assert_checking != x ; then
 451   AC_DEFINE(ENABLE_ASSERT_CHECKING, 1,
 452 [Define if you want assertions enabled.  This is a cheap check.])
 453 fi
 454 if test x$ac_tree_checking != x ; then
 455   AC_DEFINE(ENABLE_TREE_CHECKING, 1,
 456 [Define if you want all operations on trees (the basic data
 457    structure of the front ends) to be checked for dynamic type safety
 458    at runtime.  This is moderately expensive.  The tree browser debugging
 459    routines will also be enabled by this option.
 460    ])
 461   TREEBROWSER=tree-browser.o
 462 fi
 463 AC_SUBST(TREEBROWSER)
 464 if test x$ac_rtl_checking != x ; then
 465   AC_DEFINE(ENABLE_RTL_CHECKING, 1,
 466 [Define if you want all operations on RTL (the basic data structure
 467    of the optimizer and back end) to be checked for dynamic type safety
 468    at runtime.  This is quite expensive.])
 469 fi
 470 if test x$ac_rtlflag_checking != x ; then
 471   AC_DEFINE(ENABLE_RTL_FLAG_CHECKING, 1,
 472 [Define if you want RTL flag accesses to be checked against the RTL
 473    codes that are supported for each access macro.  This is relatively
 474    cheap.])
 475 fi
 476 if test x$ac_gc_checking != x ; then
 477   AC_DEFINE(ENABLE_GC_CHECKING, 1,
 478 [Define if you want the garbage collector to do object poisoning and
 479    other memory allocation checks.  This is quite expensive.])
 480 fi
 481 if test x$ac_gc_always_collect != x ; then
 482   AC_DEFINE(ENABLE_GC_ALWAYS_COLLECT, 1,
 483 [Define if you want the garbage collector to operate in maximally
 484    paranoid mode, validating the entire heap and collecting garbage at
 485    every opportunity.  This is extremely expensive.])
 486 fi
 487 if test x$ac_fold_checking != x ; then
 488   AC_DEFINE(ENABLE_FOLD_CHECKING, 1,
 489 [Define if you want fold checked that it never destructs its argument.
 490    This is quite expensive.])
 491 fi
 492 valgrind_path_defines=
 493 valgrind_command=
 494
 495 dnl # This check AC_REQUIREs various stuff, so it *must not* be inside
 496 dnl # an if statement.  This was the source of very frustrating bugs
 497 dnl # in converting to autoconf 2.5x!
 498 AC_CHECK_HEADER(valgrind.h, have_valgrind_h=yes, have_valgrind_h=no)
 499
 500 if test x$ac_checking_valgrind != x ; then
 501   # It is certainly possible that there's valgrind but no valgrind.h.
 502   # GCC relies on making annotations so we must have both.
 503   AC_MSG_CHECKING(for VALGRIND_DISCARD in <valgrind/memcheck.h>)
 504   AC_TRY_CPP(
 505     [#include <valgrind/memcheck.h>
 506 #ifndef VALGRIND_DISCARD
 507 #error VALGRIND_DISCARD not defined
 508 #endif],
 509   [gcc_cv_header_valgrind_memcheck_h=yes],
 510   [gcc_cv_header_valgrind_memcheck_h=no])
 511   AC_MSG_RESULT($gcc_cv_header_valgrind_memcheck_h)
 512   AC_MSG_CHECKING(for VALGRIND_DISCARD in <memcheck.h>)
 513   AC_TRY_CPP(
 514     [#include <memcheck.h>
 515 #ifndef VALGRIND_DISCARD
 516 #error VALGRIND_DISCARD not defined
 517 #endif],
 518   [gcc_cv_header_memcheck_h=yes],
 519   gcc_cv_header_memcheck_h=no)
 520   AC_MSG_RESULT($gcc_cv_header_memcheck_h)
 521   AM_PATH_PROG_WITH_TEST(valgrind_path, valgrind,
 522         [$ac_dir/$ac_word --version | grep valgrind- >/dev/null 2>&1])
 523   if test "x$valgrind_path" = "x" \
 524     || (test $have_valgrind_h = no \
 525         && test $gcc_cv_header_memcheck_h = no \
 526         && test $gcc_cv_header_valgrind_memcheck_h = no); then
 527         AC_MSG_ERROR([*** Can't find both valgrind and valgrind/memcheck.h, memcheck.h or valgrind.h])
 528   fi
 529   valgrind_path_defines=-DVALGRIND_PATH='\"'$valgrind_path'\"'
 530   valgrind_command="$valgrind_path -q"
 531   AC_DEFINE(ENABLE_VALGRIND_CHECKING, 1,
 532 [Define if you want to run subprograms and generated programs
 533    through valgrind (a memory checker).  This is extremely expensive.])
 534   if test $gcc_cv_header_valgrind_memcheck_h = yes; then
 535     AC_DEFINE(HAVE_VALGRIND_MEMCHECK_H, 1,
 536         [Define if valgrind's valgrind/memcheck.h header is installed.])
 537   fi
 538   if test $gcc_cv_header_memcheck_h = yes; then
 539     AC_DEFINE(HAVE_MEMCHECK_H, 1,
 540         [Define if valgrind's memcheck.h header is installed.])
 541   fi
 542 fi
 543 AC_SUBST(valgrind_path_defines)
 544 AC_SUBST(valgrind_command)
 545
 546 AC_ARG_ENABLE(mapped-location,
 547 [  --enable-mapped-location   location_t is fileline integer cookie],,
 548 enable_mapped_location=no)
 549
 550 if test "$enable_mapped_location" = yes ; then
 551   AC_DEFINE(USE_MAPPED_LOCATION, 1,
 552 [Define if location_t is fileline integer cookie.])
 553 fi
 554
 555 # Enable code coverage collection
 556 AC_ARG_ENABLE(coverage,
 557 [  --enable-coverage[=LEVEL]
 558                           enable compiler's code coverage collection.
 559                           Use to measure compiler performance and locate
 560                           unused parts of the compiler. With LEVEL, specify
 561                           optimization. Values are opt, noopt,
 562                           default is noopt],
 563 [case "${enableval}" in
 564   yes|noopt)
 565     coverage_flags="-fprofile-arcs -ftest-coverage -frandom-seed=\$@ -O0"
 566     ;;
 567   opt)
 568     coverage_flags="-fprofile-arcs -ftest-coverage -frandom-seed=\$@ -O2"
 569     ;;
 570   no)
 571     # a.k.a. --disable-coverage
 572     coverage_flags=""
 573     ;;
 574   *)
 575     AC_MSG_ERROR(unknown coverage setting $enableval)
 576     ;;
 577 esac],
 578 [coverage_flags=""])
 579 AC_SUBST(coverage_flags)
 580
 581 AC_ARG_ENABLE(gather-detailed-mem-stats,
 582 [  --enable-gather-detailed-mem-stats         enable detailed memory allocation stats gathering], [],
 583 [enable_gather_detailed_mem_stats=no])
 584 if test x$enable_gather_detailed_mem_stats = xyes ; then
 585   AC_DEFINE(GATHER_STATISTICS, 1,
 586         [Define to enable detailed memory allocation stats gathering.])
 587 fi
 588
 589 # -------------------------------
 590 # Miscenalleous configure options
 591 # -------------------------------
 592
 593 # With stabs
 594 AC_ARG_WITH(stabs,
 595 [  --with-stabs            arrange to use stabs instead of host debug format],
 596 stabs="$with_stabs",
 597 stabs=no)
 598
 599 # Determine whether or not multilibs are enabled.
 600 AC_ARG_ENABLE(multilib,
 601 [  --enable-multilib       enable library support for multiple ABIs],
 602 [], [enable_multilib=yes])
 603 AC_SUBST(enable_multilib)
 604
 605 # Enable __cxa_atexit for C++.
 606 AC_ARG_ENABLE(__cxa_atexit,
 607 [  --enable-__cxa_atexit   enable __cxa_atexit for C++],
 608 [], [])
 609
 610 # Enable threads
 611 # Pass with no value to take the default
 612 # Pass with a value to specify a thread package
 613 AC_ARG_ENABLE(threads,
 614 [  --enable-threads        enable thread usage for target GCC
 615   --enable-threads=LIB    use LIB thread package for target GCC],,
 616 [enable_threads=''])
 617
 618 AC_ARG_ENABLE(objc-gc,
 619 [  --enable-objc-gc       enable the use of Boehm's garbage collector with
 620                           the GNU Objective-C runtime],
 621 if test x$enable_objc_gc = xno; then
 622         objc_boehm_gc=''
 623 else
 624         objc_boehm_gc=1
 625 fi,
 626 objc_boehm_gc='')
 627
 628 AC_ARG_WITH(dwarf2,
 629 [  --with-dwarf2           force the default debug format to be DWARF 2],
 630 dwarf2="$with_dwarf2",
 631 dwarf2=no)
 632
 633 AC_ARG_ENABLE(shared,
 634 [  --disable-shared        don't provide a shared libgcc],
 635 [
 636   case $enable_shared in
 637   yes | no) ;;
 638   *)
 639     enable_shared=no
 640     IFS="${IFS=         }"; ac_save_ifs="$IFS"; IFS="${IFS}:,"
 641     for pkg in $enableval; do
 642       if test "X$pkg" = "Xgcc" || test "X$pkg" = "Xlibgcc"; then
 643         enable_shared=yes
 644       fi
 645     done
 646     IFS="$ac_save_ifs"
 647     ;;
 648   esac
 649 ], [enable_shared=yes])
 650 AC_SUBST(enable_shared)
 651
 652 AC_ARG_WITH(sysroot,
 653 [  --with-sysroot[=DIR] Search for usr/lib, usr/include, et al, within DIR.],
 654 [
 655  case ${with_sysroot} in
 656  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_noncanonical}/sys-root' ;;
 657  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
 658  esac
 659
 660  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
 661  CROSS_SYSTEM_HEADER_DIR='$(TARGET_SYSTEM_ROOT)$(NATIVE_SYSTEM_HEADER_DIR)'
 662
 663  if test "x$exec_prefix" = xNONE; then
 664   if test "x$prefix" = xNONE; then
 665    test_prefix=/usr/local
 666   else
 667    test_prefix=$prefix
 668   fi
 669  else
 670   test_prefix=$exec_prefix
 671  fi
 672  case ${TARGET_SYSTEM_ROOT} in
 673  "${test_prefix}"|"${test_prefix}/"*|\
 674  '${exec_prefix}'|'${exec_prefix}/'*)
 675    t="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE"
 676    TARGET_SYSTEM_ROOT_DEFINE="$t"
 677    ;;
 678  esac
 679 ], [
 680  TARGET_SYSTEM_ROOT=
 681  TARGET_SYSTEM_ROOT_DEFINE=
 682  CROSS_SYSTEM_HEADER_DIR='$(gcc_tooldir)/sys-include'
 683 ])
 684 AC_SUBST(TARGET_SYSTEM_ROOT)
 685 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
 686 AC_SUBST(CROSS_SYSTEM_HEADER_DIR)
 687
 688 # Build with intermodule optimisations
 689 AC_ARG_ENABLE(intermodule,
 690 [  --enable-intermodule    build the compiler in one step],
 691 [case ${enable_intermodule} in
 692   yes) onestep="-onestep";;
 693   *) onestep="";;
 694 esac],
 695 [onestep=""])
 696 AC_SUBST(onestep)
 697
 698 # Sanity check enable_languages in case someone does not run the toplevel
 699 # configure # script.
 700 AC_ARG_ENABLE(languages,
 701 [  --enable-languages=LIST specify which front-ends to build],
 702 [case ,${enable_languages}, in
 703        ,,|,yes,)
 704                 # go safe -- we cannot be much sure without the toplevel
 705                 # configure's
 706                 # analysis of which target libs are present and usable
 707                 enable_languages=c
 708                 ;;
 709          *,all,*)
 710                 AC_MSG_ERROR([only the toplevel supports --enable-languages=all])
 711                 ;;
 712         *,c,*)
 713                 ;;
 714         *)
 715                 enable_languages=c,${enable_languages}
 716                 ;;
 717 esac],
 718 [enable_languages=c])
 719
 720 subdirs=
 721 for lang in ${srcdir}/*/config-lang.in
 722 do
 723         case $lang in
 724         # The odd quoting in the next line works around
 725         # an apparent bug in bash 1.12 on linux.
 726 changequote(,)dnl
 727         ${srcdir}/[*]/config-lang.in) ;;
 728         *)
 729           lang_alias=`sed -n -e 's,^language=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^language=\([^   ]*\).*$,\1,p' $lang`
 730           if test "x$lang_alias" = x
 731           then
 732                 echo "$lang doesn't set \$language." 1>&2
 733                 exit 1
 734           fi
 735           case ",$enable_languages," in
 736           *,$lang_alias,*)
 737             subdirs="$subdirs `echo $lang | sed -e 's,^.*/\([^/]*\)/config-lang.in$,\1,'`" ;;
 738           esac
 739           ;;
 740 changequote([,])dnl
 741         esac
 742 done
 743
 744
 745 # -------------------------
 746 # Checks for other programs
 747 # -------------------------
 748
 749 AC_PROG_MAKE_SET
 750
 751 # Find some useful tools
 752 AC_PROG_AWK
 753 # We need awk to create options.c and options.h.
 754 # Bail out if it's missing.
 755 case ${AWK} in
 756   "") AC_MSG_ERROR([can't build without awk, bailing out]) ;;
 757 esac
 758
 759 gcc_AC_PROG_LN_S
 760 ACX_PROG_LN($LN_S)
 761 AC_PROG_RANLIB
 762 case "${host}" in
 763 *-*-darwin*)
 764   # By default, the Darwin ranlib will not treat common symbols as
 765   # definitions when  building the archive table of contents.  Other
 766   # ranlibs do that; pass an option to the Darwin ranlib that makes
 767   # it behave similarly.
 768   ranlib_flags="-c"
 769   ;;
 770 *)
 771   ranlib_flags=""
 772 esac
 773 AC_SUBST(ranlib_flags)
 774
 775 gcc_AC_PROG_INSTALL
 776
 777 # See if cmp has --ignore-initial.
 778 gcc_AC_PROG_CMP_IGNORE_INITIAL
 779
 780 # See if we have the mktemp command.
 781 AC_CHECK_PROG(have_mktemp_command, mktemp, yes, no)
 782
 783 MISSING="${CONFIG_SHELL-/bin/sh} $srcdir/../missing"
 784
 785 # See if makeinfo has been installed and is modern enough
 786 # that we can use it.
 787 gcc_AC_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
 788   [GNU texinfo.* \([0-9][0-9.]*\)],
 789   [4.[2-9]*])
 790 if test $gcc_cv_prog_makeinfo_modern = no; then
 791   MAKEINFO="$MISSING makeinfo"
 792   AC_MSG_WARN([
 793 *** Makeinfo is missing or too old.
 794 *** Info documentation will not be built.])
 795   BUILD_INFO=
 796 else
 797   BUILD_INFO=info
 798 fi
 799 AC_SUBST(BUILD_INFO)
 800
 801 # Is pod2man recent enough to regenerate manpages?
 802 AC_MSG_CHECKING([for recent Pod::Man])
 803 if (perl -e 'use 1.10 Pod::Man') >/dev/null 2>&1; then
 804   AC_MSG_RESULT(yes)
 805   GENERATED_MANPAGES=generated-manpages
 806 else
 807   AC_MSG_RESULT(no)
 808   GENERATED_MANPAGES=
 809 fi
 810 AC_SUBST(GENERATED_MANPAGES)
 811
 812 # How about lex?
 813 dnl Don't use AC_PROG_LEX; we insist on flex.
 814 dnl LEXLIB is not useful in gcc.
 815 AC_CHECK_PROGS([FLEX], flex, [$MISSING flex])
 816
 817 # Bison?
 818 AC_CHECK_PROGS([BISON], bison, [$MISSING bison])
 819
 820 # Binutils are not build modules, unlike bison/flex/makeinfo.  So we
 821 # check for build == host before using them.
 822
 823 # NM
 824 if test x${build} = x${host} && test -f $srcdir/../binutils/nm.c \
 825   && test -d ../binutils ; then
 826   NM='$(objdir)/../binutils/nm-new'
 827 else
 828   AC_CHECK_PROG(NM, nm, nm, ${CONFIG_SHELL-/bin/sh} ${srcdir}/../missing nm)
 829 fi
 830
 831 # AR
 832 if test x${build} = x${host} && test -f $srcdir/../binutils/ar.c \
 833   && test -d ../binutils ; then
 834   AR='$(objdir)/../binutils/ar'
 835 else
 836   AC_CHECK_PROG(AR, ar, ar, ${CONFIG_SHELL-/bin/sh} ${srcdir}/../missing ar)
 837 fi
 838
 839
 840 # --------------------
 841 # Checks for C headers
 842 # --------------------
 843
 844 AC_MSG_CHECKING(for GNU C library)
 845 AC_CACHE_VAL(gcc_cv_glibc,
 846 [AC_TRY_COMPILE(
 847   [#include <features.h>],[
 848 #if ! (defined __GLIBC__ || defined __GNU_LIBRARY__)
 849 #error Not a GNU C library system
 850 #endif],
 851   [gcc_cv_glibc=yes],
 852   gcc_cv_glibc=no)])
 853 AC_MSG_RESULT($gcc_cv_glibc)
 854 if test $gcc_cv_glibc = yes; then
 855   AC_DEFINE(_GNU_SOURCE, 1, [Always define this when using the GNU C Library])
 856 fi
 857
 858 # Need to reject headers which give warnings, so that the -Werror bootstrap
 859 # works later. *sigh*  This needs to come before all header checks.
 860 AC_PROG_CPP_WERROR
 861
 862 AC_HEADER_STDC
 863 AC_HEADER_TIME
 864 ACX_HEADER_STRING
 865 AC_HEADER_SYS_WAIT
 866 AC_CHECK_HEADERS(limits.h stddef.h string.h strings.h stdlib.h time.h iconv.h \
 867                  fcntl.h unistd.h sys/file.h sys/time.h sys/mman.h \
 868                  sys/resource.h sys/param.h sys/times.h sys/stat.h \
 869                  direct.h malloc.h langinfo.h ldfcn.h locale.h wchar.h)
 870
 871 # Check for thread headers.
 872 AC_CHECK_HEADER(thread.h, [have_thread_h=yes], [have_thread_h=])
 873 AC_CHECK_HEADER(pthread.h, [have_pthread_h=yes], [have_pthread_h=])
 874
 875 # These tests can't be done till we know if we have limits.h.
 876 gcc_AC_C_CHAR_BIT
 877 AC_C_BIGENDIAN_CROSS
 878
 879 # --------
 880 # UNSORTED
 881 # --------
 882
 883 # Stage specific cflags for build.
 884 stage1_cflags=
 885 case $build in
 886 vax-*-*)
 887   if test x$GCC = xyes
 888   then
 889     stage1_cflags="-Wa,-J"
 890   else
 891     stage1_cflags="-J"
 892   fi
 893   ;;
 894 powerpc-*-darwin*)
 895   # The spiffy cpp-precomp chokes on some legitimate constructs in GCC
 896   # sources; use -no-cpp-precomp to get to GNU cpp.
 897   # Apple's GCC has bugs in designated initializer handling, so disable
 898   # that too.
 899   stage1_cflags="-no-cpp-precomp -DHAVE_DESIGNATED_INITIALIZERS=0"
 900   ;;
 901 esac
 902 AC_SUBST(stage1_cflags)
 903
 904 # These libraries may be used by collect2.
 905 # We may need a special search path to get them linked.
 906 AC_CACHE_CHECK(for collect2 libraries, gcc_cv_collect2_libs,
 907 [save_LIBS="$LIBS"
 908 for libs in '' -lld -lmld \
 909                 '-L/usr/lib/cmplrs/cc2.11 -lmld' \
 910                 '-L/usr/lib/cmplrs/cc3.11 -lmld'
 911 do
 912         LIBS="$libs"
 913         AC_TRY_LINK_FUNC(ldopen,
 914                 [gcc_cv_collect2_libs="$libs"; break])
 915 done
 916 LIBS="$save_LIBS"
 917 test -z "$gcc_cv_collect2_libs" && gcc_cv_collect2_libs='none required'])
 918 case $gcc_cv_collect2_libs in
 919         "none required")        ;;
 920         *)      COLLECT2_LIBS=$gcc_cv_collect2_libs ;;
 921 esac
 922 AC_SUBST(COLLECT2_LIBS)
 923
 924 # When building Ada code on Alpha, we need exc_resume which is usually in
 925 # -lexc.  So test for it.
 926 save_LIBS="$LIBS"
 927 LIBS=
 928 AC_SEARCH_LIBS(exc_resume, exc)
 929 GNAT_LIBEXC="$LIBS"
 930 LIBS="$save_LIBS"
 931 AC_SUBST(GNAT_LIBEXC)
 932
 933 # Some systems put ldexp and frexp in libm instead of libc; assume
 934 # they're both in the same place.  jcf-dump needs them.
 935 save_LIBS="$LIBS"
 936 LIBS=
 937 AC_SEARCH_LIBS(ldexp, m)
 938 LDEXP_LIB="$LIBS"
 939 LIBS="$save_LIBS"
 940 AC_SUBST(LDEXP_LIB)
 941
 942 # Use <inttypes.h> only if it exists,
 943 # doesn't clash with <sys/types.h>, and declares intmax_t.
 944 AC_MSG_CHECKING(for inttypes.h)
 945 AC_CACHE_VAL(gcc_cv_header_inttypes_h,
 946 [AC_TRY_COMPILE(
 947   [#include <sys/types.h>
 948 #include <inttypes.h>],
 949   [intmax_t i = -1;],
 950   [gcc_cv_header_inttypes_h=yes],
 951   gcc_cv_header_inttypes_h=no)])
 952 AC_MSG_RESULT($gcc_cv_header_inttypes_h)
 953 if test $gcc_cv_header_inttypes_h = yes; then
 954   AC_DEFINE(HAVE_INTTYPES_H, 1,
 955         [Define if you have a working <inttypes.h> header file.])
 956 fi
 957
 958 dnl Disabled until we have a complete test for buggy enum bitfields.
 959 dnl gcc_AC_C_ENUM_BF_UNSIGNED
 960
 961 AC_CHECK_FUNCS(times clock dup2 kill getrlimit setrlimit atoll atoq \
 962         sysconf strsignal putc_unlocked fputc_unlocked fputs_unlocked \
 963         fwrite_unlocked fprintf_unlocked getrusage nl_langinfo \
 964         scandir alphasort gettimeofday mbstowcs wcswidth mmap mincore \
 965         setlocale)
 966
 967 if test x$ac_cv_func_mbstowcs = xyes; then
 968   AC_CACHE_CHECK(whether mbstowcs works, gcc_cv_func_mbstowcs_works,
 969 [    AC_TRY_RUN([#include <stdlib.h>
 970 int main()
 971 {
 972   mbstowcs(0, "", 0);
 973   return 0;
 974 }],
 975     gcc_cv_func_mbstowcs_works=yes,
 976     gcc_cv_func_mbstowcs_works=no,
 977     gcc_cv_func_mbstowcs_works=yes)])
 978   if test x$gcc_cv_func_mbstowcs_works = xyes; then
 979     AC_DEFINE(HAVE_WORKING_MBSTOWCS, 1,
 980   [Define this macro if mbstowcs does not crash when its
 981    first argument is NULL.])
 982   fi
 983 fi
 984
 985 AC_CHECK_TYPE(ssize_t, int)
 986
 987 # Try to determine the array type of the second argument of getgroups
 988 # for the target system (int or gid_t).
 989 AC_TYPE_GETGROUPS
 990 if test "${target}" = "${build}"; then
 991   TARGET_GETGROUPS_T=$ac_cv_type_getgroups
 992 else
 993   case "${target}" in
 994         # This condition may need some tweaking.  It should include all
 995         # targets where the array type of the second argument of getgroups
 996         # is int and the type of gid_t is not equivalent to int.
 997         *-*-sunos* | *-*-ultrix*)
 998                 TARGET_GETGROUPS_T=int
 999                 ;;
1000         *)
1001                 TARGET_GETGROUPS_T=gid_t
1002                 ;;
1003   esac
1004 fi
1005 AC_SUBST(TARGET_GETGROUPS_T)
1006
1007 gcc_AC_FUNC_PRINTF_PTR
1008 gcc_AC_FUNC_MMAP_BLACKLIST
1009
1010 case "${host}" in
1011 *-*-*vms*)
1012   # Under VMS, vfork works very differently than on Unix. The standard test
1013   # won't work, and it isn't easily adaptable. It makes more sense to
1014   # just force it.
1015   ac_cv_func_vfork_works=yes
1016   ;;
1017 esac
1018 AC_FUNC_VFORK
1019
1020 AM_ICONV
1021 # Until we have in-tree GNU iconv:
1022 LIBICONV_DEP=
1023 AC_SUBST(LIBICONV_DEP)
1024
1025 AM_LC_MESSAGES
1026
1027 AM_LANGINFO_CODESET
1028
1029 # We will need to find libiberty.h and ansidecl.h
1030 saved_CFLAGS="$CFLAGS"
1031 CFLAGS="$CFLAGS -I${srcdir} -I${srcdir}/../include"
1032 gcc_AC_CHECK_DECLS(getenv atol sbrk abort atof getcwd getwd \
1033         strsignal putc_unlocked fputs_unlocked fwrite_unlocked \
1034         fprintf_unlocked strstr errno snprintf vasprintf \
1035         malloc realloc calloc free basename getopt clock getpagesize, , ,[
1036 #include "ansidecl.h"
1037 #include "system.h"])
1038
1039 gcc_AC_CHECK_DECLS(getrlimit setrlimit getrusage, , ,[
1040 #include "ansidecl.h"
1041 #include "system.h"
1042 #ifdef HAVE_SYS_RESOURCE_H
1043 #include <sys/resource.h>
1044 #endif
1045 ])
1046
1047 AC_TRY_COMPILE([
1048 #include "ansidecl.h"
1049 #include "system.h"
1050 #ifdef HAVE_SYS_RESOURCE_H
1051 #include <sys/resource.h>
1052 #endif
1053 ],[rlim_t l = 0;],,[AC_DEFINE([rlim_t],[long],
1054 [Define to \`long' if <sys/resource.h> doesn't define.])])
1055
1056 gcc_AC_CHECK_DECLS(ldgetname, , ,[
1057 #include "ansidecl.h"
1058 #include "system.h"
1059 #ifdef HAVE_LDFCN_H
1060 #include <ldfcn.h>
1061 #endif
1062 ])
1063
1064 gcc_AC_CHECK_DECLS(times, , ,[
1065 #include "ansidecl.h"
1066 #include "system.h"
1067 #ifdef HAVE_SYS_TIMES_H
1068 #include <sys/times.h>
1069 #endif
1070 ])
1071
1072 # More time-related stuff.
1073 AC_CACHE_CHECK(for struct tms, ac_cv_struct_tms, [
1074 AC_TRY_COMPILE([
1075 #include "ansidecl.h"
1076 #include "system.h"
1077 #ifdef HAVE_SYS_TIMES_H
1078 #include <sys/times.h>
1079 #endif
1080 ], [struct tms tms;], ac_cv_struct_tms=yes, ac_cv_struct_tms=no)])
1081 if test $ac_cv_struct_tms = yes; then
1082   AC_DEFINE(HAVE_STRUCT_TMS, 1,
1083   [Define if <sys/times.h> defines struct tms.])
1084 fi
1085
1086 # use gcc_cv_* here because this doesn't match the behavior of AC_CHECK_TYPE.
1087 # revisit after autoconf 2.50.
1088 AC_CACHE_CHECK(for clock_t, gcc_cv_type_clock_t, [
1089 AC_TRY_COMPILE([
1090 #include "ansidecl.h"
1091 #include "system.h"
1092 ], [clock_t x;], gcc_cv_type_clock_t=yes, gcc_cv_type_clock_t=no)])
1093 if test $gcc_cv_type_clock_t = yes; then
1094   AC_DEFINE(HAVE_CLOCK_T, 1,
1095   [Define if <time.h> defines clock_t.])
1096 fi
1097
1098 # Restore CFLAGS from before the gcc_AC_NEED_DECLARATIONS tests.
1099 CFLAGS="$saved_CFLAGS"
1100
1101 gcc_AC_INITFINI_ARRAY
1102
1103 # mkdir takes a single argument on some systems.
1104 gcc_AC_FUNC_MKDIR_TAKES_ONE_ARG
1105
1106 # File extensions
1107 manext='.1'
1108 objext='.o'
1109 AC_SUBST(manext)
1110 AC_SUBST(objext)
1111
1112 # With Setjmp/Longjmp based exception handling.
1113 AC_ARG_ENABLE(sjlj-exceptions,
1114 [  --enable-sjlj-exceptions
1115                           arrange to use setjmp/longjmp exception handling],
1116 [sjlj=`if test $enableval = yes; then echo 1; else echo 0; fi`
1117 AC_DEFINE_UNQUOTED(CONFIG_SJLJ_EXCEPTIONS, $sjlj,
1118   [Define 0/1 to force the choice for exception handling model.])])
1119
1120 # For platforms with the unwind ABI which includes an unwind library,
1121 # libunwind, we can choose to use the system libunwind.
1122 AC_ARG_WITH(system-libunwind,
1123 [  --with-system-libunwind use installed libunwind])
1124
1125 # --------------------------------------------------------
1126 # Build, host, and target specific configuration fragments
1127 # --------------------------------------------------------
1128
1129 # Collect build-machine-specific information.
1130 . ${srcdir}/config.build
1131
1132 # Collect host-machine-specific information.
1133 . ${srcdir}/config.host
1134
1135 target_gtfiles=
1136
1137 # Collect target-machine-specific information.
1138 . ${srcdir}/config.gcc
1139
1140 extra_objs="${host_extra_objs} ${extra_objs}"
1141 extra_gcc_objs="${host_extra_gcc_objs} ${extra_gcc_objs}"
1142
1143 # Default the target-machine variables that were not explicitly set.
1144 if test x"$tm_file" = x
1145 then tm_file=$cpu_type/$cpu_type.h; fi
1146
1147 if test x"$extra_headers" = x
1148 then extra_headers=; fi
1149
1150 if test x$md_file = x
1151 then md_file=$cpu_type/$cpu_type.md; fi
1152
1153 if test x$out_file = x
1154 then out_file=$cpu_type/$cpu_type.c; fi
1155
1156 if test x"$tmake_file" = x
1157 then tmake_file=$cpu_type/t-$cpu_type
1158 fi
1159
1160 if test x"$dwarf2" = xyes
1161 then tm_file="$tm_file tm-dwarf2.h"
1162 fi
1163
1164 # Say what files are being used for the output code and MD file.
1165 echo "Using \`$srcdir/config/$out_file' for machine-specific logic."
1166 echo "Using \`$srcdir/config/$md_file' as machine description file."
1167
1168 # If any of the xm_file variables contain nonexistent files, warn
1169 # about them and drop them.
1170
1171 bx=
1172 for x in $build_xm_file; do
1173   if    test -f $srcdir/config/$x
1174   then      bx="$bx $x"
1175   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1176   fi
1177 done
1178 build_xm_file="$bx"
1179
1180 hx=
1181 for x in $host_xm_file; do
1182   if    test -f $srcdir/config/$x
1183   then      hx="$hx $x"
1184   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1185   fi
1186 done
1187 host_xm_file="$hx"
1188
1189 tx=
1190 for x in $xm_file; do
1191   if    test -f $srcdir/config/$x
1192   then      tx="$tx $x"
1193   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1194   fi
1195 done
1196 xm_file="$tx"
1197
1198 count=a
1199 for f in $tm_file; do
1200         count=${count}x
1201 done
1202 if test $count = ax; then
1203         echo "Using \`$srcdir/config/$tm_file' as target machine macro file."
1204 else
1205         echo "Using the following target machine macro files:"
1206         for f in $tm_file; do
1207                 echo "  $srcdir/config/$f"
1208         done
1209 fi
1210
1211 if test x$need_64bit_hwint = xyes; then
1212         AC_DEFINE(NEED_64BIT_HOST_WIDE_INT, 1,
1213 [Define to 1 if HOST_WIDE_INT must be 64 bits wide (see hwint.h).])
1214 fi
1215
1216 if test x$use_long_long_for_widest_fast_int = xyes; then
1217         AC_DEFINE(USE_LONG_LONG_FOR_WIDEST_FAST_INT, 1,
1218 [Define to 1 if the 'long long' (or '__int64') is wider than 'long' but still
1219 efficiently supported by the host hardware.])
1220 fi
1221
1222 count=a
1223 for f in $host_xm_file; do
1224         count=${count}x
1225 done
1226 if test $count = a; then
1227         :
1228 elif test $count = ax; then
1229         echo "Using \`$srcdir/config/$host_xm_file' as host machine macro file."
1230 else
1231         echo "Using the following host machine macro files:"
1232         for f in $host_xm_file; do
1233                 echo "  $srcdir/config/$f"
1234         done
1235 fi
1236 echo "Using ${out_host_hook_obj} for host machine hooks."
1237
1238 if test "$host_xm_file" != "$build_xm_file"; then
1239         count=a
1240         for f in $build_xm_file; do
1241                 count=${count}x
1242         done
1243         if test $count = a; then
1244                 :
1245         elif test $count = ax; then
1246                 echo "Using \`$srcdir/config/$build_xm_file' as build machine macro file."
1247         else
1248                 echo "Using the following build machine macro files:"
1249                 for f in $build_xm_file; do
1250                         echo "  $srcdir/config/$f"
1251                 done
1252         fi
1253 fi
1254
1255 # ---------
1256 # Threading
1257 # ---------
1258
1259 # Check if a valid thread package
1260 case ${enable_threads} in
1261   "" | no)
1262     # No threads
1263     target_thread_file='single'
1264     ;;
1265   yes)
1266     # default
1267     target_thread_file='single'
1268     ;;
1269   aix | dce | gnat | irix | posix | posix95 | rtems | \
1270   single | solaris | vxworks | win32 )
1271     target_thread_file=${enable_threads}
1272     ;;
1273   *)
1274     echo "${enable_threads} is an unknown thread package" 1>&2
1275     exit 1
1276     ;;
1277 esac
1278
1279 if test x${thread_file} = x; then
1280   # No thread file set by target-specific clauses in config.gcc,
1281   # so use file chosen by default logic above
1282   thread_file=${target_thread_file}
1283 fi
1284
1285 # Make gthr-default.h if we have a thread file.
1286 gthread_flags=
1287 if test $thread_file != single; then
1288   rm -f gthr-default.h
1289   echo "#include \"gthr-${thread_file}.h\"" > gthr-default.h
1290   gthread_flags=-DHAVE_GTHR_DEFAULT
1291 fi
1292 AC_SUBST(gthread_flags)
1293
1294 # --------
1295 # UNSORTED
1296 # --------
1297
1298 use_cxa_atexit=no
1299 if test x$enable___cxa_atexit = xyes || \
1300    test x$enable___cxa_atexit = x -a x$default_use_cxa_atexit = xyes; then
1301   if test x$host = x$target; then
1302     AC_CHECK_FUNC(__cxa_atexit,[use_cxa_atexit=yes],
1303         [echo "__cxa_atexit can't be enabled on this target"])
1304   else
1305     # We can't check for __cxa_atexit when building a cross, so assume
1306     # it is available
1307     use_cxa_atexit=yes
1308   fi
1309   if test x$use_cxa_atexit = xyes; then
1310     AC_DEFINE(DEFAULT_USE_CXA_ATEXIT, 1,
1311       [Define if you want to use __cxa_atexit, rather than atexit, to
1312       register C++ destructors for local statics and global objects.
1313       This is essential for fully standards-compliant handling of
1314       destructors, but requires __cxa_atexit in libc.])
1315   fi
1316 fi
1317
1318 # Look for a file containing extra machine modes.
1319 if test -n "$extra_modes" && test -f $srcdir/config/$extra_modes; then
1320   extra_modes_file='$(srcdir)'/config/${extra_modes}
1321   AC_SUBST(extra_modes_file)
1322   AC_DEFINE_UNQUOTED(EXTRA_MODES_FILE, "config/$extra_modes",
1323   [Define to the name of a file containing a list of extra machine modes
1324    for this architecture.])
1325 fi
1326
1327 # auto-host.h is the file containing items generated by autoconf and is
1328 # the first file included by config.h.
1329 # If host=build, it is correct to have bconfig include auto-host.h
1330 # as well.  If host!=build, we are in error and need to do more
1331 # work to find out the build config parameters.
1332 if test x$host = x$build
1333 then
1334         build_auto=auto-host.h
1335 else
1336         # We create a subdir, then run autoconf in the subdir.
1337         # To prevent recursion we set host and build for the new
1338         # invocation of configure to the build for this invocation
1339         # of configure.
1340         tempdir=build.$$
1341         rm -rf $tempdir
1342         mkdir $tempdir
1343         cd $tempdir
1344         case ${srcdir} in
1345         /* | [A-Za-z]:[\\/]* ) realsrcdir=${srcdir};;
1346         *) realsrcdir=../${srcdir};;
1347         esac
1348         saved_CFLAGS="${CFLAGS}"
1349         CC="${CC_FOR_BUILD}" CFLAGS="${CFLAGS_FOR_BUILD}" \
1350         ${realsrcdir}/configure \
1351                 --enable-languages=${enable_languages-all} \
1352                 --target=$target_alias --host=$build_alias --build=$build_alias
1353         CFLAGS="${saved_CFLAGS}"
1354
1355         # We just finished tests for the build machine, so rename
1356         # the file auto-build.h in the gcc directory.
1357         mv auto-host.h ../auto-build.h
1358         cd ..
1359         rm -rf $tempdir
1360         build_auto=auto-build.h
1361 fi
1362 AC_SUBST(build_subdir)
1363
1364 tm_file="${tm_file} defaults.h"
1365 tm_p_file="${tm_p_file} tm-preds.h"
1366 host_xm_file="auto-host.h ansidecl.h ${host_xm_file}"
1367 build_xm_file="${build_auto} ansidecl.h ${build_xm_file}"
1368 # We don't want ansidecl.h in target files, write code there in ISO/GNU C.
1369 # put this back in temporarily.
1370 xm_file="ansidecl.h ${xm_file}"
1371
1372 # --------
1373 # UNSORTED
1374 # --------
1375
1376 # Get the version trigger filename from the toplevel
1377 if test "${with_gcc_version_trigger+set}" = set; then
1378         gcc_version_trigger=$with_gcc_version_trigger
1379 else
1380         gcc_version_trigger=${srcdir}/version.c
1381 fi
1382 changequote(,)dnl
1383 gcc_version_full=`grep version_string ${gcc_version_trigger} | sed -e 's/.*"\([^"]*\)".*/\1/'`
1384 gcc_version=`echo ${gcc_version_full} | sed -e 's/\([^ ]*\) .*/\1/'`
1385
1386 # Compile in configure arguments.
1387 if test -f configargs.h ; then
1388         # Being re-configured.
1389         gcc_config_arguments=`grep configuration_arguments configargs.h | sed -e 's/.*"\([^"]*\)".*/\1/'`
1390         gcc_config_arguments="$gcc_config_arguments : (reconfigured) $TOPLEVEL_CONFIGURE_ARGUMENTS"
1391 else
1392         gcc_config_arguments="$TOPLEVEL_CONFIGURE_ARGUMENTS"
1393 fi
1394
1395 # Double all backslashes and backslash all quotes to turn
1396 # gcc_config_arguments into a C string.
1397 sed -e 's/\\/\\\\/g; s/"/\\"/g' <<EOF >conftest.out
1398 $gcc_config_arguments
1399 EOF
1400 gcc_config_arguments_str=`cat conftest.out`
1401 rm -f conftest.out
1402
1403 cat > configargs.h <<EOF
1404 /* Generated automatically. */
1405 static const char configuration_arguments[] = "$gcc_config_arguments_str";
1406 static const char thread_model[] = "$thread_file";
1407
1408 static const struct {
1409   const char *name, *value;
1410 } configure_default_options[] = $configure_default_options;
1411 EOF
1412 changequote([,])dnl
1413
1414 # Internationalization
1415 PACKAGE=gcc
1416 VERSION="$gcc_version"
1417 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE",
1418   [The name of this program for internationalization purposes.])
1419 AC_SUBST(PACKAGE)
1420 AC_SUBST(VERSION)
1421
1422 ZW_GNU_GETTEXT_SISTER_DIR
1423
1424 # If LIBINTL contains LIBICONV, then clear LIBICONV so we don't get
1425 # -liconv on the link line twice.
1426 case "$LIBINTL" in *$LIBICONV*)
1427         LIBICONV= ;;
1428 esac
1429
1430 # Windows32 Registry support for specifying GCC installation paths.
1431 AC_ARG_ENABLE(win32-registry,
1432 [  --disable-win32-registry
1433                           disable lookup of installation paths in the
1434                           Registry on Windows hosts
1435   --enable-win32-registry enable registry lookup (default)
1436   --enable-win32-registry=KEY
1437                           use KEY instead of GCC version as the last portion
1438                           of the registry key],,)
1439 case $host_os in
1440         win32 | pe | cygwin* | mingw32* | uwin*)
1441 AC_MSG_CHECKING(whether windows registry support is requested)
1442 if test "x$enable_win32_registry" != xno; then
1443   AC_DEFINE(ENABLE_WIN32_REGISTRY, 1,
1444 [Define to 1 if installation paths should be looked up in Windows32
1445    Registry. Ignored on non windows32 hosts.])
1446   AC_MSG_RESULT(yes)
1447   AC_SEARCH_LIBS(RegOpenKeyExA, advapi32)
1448 else
1449   AC_MSG_RESULT(no)
1450 fi
1451
1452 # Check if user specified a different registry key.
1453 case "x${enable_win32_registry}" in
1454 x | xyes)
1455   # default.
1456   gcc_cv_win32_registry_key="$VERSION"
1457   ;;
1458 xno)
1459   # no registry lookup.
1460   gcc_cv_win32_registry_key=''
1461   ;;
1462 *)
1463   # user-specified key.
1464   gcc_cv_win32_registry_key="$enable_win32_registry"
1465   ;;
1466 esac
1467
1468 if test "x$enable_win32_registry" != xno; then
1469   AC_MSG_CHECKING(registry key on windows hosts)
1470   AC_DEFINE_UNQUOTED(WIN32_REGISTRY_KEY, "$gcc_cv_win32_registry_key",
1471         [Define to be the last portion of registry key on windows hosts.])
1472   AC_MSG_RESULT($gcc_cv_win32_registry_key)
1473 fi
1474 ;;
1475 esac
1476
1477 # Get an absolute path to the GCC top-level source directory
1478 holddir=`${PWDCMD-pwd}`
1479 cd $srcdir
1480 topdir=`${PWDCMD-pwd}`
1481 cd $holddir
1482
1483 # Conditionalize the makefile for this host machine.
1484 xmake_file=
1485 for f in ${host_xmake_file}
1486 do
1487         if test -f ${srcdir}/config/$f
1488         then
1489                 xmake_file="${xmake_file} \$(srcdir)/config/$f"
1490         fi
1491 done
1492
1493 # Conditionalize the makefile for this target machine.
1494 tmake_file_=
1495 for f in ${tmake_file}
1496 do
1497         if test -f ${srcdir}/config/$f
1498         then
1499                 tmake_file_="${tmake_file_} \$(srcdir)/config/$f"
1500         fi
1501 done
1502 tmake_file="${tmake_file_}"
1503
1504 # If the host doesn't support symlinks, modify CC in
1505 # FLAGS_TO_PASS so CC="stage1/xgcc -Bstage1/" works.
1506 # Otherwise, we can use "CC=$(CC)".
1507 rm -f symtest.tem
1508 case "$LN_S" in
1509         *-s*)
1510                 cc_set_by_configure="\$(CC)"
1511                 quoted_cc_set_by_configure="\$(CC)"
1512                 stage_prefix_set_by_configure="\$(STAGE_PREFIX)"
1513                 quoted_stage_prefix_set_by_configure="\$(STAGE_PREFIX)"
1514                 ;;
1515         *)
1516                 cc_set_by_configure="\`case '\$(CC)' in stage*) echo '\$(CC)' | sed -e 's|stage|../stage|g';; *) echo '\$(CC)';; esac\`"
1517                 quoted_cc_set_by_configure="\\\`case '\\\$(CC)' in stage*) echo '\\\$(CC)' | sed -e 's|stage|../stage|g';; *) echo '\\\$(CC)';; esac\\\`"
1518                 stage_prefix_set_by_configure="\`case '\$(STAGE_PREFIX)' in stage*) echo '\$(STAGE_PREFIX)' | sed -e 's|stage|../stage|g';; *) echo '\$(STAGE_PREFIX)';; esac\`"
1519                 quoted_stage_prefix_set_by_configure="\\\`case '\\\$(STAGE_PREFIX)' in stage*) echo '\\\$(STAGE_PREFIX)' | sed -e 's|stage|../stage|g';; *) echo '\\\$(STAGE_PREFIX)';; esac\\\`"
1520                 ;;
1521 esac
1522
1523 out_object_file=`basename $out_file .c`.o
1524
1525 tm_file_list=
1526 tm_include_list=
1527 for f in $tm_file; do
1528   case $f in
1529     defaults.h )
1530        tm_file_list="${tm_file_list} \$(srcdir)/$f"
1531        tm_include_list="${tm_include_list} $f"
1532        ;;
1533     * )
1534        tm_file_list="${tm_file_list} \$(srcdir)/config/$f"
1535        tm_include_list="${tm_include_list} config/$f"
1536        ;;
1537   esac
1538 done
1539
1540 tm_p_file_list=
1541 tm_p_include_list=
1542 for f in $tm_p_file; do
1543   case $f in
1544     tm-preds.h )
1545        tm_p_file_list="${tm_p_file_list} $f"
1546        tm_p_include_list="${tm_p_include_list} $f"
1547        ;;
1548     * )
1549        tm_p_file_list="${tm_p_file_list} \$(srcdir)/config/$f"
1550        tm_p_include_list="${tm_p_include_list} config/$f"
1551   esac
1552 done
1553
1554 xm_file_list=
1555 xm_include_list=
1556 for f in $xm_file; do
1557   case $f in
1558     ansidecl.h )
1559        xm_file_list="${xm_file_list} \$(srcdir)/../include/$f"
1560        xm_include_list="${xm_include_list} $f"
1561        ;;
1562     auto-host.h )
1563        xm_file_list="${xm_file_list} $f"
1564        xm_include_list="${xm_include_list} $f"
1565        ;;
1566     * )
1567        xm_file_list="${xm_file_list} \$(srcdir)/config/$f"
1568        xm_include_list="${xm_include_list} config/$f"
1569        ;;
1570   esac
1571 done
1572
1573 host_xm_file_list=
1574 host_xm_include_list=
1575 for f in $host_xm_file; do
1576   case $f in
1577     ansidecl.h )
1578        host_xm_file_list="${host_xm_file_list} \$(srcdir)/../include/$f"
1579        host_xm_include_list="${host_xm_include_list} $f"
1580        ;;
1581     auto-host.h )
1582        host_xm_file_list="${host_xm_file_list} $f"
1583        host_xm_include_list="${host_xm_include_list} $f"
1584        ;;
1585     * )
1586        host_xm_file_list="${host_xm_file_list} \$(srcdir)/config/$f"
1587        host_xm_include_list="${host_xm_include_list} config/$f"
1588        ;;
1589   esac
1590 done
1591
1592 build_xm_file_list=
1593 for f in $build_xm_file; do
1594   case $f in
1595     ansidecl.h )
1596        build_xm_file_list="${build_xm_file_list} \$(srcdir)/../include/$f"
1597        build_xm_include_list="${build_xm_include_list} $f"
1598        ;;
1599     auto-build.h | auto-host.h )
1600        build_xm_file_list="${build_xm_file_list} $f"
1601        build_xm_include_list="${build_xm_include_list} $f"
1602        ;;
1603     * )
1604        build_xm_file_list="${build_xm_file_list} \$(srcdir)/config/$f"
1605        build_xm_include_list="${build_xm_include_list} config/$f"
1606        ;;
1607   esac
1608 done
1609
1610 # Define macro CROSS_COMPILE in compilation if this is a cross-compiler.
1611 # Also use all.cross instead of all.internal and adjust SYSTEM_HEADER_DIR.
1612 CROSS=                                          AC_SUBST(CROSS)
1613 ALL=all.internal                                AC_SUBST(ALL)
1614 SYSTEM_HEADER_DIR='$(NATIVE_SYSTEM_HEADER_DIR)' AC_SUBST(SYSTEM_HEADER_DIR)
1615 if test x$host != x$target
1616 then
1617         CROSS="-DCROSS_COMPILE"
1618         ALL=all.cross
1619         SYSTEM_HEADER_DIR='$(CROSS_SYSTEM_HEADER_DIR)'
1620         case "$host","$target" in
1621         # Darwin crosses can use the host system's libraries and headers,
1622         # because of the fat library support.  Of course, it must be the
1623         # same version of Darwin on both sides.  Allow the user to
1624         # just say --target=foo-darwin without a version number to mean
1625         # "the version on this system".
1626             *-*-darwin*,*-*-darwin*)
1627                 hostos=`echo $host | sed 's/.*-darwin/darwin/'`
1628                 targetos=`echo $target | sed 's/.*-darwin/darwin/'`
1629                 if test $hostos = $targetos -o $targetos = darwin ; then
1630                     CROSS=
1631                     SYSTEM_HEADER_DIR='$(NATIVE_SYSTEM_HEADER_DIR)'
1632                     with_headers=yes
1633                 fi
1634                 ;;
1635
1636             i?86-*-*,x86_64-*-* \
1637             | powerpc*-*-*,powerpc64*-*-*)
1638                 CROSS="$CROSS -DNATIVE_CROSS" ;;
1639         esac
1640 elif test "x$TARGET_SYSTEM_ROOT" != x; then
1641         # This is just $(TARGET_SYSTEM_ROOT)$(NATIVE_SYSTEM_HEADER_DIR)
1642         SYSTEM_HEADER_DIR='$(CROSS_SYSTEM_HEADER_DIR)'
1643 fi
1644
1645 # If this is a cross-compiler that does not
1646 # have its own set of headers then define
1647 # inhibit_libc
1648
1649 # If this is using newlib, without having the headers available now,
1650 # then define inhibit_libc in LIBGCC2_CFLAGS.
1651 # This prevents libgcc2 from containing any code which requires libc
1652 # support.
1653 inhibit_libc=
1654 if { { test x$host != x$target && test "x$with_sysroot" = x ; } ||
1655        test x$with_newlib = xyes ; } &&
1656      { test "x$with_headers" = x || test "x$with_headers" = xno ; } ; then
1657        inhibit_libc=-Dinhibit_libc
1658 fi
1659 AC_SUBST(inhibit_libc)
1660
1661 # When building gcc with a cross-compiler, we need to adjust things so
1662 # that the generator programs are still built with the native compiler.
1663 # Also, we cannot run fixincludes or fix-header.
1664
1665 # These are the normal (build=host) settings:
1666 CC_FOR_BUILD='$(CC)'            AC_SUBST(CC_FOR_BUILD)
1667 BUILD_CFLAGS='$(ALL_CFLAGS)'    AC_SUBST(BUILD_CFLAGS)
1668 STMP_FIXINC=stmp-fixinc         AC_SUBST(STMP_FIXINC)
1669
1670 # Possibly disable fixproto, on a per-target basis.
1671 case ${use_fixproto} in
1672   no)
1673     STMP_FIXPROTO=
1674     ;;
1675   yes)
1676     STMP_FIXPROTO=stmp-fixproto
1677     ;;
1678 esac
1679 AC_SUBST(STMP_FIXPROTO)
1680
1681 # And these apply if build != host, or we are generating coverage data
1682 if test x$build != x$host || test "x$coverage_flags" != x
1683 then
1684     BUILD_CFLAGS='$(INTERNAL_CFLAGS) $(T_CFLAGS) $(CFLAGS_FOR_BUILD)'
1685
1686     if test "x$TARGET_SYSTEM_ROOT" = x; then
1687         if [ "x$STMP_FIXPROTO" != x ] ; then
1688           STMP_FIXPROTO=stmp-install-fixproto
1689         fi
1690     fi
1691 fi
1692
1693 # Expand extra_headers to include complete path.
1694 # This substitutes for lots of t-* files.
1695 extra_headers_list=
1696 # Prepend $(srcdir)/config/${cpu_type}/ to every entry in extra_headers.
1697 for file in ${extra_headers} ; do
1698   extra_headers_list="${extra_headers_list} \$(srcdir)/config/${cpu_type}/${file}"
1699 done
1700
1701 # Define collect2 in Makefile.
1702 case $host_can_use_collect2 in
1703   no) collect2= ;;
1704   *) collect2='collect2$(exeext)' ;;
1705 esac
1706 AC_SUBST([collect2])
1707
1708 # Add a definition of USE_COLLECT2 if system wants one.
1709 case $use_collect2 in
1710   no) use_collect2= ;;
1711   "") ;;
1712   *)
1713     host_xm_defines="${host_xm_defines} USE_COLLECT2"
1714     xm_defines="${xm_defines} USE_COLLECT2"
1715     case $host_can_use_collect2 in
1716       no)
1717         AC_MSG_ERROR([collect2 is required but cannot be built on this system])
1718         ;;
1719     esac
1720     ;;
1721 esac
1722
1723 # ---------------------------
1724 # Assembler & linker features
1725 # ---------------------------
1726
1727 # Identify the assembler which will work hand-in-glove with the newly
1728 # built GCC, so that we can examine its features.  This is the assembler
1729 # which will be driven by the driver program.
1730 #
1731 # If build != host, and we aren't building gas in-tree, we identify a
1732 # build->target assembler and hope that it will have the same features
1733 # as the host->target assembler we'll be using.
1734 AC_MSG_CHECKING(what assembler to use)
1735 in_tree_gas=no
1736 gcc_cv_as=
1737 gcc_cv_gas_major_version=
1738 gcc_cv_gas_minor_version=
1739 gcc_cv_as_gas_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/gas
1740 if test -x "$DEFAULT_ASSEMBLER"; then
1741         gcc_cv_as="$DEFAULT_ASSEMBLER"
1742 elif test -x as$build_exeext; then
1743         # Build using assembler in the current directory.
1744         gcc_cv_as=./as$build_exeext
1745 elif test -f $gcc_cv_as_gas_srcdir/configure.in \
1746      && test -f ../gas/Makefile \
1747      && test x$build = x$host; then
1748   # Single tree build which includes gas.  We want to prefer it
1749   # over whatever linker top-level may have detected, since
1750   # we'll use what we're building after installation anyway.
1751   in_tree_gas=yes
1752   _gcc_COMPUTE_GAS_VERSION
1753   rm -f as$build_exeext
1754   $LN_S ../gas/as-new$build_exeext as$build_exeext 2>/dev/null
1755   in_tree_gas_is_elf=no
1756   if grep 'obj_format = elf' ../gas/Makefile > /dev/null \
1757      || (grep 'obj_format = multi' ../gas/Makefile \
1758          && grep 'extra_objects =.* obj-elf' ../gas/Makefile) > /dev/null
1759   then
1760     in_tree_gas_is_elf=yes
1761   fi
1762 m4_pattern_allow([AS_FOR_TARGET])dnl
1763 elif test -x "$AS_FOR_TARGET"; then
1764         gcc_cv_as="$AS_FOR_TARGET"
1765 elif test -x "$AS" && test x$host = x$target; then
1766         gcc_cv_as="$AS"
1767 fi
1768
1769 if test "x$gcc_cv_as" = x; then
1770         # Search the same directories that the installed compiler will
1771         # search.  Else we may find the wrong assembler and lose.  If we
1772         # do not find a suitable assembler binary, then try the user's
1773         # path.
1774         #
1775         # Also note we have to check MD_EXEC_PREFIX before checking the
1776         # user's path.  Unfortunately, there is no good way to get at the
1777         # value of MD_EXEC_PREFIX here.  So we do a brute force search
1778         # through all the known MD_EXEC_PREFIX values.  Ugh.  This needs
1779         # to be fixed as part of the make/configure rewrite too.
1780
1781         if test "x$exec_prefix" = xNONE; then
1782                 if test "x$prefix" = xNONE; then
1783                         test_prefix=/usr/local
1784                 else
1785                         test_prefix=$prefix
1786                 fi
1787         else
1788                 test_prefix=$exec_prefix
1789         fi
1790
1791         # If the loop below does not find an assembler, then use whatever
1792         # one we can find in the users's path.
1793         # user's path.
1794         if test "x$program_prefix" != xNONE; then
1795                 gcc_cv_as=${program_prefix}as$build_exeext
1796         else
1797                 gcc_cv_as=`echo as | sed "${program_transform_name}"`$build_exeext
1798         fi
1799
1800         if test x$host = x$build; then
1801             test_dirs="$test_prefix/libexec/gcc/$target_noncanonical/$gcc_version \
1802                        $test_prefix/libexec/gcc/$target_noncanonical \
1803                        /usr/lib/gcc/$target_noncanonical/$gcc_version \
1804                        /usr/lib/gcc/$target_noncanonical \
1805                        $test_prefix/$target_noncanonical/bin/$target_noncanonical/$gcc_version \
1806                        $test_prefix/$target_noncanonical/bin"
1807         else
1808             test_dirs=
1809         fi
1810
1811         if test x$host = x$target; then
1812             test_dirs="$test_dirs \
1813                    /usr/libexec \
1814                    /usr/ccs/gcc \
1815                    /usr/ccs/bin \
1816                    /udk/usr/ccs/bin \
1817                    /bsd43/usr/lib/cmplrs/cc \
1818                    /usr/cross64/usr/bin \
1819                    /usr/lib/cmplrs/cc \
1820                    /sysv/usr/lib/cmplrs/cc \
1821                    /svr4/usr/lib/cmplrs/cc \
1822                    /usr/bin"
1823         fi
1824
1825         for dir in $test_dirs; do
1826                 if test -x $dir/as$build_exeext; then
1827                         gcc_cv_as=$dir/as$build_exeext
1828                         break;
1829                 fi
1830         done
1831 fi
1832 case $in_tree_gas in
1833   yes)
1834     AC_MSG_RESULT("newly built gas")
1835     ;;
1836   no)
1837     AC_MSG_RESULT($gcc_cv_as)
1838     ;;
1839 esac
1840
1841 # Identify the linker which will work hand-in-glove with the newly
1842 # built GCC, so that we can examine its features.  This is the linker
1843 # which will be driven by the driver program.
1844 #
1845 # If build != host, and we aren't building gas in-tree, we identify a
1846 # build->target linker and hope that it will have the same features
1847 # as the host->target linker we'll be using.
1848 AC_MSG_CHECKING(what linker to use)
1849 in_tree_ld=no
1850 gcc_cv_ld=
1851 gcc_cv_gld_major_version=
1852 gcc_cv_gld_minor_version=
1853 gcc_cv_ld_gld_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/ld
1854 gcc_cv_ld_bfd_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/bfd
1855 if test -x "$DEFAULT_LINKER"; then
1856         gcc_cv_ld="$DEFAULT_LINKER"
1857 elif test -x collect-ld$build_exeext; then
1858         # Build using linker in the current directory.
1859         gcc_cv_ld=./collect-ld$build_exeext
1860 elif test -f $gcc_cv_ld_gld_srcdir/configure.in \
1861      && test -f ../ld/Makefile \
1862      && test x$build = x$host; then
1863         # Single tree build which includes ld.  We want to prefer it
1864         # over whatever linker top-level may have detected, since
1865         # we'll use what we're building after installation anyway.
1866         in_tree_ld=yes
1867         in_tree_ld_is_elf=no
1868         if (grep 'EMUL = .*elf' ../ld/Makefile \
1869             || grep 'EMUL = .*linux' ../ld/Makefile \
1870             || grep 'EMUL = .*lynx' ../ld/Makefile) > /dev/null; then
1871           in_tree_ld_is_elf=yes
1872         fi
1873         for f in $gcc_cv_ld_bfd_srcdir/configure $gcc_cv_ld_gld_srcdir/configure $gcc_cv_ld_gld_srcdir/configure.in $gcc_cv_ld_gld_srcdir/Makefile.in
1874         do
1875 changequote(,)dnl
1876                 gcc_cv_gld_version=`sed -n -e 's/^[     ]*\(VERSION=[0-9]*\.[0-9]*.*\)/\1/p' < $f`
1877 changequote([,])dnl
1878                 if test x$gcc_cv_gld_version != x; then
1879                         break
1880                 fi
1881         done
1882 changequote(,)dnl
1883         gcc_cv_gld_major_version=`expr "$gcc_cv_gld_version" : "VERSION=\([0-9]*\)"`
1884         gcc_cv_gld_minor_version=`expr "$gcc_cv_gld_version" : "VERSION=[0-9]*\.\([0-9]*\)"`
1885 changequote([,])dnl
1886         rm -f collect-ld$build_exeext
1887         $LN_S ../ld/ld-new$build_exeext collect-ld$build_exeext 2>/dev/null
1888 elif test -x "$LD_FOR_TARGET"; then
1889         gcc_cv_ld="$LD_FOR_TARGET"
1890 elif test -x "$LD" && test x$host = x$target; then
1891         gcc_cv_ld="$LD"
1892 fi
1893
1894 if test "x$gcc_cv_ld" = x; then
1895         # Search the same directories that the installed compiler will
1896         # search.  Else we may find the wrong linker and lose.  If we
1897         # do not find a suitable linker binary, then try the user's
1898         # path.
1899         #
1900         # Also note we have to check MD_EXEC_PREFIX before checking the
1901         # user's path.  Unfortunately, there is no good way to get at the
1902         # value of MD_EXEC_PREFIX here.  So we do a brute force search
1903         # through all the known MD_EXEC_PREFIX values.  Ugh.  This needs
1904         # to be fixed as part of the make/configure rewrite too.
1905
1906         if test "x$exec_prefix" = xNONE; then
1907                 if test "x$prefix" = xNONE; then
1908                         test_prefix=/usr/local
1909                 else
1910                         test_prefix=$prefix
1911                 fi
1912         else
1913                 test_prefix=$exec_prefix
1914         fi
1915
1916         # If the loop below does not find an linker, then use whatever
1917         # one we can find in the users's path.
1918         # user's path.
1919         if test "x$program_prefix" != xNONE; then
1920                 gcc_cv_ld=${program_prefix}ld$build_exeext
1921         else
1922                 gcc_cv_ld=`echo ld | sed "${program_transform_name}"`$build_exeext
1923         fi
1924
1925         if test x$host = x$build; then
1926             test_dirs="$test_prefix/libexec/gcc/$target_noncanonical/$gcc_version \
1927                        $test_prefix/libexec/gcc/$target_noncanonical \
1928                        /usr/lib/gcc/$target_noncanonical/$gcc_version \
1929                        /usr/lib/gcc/$target_noncanonical \
1930                        $test_prefix/$target_noncanonical/bin/$target_noncanonical/$gcc_version \
1931                        $test_prefix/$target_noncanonical/bin"
1932         else
1933             test_dirs=
1934         fi
1935
1936         if test x$host = x$target; then
1937             test_dirs="$test_dirs \
1938                    /usr/libexec \
1939                    /usr/ccs/gcc \
1940                    /usr/ccs/bin \
1941                    /udk/usr/ccs/bin \
1942                    /bsd43/usr/lib/cmplrs/cc \
1943                    /usr/cross64/usr/bin \
1944                    /usr/lib/cmplrs/cc \
1945                    /sysv/usr/lib/cmplrs/cc \
1946                    /svr4/usr/lib/cmplrs/cc \
1947                    /usr/bin"
1948         fi
1949
1950         for dir in $test_dirs; do
1951                 if test -x $dir/ld$build_exeext; then
1952                         gcc_cv_ld=$dir/ld$build_exeext
1953                         break;
1954                 fi
1955         done
1956 fi
1957 case $in_tree_ld in
1958   yes)
1959     AC_MSG_RESULT("newly built ld")
1960     ;;
1961   no)
1962     AC_MSG_RESULT($gcc_cv_ld)
1963     ;;
1964 esac
1965
1966 # Figure out what nm we will be using.
1967 gcc_cv_binutils_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/binutils
1968 AC_MSG_CHECKING(what nm to use)
1969 in_tree_nm=no
1970 if test -x nm$build_exeext; then
1971         gcc_cv_nm=./nm$build_exeext
1972 elif test -f $gcc_cv_binutils_srcdir/configure.in \
1973      && test -f ../binutils/Makefile; then
1974         # Single tree build which includes binutils.
1975         in_tree_nm=yes
1976         gcc_cv_nm=./nm$build_exeext
1977         rm -f nm$build_exeext
1978         $LN_S ../binutils/nm-new$build_exeext nm$build_exeext 2>/dev/null
1979 elif test "x$program_prefix" != xNONE; then
1980         gcc_cv_nm=${program_prefix}nm$build_exeext
1981 else
1982         gcc_cv_nm=`echo nm | sed "${program_transform_name}"`$build_exeext
1983 fi
1984 case $in_tree_nm in
1985   yes) AC_MSG_RESULT("newly built nm") ;;
1986   no)  AC_MSG_RESULT($gcc_cv_nm) ;;
1987 esac
1988
1989 # Figure out what objdump we will be using.
1990 AC_MSG_CHECKING(what objdump to use)
1991 in_tree_objdump=no
1992 if test -x objdump$build_exeext; then
1993         gcc_cv_objdump=./objdump$build_exeext
1994 elif test -f $gcc_cv_binutils_srcdir/configure.in \
1995      && test -f ../binutils/Makefile; then
1996         # Single tree build which includes binutils.
1997         in_tree_objdump=yes
1998         gcc_cv_objdump=./objdump$build_exeext
1999         rm -f objdump$build_exeext
2000         $LN_S ../binutils/objdump$build_exeext objdump$build_exeext 2>/dev/null
2001 elif test "x$program_prefix" != xNONE; then
2002         gcc_cv_objdump=${program_prefix}objdump$build_exeext
2003 else
2004         gcc_cv_objdump=`echo objdump | \
2005                 sed "${program_transform_name}"`$build_exeext
2006 fi
2007 case $in_tree_objdump in
2008   yes) AC_MSG_RESULT("newly built objdump") ;;
2009   no)  AC_MSG_RESULT($gcc_cv_objdump) ;;
2010 esac
2011
2012 # Figure out what assembler alignment features are present.
2013 gcc_GAS_CHECK_FEATURE([.balign and .p2align], gcc_cv_as_balign_and_p2align,
2014  [2,6,0],,
2015 [.balign 4
2016 .p2align 2],,
2017 [AC_DEFINE(HAVE_GAS_BALIGN_AND_P2ALIGN, 1,
2018   [Define if your assembler supports .balign and .p2align.])])
2019
2020 gcc_GAS_CHECK_FEATURE([.p2align with maximum skip], gcc_cv_as_max_skip_p2align,
2021  [2,8,0],,
2022  [.p2align 4,,7],,
2023 [AC_DEFINE(HAVE_GAS_MAX_SKIP_P2ALIGN, 1,
2024   [Define if your assembler supports specifying the maximum number
2025    of bytes to skip when using the GAS .p2align command.])])
2026
2027 gcc_GAS_CHECK_FEATURE([working .subsection -1], gcc_cv_as_subsection_m1,
2028  [elf,2,9,0],,
2029  [conftest_label1: .word 0
2030 .subsection -1
2031 conftest_label2: .word 0
2032 .previous],
2033  [if test x$gcc_cv_nm != x; then
2034     $gcc_cv_nm conftest.o | grep conftest_label1 > conftest.nm1
2035     $gcc_cv_nm conftest.o | grep conftest_label2 | sed -e 's/label2/label1/' > conftest.nm2
2036     if cmp conftest.nm1 conftest.nm2 > /dev/null 2>&1
2037     then :
2038     else gcc_cv_as_subsection_m1=yes
2039     fi
2040     rm -f conftest.nm1 conftest.nm2
2041   fi],
2042  [AC_DEFINE(HAVE_GAS_SUBSECTION_ORDERING, 1,
2043   [Define if your assembler supports .subsection and .subsection -1 starts
2044    emitting at the beginning of your section.])])
2045
2046 gcc_GAS_CHECK_FEATURE([.weak], gcc_cv_as_weak,
2047  [2,2,0],,
2048  [      .weak foobar],,
2049 [AC_DEFINE(HAVE_GAS_WEAK, 1, [Define if your assembler supports .weak.])])
2050
2051 # .hidden needs to be supported in both the assembler and the linker,
2052 # because GNU LD versions before 2.12.1 have buggy support for STV_HIDDEN.
2053 # This is irritatingly difficult to feature test for; we have to check the
2054 # date string after the version number.  If we've got an in-tree
2055 # ld, we don't know its patchlevel version, so we set the baseline at 2.13
2056 # to be safe.
2057 # The gcc_GAS_CHECK_FEATURE call just sets a cache variable.
2058 gcc_GAS_CHECK_FEATURE([.hidden], gcc_cv_as_hidden,
2059  [elf,2,13,0],,
2060 [       .hidden foobar
2061 foobar:])
2062
2063 AC_CACHE_CHECK(linker for .hidden support, gcc_cv_ld_hidden,
2064 [if test $in_tree_ld = yes ; then
2065   gcc_cv_ld_hidden=no
2066   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 13 -o "$gcc_cv_gld_major_version" -gt 2 \
2067      && test $in_tree_ld_is_elf = yes; then
2068      gcc_cv_ld_hidden=yes
2069   fi
2070 else
2071   gcc_cv_ld_hidden=yes
2072   ld_ver=`$gcc_cv_ld --version 2>/dev/null | sed 1q`
2073   if echo "$ld_ver" | grep GNU > /dev/null; then
2074 changequote(,)dnl
2075     ld_vers=`echo $ld_ver | sed -n \
2076         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\)$,\1,p' \
2077         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\)$,\1,p' \
2078         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\)$,\1,p' \
2079         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\)[  ].*$,\1,p' \
2080         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\)[     ].*$,\1,p' \
2081         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\)[        ].*$,\1,p'`
2082     ld_date=`echo $ld_ver | sed -n 's,^.*\([2-9][0-9][0-9][0-9]\)[-]*\([01][0-9]\)[-]*\([0-3][0-9]\).*$,\1\2\3,p'`
2083     if test 0"$ld_date" -lt 20020404; then
2084       if test -n "$ld_date"; then
2085         # If there was date string, but was earlier than 2002-04-04, fail
2086         gcc_cv_ld_hidden=no
2087       elif test -z "$ld_vers"; then
2088         # If there was no date string nor ld version number, something is wrong
2089         gcc_cv_ld_hidden=no
2090       else
2091         ld_vers_major=`expr "$ld_vers" : '\([0-9]*\)'`
2092         ld_vers_minor=`expr "$ld_vers" : '[0-9]*\.\([0-9]*\)'`
2093         ld_vers_patch=`expr "$ld_vers" : '[0-9]*\.[0-9]*\.\([0-9]*\)'`
2094         test -z "$ld_vers_patch" && ld_vers_patch=0
2095         if test "$ld_vers_major" -lt 2; then
2096           gcc_cv_ld_hidden=no
2097         elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -lt 12; then
2098           gcc_cv_ld_hidden="no"
2099         elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -eq 12 -a "$ld_vers_patch" -eq 0; then
2100           gcc_cv_ld_hidden=no
2101         fi
2102       fi
2103 changequote([,])dnl
2104     fi
2105   else
2106     case "${target}" in
2107       hppa64*-*-hpux* | ia64*-*-hpux*)
2108         gcc_cv_ld_hidden=yes
2109         ;;
2110       *)
2111         gcc_cv_ld_hidden=no
2112         ;;
2113     esac
2114   fi
2115 fi])
2116 libgcc_visibility=no
2117 AC_SUBST(libgcc_visibility)
2118 if test $gcc_cv_as_hidden = yes && test $gcc_cv_ld_hidden = yes; then
2119   libgcc_visibility=yes
2120   AC_DEFINE(HAVE_GAS_HIDDEN, 1,
2121   [Define if your assembler and linker support .hidden.])
2122 fi
2123
2124 # Check if we have .[us]leb128, and support symbol arithmetic with it.
2125 gcc_GAS_CHECK_FEATURE([.sleb128 and .uleb128], gcc_cv_as_leb128,
2126   [elf,2,11,0],,
2127 [       .data
2128         .uleb128 L2 - L1
2129 L1:
2130         .uleb128 1280
2131         .sleb128 -1010
2132 L2:],
2133  [# GAS versions before 2.11 do not support uleb128,
2134   # despite appearing to.
2135   # ??? There exists an elf-specific test that will crash
2136   # the assembler.  Perhaps it's better to figure out whether
2137   # arbitrary sections are supported and try the test.
2138   as_ver=`$gcc_cv_as --version 2>/dev/null | sed 1q`
2139   if echo "$as_ver" | grep GNU > /dev/null; then
2140 changequote(,)dnl
2141     as_ver=`echo $as_ver | sed -e 's/GNU assembler \([0-9.][0-9.]*\).*/\1/'`
2142     as_major=`echo $as_ver | sed 's/\..*//'`
2143     as_minor=`echo $as_ver | sed 's/[^.]*\.\([0-9]*\).*/\1/'`
2144 changequote([,])dnl
2145     if test $as_major -eq 2 && test $as_minor -lt 11
2146     then :
2147     else gcc_cv_as_leb128=yes
2148     fi
2149   fi],
2150   [AC_DEFINE(HAVE_AS_LEB128, 1,
2151     [Define if your assembler supports .sleb128 and .uleb128.])])
2152
2153 # GAS versions up to and including 2.11.0 may mis-optimize
2154 # .eh_frame data.
2155 gcc_GAS_CHECK_FEATURE(eh_frame optimization, gcc_cv_as_eh_frame,
2156   [elf,2,12,0],,
2157 [       .text
2158 .LFB1:
2159         .4byte  0
2160 .L1:
2161         .4byte  0
2162 .LFE1:
2163         .section        .eh_frame,"aw",@progbits
2164 __FRAME_BEGIN__:
2165         .4byte  .LECIE1-.LSCIE1
2166 .LSCIE1:
2167         .4byte  0x0
2168         .byte   0x1
2169         .ascii "z\0"
2170         .byte   0x1
2171         .byte   0x78
2172         .byte   0x1a
2173         .byte   0x0
2174         .byte   0x4
2175         .4byte  1
2176         .p2align 1
2177 .LECIE1:
2178 .LSFDE1:
2179         .4byte  .LEFDE1-.LASFDE1
2180 .LASFDE1:
2181         .4byte  .LASFDE1-__FRAME_BEGIN__
2182         .4byte  .LFB1
2183         .4byte  .LFE1-.LFB1
2184         .byte   0x4
2185         .4byte  .LFE1-.LFB1
2186         .byte   0x4
2187         .4byte  .L1-.LFB1
2188 .LEFDE1:],
2189 [  dnl # For autoconf 2.5x, must protect trailing spaces with @&t@.
2190 cat > conftest.lit <<EOF
2191  0000 10000000 00000000 017a0001 781a0004  .........z..x...
2192  0010 01000000 12000000 18000000 00000000  ................
2193  0020 08000000 04080000 0044               .........D      @&t@
2194 EOF
2195 cat > conftest.big <<EOF
2196  0000 00000010 00000000 017a0001 781a0004  .........z..x...
2197  0010 00000001 00000012 00000018 00000000  ................
2198  0020 00000008 04000000 0844               .........D      @&t@
2199 EOF
2200   # If the assembler didn't choke, and we can objdump,
2201   # and we got the correct data, then succeed.
2202   if test x$gcc_cv_objdump != x \
2203   && $gcc_cv_objdump -s -j .eh_frame conftest.o 2>/dev/null \
2204      | tail -3 > conftest.got \
2205   && { cmp conftest.lit conftest.got > /dev/null 2>&1 \
2206     || cmp conftest.big conftest.got > /dev/null 2>&1; }
2207   then
2208     gcc_cv_as_eh_frame=yes
2209   elif AC_TRY_COMMAND($gcc_cv_as -o conftest.o --traditional-format /dev/null); then
2210     gcc_cv_as_eh_frame=buggy
2211   else
2212     # Uh oh, what do we do now?
2213     gcc_cv_as_eh_frame=no
2214   fi])
2215
2216 if test $gcc_cv_as_eh_frame = buggy; then
2217   AC_DEFINE(USE_AS_TRADITIONAL_FORMAT, 1,
2218   [Define if your assembler mis-optimizes .eh_frame data.])
2219 fi
2220
2221 gcc_GAS_CHECK_FEATURE(section merging support, gcc_cv_as_shf_merge,
2222  [elf,2,12,0], [--fatal-warnings],
2223  [.section .rodata.str, "aMS", @progbits, 1])
2224 if test $gcc_cv_as_shf_merge = no; then
2225   gcc_GAS_CHECK_FEATURE(section merging support, gcc_cv_as_shf_merge,
2226     [elf,2,12,0], [--fatal-warnings],
2227     [.section .rodata.str, "aMS", %progbits, 1])
2228 fi
2229 AC_DEFINE_UNQUOTED(HAVE_GAS_SHF_MERGE,
2230   [`if test $gcc_cv_as_shf_merge = yes; then echo 1; else echo 0; fi`],
2231 [Define 0/1 if your assembler supports marking sections with SHF_MERGE flag.])
2232
2233 gcc_GAS_CHECK_FEATURE(COMDAT group support, gcc_cv_as_comdat_group,
2234  [elf,2,15,91], [--fatal-warnings],
2235  [.section .text,"axG",@progbits,.foo,comdat])
2236 if test $gcc_cv_as_comdat_group = yes; then
2237   gcc_cv_as_comdat_group_percent=no
2238 else
2239  gcc_GAS_CHECK_FEATURE(COMDAT group support, gcc_cv_as_comdat_group_percent,
2240    [elf,2,15,91], [--fatal-warnings],
2241    [.section .text,"axG",%progbits,.foo,comdat])
2242 fi
2243 AC_DEFINE_UNQUOTED(HAVE_GAS_COMDAT_GROUP,
2244   [`if test $gcc_cv_as_comdat_group = yes || test $gcc_cv_as_comdat_group_percent = yes; then echo 1; else echo 0; fi`],
2245 [Define 0/1 if your assembler supports COMDAT group.])
2246
2247 # Thread-local storage - the check is heavily parametrized.
2248 conftest_s=
2249 tls_first_major=
2250 tls_first_minor=
2251 tls_as_opt=
2252 case "$target" in
2253 changequote(,)dnl
2254   alpha*-*-*)
2255     conftest_s='
2256         .section ".tdata","awT",@progbits
2257 foo:    .long   25
2258         .text
2259         ldq     $27,__tls_get_addr($29)         !literal!1
2260         lda     $16,foo($29)                    !tlsgd!1
2261         jsr     $26,($27),__tls_get_addr        !lituse_tlsgd!1
2262         ldq     $27,__tls_get_addr($29)         !literal!2
2263         lda     $16,foo($29)                    !tlsldm!2
2264         jsr     $26,($27),__tls_get_addr        !lituse_tlsldm!2
2265         ldq     $1,foo($29)                     !gotdtprel
2266         ldah    $2,foo($29)                     !dtprelhi
2267         lda     $3,foo($2)                      !dtprello
2268         lda     $4,foo($29)                     !dtprel
2269         ldq     $1,foo($29)                     !gottprel
2270         ldah    $2,foo($29)                     !tprelhi
2271         lda     $3,foo($2)                      !tprello
2272         lda     $4,foo($29)                     !tprel'
2273         tls_first_major=2
2274         tls_first_minor=13
2275         tls_as_opt=--fatal-warnings
2276         ;;
2277   i[34567]86-*-*)
2278     conftest_s='
2279         .section ".tdata","awT",@progbits
2280 foo:    .long   25
2281         .text
2282         movl    %gs:0, %eax
2283         leal    foo@TLSGD(,%ebx,1), %eax
2284         leal    foo@TLSLDM(%ebx), %eax
2285         leal    foo@DTPOFF(%eax), %edx
2286         movl    foo@GOTTPOFF(%ebx), %eax
2287         subl    foo@GOTTPOFF(%ebx), %eax
2288         addl    foo@GOTNTPOFF(%ebx), %eax
2289         movl    foo@INDNTPOFF, %eax
2290         movl    $foo@TPOFF, %eax
2291         subl    $foo@TPOFF, %eax
2292         leal    foo@NTPOFF(%ecx), %eax'
2293         tls_first_major=2
2294         tls_first_minor=14
2295         tls_as_opt=--fatal-warnings
2296         ;;
2297   x86_64-*-*)
2298     conftest_s='
2299         .section ".tdata","awT",@progbits
2300 foo:    .long   25
2301         .text
2302         movq    %fs:0, %rax
2303         leaq    foo@TLSGD(%rip), %rdi
2304         leaq    foo@TLSLD(%rip), %rdi
2305         leaq    foo@DTPOFF(%rax), %rdx
2306         movq    foo@GOTTPOFF(%rip), %rax
2307         movq    $foo@TPOFF, %rax'
2308         tls_first_major=2
2309         tls_first_minor=14
2310         tls_as_opt=--fatal-warnings
2311         ;;
2312   ia64-*-*)
2313     conftest_s='
2314         .section ".tdata","awT",@progbits
2315 foo:    data8   25
2316         .text
2317         addl    r16 = @ltoff(@dtpmod(foo#)), gp
2318         addl    r17 = @ltoff(@dtprel(foo#)), gp
2319         addl    r18 = @ltoff(@tprel(foo#)), gp
2320         addl    r19 = @dtprel(foo#), gp
2321         adds    r21 = @dtprel(foo#), r13
2322         movl    r23 = @dtprel(foo#)
2323         addl    r20 = @tprel(foo#), gp
2324         adds    r22 = @tprel(foo#), r13
2325         movl    r24 = @tprel(foo#)'
2326         tls_first_major=2
2327         tls_first_minor=13
2328         tls_as_opt=--fatal-warnings
2329         ;;
2330   powerpc-*-*)
2331     conftest_s='
2332         .section ".tdata","awT",@progbits
2333         .align 2
2334 ld0:    .space 4
2335 ld1:    .space 4
2336 x1:     .space 4
2337 x2:     .space 4
2338 x3:     .space 4
2339         .text
2340         addi 3,31,ld0@got@tlsgd
2341         bl __tls_get_addr
2342         addi 3,31,x1@got@tlsld
2343         bl __tls_get_addr
2344         addi 9,3,x1@dtprel
2345         addis 9,3,x2@dtprel@ha
2346         addi 9,9,x2@dtprel@l
2347         lwz 9,x3@got@tprel(31)
2348         add 9,9,x@tls
2349         addi 9,2,x1@tprel
2350         addis 9,2,x2@tprel@ha
2351         addi 9,9,x2@tprel@l'
2352         tls_first_major=2
2353         tls_first_minor=14
2354         tls_as_opt="-a32 --fatal-warnings"
2355         ;;
2356   powerpc64-*-*)
2357     conftest_s='
2358         .section ".tdata","awT",@progbits
2359         .align 3
2360 ld0:    .space 8
2361 ld1:    .space 8
2362 x1:     .space 8
2363 x2:     .space 8
2364 x3:     .space 8
2365         .text
2366         addi 3,2,ld0@got@tlsgd
2367         bl .__tls_get_addr
2368         nop
2369         addi 3,2,ld1@toc
2370         bl .__tls_get_addr
2371         nop
2372         addi 3,2,x1@got@tlsld
2373         bl .__tls_get_addr
2374         nop
2375         addi 9,3,x1@dtprel
2376         bl .__tls_get_addr
2377         nop
2378         addis 9,3,x2@dtprel@ha
2379         addi 9,9,x2@dtprel@l
2380         bl .__tls_get_addr
2381         nop
2382         ld 9,x3@got@dtprel(2)
2383         add 9,9,3
2384         bl .__tls_get_addr
2385         nop'
2386         tls_first_major=2
2387         tls_first_minor=14
2388         tls_as_opt="-a64 --fatal-warnings"
2389         ;;
2390   s390-*-*)
2391     conftest_s='
2392         .section ".tdata","awT",@progbits
2393 foo:    .long   25
2394         .text
2395         .long   foo@TLSGD
2396         .long   foo@TLSLDM
2397         .long   foo@DTPOFF
2398         .long   foo@NTPOFF
2399         .long   foo@GOTNTPOFF
2400         .long   foo@INDNTPOFF
2401         l       %r1,foo@GOTNTPOFF(%r12)
2402         l       %r1,0(%r1):tls_load:foo
2403         bas     %r14,0(%r1,%r13):tls_gdcall:foo
2404         bas     %r14,0(%r1,%r13):tls_ldcall:foo'
2405         tls_first_major=2
2406         tls_first_minor=14
2407         tls_as_opt="-m31 --fatal-warnings"
2408         ;;
2409   s390x-*-*)
2410     conftest_s='
2411         .section ".tdata","awT",@progbits
2412 foo:    .long   25
2413         .text
2414         .quad   foo@TLSGD
2415         .quad   foo@TLSLDM
2416         .quad   foo@DTPOFF
2417         .quad   foo@NTPOFF
2418         .quad   foo@GOTNTPOFF
2419         lg      %r1,foo@GOTNTPOFF(%r12)
2420         larl    %r1,foo@INDNTPOFF
2421         brasl   %r14,__tls_get_offset@PLT:tls_gdcall:foo
2422         brasl   %r14,__tls_get_offset@PLT:tls_ldcall:foo'
2423         tls_first_major=2
2424         tls_first_minor=14
2425         tls_as_opt="-m64 -Aesame --fatal-warnings"
2426         ;;
2427   sh-*-* | sh[34]-*-*)
2428     conftest_s='
2429         .section ".tdata","awT",@progbits
2430 foo:    .long   25
2431         .text
2432         .long   foo@TLSGD
2433         .long   foo@TLSLDM
2434         .long   foo@DTPOFF
2435         .long   foo@GOTTPOFF
2436         .long   foo@TPOFF'
2437         tls_first_major=2
2438         tls_first_minor=13
2439         tls_as_opt=--fatal-warnings
2440         ;;
2441   sparc*-*-*)
2442     case "$target" in
2443       sparc*-sun-solaris2.*)
2444         on_solaris=yes
2445         ;;
2446       *)
2447         on_solaris=no
2448         ;;
2449     esac
2450     if test x$on_solaris = xyes && test x$gas_flag = xno; then
2451       conftest_s='
2452         .section ".tdata",#alloc,#write,#tls
2453 foo:    .long   25
2454         .text
2455         sethi   %tgd_hi22(foo), %o0
2456         add     %o0, %tgd_lo10(foo), %o1
2457         add     %l7, %o1, %o0, %tgd_add(foo)
2458         call    __tls_get_addr, %tgd_call(foo)
2459         sethi   %tldm_hi22(foo), %l1
2460         add     %l1, %tldm_lo10(foo), %l2
2461         add     %l7, %l2, %o0, %tldm_add(foo)
2462         call    __tls_get_addr, %tldm_call(foo)
2463         sethi   %tldo_hix22(foo), %l3
2464         xor     %l3, %tldo_lox10(foo), %l4
2465         add     %o0, %l4, %l5, %tldo_add(foo)
2466         sethi   %tie_hi22(foo), %o3
2467         add     %o3, %tie_lo10(foo), %o3
2468         ld      [%l7 + %o3], %o2, %tie_ld(foo)
2469         add     %g7, %o2, %o4, %tie_add(foo)
2470         sethi   %tle_hix22(foo), %l1
2471         xor     %l1, %tle_lox10(foo), %o5
2472         ld      [%g7 + %o5], %o1'
2473         tls_first_major=0
2474         tls_first_minor=0
2475     else
2476       conftest_s='
2477         .section ".tdata","awT",@progbits
2478 foo:    .long   25
2479         .text
2480         sethi   %tgd_hi22(foo), %o0
2481         add     %o0, %tgd_lo10(foo), %o1
2482         add     %l7, %o1, %o0, %tgd_add(foo)
2483         call    __tls_get_addr, %tgd_call(foo)
2484         sethi   %tldm_hi22(foo), %l1
2485         add     %l1, %tldm_lo10(foo), %l2
2486         add     %l7, %l2, %o0, %tldm_add(foo)
2487         call    __tls_get_addr, %tldm_call(foo)
2488         sethi   %tldo_hix22(foo), %l3
2489         xor     %l3, %tldo_lox10(foo), %l4
2490         add     %o0, %l4, %l5, %tldo_add(foo)
2491         sethi   %tie_hi22(foo), %o3
2492         add     %o3, %tie_lo10(foo), %o3
2493         ld      [%l7 + %o3], %o2, %tie_ld(foo)
2494         add     %g7, %o2, %o4, %tie_add(foo)
2495         sethi   %tle_hix22(foo), %l1
2496         xor     %l1, %tle_lox10(foo), %o5
2497         ld      [%g7 + %o5], %o1'
2498         tls_first_major=2
2499         tls_first_minor=14
2500         tls_as_opt="-32 --fatal-warnings"
2501       fi
2502         ;;
2503 changequote([,])dnl
2504 esac
2505 if test -z "$tls_first_major"; then
2506   : # If we don't have a check, assume no support.
2507 else
2508   gcc_GAS_CHECK_FEATURE(thread-local storage support, gcc_cv_as_tls,
2509   [$tls_first_major,$tls_first_minor,0], [$tls_as_opt], [$conftest_s],,
2510   [AC_DEFINE(HAVE_AS_TLS, 1,
2511             [Define if your assembler supports thread-local storage.])])
2512 fi
2513
2514 # Target-specific assembler checks.
2515
2516 if test x"$demangler_in_ld" = xyes; then
2517   AC_MSG_CHECKING(linker --demangle support)
2518   gcc_cv_ld_demangle=no
2519   if test $in_tree_ld = yes; then
2520     if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 14 -o "$gcc_cv_gld_major_version" -gt 2; then \
2521       gcc_cv_ld_demangle=yes
2522     fi
2523   elif test x$gcc_cv_ld != x -a x"$gnu_ld" = xyes; then
2524     # Check if the GNU linker supports --demangle option
2525     if $gcc_cv_ld --help 2>/dev/null | grep no-demangle > /dev/null; then
2526       gcc_cv_ld_demangle=yes
2527     fi
2528   fi
2529   if test x"$gcc_cv_ld_demangle" = xyes; then
2530     AC_DEFINE(HAVE_LD_DEMANGLE, 1,
2531 [Define if your linker supports --demangle option.])
2532   fi
2533   AC_MSG_RESULT($gcc_cv_ld_demangle)
2534 fi
2535
2536 case "$target" in
2537   # All TARGET_ABI_OSF targets.
2538   alpha*-*-osf* | alpha*-*-linux* | alpha*-*-*bsd*)
2539     gcc_GAS_CHECK_FEATURE([explicit relocation support],
2540         gcc_cv_as_alpha_explicit_relocs, [2,12,0],,
2541 [       .set nomacro
2542         .text
2543         extbl   $3, $2, $3      !lituse_bytoff!1
2544         ldq     $2, a($29)      !literal!1
2545         ldq     $4, b($29)      !literal!2
2546         ldq_u   $3, 0($2)       !lituse_base!1
2547         ldq     $27, f($29)     !literal!5
2548         jsr     $26, ($27), f   !lituse_jsr!5
2549         ldah    $29, 0($26)     !gpdisp!3
2550         lda     $0, c($29)      !gprel
2551         ldah    $1, d($29)      !gprelhigh
2552         lda     $1, d($1)       !gprellow
2553         lda     $29, 0($29)     !gpdisp!3],,
2554     [AC_DEFINE(HAVE_AS_EXPLICIT_RELOCS, 1,
2555   [Define if your assembler supports explicit relocations.])])
2556     ;;
2557
2558   cris-*-*)
2559     gcc_GAS_CHECK_FEATURE([-no-mul-bug-abort option],
2560       gcc_cv_as_cris_no_mul_bug,[2,15,91],
2561       [-no-mul-bug-abort], [.text],,
2562       [AC_DEFINE(HAVE_AS_NO_MUL_BUG_ABORT_OPTION, 1,
2563                 [Define if your assembler supports the -no-mul-bug-abort option.])])
2564     ;;
2565
2566   sparc*-*-*)
2567     gcc_GAS_CHECK_FEATURE([.register], gcc_cv_as_sparc_register_op,,,
2568       [.register %g2, #scratch],,
2569       [AC_DEFINE(HAVE_AS_REGISTER_PSEUDO_OP, 1,
2570                 [Define if your assembler supports .register.])])
2571
2572     gcc_GAS_CHECK_FEATURE([-relax option], gcc_cv_as_sparc_relax,,
2573       [-relax], [.text],,
2574       [AC_DEFINE(HAVE_AS_RELAX_OPTION, 1,
2575                 [Define if your assembler supports -relax option.])])
2576
2577     gcc_GAS_CHECK_FEATURE([unaligned pcrel relocs],
2578       gcc_cv_as_sparc_ua_pcrel,,
2579       [-K PIC],
2580 [.text
2581 foo:
2582         nop
2583 .data
2584 .align 4
2585 .byte 0
2586 .uaword %r_disp32(foo)],
2587       [if test x$gcc_cv_ld != x \
2588        && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1; then
2589          gcc_cv_as_sparc_ua_pcrel=yes
2590        fi
2591        rm -f conftest],
2592       [AC_DEFINE(HAVE_AS_SPARC_UA_PCREL, 1,
2593                 [Define if your assembler and linker support unaligned PC relative relocs.])
2594
2595       gcc_GAS_CHECK_FEATURE([unaligned pcrel relocs against hidden symbols],
2596         gcc_cv_as_sparc_ua_pcrel_hidden,,
2597         [-K PIC],
2598 [.data
2599 .align 4
2600 .byte 0x31
2601 .uaword %r_disp32(foo)
2602 .byte 0x32, 0x33, 0x34
2603 .global foo
2604 .hidden foo
2605 foo:
2606 .skip 4],
2607         [if test x$gcc_cv_ld != x && test x$gcc_cv_objdump != x \
2608          && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1 \
2609          && $gcc_cv_objdump -s -j .data conftest 2> /dev/null \
2610             | grep ' 31000000 07323334' > /dev/null 2>&1; then
2611             if $gcc_cv_objdump -R conftest 2> /dev/null \
2612                | grep 'DISP32' > /dev/null 2>&1; then
2613                 :
2614             else
2615                 gcc_cv_as_sparc_ua_pcrel_hidden=yes
2616             fi
2617          fi
2618          rm -f conftest],
2619          [AC_DEFINE(HAVE_AS_SPARC_UA_PCREL_HIDDEN, 1,
2620                    [Define if your assembler and linker support unaligned PC relative relocs against hidden symbols.])])
2621     ]) # unaligned pcrel relocs
2622
2623     gcc_GAS_CHECK_FEATURE([offsetable %lo()],
2624       gcc_cv_as_sparc_offsetable_lo10,,
2625       [-xarch=v9],
2626 [.text
2627         or %g1, %lo(ab) + 12, %g1
2628         or %g1, %lo(ab + 12), %g1],
2629       [if test x$gcc_cv_objdump != x \
2630        && $gcc_cv_objdump -s -j .text conftest.o 2> /dev/null \
2631           | grep ' 82106000 82106000' > /dev/null 2>&1; then
2632          gcc_cv_as_offsetable_lo10=yes
2633        fi],
2634        [AC_DEFINE(HAVE_AS_OFFSETABLE_LO10, 1,
2635                  [Define if your assembler supports offsetable %lo().])])
2636     ;;
2637
2638 changequote(,)dnl
2639   i[34567]86-*-* | x86_64-*-*)
2640 changequote([,])dnl
2641     case $target_os in
2642       cygwin* | pe | mingw32*)
2643         # Used for DWARF 2 in PE
2644         gcc_GAS_CHECK_FEATURE([.secrel32 relocs],
2645           gcc_cv_as_ix86_pe_secrel32,
2646           [2,15,91],,
2647 [.text
2648 foo:    nop
2649 .data
2650         .secrel32 foo],
2651           [if test x$gcc_cv_ld != x \
2652            && $gcc_cv_ld -o conftest conftest.o > /dev/null 2>&1; then
2653              gcc_cv_as_ix86_pe_secrel32=yes
2654            fi
2655            rm -f conftest],
2656           [AC_DEFINE(HAVE_GAS_PE_SECREL32_RELOC, 1,
2657             [Define if your assembler and linker support 32-bit section relative relocs via '.secrel32 label'.])])
2658         ;;
2659     esac
2660
2661     gcc_GAS_CHECK_FEATURE([filds and fists mnemonics],
2662        gcc_cv_as_ix86_filds_fists,
2663       [2,9,0],, [filds mem; fists mem],,
2664       [AC_DEFINE(HAVE_GAS_FILDS_FISTS, 1,
2665         [Define if your assembler uses the new HImode fild and fist notation.])])
2666
2667     gcc_GAS_CHECK_FEATURE([cmov syntax],
2668       gcc_cv_as_ix86_cmov_sun_syntax,,,
2669       [cmovl.l %edx, %eax],,
2670       [AC_DEFINE(HAVE_AS_IX86_CMOV_SUN_SYNTAX, 1,
2671         [Define if your assembler supports the Sun syntax for cmov.])])
2672
2673     # This one is used unconditionally by i386.[ch]; it is to be defined
2674     # to 1 if the feature is present, 0 otherwise.
2675     gcc_GAS_CHECK_FEATURE([GOTOFF in data],
2676         gcc_cv_as_ix86_gotoff_in_data, [2,11,0],,
2677 [       .text
2678 .L0:
2679         nop
2680         .data
2681         .long .L0@GOTOFF])
2682     AC_DEFINE_UNQUOTED(HAVE_AS_GOTOFF_IN_DATA,
2683       [`if test $gcc_cv_as_ix86_gotoff_in_data = yes; then echo 1; else echo 0; fi`],
2684       [Define true if the assembler supports '.long foo@GOTOFF'.])
2685     ;;
2686
2687   ia64*-*-*)
2688     gcc_GAS_CHECK_FEATURE([ltoffx and ldxmov relocs],
2689         gcc_cv_as_ia64_ltoffx_ldxmov_relocs, [2,14,0],,
2690 [       .text
2691         addl r15 = @ltoffx(x#), gp
2692         ;;
2693         ld8.mov r16 = [[r15]], x#],,
2694     [AC_DEFINE(HAVE_AS_LTOFFX_LDXMOV_RELOCS, 1,
2695           [Define if your assembler supports ltoffx and ldxmov relocations.])])
2696
2697     ;;
2698
2699   powerpc*-*-*)
2700     case $target in
2701       *-*-aix*) conftest_s='    .csect .text[[PR]]
2702         mfcr 3,128';;
2703       *-*-darwin*) conftest_s=' .text
2704         mfcr r3,128';;
2705       *) conftest_s='   .machine power4
2706         .text
2707         mfcr 3,128';;
2708     esac
2709
2710     gcc_GAS_CHECK_FEATURE([mfcr field support],
2711       gcc_cv_as_powerpc_mfcrf, [2,14,0],,
2712       [$conftest_s],,
2713       [AC_DEFINE(HAVE_AS_MFCRF, 1,
2714           [Define if your assembler supports mfcr field.])])
2715     ;;
2716
2717   mips*-*-*)
2718     gcc_GAS_CHECK_FEATURE([explicit relocation support],
2719       gcc_cv_as_mips_explicit_relocs, [2,14,0],,
2720 [       lw $4,%gp_rel(foo)($4)],,
2721       [if test x$target_cpu_default = x
2722        then target_cpu_default=MASK_EXPLICIT_RELOCS
2723        else target_cpu_default="($target_cpu_default)|MASK_EXPLICIT_RELOCS"
2724        fi])
2725
2726     if test x$gas_flag = xyes \
2727        || test x"$host" != x"$build" \
2728        || test ! -x "$gcc_cv_as" \
2729        || "$gcc_cv_as" -v < /dev/null 2>&1 | grep GNU > /dev/null; then
2730       :
2731     else
2732       echo "*** This configuration requires the GNU assembler" >&2
2733       exit 1
2734     fi
2735     ;;
2736 esac
2737 # ??? Not all targets support dwarf2 debug_line, even within a version
2738 # of gas.  Moreover, we need to emit a valid instruction to trigger any
2739 # info to the output file.  So, as supported targets are added to gas 2.11,
2740 # add some instruction here to (also) show we expect this might work.
2741 # ??? Once 2.11 is released, probably need to add first known working
2742 # version to the per-target configury.
2743 case "$target" in
2744   i?86*-*-* | mips*-*-* | alpha*-*-* | powerpc*-*-* | sparc*-*-* | m68*-*-* \
2745   | x86_64*-*-* | hppa*-*-* | arm*-*-* | strongarm*-*-* | xscale*-*-* \
2746   | xstormy16*-*-* | cris-*-* | xtensa-*-*)
2747     insn="nop"
2748     ;;
2749   ia64*-*-* | s390*-*-*)
2750     insn="nop 0"
2751     ;;
2752   mmix-*-*)
2753     insn="swym 0"
2754     ;;
2755 esac
2756 if test x"$insn" != x; then
2757  conftest_s="\
2758         .file 1 \"conftest.s\"
2759         .loc 1 3 0
2760         $insn"
2761  gcc_GAS_CHECK_FEATURE([dwarf2 debug_line support],
2762   gcc_cv_as_dwarf2_debug_line,
2763   [elf,2,11,0],, [$conftest_s],
2764   [# ??? This fails with non-gnu grep.  Maybe use objdump?
2765    if grep debug_line conftest.o > /dev/null 2>&1; then
2766      gcc_cv_as_dwarf2_debug_line=yes
2767    fi])
2768
2769 # The .debug_line file table must be in the exact order that
2770 # we specified the files, since these indices are also used
2771 # by DW_AT_decl_file.  Approximate this test by testing if
2772 # the assembler bitches if the same index is assigned twice.
2773  gcc_GAS_CHECK_FEATURE([buggy dwarf2 .file directive],
2774   gcc_cv_as_dwarf2_file_buggy,,,
2775 [       .file 1 "foo.s"
2776         .file 1 "bar.s"])
2777
2778  if test $gcc_cv_as_dwarf2_debug_line = yes \
2779  && test $gcc_cv_as_dwarf2_file_buggy = no; then
2780         AC_DEFINE(HAVE_AS_DWARF2_DEBUG_LINE, 1,
2781   [Define if your assembler supports dwarf2 .file/.loc directives,
2782    and preserves file table indices exactly as given.])
2783  fi
2784
2785  gcc_GAS_CHECK_FEATURE([--gdwarf2 option],
2786   gcc_cv_as_gdwarf2_flag,
2787   [elf,2,11,0], [--gdwarf2], [$insn],,
2788   [AC_DEFINE(HAVE_AS_GDWARF2_DEBUG_FLAG, 1,
2789 [Define if your assembler supports the --gdwarf2 option.])])
2790
2791  gcc_GAS_CHECK_FEATURE([--gstabs option],
2792   gcc_cv_as_gstabs_flag,
2793   [elf,2,11,0], [--gstabs], [$insn],
2794   [# The native Solaris 9/Intel assembler doesn't understand --gstabs
2795    # and warns about it, but still exits successfully.  So check for
2796    # this.
2797    if AC_TRY_COMMAND([$gcc_cv_as --gstabs -o conftest.o conftest.s 2>&1 | grep -i warning > /dev/null])
2798    then :
2799    else gcc_cv_as_gstabs_flag=yes
2800    fi],
2801   [AC_DEFINE(HAVE_AS_GSTABS_DEBUG_FLAG, 1,
2802 [Define if your assembler supports the --gstabs option.])])
2803 fi
2804
2805 AC_MSG_CHECKING(linker read-only and read-write section mixing)
2806 gcc_cv_ld_ro_rw_mix=unknown
2807 if test $in_tree_ld = yes ; then
2808   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 10 -o "$gcc_cv_gld_major_version" -gt 2 \
2809      && test $in_tree_ld_is_elf = yes; then
2810     gcc_cv_ld_ro_rw_mix=read-write
2811   fi
2812 elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x -a x$gcc_cv_objdump != x ; then
2813   echo '.section myfoosect, "a"' > conftest1.s
2814   echo '.section myfoosect, "aw"' > conftest2.s
2815   echo '.byte 1' >> conftest2.s
2816   echo '.section myfoosect, "a"' > conftest3.s
2817   echo '.byte 0' >> conftest3.s
2818   if $gcc_cv_as -o conftest1.o conftest1.s > /dev/null 2>&1 \
2819      && $gcc_cv_as -o conftest2.o conftest2.s > /dev/null 2>&1 \
2820      && $gcc_cv_as -o conftest3.o conftest3.s > /dev/null 2>&1 \
2821      && $gcc_cv_ld -shared -o conftest1.so conftest1.o \
2822         conftest2.o conftest3.o > /dev/null 2>&1; then
2823     gcc_cv_ld_ro_rw_mix=`$gcc_cv_objdump -h conftest1.so \
2824                          | sed -e '/myfoosect/!d' -e N`
2825     if echo "$gcc_cv_ld_ro_rw_mix" | grep CONTENTS > /dev/null; then
2826       if echo "$gcc_cv_ld_ro_rw_mix" | grep READONLY > /dev/null; then
2827         gcc_cv_ld_ro_rw_mix=read-only
2828       else
2829         gcc_cv_ld_ro_rw_mix=read-write
2830       fi
2831     fi
2832   fi
2833 changequote(,)dnl
2834   rm -f conftest.* conftest[123].*
2835 changequote([,])dnl
2836 fi
2837 if test x$gcc_cv_ld_ro_rw_mix = xread-write; then
2838         AC_DEFINE(HAVE_LD_RO_RW_SECTION_MIXING, 1,
2839   [Define if your linker links a mix of read-only
2840    and read-write sections into a read-write section.])
2841 fi
2842 AC_MSG_RESULT($gcc_cv_ld_ro_rw_mix)
2843
2844 AC_MSG_CHECKING(linker PT_GNU_EH_FRAME support)
2845 gcc_cv_ld_eh_frame_hdr=no
2846 if test $in_tree_ld = yes ; then
2847   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 12 -o "$gcc_cv_gld_major_version" -gt 2 \
2848      && test $in_tree_ld_is_elf = yes; then
2849     gcc_cv_ld_eh_frame_hdr=yes
2850   fi
2851 elif test x$gcc_cv_ld != x; then
2852         # Check if linker supports --eh-frame-hdr option
2853         if $gcc_cv_ld --help 2>/dev/null | grep eh-frame-hdr > /dev/null; then
2854                 gcc_cv_ld_eh_frame_hdr=yes
2855         fi
2856 fi
2857 if test x"$gcc_cv_ld_eh_frame_hdr" = xyes; then
2858         AC_DEFINE(HAVE_LD_EH_FRAME_HDR, 1,
2859 [Define if your linker supports --eh-frame-hdr option.])
2860 fi
2861 AC_MSG_RESULT($gcc_cv_ld_eh_frame_hdr)
2862
2863 AC_MSG_CHECKING(linker position independent executable support)
2864 gcc_cv_ld_pie=no
2865 if test $in_tree_ld = yes ; then
2866   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 15 -o "$gcc_cv_gld_major_version" -gt 2 \
2867      && test $in_tree_ld_is_elf = yes; then
2868     gcc_cv_ld_pie=yes
2869   fi
2870 elif test x$gcc_cv_ld != x; then
2871         # Check if linker supports -pie option
2872         if $gcc_cv_ld --help 2>/dev/null | grep -- -pie > /dev/null; then
2873                 gcc_cv_ld_pie=yes
2874         fi
2875 fi
2876 if test x"$gcc_cv_ld_pie" = xyes; then
2877         AC_DEFINE(HAVE_LD_PIE, 1,
2878 [Define if your linker supports -pie option.])
2879 fi
2880 AC_MSG_RESULT($gcc_cv_ld_pie)
2881
2882 # --------
2883 # UNSORTED
2884 # --------
2885
2886 AC_CACHE_CHECK(linker --as-needed support,
2887 gcc_cv_ld_as_needed,
2888 [gcc_cv_ld_as_needed=no
2889 if test $in_tree_ld = yes ; then
2890   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2 \
2891      && test $in_tree_ld_is_elf = yes; then
2892     gcc_cv_ld_as_needed=yes
2893   fi
2894 elif test x$gcc_cv_ld != x; then
2895         # Check if linker supports --as-needed and --no-as-needed options
2896         if $gcc_cv_ld --help 2>/dev/null | grep as-needed > /dev/null; then
2897                 gcc_cv_ld_as_needed=yes
2898         fi
2899 fi
2900 ])
2901 if test x"$gcc_cv_ld_as_needed" = xyes; then
2902         AC_DEFINE(HAVE_LD_AS_NEEDED, 1,
2903 [Define if your linker supports --as-needed and --no-as-needed options.])
2904 fi
2905
2906 case "$target" in
2907   powerpc64*-*-linux*)
2908     AC_CACHE_CHECK(linker support for omitting dot symbols,
2909     gcc_cv_ld_no_dot_syms,
2910     [gcc_cv_ld_no_dot_syms=no
2911     if test $in_tree_ld = yes ; then
2912       if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2; then
2913         gcc_cv_ld_no_dot_syms=yes
2914       fi
2915     elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x ; then
2916       cat > conftest1.s <<EOF
2917         .text
2918         bl .foo
2919 EOF
2920       cat > conftest2.s <<EOF
2921         .section ".opd","aw"
2922         .align 3
2923         .globl foo
2924         .type foo,@function
2925 foo:
2926         .quad .LEfoo,.TOC.@tocbase,0
2927         .text
2928 .LEfoo:
2929         blr
2930         .size foo,.-.LEfoo
2931 EOF
2932       if $gcc_cv_as -a64 -o conftest1.o conftest1.s > /dev/null 2>&1 \
2933          && $gcc_cv_as -a64 -o conftest2.o conftest2.s > /dev/null 2>&1 \
2934          && $gcc_cv_ld -melf64ppc -o conftest conftest1.o conftest2.o > /dev/null 2>&1; then
2935         gcc_cv_ld_no_dot_syms=yes
2936       fi
2937       rm -f conftest conftest1.o conftest2.o conftest1.s conftest2.s
2938     fi
2939     ])
2940     if test x"$gcc_cv_ld_no_dot_syms" = xyes; then
2941       AC_DEFINE(HAVE_LD_NO_DOT_SYMS, 1,
2942     [Define if your PowerPC64 linker only needs function descriptor syms.])
2943     fi
2944     ;;
2945 esac
2946
2947 if test x$with_sysroot = x && test x$host = x$target \
2948    && test "$prefix" != "/usr" && test "x$prefix" != "x$local_prefix" ; then
2949   AC_DEFINE_UNQUOTED(PREFIX_INCLUDE_DIR, "$prefix/include",
2950 [Define to PREFIX/include if cpp should also search that directory.])
2951 fi
2952
2953 # Find out what GC implementation we want, or may, use.
2954 AC_ARG_WITH(gc,
2955 [  --with-gc={page,zone}   choose the garbage collection mechanism to use
2956                           with the compiler],
2957 [case "$withval" in
2958   page | zone)
2959     GGC=ggc-$withval
2960     ;;
2961   *)
2962     AC_MSG_ERROR([$withval is an invalid option to --with-gc])
2963     ;;
2964 esac],
2965 [GGC=ggc-page])
2966 AC_SUBST(GGC)
2967 echo "Using $GGC for garbage collection."
2968
2969 # Use the system's zlib library.
2970 zlibdir=-L../zlib
2971 zlibinc="-I\$(srcdir)/../zlib"
2972 AC_ARG_WITH(system-zlib,
2973 [  --with-system-zlib      use installed libz],
2974 zlibdir=
2975 zlibinc=
2976 )
2977 AC_SUBST(zlibdir)
2978 AC_SUBST(zlibinc)
2979
2980 dnl Very limited version of automake's enable-maintainer-mode
2981
2982 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
2983   dnl maintainer-mode is disabled by default
2984   AC_ARG_ENABLE(maintainer-mode,
2985 [  --enable-maintainer-mode
2986                           enable make rules and dependencies not useful
2987                           (and sometimes confusing) to the casual installer],
2988       maintainer_mode=$enableval,
2989       maintainer_mode=no)
2990
2991 AC_MSG_RESULT($maintainer_mode)
2992
2993 if test "$maintainer_mode" = "yes"; then
2994   MAINT=''
2995 else
2996   MAINT='#'
2997 fi
2998 AC_SUBST(MAINT)dnl
2999
3000 # --------------
3001 # Language hooks
3002 # --------------
3003
3004 # Make empty files to contain the specs and options for each language.
3005 # Then add #include lines to for a compiler that has specs and/or options.
3006
3007 lang_opt_files=
3008 lang_specs_files=
3009 lang_tree_files=
3010 for subdir in . $subdirs
3011 do
3012         if test -f $srcdir/$subdir/lang.opt; then
3013             lang_opt_files="$lang_opt_files $srcdir/$subdir/lang.opt"
3014         fi
3015         if test -f $srcdir/$subdir/lang-specs.h; then
3016             lang_specs_files="$lang_specs_files $srcdir/$subdir/lang-specs.h"
3017         fi
3018         if test -f $srcdir/$subdir/$subdir-tree.def; then
3019             lang_tree_files="$lang_tree_files $srcdir/$subdir/$subdir-tree.def"
3020         fi
3021 done
3022
3023 # These (without "all_") are set in each config-lang.in.
3024 # `language' must be a single word so is spelled singularly.
3025 all_languages=
3026 all_boot_languages=
3027 all_compilers=
3028 all_stagestuff=
3029 all_outputs='Makefile gccbug mklibgcc libada-mk'
3030 # List of language makefile fragments.
3031 all_lang_makefrags=
3032 # List of language subdirectory makefiles.  Deprecated.
3033 all_lang_makefiles=
3034 # Files for gengtype
3035 all_gtfiles="$target_gtfiles"
3036 # Files for gengtype with language
3037 all_gtfiles_files_langs=
3038 all_gtfiles_files_files=
3039
3040 # Add the language fragments.
3041 # Languages are added via two mechanisms.  Some information must be
3042 # recorded in makefile variables, these are defined in config-lang.in.
3043 # We accumulate them and plug them into the main Makefile.
3044 # The other mechanism is a set of hooks for each of the main targets
3045 # like `clean', `install', etc.
3046
3047 language_hooks="Make-hooks"
3048
3049 for s in $subdirs
3050 do
3051                 language=
3052                 boot_language=
3053                 compilers=
3054                 stagestuff=
3055                 outputs=
3056                 gtfiles=
3057                 . ${srcdir}/$s/config-lang.in
3058                 if test "x$language" = x
3059                 then
3060                         echo "${srcdir}/$s/config-lang.in doesn't set \$language." 1>&2
3061                         exit 1
3062                 fi
3063                 all_lang_makefrags="$all_lang_makefrags \$(srcdir)/$s/Make-lang.in"
3064                 if test -f ${srcdir}/$s/Makefile.in
3065                 then all_lang_makefiles="$s/Makefile"
3066                 fi
3067                 all_languages="$all_languages $language"
3068                 if test "x$boot_language" = xyes
3069                 then
3070                         all_boot_languages="$all_boot_languages $language"
3071                 fi
3072                 all_compilers="$all_compilers $compilers"
3073                 all_stagestuff="$all_stagestuff $stagestuff"
3074                 all_outputs="$all_outputs $outputs"
3075                 all_gtfiles="$all_gtfiles $gtfiles"
3076                 for f in $gtfiles
3077                 do
3078                          all_gtfiles_files_langs="$all_gtfiles_files_langs ${s} "
3079                          all_gtfiles_files_files="$all_gtfiles_files_files ${f} "
3080                 done
3081 done
3082
3083 # Pick up gtfiles for c
3084 gtfiles=
3085 s="c"
3086 . ${srcdir}/c-config-lang.in
3087 all_gtfiles="$all_gtfiles $gtfiles"
3088 for f in $gtfiles
3089 do
3090         all_gtfiles_files_langs="$all_gtfiles_files_langs ${s} "
3091         all_gtfiles_files_files="$all_gtfiles_files_files ${f} "
3092 done
3093
3094 check_languages=
3095 for language in $all_languages
3096 do
3097                 check_languages="$check_languages check-$language"
3098 done
3099
3100 # We link each language in with a set of hooks, reached indirectly via
3101 # lang.${target}.
3102
3103 rm -f Make-hooks
3104 touch Make-hooks
3105 target_list="all.build all.cross start.encap rest.encap tags \
3106         install-normal install-common install-man \
3107         uninstall info man srcextra srcman srcinfo \
3108         mostlyclean clean distclean maintainer-clean \
3109         stage1 stage2 stage3 stage4 stageprofile stagefeedback"
3110 for t in $target_list
3111 do
3112         x=
3113         for lang in $all_languages
3114         do
3115                         x="$x $lang.$t"
3116         done
3117         echo "lang.$t: $x" >> Make-hooks
3118 done
3119
3120 # --------
3121 # UNSORTED
3122 # --------
3123
3124 # Create .gdbinit.
3125
3126 echo "dir ." > .gdbinit
3127 echo "dir ${srcdir}" >> .gdbinit
3128 if test x$gdb_needs_out_file_path = xyes
3129 then
3130         echo "dir ${srcdir}/config/"`dirname ${out_file}` >> .gdbinit
3131 fi
3132 if test "x$subdirs" != x; then
3133         for s in $subdirs
3134         do
3135                 echo "dir ${srcdir}/$s" >> .gdbinit
3136         done
3137 fi
3138 echo "source ${srcdir}/gdbinit.in" >> .gdbinit
3139
3140 # If $(exec_prefix) exists and is not the same as $(prefix), then compute an
3141 # absolute path for gcc_tooldir based on inserting the number of up-directory
3142 # movements required to get from $(exec_prefix) to $(prefix) into the basic
3143 # $(libsubdir)/@(unlibsubdir) based path.
3144 # Don't set gcc_tooldir to tooldir since that's only passed in by the toplevel
3145 # make and thus we'd get different behavior depending on where we built the
3146 # sources.
3147 if test x$exec_prefix = xNONE -o x$exec_prefix = x$prefix; then
3148     gcc_tooldir='$(libsubdir)/$(unlibsubdir)/../$(target_noncanonical)'
3149 else
3150 changequote(<<, >>)dnl
3151 # An explanation of the sed strings:
3152 #  -e 's|^\$(prefix)||'   matches and eliminates 'prefix' from 'exec_prefix'
3153 #  -e 's|/$||'            match a trailing forward slash and eliminates it
3154 #  -e 's|^[^/]|/|'        forces the string to start with a forward slash (*)
3155 #  -e 's|/[^/]*|../|g'    replaces each occurrence of /<directory> with ../
3156 #
3157 # (*) Note this pattern overwrites the first character of the string
3158 # with a forward slash if one is not already present.  This is not a
3159 # problem because the exact names of the sub-directories concerned is
3160 # unimportant, just the number of them matters.
3161 #
3162 # The practical upshot of these patterns is like this:
3163 #
3164 #  prefix     exec_prefix        result
3165 #  ------     -----------        ------
3166 #   /foo        /foo/bar          ../
3167 #   /foo/       /foo/bar          ../
3168 #   /foo        /foo/bar/         ../
3169 #   /foo/       /foo/bar/         ../
3170 #   /foo        /foo/bar/ugg      ../../
3171 #
3172     dollar='$$'
3173     gcc_tooldir="\$(libsubdir)/\$(unlibsubdir)/\`echo \$(exec_prefix) | sed -e 's|^\$(prefix)||' -e 's|/\$(dollar)||' -e 's|^[^/]|/|' -e 's|/[^/]*|../|g'\`\$(target_noncanonical)"
3174 changequote([, ])dnl
3175 fi
3176 AC_SUBST(gcc_tooldir)
3177 AC_SUBST(dollar)
3178
3179 # Find a directory in which to install a shared libgcc.
3180
3181 AC_ARG_ENABLE(version-specific-runtime-libs,
3182 [  --enable-version-specific-runtime-libs
3183                           specify that runtime libraries should be
3184                           installed in a compiler-specific directory])
3185
3186 AC_ARG_WITH(slibdir,
3187 [  --with-slibdir=DIR      shared libraries in DIR [LIBDIR]],
3188 slibdir="$with_slibdir",
3189 if test "${enable_version_specific_runtime_libs+set}" = set; then
3190   slibdir='$(libsubdir)'
3191 elif test "$host" != "$target"; then
3192   slibdir='$(build_tooldir)/lib'
3193 else
3194   slibdir='$(libdir)'
3195 fi)
3196 AC_SUBST(slibdir)
3197
3198 objdir=`${PWDCMD-pwd}`
3199 AC_SUBST(objdir)
3200
3201 # Substitute configuration variables
3202 AC_SUBST(subdirs)
3203 AC_SUBST(srcdir)
3204 AC_SUBST(all_boot_languages)
3205 AC_SUBST(all_compilers)
3206 AC_SUBST(all_gtfiles)
3207 AC_SUBST(all_gtfiles_files_langs)
3208 AC_SUBST(all_gtfiles_files_files)
3209 AC_SUBST(all_lang_makefrags)
3210 AC_SUBST(all_lang_makefiles)
3211 AC_SUBST(all_languages)
3212 AC_SUBST(all_stagestuff)
3213 AC_SUBST(build_exeext)
3214 AC_SUBST(build_install_headers_dir)
3215 AC_SUBST(build_xm_file_list)
3216 AC_SUBST(build_xm_include_list)
3217 AC_SUBST(build_xm_defines)
3218 AC_SUBST(check_languages)
3219 AC_SUBST(cc_set_by_configure)
3220 AC_SUBST(quoted_cc_set_by_configure)
3221 AC_SUBST(cpp_install_dir)
3222 AC_SUBST(xmake_file)
3223 AC_SUBST(tmake_file)
3224 AC_SUBST(extra_gcc_objs)
3225 AC_SUBST(extra_headers_list)
3226 AC_SUBST(extra_objs)
3227 AC_SUBST(extra_parts)
3228 AC_SUBST(extra_passes)
3229 AC_SUBST(extra_programs)
3230 AC_SUBST(float_h_file)
3231 AC_SUBST(gcc_config_arguments)
3232 AC_SUBST(gcc_gxx_include_dir)
3233 AC_SUBST(libstdcxx_incdir)
3234 AC_SUBST(gcc_version)
3235 AC_SUBST(gcc_version_full)
3236 AC_SUBST(gcc_version_trigger)
3237 AC_SUBST(host_exeext)
3238 AC_SUBST(host_xm_file_list)
3239 AC_SUBST(host_xm_include_list)
3240 AC_SUBST(host_xm_defines)
3241 AC_SUBST(out_host_hook_obj)
3242 AC_SUBST(install)
3243 AC_SUBST(lang_opt_files)
3244 AC_SUBST(lang_specs_files)
3245 AC_SUBST(lang_tree_files)
3246 AC_SUBST(local_prefix)
3247 AC_SUBST(md_file)
3248 AC_SUBST(objc_boehm_gc)
3249 AC_SUBST(out_file)
3250 AC_SUBST(out_object_file)
3251 AC_SUBST(stage_prefix_set_by_configure)
3252 AC_SUBST(quoted_stage_prefix_set_by_configure)
3253 AC_SUBST(thread_file)
3254 AC_SUBST(tm_file_list)
3255 AC_SUBST(tm_include_list)
3256 AC_SUBST(tm_defines)
3257 AC_SUBST(tm_p_file_list)
3258 AC_SUBST(tm_p_include_list)
3259 AC_SUBST(xm_file_list)
3260 AC_SUBST(xm_include_list)
3261 AC_SUBST(xm_defines)
3262 AC_SUBST(c_target_objs)
3263 AC_SUBST(cxx_target_objs)
3264 AC_SUBST(target_cpu_default)
3265
3266 AC_SUBST_FILE(language_hooks)
3267
3268 TL_AC_GNU_MAKE_GCC_LIB_PATH
3269
3270 # Echo link setup.
3271 if test x${build} = x${host} ; then
3272   if test x${host} = x${target} ; then
3273     echo "Links are now set up to build a native compiler for ${target}." 1>&2
3274   else
3275     echo "Links are now set up to build a cross-compiler" 1>&2
3276     echo " from ${host} to ${target}." 1>&2
3277   fi
3278 else
3279   if test x${host} = x${target} ; then
3280     echo "Links are now set up to build (on ${build}) a native compiler" 1>&2
3281     echo " for ${target}." 1>&2
3282   else
3283     echo "Links are now set up to build (on ${build}) a cross-compiler" 1>&2
3284     echo " from ${host} to ${target}." 1>&2
3285   fi
3286 fi
3287
3288 AC_ARG_VAR(GMPLIBS,[How to link GMP])
3289 AC_ARG_VAR(GMPINC,[How to find GMP include files])
3290
3291 # Configure the subdirectories
3292 # AC_CONFIG_SUBDIRS($subdirs)
3293
3294 # Create the Makefile
3295 # and configure language subdirectories
3296 AC_CONFIG_FILES($all_outputs)
3297
3298 AC_CONFIG_COMMANDS([default],
3299 [
3300 case ${CONFIG_HEADERS} in
3301   *auto-host.h:config.in*)
3302   echo > cstamp-h ;;
3303 esac
3304 # Make sure all the subdirs exist.
3305 for d in $subdirs doc build
3306 do
3307     test -d $d || mkdir $d
3308 done
3309 # If the host supports symlinks, point stage[1234] at ../stage[1234] so
3310 # bootstrapping and the installation procedure can still use
3311 # CC="stage1/xgcc -Bstage1/".  If the host doesn't support symlinks,
3312 # FLAGS_TO_PASS has been modified to solve the problem there.
3313 # This is virtually a duplicate of what happens in configure.lang; we do
3314 # an extra check to make sure this only happens if ln -s can be used.
3315 case "$LN_S" in
3316   *-s*)
3317     for d in ${subdirs} ; do
3318         STARTDIR=`${PWDCMD-pwd}`
3319         cd $d
3320         for t in stage1 stage2 stage3 stage4 stageprofile stagefeedback include
3321         do
3322                 rm -f $t
3323                 $LN_S ../$t $t 2>/dev/null
3324         done
3325         cd $STARTDIR
3326     done
3327   ;;
3328 esac
3329 ],
3330 [subdirs='$subdirs'])
3331 AC_OUTPUT