gcc/configure.ac

   1 # configure.ac for GCC
   2 # Process this file with autoconf to generate a configuration script.
   3
   4 # Copyright 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2004, 2005, 2006,
   5 # 2007, 2008, 2009 Free Software Foundation, Inc.
   6
   7 #This file is part of GCC.
   8
   9 #GCC is free software; you can redistribute it and/or modify it under
  10 #the terms of the GNU General Public License as published by the Free
  11 #Software Foundation; either version 3, or (at your option) any later
  12 #version.
  13
  14 #GCC is distributed in the hope that it will be useful, but WITHOUT
  15 #ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  16 #FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  17 #for more details.
  18
  19 #You should have received a copy of the GNU General Public License
  20 #along with GCC; see the file COPYING3.  If not see
  21 #<http://www.gnu.org/licenses/>.
  22
  23 # --------------------------------
  24 # Initialization and sanity checks
  25 # --------------------------------
  26
  27 AC_PREREQ(2.64)
  28 AC_INIT
  29 AC_CONFIG_SRCDIR(tree.c)
  30 AC_CONFIG_HEADER(auto-host.h:config.in)
  31
  32 gcc_version=`cat $srcdir/BASE-VER`
  33
  34 # Determine the host, build, and target systems
  35 AC_CANONICAL_BUILD
  36 AC_CANONICAL_HOST
  37 AC_CANONICAL_TARGET
  38
  39 # Determine the noncanonical target name, for directory use.
  40 ACX_NONCANONICAL_TARGET
  41
  42 # Determine the target- and build-specific subdirectories
  43 GCC_TOPLEV_SUBDIRS
  44
  45 # Set program_transform_name
  46 AC_ARG_PROGRAM
  47
  48 # Check for bogus environment variables.
  49 # Test if LIBRARY_PATH contains the notation for the current directory
  50 # since this would lead to problems installing/building glibc.
  51 # LIBRARY_PATH contains the current directory if one of the following
  52 # is true:
  53 # - one of the terminals (":" and ";") is the first or last sign
  54 # - two terminals occur directly after each other
  55 # - the path contains an element with a dot in it
  56 AC_MSG_CHECKING(LIBRARY_PATH variable)
  57 changequote(,)dnl
  58 case ${LIBRARY_PATH} in
  59   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
  60     library_path_setting="contains current directory"
  61     ;;
  62   *)
  63     library_path_setting="ok"
  64     ;;
  65 esac
  66 changequote([,])dnl
  67 AC_MSG_RESULT($library_path_setting)
  68 if test "$library_path_setting" != "ok"; then
  69 AC_MSG_ERROR([
  70 *** LIBRARY_PATH shouldn't contain the current directory when
  71 *** building gcc. Please change the environment variable
  72 *** and run configure again.])
  73 fi
  74
  75 # Test if GCC_EXEC_PREFIX contains the notation for the current directory
  76 # since this would lead to problems installing/building glibc.
  77 # GCC_EXEC_PREFIX contains the current directory if one of the following
  78 # is true:
  79 # - one of the terminals (":" and ";") is the first or last sign
  80 # - two terminals occur directly after each other
  81 # - the path contains an element with a dot in it
  82 AC_MSG_CHECKING(GCC_EXEC_PREFIX variable)
  83 changequote(,)dnl
  84 case ${GCC_EXEC_PREFIX} in
  85   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
  86     gcc_exec_prefix_setting="contains current directory"
  87     ;;
  88   *)
  89     gcc_exec_prefix_setting="ok"
  90     ;;
  91 esac
  92 changequote([,])dnl
  93 AC_MSG_RESULT($gcc_exec_prefix_setting)
  94 if test "$gcc_exec_prefix_setting" != "ok"; then
  95 AC_MSG_ERROR([
  96 *** GCC_EXEC_PREFIX shouldn't contain the current directory when
  97 *** building gcc. Please change the environment variable
  98 *** and run configure again.])
  99 fi
 100
 101 # -----------
 102 # Directories
 103 # -----------
 104
 105 # Specify the local prefix
 106 local_prefix=
 107 AC_ARG_WITH(local-prefix,
 108 [  --with-local-prefix=DIR specifies directory to put local include],
 109 [case "${withval}" in
 110 yes)    AC_MSG_ERROR(bad value ${withval} given for local include directory prefix) ;;
 111 no)     ;;
 112 *)      local_prefix=$with_local_prefix ;;
 113 esac])
 114
 115 # Default local prefix if it is empty
 116 if test x$local_prefix = x; then
 117         local_prefix=/usr/local
 118 fi
 119
 120 # Don't set gcc_gxx_include_dir to gxx_include_dir since that's only
 121 # passed in by the toplevel make and thus we'd get different behavior
 122 # depending on where we built the sources.
 123 gcc_gxx_include_dir=
 124 # Specify the g++ header file directory
 125 AC_ARG_WITH(gxx-include-dir,
 126 [  --with-gxx-include-dir=DIR
 127                           specifies directory to put g++ header files],
 128 [case "${withval}" in
 129 yes)    AC_MSG_ERROR(bad value ${withval} given for g++ include directory) ;;
 130 no)     ;;
 131 *)      gcc_gxx_include_dir=$with_gxx_include_dir ;;
 132 esac])
 133
 134 # This logic must match libstdc++-v3/acinclude.m4:GLIBCXX_EXPORT_INSTALL_INFO.
 135 if test x${gcc_gxx_include_dir} = x; then
 136   if test x${enable_version_specific_runtime_libs} = xyes; then
 137     gcc_gxx_include_dir='${libsubdir}/include/c++'
 138   else
 139     libstdcxx_incdir='include/c++/$(version)'
 140     if test x$host != x$target; then
 141        libstdcxx_incdir="$target_alias/$libstdcxx_incdir"
 142     fi
 143     gcc_gxx_include_dir="\$(libsubdir)/\$(libsubdir_to_prefix)$libstdcxx_incdir"
 144   fi
 145 fi
 146
 147 AC_ARG_WITH(cpp_install_dir,
 148 [  --with-cpp-install-dir=DIR
 149                           install the user visible C preprocessor in DIR
 150                           (relative to PREFIX) as well as PREFIX/bin],
 151 [if test x$withval = xyes; then
 152   AC_MSG_ERROR([option --with-cpp-install-dir requires an argument])
 153 elif test x$withval != xno; then
 154   cpp_install_dir=$withval
 155 fi])
 156
 157 # We would like to our source tree to be readonly.  However when releases or
 158 # pre-releases are generated, the flex/bison generated files as well as the
 159 # various formats of manuals need to be included along with the rest of the
 160 # sources.  Therefore we have --enable-generated-files-in-srcdir to do
 161 # just that.
 162
 163 AC_MSG_CHECKING([whether to place generated files in the source directory])
 164   dnl generated-files-in-srcdir is disabled by default
 165   AC_ARG_ENABLE(generated-files-in-srcdir,
 166 [  --enable-generated-files-in-srcdir
 167                           put copies of generated files in source dir
 168                           intended for creating source tarballs for users
 169                           without texinfo bison or flex.],
 170       generated_files_in_srcdir=$enableval,
 171       generated_files_in_srcdir=no)
 172
 173 AC_MSG_RESULT($generated_files_in_srcdir)
 174
 175 if test "$generated_files_in_srcdir" = "yes"; then
 176   GENINSRC=''
 177 else
 178   GENINSRC='#'
 179 fi
 180 AC_SUBST(GENINSRC)
 181
 182 # -------------------
 183 # Find default linker
 184 # -------------------
 185
 186 # With GNU ld
 187 AC_ARG_WITH(gnu-ld,
 188 [  --with-gnu-ld           arrange to work with GNU ld.],
 189 gnu_ld_flag="$with_gnu_ld",
 190 gnu_ld_flag=no)
 191
 192 # With pre-defined ld
 193 AC_ARG_WITH(ld,
 194 [  --with-ld               arrange to use the specified ld (full pathname)],
 195 DEFAULT_LINKER="$with_ld")
 196 if test x"${DEFAULT_LINKER+set}" = x"set"; then
 197   if test ! -x "$DEFAULT_LINKER"; then
 198     AC_MSG_ERROR([cannot execute: $DEFAULT_LINKER: check --with-ld or env. var. DEFAULT_LINKER])
 199   elif $DEFAULT_LINKER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
 200     gnu_ld_flag=yes
 201   fi
 202   AC_DEFINE_UNQUOTED(DEFAULT_LINKER,"$DEFAULT_LINKER",
 203         [Define to enable the use of a default linker.])
 204 fi
 205
 206 gnu_ld=`if test x"$gnu_ld_flag" = x"yes"; then echo 1; else echo 0; fi`
 207 AC_DEFINE_UNQUOTED(HAVE_GNU_LD, $gnu_ld, [Define if using GNU ld.])
 208
 209 AC_MSG_CHECKING([whether a default linker was specified])
 210 if test x"${DEFAULT_LINKER+set}" = x"set"; then
 211   if test x"$gnu_ld_flag" = x"no"; then
 212     AC_MSG_RESULT([yes ($DEFAULT_LINKER)])
 213   else
 214     AC_MSG_RESULT([yes ($DEFAULT_LINKER - GNU ld)])
 215   fi
 216 else
 217   AC_MSG_RESULT(no)
 218 fi
 219
 220 # With demangler in GNU ld
 221 AC_ARG_WITH(demangler-in-ld,
 222 [  --with-demangler-in-ld  try to use demangler in GNU ld.],
 223 demangler_in_ld="$with_demangler_in_ld",
 224 demangler_in_ld=no)
 225
 226 # ----------------------
 227 # Find default assembler
 228 # ----------------------
 229
 230 # With GNU as
 231 AC_ARG_WITH(gnu-as,
 232 [  --with-gnu-as           arrange to work with GNU as],
 233 gas_flag="$with_gnu_as",
 234 gas_flag=no)
 235
 236 AC_ARG_WITH(as,
 237 [  --with-as               arrange to use the specified as (full pathname)],
 238 DEFAULT_ASSEMBLER="$with_as")
 239 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
 240   if test ! -x "$DEFAULT_ASSEMBLER"; then
 241     AC_MSG_ERROR([cannot execute: $DEFAULT_ASSEMBLER: check --with-as or env. var. DEFAULT_ASSEMBLER])
 242   elif $DEFAULT_ASSEMBLER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
 243     gas_flag=yes
 244   fi
 245   AC_DEFINE_UNQUOTED(DEFAULT_ASSEMBLER,"$DEFAULT_ASSEMBLER",
 246         [Define to enable the use of a default assembler.])
 247 fi
 248
 249 gnu_as=`if test x"$gas_flag" = x"yes"; then echo 1; else echo 0; fi`
 250 AC_DEFINE_UNQUOTED(HAVE_GNU_AS, $gnu_as, [Define if using GNU as.])
 251
 252 AC_MSG_CHECKING([whether a default assembler was specified])
 253 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
 254   if test x"$gas_flag" = x"no"; then
 255     AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER)])
 256   else
 257     AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER - GNU as)])
 258   fi
 259 else
 260   AC_MSG_RESULT(no)
 261 fi
 262
 263 # ---------------
 264 # Find C compiler
 265 # ---------------
 266
 267 # If a non-executable a.out is present (e.g. created by GNU as above even if
 268 # invoked with -v only), the IRIX 6 native ld just overwrites the existing
 269 # file, even when creating an executable, so an execution test fails.
 270 # Remove possible default executable files to avoid this.
 271 #
 272 # FIXME: This really belongs into AC_PROG_CC and can be removed once
 273 # Autoconf includes it.
 274 rm -f a.out a.exe b.out
 275
 276 # Find the native compiler
 277 AC_PROG_CC
 278 AM_PROG_CC_C_O
 279 AC_PROG_CXX
 280 ACX_PROG_GNAT([-I"$srcdir"/ada])
 281
 282 # autoconf is lame and doesn't give us any substitution variable for this.
 283 if eval "test \"`echo '$ac_cv_prog_cc_'${ac_cc}_c_o`\" = no"; then
 284   NO_MINUS_C_MINUS_O=yes
 285 else
 286   OUTPUT_OPTION='-o $@'
 287 fi
 288 AC_SUBST(NO_MINUS_C_MINUS_O)
 289 AC_SUBST(OUTPUT_OPTION)
 290
 291 # Remove the -O2: for historical reasons, unless bootstrapping we prefer
 292 # optimizations to be activated explicitly by the toplevel.
 293 case "$CC" in
 294   */prev-gcc/xgcc*) ;;
 295   *) CFLAGS=`echo $CFLAGS | sed "s/-O[[s0-9]]* *//" ` ;;
 296 esac
 297 AC_SUBST(CFLAGS)
 298
 299 # -------------------------
 300 # Check C compiler features
 301 # -------------------------
 302
 303 AC_USE_SYSTEM_EXTENSIONS
 304 AC_PROG_CPP
 305 AC_C_INLINE
 306
 307 # sizeof(char) is 1 by definition.
 308 AC_CHECK_SIZEOF(void *)
 309 AC_CHECK_SIZEOF(short)
 310 AC_CHECK_SIZEOF(int)
 311 AC_CHECK_SIZEOF(long)
 312 AC_CHECK_TYPES([long long], [AC_CHECK_SIZEOF(long long)])
 313 AC_CHECK_TYPES([__int64], [AC_CHECK_SIZEOF(__int64)])
 314 GCC_STDINT_TYPES
 315
 316 # ---------------------
 317 # Warnings and checking
 318 # ---------------------
 319
 320 # Check $CC warning features (if it's GCC).
 321 # We want to use -pedantic, but we don't want warnings about
 322 # * 'long long'
 323 # * variadic macros
 324 # * overlong strings
 325 # So, we only use -pedantic if we can disable those warnings.
 326
 327 ACX_PROG_CC_WARNING_OPTS(
 328         m4_quote(m4_do([-W -Wall -Wwrite-strings -Wcast-qual])), [loose_warn])
 329 ACX_PROG_CC_WARNING_OPTS(
 330         m4_quote(m4_do([-Wstrict-prototypes -Wmissing-prototypes])),
 331         [c_loose_warn])
 332 ACX_PROG_CC_WARNING_OPTS(
 333         m4_quote(m4_do([-Wmissing-format-attribute])), [strict_warn])
 334 ACX_PROG_CC_WARNING_OPTS(
 335         m4_quote(m4_do([-Wold-style-definition -Wc++-compat])), [c_strict_warn])
 336 ACX_PROG_CC_WARNING_ALMOST_PEDANTIC(
 337         m4_quote(m4_do([-Wno-long-long -Wno-variadic-macros ],
 338                        [-Wno-overlength-strings])), [strict_warn])
 339 ACX_PROG_CC_WARNINGS_ARE_ERRORS([manual], [strict_warn])
 340
 341 # The above macros do nothing if the compiler is not GCC.  However, the
 342 # Makefile has more goo to add other flags, so these variables are used
 343 # to enable warnings only for GCC.
 344 warn_cflags=
 345 warn_cxxflags=
 346 if test "x$GCC" = "xyes"; then
 347   warn_cflags='$(GCC_WARN_CFLAGS)'
 348   warn_cxxflags='$(GCC_WARN_CXXFLAGS)'
 349 fi
 350 AC_SUBST(warn_cflags)
 351 AC_SUBST(warn_cxxflags)
 352
 353 # Enable expensive internal checks
 354 is_release=
 355 if test x"`cat $srcdir/DEV-PHASE`" != xexperimental; then
 356   is_release=yes
 357 fi
 358
 359 AC_ARG_ENABLE(checking,
 360 [  --enable-checking[=LIST]
 361                           enable expensive run-time checks.  With LIST,
 362                           enable only specific categories of checks.
 363                           Categories are: yes,no,all,none,release.
 364                           Flags are: assert,df,fold,gc,gcac,gimple,misc,
 365                           rtlflag,rtl,runtime,tree,valgrind,types.],
 366 [ac_checking_flags="${enableval}"],[
 367 # Determine the default checks.
 368 if test x$is_release = x ; then
 369   ac_checking_flags=yes
 370 else
 371   ac_checking_flags=release
 372 fi])
 373 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 374 for check in release $ac_checking_flags
 375 do
 376         case $check in
 377         # these set all the flags to specific states
 378         yes)            ac_assert_checking=1 ; ac_checking=1 ; ac_df_checking= ;
 379                         ac_fold_checking= ; ac_gc_checking=1 ;
 380                         ac_gc_always_collect= ; ac_gimple_checking=1 ; ac_rtl_checking= ;
 381                         ac_rtlflag_checking=1 ; ac_runtime_checking=1 ;
 382                         ac_tree_checking=1 ; ac_valgrind_checking= ;
 383                         ac_types_checking=1 ;;
 384         no|none)        ac_assert_checking= ; ac_checking= ; ac_df_checking= ;
 385                         ac_fold_checking= ; ac_gc_checking= ;
 386                         ac_gc_always_collect= ; ac_gimple_checking= ; ac_rtl_checking= ;
 387                         ac_rtlflag_checking= ; ac_runtime_checking= ;
 388                         ac_tree_checking= ; ac_valgrind_checking= ;
 389                         ac_types_checking= ;;
 390         all)            ac_assert_checking=1 ; ac_checking=1 ; ac_df_checking=1 ;
 391                         ac_fold_checking=1 ; ac_gc_checking=1 ;
 392                         ac_gc_always_collect=1 ; ac_gimple_checking=1 ; ac_rtl_checking=1 ;
 393                         ac_rtlflag_checking=1 ; ac_runtime_checking=1 ;
 394                         ac_tree_checking=1 ; ac_valgrind_checking= ;
 395                         ac_types_checking=1 ;;
 396         release)        ac_assert_checking=1 ; ac_checking= ; ac_df_checking= ;
 397                         ac_fold_checking= ; ac_gc_checking= ;
 398                         ac_gc_always_collect= ; ac_gimple_checking= ; ac_rtl_checking= ;
 399                         ac_rtlflag_checking= ; ac_runtime_checking=1 ;
 400                         ac_tree_checking= ; ac_valgrind_checking= ;
 401                         ac_types_checking= ;;
 402         # these enable particular checks
 403         assert)         ac_assert_checking=1 ;;
 404         df)             ac_df_checking=1 ;;
 405         fold)           ac_fold_checking=1 ;;
 406         gc)             ac_gc_checking=1 ;;
 407         gcac)           ac_gc_always_collect=1 ;;
 408         gimple)         ac_gimple_checking=1 ;;
 409         misc)           ac_checking=1 ;;
 410         rtl)            ac_rtl_checking=1 ;;
 411         rtlflag)        ac_rtlflag_checking=1 ;;
 412         runtime)        ac_runtime_checking=1 ;;
 413         tree)           ac_tree_checking=1 ;;
 414         types)          ac_types_checking=1 ;;
 415         valgrind)       ac_valgrind_checking=1 ;;
 416         *)      AC_MSG_ERROR(unknown check category $check) ;;
 417         esac
 418 done
 419 IFS="$ac_save_IFS"
 420
 421 nocommon_flag=""
 422 if test x$ac_checking != x ; then
 423   AC_DEFINE(ENABLE_CHECKING, 1,
 424 [Define if you want more run-time sanity checks.  This one gets a grab
 425    bag of miscellaneous but relatively cheap checks.])
 426   nocommon_flag=-fno-common
 427 fi
 428 AC_SUBST(nocommon_flag)
 429 if test x$ac_df_checking != x ; then
 430   AC_DEFINE(ENABLE_DF_CHECKING, 1,
 431 [Define if you want more run-time sanity checks for dataflow.])
 432 fi
 433 if test x$ac_assert_checking != x ; then
 434   AC_DEFINE(ENABLE_ASSERT_CHECKING, 1,
 435 [Define if you want assertions enabled.  This is a cheap check.])
 436 fi
 437 if test x$ac_gimple_checking != x ; then
 438   AC_DEFINE(ENABLE_GIMPLE_CHECKING, 1,
 439 [Define if you want operations on GIMPLE (the basic data structure of
 440 the high-level optimizers) to be checked for dynamic type safety at
 441 runtime.  This is moderately expensive.])
 442 fi
 443 GCC_TARGET_TEMPLATE(ENABLE_RUNTIME_CHECKING)
 444 if test x$ac_runtime_checking != x ; then
 445   AC_DEFINE(ENABLE_RUNTIME_CHECKING, 1,
 446 [Define if you want runtime assertions enabled.  This is a cheap check.])
 447 fi
 448 if test x$ac_tree_checking != x ; then
 449   AC_DEFINE(ENABLE_TREE_CHECKING, 1,
 450 [Define if you want all operations on trees (the basic data
 451    structure of the front ends) to be checked for dynamic type safety
 452    at runtime.  This is moderately expensive.  The tree browser debugging
 453    routines will also be enabled by this option.
 454    ])
 455   TREEBROWSER=tree-browser.o
 456 fi
 457 if test x$ac_types_checking != x ; then
 458   AC_DEFINE(ENABLE_TYPES_CHECKING, 1,
 459 [Define if you want all gimple types to be verified after gimplifiation.
 460    This is cheap.
 461    ])
 462 fi
 463 AC_SUBST(TREEBROWSER)
 464 if test x$ac_rtl_checking != x ; then
 465   AC_DEFINE(ENABLE_RTL_CHECKING, 1,
 466 [Define if you want all operations on RTL (the basic data structure
 467    of the optimizer and back end) to be checked for dynamic type safety
 468    at runtime.  This is quite expensive.])
 469 fi
 470 if test x$ac_rtlflag_checking != x ; then
 471   AC_DEFINE(ENABLE_RTL_FLAG_CHECKING, 1,
 472 [Define if you want RTL flag accesses to be checked against the RTL
 473    codes that are supported for each access macro.  This is relatively
 474    cheap.])
 475 fi
 476 if test x$ac_gc_checking != x ; then
 477   AC_DEFINE(ENABLE_GC_CHECKING, 1,
 478 [Define if you want the garbage collector to do object poisoning and
 479    other memory allocation checks.  This is quite expensive.])
 480 fi
 481 if test x$ac_gc_always_collect != x ; then
 482   AC_DEFINE(ENABLE_GC_ALWAYS_COLLECT, 1,
 483 [Define if you want the garbage collector to operate in maximally
 484    paranoid mode, validating the entire heap and collecting garbage at
 485    every opportunity.  This is extremely expensive.])
 486 fi
 487 if test x$ac_fold_checking != x ; then
 488   AC_DEFINE(ENABLE_FOLD_CHECKING, 1,
 489 [Define if you want fold checked that it never destructs its argument.
 490    This is quite expensive.])
 491 fi
 492 valgrind_path_defines=
 493 valgrind_command=
 494
 495 dnl # This check AC_REQUIREs various stuff, so it *must not* be inside
 496 dnl # an if statement.  This was the source of very frustrating bugs
 497 dnl # in converting to autoconf 2.5x!
 498 AC_CHECK_HEADER(valgrind.h, have_valgrind_h=yes, have_valgrind_h=no)
 499
 500 if test x$ac_valgrind_checking != x ; then
 501   # It is certainly possible that there's valgrind but no valgrind.h.
 502   # GCC relies on making annotations so we must have both.
 503   AC_MSG_CHECKING(for VALGRIND_DISCARD in <valgrind/memcheck.h>)
 504   AC_PREPROC_IFELSE([AC_LANG_SOURCE(
 505     [[#include <valgrind/memcheck.h>
 506 #ifndef VALGRIND_DISCARD
 507 #error VALGRIND_DISCARD not defined
 508 #endif]])],
 509   [gcc_cv_header_valgrind_memcheck_h=yes],
 510   [gcc_cv_header_valgrind_memcheck_h=no])
 511   AC_MSG_RESULT($gcc_cv_header_valgrind_memcheck_h)
 512   AC_MSG_CHECKING(for VALGRIND_DISCARD in <memcheck.h>)
 513   AC_PREPROC_IFELSE([AC_LANG_SOURCE(
 514     [[#include <memcheck.h>
 515 #ifndef VALGRIND_DISCARD
 516 #error VALGRIND_DISCARD not defined
 517 #endif]])],
 518   [gcc_cv_header_memcheck_h=yes],
 519   [gcc_cv_header_memcheck_h=no])
 520   AC_MSG_RESULT($gcc_cv_header_memcheck_h)
 521   AM_PATH_PROG_WITH_TEST(valgrind_path, valgrind,
 522         [$ac_dir/$ac_word --version | grep valgrind- >/dev/null 2>&1])
 523   if test "x$valgrind_path" = "x" \
 524     || (test $have_valgrind_h = no \
 525         && test $gcc_cv_header_memcheck_h = no \
 526         && test $gcc_cv_header_valgrind_memcheck_h = no); then
 527         AC_MSG_ERROR([*** Can't find both valgrind and valgrind/memcheck.h, memcheck.h or valgrind.h])
 528   fi
 529   valgrind_path_defines=-DVALGRIND_PATH='\"'$valgrind_path'\"'
 530   valgrind_command="$valgrind_path -q"
 531   AC_DEFINE(ENABLE_VALGRIND_CHECKING, 1,
 532 [Define if you want to run subprograms and generated programs
 533    through valgrind (a memory checker).  This is extremely expensive.])
 534   if test $gcc_cv_header_valgrind_memcheck_h = yes; then
 535     AC_DEFINE(HAVE_VALGRIND_MEMCHECK_H, 1,
 536         [Define if valgrind's valgrind/memcheck.h header is installed.])
 537   fi
 538   if test $gcc_cv_header_memcheck_h = yes; then
 539     AC_DEFINE(HAVE_MEMCHECK_H, 1,
 540         [Define if valgrind's memcheck.h header is installed.])
 541   fi
 542 fi
 543 AC_SUBST(valgrind_path_defines)
 544 AC_SUBST(valgrind_command)
 545
 546 # Enable code coverage collection
 547 AC_ARG_ENABLE(coverage,
 548 [  --enable-coverage[=LEVEL]
 549                           enable compiler's code coverage collection.
 550                           Use to measure compiler performance and locate
 551                           unused parts of the compiler. With LEVEL, specify
 552                           optimization. Values are opt, noopt,
 553                           default is noopt],
 554 [case "${enableval}" in
 555   yes|noopt)
 556     coverage_flags="-fprofile-arcs -ftest-coverage -frandom-seed=\$@ -O0"
 557     ;;
 558   opt)
 559     coverage_flags="-fprofile-arcs -ftest-coverage -frandom-seed=\$@ -O2"
 560     ;;
 561   no)
 562     # a.k.a. --disable-coverage
 563     coverage_flags=""
 564     ;;
 565   *)
 566     AC_MSG_ERROR(unknown coverage setting $enableval)
 567     ;;
 568 esac],
 569 [coverage_flags=""])
 570 AC_SUBST(coverage_flags)
 571
 572 AC_ARG_ENABLE(gather-detailed-mem-stats,
 573 [  --enable-gather-detailed-mem-stats         enable detailed memory allocation stats gathering], [],
 574 [enable_gather_detailed_mem_stats=no])
 575 if test x$enable_gather_detailed_mem_stats = xyes ; then
 576   AC_DEFINE(GATHER_STATISTICS, 1,
 577         [Define to enable detailed memory allocation stats gathering.])
 578 fi
 579
 580 # -------------------------------
 581 # Miscenalleous configure options
 582 # -------------------------------
 583
 584 # See if we are building gcc with C++.
 585 AC_ARG_ENABLE(build-with-cxx,
 586 [  --enable-build-with-cxx build with C++ compiler instead of C compiler],
 587 ENABLE_BUILD_WITH_CXX=$enableval,
 588 ENABLE_BUILD_WITH_CXX=no)
 589 AC_SUBST(ENABLE_BUILD_WITH_CXX)
 590
 591 # With stabs
 592 AC_ARG_WITH(stabs,
 593 [  --with-stabs            arrange to use stabs instead of host debug format],
 594 stabs="$with_stabs",
 595 stabs=no)
 596
 597 # Determine whether or not multilibs are enabled.
 598 AC_ARG_ENABLE(multilib,
 599 [  --enable-multilib       enable library support for multiple ABIs],
 600 [], [enable_multilib=yes])
 601 AC_SUBST(enable_multilib)
 602
 603 # Enable __cxa_atexit for C++.
 604 AC_ARG_ENABLE(__cxa_atexit,
 605 [  --enable-__cxa_atexit   enable __cxa_atexit for C++],
 606 [], [])
 607
 608 # Enable C extension for decimal float if target supports it.
 609 AC_ARG_ENABLE(decimal-float,
 610 [  --enable-decimal-float={no,yes,bid,dpd}
 611                         enable decimal float extension to C.  Selecting 'bid'
 612                         or 'dpd' choses which decimal floating point format
 613                         to use],
 614 [
 615   case $enable_decimal_float in
 616     yes | no | bid | dpd) ;;
 617     *) AC_MSG_ERROR(['$enable_decimal_float' is an invalid value for --enable-decimal-float.
 618 Valid choices are 'yes', 'bid', 'dpd', and 'no'.]) ;;
 619   esac
 620 ],
 621 [
 622   case $target in
 623     powerpc*-*-linux* | i?86*-*-linux* | x86_64*-*-linux*)
 624       enable_decimal_float=yes
 625       ;;
 626     *)
 627       AC_MSG_WARN(decimal float is not supported for this target, ignored)
 628       enable_decimal_float=no
 629       ;;
 630   esac
 631 ])
 632
 633 dfp=`if test $enable_decimal_float != no; then echo 1; else echo 0; fi`
 634 AC_DEFINE_UNQUOTED(ENABLE_DECIMAL_FLOAT, $dfp,
 635 [Define to 1 to enable decimal float extension to C.])
 636
 637 # x86's use BID format instead of DPD
 638 case x$enable_decimal_float in
 639   xyes)
 640     case $target in
 641       i?86*-*-linux* | x86_64*-*-linux*)
 642         enable_decimal_float=bid
 643         ;;
 644       *)
 645         enable_decimal_float=dpd
 646         ;;
 647     esac
 648     ;;
 649   xno)
 650     # ENABLE_DECIMAL_FLOAT is set to 0. But we have to have proper
 651     # dependency on libdecnumber.
 652     enable_decimal_float=dpd
 653     ;;
 654 esac
 655 AC_SUBST(enable_decimal_float)
 656
 657 bid=`if test $enable_decimal_float = bid; then echo 1; else echo 0; fi`
 658 AC_DEFINE_UNQUOTED(ENABLE_DECIMAL_BID_FORMAT, $bid,
 659 [Define to 1 to specify that we are using the BID decimal floating
 660 point format instead of DPD])
 661
 662 # Enable C extension for fixed-point arithmetic.
 663 AC_ARG_ENABLE(fixed-point,
 664 [  --enable-fixed-point    enable fixed-point arithmetic extension to C],
 665 [
 666 ],
 667 [
 668   case $target in
 669     mips*-*-*)
 670       case $host in
 671         mips*-sgi-irix*)
 672           AC_MSG_WARN(fixed-point is not supported on IRIX, ignored)
 673           enable_fixed_point=no
 674           ;;
 675         *)
 676           enable_fixed_point=yes
 677           ;;
 678       esac
 679       ;;
 680     *)
 681       AC_MSG_WARN(fixed-point is not supported for this target, ignored)
 682       enable_fixed_point=no
 683       ;;
 684   esac
 685 ])
 686 AC_SUBST(enable_fixed_point)
 687
 688 fixedpoint=`if test $enable_fixed_point = yes; then echo 1; else echo 0; fi`
 689 AC_DEFINE_UNQUOTED(ENABLE_FIXED_POINT, $fixedpoint,
 690 [Define to 1 to enable fixed-point arithmetic extension to C.])
 691
 692 # Enable threads
 693 # Pass with no value to take the default
 694 # Pass with a value to specify a thread package
 695 AC_ARG_ENABLE(threads,
 696 [  --enable-threads        enable thread usage for target GCC
 697   --enable-threads=LIB    use LIB thread package for target GCC],,
 698 [enable_threads=''])
 699
 700 AC_ARG_ENABLE(tls,
 701 [  --enable-tls            enable or disable generation of tls code
 702                           overriding the assembler check for tls support],
 703 [
 704   case $enable_tls in
 705     yes | no) ;;
 706     *) AC_MSG_ERROR(['$enable_tls' is an invalid value for --enable-tls.
 707 Valid choices are 'yes' and 'no'.]) ;;
 708   esac
 709 ], [enable_tls=''])
 710
 711 AC_ARG_ENABLE(objc-gc,
 712 [  --enable-objc-gc       enable the use of Boehm's garbage collector with
 713                           the GNU Objective-C runtime],
 714 if test x$enable_objc_gc = xno; then
 715         objc_boehm_gc=''
 716 else
 717         objc_boehm_gc=1
 718 fi,
 719 objc_boehm_gc='')
 720
 721 AC_ARG_WITH(dwarf2,
 722 [  --with-dwarf2           force the default debug format to be DWARF 2],
 723 dwarf2="$with_dwarf2",
 724 dwarf2=no)
 725
 726 AC_ARG_ENABLE(shared,
 727 [  --disable-shared        don't provide a shared libgcc],
 728 [
 729   case $enable_shared in
 730   yes | no) ;;
 731   *)
 732     enable_shared=no
 733     IFS="${IFS=         }"; ac_save_ifs="$IFS"; IFS="${IFS}:,"
 734     for pkg in $enableval; do
 735       if test "X$pkg" = "Xgcc" || test "X$pkg" = "Xlibgcc"; then
 736         enable_shared=yes
 737       fi
 738     done
 739     IFS="$ac_save_ifs"
 740     ;;
 741   esac
 742 ], [enable_shared=yes])
 743 AC_SUBST(enable_shared)
 744
 745 AC_ARG_WITH(build-sysroot,
 746   [  --with-build-sysroot=sysroot
 747                           use sysroot as the system root during the build])
 748
 749 AC_ARG_WITH(sysroot,
 750 [  --with-sysroot[=DIR] Search for usr/lib, usr/include, et al, within DIR.],
 751 [
 752  case ${with_sysroot} in
 753  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_noncanonical}/sys-root' ;;
 754  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
 755  esac
 756
 757  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
 758  CROSS_SYSTEM_HEADER_DIR='$(TARGET_SYSTEM_ROOT)$${sysroot_headers_suffix}$(NATIVE_SYSTEM_HEADER_DIR)'
 759
 760  if test "x$prefix" = xNONE; then
 761   test_prefix=/usr/local
 762  else
 763   test_prefix=$prefix
 764  fi
 765  if test "x$exec_prefix" = xNONE; then
 766   test_exec_prefix=$test_prefix
 767  else
 768   test_exec_prefix=$exec_prefix
 769  fi
 770  case ${TARGET_SYSTEM_ROOT} in
 771  "${test_prefix}"|"${test_prefix}/"*|\
 772  "${test_exec_prefix}"|"${test_exec_prefix}/"*|\
 773  '${prefix}'|'${prefix}/'*|\
 774  '${exec_prefix}'|'${exec_prefix}/'*)
 775    t="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE"
 776    TARGET_SYSTEM_ROOT_DEFINE="$t"
 777    ;;
 778  esac
 779 ], [
 780  TARGET_SYSTEM_ROOT=
 781  TARGET_SYSTEM_ROOT_DEFINE=
 782  CROSS_SYSTEM_HEADER_DIR='$(gcc_tooldir)/sys-include'
 783 ])
 784 AC_SUBST(TARGET_SYSTEM_ROOT)
 785 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
 786 AC_SUBST(CROSS_SYSTEM_HEADER_DIR)
 787
 788 # Build with intermodule optimisations
 789 AC_ARG_ENABLE(intermodule,
 790 [  --enable-intermodule    build the compiler in one step],
 791 [case ${enable_intermodule} in
 792   yes) onestep="-onestep";;
 793   *) onestep="";;
 794 esac],
 795 [onestep=""])
 796 AC_SUBST(onestep)
 797
 798 ACX_PKGVERSION([GCC])
 799 ACX_BUGURL([http://gcc.gnu.org/bugs.html])
 800
 801 # Sanity check enable_languages in case someone does not run the toplevel
 802 # configure # script.
 803 AC_ARG_ENABLE(languages,
 804 [  --enable-languages=LIST specify which front-ends to build],
 805 [case ,${enable_languages}, in
 806        ,,|,yes,)
 807                 # go safe -- we cannot be much sure without the toplevel
 808                 # configure's
 809                 # analysis of which target libs are present and usable
 810                 enable_languages=c
 811                 ;;
 812          *,all,*)
 813                 AC_MSG_ERROR([only the toplevel supports --enable-languages=all])
 814                 ;;
 815         *,c,*)
 816                 ;;
 817         *)
 818                 enable_languages=c,${enable_languages}
 819                 ;;
 820 esac],
 821 [enable_languages=c])
 822
 823 AC_ARG_WITH(multilib-list,
 824 [  --with-multilib-list    Select multilibs (SH only)],
 825 :,
 826 with_multilib_list=default)
 827
 828 # -------------------------
 829 # Checks for other programs
 830 # -------------------------
 831
 832 AC_PROG_MAKE_SET
 833
 834 # Find some useful tools
 835 AC_PROG_AWK
 836 # We need awk to create options.c and options.h.
 837 # Bail out if it's missing.
 838 case ${AWK} in
 839   "") AC_MSG_ERROR([can't build without awk, bailing out]) ;;
 840 esac
 841
 842 gcc_AC_PROG_LN_S
 843 ACX_PROG_LN($LN_S)
 844 AC_PROG_RANLIB
 845 case "${host}" in
 846 *-*-darwin*)
 847   # By default, the Darwin ranlib will not treat common symbols as
 848   # definitions when  building the archive table of contents.  Other
 849   # ranlibs do that; pass an option to the Darwin ranlib that makes
 850   # it behave similarly.
 851   ranlib_flags="-c"
 852   ;;
 853 *)
 854   ranlib_flags=""
 855 esac
 856 AC_SUBST(ranlib_flags)
 857
 858 gcc_AC_PROG_INSTALL
 859
 860 # See if cmp has --ignore-initial.
 861 gcc_AC_PROG_CMP_IGNORE_INITIAL
 862
 863 # See if we have the mktemp command.
 864 AC_CHECK_PROG(have_mktemp_command, mktemp, yes, no)
 865
 866 # See if makeinfo has been installed and is modern enough
 867 # that we can use it.
 868 ACX_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
 869   [GNU texinfo.* \([0-9][0-9.]*\)],
 870   [4.[7-9]*|4.[1-9][0-9]*|[5-9]*|[1-9][0-9]*])
 871 if test $gcc_cv_prog_makeinfo_modern = no; then
 872   AC_MSG_WARN([
 873 *** Makeinfo is missing or too old.
 874 *** Info documentation will not be built.])
 875   BUILD_INFO=
 876 else
 877   BUILD_INFO=info
 878 fi
 879 AC_SUBST(BUILD_INFO)
 880
 881 # Is pod2man recent enough to regenerate manpages?
 882 AC_MSG_CHECKING([for recent Pod::Man])
 883 if (perl -e 'use 1.10 Pod::Man') >/dev/null 2>&1; then
 884   AC_MSG_RESULT(yes)
 885   GENERATED_MANPAGES=generated-manpages
 886 else
 887   AC_MSG_RESULT(no)
 888   GENERATED_MANPAGES=
 889 fi
 890 AC_SUBST(GENERATED_MANPAGES)
 891
 892 MISSING="${CONFIG_SHELL-/bin/sh} $ac_aux_dir/missing"
 893
 894 # How about lex?
 895 dnl Don't use AC_PROG_LEX; we insist on flex.
 896 dnl LEXLIB is not useful in gcc.
 897 AC_CHECK_PROGS([FLEX], flex, [$MISSING flex])
 898
 899 # Bison?
 900 AC_CHECK_PROGS([BISON], bison, [$MISSING bison])
 901
 902 # Binutils are not build modules, unlike bison/flex/makeinfo.  So we
 903 # check for build == host before using them.
 904
 905 # NM
 906 if test x${build} = x${host} && test -f $srcdir/../binutils/nm.c \
 907   && test -d ../binutils ; then
 908   NM='$(objdir)/../binutils/nm-new'
 909 else
 910   AC_CHECK_PROG(NM, nm, nm, ${CONFIG_SHELL-/bin/sh} ${srcdir}/../missing nm)
 911 fi
 912
 913 # AR
 914 if test x${build} = x${host} && test -f $srcdir/../binutils/ar.c \
 915   && test -d ../binutils ; then
 916   AR='$(objdir)/../binutils/ar'
 917 else
 918   AC_CHECK_PROG(AR, ar, ar, ${CONFIG_SHELL-/bin/sh} ${srcdir}/../missing ar)
 919 fi
 920
 921
 922 # --------------------
 923 # Checks for C headers
 924 # --------------------
 925
 926 # Need to reject headers which give warnings, so that the -Werror bootstrap
 927 # works later. *sigh*  This needs to come before all header checks.
 928 AC_PROG_CPP_WERROR
 929
 930 AC_HEADER_STDC
 931 AC_HEADER_TIME
 932 ACX_HEADER_STRING
 933 AC_HEADER_SYS_WAIT
 934 AC_CHECK_HEADERS(limits.h stddef.h string.h strings.h stdlib.h time.h iconv.h \
 935                  fcntl.h unistd.h sys/file.h sys/time.h sys/mman.h \
 936                  sys/resource.h sys/param.h sys/times.h sys/stat.h \
 937                  direct.h malloc.h langinfo.h ldfcn.h locale.h wchar.h)
 938
 939 # Check for thread headers.
 940 AC_CHECK_HEADER(thread.h, [have_thread_h=yes], [have_thread_h=])
 941 AC_CHECK_HEADER(pthread.h, [have_pthread_h=yes], [have_pthread_h=])
 942
 943 # These tests can't be done till we know if we have limits.h.
 944 gcc_AC_C_CHAR_BIT
 945 AC_C_BIGENDIAN
 946
 947 # --------
 948 # UNSORTED
 949 # --------
 950
 951
 952 # These libraries may be used by collect2.
 953 # We may need a special search path to get them linked.
 954 AC_CACHE_CHECK(for collect2 libraries, gcc_cv_collect2_libs,
 955 [save_LIBS="$LIBS"
 956 for libs in '' -lld -lmld \
 957                 '-L/usr/lib/cmplrs/cc2.11 -lmld' \
 958                 '-L/usr/lib/cmplrs/cc3.11 -lmld'
 959 do
 960         LIBS="$libs"
 961         AC_TRY_LINK_FUNC(ldopen,
 962                 [gcc_cv_collect2_libs="$libs"; break])
 963 done
 964 LIBS="$save_LIBS"
 965 test -z "$gcc_cv_collect2_libs" && gcc_cv_collect2_libs='none required'])
 966 case $gcc_cv_collect2_libs in
 967         "none required")        ;;
 968         *)      COLLECT2_LIBS=$gcc_cv_collect2_libs ;;
 969 esac
 970 AC_SUBST(COLLECT2_LIBS)
 971
 972 # When building Ada code on Alpha, we need exc_resume which is usually in
 973 # -lexc.  So test for it.
 974 save_LIBS="$LIBS"
 975 LIBS=
 976 AC_SEARCH_LIBS(exc_resume, exc)
 977 GNAT_LIBEXC="$LIBS"
 978 LIBS="$save_LIBS"
 979 AC_SUBST(GNAT_LIBEXC)
 980
 981 # Some systems put ldexp and frexp in libm instead of libc; assume
 982 # they're both in the same place.  jcf-dump needs them.
 983 save_LIBS="$LIBS"
 984 LIBS=
 985 AC_SEARCH_LIBS(ldexp, m)
 986 LDEXP_LIB="$LIBS"
 987 LIBS="$save_LIBS"
 988 AC_SUBST(LDEXP_LIB)
 989
 990 # Use <inttypes.h> only if it exists,
 991 # doesn't clash with <sys/types.h>, and declares intmax_t.
 992 AC_MSG_CHECKING(for inttypes.h)
 993 AC_CACHE_VAL(gcc_cv_header_inttypes_h,
 994 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 995 [[#include <sys/types.h>
 996 #include <inttypes.h>]],
 997   [[intmax_t i = -1;]])],
 998   [gcc_cv_header_inttypes_h=yes],
 999   [gcc_cv_header_inttypes_h=no])])
