gcc/configure.ac

   1 # configure.ac for GCC
   2 # Process this file with autoconf to generate a configuration script.
   3
   4 # Copyright 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2004, 2005, 2006,
   5 # 2007, 2008 Free Software Foundation, Inc.
   6
   7 #This file is part of GCC.
   8
   9 #GCC is free software; you can redistribute it and/or modify it under
  10 #the terms of the GNU General Public License as published by the Free
  11 #Software Foundation; either version 3, or (at your option) any later
  12 #version.
  13
  14 #GCC is distributed in the hope that it will be useful, but WITHOUT
  15 #ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  16 #FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  17 #for more details.
  18
  19 #You should have received a copy of the GNU General Public License
  20 #along with GCC; see the file COPYING3.  If not see
  21 #<http://www.gnu.org/licenses/>.
  22
  23 # --------------------------------
  24 # Initialization and sanity checks
  25 # --------------------------------
  26
  27 AC_PREREQ(2.59)
  28 AC_INIT
  29 AC_CONFIG_SRCDIR(tree.c)
  30 AC_CONFIG_HEADER(auto-host.h:config.in)
  31
  32 gcc_version=`cat $srcdir/BASE-VER`
  33
  34 # Determine the host, build, and target systems
  35 AC_CANONICAL_BUILD
  36 AC_CANONICAL_HOST
  37 AC_CANONICAL_TARGET
  38
  39 # Determine the noncanonical target name, for directory use.
  40 ACX_NONCANONICAL_TARGET
  41
  42 # Determine the target- and build-specific subdirectories
  43 GCC_TOPLEV_SUBDIRS
  44
  45 # Set program_transform_name
  46 AC_ARG_PROGRAM
  47
  48 # Check for bogus environment variables.
  49 # Test if LIBRARY_PATH contains the notation for the current directory
  50 # since this would lead to problems installing/building glibc.
  51 # LIBRARY_PATH contains the current directory if one of the following
  52 # is true:
  53 # - one of the terminals (":" and ";") is the first or last sign
  54 # - two terminals occur directly after each other
  55 # - the path contains an element with a dot in it
  56 AC_MSG_CHECKING(LIBRARY_PATH variable)
  57 changequote(,)dnl
  58 case ${LIBRARY_PATH} in
  59   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
  60     library_path_setting="contains current directory"
  61     ;;
  62   *)
  63     library_path_setting="ok"
  64     ;;
  65 esac
  66 changequote([,])dnl
  67 AC_MSG_RESULT($library_path_setting)
  68 if test "$library_path_setting" != "ok"; then
  69 AC_MSG_ERROR([
  70 *** LIBRARY_PATH shouldn't contain the current directory when
  71 *** building gcc. Please change the environment variable
  72 *** and run configure again.])
  73 fi
  74
  75 # Test if GCC_EXEC_PREFIX contains the notation for the current directory
  76 # since this would lead to problems installing/building glibc.
  77 # GCC_EXEC_PREFIX contains the current directory if one of the following
  78 # is true:
  79 # - one of the terminals (":" and ";") is the first or last sign
  80 # - two terminals occur directly after each other
  81 # - the path contains an element with a dot in it
  82 AC_MSG_CHECKING(GCC_EXEC_PREFIX variable)
  83 changequote(,)dnl
  84 case ${GCC_EXEC_PREFIX} in
  85   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
  86     gcc_exec_prefix_setting="contains current directory"
  87     ;;
  88   *)
  89     gcc_exec_prefix_setting="ok"
  90     ;;
  91 esac
  92 changequote([,])dnl
  93 AC_MSG_RESULT($gcc_exec_prefix_setting)
  94 if test "$gcc_exec_prefix_setting" != "ok"; then
  95 AC_MSG_ERROR([
  96 *** GCC_EXEC_PREFIX shouldn't contain the current directory when
  97 *** building gcc. Please change the environment variable
  98 *** and run configure again.])
  99 fi
 100
 101 # -----------
 102 # Directories
 103 # -----------
 104
 105 # Specify the local prefix
 106 local_prefix=
 107 AC_ARG_WITH(local-prefix,
 108 [  --with-local-prefix=DIR specifies directory to put local include],
 109 [case "${withval}" in
 110 yes)    AC_MSG_ERROR(bad value ${withval} given for local include directory prefix) ;;
 111 no)     ;;
 112 *)      local_prefix=$with_local_prefix ;;
 113 esac])
 114
 115 # Default local prefix if it is empty
 116 if test x$local_prefix = x; then
 117         local_prefix=/usr/local
 118 fi
 119
 120 # Don't set gcc_gxx_include_dir to gxx_include_dir since that's only
 121 # passed in by the toplevel make and thus we'd get different behavior
 122 # depending on where we built the sources.
 123 gcc_gxx_include_dir=
 124 # Specify the g++ header file directory
 125 AC_ARG_WITH(gxx-include-dir,
 126 [  --with-gxx-include-dir=DIR
 127                           specifies directory to put g++ header files],
 128 [case "${withval}" in
 129 yes)    AC_MSG_ERROR(bad value ${withval} given for g++ include directory) ;;
 130 no)     ;;
 131 *)      gcc_gxx_include_dir=$with_gxx_include_dir ;;
 132 esac])
 133
 134 # This logic must match libstdc++-v3/acinclude.m4:GLIBCXX_EXPORT_INSTALL_INFO.
 135 if test x${gcc_gxx_include_dir} = x; then
 136   if test x${enable_version_specific_runtime_libs} = xyes; then
 137     gcc_gxx_include_dir='${libsubdir}/include/c++'
 138   else
 139     libstdcxx_incdir='include/c++/$(version)'
 140     if test x$host != x$target; then
 141        libstdcxx_incdir="$target_alias/$libstdcxx_incdir"
 142     fi
 143     gcc_gxx_include_dir="\$(libsubdir)/\$(libsubdir_to_prefix)$libstdcxx_incdir"
 144   fi
 145 fi
 146
 147 AC_ARG_WITH(cpp_install_dir,
 148 [  --with-cpp-install-dir=DIR
 149                           install the user visible C preprocessor in DIR
 150                           (relative to PREFIX) as well as PREFIX/bin],
 151 [if test x$withval = xyes; then
 152   AC_MSG_ERROR([option --with-cpp-install-dir requires an argument])
 153 elif test x$withval != xno; then
 154   cpp_install_dir=$withval
 155 fi])
 156
 157 # We would like to our source tree to be readonly.  However when releases or
 158 # pre-releases are generated, the flex/bison generated files as well as the
 159 # various formats of manuals need to be included along with the rest of the
 160 # sources.  Therefore we have --enable-generated-files-in-srcdir to do
 161 # just that.
 162
 163 AC_MSG_CHECKING([whether to place generated files in the source directory])
 164   dnl generated-files-in-srcdir is disabled by default
 165   AC_ARG_ENABLE(generated-files-in-srcdir,
 166 [  --enable-generated-files-in-srcdir
 167                           put copies of generated files in source dir
 168                           intended for creating source tarballs for users
 169                           without texinfo bison or flex.],
 170       generated_files_in_srcdir=$enableval,
 171       generated_files_in_srcdir=no)
 172
 173 AC_MSG_RESULT($generated_files_in_srcdir)
 174
 175 if test "$generated_files_in_srcdir" = "yes"; then
 176   GENINSRC=''
 177 else
 178   GENINSRC='#'
 179 fi
 180 AC_SUBST(GENINSRC)
 181
 182 # -------------------
 183 # Find default linker
 184 # -------------------
 185
 186 # With GNU ld
 187 AC_ARG_WITH(gnu-ld,
 188 [  --with-gnu-ld           arrange to work with GNU ld.],
 189 gnu_ld_flag="$with_gnu_ld",
 190 gnu_ld_flag=no)
 191
 192 # With pre-defined ld
 193 AC_ARG_WITH(ld,
 194 [  --with-ld               arrange to use the specified ld (full pathname)],
 195 DEFAULT_LINKER="$with_ld")
 196 if test x"${DEFAULT_LINKER+set}" = x"set"; then
 197   if test ! -x "$DEFAULT_LINKER"; then
 198     AC_MSG_ERROR([cannot execute: $DEFAULT_LINKER: check --with-ld or env. var. DEFAULT_LINKER])
 199   elif $DEFAULT_LINKER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
 200     gnu_ld_flag=yes
 201   fi
 202   AC_DEFINE_UNQUOTED(DEFAULT_LINKER,"$DEFAULT_LINKER",
 203         [Define to enable the use of a default linker.])
 204 fi
 205
 206 gnu_ld=`if test x"$gnu_ld_flag" = x"yes"; then echo 1; else echo 0; fi`
 207 AC_DEFINE_UNQUOTED(HAVE_GNU_LD, $gnu_ld, [Define if using GNU ld.])
 208
 209 AC_MSG_CHECKING([whether a default linker was specified])
 210 if test x"${DEFAULT_LINKER+set}" = x"set"; then
 211   if test x"$gnu_ld_flag" = x"no"; then
 212     AC_MSG_RESULT([yes ($DEFAULT_LINKER)])
 213   else
 214     AC_MSG_RESULT([yes ($DEFAULT_LINKER - GNU ld)])
 215   fi
 216 else
 217   AC_MSG_RESULT(no)
 218 fi
 219
 220 # With demangler in GNU ld
 221 AC_ARG_WITH(demangler-in-ld,
 222 [  --with-demangler-in-ld  try to use demangler in GNU ld.],
 223 demangler_in_ld="$with_demangler_in_ld",
 224 demangler_in_ld=no)
 225
 226 # ----------------------
 227 # Find default assembler
 228 # ----------------------
 229
 230 # With GNU as
 231 AC_ARG_WITH(gnu-as,
 232 [  --with-gnu-as           arrange to work with GNU as],
 233 gas_flag="$with_gnu_as",
 234 gas_flag=no)
 235
 236 AC_ARG_WITH(as,
 237 [  --with-as               arrange to use the specified as (full pathname)],
 238 DEFAULT_ASSEMBLER="$with_as")
 239 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
 240   if test ! -x "$DEFAULT_ASSEMBLER"; then
 241     AC_MSG_ERROR([cannot execute: $DEFAULT_ASSEMBLER: check --with-as or env. var. DEFAULT_ASSEMBLER])
 242   elif $DEFAULT_ASSEMBLER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
 243     gas_flag=yes
 244   fi
 245   AC_DEFINE_UNQUOTED(DEFAULT_ASSEMBLER,"$DEFAULT_ASSEMBLER",
 246         [Define to enable the use of a default assembler.])
 247 fi
 248
 249 gnu_as=`if test x"$gas_flag" = x"yes"; then echo 1; else echo 0; fi`
 250 AC_DEFINE_UNQUOTED(HAVE_GNU_AS, $gnu_as, [Define if using GNU as.])
 251
 252 AC_MSG_CHECKING([whether a default assembler was specified])
 253 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
 254   if test x"$gas_flag" = x"no"; then
 255     AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER)])
 256   else
 257     AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER - GNU as)])
 258   fi
 259 else
 260   AC_MSG_RESULT(no)
 261 fi
 262
 263 # ---------------
 264 # Find C compiler
 265 # ---------------
 266
 267 # If a non-executable a.out is present (e.g. created by GNU as above even if
 268 # invoked with -v only), the IRIX 6 native ld just overwrites the existing
 269 # file, even when creating an executable, so an execution test fails.
 270 # Remove possible default executable files to avoid this.
 271 #
 272 # FIXME: This really belongs into AC_PROG_CC and can be removed once
 273 # Autoconf includes it.
 274 rm -f a.out a.exe b.out
 275
 276 # Find the native compiler
 277 AC_PROG_CC
 278 AM_PROG_CC_C_O
 279 ACX_PROG_GNAT([-I"$srcdir"/ada])
 280
 281 # autoconf is lame and doesn't give us any substitution variable for this.
 282 if eval "test \"`echo '$ac_cv_prog_cc_'${ac_cc}_c_o`\" = no"; then
 283   NO_MINUS_C_MINUS_O=yes
 284 else
 285   OUTPUT_OPTION='-o $@'
 286 fi
 287 AC_SUBST(NO_MINUS_C_MINUS_O)
 288 AC_SUBST(OUTPUT_OPTION)
 289
 290 # Remove the -O2: for historical reasons, unless bootstrapping we prefer
 291 # optimizations to be activated explicitly by the toplevel.
 292 case "$CC" in
 293   */prev-gcc/xgcc*) ;;
 294   *) CFLAGS=`echo $CFLAGS | sed "s/-O[[s0-9]]* *//" ` ;;
 295 esac
 296 AC_SUBST(CFLAGS)
 297
 298 # -------------------------
 299 # Check C compiler features
 300 # -------------------------
 301
 302 AC_USE_SYSTEM_EXTENSIONS
 303 AC_PROG_CPP
 304 AC_C_INLINE
 305
 306 # sizeof(char) is 1 by definition.
 307 AC_CHECK_SIZEOF(void *)
 308 AC_CHECK_SIZEOF(short)
 309 AC_CHECK_SIZEOF(int)
 310 AC_CHECK_SIZEOF(long)
 311 AC_CHECK_TYPES([long long], [AC_CHECK_SIZEOF(long long)])
 312 AC_CHECK_TYPES([__int64], [AC_CHECK_SIZEOF(__int64)])
 313
 314 # ---------------------
 315 # Warnings and checking
 316 # ---------------------
 317
 318 # Check $CC warning features (if it's GCC).
 319 # We want to use -pedantic, but we don't want warnings about
 320 # * 'long long'
 321 # * variadic macros
 322 # * overlong strings
 323 # So, we only use -pedantic if we can disable those warnings.
 324
 325 ACX_PROG_CC_WARNING_OPTS([-W -Wall -Wwrite-strings -Wstrict-prototypes \
 326                           -Wmissing-prototypes], [loose_warn])
 327 ACX_PROG_CC_WARNING_OPTS([-Wc++-compat], [cxx_compat_warn])
 328 ACX_PROG_CC_WARNING_OPTS([-Wold-style-definition \
 329                           -Wmissing-format-attribute], [strict_warn])
 330 ACX_PROG_CC_WARNING_ALMOST_PEDANTIC([-Wno-long-long -Wno-variadic-macros \
 331                                      -Wno-overlength-strings], [strict_warn])
 332 ACX_PROG_CC_WARNINGS_ARE_ERRORS([manual], [strict_warn])
 333
 334 # The above macros do nothing if the compiler is not GCC.  However, the
 335 # Makefile has more goo to add other flags, so this variabl is used to
 336 # enables warnings only for GCC.
 337 warn_cflags=
 338 if test "x$GCC" = "xyes"; then
 339   warn_cflags='$(GCC_WARN_CFLAGS)'
 340 fi
 341 AC_SUBST(warn_cflags)
 342
 343 # Enable expensive internal checks
 344 is_release=
 345 if test x"`cat $srcdir/DEV-PHASE`" != xexperimental; then
 346   is_release=yes
 347 fi
 348
 349 AC_ARG_ENABLE(checking,
 350 [  --enable-checking[=LIST]
 351                           enable expensive run-time checks.  With LIST,
 352                           enable only specific categories of checks.
 353                           Categories are: yes,no,all,none,release.
 354                           Flags are: assert,df,fold,gc,gcac,misc,
 355                           rtlflag,rtl,runtime,tree,valgrind,types.],
 356 [ac_checking_flags="${enableval}"],[
 357 # Determine the default checks.
 358 if test x$is_release = x ; then
 359   ac_checking_flags=yes
 360 else
 361   ac_checking_flags=release
 362 fi])
 363 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 364 for check in release $ac_checking_flags
 365 do
 366         case $check in
 367         # these set all the flags to specific states
 368         yes)            ac_assert_checking=1 ; ac_checking=1 ; ac_df_checking= ;
 369                         ac_fold_checking= ; ac_gc_checking=1 ;
 370                         ac_gc_always_collect= ; ac_rtl_checking= ;
 371                         ac_rtlflag_checking=1 ; ac_runtime_checking=1 ;
 372                         ac_tree_checking=1 ; ac_valgrind_checking= ;
 373                         ac_types_checking=1 ;;
 374         no|none)        ac_assert_checking= ; ac_checking= ; ac_df_checking= ;
 375                         ac_fold_checking= ; ac_gc_checking= ;
 376                         ac_gc_always_collect= ; ac_rtl_checking= ;
 377                         ac_rtlflag_checking= ; ac_runtime_checking= ;
 378                         ac_tree_checking= ; ac_valgrind_checking= ;
 379                         ac_types_checking= ;;
 380         all)            ac_assert_checking=1 ; ac_checking=1 ; ac_df_checking=1 ;
 381                         ac_fold_checking=1 ; ac_gc_checking=1 ;
 382                         ac_gc_always_collect=1 ; ac_rtl_checking=1 ;
 383                         ac_rtlflag_checking=1 ; ac_runtime_checking=1 ;
 384                         ac_tree_checking=1 ; ac_valgrind_checking= ;
 385                         ac_types_checking=1 ;;
 386         release)        ac_assert_checking=1 ; ac_checking= ; ac_df_checking= ;
 387                         ac_fold_checking= ; ac_gc_checking= ;
 388                         ac_gc_always_collect= ; ac_rtl_checking= ;
 389                         ac_rtlflag_checking= ; ac_runtime_checking=1 ;
 390                         ac_tree_checking= ; ac_valgrind_checking= ;
 391                         ac_types_checking= ;;
 392         # these enable particular checks
 393         assert)         ac_assert_checking=1 ;;
 394         df)             ac_df_checking=1 ;;
 395         fold)           ac_fold_checking=1 ;;
 396         gc)             ac_gc_checking=1 ;;
 397         gcac)           ac_gc_always_collect=1 ;;
 398         misc)           ac_checking=1 ;;
 399         rtl)            ac_rtl_checking=1 ;;
 400         rtlflag)        ac_rtlflag_checking=1 ;;
 401         runtime)        ac_runtime_checking=1 ;;
 402         tree)           ac_tree_checking=1 ;;
 403         types)          ac_types_checking=1 ;;
 404         valgrind)       ac_valgrind_checking=1 ;;
 405         *)      AC_MSG_ERROR(unknown check category $check) ;;
 406         esac
 407 done
 408 IFS="$ac_save_IFS"
 409
 410 nocommon_flag=""
 411 if test x$ac_checking != x ; then
 412   AC_DEFINE(ENABLE_CHECKING, 1,
 413 [Define if you want more run-time sanity checks.  This one gets a grab
 414    bag of miscellaneous but relatively cheap checks.])
 415   nocommon_flag=-fno-common
 416 fi
 417 AC_SUBST(nocommon_flag)
 418 if test x$ac_df_checking != x ; then
 419   AC_DEFINE(ENABLE_DF_CHECKING, 1,
 420 [Define if you want more run-time sanity checks for dataflow.])
 421 fi
 422 if test x$ac_assert_checking != x ; then
 423   AC_DEFINE(ENABLE_ASSERT_CHECKING, 1,
 424 [Define if you want assertions enabled.  This is a cheap check.])
 425 fi
 426 GCC_TARGET_TEMPLATE(ENABLE_RUNTIME_CHECKING)
 427 if test x$ac_runtime_checking != x ; then
 428   AC_DEFINE(ENABLE_RUNTIME_CHECKING, 1,
 429 [Define if you want runtime assertions enabled.  This is a cheap check.])
 430 fi
 431 if test x$ac_tree_checking != x ; then
 432   AC_DEFINE(ENABLE_TREE_CHECKING, 1,
 433 [Define if you want all operations on trees (the basic data
 434    structure of the front ends) to be checked for dynamic type safety
 435    at runtime.  This is moderately expensive.  The tree browser debugging
 436    routines will also be enabled by this option.
 437    ])
 438   TREEBROWSER=tree-browser.o
 439 fi
 440 if test x$ac_types_checking != x ; then
 441   AC_DEFINE(ENABLE_TYPES_CHECKING, 1,
 442 [Define if you want all gimple types to be verified after gimplifiation.
 443    This is cheap.
 444    ])
 445 fi
 446 AC_SUBST(TREEBROWSER)
 447 if test x$ac_rtl_checking != x ; then
 448   AC_DEFINE(ENABLE_RTL_CHECKING, 1,
 449 [Define if you want all operations on RTL (the basic data structure
 450    of the optimizer and back end) to be checked for dynamic type safety
 451    at runtime.  This is quite expensive.])
 452 fi
 453 if test x$ac_rtlflag_checking != x ; then
 454   AC_DEFINE(ENABLE_RTL_FLAG_CHECKING, 1,
 455 [Define if you want RTL flag accesses to be checked against the RTL
 456    codes that are supported for each access macro.  This is relatively
 457    cheap.])
 458 fi
 459 if test x$ac_gc_checking != x ; then
 460   AC_DEFINE(ENABLE_GC_CHECKING, 1,
 461 [Define if you want the garbage collector to do object poisoning and
 462    other memory allocation checks.  This is quite expensive.])
 463 fi
 464 if test x$ac_gc_always_collect != x ; then
 465   AC_DEFINE(ENABLE_GC_ALWAYS_COLLECT, 1,
 466 [Define if you want the garbage collector to operate in maximally
 467    paranoid mode, validating the entire heap and collecting garbage at
 468    every opportunity.  This is extremely expensive.])
 469 fi
 470 if test x$ac_fold_checking != x ; then
 471   AC_DEFINE(ENABLE_FOLD_CHECKING, 1,
 472 [Define if you want fold checked that it never destructs its argument.
 473    This is quite expensive.])
 474 fi
 475 valgrind_path_defines=
 476 valgrind_command=
 477
 478 dnl # This check AC_REQUIREs various stuff, so it *must not* be inside
 479 dnl # an if statement.  This was the source of very frustrating bugs
 480 dnl # in converting to autoconf 2.5x!
 481 AC_CHECK_HEADER(valgrind.h, have_valgrind_h=yes, have_valgrind_h=no)
 482
 483 if test x$ac_valgrind_checking != x ; then
 484   # It is certainly possible that there's valgrind but no valgrind.h.
 485   # GCC relies on making annotations so we must have both.
 486   AC_MSG_CHECKING(for VALGRIND_DISCARD in <valgrind/memcheck.h>)
 487   AC_PREPROC_IFELSE([AC_LANG_SOURCE(
 488     [[#include <valgrind/memcheck.h>
 489 #ifndef VALGRIND_DISCARD
 490 #error VALGRIND_DISCARD not defined
 491 #endif]])],
 492   [gcc_cv_header_valgrind_memcheck_h=yes],
 493   [gcc_cv_header_valgrind_memcheck_h=no])
 494   AC_MSG_RESULT($gcc_cv_header_valgrind_memcheck_h)
 495   AC_MSG_CHECKING(for VALGRIND_DISCARD in <memcheck.h>)
 496   AC_PREPROC_IFELSE([AC_LANG_SOURCE(
 497     [[#include <memcheck.h>
 498 #ifndef VALGRIND_DISCARD
 499 #error VALGRIND_DISCARD not defined
 500 #endif]])],
 501   [gcc_cv_header_memcheck_h=yes],
 502   [gcc_cv_header_memcheck_h=no])
 503   AC_MSG_RESULT($gcc_cv_header_memcheck_h)
 504   AM_PATH_PROG_WITH_TEST(valgrind_path, valgrind,
 505         [$ac_dir/$ac_word --version | grep valgrind- >/dev/null 2>&1])
 506   if test "x$valgrind_path" = "x" \
 507     || (test $have_valgrind_h = no \
 508         && test $gcc_cv_header_memcheck_h = no \
 509         && test $gcc_cv_header_valgrind_memcheck_h = no); then
 510         AC_MSG_ERROR([*** Can't find both valgrind and valgrind/memcheck.h, memcheck.h or valgrind.h])
 511   fi
 512   valgrind_path_defines=-DVALGRIND_PATH='\"'$valgrind_path'\"'
 513   valgrind_command="$valgrind_path -q"
 514   AC_DEFINE(ENABLE_VALGRIND_CHECKING, 1,
 515 [Define if you want to run subprograms and generated programs
 516    through valgrind (a memory checker).  This is extremely expensive.])
 517   if test $gcc_cv_header_valgrind_memcheck_h = yes; then
 518     AC_DEFINE(HAVE_VALGRIND_MEMCHECK_H, 1,
 519         [Define if valgrind's valgrind/memcheck.h header is installed.])
 520   fi
 521   if test $gcc_cv_header_memcheck_h = yes; then
 522     AC_DEFINE(HAVE_MEMCHECK_H, 1,
 523         [Define if valgrind's memcheck.h header is installed.])
 524   fi
 525 fi
 526 AC_SUBST(valgrind_path_defines)
 527 AC_SUBST(valgrind_command)
 528
 529 # Enable code coverage collection
 530 AC_ARG_ENABLE(coverage,
 531 [  --enable-coverage[=LEVEL]
 532                           enable compiler's code coverage collection.
 533                           Use to measure compiler performance and locate
 534                           unused parts of the compiler. With LEVEL, specify
 535                           optimization. Values are opt, noopt,
 536                           default is noopt],
 537 [case "${enableval}" in
 538   yes|noopt)
 539     coverage_flags="-fprofile-arcs -ftest-coverage -frandom-seed=\$@ -O0"
 540     ;;
 541   opt)
 542     coverage_flags="-fprofile-arcs -ftest-coverage -frandom-seed=\$@ -O2"
 543     ;;
 544   no)
 545     # a.k.a. --disable-coverage
 546     coverage_flags=""
 547     ;;
 548   *)
 549     AC_MSG_ERROR(unknown coverage setting $enableval)
 550     ;;
 551 esac],
 552 [coverage_flags=""])
 553 AC_SUBST(coverage_flags)
 554
 555 AC_ARG_ENABLE(gather-detailed-mem-stats,
 556 [  --enable-gather-detailed-mem-stats         enable detailed memory allocation stats gathering], [],
 557 [enable_gather_detailed_mem_stats=no])
 558 if test x$enable_gather_detailed_mem_stats = xyes ; then
 559   AC_DEFINE(GATHER_STATISTICS, 1,
 560         [Define to enable detailed memory allocation stats gathering.])
 561 fi
 562
 563 # -------------------------------
 564 # Miscenalleous configure options
 565 # -------------------------------
 566
 567 # With stabs
 568 AC_ARG_WITH(stabs,
 569 [  --with-stabs            arrange to use stabs instead of host debug format],
 570 stabs="$with_stabs",
 571 stabs=no)
 572
 573 # Determine whether or not multilibs are enabled.
 574 AC_ARG_ENABLE(multilib,
 575 [  --enable-multilib       enable library support for multiple ABIs],
 576 [], [enable_multilib=yes])
 577 AC_SUBST(enable_multilib)
 578
 579 # Enable __cxa_atexit for C++.
 580 AC_ARG_ENABLE(__cxa_atexit,
 581 [  --enable-__cxa_atexit   enable __cxa_atexit for C++],
 582 [], [])
 583
 584 # Enable C extension for decimal float if target supports it.
 585 AC_ARG_ENABLE(decimal-float,
 586 [  --enable-decimal-float={no,yes,bid,dpd}
 587                         enable decimal float extension to C.  Selecting 'bid'
 588                         or 'dpd' choses which decimal floating point format
 589                         to use],
 590 [
 591   case $enable_decimal_float in
 592     yes | no | bid | dpd) ;;
 593     *) AC_MSG_ERROR(['$enable_decimal_float' is an invalid value for --enable-decimal-float.
 594 Valid choices are 'yes', 'bid', 'dpd', and 'no'.]) ;;
 595   esac
 596 ],
 597 [
 598   case $target in
 599     powerpc*-*-linux* | i?86*-*-linux* | x86_64*-*-linux*)
 600       enable_decimal_float=yes
 601       ;;
 602     *)
 603       AC_MSG_WARN(decimal float is not supported for this target, ignored)
 604       enable_decimal_float=no
 605       ;;
 606   esac
 607 ])
 608
 609 dfp=`if test $enable_decimal_float != no; then echo 1; else echo 0; fi`
 610 AC_DEFINE_UNQUOTED(ENABLE_DECIMAL_FLOAT, $dfp,
 611 [Define to 1 to enable decimal float extension to C.])
 612
 613 # x86's use BID format instead of DPD
 614 case x$enable_decimal_float in
 615   xyes)
 616     case $target in
 617       i?86*-*-linux* | x86_64*-*-linux*)
 618         enable_decimal_float=bid
 619         ;;
 620       *)
 621         enable_decimal_float=dpd
 622         ;;
 623     esac
 624     ;;
 625   xno)
 626     # ENABLE_DECIMAL_FLOAT is set to 0. But we have to have proper
 627     # dependency on libdecnumber.
 628     enable_decimal_float=dpd
 629     ;;
 630 esac
 631 AC_SUBST(enable_decimal_float)
 632
 633 bid=`if test $enable_decimal_float = bid; then echo 1; else echo 0; fi`
 634 AC_DEFINE_UNQUOTED(ENABLE_DECIMAL_BID_FORMAT, $bid,
 635 [Define to 1 to specify that we are using the BID decimal floating
 636 point format instead of DPD])
 637
 638 # Enable C extension for fixed-point arithmetic.
 639 AC_ARG_ENABLE(fixed-point,
 640 [  --enable-fixed-point    enable fixed-point arithmetic extension to C],
 641 [
 642 ],
 643 [
 644   case $target in
 645     mips*-*-*)
 646       case $host in
 647         mips*-sgi-irix*)
 648           AC_MSG_WARN(fixed-point is not supported on IRIX, ignored)
 649           enable_fixed_point=no
 650           ;;
 651         *)
 652           enable_fixed_point=yes
 653           ;;
 654       esac
 655       ;;
 656     *)
 657       AC_MSG_WARN(fixed-point is not supported for this target, ignored)
 658       enable_fixed_point=no
 659       ;;
 660   esac
 661 ])
 662 AC_SUBST(enable_fixed_point)
 663
 664 fixedpoint=`if test $enable_fixed_point = yes; then echo 1; else echo 0; fi`
 665 AC_DEFINE_UNQUOTED(ENABLE_FIXED_POINT, $fixedpoint,
 666 [Define to 1 to enable fixed-point arithmetic extension to C.])
 667
 668 # Enable threads
 669 # Pass with no value to take the default
 670 # Pass with a value to specify a thread package
 671 AC_ARG_ENABLE(threads,
 672 [  --enable-threads        enable thread usage for target GCC
 673   --enable-threads=LIB    use LIB thread package for target GCC],,
 674 [enable_threads=''])
 675
 676 AC_ARG_ENABLE(tls,
 677 [  --enable-tls            enable or disable generation of tls code
 678                           overriding the assembler check for tls support],
 679 [
 680   case $enable_tls in
 681     yes | no) ;;
 682     *) AC_MSG_ERROR(['$enable_tls' is an invalid value for --enable-tls.
 683 Valid choices are 'yes' and 'no'.]) ;;
 684   esac
 685 ], [enable_tls=''])
 686
 687 AC_ARG_ENABLE(objc-gc,
 688 [  --enable-objc-gc       enable the use of Boehm's garbage collector with
 689                           the GNU Objective-C runtime],
 690 if test x$enable_objc_gc = xno; then
 691         objc_boehm_gc=''
 692 else
 693         objc_boehm_gc=1
 694 fi,
 695 objc_boehm_gc='')
 696
 697 AC_ARG_WITH(dwarf2,
 698 [  --with-dwarf2           force the default debug format to be DWARF 2],
 699 dwarf2="$with_dwarf2",
 700 dwarf2=no)
 701
 702 AC_ARG_ENABLE(shared,
 703 [  --disable-shared        don't provide a shared libgcc],
 704 [
 705   case $enable_shared in
 706   yes | no) ;;
 707   *)
 708     enable_shared=no
 709     IFS="${IFS=         }"; ac_save_ifs="$IFS"; IFS="${IFS}:,"
 710     for pkg in $enableval; do
 711       if test "X$pkg" = "Xgcc" || test "X$pkg" = "Xlibgcc"; then
 712         enable_shared=yes
 713       fi
 714     done
 715     IFS="$ac_save_ifs"
 716     ;;
 717   esac
 718 ], [enable_shared=yes])
 719 AC_SUBST(enable_shared)
 720
 721 AC_ARG_WITH(build-sysroot,
 722   [  --with-build-sysroot=sysroot
 723                           use sysroot as the system root during the build])
 724
 725 AC_ARG_WITH(sysroot,
 726 [  --with-sysroot[=DIR] Search for usr/lib, usr/include, et al, within DIR.],
 727 [
 728  case ${with_sysroot} in
 729  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_noncanonical}/sys-root' ;;
 730  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
 731  esac
 732
 733  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
 734  CROSS_SYSTEM_HEADER_DIR='$(TARGET_SYSTEM_ROOT)$${sysroot_headers_suffix}$(NATIVE_SYSTEM_HEADER_DIR)'
 735
 736  if test "x$prefix" = xNONE; then
 737   test_prefix=/usr/local
 738  else
 739   test_prefix=$prefix
 740  fi
 741  if test "x$exec_prefix" = xNONE; then
 742   test_exec_prefix=$test_prefix
 743  else
 744   test_exec_prefix=$exec_prefix
 745  fi
 746  case ${TARGET_SYSTEM_ROOT} in
 747  "${test_prefix}"|"${test_prefix}/"*|\
 748  "${test_exec_prefix}"|"${test_exec_prefix}/"*|\
 749  '${prefix}'|'${prefix}/'*|\
 750  '${exec_prefix}'|'${exec_prefix}/'*)
 751    t="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE"
 752    TARGET_SYSTEM_ROOT_DEFINE="$t"
 753    ;;
 754  esac
 755 ], [
 756  TARGET_SYSTEM_ROOT=
 757  TARGET_SYSTEM_ROOT_DEFINE=
 758  CROSS_SYSTEM_HEADER_DIR='$(gcc_tooldir)/sys-include'
 759 ])
 760 AC_SUBST(TARGET_SYSTEM_ROOT)
 761 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
 762 AC_SUBST(CROSS_SYSTEM_HEADER_DIR)
 763
 764 # Build with intermodule optimisations
 765 AC_ARG_ENABLE(intermodule,
 766 [  --enable-intermodule    build the compiler in one step],
 767 [case ${enable_intermodule} in
 768   yes) onestep="-onestep";;
 769   *) onestep="";;
 770 esac],
 771 [onestep=""])
 772 AC_SUBST(onestep)
 773
 774 ACX_PKGVERSION([GCC])
 775 ACX_BUGURL([http://gcc.gnu.org/bugs.html])
 776
 777 # Sanity check enable_languages in case someone does not run the toplevel
 778 # configure # script.
 779 AC_ARG_ENABLE(languages,
 780 [  --enable-languages=LIST specify which front-ends to build],
 781 [case ,${enable_languages}, in
 782        ,,|,yes,)
 783                 # go safe -- we cannot be much sure without the toplevel
 784                 # configure's
 785                 # analysis of which target libs are present and usable
 786                 enable_languages=c
 787                 ;;
 788          *,all,*)
 789                 AC_MSG_ERROR([only the toplevel supports --enable-languages=all])
 790                 ;;
 791         *,c,*)
 792                 ;;
 793         *)
 794                 enable_languages=c,${enable_languages}
 795                 ;;
 796 esac],
 797 [enable_languages=c])
 798
 799 # Used by documentation targets
 800 AC_SUBST(datarootdir)
 801 AC_SUBST(docdir)
 802 AC_SUBST(htmldir)
 803
 804 # -------------------------
 805 # Checks for other programs
 806 # -------------------------
 807
 808 AC_PROG_MAKE_SET
 809
 810 # Find some useful tools
 811 AC_PROG_AWK
 812 # We need awk to create options.c and options.h.
 813 # Bail out if it's missing.
 814 case ${AWK} in
 815   "") AC_MSG_ERROR([can't build without awk, bailing out]) ;;
 816 esac
 817
 818 gcc_AC_PROG_LN_S
 819 ACX_PROG_LN($LN_S)
 820 AC_PROG_RANLIB
 821 case "${host}" in
 822 *-*-darwin*)
 823   # By default, the Darwin ranlib will not treat common symbols as
 824   # definitions when  building the archive table of contents.  Other
 825   # ranlibs do that; pass an option to the Darwin ranlib that makes
 826   # it behave similarly.
 827   ranlib_flags="-c"
 828   ;;
 829 *)
 830   ranlib_flags=""
 831 esac
 832 AC_SUBST(ranlib_flags)
 833
 834 gcc_AC_PROG_INSTALL
 835
 836 # See if cmp has --ignore-initial.
 837 gcc_AC_PROG_CMP_IGNORE_INITIAL
 838
 839 # See if we have the mktemp command.
 840 AC_CHECK_PROG(have_mktemp_command, mktemp, yes, no)
 841
 842 # See if makeinfo has been installed and is modern enough
 843 # that we can use it.
 844 ACX_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
 845   [GNU texinfo.* \([0-9][0-9.]*\)],
 846   [4.[4-9]*|4.[1-9][0-9]*|[5-9]*|[1-9][0-9]*])
 847 if test $gcc_cv_prog_makeinfo_modern = no; then
 848   AC_MSG_WARN([
 849 *** Makeinfo is missing or too old.
 850 *** Info documentation will not be built.])
 851   BUILD_INFO=
 852 else
 853   BUILD_INFO=info
 854 fi
 855 AC_SUBST(BUILD_INFO)
 856
 857 # Is pod2man recent enough to regenerate manpages?
 858 AC_MSG_CHECKING([for recent Pod::Man])
 859 if (perl -e 'use 1.10 Pod::Man') >/dev/null 2>&1; then
 860   AC_MSG_RESULT(yes)
 861   GENERATED_MANPAGES=generated-manpages
 862 else
 863   AC_MSG_RESULT(no)
 864   GENERATED_MANPAGES=
 865 fi
 866 AC_SUBST(GENERATED_MANPAGES)
 867
 868 MISSING="${CONFIG_SHELL-/bin/sh} $ac_aux_dir/missing"
 869
 870 # How about lex?
 871 dnl Don't use AC_PROG_LEX; we insist on flex.
 872 dnl LEXLIB is not useful in gcc.
 873 AC_CHECK_PROGS([FLEX], flex, [$MISSING flex])
 874
 875 # Bison?
 876 AC_CHECK_PROGS([BISON], bison, [$MISSING bison])
 877
 878 # Binutils are not build modules, unlike bison/flex/makeinfo.  So we
 879 # check for build == host before using them.
 880
 881 # NM
 882 if test x${build} = x${host} && test -f $srcdir/../binutils/nm.c \
 883   && test -d ../binutils ; then
 884   NM='$(objdir)/../binutils/nm-new'
 885 else
 886   AC_CHECK_PROG(NM, nm, nm, ${CONFIG_SHELL-/bin/sh} ${srcdir}/../missing nm)
 887 fi
 888
 889 # AR
 890 if test x${build} = x${host} && test -f $srcdir/../binutils/ar.c \
 891   && test -d ../binutils ; then
 892   AR='$(objdir)/../binutils/ar'
 893 else
 894   AC_CHECK_PROG(AR, ar, ar, ${CONFIG_SHELL-/bin/sh} ${srcdir}/../missing ar)
 895 fi
 896
 897
 898 # --------------------
 899 # Checks for C headers
 900 # --------------------
 901
 902 # Need to reject headers which give warnings, so that the -Werror bootstrap
 903 # works later. *sigh*  This needs to come before all header checks.
 904 AC_PROG_CPP_WERROR
 905
 906 AC_HEADER_STDC
 907 AC_HEADER_TIME
 908 ACX_HEADER_STRING
 909 AC_HEADER_SYS_WAIT
 910 AC_CHECK_HEADERS(limits.h stddef.h string.h strings.h stdlib.h time.h iconv.h \
 911                  fcntl.h unistd.h sys/file.h sys/time.h sys/mman.h \
 912                  sys/resource.h sys/param.h sys/times.h sys/stat.h \
 913                  direct.h malloc.h langinfo.h ldfcn.h locale.h wchar.h)
 914
 915 # Check for thread headers.
 916 AC_CHECK_HEADER(thread.h, [have_thread_h=yes], [have_thread_h=])
 917 AC_CHECK_HEADER(pthread.h, [have_pthread_h=yes], [have_pthread_h=])
 918
 919 # These tests can't be done till we know if we have limits.h.
 920 gcc_AC_C_CHAR_BIT
 921 AC_C_BIGENDIAN
 922
 923 # --------
 924 # UNSORTED
 925 # --------
 926
 927
 928 # These libraries may be used by collect2.
 929 # We may need a special search path to get them linked.
 930 AC_CACHE_CHECK(for collect2 libraries, gcc_cv_collect2_libs,
 931 [save_LIBS="$LIBS"
 932 for libs in '' -lld -lmld \
 933                 '-L/usr/lib/cmplrs/cc2.11 -lmld' \
 934                 '-L/usr/lib/cmplrs/cc3.11 -lmld'
 935 do
 936         LIBS="$libs"
 937         AC_TRY_LINK_FUNC(ldopen,
 938                 [gcc_cv_collect2_libs="$libs"; break])
 939 done
 940 LIBS="$save_LIBS"
 941 test -z "$gcc_cv_collect2_libs" && gcc_cv_collect2_libs='none required'])
 942 case $gcc_cv_collect2_libs in
 943         "none required")        ;;
 944         *)      COLLECT2_LIBS=$gcc_cv_collect2_libs ;;
 945 esac
 946 AC_SUBST(COLLECT2_LIBS)
 947
 948 # When building Ada code on Alpha, we need exc_resume which is usually in
 949 # -lexc.  So test for it.
 950 save_LIBS="$LIBS"
 951 LIBS=
 952 AC_SEARCH_LIBS(exc_resume, exc)
 953 GNAT_LIBEXC="$LIBS"
 954 LIBS="$save_LIBS"
 955 AC_SUBST(GNAT_LIBEXC)
 956
 957 # Some systems put ldexp and frexp in libm instead of libc; assume
 958 # they're both in the same place.  jcf-dump needs them.
 959 save_LIBS="$LIBS"
 960 LIBS=
 961 AC_SEARCH_LIBS(ldexp, m)
 962 LDEXP_LIB="$LIBS"
 963 LIBS="$save_LIBS"
 964 AC_SUBST(LDEXP_LIB)
 965
 966 # Use <inttypes.h> only if it exists,
 967 # doesn't clash with <sys/types.h>, and declares intmax_t.
 968 AC_MSG_CHECKING(for inttypes.h)
 969 AC_CACHE_VAL(gcc_cv_header_inttypes_h,
 970 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 971 [[#include <sys/types.h>
 972 #include <inttypes.h>]],
 973   [[intmax_t i = -1;]])],
 974   [gcc_cv_header_inttypes_h=yes],
 975   [gcc_cv_header_inttypes_h=no])])
 976 AC_MSG_RESULT($gcc_cv_header_inttypes_h)
 977 if test $gcc_cv_header_inttypes_h = yes; then
 978   AC_DEFINE(HAVE_INTTYPES_H, 1,
 979         [Define if you have a working <inttypes.h> header file.])
 980 fi
 981
 982 dnl Disabled until we have a complete test for buggy enum bitfields.
 983 dnl gcc_AC_C_ENUM_BF_UNSIGNED
 984
 985 define(gcc_UNLOCKED_FUNCS, clearerr_unlocked feof_unlocked dnl
 986   ferror_unlocked fflush_unlocked fgetc_unlocked fgets_unlocked dnl
 987   fileno_unlocked fprintf_unlocked fputc_unlocked fputs_unlocked dnl
 988   fread_unlocked fwrite_unlocked getchar_unlocked getc_unlocked dnl
 989   putchar_unlocked putc_unlocked)
 990 AC_CHECK_FUNCS(times clock kill getrlimit setrlimit atoll atoq \
 991         sysconf strsignal getrusage nl_langinfo scandir alphasort \
 992         gettimeofday mbstowcs wcswidth mmap mincore setlocale \
 993         gcc_UNLOCKED_FUNCS)
 994
 995 if test x$ac_cv_func_mbstowcs = xyes; then
 996   AC_CACHE_CHECK(whether mbstowcs works, gcc_cv_func_mbstowcs_works,
 997 [    AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdlib.h>
 998 int main()
 999 {
1000   mbstowcs(0, "", 0);
1001   return 0;
1002 }]])],
1003     [gcc_cv_func_mbstowcs_works=yes],
1004     [gcc_cv_func_mbstowcs_works=no],
1005     [gcc_cv_func_mbstowcs_works=yes])])
1006   if test x$gcc_cv_func_mbstowcs_works = xyes; then
1007     AC_DEFINE(HAVE_WORKING_MBSTOWCS, 1,
1008   [Define this macro if mbstowcs does not crash when its
1009    first argument is NULL.])
1010   fi
1011 fi
1012
1013 AC_CHECK_TYPE(ssize_t, int)
1014
1015 # Try to determine the array type of the second argument of getgroups
1016 # for the target system (int or gid_t).
1017 AC_TYPE_GETGROUPS
1018 if test "${target}" = "${build}"; then
1019   TARGET_GETGROUPS_T=$ac_cv_type_getgroups
1020 else
1021   case "${target}" in
1022         # This condition may need some tweaking.  It should include all
1023         # targets where the array type of the second argument of getgroups
1024         # is int and the type of gid_t is not equivalent to int.
1025         *-*-sunos* | *-*-ultrix*)
1026                 TARGET_GETGROUPS_T=int
1027                 ;;
1028         *)
1029                 TARGET_GETGROUPS_T=gid_t
1030                 ;;
1031   esac
1032 fi
1033 AC_SUBST(TARGET_GETGROUPS_T)
1034
1035 gcc_AC_FUNC_MMAP_BLACKLIST
1036
1037 case "${host}" in
1038 *-*-*vms*)
1039   # Under VMS, vfork works very differently than on Unix. The standard test
1040   # won't work, and it isn't easily adaptable. It makes more sense to
1041   # just force it.
1042   ac_cv_func_vfork_works=yes
1043   ;;
1044 esac
1045 AC_FUNC_FORK
1046
1047 AM_ICONV
1048 # Until we have in-tree GNU iconv:
1049 LIBICONV_DEP=
1050 AC_SUBST(LIBICONV_DEP)
1051
1052 AM_LC_MESSAGES
1053
1054 AM_LANGINFO_CODESET
1055
1056 # We will need to find libiberty.h and ansidecl.h
1057 saved_CFLAGS="$CFLAGS"
1058 CFLAGS="$CFLAGS -I${srcdir} -I${srcdir}/../include"
1059 gcc_AC_CHECK_DECLS(getenv atol asprintf sbrk abort atof getcwd getwd \
1060         strsignal strstr strverscmp \
1061         errno snprintf vsnprintf vasprintf malloc realloc calloc \
1062         free basename getopt clock getpagesize gcc_UNLOCKED_FUNCS, , ,[
1063 #include "ansidecl.h"
1064 #include "system.h"])
1065
1066 gcc_AC_CHECK_DECLS(getrlimit setrlimit getrusage, , ,[
1067 #include "ansidecl.h"
1068 #include "system.h"
1069 #ifdef HAVE_SYS_RESOURCE_H
1070 #include <sys/resource.h>
1071 #endif
1072 ])
1073
1074 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1075 #include "ansidecl.h"
1076 #include "system.h"
1077 #ifdef HAVE_SYS_RESOURCE_H
1078 #include <sys/resource.h>
1079 #endif
1080 ]], [[rlim_t l = 0;]])],[],[AC_DEFINE([rlim_t],[long],
1081 [Define to `long' if <sys/resource.h> doesn't define.])])
1082
1083 # On AIX 5.2, <ldfcn.h> conflicts with <fcntl.h>, as both define incompatible
1084 # FREAD and FWRITE macros.  Fortunately, for GCC's single usage of ldgetname
1085 # in collect2.c, <fcntl.h> isn't visible, but the configure test below needs
1086 # to undef these macros to get the correct value for HAVE_DECL_LDGETNAME.
1087 gcc_AC_CHECK_DECLS(ldgetname, , ,[
1088 #include "ansidecl.h"
1089 #include "system.h"
1090 #ifdef HAVE_LDFCN_H
1091 #undef FREAD
1092 #undef FWRITE
1093 #include <ldfcn.h>
1094 #endif
1095 ])
1096
1097 gcc_AC_CHECK_DECLS(times, , ,[
1098 #include "ansidecl.h"
1099 #include "system.h"
1100 #ifdef HAVE_SYS_TIMES_H
1101 #include <sys/times.h>
1102 #endif
1103 ])
1104
1105 gcc_AC_CHECK_DECLS(sigaltstack, , ,[
1106 #include "ansidecl.h"
1107 #include "system.h"
1108 #include <signal.h>
1109 ])
1110
1111 # More time-related stuff.
1112 AC_CACHE_CHECK(for struct tms, ac_cv_struct_tms, [
1113 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1114 #include "ansidecl.h"
1115 #include "system.h"
1116 #ifdef HAVE_SYS_TIMES_H
1117 #include <sys/times.h>
1118 #endif
1119 ]], [[struct tms tms;]])],[ac_cv_struct_tms=yes],[ac_cv_struct_tms=no])])
1120 if test $ac_cv_struct_tms = yes; then
1121   AC_DEFINE(HAVE_STRUCT_TMS, 1,
1122   [Define if <sys/times.h> defines struct tms.])
1123 fi
1124
1125 # use gcc_cv_* here because this doesn't match the behavior of AC_CHECK_TYPE.
1126 # revisit after autoconf 2.50.
1127 AC_CACHE_CHECK(for clock_t, gcc_cv_type_clock_t, [
1128 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1129 #include "ansidecl.h"
1130 #include "system.h"
1131 ]], [[clock_t x;]])],[gcc_cv_type_clock_t=yes],[gcc_cv_type_clock_t=no])])
1132 if test $gcc_cv_type_clock_t = yes; then
1133   AC_DEFINE(HAVE_CLOCK_T, 1,
1134   [Define if <time.h> defines clock_t.])
1135 fi
1136
1137 # Restore CFLAGS from before the gcc_AC_NEED_DECLARATIONS tests.
1138 CFLAGS="$saved_CFLAGS"
1139
1140 gcc_AC_INITFINI_ARRAY
1141
1142 # mkdir takes a single argument on some systems.
1143 gcc_AC_FUNC_MKDIR_TAKES_ONE_ARG
1144
1145 # File extensions
1146 manext='.1'
1147 objext='.o'
1148 AC_SUBST(manext)
1149 AC_SUBST(objext)
1150
1151 # With Setjmp/Longjmp based exception handling.
1152 AC_ARG_ENABLE(sjlj-exceptions,
1153 [  --enable-sjlj-exceptions
1154                           arrange to use setjmp/longjmp exception handling],
1155 [case $target in
1156   *-*-hpux10*)
1157     if test $enableval != yes; then
1158       AC_MSG_WARN([dwarf2 exceptions not supported, sjlj exceptions forced])
1159       enableval=yes
1160     fi
1161     ;;
1162 esac
1163 force_sjlj_exceptions=yes],
1164 [case $target in
1165   *-*-hpux10*)
1166     force_sjlj_exceptions=yes
1167     enableval=yes
1168     ;;
1169   *)
1170     force_sjlj_exceptions=no
1171     ;;
1172 esac])
1173 if test $force_sjlj_exceptions = yes; then
1174   sjlj=`if test $enableval = yes; then echo 1; else echo 0; fi`
1175   AC_DEFINE_UNQUOTED(CONFIG_SJLJ_EXCEPTIONS, $sjlj,
1176     [Define 0/1 to force the choice for exception handling model.])
1177 fi
1178
1179 # For platforms with the unwind ABI which includes an unwind library,
1180 # libunwind, we can choose to use the system libunwind.
1181 AC_ARG_WITH(system-libunwind,
1182 [  --with-system-libunwind use installed libunwind])
1183
1184 # config.gcc also contains tests of with_system_libunwind.
1185 if test x$with_system_libunwind = xyes; then
1186         AC_DEFINE(HAVE_GETIPINFO, 1,
1187 [Define to 1 if system unwind library has _Unwind_GetIPInfo.])
1188 fi
1189
1190 # --------------------------------------------------------
1191 # Build, host, and target specific configuration fragments
1192 # --------------------------------------------------------
1193
1194 # Collect build-machine-specific information.
1195 . ${srcdir}/config.build
1196
1197 # Collect host-machine-specific information.
1198 . ${srcdir}/config.host
1199
1200 target_gtfiles=
1201
1202 # Collect target-machine-specific information.
1203 . ${srcdir}/config.gcc
1204
1205 extra_objs="${host_extra_objs} ${extra_objs}"
1206 extra_gcc_objs="${host_extra_gcc_objs} ${extra_gcc_objs}"
1207
1208 # Default the target-machine variables that were not explicitly set.
1209 if test x"$tm_file" = x
1210 then tm_file=$cpu_type/$cpu_type.h; fi
1211
1212 if test x"$extra_headers" = x
1213 then extra_headers=; fi
1214
1215 if test x$md_file = x
1216 then md_file=$cpu_type/$cpu_type.md; fi
1217
1218 if test x$out_file = x
1219 then out_file=$cpu_type/$cpu_type.c; fi
1220
1221 if test x"$tmake_file" = x
1222 then tmake_file=$cpu_type/t-$cpu_type
1223 fi
1224
1225 if test x"$dwarf2" = xyes
1226 then tm_file="$tm_file tm-dwarf2.h"
1227 fi
1228
1229 # Say what files are being used for the output code and MD file.
1230 echo "Using \`$srcdir/config/$out_file' for machine-specific logic."
1231 echo "Using \`$srcdir/config/$md_file' as machine description file."
1232
1233 # If any of the xm_file variables contain nonexistent files, warn
1234 # about them and drop them.
1235
1236 bx=
1237 for x in $build_xm_file; do
1238   if    test -f $srcdir/config/$x
1239   then      bx="$bx $x"
1240   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1241   fi
1242 done
1243 build_xm_file="$bx"
1244
1245 hx=
1246 for x in $host_xm_file; do
1247   if    test -f $srcdir/config/$x
1248   then      hx="$hx $x"
1249   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1250   fi
1251 done
1252 host_xm_file="$hx"
1253
1254 tx=
1255 for x in $xm_file; do
1256   if    test -f $srcdir/config/$x
1257   then      tx="$tx $x"
1258   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1259   fi
1260 done
1261 xm_file="$tx"
1262
1263 count=a
1264 for f in $tm_file; do
1265         count=${count}x
1266 done
1267 if test $count = ax; then
1268         echo "Using \`$srcdir/config/$tm_file' as target machine macro file."
1269 else
1270         echo "Using the following target machine macro files:"
1271         for f in $tm_file; do
1272                 echo "  $srcdir/config/$f"
1273         done
1274 fi
1275
1276 if test x$need_64bit_hwint = xyes; then
1277         AC_DEFINE(NEED_64BIT_HOST_WIDE_INT, 1,
1278 [Define to 1 if HOST_WIDE_INT must be 64 bits wide (see hwint.h).])
1279 fi
1280
1281 if test x$use_long_long_for_widest_fast_int = xyes; then
1282         AC_DEFINE(USE_LONG_LONG_FOR_WIDEST_FAST_INT, 1,
1283 [Define to 1 if the 'long long' (or '__int64') is wider than 'long' but still
1284 efficiently supported by the host hardware.])
1285 fi
1286
1287 count=a
1288 for f in $host_xm_file; do
1289         count=${count}x
1290 done
1291 if test $count = a; then
1292         :
1293 elif test $count = ax; then
1294         echo "Using \`$srcdir/config/$host_xm_file' as host machine macro file."
1295 else
1296         echo "Using the following host machine macro files:"
1297         for f in $host_xm_file; do
1298                 echo "  $srcdir/config/$f"
1299         done
1300 fi
1301 echo "Using ${out_host_hook_obj} for host machine hooks."
1302
1303 if test "$host_xm_file" != "$build_xm_file"; then
1304         count=a
1305         for f in $build_xm_file; do
1306                 count=${count}x
1307         done
1308         if test $count = a; then
1309                 :
1310         elif test $count = ax; then
1311                 echo "Using \`$srcdir/config/$build_xm_file' as build machine macro file."
1312         else
1313                 echo "Using the following build machine macro files:"
1314                 for f in $build_xm_file; do
1315                         echo "  $srcdir/config/$f"
1316                 done
1317         fi
1318 fi
1319
1320 case ${host} in
1321   powerpc*-*-darwin*)
1322     AC_CACHE_CHECK([whether mcontext_t fields have underscores],
1323       gcc_cv_mcontext_underscores,
1324       AC_COMPILE_IFELSE([
1325 #include <sys/cdefs.h>
1326 #include <sys/signal.h>
1327 #include <ucontext.h>
1328 int main() { mcontext_t m; if (m->ss.srr0) return 0; return 0; }
1329 ],
1330         gcc_cv_mcontext_underscores=no, gcc_cv_mcontext_underscores=yes))
1331       if test $gcc_cv_mcontext_underscores = yes; then
1332         AC_DEFINE(HAS_MCONTEXT_T_UNDERSCORES,,dnl
1333           [mcontext_t fields start with __])
1334       fi
1335     ;;
1336 esac
1337
1338 # ---------
1339 # Threading
1340 # ---------
1341
1342 # Check if a valid thread package
1343 case ${enable_threads} in
1344   "" | no)
1345     # No threads
1346     target_thread_file='single'
1347     ;;
1348   yes)
1349     # default
1350     target_thread_file='single'
1351     ;;
1352   aix | dce | gnat | irix | posix | posix95 | rtems | \
1353   single | solaris | vxworks | win32 | mipssde)
1354     target_thread_file=${enable_threads}
1355     ;;
1356   *)
1357     echo "${enable_threads} is an unknown thread package" 1>&2
1358     exit 1
1359     ;;
1360 esac
1361
1362 if test x${thread_file} = x; then
1363   # No thread file set by target-specific clauses in config.gcc,
1364   # so use file chosen by default logic above
1365   thread_file=${target_thread_file}
1366 fi
1367
1368 # Make gthr-default.h if we have a thread file.
1369 gthread_flags=
1370 if test $thread_file != single; then
1371   echo "#include \"gthr-${thread_file}.h\"" > gthr-default.h-t
1372   if diff gthr-default.h-t gthr-default.h 2>/dev/null; then
1373     rm -f gthr-default.h-t
1374   else
1375     mv -f gthr-default.h-t gthr-default.h
1376   fi
1377   gthread_flags=-DHAVE_GTHR_DEFAULT
1378 fi
1379 AC_SUBST(gthread_flags)
1380
1381 # --------
1382 # UNSORTED
1383 # --------
1384
1385 use_cxa_atexit=no
1386 if test x$enable___cxa_atexit = xyes || \
1387    test x$enable___cxa_atexit = x -a x$default_use_cxa_atexit = xyes; then
1388   if test x$host = x$target; then
1389     case $host in
1390       # mingw32 doesn't have __cxa_atexit but uses atexit registration
1391       # keyed to flag_use_cxa_atexit
1392       *-*-mingw32*)
1393         use_cxa_atexit=yes
1394         ;;
1395       *)
1396         AC_CHECK_FUNC(__cxa_atexit,[use_cxa_atexit=yes],
1397           [echo "__cxa_atexit can't be enabled on this target"])
1398         ;;
1399     esac
1400   else
1401     # We can't check for __cxa_atexit when building a cross, so assume
1402     # it is available
1403     use_cxa_atexit=yes
1404   fi
1405   if test x$use_cxa_atexit = xyes; then
1406     AC_DEFINE(DEFAULT_USE_CXA_ATEXIT, 2,
1407       [Define if you want to use __cxa_atexit, rather than atexit, to
1408       register C++ destructors for local statics and global objects.
1409       This is essential for fully standards-compliant handling of
1410       destructors, but requires __cxa_atexit in libc.])
1411   fi
1412 fi
1413
1414 use_getipinfo=yes
1415 if test x$with_system_libunwind = xyes; then
1416    if test x$host = x$target; then
1417      AC_SEARCH_LIBS(_Unwind_GetIPInfo, unwind,, [use_getipinfo=no])
1418    fi
1419 fi
1420 GCC_TARGET_TEMPLATE(HAVE_GETIPINFO)
1421 if test x$use_getipinfo = xyes; then
1422    AC_DEFINE(HAVE_GETIPINFO, 1,
1423         [Define to 1 if system unwind library has _Unwind_GetIPInfo.])
1424 else
1425    echo "The system unwind library does not support _Unwind_GetIPInfo."
1426 fi
1427
1428 # Look for a file containing extra machine modes.
1429 if test -n "$extra_modes" && test -f $srcdir/config/$extra_modes; then
1430   extra_modes_file='$(srcdir)'/config/${extra_modes}
1431   AC_SUBST(extra_modes_file)
1432   AC_DEFINE_UNQUOTED(EXTRA_MODES_FILE, "config/$extra_modes",
1433   [Define to the name of a file containing a list of extra machine modes
1434    for this architecture.])
1435 fi
1436
1437 # Convert extra_options into a form suitable for Makefile use.
1438 extra_opt_files=
1439 for f in $extra_options; do
1440   extra_opt_files="$extra_opt_files \$(srcdir)/config/$f"
1441 done
1442 AC_SUBST(extra_opt_files)
1443
1444 # auto-host.h is the file containing items generated by autoconf and is
1445 # the first file included by config.h.
1446 # If host=build, it is correct to have bconfig include auto-host.h
1447 # as well.  If host!=build, we are in error and need to do more
1448 # work to find out the build config parameters.
1449 if test x$host = x$build
1450 then
1451         build_auto=auto-host.h
1452 else
1453         # We create a subdir, then run autoconf in the subdir.
1454         # To prevent recursion we set host and build for the new
1455         # invocation of configure to the build for this invocation
1456         # of configure.
1457         tempdir=build.$$
1458         rm -rf $tempdir
1459         mkdir $tempdir
1460         cd $tempdir
1461         case ${srcdir} in
1462         /* | [A-Za-z]:[\\/]* ) realsrcdir=${srcdir};;
1463         *) realsrcdir=../${srcdir};;
1464         esac
1465         saved_CFLAGS="${CFLAGS}"
1466         CC="${CC_FOR_BUILD}" CFLAGS="${CFLAGS_FOR_BUILD}" \
1467         LDFLAGS="${LDFLAGS_FOR_BUILD}" \
1468         ${realsrcdir}/configure \
1469                 --enable-languages=${enable_languages-all} \
1470                 --target=$target_alias --host=$build_alias --build=$build_alias
1471         CFLAGS="${saved_CFLAGS}"
1472
1473         # We just finished tests for the build machine, so rename
1474         # the file auto-build.h in the gcc directory.
1475         mv auto-host.h ../auto-build.h
1476         cd ..
1477         rm -rf $tempdir
1478         build_auto=auto-build.h
1479 fi
1480 AC_SUBST(build_subdir)
1481
1482 tm_file="${tm_file} defaults.h"
1483 tm_p_file="${tm_p_file} tm-preds.h"
1484 host_xm_file="auto-host.h ansidecl.h ${host_xm_file}"
1485 build_xm_file="${build_auto} ansidecl.h ${build_xm_file}"
1486 # We don't want ansidecl.h in target files, write code there in ISO/GNU C.
1487 # put this back in temporarily.
1488 xm_file="auto-host.h ansidecl.h ${xm_file}"
1489
1490 # --------
1491 # UNSORTED
1492 # --------
1493
1494 changequote(,)dnl
1495 # Compile in configure arguments.
1496 if test -f configargs.h ; then
1497         # Being re-configured.
1498         gcc_config_arguments=`grep configuration_arguments configargs.h | sed -e 's/.*"\([^"]*\)".*/\1/'`
1499         gcc_config_arguments="$gcc_config_arguments : (reconfigured) $TOPLEVEL_CONFIGURE_ARGUMENTS"
1500 else
1501         gcc_config_arguments="$TOPLEVEL_CONFIGURE_ARGUMENTS"
1502 fi
1503
1504 # Double all backslashes and backslash all quotes to turn
1505 # gcc_config_arguments into a C string.
1506 sed -e 's/\\/\\\\/g; s/"/\\"/g' <<EOF >conftest.out
1507 $gcc_config_arguments
1508 EOF
1509 gcc_config_arguments_str=`cat conftest.out`
1510 rm -f conftest.out
1511
1512 cat > configargs.h <<EOF
1513 /* Generated automatically. */
1514 static const char configuration_arguments[] = "$gcc_config_arguments_str";
1515 static const char thread_model[] = "$thread_file";
1516
1517 static const struct {
1518   const char *name, *value;
1519 } configure_default_options[] = $configure_default_options;
1520 EOF
1521 changequote([,])dnl
1522
1523 # Internationalization
1524 ZW_GNU_GETTEXT_SISTER_DIR
1525
1526 # If LIBINTL contains LIBICONV, then clear LIBICONV so we don't get
1527 # -liconv on the link line twice.
1528 case "$LIBINTL" in *$LIBICONV*)
1529         LIBICONV= ;;
1530 esac
1531
1532 AC_ARG_ENABLE(secureplt,
1533 [  --enable-secureplt      enable -msecure-plt by default for PowerPC],
1534 [], [])
1535
1536 AC_ARG_ENABLE(cld,
1537 [  --enable-cld            enable -mcld by default for 32bit x86], [],
1538 [enable_cld=no])
1539
1540 # Windows32 Registry support for specifying GCC installation paths.
1541 AC_ARG_ENABLE(win32-registry,
1542 [  --disable-win32-registry
1543                           disable lookup of installation paths in the
1544                           Registry on Windows hosts
1545   --enable-win32-registry enable registry lookup (default)
1546   --enable-win32-registry=KEY
1547                           use KEY instead of GCC version as the last portion
1548                           of the registry key],,)
1549
1550 case $host_os in
1551   win32 | pe | cygwin* | mingw32* | uwin*)
1552     if test "x$enable_win32_registry" != xno; then
1553       AC_SEARCH_LIBS(RegOpenKeyExA, advapi32,, [enable_win32_registry=no])
1554     fi
1555
1556     if test "x$enable_win32_registry" != xno; then
1557       AC_DEFINE(ENABLE_WIN32_REGISTRY, 1,
1558   [Define to 1 if installation paths should be looked up in the Windows
1559    Registry. Ignored on non-Windows hosts.])
1560
1561       if test "x$enable_win32_registry" != xyes \
1562          && test "x$enable_win32_registry" != x; then
1563         AC_DEFINE_UNQUOTED(WIN32_REGISTRY_KEY, "$enable_win32_registry",
1564   [Define to be the last component of the Windows registry key under which
1565    to look for installation paths.  The full key used will be
1566    HKEY_LOCAL_MACHINE/SOFTWARE/Free Software Foundation/{WIN32_REGISTRY_KEY}.
1567    The default is the GCC version number.])
1568       fi
1569     fi
1570   ;;
1571 esac
1572
1573 # Get an absolute path to the GCC top-level source directory
1574 holddir=`${PWDCMD-pwd}`
1575 cd $srcdir
1576 topdir=`${PWDCMD-pwd}`
1577 cd $holddir
1578
1579 # Conditionalize the makefile for this host machine.
1580 xmake_file=
1581 for f in ${host_xmake_file}
1582 do
1583         if test -f ${srcdir}/config/$f
1584         then
1585                 xmake_file="${xmake_file} \$(srcdir)/config/$f"
1586         fi
1587 done
1588
1589 # Conditionalize the makefile for this target machine.
1590 tmake_file_=
1591 for f in ${tmake_file}
1592 do
1593         if test -f ${srcdir}/config/$f
1594         then
1595                 tmake_file_="${tmake_file_} \$(srcdir)/config/$f"
1596         fi
1597 done
1598 tmake_file="${tmake_file_}"
1599
1600 # This is a terrible hack which will go away some day.
1601 host_cc_for_libada=${CC}
1602 AC_SUBST(host_cc_for_libada)
1603
1604 out_object_file=`basename $out_file .c`.o
1605
1606 tm_file_list="options.h"
1607 tm_include_list="options.h"
1608 for f in $tm_file; do
1609   case $f in
1610     ./* )
1611        f=`echo $f | sed 's/^..//'`
1612        tm_file_list="${tm_file_list} $f"
1613        tm_include_list="${tm_include_list} $f"
1614        ;;
1615     defaults.h )
1616        tm_file_list="${tm_file_list} \$(srcdir)/$f"
1617        tm_include_list="${tm_include_list} $f"
1618        ;;
1619     * )
1620        tm_file_list="${tm_file_list} \$(srcdir)/config/$f"
1621        tm_include_list="${tm_include_list} config/$f"
1622        ;;
1623   esac
1624 done
1625
1626 tm_p_file_list=
1627 tm_p_include_list=
1628 for f in $tm_p_file; do
1629   case $f in
1630     tm-preds.h )
1631        tm_p_file_list="${tm_p_file_list} $f"
1632        tm_p_include_list="${tm_p_include_list} $f"
1633        ;;
1634     * )
1635        tm_p_file_list="${tm_p_file_list} \$(srcdir)/config/$f"
1636        tm_p_include_list="${tm_p_include_list} config/$f"
1637   esac
1638 done
1639
1640 xm_file_list=
1641 xm_include_list=
1642 for f in $xm_file; do
1643   case $f in
1644     ansidecl.h )
1645        xm_file_list="${xm_file_list} \$(srcdir)/../include/$f"
1646        xm_include_list="${xm_include_list} $f"
1647        ;;
1648     auto-host.h )
1649        xm_file_list="${xm_file_list} $f"
1650        xm_include_list="${xm_include_list} $f"
1651        ;;
1652     * )
1653        xm_file_list="${xm_file_list} \$(srcdir)/config/$f"
1654        xm_include_list="${xm_include_list} config/$f"
1655        ;;
1656   esac
1657 done
1658
1659 host_xm_file_list=
1660 host_xm_include_list=
1661 for f in $host_xm_file; do
1662   case $f in
1663     ansidecl.h )
1664        host_xm_file_list="${host_xm_file_list} \$(srcdir)/../include/$f"
1665        host_xm_include_list="${host_xm_include_list} $f"
1666        ;;
1667     auto-host.h )
1668        host_xm_file_list="${host_xm_file_list} $f"
1669        host_xm_include_list="${host_xm_include_list} $f"
1670        ;;
1671     * )
1672        host_xm_file_list="${host_xm_file_list} \$(srcdir)/config/$f"
1673        host_xm_include_list="${host_xm_include_list} config/$f"
1674        ;;
1675   esac
1676 done
1677
1678 build_xm_file_list=
1679 for f in $build_xm_file; do
1680   case $f in
1681     ansidecl.h )
1682        build_xm_file_list="${build_xm_file_list} \$(srcdir)/../include/$f"
1683        build_xm_include_list="${build_xm_include_list} $f"
1684        ;;
1685     auto-build.h | auto-host.h )
1686        build_xm_file_list="${build_xm_file_list} $f"
1687        build_xm_include_list="${build_xm_include_list} $f"
1688        ;;
1689     * )
1690        build_xm_file_list="${build_xm_file_list} \$(srcdir)/config/$f"
1691        build_xm_include_list="${build_xm_include_list} config/$f"
1692        ;;
1693   esac
1694 done
1695
1696 # Define macro CROSS_DIRECTORY_STRUCTURE in compilation if this is a
1697 # cross-compiler which does not use the native headers and libraries.
1698 # Also use all.cross instead of all.internal and adjust SYSTEM_HEADER_DIR.
1699 CROSS=                                          AC_SUBST(CROSS)
1700 ALL=all.internal                                AC_SUBST(ALL)
1701 SYSTEM_HEADER_DIR='$(NATIVE_SYSTEM_HEADER_DIR)' AC_SUBST(SYSTEM_HEADER_DIR)
1702
1703 if test "x$with_build_sysroot" != x; then
1704   build_system_header_dir=$with_build_sysroot'$${sysroot_headers_suffix}$(NATIVE_SYSTEM_HEADER_DIR)'
1705 else
1706   # This value is used, even on a native system, because
1707   # CROSS_SYSTEM_HEADER_DIR is just
1708   # $(TARGET_SYSTEM_ROOT)$(NATIVE_SYSTEM_HEADER_DIR).
1709   build_system_header_dir='$(CROSS_SYSTEM_HEADER_DIR)'
1710 fi
1711
1712 if test x$host != x$target
1713 then
1714         CROSS="-DCROSS_DIRECTORY_STRUCTURE"
1715         ALL=all.cross
1716         SYSTEM_HEADER_DIR=$build_system_header_dir
1717         case "$host","$target" in
1718         # Darwin crosses can use the host system's libraries and headers,
1719         # because of the fat library support.  Of course, it must be the
1720         # same version of Darwin on both sides.  Allow the user to
1721         # just say --target=foo-darwin without a version number to mean
1722         # "the version on this system".
1723             *-*-darwin*,*-*-darwin*)
1724                 hostos=`echo $host | sed 's/.*-darwin/darwin/'`
1725                 targetos=`echo $target | sed 's/.*-darwin/darwin/'`
1726                 if test $hostos = $targetos -o $targetos = darwin ; then
1727                     CROSS=
1728                     SYSTEM_HEADER_DIR='$(NATIVE_SYSTEM_HEADER_DIR)'
1729                     with_headers=yes
1730                 fi
1731                 ;;
1732
1733             i?86-*-*,x86_64-*-* \
1734             | powerpc*-*-*,powerpc64*-*-*)
1735                 CROSS="$CROSS -DNATIVE_CROSS" ;;
1736         esac
1737 elif test "x$TARGET_SYSTEM_ROOT" != x; then
1738         SYSTEM_HEADER_DIR=$build_system_header_dir
1739 fi
1740
1741 # If this is a cross-compiler that does not
1742 # have its own set of headers then define
1743 # inhibit_libc
1744
1745 # If this is using newlib, without having the headers available now,
1746 # then define inhibit_libc in LIBGCC2_CFLAGS.
1747 # This prevents libgcc2 from containing any code which requires libc
1748 # support.
1749 : ${inhibit_libc=false}
1750 if { { test x$host != x$target && test "x$with_sysroot" = x ; } ||
1751        test x$with_newlib = xyes ; } &&
1752      { test "x$with_headers" = x || test "x$with_headers" = xno ; } ; then
1753        inhibit_libc=true
1754 fi
1755 AC_SUBST(inhibit_libc)
1756
1757 # When building gcc with a cross-compiler, we need to adjust things so
1758 # that the generator programs are still built with the native compiler.
1759 # Also, we cannot run fixincludes or fix-header.
1760
1761 # These are the normal (build=host) settings:
1762 CC_FOR_BUILD='$(CC)'            AC_SUBST(CC_FOR_BUILD)
1763 BUILD_CFLAGS='$(ALL_CFLAGS)'    AC_SUBST(BUILD_CFLAGS)
1764 BUILD_LDFLAGS='$(LDFLAGS)'      AC_SUBST(BUILD_LDFLAGS)
1765 STMP_FIXINC=stmp-fixinc         AC_SUBST(STMP_FIXINC)
1766
1767 # Possibly disable fixproto, on a per-target basis.
1768 case ${use_fixproto} in
1769   no)
1770     STMP_FIXPROTO=
1771     ;;
1772   yes)
1773     STMP_FIXPROTO=stmp-fixproto
1774     ;;
1775 esac
1776 AC_SUBST(STMP_FIXPROTO)
1777
1778 # And these apply if build != host, or we are generating coverage data
1779 if test x$build != x$host || test "x$coverage_flags" != x
1780 then
1781     BUILD_CFLAGS='$(INTERNAL_CFLAGS) $(T_CFLAGS) $(CFLAGS_FOR_BUILD)'
1782     BUILD_LDFLAGS='$(LDFLAGS_FOR_BUILD)'
1783
1784     if test "x$TARGET_SYSTEM_ROOT" = x; then
1785         if test "x$STMP_FIXPROTO" != x; then
1786           STMP_FIXPROTO=stmp-install-fixproto
1787         fi
1788     fi
1789 fi
1790
1791 # Expand extra_headers to include complete path.
1792 # This substitutes for lots of t-* files.
1793 extra_headers_list=
1794 # Prepend $(srcdir)/config/${cpu_type}/ to every entry in extra_headers.
1795 for file in ${extra_headers} ; do
1796   extra_headers_list="${extra_headers_list} \$(srcdir)/config/${cpu_type}/${file}"
1797 done
1798
1799 # If use_gcc_tgmath is set, append ginclude/tgmath.h.
1800 if test x"$use_gcc_tgmath" = xyes
1801 then extra_headers_list="${extra_headers_list} \$(srcdir)/ginclude/tgmath.h"
1802 fi
1803
1804 # Define collect2 in Makefile.
1805 case $host_can_use_collect2 in
1806   no) collect2= ;;
1807   *) collect2='collect2$(exeext)' ;;
1808 esac
1809 AC_SUBST([collect2])
1810
1811 # Add a definition of USE_COLLECT2 if system wants one.
1812 case $use_collect2 in
1813   no) use_collect2= ;;
1814   "") ;;
1815   *)
1816     host_xm_defines="${host_xm_defines} USE_COLLECT2"
1817     xm_defines="${xm_defines} USE_COLLECT2"
1818     case $host_can_use_collect2 in
1819       no)
1820         AC_MSG_ERROR([collect2 is required but cannot be built on this system])
1821         ;;
1822     esac
1823     ;;
1824 esac
1825
1826 # ---------------------------
1827 # Assembler & linker features
1828 # ---------------------------
1829
1830 # During stage 2, ld is actually gcc/collect-ld, which is a small script to
1831 # discern between when to use prev-ld/ld-new and when to use ld/ld-new.
1832 # However when ld-new is first executed from the build tree, libtool will
1833 # relink it as .libs/lt-ld-new, so that it can give it an RPATH that refers
1834 # to the build tree.  While doing this we need to use the previous-stage
1835 # linker, or we have an infinite loop.  The presence of a shell script as
1836 # ld/ld-new, and the fact that the script *uses ld itself*, is what confuses
1837 # the gcc/collect-ld script.  So we need to know how libtool works, or
1838 # exec-tool will fail.
1839
1840 m4_defun([_LT_CONFIG_COMMANDS], [])
1841 AC_PROG_LIBTOOL
1842 AC_SUBST(objdir)
1843 AC_SUBST(enable_fast_install)
1844
1845 # Identify the assembler which will work hand-in-glove with the newly
1846 # built GCC, so that we can examine its features.  This is the assembler
1847 # which will be driven by the driver program.
1848 #
1849 # If build != host, and we aren't building gas in-tree, we identify a
1850 # build->target assembler and hope that it will have the same features
1851 # as the host->target assembler we'll be using.
1852 gcc_cv_gas_major_version=
1853 gcc_cv_gas_minor_version=
1854 gcc_cv_as_gas_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/gas
1855
1856 m4_pattern_allow([AS_FOR_TARGET])dnl
1857 AS_VAR_SET_IF(gcc_cv_as,, [
1858 if test -x "$DEFAULT_ASSEMBLER"; then
1859         gcc_cv_as="$DEFAULT_ASSEMBLER"
1860 elif test -f $gcc_cv_as_gas_srcdir/configure.in \
1861      && test -f ../gas/Makefile \
1862      && test x$build = x$host; then
1863         gcc_cv_as=../gas/as-new$build_exeext
1864 elif test -x as$build_exeext; then
1865         # Build using assembler in the current directory.
1866         gcc_cv_as=./as$build_exeext
1867 elif test -x $AS_FOR_TARGET; then
1868         gcc_cv_as="$AS_FOR_TARGET"
1869 else
1870         AC_PATH_PROG(gcc_cv_as, $AS_FOR_TARGET)
1871 fi])
1872
1873 ORIGINAL_AS_FOR_TARGET=$gcc_cv_as
1874 AC_SUBST(ORIGINAL_AS_FOR_TARGET)
1875 case "$ORIGINAL_AS_FOR_TARGET" in
1876   ./as | ./as$build_exeext) ;;
1877   *) AC_CONFIG_FILES(as:exec-tool.in, [chmod +x as]) ;;
1878 esac
1879
1880 AC_MSG_CHECKING(what assembler to use)
1881 if test "$gcc_cv_as" = ../gas/as-new$build_exeext; then
1882   # Single tree build which includes gas.  We want to prefer it
1883   # over whatever linker top-level may have detected, since
1884   # we'll use what we're building after installation anyway.
1885   AC_MSG_RESULT(newly built gas)
1886   in_tree_gas=yes
1887   _gcc_COMPUTE_GAS_VERSION
1888   in_tree_gas_is_elf=no
1889   if grep 'obj_format = elf' ../gas/Makefile > /dev/null \
1890      || (grep 'obj_format = multi' ../gas/Makefile \
1891          && grep 'extra_objects =.* obj-elf' ../gas/Makefile) > /dev/null
1892   then
1893     in_tree_gas_is_elf=yes
1894   fi
1895 else
1896   AC_MSG_RESULT($gcc_cv_as)
1897   in_tree_gas=no
1898 fi
1899
1900 # Identify the linker which will work hand-in-glove with the newly
1901 # built GCC, so that we can examine its features.  This is the linker
1902 # which will be driven by the driver program.
1903 #
1904 # If build != host, and we aren't building gas in-tree, we identify a
1905 # build->target linker and hope that it will have the same features
1906 # as the host->target linker we'll be using.
1907 gcc_cv_gld_major_version=
1908 gcc_cv_gld_minor_version=
1909 gcc_cv_ld_gld_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/ld
1910 gcc_cv_ld_bfd_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/bfd
1911
1912 AS_VAR_SET_IF(gcc_cv_ld,, [
1913 if test -x "$DEFAULT_LINKER"; then
1914         gcc_cv_ld="$DEFAULT_LINKER"
1915 elif test -f $gcc_cv_ld_gld_srcdir/configure.in \
1916      && test -f ../ld/Makefile \
1917      && test x$build = x$host; then
1918         gcc_cv_ld=../ld/ld-new$build_exeext
1919 elif test -x collect-ld$build_exeext; then
1920         # Build using linker in the current directory.
1921         gcc_cv_ld=./collect-ld$build_exeext
1922 elif test -x $LD_FOR_TARGET; then
1923         gcc_cv_ld="$LD_FOR_TARGET"
1924 else
1925         AC_PATH_PROG(gcc_cv_ld, $LD_FOR_TARGET)
1926 fi])
1927
1928 ORIGINAL_LD_FOR_TARGET=$gcc_cv_ld
1929 AC_SUBST(ORIGINAL_LD_FOR_TARGET)
1930 case "$ORIGINAL_LD_FOR_TARGET" in
1931   ./collect-ld | ./collect-ld$build_exeext) ;;
1932   *) AC_CONFIG_FILES(collect-ld:exec-tool.in, [chmod +x collect-ld]) ;;
1933 esac
1934
1935 AC_MSG_CHECKING(what linker to use)
1936 if test "$gcc_cv_ld" = ../ld/ld-new$build_exeext; then
1937         # Single tree build which includes ld.  We want to prefer it
1938         # over whatever linker top-level may have detected, since
1939         # we'll use what we're building after installation anyway.
1940         AC_MSG_RESULT(newly built ld)
1941         in_tree_ld=yes
1942         in_tree_ld_is_elf=no
1943         if (grep 'EMUL = .*elf' ../ld/Makefile \
1944             || grep 'EMUL = .*linux' ../ld/Makefile \
1945             || grep 'EMUL = .*lynx' ../ld/Makefile) > /dev/null; then
1946           in_tree_ld_is_elf=yes
1947         fi
1948         for f in $gcc_cv_ld_bfd_srcdir/configure $gcc_cv_ld_gld_srcdir/configure $gcc_cv_ld_gld_srcdir/configure.in $gcc_cv_ld_gld_srcdir/Makefile.in
1949         do
1950 changequote(,)dnl
1951                 gcc_cv_gld_version=`sed -n -e 's/^[     ]*\(VERSION=[0-9]*\.[0-9]*.*\)/\1/p' < $f`
1952                 if test x$gcc_cv_gld_version != x; then
1953                         break
1954                 fi
1955         done
1956         gcc_cv_gld_major_version=`expr "$gcc_cv_gld_version" : "VERSION=\([0-9]*\)"`
1957         gcc_cv_gld_minor_version=`expr "$gcc_cv_gld_version" : "VERSION=[0-9]*\.\([0-9]*\)"`
1958 changequote([,])dnl
1959 else
1960         AC_MSG_RESULT($gcc_cv_ld)
1961         in_tree_ld=no
1962 fi
1963
1964 # Figure out what nm we will be using.
1965 gcc_cv_binutils_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/binutils
1966 AS_VAR_SET_IF(gcc_cv_nm,, [
1967 if test -f $gcc_cv_binutils_srcdir/configure.in \
1968      && test -f ../binutils/Makefile \
1969      && test x$build = x$host; then
1970         gcc_cv_nm=../binutils/nm-new$build_exeext
1971 elif test -x nm$build_exeext; then
1972         gcc_cv_nm=./nm$build_exeext
1973 elif test -x $NM_FOR_TARGET; then
1974         gcc_cv_nm="$NM_FOR_TARGET"
1975 else
1976         AC_PATH_PROG(gcc_cv_nm, $NM_FOR_TARGET)
1977 fi])
1978
1979 AC_MSG_CHECKING(what nm to use)
1980 if test "$gcc_cv_nm" = ../binutils/nm-new$build_exeext; then
1981         # Single tree build which includes binutils.
1982         AC_MSG_RESULT(newly built nm)
1983         in_tree_nm=yes
1984 else
1985         AC_MSG_RESULT($gcc_cv_nm)
1986         in_tree_nm=no
1987 fi
1988
1989 ORIGINAL_NM_FOR_TARGET=$gcc_cv_nm
1990 AC_SUBST(ORIGINAL_NM_FOR_TARGET)
1991 case "$ORIGINAL_NM_FOR_TARGET" in
1992   ./nm | ./nm$build_exeext) ;;
1993   *) AC_CONFIG_FILES(nm:exec-tool.in, [chmod +x nm]) ;;
1994 esac
1995
1996
1997 # Figure out what objdump we will be using.
1998 AS_VAR_SET_IF(gcc_cv_objdump,, [
1999 if test -f $gcc_cv_binutils_srcdir/configure.in \
2000      && test -f ../binutils/Makefile \
2001      && test x$build = x$host; then
2002         # Single tree build which includes binutils.
2003         gcc_cv_objdump=../binutils/objdump$build_exeext
2004 elif test -x objdump$build_exeext; then
2005         gcc_cv_objdump=./objdump$build_exeext
2006 elif test -x $OBJDUMP_FOR_TARGET; then
2007         gcc_cv_objdump="$OBJDUMP_FOR_TARGET"
2008 else
2009         AC_PATH_PROG(gcc_cv_objdump, $OBJDUMP_FOR_TARGET)
2010 fi])
2011
2012 AC_MSG_CHECKING(what objdump to use)
2013 if test "$gcc_cv_objdump" = ../binutils/objdump$build_exeext; then
2014         # Single tree build which includes binutils.
2015         AC_MSG_RESULT(newly built objdump)
2016 elif test x$gcc_cv_objdump = x; then
2017         AC_MSG_RESULT(not found)
2018 else
2019         AC_MSG_RESULT($gcc_cv_objdump)
2020 fi
2021
2022 # Figure out what assembler alignment features are present.
2023 gcc_GAS_CHECK_FEATURE([.balign and .p2align], gcc_cv_as_balign_and_p2align,
2024  [2,6,0],,
2025 [.balign 4
2026 .p2align 2],,
2027 [AC_DEFINE(HAVE_GAS_BALIGN_AND_P2ALIGN, 1,
2028   [Define if your assembler supports .balign and .p2align.])])
2029
2030 gcc_GAS_CHECK_FEATURE([.p2align with maximum skip], gcc_cv_as_max_skip_p2align,
2031  [2,8,0],,
2032  [.p2align 4,,7],,
2033 [AC_DEFINE(HAVE_GAS_MAX_SKIP_P2ALIGN, 1,
2034   [Define if your assembler supports specifying the maximum number
2035    of bytes to skip when using the GAS .p2align command.])])
2036
2037 gcc_GAS_CHECK_FEATURE([.literal16], gcc_cv_as_literal16,
2038  [2,8,0],,
2039  [.literal16],,
2040 [AC_DEFINE(HAVE_GAS_LITERAL16, 1,
2041   [Define if your assembler supports .literal16.])])
2042
2043 gcc_GAS_CHECK_FEATURE([working .subsection -1], gcc_cv_as_subsection_m1,
2044  [elf,2,9,0],,
2045  [conftest_label1: .word 0
2046 .subsection -1
2047 conftest_label2: .word 0
2048 .previous],
2049  [if test x$gcc_cv_nm != x; then
2050     $gcc_cv_nm conftest.o | grep conftest_label1 > conftest.nm1
2051     $gcc_cv_nm conftest.o | grep conftest_label2 | sed -e 's/label2/label1/' > conftest.nm2
2052     if cmp conftest.nm1 conftest.nm2 > /dev/null 2>&1
2053     then :
2054     else gcc_cv_as_subsection_m1=yes
2055     fi
2056     rm -f conftest.nm1 conftest.nm2
2057   fi],
2058  [AC_DEFINE(HAVE_GAS_SUBSECTION_ORDERING, 1,
2059   [Define if your assembler supports .subsection and .subsection -1 starts
2060    emitting at the beginning of your section.])])
2061
2062 gcc_GAS_CHECK_FEATURE([.weak], gcc_cv_as_weak,
2063  [2,2,0],,
2064  [      .weak foobar],,
2065 [AC_DEFINE(HAVE_GAS_WEAK, 1, [Define if your assembler supports .weak.])])
2066
2067 gcc_GAS_CHECK_FEATURE([.weakref], gcc_cv_as_weakref,
2068  [2,17,0],,
2069  [      .weakref foobar, barfnot],,
2070 [AC_DEFINE(HAVE_GAS_WEAKREF, 1, [Define if your assembler supports .weakref.])])
2071
2072 gcc_GAS_CHECK_FEATURE([.nsubspa comdat], gcc_cv_as_nsubspa_comdat,
2073  [2,15,91],,
2074  [      .SPACE $TEXT$
2075         .NSUBSPA $CODE$,COMDAT],,
2076 [AC_DEFINE(HAVE_GAS_NSUBSPA_COMDAT, 1, [Define if your assembler supports .nsubspa comdat option.])])
2077
2078 # .hidden needs to be supported in both the assembler and the linker,
2079 # because GNU LD versions before 2.12.1 have buggy support for STV_HIDDEN.
2080 # This is irritatingly difficult to feature test for; we have to check the
2081 # date string after the version number.  If we've got an in-tree
2082 # ld, we don't know its patchlevel version, so we set the baseline at 2.13
2083 # to be safe.
2084 # The gcc_GAS_CHECK_FEATURE call just sets a cache variable.
2085 gcc_GAS_CHECK_FEATURE([.hidden], gcc_cv_as_hidden,
2086  [elf,2,13,0],,
2087 [       .hidden foobar
2088 foobar:])
2089
2090 AC_CACHE_CHECK(linker for .hidden support, gcc_cv_ld_hidden,
2091 [if test $in_tree_ld = yes ; then
2092   gcc_cv_ld_hidden=no
2093   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 13 -o "$gcc_cv_gld_major_version" -gt 2 \
2094      && test $in_tree_ld_is_elf = yes; then
2095      gcc_cv_ld_hidden=yes
2096   fi
2097 else
2098   gcc_cv_ld_hidden=yes
2099   ld_ver=`$gcc_cv_ld --version 2>/dev/null | sed 1q`
2100   if echo "$ld_ver" | grep GNU > /dev/null; then
2101 changequote(,)dnl
2102     ld_vers=`echo $ld_ver | sed -n \
2103         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*.*\)$,\1,p'`
2104     ld_date=`echo $ld_ver | sed -n 's,^.*\([2-9][0-9][0-9][0-9]\)[-]*\([01][0-9]\)[-]*\([0-3][0-9]\).*$,\1\2\3,p'`
2105     ld_vers_major=`expr "$ld_vers" : '\([0-9]*\)'`
2106     ld_vers_minor=`expr "$ld_vers" : '[0-9]*\.\([0-9]*\)'`
2107     ld_vers_patch=`expr "$ld_vers" : '[0-9]*\.[0-9]*\.\([0-9]*\)'`
2108     if test 0"$ld_date" -lt 20020404; then
2109       if test -n "$ld_date"; then
2110         # If there was date string, but was earlier than 2002-04-04, fail
2111         gcc_cv_ld_hidden=no
2112       elif test -z "$ld_vers"; then
2113         # If there was no date string nor ld version number, something is wrong
2114         gcc_cv_ld_hidden=no
2115       else
2116         test -z "$ld_vers_patch" && ld_vers_patch=0
2117         if test "$ld_vers_major" -lt 2; then
2118           gcc_cv_ld_hidden=no
2119         elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -lt 12; then
2120           gcc_cv_ld_hidden="no"
2121         elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -eq 12 -a "$ld_vers_patch" -eq 0; then
2122           gcc_cv_ld_hidden=no
2123         fi
2124       fi
2125 changequote([,])dnl
2126     fi
2127   else
2128     case "${target}" in
2129       hppa64*-*-hpux* | ia64*-*-hpux*)
2130         gcc_cv_ld_hidden=yes
2131         ;;
2132       *)
2133         gcc_cv_ld_hidden=no
2134         ;;
2135     esac
2136   fi
2137 fi])
2138 libgcc_visibility=no
2139 AC_SUBST(libgcc_visibility)
2140 GCC_TARGET_TEMPLATE([HAVE_GAS_HIDDEN])
2141 if test $gcc_cv_as_hidden = yes && test $gcc_cv_ld_hidden = yes; then
2142   libgcc_visibility=yes
2143   AC_DEFINE(HAVE_GAS_HIDDEN, 1,
2144   [Define if your assembler and linker support .hidden.])
2145 fi
2146
2147 # Check if we have .[us]leb128, and support symbol arithmetic with it.
2148 gcc_GAS_CHECK_FEATURE([.sleb128 and .uleb128], gcc_cv_as_leb128,
2149   [elf,2,11,0],,
2150 [       .data
2151         .uleb128 L2 - L1
2152 L1:
2153         .uleb128 1280
2154         .sleb128 -1010
2155 L2:],
2156  [# GAS versions before 2.11 do not support uleb128,
2157   # despite appearing to.
2158   # ??? There exists an elf-specific test that will crash
2159   # the assembler.  Perhaps it's better to figure out whether
2160   # arbitrary sections are supported and try the test.
2161   as_ver=`$gcc_cv_as --version 2>/dev/null | sed 1q`
2162   if echo "$as_ver" | grep GNU > /dev/null; then
2163 changequote(,)dnl
2164     as_vers=`echo $as_ver | sed -n \
2165         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*.*\)$,\1,p'`
2166     as_major=`expr "$as_vers" : '\([0-9]*\)'`
2167     as_minor=`expr "$as_vers" : '[0-9]*\.\([0-9]*\)'`
2168 changequote([,])dnl
2169     if test $as_major -eq 2 && test $as_minor -lt 11
2170     then :
2171     else gcc_cv_as_leb128=yes
2172     fi
2173   fi],
2174   [AC_DEFINE(HAVE_AS_LEB128, 1,
2175     [Define if your assembler supports .sleb128 and .uleb128.])])
2176
2177 # GAS versions up to and including 2.11.0 may mis-optimize
2178 # .eh_frame data.
2179 gcc_GAS_CHECK_FEATURE(eh_frame optimization, gcc_cv_as_eh_frame,
2180   [elf,2,12,0],,
2181 [       .text
2182 .LFB1:
2183         .4byte  0
2184 .L1:
2185         .4byte  0
2186 .LFE1:
2187         .section        .eh_frame,"aw",@progbits
2188 __FRAME_BEGIN__:
2189         .4byte  .LECIE1-.LSCIE1
2190 .LSCIE1:
2191         .4byte  0x0
2192         .byte   0x1
2193         .ascii "z\0"
2194         .byte   0x1
2195         .byte   0x78
2196         .byte   0x1a
2197         .byte   0x0
2198         .byte   0x4
2199         .4byte  1
2200         .p2align 1
2201 .LECIE1:
2202 .LSFDE1:
2203         .4byte  .LEFDE1-.LASFDE1
2204 .LASFDE1:
2205         .4byte  .LASFDE1-__FRAME_BEGIN__
2206         .4byte  .LFB1
2207         .4byte  .LFE1-.LFB1
2208         .byte   0x4
2209         .4byte  .LFE1-.LFB1
2210         .byte   0x4
2211         .4byte  .L1-.LFB1
2212 .LEFDE1:],
2213 [  dnl # For autoconf 2.5x, must protect trailing spaces with @&t@.
2214 cat > conftest.lit <<EOF
2215  0000 10000000 00000000 017a0001 781a0004  .........z..x...
2216  0010 01000000 12000000 18000000 00000000  ................
2217  0020 08000000 04080000 0044               .........D      @&t@
2218 EOF
2219 cat > conftest.big <<EOF
2220  0000 00000010 00000000 017a0001 781a0004  .........z..x...
2221  0010 00000001 00000012 00000018 00000000  ................
2222  0020 00000008 04000000 0844               .........D      @&t@
2223 EOF
2224   # If the assembler didn't choke, and we can objdump,
2225   # and we got the correct data, then succeed.
2226   # The text in the here-document typically retains its unix-style line
2227   # endings, while the output of objdump will use host line endings.
2228   # Therefore, use diff -b for the comparisons.
2229   if test x$gcc_cv_objdump != x \
2230   && $gcc_cv_objdump -s -j .eh_frame conftest.o 2>/dev/null \
2231      | tail -3 > conftest.got \
2232   && { diff -b conftest.lit conftest.got > /dev/null 2>&1 \
2233     || diff -b conftest.big conftest.got > /dev/null 2>&1; }
2234   then
2235     gcc_cv_as_eh_frame=yes
2236   elif AC_TRY_COMMAND($gcc_cv_as -o conftest.o --traditional-format /dev/null); then
2237     gcc_cv_as_eh_frame=buggy
2238   else
2239     # Uh oh, what do we do now?
2240     gcc_cv_as_eh_frame=no
2241   fi])
2242
2243 if test $gcc_cv_as_eh_frame = buggy; then
2244   AC_DEFINE(USE_AS_TRADITIONAL_FORMAT, 1,
2245   [Define if your assembler mis-optimizes .eh_frame data.])
2246 fi
2247
2248 gcc_GAS_CHECK_FEATURE(section merging support, gcc_cv_as_shf_merge,
2249  [elf,2,12,0], [--fatal-warnings],
2250  [.section .rodata.str, "aMS", @progbits, 1])
2251 if test $gcc_cv_as_shf_merge = no; then
2252   gcc_GAS_CHECK_FEATURE(section merging support, gcc_cv_as_shf_merge,
2253     [elf,2,12,0], [--fatal-warnings],
2254     [.section .rodata.str, "aMS", %progbits, 1])
2255 fi
2256 AC_DEFINE_UNQUOTED(HAVE_GAS_SHF_MERGE,
2257   [`if test $gcc_cv_as_shf_merge = yes; then echo 1; else echo 0; fi`],
2258 [Define 0/1 if your assembler supports marking sections with SHF_MERGE flag.])
2259
2260 gcc_GAS_CHECK_FEATURE(COMDAT group support, gcc_cv_as_comdat_group,
2261  [elf,2,16,0], [--fatal-warnings],
2262  [.section .text,"axG",@progbits,.foo,comdat])
2263 if test $gcc_cv_as_comdat_group = yes; then
2264   gcc_cv_as_comdat_group_percent=no
2265 else
2266  gcc_GAS_CHECK_FEATURE(COMDAT group support, gcc_cv_as_comdat_group_percent,
2267    [elf,2,16,0], [--fatal-warnings],
2268    [.section .text,"axG",%progbits,.foo,comdat])
2269 fi
2270 if test $in_tree_ld != yes && test x"$ld_vers" != x; then
2271   comdat_group=yes
2272   if test 0"$ld_date" -lt 20050308; then
2273     if test -n "$ld_date"; then
2274       # If there was date string, but was earlier than 2005-03-08, fail
2275       comdat_group=no
2276     elif test "$ld_vers_major" -lt 2; then
2277       comdat_group=no
2278     elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -lt 16; then
2279       comdat_group=no
2280     fi
2281   fi
2282 else
2283   # assume linkers other than GNU ld don't support COMDAT group
2284   comdat_group=no
2285 fi
2286 if test $comdat_group = no; then
2287   gcc_cv_as_comdat_group=no
2288   gcc_cv_as_comdat_group_percent=no
2289 fi
2290 AC_DEFINE_UNQUOTED(HAVE_COMDAT_GROUP,
2291   [`if test $gcc_cv_as_comdat_group = yes || test $gcc_cv_as_comdat_group_percent = yes; then echo 1; else echo 0; fi`],
2292 [Define 0/1 if your assembler and linker support COMDAT groups.])
2293
2294 # Thread-local storage - the check is heavily parametrized.
2295 conftest_s=
2296 tls_first_major=
2297 tls_first_minor=
2298 tls_as_opt=
2299 case "$target" in
2300 changequote(,)dnl
2301   alpha*-*-*)
2302     conftest_s='
2303         .section ".tdata","awT",@progbits
2304 foo:    .long   25
2305         .text
2306         ldq     $27,__tls_get_addr($29)         !literal!1
2307         lda     $16,foo($29)                    !tlsgd!1
2308         jsr     $26,($27),__tls_get_addr        !lituse_tlsgd!1
2309         ldq     $27,__tls_get_addr($29)         !literal!2
2310         lda     $16,foo($29)                    !tlsldm!2
2311         jsr     $26,($27),__tls_get_addr        !lituse_tlsldm!2
2312         ldq     $1,foo($29)                     !gotdtprel
2313         ldah    $2,foo($29)                     !dtprelhi
2314         lda     $3,foo($2)                      !dtprello
2315         lda     $4,foo($29)                     !dtprel
2316         ldq     $1,foo($29)                     !gottprel
2317         ldah    $2,foo($29)                     !tprelhi
2318         lda     $3,foo($2)                      !tprello
2319         lda     $4,foo($29)                     !tprel'
2320         tls_first_major=2
2321         tls_first_minor=13
2322         tls_as_opt=--fatal-warnings
2323         ;;
2324   frv*-*-*)
2325     conftest_s='
2326         .section ".tdata","awT",@progbits
2327 x:      .long   25
2328         .text
2329         call    #gettlsoff(x)'
2330         tls_first_major=2
2331         tls_first_minor=14
2332         ;;
2333   hppa*-*-linux*)
2334     conftest_s='
2335 t1:     .reg    %r20
2336 t2:     .reg    %r21
2337 gp:     .reg    %r19
2338         .section ".tdata","awT",@progbits
2339 foo:    .long   25
2340         .text
2341         .align  4
2342         addil LT%foo-$tls_gdidx$,gp
2343         ldo RT%foo-$tls_gdidx$(%r1),%arg0
2344         b __tls_get_addr
2345         nop
2346         addil LT%foo-$tls_ldidx$,gp
2347         b __tls_get_addr
2348         ldo RT%foo-$tls_ldidx$(%r1),%arg0
2349         addil LR%foo-$tls_dtpoff$,%ret0
2350         ldo RR%foo-$tls_dtpoff$(%r1),%t1
2351         mfctl %cr27,%t1
2352         addil LT%foo-$tls_ieoff$,gp
2353         ldw RT%foo-$tls_ieoff$(%r1),%t2
2354         add %t1,%t2,%t3
2355         mfctl %cr27,%t1
2356         addil LR%foo-$tls_leoff$,%t1
2357         ldo RR%foo-$tls_leoff$(%r1),%t2'
2358         tls_first_major=2
2359         tls_first_minor=15
2360         tls_as_opt=--fatal-warnings
2361         ;;
2362   arm*-*-*)
2363     conftest_s='
2364         .section ".tdata","awT",%progbits
2365 foo:    .long   25
2366         .text
2367 .word foo(gottpoff)
2368 .word foo(tpoff)
2369 .word foo(tlsgd)
2370 .word foo(tlsldm)
2371 .word foo(tlsldo)'
2372         tls_first_major=2
2373         tls_first_minor=17
2374         ;;
2375   i[34567]86-*-*)
2376     conftest_s='
2377         .section ".tdata","awT",@progbits
2378 foo:    .long   25
2379         .text
2380         movl    %gs:0, %eax
2381         leal    foo@TLSGD(,%ebx,1), %eax
2382         leal    foo@TLSLDM(%ebx), %eax
2383         leal    foo@DTPOFF(%eax), %edx
2384         movl    foo@GOTTPOFF(%ebx), %eax
2385         subl    foo@GOTTPOFF(%ebx), %eax
2386         addl    foo@GOTNTPOFF(%ebx), %eax
2387         movl    foo@INDNTPOFF, %eax
2388         movl    $foo@TPOFF, %eax
2389         subl    $foo@TPOFF, %eax
2390         leal    foo@NTPOFF(%ecx), %eax'
2391         tls_first_major=2
2392         tls_first_minor=14
2393         tls_as_opt=--fatal-warnings
2394         ;;
2395   x86_64-*-*)
2396     conftest_s='
2397         .section ".tdata","awT",@progbits
2398 foo:    .long   25
2399         .text
2400         movq    %fs:0, %rax
2401         leaq    foo@TLSGD(%rip), %rdi
2402         leaq    foo@TLSLD(%rip), %rdi
2403         leaq    foo@DTPOFF(%rax), %rdx
2404         movq    foo@GOTTPOFF(%rip), %rax
2405         movq    $foo@TPOFF, %rax'
2406         tls_first_major=2
2407         tls_first_minor=14
2408         tls_as_opt=--fatal-warnings
2409         ;;
2410   ia64-*-*)
2411     conftest_s='
2412         .section ".tdata","awT",@progbits
2413 foo:    data8   25
2414         .text
2415         addl    r16 = @ltoff(@dtpmod(foo#)), gp
2416         addl    r17 = @ltoff(@dtprel(foo#)), gp
2417         addl    r18 = @ltoff(@tprel(foo#)), gp
2418         addl    r19 = @dtprel(foo#), gp
2419         adds    r21 = @dtprel(foo#), r13
2420         movl    r23 = @dtprel(foo#)
2421         addl    r20 = @tprel(foo#), gp
2422         adds    r22 = @tprel(foo#), r13
2423         movl    r24 = @tprel(foo#)'
2424         tls_first_major=2
2425         tls_first_minor=13
2426         tls_as_opt=--fatal-warnings
2427         ;;
2428   mips*-*-*)
2429     conftest_s='
2430         .section .tdata,"awT",@progbits
2431 x:
2432         .word 2
2433         .text
2434         addiu $4, $28, %tlsgd(x)
2435         addiu $4, $28, %tlsldm(x)
2436         lui $4, %dtprel_hi(x)
2437         addiu $4, $4, %dtprel_lo(x)
2438         lw $4, %gottprel(x)($28)
2439         lui $4, %tprel_hi(x)
2440         addiu $4, $4, %tprel_lo(x)'
2441         tls_first_major=2
2442         tls_first_minor=16
2443         tls_as_opt='-32 --fatal-warnings'
2444         ;;
2445   powerpc-*-*)
2446     conftest_s='
2447         .section ".tdata","awT",@progbits
2448         .align 2
2449 ld0:    .space 4
2450 ld1:    .space 4
2451 x1:     .space 4
2452 x2:     .space 4
2453 x3:     .space 4
2454         .text
2455         addi 3,31,ld0@got@tlsgd
2456         bl __tls_get_addr
2457         addi 3,31,x1@got@tlsld
2458         bl __tls_get_addr
2459         addi 9,3,x1@dtprel
2460         addis 9,3,x2@dtprel@ha
2461         addi 9,9,x2@dtprel@l
2462         lwz 9,x3@got@tprel(31)
2463         add 9,9,x@tls
2464         addi 9,2,x1@tprel
2465         addis 9,2,x2@tprel@ha
2466         addi 9,9,x2@tprel@l'
2467         tls_first_major=2
2468         tls_first_minor=14
2469         tls_as_opt="-a32 --fatal-warnings"
2470         ;;
2471   powerpc64-*-*)
2472     conftest_s='
2473         .section ".tdata","awT",@progbits
2474         .align 3
2475 ld0:    .space 8
2476 ld1:    .space 8
2477 x1:     .space 8
2478 x2:     .space 8
2479 x3:     .space 8
2480         .text
2481         addi 3,2,ld0@got@tlsgd
2482         bl .__tls_get_addr
2483         nop
2484         addi 3,2,ld1@toc
2485         bl .__tls_get_addr
2486         nop
2487         addi 3,2,x1@got@tlsld
2488         bl .__tls_get_addr
2489         nop
2490         addi 9,3,x1@dtprel
2491         bl .__tls_get_addr
2492         nop
2493         addis 9,3,x2@dtprel@ha
2494         addi 9,9,x2@dtprel@l
2495         bl .__tls_get_addr
2496         nop
2497         ld 9,x3@got@dtprel(2)
2498         add 9,9,3
2499         bl .__tls_get_addr
2500         nop'
2501         tls_first_major=2
2502         tls_first_minor=14
2503         tls_as_opt="-a64 --fatal-warnings"
2504         ;;
2505   s390-*-*)
2506     conftest_s='
2507         .section ".tdata","awT",@progbits
2508 foo:    .long   25
2509         .text
2510         .long   foo@TLSGD
2511         .long   foo@TLSLDM
2512         .long   foo@DTPOFF
2513         .long   foo@NTPOFF
2514         .long   foo@GOTNTPOFF
2515         .long   foo@INDNTPOFF
2516         l       %r1,foo@GOTNTPOFF(%r12)
2517         l       %r1,0(%r1):tls_load:foo
2518         bas     %r14,0(%r1,%r13):tls_gdcall:foo
2519         bas     %r14,0(%r1,%r13):tls_ldcall:foo'
2520         tls_first_major=2
2521         tls_first_minor=14
2522         tls_as_opt="-m31 --fatal-warnings"
2523         ;;
2524   s390x-*-*)
2525     conftest_s='
2526         .section ".tdata","awT",@progbits
2527 foo:    .long   25
2528         .text
2529         .quad   foo@TLSGD
2530         .quad   foo@TLSLDM
2531         .quad   foo@DTPOFF
2532         .quad   foo@NTPOFF
2533         .quad   foo@GOTNTPOFF
2534         lg      %r1,foo@GOTNTPOFF(%r12)
2535         larl    %r1,foo@INDNTPOFF
2536         brasl   %r14,__tls_get_offset@PLT:tls_gdcall:foo
2537         brasl   %r14,__tls_get_offset@PLT:tls_ldcall:foo'
2538         tls_first_major=2
2539         tls_first_minor=14
2540         tls_as_opt="-m64 -Aesame --fatal-warnings"
2541         ;;
2542   sh-*-* | sh[34]-*-*)
2543     conftest_s='
2544         .section ".tdata","awT",@progbits
2545 foo:    .long   25
2546         .text
2547         .long   foo@TLSGD
2548         .long   foo@TLSLDM
2549         .long   foo@DTPOFF
2550         .long   foo@GOTTPOFF
2551         .long   foo@TPOFF'
2552         tls_first_major=2
2553         tls_first_minor=13
2554         tls_as_opt=--fatal-warnings
2555         ;;
2556   sparc*-*-*)
2557     case "$target" in
2558       sparc*-sun-solaris2.[56789]*)
2559         # TLS was introduced in the Solaris 9 4/04 release but
2560         # we do not enable it by default on Solaris 9 either.
2561         if test "x$enable_tls" = xyes ; then
2562           on_solaris=yes
2563         else
2564           enable_tls=no;
2565         fi
2566         ;;
2567       sparc*-sun-solaris2.*)
2568         on_solaris=yes
2569         ;;
2570       *)
2571         on_solaris=no
2572         ;;
2573     esac
2574     if test x$on_solaris = xyes && test x$gas_flag = xno; then
2575       conftest_s='
2576         .section ".tdata",#alloc,#write,#tls
2577 foo:    .long   25
2578         .text
2579         sethi   %tgd_hi22(foo), %o0
2580         add     %o0, %tgd_lo10(foo), %o1
2581         add     %l7, %o1, %o0, %tgd_add(foo)
2582         call    __tls_get_addr, %tgd_call(foo)
2583         sethi   %tldm_hi22(foo), %l1
2584         add     %l1, %tldm_lo10(foo), %l2
2585         add     %l7, %l2, %o0, %tldm_add(foo)
2586         call    __tls_get_addr, %tldm_call(foo)
2587         sethi   %tldo_hix22(foo), %l3
2588         xor     %l3, %tldo_lox10(foo), %l4
2589         add     %o0, %l4, %l5, %tldo_add(foo)
2590         sethi   %tie_hi22(foo), %o3
2591         add     %o3, %tie_lo10(foo), %o3
2592         ld      [%l7 + %o3], %o2, %tie_ld(foo)
2593         add     %g7, %o2, %o4, %tie_add(foo)
2594         sethi   %tle_hix22(foo), %l1
2595         xor     %l1, %tle_lox10(foo), %o5
2596         ld      [%g7 + %o5], %o1'
2597         tls_first_major=0
2598         tls_first_minor=0
2599     else
2600       conftest_s='
2601         .section ".tdata","awT",@progbits
2602 foo:    .long   25
2603         .text
2604         sethi   %tgd_hi22(foo), %o0
2605         add     %o0, %tgd_lo10(foo), %o1
2606         add     %l7, %o1, %o0, %tgd_add(foo)
2607         call    __tls_get_addr, %tgd_call(foo)
2608         sethi   %tldm_hi22(foo), %l1
2609         add     %l1, %tldm_lo10(foo), %l2
2610         add     %l7, %l2, %o0, %tldm_add(foo)
2611         call    __tls_get_addr, %tldm_call(foo)
2612         sethi   %tldo_hix22(foo), %l3
2613         xor     %l3, %tldo_lox10(foo), %l4
2614         add     %o0, %l4, %l5, %tldo_add(foo)
2615         sethi   %tie_hi22(foo), %o3
2616         add     %o3, %tie_lo10(foo), %o3
2617         ld      [%l7 + %o3], %o2, %tie_ld(foo)
2618         add     %g7, %o2, %o4, %tie_add(foo)
2619         sethi   %tle_hix22(foo), %l1
2620         xor     %l1, %tle_lox10(foo), %o5
2621         ld      [%g7 + %o5], %o1'
2622         tls_first_major=2
2623         tls_first_minor=14
2624         tls_as_opt="-32 --fatal-warnings"
2625       fi
2626         ;;
2627 changequote([,])dnl
2628 esac
2629 set_have_as_tls=no
2630 if test "x$enable_tls" = xno ; then
2631   : # TLS explicitly disabled.
2632 elif test "x$enable_tls" = xyes ; then
2633   set_have_as_tls=yes # TLS explicitly enabled.
2634 elif test -z "$tls_first_major"; then
2635   : # If we don't have a check, assume no support.
2636 else
2637   gcc_GAS_CHECK_FEATURE(thread-local storage support, gcc_cv_as_tls,
2638   [$tls_first_major,$tls_first_minor,0], [$tls_as_opt], [$conftest_s],,
2639   [set_have_as_tls=yes])
2640 fi
2641 if test $set_have_as_tls = yes ; then
2642   AC_DEFINE(HAVE_AS_TLS, 1,
2643             [Define if your assembler supports thread-local storage.])
2644 fi
2645
2646 # Target-specific assembler checks.
2647
2648 AC_MSG_CHECKING(linker -Bstatic/-Bdynamic option)
2649 gcc_cv_ld_static_dynamic=no
2650 if test $in_tree_ld = yes ; then
2651   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 10; then
2652     gcc_cv_ld_static_dynamic=yes
2653   fi
2654 elif test x$gcc_cv_ld != x; then
2655         # Check if linker supports -Bstatic/-Bdynamic option
2656         if $gcc_cv_ld --help 2>/dev/null | grep -- -Bstatic > /dev/null \
2657           && $gcc_cv_ld --help 2>/dev/null | grep -- -Bdynamic > /dev/null; then
2658                 gcc_cv_ld_static_dynamic=yes
2659         fi
2660 fi
2661 if test x"$gcc_cv_ld_static_dynamic" = xyes; then
2662         AC_DEFINE(HAVE_LD_STATIC_DYNAMIC, 1,
2663 [Define if your linker supports -Bstatic/-Bdynamic option.])
2664 fi
2665 AC_MSG_RESULT($gcc_cv_ld_static_dynamic)
2666
2667 if test x"$demangler_in_ld" = xyes; then
2668   AC_MSG_CHECKING(linker --demangle support)
2669   gcc_cv_ld_demangle=no
2670   if test $in_tree_ld = yes; then
2671     if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 14 -o "$gcc_cv_gld_major_version" -gt 2; then \
2672       gcc_cv_ld_demangle=yes
2673     fi
2674   elif test x$gcc_cv_ld != x -a x"$gnu_ld" = xyes; then
2675     # Check if the GNU linker supports --demangle option
2676     if $gcc_cv_ld --help 2>/dev/null | grep no-demangle > /dev/null; then
2677       gcc_cv_ld_demangle=yes
2678     fi
2679   fi
2680   if test x"$gcc_cv_ld_demangle" = xyes; then
2681     AC_DEFINE(HAVE_LD_DEMANGLE, 1,
2682 [Define if your linker supports --demangle option.])
2683   fi
2684   AC_MSG_RESULT($gcc_cv_ld_demangle)
2685 fi
2686
2687 case "$target" in
2688   # All TARGET_ABI_OSF targets.
2689   alpha*-*-osf* | alpha*-*-linux* | alpha*-*-*bsd*)
2690     gcc_GAS_CHECK_FEATURE([explicit relocation support],
2691         gcc_cv_as_alpha_explicit_relocs, [2,12,0],,
2692 [       .set nomacro
2693         .text
2694         extbl   $3, $2, $3      !lituse_bytoff!1
2695         ldq     $2, a($29)      !literal!1
2696         ldq     $4, b($29)      !literal!2
2697         ldq_u   $3, 0($2)       !lituse_base!1
2698         ldq     $27, f($29)     !literal!5
2699         jsr     $26, ($27), f   !lituse_jsr!5
2700         ldah    $29, 0($26)     !gpdisp!3
2701         lda     $0, c($29)      !gprel
2702         ldah    $1, d($29)      !gprelhigh
2703         lda     $1, d($1)       !gprellow
2704         lda     $29, 0($29)     !gpdisp!3],,
2705     [AC_DEFINE(HAVE_AS_EXPLICIT_RELOCS, 1,
2706   [Define if your assembler supports explicit relocations.])])
2707     gcc_GAS_CHECK_FEATURE([jsrdirect relocation support],
2708         gcc_cv_as_alpha_jsrdirect_relocs, [2,16,90],,
2709 [       .set nomacro
2710         .text
2711         ldq     $27, a($29)     !literal!1
2712         jsr     $26, ($27), a   !lituse_jsrdirect!1],,
2713     [AC_DEFINE(HAVE_AS_JSRDIRECT_RELOCS, 1,
2714   [Define if your assembler supports the lituse_jsrdirect relocation.])])
2715     ;;
2716
2717   cris-*-*)
2718     gcc_GAS_CHECK_FEATURE([-no-mul-bug-abort option],
2719       gcc_cv_as_cris_no_mul_bug,[2,15,91],
2720       [-no-mul-bug-abort], [.text],,
2721       [AC_DEFINE(HAVE_AS_NO_MUL_BUG_ABORT_OPTION, 1,
2722                 [Define if your assembler supports the -no-mul-bug-abort option.])])
2723     ;;
2724
2725   sparc*-*-*)
2726     gcc_GAS_CHECK_FEATURE([.register], gcc_cv_as_sparc_register_op,,,
2727       [.register %g2, #scratch],,
2728       [AC_DEFINE(HAVE_AS_REGISTER_PSEUDO_OP, 1,
2729                 [Define if your assembler supports .register.])])
2730
2731     gcc_GAS_CHECK_FEATURE([-relax option], gcc_cv_as_sparc_relax,,
2732       [-relax], [.text],,
2733       [AC_DEFINE(HAVE_AS_RELAX_OPTION, 1,
2734                 [Define if your assembler supports -relax option.])])
2735
2736     gcc_GAS_CHECK_FEATURE([unaligned pcrel relocs],
2737       gcc_cv_as_sparc_ua_pcrel,,
2738       [-K PIC],
2739 [.text
2740 foo:
2741         nop
2742 .data
2743 .align 4
2744 .byte 0
2745 .uaword %r_disp32(foo)],
2746       [if test x$gcc_cv_ld != x \
2747        && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1; then
2748          gcc_cv_as_sparc_ua_pcrel=yes
2749        fi
2750        rm -f conftest],
2751       [AC_DEFINE(HAVE_AS_SPARC_UA_PCREL, 1,
2752                 [Define if your assembler and linker support unaligned PC relative relocs.])
2753
2754       gcc_GAS_CHECK_FEATURE([unaligned pcrel relocs against hidden symbols],
2755         gcc_cv_as_sparc_ua_pcrel_hidden,,
2756         [-K PIC],
2757 [.data
2758 .align 4
2759 .byte 0x31
2760 .uaword %r_disp32(foo)
2761 .byte 0x32, 0x33, 0x34
2762 .global foo
2763 .hidden foo
2764 foo:
2765 .skip 4],
2766         [if test x$gcc_cv_ld != x && test x$gcc_cv_objdump != x \
2767          && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1 \
2768          && $gcc_cv_objdump -s -j .data conftest 2> /dev/null \
2769             | grep ' 31000000 07323334' > /dev/null 2>&1; then
2770             if $gcc_cv_objdump -R conftest 2> /dev/null \
2771                | grep 'DISP32' > /dev/null 2>&1; then
2772                 :
2773             else
2774                 gcc_cv_as_sparc_ua_pcrel_hidden=yes
2775             fi
2776          fi
2777          rm -f conftest],
2778          [AC_DEFINE(HAVE_AS_SPARC_UA_PCREL_HIDDEN, 1,
2779                    [Define if your assembler and linker support unaligned PC relative relocs against hidden symbols.])])
2780     ]) # unaligned pcrel relocs
2781
2782     gcc_GAS_CHECK_FEATURE([offsetable %lo()],
2783       gcc_cv_as_sparc_offsetable_lo10,,
2784       [-xarch=v9],
2785 [.text
2786         or %g1, %lo(ab) + 12, %g1
2787         or %g1, %lo(ab + 12), %g1],
2788       [if test x$gcc_cv_objdump != x \
2789        && $gcc_cv_objdump -s -j .text conftest.o 2> /dev/null \
2790           | grep ' 82106000 82106000' > /dev/null 2>&1; then
2791          gcc_cv_as_sparc_offsetable_lo10=yes
2792        fi],
2793        [AC_DEFINE(HAVE_AS_OFFSETABLE_LO10, 1,
2794                  [Define if your assembler supports offsetable %lo().])])
2795     ;;
2796
2797 changequote(,)dnl
2798   i[34567]86-*-* | x86_64-*-*)
2799 changequote([,])dnl
2800     case $target_os in
2801       cygwin* | pe | mingw32*)
2802         # Used for DWARF 2 in PE
2803         gcc_GAS_CHECK_FEATURE([.secrel32 relocs],
2804           gcc_cv_as_ix86_pe_secrel32,
2805           [2,15,91],,
2806 [.text
2807 foo:    nop
2808 .data
2809         .secrel32 foo],
2810           [if test x$gcc_cv_ld != x \
2811            && $gcc_cv_ld -o conftest conftest.o > /dev/null 2>&1; then
2812              gcc_cv_as_ix86_pe_secrel32=yes
2813            fi
2814            rm -f conftest],
2815           [AC_DEFINE(HAVE_GAS_PE_SECREL32_RELOC, 1,
2816             [Define if your assembler and linker support 32-bit section relative relocs via '.secrel32 label'.])])
2817         ;;
2818     esac
2819
2820     gcc_GAS_CHECK_FEATURE([filds and fists mnemonics],
2821        gcc_cv_as_ix86_filds_fists,
2822       [2,9,0],, [filds mem; fists mem],,
2823       [AC_DEFINE(HAVE_GAS_FILDS_FISTS, 1,
2824         [Define if your assembler uses the new HImode fild and fist notation.])])
2825
2826     gcc_GAS_CHECK_FEATURE([cmov syntax],
2827       gcc_cv_as_ix86_cmov_sun_syntax,,,
2828       [cmovl.l %edx, %eax],,
2829       [AC_DEFINE(HAVE_AS_IX86_CMOV_SUN_SYNTAX, 1,
2830         [Define if your assembler supports the Sun syntax for cmov.])])
2831
2832     gcc_GAS_CHECK_FEATURE([ffreep mnemonic],
2833       gcc_cv_as_ix86_ffreep,,,
2834       [ffreep %st(1)],,
2835       [AC_DEFINE(HAVE_AS_IX86_FFREEP, 1,
2836         [Define if your assembler supports the ffreep mnemonic.])])
2837
2838     gcc_GAS_CHECK_FEATURE([sahf mnemonic],
2839       gcc_cv_as_ix86_sahf,,,
2840       [sahf],,
2841       [AC_DEFINE(HAVE_AS_IX86_SAHF, 1,
2842         [Define if your assembler supports the sahf mnemonic.])])
2843
2844     gcc_GAS_CHECK_FEATURE([different section symbol subtraction],
2845       gcc_cv_as_ix86_diff_sect_delta,,,
2846       [.section .rodata
2847 .L1:
2848         .long .L2-.L1
2849         .long .L3-.L1
2850         .text
2851 .L3:    nop
2852 .L2:    nop],,
2853       [AC_DEFINE(HAVE_AS_IX86_DIFF_SECT_DELTA, 1,
2854         [Define if your assembler supports the subtraction of symbols in different sections.])])
2855
2856     # This one is used unconditionally by i386.[ch]; it is to be defined
2857     # to 1 if the feature is present, 0 otherwise.
2858     gcc_GAS_CHECK_FEATURE([GOTOFF in data],
2859         gcc_cv_as_ix86_gotoff_in_data, [2,11,0],,
2860 [       .text
2861 .L0:
2862         nop
2863         .data
2864         .long .L0@GOTOFF])
2865     AC_DEFINE_UNQUOTED(HAVE_AS_GOTOFF_IN_DATA,
2866       [`if test $gcc_cv_as_ix86_gotoff_in_data = yes; then echo 1; else echo 0; fi`],
2867       [Define true if the assembler supports '.long foo@GOTOFF'.])
2868     ;;
2869
2870   ia64*-*-*)
2871     gcc_GAS_CHECK_FEATURE([ltoffx and ldxmov relocs],
2872         gcc_cv_as_ia64_ltoffx_ldxmov_relocs, [2,14,0],,
2873 [       .text
2874         addl r15 = @ltoffx(x#), gp
2875         ;;
2876         ld8.mov r16 = [[r15]], x#],,
2877     [AC_DEFINE(HAVE_AS_LTOFFX_LDXMOV_RELOCS, 1,
2878           [Define if your assembler supports ltoffx and ldxmov relocations.])])
2879
2880     ;;
2881
2882   powerpc*-*-*)
2883     case $target in
2884       *-*-aix*) conftest_s='    .machine "pwr5"
2885         .csect .text[[PR]]
2886         mfcr 3,128';;
2887       *-*-darwin*)
2888         gcc_GAS_CHECK_FEATURE([.machine directive support],
2889           gcc_cv_as_machine_directive,,,
2890           [     .machine ppc7400])
2891         if test x$gcc_cv_as_machine_directive != xyes; then
2892           echo "*** This target requires an assembler supporting \".machine\"" >&2
2893           echo you can get it from: ftp://gcc.gnu.org/pub/gcc/infrastructure/cctools-528.5.dmg >&2
2894           test x$build = x$target && exit 1
2895         fi
2896         conftest_s='    .text
2897         mfcr r3,128';;
2898       *) conftest_s='   .machine power4
2899         .text
2900         mfcr 3,128';;
2901     esac
2902
2903     gcc_GAS_CHECK_FEATURE([mfcr field support],
2904       gcc_cv_as_powerpc_mfcrf, [2,14,0],,
2905       [$conftest_s],,
2906       [AC_DEFINE(HAVE_AS_MFCRF, 1,
2907           [Define if your assembler supports mfcr field.])])
2908
2909     case $target in
2910       *-*-aix*) conftest_s='    .machine "pwr5"
2911         .csect .text[[PR]]
2912         popcntb 3,3';;
2913       *) conftest_s='   .machine power5
2914         .text
2915         popcntb 3,3';;
2916     esac
2917
2918     gcc_GAS_CHECK_FEATURE([popcntb support],
2919       gcc_cv_as_powerpc_popcntb, [2,17,0],,
2920       [$conftest_s],,
2921       [AC_DEFINE(HAVE_AS_POPCNTB, 1,
2922           [Define if your assembler supports popcntb field.])])
2923
2924     case $target in
2925       *-*-aix*) conftest_s='    .machine "pwr5x"
2926         .csect .text[[PR]]
2927         frin 1,1';;
2928       *) conftest_s='   .machine power5
2929         .text
2930         frin 1,1';;
2931     esac
2932
2933     gcc_GAS_CHECK_FEATURE([fp round support],
2934       gcc_cv_as_powerpc_fprnd, [2,17,0],,
2935       [$conftest_s],,
2936       [AC_DEFINE(HAVE_AS_FPRND, 1,
2937           [Define if your assembler supports fprnd.])])
2938
2939     case $target in
2940       *-*-aix*) conftest_s='    .machine "pwr6"
2941         .csect .text[[PR]]
2942         mffgpr 1,3';;
2943       *) conftest_s='   .machine power6
2944         .text
2945         mffgpr 1,3';;
2946     esac
2947
2948     gcc_GAS_CHECK_FEATURE([move fp gpr support],
2949       gcc_cv_as_powerpc_mfpgpr, [9,99,0],,
2950       [$conftest_s],,
2951       [AC_DEFINE(HAVE_AS_MFPGPR, 1,
2952           [Define if your assembler supports mffgpr and mftgpr.])])
2953
2954     case $target in
2955       *-*-aix*) conftest_s='    .csect .text[[PR]]
2956 LCF..0:
2957         addis 11,30,_GLOBAL_OFFSET_TABLE_-LCF..0@ha';;
2958       *-*-darwin*)
2959         conftest_s='    .text
2960 LCF0:
2961         addis r11,r30,_GLOBAL_OFFSET_TABLE_-LCF0@ha';;
2962       *) conftest_s='   .text
2963 .LCF0:
2964         addis 11,30,_GLOBAL_OFFSET_TABLE_-.LCF0@ha';;
2965     esac
2966
2967     gcc_GAS_CHECK_FEATURE([rel16 relocs],
2968       gcc_cv_as_powerpc_rel16, [2,17,0], -a32,
2969       [$conftest_s],,
2970       [AC_DEFINE(HAVE_AS_REL16, 1,
2971           [Define if your assembler supports R_PPC_REL16 relocs.])])
2972
2973     case $target in
2974       *-*-aix*) conftest_s='    .machine "pwr6"
2975         .csect .text[[PR]]
2976         cmpb 3,4,5';;
2977       *) conftest_s='   .machine power6
2978         .text
2979         cmpb 3,4,5';;
2980     esac
2981
2982     gcc_GAS_CHECK_FEATURE([compare bytes support],
2983       gcc_cv_as_powerpc_cmpb, [9,99,0], -a32,
2984       [$conftest_s],,
2985       [AC_DEFINE(HAVE_AS_CMPB, 1,
2986           [Define if your assembler supports cmpb.])])
2987
2988     case $target in
2989       *-*-aix*) conftest_s='    .machine "pwr6"
2990         .csect .text[[PR]]
2991         dadd 1,2,3';;
2992       *) conftest_s='   .machine power6
2993         .text
2994         dadd 1,2,3';;
2995     esac
2996
2997     gcc_GAS_CHECK_FEATURE([decimal float support],
2998       gcc_cv_as_powerpc_dfp, [9,99,0], -a32,
2999       [$conftest_s],,
3000       [AC_DEFINE(HAVE_AS_DFP, 1,
3001           [Define if your assembler supports DFP instructions.])])
3002
3003     gcc_GAS_CHECK_FEATURE([.gnu_attribute support],
3004       gcc_cv_as_powerpc_gnu_attribute, [2,18,0],,
3005       [.gnu_attribute 4,1],,
3006       [AC_DEFINE(HAVE_AS_GNU_ATTRIBUTE, 1,
3007           [Define if your assembler supports .gnu_attribute.])])
3008     ;;
3009
3010   mips*-*-*)
3011     gcc_GAS_CHECK_FEATURE([explicit relocation support],
3012       gcc_cv_as_mips_explicit_relocs, [2,14,0],,
3013 [       lw $4,%gp_rel(foo)($4)],,
3014       [if test x$target_cpu_default = x
3015        then target_cpu_default=MASK_EXPLICIT_RELOCS
3016        else target_cpu_default="($target_cpu_default)|MASK_EXPLICIT_RELOCS"
3017        fi])
3018     gcc_GAS_CHECK_FEATURE([-mno-shared support],
3019       gcc_cv_as_mips_no_shared, [2,16,0], [-mno-shared], [nop],,
3020       [AC_DEFINE(HAVE_AS_NO_SHARED, 1,
3021                  [Define if the assembler understands -mno-shared.])])
3022
3023     gcc_GAS_CHECK_FEATURE([.gnu_attribute support],
3024       gcc_cv_as_mips_gnu_attribute, [2,18,0],,
3025       [.gnu_attribute 4,1],,
3026       [AC_DEFINE(HAVE_AS_GNU_ATTRIBUTE, 1,
3027           [Define if your assembler supports .gnu_attribute.])])
3028
3029     gcc_GAS_CHECK_FEATURE([.dtprelword support],
3030       gcc_cv_as_mips_dtprelword, [2,18,0],,
3031       [.section .tdata,"awT",@progbits
3032 x:
3033         .word 2
3034         .text
3035         .dtprelword x+0x8000],,
3036       [AC_DEFINE(HAVE_AS_DTPRELWORD, 1,
3037           [Define if your assembler supports .dtprelword.])])
3038     ;;
3039 esac
3040
3041 # Mips and HP-UX need the GNU assembler.
3042 # Linux on IA64 might be able to use the Intel assembler.
3043
3044 case "$target" in
3045   mips*-*-* | *-*-hpux* )
3046     if test x$gas_flag = xyes \
3047        || test x"$host" != x"$build" \
3048        || test ! -x "$gcc_cv_as" \
3049        || "$gcc_cv_as" -v < /dev/null 2>&1 | grep GNU > /dev/null; then
3050       :
3051     else
3052       echo "*** This configuration requires the GNU assembler" >&2
3053       exit 1
3054     fi
3055     ;;
3056 esac
3057
3058 # ??? Not all targets support dwarf2 debug_line, even within a version
3059 # of gas.  Moreover, we need to emit a valid instruction to trigger any
3060 # info to the output file.  So, as supported targets are added to gas 2.11,
3061 # add some instruction here to (also) show we expect this might work.
3062 # ??? Once 2.11 is released, probably need to add first known working
3063 # version to the per-target configury.
3064 case "$target" in
3065   i?86*-*-* | mips*-*-* | alpha*-*-* | powerpc*-*-* | sparc*-*-* | m68*-*-* \
3066   | x86_64*-*-* | hppa*-*-* | arm*-*-* \
3067   | xstormy16*-*-* | cris-*-* | xtensa-*-* | bfin-*-* | score*-*-* \
3068   | spu-*-* | fido*-*-*)
3069     insn="nop"
3070     ;;
3071   ia64*-*-* | s390*-*-*)
3072     insn="nop 0"
3073     ;;
3074   mmix-*-*)
3075     insn="swym 0"
3076     ;;
3077 esac
3078 if test x"$insn" != x; then
3079  conftest_s="\
3080         .file 1 \"conftest.s\"
3081         .loc 1 3 0
3082         $insn"
3083  gcc_GAS_CHECK_FEATURE([dwarf2 debug_line support],
3084   gcc_cv_as_dwarf2_debug_line,
3085   [elf,2,11,0],, [$conftest_s],
3086   [if test x$gcc_cv_objdump != x \
3087    && $gcc_cv_objdump -h conftest.o 2> /dev/null \
3088       | grep debug_line > /dev/null 2>&1; then
3089      gcc_cv_as_dwarf2_debug_line=yes
3090    fi])
3091
3092 # The .debug_line file table must be in the exact order that
3093 # we specified the files, since these indices are also used
3094 # by DW_AT_decl_file.  Approximate this test by testing if
3095 # the assembler bitches if the same index is assigned twice.
3096  gcc_GAS_CHECK_FEATURE([buggy dwarf2 .file directive],
3097   gcc_cv_as_dwarf2_file_buggy,,,
3098 [       .file 1 "foo.s"
3099         .file 1 "bar.s"])
3100
3101  if test $gcc_cv_as_dwarf2_debug_line = yes \
3102  && test $gcc_cv_as_dwarf2_file_buggy = no; then
3103         AC_DEFINE(HAVE_AS_DWARF2_DEBUG_LINE, 1,
3104   [Define if your assembler supports dwarf2 .file/.loc directives,
3105    and preserves file table indices exactly as given.])
3106  fi
3107
3108  gcc_GAS_CHECK_FEATURE([--gdwarf2 option],
3109   gcc_cv_as_gdwarf2_flag,
3110   [elf,2,11,0], [--gdwarf2], [$insn],,
3111   [AC_DEFINE(HAVE_AS_GDWARF2_DEBUG_FLAG, 1,
3112 [Define if your assembler supports the --gdwarf2 option.])])
3113
3114  gcc_GAS_CHECK_FEATURE([--gstabs option],
3115   gcc_cv_as_gstabs_flag,
3116   [elf,2,11,0], [--gstabs], [$insn],
3117   [# The native Solaris 9/Intel assembler doesn't understand --gstabs
3118    # and warns about it, but still exits successfully.  So check for
3119    # this.
3120    if AC_TRY_COMMAND([$gcc_cv_as --gstabs -o conftest.o conftest.s 2>&1 | grep -i warning > /dev/null])
3121    then :
3122    else gcc_cv_as_gstabs_flag=yes
3123    fi],
3124   [AC_DEFINE(HAVE_AS_GSTABS_DEBUG_FLAG, 1,
3125 [Define if your assembler supports the --gstabs option.])])
3126
3127  gcc_GAS_CHECK_FEATURE([--debug-prefix-map option],
3128   gcc_cv_as_debug_prefix_map_flag,
3129   [2,18,0], [--debug-prefix-map /a=/b], [$insn],,
3130   [AC_DEFINE(HAVE_AS_DEBUG_PREFIX_MAP, 1,
3131 [Define if your assembler supports the --debug-prefix-map option.])])
3132 fi
3133
3134 AC_CACHE_CHECK([assembler for tolerance to line number 0],
3135  [gcc_cv_as_line_zero],
3136  [gcc_cv_as_line_zero=no
3137   if test $in_tree_gas = yes; then
3138     gcc_GAS_VERSION_GTE_IFELSE(2, 16, 91, [gcc_cv_as_line_zero=yes])
3139   elif test "x$gcc_cv_as" != x; then
3140     { echo '# 1 "test.s" 1'; echo '# 0 "" 2'; } > conftest.s
3141     if AC_TRY_COMMAND([$gcc_cv_as -o conftest.o conftest.s >&AS_MESSAGE_LOG_FD 2>conftest.out]) &&
3142        test "x`cat conftest.out`" = x
3143     then
3144       gcc_cv_as_line_zero=yes
3145     else
3146       echo "configure: failed program was" >&AS_MESSAGE_LOG_FD
3147       cat conftest.s >&AS_MESSAGE_LOG_FD
3148       echo "configure: error output was" >&AS_MESSAGE_LOG_FD
3149       cat conftest.out >&AS_MESSAGE_LOG_FD
3150     fi
3151     rm -f conftest.o conftest.s conftest.out
3152   fi])
3153 if test "x$gcc_cv_as_line_zero" = xyes; then
3154   AC_DEFINE([HAVE_AS_LINE_ZERO], 1,
3155 [Define if the assembler won't complain about a line such as # 0 "" 2.])
3156 fi
3157
3158 AC_MSG_CHECKING(linker read-only and read-write section mixing)
3159 gcc_cv_ld_ro_rw_mix=unknown
3160 if test $in_tree_ld = yes ; then
3161   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 10 -o "$gcc_cv_gld_major_version" -gt 2 \
3162      && test $in_tree_ld_is_elf = yes; then
3163     gcc_cv_ld_ro_rw_mix=read-write
3164   fi
3165 elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x -a x$gcc_cv_objdump != x ; then
3166   echo '.section myfoosect, "a"' > conftest1.s
3167   echo '.section myfoosect, "aw"' > conftest2.s
3168   echo '.byte 1' >> conftest2.s
3169   echo '.section myfoosect, "a"' > conftest3.s
3170   echo '.byte 0' >> conftest3.s
3171   if $gcc_cv_as -o conftest1.o conftest1.s > /dev/null 2>&1 \
3172      && $gcc_cv_as -o conftest2.o conftest2.s > /dev/null 2>&1 \
3173      && $gcc_cv_as -o conftest3.o conftest3.s > /dev/null 2>&1 \
3174      && $gcc_cv_ld -shared -o conftest1.so conftest1.o \
3175         conftest2.o conftest3.o > /dev/null 2>&1; then
3176     gcc_cv_ld_ro_rw_mix=`$gcc_cv_objdump -h conftest1.so \
3177                          | sed -e '/myfoosect/!d' -e N`
3178     if echo "$gcc_cv_ld_ro_rw_mix" | grep CONTENTS > /dev/null; then
3179       if echo "$gcc_cv_ld_ro_rw_mix" | grep READONLY > /dev/null; then
3180         gcc_cv_ld_ro_rw_mix=read-only
3181       else
3182         gcc_cv_ld_ro_rw_mix=read-write
3183       fi
3184     fi
3185   fi
3186 changequote(,)dnl
3187   rm -f conftest.* conftest[123].*
3188 changequote([,])dnl
3189 fi
3190 if test x$gcc_cv_ld_ro_rw_mix = xread-write; then
3191         AC_DEFINE(HAVE_LD_RO_RW_SECTION_MIXING, 1,
3192   [Define if your linker links a mix of read-only
3193    and read-write sections into a read-write section.])
3194 fi
3195 AC_MSG_RESULT($gcc_cv_ld_ro_rw_mix)
3196
3197 AC_MSG_CHECKING(linker PT_GNU_EH_FRAME support)
3198 gcc_cv_ld_eh_frame_hdr=no
3199 if test $in_tree_ld = yes ; then
3200   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 12 -o "$gcc_cv_gld_major_version" -gt 2 \
3201      && test $in_tree_ld_is_elf = yes; then
3202     gcc_cv_ld_eh_frame_hdr=yes
3203   fi
3204 elif test x$gcc_cv_ld != x; then
3205         # Check if linker supports --eh-frame-hdr option
3206         if $gcc_cv_ld --help 2>/dev/null | grep eh-frame-hdr > /dev/null; then
3207                 gcc_cv_ld_eh_frame_hdr=yes
3208         fi
3209 fi
3210 GCC_TARGET_TEMPLATE([HAVE_LD_EH_FRAME_HDR])
3211 if test x"$gcc_cv_ld_eh_frame_hdr" = xyes; then
3212         AC_DEFINE(HAVE_LD_EH_FRAME_HDR, 1,
3213 [Define if your linker supports --eh-frame-hdr option.])
3214 fi
3215 AC_MSG_RESULT($gcc_cv_ld_eh_frame_hdr)
3216
3217 AC_MSG_CHECKING(linker position independent executable support)
3218 gcc_cv_ld_pie=no
3219 if test $in_tree_ld = yes ; then
3220   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 15 -o "$gcc_cv_gld_major_version" -gt 2 \
3221      && test $in_tree_ld_is_elf = yes; then
3222     gcc_cv_ld_pie=yes
3223   fi
3224 elif test x$gcc_cv_ld != x; then
3225         # Check if linker supports -pie option
3226         if $gcc_cv_ld --help 2>/dev/null | grep -- -pie > /dev/null; then
3227                 gcc_cv_ld_pie=yes
3228         fi
3229 fi
3230 if test x"$gcc_cv_ld_pie" = xyes; then
3231         AC_DEFINE(HAVE_LD_PIE, 1,
3232 [Define if your linker supports -pie option.])
3233 fi
3234 AC_MSG_RESULT($gcc_cv_ld_pie)
3235
3236 AC_MSG_CHECKING(linker EH-compatible garbage collection of sections)
3237 gcc_cv_ld_eh_gc_sections=no
3238 if test $in_tree_ld = yes ; then
3239   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 17 -o "$gcc_cv_gld_major_version" -gt 2 \
3240      && test $in_tree_ld_is_elf = yes; then
3241     gcc_cv_ld_eh_gc_sections=yes
3242   fi
3243 elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x -a x$gcc_cv_objdump != x ; then
3244   cat > conftest.s <<EOF
3245         .section        .text
3246 .globl _start
3247         .type _start, @function
3248 _start:
3249         .long foo
3250         .size _start, .-_start
3251         .section        .text.foo,"ax",@progbits
3252         .type foo, @function
3253 foo:
3254         .long 0
3255         .size foo, .-foo
3256         .section        .gcc_except_table.foo,"a",@progbits
3257 .L0:
3258         .long 0
3259         .section        .eh_frame,"a",@progbits
3260         .long .L0
3261 EOF
3262   if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
3263     if $gcc_cv_ld -o conftest conftest.o --entry=_start --gc-sections 2>&1 \
3264          | grep "gc-sections option ignored" > /dev/null; then
3265       gcc_cv_ld_eh_gc_sections=no
3266     elif $gcc_cv_objdump -h conftest | grep gcc_except_table > /dev/null; then
3267       gcc_cv_ld_eh_gc_sections=yes
3268       # If no COMDAT groups, the compiler will emit .gnu.linkonce.t. sections.
3269       if test x$gcc_cv_as_comdat_group != xyes; then
3270         gcc_cv_ld_eh_gc_sections=no
3271         cat > conftest.s <<EOF
3272         .section        .text
3273 .globl _start
3274         .type _start, @function
3275 _start:
3276         .long foo
3277         .size _start, .-_start
3278         .section        .gnu.linkonce.t.foo,"ax",@progbits
3279         .type foo, @function
3280 foo:
3281         .long 0
3282         .size foo, .-foo
3283         .section        .gcc_except_table.foo,"a",@progbits
3284 .L0:
3285         .long 0
3286         .section        .eh_frame,"a",@progbits
3287         .long .L0
3288 EOF
3289         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
3290           if $gcc_cv_ld -o conftest conftest.o --entry=_start --gc-sections 2>&1 \
3291                | grep "gc-sections option ignored" > /dev/null; then
3292             gcc_cv_ld_eh_gc_sections=no
3293           elif $gcc_cv_objdump -h conftest | grep gcc_except_table > /dev/null; then
3294             gcc_cv_ld_eh_gc_sections=yes
3295           fi
3296         fi
3297       fi
3298     fi
3299   fi
3300   rm -f conftest.s conftest.o conftest
3301 fi
3302 case "$target" in
3303   hppa*-*-linux*)
3304     # ??? This apparently exposes a binutils bug with PC-relative relocations.
3305     gcc_cv_ld_eh_gc_sections=no
3306     ;;
3307 esac
3308 if test x$gcc_cv_ld_eh_gc_sections = xyes; then
3309         AC_DEFINE(HAVE_LD_EH_GC_SECTIONS, 1,
3310   [Define if your linker supports garbage collection of
3311    sections in presence of EH frames.])
3312 fi
3313 AC_MSG_RESULT($gcc_cv_ld_eh_gc_sections)
3314
3315 # --------
3316 # UNSORTED
3317 # --------
3318
3319 AC_CACHE_CHECK(linker --as-needed support,
3320 gcc_cv_ld_as_needed,
3321 [gcc_cv_ld_as_needed=no
3322 if test $in_tree_ld = yes ; then
3323   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2 \
3324      && test $in_tree_ld_is_elf = yes; then
3325     gcc_cv_ld_as_needed=yes
3326   fi
3327 elif test x$gcc_cv_ld != x; then
3328         # Check if linker supports --as-needed and --no-as-needed options
3329         if $gcc_cv_ld --help 2>/dev/null | grep as-needed > /dev/null; then
3330                 gcc_cv_ld_as_needed=yes
3331         fi
3332 fi
3333 ])
3334 if test x"$gcc_cv_ld_as_needed" = xyes; then
3335         AC_DEFINE(HAVE_LD_AS_NEEDED, 1,
3336 [Define if your linker supports --as-needed and --no-as-needed options.])
3337 fi
3338
3339 case "$target:$tm_file" in
3340   powerpc64*-*-linux* | powerpc*-*-linux*rs6000/biarch64.h*)
3341     AC_CACHE_CHECK(linker support for omitting dot symbols,
3342     gcc_cv_ld_no_dot_syms,
3343     [gcc_cv_ld_no_dot_syms=no
3344     if test $in_tree_ld = yes ; then
3345       if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2; then
3346         gcc_cv_ld_no_dot_syms=yes
3347       fi
3348     elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x ; then
3349       cat > conftest1.s <<EOF
3350         .text
3351         bl .foo
3352 EOF
3353       cat > conftest2.s <<EOF
3354         .section ".opd","aw"
3355         .align 3
3356         .globl foo
3357         .type foo,@function
3358 foo:
3359         .quad .LEfoo,.TOC.@tocbase,0
3360         .text
3361 .LEfoo:
3362         blr
3363         .size foo,.-.LEfoo
3364 EOF
3365       if $gcc_cv_as -a64 -o conftest1.o conftest1.s > /dev/null 2>&1 \
3366          && $gcc_cv_as -a64 -o conftest2.o conftest2.s > /dev/null 2>&1 \
3367          && $gcc_cv_ld -melf64ppc -o conftest conftest1.o conftest2.o > /dev/null 2>&1; then
3368         gcc_cv_ld_no_dot_syms=yes
3369       fi
3370       rm -f conftest conftest1.o conftest2.o conftest1.s conftest2.s
3371     fi
3372     ])
3373     if test x"$gcc_cv_ld_no_dot_syms" = xyes; then
3374       AC_DEFINE(HAVE_LD_NO_DOT_SYMS, 1,
3375     [Define if your PowerPC64 linker only needs function descriptor syms.])
3376     fi
3377     ;;
3378 esac
3379
3380 AC_CACHE_CHECK(linker --sysroot support,
3381   gcc_cv_ld_sysroot,
3382   [gcc_cv_ld_sysroot=no
3383   if test $in_tree_ld = yes ; then
3384       if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2 ; then
3385         gcc_cv_ld_sysroot=yes
3386       fi
3387   elif test x$gcc_cv_ld != x; then
3388     if $gcc_cv_ld --help 2>/dev/null | grep sysroot > /dev/null; then
3389       gcc_cv_ld_sysroot=yes
3390     fi
3391   fi])
3392 if test x"$gcc_cv_ld_sysroot" = xyes; then
3393   AC_DEFINE(HAVE_LD_SYSROOT, 1,
3394   [Define if your linker supports --sysroot.])
3395 fi
3396
3397 if test x$with_sysroot = x && test x$host = x$target \
3398    && test "$prefix" != "/usr" && test "x$prefix" != "x$local_prefix" \
3399    && test "$prefix" != "NONE"; then
3400   AC_DEFINE_UNQUOTED(PREFIX_INCLUDE_DIR, "$prefix/include",
3401 [Define to PREFIX/include if cpp should also search that directory.])
3402 fi
3403
3404 # Test for stack protector support in target C library.
3405 AC_CACHE_CHECK(__stack_chk_fail in target C library,
3406       gcc_cv_libc_provides_ssp,
3407       [gcc_cv_libc_provides_ssp=no
3408     case "$target" in
3409        *-*-linux*)
3410       if test x$host != x$target || test "x$TARGET_SYSTEM_ROOT" != x; then
3411         if test "x$with_sysroot" = x; then
3412           glibc_header_dir="${exec_prefix}/${target_noncanonical}/sys-include"
3413         elif test "x$with_build_sysroot" != "x"; then
3414           glibc_header_dir="${with_build_sysroot}/usr/include"
3415         elif test "x$with_sysroot" = xyes; then
3416           glibc_header_dir="${exec_prefix}/${target_noncanonical}/sys-root/usr/include"
3417         else
3418           glibc_header_dir="${with_sysroot}/usr/include"
3419         fi
3420       else
3421         glibc_header_dir=/usr/include
3422       fi
3423       # glibc 2.4 and later provides __stack_chk_fail and
3424       # either __stack_chk_guard, or TLS access to stack guard canary.
3425       if test -f $glibc_header_dir/features.h \
3426          && $EGREP '^@<:@       @:>@*#[         ]*define[       ]+__GNU_LIBRARY__[      ]+([1-9][0-9]|[6-9])' \
3427             $glibc_header_dir/features.h > /dev/null; then
3428         if $EGREP '^@<:@        @:>@*#[         ]*define[       ]+__GLIBC__[    ]+([1-9][0-9]|[3-9])' \
3429            $glibc_header_dir/features.h > /dev/null; then
3430           gcc_cv_libc_provides_ssp=yes
3431         elif $EGREP '^@<:@      @:>@*#[         ]*define[       ]+__GLIBC__[    ]+2' \
3432              $glibc_header_dir/features.h > /dev/null \
3433              && $EGREP '^@<:@   @:>@*#[         ]*define[       ]+__GLIBC_MINOR__[      ]+([1-9][0-9]|[4-9])' \
3434              $glibc_header_dir/features.h > /dev/null; then
3435           gcc_cv_libc_provides_ssp=yes
3436         elif $EGREP '^@<:@      @:>@*#[         ]*define[       ]+__UCLIBC__[   ]+1' \
3437              $glibc_header_dir/features.h > /dev/null && \
3438              test -f $glibc_header_dir/bits/uClibc_config.h && \
3439              $EGREP '^@<:@      @:>@*#[         ]*define[       ]+__UCLIBC_HAS_SSP__[   ]+1' \
3440              $glibc_header_dir/bits/uClibc_config.h > /dev/null; then
3441           gcc_cv_libc_provides_ssp=yes
3442         fi
3443       fi
3444         ;;
3445        *-*-darwin*)
3446          AC_CHECK_FUNC(__stack_chk_fail,[gcc_cv_libc_provides_ssp=yes],
3447            [echo "no __stack_chk_fail on this target"])
3448         ;;
3449   *) gcc_cv_libc_provides_ssp=no ;;
3450     esac])
3451
3452 if test x$gcc_cv_libc_provides_ssp = xyes; then
3453   AC_DEFINE(TARGET_LIBC_PROVIDES_SSP, 1,
3454             [Define if your target C library provides stack protector support])
3455 fi
3456
3457 # Check if TFmode long double should be used by default or not.
3458 # Some glibc targets used DFmode long double, but with glibc 2.4
3459 # and later they can use TFmode.
3460 case "$target" in
3461   powerpc*-*-linux* | \
3462   powerpc*-*-gnu* | \
3463   sparc*-*-linux* | \
3464   s390*-*-linux* | \
3465   alpha*-*-linux*)
3466     AC_ARG_WITH(long-double-128,
3467 [  --with-long-double-128  Use 128-bit long double by default.],
3468       gcc_cv_target_ldbl128="$with_long_double_128",
3469       [gcc_cv_target_ldbl128=no
3470       if test x$host != x$target || test "x$TARGET_SYSTEM_ROOT" != x; then
3471         if test "x$with_sysroot" = x; then
3472           glibc_header_dir="${exec_prefix}/${target_noncanonical}/sys-include"
3473         elif test "x$with_build_sysroot" != "x"; then
3474           glibc_header_dir="${with_build_sysroot}/usr/include"
3475         elif test "x$with_sysroot" = xyes; then
3476           glibc_header_dir="${exec_prefix}/${target_noncanonical}/sys-root/usr/include"
3477         else
3478           glibc_header_dir="${with_sysroot}/usr/include"
3479         fi
3480       else
3481         glibc_header_dir=/usr/include
3482       fi
3483 changequote(,)dnl
3484       grep '^[  ]*#[    ]*define[       ][      ]*__LONG_DOUBLE_MATH_OPTIONAL' \
3485         $glibc_header_dir/bits/wordsize.h > /dev/null 2>&1 \
3486       && gcc_cv_target_ldbl128=yes
3487 changequote([,])dnl
3488       ])
3489     ;;
3490 esac
3491 if test x$gcc_cv_target_ldbl128 = xyes; then
3492   AC_DEFINE(TARGET_DEFAULT_LONG_DOUBLE_128, 1,
3493             [Define if TFmode long double should be the default])
3494 fi
3495
3496 # Find out what GC implementation we want, or may, use.
3497 AC_ARG_WITH(gc,
3498 [  --with-gc={page,zone}   choose the garbage collection mechanism to use
3499                           with the compiler],
3500 [case "$withval" in
3501   page)
3502     GGC=ggc-$withval
3503     ;;
3504   zone)
3505     GGC=ggc-$withval
3506     AC_DEFINE(GGC_ZONE, 1, [Define if the zone collector is in use])
3507     ;;
3508   *)
3509     AC_MSG_ERROR([$withval is an invalid option to --with-gc])
3510     ;;
3511 esac],
3512 [GGC=ggc-page])
3513 AC_SUBST(GGC)
3514 echo "Using $GGC for garbage collection."
3515
3516 # Use the system's zlib library.
3517 zlibdir=-L../zlib
3518 zlibinc="-I\$(srcdir)/../zlib"
3519 AC_ARG_WITH(system-zlib,
3520 [  --with-system-zlib      use installed libz],
3521 zlibdir=
3522 zlibinc=
3523 )
3524 AC_SUBST(zlibdir)
3525 AC_SUBST(zlibinc)
3526
3527 dnl Very limited version of automake's enable-maintainer-mode
3528
3529 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
3530   dnl maintainer-mode is disabled by default
3531   AC_ARG_ENABLE(maintainer-mode,
3532 [  --enable-maintainer-mode
3533                           enable make rules and dependencies not useful
3534                           (and sometimes confusing) to the casual installer],
3535       maintainer_mode=$enableval,
3536       maintainer_mode=no)
3537
3538 AC_MSG_RESULT($maintainer_mode)
3539
3540 if test "$maintainer_mode" = "yes"; then
3541   MAINT=''
3542 else
3543   MAINT='#'
3544 fi
3545 AC_SUBST(MAINT)dnl
3546
3547 # --------------
3548 # Language hooks
3549 # --------------
3550
3551 # Make empty files to contain the specs and options for each language.
3552 # Then add #include lines to for a compiler that has specs and/or options.
3553
3554 subdirs=
3555 lang_opt_files=
3556 lang_specs_files=
3557 lang_tree_files=
3558 # These (without "all_") are set in each config-lang.in.
3559 # `language' must be a single word so is spelled singularly.
3560 all_languages=
3561 all_compilers=
3562 all_outputs='Makefile gccbug libada-mk'
3563 # List of language makefile fragments.
3564 all_lang_makefrags=
3565 # List of language subdirectory makefiles.  Deprecated.
3566 all_lang_makefiles=
3567 # Additional files for gengtype
3568 all_gtfiles="$target_gtfiles"
3569
3570 # These are the languages that are set in --enable-languages,
3571 # and are available in the GCC tree.
3572 all_selected_languages=
3573
3574 # Add the language fragments.
3575 # Languages are added via two mechanisms.  Some information must be
3576 # recorded in makefile variables, these are defined in config-lang.in.
3577 # We accumulate them and plug them into the main Makefile.
3578 # The other mechanism is a set of hooks for each of the main targets
3579 # like `clean', `install', etc.
3580
3581 language_hooks="Make-hooks"
3582
3583 for lang in ${srcdir}/*/config-lang.in
3584 do
3585 changequote(,)dnl
3586         test "$lang" = "${srcdir}/*/config-lang.in" && continue
3587
3588         lang_alias=`sed -n -e 's,^language=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^language=\([^   ]*\).*$,\1,p' $lang`
3589         if test "x$lang_alias" = x
3590         then
3591               echo "$lang doesn't set \$language." 1>&2
3592               exit 1
3593         fi
3594         subdir="`echo $lang | sed -e 's,^.*/\([^/]*\)/config-lang.in$,\1,'`"
3595         subdirs="$subdirs $subdir"
3596
3597         # $gcc_subdir is where the gcc integration files are to be found
3598         # for a language, both for internal compiler purposes (compiler
3599         # sources implementing front-end to GCC tree converters), and for
3600         # build infrastructure purposes (Make-lang.in, etc.)
3601         #
3602         # This will be <subdir> (relative to $srcdir) if a line like
3603         # gcc_subdir="<subdir>" or gcc_subdir=<subdir>
3604         # is found in <langdir>/config-lang.in, and will remain <langdir>
3605         # otherwise.
3606         #
3607         # Except for the language alias (fetched above), the regular
3608         # "config-lang.in" contents are always retrieved from $gcc_subdir,
3609         # so a <langdir>/config-lang.in setting gcc_subdir typically sets
3610         # only this and the language alias.
3611
3612         gcc_subdir=`sed -n -e 's,^gcc_subdir=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^gcc_subdir=\([^   ]*\).*$,\1,p' $lang`
3613         if [ "$gcc_subdir" = "" ]; then
3614            gcc_subdir="$subdir"
3615         fi
3616
3617         case ",$enable_languages," in
3618         *,$lang_alias,*)
3619             all_selected_languages="$all_selected_languages $lang_alias"
3620             if test -f $srcdir/$gcc_subdir/lang-specs.h; then
3621                 lang_specs_files="$lang_specs_files $srcdir/$gcc_subdir/lang-specs.h"
3622             fi
3623             ;;
3624         esac
3625 changequote([,])dnl
3626
3627         language=
3628         boot_language=
3629         compilers=
3630         outputs=
3631         gtfiles=
3632         subdir_requires=
3633         . ${srcdir}/$gcc_subdir/config-lang.in
3634         if test "x$language" = x
3635         then
3636                 echo "${srcdir}/$gcc_subdir/config-lang.in doesn't set \$language." 1>&2
3637                 exit 1
3638         fi
3639
3640         ok=:
3641         case ",$enable_languages," in
3642                 *,$lang_alias,*) ;;
3643                 *)
3644                         for i in $subdir_requires; do
3645                                 test -f "${srcdir}/$i/config-lang.in" && continue
3646                                 ok=false
3647                                 break
3648                         done
3649                 ;;
3650         esac
3651         $ok || continue
3652
3653         all_lang_makefrags="$all_lang_makefrags \$(srcdir)/$gcc_subdir/Make-lang.in"
3654         if test -f $srcdir/$gcc_subdir/lang.opt; then
3655             lang_opt_files="$lang_opt_files $srcdir/$gcc_subdir/lang.opt"
3656         fi
3657         if test -f $srcdir/$gcc_subdir/$subdir-tree.def; then
3658             lang_tree_files="$lang_tree_files $srcdir/$gcc_subdir/$subdir-tree.def"
3659         fi
3660         if test -f ${srcdir}/$gcc_subdir/Makefile.in
3661                 then all_lang_makefiles="$gcc_subdir/Makefile"
3662         fi
3663         all_languages="$all_languages $language"
3664         all_compilers="$all_compilers $compilers"
3665         all_outputs="$all_outputs $outputs"
3666         all_gtfiles="$all_gtfiles [[$subdir]] $gtfiles"
3667 done
3668
3669 # Pick up gtfiles for c
3670 gtfiles=
3671 . ${srcdir}/c-config-lang.in
3672 all_gtfiles="$all_gtfiles [[c]] $gtfiles"
3673
3674 check_languages=
3675 for language in $all_selected_languages
3676 do
3677         check_languages="$check_languages check-$language"
3678 done
3679
3680 # We link each language in with a set of hooks, reached indirectly via
3681 # lang.${target}.  Only do so for selected languages.
3682
3683 rm -f Make-hooks
3684 touch Make-hooks
3685 target_list="all.cross start.encap rest.encap tags \
3686         install-common install-man install-info install-pdf dvi pdf \
3687         html uninstall info man srcextra srcman srcinfo \
3688         mostlyclean clean distclean maintainer-clean"
3689
3690 for t in $target_list
3691 do
3692         x=
3693         for lang in $all_selected_languages
3694         do
3695                 x="$x $lang.$t"
3696         done
3697         echo "lang.$t: $x" >> Make-hooks
3698 done
3699
3700 # --------
3701 # UNSORTED
3702 # --------
3703
3704 # Create .gdbinit.
3705
3706 echo "dir ." > .gdbinit
3707 echo "dir ${srcdir}" >> .gdbinit
3708 if test x$gdb_needs_out_file_path = xyes
3709 then
3710         echo "dir ${srcdir}/config/"`dirname ${out_file}` >> .gdbinit
3711 fi
3712 if test "x$subdirs" != x; then
3713         for s in $subdirs
3714         do
3715                 echo "dir ${srcdir}/$s" >> .gdbinit
3716         done
3717 fi
3718 echo "source ${srcdir}/gdbinit.in" >> .gdbinit
3719
3720 gcc_tooldir='$(libsubdir)/$(libsubdir_to_prefix)$(target_noncanonical)'
3721 AC_SUBST(gcc_tooldir)
3722 AC_SUBST(dollar)
3723
3724 # Find a directory in which to install a shared libgcc.
3725
3726 AC_ARG_ENABLE(version-specific-runtime-libs,
3727 [  --enable-version-specific-runtime-libs
3728                           specify that runtime libraries should be
3729                           installed in a compiler-specific directory])
3730
3731 AC_ARG_WITH(slibdir,
3732 [  --with-slibdir=DIR      shared libraries in DIR [[LIBDIR]]],
3733 slibdir="$with_slibdir",
3734 if test "${enable_version_specific_runtime_libs+set}" = set; then
3735   slibdir='$(libsubdir)'
3736 elif test "$host" != "$target"; then
3737   slibdir='$(build_tooldir)/lib'
3738 else
3739   slibdir='$(libdir)'
3740 fi)
3741 AC_SUBST(slibdir)
3742
3743 AC_ARG_WITH(datarootdir,
3744 [  --with-datarootdir=DIR  Use DIR as the data root [[PREFIX/share]]],
3745 datarootdir="\${prefix}/$with_datarootdir",
3746 datarootdir='$(prefix)/share')
3747 AC_SUBST(datarootdir)
3748
3749 AC_ARG_WITH(docdir,
3750 [  --with-docdir=DIR       Install documentation in DIR [[DATAROOTDIR]]],
3751 docdir="\${prefix}/$with_docdir",
3752 docdir='$(datarootdir)')
3753 AC_SUBST(docdir)
3754
3755 AC_ARG_WITH(htmldir,
3756 [  --with-htmldir=DIR      html documentation in in DIR [[DOCDIR]]],
3757 htmldir="\${prefix}/$with_htmldir",
3758 htmldir='$(docdir)')
3759 AC_SUBST(htmldir)
3760
3761 # Substitute configuration variables
3762 AC_SUBST(subdirs)
3763 AC_SUBST(srcdir)
3764 AC_SUBST(all_compilers)
3765 AC_SUBST(all_gtfiles)
3766 AC_SUBST(all_lang_makefrags)
3767 AC_SUBST(all_lang_makefiles)
3768 AC_SUBST(all_languages)
3769 AC_SUBST(all_selected_languages)
3770 AC_SUBST(build_exeext)
3771 AC_SUBST(build_install_headers_dir)
3772 AC_SUBST(build_xm_file_list)
3773 AC_SUBST(build_xm_include_list)
3774 AC_SUBST(build_xm_defines)
3775 AC_SUBST(build_file_translate)
3776 AC_SUBST(check_languages)
3777 AC_SUBST(cpp_install_dir)
3778 AC_SUBST(xmake_file)
3779 AC_SUBST(tmake_file)
3780 AC_SUBST(extra_gcc_objs)
3781 AC_SUBST(extra_headers_list)
3782 AC_SUBST(extra_objs)
3783 AC_SUBST(extra_parts)
3784 AC_SUBST(extra_passes)
3785 AC_SUBST(extra_programs)
3786 AC_SUBST(float_h_file)
3787 AC_SUBST(gcc_config_arguments)
3788 AC_SUBST(gcc_gxx_include_dir)
3789 AC_SUBST(host_exeext)
3790 AC_SUBST(host_xm_file_list)
3791 AC_SUBST(host_xm_include_list)
3792 AC_SUBST(host_xm_defines)
3793 AC_SUBST(out_host_hook_obj)
3794 AC_SUBST(install)
3795 AC_SUBST(lang_opt_files)
3796 AC_SUBST(lang_specs_files)
3797 AC_SUBST(lang_tree_files)
3798 AC_SUBST(local_prefix)
3799 AC_SUBST(md_file)
3800 AC_SUBST(objc_boehm_gc)
3801 AC_SUBST(out_file)
3802 AC_SUBST(out_object_file)
3803 AC_SUBST(thread_file)
3804 AC_SUBST(tm_file_list)
3805 AC_SUBST(tm_include_list)
3806 AC_SUBST(tm_defines)
3807 AC_SUBST(tm_p_file_list)
3808 AC_SUBST(tm_p_include_list)
3809 AC_SUBST(xm_file_list)
3810 AC_SUBST(xm_include_list)
3811 AC_SUBST(xm_defines)
3812 AC_SUBST(c_target_objs)
3813 AC_SUBST(cxx_target_objs)
3814 AC_SUBST(fortran_target_objs)
3815 AC_SUBST(target_cpu_default)
3816
3817 AC_SUBST_FILE(language_hooks)
3818
3819 # Echo link setup.
3820 if test x${build} = x${host} ; then
3821   if test x${host} = x${target} ; then
3822     echo "Links are now set up to build a native compiler for ${target}." 1>&2
3823   else
3824     echo "Links are now set up to build a cross-compiler" 1>&2
3825     echo " from ${host} to ${target}." 1>&2
3826   fi
3827 else
3828   if test x${host} = x${target} ; then
3829     echo "Links are now set up to build (on ${build}) a native compiler" 1>&2
3830     echo " for ${target}." 1>&2
3831   else
3832     echo "Links are now set up to build (on ${build}) a cross-compiler" 1>&2
3833     echo " from ${host} to ${target}." 1>&2
3834   fi
3835 fi
3836
3837 AC_ARG_VAR(GMPLIBS,[How to link GMP])
3838 AC_ARG_VAR(GMPINC,[How to find GMP include files])
3839
3840 # Configure the subdirectories
3841 # AC_CONFIG_SUBDIRS($subdirs)
3842
3843 # Create the Makefile
3844 # and configure language subdirectories
3845 AC_CONFIG_FILES($all_outputs)
3846
3847 AC_CONFIG_COMMANDS([default],
3848 [
3849 case ${CONFIG_HEADERS} in
3850   *auto-host.h:config.in*)
3851   echo > cstamp-h ;;
3852 esac
3853 # Make sure all the subdirs exist.
3854 for d in $subdirs doc build
3855 do
3856     test -d $d || mkdir $d
3857 done
3858 ],
3859 [subdirs='$subdirs'])
3860 AC_OUTPUT