gcc/configure.ac

   1 # configure.ac for GCC
   2 # Process this file with autoconf to generate a configuration script.
   3
   4 # Copyright 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2004, 2005, 2006,
   5 # 2007, 2008, 2009 Free Software Foundation, Inc.
   6
   7 #This file is part of GCC.
   8
   9 #GCC is free software; you can redistribute it and/or modify it under
  10 #the terms of the GNU General Public License as published by the Free
  11 #Software Foundation; either version 3, or (at your option) any later
  12 #version.
  13
  14 #GCC is distributed in the hope that it will be useful, but WITHOUT
  15 #ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  16 #FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  17 #for more details.
  18
  19 #You should have received a copy of the GNU General Public License
  20 #along with GCC; see the file COPYING3.  If not see
  21 #<http://www.gnu.org/licenses/>.
  22
  23 # --------------------------------
  24 # Initialization and sanity checks
  25 # --------------------------------
  26
  27 AC_PREREQ(2.59)
  28 AC_INIT
  29 AC_CONFIG_SRCDIR(tree.c)
  30 AC_CONFIG_HEADER(auto-host.h:config.in)
  31
  32 gcc_version=`cat $srcdir/BASE-VER`
  33
  34 # Determine the host, build, and target systems
  35 AC_CANONICAL_BUILD
  36 AC_CANONICAL_HOST
  37 AC_CANONICAL_TARGET
  38
  39 # Determine the noncanonical target name, for directory use.
  40 ACX_NONCANONICAL_TARGET
  41
  42 # Determine the target- and build-specific subdirectories
  43 GCC_TOPLEV_SUBDIRS
  44
  45 # Set program_transform_name
  46 AC_ARG_PROGRAM
  47
  48 # Check for bogus environment variables.
  49 # Test if LIBRARY_PATH contains the notation for the current directory
  50 # since this would lead to problems installing/building glibc.
  51 # LIBRARY_PATH contains the current directory if one of the following
  52 # is true:
  53 # - one of the terminals (":" and ";") is the first or last sign
  54 # - two terminals occur directly after each other
  55 # - the path contains an element with a dot in it
  56 AC_MSG_CHECKING(LIBRARY_PATH variable)
  57 changequote(,)dnl
  58 case ${LIBRARY_PATH} in
  59   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
  60     library_path_setting="contains current directory"
  61     ;;
  62   *)
  63     library_path_setting="ok"
  64     ;;
  65 esac
  66 changequote([,])dnl
  67 AC_MSG_RESULT($library_path_setting)
  68 if test "$library_path_setting" != "ok"; then
  69 AC_MSG_ERROR([
  70 *** LIBRARY_PATH shouldn't contain the current directory when
  71 *** building gcc. Please change the environment variable
  72 *** and run configure again.])
  73 fi
  74
  75 # Test if GCC_EXEC_PREFIX contains the notation for the current directory
  76 # since this would lead to problems installing/building glibc.
  77 # GCC_EXEC_PREFIX contains the current directory if one of the following
  78 # is true:
  79 # - one of the terminals (":" and ";") is the first or last sign
  80 # - two terminals occur directly after each other
  81 # - the path contains an element with a dot in it
  82 AC_MSG_CHECKING(GCC_EXEC_PREFIX variable)
  83 changequote(,)dnl
  84 case ${GCC_EXEC_PREFIX} in
  85   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
  86     gcc_exec_prefix_setting="contains current directory"
  87     ;;
  88   *)
  89     gcc_exec_prefix_setting="ok"
  90     ;;
  91 esac
  92 changequote([,])dnl
  93 AC_MSG_RESULT($gcc_exec_prefix_setting)
  94 if test "$gcc_exec_prefix_setting" != "ok"; then
  95 AC_MSG_ERROR([
  96 *** GCC_EXEC_PREFIX shouldn't contain the current directory when
  97 *** building gcc. Please change the environment variable
  98 *** and run configure again.])
  99 fi
 100
 101 # -----------
 102 # Directories
 103 # -----------
 104
 105 # Specify the local prefix
 106 local_prefix=
 107 AC_ARG_WITH(local-prefix,
 108 [  --with-local-prefix=DIR specifies directory to put local include],
 109 [case "${withval}" in
 110 yes)    AC_MSG_ERROR(bad value ${withval} given for local include directory prefix) ;;
 111 no)     ;;
 112 *)      local_prefix=$with_local_prefix ;;
 113 esac])
 114
 115 # Default local prefix if it is empty
 116 if test x$local_prefix = x; then
 117         local_prefix=/usr/local
 118 fi
 119
 120 # Don't set gcc_gxx_include_dir to gxx_include_dir since that's only
 121 # passed in by the toplevel make and thus we'd get different behavior
 122 # depending on where we built the sources.
 123 gcc_gxx_include_dir=
 124 # Specify the g++ header file directory
 125 AC_ARG_WITH(gxx-include-dir,
 126 [  --with-gxx-include-dir=DIR
 127                           specifies directory to put g++ header files],
 128 [case "${withval}" in
 129 yes)    AC_MSG_ERROR(bad value ${withval} given for g++ include directory) ;;
 130 no)     ;;
 131 *)      gcc_gxx_include_dir=$with_gxx_include_dir ;;
 132 esac])
 133
 134 # This logic must match libstdc++-v3/acinclude.m4:GLIBCXX_EXPORT_INSTALL_INFO.
 135 if test x${gcc_gxx_include_dir} = x; then
 136   if test x${enable_version_specific_runtime_libs} = xyes; then
 137     gcc_gxx_include_dir='${libsubdir}/include/c++'
 138   else
 139     libstdcxx_incdir='include/c++/$(version)'
 140     if test x$host != x$target; then
 141        libstdcxx_incdir="$target_alias/$libstdcxx_incdir"
 142     fi
 143     gcc_gxx_include_dir="\$(libsubdir)/\$(libsubdir_to_prefix)$libstdcxx_incdir"
 144   fi
 145 fi
 146
 147 AC_ARG_WITH(cpp_install_dir,
 148 [  --with-cpp-install-dir=DIR
 149                           install the user visible C preprocessor in DIR
 150                           (relative to PREFIX) as well as PREFIX/bin],
 151 [if test x$withval = xyes; then
 152   AC_MSG_ERROR([option --with-cpp-install-dir requires an argument])
 153 elif test x$withval != xno; then
 154   cpp_install_dir=$withval
 155 fi])
 156
 157 # We would like to our source tree to be readonly.  However when releases or
 158 # pre-releases are generated, the flex/bison generated files as well as the
 159 # various formats of manuals need to be included along with the rest of the
 160 # sources.  Therefore we have --enable-generated-files-in-srcdir to do
 161 # just that.
 162
 163 AC_MSG_CHECKING([whether to place generated files in the source directory])
 164   dnl generated-files-in-srcdir is disabled by default
 165   AC_ARG_ENABLE(generated-files-in-srcdir,
 166 [  --enable-generated-files-in-srcdir
 167                           put copies of generated files in source dir
 168                           intended for creating source tarballs for users
 169                           without texinfo bison or flex.],
 170       generated_files_in_srcdir=$enableval,
 171       generated_files_in_srcdir=no)
 172
 173 AC_MSG_RESULT($generated_files_in_srcdir)
 174
 175 if test "$generated_files_in_srcdir" = "yes"; then
 176   GENINSRC=''
 177 else
 178   GENINSRC='#'
 179 fi
 180 AC_SUBST(GENINSRC)
 181
 182 # -------------------
 183 # Find default linker
 184 # -------------------
 185
 186 # With GNU ld
 187 AC_ARG_WITH(gnu-ld,
 188 [  --with-gnu-ld           arrange to work with GNU ld.],
 189 gnu_ld_flag="$with_gnu_ld",
 190 gnu_ld_flag=no)
 191
 192 # With pre-defined ld
 193 AC_ARG_WITH(ld,
 194 [  --with-ld               arrange to use the specified ld (full pathname)],
 195 DEFAULT_LINKER="$with_ld")
 196 if test x"${DEFAULT_LINKER+set}" = x"set"; then
 197   if test ! -x "$DEFAULT_LINKER"; then
 198     AC_MSG_ERROR([cannot execute: $DEFAULT_LINKER: check --with-ld or env. var. DEFAULT_LINKER])
 199   elif $DEFAULT_LINKER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
 200     gnu_ld_flag=yes
 201   fi
 202   AC_DEFINE_UNQUOTED(DEFAULT_LINKER,"$DEFAULT_LINKER",
 203         [Define to enable the use of a default linker.])
 204 fi
 205
 206 gnu_ld=`if test x"$gnu_ld_flag" = x"yes"; then echo 1; else echo 0; fi`
 207 AC_DEFINE_UNQUOTED(HAVE_GNU_LD, $gnu_ld, [Define if using GNU ld.])
 208
 209 AC_MSG_CHECKING([whether a default linker was specified])
 210 if test x"${DEFAULT_LINKER+set}" = x"set"; then
 211   if test x"$gnu_ld_flag" = x"no"; then
 212     AC_MSG_RESULT([yes ($DEFAULT_LINKER)])
 213   else
 214     AC_MSG_RESULT([yes ($DEFAULT_LINKER - GNU ld)])
 215   fi
 216 else
 217   AC_MSG_RESULT(no)
 218 fi
 219
 220 # With demangler in GNU ld
 221 AC_ARG_WITH(demangler-in-ld,
 222 [  --with-demangler-in-ld  try to use demangler in GNU ld.],
 223 demangler_in_ld="$with_demangler_in_ld",
 224 demangler_in_ld=no)
 225
 226 # ----------------------
 227 # Find default assembler
 228 # ----------------------
 229
 230 # With GNU as
 231 AC_ARG_WITH(gnu-as,
 232 [  --with-gnu-as           arrange to work with GNU as],
 233 gas_flag="$with_gnu_as",
 234 gas_flag=no)
 235
 236 AC_ARG_WITH(as,
 237 [  --with-as               arrange to use the specified as (full pathname)],
 238 DEFAULT_ASSEMBLER="$with_as")
 239 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
 240   if test ! -x "$DEFAULT_ASSEMBLER"; then
 241     AC_MSG_ERROR([cannot execute: $DEFAULT_ASSEMBLER: check --with-as or env. var. DEFAULT_ASSEMBLER])
 242   elif $DEFAULT_ASSEMBLER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
 243     gas_flag=yes
 244   fi
 245   AC_DEFINE_UNQUOTED(DEFAULT_ASSEMBLER,"$DEFAULT_ASSEMBLER",
 246         [Define to enable the use of a default assembler.])
 247 fi
 248
 249 gnu_as=`if test x"$gas_flag" = x"yes"; then echo 1; else echo 0; fi`
 250 AC_DEFINE_UNQUOTED(HAVE_GNU_AS, $gnu_as, [Define if using GNU as.])
 251
 252 AC_MSG_CHECKING([whether a default assembler was specified])
 253 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
 254   if test x"$gas_flag" = x"no"; then
 255     AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER)])
 256   else
 257     AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER - GNU as)])
 258   fi
 259 else
 260   AC_MSG_RESULT(no)
 261 fi
 262
 263 # ---------------
 264 # Find C compiler
 265 # ---------------
 266
 267 # If a non-executable a.out is present (e.g. created by GNU as above even if
 268 # invoked with -v only), the IRIX 6 native ld just overwrites the existing
 269 # file, even when creating an executable, so an execution test fails.
 270 # Remove possible default executable files to avoid this.
 271 #
 272 # FIXME: This really belongs into AC_PROG_CC and can be removed once
 273 # Autoconf includes it.
 274 rm -f a.out a.exe b.out
 275
 276 # Find the native compiler
 277 AC_PROG_CC
 278 AM_PROG_CC_C_O
 279 ACX_PROG_GNAT([-I"$srcdir"/ada])
 280
 281 # autoconf is lame and doesn't give us any substitution variable for this.
 282 if eval "test \"`echo '$ac_cv_prog_cc_'${ac_cc}_c_o`\" = no"; then
 283   NO_MINUS_C_MINUS_O=yes
 284 else
 285   OUTPUT_OPTION='-o $@'
 286 fi
 287 AC_SUBST(NO_MINUS_C_MINUS_O)
 288 AC_SUBST(OUTPUT_OPTION)
 289
 290 # Remove the -O2: for historical reasons, unless bootstrapping we prefer
 291 # optimizations to be activated explicitly by the toplevel.
 292 case "$CC" in
 293   */prev-gcc/xgcc*) ;;
 294   *) CFLAGS=`echo $CFLAGS | sed "s/-O[[s0-9]]* *//" ` ;;
 295 esac
 296 AC_SUBST(CFLAGS)
 297
 298 # -------------------------
 299 # Check C compiler features
 300 # -------------------------
 301
 302 AC_USE_SYSTEM_EXTENSIONS
 303 AC_PROG_CPP
 304 AC_C_INLINE
 305
 306 # sizeof(char) is 1 by definition.
 307 AC_CHECK_SIZEOF(void *)
 308 AC_CHECK_SIZEOF(short)
 309 AC_CHECK_SIZEOF(int)
 310 AC_CHECK_SIZEOF(long)
 311 AC_CHECK_TYPES([long long], [AC_CHECK_SIZEOF(long long)])
 312 AC_CHECK_TYPES([__int64], [AC_CHECK_SIZEOF(__int64)])
 313
 314 # ---------------------
 315 # Warnings and checking
 316 # ---------------------
 317
 318 # Check $CC warning features (if it's GCC).
 319 # We want to use -pedantic, but we don't want warnings about
 320 # * 'long long'
 321 # * variadic macros
 322 # * overlong strings
 323 # So, we only use -pedantic if we can disable those warnings.
 324
 325 ACX_PROG_CC_WARNING_OPTS(
 326         m4_quote(m4_do([-W -Wall -Wwrite-strings -Wstrict-prototypes ],
 327                        [-Wmissing-prototypes -Wcast-qual])), [loose_warn])
 328 ACX_PROG_CC_WARNING_OPTS(
 329         m4_quote(m4_do([-Wold-style-definition -Wc++-compat ],
 330                        [-Wmissing-format-attribute])), [strict_warn])
 331 ACX_PROG_CC_WARNING_ALMOST_PEDANTIC(
 332         m4_quote(m4_do([-Wno-long-long -Wno-variadic-macros ],
 333                        [-Wno-overlength-strings])), [strict_warn])
 334 ACX_PROG_CC_WARNINGS_ARE_ERRORS([manual], [strict_warn])
 335
 336 # The above macros do nothing if the compiler is not GCC.  However, the
 337 # Makefile has more goo to add other flags, so this variabl is used to
 338 # enables warnings only for GCC.
 339 warn_cflags=
 340 if test "x$GCC" = "xyes"; then
 341   warn_cflags='$(GCC_WARN_CFLAGS)'
 342 fi
 343 AC_SUBST(warn_cflags)
 344
 345 # Enable expensive internal checks
 346 is_release=
 347 if test x"`cat $srcdir/DEV-PHASE`" != xexperimental; then
 348   is_release=yes
 349 fi
 350
 351 AC_ARG_ENABLE(checking,
 352 [  --enable-checking[=LIST]
 353                           enable expensive run-time checks.  With LIST,
 354                           enable only specific categories of checks.
 355                           Categories are: yes,no,all,none,release.
 356                           Flags are: assert,df,fold,gc,gcac,gimple,misc,
 357                           rtlflag,rtl,runtime,tree,valgrind,types.],
 358 [ac_checking_flags="${enableval}"],[
 359 # Determine the default checks.
 360 if test x$is_release = x ; then
 361   ac_checking_flags=yes
 362 else
 363   ac_checking_flags=release
 364 fi])
 365 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 366 for check in release $ac_checking_flags
 367 do
 368         case $check in
 369         # these set all the flags to specific states
 370         yes)            ac_assert_checking=1 ; ac_checking=1 ; ac_df_checking= ;
 371                         ac_fold_checking= ; ac_gc_checking=1 ;
 372                         ac_gc_always_collect= ; ac_gimple_checking=1 ; ac_rtl_checking= ;
 373                         ac_rtlflag_checking=1 ; ac_runtime_checking=1 ;
 374                         ac_tree_checking=1 ; ac_valgrind_checking= ;
 375                         ac_types_checking=1 ;;
 376         no|none)        ac_assert_checking= ; ac_checking= ; ac_df_checking= ;
 377                         ac_fold_checking= ; ac_gc_checking= ;
 378                         ac_gc_always_collect= ; ac_gimple_checking= ; ac_rtl_checking= ;
 379                         ac_rtlflag_checking= ; ac_runtime_checking= ;
 380                         ac_tree_checking= ; ac_valgrind_checking= ;
 381                         ac_types_checking= ;;
 382         all)            ac_assert_checking=1 ; ac_checking=1 ; ac_df_checking=1 ;
 383                         ac_fold_checking=1 ; ac_gc_checking=1 ;
 384                         ac_gc_always_collect=1 ; ac_gimple_checking=1 ; ac_rtl_checking=1 ;
 385                         ac_rtlflag_checking=1 ; ac_runtime_checking=1 ;
 386                         ac_tree_checking=1 ; ac_valgrind_checking= ;
 387                         ac_types_checking=1 ;;
 388         release)        ac_assert_checking=1 ; ac_checking= ; ac_df_checking= ;
 389                         ac_fold_checking= ; ac_gc_checking= ;
 390                         ac_gc_always_collect= ; ac_gimple_checking= ; ac_rtl_checking= ;
 391                         ac_rtlflag_checking= ; ac_runtime_checking=1 ;
 392                         ac_tree_checking= ; ac_valgrind_checking= ;
 393                         ac_types_checking= ;;
 394         # these enable particular checks
 395         assert)         ac_assert_checking=1 ;;
 396         df)             ac_df_checking=1 ;;
 397         fold)           ac_fold_checking=1 ;;
 398         gc)             ac_gc_checking=1 ;;
 399         gcac)           ac_gc_always_collect=1 ;;
 400         gimple)         ac_gimple_checking=1 ;;
 401         misc)           ac_checking=1 ;;
 402         rtl)            ac_rtl_checking=1 ;;
 403         rtlflag)        ac_rtlflag_checking=1 ;;
 404         runtime)        ac_runtime_checking=1 ;;
 405         tree)           ac_tree_checking=1 ;;
 406         types)          ac_types_checking=1 ;;
 407         valgrind)       ac_valgrind_checking=1 ;;
 408         *)      AC_MSG_ERROR(unknown check category $check) ;;
 409         esac
 410 done
 411 IFS="$ac_save_IFS"
 412
 413 nocommon_flag=""
 414 if test x$ac_checking != x ; then
 415   AC_DEFINE(ENABLE_CHECKING, 1,
 416 [Define if you want more run-time sanity checks.  This one gets a grab
 417    bag of miscellaneous but relatively cheap checks.])
 418   nocommon_flag=-fno-common
 419 fi
 420 AC_SUBST(nocommon_flag)
 421 if test x$ac_df_checking != x ; then
 422   AC_DEFINE(ENABLE_DF_CHECKING, 1,
 423 [Define if you want more run-time sanity checks for dataflow.])
 424 fi
 425 if test x$ac_assert_checking != x ; then
 426   AC_DEFINE(ENABLE_ASSERT_CHECKING, 1,
 427 [Define if you want assertions enabled.  This is a cheap check.])
 428 fi
 429 if test x$ac_gimple_checking != x ; then
 430   AC_DEFINE(ENABLE_GIMPLE_CHECKING, 1,
 431 [Define if you want operations on GIMPLE (the basic data structure of
 432 the high-level optimizers) to be checked for dynamic type safety at
 433 runtime.  This is moderately expensive.])
 434 fi
 435 GCC_TARGET_TEMPLATE(ENABLE_RUNTIME_CHECKING)
 436 if test x$ac_runtime_checking != x ; then
 437   AC_DEFINE(ENABLE_RUNTIME_CHECKING, 1,
 438 [Define if you want runtime assertions enabled.  This is a cheap check.])
 439 fi
 440 if test x$ac_tree_checking != x ; then
 441   AC_DEFINE(ENABLE_TREE_CHECKING, 1,
 442 [Define if you want all operations on trees (the basic data
 443    structure of the front ends) to be checked for dynamic type safety
 444    at runtime.  This is moderately expensive.  The tree browser debugging
 445    routines will also be enabled by this option.
 446    ])
 447   TREEBROWSER=tree-browser.o
 448 fi
 449 if test x$ac_types_checking != x ; then
 450   AC_DEFINE(ENABLE_TYPES_CHECKING, 1,
 451 [Define if you want all gimple types to be verified after gimplifiation.
 452    This is cheap.
 453    ])
 454 fi
 455 AC_SUBST(TREEBROWSER)
 456 if test x$ac_rtl_checking != x ; then
 457   AC_DEFINE(ENABLE_RTL_CHECKING, 1,
 458 [Define if you want all operations on RTL (the basic data structure
 459    of the optimizer and back end) to be checked for dynamic type safety
 460    at runtime.  This is quite expensive.])
 461 fi
 462 if test x$ac_rtlflag_checking != x ; then
 463   AC_DEFINE(ENABLE_RTL_FLAG_CHECKING, 1,
 464 [Define if you want RTL flag accesses to be checked against the RTL
 465    codes that are supported for each access macro.  This is relatively
 466    cheap.])
 467 fi
 468 if test x$ac_gc_checking != x ; then
 469   AC_DEFINE(ENABLE_GC_CHECKING, 1,
 470 [Define if you want the garbage collector to do object poisoning and
 471    other memory allocation checks.  This is quite expensive.])
 472 fi
 473 if test x$ac_gc_always_collect != x ; then
 474   AC_DEFINE(ENABLE_GC_ALWAYS_COLLECT, 1,
 475 [Define if you want the garbage collector to operate in maximally
 476    paranoid mode, validating the entire heap and collecting garbage at
 477    every opportunity.  This is extremely expensive.])
 478 fi
 479 if test x$ac_fold_checking != x ; then
 480   AC_DEFINE(ENABLE_FOLD_CHECKING, 1,
 481 [Define if you want fold checked that it never destructs its argument.
 482    This is quite expensive.])
 483 fi
 484 valgrind_path_defines=
 485 valgrind_command=
 486
 487 dnl # This check AC_REQUIREs various stuff, so it *must not* be inside
 488 dnl # an if statement.  This was the source of very frustrating bugs
 489 dnl # in converting to autoconf 2.5x!
 490 AC_CHECK_HEADER(valgrind.h, have_valgrind_h=yes, have_valgrind_h=no)
 491
 492 if test x$ac_valgrind_checking != x ; then
 493   # It is certainly possible that there's valgrind but no valgrind.h.
 494   # GCC relies on making annotations so we must have both.
 495   AC_MSG_CHECKING(for VALGRIND_DISCARD in <valgrind/memcheck.h>)
 496   AC_PREPROC_IFELSE([AC_LANG_SOURCE(
 497     [[#include <valgrind/memcheck.h>
 498 #ifndef VALGRIND_DISCARD
 499 #error VALGRIND_DISCARD not defined
 500 #endif]])],
 501   [gcc_cv_header_valgrind_memcheck_h=yes],
 502   [gcc_cv_header_valgrind_memcheck_h=no])
 503   AC_MSG_RESULT($gcc_cv_header_valgrind_memcheck_h)
 504   AC_MSG_CHECKING(for VALGRIND_DISCARD in <memcheck.h>)
 505   AC_PREPROC_IFELSE([AC_LANG_SOURCE(
 506     [[#include <memcheck.h>
 507 #ifndef VALGRIND_DISCARD
 508 #error VALGRIND_DISCARD not defined
 509 #endif]])],
 510   [gcc_cv_header_memcheck_h=yes],
 511   [gcc_cv_header_memcheck_h=no])
 512   AC_MSG_RESULT($gcc_cv_header_memcheck_h)
 513   AM_PATH_PROG_WITH_TEST(valgrind_path, valgrind,
 514         [$ac_dir/$ac_word --version | grep valgrind- >/dev/null 2>&1])
 515   if test "x$valgrind_path" = "x" \
 516     || (test $have_valgrind_h = no \
 517         && test $gcc_cv_header_memcheck_h = no \
 518         && test $gcc_cv_header_valgrind_memcheck_h = no); then
 519         AC_MSG_ERROR([*** Can't find both valgrind and valgrind/memcheck.h, memcheck.h or valgrind.h])
 520   fi
 521   valgrind_path_defines=-DVALGRIND_PATH='\"'$valgrind_path'\"'
 522   valgrind_command="$valgrind_path -q"
 523   AC_DEFINE(ENABLE_VALGRIND_CHECKING, 1,
 524 [Define if you want to run subprograms and generated programs
 525    through valgrind (a memory checker).  This is extremely expensive.])
 526   if test $gcc_cv_header_valgrind_memcheck_h = yes; then
 527     AC_DEFINE(HAVE_VALGRIND_MEMCHECK_H, 1,
 528         [Define if valgrind's valgrind/memcheck.h header is installed.])
 529   fi
 530   if test $gcc_cv_header_memcheck_h = yes; then
 531     AC_DEFINE(HAVE_MEMCHECK_H, 1,
 532         [Define if valgrind's memcheck.h header is installed.])
 533   fi
 534 fi
 535 AC_SUBST(valgrind_path_defines)
 536 AC_SUBST(valgrind_command)
 537
 538 # Enable code coverage collection
 539 AC_ARG_ENABLE(coverage,
 540 [  --enable-coverage[=LEVEL]
 541                           enable compiler's code coverage collection.
 542                           Use to measure compiler performance and locate
 543                           unused parts of the compiler. With LEVEL, specify
 544                           optimization. Values are opt, noopt,
 545                           default is noopt],
 546 [case "${enableval}" in
 547   yes|noopt)
 548     coverage_flags="-fprofile-arcs -ftest-coverage -frandom-seed=\$@ -O0"
 549     ;;
 550   opt)
 551     coverage_flags="-fprofile-arcs -ftest-coverage -frandom-seed=\$@ -O2"
 552     ;;
 553   no)
 554     # a.k.a. --disable-coverage
 555     coverage_flags=""
 556     ;;
 557   *)
 558     AC_MSG_ERROR(unknown coverage setting $enableval)
 559     ;;
 560 esac],
 561 [coverage_flags=""])
 562 AC_SUBST(coverage_flags)
 563
 564 AC_ARG_ENABLE(gather-detailed-mem-stats,
 565 [  --enable-gather-detailed-mem-stats         enable detailed memory allocation stats gathering], [],
 566 [enable_gather_detailed_mem_stats=no])
 567 if test x$enable_gather_detailed_mem_stats = xyes ; then
 568   AC_DEFINE(GATHER_STATISTICS, 1,
 569         [Define to enable detailed memory allocation stats gathering.])
 570 fi
 571
 572 # -------------------------------
 573 # Miscenalleous configure options
 574 # -------------------------------
 575
 576 # With stabs
 577 AC_ARG_WITH(stabs,
 578 [  --with-stabs            arrange to use stabs instead of host debug format],
 579 stabs="$with_stabs",
 580 stabs=no)
 581
 582 # Determine whether or not multilibs are enabled.
 583 AC_ARG_ENABLE(multilib,
 584 [  --enable-multilib       enable library support for multiple ABIs],
 585 [], [enable_multilib=yes])
 586 AC_SUBST(enable_multilib)
 587
 588 # Enable __cxa_atexit for C++.
 589 AC_ARG_ENABLE(__cxa_atexit,
 590 [  --enable-__cxa_atexit   enable __cxa_atexit for C++],
 591 [], [])
 592
 593 # Enable C extension for decimal float if target supports it.
 594 AC_ARG_ENABLE(decimal-float,
 595 [  --enable-decimal-float={no,yes,bid,dpd}
 596                         enable decimal float extension to C.  Selecting 'bid'
 597                         or 'dpd' choses which decimal floating point format
 598                         to use],
 599 [
 600   case $enable_decimal_float in
 601     yes | no | bid | dpd) ;;
 602     *) AC_MSG_ERROR(['$enable_decimal_float' is an invalid value for --enable-decimal-float.
 603 Valid choices are 'yes', 'bid', 'dpd', and 'no'.]) ;;
 604   esac
 605 ],
 606 [
 607   case $target in
 608     powerpc*-*-linux* | i?86*-*-linux* | x86_64*-*-linux*)
 609       enable_decimal_float=yes
 610       ;;
 611     *)
 612       AC_MSG_WARN(decimal float is not supported for this target, ignored)
 613       enable_decimal_float=no
 614       ;;
 615   esac
 616 ])
 617
 618 dfp=`if test $enable_decimal_float != no; then echo 1; else echo 0; fi`
 619 AC_DEFINE_UNQUOTED(ENABLE_DECIMAL_FLOAT, $dfp,
 620 [Define to 1 to enable decimal float extension to C.])
 621
 622 # x86's use BID format instead of DPD
 623 case x$enable_decimal_float in
 624   xyes)
 625     case $target in
 626       i?86*-*-linux* | x86_64*-*-linux*)
 627         enable_decimal_float=bid
 628         ;;
 629       *)
 630         enable_decimal_float=dpd
 631         ;;
 632     esac
 633     ;;
 634   xno)
 635     # ENABLE_DECIMAL_FLOAT is set to 0. But we have to have proper
 636     # dependency on libdecnumber.
 637     enable_decimal_float=dpd
 638     ;;
 639 esac
 640 AC_SUBST(enable_decimal_float)
 641
 642 bid=`if test $enable_decimal_float = bid; then echo 1; else echo 0; fi`
 643 AC_DEFINE_UNQUOTED(ENABLE_DECIMAL_BID_FORMAT, $bid,
 644 [Define to 1 to specify that we are using the BID decimal floating
 645 point format instead of DPD])
 646
 647 # Enable C extension for fixed-point arithmetic.
 648 AC_ARG_ENABLE(fixed-point,
 649 [  --enable-fixed-point    enable fixed-point arithmetic extension to C],
 650 [
 651 ],
 652 [
 653   case $target in
 654     mips*-*-*)
 655       case $host in
 656         mips*-sgi-irix*)
 657           AC_MSG_WARN(fixed-point is not supported on IRIX, ignored)
 658           enable_fixed_point=no
 659           ;;
 660         *)
 661           enable_fixed_point=yes
 662           ;;
 663       esac
 664       ;;
 665     *)
 666       AC_MSG_WARN(fixed-point is not supported for this target, ignored)
 667       enable_fixed_point=no
 668       ;;
 669   esac
 670 ])
 671 AC_SUBST(enable_fixed_point)
 672
 673 fixedpoint=`if test $enable_fixed_point = yes; then echo 1; else echo 0; fi`
 674 AC_DEFINE_UNQUOTED(ENABLE_FIXED_POINT, $fixedpoint,
 675 [Define to 1 to enable fixed-point arithmetic extension to C.])
 676
 677 # Enable threads
 678 # Pass with no value to take the default
 679 # Pass with a value to specify a thread package
 680 AC_ARG_ENABLE(threads,
 681 [  --enable-threads        enable thread usage for target GCC
 682   --enable-threads=LIB    use LIB thread package for target GCC],,
 683 [enable_threads=''])
 684
 685 AC_ARG_ENABLE(tls,
 686 [  --enable-tls            enable or disable generation of tls code
 687                           overriding the assembler check for tls support],
 688 [
 689   case $enable_tls in
 690     yes | no) ;;
 691     *) AC_MSG_ERROR(['$enable_tls' is an invalid value for --enable-tls.
 692 Valid choices are 'yes' and 'no'.]) ;;
 693   esac
 694 ], [enable_tls=''])
 695
 696 AC_ARG_ENABLE(objc-gc,
 697 [  --enable-objc-gc       enable the use of Boehm's garbage collector with
 698                           the GNU Objective-C runtime],
 699 if test x$enable_objc_gc = xno; then
 700         objc_boehm_gc=''
 701 else
 702         objc_boehm_gc=1
 703 fi,
 704 objc_boehm_gc='')
 705
 706 AC_ARG_WITH(dwarf2,
 707 [  --with-dwarf2           force the default debug format to be DWARF 2],
 708 dwarf2="$with_dwarf2",
 709 dwarf2=no)
 710
 711 AC_ARG_ENABLE(shared,
 712 [  --disable-shared        don't provide a shared libgcc],
 713 [
 714   case $enable_shared in
 715   yes | no) ;;
 716   *)
 717     enable_shared=no
 718     IFS="${IFS=         }"; ac_save_ifs="$IFS"; IFS="${IFS}:,"
 719     for pkg in $enableval; do
 720       if test "X$pkg" = "Xgcc" || test "X$pkg" = "Xlibgcc"; then
 721         enable_shared=yes
 722       fi
 723     done
 724     IFS="$ac_save_ifs"
 725     ;;
 726   esac
 727 ], [enable_shared=yes])
 728 AC_SUBST(enable_shared)
 729
 730 AC_ARG_WITH(build-sysroot,
 731   [  --with-build-sysroot=sysroot
 732                           use sysroot as the system root during the build])
 733
 734 AC_ARG_WITH(sysroot,
 735 [  --with-sysroot[=DIR] Search for usr/lib, usr/include, et al, within DIR.],
 736 [
 737  case ${with_sysroot} in
 738  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_noncanonical}/sys-root' ;;
 739  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
 740  esac
 741
 742  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
 743  CROSS_SYSTEM_HEADER_DIR='$(TARGET_SYSTEM_ROOT)$${sysroot_headers_suffix}$(NATIVE_SYSTEM_HEADER_DIR)'
 744
 745  if test "x$prefix" = xNONE; then
 746   test_prefix=/usr/local
 747  else
 748   test_prefix=$prefix
 749  fi
 750  if test "x$exec_prefix" = xNONE; then
 751   test_exec_prefix=$test_prefix
 752  else
 753   test_exec_prefix=$exec_prefix
 754  fi
 755  case ${TARGET_SYSTEM_ROOT} in
 756  "${test_prefix}"|"${test_prefix}/"*|\
 757  "${test_exec_prefix}"|"${test_exec_prefix}/"*|\
 758  '${prefix}'|'${prefix}/'*|\
 759  '${exec_prefix}'|'${exec_prefix}/'*)
 760    t="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE"
 761    TARGET_SYSTEM_ROOT_DEFINE="$t"
 762    ;;
 763  esac
 764 ], [
 765  TARGET_SYSTEM_ROOT=
 766  TARGET_SYSTEM_ROOT_DEFINE=
 767  CROSS_SYSTEM_HEADER_DIR='$(gcc_tooldir)/sys-include'
 768 ])
 769 AC_SUBST(TARGET_SYSTEM_ROOT)
 770 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
 771 AC_SUBST(CROSS_SYSTEM_HEADER_DIR)
 772
 773 # Build with intermodule optimisations
 774 AC_ARG_ENABLE(intermodule,
 775 [  --enable-intermodule    build the compiler in one step],
 776 [case ${enable_intermodule} in
 777   yes) onestep="-onestep";;
 778   *) onestep="";;
 779 esac],
 780 [onestep=""])
 781 AC_SUBST(onestep)
 782
 783 ACX_PKGVERSION([GCC])
 784 ACX_BUGURL([http://gcc.gnu.org/bugs.html])
 785
 786 # Sanity check enable_languages in case someone does not run the toplevel
 787 # configure # script.
 788 AC_ARG_ENABLE(languages,
 789 [  --enable-languages=LIST specify which front-ends to build],
 790 [case ,${enable_languages}, in
 791        ,,|,yes,)
 792                 # go safe -- we cannot be much sure without the toplevel
 793                 # configure's
 794                 # analysis of which target libs are present and usable
 795                 enable_languages=c
 796                 ;;
 797          *,all,*)
 798                 AC_MSG_ERROR([only the toplevel supports --enable-languages=all])
 799                 ;;
 800         *,c,*)
 801                 ;;
 802         *)
 803                 enable_languages=c,${enable_languages}
 804                 ;;
 805 esac],
 806 [enable_languages=c])
 807
 808 # Used by documentation targets
 809 AC_SUBST(datarootdir)
 810 AC_SUBST(docdir)
 811 AC_SUBST(htmldir)
 812
 813 AC_ARG_WITH(multilib-list,
 814 [  --with-multilib-list    Select multilibs (SH only)],
 815 :,
 816 with_multilib_list=default)
 817
 818 # -------------------------
 819 # Checks for other programs
 820 # -------------------------
 821
 822 AC_PROG_MAKE_SET
 823
 824 # Find some useful tools
 825 AC_PROG_AWK
 826 # We need awk to create options.c and options.h.
 827 # Bail out if it's missing.
 828 case ${AWK} in
 829   "") AC_MSG_ERROR([can't build without awk, bailing out]) ;;
 830 esac
 831
 832 gcc_AC_PROG_LN_S
 833 ACX_PROG_LN($LN_S)
 834 AC_PROG_RANLIB
 835 case "${host}" in
 836 *-*-darwin*)
 837   # By default, the Darwin ranlib will not treat common symbols as
 838   # definitions when  building the archive table of contents.  Other
 839   # ranlibs do that; pass an option to the Darwin ranlib that makes
 840   # it behave similarly.
 841   ranlib_flags="-c"
 842   ;;
 843 *)
 844   ranlib_flags=""
 845 esac
 846 AC_SUBST(ranlib_flags)
 847
 848 gcc_AC_PROG_INSTALL
 849
 850 # See if cmp has --ignore-initial.
 851 gcc_AC_PROG_CMP_IGNORE_INITIAL
 852
 853 # See if we have the mktemp command.
 854 AC_CHECK_PROG(have_mktemp_command, mktemp, yes, no)
 855
 856 # See if makeinfo has been installed and is modern enough
 857 # that we can use it.
 858 ACX_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
 859   [GNU texinfo.* \([0-9][0-9.]*\)],
 860   [4.[7-9]*|4.[1-9][0-9]*|[5-9]*|[1-9][0-9]*])
 861 if test $gcc_cv_prog_makeinfo_modern = no; then
 862   AC_MSG_WARN([
 863 *** Makeinfo is missing or too old.
 864 *** Info documentation will not be built.])
 865   BUILD_INFO=
 866 else
 867   BUILD_INFO=info
 868 fi
 869 AC_SUBST(BUILD_INFO)
 870
 871 # Is pod2man recent enough to regenerate manpages?
 872 AC_MSG_CHECKING([for recent Pod::Man])
 873 if (perl -e 'use 1.10 Pod::Man') >/dev/null 2>&1; then
 874   AC_MSG_RESULT(yes)
 875   GENERATED_MANPAGES=generated-manpages
 876 else
 877   AC_MSG_RESULT(no)
 878   GENERATED_MANPAGES=
 879 fi
 880 AC_SUBST(GENERATED_MANPAGES)
 881
 882 MISSING="${CONFIG_SHELL-/bin/sh} $ac_aux_dir/missing"
 883
 884 # How about lex?
 885 dnl Don't use AC_PROG_LEX; we insist on flex.
 886 dnl LEXLIB is not useful in gcc.
 887 AC_CHECK_PROGS([FLEX], flex, [$MISSING flex])
 888
 889 # Bison?
 890 AC_CHECK_PROGS([BISON], bison, [$MISSING bison])
 891
 892 # Binutils are not build modules, unlike bison/flex/makeinfo.  So we
 893 # check for build == host before using them.
 894
 895 # NM
 896 if test x${build} = x${host} && test -f $srcdir/../binutils/nm.c \
 897   && test -d ../binutils ; then
 898   NM='$(objdir)/../binutils/nm-new'
 899 else
 900   AC_CHECK_PROG(NM, nm, nm, ${CONFIG_SHELL-/bin/sh} ${srcdir}/../missing nm)
 901 fi
 902
 903 # AR
 904 if test x${build} = x${host} && test -f $srcdir/../binutils/ar.c \
 905   && test -d ../binutils ; then
 906   AR='$(objdir)/../binutils/ar'
 907 else
 908   AC_CHECK_PROG(AR, ar, ar, ${CONFIG_SHELL-/bin/sh} ${srcdir}/../missing ar)
 909 fi
 910
 911
 912 # --------------------
 913 # Checks for C headers
 914 # --------------------
 915
 916 # Need to reject headers which give warnings, so that the -Werror bootstrap
 917 # works later. *sigh*  This needs to come before all header checks.
 918 AC_PROG_CPP_WERROR
 919
 920 AC_HEADER_STDC
 921 AC_HEADER_TIME
 922 ACX_HEADER_STRING
 923 AC_HEADER_SYS_WAIT
 924 AC_CHECK_HEADERS(limits.h stddef.h string.h strings.h stdlib.h time.h iconv.h \
 925                  fcntl.h unistd.h sys/file.h sys/time.h sys/mman.h \
 926                  sys/resource.h sys/param.h sys/times.h sys/stat.h \
 927                  direct.h malloc.h langinfo.h ldfcn.h locale.h wchar.h)
 928
 929 # Check for thread headers.
 930 AC_CHECK_HEADER(thread.h, [have_thread_h=yes], [have_thread_h=])
 931 AC_CHECK_HEADER(pthread.h, [have_pthread_h=yes], [have_pthread_h=])
 932
 933 # These tests can't be done till we know if we have limits.h.
 934 gcc_AC_C_CHAR_BIT
 935 AC_C_BIGENDIAN
 936
 937 # --------
 938 # UNSORTED
 939 # --------
 940
 941
 942 # These libraries may be used by collect2.
 943 # We may need a special search path to get them linked.
 944 AC_CACHE_CHECK(for collect2 libraries, gcc_cv_collect2_libs,
 945 [save_LIBS="$LIBS"
 946 for libs in '' -lld -lmld \
 947                 '-L/usr/lib/cmplrs/cc2.11 -lmld' \
 948                 '-L/usr/lib/cmplrs/cc3.11 -lmld'
 949 do
 950         LIBS="$libs"
 951         AC_TRY_LINK_FUNC(ldopen,
 952                 [gcc_cv_collect2_libs="$libs"; break])
 953 done
 954 LIBS="$save_LIBS"
 955 test -z "$gcc_cv_collect2_libs" && gcc_cv_collect2_libs='none required'])
 956 case $gcc_cv_collect2_libs in
 957         "none required")        ;;
 958         *)      COLLECT2_LIBS=$gcc_cv_collect2_libs ;;
 959 esac
 960 AC_SUBST(COLLECT2_LIBS)
 961
 962 # When building Ada code on Alpha, we need exc_resume which is usually in
 963 # -lexc.  So test for it.
 964 save_LIBS="$LIBS"
 965 LIBS=
 966 AC_SEARCH_LIBS(exc_resume, exc)
 967 GNAT_LIBEXC="$LIBS"
 968 LIBS="$save_LIBS"
 969 AC_SUBST(GNAT_LIBEXC)
 970
 971 # Some systems put ldexp and frexp in libm instead of libc; assume
 972 # they're both in the same place.  jcf-dump needs them.
 973 save_LIBS="$LIBS"
 974 LIBS=
 975 AC_SEARCH_LIBS(ldexp, m)
 976 LDEXP_LIB="$LIBS"
 977 LIBS="$save_LIBS"
 978 AC_SUBST(LDEXP_LIB)
 979
 980 # Use <inttypes.h> only if it exists,
 981 # doesn't clash with <sys/types.h>, and declares intmax_t.
 982 AC_MSG_CHECKING(for inttypes.h)
 983 AC_CACHE_VAL(gcc_cv_header_inttypes_h,
 984 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 985 [[#include <sys/types.h>
 986 #include <inttypes.h>]],
 987   [[intmax_t i = -1;]])],
 988   [gcc_cv_header_inttypes_h=yes],
 989   [gcc_cv_header_inttypes_h=no])])
 990 AC_MSG_RESULT($gcc_cv_header_inttypes_h)
 991 if test $gcc_cv_header_inttypes_h = yes; then
 992   AC_DEFINE(HAVE_INTTYPES_H, 1,
 993         [Define if you have a working <inttypes.h> header file.])
 994 fi
 995
 996 dnl Disabled until we have a complete test for buggy enum bitfields.
 997 dnl gcc_AC_C_ENUM_BF_UNSIGNED
 998
 999 define(gcc_UNLOCKED_FUNCS, clearerr_unlocked feof_unlocked dnl
1000   ferror_unlocked fflush_unlocked fgetc_unlocked fgets_unlocked dnl
1001   fileno_unlocked fprintf_unlocked fputc_unlocked fputs_unlocked dnl
1002   fread_unlocked fwrite_unlocked getchar_unlocked getc_unlocked dnl
1003   putchar_unlocked putc_unlocked)
1004 AC_CHECK_FUNCS(times clock kill getrlimit setrlimit atoll atoq \
1005         sysconf strsignal getrusage nl_langinfo \
1006         gettimeofday mbstowcs wcswidth mmap mincore setlocale \
1007         gcc_UNLOCKED_FUNCS)
1008
1009 if test x$ac_cv_func_mbstowcs = xyes; then
1010   AC_CACHE_CHECK(whether mbstowcs works, gcc_cv_func_mbstowcs_works,
1011 [    AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdlib.h>
1012 int main()
1013 {
1014   mbstowcs(0, "", 0);
1015   return 0;
1016 }]])],
1017     [gcc_cv_func_mbstowcs_works=yes],
1018     [gcc_cv_func_mbstowcs_works=no],
1019     [gcc_cv_func_mbstowcs_works=yes])])
1020   if test x$gcc_cv_func_mbstowcs_works = xyes; then
1021     AC_DEFINE(HAVE_WORKING_MBSTOWCS, 1,
1022   [Define this macro if mbstowcs does not crash when its
1023    first argument is NULL.])
1024   fi
1025 fi
1026
1027 AC_CHECK_TYPE(ssize_t, int)
1028 AC_CHECK_TYPE(caddr_t, char *)
1029
1030 gcc_AC_FUNC_MMAP_BLACKLIST
1031
1032 case "${host}" in
1033 *-*-*vms*)
1034   # Under VMS, vfork works very differently than on Unix. The standard test
1035   # won't work, and it isn't easily adaptable. It makes more sense to
1036   # just force it.
1037   ac_cv_func_vfork_works=yes
1038   ;;
1039 esac
1040 AC_FUNC_FORK
1041
1042 AM_ICONV
1043 # Until we have in-tree GNU iconv:
1044 LIBICONV_DEP=
1045 AC_SUBST(LIBICONV_DEP)
1046
1047 AM_LC_MESSAGES
1048
1049 AM_LANGINFO_CODESET
1050
1051 # We will need to find libiberty.h and ansidecl.h
1052 saved_CFLAGS="$CFLAGS"
1053 CFLAGS="$CFLAGS -I${srcdir} -I${srcdir}/../include"
1054 gcc_AC_CHECK_DECLS(getenv atol asprintf sbrk abort atof getcwd getwd \
1055         strsignal strstr strverscmp \
1056         errno snprintf vsnprintf vasprintf malloc realloc calloc \
1057         free basename getopt clock getpagesize gcc_UNLOCKED_FUNCS, , ,[
1058 #include "ansidecl.h"
1059 #include "system.h"])
1060
1061 gcc_AC_CHECK_DECLS(getrlimit setrlimit getrusage, , ,[
1062 #include "ansidecl.h"
1063 #include "system.h"
1064 #ifdef HAVE_SYS_RESOURCE_H
1065 #include <sys/resource.h>
1066 #endif
1067 ])
1068
1069 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1070 #include "ansidecl.h"
1071 #include "system.h"
1072 #ifdef HAVE_SYS_RESOURCE_H
1073 #include <sys/resource.h>
1074 #endif
1075 ]], [[rlim_t l = 0;]])],[],[AC_DEFINE([rlim_t],[long],
1076 [Define to `long' if <sys/resource.h> doesn't define.])])
1077
1078 # On AIX 5.2, <ldfcn.h> conflicts with <fcntl.h>, as both define incompatible
1079 # FREAD and FWRITE macros.  Fortunately, for GCC's single usage of ldgetname
1080 # in collect2.c, <fcntl.h> isn't visible, but the configure test below needs
1081 # to undef these macros to get the correct value for HAVE_DECL_LDGETNAME.
1082 gcc_AC_CHECK_DECLS(ldgetname, , ,[
1083 #include "ansidecl.h"
1084 #include "system.h"
1085 #ifdef HAVE_LDFCN_H
1086 #undef FREAD
1087 #undef FWRITE
1088 #include <ldfcn.h>
1089 #endif
1090 ])
1091
1092 gcc_AC_CHECK_DECLS(times, , ,[
1093 #include "ansidecl.h"
1094 #include "system.h"
1095 #ifdef HAVE_SYS_TIMES_H
1096 #include <sys/times.h>
1097 #endif
1098 ])
1099
1100 gcc_AC_CHECK_DECLS(sigaltstack, , ,[
1101 #include "ansidecl.h"
1102 #include "system.h"
1103 #include <signal.h>
1104 ])
1105
1106 # More time-related stuff.
1107 AC_CACHE_CHECK(for struct tms, ac_cv_struct_tms, [
1108 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1109 #include "ansidecl.h"
1110 #include "system.h"
1111 #ifdef HAVE_SYS_TIMES_H
1112 #include <sys/times.h>
1113 #endif
1114 ]], [[struct tms tms;]])],[ac_cv_struct_tms=yes],[ac_cv_struct_tms=no])])
1115 if test $ac_cv_struct_tms = yes; then
1116   AC_DEFINE(HAVE_STRUCT_TMS, 1,
1117   [Define if <sys/times.h> defines struct tms.])
1118 fi
1119
1120 # use gcc_cv_* here because this doesn't match the behavior of AC_CHECK_TYPE.
1121 # revisit after autoconf 2.50.
1122 AC_CACHE_CHECK(for clock_t, gcc_cv_type_clock_t, [
1123 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1124 #include "ansidecl.h"
1125 #include "system.h"
1126 ]], [[clock_t x;]])],[gcc_cv_type_clock_t=yes],[gcc_cv_type_clock_t=no])])
1127 if test $gcc_cv_type_clock_t = yes; then
1128   AC_DEFINE(HAVE_CLOCK_T, 1,
1129   [Define if <time.h> defines clock_t.])
1130 fi
1131
1132 # Restore CFLAGS from before the gcc_AC_NEED_DECLARATIONS tests.
1133 CFLAGS="$saved_CFLAGS"
1134
1135 gcc_AC_INITFINI_ARRAY
1136
1137 # mkdir takes a single argument on some systems.
1138 gcc_AC_FUNC_MKDIR_TAKES_ONE_ARG
1139
1140 # File extensions
1141 manext='.1'
1142 objext='.o'
1143 AC_SUBST(manext)
1144 AC_SUBST(objext)
1145
1146 # With Setjmp/Longjmp based exception handling.
1147 AC_ARG_ENABLE(sjlj-exceptions,
1148 [  --enable-sjlj-exceptions
1149                           arrange to use setjmp/longjmp exception handling],
1150 [case $target in
1151   *-*-hpux10*)
1152     if test $enableval != yes; then
1153       AC_MSG_WARN([dwarf2 exceptions not supported, sjlj exceptions forced])
1154       enableval=yes
1155     fi
1156     ;;
1157 esac
1158 force_sjlj_exceptions=yes],
1159 [case $target in
1160   *-*-hpux10*)
1161     force_sjlj_exceptions=yes
1162     enableval=yes
1163     ;;
1164   *)
1165     force_sjlj_exceptions=no
1166     ;;
1167 esac])
1168 if test $force_sjlj_exceptions = yes; then
1169   sjlj=`if test $enableval = yes; then echo 1; else echo 0; fi`
1170   AC_DEFINE_UNQUOTED(CONFIG_SJLJ_EXCEPTIONS, $sjlj,
1171     [Define 0/1 to force the choice for exception handling model.])
1172 fi
1173
1174 # For platforms with the unwind ABI which includes an unwind library,
1175 # libunwind, we can choose to use the system libunwind.
1176 # config.gcc also contains tests of with_system_libunwind.
1177 GCC_CHECK_UNWIND_GETIPINFO
1178
1179 # --------------------------------------------------------
1180 # Build, host, and target specific configuration fragments
1181 # --------------------------------------------------------
1182
1183 # Collect build-machine-specific information.
1184 . ${srcdir}/config.build
1185
1186 # Collect host-machine-specific information.
1187 . ${srcdir}/config.host
1188
1189 target_gtfiles=
1190
1191 # Collect target-machine-specific information.
1192 . ${srcdir}/config.gcc
1193
1194 extra_objs="${host_extra_objs} ${extra_objs}"
1195 extra_gcc_objs="${host_extra_gcc_objs} ${extra_gcc_objs}"
1196
1197 # Default the target-machine variables that were not explicitly set.
1198 if test x"$tm_file" = x
1199 then tm_file=$cpu_type/$cpu_type.h; fi
1200
1201 if test x"$extra_headers" = x
1202 then extra_headers=; fi
1203
1204 if test x$md_file = x
1205 then md_file=$cpu_type/$cpu_type.md; fi
1206
1207 if test x$out_file = x
1208 then out_file=$cpu_type/$cpu_type.c; fi
1209
1210 if test x"$tmake_file" = x
1211 then tmake_file=$cpu_type/t-$cpu_type
1212 fi
1213
1214 if test x"$dwarf2" = xyes
1215 then tm_file="$tm_file tm-dwarf2.h"
1216 fi
1217
1218 # Say what files are being used for the output code and MD file.
1219 echo "Using \`$srcdir/config/$out_file' for machine-specific logic."
1220 echo "Using \`$srcdir/config/$md_file' as machine description file."
1221
1222 # If any of the xm_file variables contain nonexistent files, warn
1223 # about them and drop them.
1224
1225 bx=
1226 for x in $build_xm_file; do
1227   if    test -f $srcdir/config/$x
1228   then      bx="$bx $x"
1229   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1230   fi
1231 done
1232 build_xm_file="$bx"
1233
1234 hx=
1235 for x in $host_xm_file; do
1236   if    test -f $srcdir/config/$x
1237   then      hx="$hx $x"
1238   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1239   fi
1240 done
1241 host_xm_file="$hx"
1242
1243 tx=
1244 for x in $xm_file; do
1245   if    test -f $srcdir/config/$x
1246   then      tx="$tx $x"
1247   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1248   fi
1249 done
1250 xm_file="$tx"
1251
1252 count=a
1253 for f in $tm_file; do
1254         count=${count}x
1255 done
1256 if test $count = ax; then
1257         echo "Using \`$srcdir/config/$tm_file' as target machine macro file."
1258 else
1259         echo "Using the following target machine macro files:"
1260         for f in $tm_file; do
1261                 echo "  $srcdir/config/$f"
1262         done
1263 fi
1264
1265 if test x$need_64bit_hwint = xyes; then
1266         AC_DEFINE(NEED_64BIT_HOST_WIDE_INT, 1,
1267 [Define to 1 if HOST_WIDE_INT must be 64 bits wide (see hwint.h).])
1268 fi
1269
1270 if test x$use_long_long_for_widest_fast_int = xyes; then
1271         AC_DEFINE(USE_LONG_LONG_FOR_WIDEST_FAST_INT, 1,
1272 [Define to 1 if the 'long long' (or '__int64') is wider than 'long' but still
1273 efficiently supported by the host hardware.])
1274 fi
1275
1276 count=a
1277 for f in $host_xm_file; do
1278         count=${count}x
1279 done
1280 if test $count = a; then
1281         :
1282 elif test $count = ax; then
1283         echo "Using \`$srcdir/config/$host_xm_file' as host machine macro file."
1284 else
1285         echo "Using the following host machine macro files:"
1286         for f in $host_xm_file; do
1287                 echo "  $srcdir/config/$f"
1288         done
1289 fi
1290 echo "Using ${out_host_hook_obj} for host machine hooks."
1291
1292 if test "$host_xm_file" != "$build_xm_file"; then
1293         count=a
1294         for f in $build_xm_file; do
1295                 count=${count}x
1296         done
1297         if test $count = a; then
1298                 :
1299         elif test $count = ax; then
1300                 echo "Using \`$srcdir/config/$build_xm_file' as build machine macro file."
1301         else
1302                 echo "Using the following build machine macro files:"
1303                 for f in $build_xm_file; do
1304                         echo "  $srcdir/config/$f"
1305                 done
1306         fi
1307 fi
1308
1309 case ${host} in
1310   powerpc*-*-darwin*)
1311     AC_CACHE_CHECK([whether mcontext_t fields have underscores],
1312       gcc_cv_mcontext_underscores,
1313       AC_COMPILE_IFELSE([
1314 #include <sys/cdefs.h>
1315 #include <sys/signal.h>
1316 #include <ucontext.h>
1317 int main() { mcontext_t m; if (m->ss.srr0) return 0; return 0; }
1318 ],
1319         gcc_cv_mcontext_underscores=no, gcc_cv_mcontext_underscores=yes))
1320       if test $gcc_cv_mcontext_underscores = yes; then
1321         AC_DEFINE(HAS_MCONTEXT_T_UNDERSCORES,,dnl
1322           [mcontext_t fields start with __])
1323       fi
1324     ;;
1325 esac
1326
1327 # ---------
1328 # Threading
1329 # ---------
1330
1331 # Check if a valid thread package
1332 case ${enable_threads} in
1333   "" | no)
1334     # No threads
1335     target_thread_file='single'
1336     ;;
1337   yes)
1338     # default
1339     target_thread_file='single'
1340     ;;
1341   aix | dce | gnat | irix | posix | posix95 | rtems | \
1342   single | solaris | vxworks | win32 | mipssde)
1343     target_thread_file=${enable_threads}
1344     ;;
1345   *)
1346     echo "${enable_threads} is an unknown thread package" 1>&2
1347     exit 1
1348     ;;
1349 esac
1350
1351 if test x${thread_file} = x; then
1352   # No thread file set by target-specific clauses in config.gcc,
1353   # so use file chosen by default logic above
1354   thread_file=${target_thread_file}
1355 fi
1356
1357 # Make gthr-default.h if we have a thread file.
1358 gthread_flags=
1359 if test $thread_file != single; then
1360   echo "#include \"gthr-${thread_file}.h\"" > gthr-default.h-t
1361   if diff gthr-default.h-t gthr-default.h 2>/dev/null; then
1362     rm -f gthr-default.h-t
1363   else
1364     mv -f gthr-default.h-t gthr-default.h
1365   fi
1366   gthread_flags=-DHAVE_GTHR_DEFAULT
1367 fi
1368 AC_SUBST(gthread_flags)
1369
1370 # --------
1371 # UNSORTED
1372 # --------
1373
1374 use_cxa_atexit=no
1375 if test x$enable___cxa_atexit = xyes || \
1376    test x$enable___cxa_atexit = x -a x$default_use_cxa_atexit = xyes; then
1377   if test x$host = x$target; then
1378     case $host in
1379       # mingw32 doesn't have __cxa_atexit but uses atexit registration
1380       # keyed to flag_use_cxa_atexit
1381       *-*-mingw32*)
1382         use_cxa_atexit=yes
1383         ;;
1384       *)
1385         AC_CHECK_FUNC(__cxa_atexit,[use_cxa_atexit=yes],
1386           [echo "__cxa_atexit can't be enabled on this target"])
1387         ;;
1388     esac
1389   else
1390     # We can't check for __cxa_atexit when building a cross, so assume
1391     # it is available
1392     use_cxa_atexit=yes
1393   fi
1394   if test x$use_cxa_atexit = xyes; then
1395     AC_DEFINE(DEFAULT_USE_CXA_ATEXIT, 2,
1396       [Define if you want to use __cxa_atexit, rather than atexit, to
1397       register C++ destructors for local statics and global objects.
1398       This is essential for fully standards-compliant handling of
1399       destructors, but requires __cxa_atexit in libc.])
1400   fi
1401 fi
1402
1403 # Look for a file containing extra machine modes.
1404 if test -n "$extra_modes" && test -f $srcdir/config/$extra_modes; then
1405   extra_modes_file='$(srcdir)'/config/${extra_modes}
1406   AC_SUBST(extra_modes_file)
1407   AC_DEFINE_UNQUOTED(EXTRA_MODES_FILE, "config/$extra_modes",
1408   [Define to the name of a file containing a list of extra machine modes
1409    for this architecture.])
1410 fi
1411
1412 # Convert extra_options into a form suitable for Makefile use.
1413 extra_opt_files=
1414 for f in $extra_options; do
1415   extra_opt_files="$extra_opt_files \$(srcdir)/config/$f"
1416 done
1417 AC_SUBST(extra_opt_files)
1418
1419 # auto-host.h is the file containing items generated by autoconf and is
1420 # the first file included by config.h.
1421 # If host=build, it is correct to have bconfig include auto-host.h
1422 # as well.  If host!=build, we are in error and need to do more
1423 # work to find out the build config parameters.
1424 if test x$host = x$build
1425 then
1426         build_auto=auto-host.h
1427 else
1428         # We create a subdir, then run autoconf in the subdir.
1429         # To prevent recursion we set host and build for the new
1430         # invocation of configure to the build for this invocation
1431         # of configure.
1432         tempdir=build.$$
1433         rm -rf $tempdir
1434         mkdir $tempdir
1435         cd $tempdir
1436         case ${srcdir} in
1437         /* | [A-Za-z]:[\\/]* ) realsrcdir=${srcdir};;
1438         *) realsrcdir=../${srcdir};;
1439         esac
1440         saved_CFLAGS="${CFLAGS}"
1441         CC="${CC_FOR_BUILD}" CFLAGS="${CFLAGS_FOR_BUILD}" \
1442         LDFLAGS="${LDFLAGS_FOR_BUILD}" \
1443         ${realsrcdir}/configure \
1444                 --enable-languages=${enable_languages-all} \
1445                 --target=$target_alias --host=$build_alias --build=$build_alias
1446         CFLAGS="${saved_CFLAGS}"
1447
1448         # We just finished tests for the build machine, so rename
1449         # the file auto-build.h in the gcc directory.
1450         mv auto-host.h ../auto-build.h
1451         cd ..
1452         rm -rf $tempdir
1453         build_auto=auto-build.h
1454 fi
1455 AC_SUBST(build_subdir)
1456
1457 tm_file="${tm_file} defaults.h"
1458 tm_p_file="${tm_p_file} tm-preds.h"
1459 host_xm_file="auto-host.h ansidecl.h ${host_xm_file}"
1460 build_xm_file="${build_auto} ansidecl.h ${build_xm_file}"
1461 # We don't want ansidecl.h in target files, write code there in ISO/GNU C.
1462 # put this back in temporarily.
1463 xm_file="auto-host.h ansidecl.h ${xm_file}"
1464
1465 # --------
1466 # UNSORTED
1467 # --------
1468
1469 changequote(,)dnl
1470 # Compile in configure arguments.
1471 if test -f configargs.h ; then
1472         # Being re-configured.
1473         gcc_config_arguments=`grep configuration_arguments configargs.h | sed -e 's/.*"\([^"]*\)".*/\1/'`
1474         gcc_config_arguments="$gcc_config_arguments : (reconfigured) $TOPLEVEL_CONFIGURE_ARGUMENTS"
1475 else
1476         gcc_config_arguments="$TOPLEVEL_CONFIGURE_ARGUMENTS"
1477 fi
1478
1479 # Double all backslashes and backslash all quotes to turn
1480 # gcc_config_arguments into a C string.
1481 sed -e 's/\\/\\\\/g; s/"/\\"/g' <<EOF >conftest.out
1482 $gcc_config_arguments
1483 EOF
1484 gcc_config_arguments_str=`cat conftest.out`
1485 rm -f conftest.out
1486
1487 cat > configargs.h <<EOF
1488 /* Generated automatically. */
1489 static const char configuration_arguments[] = "$gcc_config_arguments_str";
1490 static const char thread_model[] = "$thread_file";
1491
1492 static const struct {
1493   const char *name, *value;
1494 } configure_default_options[] = $configure_default_options;
1495 EOF
1496 changequote([,])dnl
1497
1498 # Internationalization
1499 ZW_GNU_GETTEXT_SISTER_DIR
1500
1501 # If LIBINTL contains LIBICONV, then clear LIBICONV so we don't get
1502 # -liconv on the link line twice.
1503 case "$LIBINTL" in *$LIBICONV*)
1504         LIBICONV= ;;
1505 esac
1506
1507 AC_ARG_ENABLE(secureplt,
1508 [  --enable-secureplt      enable -msecure-plt by default for PowerPC],
1509 [], [])
1510
1511 AC_ARG_ENABLE(cld,
1512 [  --enable-cld            enable -mcld by default for 32bit x86], [],
1513 [enable_cld=no])
1514
1515 # Windows32 Registry support for specifying GCC installation paths.
1516 AC_ARG_ENABLE(win32-registry,
1517 [  --disable-win32-registry
1518                           disable lookup of installation paths in the
1519                           Registry on Windows hosts
1520   --enable-win32-registry enable registry lookup (default)
1521   --enable-win32-registry=KEY
1522                           use KEY instead of GCC version as the last portion
1523                           of the registry key],,)
1524
1525 case $host_os in
1526   win32 | pe | cygwin* | mingw32* | uwin*)
1527     if test "x$enable_win32_registry" != xno; then
1528       AC_SEARCH_LIBS(RegOpenKeyExA, advapi32,, [enable_win32_registry=no])
1529     fi
1530
1531     if test "x$enable_win32_registry" != xno; then
1532       AC_DEFINE(ENABLE_WIN32_REGISTRY, 1,
1533   [Define to 1 if installation paths should be looked up in the Windows
1534    Registry. Ignored on non-Windows hosts.])
1535
1536       if test "x$enable_win32_registry" != xyes \
1537          && test "x$enable_win32_registry" != x; then
1538         AC_DEFINE_UNQUOTED(WIN32_REGISTRY_KEY, "$enable_win32_registry",
1539   [Define to be the last component of the Windows registry key under which
1540    to look for installation paths.  The full key used will be
1541    HKEY_LOCAL_MACHINE/SOFTWARE/Free Software Foundation/{WIN32_REGISTRY_KEY}.
1542    The default is the GCC version number.])
1543       fi
1544     fi
1545   ;;
1546 esac
1547
1548 # Get an absolute path to the GCC top-level source directory
1549 holddir=`${PWDCMD-pwd}`
1550 cd $srcdir
1551 topdir=`${PWDCMD-pwd}`
1552 cd $holddir
1553
1554 # Conditionalize the makefile for this host machine.
1555 xmake_file=
1556 for f in ${host_xmake_file}
1557 do
1558         if test -f ${srcdir}/config/$f
1559         then
1560                 xmake_file="${xmake_file} \$(srcdir)/config/$f"
1561         fi
1562 done
1563
1564 # Conditionalize the makefile for this target machine.
1565 tmake_file_=
1566 for f in ${tmake_file}
1567 do
1568         if test -f ${srcdir}/config/$f
1569         then
1570                 tmake_file_="${tmake_file_} \$(srcdir)/config/$f"
1571         fi
1572 done
1573 tmake_file="${tmake_file_}"
1574
1575 out_object_file=`basename $out_file .c`.o
1576
1577 tm_file_list="options.h"
1578 tm_include_list="options.h"
1579 for f in $tm_file; do
1580   case $f in
1581     ./* )
1582        f=`echo $f | sed 's/^..//'`
1583        tm_file_list="${tm_file_list} $f"
1584        tm_include_list="${tm_include_list} $f"
1585        ;;
1586     defaults.h )
1587        tm_file_list="${tm_file_list} \$(srcdir)/$f"
1588        tm_include_list="${tm_include_list} $f"
1589        ;;
1590     * )
1591        tm_file_list="${tm_file_list} \$(srcdir)/config/$f"
1592        tm_include_list="${tm_include_list} config/$f"
1593        ;;
1594   esac
1595 done
1596
1597 tm_p_file_list=
1598 tm_p_include_list=
1599 for f in $tm_p_file; do
1600   case $f in
1601     tm-preds.h )
1602        tm_p_file_list="${tm_p_file_list} $f"
1603        tm_p_include_list="${tm_p_include_list} $f"
1604        ;;
1605     * )
1606        tm_p_file_list="${tm_p_file_list} \$(srcdir)/config/$f"
1607        tm_p_include_list="${tm_p_include_list} config/$f"
1608   esac
1609 done
1610
1611 xm_file_list=
1612 xm_include_list=
1613 for f in $xm_file; do
1614   case $f in
1615     ansidecl.h )
1616        xm_file_list="${xm_file_list} \$(srcdir)/../include/$f"
1617        xm_include_list="${xm_include_list} $f"
1618        ;;
1619     auto-host.h )
1620        xm_file_list="${xm_file_list} $f"
1621        xm_include_list="${xm_include_list} $f"
1622        ;;
1623     * )
1624        xm_file_list="${xm_file_list} \$(srcdir)/config/$f"
1625        xm_include_list="${xm_include_list} config/$f"
1626        ;;
1627   esac
1628 done
1629
1630 host_xm_file_list=
1631 host_xm_include_list=
1632 for f in $host_xm_file; do
1633   case $f in
1634     ansidecl.h )
1635        host_xm_file_list="${host_xm_file_list} \$(srcdir)/../include/$f"
1636        host_xm_include_list="${host_xm_include_list} $f"
1637        ;;
1638     auto-host.h )
1639        host_xm_file_list="${host_xm_file_list} $f"
1640        host_xm_include_list="${host_xm_include_list} $f"
1641        ;;
1642     * )
1643        host_xm_file_list="${host_xm_file_list} \$(srcdir)/config/$f"
1644        host_xm_include_list="${host_xm_include_list} config/$f"
1645        ;;
1646   esac
1647 done
1648
1649 build_xm_file_list=
1650 for f in $build_xm_file; do
1651   case $f in
1652     ansidecl.h )
1653        build_xm_file_list="${build_xm_file_list} \$(srcdir)/../include/$f"
1654        build_xm_include_list="${build_xm_include_list} $f"
1655        ;;
1656     auto-build.h | auto-host.h )
1657        build_xm_file_list="${build_xm_file_list} $f"
1658        build_xm_include_list="${build_xm_include_list} $f"
1659        ;;
1660     * )
1661        build_xm_file_list="${build_xm_file_list} \$(srcdir)/config/$f"
1662        build_xm_include_list="${build_xm_include_list} config/$f"
1663        ;;
1664   esac
1665 done
1666
1667 # Define macro CROSS_DIRECTORY_STRUCTURE in compilation if this is a
1668 # cross-compiler which does not use the native headers and libraries.
1669 # Also use all.cross instead of all.internal and adjust SYSTEM_HEADER_DIR.
1670 CROSS=                                          AC_SUBST(CROSS)
1671 ALL=all.internal                                AC_SUBST(ALL)
1672 SYSTEM_HEADER_DIR='$(NATIVE_SYSTEM_HEADER_DIR)' AC_SUBST(SYSTEM_HEADER_DIR)
1673
1674 if test "x$with_build_sysroot" != x; then
1675   build_system_header_dir=$with_build_sysroot'$${sysroot_headers_suffix}$(NATIVE_SYSTEM_HEADER_DIR)'
1676 else
1677   # This value is used, even on a native system, because
1678   # CROSS_SYSTEM_HEADER_DIR is just
1679   # $(TARGET_SYSTEM_ROOT)$(NATIVE_SYSTEM_HEADER_DIR).
1680   build_system_header_dir='$(CROSS_SYSTEM_HEADER_DIR)'
1681 fi
1682
1683 if test x$host != x$target
1684 then
1685         CROSS="-DCROSS_DIRECTORY_STRUCTURE"
1686         ALL=all.cross
1687         SYSTEM_HEADER_DIR=$build_system_header_dir
1688         case "$host","$target" in
1689         # Darwin crosses can use the host system's libraries and headers,
1690         # because of the fat library support.  Of course, it must be the
1691         # same version of Darwin on both sides.  Allow the user to
1692         # just say --target=foo-darwin without a version number to mean
1693         # "the version on this system".
1694             *-*-darwin*,*-*-darwin*)
1695                 hostos=`echo $host | sed 's/.*-darwin/darwin/'`
1696                 targetos=`echo $target | sed 's/.*-darwin/darwin/'`
1697                 if test $hostos = $targetos -o $targetos = darwin ; then
1698                     CROSS=
1699                     SYSTEM_HEADER_DIR='$(NATIVE_SYSTEM_HEADER_DIR)'
1700                     with_headers=yes
1701                 fi
1702                 ;;
1703
1704             i?86-*-*,x86_64-*-* \
1705             | powerpc*-*-*,powerpc64*-*-*)
1706                 CROSS="$CROSS -DNATIVE_CROSS" ;;
1707         esac
1708 elif test "x$TARGET_SYSTEM_ROOT" != x; then
1709         SYSTEM_HEADER_DIR=$build_system_header_dir
1710 fi
1711
1712 # If this is a cross-compiler that does not
1713 # have its own set of headers then define
1714 # inhibit_libc
1715
1716 # If this is using newlib, without having the headers available now,
1717 # then define inhibit_libc in LIBGCC2_CFLAGS.
1718 # This prevents libgcc2 from containing any code which requires libc
1719 # support.
1720 : ${inhibit_libc=false}
1721 if { { test x$host != x$target && test "x$with_sysroot" = x ; } ||
1722        test x$with_newlib = xyes ; } &&
1723      { test "x$with_headers" = x || test "x$with_headers" = xno ; } ; then
1724        inhibit_libc=true
1725 fi
1726 AC_SUBST(inhibit_libc)
1727
1728 # When building gcc with a cross-compiler, we need to adjust things so
1729 # that the generator programs are still built with the native compiler.
1730 # Also, we cannot run fixincludes.
1731
1732 # These are the normal (build=host) settings:
1733 CC_FOR_BUILD='$(CC)'            AC_SUBST(CC_FOR_BUILD)
1734 BUILD_CFLAGS='$(ALL_CFLAGS)'    AC_SUBST(BUILD_CFLAGS)
1735 BUILD_LDFLAGS='$(LDFLAGS)'      AC_SUBST(BUILD_LDFLAGS)
1736 STMP_FIXINC=stmp-fixinc         AC_SUBST(STMP_FIXINC)
1737
1738 # And these apply if build != host, or we are generating coverage data
1739 if test x$build != x$host || test "x$coverage_flags" != x
1740 then
1741     BUILD_CFLAGS='$(INTERNAL_CFLAGS) $(T_CFLAGS) $(CFLAGS_FOR_BUILD)'
1742     BUILD_LDFLAGS='$(LDFLAGS_FOR_BUILD)'
1743 fi
1744
1745 # Expand extra_headers to include complete path.
1746 # This substitutes for lots of t-* files.
1747 extra_headers_list=
1748 # Prepend $(srcdir)/config/${cpu_type}/ to every entry in extra_headers.
1749 for file in ${extra_headers} ; do
1750   extra_headers_list="${extra_headers_list} \$(srcdir)/config/${cpu_type}/${file}"
1751 done
1752
1753 # If use_gcc_tgmath is set, append ginclude/tgmath.h.
1754 if test x"$use_gcc_tgmath" = xyes
1755 then extra_headers_list="${extra_headers_list} \$(srcdir)/ginclude/tgmath.h"
1756 fi
1757
1758 # Define collect2 in Makefile.
1759 case $host_can_use_collect2 in
1760   no) collect2= ;;
1761   *) collect2='collect2$(exeext)' ;;
1762 esac
1763 AC_SUBST([collect2])
1764
1765 # Add a definition of USE_COLLECT2 if system wants one.
1766 case $use_collect2 in
1767   no) use_collect2= ;;
1768   "") ;;
1769   *)
1770     host_xm_defines="${host_xm_defines} USE_COLLECT2"
1771     xm_defines="${xm_defines} USE_COLLECT2"
1772     case $host_can_use_collect2 in
1773       no)
1774         AC_MSG_ERROR([collect2 is required but cannot be built on this system])
1775         ;;
1776     esac
1777     ;;
1778 esac
1779
1780 # ---------------------------
1781 # Assembler & linker features
1782 # ---------------------------
1783
1784 # During stage 2, ld is actually gcc/collect-ld, which is a small script to
1785 # discern between when to use prev-ld/ld-new and when to use ld/ld-new.
1786 # However when ld-new is first executed from the build tree, libtool will
1787 # relink it as .libs/lt-ld-new, so that it can give it an RPATH that refers
1788 # to the build tree.  While doing this we need to use the previous-stage
1789 # linker, or we have an infinite loop.  The presence of a shell script as
1790 # ld/ld-new, and the fact that the script *uses ld itself*, is what confuses
1791 # the gcc/collect-ld script.  So we need to know how libtool works, or
1792 # exec-tool will fail.
1793
1794 m4_defun([_LT_CONFIG_COMMANDS], [])
1795 AC_PROG_LIBTOOL
1796 AC_SUBST(objdir)
1797 AC_SUBST(enable_fast_install)
1798
1799 # Identify the assembler which will work hand-in-glove with the newly
1800 # built GCC, so that we can examine its features.  This is the assembler
1801 # which will be driven by the driver program.
1802 #
1803 # If build != host, and we aren't building gas in-tree, we identify a
1804 # build->target assembler and hope that it will have the same features
1805 # as the host->target assembler we'll be using.
1806 gcc_cv_gas_major_version=
1807 gcc_cv_gas_minor_version=
1808 gcc_cv_as_gas_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/gas
1809
1810 m4_pattern_allow([AS_FOR_TARGET])dnl
1811 AS_VAR_SET_IF(gcc_cv_as,, [
1812 if test -x "$DEFAULT_ASSEMBLER"; then
1813         gcc_cv_as="$DEFAULT_ASSEMBLER"
1814 elif test -f $gcc_cv_as_gas_srcdir/configure.in \
1815      && test -f ../gas/Makefile \
1816      && test x$build = x$host; then
1817         gcc_cv_as=../gas/as-new$build_exeext
1818 elif test -x as$build_exeext; then
1819         # Build using assembler in the current directory.
1820         gcc_cv_as=./as$build_exeext
1821 elif test -x $AS_FOR_TARGET; then
1822         gcc_cv_as="$AS_FOR_TARGET"
1823 else
1824         AC_PATH_PROG(gcc_cv_as, $AS_FOR_TARGET)
1825 fi])
1826
1827 ORIGINAL_AS_FOR_TARGET=$gcc_cv_as
1828 AC_SUBST(ORIGINAL_AS_FOR_TARGET)
1829 case "$ORIGINAL_AS_FOR_TARGET" in
1830   ./as | ./as$build_exeext) ;;
1831   *) AC_CONFIG_FILES(as:exec-tool.in, [chmod +x as]) ;;
1832 esac
1833
1834 AC_MSG_CHECKING(what assembler to use)
1835 if test "$gcc_cv_as" = ../gas/as-new$build_exeext; then
1836   # Single tree build which includes gas.  We want to prefer it
1837   # over whatever linker top-level may have detected, since
1838   # we'll use what we're building after installation anyway.
1839   AC_MSG_RESULT(newly built gas)
1840   in_tree_gas=yes
1841   _gcc_COMPUTE_GAS_VERSION
1842   in_tree_gas_is_elf=no
1843   if grep 'obj_format = elf' ../gas/Makefile > /dev/null \
1844      || (grep 'obj_format = multi' ../gas/Makefile \
1845          && grep 'extra_objects =.* obj-elf' ../gas/Makefile) > /dev/null
1846   then
1847     in_tree_gas_is_elf=yes
1848   fi
1849 else
1850   AC_MSG_RESULT($gcc_cv_as)
1851   in_tree_gas=no
1852 fi
1853
1854 # Identify the linker which will work hand-in-glove with the newly
1855 # built GCC, so that we can examine its features.  This is the linker
1856 # which will be driven by the driver program.
1857 #
1858 # If build != host, and we aren't building gas in-tree, we identify a
1859 # build->target linker and hope that it will have the same features
1860 # as the host->target linker we'll be using.
1861 gcc_cv_gld_major_version=
1862 gcc_cv_gld_minor_version=
1863 gcc_cv_ld_gld_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/ld
1864 gcc_cv_ld_bfd_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/bfd
1865
1866 AS_VAR_SET_IF(gcc_cv_ld,, [
1867 if test -x "$DEFAULT_LINKER"; then
1868         gcc_cv_ld="$DEFAULT_LINKER"
1869 elif test -f $gcc_cv_ld_gld_srcdir/configure.in \
1870      && test -f ../ld/Makefile \
1871      && test x$build = x$host; then
1872         gcc_cv_ld=../ld/ld-new$build_exeext
1873 elif test -x collect-ld$build_exeext; then
1874         # Build using linker in the current directory.
1875         gcc_cv_ld=./collect-ld$build_exeext
1876 elif test -x $LD_FOR_TARGET; then
1877         gcc_cv_ld="$LD_FOR_TARGET"
1878 else
1879         AC_PATH_PROG(gcc_cv_ld, $LD_FOR_TARGET)
1880 fi])
1881
1882 ORIGINAL_LD_FOR_TARGET=$gcc_cv_ld
1883 AC_SUBST(ORIGINAL_LD_FOR_TARGET)
1884 case "$ORIGINAL_LD_FOR_TARGET" in
1885   ./collect-ld | ./collect-ld$build_exeext) ;;
1886   *) AC_CONFIG_FILES(collect-ld:exec-tool.in, [chmod +x collect-ld]) ;;
1887 esac
1888
1889 AC_MSG_CHECKING(what linker to use)
1890 if test "$gcc_cv_ld" = ../ld/ld-new$build_exeext; then
1891         # Single tree build which includes ld.  We want to prefer it
1892         # over whatever linker top-level may have detected, since
1893         # we'll use what we're building after installation anyway.
1894         AC_MSG_RESULT(newly built ld)
1895         in_tree_ld=yes
1896         in_tree_ld_is_elf=no
1897         if (grep 'EMUL = .*elf' ../ld/Makefile \
1898             || grep 'EMUL = .*linux' ../ld/Makefile \
1899             || grep 'EMUL = .*lynx' ../ld/Makefile) > /dev/null; then
1900           in_tree_ld_is_elf=yes
1901         fi
1902         for f in $gcc_cv_ld_bfd_srcdir/configure $gcc_cv_ld_gld_srcdir/configure $gcc_cv_ld_gld_srcdir/configure.in $gcc_cv_ld_gld_srcdir/Makefile.in
1903         do
1904 changequote(,)dnl
1905                 gcc_cv_gld_version=`sed -n -e 's/^[     ]*\(VERSION=[0-9]*\.[0-9]*.*\)/\1/p' < $f`
1906                 if test x$gcc_cv_gld_version != x; then
1907                         break
1908                 fi
1909         done
1910         gcc_cv_gld_major_version=`expr "$gcc_cv_gld_version" : "VERSION=\([0-9]*\)"`
1911         gcc_cv_gld_minor_version=`expr "$gcc_cv_gld_version" : "VERSION=[0-9]*\.\([0-9]*\)"`
1912 changequote([,])dnl
1913 else
1914         AC_MSG_RESULT($gcc_cv_ld)
1915         in_tree_ld=no
1916 fi
1917
1918 # Figure out what nm we will be using.
1919 gcc_cv_binutils_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/binutils
1920 AS_VAR_SET_IF(gcc_cv_nm,, [
1921 if test -f $gcc_cv_binutils_srcdir/configure.in \
1922      && test -f ../binutils/Makefile \
1923      && test x$build = x$host; then
1924         gcc_cv_nm=../binutils/nm-new$build_exeext
1925 elif test -x nm$build_exeext; then
1926         gcc_cv_nm=./nm$build_exeext
1927 elif test -x $NM_FOR_TARGET; then
1928         gcc_cv_nm="$NM_FOR_TARGET"
1929 else
1930         AC_PATH_PROG(gcc_cv_nm, $NM_FOR_TARGET)
1931 fi])
1932
1933 AC_MSG_CHECKING(what nm to use)
1934 if test "$gcc_cv_nm" = ../binutils/nm-new$build_exeext; then
1935         # Single tree build which includes binutils.
1936         AC_MSG_RESULT(newly built nm)
1937         in_tree_nm=yes
1938 else
1939         AC_MSG_RESULT($gcc_cv_nm)
1940         in_tree_nm=no
1941 fi
1942
1943 ORIGINAL_NM_FOR_TARGET=$gcc_cv_nm
1944 AC_SUBST(ORIGINAL_NM_FOR_TARGET)
1945 case "$ORIGINAL_NM_FOR_TARGET" in
1946   ./nm | ./nm$build_exeext) ;;
1947   *) AC_CONFIG_FILES(nm:exec-tool.in, [chmod +x nm]) ;;
1948 esac
1949
1950
1951 # Figure out what objdump we will be using.
1952 AS_VAR_SET_IF(gcc_cv_objdump,, [
1953 if test -f $gcc_cv_binutils_srcdir/configure.in \
1954      && test -f ../binutils/Makefile \
1955      && test x$build = x$host; then
1956         # Single tree build which includes binutils.
1957         gcc_cv_objdump=../binutils/objdump$build_exeext
1958 elif test -x objdump$build_exeext; then
1959         gcc_cv_objdump=./objdump$build_exeext
1960 elif test -x $OBJDUMP_FOR_TARGET; then
1961         gcc_cv_objdump="$OBJDUMP_FOR_TARGET"
1962 else
1963         AC_PATH_PROG(gcc_cv_objdump, $OBJDUMP_FOR_TARGET)
1964 fi])
1965
1966 AC_MSG_CHECKING(what objdump to use)
1967 if test "$gcc_cv_objdump" = ../binutils/objdump$build_exeext; then
1968         # Single tree build which includes binutils.
1969         AC_MSG_RESULT(newly built objdump)
1970 elif test x$gcc_cv_objdump = x; then
1971         AC_MSG_RESULT(not found)
1972 else
1973         AC_MSG_RESULT($gcc_cv_objdump)
1974 fi
1975
1976 # Figure out what readelf we will be using.
1977 AS_VAR_SET_IF(gcc_cv_readelf,, [
1978 if test -f $gcc_cv_binutils_srcdir/configure.in \
1979      && test -f ../binutils/Makefile \
1980      && test x$build = x$host; then
1981         # Single tree build which includes binutils.
1982         gcc_cv_readelf=../binutils/readelf$build_exeext
1983 elif test -x readelf$build_exeext; then
1984         gcc_cv_readelf=./readelf$build_exeext
1985 else
1986         AC_PATH_PROG(gcc_cv_readelf, readelf)
1987 fi])
1988
1989 AC_MSG_CHECKING(what readelf to use)
1990 if test "$gcc_cv_readelf" = ../binutils/readelf$build_exeext; then
1991         # Single tree build which includes binutils.
1992         AC_MSG_RESULT(newly built readelf)
1993 elif test x$gcc_cv_readelf = x; then
1994         AC_MSG_RESULT(not found)
1995 else
1996         AC_MSG_RESULT($gcc_cv_readelf)
1997 fi
1998
1999 # Figure out what assembler alignment features are present.
2000 gcc_GAS_CHECK_FEATURE([.balign and .p2align], gcc_cv_as_balign_and_p2align,
2001  [2,6,0],,
2002 [.balign 4
2003 .p2align 2],,
2004 [AC_DEFINE(HAVE_GAS_BALIGN_AND_P2ALIGN, 1,
2005   [Define if your assembler supports .balign and .p2align.])])
2006
2007 gcc_GAS_CHECK_FEATURE([.p2align with maximum skip], gcc_cv_as_max_skip_p2align,
2008  [2,8,0],,
2009  [.p2align 4,,7],,
2010 [AC_DEFINE(HAVE_GAS_MAX_SKIP_P2ALIGN, 1,
2011   [Define if your assembler supports specifying the maximum number
2012    of bytes to skip when using the GAS .p2align command.])])
2013
2014 gcc_GAS_CHECK_FEATURE([.literal16], gcc_cv_as_literal16,
2015  [2,8,0],,
2016  [.literal16],,
2017 [AC_DEFINE(HAVE_GAS_LITERAL16, 1,
2018   [Define if your assembler supports .literal16.])])
2019
2020 gcc_GAS_CHECK_FEATURE([working .subsection -1], gcc_cv_as_subsection_m1,
2021  [elf,2,9,0],,
2022  [conftest_label1: .word 0
2023 .subsection -1
2024 conftest_label2: .word 0
2025 .previous],
2026  [if test x$gcc_cv_nm != x; then
2027     $gcc_cv_nm conftest.o | grep conftest_label1 > conftest.nm1
2028     $gcc_cv_nm conftest.o | grep conftest_label2 | sed -e 's/label2/label1/' > conftest.nm2
2029     if cmp conftest.nm1 conftest.nm2 > /dev/null 2>&1
2030     then :
2031     else gcc_cv_as_subsection_m1=yes
2032     fi
2033     rm -f conftest.nm1 conftest.nm2
2034   fi],
2035  [AC_DEFINE(HAVE_GAS_SUBSECTION_ORDERING, 1,
2036   [Define if your assembler supports .subsection and .subsection -1 starts
2037    emitting at the beginning of your section.])])
2038
2039 gcc_GAS_CHECK_FEATURE([.weak], gcc_cv_as_weak,
2040  [2,2,0],,
2041  [      .weak foobar],,
2042 [AC_DEFINE(HAVE_GAS_WEAK, 1, [Define if your assembler supports .weak.])])
2043
2044 gcc_GAS_CHECK_FEATURE([.weakref], gcc_cv_as_weakref,
2045  [2,17,0],,
2046  [      .weakref foobar, barfnot],,
2047 [AC_DEFINE(HAVE_GAS_WEAKREF, 1, [Define if your assembler supports .weakref.])])
2048
2049 gcc_GAS_CHECK_FEATURE([.nsubspa comdat], gcc_cv_as_nsubspa_comdat,
2050  [2,15,91],,
2051  [      .SPACE $TEXT$
2052         .NSUBSPA $CODE$,COMDAT],,
2053 [AC_DEFINE(HAVE_GAS_NSUBSPA_COMDAT, 1, [Define if your assembler supports .nsubspa comdat option.])])
2054
2055 # .hidden needs to be supported in both the assembler and the linker,
2056 # because GNU LD versions before 2.12.1 have buggy support for STV_HIDDEN.
2057 # This is irritatingly difficult to feature test for; we have to check the
2058 # date string after the version number.  If we've got an in-tree
2059 # ld, we don't know its patchlevel version, so we set the baseline at 2.13
2060 # to be safe.
2061 # The gcc_GAS_CHECK_FEATURE call just sets a cache variable.
2062 gcc_GAS_CHECK_FEATURE([.hidden], gcc_cv_as_hidden,
2063  [elf,2,13,0],,
2064 [       .hidden foobar
2065 foobar:])
2066
2067 AC_CACHE_CHECK(linker for .hidden support, gcc_cv_ld_hidden,
2068 [if test $in_tree_ld = yes ; then
2069   gcc_cv_ld_hidden=no
2070   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 13 -o "$gcc_cv_gld_major_version" -gt 2 \
2071      && test $in_tree_ld_is_elf = yes; then
2072      gcc_cv_ld_hidden=yes
2073   fi
2074 else
2075 changequote(,)dnl
2076   gcc_cv_ld_hidden=yes
2077   ld_ver=`$gcc_cv_ld --version 2>/dev/null | sed 1q`
2078   if echo "$ld_ver" | grep GNU > /dev/null; then
2079     ld_vers=`echo $ld_ver | sed -n \
2080         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*.*\)$,\1,p'`
2081     ld_date=`echo $ld_ver | sed -n 's,^.*\([2-9][0-9][0-9][0-9]\)[-]*\([01][0-9]\)[-]*\([0-3][0-9]\).*$,\1\2\3,p'`
2082     ld_vers_major=`expr "$ld_vers" : '\([0-9]*\)'`
2083     ld_vers_minor=`expr "$ld_vers" : '[0-9]*\.\([0-9]*\)'`
2084     ld_vers_patch=`expr "$ld_vers" : '[0-9]*\.[0-9]*\.\([0-9]*\)'`
2085     if test 0"$ld_date" -lt 20020404; then
2086       if test -n "$ld_date"; then
2087         # If there was date string, but was earlier than 2002-04-04, fail
2088         gcc_cv_ld_hidden=no
2089       elif test -z "$ld_vers"; then
2090         # If there was no date string nor ld version number, something is wrong
2091         gcc_cv_ld_hidden=no
2092       else
2093         test -z "$ld_vers_patch" && ld_vers_patch=0
2094         if test "$ld_vers_major" -lt 2; then
2095           gcc_cv_ld_hidden=no
2096         elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -lt 12; then
2097           gcc_cv_ld_hidden="no"
2098         elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -eq 12 -a "$ld_vers_patch" -eq 0; then
2099           gcc_cv_ld_hidden=no
2100         fi
2101       fi
2102     fi
2103   else
2104     case "${target}" in
2105       hppa64*-*-hpux* | ia64*-*-hpux*)
2106         gcc_cv_ld_hidden=yes
2107         ;;
2108       *-*-solaris2.9* | *-*-solaris2.1[0-9]*)
2109         gcc_cv_ld_hidden=yes
2110         ;;
2111       *)
2112         gcc_cv_ld_hidden=no
2113         ;;
2114     esac
2115   fi
2116 changequote([,])dnl
2117 fi])
2118 libgcc_visibility=no
2119 AC_SUBST(libgcc_visibility)
2120 GCC_TARGET_TEMPLATE([HAVE_GAS_HIDDEN])
2121 if test $gcc_cv_as_hidden = yes && test $gcc_cv_ld_hidden = yes; then
2122   libgcc_visibility=yes
2123   AC_DEFINE(HAVE_GAS_HIDDEN, 1,
2124   [Define if your assembler and linker support .hidden.])
2125 fi
2126
2127 AC_MSG_CHECKING(linker read-only and read-write section mixing)
2128 gcc_cv_ld_ro_rw_mix=unknown
2129 if test $in_tree_ld = yes ; then
2130   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 10 -o "$gcc_cv_gld_major_version" -gt 2 \
2131      && test $in_tree_ld_is_elf = yes; then
2132     gcc_cv_ld_ro_rw_mix=read-write
2133   fi
2134 elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x -a x$gcc_cv_objdump != x ; then
2135   echo '.section myfoosect, "a"' > conftest1.s
2136   echo '.section myfoosect, "aw"' > conftest2.s
2137   echo '.byte 1' >> conftest2.s
2138   echo '.section myfoosect, "a"' > conftest3.s
2139   echo '.byte 0' >> conftest3.s
2140   if $gcc_cv_as -o conftest1.o conftest1.s > /dev/null 2>&1 \
2141      && $gcc_cv_as -o conftest2.o conftest2.s > /dev/null 2>&1 \
2142      && $gcc_cv_as -o conftest3.o conftest3.s > /dev/null 2>&1 \
2143      && $gcc_cv_ld -shared -o conftest1.so conftest1.o \
2144         conftest2.o conftest3.o > /dev/null 2>&1; then
2145     gcc_cv_ld_ro_rw_mix=`$gcc_cv_objdump -h conftest1.so \
2146                          | sed -e '/myfoosect/!d' -e N`
2147     if echo "$gcc_cv_ld_ro_rw_mix" | grep CONTENTS > /dev/null; then
2148       if echo "$gcc_cv_ld_ro_rw_mix" | grep READONLY > /dev/null; then
2149         gcc_cv_ld_ro_rw_mix=read-only
2150       else
2151         gcc_cv_ld_ro_rw_mix=read-write
2152       fi
2153     fi
2154   fi
2155 changequote(,)dnl
2156   rm -f conftest.* conftest[123].*
2157 changequote([,])dnl
2158 fi
2159 if test x$gcc_cv_ld_ro_rw_mix = xread-write; then
2160         AC_DEFINE(HAVE_LD_RO_RW_SECTION_MIXING, 1,
2161   [Define if your linker links a mix of read-only
2162    and read-write sections into a read-write section.])
2163 fi
2164 AC_MSG_RESULT($gcc_cv_ld_ro_rw_mix)
2165
2166 # Check if we have .[us]leb128, and support symbol arithmetic with it.
2167 gcc_GAS_CHECK_FEATURE([.sleb128 and .uleb128], gcc_cv_as_leb128,
2168   [elf,2,11,0],,
2169 [       .data
2170         .uleb128 L2 - L1
2171 L1:
2172         .uleb128 1280
2173         .sleb128 -1010
2174 L2:],
2175  [# GAS versions before 2.11 do not support uleb128,
2176   # despite appearing to.
2177   # ??? There exists an elf-specific test that will crash
2178   # the assembler.  Perhaps it's better to figure out whether
2179   # arbitrary sections are supported and try the test.
2180   as_ver=`$gcc_cv_as --version 2>/dev/null | sed 1q`
2181   if echo "$as_ver" | grep GNU > /dev/null; then
2182 changequote(,)dnl
2183     as_vers=`echo $as_ver | sed -n \
2184         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*.*\)$,\1,p'`
2185     as_major=`expr "$as_vers" : '\([0-9]*\)'`
2186     as_minor=`expr "$as_vers" : '[0-9]*\.\([0-9]*\)'`
2187 changequote([,])dnl
2188     if test $as_major -eq 2 && test $as_minor -lt 11
2189     then :
2190     else gcc_cv_as_leb128=yes
2191     fi
2192   fi],
2193   [AC_DEFINE(HAVE_AS_LEB128, 1,
2194     [Define if your assembler supports .sleb128 and .uleb128.])])
2195
2196 # Check if we have assembler support for unwind directives.
2197 gcc_GAS_CHECK_FEATURE([cfi directives], gcc_cv_as_cfi_directive,
2198   ,,
2199 [       .text
2200         .cfi_startproc
2201         .cfi_offset 0, 0
2202         .cfi_same_value 1
2203         .cfi_def_cfa 1, 2
2204         .cfi_escape 1, 2, 3, 4, 5
2205         .cfi_endproc],
2206 [case "$target" in
2207   *-*-solaris*)
2208     # If the linker used on Solaris (like Sun ld) isn't capable of merging
2209     # read-only and read-write sections, we need to make sure that the
2210     # assembler used emits read-write .eh_frame sections.
2211     if test "x$gcc_cv_ld_ro_rw_mix" != xread-write; then
2212       if test "x$gcc_cv_objdump" != x; then
2213         if $gcc_cv_objdump -h conftest.o 2>/dev/null | \
2214                 sed -e /.eh_frame/!d -e N | grep READONLY > /dev/null; then
2215           gcc_cv_as_cfi_directive=no
2216         else
2217           gcc_cv_as_cfi_directive=yes
2218         fi
2219       else
2220         # no objdump, err on the side of caution
2221         gcc_cv_as_cfi_directive=no
2222       fi
2223     else
2224       gcc_cv_as_cfi_directive=yes
2225     fi
2226     ;;
2227   *-*-*)
2228     gcc_cv_as_cfi_directive=yes
2229     ;;
2230 esac])
2231 if test $gcc_cv_as_cfi_directive = yes && test x$gcc_cv_readelf != x; then
2232 gcc_GAS_CHECK_FEATURE([working cfi advance], gcc_cv_as_cfi_advance_working,
2233   ,,
2234 [       .text
2235         .cfi_startproc
2236         .cfi_adjust_cfa_offset 64
2237         .skip 512, 0
2238         .cfi_adjust_cfa_offset 128
2239         .cfi_endproc],
2240 [
2241 changequote(,)dnl
2242 if $gcc_cv_readelf -wf conftest.o 2>/dev/null \
2243     | grep 'DW_CFA_advance_loc[12]:[    ][      ]*512[  ]' >/dev/null; then
2244    gcc_cv_as_cfi_advance_working=yes
2245 fi
2246 changequote([,])dnl
2247 ])
2248 else
2249   # no readelf, err on the side of caution
2250   gcc_cv_as_cfi_advance_working=no
2251 fi
2252 AC_DEFINE_UNQUOTED(HAVE_GAS_CFI_DIRECTIVE,
2253   [`if test $gcc_cv_as_cfi_directive = yes \
2254        && test $gcc_cv_as_cfi_advance_working = yes; then echo 1; else echo 0; fi`],
2255   [Define 0/1 if your assembler supports CFI directives.])
2256
2257 gcc_GAS_CHECK_FEATURE([cfi personality directive],
2258   gcc_cv_as_cfi_personality_directive, ,,
2259 [       .text
2260         .cfi_startproc
2261         .cfi_personality 0, symbol
2262         .cfi_endproc])
2263 AC_DEFINE_UNQUOTED(HAVE_GAS_CFI_PERSONALITY_DIRECTIVE,
2264   [`if test $gcc_cv_as_cfi_personality_directive = yes;
2265     then echo 1; else echo 0; fi`],
2266   [Define 0/1 if your assembler supports .cfi_personality.])
2267
2268 # GAS versions up to and including 2.11.0 may mis-optimize
2269 # .eh_frame data.
2270 gcc_GAS_CHECK_FEATURE(eh_frame optimization, gcc_cv_as_eh_frame,
2271   [elf,2,12,0],,
2272 [       .text
2273 .LFB1:
2274         .4byte  0
2275 .L1:
2276         .4byte  0
2277 .LFE1:
2278         .section        .eh_frame,"aw",@progbits
2279 __FRAME_BEGIN__:
2280         .4byte  .LECIE1-.LSCIE1
2281 .LSCIE1:
2282         .4byte  0x0
2283         .byte   0x1
2284         .ascii "z\0"
2285         .byte   0x1
2286         .byte   0x78
2287         .byte   0x1a
2288         .byte   0x0
2289         .byte   0x4
2290         .4byte  1
2291         .p2align 1
2292 .LECIE1:
2293 .LSFDE1:
2294         .4byte  .LEFDE1-.LASFDE1
2295 .LASFDE1:
2296         .4byte  .LASFDE1-__FRAME_BEGIN__
2297         .4byte  .LFB1
2298         .4byte  .LFE1-.LFB1
2299         .byte   0x4
2300         .4byte  .LFE1-.LFB1
2301         .byte   0x4
2302         .4byte  .L1-.LFB1
2303 .LEFDE1:],
2304 [  dnl # For autoconf 2.5x, must protect trailing spaces with @&t@.
2305 cat > conftest.lit <<EOF
2306  0000 10000000 00000000 017a0001 781a0004  .........z..x...
2307  0010 01000000 12000000 18000000 00000000  ................
2308  0020 08000000 04080000 0044               .........D      @&t@
2309 EOF
2310 cat > conftest.big <<EOF
2311  0000 00000010 00000000 017a0001 781a0004  .........z..x...
2312  0010 00000001 00000012 00000018 00000000  ................
2313  0020 00000008 04000000 0844               .........D      @&t@
2314 EOF
2315   # If the assembler didn't choke, and we can objdump,
2316   # and we got the correct data, then succeed.
2317   # The text in the here-document typically retains its unix-style line
2318   # endings, while the output of objdump will use host line endings.
2319   # Therefore, use diff -b for the comparisons.
2320   if test x$gcc_cv_objdump != x \
2321   && $gcc_cv_objdump -s -j .eh_frame conftest.o 2>/dev/null \
2322      | tail -3 > conftest.got \
2323   && { diff -b conftest.lit conftest.got > /dev/null 2>&1 \
2324     || diff -b conftest.big conftest.got > /dev/null 2>&1; }
2325   then
2326     gcc_cv_as_eh_frame=yes
2327   elif AC_TRY_COMMAND($gcc_cv_as -o conftest.o --traditional-format /dev/null); then
2328     gcc_cv_as_eh_frame=buggy
2329   else
2330     # Uh oh, what do we do now?
2331     gcc_cv_as_eh_frame=no
2332   fi])
2333
2334 if test $gcc_cv_as_eh_frame = buggy; then
2335   AC_DEFINE(USE_AS_TRADITIONAL_FORMAT, 1,
2336   [Define if your assembler mis-optimizes .eh_frame data.])
2337 fi
2338
2339 gcc_GAS_CHECK_FEATURE(section merging support, gcc_cv_as_shf_merge,
2340  [elf,2,12,0], [--fatal-warnings],
2341  [.section .rodata.str, "aMS", @progbits, 1])
2342 if test $gcc_cv_as_shf_merge = no; then
2343   gcc_GAS_CHECK_FEATURE(section merging support, gcc_cv_as_shf_merge,
2344     [elf,2,12,0], [--fatal-warnings],
2345     [.section .rodata.str, "aMS", %progbits, 1])
2346 fi
2347 AC_DEFINE_UNQUOTED(HAVE_GAS_SHF_MERGE,
2348   [`if test $gcc_cv_as_shf_merge = yes; then echo 1; else echo 0; fi`],
2349 [Define 0/1 if your assembler supports marking sections with SHF_MERGE flag.])
2350
2351 gcc_GAS_CHECK_FEATURE(COMDAT group support, gcc_cv_as_comdat_group,
2352  [elf,2,16,0], [--fatal-warnings],
2353  [.section .text,"axG",@progbits,.foo,comdat])
2354 if test $gcc_cv_as_comdat_group = yes; then
2355   gcc_cv_as_comdat_group_percent=no
2356 else
2357  gcc_GAS_CHECK_FEATURE(COMDAT group support, gcc_cv_as_comdat_group_percent,
2358    [elf,2,16,0], [--fatal-warnings],
2359    [.section .text,"axG",%progbits,.foo,comdat])
2360 fi
2361 if test $in_tree_ld != yes && test x"$ld_vers" != x; then
2362   comdat_group=yes
2363   if test 0"$ld_date" -lt 20050308; then
2364     if test -n "$ld_date"; then
2365       # If there was date string, but was earlier than 2005-03-08, fail
2366       comdat_group=no
2367     elif test "$ld_vers_major" -lt 2; then
2368       comdat_group=no
2369     elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -lt 16; then
2370       comdat_group=no
2371     fi
2372   fi
2373 else
2374   # assume linkers other than GNU ld don't support COMDAT group
2375   comdat_group=no
2376 fi
2377 if test $comdat_group = no; then
2378   gcc_cv_as_comdat_group=no
2379   gcc_cv_as_comdat_group_percent=no
2380 fi
2381 AC_DEFINE_UNQUOTED(HAVE_COMDAT_GROUP,
2382   [`if test $gcc_cv_as_comdat_group = yes || test $gcc_cv_as_comdat_group_percent = yes; then echo 1; else echo 0; fi`],
2383 [Define 0/1 if your assembler and linker support COMDAT groups.])
2384
2385 # Thread-local storage - the check is heavily parameterized.
2386 conftest_s=
2387 tls_first_major=
2388 tls_first_minor=
2389 tls_as_opt=
2390 case "$target" in
2391 changequote(,)dnl
2392   alpha*-*-*)
2393     conftest_s='
2394         .section ".tdata","awT",@progbits
2395 foo:    .long   25
2396         .text
2397         ldq     $27,__tls_get_addr($29)         !literal!1
2398         lda     $16,foo($29)                    !tlsgd!1
2399         jsr     $26,($27),__tls_get_addr        !lituse_tlsgd!1
2400         ldq     $27,__tls_get_addr($29)         !literal!2
2401         lda     $16,foo($29)                    !tlsldm!2
2402         jsr     $26,($27),__tls_get_addr        !lituse_tlsldm!2
2403         ldq     $1,foo($29)                     !gotdtprel
2404         ldah    $2,foo($29)                     !dtprelhi
2405         lda     $3,foo($2)                      !dtprello
2406         lda     $4,foo($29)                     !dtprel
2407         ldq     $1,foo($29)                     !gottprel
2408         ldah    $2,foo($29)                     !tprelhi
2409         lda     $3,foo($2)                      !tprello
2410         lda     $4,foo($29)                     !tprel'
2411         tls_first_major=2
2412         tls_first_minor=13
2413         tls_as_opt=--fatal-warnings
2414         ;;
2415   cris-*-*|crisv32-*-*)
2416     conftest_s='
2417         .section ".tdata","awT",@progbits
2418 x:      .long   25
2419         .text
2420         move.d x:IE,$r10
2421         nop'
2422         tls_first_major=2
2423         tls_first_minor=20
2424         tls_as_opt=--fatal-warnings
2425         ;;
2426   frv*-*-*)
2427     conftest_s='
2428         .section ".tdata","awT",@progbits
2429 x:      .long   25
2430         .text
2431         call    #gettlsoff(x)'
2432         tls_first_major=2
2433         tls_first_minor=14
2434         ;;
2435   hppa*-*-linux*)
2436     conftest_s='
2437 t1:     .reg    %r20
2438 t2:     .reg    %r21
2439 gp:     .reg    %r19
2440         .section ".tdata","awT",@progbits
2441 foo:    .long   25
2442         .text
2443         .align  4
2444         addil LT%foo-$tls_gdidx$,gp
2445         ldo RT%foo-$tls_gdidx$(%r1),%arg0
2446         b __tls_get_addr
2447         nop
2448         addil LT%foo-$tls_ldidx$,gp
2449         b __tls_get_addr
2450         ldo RT%foo-$tls_ldidx$(%r1),%arg0
2451         addil LR%foo-$tls_dtpoff$,%ret0
2452         ldo RR%foo-$tls_dtpoff$(%r1),%t1
2453         mfctl %cr27,%t1
2454         addil LT%foo-$tls_ieoff$,gp
2455         ldw RT%foo-$tls_ieoff$(%r1),%t2
2456         add %t1,%t2,%t3
2457         mfctl %cr27,%t1
2458         addil LR%foo-$tls_leoff$,%t1
2459         ldo RR%foo-$tls_leoff$(%r1),%t2'
2460         tls_first_major=2
2461         tls_first_minor=15
2462         tls_as_opt=--fatal-warnings
2463         ;;
2464   arm*-*-*)
2465     conftest_s='
2466         .section ".tdata","awT",%progbits
2467 foo:    .long   25
2468         .text
2469 .word foo(gottpoff)
2470 .word foo(tpoff)
2471 .word foo(tlsgd)
2472 .word foo(tlsldm)
2473 .word foo(tlsldo)'
2474         tls_first_major=2
2475         tls_first_minor=17
2476         ;;
2477   i[34567]86-*-*)
2478     conftest_s='
2479         .section ".tdata","awT",@progbits
2480 foo:    .long   25
2481         .text
2482         movl    %gs:0, %eax
2483         leal    foo@TLSGD(,%ebx,1), %eax
2484         leal    foo@TLSLDM(%ebx), %eax
2485         leal    foo@DTPOFF(%eax), %edx
2486         movl    foo@GOTTPOFF(%ebx), %eax
2487         subl    foo@GOTTPOFF(%ebx), %eax
2488         addl    foo@GOTNTPOFF(%ebx), %eax
2489         movl    foo@INDNTPOFF, %eax
2490         movl    $foo@TPOFF, %eax
2491         subl    $foo@TPOFF, %eax
2492         leal    foo@NTPOFF(%ecx), %eax'
2493         tls_first_major=2
2494         tls_first_minor=14
2495         tls_as_opt=--fatal-warnings
2496         ;;
2497   x86_64-*-*)
2498     conftest_s='
2499         .section ".tdata","awT",@progbits
2500 foo:    .long   25
2501         .text
2502         movq    %fs:0, %rax
2503         leaq    foo@TLSGD(%rip), %rdi
2504         leaq    foo@TLSLD(%rip), %rdi
2505         leaq    foo@DTPOFF(%rax), %rdx
2506         movq    foo@GOTTPOFF(%rip), %rax
2507         movq    $foo@TPOFF, %rax'
2508         tls_first_major=2
2509         tls_first_minor=14
2510         tls_as_opt=--fatal-warnings
2511         ;;
2512   ia64-*-*)
2513     conftest_s='
2514         .section ".tdata","awT",@progbits
2515 foo:    data8   25
2516         .text
2517         addl    r16 = @ltoff(@dtpmod(foo#)), gp
2518         addl    r17 = @ltoff(@dtprel(foo#)), gp
2519         addl    r18 = @ltoff(@tprel(foo#)), gp
2520         addl    r19 = @dtprel(foo#), gp
2521         adds    r21 = @dtprel(foo#), r13
2522         movl    r23 = @dtprel(foo#)
2523         addl    r20 = @tprel(foo#), gp
2524         adds    r22 = @tprel(foo#), r13
2525         movl    r24 = @tprel(foo#)'
2526         tls_first_major=2
2527         tls_first_minor=13
2528         tls_as_opt=--fatal-warnings
2529         ;;
2530   mips*-*-*)
2531     conftest_s='
2532         .section .tdata,"awT",@progbits
2533 x:
2534         .word 2
2535         .text
2536         addiu $4, $28, %tlsgd(x)
2537         addiu $4, $28, %tlsldm(x)
2538         lui $4, %dtprel_hi(x)
2539         addiu $4, $4, %dtprel_lo(x)
2540         lw $4, %gottprel(x)($28)
2541         lui $4, %tprel_hi(x)
2542         addiu $4, $4, %tprel_lo(x)'
2543         tls_first_major=2
2544         tls_first_minor=16
2545         tls_as_opt='-32 --fatal-warnings'
2546         ;;
2547   powerpc-*-*)
2548     conftest_s='
2549         .section ".tdata","awT",@progbits
2550         .align 2
2551 ld0:    .space 4
2552 ld1:    .space 4
2553 x1:     .space 4
2554 x2:     .space 4
2555 x3:     .space 4
2556         .text
2557         addi 3,31,ld0@got@tlsgd
2558         bl __tls_get_addr
2559         addi 3,31,x1@got@tlsld
2560         bl __tls_get_addr
2561         addi 9,3,x1@dtprel
2562         addis 9,3,x2@dtprel@ha
2563         addi 9,9,x2@dtprel@l
2564         lwz 9,x3@got@tprel(31)
2565         add 9,9,x@tls
2566         addi 9,2,x1@tprel
2567         addis 9,2,x2@tprel@ha
2568         addi 9,9,x2@tprel@l'
2569         tls_first_major=2
2570         tls_first_minor=14
2571         tls_as_opt="-a32 --fatal-warnings"
2572         ;;
2573   powerpc64-*-*)
2574     conftest_s='
2575         .section ".tdata","awT",@progbits
2576         .align 3
2577 ld0:    .space 8
2578 ld1:    .space 8
2579 x1:     .space 8
2580 x2:     .space 8
2581 x3:     .space 8
2582         .text
2583         addi 3,2,ld0@got@tlsgd
2584         bl .__tls_get_addr
2585         nop
2586         addi 3,2,ld1@toc
2587         bl .__tls_get_addr
2588         nop
2589         addi 3,2,x1@got@tlsld
2590         bl .__tls_get_addr
2591         nop
2592         addi 9,3,x1@dtprel
2593         bl .__tls_get_addr
2594         nop
2595         addis 9,3,x2@dtprel@ha
2596         addi 9,9,x2@dtprel@l
2597         bl .__tls_get_addr
2598         nop
2599         ld 9,x3@got@dtprel(2)
2600         add 9,9,3
2601         bl .__tls_get_addr
2602         nop'
2603         tls_first_major=2
2604         tls_first_minor=14
2605         tls_as_opt="-a64 --fatal-warnings"
2606         ;;
2607   s390-*-*)
2608     conftest_s='
2609         .section ".tdata","awT",@progbits
2610 foo:    .long   25
2611         .text
2612         .long   foo@TLSGD
2613         .long   foo@TLSLDM
2614         .long   foo@DTPOFF
2615         .long   foo@NTPOFF
2616         .long   foo@GOTNTPOFF
2617         .long   foo@INDNTPOFF
2618         l       %r1,foo@GOTNTPOFF(%r12)
2619         l       %r1,0(%r1):tls_load:foo
2620         bas     %r14,0(%r1,%r13):tls_gdcall:foo
2621         bas     %r14,0(%r1,%r13):tls_ldcall:foo'
2622         tls_first_major=2
2623         tls_first_minor=14
2624         tls_as_opt="-m31 --fatal-warnings"
2625         ;;
2626   s390x-*-*)
2627     conftest_s='
2628         .section ".tdata","awT",@progbits
2629 foo:    .long   25
2630         .text
2631         .quad   foo@TLSGD
2632         .quad   foo@TLSLDM
2633         .quad   foo@DTPOFF
2634         .quad   foo@NTPOFF
2635         .quad   foo@GOTNTPOFF
2636         lg      %r1,foo@GOTNTPOFF(%r12)
2637         larl    %r1,foo@INDNTPOFF
2638         brasl   %r14,__tls_get_offset@PLT:tls_gdcall:foo
2639         brasl   %r14,__tls_get_offset@PLT:tls_ldcall:foo'
2640         tls_first_major=2
2641         tls_first_minor=14
2642         tls_as_opt="-m64 -Aesame --fatal-warnings"
2643         ;;
2644   sh-*-* | sh[34]-*-*)
2645     conftest_s='
2646         .section ".tdata","awT",@progbits
2647 foo:    .long   25
2648         .text
2649         .long   foo@TLSGD
2650         .long   foo@TLSLDM
2651         .long   foo@DTPOFF
2652         .long   foo@GOTTPOFF
2653         .long   foo@TPOFF'
2654         tls_first_major=2
2655         tls_first_minor=13
2656         tls_as_opt=--fatal-warnings
2657         ;;
2658   sparc*-*-*)
2659     case "$target" in
2660       sparc*-sun-solaris2.[56789]*)
2661         # TLS was introduced in the Solaris 9 4/04 release but
2662         # we do not enable it by default on Solaris 9 either.
2663         if test "x$enable_tls" = xyes ; then
2664           on_solaris=yes
2665         else
2666           enable_tls=no;
2667         fi
2668         ;;
2669       sparc*-sun-solaris2.*)
2670         on_solaris=yes
2671         ;;
2672       *)
2673         on_solaris=no
2674         ;;
2675     esac
2676     if test x$on_solaris = xyes && test x$gas_flag = xno; then
2677       conftest_s='
2678         .section ".tdata",#alloc,#write,#tls
2679 foo:    .long   25
2680         .text
2681         sethi   %tgd_hi22(foo), %o0
2682         add     %o0, %tgd_lo10(foo), %o1
2683         add     %l7, %o1, %o0, %tgd_add(foo)
2684         call    __tls_get_addr, %tgd_call(foo)
2685         sethi   %tldm_hi22(foo), %l1
2686         add     %l1, %tldm_lo10(foo), %l2
2687         add     %l7, %l2, %o0, %tldm_add(foo)
2688         call    __tls_get_addr, %tldm_call(foo)
2689         sethi   %tldo_hix22(foo), %l3
2690         xor     %l3, %tldo_lox10(foo), %l4
2691         add     %o0, %l4, %l5, %tldo_add(foo)
2692         sethi   %tie_hi22(foo), %o3
2693         add     %o3, %tie_lo10(foo), %o3
2694         ld      [%l7 + %o3], %o2, %tie_ld(foo)
2695         add     %g7, %o2, %o4, %tie_add(foo)
2696         sethi   %tle_hix22(foo), %l1
2697         xor     %l1, %tle_lox10(foo), %o5
2698         ld      [%g7 + %o5], %o1'
2699         tls_first_major=0
2700         tls_first_minor=0
2701     else
2702       conftest_s='
2703         .section ".tdata","awT",@progbits
2704 foo:    .long   25
2705         .text
2706         sethi   %tgd_hi22(foo), %o0
2707         add     %o0, %tgd_lo10(foo), %o1
2708         add     %l7, %o1, %o0, %tgd_add(foo)
2709         call    __tls_get_addr, %tgd_call(foo)
2710         sethi   %tldm_hi22(foo), %l1
2711         add     %l1, %tldm_lo10(foo), %l2
2712         add     %l7, %l2, %o0, %tldm_add(foo)
2713         call    __tls_get_addr, %tldm_call(foo)
2714         sethi   %tldo_hix22(foo), %l3
2715         xor     %l3, %tldo_lox10(foo), %l4
2716         add     %o0, %l4, %l5, %tldo_add(foo)
2717         sethi   %tie_hi22(foo), %o3
2718         add     %o3, %tie_lo10(foo), %o3
2719         ld      [%l7 + %o3], %o2, %tie_ld(foo)
2720         add     %g7, %o2, %o4, %tie_add(foo)
2721         sethi   %tle_hix22(foo), %l1
2722         xor     %l1, %tle_lox10(foo), %o5
2723         ld      [%g7 + %o5], %o1'
2724         tls_first_major=2
2725         tls_first_minor=14
2726         tls_as_opt="-32 --fatal-warnings"
2727       fi
2728         ;;
2729   xtensa*-*-*)
2730     conftest_s='
2731         .section ".tdata","awT",@progbits
2732 foo:    .long   25
2733         .text
2734         movi    a8, foo@TLSFUNC
2735         movi    a10, foo@TLSARG
2736         callx8.tls a8, foo@TLSCALL'
2737         tls_first_major=2
2738         tls_first_minor=19
2739         ;;
2740 changequote([,])dnl
2741 esac
2742 set_have_as_tls=no
2743 if test "x$enable_tls" = xno ; then
2744   : # TLS explicitly disabled.
2745 elif test "x$enable_tls" = xyes ; then
2746   set_have_as_tls=yes # TLS explicitly enabled.
2747 elif test -z "$tls_first_major"; then
2748   : # If we don't have a check, assume no support.
2749 else
2750   gcc_GAS_CHECK_FEATURE(thread-local storage support, gcc_cv_as_tls,
2751   [$tls_first_major,$tls_first_minor,0], [$tls_as_opt], [$conftest_s],,
2752   [set_have_as_tls=yes])
2753 fi
2754 if test $set_have_as_tls = yes ; then
2755   AC_DEFINE(HAVE_AS_TLS, 1,
2756             [Define if your assembler supports thread-local storage.])
2757 fi
2758
2759 # Target-specific assembler checks.
2760
2761 AC_MSG_CHECKING(linker -Bstatic/-Bdynamic option)
2762 gcc_cv_ld_static_dynamic=no
2763 if test $in_tree_ld = yes ; then
2764   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 10 -o "$gcc_cv_gld_major_version" -gt 2; then
2765     gcc_cv_ld_static_dynamic=yes
2766   fi
2767 elif test x$gcc_cv_ld != x; then
2768         # Check if linker supports -Bstatic/-Bdynamic option
2769         if $gcc_cv_ld --help 2>/dev/null | grep -- -Bstatic > /dev/null \
2770           && $gcc_cv_ld --help 2>/dev/null | grep -- -Bdynamic > /dev/null; then
2771                 gcc_cv_ld_static_dynamic=yes
2772         fi
2773 fi
2774 if test x"$gcc_cv_ld_static_dynamic" = xyes; then
2775         AC_DEFINE(HAVE_LD_STATIC_DYNAMIC, 1,
2776 [Define if your linker supports -Bstatic/-Bdynamic option.])
2777 fi
2778 AC_MSG_RESULT($gcc_cv_ld_static_dynamic)
2779
2780 if test x"$demangler_in_ld" = xyes; then
2781   AC_MSG_CHECKING(linker --demangle support)
2782   gcc_cv_ld_demangle=no
2783   if test $in_tree_ld = yes; then
2784     if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 14 -o "$gcc_cv_gld_major_version" -gt 2; then \
2785       gcc_cv_ld_demangle=yes
2786     fi
2787   elif test x$gcc_cv_ld != x -a x"$gnu_ld" = xyes; then
2788     # Check if the GNU linker supports --demangle option
2789     if $gcc_cv_ld --help 2>/dev/null | grep no-demangle > /dev/null; then
2790       gcc_cv_ld_demangle=yes
2791     fi
2792   fi
2793   if test x"$gcc_cv_ld_demangle" = xyes; then
2794     AC_DEFINE(HAVE_LD_DEMANGLE, 1,
2795 [Define if your linker supports --demangle option.])
2796   fi
2797   AC_MSG_RESULT($gcc_cv_ld_demangle)
2798 fi
2799
2800 case "$target" in
2801   # All TARGET_ABI_OSF targets.
2802   alpha*-*-osf* | alpha*-*-linux* | alpha*-*-*bsd*)
2803     gcc_GAS_CHECK_FEATURE([explicit relocation support],
2804         gcc_cv_as_alpha_explicit_relocs, [2,12,0],,
2805 [       .set nomacro
2806         .text
2807         extbl   $3, $2, $3      !lituse_bytoff!1
2808         ldq     $2, a($29)      !literal!1
2809         ldq     $4, b($29)      !literal!2
2810         ldq_u   $3, 0($2)       !lituse_base!1
2811         ldq     $27, f($29)     !literal!5
2812         jsr     $26, ($27), f   !lituse_jsr!5
2813         ldah    $29, 0($26)     !gpdisp!3
2814         lda     $0, c($29)      !gprel
2815         ldah    $1, d($29)      !gprelhigh
2816         lda     $1, d($1)       !gprellow
2817         lda     $29, 0($29)     !gpdisp!3],,
2818     [AC_DEFINE(HAVE_AS_EXPLICIT_RELOCS, 1,
2819   [Define if your assembler supports explicit relocations.])])
2820     gcc_GAS_CHECK_FEATURE([jsrdirect relocation support],
2821         gcc_cv_as_alpha_jsrdirect_relocs, [2,16,90],,
2822 [       .set nomacro
2823         .text
2824         ldq     $27, a($29)     !literal!1
2825         jsr     $26, ($27), a   !lituse_jsrdirect!1],,
2826     [AC_DEFINE(HAVE_AS_JSRDIRECT_RELOCS, 1,
2827   [Define if your assembler supports the lituse_jsrdirect relocation.])])
2828     ;;
2829
2830   cris-*-*)
2831     gcc_GAS_CHECK_FEATURE([-no-mul-bug-abort option],
2832       gcc_cv_as_cris_no_mul_bug,[2,15,91],
2833       [-no-mul-bug-abort], [.text],,
2834       [AC_DEFINE(HAVE_AS_NO_MUL_BUG_ABORT_OPTION, 1,
2835                 [Define if your assembler supports the -no-mul-bug-abort option.])])
2836     ;;
2837
2838   sparc*-*-*)
2839     gcc_GAS_CHECK_FEATURE([.register], gcc_cv_as_sparc_register_op,,,
2840       [.register %g2, #scratch],,
2841       [AC_DEFINE(HAVE_AS_REGISTER_PSEUDO_OP, 1,
2842                 [Define if your assembler supports .register.])])
2843
2844     gcc_GAS_CHECK_FEATURE([-relax option], gcc_cv_as_sparc_relax,,
2845       [-relax], [.text],,
2846       [AC_DEFINE(HAVE_AS_RELAX_OPTION, 1,
2847                 [Define if your assembler supports -relax option.])])
2848
2849     gcc_GAS_CHECK_FEATURE([unaligned pcrel relocs],
2850       gcc_cv_as_sparc_ua_pcrel,,
2851       [-K PIC],
2852 [.text
2853 foo:
2854         nop
2855 .data
2856 .align 4
2857 .byte 0
2858 .uaword %r_disp32(foo)],
2859       [if test x$gcc_cv_ld != x \
2860        && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1; then
2861          gcc_cv_as_sparc_ua_pcrel=yes
2862        fi
2863        rm -f conftest],
2864       [AC_DEFINE(HAVE_AS_SPARC_UA_PCREL, 1,
2865                 [Define if your assembler and linker support unaligned PC relative relocs.])
2866
2867       gcc_GAS_CHECK_FEATURE([unaligned pcrel relocs against hidden symbols],
2868         gcc_cv_as_sparc_ua_pcrel_hidden,,
2869         [-K PIC],
2870 [.data
2871 .align 4
2872 .byte 0x31
2873 .uaword %r_disp32(foo)
2874 .byte 0x32, 0x33, 0x34
2875 .global foo
2876 .hidden foo
2877 foo:
2878 .skip 4],
2879         [if test x$gcc_cv_ld != x && test x$gcc_cv_objdump != x \
2880          && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1 \
2881          && $gcc_cv_objdump -s -j .data conftest 2> /dev/null \
2882             | grep ' 31000000 07323334' > /dev/null 2>&1; then
2883             if $gcc_cv_objdump -R conftest 2> /dev/null \
2884                | grep 'DISP32' > /dev/null 2>&1; then
2885                 :
2886             else
2887                 gcc_cv_as_sparc_ua_pcrel_hidden=yes
2888             fi
2889          fi
2890          rm -f conftest],
2891          [AC_DEFINE(HAVE_AS_SPARC_UA_PCREL_HIDDEN, 1,
2892                    [Define if your assembler and linker support unaligned PC relative relocs against hidden symbols.])])
2893     ]) # unaligned pcrel relocs
2894
2895     gcc_GAS_CHECK_FEATURE([offsetable %lo()],
2896       gcc_cv_as_sparc_offsetable_lo10,,
2897       [-xarch=v9],
2898 [.text
2899         or %g1, %lo(ab) + 12, %g1
2900         or %g1, %lo(ab + 12), %g1],
2901       [if test x$gcc_cv_objdump != x \
2902        && $gcc_cv_objdump -s -j .text conftest.o 2> /dev/null \
2903           | grep ' 82106000 82106000' > /dev/null 2>&1; then
2904          gcc_cv_as_sparc_offsetable_lo10=yes
2905        fi],
2906        [AC_DEFINE(HAVE_AS_OFFSETABLE_LO10, 1,
2907                  [Define if your assembler supports offsetable %lo().])])
2908     ;;
2909
2910 changequote(,)dnl
2911   i[34567]86-*-* | x86_64-*-*)
2912 changequote([,])dnl
2913     case $target_os in
2914       cygwin* | pe | mingw32*)
2915         # Used for DWARF 2 in PE
2916         gcc_GAS_CHECK_FEATURE([.secrel32 relocs],
2917           gcc_cv_as_ix86_pe_secrel32,
2918           [2,15,91],,
2919 [.text
2920 foo:    nop
2921 .data
2922         .secrel32 foo],
2923           [if test x$gcc_cv_ld != x \
2924            && $gcc_cv_ld -o conftest conftest.o > /dev/null 2>&1; then
2925              gcc_cv_as_ix86_pe_secrel32=yes
2926            fi
2927            rm -f conftest],
2928           [AC_DEFINE(HAVE_GAS_PE_SECREL32_RELOC, 1,
2929             [Define if your assembler and linker support 32-bit section relative relocs via '.secrel32 label'.])])
2930         ;;
2931     esac
2932
2933     gcc_GAS_CHECK_FEATURE([filds and fists mnemonics],
2934        gcc_cv_as_ix86_filds_fists,
2935       [2,9,0],, [filds mem; fists mem],,
2936       [AC_DEFINE(HAVE_GAS_FILDS_FISTS, 1,
2937         [Define if your assembler uses the new HImode fild and fist notation.])])
2938
2939     gcc_GAS_CHECK_FEATURE([cmov syntax],
2940       gcc_cv_as_ix86_cmov_sun_syntax,,,
2941       [cmovl.l %edx, %eax],,
2942       [AC_DEFINE(HAVE_AS_IX86_CMOV_SUN_SYNTAX, 1,
2943         [Define if your assembler supports the Sun syntax for cmov.])])
2944
2945     gcc_GAS_CHECK_FEATURE([ffreep mnemonic],
2946       gcc_cv_as_ix86_ffreep,,,
2947       [ffreep %st(1)],,
2948       [AC_DEFINE(HAVE_AS_IX86_FFREEP, 1,
2949         [Define if your assembler supports the ffreep mnemonic.])])
2950
2951     gcc_GAS_CHECK_FEATURE([sahf mnemonic],
2952       gcc_cv_as_ix86_sahf,,,
2953       [sahf],,
2954       [AC_DEFINE(HAVE_AS_IX86_SAHF, 1,
2955         [Define if your assembler supports the sahf mnemonic.])])
2956
2957     gcc_GAS_CHECK_FEATURE([different section symbol subtraction],
2958       gcc_cv_as_ix86_diff_sect_delta,,,
2959       [.section .rodata
2960 .L1:
2961         .long .L2-.L1
2962         .long .L3-.L1
2963         .text
2964 .L3:    nop
2965 .L2:    nop],,
2966       [AC_DEFINE(HAVE_AS_IX86_DIFF_SECT_DELTA, 1,
2967         [Define if your assembler supports the subtraction of symbols in different sections.])])
2968
2969     # This one is used unconditionally by i386.[ch]; it is to be defined
2970     # to 1 if the feature is present, 0 otherwise.
2971     gcc_GAS_CHECK_FEATURE([GOTOFF in data],
2972         gcc_cv_as_ix86_gotoff_in_data, [2,11,0],,
2973 [       .text
2974 .L0:
2975         nop
2976         .data
2977         .long .L0@GOTOFF])
2978     AC_DEFINE_UNQUOTED(HAVE_AS_GOTOFF_IN_DATA,
2979       [`if test $gcc_cv_as_ix86_gotoff_in_data = yes; then echo 1; else echo 0; fi`],
2980       [Define true if the assembler supports '.long foo@GOTOFF'.])
2981     ;;
2982
2983   ia64*-*-*)
2984     gcc_GAS_CHECK_FEATURE([ltoffx and ldxmov relocs],
2985         gcc_cv_as_ia64_ltoffx_ldxmov_relocs, [2,14,0],,
2986 [       .text
2987         addl r15 = @ltoffx(x#), gp
2988         ;;
2989         ld8.mov r16 = [[r15]], x#],,
2990     [AC_DEFINE(HAVE_AS_LTOFFX_LDXMOV_RELOCS, 1,
2991           [Define if your assembler supports ltoffx and ldxmov relocations.])])
2992
2993     ;;
2994
2995   powerpc*-*-*)
2996     case $target in
2997       *-*-aix*) conftest_s='    .machine "pwr5"
2998         .csect .text[[PR]]
2999         mfcr 3,128';;
3000       *-*-darwin*)
3001         gcc_GAS_CHECK_FEATURE([.machine directive support],
3002           gcc_cv_as_machine_directive,,,
3003           [     .machine ppc7400])
3004         if test x$gcc_cv_as_machine_directive != xyes; then
3005           echo "*** This target requires an assembler supporting \".machine\"" >&2
3006           echo you can get it from: ftp://gcc.gnu.org/pub/gcc/infrastructure/cctools-528.5.dmg >&2
3007           test x$build = x$target && exit 1
3008         fi
3009         conftest_s='    .text
3010         mfcr r3,128';;
3011       *) conftest_s='   .machine power4
3012         .text
3013         mfcr 3,128';;
3014     esac
3015
3016     gcc_GAS_CHECK_FEATURE([mfcr field support],
3017       gcc_cv_as_powerpc_mfcrf, [2,14,0],,
3018       [$conftest_s],,
3019       [AC_DEFINE(HAVE_AS_MFCRF, 1,
3020           [Define if your assembler supports mfcr field.])])
3021
3022     case $target in
3023       *-*-aix*) conftest_s='    .machine "pwr5"
3024         .csect .text[[PR]]
3025         popcntb 3,3';;
3026       *) conftest_s='   .machine power5
3027         .text
3028         popcntb 3,3';;
3029     esac
3030
3031     gcc_GAS_CHECK_FEATURE([popcntb support],
3032       gcc_cv_as_powerpc_popcntb, [2,17,0],,
3033       [$conftest_s],,
3034       [AC_DEFINE(HAVE_AS_POPCNTB, 1,
3035           [Define if your assembler supports popcntb field.])])
3036
3037     case $target in
3038       *-*-aix*) conftest_s='    .machine "pwr5x"
3039         .csect .text[[PR]]
3040         frin 1,1';;
3041       *) conftest_s='   .machine power5
3042         .text
3043         frin 1,1';;
3044     esac
3045
3046     gcc_GAS_CHECK_FEATURE([fp round support],
3047       gcc_cv_as_powerpc_fprnd, [2,17,0],,
3048       [$conftest_s],,
3049       [AC_DEFINE(HAVE_AS_FPRND, 1,
3050           [Define if your assembler supports fprnd.])])
3051
3052     case $target in
3053       *-*-aix*) conftest_s='    .machine "pwr6"
3054         .csect .text[[PR]]
3055         mffgpr 1,3';;
3056       *) conftest_s='   .machine power6
3057         .text
3058         mffgpr 1,3';;
3059     esac
3060
3061     gcc_GAS_CHECK_FEATURE([move fp gpr support],
3062       gcc_cv_as_powerpc_mfpgpr, [9,99,0],,
3063       [$conftest_s],,
3064       [AC_DEFINE(HAVE_AS_MFPGPR, 1,
3065           [Define if your assembler supports mffgpr and mftgpr.])])
3066
3067     case $target in
3068       *-*-aix*) conftest_s='    .csect .text[[PR]]
3069 LCF..0:
3070         addis 11,30,_GLOBAL_OFFSET_TABLE_-LCF..0@ha';;
3071       *-*-darwin*)
3072         conftest_s='    .text
3073 LCF0:
3074         addis r11,r30,_GLOBAL_OFFSET_TABLE_-LCF0@ha';;
3075       *) conftest_s='   .text
3076 .LCF0:
3077         addis 11,30,_GLOBAL_OFFSET_TABLE_-.LCF0@ha';;
3078     esac
3079
3080     gcc_GAS_CHECK_FEATURE([rel16 relocs],
3081       gcc_cv_as_powerpc_rel16, [2,17,0], -a32,
3082       [$conftest_s],,
3083       [AC_DEFINE(HAVE_AS_REL16, 1,
3084           [Define if your assembler supports R_PPC_REL16 relocs.])])
3085
3086     case $target in
3087       *-*-aix*) conftest_s='    .machine "pwr6"
3088         .csect .text[[PR]]
3089         cmpb 3,4,5';;
3090       *) conftest_s='   .machine power6
3091         .text
3092         cmpb 3,4,5';;
3093     esac
3094
3095     gcc_GAS_CHECK_FEATURE([compare bytes support],
3096       gcc_cv_as_powerpc_cmpb, [9,99,0], -a32,
3097       [$conftest_s],,
3098       [AC_DEFINE(HAVE_AS_CMPB, 1,
3099           [Define if your assembler supports cmpb.])])
3100
3101     case $target in
3102       *-*-aix*) conftest_s='    .machine "pwr6"
3103         .csect .text[[PR]]
3104         dadd 1,2,3';;
3105       *) conftest_s='   .machine power6
3106         .text
3107         dadd 1,2,3';;
3108     esac
3109
3110     gcc_GAS_CHECK_FEATURE([decimal float support],
3111       gcc_cv_as_powerpc_dfp, [9,99,0], -a32,
3112       [$conftest_s],,
3113       [AC_DEFINE(HAVE_AS_DFP, 1,
3114           [Define if your assembler supports DFP instructions.])])
3115
3116     case $target in
3117       *-*-aix*) conftest_s='    .machine "pwr7"
3118         .csect .text[[PR]]
3119         lxvd2x 1,2,3';;
3120       *) conftest_s='   .machine power7
3121         .text
3122         lxvd2x 1,2,3';;
3123     esac
3124
3125     gcc_GAS_CHECK_FEATURE([vector-scalar support],
3126       gcc_cv_as_powerpc_vsx, [9,99,0], -a32,
3127       [$conftest_s],,
3128       [AC_DEFINE(HAVE_AS_VSX, 1,
3129           [Define if your assembler supports VSX instructions.])])
3130
3131     gcc_GAS_CHECK_FEATURE([.gnu_attribute support],
3132       gcc_cv_as_powerpc_gnu_attribute, [2,18,0],,
3133       [.gnu_attribute 4,1],,
3134       [AC_DEFINE(HAVE_AS_GNU_ATTRIBUTE, 1,
3135           [Define if your assembler supports .gnu_attribute.])])
3136
3137     gcc_GAS_CHECK_FEATURE([tls marker support],
3138       gcc_cv_as_powerpc_tls_markers, [2,20,0],,
3139       [ bl __tls_get_addr(x@tlsgd)],,
3140       [AC_DEFINE(HAVE_AS_TLS_MARKERS, 1,
3141           [Define if your assembler supports arg info for __tls_get_addr.])])
3142     ;;
3143
3144   mips*-*-*)
3145     gcc_GAS_CHECK_FEATURE([explicit relocation support],
3146       gcc_cv_as_mips_explicit_relocs, [2,14,0],,
3147 [       lw $4,%gp_rel(foo)($4)],,
3148       [if test x$target_cpu_default = x
3149        then target_cpu_default=MASK_EXPLICIT_RELOCS
3150        else target_cpu_default="($target_cpu_default)|MASK_EXPLICIT_RELOCS"
3151        fi])
3152     gcc_GAS_CHECK_FEATURE([-mno-shared support],
3153       gcc_cv_as_mips_no_shared, [2,16,0], [-mno-shared], [nop],,
3154       [AC_DEFINE(HAVE_AS_NO_SHARED, 1,
3155                  [Define if the assembler understands -mno-shared.])])
3156
3157     gcc_GAS_CHECK_FEATURE([.gnu_attribute support],
3158       gcc_cv_as_mips_gnu_attribute, [2,18,0],,
3159       [.gnu_attribute 4,1],,
3160       [AC_DEFINE(HAVE_AS_GNU_ATTRIBUTE, 1,
3161           [Define if your assembler supports .gnu_attribute.])])
3162
3163     gcc_GAS_CHECK_FEATURE([.dtprelword support],
3164       gcc_cv_as_mips_dtprelword, [2,18,0],,
3165       [.section .tdata,"awT",@progbits
3166 x:
3167         .word 2
3168         .text
3169         .dtprelword x+0x8000],,
3170       [AC_DEFINE(HAVE_AS_DTPRELWORD, 1,
3171           [Define if your assembler supports .dtprelword.])])
3172     ;;
3173 esac
3174
3175 # Mips and HP-UX need the GNU assembler.
3176 # Linux on IA64 might be able to use the Intel assembler.
3177
3178 case "$target" in
3179   mips*-*-* | *-*-hpux* )
3180     if test x$gas_flag = xyes \
3181        || test x"$host" != x"$build" \
3182        || test ! -x "$gcc_cv_as" \
3183        || "$gcc_cv_as" -v < /dev/null 2>&1 | grep GNU > /dev/null; then
3184       :
3185     else
3186       echo "*** This configuration requires the GNU assembler" >&2
3187       exit 1
3188     fi
3189     ;;
3190 esac
3191
3192 # ??? Not all targets support dwarf2 debug_line, even within a version
3193 # of gas.  Moreover, we need to emit a valid instruction to trigger any
3194 # info to the output file.  So, as supported targets are added to gas 2.11,
3195 # add some instruction here to (also) show we expect this might work.
3196 # ??? Once 2.11 is released, probably need to add first known working
3197 # version to the per-target configury.
3198 case "$target" in
3199   i?86*-*-* | mips*-*-* | alpha*-*-* | powerpc*-*-* | sparc*-*-* | m68*-*-* \
3200   | x86_64*-*-* | hppa*-*-* | arm*-*-* \
3201   | xstormy16*-*-* | cris-*-* | crisv32-*-* | xtensa*-*-* | bfin-*-* | score*-*-* \
3202   | spu-*-* | fido*-*-* | m32c-*-*)
3203     insn="nop"
3204     ;;
3205   ia64*-*-* | s390*-*-*)
3206     insn="nop 0"
3207     ;;
3208   mmix-*-*)
3209     insn="swym 0"
3210     ;;
3211 esac
3212 if test x"$insn" != x; then
3213  conftest_s="\
3214         .file 1 \"conftest.s\"
3215         .loc 1 3 0
3216         $insn"
3217  gcc_GAS_CHECK_FEATURE([dwarf2 debug_line support],
3218   gcc_cv_as_dwarf2_debug_line,
3219   [elf,2,11,0],, [$conftest_s],
3220   [if test x$gcc_cv_objdump != x \
3221    && $gcc_cv_objdump -h conftest.o 2> /dev/null \
3222       | grep debug_line > /dev/null 2>&1; then
3223      gcc_cv_as_dwarf2_debug_line=yes
3224    fi])
3225
3226 # The .debug_line file table must be in the exact order that
3227 # we specified the files, since these indices are also used
3228 # by DW_AT_decl_file.  Approximate this test by testing if
3229 # the assembler bitches if the same index is assigned twice.
3230  gcc_GAS_CHECK_FEATURE([buggy dwarf2 .file directive],
3231   gcc_cv_as_dwarf2_file_buggy,,,
3232 [       .file 1 "foo.s"
3233         .file 1 "bar.s"])
3234
3235  if test $gcc_cv_as_dwarf2_debug_line = yes \
3236  && test $gcc_cv_as_dwarf2_file_buggy = no; then
3237         AC_DEFINE(HAVE_AS_DWARF2_DEBUG_LINE, 1,
3238   [Define if your assembler supports dwarf2 .file/.loc directives,
3239    and preserves file table indices exactly as given.])
3240  fi
3241
3242  gcc_GAS_CHECK_FEATURE([--gdwarf2 option],
3243   gcc_cv_as_gdwarf2_flag,
3244   [elf,2,11,0], [--gdwarf2], [$insn],,
3245   [AC_DEFINE(HAVE_AS_GDWARF2_DEBUG_FLAG, 1,
3246 [Define if your assembler supports the --gdwarf2 option.])])
3247
3248  gcc_GAS_CHECK_FEATURE([--gstabs option],
3249   gcc_cv_as_gstabs_flag,
3250   [elf,2,11,0], [--gstabs], [$insn],
3251   [# The native Solaris 9/Intel assembler doesn't understand --gstabs
3252    # and warns about it, but still exits successfully.  So check for
3253    # this.
3254    if AC_TRY_COMMAND([$gcc_cv_as --gstabs -o conftest.o conftest.s 2>&1 | grep -i warning > /dev/null])
3255    then :
3256    else gcc_cv_as_gstabs_flag=yes
3257    fi],
3258   [AC_DEFINE(HAVE_AS_GSTABS_DEBUG_FLAG, 1,
3259 [Define if your assembler supports the --gstabs option.])])
3260
3261  gcc_GAS_CHECK_FEATURE([--debug-prefix-map option],
3262   gcc_cv_as_debug_prefix_map_flag,
3263   [2,18,0], [--debug-prefix-map /a=/b], [$insn],,
3264   [AC_DEFINE(HAVE_AS_DEBUG_PREFIX_MAP, 1,
3265 [Define if your assembler supports the --debug-prefix-map option.])])
3266 fi
3267
3268 gcc_GAS_CHECK_FEATURE([.lcomm with alignment], gcc_cv_as_lcomm_with_alignment,
3269  ,,
3270 [.lcomm bar,4,16],,
3271 [AC_DEFINE(HAVE_GAS_LCOMM_WITH_ALIGNMENT, 1,
3272   [Define if your assembler supports .lcomm with an alignment field.])])
3273
3274 AC_CACHE_CHECK([assembler for tolerance to line number 0],
3275  [gcc_cv_as_line_zero],
3276  [gcc_cv_as_line_zero=no
3277   if test $in_tree_gas = yes; then
3278     gcc_GAS_VERSION_GTE_IFELSE(2, 16, 91, [gcc_cv_as_line_zero=yes])
3279   elif test "x$gcc_cv_as" != x; then
3280     { echo '# 1 "test.s" 1'; echo '# 0 "" 2'; } > conftest.s
3281     if AC_TRY_COMMAND([$gcc_cv_as -o conftest.o conftest.s >&AS_MESSAGE_LOG_FD 2>conftest.out]) &&
3282        test "x`cat conftest.out`" = x
3283     then
3284       gcc_cv_as_line_zero=yes
3285     else
3286       echo "configure: failed program was" >&AS_MESSAGE_LOG_FD
3287       cat conftest.s >&AS_MESSAGE_LOG_FD
3288       echo "configure: error output was" >&AS_MESSAGE_LOG_FD
3289       cat conftest.out >&AS_MESSAGE_LOG_FD
3290     fi
3291     rm -f conftest.o conftest.s conftest.out
3292   fi])
3293 if test "x$gcc_cv_as_line_zero" = xyes; then
3294   AC_DEFINE([HAVE_AS_LINE_ZERO], 1,
3295 [Define if the assembler won't complain about a line such as # 0 "" 2.])
3296 fi
3297
3298 AC_MSG_CHECKING(linker PT_GNU_EH_FRAME support)
3299 gcc_cv_ld_eh_frame_hdr=no
3300 if test $in_tree_ld = yes ; then
3301   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 12 -o "$gcc_cv_gld_major_version" -gt 2 \
3302      && test $in_tree_ld_is_elf = yes; then
3303     gcc_cv_ld_eh_frame_hdr=yes
3304   fi
3305 elif test x$gcc_cv_ld != x; then
3306         # Check if linker supports --eh-frame-hdr option
3307         if $gcc_cv_ld --help 2>/dev/null | grep eh-frame-hdr > /dev/null; then
3308                 gcc_cv_ld_eh_frame_hdr=yes
3309         fi
3310 fi
3311 GCC_TARGET_TEMPLATE([HAVE_LD_EH_FRAME_HDR])
3312 if test x"$gcc_cv_ld_eh_frame_hdr" = xyes; then
3313         AC_DEFINE(HAVE_LD_EH_FRAME_HDR, 1,
3314 [Define if your linker supports --eh-frame-hdr option.])
3315 fi
3316 AC_MSG_RESULT($gcc_cv_ld_eh_frame_hdr)
3317
3318 AC_MSG_CHECKING(linker position independent executable support)
3319 gcc_cv_ld_pie=no
3320 if test $in_tree_ld = yes ; then
3321   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 15 -o "$gcc_cv_gld_major_version" -gt 2 \
3322      && test $in_tree_ld_is_elf = yes; then
3323     gcc_cv_ld_pie=yes
3324   fi
3325 elif test x$gcc_cv_ld != x; then
3326         # Check if linker supports -pie option
3327         if $gcc_cv_ld --help 2>/dev/null | grep -- -pie > /dev/null; then
3328                 gcc_cv_ld_pie=yes
3329         fi
3330 fi
3331 if test x"$gcc_cv_ld_pie" = xyes; then
3332         AC_DEFINE(HAVE_LD_PIE, 1,
3333 [Define if your linker supports -pie option.])
3334 fi
3335 AC_MSG_RESULT($gcc_cv_ld_pie)
3336
3337 AC_MSG_CHECKING(linker EH-compatible garbage collection of sections)
3338 gcc_cv_ld_eh_gc_sections=no
3339 if test $in_tree_ld = yes ; then
3340   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 17 -o "$gcc_cv_gld_major_version" -gt 2 \
3341      && test $in_tree_ld_is_elf = yes; then
3342     gcc_cv_ld_eh_gc_sections=yes
3343   fi
3344 elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x -a x$gcc_cv_objdump != x ; then
3345   cat > conftest.s <<EOF
3346         .section        .text
3347 .globl _start
3348         .type _start, @function
3349 _start:
3350         .long foo
3351         .size _start, .-_start
3352         .section        .text.foo,"ax",@progbits
3353         .type foo, @function
3354 foo:
3355         .long 0
3356         .size foo, .-foo
3357         .section        .gcc_except_table.foo,"a",@progbits
3358 .L0:
3359         .long 0
3360         .section        .eh_frame,"a",@progbits
3361         .long .L0
3362 EOF
3363   if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
3364     if $gcc_cv_ld -o conftest conftest.o --entry=_start --gc-sections 2>&1 \
3365          | grep "gc-sections option ignored" > /dev/null; then
3366       gcc_cv_ld_eh_gc_sections=no
3367     elif $gcc_cv_objdump -h conftest | grep gcc_except_table > /dev/null; then
3368       gcc_cv_ld_eh_gc_sections=yes
3369       # If no COMDAT groups, the compiler will emit .gnu.linkonce.t. sections.
3370       if test x$gcc_cv_as_comdat_group != xyes; then
3371         gcc_cv_ld_eh_gc_sections=no
3372         cat > conftest.s <<EOF
3373         .section        .text
3374 .globl _start
3375         .type _start, @function
3376 _start:
3377         .long foo
3378         .size _start, .-_start
3379         .section        .gnu.linkonce.t.foo,"ax",@progbits
3380         .type foo, @function
3381 foo:
3382         .long 0
3383         .size foo, .-foo
3384         .section        .gcc_except_table.foo,"a",@progbits
3385 .L0:
3386         .long 0
3387         .section        .eh_frame,"a",@progbits
3388         .long .L0
3389 EOF
3390         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
3391           if $gcc_cv_ld -o conftest conftest.o --entry=_start --gc-sections 2>&1 \
3392                | grep "gc-sections option ignored" > /dev/null; then
3393             gcc_cv_ld_eh_gc_sections=no
3394           elif $gcc_cv_objdump -h conftest | grep gcc_except_table > /dev/null; then
3395             gcc_cv_ld_eh_gc_sections=yes
3396           fi
3397         fi
3398       fi
3399     fi
3400   fi
3401   rm -f conftest.s conftest.o conftest
3402 fi
3403 case "$target" in
3404   hppa*-*-linux*)
3405     # ??? This apparently exposes a binutils bug with PC-relative relocations.
3406     gcc_cv_ld_eh_gc_sections=no
3407     ;;
3408 esac
3409 if test x$gcc_cv_ld_eh_gc_sections = xyes; then
3410         AC_DEFINE(HAVE_LD_EH_GC_SECTIONS, 1,
3411   [Define if your linker supports garbage collection of
3412    sections in presence of EH frames.])
3413 fi
3414 AC_MSG_RESULT($gcc_cv_ld_eh_gc_sections)
3415
3416 # --------
3417 # UNSORTED
3418 # --------
3419
3420 AC_CACHE_CHECK(linker --as-needed support,
3421 gcc_cv_ld_as_needed,
3422 [gcc_cv_ld_as_needed=no
3423 if test $in_tree_ld = yes ; then
3424   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2 \
3425      && test $in_tree_ld_is_elf = yes; then
3426     gcc_cv_ld_as_needed=yes
3427   fi
3428 elif test x$gcc_cv_ld != x; then
3429         # Check if linker supports --as-needed and --no-as-needed options
3430         if $gcc_cv_ld --help 2>/dev/null | grep as-needed > /dev/null; then
3431                 gcc_cv_ld_as_needed=yes
3432         fi
3433 fi
3434 ])
3435 if test x"$gcc_cv_ld_as_needed" = xyes; then
3436         AC_DEFINE(HAVE_LD_AS_NEEDED, 1,
3437 [Define if your linker supports --as-needed and --no-as-needed options.])
3438 fi
3439
3440 case "$target:$tm_file" in
3441   powerpc64*-*-linux* | powerpc*-*-linux*rs6000/biarch64.h*)
3442     AC_CACHE_CHECK(linker support for omitting dot symbols,
3443     gcc_cv_ld_no_dot_syms,
3444     [gcc_cv_ld_no_dot_syms=no
3445     if test $in_tree_ld = yes ; then
3446       if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2; then
3447         gcc_cv_ld_no_dot_syms=yes
3448       fi
3449     elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x ; then
3450       cat > conftest1.s <<EOF
3451         .text
3452         bl .foo
3453 EOF
3454       cat > conftest2.s <<EOF
3455         .section ".opd","aw"
3456         .align 3
3457         .globl foo
3458         .type foo,@function
3459 foo:
3460         .quad .LEfoo,.TOC.@tocbase,0
3461         .text
3462 .LEfoo:
3463         blr
3464         .size foo,.-.LEfoo
3465 EOF
3466       if $gcc_cv_as -a64 -o conftest1.o conftest1.s > /dev/null 2>&1 \
3467          && $gcc_cv_as -a64 -o conftest2.o conftest2.s > /dev/null 2>&1 \
3468          && $gcc_cv_ld -melf64ppc -o conftest conftest1.o conftest2.o > /dev/null 2>&1; then
3469         gcc_cv_ld_no_dot_syms=yes
3470       fi
3471       rm -f conftest conftest1.o conftest2.o conftest1.s conftest2.s
3472     fi
3473     ])
3474     if test x"$gcc_cv_ld_no_dot_syms" = xyes; then
3475       AC_DEFINE(HAVE_LD_NO_DOT_SYMS, 1,
3476     [Define if your PowerPC64 linker only needs function descriptor syms.])
3477     fi
3478     ;;
3479 esac
3480
3481 AC_CACHE_CHECK(linker --sysroot support,
3482   gcc_cv_ld_sysroot,
3483   [gcc_cv_ld_sysroot=no
3484   if test $in_tree_ld = yes ; then
3485       if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2 ; then
3486         gcc_cv_ld_sysroot=yes
3487       fi
3488   elif test x$gcc_cv_ld != x; then
3489     if $gcc_cv_ld --help 2>/dev/null | grep sysroot > /dev/null; then
3490       gcc_cv_ld_sysroot=yes
3491     fi
3492   fi])
3493 if test x"$gcc_cv_ld_sysroot" = xyes; then
3494   AC_DEFINE(HAVE_LD_SYSROOT, 1,
3495   [Define if your linker supports --sysroot.])
3496 fi
3497
3498 if test x$with_sysroot = x && test x$host = x$target \
3499    && test "$prefix" != "/usr" && test "x$prefix" != "x$local_prefix" \
3500    && test "$prefix" != "NONE"; then
3501   AC_DEFINE_UNQUOTED(PREFIX_INCLUDE_DIR, "$prefix/include",
3502 [Define to PREFIX/include if cpp should also search that directory.])
3503 fi
3504
3505 # Test for stack protector support in target C library.
3506 AC_CACHE_CHECK(__stack_chk_fail in target C library,
3507       gcc_cv_libc_provides_ssp,
3508       [gcc_cv_libc_provides_ssp=no
3509     case "$target" in
3510        *-*-linux* | *-*-kfreebsd*-gnu | *-*-knetbsd*-gnu)
3511       if test x$host != x$target || test "x$TARGET_SYSTEM_ROOT" != x; then
3512         if test "x$with_sysroot" = x; then
3513           glibc_header_dir="${exec_prefix}/${target_noncanonical}/sys-include"
3514         elif test "x$with_build_sysroot" != "x"; then
3515           glibc_header_dir="${with_build_sysroot}/usr/include"
3516         elif test "x$with_sysroot" = xyes; then
3517           glibc_header_dir="${exec_prefix}/${target_noncanonical}/sys-root/usr/include"
3518         else
3519           glibc_header_dir="${with_sysroot}/usr/include"
3520         fi
3521       else
3522         glibc_header_dir=/usr/include
3523       fi
3524       # glibc 2.4 and later provides __stack_chk_fail and
3525       # either __stack_chk_guard, or TLS access to stack guard canary.
3526       if test -f $glibc_header_dir/features.h \
3527          && $EGREP '^@<:@       @:>@*#[         ]*define[       ]+__GNU_LIBRARY__[      ]+([1-9][0-9]|[6-9])' \
3528             $glibc_header_dir/features.h > /dev/null; then
3529         if $EGREP '^@<:@        @:>@*#[         ]*define[       ]+__GLIBC__[    ]+([1-9][0-9]|[3-9])' \
3530            $glibc_header_dir/features.h > /dev/null; then
3531           gcc_cv_libc_provides_ssp=yes
3532         elif $EGREP '^@<:@      @:>@*#[         ]*define[       ]+__GLIBC__[    ]+2' \
3533              $glibc_header_dir/features.h > /dev/null \
3534              && $EGREP '^@<:@   @:>@*#[         ]*define[       ]+__GLIBC_MINOR__[      ]+([1-9][0-9]|[4-9])' \
3535              $glibc_header_dir/features.h > /dev/null; then
3536           gcc_cv_libc_provides_ssp=yes
3537         elif $EGREP '^@<:@      @:>@*#[         ]*define[       ]+__UCLIBC__[   ]+1' \
3538              $glibc_header_dir/features.h > /dev/null && \
3539              test -f $glibc_header_dir/bits/uClibc_config.h && \
3540              $EGREP '^@<:@      @:>@*#[         ]*define[       ]+__UCLIBC_HAS_SSP__[   ]+1' \
3541              $glibc_header_dir/bits/uClibc_config.h > /dev/null; then
3542           gcc_cv_libc_provides_ssp=yes
3543         fi
3544       fi
3545         ;;
3546        *-*-gnu*)
3547          # Avoid complicated tests (see
3548          # <http://gcc.gnu.org/ml/gcc/2008-10/msg00130.html>) and for now
3549          # simply assert that glibc does provide this, which is true for all
3550          # realistically usable GNU/Hurd configurations.
3551          gcc_cv_libc_provides_ssp=yes;;
3552        *-*-darwin*)
3553          AC_CHECK_FUNC(__stack_chk_fail,[gcc_cv_libc_provides_ssp=yes],
3554            [echo "no __stack_chk_fail on this target"])
3555         ;;
3556   *) gcc_cv_libc_provides_ssp=no ;;
3557     esac])
3558
3559 if test x$gcc_cv_libc_provides_ssp = xyes; then
3560   AC_DEFINE(TARGET_LIBC_PROVIDES_SSP, 1,
3561             [Define if your target C library provides stack protector support])
3562 fi
3563
3564 # Check if TFmode long double should be used by default or not.
3565 # Some glibc targets used DFmode long double, but with glibc 2.4
3566 # and later they can use TFmode.
3567 case "$target" in
3568   powerpc*-*-linux* | \
3569   powerpc*-*-gnu* | \
3570   sparc*-*-linux* | \
3571   s390*-*-linux* | \
3572   alpha*-*-linux*)
3573     AC_ARG_WITH(long-double-128,
3574 [  --with-long-double-128  Use 128-bit long double by default.],
3575       gcc_cv_target_ldbl128="$with_long_double_128",
3576       [gcc_cv_target_ldbl128=no
3577       if test x$host != x$target || test "x$TARGET_SYSTEM_ROOT" != x; then
3578         if test "x$with_sysroot" = x; then
3579           glibc_header_dir="${exec_prefix}/${target_noncanonical}/sys-include"
3580         elif test "x$with_build_sysroot" != "x"; then
3581           glibc_header_dir="${with_build_sysroot}/usr/include"
3582         elif test "x$with_sysroot" = xyes; then
3583           glibc_header_dir="${exec_prefix}/${target_noncanonical}/sys-root/usr/include"
3584         else
3585           glibc_header_dir="${with_sysroot}/usr/include"
3586         fi
3587       else
3588         glibc_header_dir=/usr/include
3589       fi
3590 changequote(,)dnl
3591       grep '^[  ]*#[    ]*define[       ][      ]*__LONG_DOUBLE_MATH_OPTIONAL' \
3592         $glibc_header_dir/bits/wordsize.h > /dev/null 2>&1 \
3593       && gcc_cv_target_ldbl128=yes
3594 changequote([,])dnl
3595       ])
3596     ;;
3597 esac
3598 if test x$gcc_cv_target_ldbl128 = xyes; then
3599   AC_DEFINE(TARGET_DEFAULT_LONG_DOUBLE_128, 1,
3600             [Define if TFmode long double should be the default])
3601 fi
3602
3603 # Find out what GC implementation we want, or may, use.
3604 AC_ARG_WITH(gc,
3605 [  --with-gc={page,zone}   choose the garbage collection mechanism to use
3606                           with the compiler],
3607 [case "$withval" in
3608   page)
3609     GGC=ggc-$withval
3610     ;;
3611   zone)
3612     GGC=ggc-$withval
3613     AC_DEFINE(GGC_ZONE, 1, [Define if the zone collector is in use])
3614     ;;
3615   *)
3616     AC_MSG_ERROR([$withval is an invalid option to --with-gc])
3617     ;;
3618 esac],
3619 [GGC=ggc-page])
3620 AC_SUBST(GGC)
3621 echo "Using $GGC for garbage collection."
3622
3623 # Use the system's zlib library.
3624 zlibdir=-L../zlib
3625 zlibinc="-I\$(srcdir)/../zlib"
3626 AC_ARG_WITH(system-zlib,
3627 [  --with-system-zlib      use installed libz],
3628 zlibdir=
3629 zlibinc=
3630 )
3631 AC_SUBST(zlibdir)
3632 AC_SUBST(zlibinc)
3633
3634 dnl Very limited version of automake's enable-maintainer-mode
3635
3636 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
3637   dnl maintainer-mode is disabled by default
3638   AC_ARG_ENABLE(maintainer-mode,
3639 [  --enable-maintainer-mode
3640                           enable make rules and dependencies not useful
3641                           (and sometimes confusing) to the casual installer],
3642       maintainer_mode=$enableval,
3643       maintainer_mode=no)
3644
3645 AC_MSG_RESULT($maintainer_mode)
3646
3647 if test "$maintainer_mode" = "yes"; then
3648   MAINT=''
3649 else
3650   MAINT='#'
3651 fi
3652 AC_SUBST(MAINT)dnl
3653
3654 # --------------
3655 # Language hooks
3656 # --------------
3657
3658 # Make empty files to contain the specs and options for each language.
3659 # Then add #include lines to for a compiler that has specs and/or options.
3660
3661 subdirs=
3662 lang_opt_files=
3663 lang_specs_files=
3664 lang_tree_files=
3665 # These (without "all_") are set in each config-lang.in.
3666 # `language' must be a single word so is spelled singularly.
3667 all_languages=
3668 all_compilers=
3669 all_outputs='Makefile gccbug'
3670 # List of language makefile fragments.
3671 all_lang_makefrags=
3672 # List of language subdirectory makefiles.  Deprecated.
3673 all_lang_makefiles=
3674 # Additional files for gengtype
3675 all_gtfiles="$target_gtfiles"
3676
3677 # These are the languages that are set in --enable-languages,
3678 # and are available in the GCC tree.
3679 all_selected_languages=
3680
3681 # Add the language fragments.
3682 # Languages are added via two mechanisms.  Some information must be
3683 # recorded in makefile variables, these are defined in config-lang.in.
3684 # We accumulate them and plug them into the main Makefile.
3685 # The other mechanism is a set of hooks for each of the main targets
3686 # like `clean', `install', etc.
3687
3688 language_hooks="Make-hooks"
3689
3690 for lang in ${srcdir}/*/config-lang.in
3691 do
3692 changequote(,)dnl
3693         test "$lang" = "${srcdir}/*/config-lang.in" && continue
3694
3695         lang_alias=`sed -n -e 's,^language=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^language=\([^   ]*\).*$,\1,p' $lang`
3696         if test "x$lang_alias" = x
3697         then
3698               echo "$lang doesn't set \$language." 1>&2
3699               exit 1
3700         fi
3701         subdir="`echo $lang | sed -e 's,^.*/\([^/]*\)/config-lang.in$,\1,'`"
3702         subdirs="$subdirs $subdir"
3703
3704         # $gcc_subdir is where the gcc integration files are to be found
3705         # for a language, both for internal compiler purposes (compiler
3706         # sources implementing front-end to GCC tree converters), and for
3707         # build infrastructure purposes (Make-lang.in, etc.)
3708         #
3709         # This will be <subdir> (relative to $srcdir) if a line like
3710         # gcc_subdir="<subdir>" or gcc_subdir=<subdir>
3711         # is found in <langdir>/config-lang.in, and will remain <langdir>
3712         # otherwise.
3713         #
3714         # Except for the language alias (fetched above), the regular
3715         # "config-lang.in" contents are always retrieved from $gcc_subdir,
3716         # so a <langdir>/config-lang.in setting gcc_subdir typically sets
3717         # only this and the language alias.
3718
3719         gcc_subdir=`sed -n -e 's,^gcc_subdir=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^gcc_subdir=\([^   ]*\).*$,\1,p' $lang`
3720         if [ "$gcc_subdir" = "" ]; then
3721            gcc_subdir="$subdir"
3722         fi
3723
3724         case ",$enable_languages," in
3725         *,$lang_alias,*)
3726             all_selected_languages="$all_selected_languages $lang_alias"
3727             if test -f $srcdir/$gcc_subdir/lang-specs.h; then
3728                 lang_specs_files="$lang_specs_files $srcdir/$gcc_subdir/lang-specs.h"
3729             fi
3730             ;;
3731         esac
3732 changequote([,])dnl
3733
3734         language=
3735         boot_language=
3736         compilers=
3737         outputs=
3738         gtfiles=
3739         subdir_requires=
3740         . ${srcdir}/$gcc_subdir/config-lang.in
3741         if test "x$language" = x
3742         then
3743                 echo "${srcdir}/$gcc_subdir/config-lang.in doesn't set \$language." 1>&2
3744                 exit 1
3745         fi
3746
3747         ok=:
3748         case ",$enable_languages," in
3749                 *,$lang_alias,*) ;;
3750                 *)
3751                         for i in $subdir_requires; do
3752                                 test -f "${srcdir}/$i/config-lang.in" && continue
3753                                 ok=false
3754                                 break
3755                         done
3756                 ;;
3757         esac
3758         $ok || continue
3759
3760         all_lang_makefrags="$all_lang_makefrags \$(srcdir)/$gcc_subdir/Make-lang.in"
3761         if test -f $srcdir/$gcc_subdir/lang.opt; then
3762             lang_opt_files="$lang_opt_files $srcdir/$gcc_subdir/lang.opt"
3763         fi
3764         if test -f $srcdir/$gcc_subdir/$subdir-tree.def; then
3765             lang_tree_files="$lang_tree_files $srcdir/$gcc_subdir/$subdir-tree.def"
3766         fi
3767         if test -f ${srcdir}/$gcc_subdir/Makefile.in
3768                 then all_lang_makefiles="$gcc_subdir/Makefile"
3769         fi
3770         all_languages="$all_languages $language"
3771         all_compilers="$all_compilers $compilers"
3772         all_outputs="$all_outputs $outputs"
3773         all_gtfiles="$all_gtfiles [[$subdir]] $gtfiles"
3774 done
3775
3776 # Pick up gtfiles for c
3777 gtfiles=
3778 . ${srcdir}/c-config-lang.in
3779 all_gtfiles="$all_gtfiles [[c]] $gtfiles"
3780
3781 check_languages=
3782 for language in $all_selected_languages
3783 do
3784         check_languages="$check_languages check-$language"
3785 done
3786
3787 # We link each language in with a set of hooks, reached indirectly via
3788 # lang.${target}.  Only do so for selected languages.
3789
3790 rm -f Make-hooks
3791 touch Make-hooks
3792 target_list="all.cross start.encap rest.encap tags \
3793         install-common install-man install-info install-pdf dvi pdf \
3794         html uninstall info man srcextra srcman srcinfo \
3795         mostlyclean clean distclean maintainer-clean"
3796
3797 for t in $target_list
3798 do
3799         x=
3800         for lang in $all_selected_languages
3801         do
3802                 x="$x $lang.$t"
3803         done
3804         echo "lang.$t: $x" >> Make-hooks
3805 done
3806
3807 # --------
3808 # UNSORTED
3809 # --------
3810
3811 # Create .gdbinit.
3812
3813 echo "dir ." > .gdbinit
3814 echo "dir ${srcdir}" >> .gdbinit
3815 if test x$gdb_needs_out_file_path = xyes
3816 then
3817         echo "dir ${srcdir}/config/"`dirname ${out_file}` >> .gdbinit
3818 fi
3819 if test "x$subdirs" != x; then
3820         for s in $subdirs
3821         do
3822                 echo "dir ${srcdir}/$s" >> .gdbinit
3823         done
3824 fi
3825 echo "source ${srcdir}/gdbinit.in" >> .gdbinit
3826
3827 gcc_tooldir='$(libsubdir)/$(libsubdir_to_prefix)$(target_noncanonical)'
3828 AC_SUBST(gcc_tooldir)
3829 AC_SUBST(dollar)
3830
3831 # Find a directory in which to install a shared libgcc.
3832
3833 AC_ARG_ENABLE(version-specific-runtime-libs,
3834 [  --enable-version-specific-runtime-libs
3835                           specify that runtime libraries should be
3836                           installed in a compiler-specific directory])
3837
3838 AC_ARG_WITH(slibdir,
3839 [  --with-slibdir=DIR      shared libraries in DIR [[LIBDIR]]],
3840 slibdir="$with_slibdir",
3841 if test "${enable_version_specific_runtime_libs+set}" = set; then
3842   slibdir='$(libsubdir)'
3843 elif test "$host" != "$target"; then
3844   slibdir='$(build_tooldir)/lib'
3845 else
3846   slibdir='$(libdir)'
3847 fi)
3848 AC_SUBST(slibdir)
3849
3850 AC_ARG_WITH(datarootdir,
3851 [  --with-datarootdir=DIR  Use DIR as the data root [[PREFIX/share]]],
3852 datarootdir="\${prefix}/$with_datarootdir",
3853 datarootdir='$(prefix)/share')
3854 AC_SUBST(datarootdir)
3855
3856 AC_ARG_WITH(docdir,
3857 [  --with-docdir=DIR       Install documentation in DIR [[DATAROOTDIR]]],
3858 docdir="\${prefix}/$with_docdir",
3859 docdir='$(datarootdir)')
3860 AC_SUBST(docdir)
3861
3862 AC_ARG_WITH(htmldir,
3863 [  --with-htmldir=DIR      html documentation in in DIR [[DOCDIR]]],
3864 htmldir="\${prefix}/$with_htmldir",
3865 htmldir='$(docdir)')
3866 AC_SUBST(htmldir)
3867
3868 # Substitute configuration variables
3869 AC_SUBST(subdirs)
3870 AC_SUBST(srcdir)
3871 AC_SUBST(all_compilers)
3872 AC_SUBST(all_gtfiles)
3873 AC_SUBST(all_lang_makefrags)
3874 AC_SUBST(all_lang_makefiles)
3875 AC_SUBST(all_languages)
3876 AC_SUBST(all_selected_languages)
3877 AC_SUBST(build_exeext)
3878 AC_SUBST(build_install_headers_dir)
3879 AC_SUBST(build_xm_file_list)
3880 AC_SUBST(build_xm_include_list)
3881 AC_SUBST(build_xm_defines)
3882 AC_SUBST(build_file_translate)
3883 AC_SUBST(check_languages)
3884 AC_SUBST(cpp_install_dir)
3885 AC_SUBST(xmake_file)
3886 AC_SUBST(tmake_file)
3887 AC_SUBST(TM_ENDIAN_CONFIG)
3888 AC_SUBST(TM_MULTILIB_CONFIG)
3889 AC_SUBST(TM_MULTILIB_EXCEPTIONS_CONFIG)
3890 AC_SUBST(extra_gcc_objs)
3891 AC_SUBST(extra_headers_list)
3892 AC_SUBST(extra_objs)
3893 AC_SUBST(extra_parts)
3894 AC_SUBST(extra_passes)
3895 AC_SUBST(extra_programs)
3896 AC_SUBST(float_h_file)
3897 AC_SUBST(gcc_config_arguments)
3898 AC_SUBST(gcc_gxx_include_dir)
3899 AC_SUBST(host_exeext)
3900 AC_SUBST(host_xm_file_list)
3901 AC_SUBST(host_xm_include_list)
3902 AC_SUBST(host_xm_defines)
3903 AC_SUBST(out_host_hook_obj)
3904 AC_SUBST(install)
3905 AC_SUBST(lang_opt_files)
3906 AC_SUBST(lang_specs_files)
3907 AC_SUBST(lang_tree_files)
3908 AC_SUBST(local_prefix)
3909 AC_SUBST(md_file)
3910 AC_SUBST(objc_boehm_gc)
3911 AC_SUBST(out_file)
3912 AC_SUBST(out_object_file)
3913 AC_SUBST(thread_file)
3914 AC_SUBST(tm_file_list)
3915 AC_SUBST(tm_include_list)
3916 AC_SUBST(tm_defines)
3917 AC_SUBST(tm_p_file_list)
3918 AC_SUBST(tm_p_include_list)
3919 AC_SUBST(xm_file_list)
3920 AC_SUBST(xm_include_list)
3921 AC_SUBST(xm_defines)
3922 AC_SUBST(use_gcc_stdint)
3923 AC_SUBST(c_target_objs)
3924 AC_SUBST(cxx_target_objs)
3925 AC_SUBST(fortran_target_objs)
3926 AC_SUBST(target_cpu_default)
3927
3928 AC_SUBST_FILE(language_hooks)
3929
3930 # Echo link setup.
3931 if test x${build} = x${host} ; then
3932   if test x${host} = x${target} ; then
3933     echo "Links are now set up to build a native compiler for ${target}." 1>&2
3934   else
3935     echo "Links are now set up to build a cross-compiler" 1>&2
3936     echo " from ${host} to ${target}." 1>&2
3937   fi
3938 else
3939   if test x${host} = x${target} ; then
3940     echo "Links are now set up to build (on ${build}) a native compiler" 1>&2
3941     echo " for ${target}." 1>&2
3942   else
3943     echo "Links are now set up to build (on ${build}) a cross-compiler" 1>&2
3944     echo " from ${host} to ${target}." 1>&2
3945   fi
3946 fi
3947
3948 AC_ARG_VAR(GMPLIBS,[How to link GMP])
3949 AC_ARG_VAR(GMPINC,[How to find GMP include files])
3950
3951 AC_ARG_VAR(PPLLIBS,[How to link PPL])
3952 AC_ARG_VAR(PPLINC,[How to find PPL include files])
3953
3954 AC_ARG_VAR(CLOOGLIBS,[How to link CLOOG])
3955 AC_ARG_VAR(CLOOGINC,[How to find CLOOG include files])
3956 if test "x${CLOOGLIBS}" != "x" ; then
3957    AC_DEFINE(HAVE_cloog, 1, [Define if cloog is in use.])
3958 fi
3959
3960 # Check for plugin support
3961 AC_ARG_ENABLE(plugin,
3962 [  --enable-plugin         enable plugin support],
3963 enable_plugin=$enableval,
3964 enable_plugin=yes; default_plugin=yes)
3965
3966 pluginlibs=
3967 if test x"$enable_plugin" = x"yes"; then
3968   # Check that the host supports -rdynamic and -ldl
3969   have_rdynamic=no
3970   have_dl=no
3971   saved_LDFLAGS="$LDFLAGS"
3972   saved_LIBS="$LIBS"
3973   LIBS=
3974
3975   # Check -rdynamic
3976   LDFLAGS="$LDFLAGS -rdynamic"
3977   AC_MSG_CHECKING([for -rdynamic])
3978   AC_TRY_LINK([],[return 0;],
3979     [AC_MSG_RESULT([yes]); have_rdynamic=yes],
3980     [AC_MSG_RESULT([no])])
3981   if test x"$have_rdynamic" = x"yes" ; then
3982     pluginlibs="-rdynamic"
3983   fi
3984
3985   # Check -ldl
3986   LDFLAGS="$LDFLAGS -ldl"
3987   AC_MSG_CHECKING([for -ldl])
3988   AC_TRY_LINK(
3989     [#include <dlfcn.h>],
3990     [volatile int f = 0; if (f) dlopen ("dummy", 0);],
3991     [AC_MSG_RESULT([yes]); have_dl=yes],
3992     [AC_MSG_RESULT([no])])
3993   if test x"$have_dl" = x"yes"; then
3994     pluginlibs="$pluginlibs -ldl"
3995   fi
3996
3997   # Check that we can build shared objects with -fPIC -shared
3998   LDFLAGS="$LDFLAGS -fPIC -shared"
3999   AC_MSG_CHECKING([for -fPIC -shared])
4000   AC_TRY_LINK(
4001     [extern int X;],[return X == 0;],
4002     [AC_MSG_RESULT([yes]); have_pic_shared=yes],
4003     [AC_MSG_RESULT([no]); have_pic_shared=no])
4004   if test x"$have_pic_shared" != x"yes"; then
4005     pluginlibs=
4006     enable_plugin=no
4007   fi
4008
4009   # If plugin support had been requested but not available, fail.
4010   if test x"$enable_plugin" = x"no" ; then
4011     if test x"$default_plugin" != x"yes"; then
4012       AC_MSG_ERROR([
4013 Building GCC with plugin support requires a host that supports
4014 -fPIC, -shared, -ldl and -rdynamic.])
4015     fi
4016   fi
4017
4018   LDFLAGS="$saved_LDFLAGS"
4019   LIBS="$saved_LIBS"
4020 fi
4021
4022 AC_SUBST(pluginlibs)
4023 AC_SUBST(enable_plugin)
4024 if test x"$enable_plugin" = x"yes"; then
4025   AC_DEFINE(ENABLE_PLUGIN, 1, [Define to enable plugin support.])
4026 fi
4027
4028 # Configure the subdirectories
4029 # AC_CONFIG_SUBDIRS($subdirs)
4030
4031 # Create the Makefile
4032 # and configure language subdirectories
4033 AC_CONFIG_FILES($all_outputs)
4034
4035 AC_CONFIG_COMMANDS([default],
4036 [
4037 case ${CONFIG_HEADERS} in
4038   *auto-host.h:config.in*)
4039   echo > cstamp-h ;;
4040 esac
4041 # Make sure all the subdirs exist.
4042 for d in $subdirs doc build
4043 do
4044     test -d $d || mkdir $d
4045 done
4046 ],
4047 [subdirs='$subdirs'])
4048 AC_OUTPUT