1000 AC_MSG_RESULT($gcc_cv_header_inttypes_h)
1001 if test $gcc_cv_header_inttypes_h = yes; then
1002   AC_DEFINE(HAVE_INTTYPES_H, 1,
1003         [Define if you have a working <inttypes.h> header file.])
1004 fi
1005
1006 dnl Disabled until we have a complete test for buggy enum bitfields.
1007 dnl gcc_AC_C_ENUM_BF_UNSIGNED
1008
1009 define(gcc_UNLOCKED_FUNCS, clearerr_unlocked feof_unlocked dnl
1010   ferror_unlocked fflush_unlocked fgetc_unlocked fgets_unlocked dnl
1011   fileno_unlocked fprintf_unlocked fputc_unlocked fputs_unlocked dnl
1012   fread_unlocked fwrite_unlocked getchar_unlocked getc_unlocked dnl
1013   putchar_unlocked putc_unlocked)
1014 AC_CHECK_FUNCS(times clock kill getrlimit setrlimit atoll atoq \
1015         sysconf strsignal getrusage nl_langinfo \
1016         gettimeofday mbstowcs wcswidth mmap mincore setlocale \
1017         gcc_UNLOCKED_FUNCS)
1018
1019 if test x$ac_cv_func_mbstowcs = xyes; then
1020   AC_CACHE_CHECK(whether mbstowcs works, gcc_cv_func_mbstowcs_works,
1021 [    AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdlib.h>
1022 int main()
1023 {
1024   mbstowcs(0, "", 0);
1025   return 0;
1026 }]])],
1027     [gcc_cv_func_mbstowcs_works=yes],
1028     [gcc_cv_func_mbstowcs_works=no],
1029     [gcc_cv_func_mbstowcs_works=yes])])
1030   if test x$gcc_cv_func_mbstowcs_works = xyes; then
1031     AC_DEFINE(HAVE_WORKING_MBSTOWCS, 1,
1032   [Define this macro if mbstowcs does not crash when its
1033    first argument is NULL.])
1034   fi
1035 fi
1036
1037 AC_CHECK_TYPE(ssize_t, int)
1038 AC_CHECK_TYPE(caddr_t, char *)
1039
1040 gcc_AC_FUNC_MMAP_BLACKLIST
1041
1042 case "${host}" in
1043 *-*-*vms*)
1044   # Under VMS, vfork works very differently than on Unix. The standard test
1045   # won't work, and it isn't easily adaptable. It makes more sense to
1046   # just force it.
1047   ac_cv_func_vfork_works=yes
1048   ;;
1049 esac
1050 AC_FUNC_FORK
1051
1052 AM_ICONV
1053 # Until we have in-tree GNU iconv:
1054 LIBICONV_DEP=
1055 AC_SUBST(LIBICONV_DEP)
1056
1057 AM_LC_MESSAGES
1058
1059 AM_LANGINFO_CODESET
1060
1061 # We will need to find libiberty.h and ansidecl.h
1062 saved_CFLAGS="$CFLAGS"
1063 CFLAGS="$CFLAGS -I${srcdir} -I${srcdir}/../include"
1064 gcc_AC_CHECK_DECLS(getenv atol asprintf sbrk abort atof getcwd getwd \
1065         strsignal strstr strverscmp \
1066         errno snprintf vsnprintf vasprintf malloc realloc calloc \
1067         free basename getopt clock getpagesize gcc_UNLOCKED_FUNCS, , ,[
1068 #include "ansidecl.h"
1069 #include "system.h"])
1070
1071 gcc_AC_CHECK_DECLS(getrlimit setrlimit getrusage, , ,[
1072 #include "ansidecl.h"
1073 #include "system.h"
1074 #ifdef HAVE_SYS_RESOURCE_H
1075 #include <sys/resource.h>
1076 #endif
1077 ])
1078
1079 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1080 #include "ansidecl.h"
1081 #include "system.h"
1082 #ifdef HAVE_SYS_RESOURCE_H
1083 #include <sys/resource.h>
1084 #endif
1085 ]], [[rlim_t l = 0;]])],[],[AC_DEFINE([rlim_t],[long],
1086 [Define to `long' if <sys/resource.h> doesn't define.])])
1087
1088 # On AIX 5.2, <ldfcn.h> conflicts with <fcntl.h>, as both define incompatible
1089 # FREAD and FWRITE macros.  Fortunately, for GCC's single usage of ldgetname
1090 # in collect2.c, <fcntl.h> isn't visible, but the configure test below needs
1091 # to undef these macros to get the correct value for HAVE_DECL_LDGETNAME.
1092 gcc_AC_CHECK_DECLS(ldgetname, , ,[
1093 #include "ansidecl.h"
1094 #include "system.h"
1095 #ifdef HAVE_LDFCN_H
1096 #undef FREAD
1097 #undef FWRITE
1098 #include <ldfcn.h>
1099 #endif
1100 ])
1101
1102 gcc_AC_CHECK_DECLS(times, , ,[
1103 #include "ansidecl.h"
1104 #include "system.h"
1105 #ifdef HAVE_SYS_TIMES_H
1106 #include <sys/times.h>
1107 #endif
1108 ])
1109
1110 gcc_AC_CHECK_DECLS(sigaltstack, , ,[
1111 #include "ansidecl.h"
1112 #include "system.h"
1113 #include <signal.h>
1114 ])
1115
1116 # More time-related stuff.
1117 AC_CACHE_CHECK(for struct tms, ac_cv_struct_tms, [
1118 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1119 #include "ansidecl.h"
1120 #include "system.h"
1121 #ifdef HAVE_SYS_TIMES_H
1122 #include <sys/times.h>
1123 #endif
1124 ]], [[struct tms tms;]])],[ac_cv_struct_tms=yes],[ac_cv_struct_tms=no])])
1125 if test $ac_cv_struct_tms = yes; then
1126   AC_DEFINE(HAVE_STRUCT_TMS, 1,
1127   [Define if <sys/times.h> defines struct tms.])
1128 fi
1129
1130 # use gcc_cv_* here because this doesn't match the behavior of AC_CHECK_TYPE.
1131 # revisit after autoconf 2.50.
1132 AC_CACHE_CHECK(for clock_t, gcc_cv_type_clock_t, [
1133 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1134 #include "ansidecl.h"
1135 #include "system.h"
1136 ]], [[clock_t x;]])],[gcc_cv_type_clock_t=yes],[gcc_cv_type_clock_t=no])])
1137 if test $gcc_cv_type_clock_t = yes; then
1138   AC_DEFINE(HAVE_CLOCK_T, 1,
1139   [Define if <time.h> defines clock_t.])
1140 fi
1141
1142 # Restore CFLAGS from before the gcc_AC_NEED_DECLARATIONS tests.
1143 CFLAGS="$saved_CFLAGS"
1144
1145 gcc_AC_INITFINI_ARRAY
1146
1147 # mkdir takes a single argument on some systems.
1148 gcc_AC_FUNC_MKDIR_TAKES_ONE_ARG
1149
1150 # File extensions
1151 manext='.1'
1152 objext='.o'
1153 AC_SUBST(manext)
1154 AC_SUBST(objext)
1155
1156 # With Setjmp/Longjmp based exception handling.
1157 AC_ARG_ENABLE(sjlj-exceptions,
1158 [  --enable-sjlj-exceptions
1159                           arrange to use setjmp/longjmp exception handling],
1160 [case $target in
1161   *-*-hpux10*)
1162     if test $enableval != yes; then
1163       AC_MSG_WARN([dwarf2 exceptions not supported, sjlj exceptions forced])
1164       enableval=yes
1165     fi
1166     ;;
1167 esac
1168 force_sjlj_exceptions=yes],
1169 [case $target in
1170   *-*-hpux10*)
1171     force_sjlj_exceptions=yes
1172     enableval=yes
1173     ;;
1174   *)
1175     force_sjlj_exceptions=no
1176     ;;
1177 esac])
1178 if test $force_sjlj_exceptions = yes; then
1179   sjlj=`if test $enableval = yes; then echo 1; else echo 0; fi`
1180   AC_DEFINE_UNQUOTED(CONFIG_SJLJ_EXCEPTIONS, $sjlj,
1181     [Define 0/1 to force the choice for exception handling model.])
1182 fi
1183
1184 # For platforms with the unwind ABI which includes an unwind library,
1185 # libunwind, we can choose to use the system libunwind.
1186 # config.gcc also contains tests of with_system_libunwind.
1187 GCC_CHECK_UNWIND_GETIPINFO
1188
1189 # --------------------------------------------------------
1190 # Build, host, and target specific configuration fragments
1191 # --------------------------------------------------------
1192
1193 # Collect build-machine-specific information.
1194 . ${srcdir}/config.build
1195
1196 # Collect host-machine-specific information.
1197 . ${srcdir}/config.host
1198
1199 target_gtfiles=
1200
1201 # Collect target-machine-specific information.
1202 . ${srcdir}/config.gcc
1203
1204 extra_objs="${host_extra_objs} ${extra_objs}"
1205 extra_gcc_objs="${host_extra_gcc_objs} ${extra_gcc_objs}"
1206
1207 # Default the target-machine variables that were not explicitly set.
1208 if test x"$tm_file" = x
1209 then tm_file=$cpu_type/$cpu_type.h; fi
1210
1211 if test x"$extra_headers" = x
1212 then extra_headers=; fi
1213
1214 if test x$md_file = x
1215 then md_file=$cpu_type/$cpu_type.md; fi
1216
1217 if test x$out_file = x
1218 then out_file=$cpu_type/$cpu_type.c; fi
1219
1220 if test x"$tmake_file" = x
1221 then tmake_file=$cpu_type/t-$cpu_type
1222 fi
1223
1224 if test x"$dwarf2" = xyes
1225 then tm_file="$tm_file tm-dwarf2.h"
1226 fi
1227
1228 # Say what files are being used for the output code and MD file.
1229 echo "Using \`$srcdir/config/$out_file' for machine-specific logic."
1230 echo "Using \`$srcdir/config/$md_file' as machine description file."
1231
1232 # If any of the xm_file variables contain nonexistent files, warn
1233 # about them and drop them.
1234
1235 bx=
1236 for x in $build_xm_file; do
1237   if    test -f $srcdir/config/$x
1238   then      bx="$bx $x"
1239   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1240   fi
1241 done
1242 build_xm_file="$bx"
1243
1244 hx=
1245 for x in $host_xm_file; do
1246   if    test -f $srcdir/config/$x
1247   then      hx="$hx $x"
1248   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1249   fi
1250 done
1251 host_xm_file="$hx"
1252
1253 tx=
1254 for x in $xm_file; do
1255   if    test -f $srcdir/config/$x
1256   then      tx="$tx $x"
1257   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1258   fi
1259 done
1260 xm_file="$tx"
1261
1262 count=a
1263 for f in $tm_file; do
1264         count=${count}x
1265 done
1266 if test $count = ax; then
1267         echo "Using \`$srcdir/config/$tm_file' as target machine macro file."
1268 else
1269         echo "Using the following target machine macro files:"
1270         for f in $tm_file; do
1271                 echo "  $srcdir/config/$f"
1272         done
1273 fi
1274
1275 if test x$need_64bit_hwint = xyes; then
1276         AC_DEFINE(NEED_64BIT_HOST_WIDE_INT, 1,
1277 [Define to 1 if HOST_WIDE_INT must be 64 bits wide (see hwint.h).])
1278 fi
1279
1280 if test x$use_long_long_for_widest_fast_int = xyes; then
1281         AC_DEFINE(USE_LONG_LONG_FOR_WIDEST_FAST_INT, 1,
1282 [Define to 1 if the 'long long' (or '__int64') is wider than 'long' but still
1283 efficiently supported by the host hardware.])
1284 fi
1285
1286 count=a
1287 for f in $host_xm_file; do
1288         count=${count}x
1289 done
1290 if test $count = a; then
1291         :
1292 elif test $count = ax; then
1293         echo "Using \`$srcdir/config/$host_xm_file' as host machine macro file."
1294 else
1295         echo "Using the following host machine macro files:"
1296         for f in $host_xm_file; do
1297                 echo "  $srcdir/config/$f"
1298         done
1299 fi
1300 echo "Using ${out_host_hook_obj} for host machine hooks."
1301
1302 if test "$host_xm_file" != "$build_xm_file"; then
1303         count=a
1304         for f in $build_xm_file; do
1305                 count=${count}x
1306         done
1307         if test $count = a; then
1308                 :
1309         elif test $count = ax; then
1310                 echo "Using \`$srcdir/config/$build_xm_file' as build machine macro file."
1311         else
1312                 echo "Using the following build machine macro files:"
1313                 for f in $build_xm_file; do
1314                         echo "  $srcdir/config/$f"
1315                 done
1316         fi
1317 fi
1318
1319 case ${host} in
1320   powerpc*-*-darwin*)
1321     AC_CACHE_CHECK([whether mcontext_t fields have underscores],
1322       gcc_cv_mcontext_underscores,
1323       AC_COMPILE_IFELSE([
1324 #include <sys/cdefs.h>
1325 #include <sys/signal.h>
1326 #include <ucontext.h>
1327 int main() { mcontext_t m; if (m->ss.srr0) return 0; return 0; }
1328 ],
1329         gcc_cv_mcontext_underscores=no, gcc_cv_mcontext_underscores=yes))
1330       if test $gcc_cv_mcontext_underscores = yes; then
1331         AC_DEFINE(HAS_MCONTEXT_T_UNDERSCORES,,dnl
1332           [mcontext_t fields start with __])
1333       fi
1334     ;;
1335 esac
1336
1337 # ---------
1338 # Threading
1339 # ---------
1340
1341 # Check if a valid thread package
1342 case ${enable_threads} in
1343   "" | no)
1344     # No threads
1345     target_thread_file='single'
1346     ;;
1347   yes)
1348     # default
1349     target_thread_file='single'
1350     ;;
1351   aix | dce | gnat | irix | posix | posix95 | rtems | \
1352   single | solaris | vxworks | win32 | mipssde)
1353     target_thread_file=${enable_threads}
1354     ;;
1355   *)
1356     echo "${enable_threads} is an unknown thread package" 1>&2
1357     exit 1
1358     ;;
1359 esac
1360
1361 if test x${thread_file} = x; then
1362   # No thread file set by target-specific clauses in config.gcc,
1363   # so use file chosen by default logic above
1364   thread_file=${target_thread_file}
1365 fi
1366
1367 # Make gthr-default.h if we have a thread file.
1368 gthread_flags=
1369 if test $thread_file != single; then
1370   echo "#include \"gthr-${thread_file}.h\"" > gthr-default.h-t
1371   if diff gthr-default.h-t gthr-default.h 2>/dev/null; then
1372     rm -f gthr-default.h-t
1373   else
1374     mv -f gthr-default.h-t gthr-default.h
1375   fi
1376   gthread_flags=-DHAVE_GTHR_DEFAULT
1377 fi
1378 AC_SUBST(gthread_flags)
1379
1380 # --------
1381 # UNSORTED
1382 # --------
1383
1384 use_cxa_atexit=no
1385 if test x$enable___cxa_atexit = xyes || \
1386    test x$enable___cxa_atexit = x -a x$default_use_cxa_atexit = xyes; then
1387   if test x$host = x$target; then
1388     case $host in
1389       # mingw32 doesn't have __cxa_atexit but uses atexit registration
1390       # keyed to flag_use_cxa_atexit
1391       *-*-mingw32*)
1392         use_cxa_atexit=yes
1393         ;;
1394       *)
1395         AC_CHECK_FUNC(__cxa_atexit,[use_cxa_atexit=yes],
1396           [echo "__cxa_atexit can't be enabled on this target"])
1397         ;;
1398     esac
1399   else
1400     # We can't check for __cxa_atexit when building a cross, so assume
1401     # it is available
1402     use_cxa_atexit=yes
1403   fi
1404   if test x$use_cxa_atexit = xyes; then
1405     AC_DEFINE(DEFAULT_USE_CXA_ATEXIT, 2,
1406       [Define if you want to use __cxa_atexit, rather than atexit, to
1407       register C++ destructors for local statics and global objects.
1408       This is essential for fully standards-compliant handling of
1409       destructors, but requires __cxa_atexit in libc.])
1410   fi
1411 fi
1412
1413 # Look for a file containing extra machine modes.
1414 if test -n "$extra_modes" && test -f $srcdir/config/$extra_modes; then
1415   extra_modes_file='$(srcdir)'/config/${extra_modes}
1416   AC_SUBST(extra_modes_file)
1417   AC_DEFINE_UNQUOTED(EXTRA_MODES_FILE, "config/$extra_modes",
1418   [Define to the name of a file containing a list of extra machine modes
1419    for this architecture.])
1420 fi
1421
1422 # Convert extra_options into a form suitable for Makefile use.
1423 extra_opt_files=
1424 for f in $extra_options; do
1425   extra_opt_files="$extra_opt_files \$(srcdir)/config/$f"
1426 done
1427 AC_SUBST(extra_opt_files)
1428
1429 # auto-host.h is the file containing items generated by autoconf and is
1430 # the first file included by config.h.
1431 # If host=build, it is correct to have bconfig include auto-host.h
1432 # as well.  If host!=build, we are in error and need to do more
1433 # work to find out the build config parameters.
1434 if test x$host = x$build
1435 then
1436         build_auto=auto-host.h
1437 else
1438         # We create a subdir, then run autoconf in the subdir.
1439         # To prevent recursion we set host and build for the new
1440         # invocation of configure to the build for this invocation
1441         # of configure.
1442         tempdir=build.$$
1443         rm -rf $tempdir
1444         mkdir $tempdir
1445         cd $tempdir
1446         case ${srcdir} in
1447         /* | [A-Za-z]:[\\/]* ) realsrcdir=${srcdir};;
1448         *) realsrcdir=../${srcdir};;
1449         esac
1450         saved_CFLAGS="${CFLAGS}"
1451         CC="${CC_FOR_BUILD}" CFLAGS="${CFLAGS_FOR_BUILD}" \
1452         LDFLAGS="${LDFLAGS_FOR_BUILD}" \
1453         ${realsrcdir}/configure \
1454                 --enable-languages=${enable_languages-all} \
1455                 --target=$target_alias --host=$build_alias --build=$build_alias
1456         CFLAGS="${saved_CFLAGS}"
1457
1458         # We just finished tests for the build machine, so rename
1459         # the file auto-build.h in the gcc directory.
1460         mv auto-host.h ../auto-build.h
1461         cd ..
1462         rm -rf $tempdir
1463         build_auto=auto-build.h
1464 fi
1465 AC_SUBST(build_subdir)
1466
1467 tm_file="${tm_file} defaults.h"
1468 tm_p_file="${tm_p_file} tm-preds.h"
1469 host_xm_file="auto-host.h ansidecl.h ${host_xm_file}"
1470 build_xm_file="${build_auto} ansidecl.h ${build_xm_file}"
1471 # We don't want ansidecl.h in target files, write code there in ISO/GNU C.
1472 # put this back in temporarily.
1473 xm_file="auto-host.h ansidecl.h ${xm_file}"
1474
1475 # --------
1476 # UNSORTED
1477 # --------
1478
1479 changequote(,)dnl
1480 # Compile in configure arguments.
1481 if test -f configargs.h ; then
1482         # Being re-configured.
1483         gcc_config_arguments=`grep configuration_arguments configargs.h | sed -e 's/.*"\([^"]*\)".*/\1/'`
1484         gcc_config_arguments="$gcc_config_arguments : (reconfigured) $TOPLEVEL_CONFIGURE_ARGUMENTS"
1485 else
1486         gcc_config_arguments="$TOPLEVEL_CONFIGURE_ARGUMENTS"
1487 fi
1488
1489 # Double all backslashes and backslash all quotes to turn
1490 # gcc_config_arguments into a C string.
1491 sed -e 's/\\/\\\\/g; s/"/\\"/g' <<EOF >conftest.out
1492 $gcc_config_arguments
1493 EOF
1494 gcc_config_arguments_str=`cat conftest.out`
1495 rm -f conftest.out
1496
1497 cat > configargs.h <<EOF
1498 /* Generated automatically. */
1499 static const char configuration_arguments[] = "$gcc_config_arguments_str";
1500 static const char thread_model[] = "$thread_file";
1501
1502 static const struct {
1503   const char *name, *value;
1504 } configure_default_options[] = $configure_default_options;
1505 EOF
1506 changequote([,])dnl
1507
1508 changequote(,)dnl
1509 gcc_BASEVER=`cat $srcdir/BASE-VER`
1510 gcc_DEVPHASE=`cat $srcdir/DEV-PHASE`
1511 gcc_DATESTAMP=`cat $srcdir/DATESTAMP`
1512 if test -f $srcdir/REVISION ; then
1513         gcc_REVISION=`cat $srcdir/REVISION`
1514 else
1515         gcc_REVISION=""
1516 fi
1517 cat > plugin-version.h <<EOF
1518 #include "configargs.h"
1519
1520 static char basever[] = "$gcc_BASEVER";
1521 static char datestamp[] = "$gcc_DATESTAMP";
1522 static char devphase[] = "$gcc_DEVPHASE";
1523 static char revision[] = "$gcc_REVISION";
1524
1525 /* FIXME plugins: We should make the version information more precise.
1526    One way to do is to add a checksum. */
1527
1528 static struct plugin_gcc_version gcc_version = {basever, datestamp,
1529                                                 devphase, revision,
1530                                                 configuration_arguments};
1531 EOF
1532 changequote([,])dnl
1533
1534 # Internationalization
1535 ZW_GNU_GETTEXT_SISTER_DIR
1536
1537 # If LIBINTL contains LIBICONV, then clear LIBICONV so we don't get
1538 # -liconv on the link line twice.
1539 case "$LIBINTL" in *$LIBICONV*)
1540         LIBICONV= ;;
1541 esac
1542
1543 AC_ARG_ENABLE(secureplt,
1544 [  --enable-secureplt      enable -msecure-plt by default for PowerPC],
1545 [], [])
1546
1547 AC_ARG_ENABLE(cld,
1548 [  --enable-cld            enable -mcld by default for 32bit x86], [],
1549 [enable_cld=no])
1550
1551 # Windows32 Registry support for specifying GCC installation paths.
1552 AC_ARG_ENABLE(win32-registry,
1553 [  --disable-win32-registry
1554                           disable lookup of installation paths in the
1555                           Registry on Windows hosts
1556   --enable-win32-registry enable registry lookup (default)
1557   --enable-win32-registry=KEY
1558                           use KEY instead of GCC version as the last portion
1559                           of the registry key],,)
1560
1561 case $host_os in
1562   win32 | pe | cygwin* | mingw32* | uwin*)
1563     if test "x$enable_win32_registry" != xno; then
1564       AC_SEARCH_LIBS(RegOpenKeyExA, advapi32,, [enable_win32_registry=no])
1565     fi
1566
1567     if test "x$enable_win32_registry" != xno; then
1568       AC_DEFINE(ENABLE_WIN32_REGISTRY, 1,
1569   [Define to 1 if installation paths should be looked up in the Windows
1570    Registry. Ignored on non-Windows hosts.])
1571
1572       if test "x$enable_win32_registry" != xyes \
1573          && test "x$enable_win32_registry" != x; then
1574         AC_DEFINE_UNQUOTED(WIN32_REGISTRY_KEY, "$enable_win32_registry",
1575   [Define to be the last component of the Windows registry key under which
1576    to look for installation paths.  The full key used will be
1577    HKEY_LOCAL_MACHINE/SOFTWARE/Free Software Foundation/{WIN32_REGISTRY_KEY}.
1578    The default is the GCC version number.])
1579       fi
1580     fi
1581   ;;
1582 esac
1583
1584 # Get an absolute path to the GCC top-level source directory
1585 holddir=`${PWDCMD-pwd}`
1586 cd $srcdir
1587 topdir=`${PWDCMD-pwd}`
1588 cd $holddir
1589
1590 # Conditionalize the makefile for this host machine.
1591 xmake_file=
1592 for f in ${host_xmake_file}
1593 do
1594         if test -f ${srcdir}/config/$f
1595         then
1596                 xmake_file="${xmake_file} \$(srcdir)/config/$f"
1597         fi
1598 done
1599
1600 # Conditionalize the makefile for this target machine.
1601 tmake_file_=
1602 for f in ${tmake_file}
1603 do
1604         if test -f ${srcdir}/config/$f
1605         then
1606                 tmake_file_="${tmake_file_} \$(srcdir)/config/$f"
1607         fi
1608 done
1609 tmake_file="${tmake_file_}"
1610
1611 out_object_file=`basename $out_file .c`.o
1612
1613 tm_file_list="options.h"
1614 tm_include_list="options.h"
1615 for f in $tm_file; do
1616   case $f in
1617     ./* )
1618        f=`echo $f | sed 's/^..//'`
1619        tm_file_list="${tm_file_list} $f"
1620        tm_include_list="${tm_include_list} $f"
1621        ;;
1622     defaults.h )
1623        tm_file_list="${tm_file_list} \$(srcdir)/$f"
1624        tm_include_list="${tm_include_list} $f"
1625        ;;
1626     * )
1627        tm_file_list="${tm_file_list} \$(srcdir)/config/$f"
1628        tm_include_list="${tm_include_list} config/$f"
1629        ;;
1630   esac
1631 done
1632
1633 tm_p_file_list=
1634 tm_p_include_list=
1635 for f in $tm_p_file; do
1636   case $f in
1637     tm-preds.h )
1638        tm_p_file_list="${tm_p_file_list} $f"
1639        tm_p_include_list="${tm_p_include_list} $f"
1640        ;;
1641     * )
1642        tm_p_file_list="${tm_p_file_list} \$(srcdir)/config/$f"
1643        tm_p_include_list="${tm_p_include_list} config/$f"
1644   esac
1645 done
1646
1647 xm_file_list=
1648 xm_include_list=
1649 for f in $xm_file; do
1650   case $f in
1651     ansidecl.h )
1652        xm_file_list="${xm_file_list} \$(srcdir)/../include/$f"
1653        xm_include_list="${xm_include_list} $f"
1654        ;;
1655     auto-host.h )
1656        xm_file_list="${xm_file_list} $f"
1657        xm_include_list="${xm_include_list} $f"
1658        ;;
1659     * )
1660        xm_file_list="${xm_file_list} \$(srcdir)/config/$f"
1661        xm_include_list="${xm_include_list} config/$f"
1662        ;;
1663   esac
1664 done
1665
1666 host_xm_file_list=
1667 host_xm_include_list=
1668 for f in $host_xm_file; do
1669   case $f in
1670     ansidecl.h )
1671        host_xm_file_list="${host_xm_file_list} \$(srcdir)/../include/$f"
1672        host_xm_include_list="${host_xm_include_list} $f"
1673        ;;
1674     auto-host.h )
1675        host_xm_file_list="${host_xm_file_list} $f"
1676        host_xm_include_list="${host_xm_include_list} $f"
1677        ;;
1678     * )
1679        host_xm_file_list="${host_xm_file_list} \$(srcdir)/config/$f"
1680        host_xm_include_list="${host_xm_include_list} config/$f"
1681        ;;
1682   esac
1683 done
1684
1685 build_xm_file_list=
1686 for f in $build_xm_file; do
1687   case $f in
1688     ansidecl.h )
1689        build_xm_file_list="${build_xm_file_list} \$(srcdir)/../include/$f"
1690        build_xm_include_list="${build_xm_include_list} $f"
1691        ;;
1692     auto-build.h | auto-host.h )
1693        build_xm_file_list="${build_xm_file_list} $f"
1694        build_xm_include_list="${build_xm_include_list} $f"
1695        ;;
1696     * )
1697        build_xm_file_list="${build_xm_file_list} \$(srcdir)/config/$f"
1698        build_xm_include_list="${build_xm_include_list} config/$f"
1699        ;;
1700   esac
1701 done
1702
1703 # Define macro CROSS_DIRECTORY_STRUCTURE in compilation if this is a
1704 # cross-compiler which does not use the native headers and libraries.
1705 # Also use all.cross instead of all.internal and adjust SYSTEM_HEADER_DIR.
1706 CROSS=                                          AC_SUBST(CROSS)
1707 ALL=all.internal                                AC_SUBST(ALL)
1708 SYSTEM_HEADER_DIR='$(NATIVE_SYSTEM_HEADER_DIR)' AC_SUBST(SYSTEM_HEADER_DIR)
1709
1710 if test "x$with_build_sysroot" != x; then
1711   build_system_header_dir=$with_build_sysroot'$${sysroot_headers_suffix}$(NATIVE_SYSTEM_HEADER_DIR)'
1712 else
1713   # This value is used, even on a native system, because
1714   # CROSS_SYSTEM_HEADER_DIR is just
1715   # $(TARGET_SYSTEM_ROOT)$(NATIVE_SYSTEM_HEADER_DIR).
1716   build_system_header_dir='$(CROSS_SYSTEM_HEADER_DIR)'
1717 fi
1718
1719 if test x$host != x$target
1720 then
1721         CROSS="-DCROSS_DIRECTORY_STRUCTURE"
1722         ALL=all.cross
1723         SYSTEM_HEADER_DIR=$build_system_header_dir
1724         case "$host","$target" in
1725         # Darwin crosses can use the host system's libraries and headers,
1726         # because of the fat library support.  Of course, it must be the
1727         # same version of Darwin on both sides.  Allow the user to
1728         # just say --target=foo-darwin without a version number to mean
1729         # "the version on this system".
1730             *-*-darwin*,*-*-darwin*)
1731                 hostos=`echo $host | sed 's/.*-darwin/darwin/'`
1732                 targetos=`echo $target | sed 's/.*-darwin/darwin/'`
1733                 if test $hostos = $targetos -o $targetos = darwin ; then
1734                     CROSS=
1735                     SYSTEM_HEADER_DIR='$(NATIVE_SYSTEM_HEADER_DIR)'
1736                     with_headers=yes
1737                 fi
1738                 ;;
1739
1740             i?86-*-*,x86_64-*-* \
1741             | powerpc*-*-*,powerpc64*-*-*)
1742                 CROSS="$CROSS -DNATIVE_CROSS" ;;
1743         esac
1744 elif test "x$TARGET_SYSTEM_ROOT" != x; then
1745         SYSTEM_HEADER_DIR=$build_system_header_dir
1746 fi
1747
1748 # If this is a cross-compiler that does not
1749 # have its own set of headers then define
1750 # inhibit_libc
1751
1752 # If this is using newlib, without having the headers available now,
1753 # then define inhibit_libc in LIBGCC2_CFLAGS.
1754 # This prevents libgcc2 from containing any code which requires libc
1755 # support.
1756 : ${inhibit_libc=false}
1757 if { { test x$host != x$target && test "x$with_sysroot" = x ; } ||
1758        test x$with_newlib = xyes ; } &&
1759      { test "x$with_headers" = x || test "x$with_headers" = xno ; } ; then
1760        inhibit_libc=true
1761 fi
1762 AC_SUBST(inhibit_libc)
1763
1764 # When building gcc with a cross-compiler, we need to adjust things so
1765 # that the generator programs are still built with the native compiler.
1766 # Also, we cannot run fixincludes.
1767
1768 # These are the normal (build=host) settings:
1769 CC_FOR_BUILD='$(CC)'            AC_SUBST(CC_FOR_BUILD)
1770 BUILD_CFLAGS='$(ALL_CFLAGS)'    AC_SUBST(BUILD_CFLAGS)
1771 BUILD_LDFLAGS='$(LDFLAGS)'      AC_SUBST(BUILD_LDFLAGS)
1772 STMP_FIXINC=stmp-fixinc         AC_SUBST(STMP_FIXINC)
1773
1774 # And these apply if build != host, or we are generating coverage data
1775 if test x$build != x$host || test "x$coverage_flags" != x
1776 then
1777     BUILD_CFLAGS='$(INTERNAL_CFLAGS) $(T_CFLAGS) $(CFLAGS_FOR_BUILD)'
1778     BUILD_LDFLAGS='$(LDFLAGS_FOR_BUILD)'
1779 fi
1780
1781 # Expand extra_headers to include complete path.
1782 # This substitutes for lots of t-* files.
1783 extra_headers_list=
1784 # Prepend $(srcdir)/config/${cpu_type}/ to every entry in extra_headers.
1785 for file in ${extra_headers} ; do
1786   extra_headers_list="${extra_headers_list} \$(srcdir)/config/${cpu_type}/${file}"
1787 done
1788
1789 # If use_gcc_tgmath is set, append ginclude/tgmath.h.
1790 if test x"$use_gcc_tgmath" = xyes
1791 then extra_headers_list="${extra_headers_list} \$(srcdir)/ginclude/tgmath.h"
1792 fi
1793
1794 # Define collect2 in Makefile.
1795 case $host_can_use_collect2 in
1796   no) collect2= ;;
1797   *) collect2='collect2$(exeext)' ;;
1798 esac
1799 AC_SUBST([collect2])
1800
1801 # Add a definition of USE_COLLECT2 if system wants one.
1802 case $use_collect2 in
1803   no) use_collect2= ;;
1804   "") ;;
1805   *)
1806     host_xm_defines="${host_xm_defines} USE_COLLECT2"
1807     xm_defines="${xm_defines} USE_COLLECT2"
1808     case $host_can_use_collect2 in
1809       no)
1810         AC_MSG_ERROR([collect2 is required but cannot be built on this system])
1811         ;;
1812     esac
1813     ;;
1814 esac
1815
1816 # ---------------------------
1817 # Assembler & linker features
1818 # ---------------------------
1819
1820 # During stage 2, ld is actually gcc/collect-ld, which is a small script to
1821 # discern between when to use prev-ld/ld-new and when to use ld/ld-new.
1822 # However when ld-new is first executed from the build tree, libtool will
1823 # relink it as .libs/lt-ld-new, so that it can give it an RPATH that refers
1824 # to the build tree.  While doing this we need to use the previous-stage
1825 # linker, or we have an infinite loop.  The presence of a shell script as
1826 # ld/ld-new, and the fact that the script *uses ld itself*, is what confuses
1827 # the gcc/collect-ld script.  So we need to know how libtool works, or
1828 # exec-tool will fail.
1829
1830 m4_defun([_LT_CONFIG_COMMANDS], [])
1831 AC_PROG_LIBTOOL
1832 AC_SUBST(objdir)
1833 AC_SUBST(enable_fast_install)
1834
1835 # Identify the assembler which will work hand-in-glove with the newly
1836 # built GCC, so that we can examine its features.  This is the assembler
1837 # which will be driven by the driver program.
1838 #
1839 # If build != host, and we aren't building gas in-tree, we identify a
1840 # build->target assembler and hope that it will have the same features
1841 # as the host->target assembler we'll be using.
1842 gcc_cv_gas_major_version=
1843 gcc_cv_gas_minor_version=
1844 gcc_cv_as_gas_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/gas
1845
1846 m4_pattern_allow([AS_FOR_TARGET])dnl
1847 AS_VAR_SET_IF(gcc_cv_as,, [
1848 if test -x "$DEFAULT_ASSEMBLER"; then
1849         gcc_cv_as="$DEFAULT_ASSEMBLER"
1850 elif test -f $gcc_cv_as_gas_srcdir/configure.in \
1851      && test -f ../gas/Makefile \
1852      && test x$build = x$host; then
1853         gcc_cv_as=../gas/as-new$build_exeext
1854 elif test -x as$build_exeext; then
1855         # Build using assembler in the current directory.
1856         gcc_cv_as=./as$build_exeext
1857 elif test -x $AS_FOR_TARGET; then
1858         gcc_cv_as="$AS_FOR_TARGET"
1859 else
1860         AC_PATH_PROG(gcc_cv_as, $AS_FOR_TARGET)
1861 fi])
1862
1863 ORIGINAL_AS_FOR_TARGET=$gcc_cv_as
1864 AC_SUBST(ORIGINAL_AS_FOR_TARGET)
1865 case "$ORIGINAL_AS_FOR_TARGET" in
1866   ./as | ./as$build_exeext) ;;
1867   *) AC_CONFIG_FILES(as:exec-tool.in, [chmod +x as]) ;;
1868 esac
1869
1870 AC_MSG_CHECKING(what assembler to use)
1871 if test "$gcc_cv_as" = ../gas/as-new$build_exeext; then
1872   # Single tree build which includes gas.  We want to prefer it
1873   # over whatever linker top-level may have detected, since
1874   # we'll use what we're building after installation anyway.
1875   AC_MSG_RESULT(newly built gas)
1876   in_tree_gas=yes
1877   _gcc_COMPUTE_GAS_VERSION
1878   in_tree_gas_is_elf=no
1879   if grep 'obj_format = elf' ../gas/Makefile > /dev/null \
1880      || (grep 'obj_format = multi' ../gas/Makefile \
1881          && grep 'extra_objects =.* obj-elf' ../gas/Makefile) > /dev/null
1882   then
1883     in_tree_gas_is_elf=yes
1884   fi
1885 else
1886   AC_MSG_RESULT($gcc_cv_as)
1887   in_tree_gas=no
1888 fi
1889
1890 # Identify the linker which will work hand-in-glove with the newly
1891 # built GCC, so that we can examine its features.  This is the linker
1892 # which will be driven by the driver program.
1893 #
1894 # If build != host, and we aren't building gas in-tree, we identify a
1895 # build->target linker and hope that it will have the same features
1896 # as the host->target linker we'll be using.
1897 gcc_cv_gld_major_version=
1898 gcc_cv_gld_minor_version=
1899 gcc_cv_ld_gld_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/ld
1900 gcc_cv_ld_bfd_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/bfd
1901
1902 AS_VAR_SET_IF(gcc_cv_ld,, [
1903 if test -x "$DEFAULT_LINKER"; then
1904         gcc_cv_ld="$DEFAULT_LINKER"
1905 elif test -f $gcc_cv_ld_gld_srcdir/configure.in \
1906      && test -f ../ld/Makefile \
1907      && test x$build = x$host; then
1908         gcc_cv_ld=../ld/ld-new$build_exeext
1909 elif test -x collect-ld$build_exeext; then
1910         # Build using linker in the current directory.
1911         gcc_cv_ld=./collect-ld$build_exeext
1912 elif test -x $LD_FOR_TARGET; then
1913         gcc_cv_ld="$LD_FOR_TARGET"
1914 else
1915         AC_PATH_PROG(gcc_cv_ld, $LD_FOR_TARGET)
1916 fi])
1917
1918 ORIGINAL_PLUGIN_LD_FOR_TARGET=$gcc_cv_ld
1919 PLUGIN_LD=`basename $gcc_cv_ld`
1920 AC_ARG_WITH(plugin-ld,
1921 [  --with-plugin-ld=[[ARG]]  specify the plugin linker],
1922 [if test x"$withval" != x; then
1923    ORIGINAL_PLUGIN_LD_FOR_TARGET="$withval"
1924    PLUGIN_LD="$withval"
1925  fi])
1926 AC_SUBST(ORIGINAL_PLUGIN_LD_FOR_TARGET)
1927 AC_DEFINE_UNQUOTED(PLUGIN_LD, "$PLUGIN_LD", [Specify plugin linker])
1928
1929 ORIGINAL_LD_FOR_TARGET=$gcc_cv_ld
1930 AC_SUBST(ORIGINAL_LD_FOR_TARGET)
1931 case "$ORIGINAL_LD_FOR_TARGET" in
1932   ./collect-ld | ./collect-ld$build_exeext) ;;
1933   *) AC_CONFIG_FILES(collect-ld:exec-tool.in, [chmod +x collect-ld]) ;;
1934 esac
1935
1936 AC_MSG_CHECKING(what linker to use)
1937 if test "$gcc_cv_ld" = ../ld/ld-new$build_exeext; then
1938         # Single tree build which includes ld.  We want to prefer it
1939         # over whatever linker top-level may have detected, since
1940         # we'll use what we're building after installation anyway.
1941         AC_MSG_RESULT(newly built ld)
1942         in_tree_ld=yes
1943         in_tree_ld_is_elf=no
1944         if (grep 'EMUL = .*elf' ../ld/Makefile \
1945             || grep 'EMUL = .*linux' ../ld/Makefile \
1946             || grep 'EMUL = .*lynx' ../ld/Makefile) > /dev/null; then
1947           in_tree_ld_is_elf=yes
1948         fi
1949         for f in $gcc_cv_ld_bfd_srcdir/configure $gcc_cv_ld_gld_srcdir/configure $gcc_cv_ld_gld_srcdir/configure.in $gcc_cv_ld_gld_srcdir/Makefile.in
1950         do
1951 changequote(,)dnl
1952                 gcc_cv_gld_version=`sed -n -e 's/^[     ]*\(VERSION=[0-9]*\.[0-9]*.*\)/\1/p' < $f`
1953                 if test x$gcc_cv_gld_version != x; then
1954                         break
1955                 fi
1956         done
1957         gcc_cv_gld_major_version=`expr "$gcc_cv_gld_version" : "VERSION=\([0-9]*\)"`
1958         gcc_cv_gld_minor_version=`expr "$gcc_cv_gld_version" : "VERSION=[0-9]*\.\([0-9]*\)"`
1959 changequote([,])dnl
1960 else
1961         AC_MSG_RESULT($gcc_cv_ld)
1962         in_tree_ld=no
1963 fi
1964
1965 # Figure out what nm we will be using.
1966 gcc_cv_binutils_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/binutils
1967 AS_VAR_SET_IF(gcc_cv_nm,, [
1968 if test -f $gcc_cv_binutils_srcdir/configure.in \
1969      && test -f ../binutils/Makefile \
1970      && test x$build = x$host; then
1971         gcc_cv_nm=../binutils/nm-new$build_exeext
1972 elif test -x nm$build_exeext; then
1973         gcc_cv_nm=./nm$build_exeext
1974 elif test -x $NM_FOR_TARGET; then
1975         gcc_cv_nm="$NM_FOR_TARGET"
1976 else
1977         AC_PATH_PROG(gcc_cv_nm, $NM_FOR_TARGET)
1978 fi])
1979
1980 AC_MSG_CHECKING(what nm to use)
1981 if test "$gcc_cv_nm" = ../binutils/nm-new$build_exeext; then
1982         # Single tree build which includes binutils.
1983         AC_MSG_RESULT(newly built nm)
1984         in_tree_nm=yes
1985 else
1986         AC_MSG_RESULT($gcc_cv_nm)
1987         in_tree_nm=no
1988 fi
1989
1990 ORIGINAL_NM_FOR_TARGET=$gcc_cv_nm
1991 AC_SUBST(ORIGINAL_NM_FOR_TARGET)
1992 case "$ORIGINAL_NM_FOR_TARGET" in
1993   ./nm | ./nm$build_exeext) ;;
1994   *) AC_CONFIG_FILES(nm:exec-tool.in, [chmod +x nm]) ;;
1995 esac
1996
1997
1998 # Figure out what objdump we will be using.
1999 AS_VAR_SET_IF(gcc_cv_objdump,, [
2000 if test -f $gcc_cv_binutils_srcdir/configure.in \
2001      && test -f ../binutils/Makefile \
2002      && test x$build = x$host; then
2003         # Single tree build which includes binutils.
2004         gcc_cv_objdump=../binutils/objdump$build_exeext
2005 elif test -x objdump$build_exeext; then
2006         gcc_cv_objdump=./objdump$build_exeext
2007 elif test -x $OBJDUMP_FOR_TARGET; then
2008         gcc_cv_objdump="$OBJDUMP_FOR_TARGET"
2009 else
2010         AC_PATH_PROG(gcc_cv_objdump, $OBJDUMP_FOR_TARGET)
2011 fi])
2012
2013 AC_MSG_CHECKING(what objdump to use)
2014 if test "$gcc_cv_objdump" = ../binutils/objdump$build_exeext; then
2015         # Single tree build which includes binutils.
2016         AC_MSG_RESULT(newly built objdump)
2017 elif test x$gcc_cv_objdump = x; then
2018         AC_MSG_RESULT(not found)
2019 else
2020         AC_MSG_RESULT($gcc_cv_objdump)
2021 fi
2022
2023 # Figure out what readelf we will be using.
2024 AS_VAR_SET_IF(gcc_cv_readelf,, [
2025 if test -f $gcc_cv_binutils_srcdir/configure.in \
2026      && test -f ../binutils/Makefile \
2027      && test x$build = x$host; then
2028         # Single tree build which includes binutils.
2029         gcc_cv_readelf=../binutils/readelf$build_exeext
2030 elif test -x readelf$build_exeext; then
2031         gcc_cv_readelf=./readelf$build_exeext
2032 else
2033         AC_PATH_PROG(gcc_cv_readelf, readelf)
2034 fi])
2035
2036 AC_MSG_CHECKING(what readelf to use)
2037 if test "$gcc_cv_readelf" = ../binutils/readelf$build_exeext; then
2038         # Single tree build which includes binutils.
2039         AC_MSG_RESULT(newly built readelf)
2040 elif test x$gcc_cv_readelf = x; then
2041         AC_MSG_RESULT(not found)
2042 else
2043         AC_MSG_RESULT($gcc_cv_readelf)
2044 fi
2045
2046 # Figure out what assembler alignment features are present.
2047 gcc_GAS_CHECK_FEATURE([.balign and .p2align], gcc_cv_as_balign_and_p2align,
2048  [2,6,0],,
2049 [.balign 4
2050 .p2align 2],,
2051 [AC_DEFINE(HAVE_GAS_BALIGN_AND_P2ALIGN, 1,
2052   [Define if your assembler supports .balign and .p2align.])])
2053
2054 gcc_GAS_CHECK_FEATURE([.p2align with maximum skip], gcc_cv_as_max_skip_p2align,
2055  [2,8,0],,
2056  [.p2align 4,,7],,
2057 [AC_DEFINE(HAVE_GAS_MAX_SKIP_P2ALIGN, 1,
2058   [Define if your assembler supports specifying the maximum number
2059    of bytes to skip when using the GAS .p2align command.])])
2060
2061 gcc_GAS_CHECK_FEATURE([.literal16], gcc_cv_as_literal16,
2062  [2,8,0],,
2063  [.literal16],,
2064 [AC_DEFINE(HAVE_GAS_LITERAL16, 1,
2065   [Define if your assembler supports .literal16.])])
2066
2067 gcc_GAS_CHECK_FEATURE([working .subsection -1], gcc_cv_as_subsection_m1,
2068  [elf,2,9,0],,
2069  [conftest_label1: .word 0
2070 .subsection -1
2071 conftest_label2: .word 0
2072 .previous],
2073  [if test x$gcc_cv_nm != x; then
2074     $gcc_cv_nm conftest.o | grep conftest_label1 > conftest.nm1
2075     $gcc_cv_nm conftest.o | grep conftest_label2 | sed -e 's/label2/label1/' > conftest.nm2
2076     if cmp conftest.nm1 conftest.nm2 > /dev/null 2>&1
2077     then :
2078     else gcc_cv_as_subsection_m1=yes
2079     fi
2080     rm -f conftest.nm1 conftest.nm2
2081   fi],
2082  [AC_DEFINE(HAVE_GAS_SUBSECTION_ORDERING, 1,
2083   [Define if your assembler supports .subsection and .subsection -1 starts
2084    emitting at the beginning of your section.])])
2085
2086 gcc_GAS_CHECK_FEATURE([.weak], gcc_cv_as_weak,
2087  [2,2,0],,
2088  [      .weak foobar],,
2089 [AC_DEFINE(HAVE_GAS_WEAK, 1, [Define if your assembler supports .weak.])])
2090
2091 gcc_GAS_CHECK_FEATURE([.weakref], gcc_cv_as_weakref,
2092  [2,17,0],,
2093  [      .weakref foobar, barfnot],,
2094 [AC_DEFINE(HAVE_GAS_WEAKREF, 1, [Define if your assembler supports .weakref.])])
2095
2096 gcc_GAS_CHECK_FEATURE([.nsubspa comdat], gcc_cv_as_nsubspa_comdat,
2097  [2,15,91],,
2098  [      .SPACE $TEXT$
2099         .NSUBSPA $CODE$,COMDAT],,
2100 [AC_DEFINE(HAVE_GAS_NSUBSPA_COMDAT, 1, [Define if your assembler supports .nsubspa comdat option.])])
2101
2102 # .hidden needs to be supported in both the assembler and the linker,
2103 # because GNU LD versions before 2.12.1 have buggy support for STV_HIDDEN.
2104 # This is irritatingly difficult to feature test for; we have to check the
2105 # date string after the version number.  If we've got an in-tree
2106 # ld, we don't know its patchlevel version, so we set the baseline at 2.13
2107 # to be safe.
2108 # The gcc_GAS_CHECK_FEATURE call just sets a cache variable.
2109 gcc_GAS_CHECK_FEATURE([.hidden], gcc_cv_as_hidden,
2110  [elf,2,13,0],,
2111 [       .hidden foobar
2112 foobar:])
2113
2114 AC_CACHE_CHECK(linker for .hidden support, gcc_cv_ld_hidden,
2115 [if test $in_tree_ld = yes ; then
2116   gcc_cv_ld_hidden=no
2117   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 13 -o "$gcc_cv_gld_major_version" -gt 2 \
2118      && test $in_tree_ld_is_elf = yes; then
2119      gcc_cv_ld_hidden=yes
2120   fi
2121 else
2122 changequote(,)dnl
2123   gcc_cv_ld_hidden=yes
2124   ld_ver=`$gcc_cv_ld --version 2>/dev/null | sed 1q`
2125   if echo "$ld_ver" | grep GNU > /dev/null; then
2126     ld_vers=`echo $ld_ver | sed -n \
2127         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*.*\)$,\1,p'`
2128     ld_date=`echo $ld_ver | sed -n 's,^.*\([2-9][0-9][0-9][0-9]\)[-]*\([01][0-9]\)[-]*\([0-3][0-9]\).*$,\1\2\3,p'`
2129     ld_vers_major=`expr "$ld_vers" : '\([0-9]*\)'`
2130     ld_vers_minor=`expr "$ld_vers" : '[0-9]*\.\([0-9]*\)'`
2131     ld_vers_patch=`expr "$ld_vers" : '[0-9]*\.[0-9]*\.\([0-9]*\)'`
2132     if test 0"$ld_date" -lt 20020404; then
2133       if test -n "$ld_date"; then
2134         # If there was date string, but was earlier than 2002-04-04, fail
2135         gcc_cv_ld_hidden=no
2136       elif test -z "$ld_vers"; then
2137         # If there was no date string nor ld version number, something is wrong
2138         gcc_cv_ld_hidden=no
2139       else
2140         test -z "$ld_vers_patch" && ld_vers_patch=0
2141         if test "$ld_vers_major" -lt 2; then
2142           gcc_cv_ld_hidden=no
2143         elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -lt 12; then
2144           gcc_cv_ld_hidden="no"
2145         elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -eq 12 -a "$ld_vers_patch" -eq 0; then
2146           gcc_cv_ld_hidden=no
2147         fi
2148       fi
2149     fi
2150   else
2151     case "${target}" in
2152       hppa64*-*-hpux* | ia64*-*-hpux*)
2153         gcc_cv_ld_hidden=yes
2154         ;;
2155       *-*-solaris2.9* | *-*-solaris2.1[0-9]*)
2156         gcc_cv_ld_hidden=yes
2157         ;;
2158       *)
2159         gcc_cv_ld_hidden=no
2160         ;;
2161     esac
2162   fi
2163 changequote([,])dnl
2164 fi])
2165 libgcc_visibility=no
2166 AC_SUBST(libgcc_visibility)
2167 GCC_TARGET_TEMPLATE([HAVE_GAS_HIDDEN])
2168 if test $gcc_cv_as_hidden = yes && test $gcc_cv_ld_hidden = yes; then
2169   libgcc_visibility=yes
2170   AC_DEFINE(HAVE_GAS_HIDDEN, 1,
2171   [Define if your assembler and linker support .hidden.])
2172 fi
2173
2174 AC_MSG_CHECKING(linker read-only and read-write section mixing)
2175 gcc_cv_ld_ro_rw_mix=unknown
2176 if test $in_tree_ld = yes ; then
2177   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 10 -o "$gcc_cv_gld_major_version" -gt 2 \
2178      && test $in_tree_ld_is_elf = yes; then
2179     gcc_cv_ld_ro_rw_mix=read-write
2180   fi
2181 elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x -a x$gcc_cv_objdump != x ; then
2182   echo '.section myfoosect, "a"' > conftest1.s
2183   echo '.section myfoosect, "aw"' > conftest2.s
2184   echo '.byte 1' >> conftest2.s
2185   echo '.section myfoosect, "a"' > conftest3.s
2186   echo '.byte 0' >> conftest3.s
2187   if $gcc_cv_as -o conftest1.o conftest1.s > /dev/null 2>&1 \
2188      && $gcc_cv_as -o conftest2.o conftest2.s > /dev/null 2>&1 \
2189      && $gcc_cv_as -o conftest3.o conftest3.s > /dev/null 2>&1 \
2190      && $gcc_cv_ld -shared -o conftest1.so conftest1.o \
2191         conftest2.o conftest3.o > /dev/null 2>&1; then
2192     gcc_cv_ld_ro_rw_mix=`$gcc_cv_objdump -h conftest1.so \
2193                          | sed -e '/myfoosect/!d' -e N`
2194     if echo "$gcc_cv_ld_ro_rw_mix" | grep CONTENTS > /dev/null; then
2195       if echo "$gcc_cv_ld_ro_rw_mix" | grep READONLY > /dev/null; then
2196         gcc_cv_ld_ro_rw_mix=read-only
2197       else
2198         gcc_cv_ld_ro_rw_mix=read-write
2199       fi
2200     fi
2201   fi
2202 changequote(,)dnl
2203   rm -f conftest.* conftest[123].*
2204 changequote([,])dnl
2205 fi
2206 if test x$gcc_cv_ld_ro_rw_mix = xread-write; then
2207         AC_DEFINE(HAVE_LD_RO_RW_SECTION_MIXING, 1,
2208   [Define if your linker links a mix of read-only
2209    and read-write sections into a read-write section.])
2210 fi
2211 AC_MSG_RESULT($gcc_cv_ld_ro_rw_mix)
2212
2213 # Check if we have .[us]leb128, and support symbol arithmetic with it.
2214 gcc_GAS_CHECK_FEATURE([.sleb128 and .uleb128], gcc_cv_as_leb128,
2215   [elf,2,11,0],,
2216 [       .data
2217         .uleb128 L2 - L1
2218 L1:
2219         .uleb128 1280
2220         .sleb128 -1010
2221 L2:],
2222  [# GAS versions before 2.11 do not support uleb128,
2223   # despite appearing to.
2224   # ??? There exists an elf-specific test that will crash
2225   # the assembler.  Perhaps it's better to figure out whether
2226   # arbitrary sections are supported and try the test.
2227   as_ver=`$gcc_cv_as --version 2>/dev/null | sed 1q`
2228   if echo "$as_ver" | grep GNU > /dev/null; then
2229 changequote(,)dnl
2230     as_vers=`echo $as_ver | sed -n \
2231         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*.*\)$,\1,p'`
2232     as_major=`expr "$as_vers" : '\([0-9]*\)'`
2233     as_minor=`expr "$as_vers" : '[0-9]*\.\([0-9]*\)'`
2234 changequote([,])dnl
2235     if test $as_major -eq 2 && test $as_minor -lt 11
2236     then :
2237     else gcc_cv_as_leb128=yes
2238     fi
2239   fi],
2240   [AC_DEFINE(HAVE_AS_LEB128, 1,
2241     [Define if your assembler supports .sleb128 and .uleb128.])])
2242
2243 # Check if we have assembler support for unwind directives.
2244 gcc_GAS_CHECK_FEATURE([cfi directives], gcc_cv_as_cfi_directive,
2245   ,,
2246 [       .text
2247         .cfi_startproc
2248         .cfi_offset 0, 0
2249         .cfi_same_value 1
2250         .cfi_def_cfa 1, 2
2251         .cfi_escape 1, 2, 3, 4, 5
2252         .cfi_endproc],
2253 [case "$target" in
2254   *-*-solaris*)
2255     # If the linker used on Solaris (like Sun ld) isn't capable of merging
2256     # read-only and read-write sections, we need to make sure that the
2257     # assembler used emits read-write .eh_frame sections.
2258     if test "x$gcc_cv_ld_ro_rw_mix" != xread-write; then
2259       if test "x$gcc_cv_objdump" != x; then
2260         if $gcc_cv_objdump -h conftest.o 2>/dev/null | \
2261                 sed -e /.eh_frame/!d -e N | grep READONLY > /dev/null; then
2262           gcc_cv_as_cfi_directive=no
2263         else
2264           gcc_cv_as_cfi_directive=yes
2265         fi
2266       else
2267         # no objdump, err on the side of caution
2268         gcc_cv_as_cfi_directive=no
2269       fi
2270     else
2271       gcc_cv_as_cfi_directive=yes
2272     fi
2273     ;;
2274   *-*-*)
2275     gcc_cv_as_cfi_directive=yes
2276     ;;
2277 esac])
2278 if test $gcc_cv_as_cfi_directive = yes && test x$gcc_cv_readelf != x; then
2279 gcc_GAS_CHECK_FEATURE([working cfi advance], gcc_cv_as_cfi_advance_working,
2280   ,,
2281 [       .text
2282         .cfi_startproc
2283         .cfi_adjust_cfa_offset 64
2284         .skip 512, 0
2285         .cfi_adjust_cfa_offset 128
2286         .cfi_endproc],
2287 [
2288 changequote(,)dnl
2289 if $gcc_cv_readelf -wf conftest.o 2>/dev/null \
2290     | grep 'DW_CFA_advance_loc[12]:[    ][      ]*512[  ]' >/dev/null; then
2291    gcc_cv_as_cfi_advance_working=yes
2292 fi
2293 changequote([,])dnl
2294 ])
2295 else
2296   # no readelf, err on the side of caution
2297   gcc_cv_as_cfi_advance_working=no
2298 fi
2299 AC_DEFINE_UNQUOTED(HAVE_GAS_CFI_DIRECTIVE,
2300   [`if test $gcc_cv_as_cfi_directive = yes \
2301        && test $gcc_cv_as_cfi_advance_working = yes; then echo 1; else echo 0; fi`],
2302   [Define 0/1 if your assembler supports CFI directives.])
2303
2304 gcc_GAS_CHECK_FEATURE([cfi personality directive],
2305   gcc_cv_as_cfi_personality_directive, ,,
2306 [       .text
2307         .cfi_startproc
2308         .cfi_personality 0, symbol
2309         .cfi_endproc])
2310 AC_DEFINE_UNQUOTED(HAVE_GAS_CFI_PERSONALITY_DIRECTIVE,
2311   [`if test $gcc_cv_as_cfi_personality_directive = yes;
2312     then echo 1; else echo 0; fi`],
2313   [Define 0/1 if your assembler supports .cfi_personality.])
2314
2315 gcc_GAS_CHECK_FEATURE([cfi sections directive],
2316   gcc_cv_as_cfi_sections_directive, ,,
2317 [       .text
2318         .cfi_sections .debug_frame, .eh_frame
2319         .cfi_startproc
2320         .cfi_endproc])
2321 AC_DEFINE_UNQUOTED(HAVE_GAS_CFI_SECTIONS_DIRECTIVE,
2322   [`if test $gcc_cv_as_cfi_sections_directive = yes;
2323     then echo 1; else echo 0; fi`],
2324   [Define 0/1 if your assembler supports .cfi_sections.])
2325
2326 # GAS versions up to and including 2.11.0 may mis-optimize
2327 # .eh_frame data.
2328 gcc_GAS_CHECK_FEATURE(eh_frame optimization, gcc_cv_as_eh_frame,
2329   [elf,2,12,0],,
2330 [       .text
2331 .LFB1:
2332         .4byte  0
2333 .L1:
2334         .4byte  0
2335 .LFE1:
2336         .section        .eh_frame,"aw",@progbits
2337 __FRAME_BEGIN__:
2338         .4byte  .LECIE1-.LSCIE1
2339 .LSCIE1:
2340         .4byte  0x0
2341         .byte   0x1
2342         .ascii "z\0"
2343         .byte   0x1
2344         .byte   0x78
2345         .byte   0x1a
2346         .byte   0x0
2347         .byte   0x4
2348         .4byte  1
2349         .p2align 1
2350 .LECIE1:
2351 .LSFDE1:
2352         .4byte  .LEFDE1-.LASFDE1
2353 .LASFDE1:
2354         .4byte  .LASFDE1-__FRAME_BEGIN__
2355         .4byte  .LFB1
2356         .4byte  .LFE1-.LFB1
2357         .byte   0x4
2358         .4byte  .LFE1-.LFB1
2359         .byte   0x4
2360         .4byte  .L1-.LFB1
2361 .LEFDE1:],
2362 [  dnl # For autoconf 2.5x, must protect trailing spaces with @&t@.
2363 cat > conftest.lit <<EOF
2364  0000 10000000 00000000 017a0001 781a0004  .........z..x...
2365  0010 01000000 12000000 18000000 00000000  ................
2366  0020 08000000 04080000 0044               .........D      @&t@
2367 EOF
2368 cat > conftest.big <<EOF
2369  0000 00000010 00000000 017a0001 781a0004  .........z..x...
2370  0010 00000001 00000012 00000018 00000000  ................
2371  0020 00000008 04000000 0844               .........D      @&t@
2372 EOF
2373   # If the assembler didn't choke, and we can objdump,
2374   # and we got the correct data, then succeed.
2375   # The text in the here-document typically retains its unix-style line
2376   # endings, while the output of objdump will use host line endings.
2377   # Therefore, use diff -b for the comparisons.
2378   if test x$gcc_cv_objdump != x \
2379   && $gcc_cv_objdump -s -j .eh_frame conftest.o 2>/dev/null \
2380      | tail -3 > conftest.got \
2381   && { diff -b conftest.lit conftest.got > /dev/null 2>&1 \
2382     || diff -b conftest.big conftest.got > /dev/null 2>&1; }
2383   then
2384     gcc_cv_as_eh_frame=yes
2385   elif AC_TRY_COMMAND($gcc_cv_as -o conftest.o --traditional-format /dev/null); then
2386     gcc_cv_as_eh_frame=buggy
2387   else
2388     # Uh oh, what do we do now?
2389     gcc_cv_as_eh_frame=no
2390   fi])
2391
2392 if test $gcc_cv_as_eh_frame = buggy; then
2393   AC_DEFINE(USE_AS_TRADITIONAL_FORMAT, 1,
2394   [Define if your assembler mis-optimizes .eh_frame data.])
2395 fi
2396
2397 gcc_GAS_CHECK_FEATURE(section merging support, gcc_cv_as_shf_merge,
2398  [elf,2,12,0], [--fatal-warnings],
2399  [.section .rodata.str, "aMS", @progbits, 1])
2400 if test $gcc_cv_as_shf_merge = no; then
2401   gcc_GAS_CHECK_FEATURE(section merging support, gcc_cv_as_shf_merge,
2402     [elf,2,12,0], [--fatal-warnings],
2403     [.section .rodata.str, "aMS", %progbits, 1])
2404 fi
2405 AC_DEFINE_UNQUOTED(HAVE_GAS_SHF_MERGE,
2406   [`if test $gcc_cv_as_shf_merge = yes; then echo 1; else echo 0; fi`],
2407 [Define 0/1 if your assembler supports marking sections with SHF_MERGE flag.])
2408
2409 gcc_GAS_CHECK_FEATURE(COMDAT group support, gcc_cv_as_comdat_group,
2410  [elf,2,16,0], [--fatal-warnings],
2411  [.section .text,"axG",@progbits,.foo,comdat])
2412 if test $gcc_cv_as_comdat_group = yes; then
2413   gcc_cv_as_comdat_group_percent=no
2414 else
2415  gcc_GAS_CHECK_FEATURE(COMDAT group support, gcc_cv_as_comdat_group_percent,
2416    [elf,2,16,0], [--fatal-warnings],
2417    [.section .text,"axG",%progbits,.foo,comdat])
2418 fi
2419 if test $in_tree_ld = yes ; then
2420   comdat_group=no
2421   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2 \
2422      && test $in_tree_ld_is_elf = yes; then
2423      comdat_group=yes
2424   fi
2425 elif test x"$ld_vers" != x; then
2426   comdat_group=yes
2427   if test 0"$ld_date" -lt 20050308; then
2428     if test -n "$ld_date"; then
2429       # If there was date string, but was earlier than 2005-03-08, fail
2430       comdat_group=no
2431     elif test "$ld_vers_major" -lt 2; then
2432       comdat_group=no
2433     elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -lt 16; then
2434       comdat_group=no
2435     fi
2436   fi
2437 else
2438   # assume linkers other than GNU ld don't support COMDAT group
2439   comdat_group=no
2440 fi
2441 if test $comdat_group = no; then
2442   gcc_cv_as_comdat_group=no
2443   gcc_cv_as_comdat_group_percent=no
2444 fi
2445 AC_DEFINE_UNQUOTED(HAVE_COMDAT_GROUP,
2446   [`if test $gcc_cv_as_comdat_group = yes || test $gcc_cv_as_comdat_group_percent = yes; then echo 1; else echo 0; fi`],
2447 [Define 0/1 if your assembler and linker support COMDAT groups.])
2448
2449 gcc_GAS_CHECK_FEATURE([line table discriminator support],
2450  gcc_cv_as_discriminator,
2451  [2,19,51],,
2452 [       .text
2453         .file 1 "conf.c"
2454         .loc 1 1 0 discriminator 1],,
2455 [AC_DEFINE(HAVE_GAS_DISCRIMINATOR, 1,
2456   [Define if your assembler supports the .loc discriminator sub-directive.])])
2457
2458 # Thread-local storage - the check is heavily parameterized.
2459 conftest_s=
2460 tls_first_major=
2461 tls_first_minor=
2462 tls_as_opt=
2463 case "$target" in
2464 changequote(,)dnl
2465   alpha*-*-*)
2466     conftest_s='
2467         .section ".tdata","awT",@progbits
2468 foo:    .long   25
2469         .text
2470         ldq     $27,__tls_get_addr($29)         !literal!1
2471         lda     $16,foo($29)                    !tlsgd!1
2472         jsr     $26,($27),__tls_get_addr        !lituse_tlsgd!1
2473         ldq     $27,__tls_get_addr($29)         !literal!2
2474         lda     $16,foo($29)                    !tlsldm!2
2475         jsr     $26,($27),__tls_get_addr        !lituse_tlsldm!2
2476         ldq     $1,foo($29)                     !gotdtprel
2477         ldah    $2,foo($29)                     !dtprelhi
2478         lda     $3,foo($2)                      !dtprello
2479         lda     $4,foo($29)                     !dtprel
2480         ldq     $1,foo($29)                     !gottprel
2481         ldah    $2,foo($29)                     !tprelhi
2482         lda     $3,foo($2)                      !tprello
2483         lda     $4,foo($29)                     !tprel'
2484         tls_first_major=2
2485         tls_first_minor=13
2486         tls_as_opt=--fatal-warnings
2487         ;;
2488   cris-*-*|crisv32-*-*)
2489     conftest_s='
2490         .section ".tdata","awT",@progbits
2491 x:      .long   25
2492         .text
2493         move.d x:IE,$r10
2494         nop'
2495         tls_first_major=2
2496         tls_first_minor=20
2497         tls_as_opt=--fatal-warnings
2498         ;;
2499   frv*-*-*)
2500     conftest_s='
2501         .section ".tdata","awT",@progbits
2502 x:      .long   25
2503         .text
2504         call    #gettlsoff(x)'
2505         tls_first_major=2
2506         tls_first_minor=14
2507         ;;
2508   hppa*-*-linux*)
2509     conftest_s='
2510 t1:     .reg    %r20
2511 t2:     .reg    %r21
2512 gp:     .reg    %r19
2513         .section ".tdata","awT",@progbits
2514 foo:    .long   25
2515         .text
2516         .align  4
2517         addil LT%foo-$tls_gdidx$,gp
2518         ldo RT%foo-$tls_gdidx$(%r1),%arg0
2519         b __tls_get_addr
2520         nop
2521         addil LT%foo-$tls_ldidx$,gp
2522         b __tls_get_addr
2523         ldo RT%foo-$tls_ldidx$(%r1),%arg0
2524         addil LR%foo-$tls_dtpoff$,%ret0
2525         ldo RR%foo-$tls_dtpoff$(%r1),%t1
2526         mfctl %cr27,%t1
2527         addil LT%foo-$tls_ieoff$,gp
2528         ldw RT%foo-$tls_ieoff$(%r1),%t2
2529         add %t1,%t2,%t3
2530         mfctl %cr27,%t1
2531         addil LR%foo-$tls_leoff$,%t1
2532         ldo RR%foo-$tls_leoff$(%r1),%t2'
2533         tls_first_major=2
2534         tls_first_minor=15
2535         tls_as_opt=--fatal-warnings
2536         ;;
2537   arm*-*-*)
2538     conftest_s='
2539         .section ".tdata","awT",%progbits
2540 foo:    .long   25
2541         .text
2542 .word foo(gottpoff)
2543 .word foo(tpoff)
2544 .word foo(tlsgd)
2545 .word foo(tlsldm)
2546 .word foo(tlsldo)'
2547         tls_first_major=2
2548         tls_first_minor=17
2549         ;;
2550   i[34567]86-*-*)
2551     conftest_s='
2552         .section ".tdata","awT",@progbits
2553 foo:    .long   25
2554         .text
2555         movl    %gs:0, %eax
2556         leal    foo@TLSGD(,%ebx,1), %eax
2557         leal    foo@TLSLDM(%ebx), %eax
2558         leal    foo@DTPOFF(%eax), %edx
2559         movl    foo@GOTTPOFF(%ebx), %eax
2560         subl    foo@GOTTPOFF(%ebx), %eax
2561         addl    foo@GOTNTPOFF(%ebx), %eax
2562         movl    foo@INDNTPOFF, %eax
2563         movl    $foo@TPOFF, %eax
2564         subl    $foo@TPOFF, %eax
2565         leal    foo@NTPOFF(%ecx), %eax'
2566         tls_first_major=2
2567         tls_first_minor=14
2568         tls_as_opt=--fatal-warnings
2569         ;;
2570   x86_64-*-*)
2571     conftest_s='
2572         .section ".tdata","awT",@progbits
2573 foo:    .long   25
2574         .text
2575         movq    %fs:0, %rax
2576         leaq    foo@TLSGD(%rip), %rdi
2577         leaq    foo@TLSLD(%rip), %rdi
2578         leaq    foo@DTPOFF(%rax), %rdx
2579         movq    foo@GOTTPOFF(%rip), %rax
2580         movq    $foo@TPOFF, %rax'
2581         tls_first_major=2
2582         tls_first_minor=14
2583         tls_as_opt=--fatal-warnings
2584         ;;
2585   ia64-*-*)
2586     conftest_s='
2587         .section ".tdata","awT",@progbits
2588 foo:    data8   25
2589         .text
2590         addl    r16 = @ltoff(@dtpmod(foo#)), gp
2591         addl    r17 = @ltoff(@dtprel(foo#)), gp
2592         addl    r18 = @ltoff(@tprel(foo#)), gp
2593         addl    r19 = @dtprel(foo#), gp
2594         adds    r21 = @dtprel(foo#), r13
2595         movl    r23 = @dtprel(foo#)
2596         addl    r20 = @tprel(foo#), gp
2597         adds    r22 = @tprel(foo#), r13
2598         movl    r24 = @tprel(foo#)'
2599         tls_first_major=2
2600         tls_first_minor=13
2601         tls_as_opt=--fatal-warnings
2602         ;;
2603   mips*-*-*)
2604     conftest_s='
2605         .section .tdata,"awT",@progbits
2606 x:
2607         .word 2
2608         .text
2609         addiu $4, $28, %tlsgd(x)
2610         addiu $4, $28, %tlsldm(x)
2611         lui $4, %dtprel_hi(x)
2612         addiu $4, $4, %dtprel_lo(x)
2613         lw $4, %gottprel(x)($28)
2614         lui $4, %tprel_hi(x)
2615         addiu $4, $4, %tprel_lo(x)'
2616         tls_first_major=2
2617         tls_first_minor=16
2618         tls_as_opt='-32 --fatal-warnings'
2619         ;;
2620   m68k-*-*)
2621     conftest_s='
2622         .section .tdata,"awT",@progbits
2623 x:
2624         .word 2
2625         .text
2626 foo:
2627         move.l x@TLSGD(%a5),%a0
2628         move.l x@TLSLDM(%a5),%a0
2629         move.l x@TLSLDO(%a5),%a0
2630         move.l x@TLSIE(%a5),%a0
2631         move.l x@TLSLE(%a5),%a0'
2632         tls_first_major=2
2633         tls_first_minor=19
2634         tls_as_opt='--fatal-warnings'
2635         ;;
2636   powerpc-*-*)
2637     conftest_s='
2638         .section ".tdata","awT",@progbits
2639         .align 2
2640 ld0:    .space 4
2641 ld1:    .space 4
2642 x1:     .space 4
2643 x2:     .space 4
2644 x3:     .space 4
2645         .text
2646         addi 3,31,ld0@got@tlsgd
2647         bl __tls_get_addr
2648         addi 3,31,x1@got@tlsld
2649         bl __tls_get_addr
2650         addi 9,3,x1@dtprel
2651         addis 9,3,x2@dtprel@ha
2652         addi 9,9,x2@dtprel@l
2653         lwz 9,x3@got@tprel(31)
2654         add 9,9,x@tls
2655         addi 9,2,x1@tprel
2656         addis 9,2,x2@tprel@ha
2657         addi 9,9,x2@tprel@l'
2658         tls_first_major=2
2659         tls_first_minor=14
2660         tls_as_opt="-a32 --fatal-warnings"
2661         ;;
2662   powerpc64-*-*)
2663     conftest_s='
2664         .section ".tdata","awT",@progbits
2665         .align 3
2666 ld0:    .space 8
2667 ld1:    .space 8
2668 x1:     .space 8
2669 x2:     .space 8
2670 x3:     .space 8
2671         .text
2672         addi 3,2,ld0@got@tlsgd
2673         bl .__tls_get_addr
2674         nop
2675         addi 3,2,ld1@toc
2676         bl .__tls_get_addr
2677         nop
2678         addi 3,2,x1@got@tlsld
2679         bl .__tls_get_addr
2680         nop
2681         addi 9,3,x1@dtprel
2682         bl .__tls_get_addr
2683         nop
2684         addis 9,3,x2@dtprel@ha
2685         addi 9,9,x2@dtprel@l
2686         bl .__tls_get_addr
2687         nop
2688         ld 9,x3@got@dtprel(2)
2689         add 9,9,3
2690         bl .__tls_get_addr
2691         nop'
2692         tls_first_major=2
2693         tls_first_minor=14
2694         tls_as_opt="-a64 --fatal-warnings"
2695         ;;
2696   s390-*-*)
2697     conftest_s='
2698         .section ".tdata","awT",@progbits
2699 foo:    .long   25
2700         .text
2701         .long   foo@TLSGD
2702         .long   foo@TLSLDM
2703         .long   foo@DTPOFF
2704         .long   foo@NTPOFF
2705         .long   foo@GOTNTPOFF
2706         .long   foo@INDNTPOFF
2707         l       %r1,foo@GOTNTPOFF(%r12)
2708         l       %r1,0(%r1):tls_load:foo
2709         bas     %r14,0(%r1,%r13):tls_gdcall:foo
2710         bas     %r14,0(%r1,%r13):tls_ldcall:foo'
2711         tls_first_major=2
2712         tls_first_minor=14
2713         tls_as_opt="-m31 --fatal-warnings"
2714         ;;
2715   s390x-*-*)
2716     conftest_s='
2717         .section ".tdata","awT",@progbits
2718 foo:    .long   25
2719         .text
2720         .quad   foo@TLSGD
2721         .quad   foo@TLSLDM
2722         .quad   foo@DTPOFF
2723         .quad   foo@NTPOFF
2724         .quad   foo@GOTNTPOFF
2725         lg      %r1,foo@GOTNTPOFF(%r12)
2726         larl    %r1,foo@INDNTPOFF
2727         brasl   %r14,__tls_get_offset@PLT:tls_gdcall:foo
2728         brasl   %r14,__tls_get_offset@PLT:tls_ldcall:foo'
2729         tls_first_major=2
2730         tls_first_minor=14
2731         tls_as_opt="-m64 -Aesame --fatal-warnings"
2732         ;;
2733   sh-*-* | sh[34]-*-*)
2734     conftest_s='
2735         .section ".tdata","awT",@progbits
2736 foo:    .long   25
2737         .text
2738         .long   foo@TLSGD
2739         .long   foo@TLSLDM
2740         .long   foo@DTPOFF
2741         .long   foo@GOTTPOFF
2742         .long   foo@TPOFF'
2743         tls_first_major=2
2744         tls_first_minor=13
2745         tls_as_opt=--fatal-warnings
2746         ;;
2747   sparc*-*-*)
2748     case "$target" in
2749       sparc*-sun-solaris2.[56789]*)
2750         # TLS was introduced in the Solaris 9 4/04 release but
2751         # we do not enable it by default on Solaris 9 either.
2752         if test "x$enable_tls" = xyes ; then
2753           on_solaris=yes
2754         else
2755           enable_tls=no;
2756         fi
2757         ;;
2758       sparc*-sun-solaris2.*)
2759         on_solaris=yes
2760         ;;
2761       *)
2762         on_solaris=no
2763         ;;
2764     esac
2765     if test x$on_solaris = xyes && test x$gas_flag = xno; then
2766       conftest_s='
2767         .section ".tdata",#alloc,#write,#tls
2768 foo:    .long   25
2769         .text
2770         sethi   %tgd_hi22(foo), %o0
2771         add     %o0, %tgd_lo10(foo), %o1
2772         add     %l7, %o1, %o0, %tgd_add(foo)
2773         call    __tls_get_addr, %tgd_call(foo)
2774         sethi   %tldm_hi22(foo), %l1
2775         add     %l1, %tldm_lo10(foo), %l2
2776         add     %l7, %l2, %o0, %tldm_add(foo)
2777         call    __tls_get_addr, %tldm_call(foo)
2778         sethi   %tldo_hix22(foo), %l3
2779         xor     %l3, %tldo_lox10(foo), %l4
2780         add     %o0, %l4, %l5, %tldo_add(foo)
2781         sethi   %tie_hi22(foo), %o3
2782         add     %o3, %tie_lo10(foo), %o3
2783         ld      [%l7 + %o3], %o2, %tie_ld(foo)
2784         add     %g7, %o2, %o4, %tie_add(foo)
2785         sethi   %tle_hix22(foo), %l1
2786         xor     %l1, %tle_lox10(foo), %o5
2787         ld      [%g7 + %o5], %o1'
2788         tls_first_major=0
2789         tls_first_minor=0
2790     else
2791       conftest_s='
2792         .section ".tdata","awT",@progbits
2793 foo:    .long   25
2794         .text
2795         sethi   %tgd_hi22(foo), %o0
2796         add     %o0, %tgd_lo10(foo), %o1
2797         add     %l7, %o1, %o0, %tgd_add(foo)
2798         call    __tls_get_addr, %tgd_call(foo)
2799         sethi   %tldm_hi22(foo), %l1
2800         add     %l1, %tldm_lo10(foo), %l2
2801         add     %l7, %l2, %o0, %tldm_add(foo)
2802         call    __tls_get_addr, %tldm_call(foo)
2803         sethi   %tldo_hix22(foo), %l3
2804         xor     %l3, %tldo_lox10(foo), %l4
2805         add     %o0, %l4, %l5, %tldo_add(foo)
2806         sethi   %tie_hi22(foo), %o3
2807         add     %o3, %tie_lo10(foo), %o3
2808         ld      [%l7 + %o3], %o2, %tie_ld(foo)
2809         add     %g7, %o2, %o4, %tie_add(foo)
2810         sethi   %tle_hix22(foo), %l1
2811         xor     %l1, %tle_lox10(foo), %o5
2812         ld      [%g7 + %o5], %o1'
2813         tls_first_major=2
2814         tls_first_minor=14
2815         tls_as_opt="-32 --fatal-warnings"
2816       fi
2817         ;;
2818   xtensa*-*-*)
2819     conftest_s='
2820         .section ".tdata","awT",@progbits
2821 foo:    .long   25
2822         .text
2823         movi    a8, foo@TLSFUNC
2824         movi    a10, foo@TLSARG
2825         callx8.tls a8, foo@TLSCALL'
2826         tls_first_major=2
2827         tls_first_minor=19
2828         ;;
2829 changequote([,])dnl
2830 esac
2831 set_have_as_tls=no
2832 if test "x$enable_tls" = xno ; then
2833   : # TLS explicitly disabled.
2834 elif test "x$enable_tls" = xyes ; then
2835   set_have_as_tls=yes # TLS explicitly enabled.
2836 elif test -z "$tls_first_major"; then
2837   : # If we don't have a check, assume no support.
2838 else
2839   gcc_GAS_CHECK_FEATURE(thread-local storage support, gcc_cv_as_tls,
2840   [$tls_first_major,$tls_first_minor,0], [$tls_as_opt], [$conftest_s],,
2841   [set_have_as_tls=yes])
2842 fi
2843 if test $set_have_as_tls = yes ; then
2844   AC_DEFINE(HAVE_AS_TLS, 1,
2845             [Define if your assembler supports thread-local storage.])
2846 fi
2847
2848 # Target-specific assembler checks.
2849
2850 AC_MSG_CHECKING(linker -Bstatic/-Bdynamic option)
2851 gcc_cv_ld_static_dynamic=no
2852 if test $in_tree_ld = yes ; then
2853   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 10 -o "$gcc_cv_gld_major_version" -gt 2; then
2854     gcc_cv_ld_static_dynamic=yes
2855   fi
2856 elif test x$gcc_cv_ld != x; then
2857         # Check if linker supports -Bstatic/-Bdynamic option
2858         if $gcc_cv_ld --help 2>/dev/null | grep -- -Bstatic > /dev/null \
2859           && $gcc_cv_ld --help 2>/dev/null | grep -- -Bdynamic > /dev/null; then
2860                 gcc_cv_ld_static_dynamic=yes
2861         fi
2862 fi
2863 if test x"$gcc_cv_ld_static_dynamic" = xyes; then
2864         AC_DEFINE(HAVE_LD_STATIC_DYNAMIC, 1,
2865 [Define if your linker supports -Bstatic/-Bdynamic option.])
2866 fi
2867 AC_MSG_RESULT($gcc_cv_ld_static_dynamic)
2868
2869 if test x"$demangler_in_ld" = xyes; then
2870   AC_MSG_CHECKING(linker --demangle support)
2871   gcc_cv_ld_demangle=no
2872   if test $in_tree_ld = yes; then
2873     if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 14 -o "$gcc_cv_gld_major_version" -gt 2; then \
2874       gcc_cv_ld_demangle=yes
2875     fi
2876   elif test x$gcc_cv_ld != x -a x"$gnu_ld" = xyes; then
2877     # Check if the GNU linker supports --demangle option
2878     if $gcc_cv_ld --help 2>/dev/null | grep no-demangle > /dev/null; then
2879       gcc_cv_ld_demangle=yes
2880     fi
2881   fi
2882   if test x"$gcc_cv_ld_demangle" = xyes; then
2883     AC_DEFINE(HAVE_LD_DEMANGLE, 1,
2884 [Define if your linker supports --demangle option.])
2885   fi
2886   AC_MSG_RESULT($gcc_cv_ld_demangle)
2887 fi
2888
2889 case "$target" in
2890   # All TARGET_ABI_OSF targets.
2891   alpha*-*-osf* | alpha*-*-linux* | alpha*-*-*bsd*)
2892     gcc_GAS_CHECK_FEATURE([explicit relocation support],
2893         gcc_cv_as_alpha_explicit_relocs, [2,12,0],,
2894 [       .set nomacro
2895         .text
2896         extbl   $3, $2, $3      !lituse_bytoff!1
2897         ldq     $2, a($29)      !literal!1
2898         ldq     $4, b($29)      !literal!2
2899         ldq_u   $3, 0($2)       !lituse_base!1
2900         ldq     $27, f($29)     !literal!5
2901         jsr     $26, ($27), f   !lituse_jsr!5
2902         ldah    $29, 0($26)     !gpdisp!3
2903         lda     $0, c($29)      !gprel
2904         ldah    $1, d($29)      !gprelhigh
2905         lda     $1, d($1)       !gprellow
2906         lda     $29, 0($29)     !gpdisp!3],,
2907     [AC_DEFINE(HAVE_AS_EXPLICIT_RELOCS, 1,
2908   [Define if your assembler supports explicit relocations.])])
2909     gcc_GAS_CHECK_FEATURE([jsrdirect relocation support],
2910         gcc_cv_as_alpha_jsrdirect_relocs, [2,16,90],,
2911 [       .set nomacro
2912         .text
2913         ldq     $27, a($29)     !literal!1
2914         jsr     $26, ($27), a   !lituse_jsrdirect!1],,
2915     [AC_DEFINE(HAVE_AS_JSRDIRECT_RELOCS, 1,
2916   [Define if your assembler supports the lituse_jsrdirect relocation.])])
2917     ;;
2918
2919   cris-*-*)
2920     gcc_GAS_CHECK_FEATURE([-no-mul-bug-abort option],
2921       gcc_cv_as_cris_no_mul_bug,[2,15,91],
2922       [-no-mul-bug-abort], [.text],,
2923       [AC_DEFINE(HAVE_AS_NO_MUL_BUG_ABORT_OPTION, 1,
2924                 [Define if your assembler supports the -no-mul-bug-abort option.])])
2925     ;;
2926
2927   sparc*-*-*)
2928     gcc_GAS_CHECK_FEATURE([.register], gcc_cv_as_sparc_register_op,,,
2929       [.register %g2, #scratch],,
2930       [AC_DEFINE(HAVE_AS_REGISTER_PSEUDO_OP, 1,
2931                 [Define if your assembler supports .register.])])
2932
2933     gcc_GAS_CHECK_FEATURE([-relax option], gcc_cv_as_sparc_relax,,
2934       [-relax], [.text],,
2935       [AC_DEFINE(HAVE_AS_RELAX_OPTION, 1,
2936                 [Define if your assembler supports -relax option.])])
2937
2938     gcc_GAS_CHECK_FEATURE([unaligned pcrel relocs],
2939       gcc_cv_as_sparc_ua_pcrel,,
2940       [-K PIC],
2941 [.text
2942 foo:
2943         nop
2944 .data
2945 .align 4
2946 .byte 0
2947 .uaword %r_disp32(foo)],
2948       [if test x$gcc_cv_ld != x \
2949        && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1; then
2950          gcc_cv_as_sparc_ua_pcrel=yes
2951        fi
2952        rm -f conftest],
2953       [AC_DEFINE(HAVE_AS_SPARC_UA_PCREL, 1,
2954                 [Define if your assembler and linker support unaligned PC relative relocs.])
2955
2956       gcc_GAS_CHECK_FEATURE([unaligned pcrel relocs against hidden symbols],
2957         gcc_cv_as_sparc_ua_pcrel_hidden,,
2958         [-K PIC],
2959 [.data
2960 .align 4
2961 .byte 0x31
2962 .uaword %r_disp32(foo)
2963 .byte 0x32, 0x33, 0x34
2964 .global foo
2965 .hidden foo
2966 foo:
2967 .skip 4],
2968         [if test x$gcc_cv_ld != x && test x$gcc_cv_objdump != x \
2969          && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1 \
2970          && $gcc_cv_objdump -s -j .data conftest 2> /dev/null \
2971             | grep ' 31000000 07323334' > /dev/null 2>&1; then
2972             if $gcc_cv_objdump -R conftest 2> /dev/null \
2973                | grep 'DISP32' > /dev/null 2>&1; then
2974                 :
2975             else
2976                 gcc_cv_as_sparc_ua_pcrel_hidden=yes
2977             fi
2978          fi
2979          rm -f conftest],
2980          [AC_DEFINE(HAVE_AS_SPARC_UA_PCREL_HIDDEN, 1,
2981                    [Define if your assembler and linker support unaligned PC relative relocs against hidden symbols.])])
2982     ]) # unaligned pcrel relocs
2983
2984     gcc_GAS_CHECK_FEATURE([offsetable %lo()],
2985       gcc_cv_as_sparc_offsetable_lo10,,
2986       [-xarch=v9],
2987 [.text
2988         or %g1, %lo(ab) + 12, %g1
2989         or %g1, %lo(ab + 12), %g1],
2990       [if test x$gcc_cv_objdump != x \
2991        && $gcc_cv_objdump -s -j .text conftest.o 2> /dev/null \
2992           | grep ' 82106000 82106000' > /dev/null 2>&1; then
2993          gcc_cv_as_sparc_offsetable_lo10=yes
2994        fi],
2995        [AC_DEFINE(HAVE_AS_OFFSETABLE_LO10, 1,
2996                  [Define if your assembler supports offsetable %lo().])])
2997     ;;
2998
2999 changequote(,)dnl
3000   i[34567]86-*-* | x86_64-*-*)
3001 changequote([,])dnl
3002     case $target_os in
3003       cygwin*)
3004         # Full C++ conformance when using a shared libstdc++-v3 requires some
3005         # support from the Cygwin DLL, which in more recent versions exports
3006         # wrappers to aid in interposing and redirecting operators new, delete,
3007         # etc., as per n2800 #17.6.4.6 [replacement.functions].  Check if we
3008         # are configuring for a version of Cygwin that exports the wrappers.
3009         if test x$host = x$target; then
3010           AC_CHECK_FUNC([__wrap__Znaj],[gcc_ac_cygwin_dll_wrappers=yes],[gcc_ac_cygwin_dll_wrappers=no])
3011         else
3012           # Can't check presence of libc functions during cross-compile, so
3013           # we just have to assume we're building for an up-to-date target.
3014           gcc_ac_cygwin_dll_wrappers=yes
3015         fi
3016         AC_DEFINE_UNQUOTED(USE_CYGWIN_LIBSTDCXX_WRAPPERS,
3017           [`if test $gcc_ac_cygwin_dll_wrappers = yes; then echo 1; else echo 0; fi`],
3018           [Define if you want to generate code by default that assumes that the
3019            Cygwin DLL exports wrappers to support libstdc++ function replacement.])
3020     esac
3021     case $target_os in
3022       cygwin* | pe | mingw32*)
3023         # Recent binutils allows the three-operand form of ".comm" on PE.  This
3024         # definition is used unconditionally to initialise the default state of
3025         # the target option variable that governs usage of the feature.
3026         gcc_GAS_CHECK_FEATURE([.comm with alignment], gcc_cv_as_comm_has_align,
3027          [2,19,52],,[.comm foo,1,32])
3028         AC_DEFINE_UNQUOTED(HAVE_GAS_ALIGNED_COMM,
3029           [`if test $gcc_cv_as_comm_has_align = yes; then echo 1; else echo 0; fi`],
3030           [Define if your assembler supports specifying the alignment
3031            of objects allocated using the GAS .comm command.])
3032         # Used for DWARF 2 in PE
3033         gcc_GAS_CHECK_FEATURE([.secrel32 relocs],
3034           gcc_cv_as_ix86_pe_secrel32,
3035           [2,15,91],,
3036 [.text
3037 foo:    nop
3038 .data
3039         .secrel32 foo],
3040           [if test x$gcc_cv_ld != x \
3041            && $gcc_cv_ld -o conftest conftest.o > /dev/null 2>&1; then
3042              gcc_cv_as_ix86_pe_secrel32=yes
3043            fi
3044            rm -f conftest],
3045           [AC_DEFINE(HAVE_GAS_PE_SECREL32_RELOC, 1,
3046             [Define if your assembler and linker support 32-bit section relative relocs via '.secrel32 label'.])])
3047         ;;
3048     esac
3049
3050     gcc_GAS_CHECK_FEATURE([filds and fists mnemonics],
3051        gcc_cv_as_ix86_filds,,,
3052        [filds mem; fists mem],,
3053        [AC_DEFINE(HAVE_AS_IX86_FILDS, 1,
3054          [Define if your assembler uses filds and fists mnemonics.])])
3055
3056     gcc_GAS_CHECK_FEATURE([fildq and fistpq mnemonics],
3057        gcc_cv_as_ix86_fildq,,,
3058        [fildq mem; fistpq mem],,
3059        [AC_DEFINE(HAVE_AS_IX86_FILDQ, 1,
3060          [Define if your assembler uses fildq and fistq mnemonics.])])
3061
3062     gcc_GAS_CHECK_FEATURE([cmov syntax],
3063       gcc_cv_as_ix86_cmov_sun_syntax,,,
3064       [cmovl.l %edx, %eax],,
3065       [AC_DEFINE(HAVE_AS_IX86_CMOV_SUN_SYNTAX, 1,
3066         [Define if your assembler supports the Sun syntax for cmov.])])
3067
3068     gcc_GAS_CHECK_FEATURE([ffreep mnemonic],
3069       gcc_cv_as_ix86_ffreep,,,
3070       [ffreep %st(1)],,
3071       [AC_DEFINE(HAVE_AS_IX86_FFREEP, 1,
3072         [Define if your assembler supports the ffreep mnemonic.])])
3073
3074     gcc_GAS_CHECK_FEATURE([sahf mnemonic],
3075       gcc_cv_as_ix86_sahf,,,
3076       [sahf],,
3077       [AC_DEFINE(HAVE_AS_IX86_SAHF, 1,
3078         [Define if your assembler supports the sahf mnemonic.])])
3079
3080     gcc_GAS_CHECK_FEATURE([swap suffix],
3081       gcc_cv_as_ix86_swap,,,
3082       [movl.s %esp, %ebp],,
3083       [AC_DEFINE(HAVE_AS_IX86_SWAP, 1,
3084         [Define if your assembler supports the swap suffix.])])
3085
3086     gcc_GAS_CHECK_FEATURE([different section symbol subtraction],
3087       gcc_cv_as_ix86_diff_sect_delta,,,
3088       [.section .rodata
3089 .L1:
3090         .long .L2-.L1
3091         .long .L3-.L1
3092         .text
3093 .L3:    nop
3094 .L2:    nop],,
3095       [AC_DEFINE(HAVE_AS_IX86_DIFF_SECT_DELTA, 1,
3096         [Define if your assembler supports the subtraction of symbols in different sections.])])
3097
3098     # This one is used unconditionally by i386.[ch]; it is to be defined
3099     # to 1 if the feature is present, 0 otherwise.
3100     gcc_GAS_CHECK_FEATURE([GOTOFF in data],
3101         gcc_cv_as_ix86_gotoff_in_data, [2,11,0],,
3102 [       .text
3103 .L0:
3104         nop
3105         .data
3106         .long .L0@GOTOFF])
3107     AC_DEFINE_UNQUOTED(HAVE_AS_GOTOFF_IN_DATA,
3108       [`if test $gcc_cv_as_ix86_gotoff_in_data = yes; then echo 1; else echo 0; fi`],
3109       [Define true if the assembler supports '.long foo@GOTOFF'.])
3110     ;;
3111
3112   ia64*-*-*)
3113     gcc_GAS_CHECK_FEATURE([ltoffx and ldxmov relocs],
3114         gcc_cv_as_ia64_ltoffx_ldxmov_relocs, [2,14,0],,
3115 [       .text
3116         addl r15 = @ltoffx(x#), gp
3117         ;;
3118         ld8.mov r16 = [[r15]], x#],,
3119     [AC_DEFINE(HAVE_AS_LTOFFX_LDXMOV_RELOCS, 1,
3120           [Define if your assembler supports ltoffx and ldxmov relocations.])])
3121
3122     ;;
3123
3124   powerpc*-*-*)
3125     case $target in
3126       *-*-aix*) conftest_s='    .machine "pwr5"
3127         .csect .text[[PR]]
3128         mfcr 3,128';;
3129       *-*-darwin*)
3130         gcc_GAS_CHECK_FEATURE([.machine directive support],
3131           gcc_cv_as_machine_directive,,,
3132           [     .machine ppc7400])
3133         if test x$gcc_cv_as_machine_directive != xyes; then
3134           echo "*** This target requires an assembler supporting \".machine\"" >&2
3135           echo you can get it from: ftp://gcc.gnu.org/pub/gcc/infrastructure/cctools-528.5.dmg >&2
3136           test x$build = x$target && exit 1
3137         fi
3138         conftest_s='    .text
3139         mfcr r3,128';;
3140       *) conftest_s='   .machine power4
3141         .text
3142         mfcr 3,128';;
3143     esac
3144
3145     gcc_GAS_CHECK_FEATURE([mfcr field support],
3146       gcc_cv_as_powerpc_mfcrf, [2,14,0],,
3147       [$conftest_s],,
3148       [AC_DEFINE(HAVE_AS_MFCRF, 1,
3149           [Define if your assembler supports mfcr field.])])
3150
3151     case $target in
3152       *-*-aix*) conftest_s='    .machine "pwr5"
3153         .csect .text[[PR]]
3154         popcntb 3,3';;
3155       *) conftest_s='   .machine power5
3156         .text
3157         popcntb 3,3';;
3158     esac
3159
3160     gcc_GAS_CHECK_FEATURE([popcntb support],
3161       gcc_cv_as_powerpc_popcntb, [2,17,0],,
3162       [$conftest_s],,
3163       [AC_DEFINE(HAVE_AS_POPCNTB, 1,
3164           [Define if your assembler supports popcntb field.])])
3165
3166     case $target in
3167       *-*-aix*) conftest_s='    .machine "pwr5x"
3168         .csect .text[[PR]]
3169         frin 1,1';;
3170       *) conftest_s='   .machine power5
3171         .text
3172         frin 1,1';;
3173     esac
3174
3175     gcc_GAS_CHECK_FEATURE([fp round support],
3176       gcc_cv_as_powerpc_fprnd, [2,17,0],,
3177       [$conftest_s],,
3178       [AC_DEFINE(HAVE_AS_FPRND, 1,
3179           [Define if your assembler supports fprnd.])])
3180
3181     case $target in
3182       *-*-aix*) conftest_s='    .machine "pwr6"
3183         .csect .text[[PR]]
3184         mffgpr 1,3';;
3185       *) conftest_s='   .machine power6
3186         .text
3187         mffgpr 1,3';;
3188     esac
3189
3190     gcc_GAS_CHECK_FEATURE([move fp gpr support],
3191       gcc_cv_as_powerpc_mfpgpr, [2,19,2],,
3192       [$conftest_s],,
3193       [AC_DEFINE(HAVE_AS_MFPGPR, 1,
3194           [Define if your assembler supports mffgpr and mftgpr.])])
3195
3196     case $target in
3197       *-*-aix*) conftest_s='    .csect .text[[PR]]
3198 LCF..0:
3199         addis 11,30,_GLOBAL_OFFSET_TABLE_-LCF..0@ha';;
3200       *-*-darwin*)
3201         conftest_s='    .text
3202 LCF0:
3203         addis r11,r30,_GLOBAL_OFFSET_TABLE_-LCF0@ha';;
3204       *) conftest_s='   .text
3205 .LCF0:
3206         addis 11,30,_GLOBAL_OFFSET_TABLE_-.LCF0@ha';;
3207     esac
3208
3209     gcc_GAS_CHECK_FEATURE([rel16 relocs],
3210       gcc_cv_as_powerpc_rel16, [2,17,0], -a32,
3211       [$conftest_s],,
3212       [AC_DEFINE(HAVE_AS_REL16, 1,
3213           [Define if your assembler supports R_PPC_REL16 relocs.])])
3214
3215     case $target in
3216       *-*-aix*) conftest_s='    .machine "pwr6"
3217         .csect .text[[PR]]
3218         cmpb 3,4,5';;
3219       *) conftest_s='   .machine power6
3220         .text
3221         cmpb 3,4,5';;
3222     esac
3223
3224     gcc_GAS_CHECK_FEATURE([compare bytes support],
3225       gcc_cv_as_powerpc_cmpb, [2,19,2], -a32,
3226       [$conftest_s],,
3227       [AC_DEFINE(HAVE_AS_CMPB, 1,
3228           [Define if your assembler supports cmpb.])])
3229
3230     case $target in
3231       *-*-aix*) conftest_s='    .machine "pwr6"
3232         .csect .text[[PR]]
3233         dadd 1,2,3';;
3234       *) conftest_s='   .machine power6
3235         .text
3236         dadd 1,2,3';;
3237     esac
3238
3239     gcc_GAS_CHECK_FEATURE([decimal float support],
3240       gcc_cv_as_powerpc_dfp, [2,19,2], -a32,
3241       [$conftest_s],,
3242       [AC_DEFINE(HAVE_AS_DFP, 1,
3243           [Define if your assembler supports DFP instructions.])])
3244
3245     case $target in
3246       *-*-aix*) conftest_s='    .machine "pwr7"
3247         .csect .text[[PR]]
3248         lxvd2x 1,2,3';;
3249       *) conftest_s='   .machine power7
3250         .text
3251         lxvd2x 1,2,3';;
3252     esac
3253
3254     gcc_GAS_CHECK_FEATURE([vector-scalar support],
3255       gcc_cv_as_powerpc_vsx, [2,19,2], -a32,
3256       [$conftest_s],,
3257       [AC_DEFINE(HAVE_AS_VSX, 1,
3258           [Define if your assembler supports VSX instructions.])])
3259
3260     case $target in
3261       *-*-aix*) conftest_s='    .machine "pwr7"
3262         .csect .text[[PR]]
3263         popcntd 3,3';;
3264       *) conftest_s='   .machine power7
3265         .text
3266         popcntd 3,3';;
3267     esac
3268
3269     gcc_GAS_CHECK_FEATURE([popcntd support],
3270       gcc_cv_as_powerpc_popcntd, [2,19,2], -a32,
3271       [$conftest_s],,
3272       [AC_DEFINE(HAVE_AS_POPCNTD, 1,
3273           [Define if your assembler supports POPCNTD instructions.])])
3274
3275     case $target in
3276       *-*-aix*) conftest_s='    .csect .text[[PR]]
3277         lwsync';;
3278       *) conftest_s='   .text
3279         lwsync';;
3280     esac
3281
3282     gcc_GAS_CHECK_FEATURE([lwsync support],
3283       gcc_cv_as_powerpc_lwsync, [2,19,2], -a32,
3284       [$conftest_s],,
3285       [AC_DEFINE(HAVE_AS_LWSYNC, 1,
3286           [Define if your assembler supports LWSYNC instructions.])])
3287
3288     case $target in
3289       *-*-aix*) conftest_s='    .machine "476"
3290         .csect .text[[PR]]
3291         dci 0';;
3292       *) conftest_s='   .machine "476"
3293         .text
3294         dci 0';;
3295     esac
3296
3297     gcc_GAS_CHECK_FEATURE([data cache invalidate support],
3298       gcc_cv_as_powerpc_dci, [9,99,0], -a32,
3299       [$conftest_s],,
3300       [AC_DEFINE(HAVE_AS_DCI, 1,
3301           [Define if your assembler supports the DCI/ICI instructions.])])
3302
3303     gcc_GAS_CHECK_FEATURE([.gnu_attribute support],
3304       gcc_cv_as_powerpc_gnu_attribute, [2,18,0],,
3305       [.gnu_attribute 4,1],,
3306       [AC_DEFINE(HAVE_AS_GNU_ATTRIBUTE, 1,
3307           [Define if your assembler supports .gnu_attribute.])])
3308
3309     gcc_GAS_CHECK_FEATURE([tls marker support],
3310       gcc_cv_as_powerpc_tls_markers, [2,20,0],,
3311       [ bl __tls_get_addr(x@tlsgd)],,
3312       [AC_DEFINE(HAVE_AS_TLS_MARKERS, 1,
3313           [Define if your assembler supports arg info for __tls_get_addr.])])
3314     ;;
3315
3316   mips*-*-*)
3317     gcc_GAS_CHECK_FEATURE([explicit relocation support],
3318       gcc_cv_as_mips_explicit_relocs, [2,14,0],,
3319 [       lw $4,%gp_rel(foo)($4)],,
3320       [if test x$target_cpu_default = x
3321        then target_cpu_default=MASK_EXPLICIT_RELOCS
3322        else target_cpu_default="($target_cpu_default)|MASK_EXPLICIT_RELOCS"
3323        fi])
3324     gcc_GAS_CHECK_FEATURE([-mno-shared support],
3325       gcc_cv_as_mips_no_shared, [2,16,0], [-mno-shared], [nop],,
3326       [AC_DEFINE(HAVE_AS_NO_SHARED, 1,
3327                  [Define if the assembler understands -mno-shared.])])
3328
3329     gcc_GAS_CHECK_FEATURE([.gnu_attribute support],
3330       gcc_cv_as_mips_gnu_attribute, [2,18,0],,
3331       [.gnu_attribute 4,1],,
3332       [AC_DEFINE(HAVE_AS_GNU_ATTRIBUTE, 1,
3333           [Define if your assembler supports .gnu_attribute.])])
3334
3335     gcc_GAS_CHECK_FEATURE([.dtprelword support],
3336       gcc_cv_as_mips_dtprelword, [2,18,0],,
3337       [.section .tdata,"awT",@progbits
3338 x:
3339         .word 2
3340         .text
3341         .dtprelword x+0x8000],,
3342       [AC_DEFINE(HAVE_AS_DTPRELWORD, 1,
3343           [Define if your assembler supports .dtprelword.])])
3344
3345     AC_MSG_CHECKING(assembler and linker for explicit JALR relocation)
3346     gcc_cv_as_ld_jalr_reloc=no
3347     if test $gcc_cv_as_mips_explicit_relocs = yes; then
3348       if test $in_tree_ld = yes ; then
3349         if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 20 -o "$gcc_cv_gld_major_version" -gt 2 \
3350            && test $in_tree_ld_is_elf = yes; then
3351           gcc_cv_as_ld_jalr_reloc=yes
3352         fi
3353       elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x -a x$gcc_cv_objdump != x; then
3354         echo '  .ent x' > conftest.s
3355         echo 'x:        ld $2,%got_disp(y)($3)' >> conftest.s
3356         echo '  ld $25,%call16(y)($28)' >> conftest.s
3357         echo '  .reloc  1f,R_MIPS_JALR,y' >> conftest.s
3358         echo '1:        jalr $25' >> conftest.s
3359         echo '  .reloc  1f,R_MIPS_JALR,x' >> conftest.s
3360         echo '1:        jalr $25' >> conftest.s
3361         echo '  .end x' >> conftest.s
3362         if $gcc_cv_as -o conftest.o conftest.s >/dev/null 2>&AS_MESSAGE_LOG_FD \
3363            && $gcc_cv_ld -shared -o conftest.so conftest.o >/dev/null 2>&AS_MESSAGE_LOG_FD; then
3364           if $gcc_cv_objdump -d conftest.so | grep -q jalr \
3365              && $gcc_cv_objdump -d conftest.so | grep -q "bal.*<x>"; then
3366             gcc_cv_as_ld_jalr_reloc=yes
3367           fi
3368         fi
3369         rm -f conftest.*
3370       fi
3371     fi
3372     if test $gcc_cv_as_ld_jalr_reloc = yes; then
3373       if test x$target_cpu_default = x; then
3374         target_cpu_default=MASK_RELAX_PIC_CALLS
3375       else
3376         target_cpu_default="($target_cpu_default)|MASK_RELAX_PIC_CALLS"
3377       fi
3378     fi
3379     AC_MSG_RESULT($gcc_cv_as_ld_jalr_reloc)
3380
3381     AC_CACHE_CHECK([linker for .eh_frame personality relaxation],
3382       [gcc_cv_ld_mips_personality_relaxation],
3383       [gcc_cv_ld_mips_personality_relaxation=no
3384        if test $in_tree_ld = yes ; then
3385          if test "$gcc_cv_gld_major_version" -eq 2 \
3386                  -a "$gcc_cv_gld_minor_version" -ge 21 \
3387                  -o "$gcc_cv_gld_major_version" -gt 2; then
3388            gcc_cv_ld_mips_personality_relaxation=yes
3389          fi
3390        elif test x$gcc_cv_as != x \
3391                  -a x$gcc_cv_ld != x \
3392                  -a x$gcc_cv_readelf != x ; then
3393          cat > conftest.s <<EOF
3394         .cfi_startproc
3395         .cfi_personality 0x80,indirect_ptr
3396         .ent test
3397 test:
3398         nop
3399         .end test
3400         .cfi_endproc
3401
3402         .section .data,"aw",@progbits
3403 indirect_ptr:
3404         .dc.a personality
3405 EOF
3406          if $gcc_cv_as -KPIC -o conftest.o conftest.s > /dev/null 2>&1 \
3407             && $gcc_cv_ld -o conftest conftest.o -shared > /dev/null 2>&1; then
3408            if $gcc_cv_readelf -d conftest 2>&1 \
3409               | grep TEXTREL > /dev/null 2>&1; then
3410              :
3411            elif $gcc_cv_readelf --relocs conftest 2>&1 \
3412                 | grep 'R_MIPS_REL32 *$' > /dev/null 2>&1; then
3413              :
3414            else
3415              gcc_cv_ld_mips_personality_relaxation=yes
3416            fi
3417          fi
3418        fi
3419        rm -f conftest.s conftest.o conftest])
3420     if test x$gcc_cv_ld_mips_personality_relaxation = xyes; then
3421             AC_DEFINE(HAVE_LD_PERSONALITY_RELAXATION, 1,
3422       [Define if your linker can relax absolute .eh_frame personality
3423 pointers into PC-relative form.])
3424     fi
3425     ;;
3426 esac
3427
3428 # Mips and HP-UX need the GNU assembler.
3429 # Linux on IA64 might be able to use the Intel assembler.
3430
3431 case "$target" in
3432   mips*-*-* | *-*-hpux* )
3433     if test x$gas_flag = xyes \
3434        || test x"$host" != x"$build" \
3435        || test ! -x "$gcc_cv_as" \
3436        || "$gcc_cv_as" -v < /dev/null 2>&1 | grep GNU > /dev/null; then
3437       :
3438     else
3439       echo "*** This configuration requires the GNU assembler" >&2
3440       exit 1
3441     fi
3442     ;;
3443 esac
3444
3445 # ??? Not all targets support dwarf2 debug_line, even within a version
3446 # of gas.  Moreover, we need to emit a valid instruction to trigger any
3447 # info to the output file.  So, as supported targets are added to gas 2.11,
3448 # add some instruction here to (also) show we expect this might work.
3449 # ??? Once 2.11 is released, probably need to add first known working
3450 # version to the per-target configury.
3451 case "$target" in
3452   i?86*-*-* | mips*-*-* | alpha*-*-* | powerpc*-*-* | sparc*-*-* | m68*-*-* \
3453   | x86_64*-*-* | hppa*-*-* | arm*-*-* \
3454   | xstormy16*-*-* | cris-*-* | crisv32-*-* | xtensa*-*-* | bfin-*-* | score*-*-* \
3455   | spu-*-* | fido*-*-* | m32c-*-*)
3456     insn="nop"
3457     ;;
3458   ia64*-*-* | s390*-*-*)
3459     insn="nop 0"
3460     ;;
3461   mmix-*-*)
3462     insn="swym 0"
3463     ;;
3464 esac
3465 if test x"$insn" != x; then
3466  conftest_s="\
3467         .file 1 \"conftest.s\"
3468         .loc 1 3 0
3469         $insn"
3470  gcc_GAS_CHECK_FEATURE([dwarf2 debug_line support],
3471   gcc_cv_as_dwarf2_debug_line,
3472   [elf,2,11,0],, [$conftest_s],
3473   [if test x$gcc_cv_objdump != x \
3474    && $gcc_cv_objdump -h conftest.o 2> /dev/null \
3475       | grep debug_line > /dev/null 2>&1; then
3476      gcc_cv_as_dwarf2_debug_line=yes
3477    fi])
3478
3479 # The .debug_line file table must be in the exact order that
3480 # we specified the files, since these indices are also used
3481 # by DW_AT_decl_file.  Approximate this test by testing if
3482 # the assembler bitches if the same index is assigned twice.
3483  gcc_GAS_CHECK_FEATURE([buggy dwarf2 .file directive],
3484   gcc_cv_as_dwarf2_file_buggy,,,
3485 [       .file 1 "foo.s"
3486         .file 1 "bar.s"])
3487
3488  if test $gcc_cv_as_dwarf2_debug_line = yes \
3489  && test $gcc_cv_as_dwarf2_file_buggy = no; then
3490         AC_DEFINE(HAVE_AS_DWARF2_DEBUG_LINE, 1,
3491   [Define if your assembler supports dwarf2 .file/.loc directives,
3492    and preserves file table indices exactly as given.])
3493  fi
3494
3495  gcc_GAS_CHECK_FEATURE([--gdwarf2 option],
3496   gcc_cv_as_gdwarf2_flag,
3497   [elf,2,11,0], [--gdwarf2], [$insn],,
3498   [AC_DEFINE(HAVE_AS_GDWARF2_DEBUG_FLAG, 1,
3499 [Define if your assembler supports the --gdwarf2 option.])])
3500
3501  gcc_GAS_CHECK_FEATURE([--gstabs option],
3502   gcc_cv_as_gstabs_flag,
3503   [elf,2,11,0], [--gstabs], [$insn],
3504   [# The native Solaris 9/Intel assembler doesn't understand --gstabs
3505    # and warns about it, but still exits successfully.  So check for
3506    # this.
3507    if AC_TRY_COMMAND([$gcc_cv_as --gstabs -o conftest.o conftest.s 2>&1 | grep -i warning > /dev/null])
3508    then :
3509    else gcc_cv_as_gstabs_flag=yes
3510    fi],
3511   [AC_DEFINE(HAVE_AS_GSTABS_DEBUG_FLAG, 1,
3512 [Define if your assembler supports the --gstabs option.])])
3513
3514  gcc_GAS_CHECK_FEATURE([--debug-prefix-map option],
3515   gcc_cv_as_debug_prefix_map_flag,
3516   [2,18,0], [--debug-prefix-map /a=/b], [$insn],,
3517   [AC_DEFINE(HAVE_AS_DEBUG_PREFIX_MAP, 1,
3518 [Define if your assembler supports the --debug-prefix-map option.])])
3519 fi
3520
3521 gcc_GAS_CHECK_FEATURE([.lcomm with alignment], gcc_cv_as_lcomm_with_alignment,
3522  ,,
3523 [.lcomm bar,4,16],,
3524 [AC_DEFINE(HAVE_GAS_LCOMM_WITH_ALIGNMENT, 1,
3525   [Define if your assembler supports .lcomm with an alignment field.])])
3526
3527 AC_ARG_ENABLE(gnu-unique-object,
3528  [  --enable-gnu-unique-object  enable the use of the @gnu_unique_object ELF extension on
3529                                 glibc systems],
3530  [case $enable_gnu_unique_object in
3531     yes | no) ;;
3532     *) AC_MSG_ERROR(['$enable_gnu_unique_object' is an invalid value for --enable-gnu-unique-object.
3533 Valid choices are 'yes' and 'no'.]) ;;
3534   esac],
3535  [gcc_GAS_CHECK_FEATURE([gnu_unique_object], gcc_cv_as_gnu_unique_object,
3536    [elf,2,19,52],,
3537    [.type foo, @gnu_unique_object],,
3538 # Also check for ld.so support, i.e. glibc 2.11 or higher.
3539    [if test x$host = x$build -a x$host = x$target &&
3540        glibcver=`ldd --version 2>/dev/null`; then
3541       glibcmajor=`expr "$glibcver" : "ldd (GNU libc) \([[0-9]]*\)"`
3542       glibcminor=`expr "$glibcver" : "ldd (GNU libc) [[0-9]]*\.\([[0-9]]*\)"`
3543       glibcnum=`expr $glibcmajor \* 1000 + $glibcminor`
3544       if test "$glibcnum" -ge 2011 ; then
3545         enable_gnu_unique_object=yes
3546       fi
3547     fi])])
3548 if test x$enable_gnu_unique_object = xyes; then
3549   AC_DEFINE(HAVE_GAS_GNU_UNIQUE_OBJECT, 1,
3550    [Define if your assembler supports @gnu_unique_object.])
3551 fi
3552
3553 AC_CACHE_CHECK([assembler for tolerance to line number 0],
3554  [gcc_cv_as_line_zero],
3555  [gcc_cv_as_line_zero=no
3556   if test $in_tree_gas = yes; then
3557     gcc_GAS_VERSION_GTE_IFELSE(2, 16, 91, [gcc_cv_as_line_zero=yes])
3558   elif test "x$gcc_cv_as" != x; then
3559     { echo '# 1 "test.s" 1'; echo '# 0 "" 2'; } > conftest.s
3560     if AC_TRY_COMMAND([$gcc_cv_as -o conftest.o conftest.s >&AS_MESSAGE_LOG_FD 2>conftest.out]) &&
3561        test "x`cat conftest.out`" = x
3562     then
3563       gcc_cv_as_line_zero=yes
3564     else
3565       echo "configure: failed program was" >&AS_MESSAGE_LOG_FD
3566       cat conftest.s >&AS_MESSAGE_LOG_FD
3567       echo "configure: error output was" >&AS_MESSAGE_LOG_FD
3568       cat conftest.out >&AS_MESSAGE_LOG_FD
3569     fi
3570     rm -f conftest.o conftest.s conftest.out
3571   fi])
3572 if test "x$gcc_cv_as_line_zero" = xyes; then
3573   AC_DEFINE([HAVE_AS_LINE_ZERO], 1,
3574 [Define if the assembler won't complain about a line such as # 0 "" 2.])
3575 fi
3576
3577 AC_MSG_CHECKING(linker PT_GNU_EH_FRAME support)
3578 gcc_cv_ld_eh_frame_hdr=no
3579 if test $in_tree_ld = yes ; then
3580   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 12 -o "$gcc_cv_gld_major_version" -gt 2 \
3581      && test $in_tree_ld_is_elf = yes; then
3582     gcc_cv_ld_eh_frame_hdr=yes
3583   fi
3584 elif test x$gcc_cv_ld != x; then
3585         # Check if linker supports --eh-frame-hdr option
3586         if $gcc_cv_ld --help 2>/dev/null | grep eh-frame-hdr > /dev/null; then
3587                 gcc_cv_ld_eh_frame_hdr=yes
3588         fi
3589 fi
3590 GCC_TARGET_TEMPLATE([HAVE_LD_EH_FRAME_HDR])
3591 if test x"$gcc_cv_ld_eh_frame_hdr" = xyes; then
3592         AC_DEFINE(HAVE_LD_EH_FRAME_HDR, 1,
3593 [Define if your linker supports --eh-frame-hdr option.])
3594 fi
3595 AC_MSG_RESULT($gcc_cv_ld_eh_frame_hdr)
3596
3597 AC_MSG_CHECKING(linker position independent executable support)
3598 gcc_cv_ld_pie=no
3599 if test $in_tree_ld = yes ; then
3600   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 15 -o "$gcc_cv_gld_major_version" -gt 2 \
3601      && test $in_tree_ld_is_elf = yes; then
3602     gcc_cv_ld_pie=yes
3603   fi
3604 elif test x$gcc_cv_ld != x; then
3605         # Check if linker supports -pie option
3606         if $gcc_cv_ld --help 2>/dev/null | grep -- -pie > /dev/null; then
3607                 gcc_cv_ld_pie=yes
3608         fi
3609 fi
3610 if test x"$gcc_cv_ld_pie" = xyes; then
3611         AC_DEFINE(HAVE_LD_PIE, 1,
3612 [Define if your linker supports -pie option.])
3613 fi
3614 AC_MSG_RESULT($gcc_cv_ld_pie)
3615
3616 AC_MSG_CHECKING(linker EH-compatible garbage collection of sections)
3617 gcc_cv_ld_eh_gc_sections=no
3618 if test $in_tree_ld = yes ; then
3619   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 17 -o "$gcc_cv_gld_major_version" -gt 2 \
3620      && test $in_tree_ld_is_elf = yes; then
3621     gcc_cv_ld_eh_gc_sections=yes
3622   fi
3623 elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x -a x$gcc_cv_objdump != x ; then
3624   cat > conftest.s <<EOF
3625         .section        .text
3626 .globl _start
3627         .type _start, @function
3628 _start: