OSDN Git Service

Don't set enable_decimal_float to dpd if DFP is disabled.
[pf3gnuchains/gcc-fork.git] / gcc / configure.ac
1 # configure.ac for GCC
2 # Process this file with autoconf to generate a configuration script.
3
4 # Copyright 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2004, 2005, 2006,
5 # 2007, 2008, 2009, 2010 Free Software Foundation, Inc.
6
7 #This file is part of GCC.
8
9 #GCC is free software; you can redistribute it and/or modify it under
10 #the terms of the GNU General Public License as published by the Free
11 #Software Foundation; either version 3, or (at your option) any later
12 #version.
13
14 #GCC is distributed in the hope that it will be useful, but WITHOUT
15 #ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
16 #FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
17 #for more details.
18
19 #You should have received a copy of the GNU General Public License
20 #along with GCC; see the file COPYING3.  If not see
21 #<http://www.gnu.org/licenses/>.
22
23 # --------------------------------
24 # Initialization and sanity checks
25 # --------------------------------
26
27 AC_PREREQ(2.64)
28 AC_INIT
29 AC_CONFIG_SRCDIR(tree.c)
30 AC_CONFIG_HEADER(auto-host.h:config.in)
31
32 gcc_version=`cat $srcdir/BASE-VER`
33
34 # Determine the host, build, and target systems
35 AC_CANONICAL_BUILD
36 AC_CANONICAL_HOST
37 AC_CANONICAL_TARGET
38
39 # Determine the noncanonical target name, for directory use.
40 ACX_NONCANONICAL_TARGET
41
42 # Determine the target- and build-specific subdirectories
43 GCC_TOPLEV_SUBDIRS
44
45 # Set program_transform_name
46 AC_ARG_PROGRAM
47
48 # Check for bogus environment variables.
49 # Test if LIBRARY_PATH contains the notation for the current directory
50 # since this would lead to problems installing/building glibc.
51 # LIBRARY_PATH contains the current directory if one of the following
52 # is true:
53 # - one of the terminals (":" and ";") is the first or last sign
54 # - two terminals occur directly after each other
55 # - the path contains an element with a dot in it
56 AC_MSG_CHECKING(LIBRARY_PATH variable)
57 changequote(,)dnl
58 case ${LIBRARY_PATH} in
59   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
60     library_path_setting="contains current directory"
61     ;;
62   *)
63     library_path_setting="ok"
64     ;;
65 esac
66 changequote([,])dnl
67 AC_MSG_RESULT($library_path_setting)
68 if test "$library_path_setting" != "ok"; then
69 AC_MSG_ERROR([
70 *** LIBRARY_PATH shouldn't contain the current directory when
71 *** building gcc. Please change the environment variable
72 *** and run configure again.])
73 fi
74
75 # Test if GCC_EXEC_PREFIX contains the notation for the current directory
76 # since this would lead to problems installing/building glibc.
77 # GCC_EXEC_PREFIX contains the current directory if one of the following
78 # is true:
79 # - one of the terminals (":" and ";") is the first or last sign
80 # - two terminals occur directly after each other
81 # - the path contains an element with a dot in it
82 AC_MSG_CHECKING(GCC_EXEC_PREFIX variable)
83 changequote(,)dnl
84 case ${GCC_EXEC_PREFIX} in
85   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
86     gcc_exec_prefix_setting="contains current directory"
87     ;;
88   *)
89     gcc_exec_prefix_setting="ok"
90     ;;
91 esac
92 changequote([,])dnl
93 AC_MSG_RESULT($gcc_exec_prefix_setting)
94 if test "$gcc_exec_prefix_setting" != "ok"; then
95 AC_MSG_ERROR([
96 *** GCC_EXEC_PREFIX shouldn't contain the current directory when
97 *** building gcc. Please change the environment variable
98 *** and run configure again.])
99 fi
100
101 # -----------
102 # Directories
103 # -----------
104
105 # Specify the local prefix
106 local_prefix=
107 AC_ARG_WITH(local-prefix,
108 [  --with-local-prefix=DIR specifies directory to put local include],
109 [case "${withval}" in
110 yes)    AC_MSG_ERROR(bad value ${withval} given for local include directory prefix) ;;
111 no)     ;;
112 *)      local_prefix=$with_local_prefix ;;
113 esac])
114
115 # Default local prefix if it is empty
116 if test x$local_prefix = x; then
117         local_prefix=/usr/local
118 fi
119
120 # Don't set gcc_gxx_include_dir to gxx_include_dir since that's only
121 # passed in by the toplevel make and thus we'd get different behavior
122 # depending on where we built the sources.
123 gcc_gxx_include_dir=
124 # Specify the g++ header file directory
125 AC_ARG_WITH(gxx-include-dir,
126 [  --with-gxx-include-dir=DIR
127                           specifies directory to put g++ header files],
128 [case "${withval}" in
129 yes)    AC_MSG_ERROR(bad value ${withval} given for g++ include directory) ;;
130 no)     ;;
131 *)      gcc_gxx_include_dir=$with_gxx_include_dir ;;
132 esac])
133
134 # This logic must match libstdc++-v3/acinclude.m4:GLIBCXX_EXPORT_INSTALL_INFO.
135 if test x${gcc_gxx_include_dir} = x; then
136   if test x${enable_version_specific_runtime_libs} = xyes; then
137     gcc_gxx_include_dir='${libsubdir}/include/c++'
138   else
139     libstdcxx_incdir='include/c++/$(version)'
140     if test x$host != x$target; then
141        libstdcxx_incdir="$target_alias/$libstdcxx_incdir"
142     fi
143     gcc_gxx_include_dir="\$(libsubdir)/\$(libsubdir_to_prefix)$libstdcxx_incdir"
144   fi
145 fi
146
147 AC_ARG_WITH(cpp_install_dir,
148 [  --with-cpp-install-dir=DIR
149                           install the user visible C preprocessor in DIR
150                           (relative to PREFIX) as well as PREFIX/bin],
151 [if test x$withval = xyes; then
152   AC_MSG_ERROR([option --with-cpp-install-dir requires an argument])
153 elif test x$withval != xno; then
154   cpp_install_dir=$withval
155 fi])
156
157 # We would like to our source tree to be readonly.  However when releases or
158 # pre-releases are generated, the flex/bison generated files as well as the 
159 # various formats of manuals need to be included along with the rest of the
160 # sources.  Therefore we have --enable-generated-files-in-srcdir to do 
161 # just that.
162
163 AC_MSG_CHECKING([whether to place generated files in the source directory])
164   dnl generated-files-in-srcdir is disabled by default
165   AC_ARG_ENABLE(generated-files-in-srcdir, 
166 [  --enable-generated-files-in-srcdir
167                           put copies of generated files in source dir
168                           intended for creating source tarballs for users
169                           without texinfo bison or flex.],
170       generated_files_in_srcdir=$enableval,
171       generated_files_in_srcdir=no)
172
173 AC_MSG_RESULT($generated_files_in_srcdir)
174
175 if test "$generated_files_in_srcdir" = "yes"; then
176   GENINSRC=''
177 else
178   GENINSRC='#'
179 fi
180 AC_SUBST(GENINSRC)
181
182 # -------------------
183 # Find default linker
184 # -------------------
185
186 # With GNU ld
187 AC_ARG_WITH(gnu-ld,
188 [  --with-gnu-ld           arrange to work with GNU ld.],
189 gnu_ld_flag="$with_gnu_ld",
190 gnu_ld_flag=no)
191
192 # With pre-defined ld
193 AC_ARG_WITH(ld,
194 [  --with-ld               arrange to use the specified ld (full pathname)],
195 DEFAULT_LINKER="$with_ld")
196 if test x"${DEFAULT_LINKER+set}" = x"set"; then
197   if test ! -x "$DEFAULT_LINKER"; then
198     AC_MSG_ERROR([cannot execute: $DEFAULT_LINKER: check --with-ld or env. var. DEFAULT_LINKER])
199   elif $DEFAULT_LINKER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
200     gnu_ld_flag=yes
201   fi
202   AC_DEFINE_UNQUOTED(DEFAULT_LINKER,"$DEFAULT_LINKER",
203         [Define to enable the use of a default linker.])
204 fi
205
206 gnu_ld=`if test x"$gnu_ld_flag" = x"yes"; then echo 1; else echo 0; fi`
207 AC_DEFINE_UNQUOTED(HAVE_GNU_LD, $gnu_ld, [Define if using GNU ld.])
208
209 AC_MSG_CHECKING([whether a default linker was specified])
210 if test x"${DEFAULT_LINKER+set}" = x"set"; then
211   if test x"$gnu_ld_flag" = x"no"; then
212     AC_MSG_RESULT([yes ($DEFAULT_LINKER)])
213   else
214     AC_MSG_RESULT([yes ($DEFAULT_LINKER - GNU ld)])
215   fi
216 else
217   AC_MSG_RESULT(no)
218 fi
219
220 # With demangler in GNU ld
221 AC_ARG_WITH(demangler-in-ld,
222 [  --with-demangler-in-ld  try to use demangler in GNU ld.],
223 demangler_in_ld="$with_demangler_in_ld",
224 demangler_in_ld=no)
225
226 # ----------------------
227 # Find default assembler
228 # ----------------------
229
230 # With GNU as
231 AC_ARG_WITH(gnu-as,
232 [  --with-gnu-as           arrange to work with GNU as],
233 gas_flag="$with_gnu_as",
234 gas_flag=no)
235
236 AC_ARG_WITH(as,
237 [  --with-as               arrange to use the specified as (full pathname)],
238 DEFAULT_ASSEMBLER="$with_as")
239 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
240   if test ! -x "$DEFAULT_ASSEMBLER"; then
241     AC_MSG_ERROR([cannot execute: $DEFAULT_ASSEMBLER: check --with-as or env. var. DEFAULT_ASSEMBLER])
242   elif $DEFAULT_ASSEMBLER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
243     gas_flag=yes
244   fi
245   AC_DEFINE_UNQUOTED(DEFAULT_ASSEMBLER,"$DEFAULT_ASSEMBLER",
246         [Define to enable the use of a default assembler.])
247 fi
248
249 gnu_as=`if test x"$gas_flag" = x"yes"; then echo 1; else echo 0; fi`
250 AC_DEFINE_UNQUOTED(HAVE_GNU_AS, $gnu_as, [Define if using GNU as.])
251
252 AC_MSG_CHECKING([whether a default assembler was specified])
253 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
254   if test x"$gas_flag" = x"no"; then
255     AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER)])
256   else
257     AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER - GNU as)])
258   fi
259 else
260   AC_MSG_RESULT(no)
261 fi
262
263 # ---------------
264 # Find C compiler
265 # ---------------
266
267 # If a non-executable a.out is present (e.g. created by GNU as above even if
268 # invoked with -v only), the IRIX 6 native ld just overwrites the existing
269 # file, even when creating an executable, so an execution test fails.
270 # Remove possible default executable files to avoid this.
271 #
272 # FIXME: This really belongs into AC_PROG_CC and can be removed once
273 # Autoconf includes it.
274 rm -f a.out a.exe b.out
275
276 # Find the native compiler
277 AC_PROG_CC
278 AM_PROG_CC_C_O
279 AC_PROG_CXX
280 ACX_PROG_GNAT([-I"$srcdir"/ada])
281
282 # autoconf is lame and doesn't give us any substitution variable for this.
283 if eval "test \"`echo '$ac_cv_prog_cc_'${ac_cc}_c_o`\" = no"; then
284   NO_MINUS_C_MINUS_O=yes
285 else
286   OUTPUT_OPTION='-o $@'
287 fi
288 AC_SUBST(NO_MINUS_C_MINUS_O)
289 AC_SUBST(OUTPUT_OPTION)
290
291 # Remove the -O2: for historical reasons, unless bootstrapping we prefer
292 # optimizations to be activated explicitly by the toplevel.
293 case "$CC" in
294   */prev-gcc/xgcc*) ;;
295   *) CFLAGS=`echo $CFLAGS | sed "s/-O[[s0-9]]* *//" ` ;;
296 esac
297 AC_SUBST(CFLAGS)
298
299 # -------------------------
300 # Check C compiler features
301 # -------------------------
302
303 AC_USE_SYSTEM_EXTENSIONS
304 AC_PROG_CPP
305 AC_C_INLINE
306
307 # sizeof(char) is 1 by definition.
308 AC_CHECK_SIZEOF(void *)
309 AC_CHECK_SIZEOF(short)
310 AC_CHECK_SIZEOF(int)
311 AC_CHECK_SIZEOF(long)
312 AC_CHECK_TYPES([long long], [AC_CHECK_SIZEOF(long long)])
313 AC_CHECK_TYPES([__int64], [AC_CHECK_SIZEOF(__int64)])
314 GCC_STDINT_TYPES
315
316 # ---------------------
317 # Warnings and checking
318 # ---------------------
319
320 # Check $CC warning features (if it's GCC).
321 # We want to use -pedantic, but we don't want warnings about
322 # * 'long long'
323 # * variadic macros
324 # * overlong strings
325 # So, we only use -pedantic if we can disable those warnings.
326
327 ACX_PROG_CC_WARNING_OPTS(
328         m4_quote(m4_do([-W -Wall -Wwrite-strings -Wcast-qual])), [loose_warn])
329 ACX_PROG_CC_WARNING_OPTS(
330         m4_quote(m4_do([-Wstrict-prototypes -Wmissing-prototypes])),
331         [c_loose_warn])
332 ACX_PROG_CC_WARNING_OPTS(
333         m4_quote(m4_do([-Wmissing-format-attribute])), [strict_warn])
334 ACX_PROG_CC_WARNING_OPTS(
335         m4_quote(m4_do([-Wold-style-definition -Wc++-compat])), [c_strict_warn])
336 ACX_PROG_CC_WARNING_ALMOST_PEDANTIC(
337         m4_quote(m4_do([-Wno-long-long -Wno-variadic-macros ], 
338                        [-Wno-overlength-strings])), [strict_warn])
339 ACX_PROG_CC_WARNINGS_ARE_ERRORS([manual], [strict_warn])
340
341 # The above macros do nothing if the compiler is not GCC.  However, the
342 # Makefile has more goo to add other flags, so these variables are used
343 # to enable warnings only for GCC.
344 warn_cflags=
345 warn_cxxflags=
346 if test "x$GCC" = "xyes"; then
347   warn_cflags='$(GCC_WARN_CFLAGS)'
348   warn_cxxflags='$(GCC_WARN_CXXFLAGS)'
349 fi
350 AC_SUBST(warn_cflags)
351 AC_SUBST(warn_cxxflags)
352
353 # Enable expensive internal checks
354 is_release=
355 if test x"`cat $srcdir/DEV-PHASE`" != xexperimental; then
356   is_release=yes
357 fi
358
359 AC_ARG_ENABLE(checking,
360 [  --enable-checking[=LIST]
361                           enable expensive run-time checks.  With LIST,
362                           enable only specific categories of checks.
363                           Categories are: yes,no,all,none,release.
364                           Flags are: assert,df,fold,gc,gcac,gimple,misc,
365                           rtlflag,rtl,runtime,tree,valgrind,types.],
366 [ac_checking_flags="${enableval}"],[
367 # Determine the default checks.
368 if test x$is_release = x ; then
369   ac_checking_flags=yes
370 else
371   ac_checking_flags=release
372 fi])
373 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
374 for check in release $ac_checking_flags
375 do
376         case $check in
377         # these set all the flags to specific states
378         yes)            ac_assert_checking=1 ; ac_checking=1 ; ac_df_checking= ;
379                         ac_fold_checking= ; ac_gc_checking=1 ;
380                         ac_gc_always_collect= ; ac_gimple_checking=1 ; ac_rtl_checking= ;
381                         ac_rtlflag_checking=1 ; ac_runtime_checking=1 ;
382                         ac_tree_checking=1 ; ac_valgrind_checking= ;
383                         ac_types_checking=1 ;;
384         no|none)        ac_assert_checking= ; ac_checking= ; ac_df_checking= ;
385                         ac_fold_checking= ; ac_gc_checking= ;
386                         ac_gc_always_collect= ; ac_gimple_checking= ; ac_rtl_checking= ;
387                         ac_rtlflag_checking= ; ac_runtime_checking= ;
388                         ac_tree_checking= ; ac_valgrind_checking= ;
389                         ac_types_checking= ;;
390         all)            ac_assert_checking=1 ; ac_checking=1 ; ac_df_checking=1 ;
391                         ac_fold_checking=1 ; ac_gc_checking=1 ;
392                         ac_gc_always_collect=1 ; ac_gimple_checking=1 ; ac_rtl_checking=1 ;
393                         ac_rtlflag_checking=1 ; ac_runtime_checking=1 ;
394                         ac_tree_checking=1 ; ac_valgrind_checking= ;
395                         ac_types_checking=1 ;;
396         release)        ac_assert_checking=1 ; ac_checking= ; ac_df_checking= ;
397                         ac_fold_checking= ; ac_gc_checking= ;
398                         ac_gc_always_collect= ; ac_gimple_checking= ; ac_rtl_checking= ;
399                         ac_rtlflag_checking= ; ac_runtime_checking=1 ;
400                         ac_tree_checking= ; ac_valgrind_checking= ;
401                         ac_types_checking= ;;
402         # these enable particular checks
403         assert)         ac_assert_checking=1 ;;
404         df)             ac_df_checking=1 ;;
405         fold)           ac_fold_checking=1 ;;
406         gc)             ac_gc_checking=1 ;;
407         gcac)           ac_gc_always_collect=1 ;;
408         gimple)         ac_gimple_checking=1 ;;
409         misc)           ac_checking=1 ;;
410         rtl)            ac_rtl_checking=1 ;;
411         rtlflag)        ac_rtlflag_checking=1 ;;
412         runtime)        ac_runtime_checking=1 ;;
413         tree)           ac_tree_checking=1 ;;
414         types)          ac_types_checking=1 ;;
415         valgrind)       ac_valgrind_checking=1 ;;
416         *)      AC_MSG_ERROR(unknown check category $check) ;;
417         esac
418 done
419 IFS="$ac_save_IFS"
420
421 nocommon_flag=""
422 if test x$ac_checking != x ; then
423   AC_DEFINE(ENABLE_CHECKING, 1,
424 [Define if you want more run-time sanity checks.  This one gets a grab
425    bag of miscellaneous but relatively cheap checks.])
426   nocommon_flag=-fno-common
427 fi
428 AC_SUBST(nocommon_flag)
429 if test x$ac_df_checking != x ; then
430   AC_DEFINE(ENABLE_DF_CHECKING, 1,
431 [Define if you want more run-time sanity checks for dataflow.])
432 fi
433 if test x$ac_assert_checking != x ; then
434   AC_DEFINE(ENABLE_ASSERT_CHECKING, 1,
435 [Define if you want assertions enabled.  This is a cheap check.])
436 fi
437 if test x$ac_gimple_checking != x ; then
438   AC_DEFINE(ENABLE_GIMPLE_CHECKING, 1,
439 [Define if you want operations on GIMPLE (the basic data structure of
440 the high-level optimizers) to be checked for dynamic type safety at
441 runtime.  This is moderately expensive.])
442 fi
443 GCC_TARGET_TEMPLATE(ENABLE_RUNTIME_CHECKING)
444 if test x$ac_runtime_checking != x ; then
445   AC_DEFINE(ENABLE_RUNTIME_CHECKING, 1,
446 [Define if you want runtime assertions enabled.  This is a cheap check.])
447 fi
448 if test x$ac_tree_checking != x ; then
449   AC_DEFINE(ENABLE_TREE_CHECKING, 1,
450 [Define if you want all operations on trees (the basic data
451    structure of the front ends) to be checked for dynamic type safety
452    at runtime.  This is moderately expensive.  The tree browser debugging
453    routines will also be enabled by this option.
454    ])
455   TREEBROWSER=tree-browser.o
456 fi
457 if test x$ac_types_checking != x ; then
458   AC_DEFINE(ENABLE_TYPES_CHECKING, 1,
459 [Define if you want all gimple types to be verified after gimplifiation.
460    This is cheap.
461    ])
462 fi
463 AC_SUBST(TREEBROWSER)
464 if test x$ac_rtl_checking != x ; then
465   AC_DEFINE(ENABLE_RTL_CHECKING, 1,
466 [Define if you want all operations on RTL (the basic data structure
467    of the optimizer and back end) to be checked for dynamic type safety
468    at runtime.  This is quite expensive.])
469 fi
470 if test x$ac_rtlflag_checking != x ; then
471   AC_DEFINE(ENABLE_RTL_FLAG_CHECKING, 1,
472 [Define if you want RTL flag accesses to be checked against the RTL
473    codes that are supported for each access macro.  This is relatively
474    cheap.])
475 fi
476 if test x$ac_gc_checking != x ; then
477   AC_DEFINE(ENABLE_GC_CHECKING, 1,
478 [Define if you want the garbage collector to do object poisoning and
479    other memory allocation checks.  This is quite expensive.])
480 fi
481 if test x$ac_gc_always_collect != x ; then
482   AC_DEFINE(ENABLE_GC_ALWAYS_COLLECT, 1,
483 [Define if you want the garbage collector to operate in maximally
484    paranoid mode, validating the entire heap and collecting garbage at
485    every opportunity.  This is extremely expensive.])
486 fi
487 if test x$ac_fold_checking != x ; then
488   AC_DEFINE(ENABLE_FOLD_CHECKING, 1,
489 [Define if you want fold checked that it never destructs its argument.
490    This is quite expensive.])
491 fi
492 valgrind_path_defines=
493 valgrind_command=
494
495 dnl # This check AC_REQUIREs various stuff, so it *must not* be inside
496 dnl # an if statement.  This was the source of very frustrating bugs
497 dnl # in converting to autoconf 2.5x!
498 AC_CHECK_HEADER(valgrind.h, have_valgrind_h=yes, have_valgrind_h=no)
499
500 if test x$ac_valgrind_checking != x ; then
501   # It is certainly possible that there's valgrind but no valgrind.h.
502   # GCC relies on making annotations so we must have both.
503   AC_MSG_CHECKING(for VALGRIND_DISCARD in <valgrind/memcheck.h>)
504   AC_PREPROC_IFELSE([AC_LANG_SOURCE(
505     [[#include <valgrind/memcheck.h>
506 #ifndef VALGRIND_DISCARD
507 #error VALGRIND_DISCARD not defined
508 #endif]])],
509   [gcc_cv_header_valgrind_memcheck_h=yes],
510   [gcc_cv_header_valgrind_memcheck_h=no])
511   AC_MSG_RESULT($gcc_cv_header_valgrind_memcheck_h)
512   AC_MSG_CHECKING(for VALGRIND_DISCARD in <memcheck.h>)
513   AC_PREPROC_IFELSE([AC_LANG_SOURCE(
514     [[#include <memcheck.h>
515 #ifndef VALGRIND_DISCARD
516 #error VALGRIND_DISCARD not defined
517 #endif]])],
518   [gcc_cv_header_memcheck_h=yes],
519   [gcc_cv_header_memcheck_h=no])
520   AC_MSG_RESULT($gcc_cv_header_memcheck_h)
521   AM_PATH_PROG_WITH_TEST(valgrind_path, valgrind,
522         [$ac_dir/$ac_word --version | grep valgrind- >/dev/null 2>&1])
523   if test "x$valgrind_path" = "x" \
524     || (test $have_valgrind_h = no \
525         && test $gcc_cv_header_memcheck_h = no \
526         && test $gcc_cv_header_valgrind_memcheck_h = no); then
527         AC_MSG_ERROR([*** Can't find both valgrind and valgrind/memcheck.h, memcheck.h or valgrind.h])
528   fi
529   valgrind_path_defines=-DVALGRIND_PATH='\"'$valgrind_path'\"'
530   valgrind_command="$valgrind_path -q"
531   AC_DEFINE(ENABLE_VALGRIND_CHECKING, 1,
532 [Define if you want to run subprograms and generated programs
533    through valgrind (a memory checker).  This is extremely expensive.])
534   if test $gcc_cv_header_valgrind_memcheck_h = yes; then
535     AC_DEFINE(HAVE_VALGRIND_MEMCHECK_H, 1,
536         [Define if valgrind's valgrind/memcheck.h header is installed.])
537   fi
538   if test $gcc_cv_header_memcheck_h = yes; then
539     AC_DEFINE(HAVE_MEMCHECK_H, 1,
540         [Define if valgrind's memcheck.h header is installed.])
541   fi
542 fi
543 AC_SUBST(valgrind_path_defines)
544 AC_SUBST(valgrind_command)
545
546 # Enable code coverage collection
547 AC_ARG_ENABLE(coverage,
548 [  --enable-coverage[=LEVEL]
549                           enable compiler's code coverage collection.
550                           Use to measure compiler performance and locate
551                           unused parts of the compiler. With LEVEL, specify
552                           optimization. Values are opt, noopt,
553                           default is noopt],
554 [case "${enableval}" in
555   yes|noopt)
556     coverage_flags="-fprofile-arcs -ftest-coverage -frandom-seed=\$@ -O0"
557     ;;
558   opt)
559     coverage_flags="-fprofile-arcs -ftest-coverage -frandom-seed=\$@ -O2"
560     ;;
561   no)
562     # a.k.a. --disable-coverage
563     coverage_flags=""
564     ;;
565   *)
566     AC_MSG_ERROR(unknown coverage setting $enableval)
567     ;;
568 esac],
569 [coverage_flags=""])
570 AC_SUBST(coverage_flags)
571
572 AC_ARG_ENABLE(gather-detailed-mem-stats, 
573 [  --enable-gather-detailed-mem-stats         enable detailed memory allocation stats gathering], [],
574 [enable_gather_detailed_mem_stats=no])
575 if test x$enable_gather_detailed_mem_stats = xyes ; then
576   AC_DEFINE(GATHER_STATISTICS, 1,
577         [Define to enable detailed memory allocation stats gathering.])
578 fi
579
580 # -------------------------------
581 # Miscenalleous configure options
582 # -------------------------------
583
584 # See if we are building gcc with C++.
585 AC_ARG_ENABLE(build-with-cxx,
586 [  --enable-build-with-cxx build with C++ compiler instead of C compiler],
587 ENABLE_BUILD_WITH_CXX=$enableval,
588 ENABLE_BUILD_WITH_CXX=no)
589 AC_SUBST(ENABLE_BUILD_WITH_CXX)
590
591 # With stabs
592 AC_ARG_WITH(stabs,
593 [  --with-stabs            arrange to use stabs instead of host debug format],
594 stabs="$with_stabs",
595 stabs=no)
596
597 # Determine whether or not multilibs are enabled.
598 AC_ARG_ENABLE(multilib,
599 [  --enable-multilib       enable library support for multiple ABIs],
600 [], [enable_multilib=yes])
601 AC_SUBST(enable_multilib)
602
603 # Enable __cxa_atexit for C++.
604 AC_ARG_ENABLE(__cxa_atexit,
605 [  --enable-__cxa_atexit   enable __cxa_atexit for C++],
606 [], [])
607
608 # Enable C extension for decimal float if target supports it.
609 GCC_AC_ENABLE_DECIMAL_FLOAT([$target])
610
611 dfp=`if test $enable_decimal_float != no; then echo 1; else echo 0; fi`
612 AC_DEFINE_UNQUOTED(ENABLE_DECIMAL_FLOAT, $dfp,
613 [Define to 1 to enable decimal float extension to C.])
614
615 # Use default_decimal_float for dependency.
616 enable_decimal_float=$default_decimal_float
617
618 bid=`if test $enable_decimal_float = bid; then echo 1; else echo 0; fi`
619 AC_DEFINE_UNQUOTED(ENABLE_DECIMAL_BID_FORMAT, $bid,
620 [Define to 1 to specify that we are using the BID decimal floating
621 point format instead of DPD])
622
623 # Enable C extension for fixed-point arithmetic.
624 AC_ARG_ENABLE(fixed-point,
625 [  --enable-fixed-point    enable fixed-point arithmetic extension to C],
626 [
627 ],
628 [
629   case $target in
630     mips*-*-*)
631       case $host in
632         mips*-sgi-irix*)
633           AC_MSG_WARN([fixed-point is not supported on IRIX, ignored])
634           enable_fixed_point=no
635           ;;
636         *)
637           enable_fixed_point=yes
638           ;;
639       esac
640       ;;
641     *)
642       AC_MSG_WARN([fixed-point is not supported for this target, ignored])
643       enable_fixed_point=no
644       ;;
645   esac
646 ])
647 AC_SUBST(enable_fixed_point)
648
649 fixedpoint=`if test $enable_fixed_point = yes; then echo 1; else echo 0; fi`
650 AC_DEFINE_UNQUOTED(ENABLE_FIXED_POINT, $fixedpoint,
651 [Define to 1 to enable fixed-point arithmetic extension to C.])
652
653 # Enable threads
654 # Pass with no value to take the default
655 # Pass with a value to specify a thread package
656 AC_ARG_ENABLE(threads,
657 [  --enable-threads        enable thread usage for target GCC
658   --enable-threads=LIB    use LIB thread package for target GCC],,
659 [enable_threads=''])
660
661 AC_ARG_ENABLE(tls,
662 [  --enable-tls            enable or disable generation of tls code
663                           overriding the assembler check for tls support],
664 [
665   case $enable_tls in
666     yes | no) ;;
667     *) AC_MSG_ERROR(['$enable_tls' is an invalid value for --enable-tls.
668 Valid choices are 'yes' and 'no'.]) ;;
669   esac
670 ], [enable_tls=''])
671
672 AC_ARG_ENABLE(objc-gc,
673 [  --enable-objc-gc       enable the use of Boehm's garbage collector with
674                           the GNU Objective-C runtime],
675 if test x$enable_objc_gc = xno; then
676         objc_boehm_gc=''
677 else
678         objc_boehm_gc=1
679 fi,
680 objc_boehm_gc='')
681
682 AC_ARG_WITH(dwarf2,
683 [  --with-dwarf2           force the default debug format to be DWARF 2],
684 dwarf2="$with_dwarf2",
685 dwarf2=no)
686
687 AC_ARG_ENABLE(shared,
688 [  --disable-shared        don't provide a shared libgcc],
689 [
690   case $enable_shared in
691   yes | no) ;;
692   *)
693     enable_shared=no
694     IFS="${IFS=         }"; ac_save_ifs="$IFS"; IFS="${IFS}:,"
695     for pkg in $enableval; do
696       if test "X$pkg" = "Xgcc" || test "X$pkg" = "Xlibgcc"; then
697         enable_shared=yes
698       fi
699     done
700     IFS="$ac_save_ifs"
701     ;;
702   esac
703 ], [enable_shared=yes])
704 AC_SUBST(enable_shared)
705
706 AC_ARG_WITH(build-sysroot, 
707   [  --with-build-sysroot=sysroot
708                           use sysroot as the system root during the build])
709
710 AC_ARG_WITH(sysroot,
711 [  --with-sysroot[=DIR] Search for usr/lib, usr/include, et al, within DIR.],
712 [
713  case ${with_sysroot} in
714  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_noncanonical}/sys-root' ;;
715  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
716  esac
717    
718  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
719  CROSS_SYSTEM_HEADER_DIR='$(TARGET_SYSTEM_ROOT)$${sysroot_headers_suffix}$(NATIVE_SYSTEM_HEADER_DIR)'
720         
721  if test "x$prefix" = xNONE; then
722   test_prefix=/usr/local
723  else
724   test_prefix=$prefix
725  fi
726  if test "x$exec_prefix" = xNONE; then
727   test_exec_prefix=$test_prefix
728  else
729   test_exec_prefix=$exec_prefix
730  fi
731  case ${TARGET_SYSTEM_ROOT} in
732  "${test_prefix}"|"${test_prefix}/"*|\
733  "${test_exec_prefix}"|"${test_exec_prefix}/"*|\
734  '${prefix}'|'${prefix}/'*|\
735  '${exec_prefix}'|'${exec_prefix}/'*)
736    t="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE"
737    TARGET_SYSTEM_ROOT_DEFINE="$t"
738    ;;
739  esac
740 ], [
741  TARGET_SYSTEM_ROOT=
742  TARGET_SYSTEM_ROOT_DEFINE=
743  CROSS_SYSTEM_HEADER_DIR='$(gcc_tooldir)/sys-include'
744 ])
745 AC_SUBST(TARGET_SYSTEM_ROOT)
746 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
747 AC_SUBST(CROSS_SYSTEM_HEADER_DIR)
748
749 AC_ARG_WITH(specs,
750   [AS_HELP_STRING([--with-specs=SPECS],
751                   [add SPECS to driver command-line processing])],
752   [CONFIGURE_SPECS=$withval],
753   [CONFIGURE_SPECS=]
754 )
755 AC_SUBST(CONFIGURE_SPECS)
756
757 # Build with intermodule optimisations
758 AC_ARG_ENABLE(intermodule,
759 [  --enable-intermodule    build the compiler in one step],
760 [case ${enable_intermodule} in
761   yes) onestep="-onestep";;
762   *) onestep="";;
763 esac],
764 [onestep=""])
765 AC_SUBST(onestep)
766
767 ACX_PKGVERSION([GCC])
768 ACX_BUGURL([http://gcc.gnu.org/bugs.html])
769
770 # Sanity check enable_languages in case someone does not run the toplevel
771 # configure # script.
772 AC_ARG_ENABLE(languages,
773 [  --enable-languages=LIST specify which front-ends to build],
774 [case ,${enable_languages}, in
775        ,,|,yes,)
776                 # go safe -- we cannot be much sure without the toplevel
777                 # configure's
778                 # analysis of which target libs are present and usable
779                 enable_languages=c
780                 ;;
781          *,all,*)
782                 AC_MSG_ERROR([only the toplevel supports --enable-languages=all])
783                 ;;
784         *,c,*)
785                 ;;
786         *)
787                 enable_languages=c,${enable_languages}
788                 ;;
789 esac],
790 [enable_languages=c])
791
792 AC_ARG_WITH(multilib-list,
793 [  --with-multilib-list    Select multilibs (SH only)],
794 :,
795 with_multilib_list=default)
796
797 # -------------------------
798 # Checks for other programs
799 # -------------------------
800
801 AC_PROG_MAKE_SET
802
803 # Find some useful tools
804 AC_PROG_AWK
805 # We need awk to create options.c and options.h.
806 # Bail out if it's missing.
807 case ${AWK} in
808   "") AC_MSG_ERROR([can't build without awk, bailing out]) ;;
809 esac
810
811 gcc_AC_PROG_LN_S
812 ACX_PROG_LN($LN_S)
813 AC_PROG_RANLIB
814 case "${host}" in
815 *-*-darwin*)
816   # By default, the Darwin ranlib will not treat common symbols as
817   # definitions when  building the archive table of contents.  Other 
818   # ranlibs do that; pass an option to the Darwin ranlib that makes
819   # it behave similarly.
820   ranlib_flags="-c" 
821   ;;
822 *)
823   ranlib_flags=""
824 esac
825 AC_SUBST(ranlib_flags)
826      
827 gcc_AC_PROG_INSTALL
828
829 # See if cmp has --ignore-initial.
830 gcc_AC_PROG_CMP_IGNORE_INITIAL
831
832 # See if we have the mktemp command.
833 AC_CHECK_PROG(have_mktemp_command, mktemp, yes, no)
834
835 # See if makeinfo has been installed and is modern enough
836 # that we can use it.
837 ACX_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
838   [GNU texinfo.* \([0-9][0-9.]*\)],
839   [4.[7-9]*|4.[1-9][0-9]*|[5-9]*|[1-9][0-9]*])
840 if test $gcc_cv_prog_makeinfo_modern = no; then
841   AC_MSG_WARN([
842 *** Makeinfo is missing or too old.
843 *** Info documentation will not be built.])
844   BUILD_INFO=
845 else
846   BUILD_INFO=info
847 fi
848 AC_SUBST(BUILD_INFO)
849
850 # Is pod2man recent enough to regenerate manpages?
851 AC_MSG_CHECKING([for recent Pod::Man])
852 if (perl -e 'use 1.10 Pod::Man') >/dev/null 2>&1; then
853   AC_MSG_RESULT(yes)
854   GENERATED_MANPAGES=generated-manpages
855 else
856   AC_MSG_RESULT(no)
857   GENERATED_MANPAGES=
858 fi
859 AC_SUBST(GENERATED_MANPAGES)
860
861 MISSING="${CONFIG_SHELL-/bin/sh} $ac_aux_dir/missing"
862
863 # How about lex?
864 dnl Don't use AC_PROG_LEX; we insist on flex.
865 dnl LEXLIB is not useful in gcc.
866 AC_CHECK_PROGS([FLEX], flex, [$MISSING flex])
867
868 # Bison?
869 AC_CHECK_PROGS([BISON], bison, [$MISSING bison])
870
871 # Binutils are not build modules, unlike bison/flex/makeinfo.  So we
872 # check for build == host before using them.
873
874 # NM
875 if test x${build} = x${host} && test -f $srcdir/../binutils/nm.c \
876   && test -d ../binutils ; then
877   NM='${objdir}/../binutils/nm-new'
878 else
879   AC_CHECK_PROG(NM, nm, nm, ${CONFIG_SHELL-/bin/sh} ${srcdir}/../missing nm)
880 fi
881
882 # AR
883 if test x${build} = x${host} && test -f $srcdir/../binutils/ar.c \
884   && test -d ../binutils ; then
885   AR='${objdir}/../binutils/ar'
886 else
887   AC_CHECK_PROG(AR, ar, ar, ${CONFIG_SHELL-/bin/sh} ${srcdir}/../missing ar)
888 fi
889
890
891 # --------------------
892 # Checks for C headers
893 # --------------------
894
895 # Need to reject headers which give warnings, so that the -Werror bootstrap
896 # works later. *sigh*  This needs to come before all header checks.
897 AC_PROG_CPP_WERROR
898
899 AC_HEADER_STDC
900 AC_HEADER_TIME
901 ACX_HEADER_STRING
902 AC_HEADER_SYS_WAIT
903 AC_CHECK_HEADERS(limits.h stddef.h string.h strings.h stdlib.h time.h iconv.h \
904                  fcntl.h unistd.h sys/file.h sys/time.h sys/mman.h \
905                  sys/resource.h sys/param.h sys/times.h sys/stat.h \
906                  direct.h malloc.h langinfo.h ldfcn.h locale.h wchar.h)
907
908 # Check for thread headers.
909 AC_CHECK_HEADER(thread.h, [have_thread_h=yes], [have_thread_h=])
910 AC_CHECK_HEADER(pthread.h, [have_pthread_h=yes], [have_pthread_h=])
911
912 # These tests can't be done till we know if we have limits.h.
913 gcc_AC_C_CHAR_BIT
914 AC_C_BIGENDIAN
915
916 # --------
917 # UNSORTED
918 # --------
919
920
921 # These libraries may be used by collect2.
922 # We may need a special search path to get them linked.
923 AC_CACHE_CHECK(for collect2 libraries, gcc_cv_collect2_libs,
924 [save_LIBS="$LIBS"
925 for libs in '' -lld -lmld \
926                 '-L/usr/lib/cmplrs/cc2.11 -lmld' \
927                 '-L/usr/lib/cmplrs/cc3.11 -lmld'
928 do
929         LIBS="$libs"
930         AC_TRY_LINK_FUNC(ldopen,
931                 [gcc_cv_collect2_libs="$libs"; break])
932 done
933 LIBS="$save_LIBS"
934 test -z "$gcc_cv_collect2_libs" && gcc_cv_collect2_libs='none required'])
935 case $gcc_cv_collect2_libs in
936         "none required")        ;;
937         *)      COLLECT2_LIBS=$gcc_cv_collect2_libs ;;
938 esac
939 AC_SUBST(COLLECT2_LIBS)
940
941 # When building Ada code on Alpha, we need exc_resume which is usually in
942 # -lexc.  So test for it.
943 save_LIBS="$LIBS"
944 LIBS=
945 AC_SEARCH_LIBS(exc_resume, exc)
946 GNAT_LIBEXC="$LIBS"
947 LIBS="$save_LIBS"
948 AC_SUBST(GNAT_LIBEXC)
949
950 # Some systems put ldexp and frexp in libm instead of libc; assume
951 # they're both in the same place.  jcf-dump needs them.
952 save_LIBS="$LIBS"
953 LIBS=
954 AC_SEARCH_LIBS(ldexp, m)
955 LDEXP_LIB="$LIBS"
956 LIBS="$save_LIBS"
957 AC_SUBST(LDEXP_LIB)
958
959 # Use <inttypes.h> only if it exists,
960 # doesn't clash with <sys/types.h>, and declares intmax_t.
961 AC_MSG_CHECKING(for inttypes.h)
962 AC_CACHE_VAL(gcc_cv_header_inttypes_h,
963 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
964 [[#include <sys/types.h>
965 #include <inttypes.h>]],
966   [[intmax_t i = -1;]])],
967   [gcc_cv_header_inttypes_h=yes],
968   [gcc_cv_header_inttypes_h=no])])
969 AC_MSG_RESULT($gcc_cv_header_inttypes_h)
970 if test $gcc_cv_header_inttypes_h = yes; then
971   AC_DEFINE(HAVE_INTTYPES_H, 1,
972         [Define if you have a working <inttypes.h> header file.])
973 fi
974
975 dnl Disabled until we have a complete test for buggy enum bitfields.
976 dnl gcc_AC_C_ENUM_BF_UNSIGNED
977
978 define(gcc_UNLOCKED_FUNCS, clearerr_unlocked feof_unlocked dnl
979   ferror_unlocked fflush_unlocked fgetc_unlocked fgets_unlocked dnl
980   fileno_unlocked fprintf_unlocked fputc_unlocked fputs_unlocked dnl
981   fread_unlocked fwrite_unlocked getchar_unlocked getc_unlocked dnl
982   putchar_unlocked putc_unlocked)
983 AC_CHECK_FUNCS(times clock kill getrlimit setrlimit atoll atoq \
984         sysconf strsignal getrusage nl_langinfo \
985         gettimeofday mbstowcs wcswidth mmap mincore setlocale \
986         gcc_UNLOCKED_FUNCS)
987
988 save_CPPFLAGS="$CPPFLAGS"
989 save_LIBS="$LIBS"
990 LIBS="$LIBS $LIBELFLIBS"
991 AC_CHECK_FUNCS(elf_getshdrstrndx,,
992   [AC_CHECK_FUNCS(elf_getshstrndx,
993     [AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdlib.h>
994 #include <libelf.h>
995 int main()
996 {
997   return elf_getshstrndx (NULL, 0) == 0;
998 }]])], AC_DEFINE(HAVE_ELF_GETSHSTRNDX_GABI, 1,
999         [Define if elf_getshstrndx has gABI conformant return values.]))])]
1000   )
1001 LIBS="$save_LIBS"
1002 CPPFLAGS="$save_CPPFLAGS"
1003
1004 if test x$ac_cv_func_mbstowcs = xyes; then
1005   AC_CACHE_CHECK(whether mbstowcs works, gcc_cv_func_mbstowcs_works,
1006 [    AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdlib.h>
1007 int main()
1008 {
1009   mbstowcs(0, "", 0);
1010   return 0;
1011 }]])],
1012     [gcc_cv_func_mbstowcs_works=yes],
1013     [gcc_cv_func_mbstowcs_works=no],
1014     [gcc_cv_func_mbstowcs_works=yes])])
1015   if test x$gcc_cv_func_mbstowcs_works = xyes; then
1016     AC_DEFINE(HAVE_WORKING_MBSTOWCS, 1,
1017   [Define this macro if mbstowcs does not crash when its
1018    first argument is NULL.])
1019   fi
1020 fi
1021
1022 AC_CHECK_TYPE(ssize_t, int)
1023 AC_CHECK_TYPE(caddr_t, char *)
1024
1025 gcc_AC_FUNC_MMAP_BLACKLIST
1026
1027 case "${host}" in
1028 *-*-*vms*)
1029   # Under VMS, vfork works very differently than on Unix. The standard test 
1030   # won't work, and it isn't easily adaptable. It makes more sense to
1031   # just force it.
1032   ac_cv_func_vfork_works=yes
1033   ;;
1034 esac
1035 AC_FUNC_FORK
1036
1037 AM_ICONV
1038 # Until we have in-tree GNU iconv:
1039 LIBICONV_DEP=
1040 AC_SUBST(LIBICONV_DEP)
1041
1042 AM_LC_MESSAGES
1043
1044 AM_LANGINFO_CODESET
1045
1046 # We will need to find libiberty.h and ansidecl.h
1047 saved_CFLAGS="$CFLAGS"
1048 CFLAGS="$CFLAGS -I${srcdir} -I${srcdir}/../include"
1049 gcc_AC_CHECK_DECLS(getenv atol asprintf sbrk abort atof getcwd getwd \
1050         strsignal strstr strverscmp \
1051         errno snprintf vsnprintf vasprintf malloc realloc calloc \
1052         free basename getopt clock getpagesize gcc_UNLOCKED_FUNCS, , ,[
1053 #include "ansidecl.h"
1054 #include "system.h"])
1055
1056 gcc_AC_CHECK_DECLS(getrlimit setrlimit getrusage, , ,[
1057 #include "ansidecl.h"
1058 #include "system.h"
1059 #ifdef HAVE_SYS_RESOURCE_H
1060 #include <sys/resource.h>
1061 #endif
1062 ])
1063
1064 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1065 #include "ansidecl.h"
1066 #include "system.h"
1067 #ifdef HAVE_SYS_RESOURCE_H
1068 #include <sys/resource.h>
1069 #endif
1070 ]], [[rlim_t l = 0;]])],[],[AC_DEFINE([rlim_t],[long],
1071 [Define to `long' if <sys/resource.h> doesn't define.])])
1072
1073 # On AIX 5.2, <ldfcn.h> conflicts with <fcntl.h>, as both define incompatible
1074 # FREAD and FWRITE macros.  Fortunately, for GCC's single usage of ldgetname
1075 # in collect2.c, <fcntl.h> isn't visible, but the configure test below needs
1076 # to undef these macros to get the correct value for HAVE_DECL_LDGETNAME.
1077 gcc_AC_CHECK_DECLS(ldgetname, , ,[
1078 #include "ansidecl.h"
1079 #include "system.h"
1080 #ifdef HAVE_LDFCN_H
1081 #undef FREAD
1082 #undef FWRITE
1083 #include <ldfcn.h>
1084 #endif
1085 ])
1086
1087 gcc_AC_CHECK_DECLS(times, , ,[
1088 #include "ansidecl.h"
1089 #include "system.h"
1090 #ifdef HAVE_SYS_TIMES_H
1091 #include <sys/times.h>
1092 #endif
1093 ])
1094
1095 gcc_AC_CHECK_DECLS(sigaltstack, , ,[
1096 #include "ansidecl.h"
1097 #include "system.h"
1098 #include <signal.h>
1099 ])
1100
1101 # More time-related stuff.
1102 AC_CACHE_CHECK(for struct tms, ac_cv_struct_tms, [
1103 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1104 #include "ansidecl.h"
1105 #include "system.h"
1106 #ifdef HAVE_SYS_TIMES_H
1107 #include <sys/times.h>
1108 #endif
1109 ]], [[struct tms tms;]])],[ac_cv_struct_tms=yes],[ac_cv_struct_tms=no])])
1110 if test $ac_cv_struct_tms = yes; then
1111   AC_DEFINE(HAVE_STRUCT_TMS, 1,
1112   [Define if <sys/times.h> defines struct tms.])
1113 fi
1114
1115 # use gcc_cv_* here because this doesn't match the behavior of AC_CHECK_TYPE.
1116 # revisit after autoconf 2.50.
1117 AC_CACHE_CHECK(for clock_t, gcc_cv_type_clock_t, [
1118 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1119 #include "ansidecl.h"
1120 #include "system.h"
1121 ]], [[clock_t x;]])],[gcc_cv_type_clock_t=yes],[gcc_cv_type_clock_t=no])])
1122 if test $gcc_cv_type_clock_t = yes; then
1123   AC_DEFINE(HAVE_CLOCK_T, 1,
1124   [Define if <time.h> defines clock_t.])
1125 fi
1126
1127 # Restore CFLAGS from before the gcc_AC_NEED_DECLARATIONS tests.
1128 CFLAGS="$saved_CFLAGS"
1129
1130 gcc_AC_INITFINI_ARRAY
1131
1132 # mkdir takes a single argument on some systems. 
1133 gcc_AC_FUNC_MKDIR_TAKES_ONE_ARG
1134
1135 # File extensions
1136 manext='.1'
1137 objext='.o'
1138 AC_SUBST(manext)
1139 AC_SUBST(objext)
1140
1141 # With Setjmp/Longjmp based exception handling.
1142 AC_ARG_ENABLE(sjlj-exceptions,
1143 [  --enable-sjlj-exceptions
1144                           arrange to use setjmp/longjmp exception handling],
1145 [case $target in
1146   *-*-hpux10*)
1147     if test $enableval != yes; then
1148       AC_MSG_WARN([dwarf2 exceptions not supported, sjlj exceptions forced])
1149       enableval=yes
1150     fi
1151     ;;
1152 esac
1153 force_sjlj_exceptions=yes],
1154 [case $target in
1155   *-*-hpux10*)
1156     force_sjlj_exceptions=yes
1157     enableval=yes
1158     ;;
1159   *)
1160     force_sjlj_exceptions=no
1161     ;;
1162 esac])
1163 if test $force_sjlj_exceptions = yes; then
1164   sjlj=`if test $enableval = yes; then echo 1; else echo 0; fi`
1165   AC_DEFINE_UNQUOTED(CONFIG_SJLJ_EXCEPTIONS, $sjlj,
1166     [Define 0/1 to force the choice for exception handling model.])
1167 fi
1168
1169 # For platforms with the unwind ABI which includes an unwind library,
1170 # libunwind, we can choose to use the system libunwind.
1171 # config.gcc also contains tests of with_system_libunwind.
1172 GCC_CHECK_UNWIND_GETIPINFO
1173
1174 # --------------------------------------------------------
1175 # Build, host, and target specific configuration fragments
1176 # --------------------------------------------------------
1177
1178 # Collect build-machine-specific information.
1179 . ${srcdir}/config.build
1180
1181 # Collect host-machine-specific information.
1182 . ${srcdir}/config.host
1183
1184 target_gtfiles=
1185
1186 # Collect target-machine-specific information.
1187 . ${srcdir}/config.gcc
1188
1189 extra_objs="${host_extra_objs} ${extra_objs}"
1190 extra_gcc_objs="${host_extra_gcc_objs} ${extra_gcc_objs}"
1191
1192 # Default the target-machine variables that were not explicitly set.
1193 if test x"$tm_file" = x
1194 then tm_file=$cpu_type/$cpu_type.h; fi
1195
1196 if test x"$extra_headers" = x
1197 then extra_headers=; fi
1198
1199 if test x$md_file = x
1200 then md_file=$cpu_type/$cpu_type.md; fi
1201
1202 if test x$out_file = x
1203 then out_file=$cpu_type/$cpu_type.c; fi
1204
1205 if test x"$tmake_file" = x
1206 then tmake_file=$cpu_type/t-$cpu_type
1207 fi
1208
1209 if test x"$dwarf2" = xyes
1210 then tm_file="$tm_file tm-dwarf2.h"
1211 fi
1212
1213 # Say what files are being used for the output code and MD file.
1214 echo "Using \`$srcdir/config/$out_file' for machine-specific logic."
1215 echo "Using \`$srcdir/config/$md_file' as machine description file."
1216
1217 # If any of the xm_file variables contain nonexistent files, warn
1218 # about them and drop them.
1219
1220 bx=
1221 for x in $build_xm_file; do
1222   if    test -f $srcdir/config/$x
1223   then      bx="$bx $x"
1224   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1225   fi
1226 done
1227 build_xm_file="$bx"
1228
1229 hx=
1230 for x in $host_xm_file; do
1231   if    test -f $srcdir/config/$x
1232   then      hx="$hx $x"
1233   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1234   fi
1235 done
1236 host_xm_file="$hx"
1237
1238 tx=
1239 for x in $xm_file; do
1240   if    test -f $srcdir/config/$x
1241   then      tx="$tx $x"
1242   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1243   fi
1244 done
1245 xm_file="$tx"
1246
1247 count=a
1248 for f in $tm_file; do
1249         count=${count}x
1250 done
1251 if test $count = ax; then
1252         echo "Using \`$srcdir/config/$tm_file' as target machine macro file."
1253 else
1254         echo "Using the following target machine macro files:"
1255         for f in $tm_file; do
1256                 echo "  $srcdir/config/$f"
1257         done
1258 fi
1259
1260 if test x$need_64bit_hwint = xyes; then
1261         AC_DEFINE(NEED_64BIT_HOST_WIDE_INT, 1,
1262 [Define to 1 if HOST_WIDE_INT must be 64 bits wide (see hwint.h).])
1263 fi
1264
1265 if test x$use_long_long_for_widest_fast_int = xyes; then
1266         AC_DEFINE(USE_LONG_LONG_FOR_WIDEST_FAST_INT, 1,
1267 [Define to 1 if the 'long long' (or '__int64') is wider than 'long' but still
1268 efficiently supported by the host hardware.])
1269 fi
1270
1271 count=a
1272 for f in $host_xm_file; do
1273         count=${count}x
1274 done
1275 if test $count = a; then
1276         :
1277 elif test $count = ax; then
1278         echo "Using \`$srcdir/config/$host_xm_file' as host machine macro file."
1279 else
1280         echo "Using the following host machine macro files:"
1281         for f in $host_xm_file; do
1282                 echo "  $srcdir/config/$f"
1283         done
1284 fi
1285 echo "Using ${out_host_hook_obj} for host machine hooks."
1286
1287 if test "$host_xm_file" != "$build_xm_file"; then
1288         count=a
1289         for f in $build_xm_file; do
1290                 count=${count}x
1291         done
1292         if test $count = a; then
1293                 :
1294         elif test $count = ax; then
1295                 echo "Using \`$srcdir/config/$build_xm_file' as build machine macro file."
1296         else
1297                 echo "Using the following build machine macro files:"
1298                 for f in $build_xm_file; do
1299                         echo "  $srcdir/config/$f"
1300                 done
1301         fi
1302 fi
1303
1304 case ${host} in
1305   powerpc*-*-darwin*)
1306     AC_CACHE_CHECK([whether mcontext_t fields have underscores],
1307       gcc_cv_mcontext_underscores,
1308       AC_COMPILE_IFELSE([
1309 #include <sys/cdefs.h>
1310 #include <sys/signal.h>
1311 #include <ucontext.h>
1312 int main() { mcontext_t m; if (m->ss.srr0) return 0; return 0; }
1313 ],
1314         gcc_cv_mcontext_underscores=no, gcc_cv_mcontext_underscores=yes))
1315       if test $gcc_cv_mcontext_underscores = yes; then
1316         AC_DEFINE(HAS_MCONTEXT_T_UNDERSCORES,,dnl
1317           [mcontext_t fields start with __])
1318       fi
1319     ;;
1320 esac
1321
1322 # ---------
1323 # Threading
1324 # ---------
1325
1326 # Check if a valid thread package
1327 case ${enable_threads} in
1328   "" | no)
1329     # No threads
1330     target_thread_file='single'
1331     ;;
1332   yes)
1333     # default
1334     target_thread_file='single'
1335     ;;
1336   aix | dce | gnat | irix | posix | posix95 | rtems | \
1337   single | solaris | vxworks | win32 | mipssde)
1338     target_thread_file=${enable_threads}
1339     ;;
1340   *)
1341     echo "${enable_threads} is an unknown thread package" 1>&2
1342     exit 1
1343     ;;
1344 esac
1345
1346 if test x${thread_file} = x; then
1347   # No thread file set by target-specific clauses in config.gcc,
1348   # so use file chosen by default logic above
1349   thread_file=${target_thread_file}
1350 fi
1351
1352 # Make gthr-default.h if we have a thread file.
1353 gthread_flags=
1354 if test $thread_file != single; then
1355   echo "#include \"gthr-${thread_file}.h\"" > gthr-default.h-t
1356   if diff gthr-default.h-t gthr-default.h 2>/dev/null; then
1357     rm -f gthr-default.h-t
1358   else
1359     mv -f gthr-default.h-t gthr-default.h
1360   fi
1361   gthread_flags=-DHAVE_GTHR_DEFAULT
1362 fi
1363 AC_SUBST(gthread_flags)
1364
1365 # --------
1366 # UNSORTED
1367 # --------
1368
1369 use_cxa_atexit=no
1370 if test x$enable___cxa_atexit = xyes || \
1371    test x$enable___cxa_atexit = x -a x$default_use_cxa_atexit = xyes; then
1372   if test x$host = x$target; then
1373     case $host in
1374       # mingw32 doesn't have __cxa_atexit but uses atexit registration
1375       # keyed to flag_use_cxa_atexit
1376       *-*-mingw32*)
1377         use_cxa_atexit=yes
1378         ;;
1379       *)
1380         AC_CHECK_FUNC(__cxa_atexit,[use_cxa_atexit=yes],
1381           [echo "__cxa_atexit can't be enabled on this target"])
1382         ;;
1383     esac
1384   else
1385     # We can't check for __cxa_atexit when building a cross, so assume
1386     # it is available 
1387     use_cxa_atexit=yes
1388   fi
1389   if test x$use_cxa_atexit = xyes; then
1390     AC_DEFINE(DEFAULT_USE_CXA_ATEXIT, 2,
1391       [Define if you want to use __cxa_atexit, rather than atexit, to
1392       register C++ destructors for local statics and global objects.
1393       This is essential for fully standards-compliant handling of
1394       destructors, but requires __cxa_atexit in libc.])
1395   fi
1396 fi
1397
1398 # Look for a file containing extra machine modes.
1399 if test -n "$extra_modes" && test -f $srcdir/config/$extra_modes; then
1400   extra_modes_file='$(srcdir)'/config/${extra_modes}
1401   AC_SUBST(extra_modes_file)
1402   AC_DEFINE_UNQUOTED(EXTRA_MODES_FILE, "config/$extra_modes",
1403   [Define to the name of a file containing a list of extra machine modes
1404    for this architecture.])
1405 fi
1406
1407 # Convert extra_options into a form suitable for Makefile use.
1408 extra_opt_files=
1409 for f in $extra_options; do
1410   extra_opt_files="$extra_opt_files \$(srcdir)/config/$f"
1411 done
1412 AC_SUBST(extra_opt_files)
1413
1414 # auto-host.h is the file containing items generated by autoconf and is
1415 # the first file included by config.h.
1416 # If host=build, it is correct to have bconfig include auto-host.h
1417 # as well.  If host!=build, we are in error and need to do more 
1418 # work to find out the build config parameters.
1419 if test x$host = x$build
1420 then
1421         build_auto=auto-host.h
1422 else
1423         # We create a subdir, then run autoconf in the subdir.
1424         # To prevent recursion we set host and build for the new
1425         # invocation of configure to the build for this invocation
1426         # of configure. 
1427         tempdir=build.$$
1428         rm -rf $tempdir
1429         mkdir $tempdir
1430         cd $tempdir
1431         case ${srcdir} in
1432         /* | [A-Za-z]:[\\/]* ) realsrcdir=${srcdir};;
1433         *) realsrcdir=../${srcdir};;
1434         esac
1435         saved_CFLAGS="${CFLAGS}"
1436         CC="${CC_FOR_BUILD}" CFLAGS="${CFLAGS_FOR_BUILD}" \
1437         LDFLAGS="${LDFLAGS_FOR_BUILD}" \
1438         ${realsrcdir}/configure \
1439                 --enable-languages=${enable_languages-all} \
1440                 --target=$target_alias --host=$build_alias --build=$build_alias
1441         CFLAGS="${saved_CFLAGS}"
1442
1443         # We just finished tests for the build machine, so rename
1444         # the file auto-build.h in the gcc directory.
1445         mv auto-host.h ../auto-build.h
1446         cd ..
1447         rm -rf $tempdir
1448         build_auto=auto-build.h
1449 fi
1450 AC_SUBST(build_subdir)
1451
1452 tm_file="${tm_file} defaults.h"
1453 tm_p_file="${tm_p_file} tm-preds.h"
1454 host_xm_file="auto-host.h ansidecl.h ${host_xm_file}"
1455 build_xm_file="${build_auto} ansidecl.h ${build_xm_file}"
1456 # We don't want ansidecl.h in target files, write code there in ISO/GNU C.
1457 # put this back in temporarily.
1458 xm_file="auto-host.h ansidecl.h ${xm_file}"
1459
1460 # --------
1461 # UNSORTED
1462 # --------
1463
1464 changequote(,)dnl
1465 # Compile in configure arguments.
1466 if test -f configargs.h ; then
1467         # Being re-configured.
1468         gcc_config_arguments=`grep configuration_arguments configargs.h | sed -e 's/.*"\([^"]*\)".*/\1/'`
1469         gcc_config_arguments="$gcc_config_arguments : (reconfigured) $TOPLEVEL_CONFIGURE_ARGUMENTS"
1470 else
1471         gcc_config_arguments="$TOPLEVEL_CONFIGURE_ARGUMENTS"
1472 fi
1473
1474 # Double all backslashes and backslash all quotes to turn
1475 # gcc_config_arguments into a C string.
1476 sed -e 's/\\/\\\\/g; s/"/\\"/g' <<EOF >conftest.out
1477 $gcc_config_arguments
1478 EOF
1479 gcc_config_arguments_str=`cat conftest.out`
1480 rm -f conftest.out
1481
1482 cat > configargs.h <<EOF
1483 /* Generated automatically. */
1484 static const char configuration_arguments[] = "$gcc_config_arguments_str";
1485 static const char thread_model[] = "$thread_file";
1486
1487 static const struct {
1488   const char *name, *value;
1489 } configure_default_options[] = $configure_default_options;
1490 EOF
1491 changequote([,])dnl
1492
1493 changequote(,)dnl
1494 gcc_BASEVER=`cat $srcdir/BASE-VER`
1495 gcc_DEVPHASE=`cat $srcdir/DEV-PHASE`
1496 gcc_DATESTAMP=`cat $srcdir/DATESTAMP`
1497 if test -f $srcdir/REVISION ; then
1498         gcc_REVISION=`cat $srcdir/REVISION`
1499 else
1500         gcc_REVISION=""
1501 fi
1502 cat > plugin-version.h <<EOF
1503 #include "configargs.h"
1504
1505 static char basever[] = "$gcc_BASEVER";
1506 static char datestamp[] = "$gcc_DATESTAMP";
1507 static char devphase[] = "$gcc_DEVPHASE";
1508 static char revision[] = "$gcc_REVISION";
1509
1510 /* FIXME plugins: We should make the version information more precise.
1511    One way to do is to add a checksum. */
1512
1513 static struct plugin_gcc_version gcc_version = {basever, datestamp,
1514                                                 devphase, revision,
1515                                                 configuration_arguments};
1516 EOF
1517 changequote([,])dnl
1518
1519 # Internationalization
1520 ZW_GNU_GETTEXT_SISTER_DIR
1521
1522 # If LIBINTL contains LIBICONV, then clear LIBICONV so we don't get
1523 # -liconv on the link line twice.
1524 case "$LIBINTL" in *$LIBICONV*)
1525         LIBICONV= ;;
1526 esac
1527
1528 AC_ARG_ENABLE(secureplt,
1529 [  --enable-secureplt      enable -msecure-plt by default for PowerPC],
1530 [], [])
1531
1532 AC_ARG_ENABLE(leading-mingw64-underscores,
1533   AS_HELP_STRING([--enable-leading-mingw64-underscores],
1534                  [Enable leading underscores on 64 bit mingw targets]),
1535   [],[])
1536 AS_IF([ test x"$enable_leading_mingw64_underscores" = xyes ],
1537   [AC_DEFINE(USE_MINGW64_LEADING_UNDERSCORES, 1,
1538     [Define if we should use leading underscore on 64 bit mingw targets])])
1539
1540 AC_ARG_ENABLE(cld,
1541 [  --enable-cld            enable -mcld by default for 32bit x86], [],
1542 [enable_cld=no])
1543
1544 AC_ARG_ENABLE(frame-pointer,
1545 [  --enable-frame-pointer  enable -fno-omit-frame-pointer by default for 32bit x86], [],
1546 [
1547 case $target_os in
1548 linux* | darwin[[8912]]*)
1549   # Enable -fomit-frame-pointer by default for Linux and Darwin with
1550   # DWARF2.
1551   enable_frame_pointer=no
1552   ;;
1553 *)
1554   enable_frame_pointer=yes
1555   ;;
1556 esac
1557 ])
1558
1559 # Windows32 Registry support for specifying GCC installation paths.
1560 AC_ARG_ENABLE(win32-registry,
1561 [  --disable-win32-registry
1562                           disable lookup of installation paths in the
1563                           Registry on Windows hosts
1564   --enable-win32-registry enable registry lookup (default)
1565   --enable-win32-registry=KEY
1566                           use KEY instead of GCC version as the last portion
1567                           of the registry key],,)
1568
1569 case $host_os in
1570   win32 | pe | cygwin* | mingw32* | uwin*)
1571     if test "x$enable_win32_registry" != xno; then
1572       AC_SEARCH_LIBS(RegOpenKeyExA, advapi32,, [enable_win32_registry=no])
1573     fi
1574
1575     if test "x$enable_win32_registry" != xno; then
1576       AC_DEFINE(ENABLE_WIN32_REGISTRY, 1,
1577   [Define to 1 if installation paths should be looked up in the Windows
1578    Registry. Ignored on non-Windows hosts.])
1579
1580       if test "x$enable_win32_registry" != xyes \
1581          && test "x$enable_win32_registry" != x; then
1582         AC_DEFINE_UNQUOTED(WIN32_REGISTRY_KEY, "$enable_win32_registry",
1583   [Define to be the last component of the Windows registry key under which
1584    to look for installation paths.  The full key used will be 
1585    HKEY_LOCAL_MACHINE/SOFTWARE/Free Software Foundation/{WIN32_REGISTRY_KEY}.
1586    The default is the GCC version number.])
1587       fi
1588     fi
1589   ;;
1590 esac
1591
1592 # Get an absolute path to the GCC top-level source directory
1593 holddir=`${PWDCMD-pwd}`
1594 cd $srcdir
1595 topdir=`${PWDCMD-pwd}`
1596 cd $holddir
1597
1598 # Conditionalize the makefile for this host machine.
1599 xmake_file=
1600 for f in ${host_xmake_file}
1601 do
1602         if test -f ${srcdir}/config/$f
1603         then
1604                 xmake_file="${xmake_file} \$(srcdir)/config/$f"
1605         fi
1606 done
1607
1608 # Conditionalize the makefile for this target machine.
1609 tmake_file_=
1610 for f in ${tmake_file}
1611 do
1612         if test -f ${srcdir}/config/$f
1613         then
1614                 tmake_file_="${tmake_file_} \$(srcdir)/config/$f"
1615         fi
1616 done
1617 tmake_file="${tmake_file_}"
1618
1619 out_object_file=`basename $out_file .c`.o
1620
1621 tm_file_list="options.h"
1622 tm_include_list="options.h insn-constants.h"
1623 for f in $tm_file; do
1624   case $f in
1625     ./* )
1626        f=`echo $f | sed 's/^..//'`
1627        tm_file_list="${tm_file_list} $f"
1628        tm_include_list="${tm_include_list} $f"
1629        ;;
1630     defaults.h )
1631        tm_file_list="${tm_file_list} \$(srcdir)/$f"
1632        tm_include_list="${tm_include_list} $f"
1633        ;;
1634     * )
1635        tm_file_list="${tm_file_list} \$(srcdir)/config/$f"
1636        tm_include_list="${tm_include_list} config/$f"
1637        ;;
1638   esac
1639 done
1640
1641 tm_p_file_list=
1642 tm_p_include_list=
1643 for f in $tm_p_file; do
1644   case $f in
1645     tm-preds.h )
1646        tm_p_file_list="${tm_p_file_list} $f"
1647        tm_p_include_list="${tm_p_include_list} $f"
1648        ;;
1649     * )
1650        tm_p_file_list="${tm_p_file_list} \$(srcdir)/config/$f"
1651        tm_p_include_list="${tm_p_include_list} config/$f"
1652   esac
1653 done
1654
1655 xm_file_list=
1656 xm_include_list=
1657 for f in $xm_file; do
1658   case $f in
1659     ansidecl.h )
1660        xm_file_list="${xm_file_list} \$(srcdir)/../include/$f"
1661        xm_include_list="${xm_include_list} $f"
1662        ;;
1663     auto-host.h )
1664        xm_file_list="${xm_file_list} $f"
1665        xm_include_list="${xm_include_list} $f"
1666        ;;
1667     * )
1668        xm_file_list="${xm_file_list} \$(srcdir)/config/$f"
1669        xm_include_list="${xm_include_list} config/$f"
1670        ;;
1671   esac
1672 done
1673
1674 host_xm_file_list=
1675 host_xm_include_list=
1676 for f in $host_xm_file; do
1677   case $f in
1678     ansidecl.h )
1679        host_xm_file_list="${host_xm_file_list} \$(srcdir)/../include/$f"
1680        host_xm_include_list="${host_xm_include_list} $f"
1681        ;;
1682     auto-host.h )
1683        host_xm_file_list="${host_xm_file_list} $f"
1684        host_xm_include_list="${host_xm_include_list} $f"
1685        ;;
1686     * )
1687        host_xm_file_list="${host_xm_file_list} \$(srcdir)/config/$f"
1688        host_xm_include_list="${host_xm_include_list} config/$f"
1689        ;;
1690   esac
1691 done
1692
1693 build_xm_file_list=
1694 for f in $build_xm_file; do
1695   case $f in
1696     ansidecl.h )
1697        build_xm_file_list="${build_xm_file_list} \$(srcdir)/../include/$f"
1698        build_xm_include_list="${build_xm_include_list} $f"
1699        ;;
1700     auto-build.h | auto-host.h )
1701        build_xm_file_list="${build_xm_file_list} $f"
1702        build_xm_include_list="${build_xm_include_list} $f"
1703        ;;
1704     * )
1705        build_xm_file_list="${build_xm_file_list} \$(srcdir)/config/$f"
1706        build_xm_include_list="${build_xm_include_list} config/$f"
1707        ;;
1708   esac
1709 done
1710
1711 # Define macro CROSS_DIRECTORY_STRUCTURE in compilation if this is a
1712 # cross-compiler which does not use the native headers and libraries.
1713 # Also use all.cross instead of all.internal and adjust SYSTEM_HEADER_DIR.
1714 CROSS=                                          AC_SUBST(CROSS)
1715 ALL=all.internal                                AC_SUBST(ALL)
1716 SYSTEM_HEADER_DIR='$(NATIVE_SYSTEM_HEADER_DIR)' AC_SUBST(SYSTEM_HEADER_DIR)
1717
1718 if test "x$with_build_sysroot" != x; then
1719   build_system_header_dir=$with_build_sysroot'$${sysroot_headers_suffix}$(NATIVE_SYSTEM_HEADER_DIR)'
1720 else
1721   # This value is used, even on a native system, because 
1722   # CROSS_SYSTEM_HEADER_DIR is just 
1723   # $(TARGET_SYSTEM_ROOT)$(NATIVE_SYSTEM_HEADER_DIR).
1724   build_system_header_dir='$(CROSS_SYSTEM_HEADER_DIR)'
1725 fi
1726
1727 if test x$host != x$target
1728 then
1729         CROSS="-DCROSS_DIRECTORY_STRUCTURE"
1730         ALL=all.cross
1731         SYSTEM_HEADER_DIR=$build_system_header_dir
1732         case "$host","$target" in
1733         # Darwin crosses can use the host system's libraries and headers,
1734         # because of the fat library support.  Of course, it must be the
1735         # same version of Darwin on both sides.  Allow the user to
1736         # just say --target=foo-darwin without a version number to mean
1737         # "the version on this system".
1738             *-*-darwin*,*-*-darwin*)
1739                 hostos=`echo $host | sed 's/.*-darwin/darwin/'`
1740                 targetos=`echo $target | sed 's/.*-darwin/darwin/'`
1741                 if test $hostos = $targetos -o $targetos = darwin ; then
1742                     CROSS=
1743                     SYSTEM_HEADER_DIR='$(NATIVE_SYSTEM_HEADER_DIR)'
1744                     with_headers=yes
1745                 fi
1746                 ;;
1747
1748             i?86-*-*,x86_64-*-* \
1749             | powerpc*-*-*,powerpc64*-*-*)
1750                 CROSS="$CROSS -DNATIVE_CROSS" ;;
1751         esac
1752 elif test "x$TARGET_SYSTEM_ROOT" != x; then
1753         SYSTEM_HEADER_DIR=$build_system_header_dir 
1754 fi
1755
1756 # If this is a cross-compiler that does not
1757 # have its own set of headers then define
1758 # inhibit_libc
1759
1760 # If this is using newlib, without having the headers available now,
1761 # then define inhibit_libc in LIBGCC2_CFLAGS.
1762 # This prevents libgcc2 from containing any code which requires libc
1763 # support.
1764 : ${inhibit_libc=false}
1765 if { { test x$host != x$target && test "x$with_sysroot" = x ; } ||
1766        test x$with_newlib = xyes ; } &&
1767      { test "x$with_headers" = x || test "x$with_headers" = xno ; } ; then
1768        inhibit_libc=true
1769 fi
1770 AC_SUBST(inhibit_libc)
1771
1772 # When building gcc with a cross-compiler, we need to adjust things so
1773 # that the generator programs are still built with the native compiler.
1774 # Also, we cannot run fixincludes.
1775
1776 # These are the normal (build=host) settings:
1777 CC_FOR_BUILD='$(CC)'            AC_SUBST(CC_FOR_BUILD)
1778 BUILD_CFLAGS='$(ALL_CFLAGS)'    AC_SUBST(BUILD_CFLAGS)
1779 BUILD_LDFLAGS='$(LDFLAGS)'      AC_SUBST(BUILD_LDFLAGS)
1780 STMP_FIXINC=stmp-fixinc         AC_SUBST(STMP_FIXINC)
1781
1782 # And these apply if build != host, or we are generating coverage data
1783 if test x$build != x$host || test "x$coverage_flags" != x
1784 then
1785     BUILD_CFLAGS='$(INTERNAL_CFLAGS) $(T_CFLAGS) $(CFLAGS_FOR_BUILD)'
1786     BUILD_LDFLAGS='$(LDFLAGS_FOR_BUILD)'
1787 fi
1788
1789 # Expand extra_headers to include complete path.
1790 # This substitutes for lots of t-* files.
1791 extra_headers_list=
1792 # Prepend $(srcdir)/config/${cpu_type}/ to every entry in extra_headers.
1793 for file in ${extra_headers} ; do
1794   extra_headers_list="${extra_headers_list} \$(srcdir)/config/${cpu_type}/${file}"
1795 done
1796
1797 # If use_gcc_tgmath is set, append ginclude/tgmath.h.
1798 if test x"$use_gcc_tgmath" = xyes
1799 then extra_headers_list="${extra_headers_list} \$(srcdir)/ginclude/tgmath.h"
1800 fi
1801
1802 # Define collect2 in Makefile.
1803 case $host_can_use_collect2 in
1804   no) collect2= ;;
1805   *) collect2='collect2$(exeext)' ;;
1806 esac
1807 AC_SUBST([collect2])
1808
1809 # Add a definition of USE_COLLECT2 if system wants one.
1810 case $use_collect2 in
1811   no) use_collect2= ;;
1812   "") ;;
1813   *) 
1814     host_xm_defines="${host_xm_defines} USE_COLLECT2"
1815     xm_defines="${xm_defines} USE_COLLECT2"
1816     case $host_can_use_collect2 in
1817       no)
1818         AC_MSG_ERROR([collect2 is required but cannot be built on this system])
1819         ;;
1820     esac
1821     ;;
1822 esac
1823
1824 # ---------------------------
1825 # Assembler & linker features
1826 # ---------------------------
1827
1828 # During stage 2, ld is actually gcc/collect-ld, which is a small script to
1829 # discern between when to use prev-ld/ld-new and when to use ld/ld-new.
1830 # However when ld-new is first executed from the build tree, libtool will
1831 # relink it as .libs/lt-ld-new, so that it can give it an RPATH that refers
1832 # to the build tree.  While doing this we need to use the previous-stage
1833 # linker, or we have an infinite loop.  The presence of a shell script as
1834 # ld/ld-new, and the fact that the script *uses ld itself*, is what confuses
1835 # the gcc/collect-ld script.  So we need to know how libtool works, or
1836 # exec-tool will fail.
1837
1838 m4_defun([_LT_CONFIG_COMMANDS], [])
1839 AC_PROG_LIBTOOL
1840 AC_SUBST(objdir)
1841 AC_SUBST(enable_fast_install)
1842
1843 # Identify the assembler which will work hand-in-glove with the newly
1844 # built GCC, so that we can examine its features.  This is the assembler
1845 # which will be driven by the driver program.
1846 #
1847 # If build != host, and we aren't building gas in-tree, we identify a
1848 # build->target assembler and hope that it will have the same features
1849 # as the host->target assembler we'll be using.
1850 gcc_cv_gas_major_version=
1851 gcc_cv_gas_minor_version=
1852 gcc_cv_as_gas_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/gas
1853
1854 m4_pattern_allow([AS_FOR_TARGET])dnl
1855 AS_VAR_SET_IF(gcc_cv_as,, [
1856 if test -x "$DEFAULT_ASSEMBLER"; then
1857         gcc_cv_as="$DEFAULT_ASSEMBLER"
1858 elif test -f $gcc_cv_as_gas_srcdir/configure.in \
1859      && test -f ../gas/Makefile \
1860      && test x$build = x$host; then
1861         gcc_cv_as=../gas/as-new$build_exeext
1862 elif test -x as$build_exeext; then
1863         # Build using assembler in the current directory.
1864         gcc_cv_as=./as$build_exeext
1865 elif test -x $AS_FOR_TARGET; then
1866         gcc_cv_as="$AS_FOR_TARGET"
1867 else
1868         AC_PATH_PROG(gcc_cv_as, $AS_FOR_TARGET)
1869 fi])
1870
1871 ORIGINAL_AS_FOR_TARGET=$gcc_cv_as
1872 AC_SUBST(ORIGINAL_AS_FOR_TARGET)
1873 case "$ORIGINAL_AS_FOR_TARGET" in
1874   ./as | ./as$build_exeext) ;;
1875   *) AC_CONFIG_FILES(as:exec-tool.in, [chmod +x as]) ;;
1876 esac 
1877
1878 AC_MSG_CHECKING(what assembler to use)
1879 if test "$gcc_cv_as" = ../gas/as-new$build_exeext; then
1880   # Single tree build which includes gas.  We want to prefer it
1881   # over whatever linker top-level may have detected, since
1882   # we'll use what we're building after installation anyway.
1883   AC_MSG_RESULT(newly built gas)
1884   in_tree_gas=yes
1885   _gcc_COMPUTE_GAS_VERSION
1886   in_tree_gas_is_elf=no
1887   if grep 'obj_format = elf' ../gas/Makefile > /dev/null \
1888      || (grep 'obj_format = multi' ../gas/Makefile \
1889          && grep 'extra_objects =.* obj-elf' ../gas/Makefile) > /dev/null
1890   then
1891     in_tree_gas_is_elf=yes
1892   fi
1893 else
1894   AC_MSG_RESULT($gcc_cv_as)
1895   in_tree_gas=no
1896 fi
1897
1898 # Identify the linker which will work hand-in-glove with the newly
1899 # built GCC, so that we can examine its features.  This is the linker
1900 # which will be driven by the driver program.
1901 #
1902 # If build != host, and we aren't building gas in-tree, we identify a
1903 # build->target linker and hope that it will have the same features
1904 # as the host->target linker we'll be using.
1905 gcc_cv_gld_major_version=
1906 gcc_cv_gld_minor_version=
1907 gcc_cv_ld_gld_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/ld
1908 gcc_cv_ld_bfd_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/bfd
1909
1910 AS_VAR_SET_IF(gcc_cv_ld,, [
1911 if test -x "$DEFAULT_LINKER"; then
1912         gcc_cv_ld="$DEFAULT_LINKER"
1913 elif test -f $gcc_cv_ld_gld_srcdir/configure.in \
1914      && test -f ../ld/Makefile \
1915      && test x$build = x$host; then
1916         gcc_cv_ld=../ld/ld-new$build_exeext
1917 elif test -x collect-ld$build_exeext; then
1918         # Build using linker in the current directory.
1919         gcc_cv_ld=./collect-ld$build_exeext
1920 elif test -x $LD_FOR_TARGET; then
1921         gcc_cv_ld="$LD_FOR_TARGET"
1922 else
1923         AC_PATH_PROG(gcc_cv_ld, $LD_FOR_TARGET)
1924 fi])
1925
1926 ORIGINAL_PLUGIN_LD_FOR_TARGET=$gcc_cv_ld
1927 PLUGIN_LD=`basename $gcc_cv_ld`
1928 AC_ARG_WITH(plugin-ld,
1929 [  --with-plugin-ld=[[ARG]]  specify the plugin linker],
1930 [if test x"$withval" != x; then
1931    ORIGINAL_PLUGIN_LD_FOR_TARGET="$withval"
1932    PLUGIN_LD="$withval"
1933  fi])
1934 AC_SUBST(ORIGINAL_PLUGIN_LD_FOR_TARGET)
1935 AC_DEFINE_UNQUOTED(PLUGIN_LD, "$PLUGIN_LD", [Specify plugin linker])
1936
1937 # Check to see if we are using gold instead of ld
1938 AC_MSG_CHECKING(whether we are using gold)
1939 ld_is_gold=no
1940 if test x$gcc_cv_ld != x; then
1941   if $gcc_cv_ld --version 2>/dev/null | sed 1q \
1942      | grep "GNU gold" > /dev/null; then
1943     ld_is_gold=yes
1944   fi
1945 fi
1946 AC_MSG_RESULT($ld_is_gold)
1947
1948 ORIGINAL_LD_FOR_TARGET=$gcc_cv_ld
1949 AC_SUBST(ORIGINAL_LD_FOR_TARGET)
1950 case "$ORIGINAL_LD_FOR_TARGET" in
1951   ./collect-ld | ./collect-ld$build_exeext) ;;
1952   *) AC_CONFIG_FILES(collect-ld:exec-tool.in, [chmod +x collect-ld]) ;;
1953 esac 
1954
1955 AC_MSG_CHECKING(what linker to use)
1956 if test "$gcc_cv_ld" = ../ld/ld-new$build_exeext; then
1957         # Single tree build which includes ld.  We want to prefer it
1958         # over whatever linker top-level may have detected, since
1959         # we'll use what we're building after installation anyway.
1960         AC_MSG_RESULT(newly built ld)
1961         in_tree_ld=yes
1962         in_tree_ld_is_elf=no
1963         if (grep 'EMUL = .*elf' ../ld/Makefile \
1964             || grep 'EMUL = .*linux' ../ld/Makefile \
1965             || grep 'EMUL = .*lynx' ../ld/Makefile) > /dev/null; then
1966           in_tree_ld_is_elf=yes
1967         fi
1968         for f in $gcc_cv_ld_bfd_srcdir/configure $gcc_cv_ld_gld_srcdir/configure $gcc_cv_ld_gld_srcdir/configure.in $gcc_cv_ld_gld_srcdir/Makefile.in
1969         do
1970 changequote(,)dnl
1971                 gcc_cv_gld_version=`sed -n -e 's/^[     ]*\(VERSION=[0-9]*\.[0-9]*.*\)/\1/p' < $f`
1972                 if test x$gcc_cv_gld_version != x; then
1973                         break
1974                 fi
1975         done
1976         gcc_cv_gld_major_version=`expr "$gcc_cv_gld_version" : "VERSION=\([0-9]*\)"`
1977         gcc_cv_gld_minor_version=`expr "$gcc_cv_gld_version" : "VERSION=[0-9]*\.\([0-9]*\)"`
1978 changequote([,])dnl
1979 else
1980         AC_MSG_RESULT($gcc_cv_ld)
1981         in_tree_ld=no
1982 fi
1983
1984 # Figure out what nm we will be using.
1985 gcc_cv_binutils_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/binutils
1986 AS_VAR_SET_IF(gcc_cv_nm,, [
1987 if test -f $gcc_cv_binutils_srcdir/configure.in \
1988      && test -f ../binutils/Makefile \
1989      && test x$build = x$host; then
1990         gcc_cv_nm=../binutils/nm-new$build_exeext
1991 elif test -x nm$build_exeext; then
1992         gcc_cv_nm=./nm$build_exeext
1993 elif test -x $NM_FOR_TARGET; then
1994         gcc_cv_nm="$NM_FOR_TARGET"
1995 else
1996         AC_PATH_PROG(gcc_cv_nm, $NM_FOR_TARGET)
1997 fi])
1998
1999 AC_MSG_CHECKING(what nm to use)
2000 if test "$gcc_cv_nm" = ../binutils/nm-new$build_exeext; then
2001         # Single tree build which includes binutils.
2002         AC_MSG_RESULT(newly built nm)
2003         in_tree_nm=yes
2004 else
2005         AC_MSG_RESULT($gcc_cv_nm)
2006         in_tree_nm=no
2007 fi
2008
2009 ORIGINAL_NM_FOR_TARGET=$gcc_cv_nm
2010 AC_SUBST(ORIGINAL_NM_FOR_TARGET)
2011 case "$ORIGINAL_NM_FOR_TARGET" in
2012   ./nm | ./nm$build_exeext) ;;
2013   *) AC_CONFIG_FILES(nm:exec-tool.in, [chmod +x nm]) ;;
2014 esac
2015
2016
2017 # Figure out what objdump we will be using.
2018 AS_VAR_SET_IF(gcc_cv_objdump,, [
2019 if test -f $gcc_cv_binutils_srcdir/configure.in \
2020      && test -f ../binutils/Makefile \
2021      && test x$build = x$host; then
2022         # Single tree build which includes binutils.
2023         gcc_cv_objdump=../binutils/objdump$build_exeext
2024 elif test -x objdump$build_exeext; then
2025         gcc_cv_objdump=./objdump$build_exeext
2026 elif test -x $OBJDUMP_FOR_TARGET; then
2027         gcc_cv_objdump="$OBJDUMP_FOR_TARGET"
2028 else
2029         AC_PATH_PROG(gcc_cv_objdump, $OBJDUMP_FOR_TARGET)
2030 fi])
2031
2032 AC_MSG_CHECKING(what objdump to use)
2033 if test "$gcc_cv_objdump" = ../binutils/objdump$build_exeext; then
2034         # Single tree build which includes binutils.
2035         AC_MSG_RESULT(newly built objdump)
2036 elif test x$gcc_cv_objdump = x; then
2037         AC_MSG_RESULT(not found)
2038 else
2039         AC_MSG_RESULT($gcc_cv_objdump)
2040 fi
2041
2042 # Figure out what readelf we will be using.
2043 AS_VAR_SET_IF(gcc_cv_readelf,, [
2044 if test -f $gcc_cv_binutils_srcdir/configure.in \
2045      && test -f ../binutils/Makefile \
2046      && test x$build = x$host; then
2047         # Single tree build which includes binutils.
2048         gcc_cv_readelf=../binutils/readelf$build_exeext
2049 elif test -x readelf$build_exeext; then
2050         gcc_cv_readelf=./readelf$build_exeext
2051 else
2052         AC_PATH_PROG(gcc_cv_readelf, readelf)
2053 fi])
2054
2055 AC_MSG_CHECKING(what readelf to use)
2056 if test "$gcc_cv_readelf" = ../binutils/readelf$build_exeext; then
2057         # Single tree build which includes binutils.
2058         AC_MSG_RESULT(newly built readelf)
2059 elif test x$gcc_cv_readelf = x; then
2060         AC_MSG_RESULT(not found)
2061 else
2062         AC_MSG_RESULT($gcc_cv_readelf)
2063 fi
2064
2065 # Figure out what assembler alignment features are present.
2066 gcc_GAS_CHECK_FEATURE([.balign and .p2align], gcc_cv_as_balign_and_p2align,
2067  [2,6,0],,
2068 [.balign 4
2069 .p2align 2],,
2070 [AC_DEFINE(HAVE_GAS_BALIGN_AND_P2ALIGN, 1,
2071   [Define if your assembler supports .balign and .p2align.])])
2072
2073 gcc_GAS_CHECK_FEATURE([.p2align with maximum skip], gcc_cv_as_max_skip_p2align,
2074  [2,8,0],,
2075  [.p2align 4,,7],,
2076 [AC_DEFINE(HAVE_GAS_MAX_SKIP_P2ALIGN, 1,
2077   [Define if your assembler supports specifying the maximum number
2078    of bytes to skip when using the GAS .p2align command.])])
2079
2080 gcc_GAS_CHECK_FEATURE([.literal16], gcc_cv_as_literal16,
2081  [2,8,0],,
2082  [.literal16],,
2083 [AC_DEFINE(HAVE_GAS_LITERAL16, 1,
2084   [Define if your assembler supports .literal16.])])
2085
2086 gcc_GAS_CHECK_FEATURE([working .subsection -1], gcc_cv_as_subsection_m1,
2087  [elf,2,9,0],,
2088  [conftest_label1: .word 0
2089 .subsection -1
2090 conftest_label2: .word 0
2091 .previous],
2092  [if test x$gcc_cv_nm != x; then
2093     $gcc_cv_nm conftest.o | grep conftest_label1 > conftest.nm1
2094     $gcc_cv_nm conftest.o | grep conftest_label2 | sed -e 's/label2/label1/' > conftest.nm2
2095     if cmp conftest.nm1 conftest.nm2 > /dev/null 2>&1
2096     then :
2097     else gcc_cv_as_subsection_m1=yes
2098     fi
2099     rm -f conftest.nm1 conftest.nm2
2100   fi],
2101  [AC_DEFINE(HAVE_GAS_SUBSECTION_ORDERING, 1,
2102   [Define if your assembler supports .subsection and .subsection -1 starts
2103    emitting at the beginning of your section.])])
2104
2105 gcc_GAS_CHECK_FEATURE([.weak], gcc_cv_as_weak,
2106  [2,2,0],,
2107  [      .weak foobar],,
2108 [AC_DEFINE(HAVE_GAS_WEAK, 1, [Define if your assembler supports .weak.])])
2109
2110 gcc_GAS_CHECK_FEATURE([.weakref], gcc_cv_as_weakref,
2111  [2,17,0],,
2112  [      .weakref foobar, barfnot],,
2113 [AC_DEFINE(HAVE_GAS_WEAKREF, 1, [Define if your assembler supports .weakref.])])
2114
2115 gcc_GAS_CHECK_FEATURE([.nsubspa comdat], gcc_cv_as_nsubspa_comdat,
2116  [2,15,91],,
2117  [      .SPACE $TEXT$
2118         .NSUBSPA $CODE$,COMDAT],,
2119 [AC_DEFINE(HAVE_GAS_NSUBSPA_COMDAT, 1, [Define if your assembler supports .nsubspa comdat option.])])
2120
2121 # .hidden needs to be supported in both the assembler and the linker,
2122 # because GNU LD versions before 2.12.1 have buggy support for STV_HIDDEN.
2123 # This is irritatingly difficult to feature test for; we have to check the
2124 # date string after the version number.  If we've got an in-tree
2125 # ld, we don't know its patchlevel version, so we set the baseline at 2.13
2126 # to be safe.
2127 # The gcc_GAS_CHECK_FEATURE call just sets a cache variable.
2128 gcc_GAS_CHECK_FEATURE([.hidden], gcc_cv_as_hidden,
2129  [elf,2,13,0],,
2130 [       .hidden foobar
2131 foobar:],[
2132 # Solaris 9/x86 as incorrectly emits an alias for a hidden symbol with
2133 # STV_HIDDEN, so disable .hidden support if so.
2134 case "${target}" in
2135   i?86-*-solaris2*)
2136     if test x$gcc_cv_as != x && test x$gcc_cv_objdump != x; then
2137       cat > conftest.s <<EOF
2138 .globl hidden
2139         .hidden hidden
2140 hidden:
2141 .globl default
2142         .set    default,hidden
2143 EOF
2144       if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1 \
2145         && $gcc_cv_objdump -t conftest.o 2>/dev/null | \
2146         grep '\.hidden default' > /dev/null; then
2147         gcc_cv_as_hidden=no
2148       else
2149         gcc_cv_as_hidden=yes
2150       fi
2151     else
2152       # Assume bug is present if objdump is missing.
2153       gcc_cv_as_hidden=no
2154     fi
2155     ;;
2156   *)
2157     gcc_cv_as_hidden=yes
2158     ;;
2159 esac])
2160
2161 changequote(,)dnl
2162 if test $in_tree_ld != yes ; then
2163   ld_ver=`$gcc_cv_ld --version 2>/dev/null | sed 1q`
2164   if test x"$ld_is_gold" = xyes; then
2165     gcc_cv_ld_hidden=yes
2166   elif echo "$ld_ver" | grep GNU > /dev/null; then
2167     ld_vers=`echo $ld_ver | sed -n \
2168         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*.*\)$,\1,p'`
2169     ld_date=`echo $ld_ver | sed -n 's,^.*\([2-9][0-9][0-9][0-9]\)[-]*\([01][0-9]\)[-]*\([0-3][0-9]\).*$,\1\2\3,p'`
2170     ld_vers_major=`expr "$ld_vers" : '\([0-9]*\)'`
2171     ld_vers_minor=`expr "$ld_vers" : '[0-9]*\.\([0-9]*\)'`
2172     ld_vers_patch=`expr "$ld_vers" : '[0-9]*\.[0-9]*\.\([0-9]*\)'`
2173   else
2174     case "${target}" in
2175       *-*-solaris2*)
2176         #
2177         # Solaris 2 ld -V output looks like this for a regular version:
2178         #
2179         # ld: Software Generation Utilities - Solaris Link Editors: 5.11-1.1699
2180         #
2181         # but test versions add stuff at the end:
2182         #
2183         # ld: Software Generation Utilities - Solaris Link Editors: 5.11-1.1701:onnv-ab196087-6931056-03/25/10
2184         #
2185         ld_ver=`$gcc_cv_ld -V 2>&1`
2186         if echo "$ld_ver" | grep 'Solaris Link Editors' > /dev/null; then
2187           ld_vers=`echo $ld_ver | sed -n \
2188             -e 's,^.*: 5\.[0-9][0-9]*-\([0-9]\.[0-9][0-9]*\).*$,\1,p'`
2189           ld_vers_major=`expr "$ld_vers" : '\([0-9]*\)'`
2190           ld_vers_minor=`expr "$ld_vers" : '[0-9]*\.\([0-9]*\)'`
2191         fi
2192         ;;
2193     esac
2194   fi
2195 fi
2196 changequote([,])dnl
2197
2198 AC_CACHE_CHECK(linker for .hidden support, gcc_cv_ld_hidden,
2199 [[if test $in_tree_ld = yes ; then
2200   gcc_cv_ld_hidden=no
2201   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 13 -o "$gcc_cv_gld_major_version" -gt 2 \
2202      && test $in_tree_ld_is_elf = yes; then
2203      gcc_cv_ld_hidden=yes
2204   fi
2205 else
2206   gcc_cv_ld_hidden=yes
2207   if echo "$ld_ver" | grep GNU > /dev/null; then
2208     if test 0"$ld_date" -lt 20020404; then
2209       if test -n "$ld_date"; then
2210         # If there was date string, but was earlier than 2002-04-04, fail
2211         gcc_cv_ld_hidden=no
2212       elif test -z "$ld_vers"; then
2213         # If there was no date string nor ld version number, something is wrong
2214         gcc_cv_ld_hidden=no
2215       else
2216         test -z "$ld_vers_patch" && ld_vers_patch=0
2217         if test "$ld_vers_major" -lt 2; then
2218           gcc_cv_ld_hidden=no
2219         elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -lt 12; then
2220           gcc_cv_ld_hidden="no"
2221         elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -eq 12 -a "$ld_vers_patch" -eq 0; then
2222           gcc_cv_ld_hidden=no
2223         fi
2224       fi
2225     fi
2226   else
2227     case "${target}" in
2228       hppa64*-*-hpux* | ia64*-*-hpux*)
2229         gcc_cv_ld_hidden=yes
2230         ;;
2231       *-*-solaris2.9* | *-*-solaris2.1[0-9]*)
2232         # Support for .hidden in Sun ld appeared in Solaris 9 FCS, but
2233         # .symbolic was only added in Solaris 9 12/02.
2234         gcc_cv_ld_hidden=yes
2235         ;;
2236       *)
2237         gcc_cv_ld_hidden=no
2238         ;;
2239     esac
2240   fi
2241 fi]])
2242 libgcc_visibility=no
2243 AC_SUBST(libgcc_visibility)
2244 GCC_TARGET_TEMPLATE([HAVE_GAS_HIDDEN])
2245 if test $gcc_cv_as_hidden = yes && test $gcc_cv_ld_hidden = yes; then
2246   libgcc_visibility=yes
2247   AC_DEFINE(HAVE_GAS_HIDDEN, 1,
2248   [Define if your assembler and linker support .hidden.])
2249 fi
2250
2251 AC_MSG_CHECKING(linker read-only and read-write section mixing)
2252 gcc_cv_ld_ro_rw_mix=unknown
2253 if test $in_tree_ld = yes ; then
2254   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 10 -o "$gcc_cv_gld_major_version" -gt 2 \
2255      && test $in_tree_ld_is_elf = yes; then
2256     gcc_cv_ld_ro_rw_mix=read-write
2257   fi
2258 elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x -a x$gcc_cv_objdump != x ; then
2259   echo '.section myfoosect, "a"' > conftest1.s
2260   echo '.section myfoosect, "aw"' > conftest2.s
2261   echo '.byte 1' >> conftest2.s
2262   echo '.section myfoosect, "a"' > conftest3.s
2263   echo '.byte 0' >> conftest3.s
2264   if $gcc_cv_as -o conftest1.o conftest1.s > /dev/null 2>&1 \
2265      && $gcc_cv_as -o conftest2.o conftest2.s > /dev/null 2>&1 \
2266      && $gcc_cv_as -o conftest3.o conftest3.s > /dev/null 2>&1 \
2267      && $gcc_cv_ld -shared -o conftest1.so conftest1.o \
2268         conftest2.o conftest3.o > /dev/null 2>&1; then
2269     gcc_cv_ld_ro_rw_mix=`$gcc_cv_objdump -h conftest1.so \
2270                          | sed -e '/myfoosect/!d' -e N`
2271     if echo "$gcc_cv_ld_ro_rw_mix" | grep CONTENTS > /dev/null; then
2272       if echo "$gcc_cv_ld_ro_rw_mix" | grep READONLY > /dev/null; then
2273         gcc_cv_ld_ro_rw_mix=read-only
2274       else
2275         gcc_cv_ld_ro_rw_mix=read-write
2276       fi
2277     fi
2278   fi
2279 changequote(,)dnl
2280   rm -f conftest.* conftest[123].*
2281 changequote([,])dnl
2282 fi
2283 if test x$gcc_cv_ld_ro_rw_mix = xread-write; then
2284         AC_DEFINE(HAVE_LD_RO_RW_SECTION_MIXING, 1,
2285   [Define if your linker links a mix of read-only
2286    and read-write sections into a read-write section.])
2287 fi
2288 AC_MSG_RESULT($gcc_cv_ld_ro_rw_mix)
2289
2290 # Check if we have .[us]leb128, and support symbol arithmetic with it.
2291 gcc_GAS_CHECK_FEATURE([.sleb128 and .uleb128], gcc_cv_as_leb128,
2292   [elf,2,11,0],,
2293 [       .data
2294         .uleb128 L2 - L1
2295 L1:
2296         .uleb128 1280
2297         .sleb128 -1010
2298 L2:],
2299 [[# GAS versions before 2.11 do not support uleb128,
2300   # despite appearing to.
2301   # ??? There exists an elf-specific test that will crash
2302   # the assembler.  Perhaps it's better to figure out whether
2303   # arbitrary sections are supported and try the test.
2304   as_ver=`$gcc_cv_as --version 2>/dev/null | sed 1q`
2305   if echo "$as_ver" | grep GNU > /dev/null; then
2306     as_vers=`echo $as_ver | sed -n \
2307         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*.*\)$,\1,p'`
2308     as_major=`expr "$as_vers" : '\([0-9]*\)'`
2309     as_minor=`expr "$as_vers" : '[0-9]*\.\([0-9]*\)'`
2310     if test $as_major -eq 2 && test $as_minor -lt 11
2311     then :
2312     else gcc_cv_as_leb128=yes
2313     fi
2314   fi]],
2315   [AC_DEFINE(HAVE_AS_LEB128, 1,
2316     [Define if your assembler supports .sleb128 and .uleb128.])])
2317
2318 # Check if we have assembler support for unwind directives.
2319 gcc_GAS_CHECK_FEATURE([cfi directives], gcc_cv_as_cfi_directive,
2320   ,,
2321 [       .text
2322         .cfi_startproc
2323         .cfi_offset 0, 0
2324         .cfi_same_value 1
2325         .cfi_def_cfa 1, 2
2326         .cfi_escape 1, 2, 3, 4, 5
2327         .cfi_endproc],
2328 [case "$target" in
2329   *-*-solaris*)
2330     # If the linker used on Solaris (like Sun ld) isn't capable of merging
2331     # read-only and read-write sections, we need to make sure that the
2332     # assembler used emits read-write .eh_frame sections.
2333     if test "x$gcc_cv_ld_ro_rw_mix" != xread-write; then
2334       if test "x$gcc_cv_objdump" != x; then
2335         if $gcc_cv_objdump -h conftest.o 2>/dev/null | \
2336                 sed -e /.eh_frame/!d -e N | grep READONLY > /dev/null; then
2337           gcc_cv_as_cfi_directive=no
2338         else
2339           case "$target" in
2340             i?86-*-solaris2.1[[0-9]]*)
2341               # On Solaris/x86, make sure that GCC and gas agree on using
2342               # read-only .eh_frame sections for 64-bit.
2343               if $gcc_cv_as --64 -o conftest.o conftest.s > /dev/null 2>&1 && \
2344                 $gcc_cv_objdump -h conftest.o 2>/dev/null | \
2345                         sed -e /.eh_frame/!d -e N | \
2346                         grep READONLY > /dev/null; then
2347                 gcc_cv_as_cfi_directive=yes
2348               else
2349                 gcc_cv_as_cfi_directive=no
2350               fi
2351               ;;
2352             *)
2353               gcc_cv_as_cfi_directive=yes
2354               ;;
2355           esac 
2356         fi
2357       else
2358         # no objdump, err on the side of caution
2359         gcc_cv_as_cfi_directive=no
2360       fi
2361     else
2362       gcc_cv_as_cfi_directive=yes
2363     fi
2364     ;;
2365   *-*-*)
2366     gcc_cv_as_cfi_directive=yes
2367     ;;
2368 esac])
2369 if test $gcc_cv_as_cfi_directive = yes && test x$gcc_cv_objdump != x; then
2370 gcc_GAS_CHECK_FEATURE([working cfi advance], gcc_cv_as_cfi_advance_working,
2371   ,,
2372 [       .text
2373         .cfi_startproc
2374         .cfi_adjust_cfa_offset 64
2375         .skip 75040, 0
2376         .cfi_adjust_cfa_offset 128
2377         .cfi_endproc],
2378 [[
2379 if $gcc_cv_objdump -Wf conftest.o 2>/dev/null \
2380     | grep 'DW_CFA_advance_loc[24]:[    ][      ]*75040[        ]' >/dev/null; then
2381    gcc_cv_as_cfi_advance_working=yes
2382 fi
2383 ]])
2384 else
2385   # no objdump, err on the side of caution
2386   gcc_cv_as_cfi_advance_working=no
2387 fi
2388 AC_DEFINE_UNQUOTED(HAVE_GAS_CFI_DIRECTIVE,
2389   [`if test $gcc_cv_as_cfi_directive = yes \
2390        && test $gcc_cv_as_cfi_advance_working = yes; then echo 1; else echo 0; fi`],
2391   [Define 0/1 if your assembler supports CFI directives.])
2392
2393 gcc_GAS_CHECK_FEATURE([cfi personality directive],
2394   gcc_cv_as_cfi_personality_directive, ,,
2395 [       .text
2396         .cfi_startproc
2397         .cfi_personality 0, symbol
2398         .cfi_endproc])
2399 AC_DEFINE_UNQUOTED(HAVE_GAS_CFI_PERSONALITY_DIRECTIVE,
2400   [`if test $gcc_cv_as_cfi_personality_directive = yes;
2401     then echo 1; else echo 0; fi`],
2402   [Define 0/1 if your assembler supports .cfi_personality.])
2403
2404 gcc_GAS_CHECK_FEATURE([cfi sections directive],
2405   gcc_cv_as_cfi_sections_directive, ,,
2406 [       .text
2407         .cfi_sections .debug_frame, .eh_frame
2408         .cfi_startproc
2409         .cfi_endproc],
2410 [case $target_os in
2411   win32 | pe | cygwin* | mingw32* | uwin*)
2412     # Need to check that we generated the correct relocation for the
2413     # .debug_frame section.  This was fixed for binutils 2.21.
2414     gcc_cv_as_cfi_sections_directive=no
2415     if test "x$gcc_cv_objdump" != x; then
2416      if $gcc_cv_objdump -j .debug_frame -r conftest.o 2>/dev/null | \
2417         grep secrel > /dev/null; then
2418       gcc_cv_as_cfi_sections_directive=yes
2419      fi
2420     fi
2421     ;;
2422   *)
2423     gcc_cv_as_cfi_sections_directive=yes
2424     ;;
2425 esac])
2426 AC_DEFINE_UNQUOTED(HAVE_GAS_CFI_SECTIONS_DIRECTIVE,
2427   [`if test $gcc_cv_as_cfi_sections_directive = yes;
2428     then echo 1; else echo 0; fi`],
2429   [Define 0/1 if your assembler supports .cfi_sections.])
2430
2431 # GAS versions up to and including 2.11.0 may mis-optimize
2432 # .eh_frame data.
2433 gcc_GAS_CHECK_FEATURE(eh_frame optimization, gcc_cv_as_eh_frame,
2434   [elf,2,12,0],,
2435 [       .text
2436 .LFB1:
2437         .4byte  0
2438 .L1:
2439         .4byte  0
2440 .LFE1:
2441         .section        .eh_frame,"aw",@progbits
2442 __FRAME_BEGIN__:
2443         .4byte  .LECIE1-.LSCIE1
2444 .LSCIE1:
2445         .4byte  0x0
2446         .byte   0x1
2447         .ascii "z\0"
2448         .byte   0x1
2449         .byte   0x78
2450         .byte   0x1a
2451         .byte   0x0
2452         .byte   0x4
2453         .4byte  1
2454         .p2align 1
2455 .LECIE1:
2456 .LSFDE1:
2457         .4byte  .LEFDE1-.LASFDE1
2458 .LASFDE1:
2459         .4byte  .LASFDE1-__FRAME_BEGIN__
2460         .4byte  .LFB1
2461         .4byte  .LFE1-.LFB1
2462         .byte   0x4
2463         .4byte  .LFE1-.LFB1
2464         .byte   0x4
2465         .4byte  .L1-.LFB1
2466 .LEFDE1:],
2467 [  dnl # For autoconf 2.5x, must protect trailing spaces with @&t@.
2468 cat > conftest.lit <<EOF
2469  0000 10000000 00000000 017a0001 781a0004  .........z..x...
2470  0010 01000000 12000000 18000000 00000000  ................
2471  0020 08000000 04080000 0044               .........D      @&t@
2472 EOF
2473 cat > conftest.big <<EOF
2474  0000 00000010 00000000 017a0001 781a0004  .........z..x...
2475  0010 00000001 00000012 00000018 00000000  ................
2476  0020 00000008 04000000 0844               .........D      @&t@
2477 EOF
2478   # If the assembler didn't choke, and we can objdump,
2479   # and we got the correct data, then succeed.
2480   # The text in the here-document typically retains its unix-style line
2481   # endings, while the output of objdump will use host line endings.
2482   # Therefore, use diff -b for the comparisons.
2483   if test x$gcc_cv_objdump != x \
2484   && $gcc_cv_objdump -s -j .eh_frame conftest.o 2>/dev/null \
2485      | tail -3 > conftest.got \
2486   && { diff -b conftest.lit conftest.got > /dev/null 2>&1 \
2487     || diff -b conftest.big conftest.got > /dev/null 2>&1; }
2488   then
2489     gcc_cv_as_eh_frame=yes
2490   elif AC_TRY_COMMAND($gcc_cv_as -o conftest.o --traditional-format /dev/null); then
2491     gcc_cv_as_eh_frame=buggy
2492   else
2493     # Uh oh, what do we do now?
2494     gcc_cv_as_eh_frame=no
2495   fi])
2496
2497 if test $gcc_cv_as_eh_frame = buggy; then
2498   AC_DEFINE(USE_AS_TRADITIONAL_FORMAT, 1,
2499   [Define if your assembler mis-optimizes .eh_frame data.])
2500 fi
2501
2502 gcc_GAS_CHECK_FEATURE(section merging support, gcc_cv_as_shf_merge,
2503  [elf,2,12,0], [--fatal-warnings],
2504  [.section .rodata.str, "aMS", @progbits, 1])
2505 if test $gcc_cv_as_shf_merge = no; then
2506   gcc_GAS_CHECK_FEATURE(section merging support, gcc_cv_as_shf_merge,
2507     [elf,2,12,0], [--fatal-warnings],
2508     [.section .rodata.str, "aMS", %progbits, 1])
2509 fi
2510 AC_DEFINE_UNQUOTED(HAVE_GAS_SHF_MERGE,
2511   [`if test $gcc_cv_as_shf_merge = yes; then echo 1; else echo 0; fi`],
2512 [Define 0/1 if your assembler supports marking sections with SHF_MERGE flag.])
2513
2514 gcc_GAS_CHECK_FEATURE(COMDAT group support, gcc_cv_as_comdat_group,
2515  [elf,2,16,0], [--fatal-warnings],
2516  [.section .text,"axG",@progbits,.foo,comdat])
2517 if test $gcc_cv_as_comdat_group = yes; then
2518   gcc_cv_as_comdat_group_percent=no
2519 else
2520  gcc_GAS_CHECK_FEATURE(COMDAT group support, gcc_cv_as_comdat_group_percent,
2521    [elf,2,16,0], [--fatal-warnings],
2522    [.section .text,"axG",%progbits,.foo,comdat])
2523 fi
2524 if test x"$ld_is_gold" = xyes; then
2525   comdat_group=yes
2526 elif test $in_tree_ld = yes ; then
2527   comdat_group=no
2528   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2 \
2529      && test $in_tree_ld_is_elf = yes; then
2530      comdat_group=yes
2531   fi
2532 elif echo "$ld_ver" | grep GNU > /dev/null; then
2533   comdat_group=yes
2534   if test 0"$ld_date" -lt 20050308; then
2535     if test -n "$ld_date"; then
2536       # If there was date string, but was earlier than 2005-03-08, fail
2537       comdat_group=no
2538     elif test "$ld_vers_major" -lt 2; then
2539       comdat_group=no
2540     elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -lt 16; then
2541       comdat_group=no
2542     fi
2543   fi
2544 else
2545 changequote(,)dnl
2546   case "${target}" in
2547     *-*-solaris2.1[1-9]*)
2548       # Sun ld has COMDAT group support since Solaris 9, but it doesn't
2549       # interoperate with GNU as until Solaris 11 build 130, i.e. ld
2550       # version 1.688.
2551       #
2552       # FIXME: Maybe need to refine later when COMDAT group support with
2553       # Sun as is implemented.
2554       if test "$ld_vers_major" -gt 1 || test "$ld_vers_minor" -ge 1688; then
2555         comdat_group=yes
2556       else
2557         comdat_group=no
2558       fi
2559       ;;
2560     *)
2561       # Assume linkers other than GNU ld don't support COMDAT group.
2562       comdat_group=no
2563       ;;
2564   esac
2565 changequote([,])dnl
2566 fi
2567 # Allow overriding the automatic COMDAT group tests above.
2568 AC_ARG_ENABLE(comdat,
2569   [AS_HELP_STRING([--enable-comdat], [enable COMDAT group support])],
2570   [comdat_group="$enable_comdat"])
2571 if test $comdat_group = no; then
2572   gcc_cv_as_comdat_group=no
2573   gcc_cv_as_comdat_group_percent=no
2574 fi
2575 AC_DEFINE_UNQUOTED(HAVE_COMDAT_GROUP,
2576   [`if test $gcc_cv_as_comdat_group = yes || test $gcc_cv_as_comdat_group_percent = yes; then echo 1; else echo 0; fi`],
2577 [Define 0/1 if your assembler and linker support COMDAT groups.])
2578
2579 gcc_GAS_CHECK_FEATURE([line table discriminator support],
2580  gcc_cv_as_discriminator,
2581  [2,19,51],,
2582 [       .text
2583         .file 1 "conf.c"
2584         .loc 1 1 0 discriminator 1],,
2585 [AC_DEFINE(HAVE_GAS_DISCRIMINATOR, 1,
2586   [Define if your assembler supports the .loc discriminator sub-directive.])])
2587
2588 # Thread-local storage - the check is heavily parameterized.
2589 conftest_s=
2590 tls_first_major=
2591 tls_first_minor=
2592 tls_as_opt=
2593 case "$target" in
2594 changequote(,)dnl
2595   alpha*-*-*)
2596     conftest_s='
2597         .section ".tdata","awT",@progbits
2598 foo:    .long   25
2599         .text
2600         ldq     $27,__tls_get_addr($29)         !literal!1
2601         lda     $16,foo($29)                    !tlsgd!1
2602         jsr     $26,($27),__tls_get_addr        !lituse_tlsgd!1
2603         ldq     $27,__tls_get_addr($29)         !literal!2
2604         lda     $16,foo($29)                    !tlsldm!2
2605         jsr     $26,($27),__tls_get_addr        !lituse_tlsldm!2
2606         ldq     $1,foo($29)                     !gotdtprel
2607         ldah    $2,foo($29)                     !dtprelhi
2608         lda     $3,foo($2)                      !dtprello
2609         lda     $4,foo($29)                     !dtprel
2610         ldq     $1,foo($29)                     !gottprel
2611         ldah    $2,foo($29)                     !tprelhi
2612         lda     $3,foo($2)                      !tprello
2613         lda     $4,foo($29)                     !tprel'
2614         tls_first_major=2
2615         tls_first_minor=13
2616         tls_as_opt=--fatal-warnings
2617         ;;
2618   cris-*-*|crisv32-*-*)
2619     conftest_s='
2620         .section ".tdata","awT",@progbits
2621 x:      .long   25
2622         .text
2623         move.d x:IE,$r10
2624         nop'
2625         tls_first_major=2
2626         tls_first_minor=20
2627         tls_as_opt=--fatal-warnings
2628         ;;
2629   frv*-*-*)
2630     conftest_s='
2631         .section ".tdata","awT",@progbits
2632 x:      .long   25
2633         .text
2634         call    #gettlsoff(x)'
2635         tls_first_major=2
2636         tls_first_minor=14
2637         ;;
2638   hppa*-*-linux*)
2639     conftest_s='
2640 t1:     .reg    %r20
2641 t2:     .reg    %r21
2642 gp:     .reg    %r19
2643         .section ".tdata","awT",@progbits
2644 foo:    .long   25
2645         .text
2646         .align  4
2647         addil LT%foo-$tls_gdidx$,gp
2648         ldo RT%foo-$tls_gdidx$(%r1),%arg0
2649         b __tls_get_addr
2650         nop             
2651         addil LT%foo-$tls_ldidx$,gp
2652         b __tls_get_addr
2653         ldo RT%foo-$tls_ldidx$(%r1),%arg0
2654         addil LR%foo-$tls_dtpoff$,%ret0
2655         ldo RR%foo-$tls_dtpoff$(%r1),%t1
2656         mfctl %cr27,%t1                 
2657         addil LT%foo-$tls_ieoff$,gp
2658         ldw RT%foo-$tls_ieoff$(%r1),%t2
2659         add %t1,%t2,%t3                 
2660         mfctl %cr27,%t1                 
2661         addil LR%foo-$tls_leoff$,%t1
2662         ldo RR%foo-$tls_leoff$(%r1),%t2'
2663         tls_first_major=2
2664         tls_first_minor=15
2665         tls_as_opt=--fatal-warnings
2666         ;;
2667   arm*-*-*)
2668     conftest_s='
2669         .section ".tdata","awT",%progbits
2670 foo:    .long   25
2671         .text
2672 .word foo(gottpoff)
2673 .word foo(tpoff)
2674 .word foo(tlsgd)
2675 .word foo(tlsldm)
2676 .word foo(tlsldo)'
2677         tls_first_major=2
2678         tls_first_minor=17
2679         ;;
2680   i[34567]86-*-*)
2681     case "$target" in
2682       i[34567]86-*-solaris2.*)
2683         on_solaris=yes
2684         tga_func=___tls_get_addr
2685         ;;
2686       *)
2687         on_solaris=no
2688         ;;
2689     esac
2690     if test x$on_solaris = xyes && test x$gas_flag = xno; then
2691       conftest_s='
2692         .section .tdata,"awt",@progbits'
2693       tls_first_major=0
2694       tls_first_minor=0
2695 changequote([,])dnl
2696       AC_DEFINE(TLS_SECTION_ASM_FLAG, 't',
2697 [Define to the flag used to mark TLS sections if the default (`T') doesn't work.])
2698 changequote(,)dnl
2699     else
2700       conftest_s='
2701         .section ".tdata","awT",@progbits'
2702       tls_first_major=2
2703       tls_first_minor=14
2704       tls_as_opt="--fatal-warnings"
2705     fi
2706     conftest_s="$conftest_s
2707 foo:    .long   25
2708         .text
2709         movl    %gs:0, %eax
2710         leal    foo@tlsgd(,%ebx,1), %eax
2711         leal    foo@tlsldm(%ebx), %eax
2712         leal    foo@dtpoff(%eax), %edx
2713         movl    foo@gottpoff(%ebx), %eax
2714         subl    foo@gottpoff(%ebx), %eax
2715         addl    foo@gotntpoff(%ebx), %eax
2716         movl    foo@indntpoff, %eax
2717         movl    \$foo@tpoff, %eax
2718         subl    \$foo@tpoff, %eax
2719         leal    foo@ntpoff(%ecx), %eax"
2720     ;;
2721   x86_64-*-*)
2722     conftest_s='
2723         .section ".tdata","awT",@progbits
2724 foo:    .long   25
2725         .text
2726         movq    %fs:0, %rax
2727         leaq    foo@TLSGD(%rip), %rdi
2728         leaq    foo@TLSLD(%rip), %rdi
2729         leaq    foo@DTPOFF(%rax), %rdx
2730         movq    foo@GOTTPOFF(%rip), %rax
2731         movq    $foo@TPOFF, %rax'
2732         tls_first_major=2
2733         tls_first_minor=14
2734         tls_as_opt=--fatal-warnings
2735         ;;
2736   ia64-*-*)
2737     conftest_s='
2738         .section ".tdata","awT",@progbits
2739 foo:    data8   25
2740         .text
2741         addl    r16 = @ltoff(@dtpmod(foo#)), gp
2742         addl    r17 = @ltoff(@dtprel(foo#)), gp
2743         addl    r18 = @ltoff(@tprel(foo#)), gp
2744         addl    r19 = @dtprel(foo#), gp
2745         adds    r21 = @dtprel(foo#), r13
2746         movl    r23 = @dtprel(foo#)
2747         addl    r20 = @tprel(foo#), gp
2748         adds    r22 = @tprel(foo#), r13
2749         movl    r24 = @tprel(foo#)'
2750         tls_first_major=2
2751         tls_first_minor=13
2752         tls_as_opt=--fatal-warnings
2753         ;;
2754   mips*-*-*)
2755     conftest_s='
2756         .section .tdata,"awT",@progbits
2757 x:
2758         .word 2
2759         .text
2760         addiu $4, $28, %tlsgd(x)
2761         addiu $4, $28, %tlsldm(x)
2762         lui $4, %dtprel_hi(x)
2763         addiu $4, $4, %dtprel_lo(x)
2764         lw $4, %gottprel(x)($28)
2765         lui $4, %tprel_hi(x)
2766         addiu $4, $4, %tprel_lo(x)'
2767         tls_first_major=2
2768         tls_first_minor=16
2769         tls_as_opt='-32 --fatal-warnings'
2770         ;;
2771   m68k-*-*)
2772     conftest_s='
2773         .section .tdata,"awT",@progbits
2774 x:
2775         .word 2
2776         .text
2777 foo:
2778         move.l x@TLSGD(%a5),%a0
2779         move.l x@TLSLDM(%a5),%a0
2780         move.l x@TLSLDO(%a5),%a0
2781         move.l x@TLSIE(%a5),%a0
2782         move.l x@TLSLE(%a5),%a0'
2783         tls_first_major=2
2784         tls_first_minor=19
2785         tls_as_opt='--fatal-warnings'
2786         ;;
2787   powerpc-*-*)
2788     conftest_s='
2789         .section ".tdata","awT",@progbits
2790         .align 2
2791 ld0:    .space 4
2792 ld1:    .space 4
2793 x1:     .space 4
2794 x2:     .space 4
2795 x3:     .space 4
2796         .text
2797         addi 3,31,ld0@got@tlsgd
2798         bl __tls_get_addr
2799         addi 3,31,x1@got@tlsld
2800         bl __tls_get_addr
2801         addi 9,3,x1@dtprel
2802         addis 9,3,x2@dtprel@ha
2803         addi 9,9,x2@dtprel@l
2804         lwz 9,x3@got@tprel(31)
2805         add 9,9,x@tls
2806         addi 9,2,x1@tprel
2807         addis 9,2,x2@tprel@ha
2808         addi 9,9,x2@tprel@l'
2809         tls_first_major=2
2810         tls_first_minor=14
2811         tls_as_opt="-a32 --fatal-warnings"
2812         ;;
2813   powerpc64-*-*)
2814     conftest_s='
2815         .section ".tdata","awT",@progbits
2816         .align 3
2817 ld0:    .space 8
2818 ld1:    .space 8
2819 x1:     .space 8
2820 x2:     .space 8
2821 x3:     .space 8
2822         .text
2823         addi 3,2,ld0@got@tlsgd
2824         bl .__tls_get_addr
2825         nop
2826         addi 3,2,ld1@toc
2827         bl .__tls_get_addr
2828         nop
2829         addi 3,2,x1@got@tlsld
2830         bl .__tls_get_addr
2831         nop
2832         addi 9,3,x1@dtprel
2833         bl .__tls_get_addr
2834         nop
2835         addis 9,3,x2@dtprel@ha
2836         addi 9,9,x2@dtprel@l
2837         bl .__tls_get_addr
2838         nop
2839         ld 9,x3@got@dtprel(2)
2840         add 9,9,3
2841         bl .__tls_get_addr
2842         nop'
2843         tls_first_major=2
2844         tls_first_minor=14
2845         tls_as_opt="-a64 --fatal-warnings"
2846         ;;
2847   s390-*-*)
2848     conftest_s='
2849         .section ".tdata","awT",@progbits
2850 foo:    .long   25
2851         .text
2852         .long   foo@TLSGD
2853         .long   foo@TLSLDM
2854         .long   foo@DTPOFF
2855         .long   foo@NTPOFF
2856         .long   foo@GOTNTPOFF
2857         .long   foo@INDNTPOFF
2858         l       %r1,foo@GOTNTPOFF(%r12)
2859         l       %r1,0(%r1):tls_load:foo
2860         bas     %r14,0(%r1,%r13):tls_gdcall:foo
2861         bas     %r14,0(%r1,%r13):tls_ldcall:foo'
2862         tls_first_major=2
2863         tls_first_minor=14
2864         tls_as_opt="-m31 --fatal-warnings"
2865         ;;
2866   s390x-*-*)
2867     conftest_s='
2868         .section ".tdata","awT",@progbits
2869 foo:    .long   25
2870         .text
2871         .quad   foo@TLSGD
2872         .quad   foo@TLSLDM
2873         .quad   foo@DTPOFF
2874         .quad   foo@NTPOFF
2875         .quad   foo@GOTNTPOFF
2876         lg      %r1,foo@GOTNTPOFF(%r12)
2877         larl    %r1,foo@INDNTPOFF
2878         brasl   %r14,__tls_get_offset@PLT:tls_gdcall:foo
2879         brasl   %r14,__tls_get_offset@PLT:tls_ldcall:foo'
2880         tls_first_major=2
2881         tls_first_minor=14
2882         tls_as_opt="-m64 -Aesame --fatal-warnings"
2883         ;;
2884   sh-*-* | sh[34]-*-*)
2885     conftest_s='
2886         .section ".tdata","awT",@progbits
2887 foo:    .long   25
2888         .text
2889         .long   foo@TLSGD
2890         .long   foo@TLSLDM
2891         .long   foo@DTPOFF
2892         .long   foo@GOTTPOFF
2893         .long   foo@TPOFF'
2894         tls_first_major=2
2895         tls_first_minor=13
2896         tls_as_opt=--fatal-warnings
2897         ;;
2898   sparc*-*-*)
2899     case "$target" in
2900       sparc*-sun-solaris2.*)
2901         on_solaris=yes
2902         tga_func=__tls_get_addr
2903         ;;
2904       *)
2905         on_solaris=no
2906         ;;
2907     esac
2908     if test x$on_solaris = xyes && test x$gas_flag = xno; then
2909       conftest_s='
2910         .section ".tdata",#alloc,#write,#tls'
2911         tls_first_major=0
2912         tls_first_minor=0
2913     else
2914       conftest_s='
2915         .section ".tdata","awT",@progbits'
2916         tls_first_major=2
2917         tls_first_minor=14
2918         tls_as_opt="-32 --fatal-warnings"
2919     fi
2920     conftest_s="$conftest_s
2921 foo:    .long   25
2922         .text
2923         sethi   %tgd_hi22(foo), %o0
2924         add     %o0, %tgd_lo10(foo), %o1
2925         add     %l7, %o1, %o0, %tgd_add(foo)
2926         call    __tls_get_addr, %tgd_call(foo)
2927         sethi   %tldm_hi22(foo), %l1
2928         add     %l1, %tldm_lo10(foo), %l2
2929         add     %l7, %l2, %o0, %tldm_add(foo)
2930         call    __tls_get_addr, %tldm_call(foo)
2931         sethi   %tldo_hix22(foo), %l3
2932         xor     %l3, %tldo_lox10(foo), %l4
2933         add     %o0, %l4, %l5, %tldo_add(foo)
2934         sethi   %tie_hi22(foo), %o3
2935         add     %o3, %tie_lo10(foo), %o3
2936         ld      [%l7 + %o3], %o2, %tie_ld(foo)
2937         add     %g7, %o2, %o4, %tie_add(foo)
2938         sethi   %tle_hix22(foo), %l1
2939         xor     %l1, %tle_lox10(foo), %o5
2940         ld      [%g7 + %o5], %o1"
2941         ;;
2942   xtensa*-*-*)
2943     conftest_s='
2944         .section ".tdata","awT",@progbits
2945 foo:    .long   25
2946         .text
2947         movi    a8, foo@TLSFUNC
2948         movi    a10, foo@TLSARG
2949         callx8.tls a8, foo@TLSCALL'
2950         tls_first_major=2
2951         tls_first_minor=19
2952         ;;
2953 changequote([,])dnl
2954 esac
2955 set_have_as_tls=no
2956 if test "x$enable_tls" = xno ; then
2957   : # TLS explicitly disabled.
2958 elif test "x$enable_tls" = xyes ; then
2959   set_have_as_tls=yes # TLS explicitly enabled.
2960 elif test -z "$tls_first_major"; then
2961   : # If we don't have a check, assume no support.
2962 else
2963   gcc_GAS_CHECK_FEATURE(thread-local storage support, gcc_cv_as_tls,
2964   [$tls_first_major,$tls_first_minor,0], [$tls_as_opt], [$conftest_s],,
2965   [set_have_as_tls=yes])
2966 fi
2967 case "$target" in
2968   # TLS was introduced in the Solaris 9 FCS release and backported to
2969   # Solaris 8 patches.  Support for GNU-style TLS on x86 was only
2970   # introduced in Solaris 9 4/04, replacing the earlier Sun style that Sun
2971   # ld and GCC don't support any longer.
2972   *-*-solaris2.*)
2973     AC_MSG_CHECKING(linker and ld.so.1 TLS support)
2974     ld_tls_support=no
2975     # Check ld and ld.so.1 TLS support.
2976     if echo "$ld_ver" | grep GNU > /dev/null; then
2977       # Assume all interesting versions of GNU ld have TLS support.
2978       # FIXME: still need ld.so.1 support, i.e. ld version checks below.
2979       ld_tls_support=yes
2980     else
2981       case "$target" in
2982         # Solaris 8/x86 ld has GNU style TLS support since version 1.280.
2983         i?86-*-solaris2.8)
2984           min_tls_ld_vers_minor=280
2985           ;;
2986         # Solaris 8/SPARC ld has TLS support since version 1.272.
2987         sparc*-*-solaris2.8)
2988           min_tls_ld_vers_minor=272
2989           ;;
2990         # Solaris 9/x86 ld has GNU style TLS support since version 1.374.
2991         i?86-*-solaris2.9)
2992           min_tls_ld_vers_minor=374
2993           ;;
2994         # Solaris 9/SPARC and Solaris 10+ ld have TLS support since FCS.
2995         sparc*-*-solaris2.9 | *-*-solaris2.1[[0-9]]*)
2996           min_tls_ld_vers_minor=343
2997           ;;
2998       esac
2999       if test "$ls_vers_major" -gt 1 || \
3000         test "$ld_vers_minor" -ge "$min_tls_ld_vers_minor"; then
3001         ld_tls_support=yes
3002       else
3003         set_have_as_tls=no
3004       fi
3005     fi
3006     AC_MSG_RESULT($ld_tls_support)
3007
3008     save_LIBS="$LIBS"
3009     save_LDFLAGS="$LDFLAGS"
3010     LIBS=
3011     LDFLAGS=
3012
3013     AC_MSG_CHECKING(alternate thread library)
3014     case "$target" in
3015       # TLS support was backported to Solaris 8 patches, but only lives in
3016       # the alternate thread library which became the default in Solaris 9. 
3017       # We want to always use that, irrespective of TLS support.
3018       *-*-solaris2.8)
3019         # Take multilib subdir into account.  There's no spec to handle
3020         # this.  The 64 symlink exists since Solaris 8.
3021         lwp_dir=/usr/lib/lwp
3022         lwp_spec="-L$lwp_dir%{m64:/64} -R$lwp_dir%{m64:/64}"
3023         LDFLAGS="-L$lwp_dir -R$lwp_dir"
3024         ;;
3025       *-*-solaris2*)
3026         lwp_dir="none"
3027         lwp_spec=""
3028         ;;
3029     esac    
3030     # Always define LIB_THREAD_LDFLAGS_SPEC, even without TLS support.
3031     AC_DEFINE_UNQUOTED(LIB_THREAD_LDFLAGS_SPEC, "$lwp_spec",
3032         [Define to the linker flags to use for -pthread.])
3033     AC_MSG_RESULT($lwp_dir)
3034
3035     AC_MSG_CHECKING(library containing $tga_func)
3036     # Before Solaris 10, __tls_get_addr (SPARC/x64) resp. ___tls_get_addr
3037     # (32-bit x86) only lived in libthread, so check for that.  Keep
3038     # set_have_as_tls if found, disable if not.
3039     AC_SEARCH_LIBS([$tga_func], [thread],, [set_have_as_tls=no])
3040     # Clear LIBS if we cannot support TLS.
3041     if test $set_have_as_tls = no; then
3042       LIBS=
3043     fi
3044     # Always define LIB_TLS_SPEC, even without TLS support.
3045     AC_DEFINE_UNQUOTED(LIB_TLS_SPEC, "$LIBS",
3046         [Define to the library containing __tls_get_addr/___tls_get_addr.])
3047     AC_MSG_RESULT($LIBS)
3048
3049     LIBS="$save_LIBS"
3050     LDFLAGS="$save_LDFLAGS"
3051     ;;
3052 esac
3053 if test $set_have_as_tls = yes ; then
3054   AC_DEFINE(HAVE_AS_TLS, 1,
3055             [Define if your assembler and linker support thread-local storage.])
3056 fi
3057
3058 # Target-specific assembler checks.
3059
3060 AC_MSG_CHECKING(linker -Bstatic/-Bdynamic option)
3061 gcc_cv_ld_static_dynamic=no
3062 if test $in_tree_ld = yes ; then
3063   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 10 -o "$gcc_cv_gld_major_version" -gt 2; then
3064     gcc_cv_ld_static_dynamic=yes
3065   fi
3066 elif test x$gcc_cv_ld != x; then
3067         # Check if linker supports -Bstatic/-Bdynamic option
3068         if $gcc_cv_ld --help 2>/dev/null | grep -- -Bstatic > /dev/null \
3069           && $gcc_cv_ld --help 2>/dev/null | grep -- -Bdynamic > /dev/null; then
3070                 gcc_cv_ld_static_dynamic=yes
3071         fi
3072 fi
3073 if test x"$gcc_cv_ld_static_dynamic" = xyes; then
3074         AC_DEFINE(HAVE_LD_STATIC_DYNAMIC, 1,
3075 [Define if your linker supports -Bstatic/-Bdynamic option.])
3076 fi
3077 AC_MSG_RESULT($gcc_cv_ld_static_dynamic)
3078
3079 if test x"$demangler_in_ld" = xyes; then
3080   AC_MSG_CHECKING(linker --demangle support)
3081   gcc_cv_ld_demangle=no
3082   if test $in_tree_ld = yes; then
3083     if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 14 -o "$gcc_cv_gld_major_version" -gt 2; then \
3084       gcc_cv_ld_demangle=yes
3085     fi
3086   elif test x$gcc_cv_ld != x -a x"$gnu_ld" = xyes; then
3087     # Check if the GNU linker supports --demangle option
3088     if $gcc_cv_ld --help 2>/dev/null | grep no-demangle > /dev/null; then
3089       gcc_cv_ld_demangle=yes
3090     fi
3091   fi
3092   if test x"$gcc_cv_ld_demangle" = xyes; then
3093     AC_DEFINE(HAVE_LD_DEMANGLE, 1,
3094 [Define if your linker supports --demangle option.])
3095   fi
3096   AC_MSG_RESULT($gcc_cv_ld_demangle)
3097 fi
3098
3099 case "$target" in
3100   # All TARGET_ABI_OSF targets.
3101   alpha*-*-osf* | alpha*-*-linux* | alpha*-*-*bsd*)
3102     gcc_GAS_CHECK_FEATURE([explicit relocation support],
3103         gcc_cv_as_alpha_explicit_relocs, [2,12,0],,
3104 [       .set nomacro
3105         .text
3106         extbl   $3, $2, $3      !lituse_bytoff!1
3107         ldq     $2, a($29)      !literal!1
3108         ldq     $4, b($29)      !literal!2
3109         ldq_u   $3, 0($2)       !lituse_base!1
3110         ldq     $27, f($29)     !literal!5
3111         jsr     $26, ($27), f   !lituse_jsr!5
3112         ldah    $29, 0($26)     !gpdisp!3
3113         lda     $0, c($29)      !gprel
3114         ldah    $1, d($29)      !gprelhigh
3115         lda     $1, d($1)       !gprellow
3116         lda     $29, 0($29)     !gpdisp!3],,
3117     [AC_DEFINE(HAVE_AS_EXPLICIT_RELOCS, 1,
3118   [Define if your assembler supports explicit relocations.])])
3119     gcc_GAS_CHECK_FEATURE([jsrdirect relocation support],
3120         gcc_cv_as_alpha_jsrdirect_relocs, [2,16,90],,
3121 [       .set nomacro
3122         .text
3123         ldq     $27, a($29)     !literal!1
3124         jsr     $26, ($27), a   !lituse_jsrdirect!1],,
3125     [AC_DEFINE(HAVE_AS_JSRDIRECT_RELOCS, 1,
3126   [Define if your assembler supports the lituse_jsrdirect relocation.])])
3127     ;;
3128
3129   cris-*-*)
3130     gcc_GAS_CHECK_FEATURE([-no-mul-bug-abort option],
3131       gcc_cv_as_cris_no_mul_bug,[2,15,91],
3132       [-no-mul-bug-abort], [.text],,
3133       [AC_DEFINE(HAVE_AS_NO_MUL_BUG_ABORT_OPTION, 1,
3134                 [Define if your assembler supports the -no-mul-bug-abort option.])])
3135     ;;
3136
3137   sparc*-*-*)
3138     gcc_GAS_CHECK_FEATURE([.register], gcc_cv_as_sparc_register_op,,,
3139       [.register %g2, #scratch],,
3140       [AC_DEFINE(HAVE_AS_REGISTER_PSEUDO_OP, 1,
3141                 [Define if your assembler supports .register.])])
3142
3143     gcc_GAS_CHECK_FEATURE([-relax option], gcc_cv_as_sparc_relax,,
3144       [-relax], [.text],,
3145       [AC_DEFINE(HAVE_AS_RELAX_OPTION, 1,
3146                 [Define if your assembler supports -relax option.])])
3147
3148     gcc_GAS_CHECK_FEATURE([GOTDATA_OP relocs],
3149       gcc_cv_as_sparc_gotdata_op,,
3150       [-K PIC],
3151 [.text
3152 foo:
3153         nop
3154 bar:
3155         sethi %gdop_hix22(foo), %g1
3156         xor    %g1, %gdop_lox10(foo), %g1
3157         ld    [[%l7 + %g1]], %g2, %gdop(foo)],
3158       [if test x$gcc_cv_ld != x \
3159        && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1; then
3160          if $gcc_cv_ld -v | grep GNU >/dev/null 2>&1; then
3161            if test x$gcc_cv_objdump != x; then
3162              if $gcc_cv_objdump -s -j .text conftest 2> /dev/null \
3163                 | grep ' 03000004 82186004 c405c001'> /dev/null 2>&1; then
3164                gcc_cv_as_sparc_gotdata_op=no
3165              else
3166                gcc_cv_as_sparc_gotdata_op=yes
3167              fi
3168            fi
3169          else
3170            gcc_cv_as_sparc_gotdata_op=yes
3171          fi
3172        fi
3173        rm -f conftest],
3174       [AC_DEFINE(HAVE_AS_SPARC_GOTDATA_OP, 1,
3175                 [Define if your assembler and linker support GOTDATA_OP relocs.])])
3176
3177     gcc_GAS_CHECK_FEATURE([unaligned pcrel relocs],
3178       gcc_cv_as_sparc_ua_pcrel,,
3179       [-K PIC],
3180 [.text
3181 foo:
3182         nop
3183 .data
3184 .align 4
3185 .byte 0
3186 .uaword %r_disp32(foo)],
3187       [if test x$gcc_cv_ld != x \
3188        && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1; then
3189          gcc_cv_as_sparc_ua_pcrel=yes
3190        fi
3191        rm -f conftest],
3192       [AC_DEFINE(HAVE_AS_SPARC_UA_PCREL, 1,
3193                 [Define if your assembler and linker support unaligned PC relative relocs.])
3194
3195       gcc_GAS_CHECK_FEATURE([unaligned pcrel relocs against hidden symbols],
3196         gcc_cv_as_sparc_ua_pcrel_hidden,,
3197         [-K PIC],
3198 [.data
3199 .align 4
3200 .byte 0x31
3201 .uaword %r_disp32(foo)
3202 .byte 0x32, 0x33, 0x34
3203 .global foo
3204 .hidden foo
3205 foo:
3206 .skip 4],
3207         [if test x$gcc_cv_ld != x && test x$gcc_cv_objdump != x \
3208          && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1 \
3209          && $gcc_cv_objdump -s -j .data conftest 2> /dev/null \
3210             | grep ' 31000000 07323334' > /dev/null 2>&1; then
3211             if $gcc_cv_objdump -R conftest 2> /dev/null \
3212                | grep 'DISP32' > /dev/null 2>&1; then
3213                 :
3214             else
3215                 gcc_cv_as_sparc_ua_pcrel_hidden=yes
3216             fi
3217          fi
3218          rm -f conftest],
3219          [AC_DEFINE(HAVE_AS_SPARC_UA_PCREL_HIDDEN, 1,
3220                    [Define if your assembler and linker support unaligned PC relative relocs against hidden symbols.])])
3221     ]) # unaligned pcrel relocs
3222
3223     gcc_GAS_CHECK_FEATURE([offsetable %lo()],
3224       gcc_cv_as_sparc_offsetable_lo10,,
3225       [-xarch=v9],
3226 [.text
3227         or %g1, %lo(ab) + 12, %g1
3228         or %g1, %lo(ab + 12), %g1],
3229       [if test x$gcc_cv_objdump != x \
3230        && $gcc_cv_objdump -s -j .text conftest.o 2> /dev/null \
3231           | grep ' 82106000 82106000' > /dev/null 2>&1; then
3232          gcc_cv_as_sparc_offsetable_lo10=yes
3233        fi],
3234        [AC_DEFINE(HAVE_AS_OFFSETABLE_LO10, 1,
3235                  [Define if your assembler supports offsetable %lo().])])
3236     ;;
3237
3238 changequote(,)dnl
3239   i[34567]86-*-* | x86_64-*-*)
3240 changequote([,])dnl
3241     case $target_os in
3242       cygwin*)
3243         # Full C++ conformance when using a shared libstdc++-v3 requires some
3244         # support from the Cygwin DLL, which in more recent versions exports
3245         # wrappers to aid in interposing and redirecting operators new, delete,
3246         # etc., as per n2800 #17.6.4.6 [replacement.functions].  Check if we
3247         # are configuring for a version of Cygwin that exports the wrappers.
3248         if test x$host = x$target; then
3249           AC_CHECK_FUNC([__wrap__Znaj],[gcc_ac_cygwin_dll_wrappers=yes],[gcc_ac_cygwin_dll_wrappers=no])
3250         else
3251           # Can't check presence of libc functions during cross-compile, so
3252           # we just have to assume we're building for an up-to-date target.
3253           gcc_ac_cygwin_dll_wrappers=yes
3254         fi
3255         AC_DEFINE_UNQUOTED(USE_CYGWIN_LIBSTDCXX_WRAPPERS,
3256           [`if test $gcc_ac_cygwin_dll_wrappers = yes; then echo 1; else echo 0; fi`],
3257           [Define if you want to generate code by default that assumes that the
3258            Cygwin DLL exports wrappers to support libstdc++ function replacement.])
3259     esac
3260     case $target_os in
3261       cygwin* | pe | mingw32*)
3262         # Recent binutils allows the three-operand form of ".comm" on PE.  This
3263         # definition is used unconditionally to initialise the default state of
3264         # the target option variable that governs usage of the feature.
3265         gcc_GAS_CHECK_FEATURE([.comm with alignment], gcc_cv_as_comm_has_align,
3266          [2,19,52],,[.comm foo,1,32])
3267         AC_DEFINE_UNQUOTED(HAVE_GAS_ALIGNED_COMM,
3268           [`if test $gcc_cv_as_comm_has_align = yes; then echo 1; else echo 0; fi`],
3269           [Define if your assembler supports specifying the alignment
3270            of objects allocated using the GAS .comm command.])
3271         # Used for DWARF 2 in PE
3272         gcc_GAS_CHECK_FEATURE([.secrel32 relocs],
3273           gcc_cv_as_ix86_pe_secrel32,
3274           [2,15,91],,
3275 [.text
3276 foo:    nop
3277 .data
3278         .secrel32 foo],
3279           [if test x$gcc_cv_ld != x \
3280            && $gcc_cv_ld -o conftest conftest.o > /dev/null 2>&1; then
3281              gcc_cv_as_ix86_pe_secrel32=yes
3282            fi
3283            rm -f conftest],
3284           [AC_DEFINE(HAVE_GAS_PE_SECREL32_RELOC, 1,
3285             [Define if your assembler and linker support 32-bit section relative relocs via '.secrel32 label'.])])
3286         # Test if the assembler supports the extended form of the .section
3287         # directive that specifies section alignment.  LTO support uses this,
3288         # but normally only after installation, so we warn but don't fail the
3289         # configure if LTO is enabled but the assembler does not support it.
3290         gcc_GAS_CHECK_FEATURE([.section with alignment], gcc_cv_as_section_has_align,
3291           [2,20,1],-fatal-warnings,[.section lto_test,"dr0"])
3292         if test x$gcc_cv_as_section_has_align != xyes; then
3293           case ",$enable_languages," in
3294             *,lto,*)
3295               AC_MSG_WARN([LTO for $target requires binutils >= 2.20.1, but version found appears insufficient; LTO will not work until binutils is upgraded.])
3296               ;;
3297           esac
3298         fi
3299         ;;
3300     esac
3301
3302     gcc_GAS_CHECK_FEATURE([filds and fists mnemonics],
3303        gcc_cv_as_ix86_filds,,,
3304        [filds mem; fists mem],,
3305        [AC_DEFINE(HAVE_AS_IX86_FILDS, 1,
3306          [Define if your assembler uses filds and fists mnemonics.])])
3307
3308     gcc_GAS_CHECK_FEATURE([fildq and fistpq mnemonics],
3309        gcc_cv_as_ix86_fildq,,,
3310        [fildq mem; fistpq mem],,
3311        [AC_DEFINE(HAVE_AS_IX86_FILDQ, 1,
3312          [Define if your assembler uses fildq and fistq mnemonics.])])
3313
3314     gcc_GAS_CHECK_FEATURE([cmov syntax],
3315       gcc_cv_as_ix86_cmov_sun_syntax,,,
3316       [cmovl.l %edx, %eax],,
3317       [AC_DEFINE(HAVE_AS_IX86_CMOV_SUN_SYNTAX, 1,
3318         [Define if your assembler supports the Sun syntax for cmov.])])
3319
3320     gcc_GAS_CHECK_FEATURE([ffreep mnemonic],
3321       gcc_cv_as_ix86_ffreep,,,
3322       [ffreep %st(1)],,
3323       [AC_DEFINE(HAVE_AS_IX86_FFREEP, 1,
3324         [Define if your assembler supports the ffreep mnemonic.])])
3325
3326     gcc_GAS_CHECK_FEATURE([.quad directive],
3327       gcc_cv_as_ix86_quad,,,
3328       [.quad 0],,
3329       [AC_DEFINE(HAVE_AS_IX86_QUAD, 1,
3330         [Define if your assembler supports the .quad directive.])])
3331
3332     gcc_GAS_CHECK_FEATURE([sahf mnemonic],
3333       gcc_cv_as_ix86_sahf,,,
3334       [.code64
3335        sahf],,
3336       [AC_DEFINE(HAVE_AS_IX86_SAHF, 1,
3337         [Define if your assembler supports the sahf mnemonic in 64bit mode.])])
3338
3339     gcc_GAS_CHECK_FEATURE([swap suffix],
3340       gcc_cv_as_ix86_swap,,,
3341       [movl.s %esp, %ebp],,
3342       [AC_DEFINE(HAVE_AS_IX86_SWAP, 1,
3343         [Define if your assembler supports the swap suffix.])])
3344
3345     gcc_GAS_CHECK_FEATURE([different section symbol subtraction],
3346       gcc_cv_as_ix86_diff_sect_delta,,,
3347       [.section .rodata
3348 .L1:
3349         .long .L2-.L1
3350         .long .L3-.L1
3351         .text
3352 .L3:    nop
3353 .L2:    nop],,
3354       [AC_DEFINE(HAVE_AS_IX86_DIFF_SECT_DELTA, 1,
3355         [Define if your assembler supports the subtraction of symbols in different sections.])])
3356
3357     # These two are used unconditionally by i386.[ch]; it is to be defined
3358     # to 1 if the feature is present, 0 otherwise.
3359     gcc_GAS_CHECK_FEATURE([GOTOFF in data],
3360         gcc_cv_as_ix86_gotoff_in_data, [2,11,0],,
3361 [       .text
3362 .L0:
3363         nop
3364         .data
3365         .long .L0@GOTOFF])
3366     AC_DEFINE_UNQUOTED(HAVE_AS_GOTOFF_IN_DATA,
3367       [`if test $gcc_cv_as_ix86_gotoff_in_data = yes; then echo 1; else echo 0; fi`],
3368       [Define true if the assembler supports '.long foo@GOTOFF'.])
3369
3370     gcc_GAS_CHECK_FEATURE([rep and lock prefix],
3371         gcc_cv_as_ix86_rep_lock_prefix,,,
3372         [rep movsl
3373          lock addl %edi, (%eax,%esi)
3374          lock orl $0, (%esp)],,
3375         [AC_DEFINE(HAVE_AS_IX86_REP_LOCK_PREFIX, 1,
3376           [Define if the assembler supports 'rep <insn>, lock <insn>'.])])
3377
3378     ;;
3379
3380   ia64*-*-*)
3381     gcc_GAS_CHECK_FEATURE([ltoffx and ldxmov relocs],
3382         gcc_cv_as_ia64_ltoffx_ldxmov_relocs, [2,14,0],,
3383 [       .text
3384         addl r15 = @ltoffx(x#), gp
3385         ;;
3386         ld8.mov r16 = [[r15]], x#],,
3387     [AC_DEFINE(HAVE_AS_LTOFFX_LDXMOV_RELOCS, 1,
3388           [Define if your assembler supports ltoffx and ldxmov relocations.])])
3389
3390     ;;
3391
3392   powerpc*-*-*)
3393     case $target in
3394       *-*-aix*) conftest_s='    .machine "pwr5"
3395         .csect .text[[PR]]
3396         mfcr 3,128';;
3397       *-*-darwin*)
3398         gcc_GAS_CHECK_FEATURE([.machine directive support],
3399           gcc_cv_as_machine_directive,,,
3400           [     .machine ppc7400])
3401         if test x$gcc_cv_as_machine_directive != xyes; then
3402           echo "*** This target requires an assembler supporting \".machine\"" >&2
3403           echo you can get it from: ftp://gcc.gnu.org/pub/gcc/infrastructure/cctools-528.5.dmg >&2
3404           test x$build = x$target && exit 1
3405         fi
3406         conftest_s='    .text
3407         mfcr r3,128';;
3408       *) conftest_s='   .machine power4
3409         .text
3410         mfcr 3,128';;
3411     esac
3412
3413     gcc_GAS_CHECK_FEATURE([mfcr field support],
3414       gcc_cv_as_powerpc_mfcrf, [2,14,0],,
3415       [$conftest_s],,
3416       [AC_DEFINE(HAVE_AS_MFCRF, 1,
3417           [Define if your assembler supports mfcr field.])])
3418
3419     case $target in
3420       *-*-aix*) conftest_s='    .machine "pwr5"
3421         .csect .text[[PR]]
3422         popcntb 3,3';;
3423       *) conftest_s='   .machine power5
3424         .text
3425         popcntb 3,3';;
3426     esac
3427
3428     gcc_GAS_CHECK_FEATURE([popcntb support],
3429       gcc_cv_as_powerpc_popcntb, [2,17,0],,
3430       [$conftest_s],,
3431       [AC_DEFINE(HAVE_AS_POPCNTB, 1,
3432           [Define if your assembler supports popcntb field.])])
3433
3434     case $target in
3435       *-*-aix*) conftest_s='    .machine "pwr5x"
3436         .csect .text[[PR]]
3437         frin 1,1';;
3438       *) conftest_s='   .machine power5
3439         .text
3440         frin 1,1';;
3441     esac
3442
3443     gcc_GAS_CHECK_FEATURE([fp round support],
3444       gcc_cv_as_powerpc_fprnd, [2,17,0],,
3445       [$conftest_s],,
3446       [AC_DEFINE(HAVE_AS_FPRND, 1,
3447           [Define if your assembler supports fprnd.])])
3448
3449     case $target in
3450       *-*-aix*) conftest_s='    .machine "pwr6"
3451         .csect .text[[PR]]
3452         mffgpr 1,3';;
3453       *) conftest_s='   .machine power6
3454         .text
3455         mffgpr 1,3';;
3456     esac
3457
3458     gcc_GAS_CHECK_FEATURE([move fp gpr support],
3459       gcc_cv_as_powerpc_mfpgpr, [2,19,2],,
3460       [$conftest_s],,
3461       [AC_DEFINE(HAVE_AS_MFPGPR, 1,
3462           [Define if your assembler supports mffgpr and mftgpr.])])
3463
3464     case $target in
3465       *-*-aix*) conftest_s='    .csect .text[[PR]]
3466 LCF..0:
3467         addis 11,30,_GLOBAL_OFFSET_TABLE_-LCF..0@ha';;
3468       *-*-darwin*)
3469         conftest_s='    .text
3470 LCF0:
3471         addis r11,r30,_GLOBAL_OFFSET_TABLE_-LCF0@ha';;
3472       *) conftest_s='   .text
3473 .LCF0:
3474         addis 11,30,_GLOBAL_OFFSET_TABLE_-.LCF0@ha';;
3475     esac
3476
3477     gcc_GAS_CHECK_FEATURE([rel16 relocs],
3478       gcc_cv_as_powerpc_rel16, [2,17,0], -a32,
3479       [$conftest_s],,
3480       [AC_DEFINE(HAVE_AS_REL16, 1,
3481           [Define if your assembler supports R_PPC_REL16 relocs.])])
3482
3483     case $target in
3484       *-*-aix*) conftest_s='    .machine "pwr6"
3485         .csect .text[[PR]]
3486         cmpb 3,4,5';;
3487       *) conftest_s='   .machine power6
3488         .text
3489         cmpb 3,4,5';;
3490     esac
3491
3492     gcc_GAS_CHECK_FEATURE([compare bytes support],
3493       gcc_cv_as_powerpc_cmpb, [2,19,2], -a32,
3494       [$conftest_s],,
3495       [AC_DEFINE(HAVE_AS_CMPB, 1,
3496           [Define if your assembler supports cmpb.])])
3497
3498     case $target in
3499       *-*-aix*) conftest_s='    .machine "pwr6"
3500         .csect .text[[PR]]
3501         dadd 1,2,3';;
3502       *) conftest_s='   .machine power6
3503         .text
3504         dadd 1,2,3';;
3505     esac
3506
3507     gcc_GAS_CHECK_FEATURE([decimal float support],
3508       gcc_cv_as_powerpc_dfp, [2,19,2], -a32,
3509       [$conftest_s],,
3510       [AC_DEFINE(HAVE_AS_DFP, 1,
3511           [Define if your assembler supports DFP instructions.])])
3512
3513     case $target in
3514       *-*-aix*) conftest_s='    .machine "pwr7"
3515         .csect .text[[PR]]
3516         lxvd2x 1,2,3';;
3517       *) conftest_s='   .machine power7
3518         .text
3519         lxvd2x 1,2,3';;
3520     esac
3521
3522     gcc_GAS_CHECK_FEATURE([vector-scalar support],
3523       gcc_cv_as_powerpc_vsx, [2,19,2], -a32,
3524       [$conftest_s],,
3525       [AC_DEFINE(HAVE_AS_VSX, 1,
3526           [Define if your assembler supports VSX instructions.])])
3527
3528     case $target in
3529       *-*-aix*) conftest_s='    .machine "pwr7"
3530         .csect .text[[PR]]
3531         popcntd 3,3';;
3532       *) conftest_s='   .machine power7
3533         .text
3534         popcntd 3,3';;
3535     esac
3536
3537     gcc_GAS_CHECK_FEATURE([popcntd support],
3538       gcc_cv_as_powerpc_popcntd, [2,19,2], -a32,
3539       [$conftest_s],,
3540       [AC_DEFINE(HAVE_AS_POPCNTD, 1,
3541           [Define if your assembler supports POPCNTD instructions.])])
3542
3543     case $target in
3544       *-*-aix*) conftest_s='    .csect .text[[PR]]
3545         lwsync';;
3546       *) conftest_s='   .text
3547         lwsync';;
3548     esac
3549
3550     gcc_GAS_CHECK_FEATURE([lwsync support],
3551       gcc_cv_as_powerpc_lwsync, [2,19,2], -a32,
3552       [$conftest_s],,
3553       [AC_DEFINE(HAVE_AS_LWSYNC, 1,
3554           [Define if your assembler supports LWSYNC instructions.])])
3555
3556     case $target in
3557       *-*-aix*) conftest_s='    .machine "476"
3558         .csect .text[[PR]]
3559         dci 0';;
3560       *) conftest_s='   .machine "476"
3561         .text
3562         dci 0';;
3563     esac
3564
3565     gcc_GAS_CHECK_FEATURE([data cache invalidate support],
3566       gcc_cv_as_powerpc_dci, [9,99,0], -a32,
3567       [$conftest_s],,
3568       [AC_DEFINE(HAVE_AS_DCI, 1,
3569           [Define if your assembler supports the DCI/ICI instructions.])])
3570
3571     gcc_GAS_CHECK_FEATURE([.gnu_attribute support],
3572       gcc_cv_as_powerpc_gnu_attribute, [2,18,0],,
3573       [.gnu_attribute 4,1],,
3574       [AC_DEFINE(HAVE_AS_GNU_ATTRIBUTE, 1,
3575           [Define if your assembler supports .gnu_attribute.])])
3576
3577     gcc_GAS_CHECK_FEATURE([tls marker support],
3578       gcc_cv_as_powerpc_tls_markers, [2,20,0],,
3579       [ bl __tls_get_addr(x@tlsgd)],,
3580       [AC_DEFINE(HAVE_AS_TLS_MARKERS, 1,
3581           [Define if your assembler supports arg info for __tls_get_addr.])])
3582
3583     case $target in
3584       *-*-aix*)
3585         gcc_GAS_CHECK_FEATURE([.ref support],
3586           gcc_cv_as_aix_ref, [2.21.0],,
3587           [     .csect stuff[[rw]]
3588              stuff:
3589                 .long 1
3590                 .extern sym
3591                 .ref sym
3592           ],,
3593           [AC_DEFINE(HAVE_AS_REF, 1,
3594             [Define if your assembler supports .ref])])
3595         ;;
3596     esac
3597     ;;
3598
3599   mips*-*-*)
3600     gcc_GAS_CHECK_FEATURE([explicit relocation support],
3601       gcc_cv_as_mips_explicit_relocs, [2,14,0],,
3602 [       lw $4,%gp_rel(foo)($4)],,
3603       [if test x$target_cpu_default = x
3604        then target_cpu_default=MASK_EXPLICIT_RELOCS
3605        else target_cpu_default="($target_cpu_default)|MASK_EXPLICIT_RELOCS"
3606        fi])
3607     gcc_GAS_CHECK_FEATURE([-mno-shared support],
3608       gcc_cv_as_mips_no_shared, [2,16,0], [-mno-shared], [nop],,
3609       [AC_DEFINE(HAVE_AS_NO_SHARED, 1,
3610                  [Define if the assembler understands -mno-shared.])])
3611
3612     gcc_GAS_CHECK_FEATURE([.gnu_attribute support],
3613       gcc_cv_as_mips_gnu_attribute, [2,18,0],,
3614       [.gnu_attribute 4,1],,
3615       [AC_DEFINE(HAVE_AS_GNU_ATTRIBUTE, 1,
3616           [Define if your assembler supports .gnu_attribute.])])
3617
3618     gcc_GAS_CHECK_FEATURE([.dtprelword support],
3619       gcc_cv_as_mips_dtprelword, [2,18,0],,
3620       [.section .tdata,"awT",@progbits
3621 x:
3622         .word 2
3623         .text
3624         .dtprelword x+0x8000],,
3625       [AC_DEFINE(HAVE_AS_DTPRELWORD, 1,
3626           [Define if your assembler supports .dtprelword.])])
3627
3628     AC_MSG_CHECKING(assembler and linker for explicit JALR relocation)
3629     gcc_cv_as_ld_jalr_reloc=no
3630     if test $gcc_cv_as_mips_explicit_relocs = yes; then